qcsrc/server/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include <common/campaign_common.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/stats.qh>
   6 #include <common/weapons/_all.qh>
   7 #include <server/cheats.qh>
   8 #include <server/intermission.qh>
   9 #include <server/world.qh>
  10
  11 // campaign cvars:
  12 //   _campaign_index: index of CURRENT map
  13 //   _campaign_name: name of the current campaign
  14 //   g_campaign(name)_index: index of current LAST map (saved)
  15 //   g_campaign_skill: bot skill offset
  16
  17 float campaign_level;
  18 float campaign_won;
  19 string campaign_index_var;
  20 //float checkrules_equality;
  21
  22 float CampaignBailout(string s)
  23 {
  24         cvar_set("g_campaign", "0");
  25         LOG_INFO("^4campaign initialization failed: ", s);
  26         if(autocvar__campaign_testrun)
  27                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  28         return 1;
  29 }
  30
  31 float Campaign_Invalid()
  32 {
  33         string thismapname, wantedmapname;
  34         thismapname = GetMapname();
  35         wantedmapname = campaign_gametype[0];
  36         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname, false, false))
  37                 return CampaignBailout("wrong game type!");
  38         wantedmapname = campaign_mapname[0];
  39         if(wantedmapname != thismapname)
  40                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  41         return 0;
  42 }
  43
  44 int Campaign_GetLevelNum()
  45 {
  46         return campaign_level + 1;
  47 }
  48
  49 void CampaignPreInit()
  50 {
  51         float baseskill;
  52         campaign_level = autocvar__campaign_index;
  53         campaign_name = strzone(autocvar__campaign_name);
  54         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  55         CampaignFile_Load(campaign_level, 2);
  56
  57         if(campaign_entries < 1)
  58         {
  59                 CampaignBailout("unknown map");
  60                 return;
  61         }
  62
  63         if(autocvar_sv_cheats)
  64         {
  65                 MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0], false, false));
  66                 CampaignFile_Unload();
  67                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  68                 return;
  69         }
  70
  71         baseskill = max(0, autocvar_g_campaign_skill + campaign_botskill[0]);
  72         campaign_forcewin = false;
  73
  74         cvar_set("sv_public", "0");
  75         cvar_set("pausable", "1");
  76
  77         string cvar_campaignwrapper_list = strcat("; ", campaign_mutators[0], "; ");
  78         int argc = tokenizebyseparator(cvar_campaignwrapper_list, "; ");
  79         if(argc > 0)
  80         {
  81                 for(int j = 0; j < argc; ++j)
  82                 {
  83                         string arg = argv(j);
  84                         if(arg == "") continue;
  85                         _MapInfo_Parse_Settemp(mapname, MAPINFO_SETTEMP_ACL_USER, 0, arg, 1);
  86                 }
  87         }
  88
  89         cvar_settemp("g_campaign", "1");
  90         cvar_settemp("g_dm", "0");
  91         cvar_settemp("skill", ftos(baseskill));
  92         cvar_settemp("bot_number", ftos(campaign_bots[0]));
  93
  94         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0], false, false));
  95
  96         if(Campaign_Invalid())
  97                 return;
  98 }
  99
 100 void CampaignPostInit()
 101 {
 102         // now some sanity checks
 103         if(Campaign_Invalid())
 104                 return;
 105         if(autocvar__campaign_testrun)
 106         {
 107                 cvar_set("fraglimit", "0");
 108                 cvar_set("leadlimit", "0");
 109                 cvar_set("timelimit", "0.01");
 110         }
 111         else
 112         {
 113                 // "default" uses implicit values, "" or "0" means no limit
 114                 tokenizebyseparator(campaign_fraglimit[0], "+");
 115                 if(argv(0) != "default") {
 116                         cvar_set("fraglimit", argv(0));
 117                 }
 118                 if(argv(1) != "default") {
 119                         cvar_set("leadlimit", argv(1));
 120                 }
 121                 if(campaign_timelimit[0] != "default") {
 122                         cvar_set("timelimit", campaign_timelimit[0]);
 123                 }
 124         }
 125 }
 126
 127 void CampaignSaveCvar(string cvarname, float value)
 128 {
 129         float fh;
 130         float len;
 131         string contents;
 132         string l;
 133
 134         registercvar(cvarname, ftos(value));
 135         cvar_set(cvarname, ftos(value));
 136         // note: cvarname must be remembered
 137
 138         fh = fopen("campaign.cfg", FILE_READ);
 139         contents = "";
 140         if(fh >= 0)
 141         {
 142                 while((l = fgets(fh)))
 143                 {
 144                         len = tokenize_console(l);
 145                         if(len != 3)
 146                                 continue;
 147                         if(argv(0) != "set")
 148                                 continue;
 149                         if(argv(1) == cvarname)
 150                                 continue;
 151                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 152                 }
 153                 fclose(fh);
 154         }
 155         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 156         fh = fopen("campaign.cfg", FILE_WRITE);
 157         if(fh >= 0)
 158         {
 159                 fputs(fh, contents);
 160         }
 161         else
 162         {
 163                 error("Cannot write to campaign file");
 164         }
 165 }
 166
 167 void CampaignPreIntermission()
 168 {
 169         int won = 0;
 170         int lost = 0;
 171         string savevar;
 172
 173         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 174                 if(it.winning)
 175                         won += 1;
 176                 else
 177                         lost += 1;
 178         });
 179
 180         if(autocvar__campaign_testrun)
 181         {
 182                 campaign_won = 1;
 183                 bprint("Campaign test run, advancing level.\n");
 184         }
 185         else if(campaign_forcewin)
 186         {
 187                 campaign_won = 1;
 188                 bprint("The current level has been WON.\n");
 189         }
 190         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 191         {
 192                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 193                 {
 194                         campaign_won = 0;
 195                         bprint("Time's up! The current level has been LOST.\n");
 196                         // sound!
 197                 }
 198                 else
 199                 {
 200                         campaign_won = 1;
 201                         bprint("The current level has been WON.\n");
 202                         // sound!
 203                 }
 204         }
 205         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 206         {
 207                 campaign_won = 0;
 208                 bprint("Time's up! The current level has been LOST.\n");
 209                 // sound!
 210         }
 211         else
 212         {
 213                 campaign_won = 0;
 214                 bprint("The current level has been LOST.\n");
 215                 // sound!
 216         }
 217
 218         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 219         {
 220                 if(campaign_level == cvar(campaign_index_var))
 221                 {
 222                         if(campaign_entries < 2)
 223                         {
 224                                 // I have won
 225                                 savevar = strcat("g_campaign", campaign_name, "_won");
 226                                 CampaignSaveCvar(savevar, 1);
 227                                 // advance level (for menu to show it right)
 228                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 229                         }
 230                         else
 231                         {
 232                                 // advance level
 233                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 234                         }
 235                 }
 236         }
 237 }
 238
 239 void CampaignPostIntermission()
 240 {
 241         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 242
 243         if(campaign_won && campaign_entries < 2)
 244         {
 245                 // last map won!
 246                 LOG_DEBUG("^2test run: campaign looks GOOD");
 247                 localcmd("togglemenu 1\n");
 248                 CampaignFile_Unload();
 249                 return;
 250         }
 251
 252         CampaignSetup(campaign_won);
 253         CampaignFile_Unload();
 254         strunzone(campaign_index_var);
 255         strunzone(campaign_name);
 256         campaign_name = "";
 257 }
 258
 259
 260
 261 void CampaignLevelWarp(float n)
 262 {
 263         if(n < 0)
 264                 n = campaign_level + 1;
 265         CampaignFile_Unload();
 266         CampaignFile_Load(n, 1);
 267         if(campaign_entries)
 268                 CampaignSetup(0);
 269         else
 270                 error("Sorry, cheater. You are NOT WELCOME.");
 271         CampaignFile_Unload();
 272 }
 273