qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0';
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0';
 351                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 352                         wp.colormod = '1 0.5 0'; // orange
 353                 else if (waypoint_has_hardwiredlinks(wp))
 354                         wp.colormod = '0.5 0 1'; // purple
 355                 else
 356                         wp.colormod = '1 1 1';
 357         }
 358         else
 359                 wp.model = "";
 360 }
 361
 362 entity waypoint_get(vector m1, vector m2)
 363 {
 364         if (m1 == m2)
 365         {
 366                 m1 -= '8 8 8';
 367                 m2 += '8 8 8';
 368         }
 369         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 370
 371         return NULL;
 372 }
 373
 374 .float createdtime;
 375 entity waypoint_spawn(vector m1, vector m2, float f)
 376 {
 377         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 378         {
 379                 entity wp_found = waypoint_get(m1, m2);
 380                 if (wp_found)
 381                         return wp_found;
 382         }
 383         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 384         // otherwise links loaded from file would be applied only to the first destination
 385         // waypoint since link format doesn't specify waypoint entities but just positions
 386         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 387         {
 388                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 389                 {
 390                         return it;
 391                 });
 392         }
 393
 394         entity w = new(waypoint);
 395         IL_PUSH(g_waypoints, w);
 396         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 397         w.wpflags = f;
 398         w.solid = SOLID_TRIGGER;
 399         w.createdtime = time;
 400         setorigin(w, (m1 + m2) * 0.5);
 401         setsize(w, m1 - w.origin, m2 - w.origin);
 402         if (w.size)
 403                 w.wpisbox = true;
 404
 405         if(!w.wpisbox)
 406         {
 407                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 408                 if(!move_out_of_solid(w))
 409                 {
 410                         if(!(f & WAYPOINTFLAG_GENERATED))
 411                         {
 412                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 413                                 delete(w);
 414                                 return NULL;
 415                         }
 416                         else
 417                         {
 418                                 if(autocvar_developer)
 419                                 {
 420                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 421                                         backtrace("Waypoint stuck");
 422                                 }
 423                         }
 424                 }
 425                 setsize(w, '0 0 0', '0 0 0');
 426         }
 427
 428         waypoint_clearlinks(w);
 429         //waypoint_schedulerelink(w);
 430
 431         waypoint_setupmodel(w);
 432
 433         return w;
 434 }
 435
 436 float trigger_push_get_push_time(entity this, vector endpos);
 437 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 438 {
 439         entity jp = NULL;
 440         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 441         {
 442                 jp = it;
 443                 break;
 444         });
 445         if (!jp)
 446                 return;
 447
 448         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 449         wp_from.wp00 = wp_to;
 450         wp_from.wp00mincost = cost;
 451         jp.nearestwaypoint = wp_from;
 452         jp.nearestwaypointtimeout = -1;
 453 }
 454
 455 bool start_wp_is_spawned;
 456 vector start_wp_origin;
 457 bool start_wp_is_hardwired;
 458
 459 void waypoint_clear_start_wp(entity pl, bool warn)
 460 {
 461         start_wp_is_spawned = false;
 462         start_wp_origin = '0 0 0';
 463         pl.wp_locked = NULL;
 464         start_wp_is_hardwired = false;
 465         if (warn)
 466                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 467 }
 468
 469 void waypoint_start_hardwiredlink(entity pl)
 470 {
 471         entity wp = pl.nearestwaypoint;
 472         if ((!start_wp_is_spawned || start_wp_is_hardwired) && wp && !(wp.wpflags & WAYPOINTFLAG_NORELINK))
 473         {
 474                 start_wp_is_hardwired = true;
 475                 start_wp_is_spawned = true;
 476                 start_wp_origin = wp.origin;
 477                 pl.wp_locked = wp;
 478                 LOG_INFOF("^x80fNearest waypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 479         }
 480         else
 481                 start_wp_is_hardwired = false;
 482 }
 483
 484 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp)
 485 {
 486         if (WAYPOINT_VERSION < waypoint_version_loaded)
 487         {
 488                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 489                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 490                 return;
 491         }
 492
 493         entity e = NULL, jp = NULL;
 494         vector org = pl.origin;
 495         if (at_crosshair)
 496         {
 497                 crosshair_trace(pl);
 498                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 499                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 500                 {
 501                         jp = it;
 502                         break;
 503                 });
 504         }
 505         if (jp || is_jump_wp)
 506         {
 507                 if (start_wp_is_spawned)
 508                         start_wp_is_spawned = false;
 509                 LOG_INFO("^xf80Spawning start waypoint...\n");
 510         }
 511         int ctf_flags = havocbot_symmetry_origin_order;
 512         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 513                    || (autocvar_g_waypointeditor_symmetrical < 0));
 514         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 515                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 516         if (sym && ctf_flags < 2)
 517                 ctf_flags = 2;
 518         int wp_num = ctf_flags;
 519
 520         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp)
 521         {
 522                 // snap waypoint to item's origin if close enough
 523                 IL_EACH(g_items, true,
 524                 {
 525                         vector item_org = (it.absmin + it.absmax) * 0.5;
 526                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 527                         if (vlen(item_org - org) < 20)
 528                         {
 529                                 org = item_org;
 530                                 break;
 531                         }
 532                 });
 533         }
 534
 535         vector start_org = '0 0 0';
 536         if (start_wp_is_spawned)
 537         {
 538                 if (!start_wp_is_hardwired)
 539                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 540                 start_org = start_wp_origin;
 541         }
 542
 543         // save org as it can be modified spawning symmetrycal waypoints
 544         vector initial_origin = '0 0 0';
 545         bool initial_origin_is_set = false;
 546
 547         LABEL(add_wp);
 548
 549         if (jp)
 550         {
 551                 e = NULL;
 552                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 553                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 554                 {
 555                         e = it; break;
 556                 });
 557                 if (!e)
 558                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 559                 if (!pl.wp_locked)
 560                         pl.wp_locked = e;
 561         }
 562         else if (is_jump_wp)
 563         {
 564                 entity wp_found = waypoint_get(org, org);
 565                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 566                 {
 567                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 568                         return;
 569                 }
 570                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 571                 if (!pl.wp_locked)
 572                         pl.wp_locked = e;
 573         }
 574         else
 575                 e = waypoint_spawn(org, org, 0);
 576         if(!e)
 577         {
 578                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 579                 if (start_wp_is_spawned)
 580                         waypoint_clear_start_wp(pl, true);
 581                 return;
 582         }
 583
 584         if (!initial_origin_is_set)
 585         {
 586                 initial_origin = e.origin;
 587                 initial_origin_is_set = true;
 588         }
 589
 590         entity start_wp = NULL;
 591         if (start_wp_is_spawned)
 592         {
 593                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WAYPOINTFLAG_NORELINK)
 594                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 595                 {
 596                         start_wp = it; break;
 597                 });
 598                 if(!start_wp)
 599                 {
 600                         // should not happen
 601                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 602                         waypoint_clear_start_wp(pl, true);
 603                         return;
 604                 }
 605                 if (start_wp_is_hardwired)
 606                 {
 607                         if (waypoint_is_hardwiredlink(start_wp, e))
 608                         {
 609                                 waypoint_unmark_hardwiredlink(start_wp, e);
 610                                 waypoint_removelink(start_wp, e);
 611                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 612                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 613                         }
 614                         else
 615                         {
 616                                 if (e.createdtime == time)
 617                                 {
 618                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 619                                         waypoint_remove(e);
 620                                         waypoint_clear_start_wp(pl, true);
 621                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp);
 622                                         return;
 623                                 }
 624                                 if (start_wp == e)
 625                                 {
 626                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 627                                         waypoint_clear_start_wp(pl, true);
 628                                         return;
 629                                 }
 630                                 if (waypoint_islinked(start_wp, e))
 631                                 {
 632                                         LOG_INFO("Error: waypoints are already linked.\n");
 633                                         waypoint_clear_start_wp(pl, true);
 634                                         return;
 635                                 }
 636                                 waypoint_addlink(start_wp, e);
 637                                 waypoint_mark_hardwiredlink(start_wp, e);
 638                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 639                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 640                         }
 641                 }
 642                 else
 643                         waypoint_addlink(start_wp, e);
 644         }
 645
 646         if (!(jp || is_jump_wp || start_wp_is_hardwired))
 647                 waypoint_schedulerelink(e);
 648         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 649
 650         if (start_wp_is_spawned)
 651         {
 652                 pl.wp_locked = NULL;
 653                 if (!start_wp_is_hardwired)
 654                         waypoint_schedulerelink(start_wp);
 655                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 656                 {
 657                         if (start_wp.wp00_original == start_wp.wp00)
 658                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 659                         else
 660                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 661                 }
 662         }
 663
 664         if (sym)
 665         {
 666                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 667                 if (jp)
 668                 {
 669                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 670                         {
 671                                 jp = it; break;
 672                         });
 673                 }
 674                 if (start_wp_is_spawned)
 675                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 676                 if (vdist(org - pl.origin, >, 32))
 677                 {
 678                         if(wp_num > 2)
 679                                 wp_num--;
 680                         else
 681                                 sym = false;
 682                         goto add_wp;
 683                 }
 684         }
 685         if (jp || is_jump_wp)
 686         {
 687                 if (!start_wp_is_spawned)
 688                 {
 689                         // we've just created a custom jumppad waypoint
 690                         // the next one created by the user will be the destination waypoint
 691                         start_wp_is_spawned = true;
 692                         start_wp_origin = initial_origin;
 693                 }
 694         }
 695         else if (start_wp_is_spawned)
 696         {
 697                 waypoint_clear_start_wp(pl, false);
 698         }
 699 }
 700
 701 void waypoint_remove(entity wp)
 702 {
 703         IL_EACH(g_waypoints, it != wp,
 704         {
 705                 if (waypoint_islinked(it, wp))
 706                 {
 707                         if (waypoint_is_hardwiredlink(it, wp))
 708                                 waypoint_unmark_hardwiredlink(it, wp);
 709                         waypoint_removelink(it, wp);
 710                 }
 711         });
 712         delete(wp);
 713 }
 714
 715 void waypoint_remove_fromeditor(entity pl)
 716 {
 717         if (WAYPOINT_VERSION < waypoint_version_loaded)
 718         {
 719                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 720                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 721                 return;
 722         }
 723
 724         entity e = navigation_findnearestwaypoint(pl, false);
 725
 726         int ctf_flags = havocbot_symmetry_origin_order;
 727         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 728                    || (autocvar_g_waypointeditor_symmetrical < 0));
 729         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 730                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 731         if (sym && ctf_flags < 2)
 732                 ctf_flags = 2;
 733         int wp_num = ctf_flags;
 734
 735         LABEL(remove_wp);
 736         if (!e) return;
 737
 738         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 739         {
 740                 if (start_wp_is_spawned)
 741                         waypoint_clear_start_wp(pl, true);
 742                 return;
 743         }
 744
 745         if (waypoint_has_hardwiredlinks(e))
 746         {
 747                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 748                 return;
 749         }
 750
 751         entity wp_sym = NULL;
 752         if (sym)
 753         {
 754                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 755                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 756                         if(vdist(org - it.origin, <, 3))
 757                         {
 758                                 wp_sym = it;
 759                                 break;
 760                         }
 761                 });
 762         }
 763
 764         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 765         waypoint_remove(e);
 766
 767         if (sym && wp_sym)
 768         {
 769                 e = wp_sym;
 770                 if(wp_num > 2)
 771                         wp_num--;
 772                 else
 773                         sym = false;
 774                 goto remove_wp;
 775         }
 776
 777         if (start_wp_is_spawned)
 778                 waypoint_clear_start_wp(pl, true);
 779 }
 780
 781 void waypoint_removelink(entity from, entity to)
 782 {
 783         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & WAYPOINTFLAG_JUMP)))
 784                 return;
 785
 786         entity fromwp31_prev = from.wp31;
 787
 788         switch (waypoint_getlinknum(from, to))
 789         {
 790                 // fallthrough all the way
 791                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 792                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 793                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 794                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 795                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 796                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 797                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 798                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 799                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 800                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 801                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 802                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 803                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 804                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 805                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 806                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 807                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 808                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 809                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 810                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 811                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 812                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 813                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 814                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 815                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 816                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 817                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 818                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 819                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 820                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 821                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 822                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 823         }
 824
 825         if (fromwp31_prev && !from.wp31)
 826                 waypoint_schedulerelink(from);
 827 }
 828
 829 int waypoint_getlinknum(entity from, entity to)
 830 {
 831         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 832         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 833         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 834         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 835         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 836         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 837         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 838         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 839         return -1;
 840 }
 841
 842 bool waypoint_islinked(entity from, entity to)
 843 {
 844         return (waypoint_getlinknum(from, to) >= 0);
 845 }
 846
 847 void waypoint_updatecost_foralllinks()
 848 {
 849         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 850         {
 851                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 852                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 853                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 854                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 855                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 856                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 857                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 858                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 859                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 860                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 861                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 862                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 863                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 864                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 865                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 866                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 867                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 868                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 869                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 870                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 871                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 872                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 873                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 874                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 875                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 876                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 877                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 878                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 879                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 880                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 881                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 882                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 883         });
 884 }
 885
 886 float waypoint_getlinearcost(float dist)
 887 {
 888         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 889                 return dist / (autocvar_sv_maxspeed * 1.25);
 890         return dist / autocvar_sv_maxspeed;
 891 }
 892 float waypoint_getlinearcost_underwater(float dist)
 893 {
 894         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 895         return dist / (autocvar_sv_maxspeed * 0.7);
 896 }
 897
 898 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 899 {
 900         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 901         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 902
 903         if (submerged_from && submerged_to)
 904                 return waypoint_getlinearcost_underwater(vlen(to - from));
 905
 906         float c = waypoint_getlinearcost(vlen(to - from));
 907
 908         float height = from.z - to.z;
 909         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 910         {
 911                 float height_cost;
 912                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 913                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 914                 else
 915                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 916                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 917                 if(height_cost > c)
 918                         c = height_cost;
 919         }
 920
 921         if (submerged_from || submerged_to)
 922                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 923         return c;
 924 }
 925
 926 float waypoint_getlinkcost(entity from, entity to)
 927 {
 928         vector v1 = from.origin;
 929         vector v2 = to.origin;
 930         if (from.wpisbox)
 931         {
 932                 vector m1 = from.absmin, m2 = from.absmax;
 933                 v1.x = bound(m1.x, v2.x, m2.x);
 934                 v1.y = bound(m1.y, v2.y, m2.y);
 935                 v1.z = bound(m1.z, v2.z, m2.z);
 936         }
 937         if (to.wpisbox)
 938         {
 939                 vector m1 = to.absmin, m2 = to.absmax;
 940                 v2.x = bound(m1.x, v1.x, m2.x);
 941                 v2.y = bound(m1.y, v1.y, m2.y);
 942                 v2.z = bound(m1.z, v1.z, m2.z);
 943         }
 944         return waypoint_gettravelcost(v1, v2, from, to);
 945 }
 946
 947 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 948 // if c == -1 automatically determine cost of the link
 949 void waypoint_addlink_customcost(entity from, entity to, float c)
 950 {
 951         if (from == to || waypoint_islinked(from, to))
 952                 return;
 953         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & WAYPOINTFLAG_JUMP))
 954                 return;
 955
 956         if(c == -1)
 957                 c = waypoint_getlinkcost(from, to);
 958
 959         if (from.wp31mincost < c) return;
 960         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 961         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 962         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 963         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 964         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 965         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 966         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 967         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 968         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 969         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 970         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 971         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 972         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 973         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 974         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 975         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 976         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 977         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 978         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 979         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 980         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 981         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 982         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 983         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 984         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 985         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 986         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 987         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 988         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 989         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 990         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 991         from.wp00 = to;from.wp00mincost = c;return;
 992 }
 993
 994 void waypoint_addlink(entity from, entity to)
 995 {
 996         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP)))
 997                 waypoint_addlink_for_custom_jumppad(from, to);
 998         else
 999                 waypoint_addlink_customcost(from, to, -1);
