qcsrc/server/bot/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "bot.qh"
   4 #include "navigation.qh"
   5
   6 #include <common/state.qh>
   7
   8 #include "../antilag.qh"
   9
  10 #include <common/constants.qh>
  11
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14
  15 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  16 // them back to it as well
  17 // (suitable for spawnfunc_waypoint editor)
  18 entity waypoint_spawn(vector m1, vector m2, float f)
  19 {
  20         entity w;
  21         w = find(world, classname, "waypoint");
  22
  23         if (!(f & WAYPOINTFLAG_PERSONAL))
  24         while (w)
  25         {
  26                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
  27                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
  28                         return w;
  29                 w = find(w, classname, "waypoint");
  30         }
  31
  32         w = new(waypoint);
  33         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  34         w.wpflags = f;
  35         setorigin(w, (m1 + m2) * 0.5);
  36         setsize(w, m1 - w.origin, m2 - w.origin);
  37         if (vlen(w.size) > 0)
  38                 w.wpisbox = true;
  39
  40         if(!w.wpisbox)
  41         {
  42                 setsize(w, STAT(PL_MIN, NULL) - '1 1 0', STAT(PL_MAX, NULL) + '1 1 0');
  43                 if(!move_out_of_solid(w))
  44                 {
  45                         if(!(f & WAYPOINTFLAG_GENERATED))
  46                         {
  47                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin), "\n");
  48                                 remove(w);
  49                                 return world;
  50                         }
  51                         else
  52                         {
  53                                 if(autocvar_developer)
  54                                 {
  55                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  56                                         backtrace("Waypoint stuck");
  57                                 }
  58                         }
  59                 }
  60                 setsize(w, '0 0 0', '0 0 0');
  61         }
  62
  63         waypoint_clearlinks(w);
  64         //waypoint_schedulerelink(w);
  65
  66         if (autocvar_g_waypointeditor)
  67         {
  68                 m1 = w.mins;
  69                 m2 = w.maxs;
  70                 setmodel(w, MDL_WAYPOINT); w.effects = EF_LOWPRECISION;
  71                 setsize(w, m1, m2);
  72                 if (w.wpflags & WAYPOINTFLAG_ITEM)
  73                         w.colormod = '1 0 0';
  74                 else if (w.wpflags & WAYPOINTFLAG_GENERATED)
  75                         w.colormod = '1 1 0';
  76                 else
  77                         w.colormod = '1 1 1';
  78         }
  79         else
  80                 w.model = "";
  81
  82         return w;
  83 }
  84
  85 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  86 void waypoint_addlink(entity from, entity to)
  87 {
  88         float c;
  89
  90         if (from == to)
  91                 return;
  92         if (from.wpflags & WAYPOINTFLAG_NORELINK)
  93                 return;
  94
  95         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
  96         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
  97         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
  98         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
  99         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 100         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 101         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 102         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 103
 104         if (to.wpisbox || from.wpisbox)
 105         {
 106                 // if either is a box we have to find the nearest points on them to
 107                 // calculate the distance properly
 108                 vector v1, v2, m1, m2;
 109                 v1 = from.origin;
 110                 m1 = to.absmin;
 111                 m2 = to.absmax;
 112                 v1_x = bound(m1_x, v1_x, m2_x);
 113                 v1_y = bound(m1_y, v1_y, m2_y);
 114                 v1_z = bound(m1_z, v1_z, m2_z);
 115                 v2 = to.origin;
 116                 m1 = from.absmin;
 117                 m2 = from.absmax;
 118                 v2_x = bound(m1_x, v2_x, m2_x);
 119                 v2_y = bound(m1_y, v2_y, m2_y);
 120                 v2_z = bound(m1_z, v2_z, m2_z);
 121                 v2 = to.origin;
 122                 c = vlen(v2 - v1);
 123         }
 124         else
 125                 c = vlen(to.origin - from.origin);
 126
 127         if (from.wp31mincost < c) return;
 128         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 129         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 130         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 131         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 132         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 133         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 134         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 135         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 136         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 137         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 138         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 139         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 140         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 141         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 142         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 143         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 144         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 145         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 146         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 147         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 148         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 149         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 150         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 151         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 152         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 153         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 154         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 155         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 156         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 157         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 158         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 159         from.wp00 = to;from.wp00mincost = c;return;
 160 }
 161
 162 // relink this spawnfunc_waypoint
 163 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 164 // (SLOW!)
 165 void waypoint_think()
 166 {SELFPARAM();
 167         entity e;
 168         vector sv, sm1, sm2, ev, em1, em2, dv;
 169
 170         bot_calculate_stepheightvec();
 171
 172         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 173
 174         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 175         sm1 = self.origin + self.mins;
 176         sm2 = self.origin + self.maxs;
 177         for(e = world; (e = find(e, classname, "waypoint")); )
 178         {
 179                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 180                 {
 181                         waypoint_addlink(self, e);
 182                         waypoint_addlink(e, self);
 183                 }
 184                 else
 185                 {
 186                         ++relink_total;
 187                         if(!checkpvs(self.origin, e))
 188                         {
 189                                 ++relink_pvsculled;
 190                                 continue;
 191                         }
 192                         sv = e.origin;
 193                         sv.x = bound(sm1_x, sv.x, sm2_x);
 194                         sv.y = bound(sm1_y, sv.y, sm2_y);
 195                         sv.z = bound(sm1_z, sv.z, sm2_z);
 196                         ev = self.origin;
 197                         em1 = e.origin + e.mins;
 198                         em2 = e.origin + e.maxs;
 199                         ev.x = bound(em1_x, ev.x, em2_x);
 200                         ev.y = bound(em1_y, ev.y, em2_y);
 201                         ev.z = bound(em1_z, ev.z, em2_z);
 202                         dv = ev - sv;
 203                         dv.z = 0;
 204                         if (vlen(dv) >= 1050) // max search distance in XY
 205                         {
 206                                 ++relink_lengthculled;
 207                                 continue;
 208                         }
 209                         navigation_testtracewalk = 0;
 210                         if (!self.wpisbox)
 211                         {
 212                                 tracebox(sv - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, false, self);
 213                                 if (!trace_startsolid)
 214                                 {
 215                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 216                                         sv = trace_endpos + '0 0 1';
 217                                 }
 218                         }
 219                         if (!e.wpisbox)
 220                         {
 221                                 tracebox(ev - STAT(PL_MIN, NULL).z * '0 0 1', STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, false, e);
 222                                 if (!trace_startsolid)
 223                                 {
 224                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 225                                         ev = trace_endpos + '0 0 1';
 226                                 }
 227                         }
 228                         //traceline(self.origin, e.origin, false, world);
 229                         //if (trace_fraction == 1)
 230                         if (!self.wpisbox && tracewalk(self, sv, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), ev, MOVE_NOMONSTERS))
 231                                 waypoint_addlink(self, e);
 232                         else
 233                                 relink_walkculled += 0.5;
 234                         if (!e.wpisbox && tracewalk(e, ev, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), sv, MOVE_NOMONSTERS))
 235                                 waypoint_addlink(e, self);
 236                         else
 237                                 relink_walkculled += 0.5;
 238                 }
 239         }
 240         navigation_testtracewalk = 0;
 241         self.wplinked = true;
 242 }
 243
 244 void waypoint_clearlinks(entity wp)
 245 {
 246         // clear links to other waypoints
 247         float f;
 248         f = 10000000;
 249         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;
 250         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;
 251         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;
 252         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;
 253
 254         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 255         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 256         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 257         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 258
 259         wp.wplinked = false;
 260 }
 261
 262 // tell a spawnfunc_waypoint to relink
 263 void waypoint_schedulerelink(entity wp)
 264 {
 265         if (wp == world)
 266                 return;
 267         // TODO: add some sort of visible box in edit mode for box waypoints
 268         if (autocvar_g_waypointeditor)
 269         {
 270                 vector m1, m2;
 271                 m1 = wp.mins;
 272                 m2 = wp.maxs;
 273                 setmodel(wp, MDL_WAYPOINT); wp.effects = EF_LOWPRECISION;
 274                 setsize(wp, m1, m2);
 275                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 276                         wp.colormod = '1 0 0';
 277                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 278                         wp.colormod = '1 1 0';
 279                 else
 280                         wp.colormod = '1 1 1';
 281         }
 282         else
 283                 wp.model = "";
 284         wp.wpisbox = vlen(wp.size) > 0;
 285         wp.enemy = world;
 286         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 287                 wp.owner = world;
 288         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 289                 waypoint_clearlinks(wp);
 290         // schedule an actual relink on next frame
 291         wp.think = waypoint_think;
 292         wp.nextthink = time;
 293         wp.effects = EF_LOWPRECISION;
 294 }
 295
 296 // spawnfunc_waypoint map entity
 297 spawnfunc(waypoint)
 298 {
 299         setorigin(self, self.origin);
 300         // schedule a relink after other waypoints have had a chance to spawn
 301         waypoint_clearlinks(self);
 302         //waypoint_schedulerelink(self);
 303 }
 304
 305 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 306 void waypoint_remove(entity e)
 307 {
 308         // tell all linked waypoints that they need to relink
 309         waypoint_schedulerelink(e.wp00);
 310         waypoint_schedulerelink(e.wp01);
 311         waypoint_schedulerelink(e.wp02);
 312         waypoint_schedulerelink(e.wp03);
 313         waypoint_schedulerelink(e.wp04);
 314         waypoint_schedulerelink(e.wp05);
 315         waypoint_schedulerelink(e.wp06);
 316         waypoint_schedulerelink(e.wp07);
 317         waypoint_schedulerelink(e.wp08);
 318         waypoint_schedulerelink(e.wp09);
 319         waypoint_schedulerelink(e.wp10);
 320         waypoint_schedulerelink(e.wp11);
 321         waypoint_schedulerelink(e.wp12);
 322         waypoint_schedulerelink(e.wp13);
 323         waypoint_schedulerelink(e.wp14);
 324         waypoint_schedulerelink(e.wp15);
 325         waypoint_schedulerelink(e.wp16);
 326         waypoint_schedulerelink(e.wp17);
 327         waypoint_schedulerelink(e.wp18);
 328         waypoint_schedulerelink(e.wp19);
 329         waypoint_schedulerelink(e.wp20);
 330         waypoint_schedulerelink(e.wp21);
 331         waypoint_schedulerelink(e.wp22);
 332         waypoint_schedulerelink(e.wp23);
 333         waypoint_schedulerelink(e.wp24);
 334         waypoint_schedulerelink(e.wp25);
 335         waypoint_schedulerelink(e.wp26);
 336         waypoint_schedulerelink(e.wp27);
 337         waypoint_schedulerelink(e.wp28);
 338         waypoint_schedulerelink(e.wp29);
 339         waypoint_schedulerelink(e.wp30);
 340         waypoint_schedulerelink(e.wp31);
 341         // and now remove the spawnfunc_waypoint
 342         remove(e);
 343 }
 344
 345 // empties the map of waypoints
 346 void waypoint_removeall()
 347 {
 348         entity head, next;
 349         head = findchain(classname, "waypoint");
 350         while (head)
 351         {
 352                 next = head.chain;
 353                 remove(head);
 354                 head = next;
 355         }
 356 }
 357
 358 // tell all waypoints to relink
 359 // (is this useful at all?)
 360 void waypoint_schedulerelinkall()
 361 {
 362         entity head;
 363         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 364         head = findchain(classname, "waypoint");
 365         while (head)
 366         {
 367                 waypoint_schedulerelink(head);
 368                 head = head.chain;
 369         }
 370 }
 371
 372 // Load waypoint links from file
 373 float waypoint_load_links()
 374 {
 375         string filename, s;
 376         float file, tokens, c = 0, found;
 377         entity wp_from = world, wp_to;
 378         vector wp_to_pos, wp_from_pos;
 379         filename = strcat("maps/", mapname);
 380         filename = strcat(filename, ".waypoints.cache");
 381         file = fopen(filename, FILE_READ);
 382
 383         if (file < 0)
 384         {
 385                 LOG_TRACE("waypoint links load from ");
 386                 LOG_TRACE(filename);
 387                 LOG_TRACE(" failed\n");
 388                 return false;
 389         }
 390
 391         while ((s = fgets(file)))
 392         {
 393                 tokens = tokenizebyseparator(s, "*");
 394
 395                 if (tokens!=2)
 396                 {
 397                         // bad file format
 398                         fclose(file);
 399                         return false;
 400                 }
 401
 402                 wp_from_pos     = stov(argv(0));
 403                 wp_to_pos       = stov(argv(1));
 404
 405                 // Search "from" waypoint
 406                 if(!wp_from || wp_from.origin!=wp_from_pos)
 407                 {
 408                         wp_from = findradius(wp_from_pos, 1);
 409                         found = false;
 410                         while(wp_from)
 411                         {
 412                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 413                                 if(wp_from.classname == "waypoint")
 414                                 {
 415                                         found = true;
 416                                         break;
 417                                 }
 418                                 wp_from = wp_from.chain;
 419                         }
 420
 421                         if(!found)
 422                         {
 423                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin),"\n");
 424                                 continue;
 425                         }
 426
 427                 }
 428
 429                 // Search "to" waypoint
 430                 wp_to = findradius(wp_to_pos, 1);
 431                 found = false;
 432                 while(wp_to)
 433                 {
 434                         if(vlen(wp_to.origin-wp_to_pos)<1)
 435                         if(wp_to.classname == "waypoint")
 436                         {
 437                                 found = true;
 438                                 break;
 439                         }
 440                         wp_to = wp_to.chain;
 441                 }
 442
 443                 if(!found)
 444                 {
 445                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin),"\n");
 446                         continue;
 447                 }
 448
 449                 ++c;
 450                 waypoint_addlink(wp_from, wp_to);
 451         }
 452
 453         fclose(file);
 454
 455         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache\n");
 456
 457         botframe_cachedwaypointlinks = true;
 458         return true;
 459 }
 460
 461 void waypoint_load_links_hardwired()
 462 {
 463         string filename, s;
 464         float file, tokens, c = 0, found;
 465         entity wp_from = world, wp_to;
 466         vector wp_to_pos, wp_from_pos;
 467         filename = strcat("maps/", mapname);
 468         filename = strcat(filename, ".waypoints.hardwired");
 469         file = fopen(filename, FILE_READ);
 470
 471         botframe_loadedforcedlinks = true;
 472
 473         if (file < 0)
 474         {
 475                 LOG_TRACE("waypoint links load from ", filename, " failed\n");
 476                 return;
 477         }
 478
 479         while ((s = fgets(file)))
 480         {
 481                 if(substring(s, 0, 2)=="//")
 482                         continue;
 483
 484                 if(substring(s, 0, 1)=="#")
 485                         continue;
 486
 487                 tokens = tokenizebyseparator(s, "*");
 488
 489                 if (tokens!=2)
 490                         continue;
 491
 492                 wp_from_pos     = stov(argv(0));
 493                 wp_to_pos       = stov(argv(1));
 494
 495                 // Search "from" waypoint
 496                 if(!wp_from || wp_from.origin!=wp_from_pos)
 497                 {
 498                         wp_from = findradius(wp_from_pos, 5);
 499                         found = false;
 500                         while(wp_from)
 501                         {
 502                                 if(vlen(wp_from.origin-wp_from_pos)<5)
 503                                 if(wp_from.classname == "waypoint")
 504                                 {
 505                                         found = true;
 506                                         break;
 507                                 }
 508                                 wp_from = wp_from.chain;
 509                         }
 510
 511                         if(!found)
 512                         {
 513                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 514                                 continue;
 515                         }
 516                 }
 517
 518                 // Search "to" waypoint
 519                 wp_to = findradius(wp_to_pos, 5);
 520                 found = false;
 521                 while(wp_to)
 522                 {
 523                         if(vlen(wp_to.origin-wp_to_pos)<5)
 524                         if(wp_to.classname == "waypoint")
 525                         {
 526                                 found = true;
 527                                 break;
 528                         }
 529                         wp_to = wp_to.chain;
 530                 }
 531
 532                 if(!found)
 533                 {
 534                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 535                         continue;
 536                 }
 537
 538                 ++c;
 539                 waypoint_addlink(wp_from, wp_to);
 540                 wp_from.wphardwired = true;
 541                 wp_to.wphardwired = true;
 542         }
 543
 544         fclose(file);
 545
 546         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired\n");
 547 }
 548
 549 entity waypoint_get_link(entity w, float i)
 550 {
 551         switch(i)
 552         {
 553                 case  0:return w.wp00;
 554                 case  1:return w.wp01;
 555                 case  2:return w.wp02;
 556                 case  3:return w.wp03;
 557                 case  4:return w.wp04;
 558                 case  5:return w.wp05;
 559                 case  6:return w.wp06;
 560                 case  7:return w.wp07;
 561                 case  8:return w.wp08;
 562                 case  9:return w.wp09;
 563                 case 10:return w.wp10;
 564                 case 11:return w.wp11;
 565                 case 12:return w.wp12;
 566                 case 13:return w.wp13;
 567                 case 14:return w.wp14;
 568                 case 15:return w.wp15;
 569                 case 16:return w.wp16;
 570                 case 17:return w.wp17;
 571                 case 18:return w.wp18;
 572                 case 19:return w.wp19;
 573                 case 20:return w.wp20;
 574                 case 21:return w.wp21;
 575                 case 22:return w.wp22;
 576                 case 23:return w.wp23;
 577                 case 24:return w.wp24;
 578                 case 25:return w.wp25;
 579                 case 26:return w.wp26;
 580                 case 27:return w.wp27;
 581                 case 28:return w.wp28;
 582                 case 29:return w.wp29;
 583                 case 30:return w.wp30;
 584                 case 31:return w.wp31;
 585                 default:return world;
 586         }
 587 }
 588
 589 // Save all waypoint links to a file
 590 void waypoint_save_links()
 591 {
 592         string filename, s;
 593         float file, c, i;
 594         entity w, link;
 595         filename = strcat("maps/", mapname);
 596         filename = strcat(filename, ".waypoints.cache");
 597         file = fopen(filename, FILE_WRITE);
 598         if (file < 0)
 599         {
 600                 LOG_INFO("waypoint links save to ");
 601                 LOG_INFO(filename);
 602                 LOG_INFO(" failed\n");
 603         }
 604         c = 0;
 605         w = findchain(classname, "waypoint");
 606         while (w)
 607         {
 608                 for(i=0;i<32;++i)
 609                 {
 610                         // :S
 611                         link = waypoint_get_link(w, i);
 612                         if(link==world)
 613                                 continue;
 614
 615                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
 616                         fputs(file, s);
 617                         ++c;
 618                 }
 619                 w = w.chain;
 620         }
 621         fclose(file);
 622         botframe_cachedwaypointlinks = true;
 623
 624         LOG_INFO("saved ");
 625         LOG_INFO(ftos(c));
 626         LOG_INFO(" waypoints links to maps/");
 627         LOG_INFO(mapname);
 628         LOG_INFO(".waypoints.cache\n");
 629 }
 630
 631 // save waypoints to gamedir/data/maps/mapname.waypoints
 632 void waypoint_saveall()
 633 {
 634         string filename, s;
 635         float file, c;
 636         entity w;
 637         filename = strcat("maps/", mapname);
 638         filename = strcat(filename, ".waypoints");
 639         file = fopen(filename, FILE_WRITE);
 640         if (file >= 0)
 641         {
 642                 c = 0;
 643                 w = findchain(classname, "waypoint");
 644                 while (w)
 645                 {
 646                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 647                         {
 648                                 s = strcat(vtos(w.origin + w.mins), "\n");
 649                                 s = strcat(s, vtos(w.origin + w.maxs));
 650                                 s = strcat(s, "\n");
 651                                 s = strcat(s, ftos(w.wpflags));
 652                                 s = strcat(s, "\n");
 653                                 fputs(file, s);
 654                                 c = c + 1;
 655                         }
 656                         w = w.chain;
 657                 }
 658                 fclose(file);
 659                 bprint("saved ");
 660                 bprint(ftos(c));
 661                 bprint(" waypoints to maps/");
 662                 bprint(mapname);
 663                 bprint(".waypoints\n");
 664         }
 665         else
 666         {
 667                 bprint("waypoint save to ");
 668                 bprint(filename);
 669                 bprint(" failed\n");
 670         }
 671         waypoint_save_links();
 672         botframe_loadedforcedlinks = false;
 673 }
 674
 675 // load waypoints from file
 676 float waypoint_loadall()
 677 {
 678         string filename, s;
 679         float file, cwp, cwb, fl;
 680         vector m1, m2;
 681         cwp = 0;
 682         cwb = 0;
 683         filename = strcat("maps/", mapname);
 684         filename = strcat(filename, ".waypoints");
 685         file = fopen(filename, FILE_READ);
 686         if (file >= 0)
 687         {
 688                 while ((s = fgets(file)))
 689                 {
 690                         m1 = stov(s);
 691                         s = fgets(file);
 692                         if (!s)
 693                                 break;
 694                         m2 = stov(s);
 695                         s = fgets(file);
 696                         if (!s)
 697                                 break;
 698                         fl = stof(s);
 699                         waypoint_spawn(m1, m2, fl);
 700                         if (m1 == m2)
 701                                 cwp = cwp + 1;
 702                         else
 703                                 cwb = cwb + 1;
 704                 }
 705                 fclose(file);
 706                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints\n");
 707         }
 708         else
 709         {
 710                 LOG_TRACE("waypoint load from ", filename, " failed\n");
 711         }
 712         return cwp + cwb;
 713 }
 714
 715 vector waypoint_fixorigin(vector position)
 716 {
 717         tracebox(position + '0 0 1' * (1 - STAT(PL_MIN, NULL).z), STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), position + '0 0 -512', MOVE_NOMONSTERS, world);
 718         if(trace_fraction < 1)
 719                 position = trace_endpos;
 720         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, world);
 721         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 722         return position;
 723 }
 724
 725 void waypoint_spawnforitem_force(entity e, vector org)
 726 {
 727         entity w;
 728
 729         // Fix the waypoint altitude if necessary
 730         org = waypoint_fixorigin(org);
 731
 732         // don't spawn an item spawnfunc_waypoint if it already exists
 733         w = findchain(classname, "waypoint");
 734         while (w)
 735         {
 736                 if (w.wpisbox)
 737                 {
 738                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 739                         {
 740                                 e.nearestwaypoint = w;
 741                                 return;
 742                         }
 743                 }
 744                 else
 745                 {
 746                         if (vlen(w.origin - org) < 16)
 747                         {
 748                                 e.nearestwaypoint = w;
 749                                 return;
 750                         }
 751                 }
 752                 w = w.chain;
 753         }
 754         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 755 }
 756
 757 void waypoint_spawnforitem(entity e)
 758 {
 759         if(!bot_waypoints_for_items)
 760                 return;
 761
 762         waypoint_spawnforitem_force(e, e.origin);
 763 }
 764
 765 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 766 {
 767         entity w;
 768         entity dw;
 769         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 770         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 771         // one way link to the destination
 772         w.wp00 = dw;
 773         w.wp00mincost = timetaken; // this is just for jump pads
 774         // the teleporter's nearest spawnfunc_waypoint is this one
 775         // (teleporters are not goals, so this is probably useless)
 776         e.nearestwaypoint = w;
 777         e.nearestwaypointtimeout = time + 1000000000;
 778 }
 779
 780 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 781 {
 782         org = waypoint_fixorigin(org);
 783         destination = waypoint_fixorigin(destination);
 784         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 785 }
 786
 787 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 788 {
 789         destination = waypoint_fixorigin(destination);
 790         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 791 }
 792
 793 entity waypoint_spawnpersonal(entity this, vector position)
 794 {
 795         entity w;
 796
 797         // drop the waypoint to a proper location:
 798         //   first move it up by a player height
 799         //   then move it down to hit the floor with player bbox size
 800         position = waypoint_fixorigin(position);
 801
 802         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 803         w.nearestwaypoint = world;
 804         w.nearestwaypointtimeout = 0;
 805         w.owner = this;
 806
 807         waypoint_schedulerelink(w);
 808
 809         return w;
 810 }
 811
 812 void botframe_showwaypointlinks()
 813 {
 814         entity head, w;
 815         if (time < botframe_waypointeditorlightningtime)
 816                 return;
 817         botframe_waypointeditorlightningtime = time + 0.5;
 818         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot, LAMBDA(
 819                 if(IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
 820                 {
 821                         //navigation_testtracewalk = true;
 822                         head = navigation_findnearestwaypoint(it, false);
 823                 //      print("currently selected WP is ", etos(head), "\n");
 824                         //navigation_testtracewalk = false;
 825                         if (head)
 826                         {
 827                                 w = head     ;if (w) te_lightning2(world, w.origin, it.origin);
 828                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
 829                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
 830                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
 831                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
 832                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
 833                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
 834                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
 835                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
 836                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
 837                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
 838                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
 839                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
 840                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
 841                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
 842                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
 843                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
 844                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
 845                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
 846                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
 847                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
 848                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
 849                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
 850                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
 851                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
 852                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
 853                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
 854                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
 855                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
 856                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
 857                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
 858                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
 859                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
 860                         }
 861                 }
 862         ));
 863 }
 864
 865 float botframe_autowaypoints_fixdown(vector v)
 866 {
 867         tracebox(v, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), v + '0 0 -64', MOVE_NOMONSTERS, world);
 868         if(trace_fraction >= 1)
 869                 return 0;
 870         return 1;
 871 }
 872
 873 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 874 {
 875         entity w;
 876
 877         w = find(world, classname, "waypoint");
 878         while (w)
 879         {
 880                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 881                 if (boxesoverlap(v - '32 32 32', v + '32 32 32', w.absmin, w.absmax))
 882                 //if (boxesoverlap(v - '4 4 4', v + '4 4 4', w.absmin, w.absmax))
 883                         return 0;
 884                 w = find(w, classname, "waypoint");
 885         }
 886
 887         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 888         return 1;
 889 }
 890
 891 // return value:
 892 //    1 = WP created
 893 //    0 = no action needed
 894 //   -1 = temp fail, try from world too
 895 //   -2 = permanent fail, do not retry
 896 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 897 {
 898         // make it possible to go from p to wp, if we can
 899         // if wp is world, nearest is chosen
 900
 901         entity w;
 902         vector porg;
 903         float t, tmin, tmax;
 904         vector o;
 905         vector save;
 906
 907         if(!botframe_autowaypoints_fixdown(p.origin))
 908                 return -2;
 909         porg = trace_endpos;
 910
 911         if(wp)
 912         {
 913                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 914
 915                 // if wp -> porg, then OK
 916                 float maxdist;
 917                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 918                 {
 919                         // we may find a better one
 920                         maxdist = vlen(wp.origin - porg);
 921                 }
 922                 else
 923                 {
 924                         // accept any "good"
 925                         maxdist = 2100;
 926                 }
 927
 928                 float bestdist;
 929                 bestdist = maxdist;
 930                 w = find(world, classname, "waypoint");
 931                 while (w)
 932                 {
 933                         if(w != wp && !(w.wpflags & WAYPOINTFLAG_NORELINK))
 934                         {
 935                                 float d;
 936                                 d = vlen(wp.origin - w.origin) + vlen(w.origin - porg);
 937                                 if(d < bestdist)
 938                                         if(navigation_waypoint_will_link(wp.origin, w.origin, p, walkfromwp, 1050))
 939                                                 if(navigation_waypoint_will_link(w.origin, porg, p, walkfromwp, 1050))
 940                                                 {
 941                                                         bestdist = d;
 942                                                         p.(fld) = w;
 943                                                 }
 944                         }
 945                         w = find(w, classname, "waypoint");
 946                 }
 947                 if(bestdist < maxdist)
 948                 {
 949                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 950                         return 0;
 951                 }
 952
 953                 if(bestdist < 2100)
 954                 {
 955                         // we know maxdist < 2100
 956                         // so wp -> porg is still valid
 957                         // all is good
 958                         p.(fld) = wp;
 959                         return 0;
 960                 }
 961
 962                 // otherwise, no existing WP can fix our issues
 963         }
 964         else
 965         {
 966                 save = p.origin;
 967                 setorigin(p, porg);
 968                 w = navigation_findnearestwaypoint(p, walkfromwp);
 969                 setorigin(p, save);
 970                 if(w)
 971                 {
 972                         p.(fld) = w;
 973                         return 0;
 974                 }
 975         }
 976
 977         tmin = 0;
 978         tmax = 1;
 979         for (;;)
 980         {
 981                 if(tmax - tmin < 0.001)
 982                 {
 983                         // did not get a good candidate
 984                         return -1;
 985                 }
 986
 987                 t = (tmin + tmax) * 0.5;
 988                 o = antilag_takebackorigin(p, CS(p), time - t);
 989                 if(!botframe_autowaypoints_fixdown(o))
 990                         return -2;
 991                 o = trace_endpos;
 992
 993                 if(wp)
 994                 {
 995                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
 996                         {
 997                                 // we cannot walk from wp.origin to o
 998                                 // get closer to tmax
 999                                 tmin = t;
1000                                 continue;
1001                         }
1002                 }
1003                 else
1004                 {
1005                         save = p.origin;
1006                         setorigin(p, o);
1007                         w = navigation_findnearestwaypoint(p, walkfromwp);
1008                         setorigin(p, save);
1009                         if(!w)
1010                         {
1011                                 // we cannot walk from any WP to o
1012                                 // get closer to tmax
1013                                 tmin = t;
1014                                 continue;
1015                         }
1016                 }
1017
1018                 // if we get here, o is valid regarding waypoints
1019                 // check if o is connected right to the player
1020                 // we break if it succeeds, as that means o is a good waypoint location
1021                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1022                         break;
1023
1024                 // o is no good, we need to get closer to the player
1025                 tmax = t;
1026         }
1027
1028         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1029         botframe_autowaypoints_createwp(o, p, fld, 0);
1030         return 1;
1031 }
1032
1033 // automatically create missing waypoints
1034 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1035 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1036 {
1037         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1038         if(r != -1)
1039                 return;
1040         r = botframe_autowaypoints_fix_from(p, walkfromwp, world, fld);
1041         if(r != -1)
1042                 return;
1043
1044         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1045         if(!botframe_autowaypoints_fixdown(p.origin))
1046                 return; // shouldn't happen, caught above
1047         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1048 }
1049
1050 void botframe_deleteuselesswaypoints()
1051 {
1052         entity w, w1, w2;
1053         float i, j, k;
1054         for (w = world; (w = findfloat(w, bot_pickup, true)); )
1055         {
1056                 // NOTE: this protects waypoints if they're the ONLY nearest
1057                 // waypoint. That's the intention.
1058                 navigation_findnearestwaypoint(w, false);  // Walk TO item.
1059                 navigation_findnearestwaypoint(w, true);  // Walk FROM item.
1060         }
1061         for (w = world; (w = find(w, classname, "waypoint")); )
1062         {
1063                 w.wpflags |= WAYPOINTFLAG_DEAD_END;
1064                 w.wpflags &= ~WAYPOINTFLAG_USEFUL;
1065                 // WP is useful if:
1066                 if (w.wpflags & WAYPOINTFLAG_ITEM)
1067                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1068                 if (w.wpflags & WAYPOINTFLAG_TELEPORT)
1069                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1070                 if (w.wpflags & WAYPOINTFLAG_PROTECTED)
1071                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1072                 // b) WP is closest WP for an item/spawnpoint/other entity
1073                 //    This has been done above by protecting these WPs.
1074         }
1075         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1076         for (w1 = world; (w1 = find(w1, classname, "waypoint")); )
1077         {
1078                 if (w1.wpflags & WAYPOINTFLAG_PERSONAL)
1079                         continue;
1080                 for (i = 0; i < 32; ++i)
1081                 {
1082                         w = waypoint_get_link(w1, i);
1083                         if (!w)
1084                                 break;
1085                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1086                                 continue;
1087                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1088                                 continue;
1089                         for (j = 0; j < 32; ++j)
1090                         {
1091                                 w2 = waypoint_get_link(w, j);
1092                                 if (!w2)
1093                                         break;
1094                                 if (w1 == w2)
1095                                         continue;
1096                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1097                                         continue;
1098                                 // If we got here, w1 != w2 exist with w1 -> w
1099                                 // and w -> w2. That means the waypoint is not
1100                                 // a dead end.
1101                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1102                                 for (k = 0; k < 32; ++k)
1103                                 {
1104                                         if (waypoint_get_link(w1, k) == w2)
1105                                                 continue;
1106                                         // IF WE GET HERE, w is proven useful
1107                                         // to get from w1 to w2!
1108                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1109                                         goto next;
1110                                 }
1111                         }
1112 LABEL(next)
1113                 }
1114         }
1115         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1116         //     they are needed to complete routes while autowaypointing.
1117
1118         for (w = world; (w = find(w, classname, "waypoint")); )
1119         {
1120                 if (!(w.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)))
1121                 {
1122                         LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", w.origin);
1123                         te_explosion(w.origin);
1124                         waypoint_remove(w);
1125                         break;
1126                 }
1127         }
1128         for (w = world; (w = find(w, classname, "waypoint")); )
1129                 w.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1130 }
1131
1132 void botframe_autowaypoints()
1133 {
1134         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1135                 // going back is broken, so only fix waypoints to walk TO the player
1136                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1137                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1138                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1139         ));
1140
1141         if (autocvar_g_waypointeditor_auto >= 2) {
1142                 botframe_deleteuselesswaypoints();
1143         }
1144 }
1145