qcsrc/server/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include "defs.qh"
   4
   5 #include "cheats.qh"
   6 #include "miscfunctions.qh"
   7 #include "g_world.qh"
   8
   9 #include "../common/campaign_common.qh"
  10
  11 // campaign cvars:
  12 //   _campaign_index: index of CURRENT map
  13 //   _campaign_name: name of the current campaign
  14 //   g_campaign(name)_index: index of current LAST map (saved)
  15 //   g_campaign_skill: bot skill offset
  16
  17 float campaign_level;
  18 float campaign_won;
  19 string campaign_index_var;
  20 //float checkrules_equality;
  21
  22 float CampaignBailout(string s)
  23 {
  24 #if 0
  25         cvar = cvar_normal;
  26         cvar_string = cvar_string_normal;
  27         cvar_set = cvar_set_normal;
  28 #endif
  29         cvar_set("g_campaign", "0");
  30         LOG_INFO("^4campaign initialization failed: ", s);
  31         if(autocvar__campaign_testrun)
  32                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  33         return 1;
  34 }
  35
  36 #if 0
  37 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  38 string cvar_string_campaignwrapper(string theCvar)
  39 {
  40         float p, q;
  41         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  42         if(p < 0)
  43                 return cvar_defstring(theCvar);
  44         p += strlen(theCvar) + 3;
  45         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  46         if(q < 0)
  47                 return cvar_defstring(theCvar);
  48         return substring(cvar_campaignwrapper_list, p, q - p);
  49 }
  50 float cvar_campaignwrapper(string theCvar)
  51 {
  52         return stof(cvar_string_campaignwrapper(theCvar));
  53 }
  54 void cvar_set_campaignwrapper(string theCvar, string theValue)
  55 {
  56         if(cvar_string_campaignwrapper(theCvar) == theValue)
  57                 return;
  58         string s = cvar_campaignwrapper_list;
  59         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  60         strunzone(s);
  61         //print(cvar_campaignwrapper_list, "\n");
  62 }
  63 #endif
  64
  65 float Campaign_Invalid()
  66 {
  67         string thismapname, wantedmapname;
  68         thismapname = GetMapname();
  69         wantedmapname = campaign_gametype[0];
  70         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  71                 return CampaignBailout("wrong game type!");
  72         wantedmapname = campaign_mapname[0];
  73         if(wantedmapname != thismapname)
  74                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  75         return 0;
  76 }
  77
  78 void CampaignPreInit()
  79 {
  80         float baseskill;
  81         string title;
  82         campaign_level = autocvar__campaign_index;
  83         campaign_name = strzone(autocvar__campaign_name);
  84         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  85         CampaignFile_Load(campaign_level, 2);
  86
  87         if(campaign_entries < 1)
  88         {
  89                 CampaignBailout("unknown map");
  90                 return;
  91         }
  92
  93         if(autocvar_sv_cheats)
  94         {
  95                 MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
  96                 CampaignFile_Unload();
  97                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  98                 return;
  99         }
 100
 101         baseskill = max(0, autocvar_g_campaign_skill + campaign_botskill[0]);
 102         campaign_forcewin = false;
 103
 104         cvar_set("sv_public", "0");
 105         cvar_set("pausable", "1");
 106
 107 #if 0
 108         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
 109 #else
 110         string cvar_campaignwrapper_list = strcat("; ", campaign_mutators[0], "; ");
 111         int argc = tokenizebyseparator(cvar_campaignwrapper_list, "; ");
 112         if(argc > 0)
 113         {
 114                 for(int j = 0; j < argc; ++j)
 115                 {
 116                         string arg = argv(j);
 117                         if(arg == "") continue;
 118                         _MapInfo_Parse_Settemp(mapname, MAPINFO_SETTEMP_ACL_USER, 0, arg, 0); // no recursion!
 119                 }
 120         }
 121 #endif
 122
 123 #if 0
 124         cvar = cvar_campaignwrapper;
 125         cvar_string = cvar_string_campaignwrapper;
 126         cvar_set = cvar_set_campaignwrapper;
 127         cvar_set("g_campaign", "1");
 128         cvar_set("g_dm", "0");
 129         cvar_set("skill", ftos(baseskill));
 130         cvar_set("bot_number", ftos(campaign_bots[0]));
 131 #else
 132         cvar_settemp("g_campaign", "1");
 133         cvar_settemp("g_dm", "0");
 134         cvar_settemp("skill", ftos(baseskill));
 135         cvar_settemp("bot_number", ftos(campaign_bots[0]));
 136 #endif
 137         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
 138
 139         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
 140         // with the menu a little still...)
 141         cvar_set_normal("sv_gravity", ftos(autocvar_sv_gravity));
 142
 143         if(Campaign_Invalid())
 144                 return;
 145
 146         title = campaign_shortdesc[0];
 147         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 148         campaign_message = strzone(strcat(title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 149         strunzone(title);
 150 }
 151
 152 void CampaignPostInit()
 153 {
 154         // now some sanity checks
 155         if(Campaign_Invalid())
 156                 return;
 157         if(autocvar__campaign_testrun)
 158         {
 159                 cvar_set("fraglimit", "0");
 160                 cvar_set("leadlimit", "0");
 161                 cvar_set("timelimit", "0.01");
 162                 cvar_set_normal("fraglimit", "0");
 163                 cvar_set_normal("leadlimit", "0");
 164                 cvar_set_normal("timelimit", "0.01");
 165         }
 166         else
 167         {
 168                 // "default" uses implicit values, "" or "0" means no limit
 169                 tokenizebyseparator(campaign_fraglimit[0], "+");
 170                 if(argv(0) != "default") {
 171                         cvar_set("fraglimit", argv(0));
 172                         cvar_set_normal("fraglimit", argv(0));
 173                 }
 174                 if(argv(1) != "default") {
 175                         cvar_set("leadlimit", argv(1));
 176                         cvar_set_normal("leadlimit", argv(1));
 177                 }
 178                 if(campaign_timelimit[0] != "default") {
 179                         cvar_set("timelimit", campaign_timelimit[0]);
 180                         cvar_set_normal("timelimit", campaign_timelimit[0]);
 181                 }
 182         }
 183 }
 184
 185 void CampaignSaveCvar(string cvarname, float value)
 186 {
 187         float fh;
 188         float len;
 189         string contents;
 190         string l;
 191
 192         registercvar(cvarname, ftos(value));
 193         cvar_set_normal(cvarname, ftos(value));
 194         // note: cvarname must be remembered
 195
 196         fh = fopen("campaign.cfg", FILE_READ);
 197         contents = "";
 198         if(fh >= 0)
 199         {
 200                 while((l = fgets(fh)))
 201                 {
 202                         len = tokenize_console(l);
 203                         if(len != 3)
 204                                 continue;
 205                         if(argv(0) != "set")
 206                                 continue;
 207                         if(argv(1) == cvarname)
 208                                 continue;
 209                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 210                 }
 211                 fclose(fh);
 212         }
 213         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 214         fh = fopen("campaign.cfg", FILE_WRITE);
 215         if(fh >= 0)
 216         {
 217                 fputs(fh, contents);
 218         }
 219         else
 220         {
 221                 error("Cannot write to campaign file");
 222         }
 223 }
 224
 225 void CampaignPreIntermission()
 226 {
 227         int won = 0;
 228         int lost = 0;
 229         string savevar;
 230
 231         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 232                 if(it.winning)
 233                         won += 1;
 234                 else
 235                         lost += 1;
 236         });
 237
 238         if(autocvar__campaign_testrun)
 239         {
 240                 campaign_won = 1;
 241                 bprint("Campaign test run, advancing level.\n");
 242         }
 243         else if(campaign_forcewin)
 244         {
 245                 campaign_won = 1;
 246                 bprint("The current level has been WON.\n");
 247         }
 248         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 249         {
 250                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 251                 {
 252                         campaign_won = 0;
 253                         bprint("Time's up! The current level has been LOST.\n");
 254                         // sound!
 255                 }
 256                 else
 257                 {
 258                         campaign_won = 1;
 259                         bprint("The current level has been WON.\n");
 260                         // sound!
 261                 }
 262         }
 263         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 264         {
 265                 campaign_won = 0;
 266                 bprint("Time's up! The current level has been LOST.\n");
 267                 // sound!
 268         }
 269         else
 270         {
 271                 campaign_won = 0;
 272                 bprint("The current level has been LOST.\n");
 273                 // sound!
 274         }
 275
 276         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 277         {
 278                 if(campaign_level == cvar_normal(campaign_index_var))
 279                 {
 280                         if(campaign_entries < 2)
 281                         {
 282                                 // I have won
 283                                 savevar = strcat("g_campaign", campaign_name, "_won");
 284                                 CampaignSaveCvar(savevar, 1);
 285                                 // advance level (for menu to show it right)
 286                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 287                         }
 288                         else
 289                         {
 290                                 // advance level
 291                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 292                         }
 293                 }
 294         }
 295 }
 296
 297 void CampaignPostIntermission()
 298 {
 299         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 300
 301         if(campaign_won && campaign_entries < 2)
 302         {
 303                 // last map won!
 304                 LOG_DEBUG("^2test run: campaign looks GOOD");
 305                 localcmd("togglemenu 1\n");
 306                 CampaignFile_Unload();
 307                 return;
 308         }
 309
 310         CampaignSetup(campaign_won);
 311         CampaignFile_Unload();
 312         strunzone(campaign_message);
 313         strunzone(campaign_index_var);
 314         strunzone(campaign_name);
 315         campaign_name = "";
 316 }
 317
 318
 319
 320 void CampaignLevelWarp(float n)
 321 {
 322         if(n < 0)
 323                 n = campaign_level + 1;
 324         CampaignFile_Unload();
 325         CampaignFile_Load(n, 1);
 326         if(campaign_entries)
 327                 CampaignSetup(0);
 328         else
 329                 error("Sorry, cheater. You are NOT WELCOME.");
 330         CampaignFile_Unload();
 331 }
 332