qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2 #include "g_damage.qh"
   3 #include "race.qh"
   4 #include "t_teleporters.qh"
   5
   6 #if defined(CSQC)
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9         #include "../dpdefs/progsdefs.qh"
  10     #include "../dpdefs/dpextensions.qh"
  11     #include "../warpzonelib/anglestransform.qh"
  12     #include "../warpzonelib/util_server.qh"
  13     #include "../common/constants.qh"
  14     #include "../common/util.qh"
  15     #include "../common/monsters/monsters.qh"
  16     #include "../common/weapons/weapons.qh"
  17     #include "weapons/tracing.qh"
  18     #include "autocvars.qh"
  19     #include "defs.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "mutators/mutators_include.qh"
  22     #include "../csqcmodellib/sv_model.qh"
  23 #endif
  24
  25 void CopyBody(float keepvelocity);
  26
  27 #ifdef NOCHEATS
  28
  29 float CheatImpulse(float i) { return 0; }
  30 float CheatCommand(float argc) { return 0; }
  31 float CheatFrame() { return 0; }
  32 void CheatInit() { cheatcount_total = world.cheatcount; }
  33 void CheatShutdown() { }
  34 void CheatInitClient() { }
  35 void CheatShutdownClient() { }
  36 void Drag_MoveDrag(entity from, entity to) { }
  37
  38 #else
  39
  40 .float maycheat;
  41 float gamestart_sv_cheats;
  42
  43 const float CHIMPULSE_SPEEDRUN_INIT = 30;
  44 const float CHIMPULSE_GIVE_ALL = 99;
  45 const float CHIMPULSE_CLONE_MOVING = 140;
  46 const float CHIMPULSE_SPEEDRUN = 141;
  47 const float CHIMPULSE_CLONE_STANDING = 142;
  48 const float CHIMPULSE_TELEPORT = 143;
  49 const float CHIMPULSE_R00T = 148;
  50
  51 const float CHRAME_DRAG = 8;
  52
  53 void CheatInit()
  54 {
  55         gamestart_sv_cheats = autocvar_sv_cheats;
  56 }
  57
  58 void CheatShutdown()
  59 {
  60 }
  61
  62 void CheatInitClient()
  63 {
  64 }
  65
  66 void CheatShutdownClient()
  67 {
  68 }
  69
  70 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  71 {
  72         // dead people cannot cheat
  73         if(self.deadflag != DEAD_NO)
  74                 return 0;
  75         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  76                 return 0;
  77
  78         // sv_clones
  79         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  80                 if(self.lip < sv_clones)
  81                         return 1;
  82
  83         // haha
  84         if(self.maycheat)
  85                 return 1;
  86
  87         // sv_cheats
  88         if(gamestart_sv_cheats && autocvar_sv_cheats)
  89                 return 1;
  90
  91         // if we get here, player is not allowed to cheat. Log it.
  92         if(i)
  93                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  94         else if(argc)
  95                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  96         else if(fr)
  97                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  98         else
  99                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
 100
 101         return 0;
 102 }
 103
 104 #define BEGIN_CHEAT_FUNCTION() \
 105         float cheating, attempting; \
 106         cheating = 0; attempting = 0
 107 #define DID_CHEAT() \
 108         ++cheating
 109 #define ADD_CHEATS(e,n) \
 110         cheatcount_total += n; \
 111         e.cheatcount += n
 112 #define END_CHEAT_FUNCTION() \
 113         ADD_CHEATS(self,cheating); \
 114         return attempting
 115 #define IS_CHEAT(i,argc,fr) \
 116         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 117                 break
 118
 119 float num_autoscreenshot;
 120 void info_autoscreenshot_findtarget()
 121 {
 122         entity e;
 123         e = find(world, targetname, self.target);
 124         if(!e)
 125         {
 126                 objerror("Missing target. FAIL!");
 127                 return;
 128         }
 129         vector a = vectoangles(e.origin - self.origin);
 130         a.x = -a.x; // don't ask
 131         self.angles_x = a.x;
 132         self.angles_y = a.y;
 133         // we leave Rick Roll alone
 134 }
 135 void spawnfunc_info_autoscreenshot()
 136 {
 137         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 138         {
 139                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 140                 return;
 141         }
 142         if(self.target != "")
 143                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 144         // this one just has to exist
 145 }
 146
 147 float CheatImpulse(float i)
 148 {
 149         BEGIN_CHEAT_FUNCTION();
 150         switch(i)
 151         {
 152                 entity e, e2;
 153
 154                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 155                         // shared with regular waypoint init, so this is not a cheat by itself
 156                         if(!self.personal)
 157                         {
 158                                 self.personal = spawn();
 159                                 self.personal.classname = "personal_wp";
 160                         }
 161                         self.personal.origin = self.origin;
 162                         self.personal.v_angle = self.v_angle;
 163                         self.personal.velocity = self.velocity;
 164                         self.personal.ammo_rockets = self.ammo_rockets;
 165                         self.personal.ammo_nails = self.ammo_nails;
 166                         self.personal.ammo_cells = self.ammo_cells;
 167                         self.personal.ammo_plasma = self.ammo_plasma;
 168                         self.personal.ammo_shells = self.ammo_shells;
 169                         self.personal.ammo_fuel = self.ammo_fuel;
 170                         self.personal.health = self.health;
 171                         self.personal.armorvalue = self.armorvalue;
 172                         self.personal.weapons = self.weapons;
 173                         self.personal.items = self.items;
 174                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 175                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 176                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 177                         self.personal.pauseregen_finished = self.pauseregen_finished;
 178                         self.personal.strength_finished = self.strength_finished;
 179                         self.personal.invincible_finished = self.invincible_finished;
 180                         self.personal.teleport_time = time;
 181                         break; // this part itself doesn't cheat, so let's not count this
 182                 case CHIMPULSE_CLONE_MOVING:
 183                         IS_CHEAT(i, 0, 0);
 184                         makevectors (self.v_angle);
 185                         self.velocity = self.velocity + v_forward * 300;
 186                         CopyBody(1);
 187                         self.lip += 1;
 188                         self.velocity = self.velocity - v_forward * 300;
 189                         DID_CHEAT();
 190                         break;
 191                 case CHIMPULSE_CLONE_STANDING:
 192                         IS_CHEAT(i, 0, 0);
 193                         CopyBody(0);
 194                         self.lip += 1;
 195                         DID_CHEAT();
 196                         break;
 197                 case CHIMPULSE_GIVE_ALL:
 198                         IS_CHEAT(i, 0, 0);
 199                         CheatCommand(tokenize_console("give all"));
 200                         break; // already counted as cheat
 201                 case CHIMPULSE_SPEEDRUN:
 202                         IS_CHEAT(i, 0, 0);
 203                         if(self.personal)
 204                         {
 205                                 self.speedrunning = true;
 206                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 207                                 if(trace_startsolid)
 208                                 {
 209                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 210                                 }
 211                                 else
 212                                 {
 213                                         // Abort speedrun, teleport back
 214                                         setorigin(self, self.personal.origin);
 215                                         self.oldvelocity = self.velocity = self.personal.velocity;
 216                                         self.angles = self.personal.v_angle;
 217                                         self.fixangle = true;
 218
 219                                         MUTATOR_CALLHOOK(AbortSpeedrun);
 220                                 }
 221
 222                                 self.ammo_rockets = self.personal.ammo_rockets;
 223                                 self.ammo_nails = self.personal.ammo_nails;
 224                                 self.ammo_cells = self.personal.ammo_cells;
 225                                 self.ammo_plasma = self.personal.ammo_plasma;
 226                                 self.ammo_shells = self.personal.ammo_shells;
 227                                 self.ammo_fuel = self.personal.ammo_fuel;
 228                                 self.health = self.personal.health;
 229                                 self.armorvalue = self.personal.armorvalue;
 230                                 self.weapons = self.personal.weapons;
 231                                 self.items = self.personal.items;
 232                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 233                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 234                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 235                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 236                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 237                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 238
 239                                 DID_CHEAT();
 240                                 break;
 241                         }
 242                         if(self.deadflag != DEAD_NO)
 243                                 sprint(self, "UR DEAD AHAHAH))\n");
 244                         else
 245                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 246                         break;
 247                 case CHIMPULSE_TELEPORT:
 248                         IS_CHEAT(i, 0, 0);
 249                         if(self.movetype == MOVETYPE_NOCLIP)
 250                         {
 251                                 e = find(world, classname, "info_autoscreenshot");
 252                                 if(e)
 253                                 {
 254                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 255                                         setorigin(self, e.origin);
 256                                         self.angles = e.angles;
 257                                         remove(e);
 258                                         // should we? self.angles_x = -self.angles_x;
 259                                         self.fixangle = true;
 260                                         self.velocity = '0 0 0';
 261                                         DID_CHEAT();
 262                                         break;
 263                                 }
 264                         }
 265                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 266                         {
 267                                 sprint(self, "Emergency teleport used random location\n");
 268                                 self.angles_x = -self.angles.x;
 269                                 self.fixangle = true;
 270                                 self.velocity = '0 0 0';
 271                                 DID_CHEAT();
 272                                 break;
 273                         }
 274                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 275                         break;
 276                 case CHIMPULSE_R00T:
 277                         IS_CHEAT(i, 0, 0);
 278                         RandomSelection_Init();
 279                         FOR_EACH_PLAYER(e)
 280                                 if(e.deadflag == DEAD_NO)
 281                                         if(DIFF_TEAM(e, self))
 282                                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 283                         if(RandomSelection_chosen_ent)
 284                                 e = RandomSelection_chosen_ent;
 285                         else
 286                                 e = self;
 287
 288                         pointparticles(particleeffectnum("rocket_explode"), e.origin, '0 0 0', 1);
 289                         sound(e, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 290
 291                         e2 = spawn();
 292                         setorigin(e2, e.origin);
 293                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT, e);
 294                         remove(e2);
 295
 296                         print("404 Sportsmanship not found.\n");
 297                         DID_CHEAT();
 298                         break;
 299         }
 300
 301         END_CHEAT_FUNCTION();
 302 }
 303
 304 void DragBox_Think();
 305 float drag_lastcnt;
 306 float CheatCommand(float argc)
 307 {
 308         BEGIN_CHEAT_FUNCTION();
 309         string cmd;
 310         cmd = argv(0);
 311         switch(cmd)
 312         {
 313                 entity e;
 314                 float effectnum, f;
 315                 vector start, end;
 316                 entity oldself;
 317
 318                 case "pointparticles":
 319                         IS_CHEAT(0, argc, 0);
 320                         if(argc == 5)
 321                         {
 322                                 // arguments:
 323                                 //   effectname
 324                                 //   origin (0..1, on crosshair line)
 325                                 //   velocity
 326                                 //   howmany
 327                                 effectnum = particleeffectnum(argv(1));
 328                                 f = stof(argv(2));
 329                                 crosshair_trace(self);
 330                                 start = (1-f) * self.origin + f * trace_endpos;
 331                                 end = stov(argv(3));
 332                                 f = stof(argv(4));
 333                                 pointparticles(effectnum, start, end, f);
 334                                 DID_CHEAT();
 335                                 break;
 336                         }
 337                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 338                         break;
 339                 case "trailparticles":
 340                         IS_CHEAT(0, argc, 0);
 341                         if(argc == 2)
 342                         {
 343                                 // arguments:
 344                                 //   effectname
 345                                 effectnum = particleeffectnum(argv(1));
 346                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 347                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 348                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 349                                 DID_CHEAT();
 350                                 break;
 351                         }
 352                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 353                         break;
 354                 case "make":
 355                         IS_CHEAT(0, argc, 0);
 356                         if(argc == 3)
 357                         {
 358                                 // arguments:
 359                                 //   modelname mode
 360                                 f = stof(argv(2));
 361                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 362                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 363                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 364                                 {
 365                                         sprint(self, "cannot make stuff there (bad surface)\n");
 366                                 }
 367                                 else
 368                                 {
 369                                         e = spawn();
 370                                         e.model = strzone(argv(1));
 371                                         e.mdl = "rocket_explode";
 372                                         e.health = 1000;
 373                                         setorigin(e, trace_endpos);
 374                                         e.effects = EF_NOMODELFLAGS;
 375                                         if(f == 1)
 376                                         {
 377                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 378                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 379                                         }
 380                                         oldself = self;
 381                                         self = e;
 382                                         spawnfunc_func_breakable();
 383                                         self = oldself;
 384                                         // now, is it valid?
 385                                         if(f == 0)
 386                                         {
 387                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 388                                                 if(trace_startsolid)
 389                                                 {
 390                                                         remove(e);
 391                                                         sprint(self, "cannot make stuff there (no space)\n");
 392                                                 }
 393                                                 else
 394                                                         DID_CHEAT();
 395                                         }
 396                                         else
 397                                                 DID_CHEAT();
 398                                 }
 399                         }
 400                         else
 401                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 402                         break;
 403                 case "penalty":
 404                         IS_CHEAT(0, argc, 0);
 405                         if(argc == 3)
 406                         {
 407                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 408                                 DID_CHEAT();
 409                                 break;
 410                         }
 411                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 412                         break;
 413                 case "dragbox_spawn":
 414                         IS_CHEAT(0, argc, 0);
 415                         e = spawn();
 416                         e.classname = "dragbox_box";
 417                         e.think = DragBox_Think;
 418                         e.nextthink = time;
 419                         e.solid = -1; // black
 420                         setmodel(e, "null"); // network it
 421                         if(argc == 4)
 422                                 e.cnt = stof(argv(1));
 423                         else
 424                                 e.cnt = max(0, drag_lastcnt);
 425
 426                         e.aiment = spawn();
 427                         e.aiment.classname = "dragbox_corner_1";
 428                         e.aiment.owner = e;
 429                         setmodel(e.aiment, "models/marker.md3");
 430                         e.aiment.skin = 0;
 431                         setsize(e.aiment, '0 0 0', '0 0 0');
 432                         if(argc == 4)
 433                                 setorigin(e.aiment, stov(argv(2)));
 434                         else
 435                         {
 436                                 crosshair_trace(self);
 437                                 setorigin(e.aiment, trace_endpos);
 438                         }
 439
 440                         e.enemy = spawn();
 441                         e.enemy.classname = "dragbox_corner_2";
 442                         e.enemy.owner = e;
 443                         setmodel(e.enemy, "models/marker.md3");
 444                         e.enemy.skin = 1;
 445                         setsize(e.enemy, '0 0 0', '0 0 0');
 446                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 447                         end.x = (end.x > 0) * 2 - 1;
 448                         end.y = (end.y > 0) * 2 - 1;
 449                         end.z = (end.z > 0) * 2 - 1;
 450                         if(argc == 4)
 451                                 setorigin(e.enemy, stov(argv(3)));
 452                         else
 453                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 454
 455                         e.killindicator = spawn();
 456                         e.killindicator.classname = "drag_digit";
 457                         e.killindicator.owner = e;
 458                         setattachment(e.killindicator, e, "");
 459                         setorigin(e.killindicator, '0 0 -8');
 460                         e.killindicator.killindicator = spawn();
 461                         e.killindicator.killindicator.classname = "drag_digit";
 462                         e.killindicator.killindicator.owner = e;
 463                         setattachment(e.killindicator.killindicator, e, "");
 464                         setorigin(e.killindicator.killindicator, '0 0 8');
 465                         DID_CHEAT();
 466                         break;
 467                 case "dragpoint_spawn":
 468                         IS_CHEAT(0, argc, 0);
 469                         e = spawn();
 470                         e.classname = "dragpoint";
 471                         e.think = DragBox_Think;
 472                         e.nextthink = time;
 473                         e.solid = 0; // nothing special
 474                         setmodel(e, "models/marker.md3");
 475                         setsize(e, PL_MIN, PL_MAX);
 476                         e.skin = 2;
 477                         if(argc == 3)
 478                                 e.cnt = stof(argv(1));
 479                         else
 480                                 e.cnt = drag_lastcnt;
 481                         if(argc == 3)
 482                                 setorigin(e, stov(argv(2)));
 483                         else
 484                         {
 485                                 crosshair_trace(self);
 486                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 487                                 move_out_of_solid(e);
 488                         }
 489
 490                         e.killindicator = spawn();
 491                         e.killindicator.classname = "drag_digit";
 492                         e.killindicator.owner = e;
 493                         setattachment(e.killindicator, e, "");
 494                         setorigin(e.killindicator, '0 0 40');
 495                         e.killindicator.killindicator = spawn();
 496                         e.killindicator.killindicator.classname = "drag_digit";
 497                         e.killindicator.killindicator.owner = e;
 498                         setattachment(e.killindicator.killindicator, e, "");
 499                         setorigin(e.killindicator.killindicator, '0 0 56');
 500                         DID_CHEAT();
 501                         break;
 502                 case "drag_remove":
 503                         IS_CHEAT(0, argc, 0);
 504                         RandomSelection_Init();
 505                         crosshair_trace(self);
 506                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 507                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 508                         for(e = world; (e = find(e, classname, "dragpoint")); )
 509                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 510                         if(RandomSelection_chosen_ent)
 511                         {
 512                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 513                                 remove(RandomSelection_chosen_ent.killindicator);
 514                                 if(RandomSelection_chosen_ent.aiment)
 515                                         remove(RandomSelection_chosen_ent.aiment);
 516                                 if(RandomSelection_chosen_ent.enemy)
 517                                         remove(RandomSelection_chosen_ent.enemy);
 518                                 remove(RandomSelection_chosen_ent);
 519                         }
 520                         DID_CHEAT();
 521                         break;
 522                 case "drag_setcnt":
 523                         IS_CHEAT(0, argc, 0);
 524                         if(argc == 2)
 525                         {
 526                                 RandomSelection_Init();
 527                                 crosshair_trace(self);
 528                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 529                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 530                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 531                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 532                                 if(RandomSelection_chosen_ent)
 533                                 {
 534                                         if(substring(argv(1), 0, 1) == "*")
 535                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 536                                         else
 537                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 538                                 }
 539                                 DID_CHEAT();
 540                                 break;
 541                         }
 542                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 543                         break;
 544                 case "drag_save":
 545                         IS_CHEAT(0, argc, 0);
 546                         if(argc == 2)
 547                         {
 548                                 f = fopen(argv(1), FILE_WRITE);
 549                                 fputs(f, "cmd drag_clear\n");
 550                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 551                                 {
 552                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 553                                 }
 554                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 555                                 {
 556                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 557                                 }
 558                                 fclose(f);
 559                                 DID_CHEAT();
 560                                 break;
 561                         }
 562                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 563                         break;
 564                 case "drag_saveraceent":
 565                         IS_CHEAT(0, argc, 0);
 566                         if(argc == 2)
 567                         {
 568                                 f = fopen(argv(1), FILE_WRITE);
 569                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 570                                 {
 571                                         fputs(f, "{\n");
 572                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 573                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 574                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 575                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 576                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 577                                         fputs(f, "}\n");
 578                                 }
 579                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 580                                 {
 581                                         start = '0 0 0';
 582                                         effectnum = 0;
 583                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 584                                         {
 585                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 586                                                 {
 587                                                         start = start + oldself.origin;
 588                                                         ++effectnum;
 589                                                 }
 590                                         }
 591                                         start *= 1 / effectnum;
 592                                         fputs(f, "{\n");
 593                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 594                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 595                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 596                                         if(e.cnt == -2)
 597                                         {
 598                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 599                                                 fputs(f, "\"race_place\" \"0\"\n");
 600                                         }
 601                                         else if(e.cnt == -1)
 602                                         {
 603                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 604                                                 fputs(f, "\"race_place\" \"-1\"\n");
 605                                         }
 606                                         else
 607                                         {
 608                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 609                                                 if(e.cnt == 0)
 610                                                 {
 611                                                         // these need race_place
 612                                                         // counting...
 613                                                         effectnum = 1;
 614                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 615                                                         if(oldself.cnt == 0)
 616                                                         {
 617                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 618                                                                         ++effectnum;
 619                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 620                                                                         ++effectnum;
 621                                                         }
 622                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 623                                                 }
 624                                         }
 625                                         fputs(f, "}\n");
 626                                 }
 627                                 fclose(f);
 628                                 DID_CHEAT();
 629                                 break;
 630                         }
 631                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 632                         break;
 633                 case "drag_clear":
 634                         IS_CHEAT(0, argc, 0);
 635                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 636                                 remove(e);
 637                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 638                                 remove(e);
 639                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 640                                 remove(e);
 641                         for(e = world; (e = find(e, classname, "dragpoint")); )
 642                                 remove(e);
 643                         for(e = world; (e = find(e, classname, "drag_digit")); )
 644                                 remove(e);
 645                         DID_CHEAT();
 646                         break;
 647                 case "god":
 648                         IS_CHEAT(0, argc, 0);
 649                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 650                         if(self.flags & FL_GODMODE)
 651                         {
 652                                 sprint(self, "godmode ON\n");
 653                                 DID_CHEAT();
 654                         }
 655                         else
 656                                 sprint(self, "godmode OFF\n");
 657                         break;
 658                 case "notarget":
 659                         IS_CHEAT(0, argc, 0);
 660                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 661                         if(self.flags & FL_NOTARGET)
 662                         {
 663                                 sprint(self, "notarget ON\n");
 664                                 DID_CHEAT();
 665                         }
 666                         else
 667                                 sprint(self, "notarget OFF\n");
 668                         break;
 669                 case "noclip":
 670                         IS_CHEAT(0, argc, 0);
 671                         if(self.movetype != MOVETYPE_NOCLIP)
 672                         {
 673                                 self.movetype = MOVETYPE_NOCLIP;
 674                                 sprint(self, "noclip ON\n");
 675                                 DID_CHEAT();
 676                         }
 677                         else
 678                         {
 679                                 self.movetype = MOVETYPE_WALK;
 680                                 sprint(self, "noclip OFF\n");
 681                         }
 682                         break;
 683                 case "fly":
 684                         IS_CHEAT(0, argc, 0);
 685                         if(self.movetype != MOVETYPE_FLY)
 686                         {
 687                                 self.movetype = MOVETYPE_FLY;
 688                                 sprint(self, "flymode ON\n");
 689                                 DID_CHEAT();
 690                         }
 691                         else
 692                         {
 693                                 self.movetype = MOVETYPE_WALK;
 694                                 sprint(self, "flymode OFF\n");
 695                         }
 696                         break;
 697                 case "give":
 698                         IS_CHEAT(0, argc, 0);
 699                         if(GiveItems(self, 1, argc))
 700                                 DID_CHEAT();
 701                         break;
 702                 case "usetarget":
 703                         IS_CHEAT(0, argc, 0);
 704                         e = self;
 705                         self = spawn();
 706                         self.target = argv(1);
 707                         activator = e;
 708                         SUB_UseTargets();
 709                         remove(self);
 710                         self = e;
 711                         DID_CHEAT();
 712                         break;
 713                 case "killtarget":
 714                         IS_CHEAT(0, argc, 0);
 715                         e = self;
 716                         self = spawn();
 717                         self.killtarget = argv(1);
 718                         activator = e;
 719                         SUB_UseTargets();
 720                         remove(self);
 721                         self = e;
 722                         DID_CHEAT();
 723                         break;
 724                 case "teleporttotarget":
 725                         IS_CHEAT(0, argc, 0);
 726                         e = self;
 727                         self = spawn();
 728                         setorigin(self, self.origin);
 729                         self.classname = "cheattriggerteleport";
 730                         self.target = argv(1);
 731                         teleport_findtarget();
 732                         if(!wasfreed(self))
 733                         {
 734                                 Simple_TeleportPlayer(self, e);
 735                                 remove(self);
 736                                 self = e;
 737                                 DID_CHEAT();
 738                         }
 739                         else
 740                                 self = e;
 741                         break;
 742         }
 743
 744         END_CHEAT_FUNCTION();
 745 }
 746
 747 float Drag(float force_allow_pick, float ischeat);
 748 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 749 void Drag_Finish(entity dragger);
 750 float Drag_IsDraggable(entity draggee);
 751 float Drag_MayChangeAngles(entity draggee);
 752 void Drag_MoveForward(entity dragger);
 753 void Drag_SetSpeed(entity dragger, float s);
 754 void Drag_MoveBackward(entity dragger);
 755 void Drag_Update(entity dragger);
 756 float Drag_CanDrag(entity dragger);
 757 float Drag_IsDragging(entity dragger);
 758 void Drag_MoveDrag(entity from, entity to);
 759 .entity dragentity;
 760
 761 float CheatFrame()
 762 {
 763         BEGIN_CHEAT_FUNCTION();
 764
 765         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 766         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 767         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 768         // grabbing itself no longer being accounted as cheating.
 769
 770         switch(0)
 771         {
 772                 default:
 773                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 774                         {
 775                                 // use cheat dragging if cheats are enabled
 776                                 crosshair_trace_plusvisibletriggers(self);
 777                                 Drag(true, true);
 778                         }
 779                         else
 780                         {
 781                                 Drag(false, false); // execute dragging
 782                         }
 783                         break;
 784         }
 785
 786         END_CHEAT_FUNCTION();
 787 }
 788
 789
 790
 791
 792
 793 // ENTITY DRAGGING
 794
 795 // on dragger:
 796 .float draggravity;
 797 .float dragspeed; // speed of mouse wheel action
 798 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 799 .vector draglocalvector; // local attachment vector of the dragentity
 800 .float draglocalangle;
 801 // on draggee:
 802 .entity draggedby;
 803 .float dragmovetype;
 804
 805 float Drag(float force_allow_pick, float ischeat)
 806 {
 807         BEGIN_CHEAT_FUNCTION();
 808
 809         // returns true when an entity has been picked up
 810         // If pick is true, the object can also be picked up if it's not being held already
 811         // If pick is false, only keep dragging the object if it's already being held
 812
 813         switch(0)
 814         {
 815                 default:
 816                         if(Drag_IsDragging(self))
 817                         {
 818                                 if(self.BUTTON_DRAG)
 819                                 {
 820                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 821                                         {
 822                                                 Drag_MoveForward(self);
 823                                                 self.impulse = 0;
 824                                         }
 825                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 826                                         {
 827                                                 Drag_MoveBackward(self);
 828                                                 self.impulse = 0;
 829                                         }
 830                                         else if(self.impulse >= 1 && self.impulse <= 9)
 831                                         {
 832                                                 Drag_SetSpeed(self, self.impulse - 1);
 833                                         }
 834                                         else if(self.impulse == 14)
 835                                         {
 836                                                 Drag_SetSpeed(self, 9);
 837                                         }
 838
 839                                         if(frametime)
 840                                                 Drag_Update(self);
 841                                 }
 842                                 else
 843                                 {
 844                                         Drag_Finish(self);
 845                                 }
 846                         }
 847                         else
 848                         {
 849                                 if(Drag_CanDrag(self))
 850                                         if(self.BUTTON_DRAG)
 851                                         {
 852                                                 crosshair_trace_plusvisibletriggers(self);
 853                                                 entity e = trace_ent;
 854                                                 float pick = force_allow_pick;
 855                                                 if (e && !pick)
 856                                                 {
 857                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 858                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 859                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 860                                                         // it goes out of range while slinging it around.
 861
 862                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 863                                                         {
 864                                                                 switch(e.grab)
 865                                                                 {
 866                                                                         case 0: // can't grab
 867                                                                                 break;
 868                                                                         case 1: // owner can grab
 869                                                                                 if(e.owner == self || e.realowner == self)
 870                                                                                         pick = true;
 871                                                                                 break;
 872                                                                         case 2: // owner and team mates can grab
 873                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 874                                                                                         pick = true;
 875                                                                                 break;
 876                                                                         case 3: // anyone can grab
 877                                                                                 pick = true;
 878                                                                                 break;
 879                                                                         default:
 880                                                                                 break;
 881                                                                 }
 882                                                         }
 883                                                 }
 884                                                 // Find e and pick
 885                                                 if(e && pick)
 886                                                         if(Drag_IsDraggable(e))
 887                                                         {
 888                                                                 if(ischeat)
 889                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 890                                                                 if(e.draggedby)
 891                                                                         Drag_Finish(e.draggedby);
 892                                                                 if(e.tag_entity)
 893                                                                         detach_sameorigin(e);
 894                                                                 Drag_Begin(self, e, trace_endpos);
 895                                                                 if(ischeat)
 896                                                                         DID_CHEAT();
 897                                                                 return true;
 898                                                         }
 899                                         }
 900                         }
 901                         break;
 902         }
 903         return false;
 904 }
 905
 906 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 907 {
 908         float tagscale;
 909
 910         draggee.dragmovetype = draggee.movetype;
 911         draggee.draggravity = draggee.gravity;
 912         draggee.movetype = MOVETYPE_WALK;
 913         draggee.gravity = 0.00001;
 914         draggee.flags &= ~FL_ONGROUND;
 915         draggee.draggedby = dragger;
 916
 917         dragger.dragentity = draggee;
 918
 919         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 920         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 921         touchpoint = touchpoint - gettaginfo(draggee, 0);
 922         tagscale = pow(vlen(v_forward), -2);
 923         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 924         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 925         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 926
 927         dragger.dragspeed = 64;
 928 }
 929
 930 void Drag_Finish(entity dragger)
 931 {
 932         entity draggee;
 933         draggee = dragger.dragentity;
 934         if(dragger)
 935                 dragger.dragentity = world;
 936         draggee.draggedby = world;
 937         draggee.movetype = draggee.dragmovetype;
 938         draggee.gravity = draggee.draggravity;
 939
 940         switch(draggee.movetype)
 941         {
 942                 case MOVETYPE_TOSS:
 943                 case MOVETYPE_WALK:
 944                 case MOVETYPE_STEP:
 945                 case MOVETYPE_FLYMISSILE:
 946                 case MOVETYPE_BOUNCE:
 947                 case MOVETYPE_BOUNCEMISSILE:
 948                 case MOVETYPE_PHYSICS:
 949                         break;
 950                 default:
 951                         draggee.velocity = '0 0 0';
 952                         break;
 953         }
 954
 955         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 956         {
 957                 draggee.velocity = '0 0 0';
 958                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 959         }
 960 }
 961
 962 float Drag_IsDraggable(entity draggee)
 963 {
 964         // TODO add more checks for bad stuff here
 965         if(draggee == world)
 966                 return false;
 967         if(draggee.classname == "func_bobbing")
 968                 return false;
 969         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 970                 return false;
 971         if(draggee.classname == "plat")
 972                 return false;
 973         if(draggee.classname == "func_button")
 974                 return false;
 975 //      if(draggee.model == "")
 976 //              return false;
 977         if(IS_SPEC(draggee))
 978                 return false;
 979         if(IS_OBSERVER(draggee))
 980                 return false;
 981         if(draggee.classname == "exteriorweaponentity")
 982                 return false;
 983         if(draggee.classname == "weaponentity")
 984                 return false;
 985
 986         return true;
 987 }
 988
 989 float Drag_MayChangeAngles(entity draggee)
 990 {
 991         // TODO add more checks for bad stuff here
 992         if(substring(draggee.model, 0, 1) == "*")
 993                 return false;
 994         return true;
 995 }
 996
 997 void Drag_MoveForward(entity dragger)
 998 {
 999         dragger.dragdistance += dragger.dragspeed;
1000 }
1001
1002 void Drag_SetSpeed(entity dragger, float s)
1003 {
1004         dragger.dragspeed = pow(2, s);
1005 }
1006
1007 void Drag_MoveBackward(entity dragger)
1008 {
1009         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
1010 }
1011
1012 void Drag_Update(entity dragger)
1013 {
1014         vector curorigin, neworigin, goodvelocity;
1015         float f;
1016         entity draggee;
1017
1018         draggee = dragger.dragentity;
1019         draggee.flags &= ~FL_ONGROUND;
1020
1021         curorigin = gettaginfo(draggee, 0);
1022         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
1023         makevectors(dragger.v_angle);
1024         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
1025         goodvelocity = (neworigin - curorigin) * (1 / frametime);
1026
1027         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
1028                 dragger.draglocalangle += 360;
1029         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1030                 dragger.draglocalangle -= 360;
1031
1032         f = min(frametime * 10, 1);
1033         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1034
1035         if(Drag_MayChangeAngles(draggee))
1036                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1037
1038         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1039
1040         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
1041 }
1042
1043 float Drag_CanDrag(entity dragger)
1044 {
1045         return (dragger.deadflag == DEAD_NO) || (IS_PLAYER(dragger));
1046 }
1047
1048 float Drag_IsDragging(entity dragger)
1049 {
1050         if(!dragger.dragentity)
1051                 return false;
1052         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1053         {
1054                 dragger.dragentity = world;
1055                 return false;
1056         }
1057         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1058         {
1059                 Drag_Finish(dragger);
1060                 return false;
1061         }
1062         return true;
1063 }
1064
1065 void Drag_MoveDrag(entity from, entity to)
1066 {
1067         if(from.draggedby)
1068         {
1069                 to.draggedby = from.draggedby;
1070                 to.draggedby.dragentity = to;
1071                 from.draggedby = world;
1072         }
1073 }
1074
1075 void DragBox_Think()
1076 {
1077         if(self.aiment && self.enemy)
1078         {
1079                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1080                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1081                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1082                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1083                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1084                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1085                 self.mins = -1 * self.maxs;
1086                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1087         }
1088
1089         if(self.cnt == -1) // actually race_place -1
1090         {
1091                 // show "10 10" for qualifying spawns
1092                 setmodel(self.killindicator, "models/sprites/10.spr32");
1093                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1094         }
1095         else if(self.cnt == -2) // actually race_place 0
1096         {
1097                 // show "10 0" for loser spawns
1098                 setmodel(self.killindicator, "models/sprites/10.spr32");
1099                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1100         }
1101         else
1102         {
1103                 setmodel(self.killindicator, strcat("models/sprites/", ftos(self.cnt % 10), ".spr32"));
1104                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1105         }
1106
1107         self.nextthink = time;
1108 }
1109
1110 #endif