qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0'; // red
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0'; // yellow
 351                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 352                         wp.colormod = '0 1 0'; // green
 353                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP)
 354                         wp.colormod = '1 0.5 0'; // orange
 355                 else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 356                         wp.colormod = '1 0.5 0'; // orange
 357                 else if (wp.wpflags & WAYPOINTFLAG_LADDER)
 358                         wp.colormod = '1 0.5 0'; // orange
 359                 else if (wp.wpflags & WAYPOINTFLAG_JUMP)
 360                         wp.colormod = '1 0.5 0'; // orange
 361                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 362                         wp.colormod = '0 1 1'; // cyan
 363                 else if (waypoint_has_hardwiredlinks(wp))
 364                         wp.colormod = '0.5 0 1'; // purple
 365                 else
 366                         wp.colormod = '1 1 1';
 367         }
 368         else
 369                 wp.model = "";
 370 }
 371
 372 string waypoint_get_type_name(entity wp)
 373 {
 374         if (wp.wpflags & WAYPOINTFLAG_ITEM) return "^1Item waypoint";
 375         else if (wp.wpflags & WAYPOINTFLAG_CROUCH) return "^5Crouch waypoint";
 376         else if (wp.wpflags & WAYPOINTFLAG_JUMP) return "^xf80Jump waypoint";
 377         else if (wp.wpflags & WAYPOINTFLAG_SUPPORT) return "^2Support waypoint";
 378         else if (waypoint_has_hardwiredlinks(wp)) return "^x80fHardwired waypoint";
 379         else if (wp.wpflags & WAYPOINTFLAG_LADDER) return "^3Ladder waypoint";
 380         else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 381         {
 382                 if (!wp.wpisbox) return "^3Warpzone waypoint";
 383                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP) return "^3Custom jumppad waypoint";
 384                 else
 385                 {
 386                         IL_EACH(g_jumppads, boxesoverlap(wp.absmin, wp.absmax, it.absmin, it.absmax),
 387                                 { return "^3Jumppad waypoint"; });
 388                         return "^3Teleport waypoint";
 389                 }
 390         }
 391
 392         return "^7Waypoint";
 393 }
 394
 395 entity waypoint_get(vector m1, vector m2)
 396 {
 397         if (m1 == m2)
 398         {
 399                 m1 -= '8 8 8';
 400                 m2 += '8 8 8';
 401         }
 402         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 403
 404         return NULL;
 405 }
 406
 407 .float createdtime;
 408 entity waypoint_spawn(vector m1, vector m2, float f)
 409 {
 410         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 411         {
 412                 entity wp_found = waypoint_get(m1, m2);
 413                 if (wp_found)
 414                         return wp_found;
 415         }
 416         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 417         // otherwise links loaded from file would be applied only to the first destination
 418         // waypoint since link format doesn't specify waypoint entities but just positions
 419         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WPFLAGMASK_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 420         {
 421                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 422                 {
 423                         return it;
 424                 });
 425         }
 426
 427         entity w = new(waypoint);
 428         IL_PUSH(g_waypoints, w);
 429         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 430         w.wpflags = f;
 431         w.solid = SOLID_TRIGGER;
 432         w.createdtime = time;
 433         setorigin(w, (m1 + m2) * 0.5);
 434         setsize(w, m1 - w.origin, m2 - w.origin);
 435         if (w.size)
 436                 w.wpisbox = true;
 437
 438         if(!w.wpisbox)
 439         {
 440                 if (f & WAYPOINTFLAG_CROUCH)
 441                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 442                 else
 443                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 444                 if(!move_out_of_solid(w))
 445                 {
 446                         if(!(f & WAYPOINTFLAG_GENERATED))
 447                         {
 448                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 449                                 delete(w);
 450                                 return NULL;
 451                         }
 452                         else
 453                         {
 454                                 if(autocvar_developer)
 455                                 {
 456                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 457                                         backtrace("Waypoint stuck");
 458                                 }
 459                         }
 460                 }
 461                 setsize(w, '0 0 0', '0 0 0');
 462         }
 463
 464         waypoint_clearlinks(w);
 465         //waypoint_schedulerelink(w);
 466
 467         waypoint_setupmodel(w);
 468
 469         return w;
 470 }
 471
 472 float trigger_push_get_push_time(entity this, vector endpos);
 473 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 474 {
 475         entity jp = NULL;
 476         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 477         {
 478                 jp = it;
 479                 break;
 480         });
 481         if (!jp)
 482                 return;
 483
 484         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 485         wp_from.wp00 = wp_to;
 486         wp_from.wp00mincost = cost;
 487         jp.nearestwaypoint = wp_from;
 488         jp.nearestwaypointtimeout = -1;
 489 }
 490
 491 bool start_wp_is_spawned;
 492 vector start_wp_origin;
 493 bool start_wp_is_hardwired;
 494 bool start_wp_is_support;
 495
 496 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 497 {
 498         start_wp_is_spawned = false;
 499         start_wp_origin = '0 0 0';
 500         pl.wp_locked = NULL;
 501         start_wp_is_hardwired = false;
 502         start_wp_is_support = false;
 503         if (warn)
 504                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 505 }
 506
 507 void crosshair_trace_waypoints(entity pl);
 508 void waypoint_start_hardwiredlink(entity pl, bool at_crosshair)
 509 {
 510         entity wp = pl.nearestwaypoint;
 511         if (at_crosshair)
 512         {
 513                 crosshair_trace_waypoints(pl);
 514                 wp = trace_ent;
 515         }
 516         string err = "";
 517         if (start_wp_is_spawned && !start_wp_is_hardwired)
 518                 err = "can't hardwire while in the process of creating a special link";
 519         else if (!wp)
 520         {
 521                 if (at_crosshair)
 522                         err = "couldn't find any waypoint at crosshair";
 523                 else
 524                         err = "couldn't find any waypoint nearby";
 525         }
 526         else if (wp.wpflags & WPFLAGMASK_NORELINK)
 527                 err = "can't hardwire a waypoint with special links";
 528
 529         if (err == "")
 530         {
 531                 start_wp_is_hardwired = true;
 532                 start_wp_is_spawned = true;
 533                 start_wp_origin = wp.origin;
 534                 pl.wp_locked = wp;
 535                 LOG_INFOF("^x80fWaypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 536         }
 537         else
 538         {
 539                 start_wp_is_hardwired = false;
 540                 LOG_INFO("Error: ", err, "\n");
 541         }
 542 }
 543
 544 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 545 {
 546         if (WAYPOINT_VERSION < waypoint_version_loaded)
 547         {
 548                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 549                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 550                 return;
 551         }
 552
 553         entity e = NULL, jp = NULL;
 554         vector org = pl.origin;
 555         if (at_crosshair)
 556         {
 557                 crosshair_trace_waypoints(pl);
 558                 org = trace_endpos;
 559                 if (!trace_ent)
 560                         org.z -= PL_MIN_CONST.z;
 561                 if (!(start_wp_is_hardwired || start_wp_is_support))
 562                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 563                         {
 564                                 jp = it;
 565                                 break;
 566                         });
 567                 if (!jp && !start_wp_is_spawned && trace_ent)
 568                 {
 569                         if (trace_ent.wpflags & (WAYPOINTFLAG_JUMP))
 570                                 is_jump_wp = true;
 571                         else if (trace_ent.wpflags & (WAYPOINTFLAG_SUPPORT))
 572                                 is_support_wp = true;
 573                 }
 574         }
 575         if (jp || is_jump_wp || is_support_wp)
 576         {
 577                 if (start_wp_is_spawned)
 578                         start_wp_is_spawned = false;
 579                 LOG_INFO("^xf80Spawning start waypoint...\n");
 580         }
 581         int ctf_flags = havocbot_symmetry_origin_order;
 582         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 583                    || (autocvar_g_waypointeditor_symmetrical < 0));
 584         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 585                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 586         if (sym && ctf_flags < 2)
 587                 ctf_flags = 2;
 588         int wp_num = ctf_flags;
 589
 590         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 591         {
 592                 // snap waypoint to item's origin if close enough
 593                 IL_EACH(g_items, true,
 594                 {
 595                         vector item_org = (it.absmin + it.absmax) * 0.5;
 596                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 597                         if (vlen(item_org - org) < 20)
 598                         {
 599                                 org = item_org;
 600                                 break;
 601                         }
 602                 });
 603         }
 604
 605         vector start_org = '0 0 0';
 606         if (start_wp_is_spawned)
 607         {
 608                 if (!start_wp_is_hardwired)
 609                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 610                 start_org = start_wp_origin;
 611         }
 612
 613         // save org as it can be modified spawning symmetrycal waypoints
 614         vector initial_origin = '0 0 0';
 615         bool initial_origin_is_set = false;
 616
 617         LABEL(add_wp);
 618
 619         if (jp)
 620         {
 621                 e = NULL;
 622                 IL_EACH(g_waypoints, it.wpflags & WPFLAGMASK_NORELINK
 623                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 624                 {
 625                         e = it; break;
 626                 });
 627                 if (!e)
 628                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT);
 629                 if (!pl.wp_locked)
 630                         pl.wp_locked = e;
 631         }
 632         else if (is_jump_wp || is_support_wp)
 633         {
 634                 int type_flag = (is_jump_wp) ? WAYPOINTFLAG_JUMP : WAYPOINTFLAG_SUPPORT;
 635
 636                 entity wp_found = waypoint_get(org, org);
 637                 if (wp_found && !(wp_found.wpflags & type_flag))
 638                 {
 639                         LOG_INFOF("Error: can't spawn a %s waypoint over an existent waypoint of a different type\n", (is_jump_wp) ? "Jump" : "Support");
 640                         return;
 641                 }
 642                 e = waypoint_spawn(org, org, type_flag);
 643                 if (!pl.wp_locked)
 644                         pl.wp_locked = e;
 645         }
 646         else
 647                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 648         if(!e)
 649         {
 650                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 651                 if (start_wp_is_spawned)
 652                         waypoint_clear_start_wp_globals(pl, true);
 653                 return;
 654         }
 655
 656         if (!initial_origin_is_set)
 657         {
 658                 initial_origin = e.origin;
 659                 initial_origin_is_set = true;
 660         }
 661
 662         entity start_wp = NULL;
 663         if (start_wp_is_spawned)
 664         {
 665                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WPFLAGMASK_NORELINK)
 666                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 667                 {
 668                         start_wp = it; break;
 669                 });
 670                 if(!start_wp)
 671                 {
 672                         // should not happen
 673                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 674                         waypoint_clear_start_wp_globals(pl, true);
 675                         return;
 676                 }
 677                 if (start_wp_is_hardwired)
 678                 {
 679                         if (waypoint_is_hardwiredlink(start_wp, e))
 680                         {
 681                                 waypoint_unmark_hardwiredlink(start_wp, e);
 682                                 waypoint_removelink(start_wp, e);
 683                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 684                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 685                         }
 686                         else
 687                         {
 688                                 if (e.createdtime == time)
 689                                 {
 690                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 691                                         waypoint_remove(e);
 692                                         waypoint_clear_start_wp_globals(pl, true);
 693                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 694                                         return;
 695                                 }
 696                                 if (start_wp == e)
 697                                 {
 698                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 699                                         waypoint_clear_start_wp_globals(pl, true);
 700                                         return;
 701                                 }
 702                                 if (waypoint_islinked(start_wp, e))
 703                                 {
 704                                         LOG_INFO("Error: waypoints are already linked.\n");
 705                                         waypoint_clear_start_wp_globals(pl, true);
 706                                         return;
 707                                 }
 708                                 waypoint_addlink(start_wp, e);
 709                                 waypoint_mark_hardwiredlink(start_wp, e);
 710                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 711                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 712                         }
 713                 }
 714                 else
 715                 {
 716                         if (start_wp_is_support)
 717                         {
 718                                 if (e.SUPPORT_WP)
 719                                 {
 720                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 721                                         waypoint_clear_start_wp_globals(pl, true);
 722                                         return;
 723                                 }
 724                                 // clear all links to e
 725                                 IL_EACH(g_waypoints, it != e,
 726                                 {
 727                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 728                                                 waypoint_removelink(it, e);
 729                                 });
 730                         }
 731                         waypoint_addlink(start_wp, e);
 732                 }
 733         }
 734
 735         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 736                 waypoint_schedulerelink(e);
 737
 738         string wp_type_str = waypoint_get_type_name(e);
 739
 740         bprint(strcat(wp_type_str, "^7 spawned at ", vtos(e.origin), "\n"));
 741
 742         if (start_wp_is_spawned)
 743         {
 744                 pl.wp_locked = NULL;
 745                 if (!start_wp_is_hardwired)
 746                         waypoint_schedulerelink(start_wp);
 747                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 748                 {
 749                         if (start_wp.wp00_original == start_wp.wp00)
 750                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 751                         else
 752                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 753                 }
 754         }
 755
 756         if (sym)
 757         {
 758                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 759                 if (jp)
 760                 {
 761                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 762                         {
 763                                 jp = it; break;
 764                         });
 765                 }
 766                 if (start_wp_is_spawned)
 767                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 768                 if (vdist(org - pl.origin, >, 32))
 769                 {
 770                         if(wp_num > 2)
 771                                 wp_num--;
 772                         else
 773                                 sym = false;
 774                         goto add_wp;
 775                 }
 776         }
 777         if (jp || is_jump_wp || is_support_wp)
 778         {
 779                 if (!start_wp_is_spawned)
 780                 {
 781                         // we've just created a custom jumppad waypoint
 782                         // the next one created by the user will be the destination waypoint
 783                         start_wp_is_spawned = true;
 784                         start_wp_origin = initial_origin;
 785                         if (is_support_wp)
 786                                 start_wp_is_support = true;
 787                 }
 788         }
 789         else if (start_wp_is_spawned)
 790         {
 791                 waypoint_clear_start_wp_globals(pl, false);
 792         }
 793 }
 794
 795 void waypoint_remove(entity wp)
 796 {
 797         IL_EACH(g_waypoints, it != wp,
 798         {
 799                 if (it.SUPPORT_WP == wp)
 800                 {
 801                         it.SUPPORT_WP = NULL;
 802                         waypoint_schedulerelink(it); // restore incoming links
 803                 }
 804                 if (waypoint_islinked(it, wp))
 805                 {
 806                         if (waypoint_is_hardwiredlink(it, wp))
 807                                 waypoint_unmark_hardwiredlink(it, wp);
 808                         waypoint_removelink(it, wp);
 809                 }
 810         });
 811         delete(wp);
 812 }
 813
 814 void waypoint_remove_fromeditor(entity pl)
 815 {
 816         if (WAYPOINT_VERSION < waypoint_version_loaded)
 817         {
 818                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 819                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 820                 return;
 821         }
 822
 823         entity e = navigation_findnearestwaypoint(pl, false);
 824
 825         int ctf_flags = havocbot_symmetry_origin_order;
 826         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 827                    || (autocvar_g_waypointeditor_symmetrical < 0));
 828         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 829                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 830         if (sym && ctf_flags < 2)
 831                 ctf_flags = 2;
 832         int wp_num = ctf_flags;
 833
 834         LABEL(remove_wp);
 835         if (!e) return;
 836
 837         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 838         {
 839                 if (start_wp_is_spawned)
 840                         waypoint_clear_start_wp_globals(pl, true);
 841                 return;
 842         }
 843
 844         if (waypoint_has_hardwiredlinks(e))
 845         {
 846                 LOG_INFO("Can't remove a waypoint with hardwired links, remove links with \"wpeditor hardwire\" first\n");
 847                 return;
 848         }
 849
 850         entity wp_sym = NULL;
 851         if (sym)
 852         {
 853                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 854                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 855                         if(vdist(org - it.origin, <, 3))
 856                         {
 857                                 wp_sym = it;
 858                                 break;
 859                         }
 860                 });
 861         }
 862
 863         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 864         te_explosion(e.origin);
 865         waypoint_remove(e);
 866
 867         if (sym && wp_sym)
 868         {
 869                 e = wp_sym;
 870                 if(wp_num > 2)
 871                         wp_num--;
 872                 else
 873                         sym = false;
 874                 goto remove_wp;
 875         }
 876
 877         if (start_wp_is_spawned)
 878                 waypoint_clear_start_wp_globals(pl, true);
 879 }
 880
 881 void waypoint_removelink(entity from, entity to)
 882 {
 883         if (from == to || (from.wpflags & WPFLAGMASK_NORELINK && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 884                 return;
 885
 886         entity fromwp31_prev = from.wp31;
 887
 888         switch (waypoint_getlinknum(from, to))
 889         {
 890                 // fallthrough all the way
 891                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 892                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 893                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 894                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 895                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 896                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 897                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 898                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 899                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 900                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 901                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 902                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 903                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 904                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 905                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 906                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 907                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 908                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 909                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 910                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 911                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 912                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 913                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 914                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 915                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 916                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 917                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 918                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 919                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 920                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 921                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 922                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 923         }
 924
 925         if (fromwp31_prev && !from.wp31)
 926                 waypoint_schedulerelink(from);
 927 }
 928
 929 int waypoint_getlinknum(entity from, entity to)
 930 {
 931         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 932         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 933         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 934         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 935         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 936         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 937         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 938         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 939         return -1;
 940 }
 941
 942 bool waypoint_islinked(entity from, entity to)
 943 {
 944         return (waypoint_getlinknum(from, to) >= 0);
 945 }
 946
 947 void waypoint_updatecost_foralllinks()
 948 {
 949         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 950         {
 951                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 952                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 953                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 954                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 955                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 956                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 957                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 958                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 959                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 960                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 961                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 962                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 963                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 964                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 965                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 966                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 967                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 968                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 969                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 970                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 971                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 972                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 973                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 974                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 975                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 976                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 977                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 978                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 979                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 980                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 981                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 982                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 983         });
 984 }
 985
 986 float waypoint_getlinearcost(float dist)
 987 {
 988         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 989                 return dist / (autocvar_sv_maxspeed * 1.25);
 990         return dist / autocvar_sv_maxspeed;
 991 }
 992
 993 float waypoint_getlinearcost_underwater(float dist)
 994 {
 995         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 996         return dist / (autocvar_sv_maxspeed * 0.7);
 997 }
 998
 999 float waypoint_getlinearcost_crouched(float dist)
1000 {
1001         return dist / (autocvar_sv_maxspeed * 0.5);
1002 }
1003
1004 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
1005 {
1006         bool submerged_from = navigation_check_submerged_state(from_ent, from);
1007         bool submerged_to = navigation_check_submerged_state(to_ent, to);
1008
1009         if (submerged_from && submerged_to)
1010                 return waypoint_getlinearcost_underwater(vlen(to - from));
1011
1012         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH && to_ent.wpflags & WAYPOINTFLAG_CROUCH)
1013                 return waypoint_getlinearcost_crouched(vlen(to - from));
1014
1015         float c = waypoint_getlinearcost(vlen(to - from));
1016
1017         float height = from.z - to.z;
1018         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
1019         {
1020                 float height_cost; // fall cost
1021                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
1022                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
1023                 else
1024                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
1025                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
1026                 if(height_cost > c)
1027                         c = height_cost;
1028         }
1029
1030         // consider half path underwater
1031         if (submerged_from || submerged_to)
1032                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
1033
1034         // consider half path crouched
1035         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH || to_ent.wpflags & WAYPOINTFLAG_CROUCH)
1036                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
1037
1038         return c;
1039 }
1040
1041 float waypoint_getlinkcost(entity from, entity to)
1042 {
1043         vector v1 = from.origin;
1044         vector v2 = to.origin;
1045         if (from.wpisbox)
1046         {
1047                 vector m1 = from.absmin, m2 = from.absmax;
1048                 v1.x = bound(m1.x, v2.x, m2.x);
1049                 v1.y = bound(m1.y, v2.y, m2.y);
1050                 v1.z = bound(m1.z, v2.z, m2.z);
1051         }
1052         if (to.wpisbox)
1053         {
1054                 vector m1 = to.absmin, m2 = to.absmax;
1055                 v2.x = bound(m1.x, v1.x, m2.x);
1056                 v2.y = bound(m1.y, v1.y, m2.y);
1057                 v2.z = bound(m1.z, v1.z, m2.z);
1058         }
1059         return waypoint_gettravelcost(v1, v2, from, to);
1060 }
1061
1062 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1063 // if c == -1 automatically determine cost of the link
1064 void waypoint_addlink_customcost(entity from, entity to, float c)
1065 {
1066         if (from == to || waypoint_islinked(from, to))
1067                 return;
1068         if (c == -1 && (from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1069                 return;
1070
1071         if(c == -1)
1072                 c = waypoint_getlinkcost(from, to);
1073
1074         if (from.wp31mincost < c) return;
1075         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1076         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1077         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1078         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1079         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1080         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1081         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1082         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1083         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1084         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1085         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1086         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1087         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1088         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1089         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1090         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1091         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1092         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1093         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1094         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1095         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1096         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1097         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1098         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1099         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1100         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1101         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1102         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1103         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1104         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1105         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1106         from.wp00 = to;from.wp00mincost = c;return;
1107 }
1108
1109 void waypoint_addlink(entity from, entity to)
1110 {
1111         if ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1112                 waypoint_addlink_for_custom_jumppad(from, to);
1113         else
1114                 waypoint_addlink_customcost(from, to, -1);
1115
1116         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1117                 to.SUPPORT_WP = from;
1118 }
1119
1120 // relink this spawnfunc_waypoint
1121 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1122 // (SLOW!)
1123 void waypoint_think(entity this)
1124 {
1125         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1126         float sv2_height = 0, ev2_height = 0;
1127
1128         bot_calculate_stepheightvec();
1129
1130         int dphitcontentsmask_save = this.dphitcontentsmask;
1131         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1132
1133         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1134
1135         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1136         IL_EACH(g_waypoints, this != it,
1137         {
1138                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1139                 {
1140                         if (!(this.wpflags & WPFLAGMASK_NORELINK))
1141                                 waypoint_addlink(this, it);
1142                         if (!(it.wpflags & WPFLAGMASK_NORELINK))
1143                                 waypoint_addlink(it, this);
1144                 }
1145                 else
1146                 {
1147                         ++relink_total;
1148                         if(!checkpvs(this.origin, it))
1149                         {
1150                                 ++relink_pvsculled;
1151                                 continue;
1152                         }
1153
1154                         sv = set_tracewalk_dest_2(this, it.origin);
1155                         sv2 = tracewalk_dest;
1156                         sv2_height = tracewalk_dest_height;
1157                         ev = set_tracewalk_dest_2(it, this.origin);
1158                         ev2 = tracewalk_dest;
1159                         ev2_height = tracewalk_dest_height;
1160
1161                         dv = ev - sv;
1162                         dv.z = 0;
1163                         int maxdist = 1050;
1164                         vector m1 = PL_MIN_CONST;
1165                         vector m2 = PL_MAX_CONST;
1166
1167                         if (this.wpflags & WAYPOINTFLAG_CROUCH || it.wpflags & WAYPOINTFLAG_CROUCH)
1168                         {
1169                                 m1 = PL_CROUCH_MIN_CONST;
1170                                 m2 = PL_CROUCH_MAX_CONST;
1171                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1172                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1173                                 // links from crouch wp to crouch wp can be as long as normal links
1174                                 if (!(this.wpflags & WAYPOINTFLAG_CROUCH && it.wpflags & WAYPOINTFLAG_CROUCH))
1175                                         maxdist = 100;
1176                         }
1177
1178                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1179                         {
1180                                 ++relink_lengthculled;
1181                                 continue;
1182                         }
1183
1184                         navigation_testtracewalk = 0;
1185
1186                         //traceline(this.origin, it.origin, false, NULL);
1187                         //if (trace_fraction == 1)
1188                         if (this.wpisbox || this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT) // forbid outgoing links
1189                                 || it.SUPPORT_WP) // forbid incoming links
1190                         {
1191                                 relink_walkculled += 0.5;
1192                         }
1193                         else
1194                         {
1195                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1196                                         waypoint_addlink(this, it);
1197                                 else
1198                                         relink_walkculled += 0.5;
1199                         }
1200
1201                         // reverse direction
1202                         if (it.wpisbox || it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT) // forbid incoming links
1203                                 || this.SUPPORT_WP) // forbid outgoing links
1204                         {
1205                                 relink_walkculled += 0.5;
1206                         }
1207                         else
1208                         {
1209                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1210                                         waypoint_addlink(it, this);
1211                                 else
1212                                         relink_walkculled += 0.5;
1213                         }
1214                 }
1215         });
1216         navigation_testtracewalk = 0;
1217         this.wplinked = true;
1218         this.dphitcontentsmask = dphitcontentsmask_save;
1219
1220         setthink(this, func_null);
1221         this.nextthink = 0;
1222 }
1223
1224 void waypoint_clearlinks(entity wp)
1225 {
1226         // clear links to other waypoints
1227         float f = 10000000;
1228         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1229         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1230         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1231         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1232
1233         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1234         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1235         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1236         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1237
1238         wp.wplinked = false;
1239 }
1240
1241 // tell a spawnfunc_waypoint to relink
1242 void waypoint_schedulerelink(entity wp)
1243 {
1244         if (wp == NULL)
1245                 return;
1246
1247         waypoint_setupmodel(wp);
1248         wp.wpisbox = vdist(wp.size, >, 0);
1249         wp.enemy = NULL;
1250         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1251                 wp.owner = NULL;
1252         if (!(wp.wpflags & WPFLAGMASK_NORELINK))
1253                 waypoint_clearlinks(wp);
1254         // schedule an actual relink on next frame
1255         setthink(wp, waypoint_think);
1256         wp.nextthink = time;
1257         wp.effects = EF_LOWPRECISION;
1258 }
1259
1260 // spawnfunc_waypoint map entity
1261 spawnfunc(waypoint)
1262 {
1263         IL_PUSH(g_waypoints, this);
1264
1265         setorigin(this, this.origin);
1266         // schedule a relink after other waypoints have had a chance to spawn
1267         waypoint_clearlinks(this);
1268         //waypoint_schedulerelink(this);
1269 }
1270
1271 // tell all waypoints to relink
1272 // actually this is useful only to update relink_* stats
1273 void waypoint_schedulerelinkall()
1274 {
1275         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1276         IL_EACH(g_waypoints, true,
1277         {
1278                 waypoint_schedulerelink(it);
1279         });
1280         waypoint_load_hardwiredlinks();
1281 }
1282
1283 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1284
1285 // Load waypoint links from file
1286 bool waypoint_load_links()
1287 {
1288         string s;
1289         float file, tokens, c = 0, found;
1290         entity wp_from = NULL, wp_to;
1291         vector wp_to_pos, wp_from_pos;
1292
1293         string gt_ext = GET_GAMETYPE_EXTENSION();
1294
1295         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1296         file = fopen(filename, FILE_READ);
1297
1298         if (gt_ext != "" && file < 0)
1299         {
1300                 // if race waypoint file doesn't exist load the default one
1301                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1302                 file = fopen(filename, FILE_READ);
1303         }
1304
1305         if (file < 0)
1306         {
1307                 LOG_TRACE("waypoint links load from ", filename, " failed");
1308                 waypoint_schedulerelinkall();
1309                 return false;
1310         }
1311
1312         bool parse_comments = true;
1313         float ver = 0;
1314         string links_time = string_null;
1315
1316         while ((s = fgets(file)))
1317         {
1318                 if(parse_comments)
1319                 {
1320                         if(substring(s, 0, 2) == "//")
1321                         {
1322                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1323                                         ver = stof(substring(s, 19, -1));
1324                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1325                                         links_time = substring(s, 16, -1);
1326                                 continue;
1327                         }
1328                         else
1329                         {
1330                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1331                                 {
1332                                         if (links_time != waypoint_time)
1333                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1334                                         else
1335                                                 LOG_TRACE("waypoint links for this map are outdated.");
1336                                         if (g_assault)
1337                                         {
1338                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1339                                         }
1340                                         else
1341                                         {
1342                                                 LOG_TRACE("automatically updating...");
1343                                                 waypoint_schedulerelinkall();
1344                                                 fclose(file);
1345                                                 return false;
1346                                         }
1347                                 }
1348                                 parse_comments = false;
1349                         }
1350                 }
1351
1352                 tokens = tokenizebyseparator(s, "*");
1353
1354                 if (tokens!=2)
1355                 {
1356                         // bad file format
1357                         fclose(file);
1358                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1359                         return false;
1360                 }
1361
1362                 wp_from_pos     = stov(argv(0));
1363                 wp_to_pos       = stov(argv(1));
1364
1365                 // Search "from" waypoint
1366                 if(!wp_from || wp_from.origin!=wp_from_pos)
1367                 {
1368                         wp_from = findradius(wp_from_pos, 1);
1369                         found = false;
1370                         while(wp_from)
1371                         {
1372                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1373                                 if(wp_from.classname == "waypoint")
1374                                 {
1375                                         found = true;
1376                                         break;
1377                                 }
1378                                 wp_from = wp_from.chain;
1379                         }
1380
1381                         if(!found)
1382                         {
1383                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1384                                 continue;
1385                         }
1386                 }
1387
1388                 // Search "to" waypoint
1389                 wp_to = findradius(wp_to_pos, 1);
1390                 found = false;
1391                 while(wp_to)
1392                 {
1393                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1394                         if(wp_to.classname == "waypoint")
1395                         {
1396                                 found = true;
1397                                 break;
1398                         }
1399                         wp_to = wp_to.chain;
1400                 }
1401
1402                 if(!found)
1403                 {
1404                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1405                         continue;
1406                 }
1407
1408                 ++c;
1409                 waypoint_addlink(wp_from, wp_to);
1410                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1411                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1412         }
1413
1414         fclose(file);
1415
1416         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1417
1418         bool scheduled = false;
1419         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1420         {
1421                 if (!it.wp00)
1422                 {
1423                         waypoint_schedulerelink(it);
1424                         scheduled = true;
1425                 }
1426         });
1427         if (scheduled)
1428                 return false;
1429
1430         botframe_cachedwaypointlinks = true;
1431         return true;
1432 }
1433
1434 void waypoint_load_hardwiredlinks()
1435 {
1436         string s;
1437         float file, tokens, c = 0, found;
1438         entity wp_from = NULL, wp_to;
1439         vector wp_to_pos, wp_from_pos;
1440
1441         string gt_ext = GET_GAMETYPE_EXTENSION();
1442
1443         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1444         file = fopen(filename, FILE_READ);
1445
1446         if (gt_ext != "" && file < 0)
1447         {
1448                 // if race waypoint file doesn't exist load the default one
1449                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1450                 file = fopen(filename, FILE_READ);
1451         }
1452
1453         botframe_loadedforcedlinks = true;
1454
1455         if (file < 0)
1456         {
1457                 LOG_TRACE("waypoint links load from ", filename, " failed");
1458                 return;
1459         }
1460
1461         bool is_special = false;
1462         while ((s = fgets(file)))
1463         {
1464                 if(substring(s, 0, 2)=="//")
1465                         continue;
1466
1467                 if(substring(s, 0, 1)=="#")
1468                         continue;
1469
1470                 // special links start with *, so old xonotic versions don't load them
1471                 is_special = false;
1472                 if (substring(s, 0, 1) == "*")
1473                 {
1474                         is_special = true;
1475                         s = substring(s, 1, -1);
1476                 }
1477
1478                 tokens = tokenizebyseparator(s, "*");
1479
1480                 if (tokens!=2)
1481                         continue;
1482
1483                 wp_from_pos     = stov(argv(0));
1484                 wp_to_pos       = stov(argv(1));
1485
1486                 // Search "from" waypoint
1487                 if(!wp_from || wp_from.origin!=wp_from_pos)
1488                 {
1489                         wp_from = findradius(wp_from_pos, 5);
1490                         found = false;
1491                         while(wp_from)
1492                         {
1493                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1494                                 if(wp_from.classname == "waypoint")
1495                                 {
1496                                         found = true;
1497                                         break;
1498                                 }
1499                                 wp_from = wp_from.chain;
1500                         }
1501
1502                         if(!found)
1503                         {
1504                                 s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1505                                 LOG_INFO("NOTICE: Can not find origin waypoint of the ", s, ". Path skipped");
1506                                 continue;
1507                         }
1508                 }
1509
1510                 // Search "to" waypoint
1511                 wp_to = findradius(wp_to_pos, 5);
1512                 found = false;
1513                 while(wp_to)
1514                 {
1515                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1516                         if(wp_to.classname == "waypoint")
1517                         {
1518                                 found = true;
1519                                 break;
1520                         }
1521                         wp_to = wp_to.chain;
1522                 }
1523
1524                 if(!found)
1525                 {
1526                         s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1527                         LOG_INFO("NOTICE: Can not find destination waypoint of the ", s, ". Path skipped");
1528                         continue;
1529                 }
1530
1531                 ++c;
1532
1533                 if (!is_special)
1534                 {
1535                         waypoint_addlink(wp_from, wp_to);
1536                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1537                 } else if (wp_from.wpflags & WPFLAGMASK_NORELINK
1538                         && (wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)
1539                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1540                 {
1541                         waypoint_addlink(wp_from, wp_to);
1542                 }
1543         }
1544
1545         fclose(file);
1546
1547         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1548 }
1549
1550 entity waypoint_get_link(entity w, float i)
1551 {
1552         switch(i)
1553         {
1554                 case  0:return w.wp00;
1555                 case  1:return w.wp01;
1556                 case  2:return w.wp02;
1557                 case  3:return w.wp03;
1558                 case  4:return w.wp04;
1559                 case  5:return w.wp05;
1560                 case  6:return w.wp06;
1561                 case  7:return w.wp07;
1562                 case  8:return w.wp08;
1563                 case  9:return w.wp09;
1564                 case 10:return w.wp10;
1565                 case 11:return w.wp11;
1566                 case 12:return w.wp12;
1567                 case 13:return w.wp13;
1568                 case 14:return w.wp14;
1569                 case 15:return w.wp15;
1570                 case 16:return w.wp16;
1571                 case 17:return w.wp17;
1572                 case 18:return w.wp18;
1573                 case 19:return w.wp19;
1574                 case 20:return w.wp20;
1575                 case 21:return w.wp21;
1576                 case 22:return w.wp22;
1577                 case 23:return w.wp23;
1578                 case 24:return w.wp24;
1579                 case 25:return w.wp25;
1580                 case 26:return w.wp26;
1581                 case 27:return w.wp27;
1582                 case 28:return w.wp28;
1583                 case 29:return w.wp29;
1584                 case 30:return w.wp30;
1585                 case 31:return w.wp31;
1586                 default:return NULL;
1587         }
1588 }
1589
1590 // Save all hardwired waypoint links to a file
1591 void waypoint_save_hardwiredlinks()
1592 {
1593         string gt_ext = GET_GAMETYPE_EXTENSION();
1594
1595         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1596         int file = fopen(filename, FILE_WRITE);
1597         if (file < 0)
1598         {
1599                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1600                 return;
1601         }
1602
1603         // write hardwired links to file
1604         int count = 0;
1605         fputs(file, "// HARDWIRED LINKS\n");
1606         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1607         {
1608                 for (int j = 0; j < 32; ++j)
1609                 {
1610                         entity link = waypoint_get_link(it, j);
1611                         if (waypoint_is_hardwiredlink(it, link))
1612                         {
1613                                 // NOTE: vtos rounds vector components to 1 decimal place
1614                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1615                                 fputs(file, s);
1616                                 ++count;
1617                         }
1618                 }
1619         });
1620
1621         // write special links to file
1622         int count2 = 0;
1623         fputs(file, "\n// SPECIAL LINKS\n");
1624         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1625         {
1626                 for (int j = 0; j < 32; ++j)
1627                 {
1628                         entity link = waypoint_get_link(it, j);
1629                         if (link)
1630                         {
1631                                 // NOTE: vtos rounds vector components to 1 decimal place
1632                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1633                                 fputs(file, s);
1634                                 ++count2;
1635                         }
1636                 }
1637         });
1638
1639         fclose(file);
1640
1641         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1642 }
1643
1644 // Save all waypoint links to a file
1645 void waypoint_save_links()
1646 {
1647         string gt_ext = GET_GAMETYPE_EXTENSION();
1648
1649         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1650         int file = fopen(filename, FILE_WRITE);
1651         if (file < 0)
1652         {
1653                 LOG_INFOF("waypoint link save to %s failed", filename);
1654                 return;
1655         }
1656
1657         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1658         if (waypoint_time != "")
1659                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1660
1661         int c = 0;
1662         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1663         {
1664                 for(int j = 0; j < 32; ++j)
1665                 {
1666                         entity link = waypoint_get_link(it, j);
1667                         if (link && !waypoint_is_hardwiredlink(it, link))
1668                         {
1669                                 // NOTE: vtos rounds vector components to 1 decimal place
1670                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1671                                 fputs(file, s);
1672                                 ++c;
1673                         }
1674                 }
1675         });
1676         fclose(file);
1677
1678         botframe_cachedwaypointlinks = true;
1679
1680         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1681 }
1682
1683 // save waypoints to gamedir/data/maps/mapname.waypoints
1684 void waypoint_saveall()
1685 {
1686         if (WAYPOINT_VERSION < waypoint_version_loaded)
1687         {
1688                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1689                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1690                 return;
1691         }
1692         string gt_ext = GET_GAMETYPE_EXTENSION();
1693
1694         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1695         int file = fopen(filename, FILE_WRITE);
1696         if (file < 0)
1697         {
1698                 waypoint_save_links(); // save anyway?
1699                 botframe_loadedforcedlinks = false;
1700
1701                 LOG_INFOF("waypoint links: save to %s failed", filename);
1702                 return;
1703         }
1704
1705         float sym = autocvar_g_waypointeditor_symmetrical;
1706         string sym_str = ftos(sym);
1707         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1708         {
1709                 if (sym == 1)
1710                 {
1711                         sym_str = cons(sym_str, "-");
1712                         sym_str = cons(sym_str, "-");
1713                 }
1714                 else
1715                 {
1716                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1717                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1718                 }
1719                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1720                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1721         }
1722         else if (autocvar_g_waypointeditor_symmetrical == -2)
1723         {
1724                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1725                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1726         }
1727
1728         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1729         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1730         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1731         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1732
1733         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1734         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1735         //fputs(file, strcat("//", "\n"));
1736         //fputs(file, strcat("//", "\n"));
1737         //fputs(file, strcat("//", "\n"));
1738
1739         int c = 0;
1740         IL_EACH(g_waypoints, true,
1741         {
1742                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1743                         continue;
1744
1745                 string s;
1746                 // NOTE: vtos rounds vector components to 1 decimal place
1747                 s = strcat(vtos(it.origin + it.mins), "\n");
1748                 s = strcat(s, vtos(it.origin + it.maxs));
1749                 s = strcat(s, "\n");
1750                 s = strcat(s, ftos(it.wpflags));
1751                 s = strcat(s, "\n");
1752                 fputs(file, s);
1753                 c++;
1754         });
1755         fclose(file);
1756         waypoint_save_links();
1757         waypoint_save_hardwiredlinks();
1758
1759         botframe_loadedforcedlinks = false;
1760
1761         waypoint_version_loaded = WAYPOINT_VERSION;
1762         LOG_INFOF("saved %d waypoints to %s", c, filename);
1763 }
1764
1765 // load waypoints from file
1766 float waypoint_loadall()
1767 {
1768         string s;
1769         int file, cwp, cwb, fl;
1770         vector m1, m2;
1771         cwp = 0;
1772         cwb = 0;
1773
1774         string gt_ext = GET_GAMETYPE_EXTENSION();
1775
1776         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1777         file = fopen(filename, FILE_READ);
1778
1779         if (gt_ext != "" && file < 0)
1780         {
1781                 // if race waypoint file doesn't exist load the default one
1782                 filename = sprintf("maps/%s.waypoints", mapname);
1783                 file = fopen(filename, FILE_READ);
1784         }
1785
1786         if (file < 0)
1787         {
1788                 LOG_TRACE("waypoint load from ", filename, " failed");
1789                 return 0;
1790         }
1791
1792         bool parse_comments = true;
1793         float ver = 0;
1794         float sym = 0;
1795         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1796
1797         while ((s = fgets(file)))
1798         {
1799                 if(parse_comments)
1800                 {
1801                         if(substring(s, 0, 2) == "//")
1802                         {
1803                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1804                                         ver = stof(substring(s, 19, -1));
1805                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1806                                 {
1807                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1808                                         if (tokens) { sym = stof(argv(0)); }
1809                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1810                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1811                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1812                                 }
1813                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1814                                         strcpy(waypoint_time, substring(s, 16, -1));
1815                                 continue;
1816                         }
1817                         else
1818                         {
1819                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1820                                 {
1821                                         LOG_TRACE("waypoints for this map are outdated");
1822                                         LOG_TRACE("please update them in the editor");
1823                                 }
1824                                 parse_comments = false;
1825                         }
1826                 }
1827                 m1 = stov(s);
1828                 s = fgets(file);
1829                 if (!s)
1830                         break;
1831                 m2 = stov(s);
1832                 s = fgets(file);
1833                 if (!s)
1834                         break;
1835                 fl = stof(s);
1836                 if (fl & WAYPOINTFLAG_NORELINK__DEPRECATED)
1837                         fl &= ~WAYPOINTFLAG_NORELINK__DEPRECATED;
1838                 waypoint_spawn(m1, m2, fl);
1839                 if (m1 == m2)
1840                         cwp = cwp + 1;
1841                 else
1842                         cwb = cwb + 1;
1843         }
1844         fclose(file);
1845         waypoint_version_loaded = ver;
1846         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1847
1848         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1849         {
1850                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1851                 if (sym == 1 && sym_param3 < 2)
1852                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1853                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1854                 {
1855                         string params;
1856                         if (sym == 1)
1857                                 params = cons("-", "-");
1858                         else
1859                         {
1860                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1861                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1862                         }
1863                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1864                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1865                 }
1866                 else if (sym == -2)
1867                 {
1868                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1869                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1870                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1871                 }
1872                 else
1873                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1874                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1875         }
1876
1877         if (WAYPOINT_VERSION < waypoint_version_loaded)
1878                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1879                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1880
1881         return cwp + cwb;
1882 }
1883
1884 #define waypoint_fixorigin(position, tracetest_ent) \
1885         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1886
1887 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1888 {
1889         vector endpos = position + down_dir * 3000;
1890         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1891         if(trace_startsolid)
1892                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1893         if(trace_startsolid)
1894                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1895         if(trace_fraction < 1)
1896                 position = trace_endpos;
1897         return position;
1898 }
1899
1900 void waypoint_spawnforitem_force(entity e, vector org)
1901 {
1902         // Fix the waypoint altitude if necessary
1903         org = waypoint_fixorigin(org, NULL);
1904
1905         // don't spawn an item spawnfunc_waypoint if it already exists
1906         IL_EACH(g_waypoints, true,
1907         {
1908                 if(it.wpisbox)
1909                 {
1910                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1911                         {
1912                                 e.nearestwaypoint = it;
1913                                 return;
1914                         }
1915                 }
1916                 else
1917                 {
1918                         if(vdist(it.origin - org, <, 16))
1919                         {
1920                                 e.nearestwaypoint = it;
1921                                 return;
1922                         }
1923                 }
1924         });
1925
1926         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1927 }
1928
1929 void waypoint_spawnforitem(entity e)
1930 {
1931         if(!bot_waypoints_for_items)
1932                 return;
1933
1934         waypoint_spawnforitem_force(e, e.origin);
1935 }
1936
1937 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1938 {
1939         entity w;
1940         entity dw;
1941         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag);
1942         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1943         // one way link to the destination
1944         w.wp00_original = dw;
1945         w.wp00 = dw;
1946         w.wp00mincost = timetaken; // this is just for jump pads
1947         // the teleporter's nearest spawnfunc_waypoint is this one
1948         // (teleporters are not goals, so this is probably useless)
1949         e.nearestwaypoint = w;
1950         e.nearestwaypointtimeout = -1;
1951 }
1952
1953 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1954 {
1955         float src_angle = e.warpzone_angles.x;
1956         while (src_angle < -180) src_angle += 360;
1957         while (src_angle > 180) src_angle -= 360;
1958
1959         float dest_angle = e.enemy.warpzone_angles.x;
1960         while (dest_angle < -180) dest_angle += 360;
1961         while (dest_angle > 180) dest_angle -= 360;
1962
1963         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1964         if (src_angle == -90 || dest_angle == -90)
1965                 return;
1966
1967         makevectors(e.warpzone_angles);
1968         vector src = (e.absmin + e.absmax) * 0.5;
1969         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1970         vector down_dir_src = -v_up;
1971
1972         makevectors(e.enemy.warpzone_angles);
1973         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1974         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1975         vector down_dir_dest = -v_up;
1976
1977         int extra_flag = 0;
1978         // don't snap to the ground waypoints for source warpzones pointing downwards
1979         if (src_angle != 90)
1980         {
1981                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1982                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1983                 // oblique warpzones need a jump otherwise bots gets stuck
1984                 if (src_angle != 0)
1985                         extra_flag = WAYPOINTFLAG_JUMP;
1986         }
1987
1988         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1989 }
1990
1991 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1992 {
1993         destination = waypoint_fixorigin(destination, tracetest_ent);
1994         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1995 }
1996
1997 entity waypoint_spawnpersonal(entity this, vector position)
1998 {
1999         entity w;
2000
2001         // drop the waypoint to a proper location:
2002         //   first move it up by a player height
2003         //   then move it down to hit the floor with player bbox size
2004         position = waypoint_fixorigin(position, this);
2005
2006         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
2007         w.nearestwaypoint = NULL;
2008         w.nearestwaypointtimeout = 0;
2009         w.owner = this;
2010
2011         waypoint_schedulerelink(w);
2012
2013         return w;
2014 }
2015
2016 void waypoint_showlink(entity wp1, entity wp2, int display_type)
2017 {
2018         if (!(wp1 && wp2))
2019                 return;
2020
2021         if (waypoint_is_hardwiredlink(wp1, wp2) || wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP))
2022                 te_beam(NULL, wp1.origin, wp2.origin);
2023         else if (display_type == 1)
2024                 te_lightning2(NULL, wp1.origin, wp2.origin);
2025 }
2026
2027 void waypoint_showlinks_to(entity wp, int display_type)
2028 {
2029         IL_EACH(g_waypoints, it != wp,
2030         {
2031                 if (waypoint_islinked(it, wp))
2032                         waypoint_showlink(it, wp, display_type);
2033         });
2034 }
2035
2036 void waypoint_showlinks_from(entity wp, int display_type)
2037 {
2038         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
2039         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
2040         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
2041         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
2042         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
2043         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
2044         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
2045         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
2046         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
2047         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2048         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2049         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2050         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2051         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2052         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2053         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2054 }
2055
2056 void crosshair_trace_waypoints(entity pl)
2057 {
2058         IL_EACH(g_waypoints, true, {
2059                 it.solid = SOLID_BSP;
2060                 if (!it.wpisbox)
2061                         setsize(it, '-16 -16 -16', '16 16 16');
2062         });
2063
2064         WarpZone_crosshair_trace(pl);
2065
2066         IL_EACH(g_waypoints, true, {
2067                 it.solid = SOLID_TRIGGER;
2068                 if (!it.wpisbox)
2069                         setsize(it, '0 0 0', '0 0 0');
2070         });
2071
2072         if (trace_ent.classname != "waypoint")
2073                 trace_ent = NULL;
2074         else if (!trace_ent.wpisbox)
2075                 trace_endpos = trace_ent.origin;
2076 }
2077
2078 void botframe_showwaypointlinks()
2079 {
2080         if (time < botframe_waypointeditorlightningtime)
2081                 return;
2082         botframe_waypointeditorlightningtime = time + 0.5;
2083         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2084         {
2085                 int display_type = 0;
2086                 if (wasfreed(it.wp_aimed))
2087                         it.wp_aimed = NULL;
2088                 if (wasfreed(it.wp_locked))
2089                         it.wp_locked = NULL;
2090                 if (PHYS_INPUT_BUTTON_USE(it))
2091                         it.wp_locked = it.wp_aimed;
2092                 entity head = it.wp_locked;
2093                 if (!head)
2094                         head = navigation_findnearestwaypoint(it, false);
2095                 it.nearestwaypoint = head; // mainly useful for debug
2096                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2097                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2098                         display_type = 1; // default
2099                 else if(waypoint_has_hardwiredlinks(head))
2100                         display_type = 2; // only hardwired
2101
2102                 if (display_type)
2103                 {
2104                         //navigation_testtracewalk = true;
2105                         //print("currently selected WP is ", etos(head), "\n");
2106                         //navigation_testtracewalk = false;
2107                         if (head)
2108                         {
2109                                 te_lightning2(NULL, head.origin, it.origin);
2110                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2111                                         waypoint_showlinks_to(head, display_type);
2112                                 else
2113                                         waypoint_showlinks_from(head, display_type);
2114                         }
2115                 }
2116                 string str;
2117                 entity wp = NULL;
2118                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2119                 {
2120                         crosshair_trace_waypoints(it);
2121                         if (trace_ent)
2122                         {
2123                                 wp = trace_ent;
2124                                 if (wp != it.wp_aimed)
2125                                 {
2126                                         string wp_type_str = waypoint_get_type_name(wp);
2127                                         str = sprintf("\necho Entity %d: %s^7, flags: %d, origin: %s\n", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2128                                         if (wp.wpisbox)
2129                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2130                                         stuffcmd(it, str);
2131                                         str = sprintf("Entity %d: %s^7\nflags: %d\norigin: %s", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2132                                         if (wp.wpisbox)
2133                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2134                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2135                                 }
2136                         }
2137                 }
2138                 if (it.wp_aimed != wp)
2139                         it.wp_aimed = wp;
2140         });
2141 }
2142
2143 float botframe_autowaypoints_fixdown(vector v)
2144 {
2145         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2146         if(trace_fraction >= 1)
2147                 return 0;
2148         return 1;
2149 }
2150
2151 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2152 {
2153         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2154         {
2155                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2156                 return 0;
2157         });
2158
2159         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2160         return 1;
2161 }
2162
2163 // return value:
2164 //    1 = WP created
2165 //    0 = no action needed
2166 //   -1 = temp fail, try from world too
2167 //   -2 = permanent fail, do not retry
2168 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2169 {
2170         // make it possible to go from p to wp, if we can
2171         // if wp is NULL, nearest is chosen
2172
2173         entity w;
2174         vector porg;
2175         float t, tmin, tmax;
2176         vector o;
2177         vector save;
2178
2179         if(!botframe_autowaypoints_fixdown(p.origin))
2180                 return -2;
2181         porg = trace_endpos;
2182
2183         if(wp)
2184         {
2185                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2186
2187                 // if wp -> porg, then OK
2188                 float maxdist;
2189                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2190                 {
2191                         // we may find a better one
2192                         maxdist = vlen(wp.origin - porg);
2193                 }
2194                 else
2195                 {
2196                         // accept any "good"
2197                         maxdist = 2100;
2198                 }
2199
2200                 float bestdist = maxdist;
2201                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WPFLAGMASK_NORELINK),
2202                 {
2203                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2204                         if(d < bestdist)
2205                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2206                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2207                         {
2208                                 bestdist = d;
2209                                 p.(fld) = it;
2210                         }
2211                 });
2212                 if(bestdist < maxdist)
2213                 {
2214                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2215                         return 0;
2216                 }
2217
2218                 if(bestdist < 2100)
2219                 {
2220                         // we know maxdist < 2100
2221                         // so wp -> porg is still valid
2222                         // all is good
2223                         p.(fld) = wp;
2224                         return 0;
2225                 }
2226
2227                 // otherwise, no existing WP can fix our issues
2228         }
2229         else
2230         {
2231                 save = p.origin;
2232                 setorigin(p, porg);
2233                 w = navigation_findnearestwaypoint(p, walkfromwp);
2234                 setorigin(p, save);
2235                 if(w)
2236                 {
2237                         p.(fld) = w;
2238                         return 0;
2239                 }
2240         }
2241
2242         tmin = 0;
2243         tmax = 1;
2244         for (;;)
2245         {
2246                 if(tmax - tmin < 0.001)
2247                 {
2248                         // did not get a good candidate
2249                         return -1;
2250                 }
2251
2252                 t = (tmin + tmax) * 0.5;
2253                 o = antilag_takebackorigin(p, CS(p), time - t);
2254                 if(!botframe_autowaypoints_fixdown(o))
2255                         return -2;
2256                 o = trace_endpos;
2257
2258                 if(wp)
2259                 {
2260                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2261                         {
2262                                 // we cannot walk from wp.origin to o
2263                                 // get closer to tmax
2264                                 tmin = t;
2265                                 continue;
2266                         }
2267                 }
2268                 else
2269                 {
2270                         save = p.origin;
2271                         setorigin(p, o);
2272                         w = navigation_findnearestwaypoint(p, walkfromwp);
2273                         setorigin(p, save);
2274                         if(!w)
2275                         {
2276                                 // we cannot walk from any WP to o
2277                                 // get closer to tmax
2278                                 tmin = t;
2279                                 continue;
2280                         }
2281                 }
2282
2283                 // if we get here, o is valid regarding waypoints
2284                 // check if o is connected right to the player
2285                 // we break if it succeeds, as that means o is a good waypoint location
2286                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2287                         break;
2288
2289                 // o is no good, we need to get closer to the player
2290                 tmax = t;
2291         }
2292
2293         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2294         botframe_autowaypoints_createwp(o, p, fld, 0);
2295         return 1;
2296 }
2297
2298 // automatically create missing waypoints
2299 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2300 {
2301         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2302         if(r != -1)
2303                 return;
2304         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2305         if(r != -1)
2306                 return;
2307
2308         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2309         if(!botframe_autowaypoints_fixdown(p.origin))
2310                 return; // shouldn't happen, caught above
2311         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2312 }
2313
2314 void botframe_deleteuselesswaypoints()
2315 {
2316         IL_EACH(g_items, it.bot_pickup,
2317         {
2318                 // NOTE: this protects waypoints if they're the ONLY nearest
2319                 // waypoint. That's the intention.
2320                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2321                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2322         });
2323         IL_EACH(g_waypoints, true,
2324         {
2325                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2326                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2327                 // WP is useful if:
2328                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2329                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2330                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2331                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2332                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2333                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2334                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2335                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2336                 // b) WP is closest WP for an item/spawnpoint/other entity
2337                 //    This has been done above by protecting these WPs.
2338         });
2339         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2340         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2341         {
2342                 for (int m = 0; m < 32; ++m)
2343                 {
2344                         entity w = waypoint_get_link(it, m);
2345                         if (!w)
2346                                 break;
2347                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2348                                 continue;
2349                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2350                                 continue;
2351                         for (int j = 0; j < 32; ++j)
2352                         {
2353                                 entity w2 = waypoint_get_link(w, j);
2354                                 if (!w2)
2355                                         break;
2356                                 if (it == w2)
2357                                         continue;
2358                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2359                                         continue;
2360                                 // If we got here, it != w2 exist with it -> w
2361                                 // and w -> w2. That means the waypoint is not
2362                                 // a dead end.
2363                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2364                                 for (int k = 0; k < 32; ++k)
2365                                 {
2366                                         if (waypoint_get_link(it, k) == w2)
2367                                                 continue;
2368                                         // IF WE GET HERE, w is proven useful
2369                                         // to get from it to w2!
2370                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2371                                         goto next;
2372                                 }
2373                         }
2374 LABEL(next)
2375                 }
2376         });
2377         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2378         //     they are needed to complete routes while autowaypointing.
2379
2380         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2381         {
2382                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2383                 te_explosion(it.origin);
2384                 waypoint_remove(it);
2385                 break;
2386         });
2387
2388         IL_EACH(g_waypoints, true,
2389         {
2390                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2391         });
2392 }
2393
2394 //.entity botframe_autowaypoints_lastwp0;
2395 .entity botframe_autowaypoints_lastwp1;
2396 void botframe_autowaypoints()
2397 {
2398         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2399                 // going back is broken, so only fix waypoints to walk TO the player
2400                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2401                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2402                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2403         });
2404
2405         if (autocvar_g_waypointeditor_auto >= 2) {
2406                 botframe_deleteuselesswaypoints();
2407         }
2408 }
2409