qcsrc/server/bot/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "bot.qh"
   4 #include "navigation.qh"
   5
   6 #include <common/state.qh>
   7
   8 #include "../antilag.qh"
   9
  10 #include <common/constants.qh>
  11
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14
  15 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  16 // them back to it as well
  17 // (suitable for spawnfunc_waypoint editor)
  18 entity waypoint_spawn(vector m1, vector m2, float f)
  19 {
  20         if(!(f & WAYPOINTFLAG_PERSONAL))
  21         {
  22                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
  23                 {
  24                         return it;
  25                 });
  26         }
  27
  28         entity w = new(waypoint);
  29         IL_PUSH(g_waypoints, w);
  30         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  31         w.wpflags = f;
  32         w.solid = SOLID_TRIGGER;
  33         setorigin(w, (m1 + m2) * 0.5);
  34         setsize(w, m1 - w.origin, m2 - w.origin);
  35         if (vlen(w.size) > 0)
  36                 w.wpisbox = true;
  37
  38         if(!w.wpisbox)
  39         {
  40                 setsize(w, STAT(PL_MIN, NULL) - '1 1 0', STAT(PL_MAX, NULL) + '1 1 0');
  41                 if(!move_out_of_solid(w))
  42                 {
  43                         if(!(f & WAYPOINTFLAG_GENERATED))
  44                         {
  45                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  46                                 remove(w);
  47                                 return NULL;
  48                         }
  49                         else
  50                         {
  51                                 if(autocvar_developer)
  52                                 {
  53                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  54                                         backtrace("Waypoint stuck");
  55                                 }
  56                         }
  57                 }
  58                 setsize(w, '0 0 0', '0 0 0');
  59         }
  60
  61         waypoint_clearlinks(w);
  62         //waypoint_schedulerelink(w);
  63
  64         if (autocvar_g_waypointeditor)
  65         {
  66                 m1 = w.mins;
  67                 m2 = w.maxs;
  68                 setmodel(w, MDL_WAYPOINT); w.effects = EF_LOWPRECISION;
  69                 setsize(w, m1, m2);
  70                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  71                         w.colormod = '1 0 0';
  72                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  73                         w.colormod = '1 1 0';
  74                 else
  75                         w.colormod = '1 1 1';
  76         }
  77         else
  78                 w.model = "";
  79
  80         return w;
  81 }
  82
  83 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  84 void waypoint_addlink(entity from, entity to)
  85 {
  86         float c;
  87
  88         if (from == to)
  89                 return;
  90         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  91                 return;
  92
  93         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  94         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  95         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  96         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  97         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
  98         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
  99         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 100         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 101
 102         if (to.wpisbox || from.wpisbox)
 103         {
 104                 // if either is a box we have to find the nearest points on them to
 105                 // calculate the distance properly
 106                 vector v1, v2, m1, m2;
 107                 v1 = from.origin;
 108                 m1 = to.absmin;
 109                 m2 = to.absmax;
 110                 v1_x = bound(m1_x, v1_x, m2_x);
 111                 v1_y = bound(m1_y, v1_y, m2_y);
 112                 v1_z = bound(m1_z, v1_z, m2_z);
 113                 v2 = to.origin;
 114                 m1 = from.absmin;
 115                 m2 = from.absmax;
 116                 v2_x = bound(m1_x, v2_x, m2_x);
 117                 v2_y = bound(m1_y, v2_y, m2_y);
 118                 v2_z = bound(m1_z, v2_z, m2_z);
 119                 v2 = to.origin;
 120                 c = vlen(v2 - v1);
 121         }
 122         else
 123                 c = vlen(to.origin - from.origin);
 124
 125         if (from.wp31mincost < c) return;
 126         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 127         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 128         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 129         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 130         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 131         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 132         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 133         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 134         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 135         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 136         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 137         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 138         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 139         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 140         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 141         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 142         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 143         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 144         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 145         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 146         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 147         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 148         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 149         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 150         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 151         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 152         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 153         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 154         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 155         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 156         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 157         from.wp00 = to;from.wp00mincost = c;return;
 158 }
 159
 160 // relink this spawnfunc_waypoint
 161 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 162 // (SLOW!)
 163 void waypoint_think(entity this)
 164 {
 165         vector sv, sm1, sm2, ev, em1, em2, dv;
 166
 167         bot_calculate_stepheightvec();
 168
 169         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 170
 171         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 172         sm1 = this.origin + this.mins;
 173         sm2 = this.origin + this.maxs;
 174         IL_EACH(g_waypoints, true,
 175         {
 176                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 177                 {
 178                         waypoint_addlink(this, it);
 179                         waypoint_addlink(it, this);
 180                 }
 181                 else
 182                 {
 183                         ++relink_total;
 184                         if(!checkpvs(this.origin, it))
 185                         {
 186                                 ++relink_pvsculled;
 187                                 continue;
 188                         }
 189                         sv = it.origin;
 190                         sv.x = bound(sm1_x, sv.x, sm2_x);
 191                         sv.y = bound(sm1_y, sv.y, sm2_y);
 192                         sv.z = bound(sm1_z, sv.z, sm2_z);
 193                         ev = this.origin;
 194                         em1 = it.origin + it.mins;
 195                         em2 = it.origin + it.maxs;
 196                         ev.x = bound(em1_x, ev.x, em2_x);
 197                         ev.y = bound(em1_y, ev.y, em2_y);
 198                         ev.z = bound(em1_z, ev.z, em2_z);
 199                         dv = ev - sv;
 200                         dv.z = 0;
 201                         if(vdist(dv, >=, 1050)) // max search distance in XY
 202                         {
 203                                 ++relink_lengthculled;
 204                                 continue;
 205                         }
 206                         navigation_testtracewalk = 0;
 207                         if (!this.wpisbox)
 208                         {
 209                                 tracebox(sv - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, false, this);
 210                                 if (!trace_startsolid)
 211                                 {
 212                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 213                                         sv = trace_endpos + '0 0 1';
 214                                 }
 215                         }
 216                         if (!it.wpisbox)
 217                         {
 218                                 tracebox(ev - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, false, it);
 219                                 if (!trace_startsolid)
 220                                 {
 221                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 222                                         ev = trace_endpos + '0 0 1';
 223                                 }
 224                         }
 225                         //traceline(this.origin, it.origin, false, NULL);
 226                         //if (trace_fraction == 1)
 227                         if (!this.wpisbox && tracewalk(this, sv, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, MOVE_NOMONSTERS))
 228                                 waypoint_addlink(this, it);
 229                         else
 230                                 relink_walkculled += 0.5;
 231                         if (!it.wpisbox && tracewalk(it, ev, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, MOVE_NOMONSTERS))
 232                                 waypoint_addlink(it, this);
 233                         else
 234                                 relink_walkculled += 0.5;
 235                 }
 236         });
 237         navigation_testtracewalk = 0;
 238         this.wplinked = true;
 239 }
 240
 241 void waypoint_clearlinks(entity wp)
 242 {
 243         // clear links to other waypoints
 244         float f;
 245         f = 10000000;
 246         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 247         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 248         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 249         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 250
 251         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 252         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 253         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 254         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 255
 256         wp.wplinked = false;
 257 }
 258
 259 // tell a spawnfunc_waypoint to relink
 260 void waypoint_schedulerelink(entity wp)
 261 {
 262         if (wp == NULL)
 263                 return;
 264         // TODO: add some sort of visible box in edit mode for box waypoints
 265         if (autocvar_g_waypointeditor)
 266         {
 267                 vector m1, m2;
 268                 m1 = wp.mins;
 269                 m2 = wp.maxs;
 270                 setmodel(wp, MDL_WAYPOINT); wp.effects = EF_LOWPRECISION;
 271                 setsize(wp, m1, m2);
 272                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 273                         wp.colormod = '1 0 0';
 274                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 275                         wp.colormod = '1 1 0';
 276                 else
 277                         wp.colormod = '1 1 1';
 278         }
 279         else
 280                 wp.model = "";
 281         wp.wpisbox = vlen(wp.size) > 0;
 282         wp.enemy = NULL;
 283         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 284                 wp.owner = NULL;
 285         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 286                 waypoint_clearlinks(wp);
 287         // schedule an actual relink on next frame
 288         setthink(wp, waypoint_think);
 289         wp.nextthink = time;
 290         wp.effects = EF_LOWPRECISION;
 291 }
 292
 293 // spawnfunc_waypoint map entity
 294 spawnfunc(waypoint)
 295 {
 296         IL_PUSH(g_waypoints, this);
 297
 298         setorigin(this, this.origin);
 299         // schedule a relink after other waypoints have had a chance to spawn
 300         waypoint_clearlinks(this);
 301         //waypoint_schedulerelink(this);
 302 }
 303
 304 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 305 void waypoint_remove(entity e)
 306 {
 307         // tell all linked waypoints that they need to relink
 308         waypoint_schedulerelink(e.wp00);
 309         waypoint_schedulerelink(e.wp01);
 310         waypoint_schedulerelink(e.wp02);
 311         waypoint_schedulerelink(e.wp03);
 312         waypoint_schedulerelink(e.wp04);
 313         waypoint_schedulerelink(e.wp05);
 314         waypoint_schedulerelink(e.wp06);
 315         waypoint_schedulerelink(e.wp07);
 316         waypoint_schedulerelink(e.wp08);
 317         waypoint_schedulerelink(e.wp09);
 318         waypoint_schedulerelink(e.wp10);
 319         waypoint_schedulerelink(e.wp11);
 320         waypoint_schedulerelink(e.wp12);
 321         waypoint_schedulerelink(e.wp13);
 322         waypoint_schedulerelink(e.wp14);
 323         waypoint_schedulerelink(e.wp15);
 324         waypoint_schedulerelink(e.wp16);
 325         waypoint_schedulerelink(e.wp17);
 326         waypoint_schedulerelink(e.wp18);
 327         waypoint_schedulerelink(e.wp19);
 328         waypoint_schedulerelink(e.wp20);
 329         waypoint_schedulerelink(e.wp21);
 330         waypoint_schedulerelink(e.wp22);
 331         waypoint_schedulerelink(e.wp23);
 332         waypoint_schedulerelink(e.wp24);
 333         waypoint_schedulerelink(e.wp25);
 334         waypoint_schedulerelink(e.wp26);
 335         waypoint_schedulerelink(e.wp27);
 336         waypoint_schedulerelink(e.wp28);
 337         waypoint_schedulerelink(e.wp29);
 338         waypoint_schedulerelink(e.wp30);
 339         waypoint_schedulerelink(e.wp31);
 340         // and now remove the spawnfunc_waypoint
 341         remove(e);
 342 }
 343
 344 // empties the map of waypoints
 345 void waypoint_removeall()
 346 {
 347         IL_EACH(g_waypoints, true,
 348         {
 349                 remove(it);
 350         });
 351 }
 352
 353 // tell all waypoints to relink
 354 // (is this useful at all?)
 355 void waypoint_schedulerelinkall()
 356 {
 357         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 358         IL_EACH(g_waypoints, true,
 359         {
 360                 waypoint_schedulerelink(it);
 361         });
 362 }
 363
 364 // Load waypoint links from file
 365 float waypoint_load_links()
 366 {
 367         string filename, s;
 368         float file, tokens, c = 0, found;
 369         entity wp_from = NULL, wp_to;
 370         vector wp_to_pos, wp_from_pos;
 371         filename = strcat("maps/", mapname);
 372         filename = strcat(filename, ".waypoints.cache");
 373         file = fopen(filename, FILE_READ);
 374
 375         if (file < 0)
 376         {
 377                 LOG_TRACE("waypoint links load from ");
 378                 LOG_TRACE(filename);
 379                 LOG_TRACE(" failed\n");
 380                 return false;
 381         }
 382
 383         while ((s = fgets(file)))
 384         {
 385                 tokens = tokenizebyseparator(s, "*");
 386
 387                 if (tokens!=2)
 388                 {
 389                         // bad file format
 390                         fclose(file);
 391                         return false;
 392                 }
 393
 394                 wp_from_pos     = stov(argv(0));
 395                 wp_to_pos       = stov(argv(1));
 396
 397                 // Search "from" waypoint
 398                 if(!wp_from || wp_from.origin!=wp_from_pos)
 399                 {
 400                         wp_from = findradius(wp_from_pos, 1);
 401                         found = false;
 402                         while(wp_from)
 403                         {
 404                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 405                                 if(wp_from.classname == "waypoint")
 406                                 {
 407                                         found = true;
 408                                         break;
 409                                 }
 410                                 wp_from = wp_from.chain;
 411                         }
 412
 413                         if(!found)
 414                         {
 415                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 416                                 continue;
 417                         }
 418
 419                 }
 420
 421                 // Search "to" waypoint
 422                 wp_to = findradius(wp_to_pos, 1);
 423                 found = false;
 424                 while(wp_to)
 425                 {
 426                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 427                         if(wp_to.classname == "waypoint")
 428                         {
 429                                 found = true;
 430                                 break;
 431                         }
 432                         wp_to = wp_to.chain;
 433                 }
 434
 435                 if(!found)
 436                 {
 437                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 438                         continue;
 439                 }
 440
 441                 ++c;
 442                 waypoint_addlink(wp_from, wp_to);
 443         }
 444
 445         fclose(file);
 446
 447         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache\n");
 448
 449         botframe_cachedwaypointlinks = true;
 450         return true;
 451 }
 452
 453 void waypoint_load_links_hardwired()
 454 {
 455         string filename, s;
 456         float file, tokens, c = 0, found;
 457         entity wp_from = NULL, wp_to;
 458         vector wp_to_pos, wp_from_pos;
 459         filename = strcat("maps/", mapname);
 460         filename = strcat(filename, ".waypoints.hardwired");
 461         file = fopen(filename, FILE_READ);
 462
 463         botframe_loadedforcedlinks = true;
 464
 465         if (file < 0)
 466         {
 467                 LOG_TRACE("waypoint links load from ", filename, " failed\n");
 468                 return;
 469         }
 470
 471         while ((s = fgets(file)))
 472         {
 473                 if(substring(s, 0, 2)=="//")
 474                         continue;
 475
 476                 if(substring(s, 0, 1)=="#")
 477                         continue;
 478
 479                 tokens = tokenizebyseparator(s, "*");
 480
 481                 if (tokens!=2)
 482                         continue;
 483
 484                 wp_from_pos     = stov(argv(0));
 485                 wp_to_pos       = stov(argv(1));
 486
 487                 // Search "from" waypoint
 488                 if(!wp_from || wp_from.origin!=wp_from_pos)
 489                 {
 490                         wp_from = findradius(wp_from_pos, 5);
 491                         found = false;
 492                         while(wp_from)
 493                         {
 494                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 495                                 if(wp_from.classname == "waypoint")
 496                                 {
 497                                         found = true;
 498                                         break;
 499                                 }
 500                                 wp_from = wp_from.chain;
 501                         }
 502
 503                         if(!found)
 504                         {
 505                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 506                                 continue;
 507                         }
 508                 }
 509
 510                 // Search "to" waypoint
 511                 wp_to = findradius(wp_to_pos, 5);
 512                 found = false;
 513                 while(wp_to)
 514                 {
 515                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 516                         if(wp_to.classname == "waypoint")
 517                         {
 518                                 found = true;
 519                                 break;
 520                         }
 521                         wp_to = wp_to.chain;
 522                 }
 523
 524                 if(!found)
 525                 {
 526                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 527                         continue;
 528                 }
 529
 530                 ++c;
 531                 waypoint_addlink(wp_from, wp_to);
 532                 wp_from.wphardwired = true;
 533                 wp_to.wphardwired = true;
 534         }
 535
 536         fclose(file);
 537
 538         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired\n");
 539 }
 540
 541 entity waypoint_get_link(entity w, float i)
 542 {
 543         switch(i)
 544         {
 545                 case  0:return w.wp00;
 546                 case  1:return w.wp01;
 547                 case  2:return w.wp02;
 548                 case  3:return w.wp03;
 549                 case  4:return w.wp04;
 550                 case  5:return w.wp05;
 551                 case  6:return w.wp06;
 552                 case  7:return w.wp07;
 553                 case  8:return w.wp08;
 554                 case  9:return w.wp09;
 555                 case 10:return w.wp10;
 556                 case 11:return w.wp11;
 557                 case 12:return w.wp12;
 558                 case 13:return w.wp13;
 559                 case 14:return w.wp14;
 560                 case 15:return w.wp15;
 561                 case 16:return w.wp16;
 562                 case 17:return w.wp17;
 563                 case 18:return w.wp18;
 564                 case 19:return w.wp19;
 565                 case 20:return w.wp20;
 566                 case 21:return w.wp21;
 567                 case 22:return w.wp22;
 568                 case 23:return w.wp23;
 569                 case 24:return w.wp24;
 570                 case 25:return w.wp25;
 571                 case 26:return w.wp26;
 572                 case 27:return w.wp27;
 573                 case 28:return w.wp28;
 574                 case 29:return w.wp29;
 575                 case 30:return w.wp30;
 576                 case 31:return w.wp31;
 577                 default:return NULL;
 578         }
 579 }
 580
 581 // Save all waypoint links to a file
 582 void waypoint_save_links()
 583 {
 584         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 585         int file = fopen(filename, FILE_WRITE);
 586         if (file < 0)
 587         {
 588                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 589                 return;
 590         }
 591
 592         int c = 0;
 593         IL_EACH(g_waypoints, true,
 594         {
 595                 for(int j = 0; j < 32; ++j)
 596                 {
 597                         entity link = waypoint_get_link(it, j);
 598                         if(link)
 599                         {
 600                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 601                                 fputs(file, s);
 602                                 ++c;
 603                         }
 604                 }
 605         });
 606         fclose(file);
 607         botframe_cachedwaypointlinks = true;
 608
 609         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 610 }
 611
 612 // save waypoints to gamedir/data/maps/mapname.waypoints
 613 void waypoint_saveall()
 614 {
 615         string filename = sprintf("maps/%s.waypoints", mapname);
 616         int file = fopen(filename, FILE_WRITE);
 617         if (file < 0)
 618         {
 619                 waypoint_save_links(); // save anyway?
 620                 botframe_loadedforcedlinks = false;
 621
 622                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 623                 return;
 624         }
 625
 626         int c = 0;
 627         IL_EACH(g_waypoints, true,
 628         {
 629                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 630                         continue;
 631
 632                 for(int j = 0; j < 32; ++j)
 633                 {
 634                         string s;
 635                         s = strcat(vtos(it.origin + it.mins), "\n");
 636                         s = strcat(s, vtos(it.origin + it.maxs));
 637                         s = strcat(s, "\n");
 638                         s = strcat(s, ftos(it.wpflags));
 639                         s = strcat(s, "\n");
 640                         fputs(file, s);
 641                         ++c;
 642                 }
 643         });
 644         fclose(file);
 645         waypoint_save_links();
 646         botframe_loadedforcedlinks = false;
 647
 648         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 649 }
 650
 651 // load waypoints from file
 652 float waypoint_loadall()
 653 {
 654         string filename, s;
 655         float file, cwp, cwb, fl;
 656         vector m1, m2;
 657         cwp = 0;
 658         cwb = 0;
 659         filename = strcat("maps/", mapname);
 660         filename = strcat(filename, ".waypoints");
 661         file = fopen(filename, FILE_READ);
 662         if (file >= 0)
 663         {
 664                 while ((s = fgets(file)))
 665                 {
 666                         m1 = stov(s);
 667                         s = fgets(file);
 668                         if (!s)
 669                                 break;
 670                         m2 = stov(s);
 671                         s = fgets(file);
 672                         if (!s)
 673                                 break;
 674                         fl = stof(s);
 675                         waypoint_spawn(m1, m2, fl);
 676                         if (m1 == m2)
 677                                 cwp = cwp + 1;
 678                         else
 679                                 cwb = cwb + 1;
 680                 }
 681                 fclose(file);
 682                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints\n");
 683         }
 684         else
 685         {
 686                 LOG_TRACE("waypoint load from ", filename, " failed\n");
 687         }
 688         return cwp + cwb;
 689 }
 690
 691 vector waypoint_fixorigin(vector position)
 692 {
 693         tracebox(position + '0 0 1' * (1 - STAT(PL_MIN, NULL).z), STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 694         if(trace_fraction < 1)
 695                 position = trace_endpos;
 696         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 697         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 698         return position;
 699 }
 700
 701 void waypoint_spawnforitem_force(entity e, vector org)
 702 {
 703         // Fix the waypoint altitude if necessary
 704         org = waypoint_fixorigin(org);
 705
 706         // don't spawn an item spawnfunc_waypoint if it already exists
 707         IL_EACH(g_waypoints, true,
 708         {
 709                 if(it.wpisbox)
 710                 {
 711                         if(boxesoverlap(org, org, it.absmin, it.absmax))
 712                         {
 713                                 e.nearestwaypoint = it;
 714                                 return;
 715                         }
 716                 }
 717                 else
 718                 {
 719                         if(vdist(it.origin - org, <, 16))
 720                         {
 721                                 e.nearestwaypoint = it;
 722                                 return;
 723                         }
 724                 }
 725         });
 726
 727         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 728 }
 729
 730 void waypoint_spawnforitem(entity e)
 731 {
 732         if(!bot_waypoints_for_items)
 733                 return;
 734
 735         waypoint_spawnforitem_force(e, e.origin);
 736 }
 737
 738 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 739 {
 740         entity w;
 741         entity dw;
 742         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 743         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 744         // one way link to the destination
 745         w.wp00 = dw;
 746         w.wp00mincost = timetaken; // this is just for jump pads
 747         // the teleporter's nearest spawnfunc_waypoint is this one
 748         // (teleporters are not goals, so this is probably useless)
 749         e.nearestwaypoint = w;
 750         e.nearestwaypointtimeout = time + 1000000000;
 751 }
 752
 753 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 754 {
 755         org = waypoint_fixorigin(org);
 756         destination = waypoint_fixorigin(destination);
 757         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 758 }
 759
 760 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 761 {
 762         destination = waypoint_fixorigin(destination);
 763         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 764 }
 765
 766 entity waypoint_spawnpersonal(entity this, vector position)
 767 {
 768         entity w;
 769
 770         // drop the waypoint to a proper location:
 771         //   first move it up by a player height
 772         //   then move it down to hit the floor with player bbox size
 773         position = waypoint_fixorigin(position);
 774
 775         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 776         w.nearestwaypoint = NULL;
 777         w.nearestwaypointtimeout = 0;
 778         w.owner = this;
 779
 780         waypoint_schedulerelink(w);
 781
 782         return w;
 783 }
 784
 785 void botframe_showwaypointlinks()
 786 {
 787         if (time < botframe_waypointeditorlightningtime)
 788                 return;
 789         botframe_waypointeditorlightningtime = time + 0.5;
 790         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
 791         {
 792                 if(IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
 793                 {
 794                         //navigation_testtracewalk = true;
 795                         entity head = navigation_findnearestwaypoint(it, false);
 796                 //      print("currently selected WP is ", etos(head), "\n");
 797                         //navigation_testtracewalk = false;
 798                         if (head)
 799                         {
 800                                 entity w;
 801                                 w = head     ;if (w) te_lightning2(NULL, w.origin, it.origin);
 802                                 w = head.wp00;if (w) te_lightning2(NULL, w.origin, head.origin);
 803                                 w = head.wp01;if (w) te_lightning2(NULL, w.origin, head.origin);
 804                                 w = head.wp02;if (w) te_lightning2(NULL, w.origin, head.origin);
 805                                 w = head.wp03;if (w) te_lightning2(NULL, w.origin, head.origin);
 806                                 w = head.wp04;if (w) te_lightning2(NULL, w.origin, head.origin);
 807                                 w = head.wp05;if (w) te_lightning2(NULL, w.origin, head.origin);
 808                                 w = head.wp06;if (w) te_lightning2(NULL, w.origin, head.origin);
 809                                 w = head.wp07;if (w) te_lightning2(NULL, w.origin, head.origin);
 810                                 w = head.wp08;if (w) te_lightning2(NULL, w.origin, head.origin);
 811                                 w = head.wp09;if (w) te_lightning2(NULL, w.origin, head.origin);
 812                                 w = head.wp10;if (w) te_lightning2(NULL, w.origin, head.origin);
 813                                 w = head.wp11;if (w) te_lightning2(NULL, w.origin, head.origin);
 814                                 w = head.wp12;if (w) te_lightning2(NULL, w.origin, head.origin);
 815                                 w = head.wp13;if (w) te_lightning2(NULL, w.origin, head.origin);
 816                                 w = head.wp14;if (w) te_lightning2(NULL, w.origin, head.origin);
 817                                 w = head.wp15;if (w) te_lightning2(NULL, w.origin, head.origin);
 818                                 w = head.wp16;if (w) te_lightning2(NULL, w.origin, head.origin);
 819                                 w = head.wp17;if (w) te_lightning2(NULL, w.origin, head.origin);
 820                                 w = head.wp18;if (w) te_lightning2(NULL, w.origin, head.origin);
 821                                 w = head.wp19;if (w) te_lightning2(NULL, w.origin, head.origin);
 822                                 w = head.wp20;if (w) te_lightning2(NULL, w.origin, head.origin);
 823                                 w = head.wp21;if (w) te_lightning2(NULL, w.origin, head.origin);
 824                                 w = head.wp22;if (w) te_lightning2(NULL, w.origin, head.origin);
 825                                 w = head.wp23;if (w) te_lightning2(NULL, w.origin, head.origin);
 826                                 w = head.wp24;if (w) te_lightning2(NULL, w.origin, head.origin);
 827                                 w = head.wp25;if (w) te_lightning2(NULL, w.origin, head.origin);
 828                                 w = head.wp26;if (w) te_lightning2(NULL, w.origin, head.origin);
 829                                 w = head.wp27;if (w) te_lightning2(NULL, w.origin, head.origin);
 830                                 w = head.wp28;if (w) te_lightning2(NULL, w.origin, head.origin);
 831                                 w = head.wp29;if (w) te_lightning2(NULL, w.origin, head.origin);
 832                                 w = head.wp30;if (w) te_lightning2(NULL, w.origin, head.origin);
 833                                 w = head.wp31;if (w) te_lightning2(NULL, w.origin, head.origin);
 834                         }
 835                 }
 836         });
 837 }
 838
 839 float botframe_autowaypoints_fixdown(vector v)
 840 {
 841         tracebox(v, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v + '0 0 -64', MOVE_NOMONSTERS, NULL);
 842         if(trace_fraction >= 1)
 843                 return 0;
 844         return 1;
 845 }
 846
 847 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 848 {
 849         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
 850         {
 851                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 852                 return 0;
 853         });
 854
 855         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 856         return 1;
 857 }
 858
 859 // return value:
 860 //    1 = WP created
 861 //    0 = no action needed
 862 //   -1 = temp fail, try from world too
 863 //   -2 = permanent fail, do not retry
 864 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 865 {
 866         // make it possible to go from p to wp, if we can
 867         // if wp is NULL, nearest is chosen
 868
 869         entity w;
 870         vector porg;
 871         float t, tmin, tmax;
 872         vector o;
 873         vector save;
 874
 875         if(!botframe_autowaypoints_fixdown(p.origin))
 876                 return -2;
 877         porg = trace_endpos;
 878
 879         if(wp)
 880         {
 881                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 882
 883                 // if wp -> porg, then OK
 884                 float maxdist;
 885                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 886                 {
 887                         // we may find a better one
 888                         maxdist = vlen(wp.origin - porg);
 889                 }
 890                 else
 891                 {
 892                         // accept any "good"
 893                         maxdist = 2100;
 894                 }
 895
 896                 float bestdist = maxdist;
 897                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
 898                 {
 899                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
 900                         if(d < bestdist)
 901                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
 902                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
 903                         {
 904                                 bestdist = d;
 905                                 p.(fld) = it;
 906                         }
 907                 });
 908                 if(bestdist < maxdist)
 909                 {
 910                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 911                         return 0;
 912                 }
 913
 914                 if(bestdist < 2100)
 915                 {
 916                         // we know maxdist < 2100
 917                         // so wp -> porg is still valid
 918                         // all is good
 919                         p.(fld) = wp;
 920                         return 0;
 921                 }
 922
 923                 // otherwise, no existing WP can fix our issues
 924         }
 925         else
 926         {
 927                 save = p.origin;
 928                 setorigin(p, porg);
 929                 w = navigation_findnearestwaypoint(p, walkfromwp);
 930                 setorigin(p, save);
 931                 if(w)
 932                 {
 933                         p.(fld) = w;
 934                         return 0;
 935                 }
 936         }
 937
 938         tmin = 0;
 939         tmax = 1;
 940         for (;;)
 941         {
 942                 if(tmax - tmin < 0.001)
 943                 {
 944                         // did not get a good candidate
 945                         return -1;
 946                 }
 947
 948                 t = (tmin + tmax) * 0.5;
 949                 o = antilag_takebackorigin(p, CS(p), time - t);
 950                 if(!botframe_autowaypoints_fixdown(o))
 951                         return -2;
 952                 o = trace_endpos;
 953
 954                 if(wp)
 955                 {
 956                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
 957                         {
 958                                 // we cannot walk from wp.origin to o
 959                                 // get closer to tmax
 960                                 tmin = t;
 961                                 continue;
 962                         }
 963                 }
 964                 else
 965                 {
 966                         save = p.origin;
 967                         setorigin(p, o);
 968                         w = navigation_findnearestwaypoint(p, walkfromwp);
 969                         setorigin(p, save);
 970                         if(!w)
 971                         {
 972                                 // we cannot walk from any WP to o
 973                                 // get closer to tmax
 974                                 tmin = t;
 975                                 continue;
 976                         }
 977                 }
 978
 979                 // if we get here, o is valid regarding waypoints
 980                 // check if o is connected right to the player
 981                 // we break if it succeeds, as that means o is a good waypoint location
 982                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
 983                         break;
 984
 985                 // o is no good, we need to get closer to the player
 986                 tmax = t;
 987         }
 988
 989         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
 990         botframe_autowaypoints_createwp(o, p, fld, 0);
 991         return 1;
 992 }
 993
 994 // automatically create missing waypoints
 995 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
 996 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
 997 {
 998         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
 999         if(r != -1)
1000                 return;
1001         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1002         if(r != -1)
1003                 return;
1004
1005         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1006         if(!botframe_autowaypoints_fixdown(p.origin))
1007                 return; // shouldn't happen, caught above
1008         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1009 }
1010
1011 void botframe_deleteuselesswaypoints()
1012 {
1013         FOREACH_ENTITY_FLOAT(bot_pickup, true,
1014         {
1015                 // NOTE: this protects waypoints if they're the ONLY nearest
1016                 // waypoint. That's the intention.
1017                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1018                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1019         });
1020         IL_EACH(g_waypoints, true,
1021         {
1022                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1023                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1024                 // WP is useful if:
1025                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1026                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1027                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1028                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1029                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1030                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1031                 // b) WP is closest WP for an item/spawnpoint/other entity
1032                 //    This has been done above by protecting these WPs.
1033         });
1034         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1035         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1036         {
1037                 for (int m = 0; m < 32; ++m)
1038                 {
1039                         entity w = waypoint_get_link(it, m);
1040                         if (!w)
1041                                 break;
1042                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1043                                 continue;
1044                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1045                                 continue;
1046                         for (int j = 0; j < 32; ++j)
1047                         {
1048                                 entity w2 = waypoint_get_link(w, j);
1049                                 if (!w2)
1050                                         break;
1051                                 if (it == w2)
1052                                         continue;
1053                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1054                                         continue;
1055                                 // If we got here, it != w2 exist with it -> w
1056                                 // and w -> w2. That means the waypoint is not
1057                                 // a dead end.
1058                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1059                                 for (int k = 0; k < 32; ++k)
1060                                 {
1061                                         if (waypoint_get_link(it, k) == w2)
1062                                                 continue;
1063                                         // IF WE GET HERE, w is proven useful
1064                                         // to get from it to w2!
1065                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1066                                         goto next;
1067                                 }
1068                         }
1069 LABEL(next)
1070                 }
1071         });
1072         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1073         //     they are needed to complete routes while autowaypointing.
1074
1075         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1076         {
1077                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1078                 te_explosion(it.origin);
1079                 waypoint_remove(it);
1080                 break;
1081         });
1082
1083         IL_EACH(g_waypoints, true,
1084         {
1085                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1086         });
1087 }
1088
1089 void botframe_autowaypoints()
1090 {
1091         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1092                 // going back is broken, so only fix waypoints to walk TO the player
1093                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1094                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1095                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1096         ));
1097
1098         if (autocvar_g_waypointeditor_auto >= 2) {
1099                 botframe_deleteuselesswaypoints();
1100         }
1101 }
1102