qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return false;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  41         }
  42
  43         return true;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76 void SetSpectator(entity player, entity spectatee);
  77
  78
  79 /*
  80 =============
  81 CheckPlayerModel
  82
  83 Checks if the argument string can be a valid playermodel.
  84 Returns a valid one in doubt.
  85 =============
  86 */
  87 string FallbackPlayerModel;
  88 string CheckPlayerModel(string plyermodel) {
  89         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  90         {
  91                 // note: we cannot summon Don Strunzone here, some player may
  92                 // still have the model string set. In case anyone manages how
  93                 // to change a cvar default, we'll have a small leak here.
  94                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  95         }
  96         // only in right path
  97         if( substring(plyermodel,0,14) != "models/player/")
  98                 return FallbackPlayerModel;
  99         // only good file extensions
 100         if(substring(plyermodel,-4,4) != ".zym")
 101         if(substring(plyermodel,-4,4) != ".dpm")
 102         if(substring(plyermodel,-4,4) != ".iqm")
 103         if(substring(plyermodel,-4,4) != ".md3")
 104         if(substring(plyermodel,-4,4) != ".psk")
 105                 return FallbackPlayerModel;
 106         // forbid the LOD models
 107         if(substring(plyermodel, -9,5) == "_lod1")
 108                 return FallbackPlayerModel;
 109         if(substring(plyermodel, -9,5) == "_lod2")
 110                 return FallbackPlayerModel;
 111         if(plyermodel != strtolower(plyermodel))
 112                 return FallbackPlayerModel;
 113         // also, restrict to server models
 114         if(autocvar_sv_servermodelsonly)
 115         {
 116                 if(!fexists(plyermodel))
 117                         return FallbackPlayerModel;
 118         }
 119         return plyermodel;
 120 }
 121
 122 void setplayermodel(entity e, string modelname)
 123 {
 124         precache_model(modelname);
 125         setmodel(e, modelname);
 126         player_setupanimsformodel();
 127         UpdatePlayerSounds();
 128 }
 129
 130 /*
 131 =============
 132 PutObserverInServer
 133
 134 putting a client as observer in the server
 135 =============
 136 */
 137 void FixPlayermodel();
 138 void PutObserverInServer (void)
 139 {
 140         entity  spot;
 141     self.hud = HUD_NORMAL;
 142
 143         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 144
 145         spot = SelectSpawnPoint (true);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         self.frags = FRAGS_SPECTATOR;
 158
 159         MUTATOR_CALLHOOK(MakePlayerObserver);
 160
 161         Portal_ClearAll(self);
 162
 163         Unfreeze(self);
 164
 165         if(self.alivetime)
 166         {
 167                 if(!warmup_stage)
 168                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 169                 self.alivetime = 0;
 170         }
 171
 172         if(self.vehicle)
 173                 vehicles_exit(VHEF_RELESE);
 174
 175         WaypointSprite_PlayerDead();
 176
 177         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 178                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 179
 180         if(self.killcount != -666)
 181         {
 182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 183                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 185
 186                 if(self.just_joined == false) {
 187                         LogTeamchange(self.playerid, -1, 4);
 188                 } else
 189                         self.just_joined = false;
 190         }
 191
 192         PlayerScore_Clear(self); // clear scores when needed
 193
 194         accuracy_resend(self);
 195
 196         self.spectatortime = time;
 197
 198         self.classname = "observer";
 199         self.iscreature = false;
 200         self.teleportable = TELEPORT_SIMPLE;
 201         self.damagedbycontents = false;
 202         self.health = -666;
 203         self.takedamage = DAMAGE_NO;
 204         self.solid = SOLID_NOT;
 205         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 206         self.flags = FL_CLIENT | FL_NOTARGET;
 207         self.armorvalue = 666;
 208         self.effects = 0;
 209         self.armorvalue = autocvar_g_balance_armor_start;
 210         self.pauserotarmor_finished = 0;
 211         self.pauserothealth_finished = 0;
 212         self.pauseregen_finished = 0;
 213         self.damageforcescale = 0;
 214         self.death_time = 0;
 215         self.respawn_flags = 0;
 216         self.respawn_time = 0;
 217         self.stat_respawn_time = 0;
 218         self.alpha = 0;
 219         self.scale = 0;
 220         self.fade_time = 0;
 221         self.pain_frame = 0;
 222         self.pain_finished = 0;
 223         self.strength_finished = 0;
 224         self.invincible_finished = 0;
 225         self.superweapons_finished = 0;
 226         self.pushltime = 0;
 227         self.istypefrag = 0;
 228         self.think = func_null;
 229         self.nextthink = 0;
 230         self.hook_time = 0;
 231         self.deadflag = DEAD_NO;
 232         self.angles = spot.angles;
 233         self.angles_z = 0;
 234         self.fixangle = true;
 235         self.crouch = false;
 236         self.revival_time = 0;
 237
 238         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 239         self.prevorigin = self.origin;
 240         self.items = 0;
 241         self.weapons = '0 0 0';
 242         self.model = "";
 243         FixPlayermodel();
 244         setmodel(self, "null");
 245         self.drawonlytoclient = self;
 246
 247         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249
 250         self.weapon = 0;
 251         self.weaponname = "";
 252         self.switchingweapon = 0;
 253         self.weaponmodel = "";
 254         self.weaponentity = world;
 255         self.exteriorweaponentity = world;
 256         self.killcount = -666;
 257         self.velocity = '0 0 0';
 258         self.avelocity = '0 0 0';
 259         self.punchangle = '0 0 0';
 260         self.punchvector = '0 0 0';
 261         self.oldvelocity = self.velocity;
 262         self.fire_endtime = -1;
 263         self.event_damage = func_null;
 264 }
 265
 266 .float model_randomizer;
 267 void FixPlayermodel()
 268 {
 269         string defaultmodel;
 270         float defaultskin, chmdl, oldskin, n, i;
 271         vector m1, m2;
 272
 273         defaultmodel = "";
 274         defaultskin = 0;
 275         chmdl = false;
 276
 277         if(autocvar_sv_defaultcharacter == 1)
 278         {
 279                 if(teamplay)
 280                 {
 281                         string s;
 282                         s = Static_Team_ColorName_Lower(self.team);
 283                         if(s != "neutral")
 284                         {
 285                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 286                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 287                         }
 288                 }
 289
 290                 if(defaultmodel == "")
 291                 {
 292                         defaultmodel = autocvar_sv_defaultplayermodel;
 293                         defaultskin = autocvar_sv_defaultplayerskin;
 294                 }
 295
 296                 n = tokenize_console(defaultmodel);
 297                 if(n > 0)
 298                 {
 299                         defaultmodel = argv(floor(n * self.model_randomizer));
 300                         // However, do NOT randomize if the player-selected model is in the list.
 301                         for (i = 0; i < n; ++i)
 302                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 303                                         defaultmodel = argv(i);
 304                 }
 305
 306                 i = strstrofs(defaultmodel, ":", 0);
 307                 if(i >= 0)
 308                 {
 309                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 310                         defaultmodel = substring(defaultmodel, 0, i);
 311                 }
 312         }
 313
 314         if(defaultmodel != "")
 315         {
 316                 if (defaultmodel != self.model)
 317                 {
 318                         m1 = self.mins;
 319                         m2 = self.maxs;
 320                         setplayermodel (self, defaultmodel);
 321                         setsize (self, m1, m2);
 322                         chmdl = true;
 323                 }
 324
 325                 oldskin = self.skin;
 326                 self.skin = defaultskin;
 327         } else {
 328                 if (self.playermodel != self.model || self.playermodel == "")
 329                 {
 330                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 331                         m1 = self.mins;
 332                         m2 = self.maxs;
 333                         setplayermodel (self, self.playermodel);
 334                         setsize (self, m1, m2);
 335                         chmdl = true;
 336                 }
 337
 338                 oldskin = self.skin;
 339                 self.skin = stof(self.playerskin);
 340         }
 341
 342         if(chmdl || oldskin != self.skin) // model or skin has changed
 343         {
 344                 self.species = player_getspecies(); // update species
 345                 UpdatePlayerSounds(); // update skin sounds
 346         }
 347
 348         if(!teamplay)
 349                 if(strlen(autocvar_sv_defaultplayercolors))
 350                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 351                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 352 }
 353
 354 /*
 355 =============
 356 PutClientInServer
 357
 358 Called when a client spawns in the server
 359 =============
 360 */
 361 void PutClientInServer (void)
 362 {
 363         if(IS_BOT_CLIENT(self))
 364                 self.classname = "player";
 365         else if(IS_REAL_CLIENT(self))
 366         {
 367                 msg_entity = self;
 368                 WriteByte(MSG_ONE, SVC_SETVIEW);
 369                 WriteEntity(MSG_ONE, self);
 370         }
 371
 372         SetSpectator(self, world);
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, false, true);
 391
 392                 spot = SelectSpawnPoint (false);
 393                 if(!spot)
 394                 {
 395                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 396                         return; // spawn failed
 397                 }
 398
 399                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 400
 401                 if(self.vehicle)
 402                         vehicles_exit(VHEF_RELESE);
 403
 404                 self.classname = "player";
 405                 self.wasplayer = true;
 406                 self.iscreature = true;
 407                 self.teleportable = TELEPORT_NORMAL;
 408                 self.damagedbycontents = true;
 409                 self.movetype = MOVETYPE_WALK;
 410                 self.solid = SOLID_SLIDEBOX;
 411                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 412                 if(autocvar_g_playerclip_collisions)
 413                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 414                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 415                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 416                 self.frags = FRAGS_PLAYER;
 417                 if(INDEPENDENT_PLAYERS)
 418                         MAKE_INDEPENDENT_PLAYER(self);
 419                 self.flags = FL_CLIENT;
 420                 if(autocvar__notarget)
 421                         self.flags |= FL_NOTARGET;
 422                 self.takedamage = DAMAGE_AIM;
 423                 self.effects = 0;
 424                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 425                 self.air_finished = time + 12;
 426                 self.dmg = 2;
 427                 if(WEP_CVAR(vortex, charge))
 428                 {
 429                         if(WEP_CVAR_SEC(vortex, chargepool))
 430                                 self.vortex_chargepool_ammo = 1;
 431                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 432                 }
 433
 434                 if(warmup_stage)
 435                 {
 436                         self.ammo_shells = warmup_start_ammo_shells;
 437                         self.ammo_nails = warmup_start_ammo_nails;
 438                         self.ammo_rockets = warmup_start_ammo_rockets;
 439                         self.ammo_cells = warmup_start_ammo_cells;
 440                         self.ammo_plasma = warmup_start_ammo_plasma;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = WARMUP_START_WEAPONS;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_plasma = start_ammo_plasma;
 453                         self.ammo_fuel = start_ammo_fuel;
 454                         self.health = start_health;
 455                         self.armorvalue = start_armorvalue;
 456                         self.weapons = start_weapons;
 457                 }
 458
 459                 if(self.weapons & WEPSET_SUPERWEAPONS)
 460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 461                 else
 462                         self.superweapons_finished = 0;
 463
 464                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 465                 {
 466                         if(g_weaponarena_random_with_blaster)
 467                                 self.weapons &= ~WEPSET_BLASTER;
 468                         W_RandomWeapons(self, g_weaponarena_random);
 469                         if(g_weaponarena_random_with_blaster)
 470                                 self.weapons |= WEPSET_BLASTER;
 471                 }
 472
 473                 self.items = start_items;
 474
 475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 480                 //extend the pause of rotting if client was reset at the beginning of the countdown
 481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 482                         self.spawnshieldtime += game_starttime - time;
 483                         self.pauserotarmor_finished += game_starttime - time;
 484                         self.pauserothealth_finished += game_starttime - time;
 485                         self.pauseregen_finished += game_starttime - time;
 486                 }
 487                 self.damageforcescale = 2;
 488                 self.death_time = 0;
 489                 self.respawn_flags = 0;
 490                 self.respawn_time = 0;
 491                 self.stat_respawn_time = 0;
 492                 self.scale = 0;
 493                 self.fade_time = 0;
 494                 self.pain_frame = 0;
 495                 self.pain_finished = 0;
 496                 self.strength_finished = 0;
 497                 self.invincible_finished = 0;
 498                 self.pushltime = 0;
 499                 // players have no think function
 500                 self.think = func_null;
 501                 self.nextthink = 0;
 502                 self.hook_time = 0;
 503                 self.dmg_team = 0;
 504                 self.ballistics_density = autocvar_g_ballistics_density_player;
 505
 506                 self.metertime = 0;
 507
 508                 self.deadflag = DEAD_NO;
 509
 510                 self.angles = spot.angles;
 511
 512                 self.angles_z = 0; // never spawn tilted even if the spot says to
 513                 if(IS_BOT_CLIENT(self))
 514                         self.v_angle = self.angles;
 515                 self.fixangle = true; // turn this way immediately
 516                 self.velocity = '0 0 0';
 517                 self.avelocity = '0 0 0';
 518                 self.punchangle = '0 0 0';
 519                 self.punchvector = '0 0 0';
 520                 self.oldvelocity = self.velocity;
 521                 self.fire_endtime = -1;
 522                 self.revival_time = 0;
 523
 524                 entity spawnevent = spawn();
 525                 spawnevent.owner = self;
 526                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 527
 528                 // Cut off any still running player sounds.
 529                 stopsound(self, CH_PLAYER_SINGLE);
 530
 531                 self.model = "";
 532                 FixPlayermodel();
 533                 self.drawonlytoclient = world;
 534
 535                 self.crouch = false;
 536                 self.view_ofs = PL_VIEW_OFS;
 537                 setsize (self, PL_MIN, PL_MAX);
 538                 self.spawnorigin = spot.origin;
 539                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 540                 // don't reset back to last position, even if new position is stuck in solid
 541                 self.oldorigin = self.origin;
 542                 self.prevorigin = self.origin;
 543                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 544                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 545         self.hud = HUD_NORMAL;
 546
 547                 self.event_damage = PlayerDamage;
 548
 549                 self.bot_attack = true;
 550                 self.monster_attack = true;
 551
 552                 self.spider_slowness = 0;
 553
 554                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 555
 556                 if(self.killcount == -666) {
 557                         PlayerScore_Clear(self);
 558                         self.killcount = 0;
 559                 }
 560
 561                 CL_SpawnWeaponentity();
 562                 self.alpha = default_player_alpha;
 563                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 564                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 565
 566                 self.speedrunning = false;
 567
 568                 //stuffcmd(self, "chase_active 0");
 569                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 570
 571                 target_voicescript_clear(self);
 572
 573                 // reset fields the weapons may use
 574                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 575                 {
 576                         WEP_ACTION(j, WR_RESETPLAYER);
 577
 578                         // all weapons must be fully loaded when we spawn
 579                         entity e;
 580                         e = get_weaponinfo(j);
 581                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 582                                 self.(weapon_load[j]) = e.reloading_ammo;
 583                 }
 584
 585                 oldself = self;
 586                 self = spot;
 587                         activator = oldself;
 588                                 string s;
 589                                 s = self.target;
 590                                 self.target = string_null;
 591                                 SUB_UseTargets();
 592                                 self.target = s;
 593                         activator = world;
 594                 self = oldself;
 595
 596                 Unfreeze(self);
 597
 598                 spawn_spot = spot;
 599                 MUTATOR_CALLHOOK(PlayerSpawn);
 600
 601                 if(autocvar_spawn_debug)
 602                 {
 603                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 604                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 605                 }
 606
 607                 self.switchweapon = w_getbestweapon(self);
 608                 self.cnt = -1; // W_LastWeapon will not complain
 609                 self.weapon = 0;
 610                 self.weaponname = "";
 611                 self.switchingweapon = 0;
 612
 613                 if(!warmup_stage)
 614                         if(!self.alivetime)
 615                                 self.alivetime = time;
 616
 617                 antilag_clear(self);
 618         }
 619         else if(IS_OBSERVER(self))
 620         {
 621                 PutObserverInServer ();
 622         }
 623 }
 624
 625 .float ebouncefactor, ebouncestop; // electro's values
 626 // TODO do we need all these fields, or should we stop autodetecting runtime
 627 // changes and just have a console command to update this?
 628 float ClientInit_SendEntity(entity to, float sf)
 629 {
 630         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 631         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 640
 641         if(sv_foginterval && world.fog != "")
 642                 WriteString(MSG_ENTITY, world.fog);
 643         else
 644                 WriteString(MSG_ENTITY, "");
 645         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 646         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 647         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 648         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 649         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 650         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 651         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 652         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 653         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 654         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 655         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 656         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 657         return true;
 658 }
 659
 660 void ClientInit_CheckUpdate()
 661 {
 662         self.nextthink = time;
 663         if(self.count != autocvar_g_balance_armor_blockpercent)
 664         {
 665                 self.count = autocvar_g_balance_armor_blockpercent;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 669         {
 670                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 674         {
 675                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 679         {
 680                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 681                 self.SendFlags |= 1;
 682         }
 683         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 684         {
 685                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 686                 self.SendFlags |= 1;
 687         }
 688 }
 689
 690 void ClientInit_Spawn()
 691 {
 692         entity o;
 693         entity e;
 694         e = spawn();
 695         e.classname = "clientinit";
 696         e.think = ClientInit_CheckUpdate;
 697         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 698
 699         o = self;
 700         self = e;
 701         ClientInit_CheckUpdate();
 702         self = o;
 703 }
 704
 705 /*
 706 =============
 707 SetNewParms
 708 =============
 709 */
 710 void SetNewParms (void)
 711 {
 712         // initialize parms for a new player
 713         parm1 = -(86400 * 366);
 714 }
 715
 716 /*
 717 =============
 718 SetChangeParms
 719 =============
 720 */
 721 void SetChangeParms (void)
 722 {
 723         // save parms for level change
 724         parm1 = self.parm_idlesince - time;
 725 }
 726
 727 /*
 728 =============
 729 DecodeLevelParms
 730 =============
 731 */
 732 void DecodeLevelParms (void)
 733 {
 734         // load parms
 735         self.parm_idlesince = parm1;
 736         if(self.parm_idlesince == -(86400 * 366))
 737                 self.parm_idlesince = time;
 738
 739         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 740         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 741 }
 742
 743 /*
 744 =============
 745 ClientKill
 746
 747 Called when a client types 'kill' in the console
 748 =============
 749 */
 750
 751 .float clientkill_nexttime;
 752 void ClientKill_Now_TeamChange()
 753 {
 754         if(self.killindicator_teamchange == -1)
 755         {
 756                 JoinBestTeam( self, false, true );
 757         }
 758         else if(self.killindicator_teamchange == -2)
 759         {
 760                 if(blockSpectators)
 761                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 762                 PutObserverInServer();
 763         }
 764         else
 765                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 766         self.killindicator_teamchange = 0;
 767 }
 768
 769 void ClientKill_Now()
 770 {
 771         if(self.vehicle)
 772         {
 773             vehicles_exit(VHEF_RELESE);
 774             if(!self.killindicator_teamchange)
 775             {
 776             self.vehicle_health = -1;
 777             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 778             }
 779         }
 780
 781         if(self.killindicator && !wasfreed(self.killindicator))
 782                 remove(self.killindicator);
 783
 784         self.killindicator = world;
 785
 786         if(self.killindicator_teamchange)
 787                 ClientKill_Now_TeamChange();
 788
 789         if(IS_PLAYER(self))
 790                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 791
 792         // now I am sure the player IS dead
 793 }
 794 void KillIndicator_Think()
 795 {
 796         if (gameover)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if (self.owner.alpha < 0 && !self.owner.vehicle)
 804         {
 805                 self.owner.killindicator = world;
 806                 remove(self);
 807                 return;
 808         }
 809
 810         if(self.cnt <= 0)
 811         {
 812                 self = self.owner;
 813                 ClientKill_Now(); // no oldself needed
 814                 return;
 815         }
 816     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 817     {
 818         self.nextthink = time + 1;
 819         self.cnt -= 1;
 820     }
 821         else
 822         {
 823                 if(self.cnt <= 10)
 824                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 825                 if(IS_REAL_CLIENT(self.owner))
 826                 {
 827                         if(self.cnt <= 10)
 828                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 829                 }
 830                 self.nextthink = time + 1;
 831                 self.cnt -= 1;
 832         }
 833 }
 834
 835 float clientkilltime;
 836 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 837 {
 838         float killtime;
 839         float starttime;
 840         entity e;
 841
 842         if (gameover)
 843                 return;
 844
 845         killtime = autocvar_g_balance_kill_delay;
 846
 847         if(g_race_qualifying || g_cts)
 848                 killtime = 0;
 849
 850     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 851     {
 852                 remove(self.killindicator);
 853                 self.killindicator = world;
 854
 855         ClientKill_Now(); // allow instant kill in this case
 856         return;
 857     }
 858
 859         self.killindicator_teamchange = targetteam;
 860
 861     if(!self.killindicator)
 862         {
 863                 if(self.deadflag == DEAD_NO)
 864                 {
 865                         killtime = max(killtime, self.clientkill_nexttime - time);
 866                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 867                 }
 868
 869                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 870                 {
 871                         ClientKill_Now();
 872                 }
 873                 else
 874                 {
 875                         starttime = max(time, clientkilltime);
 876
 877                         self.killindicator = spawn();
 878                         self.killindicator.owner = self;
 879                         self.killindicator.scale = 0.5;
 880                         setattachment(self.killindicator, self, "");
 881                         setorigin(self.killindicator, '0 0 52');
 882                         self.killindicator.think = KillIndicator_Think;
 883                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 884                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 885                         self.killindicator.cnt = ceil(killtime);
 886                         self.killindicator.count = bound(0, ceil(killtime), 10);
 887                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 888
 889                         for(e = world; (e = find(e, classname, "body")) != world; )
 890                         {
 891                                 if(e.enemy != self)
 892                                         continue;
 893                                 e.killindicator = spawn();
 894                                 e.killindicator.owner = e;
 895                                 e.killindicator.scale = 0.5;
 896                                 setattachment(e.killindicator, e, "");
 897                                 setorigin(e.killindicator, '0 0 52');
 898                                 e.killindicator.think = KillIndicator_Think;
 899                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 900                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 901                                 e.killindicator.cnt = ceil(killtime);
 902                         }
 903                         self.lip = 0;
 904                 }
 905         }
 906         if(self.killindicator)
 907         {
 908                 if(targetteam == 0) // just die
 909                 {
 910                         self.killindicator.colormod = '0 0 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -1) // auto
 916                 {
 917                         self.killindicator.colormod = '0 1 0';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 921                 }
 922                 else if(targetteam == -2) // spectate
 923                 {
 924                         self.killindicator.colormod = '0.5 0.5 0.5';
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 928                 }
 929                 else
 930                 {
 931                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 932                         if(IS_REAL_CLIENT(self))
 933                         if(self.killindicator.cnt > 0)
 934                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 935                 }
 936         }
 937
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         if(gameover) return;
 943         if(self.player_blocked) return;
 944         if(self.frozen) return;
 945
 946         ClientKill_TeamChange(0);
 947 }
 948
 949 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 950 {
 951     e.killindicator = spawn();
 952     e.killindicator.owner = e;
 953     e.killindicator.think = KillIndicator_Think;
 954     e.killindicator.nextthink = time + (e.lip) * 0.05;
 955     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 956     e.killindicator.health = 1; // this is used to indicate that it should be silent
 957     e.lip = 0;
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         stuffcmd(e, "\nin_bindmap 0 0\n");
 964         if(g_race || g_cts)
 965                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970 }
 971
 972 float PlayerInIDList(entity p, string idlist)
 973 {
 974         float n, i;
 975         string s;
 976
 977         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 978         if (!p.crypto_idfp)
 979                 return 0;
 980
 981         // this function allows abbreviated player IDs too!
 982         n = tokenize_console(idlist);
 983         for(i = 0; i < n; ++i)
 984         {
 985                 s = argv(i);
 986                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 987                         return 1;
 988         }
 989
 990         return 0;
 991 }
 992
 993 /*
 994 =============
 995 ClientConnect
 996
 997 Called when a client connects to the server
 998 =============
 999 */
1000 void DecodeLevelParms (void);
1001 //void dom_player_join_team(entity pl);
1002 void set_dom_state(entity e);
1003 void ClientConnect (void)
1004 {
1005         float t;
1006
1007         if(IS_CLIENT(self))
1008         {
1009                 print("Warning: ClientConnect, but already connected!\n");
1010                 return;
1011         }
1012
1013         if(Ban_MaybeEnforceBanOnce(self))
1014                 return;
1015
1016         DecodeLevelParms();
1017
1018 #ifdef WATERMARK
1019         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1020 #endif
1021
1022         self.classname = "player_joining";
1023
1024         self.flags = FL_CLIENT;
1025         self.version_nagtime = time + 10 + random() * 10;
1026
1027         if(player_count<0)
1028         {
1029                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1030                 player_count = 0;
1031         }
1032
1033         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1034
1035         PlayerScore_Attach(self);
1036         ClientData_Attach();
1037         accuracy_init(self);
1038
1039         bot_clientconnect();
1040
1041         playerdemo_init();
1042
1043         anticheat_init();
1044
1045         // identify the right forced team
1046         if(autocvar_g_campaign)
1047         {
1048                 if(IS_REAL_CLIENT(self)) // only players, not bots
1049                 {
1050                         switch(autocvar_g_campaign_forceteam)
1051                         {
1052                                 case 1: self.team_forced = NUM_TEAM_1; break;
1053                                 case 2: self.team_forced = NUM_TEAM_2; break;
1054                                 case 3: self.team_forced = NUM_TEAM_3; break;
1055                                 case 4: self.team_forced = NUM_TEAM_4; break;
1056                                 default: self.team_forced = 0;
1057                         }
1058                 }
1059         }
1060         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1061                 self.team_forced = NUM_TEAM_1;
1062         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1063                 self.team_forced = NUM_TEAM_2;
1064         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1065                 self.team_forced = NUM_TEAM_3;
1066         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1067                 self.team_forced = NUM_TEAM_4;
1068         else if(autocvar_g_forced_team_otherwise == "red")
1069                 self.team_forced = NUM_TEAM_1;
1070         else if(autocvar_g_forced_team_otherwise == "blue")
1071                 self.team_forced = NUM_TEAM_2;
1072         else if(autocvar_g_forced_team_otherwise == "yellow")
1073                 self.team_forced = NUM_TEAM_3;
1074         else if(autocvar_g_forced_team_otherwise == "pink")
1075                 self.team_forced = NUM_TEAM_4;
1076         else if(autocvar_g_forced_team_otherwise == "spectate")
1077                 self.team_forced = -1;
1078         else if(autocvar_g_forced_team_otherwise == "spectator")
1079                 self.team_forced = -1;
1080         else
1081                 self.team_forced = 0;
1082
1083         if(!teamplay)
1084                 if(self.team_forced > 0)
1085                         self.team_forced = 0;
1086
1087         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1088
1089         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1090                 self.classname = "observer";
1091         } else {
1092                 if(teamplay)
1093                 {
1094                         if(autocvar_g_balance_teams)
1095                         {
1096                                 self.classname = "player";
1097                                 campaign_bots_may_start = 1;
1098                         }
1099                         else
1100                         {
1101                                 self.classname = "observer"; // do it anyway
1102                         }
1103                 }
1104                 else
1105                 {
1106                         self.classname = "player";
1107                         campaign_bots_may_start = 1;
1108                 }
1109         }
1110
1111         self.playerid = (playerid_last = playerid_last + 1);
1112
1113         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1114
1115     if(IS_BOT_CLIENT(self))
1116         PlayerStats_GameReport_AddPlayer(self);
1117
1118         if(autocvar_sv_eventlog)
1119                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1120
1121         LogTeamchange(self.playerid, self.team, 1);
1122
1123         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1124
1125         self.netname_previous = strzone(self.netname);
1126
1127         if(IS_PLAYER(self) && teamplay)
1128                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1129         else
1130                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1131
1132         stuffcmd(self, strcat(clientstuff, "\n"));
1133         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1134
1135         FixClientCvars(self);
1136
1137         // spawnfunc_waypoint sprites
1138         WaypointSprite_InitClient(self);
1139
1140         // Wazat's grappling hook
1141         SetGrappleHookBindings();
1142
1143         // Jetpack binds
1144         stuffcmd(self, "alias +jetpack +button10\n");
1145         stuffcmd(self, "alias -jetpack -button10\n");
1146
1147         // get version info from player
1148         stuffcmd(self, "cmd clientversion $gameversion\n");
1149
1150         // get other cvars from player
1151         GetCvars(0);
1152
1153         // notify about available teams
1154         if(teamplay)
1155         {
1156                 CheckAllowedTeams(self);
1157                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1158                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1159         }
1160         else
1161                 stuffcmd(self, "set _teams_available 0\n");
1162
1163         attach_entcs();
1164
1165         bot_relinkplayerlist();
1166
1167         self.spectatortime = time;
1168         if(blockSpectators)
1169         {
1170                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1171         }
1172
1173         self.jointime = time;
1174         self.allowed_timeouts = autocvar_sv_timeout_number;
1175
1176         if(IS_REAL_CLIENT(self))
1177         {
1178                 if(!autocvar_g_campaign)
1179                 {
1180                         self.motd_actived_time = -1;
1181                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1182                 }
1183
1184                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1185                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1186         }
1187
1188         if(!sv_foginterval && world.fog != "")
1189                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1190
1191         W_HitPlotOpen(self);
1192
1193         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1194                 send_CSQC_teamnagger();
1195
1196         CheatInitClient();
1197
1198         CSQCMODEL_AUTOINIT();
1199
1200         self.model_randomizer = random();
1201
1202         if(IS_REAL_CLIENT(self))
1203                 sv_notice_join();
1204
1205         MUTATOR_CALLHOOK(ClientConnect);
1206 }
1207 /*
1208 =============
1209 ClientDisconnect
1210
1211 Called when a client disconnects from the server
1212 =============
1213 */
1214 .entity chatbubbleentity;
1215 void ReadyCount();
1216 void ClientDisconnect (void)
1217 {
1218         if(self.vehicle)
1219             vehicles_exit(VHEF_RELESE);
1220
1221         if (!IS_CLIENT(self))
1222         {
1223                 print("Warning: ClientDisconnect without ClientConnect\n");
1224                 return;
1225         }
1226
1227         PlayerStats_GameReport_FinalizePlayer(self);
1228
1229         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1230
1231         CheatShutdownClient();
1232
1233         W_HitPlotClose(self);
1234
1235         anticheat_report();
1236         anticheat_shutdown();
1237
1238         playerdemo_shutdown();
1239
1240         bot_clientdisconnect();
1241
1242         if(self.entcs)
1243                 detach_entcs();
1244
1245         if(autocvar_sv_eventlog)
1246                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1247
1248         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1249
1250         MUTATOR_CALLHOOK(ClientDisconnect);
1251
1252         Portal_ClearAll(self);
1253
1254         Unfreeze(self);
1255
1256         RemoveGrapplingHook(self);
1257
1258         // Here, everything has been done that requires this player to be a client.
1259
1260         self.flags &= ~FL_CLIENT;
1261
1262         if (self.chatbubbleentity)
1263                 remove (self.chatbubbleentity);
1264
1265         if (self.killindicator)
1266                 remove (self.killindicator);
1267
1268         WaypointSprite_PlayerGone();
1269
1270         bot_relinkplayerlist();
1271
1272         accuracy_free(self);
1273         ClientData_Detach();
1274         PlayerScore_Detach(self);
1275
1276         if(self.netname_previous)
1277                 strunzone(self.netname_previous);
1278         if(self.clientstatus)
1279                 strunzone(self.clientstatus);
1280         if(self.weaponorder_byimpulse)
1281                 strunzone(self.weaponorder_byimpulse);
1282
1283         ClearPlayerSounds();
1284
1285         if(self.personal)
1286                 remove(self.personal);
1287
1288         self.playerid = 0;
1289         ReadyCount();
1290
1291         // free cvars
1292         GetCvars(-1);
1293 }
1294
1295 .float BUTTON_CHAT;
1296 void ChatBubbleThink()
1297 {
1298         self.nextthink = time;
1299         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1300         {
1301                 if(self.owner) // but why can that ever be world?
1302                         self.owner.chatbubbleentity = world;
1303                 remove(self);
1304                 return;
1305         }
1306         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1307 #ifdef TETRIS
1308                 || self.owner.tetris_on
1309 #endif
1310         )
1311                 self.model = self.mdl;
1312         else
1313                 self.model = "";
1314 }
1315
1316 void UpdateChatBubble()
1317 {
1318         if (self.alpha < 0)
1319                 return;
1320         // spawn a chatbubble entity if needed
1321         if (!self.chatbubbleentity)
1322         {
1323                 self.chatbubbleentity = spawn();
1324                 self.chatbubbleentity.owner = self;
1325                 self.chatbubbleentity.exteriormodeltoclient = self;
1326                 self.chatbubbleentity.think = ChatBubbleThink;
1327                 self.chatbubbleentity.nextthink = time;
1328                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1329                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1330                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1331                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1332                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1333                 self.chatbubbleentity.model = "";
1334                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1335         }
1336 }
1337
1338
1339 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1340 // added to the model skins
1341 /*void UpdateColorModHack()
1342 {
1343         float c;
1344         c = self.clientcolors & 15;
1345         // LordHavoc: only bothering to support white, green, red, yellow, blue
1346              if (!teamplay) self.colormod = '0 0 0';
1347         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1348         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1349         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1350         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1351         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1352         else self.colormod = '1 1 1';
1353 }*/
1354
1355 void respawn(void)
1356 {
1357         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1358         {
1359                 self.solid = SOLID_NOT;
1360                 self.takedamage = DAMAGE_NO;
1361                 self.movetype = MOVETYPE_FLY;
1362                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1363                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1364                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1365                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1366                 if(autocvar_g_respawn_ghosts_maxtime)
1367                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1368         }
1369
1370         CopyBody(1);
1371
1372         self.effects |= EF_NODRAW; // prevent another CopyBody
1373         PutClientInServer();
1374 }
1375
1376 void play_countdown(float finished, string samp)
1377 {
1378         if(IS_REAL_CLIENT(self))
1379                 if(floor(finished - time - frametime) != floor(finished - time))
1380                         if(finished - time < 6)
1381                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1382 }
1383
1384 void player_powerups (void)
1385 {
1386         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1387         olditems = self.items;
1388
1389         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1390                 self.modelflags |= MF_ROCKET;
1391         else
1392                 self.modelflags &= ~MF_ROCKET;
1393
1394         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1395
1396         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1397                 return;
1398
1399         Fire_ApplyDamage(self);
1400         Fire_ApplyEffect(self);
1401
1402         if (!g_instagib)
1403         {
1404                 if (self.items & IT_STRENGTH)
1405                 {
1406                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1407                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1408                         if (time > self.strength_finished)
1409                         {
1410                                 self.items = self.items - (self.items & IT_STRENGTH);
1411                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1412                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1413                         }
1414                 }
1415                 else
1416                 {
1417                         if (time < self.strength_finished)
1418                         {
1419                                 self.items = self.items | IT_STRENGTH;
1420                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1421                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1422                         }
1423                 }
1424                 if (self.items & IT_INVINCIBLE)
1425                 {
1426                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1427                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1428                         if (time > self.invincible_finished)
1429                         {
1430                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1431                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1432                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1433                         }
1434                 }
1435                 else
1436                 {
1437                         if (time < self.invincible_finished)
1438                         {
1439                                 self.items = self.items | IT_INVINCIBLE;
1440                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1441                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1442                         }
1443                 }
1444                 if (self.items & IT_SUPERWEAPON)
1445                 {
1446                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1447                         {
1448                                 self.superweapons_finished = 0;
1449                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1450                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1452                         }
1453                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1454                         {
1455                                 // don't let them run out
1456                         }
1457                         else
1458                         {
1459                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1460                                 if (time > self.superweapons_finished)
1461                                 {
1462                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1463                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1464                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1465                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1466                                 }
1467                         }
1468                 }
1469                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1470                 {
1471                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1472                         {
1473                                 self.items = self.items | IT_SUPERWEAPON;
1474                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1475                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1476                         }
1477                         else
1478                         {
1479                                 self.superweapons_finished = 0;
1480                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1481                         }
1482                 }
1483                 else
1484                 {
1485                         self.superweapons_finished = 0;
1486                 }
1487         }
1488
1489         if(autocvar_g_nodepthtestplayers)
1490                 self.effects = self.effects | EF_NODEPTHTEST;
1491
1492         if(autocvar_g_fullbrightplayers)
1493                 self.effects = self.effects | EF_FULLBRIGHT;
1494
1495         if (time >= game_starttime)
1496         if (time < self.spawnshieldtime)
1497                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1498
1499         MUTATOR_CALLHOOK(PlayerPowerups);
1500 }
1501
1502 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1503 {
1504         if(current > stable)
1505                 return current;
1506         else if(current > stable - 0.25) // when close enough, "snap"
1507                 return stable;
1508         else
1509                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1510 }
1511
1512 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1513 {
1514         if(current < stable)
1515                 return current;
1516         else if(current < stable + 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1520 }
1521
1522 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1523 {
1524         if(current > rotstable)
1525         {
1526                 if(rotframetime > 0)
1527                 {
1528                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1529                         current = max(rotstable, current - rotlinear * rotframetime);
1530                 }
1531         }
1532         else if(current < regenstable)
1533         {
1534                 if(regenframetime > 0)
1535                 {
1536                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1537                         current = min(regenstable, current + regenlinear * regenframetime);
1538                 }
1539         }
1540
1541         if(current > limit)
1542                 current = limit;
1543
1544         return current;
1545 }
1546
1547 void player_regen (void)
1548 {
1549         float max_mod, regen_mod, rot_mod, limit_mod;
1550         max_mod = regen_mod = rot_mod = limit_mod = 1;
1551         regen_mod_max = max_mod;
1552         regen_mod_regen = regen_mod;
1553         regen_mod_rot = rot_mod;
1554         regen_mod_limit = limit_mod;
1555         if(!MUTATOR_CALLHOOK(PlayerRegen))
1556         if(!self.frozen)
1557         {
1558                 float minh, mina, maxh, maxa, limith, limita;
1559                 maxh = autocvar_g_balance_health_rotstable;
1560                 maxa = autocvar_g_balance_armor_rotstable;
1561                 minh = autocvar_g_balance_health_regenstable;
1562                 mina = autocvar_g_balance_armor_regenstable;
1563                 limith = autocvar_g_balance_health_limit;
1564                 limita = autocvar_g_balance_armor_limit;
1565
1566                 max_mod = regen_mod_max;
1567                 regen_mod = regen_mod_regen;
1568                 rot_mod = regen_mod_rot;
1569                 limit_mod = regen_mod_limit;
1570
1571                 maxh = maxh * max_mod;
1572                 minh = minh * max_mod;
1573                 limith = limith * limit_mod;
1574                 limita = limita * limit_mod;
1575
1576                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1577                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1578         }
1579
1580         // if player rotted to death...  die!
1581         // check this outside above checks, as player may still be able to rot to death
1582         if(self.health < 1)
1583                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1584
1585         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1586         {
1587                 float minf, maxf, limitf;
1588
1589                 maxf = autocvar_g_balance_fuel_rotstable;
1590                 minf = autocvar_g_balance_fuel_regenstable;
1591                 limitf = autocvar_g_balance_fuel_limit;
1592
1593                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1594         }
1595 }
1596
1597 float zoomstate_set;
1598 void SetZoomState(float z)
1599 {
1600         if(z != self.zoomstate)
1601         {
1602                 self.zoomstate = z;
1603                 ClientData_Touch(self);
1604         }
1605         zoomstate_set = 1;
1606 }
1607
1608 void GetPressedKeys(void) {
1609         MUTATOR_CALLHOOK(GetPressedKeys);
1610         if (self.movement.x > 0) // get if movement keys are pressed
1611         {       // forward key pressed
1612                 self.pressedkeys |= KEY_FORWARD;
1613                 self.pressedkeys &= ~KEY_BACKWARD;
1614         }
1615         else if (self.movement.x < 0)
1616         {       // backward key pressed
1617                 self.pressedkeys |= KEY_BACKWARD;
1618                 self.pressedkeys &= ~KEY_FORWARD;
1619         }
1620         else
1621         {       // no x input
1622                 self.pressedkeys &= ~KEY_FORWARD;
1623                 self.pressedkeys &= ~KEY_BACKWARD;
1624         }
1625
1626         if (self.movement.y > 0)
1627         {       // right key pressed
1628                 self.pressedkeys |= KEY_RIGHT;
1629                 self.pressedkeys &= ~KEY_LEFT;
1630         }
1631         else if (self.movement.y < 0)
1632         {       // left key pressed
1633                 self.pressedkeys |= KEY_LEFT;
1634                 self.pressedkeys &= ~KEY_RIGHT;
1635         }
1636         else
1637         {       // no y input
1638                 self.pressedkeys &= ~KEY_RIGHT;
1639                 self.pressedkeys &= ~KEY_LEFT;
1640         }
1641
1642         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1643                 self.pressedkeys |= KEY_JUMP;
1644         else
1645                 self.pressedkeys &= ~KEY_JUMP;
1646         if (self.BUTTON_CROUCH)
1647                 self.pressedkeys |= KEY_CROUCH;
1648         else
1649                 self.pressedkeys &= ~KEY_CROUCH;
1650
1651         if (self.BUTTON_ATCK)
1652                 self.pressedkeys |= KEY_ATCK;
1653         else
1654                 self.pressedkeys &= ~KEY_ATCK;
1655         if (self.BUTTON_ATCK2)
1656                 self.pressedkeys |= KEY_ATCK2;
1657         else
1658                 self.pressedkeys &= ~KEY_ATCK2;
1659 }
1660
1661 /*
1662 ======================
1663 spectate mode routines
1664 ======================
1665 */
1666
1667 void SpectateCopy(entity spectatee) {
1668         other = spectatee;
1669         MUTATOR_CALLHOOK(SpectateCopy);
1670         self.armortype = spectatee.armortype;
1671         self.armorvalue = spectatee.armorvalue;
1672         self.ammo_cells = spectatee.ammo_cells;
1673         self.ammo_plasma = spectatee.ammo_plasma;
1674         self.ammo_shells = spectatee.ammo_shells;
1675         self.ammo_nails = spectatee.ammo_nails;
1676         self.ammo_rockets = spectatee.ammo_rockets;
1677         self.ammo_fuel = spectatee.ammo_fuel;
1678         self.clip_load = spectatee.clip_load;
1679         self.clip_size = spectatee.clip_size;
1680         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1681         self.health = spectatee.health;
1682         self.impulse = 0;
1683         self.items = spectatee.items;
1684         self.last_pickup = spectatee.last_pickup;
1685         self.hit_time = spectatee.hit_time;
1686         self.metertime = spectatee.metertime;
1687         self.strength_finished = spectatee.strength_finished;
1688         self.invincible_finished = spectatee.invincible_finished;
1689         self.pressedkeys = spectatee.pressedkeys;
1690         self.weapons = spectatee.weapons;
1691         self.switchweapon = spectatee.switchweapon;
1692         self.switchingweapon = spectatee.switchingweapon;
1693         self.weapon = spectatee.weapon;
1694         self.vortex_charge = spectatee.vortex_charge;
1695         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1696         self.hagar_load = spectatee.hagar_load;
1697         self.arc_heat_percent = spectatee.arc_heat_percent;
1698         self.minelayer_mines = spectatee.minelayer_mines;
1699         self.punchangle = spectatee.punchangle;
1700         self.view_ofs = spectatee.view_ofs;
1701         self.velocity = spectatee.velocity;
1702         self.dmg_take = spectatee.dmg_take;
1703         self.dmg_save = spectatee.dmg_save;
1704         self.dmg_inflictor = spectatee.dmg_inflictor;
1705         self.v_angle = spectatee.v_angle;
1706         self.angles = spectatee.v_angle;
1707         self.frozen = spectatee.frozen;
1708         self.revive_progress = spectatee.revive_progress;
1709         if(!self.BUTTON_USE)
1710                 self.fixangle = true;
1711         setorigin(self, spectatee.origin);
1712         setsize(self, spectatee.mins, spectatee.maxs);
1713         SetZoomState(spectatee.zoomstate);
1714
1715     anticheat_spectatecopy(spectatee);
1716         self.hud = spectatee.hud;
1717         if(spectatee.vehicle)
1718     {
1719         self.fixangle = false;
1720         //self.velocity = spectatee.vehicle.velocity;
1721         self.vehicle_health = spectatee.vehicle_health;
1722         self.vehicle_shield = spectatee.vehicle_shield;
1723         self.vehicle_energy = spectatee.vehicle_energy;
1724         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1725         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1726         self.vehicle_reload1 = spectatee.vehicle_reload1;
1727         self.vehicle_reload2 = spectatee.vehicle_reload2;
1728
1729         msg_entity = self;
1730
1731         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1732             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1733             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1734             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1735
1736         //WriteByte (MSG_ONE, SVC_SETVIEW);
1737         //    WriteEntity(MSG_ONE, self);
1738         //makevectors(spectatee.v_angle);
1739         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1740     }
1741 }
1742
1743 float SpectateUpdate()
1744 {
1745         if(!self.enemy)
1746             return 0;
1747
1748         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1749         {
1750                 SetSpectator(self, world);
1751                 return 0;
1752         }
1753
1754         SpectateCopy(self.enemy);
1755
1756         return 1;
1757 }
1758
1759 float SpectateSet()
1760 {
1761         if(self.enemy.classname != "player")
1762                 return false;
1763         /*if(self.enemy.vehicle)
1764         {
1765
1766                 msg_entity = self;
1767                 WriteByte(MSG_ONE, SVC_SETVIEW);
1768                 WriteEntity(MSG_ONE, self.enemy);
1769                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1770
1771                 self.movetype = MOVETYPE_NONE;
1772                 accuracy_resend(self);
1773         }
1774         else
1775         {*/
1776                 msg_entity = self;
1777                 WriteByte(MSG_ONE, SVC_SETVIEW);
1778                 WriteEntity(MSG_ONE, self.enemy);
1779                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1780                 self.movetype = MOVETYPE_NONE;
1781                 accuracy_resend(self);
1782
1783                 if(!SpectateUpdate())
1784                         PutObserverInServer();
1785         //}
1786         return true;
1787 }
1788
1789 void SetSpectator(entity player, entity spectatee)
1790 {
1791         entity old_spectatee = player.enemy;
1792
1793         player.enemy = spectatee;
1794
1795         // WEAPONTODO
1796         // these are required to fix the spectator bug with arc
1797         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1798         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1799 }
1800
1801 float Spectate(entity pl)
1802 {
1803         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1804         if(pl.team != self.team)
1805                 return 0;
1806
1807         SetSpectator(self, pl);
1808         return SpectateSet();
1809 }
1810
1811 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1812 entity CA_SpectateNext(entity start) {
1813         if (start.team == self.team) {
1814                 return start;
1815         }
1816
1817         other = start;
1818         // continue from current player
1819         while(other && other.team != self.team) {
1820                 other = find(other, classname, "player");
1821         }
1822
1823         if (!other) {
1824                 // restart from begining
1825                 other = find(other, classname, "player");
1826                 while(other && other.team != self.team) {
1827                         other = find(other, classname, "player");
1828                 }
1829         }
1830
1831         return other;
1832 }
1833
1834 float SpectateNext()
1835 {
1836         other = find(self.enemy, classname, "player");
1837
1838         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1839                 // CA and ca players when spectating enemies is forbidden
1840                 other = CA_SpectateNext(other);
1841         } else {
1842                 // other modes and ca spectators or spectating enemies is allowed
1843                 if (!other)
1844                         other = find(other, classname, "player");
1845         }
1846
1847         if(other) { SetSpectator(self, other); }
1848
1849         return SpectateSet();
1850 }
1851
1852 float SpectatePrev()
1853 {
1854         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1855         other = findchain(classname, "player");
1856         if (!other) // no player
1857                 return false;
1858
1859         entity first = other;
1860         // skip players until current spectated player
1861         if(self.enemy)
1862         while(other && other != self.enemy)
1863                 other = other.chain;
1864
1865         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1866         {
1867                 do { other = other.chain; }
1868                 while(other && other.team != self.team);
1869
1870                 if (!other)
1871                 {
1872                         other = first;
1873                         while(other.team != self.team)
1874                                 other = other.chain;
1875                         if(other == self.enemy)
1876                                 return true;
1877                 }
1878         }
1879         else
1880         {
1881                 if(other.chain)
1882                         other = other.chain;
1883                 else
1884                         other = first;
1885         }
1886         SetSpectator(self, other);
1887         return SpectateSet();
1888 }
1889
1890 /*
1891 =============
1892 ShowRespawnCountdown()
1893
1894 Update a respawn countdown display.
1895 =============
1896 */
1897 void ShowRespawnCountdown()
1898 {
1899         float number;
1900         if(self.deadflag == DEAD_NO) // just respawned?
1901                 return;
1902         else
1903         {
1904                 number = ceil(self.respawn_time - time);
1905                 if(number <= 0)
1906                         return;
1907                 if(number <= self.respawn_countdown)
1908                 {
1909                         self.respawn_countdown = number - 1;
1910                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1911                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1912                 }
1913         }
1914 }
1915
1916 void LeaveSpectatorMode()
1917 {
1918         if(self.caplayer)
1919                 return;
1920         if(nJoinAllowed(self))
1921         {
1922                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1923                 {
1924                         self.classname = "player";
1925                         nades_RemoveBonus(self);
1926
1927                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1928                                 { JoinBestTeam(self, false, true); }
1929
1930                         if(autocvar_g_campaign)
1931                                 { campaign_bots_may_start = 1; }
1932
1933                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1934
1935                         PutClientInServer();
1936
1937                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1938                 }
1939                 else
1940                         stuffcmd(self, "menu_showteamselect\n");
1941         }
1942         else
1943         {
1944                 // Player may not join because g_maxplayers is set
1945                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1946         }
1947 }
1948
1949 /**
1950  * Determines whether the player is allowed to join. This depends on cvar
1951  * g_maxplayers, if it isn't used this function always return true, otherwise
1952  * it checks whether the number of currently playing players exceeds g_maxplayers.
1953  * @return int number of free slots for players, 0 if none
1954  */
1955 float nJoinAllowed(entity ignore) {
1956         if(!ignore)
1957         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1958         // so report 0 free slots if restricted
1959         {
1960                 if(autocvar_g_forced_team_otherwise == "spectate")
1961                         return 0;
1962                 if(autocvar_g_forced_team_otherwise == "spectator")
1963                         return 0;
1964         }
1965
1966         if(self.team_forced < 0)
1967                 return 0; // forced spectators can never join
1968
1969         // TODO simplify this
1970         entity e;
1971         float totalClients = 0;
1972         FOR_EACH_CLIENT(e)
1973                 if(e != ignore)
1974                         totalClients += 1;
1975
1976         if (!autocvar_g_maxplayers)
1977                 return maxclients - totalClients;
1978
1979         float currentlyPlaying = 0;
1980         FOR_EACH_REALCLIENT(e)
1981                 if(IS_PLAYER(e) || e.caplayer)
1982                         currentlyPlaying += 1;
1983
1984         if(currentlyPlaying < autocvar_g_maxplayers)
1985                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1986
1987         return 0;
1988 }
1989
1990 /**
1991  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1992  * g_maxplayers_spectator_blocktime seconds
1993  */
1994 void checkSpectatorBlock() {
1995         if(IS_SPEC(self) || IS_OBSERVER(self))
1996         if(!self.caplayer)
1997         if(IS_REAL_CLIENT(self))
1998         {
1999                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2000                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2001                         dropclient(self);
2002                 }
2003         }
2004 }
2005
2006 void PrintWelcomeMessage()
2007 {
2008         if(self.motd_actived_time == 0)
2009         {
2010                 if (autocvar_g_campaign) {
2011                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2012                                 self.motd_actived_time = time;
2013                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2014                         }
2015                 } else {
2016                         if (self.BUTTON_INFO) {
2017                                 self.motd_actived_time = time;
2018                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2019                         }
2020                 }
2021         }
2022         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2023         {
2024                 if (autocvar_g_campaign) {
2025                         if (self.BUTTON_INFO)
2026                                 self.motd_actived_time = time;
2027                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2028                                 self.motd_actived_time = 0;
2029                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2030                         }
2031                 } else {
2032                         if (self.BUTTON_INFO)
2033                                 self.motd_actived_time = time;
2034                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2035                                 self.motd_actived_time = 0;
2036                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2037                         }
2038                 }
2039         }
2040         else //if(self.motd_actived_time < 0) // just connected, motd is active
2041         {
2042                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2043                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2044                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2045                 {
2046                         // instanctly hide MOTD
2047                         self.motd_actived_time = 0;
2048                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2049                 }
2050         }
2051 }
2052
2053 void ObserverThink()
2054 {
2055         float prefered_movetype;
2056         if (self.flags & FL_JUMPRELEASED) {
2057                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2058                         self.flags &= ~FL_JUMPRELEASED;
2059                         self.flags |= FL_SPAWNING;
2060                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2061                         self.flags &= ~FL_JUMPRELEASED;
2062                         if(SpectateNext()) {
2063                                 self.classname = "spectator";
2064                         }
2065                 } else {
2066                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2067                         if (self.movetype != prefered_movetype)
2068                                 self.movetype = prefered_movetype;
2069                 }
2070         } else {
2071                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2072                         self.flags |= FL_JUMPRELEASED;
2073                         if(self.flags & FL_SPAWNING)
2074                         {
2075                                 self.flags &= ~FL_SPAWNING;
2076                                 LeaveSpectatorMode();
2077                                 return;
2078                         }
2079                 }
2080         }
2081 }
2082
2083 void SpectatorThink()
2084 {
2085         if (self.flags & FL_JUMPRELEASED) {
2086                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2087                         self.flags &= ~FL_JUMPRELEASED;
2088                         self.flags |= FL_SPAWNING;
2089                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2090                         self.flags &= ~FL_JUMPRELEASED;
2091                         if(SpectateNext()) {
2092                                 self.classname = "spectator";
2093                         } else {
2094                                 self.classname = "observer";
2095                                 PutClientInServer();
2096                         }
2097                         self.impulse = 0;
2098                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2099                         self.flags &= ~FL_JUMPRELEASED;
2100                         if(SpectatePrev()) {
2101                                 self.classname = "spectator";
2102                         } else {
2103                                 self.classname = "observer";
2104                                 PutClientInServer();
2105                         }
2106                         self.impulse = 0;
2107                 } else if (self.BUTTON_ATCK2) {
2108                         self.flags &= ~FL_JUMPRELEASED;
2109                         self.classname = "observer";
2110                         PutClientInServer();
2111                 } else {
2112                         if(!SpectateUpdate())
2113                                 PutObserverInServer();
2114                 }
2115         } else {
2116                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2117                         self.flags |= FL_JUMPRELEASED;
2118                         if(self.flags & FL_SPAWNING)
2119                         {
2120                                 self.flags &= ~FL_SPAWNING;
2121                                 LeaveSpectatorMode();
2122                                 return;
2123                         }
2124                 }
2125                 if(!SpectateUpdate())
2126                         PutObserverInServer();
2127         }
2128
2129         self.flags |= FL_CLIENT | FL_NOTARGET;
2130 }
2131
2132 void PlayerUseKey()
2133 {
2134         if (!IS_PLAYER(self))
2135                 return;
2136
2137         if(self.vehicle)
2138         {
2139         vehicles_exit(VHEF_NORMAL);
2140         return;
2141         }
2142
2143         // a use key was pressed; call handlers
2144         MUTATOR_CALLHOOK(PlayerUseKey);
2145 }
2146
2147 float isInvisibleString(string s)
2148 {
2149         float i, n, c;
2150         s = strdecolorize(s);
2151         for((i = 0), (n = strlen(s)); i < n; ++i)
2152         {
2153                 c = str2chr(s, i);
2154                 switch(c)
2155                 {
2156                         case 0:
2157                         case 32: // space
2158                                 break;
2159                         case 192: // charmap space
2160                                 if (!autocvar_utf8_enable)
2161                                         break;
2162                                 return false;
2163                         case 160: // space in unicode fonts
2164                         case 0xE000 + 192: // utf8 charmap space
2165                                 if (autocvar_utf8_enable)
2166                                         break;
2167                         default:
2168                                 return false;
2169                 }
2170         }
2171         return true;
2172 }
2173
2174 /*
2175 =============
2176 PlayerPreThink
2177
2178 Called every frame for each client before the physics are run
2179 =============
2180 */
2181 .float usekeypressed;
2182 void() nexball_setstatus;
2183 .float items_added;
2184 void PlayerPreThink (void)
2185 {
2186         WarpZone_PlayerPhysics_FixVAngle();
2187
2188         self.stat_game_starttime = game_starttime;
2189         self.stat_round_starttime = round_starttime;
2190         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2191         self.stat_leadlimit = autocvar_leadlimit;
2192
2193         if(frametime)
2194         {
2195                 // physics frames: update anticheat stuff
2196                 anticheat_prethink();
2197         }
2198
2199         if(blockSpectators && frametime)
2200                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2201                 checkSpectatorBlock();
2202
2203         zoomstate_set = 0;
2204
2205         // Savage: Check for nameless players
2206         if (isInvisibleString(self.netname)) {
2207                 string new_name = strzone(strcat("Player@", self.netaddress));
2208                 if(autocvar_sv_eventlog)
2209                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2210                 if(self.netname_previous)
2211                         strunzone(self.netname_previous);
2212                 self.netname_previous = strzone(new_name);
2213                 self.netname = self.netname_previous;
2214                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2215         } else if(self.netname_previous != self.netname) {
2216                 if(autocvar_sv_eventlog)
2217                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2218                 if(self.netname_previous)
2219                         strunzone(self.netname_previous);
2220                 self.netname_previous = strzone(self.netname);
2221         }
2222
2223         // version nagging
2224         if(self.version_nagtime)
2225                 if(self.cvar_g_xonoticversion)
2226                         if(time > self.version_nagtime)
2227                         {
2228                                 // don't notify git users
2229                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2230                                 {
2231                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2232                                         {
2233                                                 // notify release users if connecting to git
2234                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2235                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2236                                         }
2237                                         else
2238                                         {
2239                                                 float r;
2240                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2241                                                 if(r < 0)
2242                                                 {
2243                                                         // give users new version
2244                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2245                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2246                                                 }
2247                                                 else if(r > 0)
2248                                                 {
2249                                                         // notify users about old server version
2250                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2251                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2252                                                 }
2253                                         }
2254                                 }
2255                                 self.version_nagtime = 0;
2256                         }
2257
2258         // GOD MODE info
2259         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2260         {
2261                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2262                 self.max_armorvalue = 0;
2263         }
2264
2265 #ifdef TETRIS
2266         if (TetrisPreFrame())
2267                 return;
2268 #endif
2269
2270         if(self.frozen == 2)
2271         {
2272                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2273                 self.health = max(1, self.revive_progress * start_health);
2274                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2275
2276                 if(self.revive_progress >= 1)
2277                         Unfreeze(self);
2278         }
2279         else if(self.frozen == 3)
2280         {
2281                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2282                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2283
2284                 if(self.health < 1)
2285                 {
2286                         if(self.vehicle)
2287                                 vehicles_exit(VHEF_RELESE);
2288                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2289                 }
2290                 else if ( self.revive_progress <= 0 )
2291                         Unfreeze(self);
2292         }
2293
2294         MUTATOR_CALLHOOK(PlayerPreThink);
2295
2296         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2297         {
2298                 if(self.BUTTON_USE && !self.usekeypressed)
2299                         PlayerUseKey();
2300                 self.usekeypressed = self.BUTTON_USE;
2301         }
2302
2303         if(IS_REAL_CLIENT(self))
2304                 PrintWelcomeMessage();
2305
2306         if(IS_PLAYER(self))
2307         {
2308
2309                 CheckRules_Player();
2310
2311                 if (intermission_running)
2312                 {
2313                         IntermissionThink ();   // otherwise a button could be missed between
2314                         return;                                 // the think tics
2315                 }
2316
2317                 //don't allow the player to turn around while game is paused!
2318                 if(timeout_status == TIMEOUT_ACTIVE) {
2319                         // FIXME turn this into CSQC stuff
2320                         self.v_angle = self.lastV_angle;
2321                         self.angles = self.lastV_angle;
2322                         self.fixangle = true;
2323                 }
2324
2325                 if(frametime)
2326                 {
2327                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2328                         {
2329                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2330                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2331                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2332
2333                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2334                                 {
2335                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2336                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2337                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2338                                 }
2339                         }
2340                         else
2341                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2342
2343                         player_powerups();
2344                 }
2345
2346                 if (self.deadflag != DEAD_NO)
2347                 {
2348                         if(self.personal && g_race_qualifying)
2349                         {
2350                                 if(time > self.respawn_time)
2351                                 {
2352                                         self.respawn_time = time + 1; // only retry once a second
2353                                         self.stat_respawn_time = self.respawn_time;
2354                                         respawn();
2355                                         self.impulse = 141;
2356                                 }
2357                         }
2358                         else
2359                         {
2360                                 float button_pressed;
2361                                 if(frametime)
2362                                         player_anim();
2363                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2364
2365                                 if (self.deadflag == DEAD_DYING)
2366                                 {
2367                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2368                                                 self.deadflag = DEAD_RESPAWNING;
2369                                         else if(!button_pressed)
2370                                                 self.deadflag = DEAD_DEAD;
2371                                 }
2372                                 else if (self.deadflag == DEAD_DEAD)
2373                                 {
2374                                         if(button_pressed)
2375                                                 self.deadflag = DEAD_RESPAWNABLE;
2376                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2377                                                 self.deadflag = DEAD_RESPAWNING;
2378                                 }
2379                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2380                                 {
2381                                         if(!button_pressed)
2382                                                 self.deadflag = DEAD_RESPAWNING;
2383                                 }
2384                                 else if (self.deadflag == DEAD_RESPAWNING)
2385                                 {
2386                                         if(time > self.respawn_time)
2387                                         {
2388                                                 self.respawn_time = time + 1; // only retry once a second
2389                                                 self.respawn_time_max = self.respawn_time;
2390                                                 respawn();
2391                                         }
2392                                 }
2393
2394                                 ShowRespawnCountdown();
2395
2396                                 if(self.respawn_flags & RESPAWN_SILENT)
2397                                         self.stat_respawn_time = 0;
2398                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2399                                         self.stat_respawn_time = self.respawn_time_max;
2400                                 else
2401                                         self.stat_respawn_time = self.respawn_time;
2402                         }
2403
2404                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2405                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2406                                 self.stat_respawn_time *= -1;
2407
2408                         return;
2409                 }
2410
2411                 self.prevorigin = self.origin;
2412
2413                 float do_crouch = self.BUTTON_CROUCH;
2414                 if(self.hook.state)
2415                         do_crouch = 0;
2416                 if(self.vehicle)
2417                         do_crouch = 0;
2418                 if(self.frozen)
2419                         do_crouch = 0;
2420
2421                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2422                 // It cannot be predicted by the engine!
2423                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2424                         do_crouch = 0;
2425
2426                 if (do_crouch)
2427                 {
2428                         if (!self.crouch)
2429                         {
2430                                 self.crouch = true;
2431                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2432                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2433                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2434                         }
2435                 }
2436                 else
2437                 {
2438                         if (self.crouch)
2439                         {
2440                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2441                                 if (!trace_startsolid)
2442                                 {
2443                                         self.crouch = false;
2444                                         self.view_ofs = PL_VIEW_OFS;
2445                                         setsize (self, PL_MIN, PL_MAX);
2446                                 }
2447                         }
2448                 }
2449
2450                 FixPlayermodel();
2451
2452                 GrapplingHookFrame();
2453
2454                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2455                 //if(frametime)
2456                 {
2457                         self.items &= ~self.items_added;
2458
2459                         W_WeaponFrame();
2460
2461                         self.items_added = 0;
2462                         if(self.items & IT_JETPACK)
2463                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2464                                         self.items_added |= IT_FUEL;
2465
2466                         self.items |= self.items_added;
2467                 }
2468
2469                 player_regen();
2470
2471                 // WEAPONTODO: Add a weapon request for this
2472                 // rot vortex charge to the charge limit
2473                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2474                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2475
2476                 if(frametime)
2477                         player_anim();
2478
2479                 // secret status
2480                 secrets_setstatus();
2481
2482                 // monsters status
2483                 monsters_setstatus();
2484
2485                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2486
2487                 //self.angles_y=self.v_angle_y + 90;   // temp
2488         } else if(gameover) {
2489                 if (intermission_running)
2490                         IntermissionThink ();   // otherwise a button could be missed between
2491                 return;
2492         } else if(IS_OBSERVER(self)) {
2493                 ObserverThink();
2494         } else if(IS_SPEC(self)) {
2495                 SpectatorThink();
2496         }
2497
2498         // WEAPONTODO: Add weapon request for this
2499         if(!zoomstate_set)
2500                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2501
2502         float oldspectatee_status;
2503         oldspectatee_status = self.spectatee_status;
2504         if(IS_SPEC(self))
2505                 self.spectatee_status = num_for_edict(self.enemy);
2506         else if(IS_OBSERVER(self))
2507                 self.spectatee_status = num_for_edict(self);
2508         else
2509                 self.spectatee_status = 0;
2510         if(self.spectatee_status != oldspectatee_status)
2511         {
2512                 ClientData_Touch(self);
2513         }
2514
2515         if(self.teamkill_soundtime)
2516         if(time > self.teamkill_soundtime)
2517         {
2518                 self.teamkill_soundtime = 0;
2519
2520                 entity oldpusher, oldself;
2521
2522                 oldself = self; self = self.teamkill_soundsource;
2523                 oldpusher = self.pusher; self.pusher = oldself;
2524
2525                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2526
2527                 self.pusher = oldpusher;
2528                 self = oldself;
2529         }
2530
2531         if(self.taunt_soundtime)
2532         if(time > self.taunt_soundtime)
2533         {
2534                 self.taunt_soundtime = 0;
2535                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2536         }
2537
2538         target_voicescript_next(self);
2539
2540         // WEAPONTODO: Move into weaponsystem somehow
2541         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2542         if(!self.weapon)
2543                 self.clip_load = self.clip_size = 0;
2544 }
2545
2546 /*
2547 =============
2548 PlayerPostThink
2549
2550 Called every frame for each client after the physics are run
2551 =============
2552 */
2553 .float idlekick_lasttimeleft;
2554 void PlayerPostThink (void)
2555 {
2556         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2557         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2558         {
2559                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2560                 {
2561                         if(self.idlekick_lasttimeleft)
2562                         {
2563                                 self.idlekick_lasttimeleft = 0;
2564                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2565                         }
2566                 }
2567                 else
2568                 {
2569                         float timeleft;
2570                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2571                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2572                         {
2573                                 if(!self.idlekick_lasttimeleft)
2574                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2575                         }
2576                         if(timeleft <= 0)
2577                         {
2578                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2579                                 dropclient(self);
2580                                 return;
2581                         }
2582                         else if(timeleft <= 10)
2583                         {
2584                                 if(timeleft != self.idlekick_lasttimeleft)
2585                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2586                                 self.idlekick_lasttimeleft = timeleft;
2587                         }
2588                 }
2589         }
2590
2591 #ifdef TETRIS
2592         if(self.impulse == 100)
2593                 ImpulseCommands();
2594         if (!TetrisPostFrame())
2595         {
2596 #endif
2597
2598         CheatFrame();
2599
2600         //CheckPlayerJump();
2601
2602         if(IS_PLAYER(self)) {
2603                 CheckRules_Player();
2604                 UpdateChatBubble();
2605                 if (self.impulse)
2606                         ImpulseCommands();
2607                 if (intermission_running)
2608                         return;         // intermission or finale
2609                 GetPressedKeys();
2610         }
2611
2612 #ifdef TETRIS
2613         }
2614 #endif
2615
2616         /*
2617         float i;
2618         for(i = 0; i < 1000; ++i)
2619         {
2620                 vector end;
2621                 end = self.origin + '0 0 1024' + 512 * randomvec();
2622                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2623                 if(trace_fraction < 1)
2624                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2625                 {
2626                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2627                         break;
2628                 }
2629         }
2630         */
2631
2632         if(self.waypointsprite_attachedforcarrier)
2633                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2634
2635         playerdemo_write();
2636
2637         CSQCMODEL_AUTOUPDATE();
2638 }