qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2
   3 #include "g_damage.qh"
   4 #include "race.qh"
   5 #include "../common/triggers/teleporters.qh"
   6
   7 #include "mutators/all.qh"
   8
   9 #include "weapons/tracing.qh"
  10
  11 #include "../common/constants.qh"
  12 #include "../common/deathtypes/all.qh"
  13 #include "../common/util.qh"
  14
  15 #include "../common/monsters/all.qh"
  16
  17 #include "../common/weapons/all.qh"
  18
  19 #include "../common/triggers/subs.qh"
  20
  21 #include "../common/triggers/func/breakable.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/anglestransform.qh"
  26 #include "../lib/warpzone/util_server.qh"
  27
  28 void CopyBody(float keepvelocity);
  29
  30 #ifdef NOCHEATS
  31
  32 float CheatImpulse(float i) { return 0; }
  33 float CheatCommand(float argc) { return 0; }
  34 float CheatFrame() { return 0; }
  35 void CheatInit() { cheatcount_total = world.cheatcount; }
  36 void CheatShutdown() { }
  37 void CheatInitClient() { }
  38 void CheatShutdownClient() { }
  39 void Drag_MoveDrag(entity from, entity to) { }
  40
  41 #else
  42
  43 .float maycheat;
  44 float gamestart_sv_cheats;
  45
  46
  47
  48 void CheatInit()
  49 {
  50         gamestart_sv_cheats = autocvar_sv_cheats;
  51 }
  52
  53 void CheatShutdown()
  54 {
  55 }
  56
  57 void CheatInitClient()
  58 {
  59 }
  60
  61 void CheatShutdownClient()
  62 {
  63 }
  64
  65 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  66 {SELFPARAM();
  67         // dead people cannot cheat
  68         if(self.deadflag != DEAD_NO)
  69                 return 0;
  70         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  71                 return 0;
  72
  73         // sv_clones
  74         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  75                 if(self.lip < sv_clones)
  76                         return 1;
  77
  78         // haha
  79         if(self.maycheat)
  80                 return 1;
  81
  82         // sv_cheats
  83         if(gamestart_sv_cheats && autocvar_sv_cheats)
  84                 return 1;
  85
  86         // if we get here, player is not allowed to cheat. Log it.
  87         if(i)
  88                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  89         else if(argc)
  90                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  91         else if(fr)
  92                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  93         else
  94                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
  95
  96         return 0;
  97 }
  98
  99 #define BEGIN_CHEAT_FUNCTION() \
 100         float cheating, attempting; \
 101         cheating = 0; attempting = 0
 102 #define DID_CHEAT() \
 103         ++cheating
 104 #define ADD_CHEATS(e,n) \
 105         cheatcount_total += n; \
 106         e.cheatcount += n
 107 #define END_CHEAT_FUNCTION() \
 108         ADD_CHEATS(self,cheating); \
 109         return attempting
 110 #define IS_CHEAT(i,argc,fr) \
 111         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 112                 break
 113
 114 float num_autoscreenshot;
 115 void info_autoscreenshot_findtarget()
 116 {SELFPARAM();
 117         entity e;
 118         e = find(world, targetname, self.target);
 119         if(!e)
 120         {
 121                 objerror("Missing target. FAIL!");
 122                 return;
 123         }
 124         vector a = vectoangles(e.origin - self.origin);
 125         a.x = -a.x; // don't ask
 126         self.angles_x = a.x;
 127         self.angles_y = a.y;
 128         // we leave Rick Roll alone
 129 }
 130 spawnfunc(info_autoscreenshot)
 131 {
 132         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 133         {
 134                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 135                 return;
 136         }
 137         if(self.target != "")
 138                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 139         // this one just has to exist
 140 }
 141
 142 float CheatImpulse(float i)
 143 {SELFPARAM();
 144         BEGIN_CHEAT_FUNCTION();
 145         switch(i)
 146         {
 147                 entity e, e2;
 148
 149                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 150                         // shared with regular waypoint init, so this is not a cheat by itself
 151                         if(!self.personal)
 152                         {
 153                                 self.personal = spawn();
 154                                 self.personal.classname = "personal_wp";
 155                         }
 156                         self.personal.origin = self.origin;
 157                         self.personal.v_angle = self.v_angle;
 158                         self.personal.velocity = self.velocity;
 159                         self.personal.ammo_rockets = self.ammo_rockets;
 160                         self.personal.ammo_nails = self.ammo_nails;
 161                         self.personal.ammo_cells = self.ammo_cells;
 162                         self.personal.ammo_plasma = self.ammo_plasma;
 163                         self.personal.ammo_shells = self.ammo_shells;
 164                         self.personal.ammo_fuel = self.ammo_fuel;
 165                         self.personal.health = self.health;
 166                         self.personal.armorvalue = self.armorvalue;
 167                         self.personal.weapons = self.weapons;
 168                         self.personal.items = self.items;
 169                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 170                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 171                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 172                         self.personal.pauseregen_finished = self.pauseregen_finished;
 173                         self.personal.strength_finished = self.strength_finished;
 174                         self.personal.invincible_finished = self.invincible_finished;
 175                         self.personal.teleport_time = time;
 176                         break; // this part itself doesn't cheat, so let's not count this
 177                 case CHIMPULSE_CLONE_MOVING:
 178                         IS_CHEAT(i, 0, 0);
 179                         makevectors (self.v_angle);
 180                         self.velocity = self.velocity + v_forward * 300;
 181                         CopyBody(1);
 182                         self.lip += 1;
 183                         self.velocity = self.velocity - v_forward * 300;
 184                         DID_CHEAT();
 185                         break;
 186                 case CHIMPULSE_CLONE_STANDING:
 187                         IS_CHEAT(i, 0, 0);
 188                         CopyBody(0);
 189                         self.lip += 1;
 190                         DID_CHEAT();
 191                         break;
 192                 case CHIMPULSE_GIVE_ALL:
 193                         IS_CHEAT(i, 0, 0);
 194                         CheatCommand(tokenize_console("give all"));
 195                         break; // already counted as cheat
 196                 case CHIMPULSE_SPEEDRUN:
 197                         IS_CHEAT(i, 0, 0);
 198                         if(self.personal)
 199                         {
 200                                 self.speedrunning = true;
 201                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 202                                 if(trace_startsolid)
 203                                 {
 204                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 205                                 }
 206                                 else
 207                                 {
 208                                         // Abort speedrun, teleport back
 209                                         setorigin(self, self.personal.origin);
 210                                         self.oldvelocity = self.velocity = self.personal.velocity;
 211                                         self.angles = self.personal.v_angle;
 212                                         self.fixangle = true;
 213
 214                                         MUTATOR_CALLHOOK(AbortSpeedrun, self);
 215                                 }
 216
 217                                 self.ammo_rockets = self.personal.ammo_rockets;
 218                                 self.ammo_nails = self.personal.ammo_nails;
 219                                 self.ammo_cells = self.personal.ammo_cells;
 220                                 self.ammo_plasma = self.personal.ammo_plasma;
 221                                 self.ammo_shells = self.personal.ammo_shells;
 222                                 self.ammo_fuel = self.personal.ammo_fuel;
 223                                 self.health = self.personal.health;
 224                                 self.armorvalue = self.personal.armorvalue;
 225                                 self.weapons = self.personal.weapons;
 226                                 self.items = self.personal.items;
 227                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 228                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 229                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 230                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 231                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 232                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 233
 234                                 DID_CHEAT();
 235                                 break;
 236                         }
 237                         if(self.deadflag != DEAD_NO)
 238                                 sprint(self, "UR DEAD AHAHAH))\n");
 239                         else
 240                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 241                         break;
 242                 case CHIMPULSE_TELEPORT:
 243                         IS_CHEAT(i, 0, 0);
 244                         if(self.movetype == MOVETYPE_NOCLIP)
 245                         {
 246                                 e = find(world, classname, "info_autoscreenshot");
 247                                 if(e)
 248                                 {
 249                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 250                                         setorigin(self, e.origin);
 251                                         self.angles = e.angles;
 252                                         remove(e);
 253                                         // should we? self.angles_x = -self.angles_x;
 254                                         self.fixangle = true;
 255                                         self.velocity = '0 0 0';
 256                                         DID_CHEAT();
 257                                         break;
 258                                 }
 259                         }
 260                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 261                         {
 262                                 sprint(self, "Emergency teleport used random location\n");
 263                                 self.angles_x = -self.angles.x;
 264                                 self.fixangle = true;
 265                                 self.velocity = '0 0 0';
 266                                 DID_CHEAT();
 267                                 break;
 268                         }
 269                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 270                         break;
 271                 case CHIMPULSE_R00T:
 272                         IS_CHEAT(i, 0, 0);
 273                         RandomSelection_Init();
 274                         FOR_EACH_PLAYER(e)
 275                                 if(e.deadflag == DEAD_NO)
 276                                         if(DIFF_TEAM(e, self))
 277                                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 278                         if(RandomSelection_chosen_ent)
 279                                 e = RandomSelection_chosen_ent;
 280                         else
 281                                 e = self;
 282
 283                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 284                         sound(e, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 285
 286                         e2 = spawn();
 287                         setorigin(e2, e.origin);
 288                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT.m_id, e);
 289                         remove(e2);
 290
 291                         LOG_INFO("404 Sportsmanship not found.\n");
 292                         DID_CHEAT();
 293                         break;
 294         }
 295
 296         END_CHEAT_FUNCTION();
 297 }
 298
 299 void DragBox_Think();
 300 float drag_lastcnt;
 301 float CheatCommand(float argc)
 302 {SELFPARAM();
 303         BEGIN_CHEAT_FUNCTION();
 304         string cmd;
 305         cmd = argv(0);
 306         switch(cmd)
 307         {
 308                 float effectnum, f;
 309                 vector start, end;
 310                 entity oldself;
 311
 312                 case "pointparticles":
 313                         IS_CHEAT(0, argc, 0);
 314                         if(argc == 5)
 315                         {
 316                                 // arguments:
 317                                 //   effectname
 318                                 //   origin (0..1, on crosshair line)
 319                                 //   velocity
 320                                 //   howmany
 321                                 f = stof(argv(2));
 322                                 crosshair_trace(self);
 323                                 start = (1-f) * self.origin + f * trace_endpos;
 324                                 end = stov(argv(3));
 325                                 f = stof(argv(4));
 326                                 Send_Effect_(argv(1), start, end, f);
 327                                 DID_CHEAT();
 328                                 break;
 329                         }
 330                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 331                         break;
 332                 case "trailparticles":
 333                         IS_CHEAT(0, argc, 0);
 334                         if(argc == 2)
 335                         {
 336                                 // arguments:
 337                                 //   effectname
 338                                 effectnum = _particleeffectnum(argv(1));
 339                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 340                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 341                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 342                                 DID_CHEAT();
 343                                 break;
 344                         }
 345                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 346                         break;
 347                 case "make":
 348                         IS_CHEAT(0, argc, 0);
 349                         if(argc == 3)
 350                         {
 351                                 // arguments:
 352                                 //   modelname mode
 353                                 f = stof(argv(2));
 354                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 355                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 356                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 357                                 {
 358                                         sprint(self, "cannot make stuff there (bad surface)\n");
 359                                 }
 360                                 else
 361                                 {
 362                                         entity e = spawn();
 363                                         e.model = strzone(argv(1));
 364                                         e.mdl = "rocket_explode";
 365                                         e.health = 1000;
 366                                         setorigin(e, trace_endpos);
 367                                         e.effects = EF_NOMODELFLAGS;
 368                                         if(f == 1)
 369                                         {
 370                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 371                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 372                                         }
 373                                         WITH(entity, self, e, spawnfunc_func_breakable(e));
 374                                         // now, is it valid?
 375                                         if(f == 0)
 376                                         {
 377                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 378                                                 if(trace_startsolid)
 379                                                 {
 380                                                         remove(e);
 381                                                         sprint(self, "cannot make stuff there (no space)\n");
 382                                                 }
 383                                                 else
 384                                                         DID_CHEAT();
 385                                         }
 386                                         else
 387                                                 DID_CHEAT();
 388                                 }
 389                         }
 390                         else
 391                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 392                         break;
 393                 case "penalty":
 394                         IS_CHEAT(0, argc, 0);
 395                         if(argc == 3)
 396                         {
 397                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 398                                 DID_CHEAT();
 399                                 break;
 400                         }
 401                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 402                         break;
 403                 case "dragbox_spawn": {
 404                         IS_CHEAT(0, argc, 0);
 405                         entity e = spawn();
 406                         e.classname = "dragbox_box";
 407                         e.think = DragBox_Think;
 408                         e.nextthink = time;
 409                         e.solid = -1; // black
 410                         setmodel(e, MDL_Null); // network it
 411                         if(argc == 4)
 412                                 e.cnt = stof(argv(1));
 413                         else
 414                                 e.cnt = max(0, drag_lastcnt);
 415
 416                         e.aiment = spawn();
 417                         e.aiment.classname = "dragbox_corner_1";
 418                         e.aiment.owner = e;
 419                         setmodel(e.aiment, MDL_MARKER);
 420                         e.aiment.skin = 0;
 421                         setsize(e.aiment, '0 0 0', '0 0 0');
 422                         if(argc == 4)
 423                                 setorigin(e.aiment, stov(argv(2)));
 424                         else
 425                         {
 426                                 crosshair_trace(self);
 427                                 setorigin(e.aiment, trace_endpos);
 428                         }
 429
 430                         e.enemy = spawn();
 431                         e.enemy.classname = "dragbox_corner_2";
 432                         e.enemy.owner = e;
 433                         setmodel(e.enemy, MDL_MARKER);
 434                         e.enemy.skin = 1;
 435                         setsize(e.enemy, '0 0 0', '0 0 0');
 436                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 437                         end.x = (end.x > 0) * 2 - 1;
 438                         end.y = (end.y > 0) * 2 - 1;
 439                         end.z = (end.z > 0) * 2 - 1;
 440                         if(argc == 4)
 441                                 setorigin(e.enemy, stov(argv(3)));
 442                         else
 443                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 444
 445                         e.killindicator = spawn();
 446                         e.killindicator.classname = "drag_digit";
 447                         e.killindicator.owner = e;
 448                         setattachment(e.killindicator, e, "");
 449                         setorigin(e.killindicator, '0 0 -8');
 450                         e.killindicator.killindicator = spawn();
 451                         e.killindicator.killindicator.classname = "drag_digit";
 452                         e.killindicator.killindicator.owner = e;
 453                         setattachment(e.killindicator.killindicator, e, "");
 454                         setorigin(e.killindicator.killindicator, '0 0 8');
 455                         DID_CHEAT();
 456                         break;
 457                 }
 458                 case "dragpoint_spawn": {
 459                         IS_CHEAT(0, argc, 0);
 460                         entity e = spawn();
 461                         e.classname = "dragpoint";
 462                         e.think = DragBox_Think;
 463                         e.nextthink = time;
 464                         e.solid = 0; // nothing special
 465                         setmodel(e, MDL_MARKER);
 466                         setsize(e, PL_MIN, PL_MAX);
 467                         e.skin = 2;
 468                         if(argc == 3)
 469                                 e.cnt = stof(argv(1));
 470                         else
 471                                 e.cnt = drag_lastcnt;
 472                         if(argc == 3)
 473                                 setorigin(e, stov(argv(2)));
 474                         else
 475                         {
 476                                 crosshair_trace(self);
 477                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 478                                 move_out_of_solid(e);
 479                         }
 480
 481                         e.killindicator = spawn();
 482                         e.killindicator.classname = "drag_digit";
 483                         e.killindicator.owner = e;
 484                         setattachment(e.killindicator, e, "");
 485                         setorigin(e.killindicator, '0 0 40');
 486                         e.killindicator.killindicator = spawn();
 487                         e.killindicator.killindicator.classname = "drag_digit";
 488                         e.killindicator.killindicator.owner = e;
 489                         setattachment(e.killindicator.killindicator, e, "");
 490                         setorigin(e.killindicator.killindicator, '0 0 56');
 491                         DID_CHEAT();
 492                         break;
 493                 }
 494                 case "drag_remove":
 495                         IS_CHEAT(0, argc, 0);
 496                         RandomSelection_Init();
 497                         crosshair_trace(self);
 498                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 499                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 500                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 501                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 502                         if(RandomSelection_chosen_ent)
 503                         {
 504                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 505                                 remove(RandomSelection_chosen_ent.killindicator);
 506                                 if(RandomSelection_chosen_ent.aiment)
 507                                         remove(RandomSelection_chosen_ent.aiment);
 508                                 if(RandomSelection_chosen_ent.enemy)
 509                                         remove(RandomSelection_chosen_ent.enemy);
 510                                 remove(RandomSelection_chosen_ent);
 511                         }
 512                         DID_CHEAT();
 513                         break;
 514                 case "drag_setcnt":
 515                         IS_CHEAT(0, argc, 0);
 516                         if(argc == 2)
 517                         {
 518                                 RandomSelection_Init();
 519                                 crosshair_trace(self);
 520                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 521                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 522                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 523                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 524                                 if(RandomSelection_chosen_ent)
 525                                 {
 526                                         if(substring(argv(1), 0, 1) == "*")
 527                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 528                                         else
 529                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 530                                 }
 531                                 DID_CHEAT();
 532                                 break;
 533                         }
 534                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 535                         break;
 536                 case "drag_save":
 537                         IS_CHEAT(0, argc, 0);
 538                         if(argc == 2)
 539                         {
 540                                 f = fopen(argv(1), FILE_WRITE);
 541                                 fputs(f, "cmd drag_clear\n");
 542                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 543                                 {
 544                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 545                                 }
 546                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 547                                 {
 548                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 549                                 }
 550                                 fclose(f);
 551                                 DID_CHEAT();
 552                                 break;
 553                         }
 554                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 555                         break;
 556                 case "drag_saveraceent":
 557                         IS_CHEAT(0, argc, 0);
 558                         if(argc == 2)
 559                         {
 560                                 f = fopen(argv(1), FILE_WRITE);
 561                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 562                                 {
 563                                         fputs(f, "{\n");
 564                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 565                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 566                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 567                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 568                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 569                                         fputs(f, "}\n");
 570                                 }
 571                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 572                                 {
 573                                         start = '0 0 0';
 574                                         effectnum = 0;
 575                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 576                                         {
 577                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 578                                                 {
 579                                                         start = start + oldself.origin;
 580                                                         ++effectnum;
 581                                                 }
 582                                         }
 583                                         start *= 1 / effectnum;
 584                                         fputs(f, "{\n");
 585                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 586                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 587                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 588                                         if(e.cnt == -2)
 589                                         {
 590                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 591                                                 fputs(f, "\"race_place\" \"0\"\n");
 592                                         }
 593                                         else if(e.cnt == -1)
 594                                         {
 595                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 596                                                 fputs(f, "\"race_place\" \"-1\"\n");
 597                                         }
 598                                         else
 599                                         {
 600                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 601                                                 if(e.cnt == 0)
 602                                                 {
 603                                                         // these need race_place
 604                                                         // counting...
 605                                                         effectnum = 1;
 606                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 607                                                         if(oldself.cnt == 0)
 608                                                         {
 609                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 610                                                                         ++effectnum;
 611                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 612                                                                         ++effectnum;
 613                                                         }
 614                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 615                                                 }
 616                                         }
 617                                         fputs(f, "}\n");
 618                                 }
 619                                 fclose(f);
 620                                 DID_CHEAT();
 621                                 break;
 622                         }
 623                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 624                         break;
 625                 case "drag_clear":
 626                         IS_CHEAT(0, argc, 0);
 627                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 628                                 remove(e);
 629                         for(entity e = world; (e = find(e, classname, "dragbox_corner_1")); )
 630                                 remove(e);
 631                         for(entity e = world; (e = find(e, classname, "dragbox_corner_2")); )
 632                                 remove(e);
 633                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 634                                 remove(e);
 635                         for(entity e = world; (e = find(e, classname, "drag_digit")); )
 636                                 remove(e);
 637                         DID_CHEAT();
 638                         break;
 639                 case "god":
 640                         IS_CHEAT(0, argc, 0);
 641                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 642                         if(self.flags & FL_GODMODE)
 643                         {
 644                                 sprint(self, "godmode ON\n");
 645                                 DID_CHEAT();
 646                         }
 647                         else
 648                                 sprint(self, "godmode OFF\n");
 649                         break;
 650                 case "notarget":
 651                         IS_CHEAT(0, argc, 0);
 652                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 653                         if(self.flags & FL_NOTARGET)
 654                         {
 655                                 sprint(self, "notarget ON\n");
 656                                 DID_CHEAT();
 657                         }
 658                         else
 659                                 sprint(self, "notarget OFF\n");
 660                         break;
 661                 case "noclip":
 662                         IS_CHEAT(0, argc, 0);
 663                         if(self.movetype != MOVETYPE_NOCLIP)
 664                         {
 665                                 self.movetype = MOVETYPE_NOCLIP;
 666                                 sprint(self, "noclip ON\n");
 667                                 DID_CHEAT();
 668                         }
 669                         else
 670                         {
 671                                 self.movetype = MOVETYPE_WALK;
 672                                 sprint(self, "noclip OFF\n");
 673                         }
 674                         break;
 675                 case "fly":
 676                         IS_CHEAT(0, argc, 0);
 677                         if(self.movetype != MOVETYPE_FLY)
 678                         {
 679                                 self.movetype = MOVETYPE_FLY;
 680                                 sprint(self, "flymode ON\n");
 681                                 DID_CHEAT();
 682                         }
 683                         else
 684                         {
 685                                 self.movetype = MOVETYPE_WALK;
 686                                 sprint(self, "flymode OFF\n");
 687                         }
 688                         break;
 689                 case "give":
 690                         IS_CHEAT(0, argc, 0);
 691                         if(GiveItems(self, 1, argc))
 692                                 DID_CHEAT();
 693                         break;
 694                 case "usetarget":
 695                         IS_CHEAT(0, argc, 0);
 696                         setself(spawn());
 697                         self.target = argv(1);
 698                         activator = this;
 699                         SUB_UseTargets();
 700                         remove(self);
 701                         setself(this);
 702                         DID_CHEAT();
 703                         break;
 704                 case "killtarget":
 705                         IS_CHEAT(0, argc, 0);
 706                         setself(spawn());
 707                         self.killtarget = argv(1);
 708                         activator = this;
 709                         SUB_UseTargets();
 710                         remove(self);
 711                         setself(this);
 712                         DID_CHEAT();
 713                         break;
 714                 case "teleporttotarget":
 715                         IS_CHEAT(0, argc, 0);
 716                         setself(spawn());
 717                         setorigin(self, self.origin);
 718                         self.classname = "cheattriggerteleport";
 719                         self.target = argv(1);
 720                         teleport_findtarget();
 721                         if(!wasfreed(self))
 722                         {
 723                                 Simple_TeleportPlayer(self, this);
 724                                 remove(self);
 725                                 DID_CHEAT();
 726                         }
 727                         setself(this);
 728                         break;
 729         }
 730
 731         END_CHEAT_FUNCTION();
 732 }
 733
 734 float Drag(float force_allow_pick, float ischeat);
 735 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 736 void Drag_Finish(entity dragger);
 737 float Drag_IsDraggable(entity draggee);
 738 float Drag_MayChangeAngles(entity draggee);
 739 void Drag_MoveForward(entity dragger);
 740 void Drag_SetSpeed(entity dragger, float s);
 741 void Drag_MoveBackward(entity dragger);
 742 void Drag_Update(entity dragger);
 743 float Drag_CanDrag(entity dragger);
 744 float Drag_IsDragging(entity dragger);
 745 void Drag_MoveDrag(entity from, entity to);
 746 .entity dragentity;
 747
 748 float CheatFrame()
 749 {SELFPARAM();
 750         BEGIN_CHEAT_FUNCTION();
 751
 752         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 753         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 754         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 755         // grabbing itself no longer being accounted as cheating.
 756
 757         switch(0)
 758         {
 759                 default:
 760                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 761                         {
 762                                 // use cheat dragging if cheats are enabled
 763                                 crosshair_trace_plusvisibletriggers(self);
 764                                 Drag(true, true);
 765                         }
 766                         else
 767                         {
 768                                 Drag(false, false); // execute dragging
 769                         }
 770                         break;
 771         }
 772
 773         END_CHEAT_FUNCTION();
 774 }
 775
 776
 777
 778
 779
 780 // ENTITY DRAGGING
 781
 782 // on dragger:
 783 .float draggravity;
 784 .float dragspeed; // speed of mouse wheel action
 785 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 786 .vector draglocalvector; // local attachment vector of the dragentity
 787 .float draglocalangle;
 788 // on draggee:
 789 .entity draggedby;
 790 .float dragmovetype;
 791
 792 float Drag(float force_allow_pick, float ischeat)
 793 {SELFPARAM();
 794         BEGIN_CHEAT_FUNCTION();
 795
 796         // returns true when an entity has been picked up
 797         // If pick is true, the object can also be picked up if it's not being held already
 798         // If pick is false, only keep dragging the object if it's already being held
 799
 800         switch(0)
 801         {
 802                 default:
 803                         if(Drag_IsDragging(self))
 804                         {
 805                                 if(self.BUTTON_DRAG)
 806                                 {
 807                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 808                                         {
 809                                                 Drag_MoveForward(self);
 810                                                 self.impulse = 0;
 811                                         }
 812                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 813                                         {
 814                                                 Drag_MoveBackward(self);
 815                                                 self.impulse = 0;
 816                                         }
 817                                         else if(self.impulse >= 1 && self.impulse <= 9)
 818                                         {
 819                                                 Drag_SetSpeed(self, self.impulse - 1);
 820                                         }
 821                                         else if(self.impulse == 14)
 822                                         {
 823                                                 Drag_SetSpeed(self, 9);
 824                                         }
 825
 826                                         if(frametime)
 827                                                 Drag_Update(self);
 828                                 }
 829                                 else
 830                                 {
 831                                         Drag_Finish(self);
 832                                 }
 833                         }
 834                         else
 835                         {
 836                                 if(Drag_CanDrag(self))
 837                                         if(self.BUTTON_DRAG)
 838                                         {
 839                                                 crosshair_trace_plusvisibletriggers(self);
 840                                                 entity e = trace_ent;
 841                                                 float pick = force_allow_pick;
 842                                                 if (e && !pick)
 843                                                 {
 844                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 845                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 846                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 847                                                         // it goes out of range while slinging it around.
 848
 849                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 850                                                         {
 851                                                                 switch(e.grab)
 852                                                                 {
 853                                                                         case 0: // can't grab
 854                                                                                 break;
 855                                                                         case 1: // owner can grab
 856                                                                                 if(e.owner == self || e.realowner == self)
 857                                                                                         pick = true;
 858                                                                                 break;
 859                                                                         case 2: // owner and team mates can grab
 860                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 861                                                                                         pick = true;
 862                                                                                 break;
 863                                                                         case 3: // anyone can grab
 864                                                                                 pick = true;
 865                                                                                 break;
 866                                                                         default:
 867                                                                                 break;
 868                                                                 }
 869                                                         }
 870                                                 }
 871                                                 // Find e and pick
 872                                                 if(e && pick)
 873                                                         if(Drag_IsDraggable(e))
 874                                                         {
 875                                                                 if(ischeat)
 876                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 877                                                                 if(e.draggedby)
 878                                                                         Drag_Finish(e.draggedby);
 879                                                                 if(e.tag_entity)
 880                                                                         detach_sameorigin(e);
 881                                                                 Drag_Begin(self, e, trace_endpos);
 882                                                                 if(ischeat)
 883                                                                         DID_CHEAT();
 884                                                                 return true;
 885                                                         }
 886                                         }
 887                         }
 888                         break;
 889         }
 890         return false;
 891 }
 892
 893 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 894 {
 895         float tagscale;
 896
 897         draggee.dragmovetype = draggee.movetype;
 898         draggee.draggravity = draggee.gravity;
 899         draggee.movetype = MOVETYPE_WALK;
 900         draggee.gravity = 0.00001;
 901         draggee.flags &= ~FL_ONGROUND;
 902         draggee.draggedby = dragger;
 903
 904         dragger.dragentity = draggee;
 905
 906         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 907         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 908         touchpoint = touchpoint - gettaginfo(draggee, 0);
 909         tagscale = pow(vlen(v_forward), -2);
 910         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 911         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 912         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 913
 914         dragger.dragspeed = 64;
 915 }
 916
 917 void Drag_Finish(entity dragger)
 918 {
 919         entity draggee;
 920         draggee = dragger.dragentity;
 921         if(dragger)
 922                 dragger.dragentity = world;
 923         draggee.draggedby = world;
 924         draggee.movetype = draggee.dragmovetype;
 925         draggee.gravity = draggee.draggravity;
 926
 927         switch(draggee.movetype)
 928         {
 929                 case MOVETYPE_TOSS:
 930                 case MOVETYPE_WALK:
 931                 case MOVETYPE_STEP:
 932                 case MOVETYPE_FLYMISSILE:
 933                 case MOVETYPE_BOUNCE:
 934                 case MOVETYPE_BOUNCEMISSILE:
 935                 case MOVETYPE_PHYSICS:
 936                         break;
 937                 default:
 938                         draggee.velocity = '0 0 0';
 939                         break;
 940         }
 941
 942         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 943         {
 944                 draggee.velocity = '0 0 0';
 945                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 946         }
 947 }
 948
 949 float Drag_IsDraggable(entity draggee)
 950 {
 951         // TODO add more checks for bad stuff here
 952         if(draggee == world)
 953                 return false;
 954         if(draggee.classname == "func_bobbing")
 955                 return false;
 956         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 957                 return false;
 958         if(draggee.classname == "plat")
 959                 return false;
 960         if(draggee.classname == "func_button")
 961                 return false;
 962 //      if(draggee.model == "")
 963 //              return false;
 964         if(IS_SPEC(draggee))
 965                 return false;
 966         if(IS_OBSERVER(draggee))
 967                 return false;
 968         if(draggee.classname == "exteriorweaponentity")
 969                 return false;
 970         if(draggee.classname == "weaponentity")
 971                 return false;
 972
 973         return true;
 974 }
 975
 976 float Drag_MayChangeAngles(entity draggee)
 977 {
 978         // TODO add more checks for bad stuff here
 979         if(substring(draggee.model, 0, 1) == "*")
 980                 return false;
 981         return true;
 982 }
 983
 984 void Drag_MoveForward(entity dragger)
 985 {
 986         dragger.dragdistance += dragger.dragspeed;
 987 }
 988
 989 void Drag_SetSpeed(entity dragger, float s)
 990 {
 991         dragger.dragspeed = pow(2, s);
 992 }
 993
 994 void Drag_MoveBackward(entity dragger)
 995 {
 996         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 997 }
 998
 999 void Drag_Update(entity dragger)
