qcsrc/server/bot/havocbot/roles.qc

   1
   2 .float max_armorvalue;
   3 .float havocbot_role_timeout;
   4
   5 .void() havocbot_previous_role;
   6 .void() havocbot_role;
   7
   8 void havocbot_goalrating_items(float ratingscale, vector org, float sradius)
   9 {
  10         entity head;
  11         entity player;
  12         float rating, d, discard, distance, friend_distance, enemy_distance;
  13         vector o;
  14         ratingscale = ratingscale * 0.0001; // items are rated around 10000 already
  15         head = findchainfloat(bot_pickup, TRUE);
  16
  17         while (head)
  18         {
  19                 o = (head.absmin + head.absmax) * 0.5;
  20                 distance = vlen(o - org);
  21                 friend_distance = 10000; enemy_distance = 10000;
  22                 rating = 0;
  23
  24                 if(!head.solid || distance > sradius || (head == self.ignoregoal && time < self.ignoregoaltime) )
  25                 {
  26                         head = head.chain;
  27                         continue;
  28                 }
  29
  30                 // Check if the item can be picked up safely
  31                 if(head.classname == "droppedweapon")
  32                 {
  33                         traceline(o, o + '0 0 -1500', TRUE, world);
  34
  35                         d = pointcontents(trace_endpos + '0 0 1');
  36                         if(d & CONTENT_WATER || d & CONTENT_SLIME || d & CONTENT_LAVA)
  37                         {
  38                                 head = head.chain;
  39                                 continue;
  40                         }
  41                         if(tracebox_hits_trigger_hurt(head.origin, head.mins, head.maxs, trace_endpos))
  42                         {
  43                                 head = head.chain;
  44                                 continue;
  45                         }
  46                 }
  47                 else
  48                 {
  49                         // Ignore items under water
  50                         traceline(head.origin + head.maxs, head.origin + head.maxs, MOVE_NORMAL, head);
  51                         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  52                         {
  53                                 head = head.chain;
  54                                 continue;
  55                         }
  56                 }
  57
  58                 if(teamplay)
  59                 {
  60                         discard = FALSE;
  61
  62                         FOR_EACH_PLAYER(player)
  63                         {
  64
  65                                 if ( self == player || player.deadflag )
  66                                         continue;
  67
  68                                 d = vlen(player.origin - o); // distance between player and item
  69
  70                                 if ( player.team == self.team )
  71                                 {
  72                                         if ( clienttype(player) != CLIENTTYPE_REAL || discard )
  73                                                 continue;
  74
  75                                         if( d > friend_distance)
  76                                                 continue;
  77
  78                                         friend_distance = d;
  79
  80                                         discard = TRUE;
  81
  82                                         if( head.health && player.health > self.health )
  83                                                 continue;
  84
  85                                         if( head.armorvalue && player.armorvalue > self.armorvalue)
  86                                                 continue;
  87
  88                                         if( head.weapons )
  89                                         if( (player.weapons & head.weapons) != head.weapons)
  90                                                 continue;
  91
  92                                         if (head.ammo_shells && player.ammo_shells > self.ammo_shells)
  93                                                 continue;
  94
  95                                         if (head.ammo_nails && player.ammo_nails > self.ammo_nails)
  96                                                 continue;
  97
  98                                         if (head.ammo_rockets && player.ammo_rockets > self.ammo_rockets)
  99                                                 continue;
 100
 101                                         if (head.ammo_cells && player.ammo_cells > self.ammo_cells )
 102                                                 continue;
 103
 104                                         discard = FALSE;
 105                                 }
 106                                 else
 107                                 {
 108                                         // If enemy only track distances
 109                                         // TODO: track only if visible ?
 110                                         if( d < enemy_distance )
 111                                                 enemy_distance = d;
 112                                 }
 113                         }
 114
 115                         // Rate the item only if no one needs it, or if an enemy is closer to it
 116                         if ( (enemy_distance < friend_distance && distance < enemy_distance) ||
 117                                 (friend_distance > autocvar_bot_ai_friends_aware_pickup_radius ) || !discard )
 118                                 rating = head.bot_pickupevalfunc(self, head);
 119
 120                 }
 121                 else
 122                         rating = head.bot_pickupevalfunc(self, head);
 123
 124                 if(rating > 0)
 125                         navigation_routerating(head, rating * ratingscale, 2000);
 126                 head = head.chain;
 127         }
 128 }
 129
 130 void havocbot_goalrating_controlpoints(float ratingscale, vector org, float sradius)
 131 {
 132         entity head;
 133         head = findchain(classname, "dom_controlpoint");
 134         while (head)
 135         {
 136                 if (vlen(( ( head.absmin + head.absmax ) * 0.5 ) - org) < sradius)
 137                 {
 138                         if(head.cnt > -1) // this is just being fought for
 139                                 navigation_routerating(head, ratingscale, 5000);
 140                         else if(head.goalentity.cnt == 0) // unclaimed point
 141                                 navigation_routerating(head, ratingscale * 0.5, 5000);
 142                         else if(head.goalentity.team != self.team) // other team's point
 143                                 navigation_routerating(head, ratingscale * 0.2, 5000);
 144                 }
 145                 head = head.chain;
 146         }
 147 }
 148
 149 void havocbot_goalrating_enemyplayers(float ratingscale, vector org, float sradius)
 150 {
 151         entity head;
 152         float t, noteam, distance;
 153         noteam = ((self.team == 0) || !teamplay); // fteqcc sucks
 154
 155         if (autocvar_bot_nofire)
 156                 return;
 157
 158         // don't chase players if we're under water
 159         if(self.waterlevel>WATERLEVEL_WETFEET)
 160                 return;
 161
 162         FOR_EACH_PLAYER(head)
 163         {
 164                 // TODO: Merge this logic with the bot_shouldattack function
 165                 if(bot_shouldattack(head))
 166                 {
 167                         distance = vlen(head.origin - org);
 168                         if (distance < 100 || distance > sradius)
 169                                 continue;
 170
 171                         // rate only visible enemies
 172                         /*
 173                         traceline(self.origin + self.view_ofs, head.origin, MOVE_NOMONSTERS, self);
 174                         if (trace_fraction < 1 || trace_ent != head)
 175                                 continue;
 176                         */
 177
 178                         if(head.flags & FL_INWATER || head.flags & FL_PARTIALGROUND)
 179                                 continue;
 180
 181                         // not falling
 182                         if(head.flags & FL_ONGROUND == 0)
 183                         {
 184                                 traceline(head.origin, head.origin + '0 0 -1500', TRUE, world);
 185                                 t = pointcontents(trace_endpos + '0 0 1');
 186                                 if( t != CONTENT_SOLID )
 187                                 if(t & CONTENT_WATER || t & CONTENT_SLIME || t & CONTENT_LAVA)
 188                                         continue;
 189                                 if(tracebox_hits_trigger_hurt(head.origin, head.mins, head.maxs, trace_endpos))
 190                                         continue;
 191                         }
 192
 193                         // TODO: rate waypoints near the targetted player at that moment, instead of the player itself
 194                         //               adding a player as a goal seems to be quite dangerous, especially on space maps
 195                         //               remove hack in navigation_poptouchedgoals() after performing this change
 196
 197                         t = (self.health + self.armorvalue ) / (head.health + head.armorvalue );
 198                         navigation_routerating(head, t * ratingscale, 2000);
 199                 }
 200         }
 201 }
 202
 203 // choose a role according to the situation
 204 void havocbot_role_dm();
 205
 206 //DOM:
 207 //go to best items, or control points you don't own
 208 void havocbot_role_dom()
 209 {
 210         if(self.deadflag != DEAD_NO)
 211                 return;
 212
 213         if (self.bot_strategytime < time)
 214         {
 215                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 216                 navigation_goalrating_start();
 217                 havocbot_goalrating_controlpoints(10000, self.origin, 15000);
 218                 havocbot_goalrating_items(8000, self.origin, 8000);
 219                 //havocbot_goalrating_enemyplayers(3000, self.origin, 2000);
 220                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 221                 navigation_goalrating_end();
 222         }
 223 }
 224
 225 //DM:
 226 //go to best items
 227 void havocbot_role_dm()
 228 {
 229         if(self.deadflag != DEAD_NO)
 230                 return;
 231
 232         if (self.bot_strategytime < time)
 233         {
 234                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 235                 navigation_goalrating_start();
 236                 havocbot_goalrating_items(10000, self.origin, 10000);
 237                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 238                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 239                 navigation_goalrating_end();
 240         }
 241 }
 242
 243 //Race:
 244 //go to next checkpoint, and annoy enemies
 245 .float race_checkpoint;
 246 void havocbot_role_race()
 247 {
 248         if(self.deadflag != DEAD_NO)
 249                 return;
 250
 251         entity e;
 252         if (self.bot_strategytime < time)
 253         {
 254                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 255                 navigation_goalrating_start();
 256                 /*
 257                 havocbot_goalrating_items(100, self.origin, 10000);
 258                 havocbot_goalrating_enemyplayers(500, self.origin, 20000);
 259                 */
 260
 261                 for(e = world; (e = find(e, classname, "trigger_race_checkpoint")) != world; )
 262                 {
 263                         if(e.cnt == self.race_checkpoint)
 264                         {
 265                                 navigation_routerating(e, 1000000, 5000);
 266                         }
 267                         else if(self.race_checkpoint == -1)
 268                         {
 269                                 navigation_routerating(e, 1000000, 5000);
 270                         }
 271                 }
 272
 273                 navigation_goalrating_end();
 274         }
 275 }
 276
 277 void havocbot_chooserole_dm()
 278 {
 279         self.havocbot_role = havocbot_role_dm;
 280 }
 281
 282 void havocbot_chooserole_race()
 283 {
 284         self.havocbot_role = havocbot_role_race;
 285 }
 286
 287 void havocbot_chooserole_dom()
 288 {
 289         self.havocbot_role = havocbot_role_dom;
 290 }
 291
 292 void havocbot_chooserole()
 293 {
 294         dprint("choosing a role...\n");
 295         self.bot_strategytime = 0;
 296         if (g_ctf)
 297                 havocbot_chooserole_ctf();
 298         else if (g_domination)
 299                 havocbot_chooserole_dom();
 300         else if (g_keyhunt)
 301                 havocbot_chooserole_kh();
 302         else if (g_race || g_cts)
 303                 havocbot_chooserole_race();
 304         else if (g_onslaught)
 305                 havocbot_chooserole_ons();
 306         else if (g_keepaway)
 307                 havocbot_chooserole_ka();
 308         else if (g_freezetag)
 309                 havocbot_chooserole_ft();
 310         else if (g_assault)
 311                 havocbot_chooserole_ast();
 312         else // assume anything else is deathmatch
 313                 havocbot_chooserole_dm();
 314 }