Merge remote-tracking branch 'origin/Mario/extralife_fix'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 float ClientData_Send(entity to, float sf)
10 {
11         if(to != self.owner)
12         {
13                 error("wtf");
14                 return FALSE;
15         }
16
17         entity e;
18
19         e = to;
20         if(IS_SPEC(to))
21                 e = to.enemy;
22
23         sf = 0;
24
25         if(e.race_completed)
26                 sf |= 1; // forced scoreboard
27         if(to.spectatee_status)
28                 sf |= 2; // spectator ent number follows
29         if(e.zoomstate)
30                 sf |= 4; // zoomed
31         if(e.porto_v_angle_held)
32                 sf |= 8; // angles held
33
34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
35         WriteByte(MSG_ENTITY, sf);
36
37         if(sf & 2)
38                 WriteByte(MSG_ENTITY, to.spectatee_status);
39
40         if(sf & 8)
41         {
42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
44         }
45
46         return TRUE;
47 }
48
49 void ClientData_Attach()
50 {
51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
52         self.clientdata.drawonlytoclient = self;
53         self.clientdata.owner = self;
54 }
55
56 void ClientData_Detach()
57 {
58         remove(self.clientdata);
59         self.clientdata = world;
60 }
61
62 void ClientData_Touch(entity e)
63 {
64         e.clientdata.SendFlags = 1;
65
66         // make it spectatable
67         entity e2;
68         FOR_EACH_REALCLIENT(e2)
69         {
70                 if(e2 != e)
71                         if(IS_SPEC(e2))
72                                 if(e2.enemy == e)
73                                         e2.clientdata.SendFlags = 1;
74         }
75 }
76
77
78 .vector spawnpoint_score;
79 .string netname_previous;
80
81 void spawnfunc_info_player_survivor (void)
82 {
83         spawnfunc_info_player_deathmatch();
84 }
85
86 void spawnfunc_info_player_start (void)
87 {
88         spawnfunc_info_player_deathmatch();
89 }
90
91 void spawnfunc_info_player_deathmatch (void)
92 {
93         self.classname = "info_player_deathmatch";
94         relocate_spawnpoint();
95 }
96
97 void spawnpoint_use()
98 {
99         if(teamplay)
100         if(have_team_spawns > 0)
101         {
102                 self.team = activator.team;
103                 some_spawn_has_been_used = 1;
104         }
105 }
106
107 // Returns:
108 //   _x: prio (-1 if unusable)
109 //   _y: weight
110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
111 {
112         float shortest, thisdist;
113         float prio;
114         entity player;
115
116         prio = 0;
117
118         // filter out spots for the wrong team
119         if(teamcheck >= 0)
120                 if(spot.team != teamcheck)
121                         return '-1 0 0';
122
123         if(race_spawns)
124                 if(spot.target == "")
125                         return '-1 0 0';
126
127         if(IS_REAL_CLIENT(self))
128         {
129                 if(spot.restriction == 1)
130                         return '-1 0 0';
131         }
132         else
133         {
134                 if(spot.restriction == 2)
135                         return '-1 0 0';
136         }
137
138         shortest = vlen(world.maxs - world.mins);
139         FOR_EACH_PLAYER(player) if (player != self)
140         {
141                 thisdist = vlen(player.origin - spot.origin);
142                 if (thisdist < shortest)
143                         shortest = thisdist;
144         }
145         if(shortest > mindist)
146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
147
148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
149         spawn_spot = spot;
150
151         // filter out spots for assault
152         if(spot.target != "") {
153                 entity ent;
154                 float found;
155
156                 found = 0;
157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
158                 {
159                         ++found;
160                         if(ent.spawn_evalfunc)
161                         {
162                                 entity oldself = self;
163                                 self = ent;
164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
165                                 self = oldself;
166                                 if(spawn_score_x < 0)
167                                         return spawn_score;
168                         }
169                 }
170
171                 if(!found)
172                 {
173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
174                         return '-1 0 0';
175                 }
176         }
177
178         MUTATOR_CALLHOOK(Spawn_Score);
179         return spawn_score;
180 }
181
182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
183 {
184         entity spot;
185         for(spot = firstspot; spot; spot = spot.chain)
186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
187 }
188
189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
190 {
191         entity spot, spotlist, spotlistend;
192
193         spotlist = world;
194         spotlistend = world;
195
196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
197
198         for(spot = firstspot; spot; spot = spot.chain)
199         {
200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
201                 {
202                         if(spotlistend)
203                                 spotlistend.chain = spot;
204                         spotlistend = spot;
205                         if(!spotlist)
206                                 spotlist = spot;
207                 }
208         }
209         if(spotlistend)
210                 spotlistend.chain = world;
211
212         return spotlist;
213 }
214
215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
216 {
217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
219         entity spot;
220
221         RandomSelection_Init();
222         for(spot = firstspot; spot; spot = spot.chain)
223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
224
225         return RandomSelection_chosen_ent;
226 }
227
228 /*
229 =============
230 SelectSpawnPoint
231
232 Finds a point to respawn
233 =============
234 */
235 entity SelectSpawnPoint (float anypoint)
236 {
237         float teamcheck;
238         entity spot, firstspot;
239
240         spot = find (world, classname, "testplayerstart");
241         if (spot)
242                 return spot;
243
244         if(anypoint || autocvar_g_spawn_useallspawns)
245                 teamcheck = -1;
246         else if(have_team_spawns > 0)
247         {
248                 if(have_team_spawns_forteam[self.team] == 0)
249                 {
250                         // we request a spawn for a team, and we have team
251                         // spawns, but that team has no spawns?
252                         if(have_team_spawns_forteam[0])
253                                 // try noteam spawns
254                                 teamcheck = 0;
255                         else
256                                 // if not, any spawn has to do
257                                 teamcheck = -1;
258                 }
259                 else
260                         teamcheck = self.team; // MUST be team
261         }
262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
263                 teamcheck = 0; // MUST be noteam
264         else
265                 teamcheck = -1;
266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
267
268
269         // get the entire list of spots
270         firstspot = findchain(classname, "info_player_deathmatch");
271         // filter out the bad ones
272         // (note this returns the original list if none survived)
273         if(anypoint)
274         {
275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
276         }
277         else
278         {
279                 float mindist;
280                 if (g_arena && arena_roundbased)
281                         mindist = 800;
282                 else
283                         mindist = 100;
284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
285
286                 // there is 50/50 chance of choosing a random spot or the furthest spot
287                 // (this means that roughly every other spawn will be furthest, so you
288                 // usually won't get fragged at spawn twice in a row)
289                 if (random() > autocvar_g_spawn_furthest)
290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
291                 else
292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
293         }
294
295         if (!spot)
296         {
297                 if(autocvar_spawn_debug)
298                         GotoNextMap(0);
299                 else
300                 {
301                         if(some_spawn_has_been_used)
302                                 return world; // team can't spawn any more, because of actions of other team
303                         else
304                                 error("Cannot find a spawn point - please fix the map!");
305                 }
306         }
307
308         return spot;
309 }
310
311 /*
312 =============
313 CheckPlayerModel
314
315 Checks if the argument string can be a valid playermodel.
316 Returns a valid one in doubt.
317 =============
318 */
319 string FallbackPlayerModel;
320 string CheckPlayerModel(string plyermodel) {
321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
322         {
323                 // note: we cannot summon Don Strunzone here, some player may
324                 // still have the model string set. In case anyone manages how
325                 // to change a cvar default, we'll have a small leak here.
326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
327         }
328         // only in right path
329         if( substring(plyermodel,0,14) != "models/player/")
330                 return FallbackPlayerModel;
331         // only good file extensions
332         if(substring(plyermodel,-4,4) != ".zym")
333         if(substring(plyermodel,-4,4) != ".dpm")
334         if(substring(plyermodel,-4,4) != ".iqm")
335         if(substring(plyermodel,-4,4) != ".md3")
336         if(substring(plyermodel,-4,4) != ".psk")
337                 return FallbackPlayerModel;
338         // forbid the LOD models
339         if(substring(plyermodel, -9,5) == "_lod1")
340                 return FallbackPlayerModel;
341         if(substring(plyermodel, -9,5) == "_lod2")
342                 return FallbackPlayerModel;
343         if(plyermodel != strtolower(plyermodel))
344                 return FallbackPlayerModel;
345         // also, restrict to server models
346         if(autocvar_sv_servermodelsonly)
347         {
348                 if(!fexists(plyermodel))
349                         return FallbackPlayerModel;
350         }
351         return plyermodel;
352 }
353
354 void setplayermodel(entity e, string modelname)
355 {
356         precache_model(modelname);
357         setmodel(e, modelname);
358         player_setupanimsformodel();
359         UpdatePlayerSounds();
360 }
361
362 /*
363 =============
364 PutObserverInServer
365
366 putting a client as observer in the server
367 =============
368 */
369 void FixPlayermodel();
370 void PutObserverInServer (void)
371 {
372         entity  spot;
373     self.hud = HUD_NORMAL;
374         race_PreSpawnObserver();
375
376         spot = SelectSpawnPoint (TRUE);
377         if(!spot)
378                 error("No spawnpoints for observers?!?\n");
379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
380
381         if(IS_REAL_CLIENT(self))
382         {
383                 msg_entity = self;
384                 WriteByte(MSG_ONE, SVC_SETVIEW);
385                 WriteEntity(MSG_ONE, self);
386         }
387
388         if((g_race && g_race_qualifying) || g_cts)
389         {
390                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
391                         self.frags = FRAGS_LMS_LOSER;
392                 else
393                         self.frags = FRAGS_SPECTATOR;
394         }
395         else
396                 self.frags = FRAGS_SPECTATOR;
397
398         MUTATOR_CALLHOOK(MakePlayerObserver);
399
400         Portal_ClearAll(self);
401         
402         if(self.alivetime)
403         {
404                 if(!inWarmupStage)
405                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
406                 self.alivetime = 0;
407         }
408
409         if(self.vehicle)
410                 vehicles_exit(VHEF_RELESE);         
411
412         WaypointSprite_PlayerDead();
413
414         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
415                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
416
417         if(self.killcount != -666)
418         {
419                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
420
421                 if(self.just_joined == FALSE) {
422                         LogTeamchange(self.playerid, -1, 4);
423                 } else
424                         self.just_joined = FALSE;
425         }
426
427         PlayerScore_Clear(self); // clear scores when needed
428
429         accuracy_resend(self);
430
431         self.spectatortime = time;
432         
433         self.classname = "observer";
434         self.iscreature = FALSE;
435         self.teleportable = TELEPORT_SIMPLE;
436         self.damagedbycontents = FALSE;
437         self.health = -666;
438         self.takedamage = DAMAGE_NO;
439         self.solid = SOLID_NOT;
440         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
441         self.flags = FL_CLIENT | FL_NOTARGET;
442         self.armorvalue = 666;
443         self.effects = 0;
444         self.armorvalue = autocvar_g_balance_armor_start;
445         self.pauserotarmor_finished = 0;
446         self.pauserothealth_finished = 0;
447         self.pauseregen_finished = 0;
448         self.damageforcescale = 0;
449         self.death_time = 0;
450         self.respawn_flags = 0;
451         self.respawn_time = 0;
452         self.stat_respawn_time = 0;
453         self.alpha = 0;
454         self.scale = 0;
455         self.fade_time = 0;
456         self.pain_frame = 0;
457         self.pain_finished = 0;
458         self.strength_finished = 0;
459         self.invincible_finished = 0;
460         self.superweapons_finished = 0;
461         self.pushltime = 0;
462         self.istypefrag = 0;
463         self.think = func_null;
464         self.nextthink = 0;
465         self.hook_time = 0;
466         self.deadflag = DEAD_NO;
467         self.angles = spot.angles;
468         self.angles_z = 0;
469         self.fixangle = TRUE;
470         self.crouch = FALSE;
471
472         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
473         self.prevorigin = self.origin;
474         self.items = 0;
475         WEPSET_CLEAR_E(self);
476         self.model = "";
477         FixPlayermodel();
478         setmodel(self, "null");
479         self.drawonlytoclient = self;
480
481         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
482         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
483
484         self.weapon = 0;
485         self.weaponname = "";
486         self.switchingweapon = 0;
487         self.weaponmodel = "";
488         self.weaponentity = world;
489         self.exteriorweaponentity = world;
490         self.killcount = -666;
491         self.velocity = '0 0 0';
492         self.avelocity = '0 0 0';
493         self.punchangle = '0 0 0';
494         self.punchvector = '0 0 0';
495         self.oldvelocity = self.velocity;
496         self.fire_endtime = -1;
497 }
498
499 .float model_randomizer;
500 void FixPlayermodel()
501 {
502         string defaultmodel;
503         float defaultskin, chmdl, oldskin, n, i;
504         vector m1, m2;
505
506         defaultmodel = "";
507         defaultskin = 0;
508         chmdl = FALSE;
509
510         if(autocvar_sv_defaultcharacter == 1)
511         {
512                 if(teamplay)
513                 {
514                         string s;
515                         s = Team_ColorName_Lower(self.team);
516                         if(s != "neutral")
517                         {
518                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
519                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
520                         }
521                 }
522
523                 if(defaultmodel == "")
524                 {
525                         defaultmodel = autocvar_sv_defaultplayermodel;
526                         defaultskin = autocvar_sv_defaultplayerskin;
527                 }
528
529                 n = tokenize_console(defaultmodel);
530                 if(n > 0)
531                         defaultmodel = argv(floor(n * self.model_randomizer));
532
533                 i = strstrofs(defaultmodel, ":", 0);
534                 if(i >= 0)
535                 {
536                         defaultskin = stof(substring(defaultmodel, i+1, -1));
537                         defaultmodel = substring(defaultmodel, 0, i);
538                 }
539         }
540
541         if(defaultmodel != "")
542         {
543                 if (defaultmodel != self.model)
544                 {
545                         m1 = self.mins;
546                         m2 = self.maxs;
547                         setplayermodel (self, defaultmodel);
548                         setsize (self, m1, m2);
549                         chmdl = TRUE;
550                 }
551
552                 oldskin = self.skin;
553                 self.skin = defaultskin;
554         } else {
555                 if (self.playermodel != self.model || self.playermodel == "")
556                 {
557                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
558                         m1 = self.mins;
559                         m2 = self.maxs;
560                         setplayermodel (self, self.playermodel);
561                         setsize (self, m1, m2);
562                         chmdl = TRUE;
563                 }
564
565                 oldskin = self.skin;
566                 self.skin = stof(self.playerskin);
567         }
568
569         if(chmdl || oldskin != self.skin) // model or skin has changed
570         {
571                 self.species = player_getspecies(); // update species
572                 UpdatePlayerSounds(); // update skin sounds
573         }
574
575         if(!teamplay)
576                 if(strlen(autocvar_sv_defaultplayercolors))
577                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
578                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
579 }
580
581 /*
582 =============
583 PutClientInServer
584
585 Called when a client spawns in the server
586 =============
587 */
588
589 void PutClientInServer (void)
590 {
591         if(IS_BOT_CLIENT(self))
592                 self.classname = "player";
593         else if(IS_REAL_CLIENT(self))
594         {
595                 msg_entity = self;
596                 WriteByte(MSG_ONE, SVC_SETVIEW);
597                 WriteEntity(MSG_ONE, self);
598         }
599
600         // reset player keys
601         self.itemkeys = 0;
602
603         MUTATOR_CALLHOOK(PutClientInServer);
604
605         if(gameover)
606                 self.classname = "observer";
607
608         if(IS_PLAYER(self))
609         {
610                 entity spot, oldself;
611                 float j;
612
613                 accuracy_resend(self);
614
615                 if(self.team < 0)
616                         JoinBestTeam(self, FALSE, TRUE);
617
618                 race_PreSpawn();
619
620                 spot = SelectSpawnPoint (FALSE);
621                 if(!spot)
622                 {
623                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
624                         return; // spawn failed
625                 }
626
627                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
628
629                 self.classname = "player";
630                 self.wasplayer = TRUE;
631                 self.iscreature = TRUE;
632                 self.teleportable = TELEPORT_NORMAL;
633                 self.damagedbycontents = TRUE;
634                 self.movetype = MOVETYPE_WALK;
635                 self.solid = SOLID_SLIDEBOX;
636                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
637                 if(autocvar_g_playerclip_collisions)
638                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
639                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
640                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
641                 self.frags = FRAGS_PLAYER;
642                 if(INDEPENDENT_PLAYERS)
643                         MAKE_INDEPENDENT_PLAYER(self);
644                 self.flags = FL_CLIENT;
645                 if(autocvar__notarget)
646                         self.flags |= FL_NOTARGET;
647                 self.takedamage = DAMAGE_AIM;
648                 self.effects = 0;
649                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
650                 self.air_finished = time + 12;
651                 self.dmg = 2;
652                 if(autocvar_g_balance_nex_charge)
653                 {
654                         if(autocvar_g_balance_nex_secondary_chargepool)
655                                 self.nex_chargepool_ammo = 1;
656                         self.nex_charge = autocvar_g_balance_nex_charge_start;
657                 }
658
659                 if(inWarmupStage)
660                 {
661                         self.ammo_shells = warmup_start_ammo_shells;
662                         self.ammo_nails = warmup_start_ammo_nails;
663                         self.ammo_rockets = warmup_start_ammo_rockets;
664                         self.ammo_cells = warmup_start_ammo_cells;
665                         self.ammo_fuel = warmup_start_ammo_fuel;
666                         self.health = warmup_start_health;
667                         self.armorvalue = warmup_start_armorvalue;
668                         WEPSET_COPY_EA(self, warmup_start_weapons);
669                 }
670                 else
671                 {
672                         self.ammo_shells = start_ammo_shells;
673                         self.ammo_nails = start_ammo_nails;
674                         self.ammo_rockets = start_ammo_rockets;
675                         self.ammo_cells = start_ammo_cells;
676                         self.ammo_fuel = start_ammo_fuel;
677                         self.health = start_health;
678                         self.armorvalue = start_armorvalue;
679                         WEPSET_COPY_EA(self, start_weapons);
680                 }
681
682                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
683                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
684                 else
685                         self.superweapons_finished = 0;
686
687                 if(g_weaponarena_random)
688                 {
689                         if(g_weaponarena_random_with_laser)
690                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
691                         W_RandomWeapons(self, g_weaponarena_random);
692                         if(g_weaponarena_random_with_laser)
693                                 WEPSET_OR_EW(self, WEP_LASER);
694                 }
695
696                 self.items = start_items;
697
698                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
699                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
700                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
701                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
702                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
703                 //extend the pause of rotting if client was reset at the beginning of the countdown
704                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
705                         self.spawnshieldtime += game_starttime - time;
706                         self.pauserotarmor_finished += game_starttime - time;
707                         self.pauserothealth_finished += game_starttime - time;
708                         self.pauseregen_finished += game_starttime - time;
709                 }
710                 self.damageforcescale = 2;
711                 self.death_time = 0;
712                 self.respawn_flags = 0;
713                 self.respawn_time = 0;
714                 self.stat_respawn_time = 0;
715                 self.scale = 0;
716                 self.fade_time = 0;
717                 self.pain_frame = 0;
718                 self.pain_finished = 0;
719                 self.strength_finished = 0;
720                 self.invincible_finished = 0;
721                 self.pushltime = 0;
722                 // players have no think function
723                 self.think = func_null;
724                 self.nextthink = 0;
725                 self.hook_time = 0;
726                 self.dmg_team = 0;
727                 self.ballistics_density = autocvar_g_ballistics_density_player;
728
729                 self.metertime = 0;
730
731                 self.deadflag = DEAD_NO;
732
733                 self.angles = spot.angles;
734
735                 self.angles_z = 0; // never spawn tilted even if the spot says to
736                 self.fixangle = TRUE; // turn this way immediately
737                 self.velocity = '0 0 0';
738                 self.avelocity = '0 0 0';
739                 self.punchangle = '0 0 0';
740                 self.punchvector = '0 0 0';
741                 self.oldvelocity = self.velocity;
742                 self.fire_endtime = -1;
743
744                 msg_entity = self;
745                 WRITESPECTATABLE_MSG_ONE({
746                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
747                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
748                 });
749
750                 self.model = "";
751                 FixPlayermodel();
752                 self.drawonlytoclient = world;
753
754                 self.crouch = FALSE;
755                 self.view_ofs = PL_VIEW_OFS;
756                 setsize (self, PL_MIN, PL_MAX);
757                 self.spawnorigin = spot.origin;
758                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
759                 // don't reset back to last position, even if new position is stuck in solid
760                 self.oldorigin = self.origin;
761                 self.prevorigin = self.origin;
762                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
763                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
764         self.hud = HUD_NORMAL;
765
766                 self.event_damage = PlayerDamage;
767
768                 self.bot_attack = TRUE;
769
770                 self.statdraintime = time + 5;
771                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
772
773                 if(self.killcount == -666) {
774                         PlayerScore_Clear(self);
775                         self.killcount = 0;
776                 }
777
778                 CL_SpawnWeaponentity();
779                 self.alpha = default_player_alpha;
780                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
781                 self.exteriorweaponentity.alpha = default_weapon_alpha;
782
783                 self.speedrunning = FALSE;
784
785                 race_PostSpawn(spot);
786
787                 //stuffcmd(self, "chase_active 0");
788                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
789                 
790                 target_voicescript_clear(self);
791
792                 // reset fields the weapons may use
793                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
794                 {
795                         weapon_action(j, WR_RESETPLAYER);
796
797                         // all weapons must be fully loaded when we spawn
798                         entity e;
799                         e = get_weaponinfo(j);
800                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
801                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
802                 }
803
804                 oldself = self;
805                 self = spot;
806                         activator = oldself;
807                                 string s;
808                                 s = self.target;
809                                 self.target = string_null;
810                                 SUB_UseTargets();
811                                 self.target = s;
812                         activator = world;
813                 self = oldself;
814
815                 spawn_spot = spot;
816                 MUTATOR_CALLHOOK(PlayerSpawn);
817
818                 if(autocvar_spawn_debug)
819                 {
820                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
821                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
822                 }
823
824                 self.switchweapon = w_getbestweapon(self);
825                 self.cnt = -1; // W_LastWeapon will not complain
826                 self.weapon = 0;
827                 self.weaponname = "";
828                 self.switchingweapon = 0;
829
830                 if(!inWarmupStage)
831                         if(!self.alivetime)
832                                 self.alivetime = time;
833
834                 antilag_clear(self);
835
836                 if (autocvar_g_spawnsound)
837                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
838         } else if(IS_OBSERVER(self)) {
839                 PutObserverInServer ();
840         }
841 }
842
843 .float ebouncefactor, ebouncestop; // electro's values
844 // TODO do we need all these fields, or should we stop autodetecting runtime
845 // changes and just have a console command to update this?
846 float ClientInit_SendEntity(entity to, float sf)
847 {
848         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
849         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
850         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
851         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
852         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
853         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
854         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
855         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
856         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
857         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
858         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
859         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
860         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
861         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
862         if(sv_foginterval && world.fog != "")
863                 WriteString(MSG_ENTITY, world.fog);
864         else
865                 WriteString(MSG_ENTITY, "");
866         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
867         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
868         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
869         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
870         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
871         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
872         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
873         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
874         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
875         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
876         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
877         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
878         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
879         return TRUE;
880 }
881
882 void ClientInit_CheckUpdate()
883 {
884         self.nextthink = time;
885         if(self.count != autocvar_g_balance_armor_blockpercent)
886         {
887                 self.count = autocvar_g_balance_armor_blockpercent;
888                 self.SendFlags |= 1;
889         }
890         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
891         {
892                 self.cnt = autocvar_g_balance_weaponswitchdelay;
893                 self.SendFlags |= 1;
894         }
895         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
896         {
897                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
898                 self.SendFlags |= 1;
899         }
900         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
901         {
902                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
903                 self.SendFlags |= 1;
904         }
905         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
906         {
907                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
908                 self.SendFlags |= 1;
909         }
910         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
911         {
912                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
913                 self.SendFlags |= 1;
914         }
915 }
916
917 void ClientInit_Spawn()
918 {
919         entity o;
920         entity e;
921         e = spawn();
922         e.classname = "clientinit";
923         e.think = ClientInit_CheckUpdate;
924         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
925
926         o = self;
927         self = e;
928         ClientInit_CheckUpdate();
929         self = o;
930 }
931
932 /*
933 =============
934 SetNewParms
935 =============
936 */
937 void SetNewParms (void)
938 {
939         // initialize parms for a new player
940         parm1 = -(86400 * 366);
941 }
942
943 /*
944 =============
945 SetChangeParms
946 =============
947 */
948 void SetChangeParms (void)
949 {
950         // save parms for level change
951         parm1 = self.parm_idlesince - time;
952 }
953
954 /*
955 =============
956 DecodeLevelParms
957 =============
958 */
959 void DecodeLevelParms (void)
960 {
961         // load parms
962         self.parm_idlesince = parm1;
963         if(self.parm_idlesince == -(86400 * 366))
964                 self.parm_idlesince = time;
965
966         // whatever happens, allow 60 seconds of idling directly after connect for map loading
967         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
968 }
969
970 /*
971 =============
972 ClientKill
973
974 Called when a client types 'kill' in the console
975 =============
976 */
977
978 .float clientkill_nexttime;
979 void ClientKill_Now_TeamChange()
980 {
981         if(self.killindicator_teamchange == -1)
982         {
983                 JoinBestTeam( self, FALSE, TRUE );
984         }
985         else if(self.killindicator_teamchange == -2)
986         {
987                 if(blockSpectators)
988                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
989                 PutObserverInServer();
990         }
991         else
992                 SV_ChangeTeam(self.killindicator_teamchange - 1);
993         self.killindicator_teamchange = 0;
994 }
995
996 void ClientKill_Now()
997 {
998         if(self.vehicle)
999         {
1000             vehicles_exit(VHEF_RELESE);
1001             if(!self.killindicator_teamchange)
1002             {
1003             self.vehicle_health = -1;
1004             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');             
1005             }
1006         }
1007
1008         if(self.killindicator && !wasfreed(self.killindicator))
1009                 remove(self.killindicator);
1010
1011         self.killindicator = world;
1012
1013         if(self.killindicator_teamchange)
1014                 ClientKill_Now_TeamChange();
1015
1016         // in any case:
1017         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1018
1019         // now I am sure the player IS dead
1020 }
1021 void KillIndicator_Think()
1022 {
1023         if (gameover)
1024         {
1025                 self.owner.killindicator = world;
1026                 remove(self);
1027                 return;
1028         }
1029
1030         if (self.owner.alpha < 0 && !self.owner.vehicle)
1031         {
1032                 self.owner.killindicator = world;
1033                 remove(self);
1034                 return;
1035         }
1036
1037         if(self.cnt <= 0)
1038         {
1039                 self = self.owner;
1040                 ClientKill_Now(); // no oldself needed
1041                 return;
1042         }
1043     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1044     {
1045         self.nextthink = time + 1;
1046         self.cnt -= 1;
1047     }
1048         else
1049         {
1050                 if(self.cnt <= 10)
1051                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1052                 if(IS_REAL_CLIENT(self.owner))
1053                 {
1054                         if(self.cnt <= 10)
1055                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1056                 }
1057                 self.nextthink = time + 1;
1058                 self.cnt -= 1;
1059         }
1060 }
1061
1062 float clientkilltime;
1063 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1064 {
1065         float killtime;
1066         float starttime;
1067         entity e;
1068
1069         if (gameover)
1070                 return;
1071
1072         killtime = autocvar_g_balance_kill_delay;
1073
1074         if(g_race_qualifying || g_cts)
1075                 killtime = 0;
1076
1077     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1078     {
1079                 remove(self.killindicator);
1080                 self.killindicator = world;
1081
1082         ClientKill_Now(); // allow instant kill in this case
1083         return;
1084     }
1085
1086         self.killindicator_teamchange = targetteam;
1087
1088     if(!self.killindicator)
1089         {
1090                 if(self.deadflag == DEAD_NO)
1091                 {
1092                         killtime = max(killtime, self.clientkill_nexttime - time);
1093                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1094                 }
1095
1096                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
1097                 {
1098                         ClientKill_Now();
1099                 }
1100                 else
1101                 {
1102                         starttime = max(time, clientkilltime);
1103
1104                         self.killindicator = spawn();
1105                         self.killindicator.owner = self;
1106                         self.killindicator.scale = 0.5;
1107                         setattachment(self.killindicator, self, "");
1108                         setorigin(self.killindicator, '0 0 52');
1109                         self.killindicator.think = KillIndicator_Think;
1110                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1111                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1112                         self.killindicator.cnt = ceil(killtime);
1113                         self.killindicator.count = bound(0, ceil(killtime), 10);
1114                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1115
1116                         for(e = world; (e = find(e, classname, "body")) != world; )
1117                         {
1118                                 if(e.enemy != self)
1119                                         continue;
1120                                 e.killindicator = spawn();
1121                                 e.killindicator.owner = e;
1122                                 e.killindicator.scale = 0.5;
1123                                 setattachment(e.killindicator, e, "");
1124                                 setorigin(e.killindicator, '0 0 52');
1125                                 e.killindicator.think = KillIndicator_Think;
1126                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1127                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1128                                 e.killindicator.cnt = ceil(killtime);
1129                         }
1130                         self.lip = 0;
1131                 }
1132         }
1133         if(self.killindicator)
1134         {
1135                 if(targetteam == 0) // just die
1136                 {
1137                         self.killindicator.colormod = '0 0 0';
1138                         if(IS_REAL_CLIENT(self))
1139                         if(self.killindicator.cnt > 0)
1140                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1141                 }
1142                 else if(targetteam == -1) // auto
1143                 {
1144                         self.killindicator.colormod = '0 1 0';
1145                         if(IS_REAL_CLIENT(self))
1146                         if(self.killindicator.cnt > 0)
1147                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1148                 }
1149                 else if(targetteam == -2) // spectate
1150                 {
1151                         self.killindicator.colormod = '0.5 0.5 0.5';
1152                         if(IS_REAL_CLIENT(self))
1153                         if(self.killindicator.cnt > 0)
1154                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1155                 }
1156                 else
1157                 {
1158                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1159                         if(IS_REAL_CLIENT(self))
1160                         if(self.killindicator.cnt > 0)
1161                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1162                 }
1163         }
1164
1165 }
1166
1167 void ClientKill (void)
1168 {
1169         if(gameover) return;
1170         if(self.player_blocked) return;
1171         if(self.freezetag_frozen) return;
1172         
1173         ClientKill_TeamChange(0);
1174 }
1175
1176 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1177 {
1178     e.killindicator = spawn();
1179     e.killindicator.owner = e;
1180     e.killindicator.think = KillIndicator_Think;
1181     e.killindicator.nextthink = time + (e.lip) * 0.05;
1182     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1183     e.killindicator.health = 1; // this is used to indicate that it should be silent
1184     e.lip = 0;
1185 }
1186
1187 void FixClientCvars(entity e)
1188 {
1189         // send prediction settings to the client
1190         stuffcmd(e, "\nin_bindmap 0 0\n");
1191         if(g_race || g_cts)
1192                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1193         if(autocvar_g_antilag == 3) // client side hitscan
1194                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1195         if(autocvar_sv_gentle)
1196                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1197         /*
1198          * we no longer need to stuff this. Remove this comment block if you feel
1199          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1200         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1201         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1202         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1203         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1204         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1205         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1206         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1207         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1208         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1209         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1210         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1211         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1212         stuffcmd(e, "cl_movement_edgefriction 1\n");
1213          */
1214 }
1215
1216 float PlayerInIDList(entity p, string idlist)
1217 {
1218         float n, i;
1219         string s;
1220
1221         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1222         if not(p.crypto_idfp)
1223                 return 0;
1224
1225         // this function allows abbreviated player IDs too!
1226         n = tokenize_console(idlist);
1227         for(i = 0; i < n; ++i)
1228         {
1229                 s = argv(i);
1230                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1231                         return 1;
1232         }
1233
1234         return 0;
1235 }
1236
1237 /*
1238 =============
1239 ClientConnect
1240
1241 Called when a client connects to the server
1242 =============
1243 */
1244 void DecodeLevelParms (void);
1245 //void dom_player_join_team(entity pl);
1246 void set_dom_state(entity e);
1247 void ClientConnect (void)
1248 {
1249         float t;
1250
1251         if(IS_CLIENT(self))
1252         {
1253                 print("Warning: ClientConnect, but already connected!\n");
1254                 return;
1255         }
1256
1257         if(Ban_MaybeEnforceBanOnce(self))
1258                 return;
1259
1260         DecodeLevelParms();
1261
1262 #ifdef WATERMARK
1263         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1264 #endif
1265
1266         self.classname = "player_joining";
1267
1268         self.flags = FL_CLIENT;
1269         self.version_nagtime = time + 10 + random() * 10;
1270
1271         if(player_count<0)
1272         {
1273                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1274                 player_count = 0;
1275         }
1276
1277         PlayerScore_Attach(self);
1278         ClientData_Attach();
1279         accuracy_init(self);
1280
1281         bot_clientconnect();
1282
1283         playerdemo_init();
1284
1285         anticheat_init();
1286
1287         race_PreSpawnObserver();
1288
1289         // identify the right forced team
1290         if(autocvar_g_campaign)
1291         {
1292                 if(IS_REAL_CLIENT(self)) // only players, not bots
1293                 {
1294                         switch(autocvar_g_campaign_forceteam)
1295                         {
1296                                 case 1: self.team_forced = NUM_TEAM_1; break;
1297                                 case 2: self.team_forced = NUM_TEAM_2; break;
1298                                 case 3: self.team_forced = NUM_TEAM_3; break;
1299                                 case 4: self.team_forced = NUM_TEAM_4; break;
1300                                 default: self.team_forced = 0;
1301                         }
1302                 }
1303         }
1304         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1305                 self.team_forced = NUM_TEAM_1;
1306         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1307                 self.team_forced = NUM_TEAM_2;
1308         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1309                 self.team_forced = NUM_TEAM_3;
1310         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1311                 self.team_forced = NUM_TEAM_4;
1312         else if(autocvar_g_forced_team_otherwise == "red")
1313                 self.team_forced = NUM_TEAM_1;
1314         else if(autocvar_g_forced_team_otherwise == "blue")
1315                 self.team_forced = NUM_TEAM_2;
1316         else if(autocvar_g_forced_team_otherwise == "yellow")
1317                 self.team_forced = NUM_TEAM_3;
1318         else if(autocvar_g_forced_team_otherwise == "pink")
1319                 self.team_forced = NUM_TEAM_4;
1320         else if(autocvar_g_forced_team_otherwise == "spectate")
1321                 self.team_forced = -1;
1322         else if(autocvar_g_forced_team_otherwise == "spectator")
1323                 self.team_forced = -1;
1324         else
1325                 self.team_forced = 0;
1326
1327         if(!teamplay)
1328                 if(self.team_forced > 0)
1329                         self.team_forced = 0;
1330
1331         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1332
1333         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1334                 self.classname = "observer";
1335         } else {
1336                 if(teamplay)
1337                 {
1338                         if(autocvar_g_balance_teams)
1339                         {
1340                                 self.classname = "player";
1341                                 campaign_bots_may_start = 1;
1342                         }
1343                         else
1344                         {
1345                                 self.classname = "observer"; // do it anyway
1346                         }
1347                 }
1348                 else
1349                 {
1350                         self.classname = "player";
1351                         campaign_bots_may_start = 1;
1352                 }
1353         }
1354
1355         self.playerid = (playerid_last = playerid_last + 1);
1356
1357         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1358
1359     if(IS_BOT_CLIENT(self))
1360         PlayerStats_AddPlayer(self);
1361
1362         if(autocvar_sv_eventlog)
1363                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1364
1365         LogTeamchange(self.playerid, self.team, 1);
1366
1367         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1368
1369         self.netname_previous = strzone(self.netname);
1370
1371         if(IS_PLAYER(self) && teamplay)
1372                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1373         else
1374                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1375
1376         stuffcmd(self, strcat(clientstuff, "\n"));
1377         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1378
1379         FixClientCvars(self);
1380
1381         // spawnfunc_waypoint sprites
1382         WaypointSprite_InitClient(self);
1383
1384         // Wazat's grappling hook
1385         SetGrappleHookBindings();
1386
1387         // get version info from player
1388         stuffcmd(self, "cmd clientversion $gameversion\n");
1389
1390         // get other cvars from player
1391         GetCvars(0);
1392
1393         // notify about available teams
1394         if(teamplay)
1395         {
1396                 CheckAllowedTeams(self);
1397                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1398                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1399         }
1400         else
1401                 stuffcmd(self, "set _teams_available 0\n");
1402
1403         attach_entcs();
1404
1405         bot_relinkplayerlist();
1406
1407         self.spectatortime = time;
1408         if(blockSpectators)
1409         {
1410                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1411         }
1412
1413         self.jointime = time;
1414         self.allowed_timeouts = autocvar_sv_timeout_number;
1415
1416         if(IS_REAL_CLIENT(self))
1417         {
1418                 if(!autocvar_g_campaign)
1419                 {
1420                         self.motd_actived_time = -1;
1421                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1422                 }
1423
1424                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1425                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1426         }
1427
1428         if(!sv_foginterval && world.fog != "")
1429                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1430
1431         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1432         {
1433                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1434                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1435         }
1436         else
1437                 self.hitplotfh = -1;
1438
1439         if(g_race || g_cts) {
1440                 string rr;
1441                 if(g_cts)
1442                         rr = CTS_RECORD;
1443                 else
1444                         rr = RACE_RECORD;
1445
1446                 msg_entity = self;
1447                 race_send_recordtime(MSG_ONE);
1448                 race_send_speedaward(MSG_ONE);
1449
1450                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1451                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1452                 race_send_speedaward_alltimebest(MSG_ONE);
1453
1454                 float i;
1455                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1456                         race_SendRankings(i, 0, 0, MSG_ONE);
1457                 }
1458         }
1459         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1460                 send_CSQC_teamnagger();
1461
1462         CheatInitClient();
1463
1464         CSQCMODEL_AUTOINIT();
1465
1466         self.model_randomizer = random();
1467
1468         if(IS_REAL_CLIENT(self))
1469                 sv_notice_join();
1470
1471         MUTATOR_CALLHOOK(ClientConnect);
1472 }
1473 /*
1474 =============
1475 ClientDisconnect
1476
1477 Called when a client disconnects from the server
1478 =============
1479 */
1480 .entity chatbubbleentity;
1481 void ReadyCount();
1482 void ClientDisconnect (void)
1483 {
1484         if(self.vehicle)
1485             vehicles_exit(VHEF_RELESE);
1486
1487         if not(IS_CLIENT(self))
1488         {
1489                 print("Warning: ClientDisconnect without ClientConnect\n");
1490                 return;
1491         }
1492
1493         PlayerStats_AddGlobalInfo(self);
1494
1495         CheatShutdownClient();
1496
1497         if(self.hitplotfh >= 0)
1498         {
1499                 fclose(self.hitplotfh);
1500                 self.hitplotfh = -1;
1501         }
1502
1503         anticheat_report();
1504         anticheat_shutdown();
1505
1506         playerdemo_shutdown();
1507
1508         bot_clientdisconnect();
1509
1510         if(self.entcs)
1511                 detach_entcs();
1512
1513         if(autocvar_sv_eventlog)
1514                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1515                 
1516         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1517
1518         MUTATOR_CALLHOOK(ClientDisconnect);
1519
1520         Portal_ClearAll(self);
1521
1522         RemoveGrapplingHook(self);
1523
1524         // Here, everything has been done that requires this player to be a client.
1525
1526         self.flags &~= FL_CLIENT;
1527
1528         if (self.chatbubbleentity)
1529                 remove (self.chatbubbleentity);
1530
1531         if (self.killindicator)
1532                 remove (self.killindicator);
1533
1534         WaypointSprite_PlayerGone();
1535
1536         bot_relinkplayerlist();
1537
1538         accuracy_free(self);
1539         ClientData_Detach();
1540         PlayerScore_Detach(self);
1541
1542         if(self.netname_previous)
1543                 strunzone(self.netname_previous);
1544         if(self.clientstatus)
1545                 strunzone(self.clientstatus);
1546         if(self.weaponorder_byimpulse)
1547                 strunzone(self.weaponorder_byimpulse);
1548
1549         ClearPlayerSounds();
1550
1551         if(self.personal)
1552                 remove(self.personal);
1553
1554         self.playerid = 0;
1555         ReadyCount();
1556
1557         // free cvars
1558         GetCvars(-1);
1559 }
1560
1561 .float BUTTON_CHAT;
1562 void ChatBubbleThink()
1563 {
1564         self.nextthink = time;
1565         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1566         {
1567                 if(self.owner) // but why can that ever be world?
1568                         self.owner.chatbubbleentity = world;
1569                 remove(self);
1570                 return;
1571         }
1572         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1573 #ifdef TETRIS
1574                 || self.owner.tetris_on
1575 #endif
1576         )
1577                 self.model = self.mdl;
1578         else
1579                 self.model = "";
1580 }
1581
1582 void UpdateChatBubble()
1583 {
1584         if (self.alpha < 0)
1585                 return;
1586         // spawn a chatbubble entity if needed
1587         if (!self.chatbubbleentity)
1588         {
1589                 self.chatbubbleentity = spawn();
1590                 self.chatbubbleentity.owner = self;
1591                 self.chatbubbleentity.exteriormodeltoclient = self;
1592                 self.chatbubbleentity.think = ChatBubbleThink;
1593                 self.chatbubbleentity.nextthink = time;
1594                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1595                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1596                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1597                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1598                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1599                 self.chatbubbleentity.model = "";
1600                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1601         }
1602 }
1603
1604
1605 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1606 // added to the model skins
1607 /*void UpdateColorModHack()
1608 {
1609         float c;
1610         c = self.clientcolors & 15;
1611         // LordHavoc: only bothering to support white, green, red, yellow, blue
1612              if (!teamplay) self.colormod = '0 0 0';
1613         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1614         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1615         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1616         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1617         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1618         else self.colormod = '1 1 1';
1619 }*/
1620
1621 void respawn(void)
1622 {
1623         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1624         {
1625                 self.solid = SOLID_NOT;
1626                 self.takedamage = DAMAGE_NO;
1627                 self.movetype = MOVETYPE_FLY;
1628                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1629                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1630                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1631                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1632                 if(autocvar_g_respawn_ghosts_maxtime)
1633                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1634         }
1635
1636         CopyBody(1);
1637
1638         self.effects |= EF_NODRAW; // prevent another CopyBody
1639         PutClientInServer();
1640 }
1641
1642 void play_countdown(float finished, string samp)
1643 {
1644         if(IS_REAL_CLIENT(self))
1645                 if(floor(finished - time - frametime) != floor(finished - time))
1646                         if(finished - time < 6)
1647                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1648 }
1649
1650 void player_powerups (void)
1651 {
1652         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1653         olditems = self.items;
1654
1655         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1656                 self.modelflags |= MF_ROCKET;
1657         else
1658                 self.modelflags &~= MF_ROCKET;
1659
1660         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1661
1662         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1663                 return;
1664
1665         Fire_ApplyDamage(self);
1666         Fire_ApplyEffect(self);
1667
1668         if not(g_minstagib)
1669         {
1670                 if (self.items & IT_STRENGTH)
1671                 {
1672                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1673                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1674                         if (time > self.strength_finished)
1675                         {
1676                                 self.items = self.items - (self.items & IT_STRENGTH);
1677                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1678                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1679                         }
1680                 }
1681                 else
1682                 {
1683                         if (time < self.strength_finished)
1684                         {
1685                                 self.items = self.items | IT_STRENGTH;
1686                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1687                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1688                         }
1689                 }
1690                 if (self.items & IT_INVINCIBLE)
1691                 {
1692                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1693                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1694                         if (time > self.invincible_finished)
1695                         {
1696                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1697                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1698                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1699                         }
1700                 }
1701                 else
1702                 {
1703                         if (time < self.invincible_finished)
1704                         {
1705                                 self.items = self.items | IT_INVINCIBLE;
1706                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1707                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1708                         }
1709                 }
1710                 if (self.items & IT_SUPERWEAPON)
1711                 {
1712                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1713                         {
1714                                 self.superweapons_finished = 0;
1715                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1716                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1717                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1718                         }
1719                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1720                         {
1721                                 // don't let them run out
1722                         }
1723                         else
1724                         {
1725                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1726                                 if (time > self.superweapons_finished)
1727                                 {
1728                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1729                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1730                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1731                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1732                                 }
1733                         }
1734                 }
1735                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1736                 {
1737                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1738                         {
1739                                 self.items = self.items | IT_SUPERWEAPON;
1740                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1741                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1742                         }
1743                         else
1744                         {
1745                                 self.superweapons_finished = 0;
1746                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1747                         }
1748                 }
1749                 else
1750                 {
1751                         self.superweapons_finished = 0;
1752                 }
1753         }
1754         
1755         if(autocvar_g_nodepthtestplayers)
1756                 self.effects = self.effects | EF_NODEPTHTEST;
1757
1758         if(autocvar_g_fullbrightplayers)
1759                 self.effects = self.effects | EF_FULLBRIGHT;
1760
1761         // midair gamemode: damage only while in the air
1762         // if in midair mode, being on ground grants temporary invulnerability
1763         // (this is so that multishot weapon don't clear the ground flag on the
1764         // first damage in the frame, leaving the player vulnerable to the
1765         // remaining hits in the same frame)
1766         if (self.flags & FL_ONGROUND)
1767         if (g_midair)
1768                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1769
1770         if (time >= game_starttime)
1771         if (time < self.spawnshieldtime)
1772                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1773
1774         MUTATOR_CALLHOOK(PlayerPowerups);
1775 }
1776
1777 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1778 {
1779         if(current > stable)
1780                 return current;
1781         else if(current > stable - 0.25) // when close enough, "snap"
1782                 return stable;
1783         else
1784                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1785 }
1786
1787 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1788 {
1789         if(current < stable)
1790                 return current;
1791         else if(current < stable + 0.25) // when close enough, "snap"
1792                 return stable;
1793         else
1794                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1795 }
1796
1797 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1798 {
1799         if(current > rotstable)
1800         {
1801                 if(rotframetime > 0)
1802                 {
1803                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1804                         current = max(rotstable, current - rotlinear * rotframetime);
1805                 }
1806         }
1807         else if(current < regenstable)
1808         {
1809                 if(regenframetime > 0)
1810                 {
1811                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1812                         current = min(regenstable, current + regenlinear * regenframetime);
1813                 }
1814         }
1815
1816         if(current > limit)
1817                 current = limit;
1818
1819         return current;
1820 }
1821
1822 void player_regen (void)
1823 {
1824         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1825         maxh = autocvar_g_balance_health_rotstable;
1826         maxa = autocvar_g_balance_armor_rotstable;
1827         maxf = autocvar_g_balance_fuel_rotstable;
1828         minh = autocvar_g_balance_health_regenstable;
1829         mina = autocvar_g_balance_armor_regenstable;
1830         minf = autocvar_g_balance_fuel_regenstable;
1831         limith = autocvar_g_balance_health_limit;
1832         limita = autocvar_g_balance_armor_limit;
1833         limitf = autocvar_g_balance_fuel_limit;
1834
1835         max_mod = regen_mod = rot_mod = limit_mod = 1;
1836
1837         maxh = maxh * max_mod;
1838         //maxa = maxa * max_mod;
1839         //maxf = maxf * max_mod;
1840         minh = minh * max_mod;
1841         //mina = mina * max_mod;
1842         //minf = minf * max_mod;
1843         limith = limith * limit_mod;
1844         limita = limita * limit_mod;
1845         //limitf = limitf * limit_mod;
1846
1847         if(g_ca)
1848                 rot_mod = 0;
1849
1850         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1851         {
1852                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1853                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1854
1855                 // if player rotted to death...  die!
1856                 if(self.health < 1)
1857                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1858         }
1859
1860         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1861                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1862 }
1863
1864 float zoomstate_set;
1865 void SetZoomState(float z)
1866 {
1867         if(z != self.zoomstate)
1868         {
1869                 self.zoomstate = z;
1870                 ClientData_Touch(self);
1871         }
1872         zoomstate_set = 1;
1873 }
1874
1875 void GetPressedKeys(void) {
1876         MUTATOR_CALLHOOK(GetPressedKeys);
1877         if (self.movement_x > 0) // get if movement keys are pressed
1878         {       // forward key pressed
1879                 self.pressedkeys |= KEY_FORWARD;
1880                 self.pressedkeys &~= KEY_BACKWARD;
1881         }
1882         else if (self.movement_x < 0)
1883         {       // backward key pressed
1884                 self.pressedkeys |= KEY_BACKWARD;
1885                 self.pressedkeys &~= KEY_FORWARD;
1886         }
1887         else
1888         {       // no x input
1889                 self.pressedkeys &~= KEY_FORWARD;
1890                 self.pressedkeys &~= KEY_BACKWARD;
1891         }
1892
1893         if (self.movement_y > 0)
1894         {       // right key pressed
1895                 self.pressedkeys |= KEY_RIGHT;
1896                 self.pressedkeys &~= KEY_LEFT;
1897         }
1898         else if (self.movement_y < 0)
1899         {       // left key pressed
1900                 self.pressedkeys |= KEY_LEFT;
1901                 self.pressedkeys &~= KEY_RIGHT;
1902         }
1903         else
1904         {       // no y input
1905                 self.pressedkeys &~= KEY_RIGHT;
1906                 self.pressedkeys &~= KEY_LEFT;
1907         }
1908
1909         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1910                 self.pressedkeys |= KEY_JUMP;
1911         else
1912                 self.pressedkeys &~= KEY_JUMP;
1913         if (self.BUTTON_CROUCH)
1914                 self.pressedkeys |= KEY_CROUCH;
1915         else
1916                 self.pressedkeys &~= KEY_CROUCH;
1917
1918         if (self.BUTTON_ATCK)
1919                 self.pressedkeys |= KEY_ATCK;
1920         else
1921                 self.pressedkeys &~= KEY_ATCK;
1922         if (self.BUTTON_ATCK2)
1923                 self.pressedkeys |= KEY_ATCK2;
1924         else
1925                 self.pressedkeys &~= KEY_ATCK2;
1926 }
1927
1928 /*
1929 ======================
1930 spectate mode routines
1931 ======================
1932 */
1933
1934 void SpectateCopy(entity spectatee) {
1935         other = spectatee;
1936         MUTATOR_CALLHOOK(SpectateCopy);
1937         self.armortype = spectatee.armortype;
1938         self.armorvalue = spectatee.armorvalue;
1939         self.ammo_cells = spectatee.ammo_cells;
1940         self.ammo_shells = spectatee.ammo_shells;
1941         self.ammo_nails = spectatee.ammo_nails;
1942         self.ammo_rockets = spectatee.ammo_rockets;
1943         self.ammo_fuel = spectatee.ammo_fuel;
1944         self.clip_load = spectatee.clip_load;
1945         self.clip_size = spectatee.clip_size;
1946         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1947         self.health = spectatee.health;
1948         self.impulse = 0;
1949         self.items = spectatee.items;
1950         self.last_pickup = spectatee.last_pickup;
1951         self.hit_time = spectatee.hit_time;
1952         self.metertime = spectatee.metertime;
1953         self.strength_finished = spectatee.strength_finished;
1954         self.invincible_finished = spectatee.invincible_finished;
1955         self.pressedkeys = spectatee.pressedkeys;
1956         WEPSET_COPY_EE(self, spectatee);
1957         self.switchweapon = spectatee.switchweapon;
1958         self.switchingweapon = spectatee.switchingweapon;
1959         self.weapon = spectatee.weapon;
1960         self.nex_charge = spectatee.nex_charge;
1961         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1962         self.hagar_load = spectatee.hagar_load;
1963         self.minelayer_mines = spectatee.minelayer_mines;
1964         self.punchangle = spectatee.punchangle;
1965         self.view_ofs = spectatee.view_ofs;
1966         self.velocity = spectatee.velocity;
1967         self.dmg_take = spectatee.dmg_take;
1968         self.dmg_save = spectatee.dmg_save;
1969         self.dmg_inflictor = spectatee.dmg_inflictor;
1970         self.v_angle = spectatee.v_angle;
1971         self.angles = spectatee.v_angle;
1972         if(!self.BUTTON_USE)
1973                 self.fixangle = TRUE;
1974         setorigin(self, spectatee.origin);
1975         setsize(self, spectatee.mins, spectatee.maxs);
1976         SetZoomState(spectatee.zoomstate);
1977     
1978     anticheat_spectatecopy(spectatee);
1979         self.hud = spectatee.hud;
1980         if(spectatee.vehicle)
1981     {
1982         self.fixangle = FALSE;
1983         //self.velocity = spectatee.vehicle.velocity;
1984         self.vehicle_health = spectatee.vehicle_health;
1985         self.vehicle_shield = spectatee.vehicle_shield;
1986         self.vehicle_energy = spectatee.vehicle_energy;
1987         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1988         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1989         self.vehicle_reload1 = spectatee.vehicle_reload1;
1990         self.vehicle_reload2 = spectatee.vehicle_reload2;
1991
1992         msg_entity = self;
1993         
1994         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1995             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1996             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1997             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1998
1999         //WriteByte (MSG_ONE, SVC_SETVIEW);
2000         //    WriteEntity(MSG_ONE, self);            
2001         //makevectors(spectatee.v_angle);
2002         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/    
2003     }
2004 }
2005
2006 float SpectateUpdate() {
2007         if(!self.enemy)
2008             return 0;           
2009
2010         if (self == self.enemy)
2011                 return 0;
2012
2013         if not(IS_PLAYER(self.enemy))
2014                 return 0;
2015
2016         SpectateCopy(self.enemy);
2017
2018         return 1;
2019 }
2020
2021
2022 float SpectateSet()
2023 {
2024         if(self.enemy.classname != "player")
2025                 return FALSE;
2026         /*if(self.enemy.vehicle)
2027         {
2028
2029                 msg_entity = self;
2030                 WriteByte(MSG_ONE, SVC_SETVIEW);
2031                 WriteEntity(MSG_ONE, self.enemy);
2032                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2033
2034                 self.movetype = MOVETYPE_NONE;
2035                 accuracy_resend(self);
2036         }
2037         else
2038         {*/
2039                 msg_entity = self;
2040                 WriteByte(MSG_ONE, SVC_SETVIEW);
2041                 WriteEntity(MSG_ONE, self.enemy);
2042                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2043                 self.movetype = MOVETYPE_NONE;
2044                 accuracy_resend(self);
2045
2046                 if(!SpectateUpdate())
2047                         PutObserverInServer();
2048         //}
2049         return TRUE;
2050 }
2051
2052 float Spectate(entity pl)
2053 {
2054         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2055         if(pl.team != self.team)
2056                 return 0;
2057
2058         self.enemy = pl;
2059         return SpectateSet();
2060 }
2061
2062 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2063 entity CA_SpectateNext(entity start) {
2064         if (start.team == self.team) {
2065                 return start;
2066         }
2067         
2068         other = start;
2069         // continue from current player
2070         while(other && other.team != self.team) {
2071                 other = find(other, classname, "player");
2072         }
2073         
2074         if (!other) {
2075                 // restart from begining
2076                 other = find(other, classname, "player");
2077                 while(other && other.team != self.team) {
2078                         other = find(other, classname, "player");
2079                 }
2080         }
2081         
2082         return other;
2083 }
2084
2085 float SpectateNext()
2086 {
2087         other = find(self.enemy, classname, "player");
2088
2089         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2090                 // CA and ca players when spectating enemies is forbidden
2091                 other = CA_SpectateNext(other);
2092         } else {
2093                 // other modes and ca spectators or spectating enemies is allowed
2094                 if (!other)
2095                         other = find(other, classname, "player");
2096         }
2097
2098         if (other)
2099                 self.enemy = other;
2100
2101         return SpectateSet();
2102 }
2103
2104 float SpectatePrev()
2105 {
2106         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2107         other = findchain(classname, "player");
2108         if not(other) // no player
2109                 return FALSE;
2110
2111         entity first = other;
2112         // skip players until current spectated player
2113         if(self.enemy)
2114         while(other && other != self.enemy)
2115                 other = other.chain;
2116
2117         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
2118         {
2119                 do { other = other.chain; }
2120                 while(other && other.team != self.team);
2121
2122                 if not(other)
2123                 {
2124                         other = first;
2125                         while(other.team != self.team)
2126                                 other = other.chain;
2127                         if(other == self.enemy)
2128                                 return TRUE;
2129                 }
2130         }
2131         else
2132         {
2133                 if(other.chain)
2134                         other = other.chain;
2135                 else
2136                         other = first;
2137         }
2138         self.enemy = other;
2139         return SpectateSet();
2140 }
2141
2142 /*
2143 =============
2144 ShowRespawnCountdown()
2145
2146 Update a respawn countdown display.
2147 =============
2148 */
2149 void ShowRespawnCountdown()
2150 {
2151         float number;
2152         if(self.deadflag == DEAD_NO) // just respawned?
2153                 return;
2154         else
2155         {
2156                 number = ceil(self.respawn_time - time);
2157                 if(number <= 0)
2158                         return;
2159                 if(number <= self.respawn_countdown)
2160                 {
2161                         self.respawn_countdown = number - 1;
2162                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2163                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number)); 
2164                 }
2165         }
2166 }
2167
2168 void LeaveSpectatorMode()
2169 {
2170         if(self.caplayer)
2171                 return;
2172         if(nJoinAllowed(self))
2173         {
2174                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2175                 {
2176                         self.classname = "player";
2177
2178                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2179                                 { JoinBestTeam(self, FALSE, TRUE); }
2180
2181                         if(autocvar_g_campaign)
2182                                 { campaign_bots_may_start = 1; }
2183
2184                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2185
2186                         PutClientInServer();
2187
2188                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2189                 }
2190                 else
2191                         stuffcmd(self, "menu_showteamselect\n");
2192         }
2193         else
2194         {
2195                 // Player may not join because g_maxplayers is set
2196                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2197         }
2198 }
2199
2200 /**
2201  * Determines whether the player is allowed to join. This depends on cvar
2202  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2203  * it checks whether the number of currently playing players exceeds g_maxplayers.
2204  * @return int number of free slots for players, 0 if none
2205  */
2206 float nJoinAllowed(entity ignore) {
2207         if(!ignore)
2208         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2209         // so report 0 free slots if restricted
2210         {
2211                 if(autocvar_g_forced_team_otherwise == "spectate")
2212                         return 0;
2213                 if(autocvar_g_forced_team_otherwise == "spectator")
2214                         return 0;
2215         }
2216
2217         if(self.team_forced < 0)
2218                 return 0; // forced spectators can never join
2219
2220         // TODO simplify this
2221         entity e;
2222         float totalClients = 0;
2223         FOR_EACH_CLIENT(e)
2224                 if(e != ignore)
2225                         totalClients += 1;
2226
2227         if (!autocvar_g_maxplayers)
2228                 return maxclients - totalClients;
2229
2230         float currentlyPlaying = 0;
2231         FOR_EACH_REALCLIENT(e)
2232                 if(IS_PLAYER(e) || e.caplayer == 1)
2233                         currentlyPlaying += 1;
2234
2235         if(currentlyPlaying < autocvar_g_maxplayers)
2236                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2237
2238         return 0;
2239 }
2240
2241 /**
2242  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2243  * g_maxplayers_spectator_blocktime seconds
2244  */
2245 void checkSpectatorBlock() {
2246         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2247                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2248                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2249                         dropclient(self);
2250                 }
2251         }
2252 }
2253
2254 void PrintWelcomeMessage()
2255 {
2256         if(self.motd_actived_time == 0)
2257         {
2258                 if (autocvar_g_campaign) {
2259                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2260                                 self.motd_actived_time = time;
2261                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2262                         }
2263                 } else {
2264                         if (self.BUTTON_INFO) {
2265                                 self.motd_actived_time = time;
2266                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2267                         }
2268                 }
2269         }
2270         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2271         {
2272                 if (autocvar_g_campaign) {
2273                         if (self.BUTTON_INFO)
2274                                 self.motd_actived_time = time;
2275                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2276                                 self.motd_actived_time = 0;
2277                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2278                         }
2279                 } else {
2280                         if (self.BUTTON_INFO)
2281                                 self.motd_actived_time = time;
2282                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2283                                 self.motd_actived_time = 0;
2284                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2285                         }
2286                 }
2287         }
2288         else //if(self.motd_actived_time < 0) // just connected, motd is active
2289         {
2290                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2291                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2292                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2293                 {
2294                         // instanctly hide MOTD
2295                         self.motd_actived_time = 0;
2296                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2297                 }
2298         }
2299 }
2300
2301 void ObserverThink()
2302 {
2303         float prefered_movetype;
2304         if (self.flags & FL_JUMPRELEASED) {
2305                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2306                         self.flags &~= FL_JUMPRELEASED;
2307                         self.flags |= FL_SPAWNING;
2308                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2309                         self.flags &~= FL_JUMPRELEASED;
2310                         if(SpectateNext()) {
2311                                 self.classname = "spectator";
2312                         }
2313                 } else {
2314                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2315                         if (self.movetype != prefered_movetype)
2316                                 self.movetype = prefered_movetype;
2317                 }
2318         } else {
2319                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2320                         self.flags |= FL_JUMPRELEASED;
2321                         if(self.flags & FL_SPAWNING)
2322                         {
2323                                 self.flags &~= FL_SPAWNING;
2324                                 LeaveSpectatorMode();
2325                                 return;
2326                         }
2327                 }
2328         }
2329 }
2330
2331 void SpectatorThink()
2332 {
2333         if (self.flags & FL_JUMPRELEASED) {
2334                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2335                         self.flags &~= FL_JUMPRELEASED;
2336                         self.flags |= FL_SPAWNING;
2337                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2338                         self.flags &~= FL_JUMPRELEASED;
2339                         if(SpectateNext()) {
2340                                 self.classname = "spectator";
2341                         } else {
2342                                 self.classname = "observer";
2343                                 PutClientInServer();
2344                         }
2345                         self.impulse = 0;
2346                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2347                         self.flags &~= FL_JUMPRELEASED;
2348                         if(SpectatePrev()) {
2349                                 self.classname = "spectator";
2350                         } else {
2351                                 self.classname = "observer";
2352                                 PutClientInServer();
2353                         }
2354                         self.impulse = 0;
2355                 } else if (self.BUTTON_ATCK2) {
2356                         self.flags &~= FL_JUMPRELEASED;
2357                         self.classname = "observer";
2358                         PutClientInServer();
2359                 } else {
2360                         if(!SpectateUpdate())
2361                                 PutObserverInServer();
2362                 }
2363         } else {
2364                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2365                         self.flags |= FL_JUMPRELEASED;
2366                         if(self.flags & FL_SPAWNING)
2367                         {
2368                                 self.flags &~= FL_SPAWNING;
2369                                 LeaveSpectatorMode();
2370                                 return;
2371                         }
2372                 }
2373                 if(!SpectateUpdate())
2374                         PutObserverInServer();
2375         }
2376
2377         self.flags |= FL_CLIENT | FL_NOTARGET;
2378 }
2379
2380 void PlayerUseKey()
2381 {
2382         if not(IS_PLAYER(self))
2383                 return;
2384
2385         if(self.vehicle)
2386         {
2387         vehicles_exit(VHEF_NORMAL);
2388         return;
2389         }
2390         
2391         // a use key was pressed; call handlers
2392         MUTATOR_CALLHOOK(PlayerUseKey);
2393 }
2394
2395 /*
2396 =============
2397 PlayerPreThink
2398
2399 Called every frame for each client before the physics are run
2400 =============
2401 */
2402 .float usekeypressed;
2403 void() nexball_setstatus;
2404 .float items_added;
2405 void PlayerPreThink (void)
2406 {
2407         WarpZone_PlayerPhysics_FixVAngle();
2408
2409         self.stat_game_starttime = game_starttime;
2410         self.stat_round_starttime = round_starttime;
2411         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2412         self.stat_leadlimit = autocvar_leadlimit;
2413
2414         if(frametime)
2415         {
2416                 // physics frames: update anticheat stuff
2417                 anticheat_prethink();
2418         }
2419
2420         if(blockSpectators && frametime)
2421                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2422                 checkSpectatorBlock();
2423
2424         zoomstate_set = 0;
2425
2426         if(self.netname_previous != self.netname)
2427         {
2428                 if(autocvar_sv_eventlog)
2429                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2430                 if(self.netname_previous)
2431                         strunzone(self.netname_previous);
2432                 self.netname_previous = strzone(self.netname);
2433         }
2434
2435         // version nagging
2436         if(self.version_nagtime)
2437                 if(self.cvar_g_xonoticversion)
2438                         if(time > self.version_nagtime)
2439                         {
2440                                 // don't notify git users
2441                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2442                                 {
2443                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2444                                         {
2445                                                 // notify release users if connecting to git
2446                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2447                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2448                                         }
2449                                         else
2450                                         {
2451                                                 float r;
2452                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2453                                                 if(r < 0)
2454                                                 {
2455                                                         // give users new version
2456                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2457                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2458                                                 }
2459                                                 else if(r > 0)
2460                                                 {
2461                                                         // notify users about old server version
2462                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2463                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2464                                                 }
2465                                         }
2466                                 }
2467                                 self.version_nagtime = 0;
2468                         }
2469
2470         // GOD MODE info
2471         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2472         {
2473                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2474                 self.max_armorvalue = 0;
2475         }
2476
2477 #ifdef TETRIS
2478         if (TetrisPreFrame())
2479                 return;
2480 #endif
2481
2482         MUTATOR_CALLHOOK(PlayerPreThink);
2483
2484         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2485         {
2486                 if(self.BUTTON_USE && !self.usekeypressed)
2487                         PlayerUseKey();
2488                 self.usekeypressed = self.BUTTON_USE;
2489         }
2490
2491         if(IS_REAL_CLIENT(self))
2492                 PrintWelcomeMessage();
2493
2494         if(IS_PLAYER(self))
2495         {
2496
2497                 CheckRules_Player();
2498
2499                 if (intermission_running)
2500                 {
2501                         IntermissionThink ();   // otherwise a button could be missed between
2502                         return;                                 // the think tics
2503                 }
2504
2505                 //don't allow the player to turn around while game is paused!
2506                 if(timeout_status == TIMEOUT_ACTIVE) {
2507                         // FIXME turn this into CSQC stuff
2508                         self.v_angle = self.lastV_angle;
2509                         self.angles = self.lastV_angle;
2510                         self.fixangle = TRUE;
2511                 }
2512
2513                 if(frametime)
2514                 {
2515                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2516                         {
2517                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2518                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2519                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2520
2521                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2522                                 {
2523                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2524                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2525                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2526                                 }
2527                         }
2528                         else
2529                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2530
2531                         player_powerups();
2532                 }
2533
2534                 if (self.deadflag != DEAD_NO)
2535                 {
2536                         if(self.personal && g_race_qualifying)
2537                         {
2538                                 if(time > self.respawn_time)
2539                                 {
2540                                         self.respawn_time = time + 1; // only retry once a second
2541                                         self.stat_respawn_time = self.respawn_time;
2542                                         respawn();
2543                                         self.impulse = 141;
2544                                 }
2545                         }
2546                         else
2547                         {
2548                                 float button_pressed;
2549                                 if(frametime)
2550                                         player_anim();
2551                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2552                                 
2553                                 if (self.deadflag == DEAD_DYING)
2554                                 {
2555                                         if(self.respawn_flags & RESPAWN_FORCE)
2556                                                 self.deadflag = DEAD_RESPAWNING;
2557                                         else if(!button_pressed)
2558                                                 self.deadflag = DEAD_DEAD;
2559                                 }
2560                                 else if (self.deadflag == DEAD_DEAD)
2561                                 {
2562                                         if(button_pressed)
2563                                                 self.deadflag = DEAD_RESPAWNABLE;
2564                                 }
2565                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2566                                 {
2567                                         if(!button_pressed)
2568                                                 self.deadflag = DEAD_RESPAWNING;
2569                                 }
2570                                 else if (self.deadflag == DEAD_RESPAWNING)
2571                                 {
2572                                         if(time > self.respawn_time)
2573                                         {
2574                                                 self.respawn_time = time + 1; // only retry once a second
2575                                                 respawn();
2576                                         }
2577                                 }
2578
2579                                 ShowRespawnCountdown();
2580
2581                                 if(self.respawn_flags & RESPAWN_SILENT)
2582                                         self.stat_respawn_time = 0;
2583                                 else
2584                                         self.stat_respawn_time = self.respawn_time;
2585                         }
2586
2587                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2588                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2589                                 self.stat_respawn_time *= -1;
2590
2591                         return;
2592                 }
2593
2594                 self.prevorigin = self.origin;
2595
2596                 float do_crouch = self.BUTTON_CROUCH;
2597                 if(self.hook.state)
2598                         do_crouch = 0;
2599                 if(self.health <= g_bloodloss)
2600                         do_crouch = 1;
2601                 if(self.vehicle)
2602                         do_crouch = 0;
2603                 if(self.freezetag_frozen)
2604                         do_crouch = 0;
2605                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2606                         do_crouch = 0;
2607
2608                 if (do_crouch)
2609                 {
2610                         if (!self.crouch)
2611                         {
2612                                 self.crouch = TRUE;
2613                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2614                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2615                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2616                         }
2617                 }
2618                 else
2619                 {
2620                         if (self.crouch)
2621                         {
2622                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2623                                 if (!trace_startsolid)
2624                                 {
2625                                         self.crouch = FALSE;
2626                                         self.view_ofs = PL_VIEW_OFS;
2627                                         setsize (self, PL_MIN, PL_MAX);
2628                                 }
2629                         }
2630                 }
2631
2632                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2633                 {
2634                         if(self.bloodloss_timer < time)
2635                         {
2636                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2637                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2638                         }
2639                 }
2640
2641                 FixPlayermodel();
2642
2643                 GrapplingHookFrame();
2644
2645                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2646                 //if(frametime)
2647                 {
2648                         self.items &~= self.items_added;
2649
2650                         W_WeaponFrame();
2651
2652                         self.items_added = 0;
2653                         if(self.items & IT_JETPACK)
2654                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2655                                         self.items_added |= IT_FUEL;
2656
2657                         self.items |= self.items_added;
2658                 }
2659
2660                 player_regen();
2661
2662                 // rot nex charge to the charge limit
2663                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2664                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2665
2666                 if(frametime)
2667                         player_anim();
2668
2669                 if(g_nexball)
2670                         nexball_setstatus();
2671                 
2672                 // secret status
2673                 secrets_setstatus();
2674                 
2675                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2676
2677                 //self.angles_y=self.v_angle_y + 90;   // temp
2678         } else if(gameover) {
2679                 if (intermission_running)
2680                         IntermissionThink ();   // otherwise a button could be missed between
2681                 return;
2682         } else if(IS_OBSERVER(self)) {
2683                 ObserverThink();
2684         } else if(IS_SPEC(self)) {
2685                 SpectatorThink();
2686         }
2687
2688         if(!zoomstate_set)
2689                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2690
2691         float oldspectatee_status;
2692         oldspectatee_status = self.spectatee_status;
2693         if(IS_SPEC(self))
2694                 self.spectatee_status = num_for_edict(self.enemy);
2695         else if(IS_OBSERVER(self))
2696                 self.spectatee_status = num_for_edict(self);
2697         else
2698                 self.spectatee_status = 0;
2699         if(self.spectatee_status != oldspectatee_status)
2700         {
2701                 ClientData_Touch(self);
2702                 if(g_race || g_cts)
2703                         race_InitSpectator();
2704         }
2705
2706         if(self.teamkill_soundtime)
2707         if(time > self.teamkill_soundtime)
2708         {
2709                 self.teamkill_soundtime = 0;
2710
2711                 entity oldpusher, oldself;
2712
2713                 oldself = self; self = self.teamkill_soundsource;
2714                 oldpusher = self.pusher; self.pusher = oldself;
2715
2716                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2717
2718                 self.pusher = oldpusher;
2719                 self = oldself;
2720         }
2721
2722         if(self.taunt_soundtime)
2723         if(time > self.taunt_soundtime)
2724         {
2725                 self.taunt_soundtime = 0;
2726                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2727         }
2728
2729         target_voicescript_next(self);
2730
2731         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2732         if(!self.weapon)
2733                 self.clip_load = self.clip_size = 0;
2734 }
2735
2736 float isInvisibleString(string s)
2737 {
2738         float i, n, c;
2739         s = strdecolorize(s);
2740         for((i = 0), (n = strlen(s)); i < n; ++i)
2741         {
2742                 c = str2chr(s, i);
2743                 switch(c)
2744                 {
2745                         case 0:
2746                         case 32: // space
2747                                 break;
2748                         case 192: // charmap space
2749                                 if (!autocvar_utf8_enable)
2750                                         break;
2751                                 return FALSE;
2752                         case 160: // space in unicode fonts
2753                         case 0xE000 + 192: // utf8 charmap space
2754                                 if (autocvar_utf8_enable)
2755                                         break;
2756                         default:
2757                                 return FALSE;
2758                 }
2759         }
2760         return TRUE;
2761 }
2762
2763 /*
2764 =============
2765 PlayerPostThink
2766
2767 Called every frame for each client after the physics are run
2768 =============
2769 */
2770 .float idlekick_lasttimeleft;
2771 void PlayerPostThink (void)
2772 {
2773         // Savage: Check for nameless players
2774         if (isInvisibleString(self.netname)) {
2775                 self.netname = "Player";
2776                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2777         }
2778
2779         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2780         {
2781                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2782                 {
2783                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2784                 }
2785                 else
2786                 {
2787                         float timeleft;
2788                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2789                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2790                         {
2791                                 if(!self.idlekick_lasttimeleft)
2792                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2793                         }
2794                         if(timeleft <= 0)
2795                         {
2796                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2797                                 dropclient(self);
2798                                 return;
2799                         }
2800                         else if(timeleft <= 10)
2801                         {
2802                                 if(timeleft != self.idlekick_lasttimeleft)
2803                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2804                                 self.idlekick_lasttimeleft = timeleft;
2805                         }
2806                 }
2807         }
2808
2809 #ifdef TETRIS
2810         if(self.impulse == 100)
2811                 ImpulseCommands();
2812         if (!TetrisPostFrame())
2813         {
2814 #endif
2815
2816         CheatFrame();
2817
2818         //CheckPlayerJump();
2819
2820         if(IS_PLAYER(self)) {
2821                 CheckRules_Player();
2822                 UpdateChatBubble();
2823                 if (self.impulse)
2824                         ImpulseCommands();
2825                 if (intermission_running)
2826                         return;         // intermission or finale
2827                 GetPressedKeys();
2828         }
2829         
2830 #ifdef TETRIS
2831         }
2832 #endif
2833
2834         /*
2835         float i;
2836         for(i = 0; i < 1000; ++i)
2837         {
2838                 vector end;
2839                 end = self.origin + '0 0 1024' + 512 * randomvec();
2840                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2841                 if(trace_fraction < 1)
2842                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2843                 {
2844                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2845                         break;
2846                 }
2847         }
2848         */
2849
2850         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2851
2852         if(self.waypointsprite_attachedforcarrier)
2853                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2854
2855         playerdemo_write();
2856
2857         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2858         {
2859                 if not(self.stored_netname)
2860                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2861                 if(self.stored_netname != self.netname)
2862                 {
2863                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2864                         strunzone(self.stored_netname);
2865                         self.stored_netname = strzone(self.netname);
2866                 }
2867         }
2868
2869         /*
2870         if(g_race)
2871                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2872         */
2873
2874         CSQCMODEL_AUTOUPDATE();
2875 }