1000 }
1001
1002 // relink this spawnfunc_waypoint
1003 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1004 // (SLOW!)
1005 void waypoint_think(entity this)
1006 {
1007         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1008         float sv2_height = 0, ev2_height = 0;
1009
1010         bot_calculate_stepheightvec();
1011
1012         int dphitcontentsmask_save = this.dphitcontentsmask;
1013         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1014
1015         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1016
1017         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1018         IL_EACH(g_waypoints, this != it,
1019         {
1020                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1021                 {
1022                         waypoint_addlink(this, it);
1023                         waypoint_addlink(it, this);
1024                 }
1025                 else
1026                 {
1027                         ++relink_total;
1028                         if(!checkpvs(this.origin, it))
1029                         {
1030                                 ++relink_pvsculled;
1031                                 continue;
1032                         }
1033
1034                         sv = set_tracewalk_dest_2(this, it.origin);
1035                         sv2 = tracewalk_dest;
1036                         sv2_height = tracewalk_dest_height;
1037                         ev = set_tracewalk_dest_2(it, this.origin);
1038                         ev2 = tracewalk_dest;
1039                         ev2_height = tracewalk_dest_height;
1040
1041                         dv = ev - sv;
1042                         dv.z = 0;
1043                         if(vdist(dv, >=, 1050)) // max search distance in XY
1044                         {
1045                                 ++relink_lengthculled;
1046                                 continue;
1047                         }
1048
1049                         navigation_testtracewalk = 0;
1050
1051                         //traceline(this.origin, it.origin, false, NULL);
1052                         //if (trace_fraction == 1)
1053                         if (this.wpisbox || this.wpflags & WAYPOINTFLAG_JUMP)
1054                                 relink_walkculled += 0.5;
1055                         else
1056                         {
1057                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
1058                                         waypoint_addlink(this, it);
1059                                 else
1060                                         relink_walkculled += 0.5;
1061                         }
1062
1063                         if (it.wpisbox || it.wpflags & WAYPOINTFLAG_JUMP)
1064                                 relink_walkculled += 0.5;
1065                         else
1066                         {
1067                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
1068                                         waypoint_addlink(it, this);
1069                                 else
1070                                         relink_walkculled += 0.5;
1071                         }
1072                 }
1073         });
1074         navigation_testtracewalk = 0;
1075         this.wplinked = true;
1076         this.dphitcontentsmask = dphitcontentsmask_save;
1077
1078         setthink(this, func_null);
1079         this.nextthink = 0;
1080 }
1081
1082 void waypoint_clearlinks(entity wp)
1083 {
1084         // clear links to other waypoints
1085         float f = 10000000;
1086         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1087         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1088         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1089         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1090
1091         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1092         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1093         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1094         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1095
1096         wp.wplinked = false;
1097 }
1098
1099 // tell a spawnfunc_waypoint to relink
1100 void waypoint_schedulerelink(entity wp)
1101 {
1102         if (wp == NULL)
1103                 return;
1104
1105         waypoint_setupmodel(wp);
1106         wp.wpisbox = vdist(wp.size, >, 0);
1107         wp.enemy = NULL;
1108         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1109                 wp.owner = NULL;
1110         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1111                 waypoint_clearlinks(wp);
1112         // schedule an actual relink on next frame
1113         setthink(wp, waypoint_think);
1114         wp.nextthink = time;
1115         wp.effects = EF_LOWPRECISION;
1116 }
1117
1118 // spawnfunc_waypoint map entity
1119 spawnfunc(waypoint)
1120 {
1121         IL_PUSH(g_waypoints, this);
1122
1123         setorigin(this, this.origin);
1124         // schedule a relink after other waypoints have had a chance to spawn
1125         waypoint_clearlinks(this);
1126         //waypoint_schedulerelink(this);
1127 }
1128
1129 // tell all waypoints to relink
1130 // actually this is useful only to update relink_* stats
1131 void waypoint_schedulerelinkall()
1132 {
1133         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1134         IL_EACH(g_waypoints, true,
1135         {
1136                 waypoint_schedulerelink(it);
1137         });
1138         waypoint_load_hardwiredlinks();
1139 }
1140
1141 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1142
1143 // Load waypoint links from file
1144 bool waypoint_load_links()
1145 {
1146         string s;
1147         float file, tokens, c = 0, found;
1148         entity wp_from = NULL, wp_to;
1149         vector wp_to_pos, wp_from_pos;
1150
1151         string gt_ext = GET_GAMETYPE_EXTENSION();
1152
1153         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1154         file = fopen(filename, FILE_READ);
1155
1156         if (gt_ext != "" && file < 0)
1157         {
1158                 // if race waypoint file doesn't exist load the default one
1159                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1160                 file = fopen(filename, FILE_READ);
1161         }
1162
1163         if (file < 0)
1164         {
1165                 LOG_TRACE("waypoint links load from ", filename, " failed");
1166                 waypoint_schedulerelinkall();
1167                 return false;
1168         }
1169
1170         bool parse_comments = true;
1171         float ver = 0;
1172         string links_time = string_null;
1173
1174         while ((s = fgets(file)))
1175         {
1176                 if(parse_comments)
1177                 {
1178                         if(substring(s, 0, 2) == "//")
1179                         {
1180                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1181                                         ver = stof(substring(s, 19, -1));
1182                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1183                                         links_time = substring(s, 16, -1);
1184                                 continue;
1185                         }
1186                         else
1187                         {
1188                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1189                                 {
1190                                         if (links_time != waypoint_time)
1191                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1192                                         else
1193                                                 LOG_TRACE("waypoint links for this map are outdated.");
1194                                         if (g_assault)
1195                                         {
1196                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1197                                         }
1198                                         else
1199                                         {
1200                                                 LOG_TRACE("automatically updating...");
1201                                                 waypoint_schedulerelinkall();
1202                                                 fclose(file);
1203                                                 return false;
1204                                         }
1205                                 }
1206                                 parse_comments = false;
1207                         }
1208                 }
1209
1210                 tokens = tokenizebyseparator(s, "*");
1211
1212                 if (tokens!=2)
1213                 {
1214                         // bad file format
1215                         fclose(file);
1216                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1217                         return false;
1218                 }
1219
1220                 wp_from_pos     = stov(argv(0));
1221                 wp_to_pos       = stov(argv(1));
1222
1223                 // Search "from" waypoint
1224                 if(!wp_from || wp_from.origin!=wp_from_pos)
1225                 {
1226                         wp_from = findradius(wp_from_pos, 1);
1227                         found = false;
1228                         while(wp_from)
1229                         {
1230                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1231                                 if(wp_from.classname == "waypoint")
1232                                 {
1233                                         found = true;
1234                                         break;
1235                                 }
1236                                 wp_from = wp_from.chain;
1237                         }
1238
1239                         if(!found)
1240                         {
1241                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1242                                 continue;
1243                         }
1244                 }
1245
1246                 // Search "to" waypoint
1247                 wp_to = findradius(wp_to_pos, 1);
1248                 found = false;
1249                 while(wp_to)
1250                 {
1251                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1252                         if(wp_to.classname == "waypoint")
1253                         {
1254                                 found = true;
1255                                 break;
1256                         }
1257                         wp_to = wp_to.chain;
1258                 }
1259
1260                 if(!found)
1261                 {
1262                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1263                         continue;
1264                 }
1265
1266                 ++c;
1267                 waypoint_addlink(wp_from, wp_to);
1268                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1269                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1270         }
1271
1272         fclose(file);
1273
1274         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1275
1276         bool scheduled = false;
1277         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1278         {
1279                 if (!it.wp00)
1280                 {
1281                         waypoint_schedulerelink(it);
1282                         scheduled = true;
1283                 }
1284         });
1285         if (scheduled)
1286                 return false;
1287
1288         botframe_cachedwaypointlinks = true;
1289         return true;
1290 }
1291
1292
1293 void waypoint_remove_hardwiredlinks()
1294 {
1295         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1296         {
1297                 if (it.wphw00) { waypoint_removelink(it, it.wphw00); it.wphw00 = NULL; }
1298                 if (it.wphw01) { waypoint_removelink(it, it.wphw01); it.wphw01 = NULL; }
1299                 if (it.wphw02) { waypoint_removelink(it, it.wphw02); it.wphw02 = NULL; }
1300                 if (it.wphw03) { waypoint_removelink(it, it.wphw03); it.wphw03 = NULL; }
1301                 if (it.wphw04) { waypoint_removelink(it, it.wphw04); it.wphw04 = NULL; }
1302                 if (it.wphw05) { waypoint_removelink(it, it.wphw05); it.wphw05 = NULL; }
1303                 if (it.wphw06) { waypoint_removelink(it, it.wphw06); it.wphw06 = NULL; }
1304                 if (it.wphw07) { waypoint_removelink(it, it.wphw07); it.wphw07 = NULL; }
1305                 waypoint_setupmodel(it);
1306         });
1307 }
1308
1309 void waypoint_load_hardwiredlinks()
1310 {
1311         string s;
1312         float file, tokens, c = 0, found;
1313         entity wp_from = NULL, wp_to;
1314         vector wp_to_pos, wp_from_pos;
1315
1316         string gt_ext = GET_GAMETYPE_EXTENSION();
1317
1318         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1319         file = fopen(filename, FILE_READ);
1320
1321         if (gt_ext != "" && file < 0)
1322         {
1323                 // if race waypoint file doesn't exist load the default one
1324                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1325                 file = fopen(filename, FILE_READ);
1326         }
1327
1328         botframe_loadedforcedlinks = true;
1329
1330         if (file < 0)
1331         {
1332                 LOG_TRACE("waypoint links load from ", filename, " failed");
1333                 return;
1334         }
1335
1336         bool is_special = false;
1337         while ((s = fgets(file)))
1338         {
1339                 if(substring(s, 0, 2)=="//")
1340                         continue;
1341
1342                 if(substring(s, 0, 1)=="#")
1343                         continue;
1344
1345                 // special links start with *, so old xonotic versions don't load them
1346                 is_special = false;
1347                 if (substring(s, 0, 1) == "*")
1348                 {
1349                         is_special = true;
1350                         s = substring(s, 1, -1);
1351                 }
1352
1353                 tokens = tokenizebyseparator(s, "*");
1354
1355                 if (tokens!=2)
1356                         continue;
1357
1358                 wp_from_pos     = stov(argv(0));
1359                 wp_to_pos       = stov(argv(1));
1360
1361                 // Search "from" waypoint
1362                 if(!wp_from || wp_from.origin!=wp_from_pos)
1363                 {
1364                         wp_from = findradius(wp_from_pos, 5);
1365                         found = false;
1366                         while(wp_from)
1367                         {
1368                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1369                                 if(wp_from.classname == "waypoint")
1370                                 {
1371                                         found = true;
1372                                         break;
1373                                 }
1374                                 wp_from = wp_from.chain;
1375                         }
1376
1377                         if(!found)
1378                         {
1379                                 LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1380                                 continue;
1381                         }
1382                 }
1383
1384                 // Search "to" waypoint
1385                 wp_to = findradius(wp_to_pos, 5);
1386                 found = false;
1387                 while(wp_to)
1388                 {
1389                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1390                         if(wp_to.classname == "waypoint")
1391                         {
1392                                 found = true;
1393                                 break;
1394                         }
1395                         wp_to = wp_to.chain;
1396                 }
1397
1398                 if(!found)
1399                 {
1400                         LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1401                         continue;
1402                 }
1403
1404                 ++c;
1405
1406                 if (!is_special)
1407                 {
1408                         waypoint_addlink(wp_from, wp_to);
1409                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1410                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1411                         && (wp_from.wpflags & WAYPOINTFLAG_JUMP || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1412                 {
1413                         waypoint_addlink(wp_from, wp_to);
1414                 }
1415         }
1416
1417         fclose(file);
1418
1419         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1420 }
1421
1422 entity waypoint_get_link(entity w, float i)
1423 {
1424         switch(i)
1425         {
1426                 case  0:return w.wp00;
1427                 case  1:return w.wp01;
1428                 case  2:return w.wp02;
1429                 case  3:return w.wp03;
1430                 case  4:return w.wp04;
1431                 case  5:return w.wp05;
1432                 case  6:return w.wp06;
1433                 case  7:return w.wp07;
1434                 case  8:return w.wp08;
1435                 case  9:return w.wp09;
1436                 case 10:return w.wp10;
1437                 case 11:return w.wp11;
1438                 case 12:return w.wp12;
1439                 case 13:return w.wp13;
1440                 case 14:return w.wp14;
1441                 case 15:return w.wp15;
1442                 case 16:return w.wp16;
1443                 case 17:return w.wp17;
1444                 case 18:return w.wp18;
1445                 case 19:return w.wp19;
1446                 case 20:return w.wp20;
1447                 case 21:return w.wp21;
1448                 case 22:return w.wp22;
1449                 case 23:return w.wp23;
1450                 case 24:return w.wp24;
1451                 case 25:return w.wp25;
1452                 case 26:return w.wp26;
1453                 case 27:return w.wp27;
1454                 case 28:return w.wp28;
1455                 case 29:return w.wp29;
1456                 case 30:return w.wp30;
1457                 case 31:return w.wp31;
1458                 default:return NULL;
1459         }
1460 }
1461
1462 // Save all hardwired waypoint links to a file
1463 void waypoint_save_hardwiredlinks()
1464 {
1465         string gt_ext = GET_GAMETYPE_EXTENSION();
1466
1467         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1468         int file = fopen(filename, FILE_WRITE);
1469         if (file < 0)
1470         {
1471                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1472                 return;
1473         }
1474
1475         // write hardwired links to file
1476         fputs(file, "// HARDWIRED LINKS\n");
1477         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1478         {
1479                 for (int j = 0; j < 32; ++j)
1480                 {
1481                         entity link = waypoint_get_link(it, j);
1482                         if (waypoint_is_hardwiredlink(it, link))
1483                         {
1484                                 // NOTE: vtos rounds vector components to 1 decimal place
1485                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1486                                 fputs(file, s);
1487                         }
1488                 }
1489         });
1490
1491         // write special links to file
1492         fputs(file, "\n// SPECIAL LINKS\n");
1493         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP),
1494         {
1495                 for (int j = 0; j < 32; ++j)
1496                 {
1497                         entity link = waypoint_get_link(it, j);
1498                         if (link)
1499                         {
1500                                 // NOTE: vtos rounds vector components to 1 decimal place
1501                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1502                                 fputs(file, s);
1503                         }
1504                 }
1505         });
1506
1507         fclose(file);
1508
1509         LOG_INFOF("saved hardwired waypoint links to %s", filename);
1510 }
1511
1512 // Save all waypoint links to a file
1513 void waypoint_save_links()
1514 {
1515         string gt_ext = GET_GAMETYPE_EXTENSION();
1516
1517         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1518         int file = fopen(filename, FILE_WRITE);
1519         if (file < 0)
1520         {
1521                 LOG_INFOF("waypoint link save to %s failed", filename);
1522                 return;
1523         }
1524
1525         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1526         if (waypoint_time != "")
1527                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1528
1529         int c = 0;
1530         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP)),
1531         {
1532                 for(int j = 0; j < 32; ++j)
1533                 {
1534                         entity link = waypoint_get_link(it, j);
1535                         if (link && !waypoint_is_hardwiredlink(it, link))
1536                         {
1537                                 // NOTE: vtos rounds vector components to 1 decimal place
1538                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1539                                 fputs(file, s);
1540                                 ++c;
1541                         }
1542                 }
1543         });
1544         fclose(file);
1545
1546         botframe_cachedwaypointlinks = true;
1547
1548         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1549 }
1550
1551 // save waypoints to gamedir/data/maps/mapname.waypoints
1552 void waypoint_saveall()
1553 {
1554         if (WAYPOINT_VERSION < waypoint_version_loaded)
1555         {
1556                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1557                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1558                 return;
1559         }
1560         string gt_ext = GET_GAMETYPE_EXTENSION();
1561
1562         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1563         int file = fopen(filename, FILE_WRITE);
1564         if (file < 0)
1565         {
1566                 waypoint_save_links(); // save anyway?
1567                 botframe_loadedforcedlinks = false;
1568
1569                 LOG_INFOF("waypoint links: save to %s failed", filename);
1570                 return;
1571         }
1572
1573         float sym = autocvar_g_waypointeditor_symmetrical;
1574         string sym_str = ftos(sym);
1575         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1576         {
1577                 if (sym == 1)
1578                 {
1579                         sym_str = cons(sym_str, "-");
1580                         sym_str = cons(sym_str, "-");
1581                 }
1582                 else
1583                 {
1584                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1585                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1586                 }
1587                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1588                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1589         }
1590         else if (autocvar_g_waypointeditor_symmetrical == -2)
1591         {
1592                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1593                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1594         }
1595
1596         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1597         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1598         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1599         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1600
1601         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1602         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1603         //fputs(file, strcat("//", "\n"));
1604         //fputs(file, strcat("//", "\n"));
1605         //fputs(file, strcat("//", "\n"));
1606
1607         int c = 0;
1608         IL_EACH(g_waypoints, true,
1609         {
1610                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1611                         continue;
1612
1613                 string s;
1614                 // NOTE: vtos rounds vector components to 1 decimal place
1615                 s = strcat(vtos(it.origin + it.mins), "\n");
1616                 s = strcat(s, vtos(it.origin + it.maxs));
1617                 s = strcat(s, "\n");
1618                 s = strcat(s, ftos(it.wpflags));
1619                 s = strcat(s, "\n");
1620                 fputs(file, s);
1621                 c++;
1622         });
1623         fclose(file);
1624         waypoint_save_links();
1625         waypoint_save_hardwiredlinks();
1626
1627         botframe_loadedforcedlinks = false;
1628
1629         waypoint_version_loaded = WAYPOINT_VERSION;
1630         LOG_INFOF("saved %d waypoints to %s", c, filename);
1631 }
1632
1633 // load waypoints from file
1634 float waypoint_loadall()
1635 {
1636         string s;
1637         float file, cwp, cwb, fl;
1638         vector m1, m2;
1639         cwp = 0;
1640         cwb = 0;
1641
1642         string gt_ext = GET_GAMETYPE_EXTENSION();
1643
1644         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1645         file = fopen(filename, FILE_READ);
1646
1647         if (gt_ext != "" && file < 0)
1648         {
1649                 // if race waypoint file doesn't exist load the default one
1650                 filename = sprintf("maps/%s.waypoints", mapname);
1651                 file = fopen(filename, FILE_READ);
1652         }
1653
1654         if (file < 0)
1655         {
1656                 LOG_TRACE("waypoint load from ", filename, " failed");
1657                 return 0;
1658         }
1659
1660         bool parse_comments = true;
1661         float ver = 0;
1662         float sym = 0;
1663         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1664
1665         while ((s = fgets(file)))
1666         {
1667                 if(parse_comments)
1668                 {
1669                         if(substring(s, 0, 2) == "//")
1670                         {
1671                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1672                                         ver = stof(substring(s, 19, -1));
1673                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1674                                 {
1675                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1676                                         if (tokens) { sym = stof(argv(0)); }
1677                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1678                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1679                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1680                                 }
1681                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1682                                         strcpy(waypoint_time, substring(s, 16, -1));
1683                                 continue;
1684                         }
1685                         else
1686                         {
1687                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1688                                 {
1689                                         LOG_TRACE("waypoints for this map are outdated");
1690                                         LOG_TRACE("please update them in the editor");
1691                                 }
1692                                 parse_comments = false;
1693                         }
1694                 }
1695                 m1 = stov(s);
1696                 s = fgets(file);
1697                 if (!s)
1698                         break;
1699                 m2 = stov(s);
1700                 s = fgets(file);
1701                 if (!s)
1702                         break;
1703                 fl = stof(s);
1704                 waypoint_spawn(m1, m2, fl);
1705                 if (m1 == m2)
1706                         cwp = cwp + 1;
1707                 else
1708                         cwb = cwb + 1;
1709         }
1710         fclose(file);
1711         waypoint_version_loaded = ver;
1712         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1713
1714         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1715         {
1716                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1717                 if (sym == 1 && sym_param3 < 2)
1718                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1719                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1720                 {
1721                         string params;
1722                         if (sym == 1)
1723                                 params = cons("-", "-");
1724                         else
1725                         {
1726                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1727                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1728                         }
1729                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1730                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1731                 }
1732                 else if (sym == -2)
1733                 {
1734                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1735                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1736                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1737                 }
1738                 else
1739                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1740                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1741         }
1742
1743         if (WAYPOINT_VERSION < waypoint_version_loaded)
1744                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1745                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1746
1747         return cwp + cwb;
1748 }
1749
1750 #define waypoint_fixorigin(position, tracetest_ent) \
1751         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1752
1753 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1754 {
1755         vector endpos = position + down_dir * 3000;
1756         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1757         if(trace_startsolid)
1758                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1759         if(trace_startsolid)
1760                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1761         if(trace_fraction < 1)
1762                 position = trace_endpos;
1763         return position;
1764 }
1765
1766 void waypoint_spawnforitem_force(entity e, vector org)
1767 {
1768         // Fix the waypoint altitude if necessary
1769         org = waypoint_fixorigin(org, NULL);
1770
1771         // don't spawn an item spawnfunc_waypoint if it already exists
1772         IL_EACH(g_waypoints, true,
1773         {
1774                 if(it.wpisbox)
1775                 {
1776                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1777                         {
1778                                 e.nearestwaypoint = it;
1779                                 return;
1780                         }
1781                 }
1782                 else
1783                 {
1784                         if(vdist(it.origin - org, <, 16))
1785                         {
1786                                 e.nearestwaypoint = it;
1787                                 return;
1788                         }
1789                 }
1790         });
1791
1792         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1793 }
1794
1795 void waypoint_spawnforitem(entity e)
1796 {
1797         if(!bot_waypoints_for_items)
1798                 return;
1799
1800         waypoint_spawnforitem_force(e, e.origin);
1801 }
1802
1803 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1804 {
1805         entity w;
1806         entity dw;
1807         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1808         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1809         // one way link to the destination
1810         w.wp00_original = dw;
1811         w.wp00 = dw;
1812         w.wp00mincost = timetaken; // this is just for jump pads
1813         // the teleporter's nearest spawnfunc_waypoint is this one
1814         // (teleporters are not goals, so this is probably useless)
1815         e.nearestwaypoint = w;
1816         e.nearestwaypointtimeout = -1;
1817 }
1818
1819 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1820 {
1821         float src_angle = e.warpzone_angles.x;
1822         while (src_angle < -180) src_angle += 360;
1823         while (src_angle > 180) src_angle -= 360;
1824
1825         float dest_angle = e.enemy.warpzone_angles.x;
1826         while (dest_angle < -180) dest_angle += 360;
1827         while (dest_angle > 180) dest_angle -= 360;
1828
1829         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1830         if (src_angle == -90 || dest_angle == -90)
1831                 return;
1832
1833         makevectors(e.warpzone_angles);
1834         vector src = (e.absmin + e.absmax) * 0.5;
1835         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1836         vector down_dir_src = -v_up;
1837
1838         makevectors(e.enemy.warpzone_angles);
1839         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1840         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1841         vector down_dir_dest = -v_up;
1842
1843         int extra_flag = 0;
1844         // don't snap to the ground waypoints for source warpzones pointing downwards
1845         if (src_angle != 90)
1846         {
1847                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1848                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1849                 // oblique warpzones need a jump otherwise bots gets stuck
1850                 if (src_angle != 0)
1851                         extra_flag = WAYPOINTFLAG_JUMP;
1852         }
1853
1854         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1855 }
1856
1857 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1858 {
1859         destination = waypoint_fixorigin(destination, tracetest_ent);
1860         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1861 }
1862
1863 entity waypoint_spawnpersonal(entity this, vector position)
1864 {
1865         entity w;
1866
1867         // drop the waypoint to a proper location:
1868         //   first move it up by a player height
1869         //   then move it down to hit the floor with player bbox size
1870         position = waypoint_fixorigin(position, this);
1871
1872         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1873         w.nearestwaypoint = NULL;
1874         w.nearestwaypointtimeout = 0;
1875         w.owner = this;
1876
1877         waypoint_schedulerelink(w);
1878
1879         return w;
1880 }
1881
1882 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1883 {
1884         if (!(wp1 && wp2))
1885                 return;
1886
1887         if (waypoint_is_hardwiredlink(wp1, wp2))
1888                 te_beam(NULL, wp1.origin, wp2.origin);
1889         else if (display_type == 1)
1890                 te_lightning2(NULL, wp1.origin, wp2.origin);
1891 }
1892
1893 void waypoint_showlinks_to(entity wp, int display_type)
1894 {
1895         IL_EACH(g_waypoints, it != wp,
1896         {
1897                 if (waypoint_islinked(it, wp))
1898                         waypoint_showlink(it, wp, display_type);
1899         });
1900 }
1901
1902 void waypoint_showlinks_from(entity wp, int display_type)
1903 {
1904         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1905         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1906         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1907         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
1908         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
1909         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
1910         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
1911         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
1912         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
1913         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
1914         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
1915         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
1916         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
1917         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
1918         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
1919         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
1920 }
1921
1922 void crosshair_trace_waypoints(entity pl)
1923 {
1924         IL_EACH(g_waypoints, true, {
1925                 it.solid = SOLID_BSP;
1926                 if (!it.wpisbox)
1927                         setsize(it, '-16 -16 -16', '16 16 16');
1928         });
1929
1930         crosshair_trace(pl);
1931
1932         IL_EACH(g_waypoints, true, {
1933                 it.solid = SOLID_TRIGGER;
1934                 if (!it.wpisbox)
1935                         setsize(it, '0 0 0', '0 0 0');
1936         });
1937         if (trace_ent.classname != "waypoint")
1938                 trace_ent = NULL;
1939 }
1940
1941 void botframe_showwaypointlinks()
1942 {
1943         if (time < botframe_waypointeditorlightningtime)
1944                 return;
1945         botframe_waypointeditorlightningtime = time + 0.5;
1946         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1947         {
1948                 int display_type = 0;
1949                 if (wasfreed(it.wp_aimed))
1950                         it.wp_aimed = NULL;
1951                 if (wasfreed(it.wp_locked))
1952                         it.wp_locked = NULL;
1953                 if (PHYS_INPUT_BUTTON_USE(it))
1954                         it.wp_locked = it.wp_aimed;
1955                 entity head = it.wp_locked;
1956                 if (!head)
1957                         head = navigation_findnearestwaypoint(it, false);
1958                 it.nearestwaypoint = head; // mainly useful for debug
1959                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1960                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1961                         display_type = 1; // default
1962                 else if(waypoint_has_hardwiredlinks(head))
1963                         display_type = 2; // only hardwired
1964
1965                 if (display_type)
1966                 {
1967                         //navigation_testtracewalk = true;
1968                         //print("currently selected WP is ", etos(head), "\n");
1969                         //navigation_testtracewalk = false;
1970                         if (head)
1971                         {
1972                                 te_lightning2(NULL, head.origin, it.origin);
1973                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1974                                         waypoint_showlinks_to(head, display_type);
1975                                 else
1976                                         waypoint_showlinks_from(head, display_type);
1977                         }
1978                 }
1979                 string str;
1980                 entity wp = NULL;
1981                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1982                 {
1983                         crosshair_trace_waypoints(it);
1984                         if (trace_ent)
1985                         {
1986                                 wp = trace_ent;
1987                                 if (wp != it.wp_aimed)
1988                                 {
1989                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: %s\n", etof(wp), wp.wpflags, vtos(wp.origin));
1990                                         if (wp.wpisbox)
1991                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1992                                         stuffcmd(it, str);
1993                                         str = sprintf("entity: %d\nflags: %d\norigin: %s", etof(wp), wp.wpflags, vtos(wp.origin));
1994                                         if (wp.wpisbox)
1995                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
1996                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1997                                 }
1998                         }
1999                 }
2000                 if (it.wp_aimed != wp)
2001                         it.wp_aimed = wp;
2002         });
2003 }
2004
2005 float botframe_autowaypoints_fixdown(vector v)
2006 {
2007         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2008         if(trace_fraction >= 1)
2009                 return 0;
2010         return 1;
2011 }
2012
2013 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2014 {
2015         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2016         {
2017                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2018                 return 0;
2019         });
2020
2021         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2022         return 1;
2023 }
2024
2025 // return value:
2026 //    1 = WP created
2027 //    0 = no action needed
2028 //   -1 = temp fail, try from world too
2029 //   -2 = permanent fail, do not retry
2030 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2031 {
2032         // make it possible to go from p to wp, if we can
2033         // if wp is NULL, nearest is chosen
2034
2035         entity w;
2036         vector porg;
2037         float t, tmin, tmax;
2038         vector o;
2039         vector save;
2040
2041         if(!botframe_autowaypoints_fixdown(p.origin))
2042                 return -2;
2043         porg = trace_endpos;
2044
2045         if(wp)
2046         {
2047                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2048
2049                 // if wp -> porg, then OK
2050                 float maxdist;
2051                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2052                 {
2053                         // we may find a better one
2054                         maxdist = vlen(wp.origin - porg);
2055                 }
2056                 else
2057                 {
2058                         // accept any "good"
2059                         maxdist = 2100;
2060                 }
2061
2062                 float bestdist = maxdist;
2063                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2064                 {
2065                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2066                         if(d < bestdist)
2067                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2068                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2069                         {
2070                                 bestdist = d;
2071                                 p.(fld) = it;
2072                         }
2073                 });
2074                 if(bestdist < maxdist)
2075                 {
2076                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2077                         return 0;
2078                 }
2079
2080                 if(bestdist < 2100)
2081                 {
2082                         // we know maxdist < 2100
2083                         // so wp -> porg is still valid
2084                         // all is good
2085                         p.(fld) = wp;
2086                         return 0;
2087                 }
2088
2089                 // otherwise, no existing WP can fix our issues
2090         }
2091         else
2092         {
2093                 save = p.origin;
2094                 setorigin(p, porg);
2095                 w = navigation_findnearestwaypoint(p, walkfromwp);
2096                 setorigin(p, save);
2097                 if(w)
2098                 {
2099                         p.(fld) = w;
2100                         return 0;
2101                 }
2102         }
2103
2104         tmin = 0;
2105         tmax = 1;
2106         for (;;)
2107         {
2108                 if(tmax - tmin < 0.001)
2109                 {
2110                         // did not get a good candidate
2111                         return -1;
2112                 }
2113
2114                 t = (tmin + tmax) * 0.5;
2115                 o = antilag_takebackorigin(p, CS(p), time - t);
2116                 if(!botframe_autowaypoints_fixdown(o))
2117                         return -2;
2118                 o = trace_endpos;
2119
2120                 if(wp)
2121                 {
2122                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2123                         {
2124                                 // we cannot walk from wp.origin to o
2125                                 // get closer to tmax
2126                                 tmin = t;
2127                                 continue;
2128                         }
2129                 }
2130                 else
2131                 {
2132                         save = p.origin;
2133                         setorigin(p, o);
2134                         w = navigation_findnearestwaypoint(p, walkfromwp);
2135                         setorigin(p, save);
2136                         if(!w)
2137                         {
2138                                 // we cannot walk from any WP to o
2139                                 // get closer to tmax
2140                                 tmin = t;
2141                                 continue;
2142                         }
2143                 }
2144
2145                 // if we get here, o is valid regarding waypoints
2146                 // check if o is connected right to the player
2147                 // we break if it succeeds, as that means o is a good waypoint location
2148                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2149                         break;
2150
2151                 // o is no good, we need to get closer to the player
2152                 tmax = t;
2153         }
2154
2155         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2156         botframe_autowaypoints_createwp(o, p, fld, 0);
2157         return 1;
2158 }
2159
2160 // automatically create missing waypoints
2161 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2162 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2163 {
2164         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2165         if(r != -1)
2166                 return;
2167         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2168         if(r != -1)
2169                 return;
2170
2171         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2172         if(!botframe_autowaypoints_fixdown(p.origin))
2173                 return; // shouldn't happen, caught above
2174         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2175 }
2176
2177 void botframe_deleteuselesswaypoints()
2178 {
2179         IL_EACH(g_items, it.bot_pickup,
2180         {
2181                 // NOTE: this protects waypoints if they're the ONLY nearest
2182                 // waypoint. That's the intention.
2183                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2184                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2185         });
2186         IL_EACH(g_waypoints, true,
2187         {
2188                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2189                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2190                 // WP is useful if:
2191                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2192                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2193                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2194                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2195                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2196                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2197                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2198                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2199                 // b) WP is closest WP for an item/spawnpoint/other entity
2200                 //    This has been done above by protecting these WPs.
2201         });
2202         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2203         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2204         {
2205                 for (int m = 0; m < 32; ++m)
2206                 {
2207                         entity w = waypoint_get_link(it, m);
2208                         if (!w)
2209                                 break;
2210                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2211                                 continue;
2212                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2213                                 continue;
2214                         for (int j = 0; j < 32; ++j)
2215                         {
2216                                 entity w2 = waypoint_get_link(w, j);
2217                                 if (!w2)
2218                                         break;
2219                                 if (it == w2)
2220                                         continue;
2221                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2222                                         continue;
2223                                 // If we got here, it != w2 exist with it -> w
2224                                 // and w -> w2. That means the waypoint is not
2225                                 // a dead end.
2226                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2227                                 for (int k = 0; k < 32; ++k)
2228                                 {
2229                                         if (waypoint_get_link(it, k) == w2)
2230                                                 continue;
2231                                         // IF WE GET HERE, w is proven useful
2232                                         // to get from it to w2!
2233                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2234                                         goto next;
2235                                 }
2236                         }
2237 LABEL(next)
2238                 }
2239         });
2240         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2241         //     they are needed to complete routes while autowaypointing.
2242
2243         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2244         {
2245                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2246                 te_explosion(it.origin);
2247                 waypoint_remove(it);
2248                 break;
2249         });
2250
2251         IL_EACH(g_waypoints, true,
2252         {
2253                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2254         });
2255 }
2256
2257 void botframe_autowaypoints()
2258 {
2259         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2260                 // going back is broken, so only fix waypoints to walk TO the player
2261                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2262                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2263                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2264         });
2265
2266         if (autocvar_g_waypointeditor_auto >= 2) {
2267                 botframe_deleteuselesswaypoints();
2268         }
2269 }
2270