qcsrc/server/bot/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "bot.qh"
   4 #include "navigation.qh"
   5
   6 #include <common/state.qh>
   7
   8 #include "../antilag.qh"
   9
  10 #include <common/constants.qh>
  11
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14
  15 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  16 // them back to it as well
  17 // (suitable for spawnfunc_waypoint editor)
  18 entity waypoint_spawn(vector m1, vector m2, float f)
  19 {
  20         if(!(f & WAYPOINTFLAG_PERSONAL))
  21         {
  22                 for(entity wp = findchain(classname, "waypoint"); wp; wp = wp.chain)
  23                 {
  24                         // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  25                         if(boxesoverlap(m1, m2, wp.absmin, wp.absmax))
  26                                 return wp;
  27                 }
  28         }
  29
  30
  31         entity w = new(waypoint);
  32         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  33         w.wpflags = f;
  34         w.solid = SOLID_TRIGGER;
  35         setorigin(w, (m1 + m2) * 0.5);
  36         setsize(w, m1 - w.origin, m2 - w.origin);
  37         if (vlen(w.size) > 0)
  38                 w.wpisbox = true;
  39
  40         if(!w.wpisbox)
  41         {
  42                 setsize(w, STAT(PL_MIN, NULL) - '1 1 0', STAT(PL_MAX, NULL) + '1 1 0');
  43                 if(!move_out_of_solid(w))
  44                 {
  45                         if(!(f & WAYPOINTFLAG_GENERATED))
  46                         {
  47                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  48                                 remove(w);
  49                                 return NULL;
  50                         }
  51                         else
  52                         {
  53                                 if(autocvar_developer)
  54                                 {
  55                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  56                                         backtrace("Waypoint stuck");
  57                                 }
  58                         }
  59                 }
  60                 setsize(w, '0 0 0', '0 0 0');
  61         }
  62
  63         waypoint_clearlinks(w);
  64         //waypoint_schedulerelink(w);
  65
  66         if (autocvar_g_waypointeditor)
  67         {
  68                 m1 = w.mins;
  69                 m2 = w.maxs;
  70                 setmodel(w, MDL_WAYPOINT); w.effects = EF_LOWPRECISION;
  71                 setsize(w, m1, m2);
  72                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  73                         w.colormod = '1 0 0';
  74                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  75                         w.colormod = '1 1 0';
  76                 else
  77                         w.colormod = '1 1 1';
  78         }
  79         else
  80                 w.model = "";
  81
  82         return w;
  83 }
  84
  85 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  86 void waypoint_addlink(entity from, entity to)
  87 {
  88         float c;
  89
  90         if (from == to)
  91                 return;
  92         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  93                 return;
  94
  95         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  96         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  97         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  98         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  99         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 100         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 101         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 102         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 103
 104         if (to.wpisbox || from.wpisbox)
 105         {
 106                 // if either is a box we have to find the nearest points on them to
 107                 // calculate the distance properly
 108                 vector v1, v2, m1, m2;
 109                 v1 = from.origin;
 110                 m1 = to.absmin;
 111                 m2 = to.absmax;
 112                 v1_x = bound(m1_x, v1_x, m2_x);
 113                 v1_y = bound(m1_y, v1_y, m2_y);
 114                 v1_z = bound(m1_z, v1_z, m2_z);
 115                 v2 = to.origin;
 116                 m1 = from.absmin;
 117                 m2 = from.absmax;
 118                 v2_x = bound(m1_x, v2_x, m2_x);
 119                 v2_y = bound(m1_y, v2_y, m2_y);
 120                 v2_z = bound(m1_z, v2_z, m2_z);
 121                 v2 = to.origin;
 122                 c = vlen(v2 - v1);
 123         }
 124         else
 125                 c = vlen(to.origin - from.origin);
 126
 127         if (from.wp31mincost < c) return;
 128         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 129         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 130         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 131         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 132         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 133         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 134         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 135         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 136         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 137         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 138         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 139         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 140         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 141         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 142         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 143         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 144         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 145         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 146         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 147         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 148         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 149         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 150         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 151         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 152         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 153         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 154         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 155         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 156         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 157         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 158         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 159         from.wp00 = to;from.wp00mincost = c;return;
 160 }
 161
 162 // relink this spawnfunc_waypoint
 163 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 164 // (SLOW!)
 165 void waypoint_think(entity this)
 166 {
 167         vector sv, sm1, sm2, ev, em1, em2, dv;
 168
 169         bot_calculate_stepheightvec();
 170
 171         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 172
 173         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 174         sm1 = this.origin + this.mins;
 175         sm2 = this.origin + this.maxs;
 176         FOREACH_ENTITY_CLASS("waypoint", true,
 177         {
 178                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 179                 {
 180                         waypoint_addlink(this, it);
 181                         waypoint_addlink(it, this);
 182                 }
 183                 else
 184                 {
 185                         ++relink_total;
 186                         if(!checkpvs(this.origin, it))
 187                         {
 188                                 ++relink_pvsculled;
 189                                 continue;
 190                         }
 191                         sv = it.origin;
 192                         sv.x = bound(sm1_x, sv.x, sm2_x);
 193                         sv.y = bound(sm1_y, sv.y, sm2_y);
 194                         sv.z = bound(sm1_z, sv.z, sm2_z);
 195                         ev = this.origin;
 196                         em1 = it.origin + it.mins;
 197                         em2 = it.origin + it.maxs;
 198                         ev.x = bound(em1_x, ev.x, em2_x);
 199                         ev.y = bound(em1_y, ev.y, em2_y);
 200                         ev.z = bound(em1_z, ev.z, em2_z);
 201                         dv = ev - sv;
 202                         dv.z = 0;
 203                         if(vdist(dv, >=, 1050)) // max search distance in XY
 204                         {
 205                                 ++relink_lengthculled;
 206                                 continue;
 207                         }
 208                         navigation_testtracewalk = 0;
 209                         if (!this.wpisbox)
 210                         {
 211                                 tracebox(sv - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, false, this);
 212                                 if (!trace_startsolid)
 213                                 {
 214                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 215                                         sv = trace_endpos + '0 0 1';
 216                                 }
 217                         }
 218                         if (!it.wpisbox)
 219                         {
 220                                 tracebox(ev - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, false, it);
 221                                 if (!trace_startsolid)
 222                                 {
 223                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 224                                         ev = trace_endpos + '0 0 1';
 225                                 }
 226                         }
 227                         //traceline(this.origin, it.origin, false, NULL);
 228                         //if (trace_fraction == 1)
 229                         if (!this.wpisbox && tracewalk(this, sv, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, MOVE_NOMONSTERS))
 230                                 waypoint_addlink(this, it);
 231                         else
 232                                 relink_walkculled += 0.5;
 233                         if (!it.wpisbox && tracewalk(it, ev, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, MOVE_NOMONSTERS))
 234                                 waypoint_addlink(it, this);
 235                         else
 236                                 relink_walkculled += 0.5;
 237                 }
 238         });
 239         navigation_testtracewalk = 0;
 240         this.wplinked = true;
 241 }
 242
 243 void waypoint_clearlinks(entity wp)
 244 {
 245         // clear links to other waypoints
 246         float f;
 247         f = 10000000;
 248         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 249         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 250         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 251         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 252
 253         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 254         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 255         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 256         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 257
 258         wp.wplinked = false;
 259 }
 260
 261 // tell a spawnfunc_waypoint to relink
 262 void waypoint_schedulerelink(entity wp)
 263 {
 264         if (wp == NULL)
 265                 return;
 266         // TODO: add some sort of visible box in edit mode for box waypoints
 267         if (autocvar_g_waypointeditor)
 268         {
 269                 vector m1, m2;
 270                 m1 = wp.mins;
 271                 m2 = wp.maxs;
 272                 setmodel(wp, MDL_WAYPOINT); wp.effects = EF_LOWPRECISION;
 273                 setsize(wp, m1, m2);
 274                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 275                         wp.colormod = '1 0 0';
 276                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 277                         wp.colormod = '1 1 0';
 278                 else
 279                         wp.colormod = '1 1 1';
 280         }
 281         else
 282                 wp.model = "";
 283         wp.wpisbox = vlen(wp.size) > 0;
 284         wp.enemy = NULL;
 285         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 286                 wp.owner = NULL;
 287         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 288                 waypoint_clearlinks(wp);
 289         // schedule an actual relink on next frame
 290         setthink(wp, waypoint_think);
 291         wp.nextthink = time;
 292         wp.effects = EF_LOWPRECISION;
 293 }
 294
 295 // spawnfunc_waypoint map entity
 296 spawnfunc(waypoint)
 297 {
 298         setorigin(this, this.origin);
 299         // schedule a relink after other waypoints have had a chance to spawn
 300         waypoint_clearlinks(this);
 301         //waypoint_schedulerelink(this);
 302 }
 303
 304 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 305 void waypoint_remove(entity e)
 306 {
 307         // tell all linked waypoints that they need to relink
 308         waypoint_schedulerelink(e.wp00);
 309         waypoint_schedulerelink(e.wp01);
 310         waypoint_schedulerelink(e.wp02);
 311         waypoint_schedulerelink(e.wp03);
 312         waypoint_schedulerelink(e.wp04);
 313         waypoint_schedulerelink(e.wp05);
 314         waypoint_schedulerelink(e.wp06);
 315         waypoint_schedulerelink(e.wp07);
 316         waypoint_schedulerelink(e.wp08);
 317         waypoint_schedulerelink(e.wp09);
 318         waypoint_schedulerelink(e.wp10);
 319         waypoint_schedulerelink(e.wp11);
 320         waypoint_schedulerelink(e.wp12);
 321         waypoint_schedulerelink(e.wp13);
 322         waypoint_schedulerelink(e.wp14);
 323         waypoint_schedulerelink(e.wp15);
 324         waypoint_schedulerelink(e.wp16);
 325         waypoint_schedulerelink(e.wp17);
 326         waypoint_schedulerelink(e.wp18);
 327         waypoint_schedulerelink(e.wp19);
 328         waypoint_schedulerelink(e.wp20);
 329         waypoint_schedulerelink(e.wp21);
 330         waypoint_schedulerelink(e.wp22);
 331         waypoint_schedulerelink(e.wp23);
 332         waypoint_schedulerelink(e.wp24);
 333         waypoint_schedulerelink(e.wp25);
 334         waypoint_schedulerelink(e.wp26);
 335         waypoint_schedulerelink(e.wp27);
 336         waypoint_schedulerelink(e.wp28);
 337         waypoint_schedulerelink(e.wp29);
 338         waypoint_schedulerelink(e.wp30);
 339         waypoint_schedulerelink(e.wp31);
 340         // and now remove the spawnfunc_waypoint
 341         remove(e);
 342 }
 343
 344 // empties the map of waypoints
 345 void waypoint_removeall()
 346 {
 347         entity head, next;
 348         head = findchain(classname, "waypoint");
 349         while (head)
 350         {
 351                 next = head.chain;
 352                 remove(head);
 353                 head = next;
 354         }
 355 }
 356
 357 // tell all waypoints to relink
 358 // (is this useful at all?)
 359 void waypoint_schedulerelinkall()
 360 {
 361         entity head;
 362         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 363         head = findchain(classname, "waypoint");
 364         while (head)
 365         {
 366                 waypoint_schedulerelink(head);
 367                 head = head.chain;
 368         }
 369 }
 370
 371 // Load waypoint links from file
 372 float waypoint_load_links()
 373 {
 374         string filename, s;
 375         float file, tokens, c = 0, found;
 376         entity wp_from = NULL, wp_to;
 377         vector wp_to_pos, wp_from_pos;
 378         filename = strcat("maps/", mapname);
 379         filename = strcat(filename, ".waypoints.cache");
 380         file = fopen(filename, FILE_READ);
 381
 382         if (file < 0)
 383         {
 384                 LOG_TRACE("waypoint links load from ");
 385                 LOG_TRACE(filename);
 386                 LOG_TRACE(" failed\n");
 387                 return false;
 388         }
 389
 390         while ((s = fgets(file)))
 391         {
 392                 tokens = tokenizebyseparator(s, "*");
 393
 394                 if (tokens!=2)
 395                 {
 396                         // bad file format
 397                         fclose(file);
 398                         return false;
 399                 }
 400
 401                 wp_from_pos     = stov(argv(0));
 402                 wp_to_pos       = stov(argv(1));
 403
 404                 // Search "from" waypoint
 405                 if(!wp_from || wp_from.origin!=wp_from_pos)
 406                 {
 407                         wp_from = findradius(wp_from_pos, 1);
 408                         found = false;
 409                         while(wp_from)
 410                         {
 411                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 412                                 if(wp_from.classname == "waypoint")
 413                                 {
 414                                         found = true;
 415                                         break;
 416                                 }
 417                                 wp_from = wp_from.chain;
 418                         }
 419
 420                         if(!found)
 421                         {
 422                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 423                                 continue;
 424                         }
 425
 426                 }
 427
 428                 // Search "to" waypoint
 429                 wp_to = findradius(wp_to_pos, 1);
 430                 found = false;
 431                 while(wp_to)
 432                 {
 433                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 434                         if(wp_to.classname == "waypoint")
 435                         {
 436                                 found = true;
 437                                 break;
 438                         }
 439                         wp_to = wp_to.chain;
 440                 }
 441
 442                 if(!found)
 443                 {
 444                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 445                         continue;
 446                 }
 447
 448                 ++c;
 449                 waypoint_addlink(wp_from, wp_to);
 450         }
 451
 452         fclose(file);
 453
 454         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache\n");
 455
 456         botframe_cachedwaypointlinks = true;
 457         return true;
 458 }
 459
 460 void waypoint_load_links_hardwired()
 461 {
 462         string filename, s;
 463         float file, tokens, c = 0, found;
 464         entity wp_from = NULL, wp_to;
 465         vector wp_to_pos, wp_from_pos;
 466         filename = strcat("maps/", mapname);
 467         filename = strcat(filename, ".waypoints.hardwired");
 468         file = fopen(filename, FILE_READ);
 469
 470         botframe_loadedforcedlinks = true;
 471
 472         if (file < 0)
 473         {
 474                 LOG_TRACE("waypoint links load from ", filename, " failed\n");
 475                 return;
 476         }
 477
 478         while ((s = fgets(file)))
 479         {
 480                 if(substring(s, 0, 2)=="//")
 481                         continue;
 482
 483                 if(substring(s, 0, 1)=="#")
 484                         continue;
 485
 486                 tokens = tokenizebyseparator(s, "*");
 487
 488                 if (tokens!=2)
 489                         continue;
 490
 491                 wp_from_pos     = stov(argv(0));
 492                 wp_to_pos       = stov(argv(1));
 493
 494                 // Search "from" waypoint
 495                 if(!wp_from || wp_from.origin!=wp_from_pos)
 496                 {
 497                         wp_from = findradius(wp_from_pos, 5);
 498                         found = false;
 499                         while(wp_from)
 500                         {
 501                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 502                                 if(wp_from.classname == "waypoint")
 503                                 {
 504                                         found = true;
 505                                         break;
 506                                 }
 507                                 wp_from = wp_from.chain;
 508                         }
 509
 510                         if(!found)
 511                         {
 512                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 513                                 continue;
 514                         }
 515                 }
 516
 517                 // Search "to" waypoint
 518                 wp_to = findradius(wp_to_pos, 5);
 519                 found = false;
 520                 while(wp_to)
 521                 {
 522                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 523                         if(wp_to.classname == "waypoint")
 524                         {
 525                                 found = true;
 526                                 break;
 527                         }
 528                         wp_to = wp_to.chain;
 529                 }
 530
 531                 if(!found)
 532                 {
 533                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 534                         continue;
 535                 }
 536
 537                 ++c;
 538                 waypoint_addlink(wp_from, wp_to);
 539                 wp_from.wphardwired = true;
 540                 wp_to.wphardwired = true;
 541         }
 542
 543         fclose(file);
 544
 545         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired\n");
 546 }
 547
 548 entity waypoint_get_link(entity w, float i)
 549 {
 550         switch(i)
 551         {
 552                 case  0:return w.wp00;
 553                 case  1:return w.wp01;
 554                 case  2:return w.wp02;
 555                 case  3:return w.wp03;
 556                 case  4:return w.wp04;
 557                 case  5:return w.wp05;
 558                 case  6:return w.wp06;
 559                 case  7:return w.wp07;
 560                 case  8:return w.wp08;
 561                 case  9:return w.wp09;
 562                 case 10:return w.wp10;
 563                 case 11:return w.wp11;
 564                 case 12:return w.wp12;
 565                 case 13:return w.wp13;
 566                 case 14:return w.wp14;
 567                 case 15:return w.wp15;
 568                 case 16:return w.wp16;
 569                 case 17:return w.wp17;
 570                 case 18:return w.wp18;
 571                 case 19:return w.wp19;
 572                 case 20:return w.wp20;
 573                 case 21:return w.wp21;
 574                 case 22:return w.wp22;
 575                 case 23:return w.wp23;
 576                 case 24:return w.wp24;
 577                 case 25:return w.wp25;
 578                 case 26:return w.wp26;
 579                 case 27:return w.wp27;
 580                 case 28:return w.wp28;
 581                 case 29:return w.wp29;
 582                 case 30:return w.wp30;
 583                 case 31:return w.wp31;
 584                 default:return NULL;
 585         }
 586 }
 587
 588 // Save all waypoint links to a file
 589 void waypoint_save_links()
 590 {
 591         string filename, s;
 592         float file, c, i;
 593         entity w, link;
 594         filename = strcat("maps/", mapname);
 595         filename = strcat(filename, ".waypoints.cache");
 596         file = fopen(filename, FILE_WRITE);
 597         if (file < 0)
 598         {
 599                 LOG_INFO("waypoint links save to ");
 600                 LOG_INFO(filename);
 601                 LOG_INFO(" failed\n");
 602         }
 603         c = 0;
 604         w = findchain(classname, "waypoint");
 605         while (w)
 606         {
 607                 for(i=0;i<32;++i)
 608                 {
 609                         // :S
 610                         link = waypoint_get_link(w, i);
 611                         if(link==NULL)
 612                                 continue;
 613
 614                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 615                         fputs(file, s);
 616                         ++c;
 617                 }
 618                 w = w.chain;
 619         }
 620         fclose(file);
 621         botframe_cachedwaypointlinks = true;
 622
 623         LOG_INFO("saved ");
 624         LOG_INFO(ftos(c));
 625         LOG_INFO(" waypoints links to maps/");
 626         LOG_INFO(mapname);
 627         LOG_INFO(".waypoints.cache\n");
 628 }
 629
 630 // save waypoints to gamedir/data/maps/mapname.waypoints
 631 void waypoint_saveall()
 632 {
 633         string filename, s;
 634         float file, c;
 635         entity w;
 636         filename = strcat("maps/", mapname);
 637         filename = strcat(filename, ".waypoints");
 638         file = fopen(filename, FILE_WRITE);
 639         if (file >= 0)
 640         {
 641                 c = 0;
 642                 w = findchain(classname, "waypoint");
 643                 while (w)
 644                 {
 645                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 646                         {
 647                                 s = strcat(vtos(w.origin + w.mins), "\n");
 648                                 s = strcat(s, vtos(w.origin + w.maxs));
 649                                 s = strcat(s, "\n");
 650                                 s = strcat(s, ftos(w.wpflags));
 651                                 s = strcat(s, "\n");
 652                                 fputs(file, s);
 653                                 c = c + 1;
 654                         }
 655                         w = w.chain;
 656                 }
 657                 fclose(file);
 658                 bprint("saved ");
 659                 bprint(ftos(c));
 660                 bprint(" waypoints to maps/");
 661                 bprint(mapname);
 662                 bprint(".waypoints\n");
 663         }
 664         else
 665         {
 666                 bprint("waypoint save to ");
 667                 bprint(filename);
 668                 bprint(" failed\n");
 669         }
 670         waypoint_save_links();
 671         botframe_loadedforcedlinks = false;
 672 }
 673
 674 // load waypoints from file
 675 float waypoint_loadall()
 676 {
 677         string filename, s;
 678         float file, cwp, cwb, fl;
 679         vector m1, m2;
 680         cwp = 0;
 681         cwb = 0;
 682         filename = strcat("maps/", mapname);
 683         filename = strcat(filename, ".waypoints");
 684         file = fopen(filename, FILE_READ);
 685         if (file >= 0)
 686         {
 687                 while ((s = fgets(file)))
 688                 {
 689                         m1 = stov(s);
 690                         s = fgets(file);
 691                         if (!s)
 692                                 break;
 693                         m2 = stov(s);
 694                         s = fgets(file);
 695                         if (!s)
 696                                 break;
 697                         fl = stof(s);
 698                         waypoint_spawn(m1, m2, fl);
 699                         if (m1 == m2)
 700                                 cwp = cwp + 1;
 701                         else
 702                                 cwb = cwb + 1;
 703                 }
 704                 fclose(file);
 705                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints\n");
 706         }
 707         else
 708         {
 709                 LOG_TRACE("waypoint load from ", filename, " failed\n");
 710         }
 711         return cwp + cwb;
 712 }
 713
 714 vector waypoint_fixorigin(vector position)
 715 {
 716         tracebox(position + '0 0 1' * (1 - STAT(PL_MIN, NULL).z), STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 717         if(trace_fraction < 1)
 718                 position = trace_endpos;
 719         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 720         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 721         return position;
 722 }
 723
 724 void waypoint_spawnforitem_force(entity e, vector org)
 725 {
 726         entity w;
 727
 728         // Fix the waypoint altitude if necessary
 729         org = waypoint_fixorigin(org);
 730
 731         // don't spawn an item spawnfunc_waypoint if it already exists
 732         w = findchain(classname, "waypoint");
 733         while (w)
 734         {
 735                 if (w.wpisbox)
 736                 {
 737                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 738                         {
 739                                 e.nearestwaypoint = w;
 740                                 return;
 741                         }
 742                 }
 743                 else
 744                 {
 745                         if (vlen(w.origin - org) < 16)
 746                         {
 747                                 e.nearestwaypoint = w;
 748                                 return;
 749                         }
 750                 }
 751                 w = w.chain;
 752         }
 753         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 754 }
 755
 756 void waypoint_spawnforitem(entity e)
 757 {
 758         if(!bot_waypoints_for_items)
 759                 return;
 760
 761         waypoint_spawnforitem_force(e, e.origin);
 762 }
 763
 764 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 765 {
 766         entity w;
 767         entity dw;
 768         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 769         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 770         // one way link to the destination
 771         w.wp00 = dw;
 772         w.wp00mincost = timetaken; // this is just for jump pads
 773         // the teleporter's nearest spawnfunc_waypoint is this one
 774         // (teleporters are not goals, so this is probably useless)
 775         e.nearestwaypoint = w;
 776         e.nearestwaypointtimeout = time + 1000000000;
 777 }
 778
 779 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 780 {
 781         org = waypoint_fixorigin(org);
 782         destination = waypoint_fixorigin(destination);
 783         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 784 }
 785
 786 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 787 {
 788         destination = waypoint_fixorigin(destination);
 789         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 790 }
 791
 792 entity waypoint_spawnpersonal(entity this, vector position)
 793 {
 794         entity w;
 795
 796         // drop the waypoint to a proper location:
 797         //   first move it up by a player height
 798         //   then move it down to hit the floor with player bbox size
 799         position = waypoint_fixorigin(position);
 800
 801         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 802         w.nearestwaypoint = NULL;
 803         w.nearestwaypointtimeout = 0;
 804         w.owner = this;
 805
 806         waypoint_schedulerelink(w);
 807
 808         return w;
 809 }
 810
 811 void botframe_showwaypointlinks()
 812 {
 813         entity head, w;
 814         if (time < botframe_waypointeditorlightningtime)
 815                 return;
 816         botframe_waypointeditorlightningtime = time + 0.5;
 817         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot, LAMBDA(
 818                 if(IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
 819                 {
 820                         //navigation_testtracewalk = true;
 821                         head = navigation_findnearestwaypoint(it, false);
 822                 //      print("currently selected WP is ", etos(head), "\n");
 823                         //navigation_testtracewalk = false;
 824                         if (head)
 825                         {
 826                                 w = head     ;if (w) te_lightning2(NULL, w.origin, it.origin);
 827                                 w = head.wp00;if (w) te_lightning2(NULL, w.origin, head.origin);
 828                                 w = head.wp01;if (w) te_lightning2(NULL, w.origin, head.origin);
 829                                 w = head.wp02;if (w) te_lightning2(NULL, w.origin, head.origin);
 830                                 w = head.wp03;if (w) te_lightning2(NULL, w.origin, head.origin);
 831                                 w = head.wp04;if (w) te_lightning2(NULL, w.origin, head.origin);
 832                                 w = head.wp05;if (w) te_lightning2(NULL, w.origin, head.origin);
 833                                 w = head.wp06;if (w) te_lightning2(NULL, w.origin, head.origin);
 834                                 w = head.wp07;if (w) te_lightning2(NULL, w.origin, head.origin);
 835                                 w = head.wp08;if (w) te_lightning2(NULL, w.origin, head.origin);
 836                                 w = head.wp09;if (w) te_lightning2(NULL, w.origin, head.origin);
 837                                 w = head.wp10;if (w) te_lightning2(NULL, w.origin, head.origin);
 838                                 w = head.wp11;if (w) te_lightning2(NULL, w.origin, head.origin);
 839                                 w = head.wp12;if (w) te_lightning2(NULL, w.origin, head.origin);
 840                                 w = head.wp13;if (w) te_lightning2(NULL, w.origin, head.origin);
 841                                 w = head.wp14;if (w) te_lightning2(NULL, w.origin, head.origin);
 842                                 w = head.wp15;if (w) te_lightning2(NULL, w.origin, head.origin);
 843                                 w = head.wp16;if (w) te_lightning2(NULL, w.origin, head.origin);
 844                                 w = head.wp17;if (w) te_lightning2(NULL, w.origin, head.origin);
 845                                 w = head.wp18;if (w) te_lightning2(NULL, w.origin, head.origin);
 846                                 w = head.wp19;if (w) te_lightning2(NULL, w.origin, head.origin);
 847                                 w = head.wp20;if (w) te_lightning2(NULL, w.origin, head.origin);
 848                                 w = head.wp21;if (w) te_lightning2(NULL, w.origin, head.origin);
 849                                 w = head.wp22;if (w) te_lightning2(NULL, w.origin, head.origin);
 850                                 w = head.wp23;if (w) te_lightning2(NULL, w.origin, head.origin);
 851                                 w = head.wp24;if (w) te_lightning2(NULL, w.origin, head.origin);
 852                                 w = head.wp25;if (w) te_lightning2(NULL, w.origin, head.origin);
 853                                 w = head.wp26;if (w) te_lightning2(NULL, w.origin, head.origin);
 854                                 w = head.wp27;if (w) te_lightning2(NULL, w.origin, head.origin);
 855                                 w = head.wp28;if (w) te_lightning2(NULL, w.origin, head.origin);
 856                                 w = head.wp29;if (w) te_lightning2(NULL, w.origin, head.origin);
 857                                 w = head.wp30;if (w) te_lightning2(NULL, w.origin, head.origin);
 858                                 w = head.wp31;if (w) te_lightning2(NULL, w.origin, head.origin);
 859                         }
 860                 }
 861         ));
 862 }
 863
 864 float botframe_autowaypoints_fixdown(vector v)
 865 {
 866         tracebox(v, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v + '0 0 -64', MOVE_NOMONSTERS, NULL);
 867         if(trace_fraction >= 1)
 868                 return 0;
 869         return 1;
 870 }
 871
 872 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 873 {
 874         entity w;
 875
 876         w = find(NULL, classname, "waypoint");
 877         while (w)
 878         {
 879                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 880                 if (boxesoverlap(v - '32 32 32', v + '32 32 32', w.absmin, w.absmax))
 881                 //if (boxesoverlap(v - '4 4 4', v + '4 4 4', w.absmin, w.absmax))
 882                         return 0;
 883                 w = find(w, classname, "waypoint");
 884         }
 885
 886         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 887         return 1;
 888 }
 889
 890 // return value:
 891 //    1 = WP created
 892 //    0 = no action needed
 893 //   -1 = temp fail, try from world too
 894 //   -2 = permanent fail, do not retry
 895 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 896 {
 897         // make it possible to go from p to wp, if we can
 898         // if wp is NULL, nearest is chosen
 899
 900         entity w;
 901         vector porg;
 902         float t, tmin, tmax;
 903         vector o;
 904         vector save;
 905
 906         if(!botframe_autowaypoints_fixdown(p.origin))
 907                 return -2;
 908         porg = trace_endpos;
 909
 910         if(wp)
 911         {
 912                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 913
 914                 // if wp -> porg, then OK
 915                 float maxdist;
 916                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 917                 {
 918                         // we may find a better one
 919                         maxdist = vlen(wp.origin - porg);
 920                 }
 921                 else
 922                 {
 923                         // accept any "good"
 924                         maxdist = 2100;
 925                 }
 926
 927                 float bestdist;
 928                 bestdist = maxdist;
 929                 w = find(NULL, classname, "waypoint");
 930                 while (w)
 931                 {
 932                         if(w != wp && !(w.wpflags & WAYPOINTFLAG_NORELINK))
 933                         {
 934                                 float d;
 935                                 d = vlen(wp.origin - w.origin) + vlen(w.origin - porg);
 936                                 if(d < bestdist)
 937                                         if(navigation_waypoint_will_link(wp.origin, w.origin, p, walkfromwp, 1050))
 938                                                 if(navigation_waypoint_will_link(w.origin, porg, p, walkfromwp, 1050))
 939                                                 {
 940                                                         bestdist = d;
 941                                                         p.(fld) = w;
 942                                                 }
 943                         }
 944                         w = find(w, classname, "waypoint");
 945                 }
 946                 if(bestdist < maxdist)
 947                 {
 948                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 949                         return 0;
 950                 }
 951
 952                 if(bestdist < 2100)
 953                 {
 954                         // we know maxdist < 2100
 955                         // so wp -> porg is still valid
 956                         // all is good
 957                         p.(fld) = wp;
 958                         return 0;
 959                 }
 960
 961                 // otherwise, no existing WP can fix our issues
 962         }
 963         else
 964         {
 965                 save = p.origin;
 966                 setorigin(p, porg);
 967                 w = navigation_findnearestwaypoint(p, walkfromwp);
 968                 setorigin(p, save);
 969                 if(w)
 970                 {
 971                         p.(fld) = w;
 972                         return 0;
 973                 }
 974         }
 975
 976         tmin = 0;
 977         tmax = 1;
 978         for (;;)
 979         {
 980                 if(tmax - tmin < 0.001)
 981                 {
 982                         // did not get a good candidate
 983                         return -1;
 984                 }
 985
 986                 t = (tmin + tmax) * 0.5;
 987                 o = antilag_takebackorigin(p, CS(p), time - t);
 988                 if(!botframe_autowaypoints_fixdown(o))
 989                         return -2;
 990                 o = trace_endpos;
 991
 992                 if(wp)
 993                 {
 994                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
 995                         {
 996                                 // we cannot walk from wp.origin to o
 997                                 // get closer to tmax
 998                                 tmin = t;
 999                                 continue;
1000                         }
1001                 }
1002                 else
1003                 {
1004                         save = p.origin;
1005                         setorigin(p, o);
1006                         w = navigation_findnearestwaypoint(p, walkfromwp);
1007                         setorigin(p, save);
1008                         if(!w)
1009                         {
1010                                 // we cannot walk from any WP to o
1011                                 // get closer to tmax
1012                                 tmin = t;
1013                                 continue;
1014                         }
1015                 }
1016
1017                 // if we get here, o is valid regarding waypoints
1018                 // check if o is connected right to the player
1019                 // we break if it succeeds, as that means o is a good waypoint location
1020                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1021                         break;
1022
1023                 // o is no good, we need to get closer to the player
1024                 tmax = t;
1025         }
1026
1027         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1028         botframe_autowaypoints_createwp(o, p, fld, 0);
1029         return 1;
1030 }
1031
1032 // automatically create missing waypoints
1033 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1034 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1035 {
1036         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1037         if(r != -1)
1038                 return;
1039         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1040         if(r != -1)
1041                 return;
1042
1043         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1044         if(!botframe_autowaypoints_fixdown(p.origin))
1045                 return; // shouldn't happen, caught above
1046         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1047 }
1048
1049 void botframe_deleteuselesswaypoints()
1050 {
1051         entity w, w1, w2;
1052         float i, j, k;
1053         for (w = NULL; (w = findfloat(w, bot_pickup, true)); )
1054         {
1055                 // NOTE: this protects waypoints if they're the ONLY nearest
1056                 // waypoint. That's the intention.
1057                 navigation_findnearestwaypoint(w, false);  // Walk TO item.
1058                 navigation_findnearestwaypoint(w, true);  // Walk FROM item.
1059         }
1060         for (w = NULL; (w = find(w, classname, "waypoint")); )
1061         {
1062                 w.wpflags |= WAYPOINTFLAG_DEAD_END;
1063                 w.wpflags &= ~WAYPOINTFLAG_USEFUL;
1064                 // WP is useful if:
1065                 if (w.wpflags & WAYPOINTFLAG_ITEM)
1066                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1067                 if (w.wpflags & WAYPOINTFLAG_TELEPORT)
1068                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1069                 if (w.wpflags & WAYPOINTFLAG_PROTECTED)
1070                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1071                 // b) WP is closest WP for an item/spawnpoint/other entity
1072                 //    This has been done above by protecting these WPs.
1073         }
1074         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1075         for (w1 = NULL; (w1 = find(w1, classname, "waypoint")); )
1076         {
1077                 if (w1.wpflags & WAYPOINTFLAG_PERSONAL)
1078                         continue;
1079                 for (i = 0; i < 32; ++i)
1080                 {
1081                         w = waypoint_get_link(w1, i);
1082                         if (!w)
1083                                 break;
1084                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1085                                 continue;
1086                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1087                                 continue;
1088                         for (j = 0; j < 32; ++j)
1089                         {
1090                                 w2 = waypoint_get_link(w, j);
1091                                 if (!w2)
1092                                         break;
1093                                 if (w1 == w2)
1094                                         continue;
1095                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1096                                         continue;
1097                                 // If we got here, w1 != w2 exist with w1 -> w
1098                                 // and w -> w2. That means the waypoint is not
1099                                 // a dead end.
1100                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1101                                 for (k = 0; k < 32; ++k)
1102                                 {
1103                                         if (waypoint_get_link(w1, k) == w2)
1104                                                 continue;
1105                                         // IF WE GET HERE, w is proven useful
1106                                         // to get from w1 to w2!
1107                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1108                                         goto next;
1109                                 }
1110                         }
1111 LABEL(next)
1112                 }
1113         }
1114         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1115         //     they are needed to complete routes while autowaypointing.
1116
1117         for (w = NULL; (w = find(w, classname, "waypoint")); )
1118         {
1119                 if (!(w.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)))
1120                 {
1121                         LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", w.origin);
1122                         te_explosion(w.origin);
1123                         waypoint_remove(w);
1124                         break;
1125                 }
1126         }
1127         for (w = NULL; (w = find(w, classname, "waypoint")); )
1128                 w.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1129 }
1130
1131 void botframe_autowaypoints()
1132 {
1133         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1134                 // going back is broken, so only fix waypoints to walk TO the player
1135                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1136                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1137                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1138         ));
1139
1140         if (autocvar_g_waypointeditor_auto >= 2) {
1141                 botframe_deleteuselesswaypoints();
1142         }
1143 }
1144