qcsrc/server/bot/navigation.qc

   1
   2 // rough simulation of walking from one point to another to test if a path
   3 // can be traveled, used for waypoint linking and havocbot
   4
   5 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
   6 {
   7         vector org;
   8         vector move;
   9         vector dir;
  10         float dist;
  11         float totaldist;
  12         float stepdist;
  13         float yaw;
  14         float ignorehazards;
  15         float swimming;
  16
  17         if(autocvar_bot_debug_tracewalk)
  18         {
  19                 debugresetnodes();
  20                 debugnode(start);
  21         }
  22
  23         move = end - start;
  24         move_z = 0;
  25         org = start;
  26         dist = totaldist = vlen(move);
  27         dir = normalize(move);
  28         stepdist = 32;
  29         ignorehazards = FALSE;
  30
  31         // Analyze starting point
  32         traceline(start, start, MOVE_NORMAL, e);
  33         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  34                 ignorehazards = TRUE;
  35         else
  36         {
  37                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  38                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  39                 {
  40                         ignorehazards = TRUE;
  41                         swimming = TRUE;
  42                 }
  43         }
  44         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  45         if (trace_startsolid)
  46         {
  47                 // Bad start
  48                 if(autocvar_bot_debug_tracewalk)
  49                         debugnodestatus(start, DEBUG_NODE_FAIL);
  50
  51                 //print("tracewalk: ", vtos(start), " is a bad start\n");
  52                 return FALSE;
  53         }
  54
  55         // Movement loop
  56         yaw = vectoyaw(move);
  57         move = end - org;
  58         for (;;)
  59         {
  60                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  61                 {
  62                         // Succeeded
  63                         if(autocvar_bot_debug_tracewalk)
  64                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
  65
  66                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
  67                         return TRUE;
  68                 }
  69                 if(autocvar_bot_debug_tracewalk)
  70                         debugnode(org);
  71
  72                 if (dist <= 0)
  73                         break;
  74                 if (stepdist > dist)
  75                         stepdist = dist;
  76                 dist = dist - stepdist;
  77                 traceline(org, org, MOVE_NORMAL, e);
  78                 if (!ignorehazards)
  79                 {
  80                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  81                         {
  82                                 // hazards blocking path
  83                                 if(autocvar_bot_debug_tracewalk)
  84                                         debugnodestatus(org, DEBUG_NODE_FAIL);
  85
  86                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
  87                                 return FALSE;
  88                         }
  89                 }
  90                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  91                 {
  92                         move = normalize(end - org);
  93                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
  94
  95                         if(autocvar_bot_debug_tracewalk)
  96                                 debugnode(trace_endpos);
  97
  98                         if (trace_fraction < 1)
  99                         {
 100                                 swimming = TRUE;
 101                                 org = trace_endpos - normalize(org - trace_endpos) * stepdist;
 102                                 for(; org_z < end_z + self.maxs_z; org_z += stepdist)
 103                                 {
 104                                                 if(autocvar_bot_debug_tracewalk)
 105                                                         debugnode(org);
 106
 107                                         if(pointcontents(org) == CONTENT_EMPTY)
 108                                                         break;
 109                                 }
 110
 111                                 if not (pointcontents(org + '0 0 1') == CONTENT_EMPTY)
 112                                 {
 113                                         if(autocvar_bot_debug_tracewalk)
 114                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 115
 116                                         return FALSE;
 117                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 118                                 }
 119                                 continue;
 120
 121                         }
 122                         else
 123                                 org = trace_endpos;
 124                 }
 125                 else
 126                 {
 127                         move = dir * stepdist + org;
 128                         tracebox(org, m1, m2, move, movemode, e);
 129
 130                         if(autocvar_bot_debug_tracewalk)
 131                                 debugnode(trace_endpos);
 132
 133                         // hit something
 134                         if (trace_fraction < 1)
 135                         {
 136                                 // check if we can walk over this obstacle, possibly by jumpstepping
 137                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 138                                 if (trace_fraction < 1 || trace_startsolid)
 139                                 {
 140                                         tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 141                                         if (trace_fraction < 1 || trace_startsolid)
 142                                         {
 143                                                 if(autocvar_bot_debug_tracewalk)
 144                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 145
 146                                                 // check for doors
 147                                                 traceline( org, move, movemode, e);
 148                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 149                                                 {
 150                                                         vector nextmove;
 151                                                         move = trace_endpos;
 152                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 153                                                         {
 154                                                                 nextmove = move + (dir * stepdist);
 155                                                                 traceline( move, nextmove, movemode, e);
 156                                                                 move = nextmove;
 157                                                         }
 158                                                 }
 159                                                 else
 160                                                 {
 161                                                         if(autocvar_bot_debug_tracewalk)
 162                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 163
 164                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 165                                                         //te_explosion(trace_endpos);
 166                                                         //print(ftos(e.dphitcontentsmask), "\n");
 167                                                         return FALSE; // failed
 168                                                 }
 169                                         }
 170                                         else
 171                                                 move = trace_endpos;
 172                                 }
 173                                 else
 174                                         move = trace_endpos;
 175                         }
 176                         else
 177                                 move = trace_endpos;
 178
 179                         // trace down from stepheight as far as possible and move there,
 180                         // if this starts in solid we try again without the stepup, and
 181                         // if that also fails we assume it is a wall
 182                         // (this is the same logic as the Quake walkmove function used)
 183                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 184
 185                         // moved successfully
 186                         if(swimming)
 187                         {
 188                                 float c;
 189                                 c = pointcontents(org + '0 0 1');
 190                                 if not(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME)
 191                                         swimming = FALSE;
 192                                 else
 193                                         continue;
 194                         }
 195
 196                         org = trace_endpos;
 197                 }
 198         }
 199
 200         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 201
 202         // moved but didn't arrive at the intended destination
 203         if(autocvar_bot_debug_tracewalk)
 204                 debugnodestatus(org, DEBUG_NODE_FAIL);
 205
 206         return FALSE;
 207 }
 208
 209 /////////////////////////////////////////////////////////////////////////////
 210 // goal stack
 211 /////////////////////////////////////////////////////////////////////////////
 212
 213 // completely empty the goal stack, used when deciding where to go
 214 void navigation_clearroute()
 215 {
 216         //print("bot ", etos(self), " clear\n");
 217         self.navigation_hasgoals = FALSE;
 218         self.goalcurrent = world;
 219         self.goalstack01 = world;
 220         self.goalstack02 = world;
 221         self.goalstack03 = world;
 222         self.goalstack04 = world;
 223         self.goalstack05 = world;
 224         self.goalstack06 = world;
 225         self.goalstack07 = world;
 226         self.goalstack08 = world;
 227         self.goalstack09 = world;
 228         self.goalstack10 = world;
 229         self.goalstack11 = world;
 230         self.goalstack12 = world;
 231         self.goalstack13 = world;
 232         self.goalstack14 = world;
 233         self.goalstack15 = world;
 234         self.goalstack16 = world;
 235         self.goalstack17 = world;
 236         self.goalstack18 = world;
 237         self.goalstack19 = world;
 238         self.goalstack20 = world;
 239         self.goalstack21 = world;
 240         self.goalstack22 = world;
 241         self.goalstack23 = world;
 242         self.goalstack24 = world;
 243         self.goalstack25 = world;
 244         self.goalstack26 = world;
 245         self.goalstack27 = world;
 246         self.goalstack28 = world;
 247         self.goalstack29 = world;
 248         self.goalstack30 = world;
 249         self.goalstack31 = world;
 250 }
 251
 252 // add a new goal at the beginning of the stack
 253 // (in other words: add a new prerequisite before going to the later goals)
 254 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 255 // next-closest WP on the shortest path to the WP
 256 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 257 // steps to the goal, and then recalculate the path.
 258 void navigation_pushroute(entity e)
 259 {
 260         //print("bot ", etos(self), " push ", etos(e), "\n");
 261         self.goalstack31 = self.goalstack30;
 262         self.goalstack30 = self.goalstack29;
 263         self.goalstack29 = self.goalstack28;
 264         self.goalstack28 = self.goalstack27;
 265         self.goalstack27 = self.goalstack26;
 266         self.goalstack26 = self.goalstack25;
 267         self.goalstack25 = self.goalstack24;
 268         self.goalstack24 = self.goalstack23;
 269         self.goalstack23 = self.goalstack22;
 270         self.goalstack22 = self.goalstack21;
 271         self.goalstack21 = self.goalstack20;
 272         self.goalstack20 = self.goalstack19;
 273         self.goalstack19 = self.goalstack18;
 274         self.goalstack18 = self.goalstack17;
 275         self.goalstack17 = self.goalstack16;
 276         self.goalstack16 = self.goalstack15;
 277         self.goalstack15 = self.goalstack14;
 278         self.goalstack14 = self.goalstack13;
 279         self.goalstack13 = self.goalstack12;
 280         self.goalstack12 = self.goalstack11;
 281         self.goalstack11 = self.goalstack10;
 282         self.goalstack10 = self.goalstack09;
 283         self.goalstack09 = self.goalstack08;
 284         self.goalstack08 = self.goalstack07;
 285         self.goalstack07 = self.goalstack06;
 286         self.goalstack06 = self.goalstack05;
 287         self.goalstack05 = self.goalstack04;
 288         self.goalstack04 = self.goalstack03;
 289         self.goalstack03 = self.goalstack02;
 290         self.goalstack02 = self.goalstack01;
 291         self.goalstack01 = self.goalcurrent;
 292         self.goalcurrent = e;
 293 }
 294
 295 // remove first goal from stack
 296 // (in other words: remove a prerequisite for reaching the later goals)
 297 // (used when a spawnfunc_waypoint is reached)
 298 void navigation_poproute()
 299 {
 300         //print("bot ", etos(self), " pop\n");
 301         self.goalcurrent = self.goalstack01;
 302         self.goalstack01 = self.goalstack02;
 303         self.goalstack02 = self.goalstack03;
 304         self.goalstack03 = self.goalstack04;
 305         self.goalstack04 = self.goalstack05;
 306         self.goalstack05 = self.goalstack06;
 307         self.goalstack06 = self.goalstack07;
 308         self.goalstack07 = self.goalstack08;
 309         self.goalstack08 = self.goalstack09;
 310         self.goalstack09 = self.goalstack10;
 311         self.goalstack10 = self.goalstack11;
 312         self.goalstack11 = self.goalstack12;
 313         self.goalstack12 = self.goalstack13;
 314         self.goalstack13 = self.goalstack14;
 315         self.goalstack14 = self.goalstack15;
 316         self.goalstack15 = self.goalstack16;
 317         self.goalstack16 = self.goalstack17;
 318         self.goalstack17 = self.goalstack18;
 319         self.goalstack18 = self.goalstack19;
 320         self.goalstack19 = self.goalstack20;
 321         self.goalstack20 = self.goalstack21;
 322         self.goalstack21 = self.goalstack22;
 323         self.goalstack22 = self.goalstack23;
 324         self.goalstack23 = self.goalstack24;
 325         self.goalstack24 = self.goalstack25;
 326         self.goalstack25 = self.goalstack26;
 327         self.goalstack26 = self.goalstack27;
 328         self.goalstack27 = self.goalstack28;
 329         self.goalstack28 = self.goalstack29;
 330         self.goalstack29 = self.goalstack30;
 331         self.goalstack30 = self.goalstack31;
 332         self.goalstack31 = world;
 333 }
 334
 335 float navigation_waypoint_will_link(vector v, vector org, entity ent, float walkfromwp, float bestdist)
 336 {
 337         float dist;
 338         dist = vlen(v - org);
 339         if (bestdist > dist)
 340         {
 341                 traceline(v, org, TRUE, ent);
 342                 if (trace_fraction == 1)
 343                 {
 344                         if (walkfromwp)
 345                         {
 346                                 if (tracewalk(ent, v, PL_MIN, PL_MAX, org, bot_navigation_movemode))
 347                                         return TRUE;
 348                         }
 349                         else
 350                         {
 351                                 if (tracewalk(ent, org, PL_MIN, PL_MAX, v, bot_navigation_movemode))
 352                                         return TRUE;
 353                         }
 354                 }
 355         }
 356         return FALSE;
 357 }
 358
 359 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 360 entity navigation_findnearestwaypoint_withdist(entity ent, float walkfromwp, float bestdist)
 361 {
 362         entity waylist, w, best;
 363         vector v, org, pm1, pm2;
 364
 365         pm1 = ent.origin + ent.mins;
 366         pm2 = ent.origin + ent.maxs;
 367         waylist = findchain(classname, "waypoint");
 368
 369         // do two scans, because box test is cheaper
 370         w = waylist;
 371         while (w)
 372         {
 373                 // if object is touching spawnfunc_waypoint
 374                 if(w != ent)
 375                         if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
 376                                 return w;
 377                 w = w.chain;
 378         }
 379
 380         org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 381         org_z = ent.origin_z + ent.mins_z - PL_MIN_z; // player height
 382         // TODO possibly make other code have the same support for bboxes
 383         if(ent.tag_entity)
 384                 org = org + ent.tag_entity.origin;
 385         if (navigation_testtracewalk)
 386                 te_plasmaburn(org);
 387
 388         best = world;
 389
 390         // box check failed, try walk
 391         w = waylist;
 392         while (w)
 393         {
 394                 // if object can walk from spawnfunc_waypoint
 395                 if(w != ent)
 396                 {
 397                         if (w.wpisbox)
 398                         {
 399                                 vector wm1, wm2;
 400                                 wm1 = w.origin + w.mins;
 401                                 wm2 = w.origin + w.maxs;
 402                                 v_x = bound(wm1_x, org_x, wm2_x);
 403                                 v_y = bound(wm1_y, org_y, wm2_y);
 404                                 v_z = bound(wm1_z, org_z, wm2_z);
 405                         }
 406                         else
 407                                 v = w.origin;
 408                         if(navigation_waypoint_will_link(v, org, ent, walkfromwp, bestdist))
 409                         {
 410                                 bestdist = vlen(v - org);
 411                                 best = w;
 412                         }
 413                 }
 414                 w = w.chain;
 415         }
 416         return best;
 417 }
 418 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 419 {
 420         return navigation_findnearestwaypoint_withdist(ent, walkfromwp, 1050);
 421 }
 422
 423 // finds the waypoints near the bot initiating a navigation query
 424 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
 425 {
 426         entity head;
 427         vector v, m1, m2, diff;
 428         float c;
 429 //      navigation_testtracewalk = TRUE;
 430         c = 0;
 431         head = waylist;
 432         while (head)
 433         {
 434                 if (!head.wpconsidered)
 435                 {
 436                         if (head.wpisbox)
 437                         {
 438                                 m1 = head.origin + head.mins;
 439                                 m2 = head.origin + head.maxs;
 440                                 v = self.origin;
 441                                 v_x = bound(m1_x, v_x, m2_x);
 442                                 v_y = bound(m1_y, v_y, m2_y);
 443                                 v_z = bound(m1_z, v_z, m2_z);
 444                         }
 445                         else
 446                                 v = head.origin;
 447                         diff = v - self.origin;
 448                         diff_z = max(0, diff_z);
 449                         if (vlen(diff) < maxdist)
 450                         {
 451                                 head.wpconsidered = TRUE;
 452                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, bot_navigation_movemode))
 453                                 {
 454                                         head.wpnearestpoint = v;
 455                                         head.wpcost = vlen(v - self.origin) + head.dmg;
 456                                         head.wpfire = 1;
 457                                         head.enemy = world;
 458                                         c = c + 1;
 459                                 }
 460                         }
 461                 }
 462                 head = head.chain;
 463         }
 464         //navigation_testtracewalk = FALSE;
 465         return c;
 466 }
 467
 468 // updates a path link if a spawnfunc_waypoint link is better than the current one
 469 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
 470 {
 471         vector m1;
 472         vector m2;
 473         vector v;
 474         if (wp.wpisbox)
 475         {
 476                 m1 = wp.absmin;
 477                 m2 = wp.absmax;
 478                 v_x = bound(m1_x, p_x, m2_x);
 479                 v_y = bound(m1_y, p_y, m2_y);
 480                 v_z = bound(m1_z, p_z, m2_z);
 481         }
 482         else
 483                 v = wp.origin;
 484         cost2 = cost2 + vlen(v - p);
 485         if (wp.wpcost > cost2)
 486         {
 487                 wp.wpcost = cost2;
 488                 wp.enemy = w;
 489                 wp.wpfire = 1;
 490                 wp.wpnearestpoint = v;
 491         }
 492 }
 493
 494 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 495 void navigation_markroutes(entity fixed_source_waypoint)
 496 {
 497         entity w, wp, waylist;
 498         float searching, cost, cost2;
 499         vector p;
 500         w = waylist = findchain(classname, "waypoint");
 501         while (w)
 502         {
 503                 w.wpconsidered = FALSE;
 504                 w.wpnearestpoint = '0 0 0';
 505                 w.wpcost = 10000000;
 506                 w.wpfire = 0;
 507                 w.enemy = world;
 508                 w = w.chain;
 509         }
 510
 511         if(fixed_source_waypoint)
 512         {
 513                 fixed_source_waypoint.wpconsidered = TRUE;
 514                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 515                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 516                 fixed_source_waypoint.wpfire = 1;
 517                 fixed_source_waypoint.enemy = world;
 518         }
 519         else
 520         {
 521                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 522                 // as this search is expensive we will use lower values if the bot is on the air
 523                 float i, increment, maxdistance;
 524                 if(self.flags & FL_ONGROUND)
 525                 {
 526                         increment = 750;
 527                         maxdistance = 50000;
 528                 }
 529                 else
 530                 {
 531                         increment = 500;
 532                         maxdistance = 1500;
 533                 }
 534
 535                 for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
 536         }
 537
 538         searching = TRUE;
 539         while (searching)
 540         {
 541                 searching = FALSE;
 542                 w = waylist;
 543                 while (w)
 544                 {
 545                         if (w.wpfire)
 546                         {
 547                                 searching = TRUE;
 548                                 w.wpfire = 0;
 549                                 cost = w.wpcost;
 550                                 p = w.wpnearestpoint;
 551                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 552                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 553                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 554                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 555                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 556                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 557                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 558                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 559                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 560                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 561                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 562                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 563                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 564                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 565                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 566                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 567                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 568                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 569                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 570                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 571                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 572                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 573                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 574                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 575                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 576                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 577                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 578                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 579                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 580                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 581                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 582                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 583                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 584                         }
 585                         w = w.chain;
 586                 }
 587         }
 588 }
 589
 590 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 591 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 592 {
 593         entity w, wp, waylist;
 594         float searching, cost, cost2;
 595         vector p;
 596         w = waylist = findchain(classname, "waypoint");
 597         while (w)
 598         {
 599                 w.wpconsidered = FALSE;
 600                 w.wpnearestpoint = '0 0 0';
 601                 w.wpcost = 10000000;
 602                 w.wpfire = 0;
 603                 w.enemy = world;
 604                 w = w.chain;
 605         }
 606
 607         if(fixed_source_waypoint)
 608         {
 609                 fixed_source_waypoint.wpconsidered = TRUE;
 610                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 611                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 612                 fixed_source_waypoint.wpfire = 1;
 613                 fixed_source_waypoint.enemy = world;
 614         }
 615         else
 616         {
 617                 error("need to start with a waypoint\n");
 618         }
 619
 620         searching = TRUE;
 621         while (searching)
 622         {
 623                 searching = FALSE;
 624                 w = waylist;
 625                 while (w)
 626                 {
 627                         if (w.wpfire)
 628                         {
 629                                 searching = TRUE;
 630                                 w.wpfire = 0;
 631                                 cost = w.wpcost; // cost to walk from w to home
 632                                 p = w.wpnearestpoint;
 633                                 for(wp = waylist; wp; wp = wp.chain)
 634                                 {
 635                                         if(w != wp.wp00) if(w != wp.wp01) if(w != wp.wp02) if(w != wp.wp03)
 636                                         if(w != wp.wp04) if(w != wp.wp05) if(w != wp.wp06) if(w != wp.wp07)
 637                                         if(w != wp.wp08) if(w != wp.wp09) if(w != wp.wp10) if(w != wp.wp11)
 638                                         if(w != wp.wp12) if(w != wp.wp13) if(w != wp.wp14) if(w != wp.wp15)
 639                                         if(w != wp.wp16) if(w != wp.wp17) if(w != wp.wp18) if(w != wp.wp19)
 640                                         if(w != wp.wp20) if(w != wp.wp21) if(w != wp.wp22) if(w != wp.wp23)
 641                                         if(w != wp.wp24) if(w != wp.wp25) if(w != wp.wp26) if(w != wp.wp27)
 642                                         if(w != wp.wp28) if(w != wp.wp29) if(w != wp.wp30) if(w != wp.wp31)
 643                                                 continue;
 644                                         cost2 = cost + wp.dmg;
 645                                         navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 646                                 }
 647                         }
 648                         w = w.chain;
 649                 }
 650         }
 651 }
 652
 653 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 654 void navigation_routerating(entity e, float f, float rangebias)
 655 {
 656         entity nwp;
 657         vector o;
 658         if (!e)
 659                 return;
 660
 661         if(e.blacklisted)
 662                 return;
 663
 664         o = (e.absmin + e.absmax) * 0.5;
 665
 666         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
 667
 668         // Evaluate path using jetpack
 669         if(g_jetpack)
 670         if(self.items & IT_JETPACK)
 671         if(autocvar_bot_ai_navigation_jetpack)
 672         if(vlen(self.origin - o) > autocvar_bot_ai_navigation_jetpack_mindistance)
 673         {
 674                 vector pointa, pointb;
 675
 676         //      dprint("jetpack ai: evaluating path for ", e.classname,"\n");
 677
 678                 // Point A
 679                 traceline(self.origin, self.origin + '0 0 65535', MOVE_NORMAL, self);
 680                 pointa = trace_endpos - '0 0 1';
 681
 682                 // Point B
 683                 traceline(o, o + '0 0 65535', MOVE_NORMAL, e);
 684                 pointb = trace_endpos - '0 0 1';
 685
 686                 // Can I see these two points from the sky?
 687                 traceline(pointa, pointb, MOVE_NORMAL, self);
 688
 689                 if(trace_fraction==1)
 690                 {
 691                 //      dprint("jetpack ai: can bridge these two points\n");
 692
 693                         // Lower the altitude of these points as much as possible
 694                         float zdistance, xydistance, cost, t, fuel;
 695                         vector down, npa, npb;
 696
 697                         down = '0 0 -1' * (PL_MAX_z - PL_MIN_z) * 10;
 698
 699                         do{
 700                                 npa = pointa + down;
 701                                 npb = pointb + down;
 702
 703                                 if(npa_z<=self.absmax_z)
 704                                         break;
 705
 706                                 if(npb_z<=e.absmax_z)
 707                                         break;
 708
 709                                 traceline(npa, npb, MOVE_NORMAL, self);
 710                                 if(trace_fraction==1)
 711                                 {
 712                                         pointa = npa;
 713                                         pointb = npb;
 714                                 }
 715                         }
 716                         while(trace_fraction == 1);
 717
 718
 719                         // Rough estimation of fuel consumption
 720                         // (ignores acceleration and current xyz velocity)
 721                         xydistance = vlen(pointa - pointb);
 722                         zdistance = fabs(pointa_z - self.origin_z);
 723
 724                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
 725                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
 726                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
 727
 728                 //      dprint("jetpack ai: required fuel ", ftos(fuel), " self.ammo_fuel ", ftos(self.ammo_fuel),"\n");
 729
 730                         // enough fuel ?
 731                         if(self.ammo_fuel>fuel)
 732                         {
 733                                 // Estimate cost
 734                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 735                                 //  - between air and ground speeds)
 736
 737                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
 738                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
 739                                 cost *= 1.5;
 740
 741                                 // Compare against other goals
 742                                 f = f * rangebias / (rangebias + cost);
 743
 744                                 if (navigation_bestrating < f)
 745                                 {
 746                         //              dprint("jetpack path: added goal", e.classname, " (with rating ", ftos(f), ")\n");
 747                                         navigation_bestrating = f;
 748                                         navigation_bestgoal = e;
 749                                         self.navigation_jetpack_goal = e;
 750                                         self.navigation_jetpack_point = pointb;
 751                                 }
 752                                 return;
 753                         }
 754                 }
 755         }
 756
 757         //te_wizspike(e.origin);
 758         //bprint(etos(e));
 759         //bprint("\n");
 760         // update the cached spawnfunc_waypoint link on a dynamic item entity
 761         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 762         {
 763                 nwp = e;
 764         }
 765         else
 766         {
 767                 float search;
 768
 769                 search = TRUE;
 770
 771                 if(e.flags & FL_ITEM)
 772                 {
 773                         if not(e.flags & FL_WEAPON)
 774                         if(e.nearestwaypoint)
 775                                 search = FALSE;
 776                 }
 777                 else if (e.flags & FL_WEAPON)
 778                 {
 779                         if(e.classname != "droppedweapon")
 780                         if(e.nearestwaypoint)
 781                                 search = FALSE;
 782                 }
 783
 784                 if(search)
 785                 if (time > e.nearestwaypointtimeout)
 786                 {
 787                         nwp = navigation_findnearestwaypoint(e, TRUE);
 788                         if(nwp)
 789                                 e.nearestwaypoint = nwp;
 790                         else
 791                         {
 792                                 dprint("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e), "\n");
 793
 794                                 if(e.flags & FL_ITEM)
 795                                         e.blacklisted = TRUE;
 796                                 else if (e.flags & FL_WEAPON)
 797                                 {
 798                                         if(e.classname != "droppedweapon")
 799                                                 e.blacklisted = TRUE;
 800                                 }
 801
 802                                 if(e.blacklisted)
 803                                 {
 804                                         dprint("The entity '", e.classname, "' is going to be excluded from path finding during this match\n");
 805                                         return;
 806                                 }
 807                         }
 808
 809                         // TODO: Cleaner solution, probably handling this timeout from ctf.qc
 810                         if(e.classname=="item_flag_team")
 811                                 e.nearestwaypointtimeout = time + 2;
 812                         else
 813                                 e.nearestwaypointtimeout = time + random() * 3 + 5;
 814                 }
 815                 nwp = e.nearestwaypoint;
 816         }
 817
 818         //dprint("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")\n");
 819         if (nwp)
 820         if (nwp.wpcost < 10000000)
 821         {
 822                 //te_wizspike(nwp.wpnearestpoint);
 823         //      dprint(e.classname, " ", ftos(f), "/(1+", ftos((nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint))), "/", ftos(rangebias), ") = ");
 824                 f = f * rangebias / (rangebias + (nwp.wpcost + vlen(o - nwp.wpnearestpoint)));
 825                 //dprint("considering ", e.classname, " (with rating ", ftos(f), ")\n");
 826                 //dprint(ftos(f));
 827                 if (navigation_bestrating < f)
 828                 {
 829                 //      dprint("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")\n");
 830                         navigation_bestrating = f;
 831                         navigation_bestgoal = e;
 832                 }
 833         }
 834         //dprint("\n");
 835 }
 836
 837 // adds an item to the the goal stack with the path to a given item
 838 float navigation_routetogoal(entity e, vector startposition)
 839 {
 840         self.goalentity = e;
 841
 842         // if there is no goal, just exit
 843         if (!e)
 844                 return FALSE;
 845
 846         self.navigation_hasgoals = TRUE;
 847
 848         // put the entity on the goal stack
 849         //print("routetogoal ", etos(e), "\n");
 850         navigation_pushroute(e);
 851
 852         if(g_jetpack)
 853         if(e==self.navigation_jetpack_goal)
 854                 return TRUE;
 855
 856         // if it can reach the goal there is nothing more to do
 857         if (tracewalk(self, startposition, PL_MIN, PL_MAX, (e.absmin + e.absmax) * 0.5, bot_navigation_movemode))
 858                 return TRUE;
 859
 860         // see if there are waypoints describing a path to the item
 861         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
 862                 e = e.nearestwaypoint;
 863         else
 864                 e = e.enemy; // we already have added it, so...
 865
 866         if(e == world)
 867                 return FALSE;
 868
 869         for (;;)
 870         {
 871                 // add the spawnfunc_waypoint to the path
 872                 navigation_pushroute(e);
 873                 e = e.enemy;
 874
 875                 if(e==world)
 876                         break;
 877         }
 878
 879         return FALSE;
 880 }
 881
 882 // removes any currently touching waypoints from the goal stack
 883 // (this is how bots detect if they reached a goal)
 884 void navigation_poptouchedgoals()
 885 {
 886         vector org, m1, m2;
 887         org = self.origin;
 888         m1 = org + self.mins;
 889         m2 = org + self.maxs;
 890
 891         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 892         {
 893                 if(self.lastteleporttime>0)
 894                 if(time-self.lastteleporttime<(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL)?2:0.15)
 895                 {
 896                         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 897                         if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 898                         {
 899                                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 900                                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 901                         }
 902                         navigation_poproute();
 903                         return;
 904                 }
 905         }
 906
 907         // If for some reason the bot is closer to the next goal, pop the current one
 908         if(self.goalstack01)
 909         if(vlen(self.goalcurrent.origin - self.origin) > vlen(self.goalstack01.origin - self.origin))
 910         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 911         if(tracewalk(self, self.origin, self.mins, self.maxs, (self.goalstack01.absmin + self.goalstack01.absmax) * 0.5, bot_navigation_movemode))
 912         {
 913         ///     dprint("path optimized for ", self.netname, ", removed a goal from the queue\n");
 914                 navigation_poproute();
 915                 // TODO this may also be a nice idea to do "early" (e.g. by
 916                 // manipulating the vlen() comparisons) to shorten paths in
 917                 // general - this would make bots walk more "on rails" than
 918                 // "zigzagging" which they currently do with sufficiently
 919                 // random-like waypoints, and thus can make a nice bot
 920                 // personality property
 921         }
 922
 923         // HACK: remove players/bots as goals, they can lead a bot to unexpected places (cliffs, lava, etc)
 924         // TODO: rate waypoints near the targetted player at that moment, instead of the player itself
 925         if(self.goalcurrent.classname=="player")
 926                 navigation_poproute();
 927
 928         // aid for detecting jump pads better (distance based check fails sometimes)
 929         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT && self.jumppadcount > 0 )
 930                 navigation_poproute();
 931
 932         // Loose goal touching check when running
 933         if(self.aistatus & AI_STATUS_RUNNING)
 934         if(self.speed >= autocvar_sv_maxspeed) // if -really- running
 935         if(self.goalcurrent.classname=="waypoint")
 936         {
 937                 if(vlen(self.origin - self.goalcurrent.origin)<150)
 938                 {
 939                         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
 940                         if(trace_fraction==1)
 941                         {
 942                                 // Detect personal waypoints
 943                                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 944                                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 945                                 {
 946                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 947                                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 948                                 }
 949
 950                                 navigation_poproute();
 951                         }
 952                 }
 953         }
 954
 955         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
 956         {
 957                 // Detect personal waypoints
 958                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 959                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 960                 {
 961                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 962                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 963                 }
 964
 965                 navigation_poproute();
 966         }
 967 }
 968
 969 // begin a goal selection session (queries spawnfunc_waypoint network)
 970 void navigation_goalrating_start()
 971 {
 972         if(self.aistatus & AI_STATUS_STUCK)
 973                 return;
 974
 975         self.navigation_jetpack_goal = world;
 976         navigation_bestrating = -1;
 977         self.navigation_hasgoals = FALSE;
 978         navigation_clearroute();
 979         navigation_bestgoal = world;
 980         navigation_markroutes(world);
 981 }
 982
 983 // ends a goal selection session (updates goal stack to the best goal)
 984 void navigation_goalrating_end()
 985 {
 986         if(self.aistatus & AI_STATUS_STUCK)
 987                 return;
 988
 989         navigation_routetogoal(navigation_bestgoal, self.origin);
 990 //      dprint("best goal ", self.goalcurrent.classname , "\n");
 991
 992         // If the bot got stuck then try to reach the farthest waypoint
 993         if not (self.navigation_hasgoals)
 994         if (autocvar_bot_wander_enable)
 995         {
 996                 if not(self.aistatus & AI_STATUS_STUCK)
 997                 {
 998                         dprint(self.netname, " cannot walk to any goal\n");
 999                         self.aistatus |= AI_STATUS_STUCK;
1000                 }
1001
1002                 self.navigation_hasgoals = FALSE; // Reset this value
1003         }
1004 }
1005
1006 void botframe_updatedangerousobjects(float maxupdate)
1007 {
1008         entity head, bot_dodgelist;
1009         vector m1, m2, v, o;
1010         float c, d, danger;
1011         c = 0;
1012         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
1013         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
1014         while (botframe_dangerwaypoint != world)
1015         {
1016                 danger = 0;
1017                 m1 = botframe_dangerwaypoint.mins;
1018                 m2 = botframe_dangerwaypoint.maxs;
1019                 head = bot_dodgelist;
1020                 while (head)
1021                 {
1022                         v = head.origin;
1023                         v_x = bound(m1_x, v_x, m2_x);
1024                         v_y = bound(m1_y, v_y, m2_y);
1025                         v_z = bound(m1_z, v_z, m2_z);
1026                         o = (head.absmin + head.absmax) * 0.5;
1027                         d = head.bot_dodgerating - vlen(o - v);
1028                         if (d > 0)
1029                         {
1030                                 traceline(o, v, TRUE, world);
1031                                 if (trace_fraction == 1)
1032                                         danger = danger + d;
1033                         }
1034                         head = head.chain;
1035                 }
1036                 botframe_dangerwaypoint.dmg = danger;
1037                 c = c + 1;
1038                 if (c >= maxupdate)
1039                         break;
1040                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
1041         }
1042 }
1043
1044 void navigation_unstuck()
1045 {
1046         float search_radius = 1000;
1047
1048         if not(autocvar_bot_wander_enable)
1049                 return;
1050
1051         if not(bot_waypoint_queue_owner)
1052         {
1053         //      dprint(self.netname, " sutck, taking over the waypoints queue\n");
1054                 bot_waypoint_queue_owner = self;
1055                 bot_waypoint_queue_bestgoal = world;
1056                 bot_waypoint_queue_bestgoalrating = 0;
1057         }
1058
1059         if(bot_waypoint_queue_owner!=self)
1060                 return;
1061
1062         if (bot_waypoint_queue_goal)
1063         {
1064                 // evaluate the next goal on the queue
1065                 float d = vlen(self.origin - bot_waypoint_queue_goal.origin);
1066                 // dprint(self.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d), "\n");
1067                 if(tracewalk(bot_waypoint_queue_goal, self.origin, PL_MIN, PL_MAX, bot_waypoint_queue_goal.origin, bot_navigation_movemode))
1068                 {
1069                         if( d > bot_waypoint_queue_bestgoalrating)
1070                         {
1071                                 bot_waypoint_queue_bestgoalrating = d;
1072                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1073                         }
1074                 }
1075                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1076
1077                 if not(bot_waypoint_queue_goal)
1078                 {
1079                         if (bot_waypoint_queue_bestgoal)
1080                         {
1081                                 dprint(self.netname, " stuck, reachable waypoint found, heading to it\n");
1082                                 navigation_routetogoal(bot_waypoint_queue_bestgoal, self.origin);
1083                                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1084                                 self.aistatus &~= AI_STATUS_STUCK;
1085                         }
1086                         else
1087                         {
1088                                 dprint(self.netname, " stuck, cannot walk to any waypoint at all\n");
1089                         }
1090
1091                         bot_waypoint_queue_owner = world;
1092                 }
1093         }
1094         else
1095         {
1096                 if(bot_strategytoken!=self)
1097                         return;
1098
1099                 // build a new queue
1100                 dprint(self.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu\n");
1101
1102                 entity head, first;
1103
1104                 first = world;
1105                 head = findradius(self.origin, search_radius);
1106
1107                 while(head)
1108                 {
1109                         if(head.classname=="waypoint")
1110                 //      if(!(head.wpflags & WAYPOINTFLAG_GENERATED))
1111                         {
1112                                 if(bot_waypoint_queue_goal)
1113                                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = head;
1114                                 else
1115                                         first = head;
1116
1117                                 bot_waypoint_queue_goal = head;
1118                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = world;
1119                         }
1120
1121                         head = head.chain;
1122                 }
1123
1124                 if (first)
1125                         bot_waypoint_queue_goal = first;
1126                 else
1127                 {
1128                         dprint(self.netname, " stuck, cannot walk to any waypoint at all\n");
1129                         bot_waypoint_queue_owner = world;
1130                 }
1131         }
1132 }
1133
1134 // Support for debugging tracewalk visually
1135
1136 void debugresetnodes()
1137 {
1138         debuglastnode = '0 0 0';
1139 }
1140
1141 void debugnode(vector node)
1142 {
1143         if not(self.classname=="player")
1144                 return;
1145
1146         if(debuglastnode=='0 0 0')
1147         {
1148                 debuglastnode = node;
1149                 return;
1150         }
1151
1152         te_lightning2(world, node, debuglastnode);
1153         debuglastnode = node;
1154 }
1155
1156 void debugnodestatus(vector position, float status)
1157 {
1158         vector c;
1159
1160         switch (status)
1161         {
1162                 case DEBUG_NODE_SUCCESS:
1163                         c = '0 15 0';
1164                         break;
1165                 case DEBUG_NODE_WARNING:
1166                         c = '15 15 0';
1167                         break;
1168                 case DEBUG_NODE_FAIL:
1169                         c = '15 0 0';
1170                         break;
1171                 default:
1172                         c = '15 15 15';
1173         }
1174
1175         te_customflash(position, 40,  2, c);
1176 }
1177
1178 // Support for debugging the goal stack visually
1179
1180 .float goalcounter;
1181 .vector lastposition;
1182
1183 // Debug the goal stack visually
1184 void debuggoalstack()
1185 {
1186         entity goal;
1187         vector org, go;
1188
1189         if(self.goalcounter==0)goal=self.goalcurrent;
1190         else if(self.goalcounter==1)goal=self.goalstack01;
1191         else if(self.goalcounter==2)goal=self.goalstack02;
1192         else if(self.goalcounter==3)goal=self.goalstack03;
1193         else if(self.goalcounter==4)goal=self.goalstack04;
1194         else if(self.goalcounter==5)goal=self.goalstack05;
1195         else if(self.goalcounter==6)goal=self.goalstack06;
1196         else if(self.goalcounter==7)goal=self.goalstack07;
1197         else if(self.goalcounter==8)goal=self.goalstack08;
1198         else if(self.goalcounter==9)goal=self.goalstack09;
1199         else if(self.goalcounter==10)goal=self.goalstack10;
1200         else if(self.goalcounter==11)goal=self.goalstack11;
1201         else if(self.goalcounter==12)goal=self.goalstack12;
1202         else if(self.goalcounter==13)goal=self.goalstack13;
1203         else if(self.goalcounter==14)goal=self.goalstack14;
1204         else if(self.goalcounter==15)goal=self.goalstack15;
1205         else if(self.goalcounter==16)goal=self.goalstack16;
1206         else if(self.goalcounter==17)goal=self.goalstack17;
1207         else if(self.goalcounter==18)goal=self.goalstack18;
1208         else if(self.goalcounter==19)goal=self.goalstack19;
1209         else if(self.goalcounter==20)goal=self.goalstack20;
1210         else if(self.goalcounter==21)goal=self.goalstack21;
1211         else if(self.goalcounter==22)goal=self.goalstack22;
1212         else if(self.goalcounter==23)goal=self.goalstack23;
1213         else if(self.goalcounter==24)goal=self.goalstack24;
1214         else if(self.goalcounter==25)goal=self.goalstack25;
1215         else if(self.goalcounter==26)goal=self.goalstack26;
1216         else if(self.goalcounter==27)goal=self.goalstack27;
1217         else if(self.goalcounter==28)goal=self.goalstack28;
1218         else if(self.goalcounter==29)goal=self.goalstack29;
1219         else if(self.goalcounter==30)goal=self.goalstack30;
1220         else if(self.goalcounter==31)goal=self.goalstack31;
1221
1222         if(goal==world)
1223         {
1224                 self.goalcounter = 0;
1225                 self.lastposition='0 0 0';
1226                 return;
1227         }
1228
1229         if(self.lastposition=='0 0 0')
1230                 org = self.origin;
1231         else
1232                 org = self.lastposition;
1233
1234
1235         go = ( goal.absmin + goal.absmax ) * 0.5;
1236         te_lightning2(world, org, go);
1237         self.lastposition = go;
1238
1239         self.goalcounter++;
1240 }