1000 {
1001         vector curorigin, neworigin, goodvelocity;
1002         float f;
1003         entity draggee;
1004
1005         draggee = dragger.dragentity;
1006         draggee.flags &= ~FL_ONGROUND;
1007
1008         curorigin = gettaginfo(draggee, 0);
1009         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
1010         makevectors(dragger.v_angle);
1011         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
1012         goodvelocity = (neworigin - curorigin) * (1 / frametime);
1013
1014         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
1015                 dragger.draglocalangle += 360;
1016         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1017                 dragger.draglocalangle -= 360;
1018
1019         f = min(frametime * 10, 1);
1020         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1021
1022         if(Drag_MayChangeAngles(draggee))
1023                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1024
1025         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1026
1027         vector vecs = '0 0 0';
1028         int slot = 0; // TODO: unhardcode
1029         if(dragger.weaponentity[slot].movedir_x > 0)
1030                 vecs = dragger.weaponentity[slot].movedir;
1031
1032         vector dv = v_right * -vecs_y + v_up * vecs_z;
1033
1034         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
1035 }
1036
1037 float Drag_CanDrag(entity dragger)
1038 {
1039         return (dragger.deadflag == DEAD_NO) || (IS_PLAYER(dragger));
1040 }
1041
1042 float Drag_IsDragging(entity dragger)
1043 {
1044         if(!dragger.dragentity)
1045                 return false;
1046         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1047         {
1048                 dragger.dragentity = world;
1049                 return false;
1050         }
1051         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1052         {
1053                 Drag_Finish(dragger);
1054                 return false;
1055         }
1056         return true;
1057 }
1058
1059 void Drag_MoveDrag(entity from, entity to)
1060 {
1061         if(from.draggedby)
1062         {
1063                 to.draggedby = from.draggedby;
1064                 to.draggedby.dragentity = to;
1065                 from.draggedby = world;
1066         }
1067 }
1068
1069 void DragBox_Think()
1070 {SELFPARAM();
1071         if(self.aiment && self.enemy)
1072         {
1073                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1074                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1075                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1076                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1077                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1078                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1079                 self.mins = -1 * self.maxs;
1080                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1081         }
1082
1083         if(self.cnt == -1) // actually race_place -1
1084         {
1085                 // show "10 10" for qualifying spawns
1086                 setmodel(self.killindicator, MDL_NUM(10));
1087                 setmodel(self.killindicator.killindicator, MDL_NUM(10));
1088         }
1089         else if(self.cnt == -2) // actually race_place 0
1090         {
1091                 // show "10 0" for loser spawns
1092                 setmodel(self.killindicator, MDL_NUM(10));
1093                 setmodel(self.killindicator.killindicator, MDL_NUM(0));
1094         }
1095         else
1096         {
1097                 setmodel(self.killindicator, MDL_NUM(self.cnt % 10));
1098                 setmodel(self.killindicator.killindicator, MDL_NUM(floor(self.cnt / 10)));
1099         }
1100
1101         self.nextthink = time;
1102 }
1103
1104 #endif