qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2 #include "g_damage.qh"
   3 #include "race.qh"
   4 #include "t_teleporters.qh"
   5
   6 #if defined(CSQC)
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9         #include "../dpdefs/progsdefs.qh"
  10     #include "../dpdefs/dpextensions.qh"
  11     #include "../warpzonelib/anglestransform.qh"
  12     #include "../warpzonelib/util_server.qh"
  13     #include "../common/constants.qh"
  14     #include "../common/util.qh"
  15     #include "../common/monsters/monsters.qh"
  16     #include "../common/weapons/weapons.qh"
  17     #include "weapons/tracing.qh"
  18     #include "autocvars.qh"
  19     #include "defs.qh"
  20     #include "../common/deathtypes.qh"
  21         #include "../common/triggers/subs.qh"
  22     #include "mutators/mutators_include.qh"
  23     #include "../csqcmodellib/sv_model.qh"
  24 #endif
  25
  26 void CopyBody(float keepvelocity);
  27
  28 #ifdef NOCHEATS
  29
  30 float CheatImpulse(float i) { return 0; }
  31 float CheatCommand(float argc) { return 0; }
  32 float CheatFrame() { return 0; }
  33 void CheatInit() { cheatcount_total = world.cheatcount; }
  34 void CheatShutdown() { }
  35 void CheatInitClient() { }
  36 void CheatShutdownClient() { }
  37 void Drag_MoveDrag(entity from, entity to) { }
  38
  39 #else
  40
  41 .float maycheat;
  42 float gamestart_sv_cheats;
  43
  44 const float CHIMPULSE_SPEEDRUN_INIT = 30;
  45 const float CHIMPULSE_GIVE_ALL = 99;
  46 const float CHIMPULSE_CLONE_MOVING = 140;
  47 const float CHIMPULSE_SPEEDRUN = 141;
  48 const float CHIMPULSE_CLONE_STANDING = 142;
  49 const float CHIMPULSE_TELEPORT = 143;
  50 const float CHIMPULSE_R00T = 148;
  51
  52 const float CHRAME_DRAG = 8;
  53
  54 void CheatInit()
  55 {
  56         gamestart_sv_cheats = autocvar_sv_cheats;
  57 }
  58
  59 void CheatShutdown()
  60 {
  61 }
  62
  63 void CheatInitClient()
  64 {
  65 }
  66
  67 void CheatShutdownClient()
  68 {
  69 }
  70
  71 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  72 {
  73         // dead people cannot cheat
  74         if(self.deadflag != DEAD_NO)
  75                 return 0;
  76         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  77                 return 0;
  78
  79         // sv_clones
  80         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  81                 if(self.lip < sv_clones)
  82                         return 1;
  83
  84         // haha
  85         if(self.maycheat)
  86                 return 1;
  87
  88         // sv_cheats
  89         if(gamestart_sv_cheats && autocvar_sv_cheats)
  90                 return 1;
  91
  92         // if we get here, player is not allowed to cheat. Log it.
  93         if(i)
  94                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  95         else if(argc)
  96                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  97         else if(fr)
  98                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  99         else
 100                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
 101
 102         return 0;
 103 }
 104
 105 #define BEGIN_CHEAT_FUNCTION() \
 106         float cheating, attempting; \
 107         cheating = 0; attempting = 0
 108 #define DID_CHEAT() \
 109         ++cheating
 110 #define ADD_CHEATS(e,n) \
 111         cheatcount_total += n; \
 112         e.cheatcount += n
 113 #define END_CHEAT_FUNCTION() \
 114         ADD_CHEATS(self,cheating); \
 115         return attempting
 116 #define IS_CHEAT(i,argc,fr) \
 117         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 118                 break
 119
 120 float num_autoscreenshot;
 121 void info_autoscreenshot_findtarget()
 122 {
 123         entity e;
 124         e = find(world, targetname, self.target);
 125         if(!e)
 126         {
 127                 objerror("Missing target. FAIL!");
 128                 return;
 129         }
 130         vector a = vectoangles(e.origin - self.origin);
 131         a.x = -a.x; // don't ask
 132         self.angles_x = a.x;
 133         self.angles_y = a.y;
 134         // we leave Rick Roll alone
 135 }
 136 void spawnfunc_info_autoscreenshot()
 137 {
 138         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 139         {
 140                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 141                 return;
 142         }
 143         if(self.target != "")
 144                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 145         // this one just has to exist
 146 }
 147
 148 float CheatImpulse(float i)
 149 {
 150         BEGIN_CHEAT_FUNCTION();
 151         switch(i)
 152         {
 153                 entity e, e2;
 154
 155                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 156                         // shared with regular waypoint init, so this is not a cheat by itself
 157                         if(!self.personal)
 158                         {
 159                                 self.personal = spawn();
 160                                 self.personal.classname = "personal_wp";
 161                         }
 162                         self.personal.origin = self.origin;
 163                         self.personal.v_angle = self.v_angle;
 164                         self.personal.velocity = self.velocity;
 165                         self.personal.ammo_rockets = self.ammo_rockets;
 166                         self.personal.ammo_nails = self.ammo_nails;
 167                         self.personal.ammo_cells = self.ammo_cells;
 168                         self.personal.ammo_plasma = self.ammo_plasma;
 169                         self.personal.ammo_shells = self.ammo_shells;
 170                         self.personal.ammo_fuel = self.ammo_fuel;
 171                         self.personal.health = self.health;
 172                         self.personal.armorvalue = self.armorvalue;
 173                         self.personal.weapons = self.weapons;
 174                         self.personal.items = self.items;
 175                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 176                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 177                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 178                         self.personal.pauseregen_finished = self.pauseregen_finished;
 179                         self.personal.strength_finished = self.strength_finished;
 180                         self.personal.invincible_finished = self.invincible_finished;
 181                         self.personal.teleport_time = time;
 182                         break; // this part itself doesn't cheat, so let's not count this
 183                 case CHIMPULSE_CLONE_MOVING:
 184                         IS_CHEAT(i, 0, 0);
 185                         makevectors (self.v_angle);
 186                         self.velocity = self.velocity + v_forward * 300;
 187                         CopyBody(1);
 188                         self.lip += 1;
 189                         self.velocity = self.velocity - v_forward * 300;
 190                         DID_CHEAT();
 191                         break;
 192                 case CHIMPULSE_CLONE_STANDING:
 193                         IS_CHEAT(i, 0, 0);
 194                         CopyBody(0);
 195                         self.lip += 1;
 196                         DID_CHEAT();
 197                         break;
 198                 case CHIMPULSE_GIVE_ALL:
 199                         IS_CHEAT(i, 0, 0);
 200                         CheatCommand(tokenize_console("give all"));
 201                         break; // already counted as cheat
 202                 case CHIMPULSE_SPEEDRUN:
 203                         IS_CHEAT(i, 0, 0);
 204                         if(self.personal)
 205                         {
 206                                 self.speedrunning = true;
 207                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 208                                 if(trace_startsolid)
 209                                 {
 210                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 211                                 }
 212                                 else
 213                                 {
 214                                         // Abort speedrun, teleport back
 215                                         setorigin(self, self.personal.origin);
 216                                         self.oldvelocity = self.velocity = self.personal.velocity;
 217                                         self.angles = self.personal.v_angle;
 218                                         self.fixangle = true;
 219
 220                                         MUTATOR_CALLHOOK(AbortSpeedrun);
 221                                 }
 222
 223                                 self.ammo_rockets = self.personal.ammo_rockets;
 224                                 self.ammo_nails = self.personal.ammo_nails;
 225                                 self.ammo_cells = self.personal.ammo_cells;
 226                                 self.ammo_plasma = self.personal.ammo_plasma;
 227                                 self.ammo_shells = self.personal.ammo_shells;
 228                                 self.ammo_fuel = self.personal.ammo_fuel;
 229                                 self.health = self.personal.health;
 230                                 self.armorvalue = self.personal.armorvalue;
 231                                 self.weapons = self.personal.weapons;
 232                                 self.items = self.personal.items;
 233                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 234                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 235                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 236                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 237                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 238                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 239
 240                                 DID_CHEAT();
 241                                 break;
 242                         }
 243                         if(self.deadflag != DEAD_NO)
 244                                 sprint(self, "UR DEAD AHAHAH))\n");
 245                         else
 246                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 247                         break;
 248                 case CHIMPULSE_TELEPORT:
 249                         IS_CHEAT(i, 0, 0);
 250                         if(self.movetype == MOVETYPE_NOCLIP)
 251                         {
 252                                 e = find(world, classname, "info_autoscreenshot");
 253                                 if(e)
 254                                 {
 255                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 256                                         setorigin(self, e.origin);
 257                                         self.angles = e.angles;
 258                                         remove(e);
 259                                         // should we? self.angles_x = -self.angles_x;
 260                                         self.fixangle = true;
 261                                         self.velocity = '0 0 0';
 262                                         DID_CHEAT();
 263                                         break;
 264                                 }
 265                         }
 266                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 267                         {
 268                                 sprint(self, "Emergency teleport used random location\n");
 269                                 self.angles_x = -self.angles.x;
 270                                 self.fixangle = true;
 271                                 self.velocity = '0 0 0';
 272                                 DID_CHEAT();
 273                                 break;
 274                         }
 275                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 276                         break;
 277                 case CHIMPULSE_R00T:
 278                         IS_CHEAT(i, 0, 0);
 279                         RandomSelection_Init();
 280                         FOR_EACH_PLAYER(e)
 281                                 if(e.deadflag == DEAD_NO)
 282                                         if(DIFF_TEAM(e, self))
 283                                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 284                         if(RandomSelection_chosen_ent)
 285                                 e = RandomSelection_chosen_ent;
 286                         else
 287                                 e = self;
 288
 289                         pointparticles(particleeffectnum("rocket_explode"), e.origin, '0 0 0', 1);
 290                         sound(e, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 291
 292                         e2 = spawn();
 293                         setorigin(e2, e.origin);
 294                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT, e);
 295                         remove(e2);
 296
 297                         print("404 Sportsmanship not found.\n");
 298                         DID_CHEAT();
 299                         break;
 300         }
 301
 302         END_CHEAT_FUNCTION();
 303 }
 304
 305 void DragBox_Think();
 306 float drag_lastcnt;
 307 float CheatCommand(float argc)
 308 {
 309         BEGIN_CHEAT_FUNCTION();
 310         string cmd;
 311         cmd = argv(0);
 312         switch(cmd)
 313         {
 314                 entity e;
 315                 float effectnum, f;
 316                 vector start, end;
 317                 entity oldself;
 318
 319                 case "pointparticles":
 320                         IS_CHEAT(0, argc, 0);
 321                         if(argc == 5)
 322                         {
 323                                 // arguments:
 324                                 //   effectname
 325                                 //   origin (0..1, on crosshair line)
 326                                 //   velocity
 327                                 //   howmany
 328                                 effectnum = particleeffectnum(argv(1));
 329                                 f = stof(argv(2));
 330                                 crosshair_trace(self);
 331                                 start = (1-f) * self.origin + f * trace_endpos;
 332                                 end = stov(argv(3));
 333                                 f = stof(argv(4));
 334                                 pointparticles(effectnum, start, end, f);
 335                                 DID_CHEAT();
 336                                 break;
 337                         }
 338                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 339                         break;
 340                 case "trailparticles":
 341                         IS_CHEAT(0, argc, 0);
 342                         if(argc == 2)
 343                         {
 344                                 // arguments:
 345                                 //   effectname
 346                                 effectnum = particleeffectnum(argv(1));
 347                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 348                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 349                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 350                                 DID_CHEAT();
 351                                 break;
 352                         }
 353                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 354                         break;
 355                 case "make":
 356                         IS_CHEAT(0, argc, 0);
 357                         if(argc == 3)
 358                         {
 359                                 // arguments:
 360                                 //   modelname mode
 361                                 f = stof(argv(2));
 362                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 363                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 364                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 365                                 {
 366                                         sprint(self, "cannot make stuff there (bad surface)\n");
 367                                 }
 368                                 else
 369                                 {
 370                                         e = spawn();
 371                                         e.model = strzone(argv(1));
 372                                         e.mdl = "rocket_explode";
 373                                         e.health = 1000;
 374                                         setorigin(e, trace_endpos);
 375                                         e.effects = EF_NOMODELFLAGS;
 376                                         if(f == 1)
 377                                         {
 378                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 379                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 380                                         }
 381                                         oldself = self;
 382                                         self = e;
 383                                         spawnfunc_func_breakable();
 384                                         self = oldself;
 385                                         // now, is it valid?
 386                                         if(f == 0)
 387                                         {
 388                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 389                                                 if(trace_startsolid)
 390                                                 {
 391                                                         remove(e);
 392                                                         sprint(self, "cannot make stuff there (no space)\n");
 393                                                 }
 394                                                 else
 395                                                         DID_CHEAT();
 396                                         }
 397                                         else
 398                                                 DID_CHEAT();
 399                                 }
 400                         }
 401                         else
 402                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 403                         break;
 404                 case "penalty":
 405                         IS_CHEAT(0, argc, 0);
 406                         if(argc == 3)
 407                         {
 408                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 409                                 DID_CHEAT();
 410                                 break;
 411                         }
 412                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 413                         break;
 414                 case "dragbox_spawn":
 415                         IS_CHEAT(0, argc, 0);
 416                         e = spawn();
 417                         e.classname = "dragbox_box";
 418                         e.think = DragBox_Think;
 419                         e.nextthink = time;
 420                         e.solid = -1; // black
 421                         setmodel(e, "null"); // network it
 422                         if(argc == 4)
 423                                 e.cnt = stof(argv(1));
 424                         else
 425                                 e.cnt = max(0, drag_lastcnt);
 426
 427                         e.aiment = spawn();
 428                         e.aiment.classname = "dragbox_corner_1";
 429                         e.aiment.owner = e;
 430                         setmodel(e.aiment, "models/marker.md3");
 431                         e.aiment.skin = 0;
 432                         setsize(e.aiment, '0 0 0', '0 0 0');
 433                         if(argc == 4)
 434                                 setorigin(e.aiment, stov(argv(2)));
 435                         else
 436                         {
 437                                 crosshair_trace(self);
 438                                 setorigin(e.aiment, trace_endpos);
 439                         }
 440
 441                         e.enemy = spawn();
 442                         e.enemy.classname = "dragbox_corner_2";
 443                         e.enemy.owner = e;
 444                         setmodel(e.enemy, "models/marker.md3");
 445                         e.enemy.skin = 1;
 446                         setsize(e.enemy, '0 0 0', '0 0 0');
 447                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 448                         end.x = (end.x > 0) * 2 - 1;
 449                         end.y = (end.y > 0) * 2 - 1;
 450                         end.z = (end.z > 0) * 2 - 1;
 451                         if(argc == 4)
 452                                 setorigin(e.enemy, stov(argv(3)));
 453                         else
 454                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 455
 456                         e.killindicator = spawn();
 457                         e.killindicator.classname = "drag_digit";
 458                         e.killindicator.owner = e;
 459                         setattachment(e.killindicator, e, "");
 460                         setorigin(e.killindicator, '0 0 -8');
 461                         e.killindicator.killindicator = spawn();
 462                         e.killindicator.killindicator.classname = "drag_digit";
 463                         e.killindicator.killindicator.owner = e;
 464                         setattachment(e.killindicator.killindicator, e, "");
 465                         setorigin(e.killindicator.killindicator, '0 0 8');
 466                         DID_CHEAT();
 467                         break;
 468                 case "dragpoint_spawn":
 469                         IS_CHEAT(0, argc, 0);
 470                         e = spawn();
 471                         e.classname = "dragpoint";
 472                         e.think = DragBox_Think;
 473                         e.nextthink = time;
 474                         e.solid = 0; // nothing special
 475                         setmodel(e, "models/marker.md3");
 476                         setsize(e, PL_MIN, PL_MAX);
 477                         e.skin = 2;
 478                         if(argc == 3)
 479                                 e.cnt = stof(argv(1));
 480                         else
 481                                 e.cnt = drag_lastcnt;
 482                         if(argc == 3)
 483                                 setorigin(e, stov(argv(2)));
 484                         else
 485                         {
 486                                 crosshair_trace(self);
 487                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 488                                 move_out_of_solid(e);
 489                         }
 490
 491                         e.killindicator = spawn();
 492                         e.killindicator.classname = "drag_digit";
 493                         e.killindicator.owner = e;
 494                         setattachment(e.killindicator, e, "");
 495                         setorigin(e.killindicator, '0 0 40');
 496                         e.killindicator.killindicator = spawn();
 497                         e.killindicator.killindicator.classname = "drag_digit";
 498                         e.killindicator.killindicator.owner = e;
 499                         setattachment(e.killindicator.killindicator, e, "");
 500                         setorigin(e.killindicator.killindicator, '0 0 56');
 501                         DID_CHEAT();
 502                         break;
 503                 case "drag_remove":
 504                         IS_CHEAT(0, argc, 0);
 505                         RandomSelection_Init();
 506                         crosshair_trace(self);
 507                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 508                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 509                         for(e = world; (e = find(e, classname, "dragpoint")); )
 510                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 511                         if(RandomSelection_chosen_ent)
 512                         {
 513                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 514                                 remove(RandomSelection_chosen_ent.killindicator);
 515                                 if(RandomSelection_chosen_ent.aiment)
 516                                         remove(RandomSelection_chosen_ent.aiment);
 517                                 if(RandomSelection_chosen_ent.enemy)
 518                                         remove(RandomSelection_chosen_ent.enemy);
 519                                 remove(RandomSelection_chosen_ent);
 520                         }
 521                         DID_CHEAT();
 522                         break;
 523                 case "drag_setcnt":
 524                         IS_CHEAT(0, argc, 0);
 525                         if(argc == 2)
 526                         {
 527                                 RandomSelection_Init();
 528                                 crosshair_trace(self);
 529                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 530                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 531                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 532                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 533                                 if(RandomSelection_chosen_ent)
 534                                 {
 535                                         if(substring(argv(1), 0, 1) == "*")
 536                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 537                                         else
 538                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 539                                 }
 540                                 DID_CHEAT();
 541                                 break;
 542                         }
 543                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 544                         break;
 545                 case "drag_save":
 546                         IS_CHEAT(0, argc, 0);
 547                         if(argc == 2)
 548                         {
 549                                 f = fopen(argv(1), FILE_WRITE);
 550                                 fputs(f, "cmd drag_clear\n");
 551                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 552                                 {
 553                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 554                                 }
 555                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 556                                 {
 557                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 558                                 }
 559                                 fclose(f);
 560                                 DID_CHEAT();
 561                                 break;
 562                         }
 563                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 564                         break;
 565                 case "drag_saveraceent":
 566                         IS_CHEAT(0, argc, 0);
 567                         if(argc == 2)
 568                         {
 569                                 f = fopen(argv(1), FILE_WRITE);
 570                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 571                                 {
 572                                         fputs(f, "{\n");
 573                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 574                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 575                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 576                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 577                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 578                                         fputs(f, "}\n");
 579                                 }
 580                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 581                                 {
 582                                         start = '0 0 0';
 583                                         effectnum = 0;
 584                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 585                                         {
 586                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 587                                                 {
 588                                                         start = start + oldself.origin;
 589                                                         ++effectnum;
 590                                                 }
 591                                         }
 592                                         start *= 1 / effectnum;
 593                                         fputs(f, "{\n");
 594                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 595                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 596                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 597                                         if(e.cnt == -2)
 598                                         {
 599                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 600                                                 fputs(f, "\"race_place\" \"0\"\n");
 601                                         }
 602                                         else if(e.cnt == -1)
 603                                         {
 604                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 605                                                 fputs(f, "\"race_place\" \"-1\"\n");
 606                                         }
 607                                         else
 608                                         {
 609                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 610                                                 if(e.cnt == 0)
 611                                                 {
 612                                                         // these need race_place
 613                                                         // counting...
 614                                                         effectnum = 1;
 615                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 616                                                         if(oldself.cnt == 0)
 617                                                         {
 618                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 619                                                                         ++effectnum;
 620                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 621                                                                         ++effectnum;
 622                                                         }
 623                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 624                                                 }
 625                                         }
 626                                         fputs(f, "}\n");
 627                                 }
 628                                 fclose(f);
 629                                 DID_CHEAT();
 630                                 break;
 631                         }
 632                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 633                         break;
 634                 case "drag_clear":
 635                         IS_CHEAT(0, argc, 0);
 636                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 637                                 remove(e);
 638                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 639                                 remove(e);
 640                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 641                                 remove(e);
 642                         for(e = world; (e = find(e, classname, "dragpoint")); )
 643                                 remove(e);
 644                         for(e = world; (e = find(e, classname, "drag_digit")); )
 645                                 remove(e);
 646                         DID_CHEAT();
 647                         break;
 648                 case "god":
 649                         IS_CHEAT(0, argc, 0);
 650                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 651                         if(self.flags & FL_GODMODE)
 652                         {
 653                                 sprint(self, "godmode ON\n");
 654                                 DID_CHEAT();
 655                         }
 656                         else
 657                                 sprint(self, "godmode OFF\n");
 658                         break;
 659                 case "notarget":
 660                         IS_CHEAT(0, argc, 0);
 661                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 662                         if(self.flags & FL_NOTARGET)
 663                         {
 664                                 sprint(self, "notarget ON\n");
 665                                 DID_CHEAT();
 666                         }
 667                         else
 668                                 sprint(self, "notarget OFF\n");
 669                         break;
 670                 case "noclip":
 671                         IS_CHEAT(0, argc, 0);
 672                         if(self.movetype != MOVETYPE_NOCLIP)
 673                         {
 674                                 self.movetype = MOVETYPE_NOCLIP;
 675                                 sprint(self, "noclip ON\n");
 676                                 DID_CHEAT();
 677                         }
 678                         else
 679                         {
 680                                 self.movetype = MOVETYPE_WALK;
 681                                 sprint(self, "noclip OFF\n");
 682                         }
 683                         break;
 684                 case "fly":
 685                         IS_CHEAT(0, argc, 0);
 686                         if(self.movetype != MOVETYPE_FLY)
 687                         {
 688                                 self.movetype = MOVETYPE_FLY;
 689                                 sprint(self, "flymode ON\n");
 690                                 DID_CHEAT();
 691                         }
 692                         else
 693                         {
 694                                 self.movetype = MOVETYPE_WALK;
 695                                 sprint(self, "flymode OFF\n");
 696                         }
 697                         break;
 698                 case "give":
 699                         IS_CHEAT(0, argc, 0);
 700                         if(GiveItems(self, 1, argc))
 701                                 DID_CHEAT();
 702                         break;
 703                 case "usetarget":
 704                         IS_CHEAT(0, argc, 0);
 705                         e = self;
 706                         self = spawn();
 707                         self.target = argv(1);
 708                         activator = e;
 709                         SUB_UseTargets();
 710                         remove(self);
 711                         self = e;
 712                         DID_CHEAT();
 713                         break;
 714                 case "killtarget":
 715                         IS_CHEAT(0, argc, 0);
 716                         e = self;
 717                         self = spawn();
 718                         self.killtarget = argv(1);
 719                         activator = e;
 720                         SUB_UseTargets();
 721                         remove(self);
 722                         self = e;
 723                         DID_CHEAT();
 724                         break;
 725                 case "teleporttotarget":
 726                         IS_CHEAT(0, argc, 0);
 727                         e = self;
 728                         self = spawn();
 729                         setorigin(self, self.origin);
 730                         self.classname = "cheattriggerteleport";
 731                         self.target = argv(1);
 732                         teleport_findtarget();
 733                         if(!wasfreed(self))
 734                         {
 735                                 Simple_TeleportPlayer(self, e);
 736                                 remove(self);
 737                                 self = e;
 738                                 DID_CHEAT();
 739                         }
 740                         else
 741                                 self = e;
 742                         break;
 743         }
 744
 745         END_CHEAT_FUNCTION();
 746 }
 747
 748 float Drag(float force_allow_pick, float ischeat);
 749 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 750 void Drag_Finish(entity dragger);
 751 float Drag_IsDraggable(entity draggee);
 752 float Drag_MayChangeAngles(entity draggee);
 753 void Drag_MoveForward(entity dragger);
 754 void Drag_SetSpeed(entity dragger, float s);
 755 void Drag_MoveBackward(entity dragger);
 756 void Drag_Update(entity dragger);
 757 float Drag_CanDrag(entity dragger);
 758 float Drag_IsDragging(entity dragger);
 759 void Drag_MoveDrag(entity from, entity to);
 760 .entity dragentity;
 761
 762 float CheatFrame()
 763 {
 764         BEGIN_CHEAT_FUNCTION();
 765
 766         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 767         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 768         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 769         // grabbing itself no longer being accounted as cheating.
 770
 771         switch(0)
 772         {
 773                 default:
 774                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 775                         {
 776                                 // use cheat dragging if cheats are enabled
 777                                 crosshair_trace_plusvisibletriggers(self);
 778                                 Drag(true, true);
 779                         }
 780                         else
 781                         {
 782                                 Drag(false, false); // execute dragging
 783                         }
 784                         break;
 785         }
 786
 787         END_CHEAT_FUNCTION();
 788 }
 789
 790
 791
 792
 793
 794 // ENTITY DRAGGING
 795
 796 // on dragger:
 797 .float draggravity;
 798 .float dragspeed; // speed of mouse wheel action
 799 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 800 .vector draglocalvector; // local attachment vector of the dragentity
 801 .float draglocalangle;
 802 // on draggee:
 803 .entity draggedby;
 804 .float dragmovetype;
 805
 806 float Drag(float force_allow_pick, float ischeat)
 807 {
 808         BEGIN_CHEAT_FUNCTION();
 809
 810         // returns true when an entity has been picked up
 811         // If pick is true, the object can also be picked up if it's not being held already
 812         // If pick is false, only keep dragging the object if it's already being held
 813
 814         switch(0)
 815         {
 816                 default:
 817                         if(Drag_IsDragging(self))
 818                         {
 819                                 if(self.BUTTON_DRAG)
 820                                 {
 821                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 822                                         {
 823                                                 Drag_MoveForward(self);
 824                                                 self.impulse = 0;
 825                                         }
 826                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 827                                         {
 828                                                 Drag_MoveBackward(self);
 829                                                 self.impulse = 0;
 830                                         }
 831                                         else if(self.impulse >= 1 && self.impulse <= 9)
 832                                         {
 833                                                 Drag_SetSpeed(self, self.impulse - 1);
 834                                         }
 835                                         else if(self.impulse == 14)
 836                                         {
 837                                                 Drag_SetSpeed(self, 9);
 838                                         }
 839
 840                                         if(frametime)
 841                                                 Drag_Update(self);
 842                                 }
 843                                 else
 844                                 {
 845                                         Drag_Finish(self);
 846                                 }
 847                         }
 848                         else
 849                         {
 850                                 if(Drag_CanDrag(self))
 851                                         if(self.BUTTON_DRAG)
 852                                         {
 853                                                 crosshair_trace_plusvisibletriggers(self);
 854                                                 entity e = trace_ent;
 855                                                 float pick = force_allow_pick;
 856                                                 if (e && !pick)
 857                                                 {
 858                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 859                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 860                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 861                                                         // it goes out of range while slinging it around.
 862
 863                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 864                                                         {
 865                                                                 switch(e.grab)
 866                                                                 {
 867                                                                         case 0: // can't grab
 868                                                                                 break;
 869                                                                         case 1: // owner can grab
 870                                                                                 if(e.owner == self || e.realowner == self)
 871                                                                                         pick = true;
 872                                                                                 break;
 873                                                                         case 2: // owner and team mates can grab
 874                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 875                                                                                         pick = true;
 876                                                                                 break;
 877                                                                         case 3: // anyone can grab
 878                                                                                 pick = true;
 879                                                                                 break;
 880                                                                         default:
 881                                                                                 break;
 882                                                                 }
 883                                                         }
 884                                                 }
 885                                                 // Find e and pick
 886                                                 if(e && pick)
 887                                                         if(Drag_IsDraggable(e))
 888                                                         {
 889                                                                 if(ischeat)
 890                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 891                                                                 if(e.draggedby)
 892                                                                         Drag_Finish(e.draggedby);
 893                                                                 if(e.tag_entity)
 894                                                                         detach_sameorigin(e);
 895                                                                 Drag_Begin(self, e, trace_endpos);
 896                                                                 if(ischeat)
 897                                                                         DID_CHEAT();
 898                                                                 return true;
 899                                                         }
 900                                         }
 901                         }
 902                         break;
 903         }
 904         return false;
 905 }
 906
 907 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 908 {
 909         float tagscale;
 910
 911         draggee.dragmovetype = draggee.movetype;
 912         draggee.draggravity = draggee.gravity;
 913         draggee.movetype = MOVETYPE_WALK;
 914         draggee.gravity = 0.00001;
 915         draggee.flags &= ~FL_ONGROUND;
 916         draggee.draggedby = dragger;
 917
 918         dragger.dragentity = draggee;
 919
 920         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 921         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 922         touchpoint = touchpoint - gettaginfo(draggee, 0);
 923         tagscale = pow(vlen(v_forward), -2);
 924         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 925         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 926         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 927
 928         dragger.dragspeed = 64;
 929 }
 930
 931 void Drag_Finish(entity dragger)
 932 {
 933         entity draggee;
 934         draggee = dragger.dragentity;
 935         if(dragger)
 936                 dragger.dragentity = world;
 937         draggee.draggedby = world;
 938         draggee.movetype = draggee.dragmovetype;
 939         draggee.gravity = draggee.draggravity;
 940
 941         switch(draggee.movetype)
 942         {
 943                 case MOVETYPE_TOSS:
 944                 case MOVETYPE_WALK:
 945                 case MOVETYPE_STEP:
 946                 case MOVETYPE_FLYMISSILE:
 947                 case MOVETYPE_BOUNCE:
 948                 case MOVETYPE_BOUNCEMISSILE:
 949                 case MOVETYPE_PHYSICS:
 950                         break;
 951                 default:
 952                         draggee.velocity = '0 0 0';
 953                         break;
 954         }
 955
 956         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 957         {
 958                 draggee.velocity = '0 0 0';
 959                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 960         }
 961 }
 962
 963 float Drag_IsDraggable(entity draggee)
 964 {
 965         // TODO add more checks for bad stuff here
 966         if(draggee == world)
 967                 return false;
 968         if(draggee.classname == "func_bobbing")
 969                 return false;
 970         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 971                 return false;
 972         if(draggee.classname == "plat")
 973                 return false;
 974         if(draggee.classname == "func_button")
 975                 return false;
 976 //      if(draggee.model == "")
 977 //              return false;
 978         if(IS_SPEC(draggee))
 979                 return false;
 980         if(IS_OBSERVER(draggee))
 981                 return false;
 982         if(draggee.classname == "exteriorweaponentity")
 983                 return false;
 984         if(draggee.classname == "weaponentity")
 985                 return false;
 986
 987         return true;
 988 }
 989
 990 float Drag_MayChangeAngles(entity draggee)
 991 {
 992         // TODO add more checks for bad stuff here
 993         if(substring(draggee.model, 0, 1) == "*")
 994                 return false;
 995         return true;
 996 }
 997
 998 void Drag_MoveForward(entity dragger)
 999 {
1000         dragger.dragdistance += dragger.dragspeed;
1001 }
1002
1003 void Drag_SetSpeed(entity dragger, float s)
1004 {
1005         dragger.dragspeed = pow(2, s);
1006 }
1007
1008 void Drag_MoveBackward(entity dragger)
1009 {
1010         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
1011 }
1012
1013 void Drag_Update(entity dragger)
1014 {
1015         vector curorigin, neworigin, goodvelocity;
1016         float f;
1017         entity draggee;
1018
1019         draggee = dragger.dragentity;
1020         draggee.flags &= ~FL_ONGROUND;
1021
1022         curorigin = gettaginfo(draggee, 0);
1023         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
1024         makevectors(dragger.v_angle);
1025         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
1026         goodvelocity = (neworigin - curorigin) * (1 / frametime);
1027
1028         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
1029                 dragger.draglocalangle += 360;
1030         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1031                 dragger.draglocalangle -= 360;
1032
1033         f = min(frametime * 10, 1);
1034         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1035
1036         if(Drag_MayChangeAngles(draggee))
1037                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1038
1039         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1040
1041         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
1042 }
1043
1044 float Drag_CanDrag(entity dragger)
1045 {
1046         return (dragger.deadflag == DEAD_NO) || (IS_PLAYER(dragger));
1047 }
1048
1049 float Drag_IsDragging(entity dragger)
1050 {
1051         if(!dragger.dragentity)
1052                 return false;
1053         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1054         {
1055                 dragger.dragentity = world;
1056                 return false;
1057         }
1058         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1059         {
1060                 Drag_Finish(dragger);
1061                 return false;
1062         }
1063         return true;
1064 }
1065
1066 void Drag_MoveDrag(entity from, entity to)
1067 {
1068         if(from.draggedby)
1069         {
1070                 to.draggedby = from.draggedby;
1071                 to.draggedby.dragentity = to;
1072                 from.draggedby = world;
1073         }
1074 }
1075
1076 void DragBox_Think()
1077 {
1078         if(self.aiment && self.enemy)
1079         {
1080                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1081                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1082                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1083                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1084                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1085                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1086                 self.mins = -1 * self.maxs;
1087                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1088         }
1089
1090         if(self.cnt == -1) // actually race_place -1
1091         {
1092                 // show "10 10" for qualifying spawns
1093                 setmodel(self.killindicator, "models/sprites/10.spr32");
1094                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1095         }
1096         else if(self.cnt == -2) // actually race_place 0
1097         {
1098                 // show "10 0" for loser spawns
1099                 setmodel(self.killindicator, "models/sprites/10.spr32");
1100                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1101         }
1102         else
1103         {
1104                 setmodel(self.killindicator, strcat("models/sprites/", ftos(self.cnt % 10), ".spr32"));
1105                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1106         }
1107
1108         self.nextthink = time;
1109 }
1110
1111 #endif