ClientKill_TeamChange: target team -2 now means spectator
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(autocvar_spawn_debugview)
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > autocvar_g_spawn_furthest)
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(autocvar_spawn_debugview)
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(autocvar_spawn_debug)
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(autocvar_sv_servermodelsonly)
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602         MUTATOR_CALLHOOK(MakePlayerObserver);
603
604         Portal_ClearAll(self);
605
606         if(self.alivetime)
607         {
608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
609                 self.alivetime = 0;
610         }
611
612         if(self.flagcarried)
613                 DropFlag(self.flagcarried, world, world);
614
615         if(self.ballcarried && g_nexball)
616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
617
618         WaypointSprite_PlayerDead();
619
620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
622
623         if(self.killcount != -666) {
624                 if(g_lms) {
625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
627                         else
628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
629                 } else
630                         bprint ("^4", self.netname, "^4 is spectating now\n");
631
632                 if(self.just_joined == FALSE) {
633                         LogTeamchange(self.playerid, -1, 4);
634                 } else
635                         self.just_joined = FALSE;
636         }
637
638         PlayerScore_Clear(self); // clear scores when needed
639
640         accuracy_resend(self);
641
642         self.spectatortime = time;
643
644         self.classname = "observer";
645         self.iscreature = FALSE;
646         self.health = -666;
647         self.takedamage = DAMAGE_NO;
648         self.solid = SOLID_NOT;
649         self.movetype = MOVETYPE_NOCLIP;
650         self.flags = FL_CLIENT | FL_NOTARGET;
651         self.armorvalue = 666;
652         self.effects = 0;
653         self.armorvalue = autocvar_g_balance_armor_start;
654         self.pauserotarmor_finished = 0;
655         self.pauserothealth_finished = 0;
656         self.pauseregen_finished = 0;
657         self.damageforcescale = 0;
658         self.death_time = 0;
659         self.dead_frame = 0;
660         self.alpha = 0;
661         self.scale = 0;
662         self.fade_time = 0;
663         self.pain_frame = 0;
664         self.pain_finished = 0;
665         self.strength_finished = 0;
666         self.invincible_finished = 0;
667         self.pushltime = 0;
668         self.think = SUB_Null;
669         self.nextthink = 0;
670         self.hook_time = 0;
671         self.runes = 0;
672         self.deadflag = DEAD_NO;
673         self.angles = spot.angles;
674         self.angles_z = 0;
675         self.fixangle = TRUE;
676         self.crouch = FALSE;
677
678         self.view_ofs = PL_VIEW_OFS;
679         setorigin (self, spot.origin);
680         setsize (self, '0 0 0', '0 0 0');
681         self.prevorigin = self.origin;
682         self.items = 0;
683         self.weapons = 0;
684         self.model = "";
685         FixPlayermodel();
686         self.model = "";
687         self.modelindex = 0;
688         self.weapon = 0;
689         self.weaponmodel = "";
690         self.weaponentity = world;
691         self.exteriorweaponentity = world;
692         self.killcount = -666;
693         self.velocity = '0 0 0';
694         self.avelocity = '0 0 0';
695         self.punchangle = '0 0 0';
696         self.punchvector = '0 0 0';
697         self.oldvelocity = self.velocity;
698         self.fire_endtime = -1;
699
700         if(sv_loddistance1)
701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
702
703         if(g_arena)
704         {
705                 if(self.version_mismatch)
706                 {
707                         Spawnqueue_Unmark(self);
708                         Spawnqueue_Remove(self);
709                 }
710                 else
711                 {
712                         Spawnqueue_Insert(self);
713                 }
714         }
715         else if(g_lms)
716         {
717                 // Only if the player cannot play at all
718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
719                         self.frags = FRAGS_SPECTATOR;
720                 else
721                         self.frags = FRAGS_LMS_LOSER;
722         }
723         else
724                 self.frags = FRAGS_SPECTATOR;
725 }
726
727 float RestrictSkin(float s)
728 {
729         if(!teams_matter)
730                 return s;
731         if(s == 6)
732                 return 6;
733         return mod(s, 3);
734 }
735
736 void FixPlayermodel()
737 {
738         local string defaultmodel;
739         local float defaultskin, chmdl, oldskin;
740         local vector m1, m2;
741
742         defaultmodel = "";
743
744         if(autocvar_sv_defaultcharacter == 1) {
745                 defaultskin = 0;
746
747                 if(teams_matter)
748                 {
749                         string s;
750                         s = Team_ColorNameLowerCase(self.team);
751                         if(s != "neutral")
752                         {
753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
755                         }
756                 }
757
758                 if(defaultmodel == "")
759                 {
760                         defaultmodel = autocvar_sv_defaultplayermodel;
761                         defaultskin = autocvar_sv_defaultplayerskin;
762                 }
763         }
764
765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
766         {
767                 if(self.model != "")
768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
769                 self.model = ""; // force the != checks to return true
770         }
771
772         if(defaultmodel != "")
773         {
774                 if (defaultmodel != self.model)
775                 {
776                         m1 = self.mins;
777                         m2 = self.maxs;
778                         setmodel_lod (self, defaultmodel);
779                         setsize (self, m1, m2);
780                         chmdl = TRUE;
781                 }
782
783                 oldskin = self.skinindex;
784                 self.skinindex = defaultskin;
785         } else {
786                 if (self.playermodel != self.model || self.playermodel == "")
787                 {
788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
789                         m1 = self.mins;
790                         m2 = self.maxs;
791                         setmodel_lod (self, self.playermodel);
792                         setsize (self, m1, m2);
793                         chmdl = TRUE;
794                 }
795
796                 oldskin = self.skinindex;
797                 self.skinindex = RestrictSkin(stof(self.playerskin));
798         }
799
800         if(chmdl || oldskin != self.skinindex)
801                 self.species = player_getspecies(); // model or skin has changed
802
803         if(!teams_matter)
804                 if(strlen(autocvar_sv_defaultplayercolors))
805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
807 }
808
809 void PlayerTouchExplode(entity p1, entity p2)
810 {
811         vector org;
812         org = (p1.origin + p2.origin) * 0.5;
813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
814
815         te_explosion(org);
816
817         entity e;
818         e = spawn();
819         setorigin(e, org);
820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
821         remove(e);
822 }
823
824 /*
825 =============
826 PutClientInServer
827
828 Called when a client spawns in the server
829 =============
830 */
831 //void() ctf_playerchanged;
832 void PutClientInServer (void)
833 {
834         if(clienttype(self) == CLIENTTYPE_BOT)
835         {
836                 self.classname = "player";
837         }
838         else if(clienttype(self) == CLIENTTYPE_REAL)
839         {
840                 msg_entity = self;
841                 WriteByte(MSG_ONE, SVC_SETVIEW);
842                 WriteEntity(MSG_ONE, self);
843         }
844
845         // player is dead and becomes observer
846         // FIXME fix LMS scoring for new system
847         if(g_lms)
848         {
849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
850                         self.classname = "observer";
851         }
852
853         if(g_arena || (g_ca && !allowed_to_spawn))
854         if(!self.spawned)
855                 self.classname = "observer";
856
857         if(gameover)
858                 self.classname = "observer";
859
860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
861                 entity spot, oldself;
862                 float j;
863
864                 accuracy_resend(self);
865
866                 if(self.team < 0)
867                         JoinBestTeam(self, FALSE, TRUE);
868
869                 race_PreSpawn();
870
871                 spot = SelectSpawnPoint (FALSE);
872                 if(!spot)
873                 {
874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
875                         return; // spawn failed
876                 }
877
878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
879
880                 self.classname = "player";
881                 self.wasplayer = TRUE;
882                 self.iscreature = TRUE;
883                 self.movetype = MOVETYPE_WALK;
884                 self.solid = SOLID_SLIDEBOX;
885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
886                 if(autocvar_g_playerclip_collisions)
887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
890                 self.frags = FRAGS_PLAYER;
891                 if(independent_players)
892                         MAKE_INDEPENDENT_PLAYER(self);
893                 self.flags = FL_CLIENT;
894                 self.takedamage = DAMAGE_AIM;
895                 if(g_minstagib)
896                         self.effects = EF_FULLBRIGHT;
897                 else
898                         self.effects = 0;
899                 self.air_finished = time + 12;
900                 self.dmg = 2;
901                 if(autocvar_g_balance_nex_charge)
902                 {
903                         if(autocvar_g_balance_nex_secondary_chargepool)
904                                 self.nex_chargepool_ammo = 1;
905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
906                 }
907
908                 if(inWarmupStage)
909                 {
910                         self.ammo_shells = warmup_start_ammo_shells;
911                         self.ammo_nails = warmup_start_ammo_nails;
912                         self.ammo_rockets = warmup_start_ammo_rockets;
913                         self.ammo_cells = warmup_start_ammo_cells;
914                         self.ammo_fuel = warmup_start_ammo_fuel;
915                         self.health = warmup_start_health;
916                         self.armorvalue = warmup_start_armorvalue;
917                         self.weapons = warmup_start_weapons;
918                 }
919                 else
920                 {
921                         self.ammo_shells = start_ammo_shells;
922                         self.ammo_nails = start_ammo_nails;
923                         self.ammo_rockets = start_ammo_rockets;
924                         self.ammo_cells = start_ammo_cells;
925                         self.ammo_fuel = start_ammo_fuel;
926                         self.health = start_health;
927                         self.armorvalue = start_armorvalue;
928                         self.weapons = start_weapons;
929                 }
930
931                 if(g_weaponarena_random)
932                 {
933                         if(g_weaponarena_random_with_laser)
934                                 self.weapons &~= WEPBIT_LASER;
935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
936                         if(g_weaponarena_random_with_laser)
937                                 self.weapons |= WEPBIT_LASER;
938                 }
939
940                 self.items = start_items;
941                 self.jump_interval = time;
942
943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
948                 //extend the pause of rotting if client was reset at the beginning of the countdown
949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
950                         self.spawnshieldtime += game_starttime - time;
951                         self.pauserotarmor_finished += game_starttime - time;
952                         self.pauserothealth_finished += game_starttime - time;
953                         self.pauseregen_finished += game_starttime - time;
954                 }
955                 self.damageforcescale = 2;
956                 self.death_time = 0;
957                 self.dead_frame = 0;
958                 self.alpha = 0;
959                 self.scale = 0;
960                 self.fade_time = 0;
961                 self.pain_frame = 0;
962                 self.pain_finished = 0;
963                 self.strength_finished = 0;
964                 self.invincible_finished = 0;
965                 self.pushltime = 0;
966                 // players have no think function
967                 self.think = SUB_Null;
968                 self.nextthink = 0;
969                 self.hook_time = 0;
970                 self.dmg_team = 0;
971                 self.ballistics_density = autocvar_g_ballistics_density_player;
972
973                 self.metertime = 0;
974
975                 self.runes = 0;
976
977                 self.deadflag = DEAD_NO;
978
979                 self.angles = spot.angles;
980
981                 self.angles_z = 0; // never spawn tilted even if the spot says to
982                 self.fixangle = TRUE; // turn this way immediately
983                 self.velocity = '0 0 0';
984                 self.avelocity = '0 0 0';
985                 self.punchangle = '0 0 0';
986                 self.punchvector = '0 0 0';
987                 self.oldvelocity = self.velocity;
988                 self.fire_endtime = -1;
989
990                 msg_entity = self;
991                 WRITESPECTATABLE_MSG_ONE({
992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
994                 });
995
996                 if(sv_loddistance1)
997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
998
999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else if(self.killindicator_teamchange == -2)
1233                 PutObserverInServer();
1234         else
1235                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1236 }
1237
1238 void ClientKill_Now()
1239 {
1240         if(self.killindicator_teamchange)
1241                 ClientKill_Now_TeamChange();
1242
1243         // in any case:
1244         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1245
1246         if(self.killindicator)
1247         {
1248                 dprint("Cleaned up after a leaked kill indicator.\n");
1249                 remove(self.killindicator);
1250                 self.killindicator = world;
1251         }
1252 }
1253 void KillIndicator_Think()
1254 {
1255         if (!self.owner.modelindex)
1256         {
1257                 self.owner.killindicator = world;
1258                 remove(self);
1259                 return;
1260         }
1261
1262         if(self.cnt <= 0)
1263         {
1264                 self = self.owner;
1265                 ClientKill_Now(); // no oldself needed
1266                 return;
1267         }
1268         else
1269         {
1270                 if(self.cnt <= 10)
1271                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1272                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1273                 {
1274                         if(self.cnt <= 10)
1275                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1276                         if(self.owner.killindicator_teamchange)
1277                         {
1278                                 if(self.owner.killindicator_teamchange == -1)
1279                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1280                                 else if(self.owner.killindicator_teamchange == -2)
1281                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1282                                 else
1283                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1284                         }
1285                         else
1286                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1287                 }
1288                 self.nextthink = time + 1;
1289                 self.cnt -= 1;
1290         }
1291 }
1292
1293 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1294 {
1295         float killtime;
1296         entity e;
1297         killtime = autocvar_g_balance_kill_delay;
1298
1299         if(g_race_qualifying)
1300                 killtime = 0;
1301
1302         self.killindicator_teamchange = targetteam;
1303
1304         if(!self.killindicator)
1305         {
1306                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1307                 {
1308                         ClientKill_Now();
1309                 }
1310                 else
1311                 {
1312                         self.killindicator = spawn();
1313                         self.killindicator.owner = self;
1314                         self.killindicator.scale = 0.5;
1315                         setattachment(self.killindicator, self, "");
1316                         setorigin(self.killindicator, '0 0 52');
1317                         self.killindicator.think = KillIndicator_Think;
1318                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1319                         self.killindicator.cnt = ceil(killtime);
1320                         self.killindicator.count = bound(0, ceil(killtime), 10);
1321                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1322
1323                         for(e = world; (e = find(e, classname, "body")) != world; )
1324                         {
1325                                 if(e.enemy != self)
1326                                         continue;
1327                                 e.killindicator = spawn();
1328                                 e.killindicator.owner = e;
1329                                 e.killindicator.scale = 0.5;
1330                                 setattachment(e.killindicator, e, "");
1331                                 setorigin(e.killindicator, '0 0 52');
1332                                 e.killindicator.think = KillIndicator_Think;
1333                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1334                                 e.killindicator.cnt = ceil(killtime);
1335                         }
1336                         self.lip = 0;
1337                 }
1338         }
1339         if(self.killindicator)
1340         {
1341                 if(targetteam)
1342                         self.killindicator.colormod = TeamColor(targetteam);
1343                 else
1344                         self.killindicator.colormod = '0 0 0';
1345         }
1346 }
1347
1348 void ClientKill (void)
1349 {
1350         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1351         {
1352                 // do nothing
1353         }
1354     else if(g_freezetag && self.freezetag_frozen == 1)
1355     {
1356         // do nothing
1357     }
1358         else
1359                 ClientKill_TeamChange(0);
1360 }
1361
1362 void CTS_ClientKill_Think (void)
1363 {
1364         self = self.owner; // set self to the player to be killed
1365         sprint(self, "^1You were killed in order to prevent cheating!");
1366         ClientKill_Now();
1367 }
1368
1369 void CTS_ClientKill (float t) // silent version of ClientKill
1370 {
1371         entity e;
1372         e = spawn();
1373         e.owner = self;
1374         e.think = CTS_ClientKill_Think;
1375         e.nextthink = t;
1376 }
1377
1378 void DoTeamChange(float destteam)
1379 {
1380         float t, c0;
1381         if(!teams_matter)
1382         {
1383                 if(destteam >= 0)
1384                         SetPlayerColors(self, destteam);
1385                 return;
1386         }
1387         if(self.classname == "player")
1388         if(destteam == -1)
1389         {
1390                 CheckAllowedTeams(self);
1391                 t = FindSmallestTeam(self, TRUE);
1392                 switch(self.team)
1393                 {
1394                         case COLOR_TEAM1: c0 = c1; break;
1395                         case COLOR_TEAM2: c0 = c2; break;
1396                         case COLOR_TEAM3: c0 = c3; break;
1397                         case COLOR_TEAM4: c0 = c4; break;
1398                         default:          c0 = 999;
1399                 }
1400                 switch(t)
1401                 {
1402                         case 1:
1403                                 if(c0 > c1)
1404                                         destteam = COLOR_TEAM1;
1405                                 break;
1406                         case 2:
1407                                 if(c0 > c2)
1408                                         destteam = COLOR_TEAM2;
1409                                 break;
1410                         case 3:
1411                                 if(c0 > c3)
1412                                         destteam = COLOR_TEAM3;
1413                                 break;
1414                         case 4:
1415                                 if(c0 > c4)
1416                                         destteam = COLOR_TEAM4;
1417                                 break;
1418                 }
1419                 if(destteam == -1)
1420                         return;
1421         }
1422         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1423                 return;
1424         ClientKill_TeamChange(destteam);
1425 }
1426
1427 void FixClientCvars(entity e)
1428 {
1429         // send prediction settings to the client
1430         stuffcmd(e, "\nin_bindmap 0 0\n");
1431         if(g_race || g_cts)
1432                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1433         if(autocvar_g_antilag == 3) // client side hitscan
1434                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1435         if(sv_gentle)
1436                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1437         /*
1438          * we no longer need to stuff this. Remove this comment block if you feel
1439          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1440         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1441         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1442         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1443         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1444         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1445         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1446         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1447         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1448         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1449         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1450         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1451         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1452         stuffcmd(e, "cl_movement_edgefriction 1\n");
1453          */
1454 }
1455
1456 float PlayerInIDList(entity p, string idlist)
1457 {
1458         float n, i;
1459         string s;
1460
1461         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1462         if not(p.crypto_idfp)
1463                 return 0;
1464
1465         // this function allows abbreviated player IDs too!
1466         n = tokenize_console(idlist);
1467         for(i = 0; i < n; ++i)
1468         {
1469                 s = argv(i);
1470                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1471                         return 1;
1472         }
1473
1474         return 0;
1475 }
1476
1477 /*
1478 =============
1479 ClientConnect
1480
1481 Called when a client connects to the server
1482 =============
1483 */
1484 //void ctf_clientconnect();
1485 string ColoredTeamName(float t);
1486 void DecodeLevelParms (void);
1487 //void dom_player_join_team(entity pl);
1488 void ClientConnect (void)
1489 {
1490         float t;
1491
1492         if(self.flags & FL_CLIENT)
1493         {
1494                 print("Warning: ClientConnect, but already connected!\n");
1495                 return;
1496         }
1497
1498         if(Ban_MaybeEnforceBan(self))
1499                 return;
1500
1501         DecodeLevelParms();
1502
1503 #ifdef WATERMARK
1504         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1505 #endif
1506
1507         self.classname = "player_joining";
1508
1509         self.flags = FL_CLIENT;
1510         self.version_nagtime = time + 10 + random() * 10;
1511
1512         if(player_count<0)
1513         {
1514                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1515                 player_count = 0;
1516         }
1517
1518         PlayerScore_Attach(self);
1519         ClientData_Attach();
1520         accuracy_init(self);
1521
1522         bot_clientconnect();
1523
1524         playerdemo_init();
1525
1526         anticheat_init();
1527         
1528         race_PreSpawnObserver();
1529
1530         //if(g_domination)
1531         //      dom_player_join_team(self);
1532
1533         // identify the right forced team
1534         if(autocvar_g_campaign)
1535         {
1536                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1537                 {
1538                         switch(autocvar_g_campaign_forceteam)
1539                         {
1540                                 case 1: self.team_forced = COLOR_TEAM1; break;
1541                                 case 2: self.team_forced = COLOR_TEAM2; break;
1542                                 case 3: self.team_forced = COLOR_TEAM3; break;
1543                                 case 4: self.team_forced = COLOR_TEAM4; break;
1544                                 default: self.team_forced = 0;
1545                         }
1546                 }
1547         }
1548         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1549                 self.team_forced = COLOR_TEAM1;
1550         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1551                 self.team_forced = COLOR_TEAM2;
1552         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1553                 self.team_forced = COLOR_TEAM3;
1554         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1555                 self.team_forced = COLOR_TEAM4;
1556         else if(autocvar_g_forced_team_otherwise == "red")
1557                 self.team_forced = COLOR_TEAM1;
1558         else if(autocvar_g_forced_team_otherwise == "blue")
1559                 self.team_forced = COLOR_TEAM2;
1560         else if(autocvar_g_forced_team_otherwise == "yellow")
1561                 self.team_forced = COLOR_TEAM3;
1562         else if(autocvar_g_forced_team_otherwise == "pink")
1563                 self.team_forced = COLOR_TEAM4;
1564         else if(autocvar_g_forced_team_otherwise == "spectate")
1565                 self.team_forced = -1;
1566         else if(autocvar_g_forced_team_otherwise == "spectator")
1567                 self.team_forced = -1;
1568         else
1569                 self.team_forced = 0;
1570
1571         if(!teams_matter)
1572                 if(self.team_forced > 0)
1573                         self.team_forced = 0;
1574
1575         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1576
1577         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1578                 self.classname = "observer";
1579         } else {
1580                 if(teams_matter)
1581                 {
1582                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1583                         {
1584                                 self.classname = "player";
1585                                 campaign_bots_may_start = 1;
1586                         }
1587                         else
1588                         {
1589                                 self.classname = "observer"; // do it anyway
1590                         }
1591                 }
1592                 else
1593                 {
1594                         self.classname = "player";
1595                         campaign_bots_may_start = 1;
1596                 }
1597         }
1598
1599         self.playerid = (playerid_last = playerid_last + 1);
1600
1601         if(autocvar_sv_eventlog)
1602                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1603
1604         LogTeamchange(self.playerid, self.team, 1);
1605
1606         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1607
1608         self.netname_previous = strzone(self.netname);
1609
1610         bprint("^4", self.netname, "^4 connected");
1611
1612         if(self.classname != "observer" && (g_domination || g_ctf))
1613                 bprint(" and joined the ", ColoredTeamName(self.team));
1614
1615         bprint("\n");
1616
1617         self.welcomemessage_time = 0;
1618
1619         stuffcmd(self, strcat(clientstuff, "\n"));
1620         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1621         stuffcmd(self, "cl_particles_reloadeffects\n");
1622
1623         FixClientCvars(self);
1624
1625         // spawnfunc_waypoint sprites
1626         WaypointSprite_InitClient(self);
1627
1628         // Wazat's grappling hook
1629         SetGrappleHookBindings();
1630
1631         // get autoswitch state from player when he toggles it
1632         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1633
1634         // get version info from player
1635         stuffcmd(self, "cmd clientversion $gameversion\n");
1636
1637         // get other cvars from player
1638         GetCvars(0);
1639
1640         // notify about available teams
1641         if(teams_matter)
1642         {
1643                 CheckAllowedTeams(self);
1644                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1645                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1646         }
1647         else
1648                 stuffcmd(self, "set _teams_available 0\n");
1649
1650         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1651
1652         if(g_arena || g_ca)
1653         {
1654                 self.classname = "observer";
1655                 if(g_arena)
1656                         Spawnqueue_Insert(self);
1657         }
1658         /*else if(g_ctf)
1659         {
1660                 ctf_clientconnect();
1661         }*/
1662
1663         if(teams_matter || radar_showennemies)
1664                 attach_entcs();
1665
1666         bot_relinkplayerlist();
1667
1668         self.spectatortime = time;
1669         if(blockSpectators)
1670         {
1671                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1672         }
1673
1674         self.jointime = time;
1675         self.allowedTimeouts = autocvar_sv_timeout_number;
1676
1677         if(clienttype(self) == CLIENTTYPE_REAL)
1678         {
1679                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1680                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1681         }
1682
1683         if(g_lms)
1684         {
1685                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1686                 {
1687                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1688                         self.frags = FRAGS_SPECTATOR;
1689                 }
1690         }
1691
1692         if(!sv_foginterval && world.fog != "")
1693                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1694
1695         SoundEntity_Attach(self);
1696
1697         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1698         {
1699                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1700                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1701         }
1702         else
1703                 self.hitplotfh = -1;
1704
1705         if(g_race || g_cts) {
1706                 string rr;
1707                 if(g_cts)
1708                         rr = CTS_RECORD;
1709                 else
1710                         rr = RACE_RECORD;
1711                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1712
1713                 msg_entity = self;
1714                 race_send_recordtime(MSG_ONE);
1715                 race_send_speedaward(MSG_ONE);
1716
1717                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1718                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1719                 race_send_speedaward_alltimebest(MSG_ONE);
1720
1721                 float i;
1722                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1723                         race_SendRankings(i, 0, 0, MSG_ONE);
1724                 }
1725         }
1726         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1727                 send_CSQC_teamnagger();
1728
1729         send_CSQC_cr_maxbullets(self);
1730
1731         CheatInitClient();
1732
1733         PlayerStats_AddPlayer(self);
1734 }
1735
1736 /*
1737 =============
1738 ClientDisconnect
1739
1740 Called when a client disconnects from the server
1741 =============
1742 */
1743 .entity chatbubbleentity;
1744 .entity teambubbleentity;
1745 void ReadyCount();
1746 void ClientDisconnect (void)
1747 {
1748         if not(self.flags & FL_CLIENT)
1749         {
1750                 print("Warning: ClientDisconnect without ClientConnect\n");
1751                 return;
1752         }
1753
1754         PlayerStats_AddGlobalInfo(self);
1755
1756         CheatShutdownClient();
1757
1758         if(self.hitplotfh >= 0)
1759         {
1760                 fclose(self.hitplotfh);
1761                 self.hitplotfh = -1;
1762         }
1763
1764         anticheat_report();
1765         anticheat_shutdown();
1766
1767         playerdemo_shutdown();
1768
1769         bot_clientdisconnect();
1770
1771         if(self.entcs)
1772                 detach_entcs();
1773
1774         if(autocvar_sv_eventlog)
1775                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1776         bprint ("^4",self.netname);
1777         bprint ("^4 disconnected\n");
1778
1779         SoundEntity_Detach(self);
1780
1781         DropAllRunes(self);
1782         MUTATOR_CALLHOOK(ClientDisconnect);
1783
1784         Portal_ClearAll(self);
1785
1786         if(self.flagcarried)
1787                 DropFlag(self.flagcarried, world, world);
1788         if(self.ballcarried && g_nexball)
1789                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1790
1791         // Here, everything has been done that requires this player to be a client.
1792
1793         self.flags &~= FL_CLIENT;
1794
1795         if (self.chatbubbleentity)
1796                 remove (self.chatbubbleentity);
1797
1798         if (self.teambubbleentity)
1799                 remove (self.teambubbleentity);
1800
1801         if (self.killindicator)
1802                 remove (self.killindicator);
1803
1804         WaypointSprite_PlayerGone();
1805
1806         bot_relinkplayerlist();
1807
1808         if(g_arena)
1809         {
1810                 Spawnqueue_Unmark(self);
1811                 Spawnqueue_Remove(self);
1812         }
1813
1814         accuracy_free(self);
1815         ClientData_Detach();
1816         PlayerScore_Detach(self);
1817
1818         if(self.netname_previous)
1819                 strunzone(self.netname_previous);
1820         if(self.clientstatus)
1821                 strunzone(self.clientstatus);
1822         if(self.weaponorder_byimpulse)
1823                 strunzone(self.weaponorder_byimpulse);
1824
1825         ClearPlayerSounds();
1826
1827         if(self.personal)
1828                 remove(self.personal);
1829
1830         self.playerid = 0;
1831         ReadyCount();
1832
1833         // free cvars
1834         GetCvars(-1);
1835 }
1836
1837 .float BUTTON_CHAT;
1838 void ChatBubbleThink()
1839 {
1840         self.nextthink = time;
1841         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1842         {
1843                 if(self.owner) // but why can that ever be world?
1844                         self.owner.chatbubbleentity = world;
1845                 remove(self);
1846                 return;
1847         }
1848         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1849 #ifdef TETRIS
1850                 || self.owner.tetris_on
1851 #endif
1852         )
1853                 self.model = self.mdl;
1854         else
1855                 self.model = "";
1856 };
1857
1858 void UpdateChatBubble()
1859 {
1860         if (!self.modelindex)
1861                 return;
1862         // spawn a chatbubble entity if needed
1863         if (!self.chatbubbleentity)
1864         {
1865                 self.chatbubbleentity = spawn();
1866                 self.chatbubbleentity.owner = self;
1867                 self.chatbubbleentity.exteriormodeltoclient = self;
1868                 self.chatbubbleentity.think = ChatBubbleThink;
1869                 self.chatbubbleentity.nextthink = time;
1870                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1871                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1872                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1873                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1874                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1875                 self.chatbubbleentity.model = "";
1876                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1877         }
1878 }
1879
1880
1881 void TeamBubbleThink()
1882 {
1883         self.nextthink = time;
1884         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1885         {
1886                 if(self.owner) // but why can that ever be world?
1887                         self.owner.teambubbleentity = world;
1888                 remove(self);
1889                 return;
1890         }
1891 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1892         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1893                 self.model = "";
1894         else
1895                 self.model = self.mdl;
1896
1897 };
1898
1899 float TeamBubble_customizeentityforclient()
1900 {
1901         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1902 }
1903
1904 void UpdateTeamBubble()
1905 {
1906         if (!self.modelindex || !teams_matter)
1907                 return;
1908         // spawn a teambubble entity if needed
1909         if (!self.teambubbleentity && teams_matter)
1910         {
1911                 self.teambubbleentity = spawn();
1912                 self.teambubbleentity.owner = self;
1913                 self.teambubbleentity.exteriormodeltoclient = self;
1914                 self.teambubbleentity.think = TeamBubbleThink;
1915                 self.teambubbleentity.nextthink = time;
1916                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1917 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1918                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1919                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1920                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1921                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1922                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1923                 self.teambubbleentity.effects = EF_LOWPRECISION;
1924         }
1925 }
1926
1927 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1928 // added to the model skins
1929 /*void UpdateColorModHack()
1930 {
1931         local float c;
1932         c = self.clientcolors & 15;
1933         // LordHavoc: only bothering to support white, green, red, yellow, blue
1934              if (!teams_matter) self.colormod = '0 0 0';
1935         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1936         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1937         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1938         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1939         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1940         else self.colormod = '1 1 1';
1941 };*/
1942
1943 .float oldcolormap;
1944 void respawn(void)
1945 {
1946         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1947         {
1948                 self.solid = SOLID_NOT;
1949                 self.takedamage = DAMAGE_NO;
1950                 self.movetype = MOVETYPE_FLY;
1951                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1952                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1953                 self.effects |= EF_ADDITIVE;
1954                 self.oldcolormap = self.colormap;
1955                 self.colormap = 512;
1956                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1957                 if(autocvar_g_respawn_ghosts_maxtime)
1958                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1959         }
1960
1961         CopyBody(1);
1962         self.effects |= EF_NODRAW; // prevent another CopyBody
1963         if(self.oldcolormap)
1964         {
1965                 self.colormap = self.oldcolormap;
1966                 self.oldcolormap = 0;
1967         }
1968         PutClientInServer();
1969 }
1970
1971 void play_countdown(float finished, string samp)
1972 {
1973         if(clienttype(self) == CLIENTTYPE_REAL)
1974                 if(floor(finished - time - frametime) != floor(finished - time))
1975                         if(finished - time < 6)
1976                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1977 }
1978
1979 /**
1980  * When sv_timeout is used this function returs strings like
1981  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1982  * Called by centerprint functions
1983  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1984  */
1985 string getTimeoutText(float addOneSecond) {
1986         if (!autocvar_sv_timeout || !timeoutStatus)
1987                 return "";
1988
1989         local string retStr;
1990         if (timeoutStatus == 1) {
1991                 if (addOneSecond == 1) {
1992                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1993                 }
1994                 else {
1995                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1996                 }
1997                 return retStr;
1998         }
1999         else if (timeoutStatus == 2) {
2000                 if (addOneSecond) {
2001                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2002                         //don't show messages like "Timeout ends in 0 seconds"...
2003                         if ((remainingTimeoutTime + 1) > 0)
2004                                 return retStr;
2005                         else
2006                                 return "";
2007                 }
2008                 else {
2009                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2010                         //don't show messages like "Timeout ends in 0 seconds"...
2011                         if (remainingTimeoutTime > 0)
2012                                 return retStr;
2013                         else
2014                                 return "";
2015                 }
2016         }
2017         else return "";
2018 }
2019
2020 void player_powerups (void)
2021 {
2022         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2023         olditems = self.items;
2024         
2025         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2026         {
2027                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2028                 self.modelflags |= MF_ROCKET;
2029         }
2030         else
2031         {
2032                 SoundEntity_StopSound(self, CHAN_PLAYER);
2033                 self.modelflags &~= MF_ROCKET;
2034         }
2035
2036         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2037
2038         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2039                 return;
2040         
2041         Fire_ApplyDamage(self);
2042         Fire_ApplyEffect(self);
2043
2044         if (g_minstagib)
2045         {
2046                 self.effects |= EF_FULLBRIGHT;
2047
2048                 if (self.items & IT_STRENGTH)
2049                 {
2050                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2051                         if (time > self.strength_finished)
2052                         {
2053                                 self.alpha = default_player_alpha;
2054                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2055                                 self.items &~= IT_STRENGTH;
2056                                 sprint(self, "^3Invisibility has worn off\n");
2057                         }
2058                 }
2059                 else
2060                 {
2061                         if (time < self.strength_finished)
2062                         {
2063                                 self.alpha = g_minstagib_invis_alpha;
2064                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2065                                 self.items |= IT_STRENGTH;
2066                                 sprint(self, "^3You are invisible\n");
2067                         }
2068                 }
2069
2070                 if (self.items & IT_INVINCIBLE)
2071                 {
2072                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2073                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2074                         {
2075                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2076                                 sprint(self, "^3Speed has worn off\n");
2077                         }
2078                 }
2079                 else
2080                 {
2081                         if (time < self.invincible_finished)
2082                         {
2083                                 self.items = self.items | IT_INVINCIBLE;
2084                                 sprint(self, "^3You are on speed\n");
2085                         }
2086                 }
2087         }
2088         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2089         {
2090                 if (self.items & IT_STRENGTH)
2091                 {
2092                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2093                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2094                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2095                         {
2096                                 self.items = self.items - (self.items & IT_STRENGTH);
2097                                 sprint(self, "^3Strength has worn off\n");
2098                         }
2099                 }
2100                 else
2101                 {
2102                         if (time < self.strength_finished)
2103                         {
2104                                 self.items = self.items | IT_STRENGTH;
2105                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2106                         }
2107                 }
2108                 if (self.items & IT_INVINCIBLE)
2109                 {
2110                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2111                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2112                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2113                         {
2114                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2115                                 sprint(self, "^3Shield has worn off\n");
2116                         }
2117                 }
2118                 else
2119                 {
2120                         if (time < self.invincible_finished)
2121                         {
2122                                 self.items = self.items | IT_INVINCIBLE;
2123                                 sprint(self, "^3Shield surrounds you\n");
2124                         }
2125                 }
2126
2127                 if(autocvar_g_nodepthtestplayers)
2128                         self.effects = self.effects | EF_NODEPTHTEST;
2129
2130                 if(autocvar_g_fullbrightplayers)
2131                         self.effects = self.effects | EF_FULLBRIGHT;
2132
2133                 // midair gamemode: damage only while in the air
2134                 // if in midair mode, being on ground grants temporary invulnerability
2135                 // (this is so that multishot weapon don't clear the ground flag on the
2136                 // first damage in the frame, leaving the player vulnerable to the
2137                 // remaining hits in the same frame)
2138                 if (self.flags & FL_ONGROUND)
2139                 if (g_midair)
2140                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2141
2142                 if (time >= game_starttime)
2143                 if (time < self.spawnshieldtime)
2144                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2145         }
2146         
2147         MUTATOR_CALLHOOK(PlayerPowerups);
2148 }
2149
2150 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2151 {
2152         if(current > stable)
2153                 return current;
2154         else if(current > stable - 0.25) // when close enough, "snap"
2155                 return stable;
2156         else
2157                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2158 }
2159
2160 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2161 {
2162         if(current < stable)
2163                 return current;
2164         else if(current < stable + 0.25) // when close enough, "snap"
2165                 return stable;
2166         else
2167                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2168 }
2169
2170 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2171 {
2172         if(current > rotstable)
2173         {
2174                 if(rotframetime > 0)
2175                 {
2176                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2177                         current = max(rotstable, current - rotlinear * rotframetime);
2178                 }
2179         }
2180         else if(current < regenstable)
2181         {
2182                 if(regenframetime > 0)
2183                 {
2184                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2185                         current = min(regenstable, current + regenlinear * regenframetime);
2186                 }
2187         }
2188
2189         if(current > limit)
2190                 current = limit;
2191
2192         return current;
2193 }
2194
2195 void player_regen (void)
2196 {
2197         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2198         maxh = autocvar_g_balance_health_rotstable;
2199         maxa = autocvar_g_balance_armor_rotstable;
2200         maxf = autocvar_g_balance_fuel_rotstable;
2201         minh = autocvar_g_balance_health_regenstable;
2202         mina = autocvar_g_balance_armor_regenstable;
2203         minf = autocvar_g_balance_fuel_regenstable;
2204         limith = autocvar_g_balance_health_limit;
2205         limita = autocvar_g_balance_armor_limit;
2206         limitf = autocvar_g_balance_fuel_limit;
2207
2208         max_mod = regen_mod = rot_mod = limit_mod = 1;
2209
2210         if (self.runes & RUNE_REGEN)
2211         {
2212                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2213                 {
2214                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2215                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2216                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2217                 }
2218                 else
2219                 {
2220                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2221                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2222                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2223                 }
2224         }
2225         else if (self.runes & CURSE_VENOM)
2226         {
2227                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2228                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2229                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2230                 else
2231                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2232                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2233                 //if (!self.runes & RUNE_REGEN)
2234                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2235         }
2236         maxh = maxh * max_mod;
2237         //maxa = maxa * max_mod;
2238         //maxf = maxf * max_mod;
2239         minh = minh * max_mod;
2240         //mina = mina * max_mod;
2241         //minf = minf * max_mod;
2242         limith = limith * limit_mod;
2243         limita = limita * limit_mod;
2244         //limitf = limitf * limit_mod;
2245
2246         if(g_lms && g_ca)
2247                 rot_mod = 0;
2248
2249         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2250         {
2251                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2252                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2253
2254                 // if player rotted to death...  die!
2255                 if(self.health < 1)
2256                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2257         }
2258
2259         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2260                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2261 }
2262
2263 float zoomstate_set;
2264 void SetZoomState(float z)
2265 {
2266         if(z != self.zoomstate)
2267         {
2268                 self.zoomstate = z;
2269                 ClientData_Touch(self);
2270         }
2271         zoomstate_set = 1;
2272 }
2273
2274 void GetPressedKeys(void) {
2275         MUTATOR_CALLHOOK(GetPressedKeys);
2276         if (self.movement_x > 0) // get if movement keys are pressed
2277         {       // forward key pressed
2278                 self.pressedkeys |= KEY_FORWARD;
2279                 self.pressedkeys &~= KEY_BACKWARD;
2280         }
2281         else if (self.movement_x < 0)
2282         {       // backward key pressed
2283                 self.pressedkeys |= KEY_BACKWARD;
2284                 self.pressedkeys &~= KEY_FORWARD;
2285         }
2286         else
2287         {       // no x input
2288                 self.pressedkeys &~= KEY_FORWARD;
2289                 self.pressedkeys &~= KEY_BACKWARD;
2290         }
2291
2292         if (self.movement_y > 0)
2293         {       // right key pressed
2294                 self.pressedkeys |= KEY_RIGHT;
2295                 self.pressedkeys &~= KEY_LEFT;
2296         }
2297         else if (self.movement_y < 0)
2298         {       // left key pressed
2299                 self.pressedkeys |= KEY_LEFT;
2300                 self.pressedkeys &~= KEY_RIGHT;
2301         }
2302         else
2303         {       // no y input
2304                 self.pressedkeys &~= KEY_RIGHT;
2305                 self.pressedkeys &~= KEY_LEFT;
2306         }
2307
2308         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2309                 self.pressedkeys |= KEY_JUMP;
2310         else
2311                 self.pressedkeys &~= KEY_JUMP;
2312         if (self.BUTTON_CROUCH)
2313                 self.pressedkeys |= KEY_CROUCH;
2314         else
2315                 self.pressedkeys &~= KEY_CROUCH;
2316 }
2317
2318 /*
2319 ======================
2320 spectate mode routines
2321 ======================
2322 */
2323
2324 void SpectateCopy(entity spectatee) {
2325         other = spectatee;
2326         MUTATOR_CALLHOOK(SpectateCopy);
2327         self.armortype = spectatee.armortype;
2328         self.armorvalue = spectatee.armorvalue;
2329         self.ammo_cells = spectatee.ammo_cells;
2330         self.ammo_shells = spectatee.ammo_shells;
2331         self.ammo_nails = spectatee.ammo_nails;
2332         self.ammo_rockets = spectatee.ammo_rockets;
2333         self.ammo_fuel = spectatee.ammo_fuel;
2334         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2335         self.health = spectatee.health;
2336         self.impulse = 0;
2337         self.items = spectatee.items;
2338         self.last_pickup = spectatee.last_pickup;
2339         self.metertime = spectatee.metertime;
2340         self.strength_finished = spectatee.strength_finished;
2341         self.invincible_finished = spectatee.invincible_finished;
2342         self.pressedkeys = spectatee.pressedkeys;
2343         self.weapons = spectatee.weapons;
2344         self.switchweapon = spectatee.switchweapon;
2345         self.weapon = spectatee.weapon;
2346         self.punchangle = spectatee.punchangle;
2347         self.view_ofs = spectatee.view_ofs;
2348         self.v_angle = spectatee.v_angle;
2349         self.velocity = spectatee.velocity;
2350         self.dmg_take = spectatee.dmg_take;
2351         self.dmg_save = spectatee.dmg_save;
2352         self.dmg_inflictor = spectatee.dmg_inflictor;
2353         self.angles = spectatee.v_angle;
2354         self.fixangle = TRUE;
2355         setorigin(self, spectatee.origin);
2356         setsize(self, spectatee.mins, spectatee.maxs);
2357         SetZoomState(spectatee.zoomstate);
2358
2359         anticheat_spectatecopy(spectatee);
2360 }
2361
2362 float SpectateUpdate() {
2363         if(!self.enemy)
2364                 return 0;
2365
2366         if (self == self.enemy)
2367                 return 0;
2368
2369         if(self.enemy.classname != "player")
2370                 return 0;
2371
2372         SpectateCopy(self.enemy);
2373
2374         return 1;
2375 }
2376
2377 float SpectateNext() {
2378         other = find(self.enemy, classname, "player");
2379
2380         if (!other)
2381                 other = find(other, classname, "player");
2382
2383         if (other)
2384                 self.enemy = other;
2385
2386         if(self.enemy.classname == "player") {
2387                 msg_entity = self;
2388                 WriteByte(MSG_ONE, SVC_SETVIEW);
2389                 WriteEntity(MSG_ONE, self.enemy);
2390                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2391                 self.movetype = MOVETYPE_NONE;
2392                 accuracy_resend(self);
2393
2394                 if(!SpectateUpdate())
2395                         PutObserverInServer();
2396
2397                 return 1;
2398         } else {
2399                 return 0;
2400         }
2401 }
2402
2403 /*
2404 =============
2405 ShowRespawnCountdown()
2406
2407 Update a respawn countdown display.
2408 =============
2409 */
2410 void ShowRespawnCountdown()
2411 {
2412         float number;
2413         if(self.deadflag == DEAD_NO) // just respawned?
2414                 return;
2415         else
2416         {
2417                 number = ceil(self.death_time - time);
2418                 if(number <= 0)
2419                         return;
2420                 if(number <= self.respawn_countdown)
2421                 {
2422                         self.respawn_countdown = number - 1;
2423                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2424                                 AnnounceTo(self, strcat(ftos(number), ""));
2425                 }
2426         }
2427 }
2428
2429 void LeaveSpectatorMode()
2430 {
2431         if(isJoinAllowed()) {
2432                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2433                         self.classname = "player";
2434
2435                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2436                                 JoinBestTeam(self, FALSE, TRUE);
2437
2438                         if(autocvar_g_campaign)
2439                                 campaign_bots_may_start = 1;
2440
2441                         PutClientInServer();
2442
2443                         if(self.classname == "player")
2444                                 bprint ("^4", self.netname, "^4 is playing now\n");
2445
2446                         if(!autocvar_g_campaign)
2447                                 centerprint(self,""); // clear MOTD
2448
2449                         return;
2450                 } else {
2451                         if (g_ca && self.caplayer) {
2452                         }       // do nothing
2453                         else
2454                                 stuffcmd(self,"menu_showteamselect\n");
2455                         return;
2456                 }
2457         }
2458         else {
2459                 //player may not join because of g_maxplayers is set
2460                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2461         }
2462 }
2463
2464 /**
2465  * Determines whether the player is allowed to join. This depends on cvar
2466  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2467  * it checks whether the number of currently playing players exceeds g_maxplayers.
2468  * @return bool TRUE if the player is allowed to join, false otherwise
2469  */
2470 float isJoinAllowed() {
2471         if(self.team_forced < 0)
2472                 return FALSE; // forced spectators can never join
2473
2474         if (!autocvar_g_maxplayers)
2475                 return TRUE;
2476
2477         local entity e;
2478         local float currentlyPlaying;
2479         FOR_EACH_REALPLAYER(e) {
2480                 if(e.classname == "player")
2481                         currentlyPlaying += 1;
2482         }
2483         if(currentlyPlaying < autocvar_g_maxplayers)
2484                 return TRUE;
2485
2486         return FALSE;
2487 }
2488
2489 /**
2490  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2491  * g_maxplayers_spectator_blocktime seconds
2492  */
2493 void checkSpectatorBlock() {
2494         if(self.classname == "spectator" || self.classname == "observer") {
2495                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2496                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2497                         dropclient(self);
2498                 }
2499         }
2500 }
2501
2502 void ObserverThink()
2503 {
2504         if (self.flags & FL_JUMPRELEASED) {
2505                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2506                         self.welcomemessage_time = 0;
2507                         self.flags &~= FL_JUMPRELEASED;
2508                         self.flags |= FL_SPAWNING;
2509                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2510                         self.welcomemessage_time = 0;
2511                         self.flags &~= FL_JUMPRELEASED;
2512                         if(SpectateNext() == 1) {
2513                                 self.classname = "spectator";
2514                         }
2515                 }
2516         } else {
2517                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2518                         self.flags |= FL_JUMPRELEASED;
2519                         if(self.flags & FL_SPAWNING)
2520                         {
2521                                 self.flags &~= FL_SPAWNING;
2522                                 LeaveSpectatorMode();
2523                                 return;
2524                         }
2525                 }
2526         }
2527         PrintWelcomeMessage(self);
2528 }
2529
2530 void SpectatorThink()
2531 {
2532         if (self.flags & FL_JUMPRELEASED) {
2533                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2534                         self.welcomemessage_time = 0;
2535                         self.flags &~= FL_JUMPRELEASED;
2536                         self.flags |= FL_SPAWNING;
2537                 } else if(self.BUTTON_ATCK) {
2538                         self.welcomemessage_time = 0;
2539                         self.flags &~= FL_JUMPRELEASED;
2540                         if(SpectateNext() == 1) {
2541                                 self.classname = "spectator";
2542                         } else {
2543                                 self.classname = "observer";
2544                                 PutClientInServer();
2545                         }
2546                 } else if (self.BUTTON_ATCK2) {
2547                         self.welcomemessage_time = 0;
2548                         self.flags &~= FL_JUMPRELEASED;
2549                         self.classname = "observer";
2550                         PutClientInServer();
2551                 } else {
2552                         if(!SpectateUpdate())
2553                                 PutObserverInServer();
2554                 }
2555         } else {
2556                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2557                         self.flags |= FL_JUMPRELEASED;
2558                         if(self.flags & FL_SPAWNING)
2559                         {
2560                                 self.flags &~= FL_SPAWNING;
2561                                 LeaveSpectatorMode();
2562                                 return;
2563                         }
2564                 }
2565         }
2566
2567         PrintWelcomeMessage(self);
2568         self.flags |= FL_CLIENT | FL_NOTARGET;
2569 }
2570
2571 .float touchexplode_time;
2572
2573 /*
2574 =============
2575 PlayerPreThink
2576
2577 Called every frame for each client before the physics are run
2578 =============
2579 */
2580 void() ctf_setstatus;
2581 void() nexball_setstatus;
2582 .float items_added;
2583 void PlayerPreThink (void)
2584 {
2585         self.stat_game_starttime = game_starttime;
2586         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2587         self.stat_leadlimit = autocvar_leadlimit;
2588
2589         if(frametime)
2590         {
2591                 // physics frames: update anticheat stuff
2592                 anticheat_prethink();
2593         }
2594
2595         if(blockSpectators && frametime)
2596                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2597                 checkSpectatorBlock();
2598
2599         zoomstate_set = 0;
2600
2601         if(self.netname_previous != self.netname)
2602         {
2603                 if(autocvar_sv_eventlog)
2604                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2605                 if(self.netname_previous)
2606                         strunzone(self.netname_previous);
2607                 self.netname_previous = strzone(self.netname);
2608         }
2609
2610         // version nagging
2611         if(self.version_nagtime)
2612                 if(self.cvar_g_xonoticversion)
2613                         if(time > self.version_nagtime)
2614                         {
2615                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2616                                 {
2617                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2618                                         {
2619                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2620                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2621                                         }
2622                                         else
2623                                         {
2624                                                 float r;
2625                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2626                                                 if(r < 0)
2627                                                 {
2628                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2629                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2630                                                 }
2631                                                 else if(r > 0)
2632                                                 {
2633                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2634                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2635                                                 }
2636                                         }
2637                                 }
2638                                 self.version_nagtime = 0;
2639                         }
2640
2641         // GOD MODE info
2642         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2643         {
2644                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2645                 self.max_armorvalue = 0;
2646         }
2647
2648 #ifdef TETRIS
2649         if (TetrisPreFrame())
2650                 return;
2651 #endif
2652
2653         MUTATOR_CALLHOOK(PlayerPreThink);
2654
2655         if(self.classname == "player") {
2656 //              if(self.netname == "Wazat")
2657 //                      bprint(self.classname, "\n");
2658
2659                 CheckRules_Player();
2660
2661                 PrintWelcomeMessage(self);
2662
2663                 if (intermission_running)
2664                 {
2665                         IntermissionThink ();   // otherwise a button could be missed between
2666                         return;                                 // the think tics
2667                 }
2668
2669                 if(self.teleport_time)
2670                 if(time > self.teleport_time)
2671                 {
2672                         self.teleport_time = 0;
2673                         self.effects = self.effects - (self.effects & EF_NODRAW);
2674                 }
2675
2676                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2677                         UpdateSelectedPlayer();
2678
2679                 //don't allow the player to turn around while game is paused!
2680                 if(timeoutStatus == 2) {
2681                         self.v_angle = self.lastV_angle;
2682                         self.angles = self.lastV_angle;
2683                         self.fixangle = TRUE;
2684                 }
2685
2686                 if(frametime)
2687                 {
2688                         if(self.health <= 0 && autocvar_g_deathglow)
2689                         {
2690                                 if(self.glowmod_x > 0)
2691                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2692                                 else
2693                                         self.glowmod_x = -1;
2694                                 if(self.glowmod_y > 0)
2695                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2696                                 else
2697                                         self.glowmod_y = -1;
2698                                 if(self.glowmod_z > 0)
2699                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2700                                 else
2701                                         self.glowmod_z = -1;
2702                         }
2703                         else
2704                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2705                         player_powerups();
2706                 }
2707
2708                 if (self.deadflag != DEAD_NO)
2709                 {
2710                         float button_pressed, force_respawn;
2711                         if(self.personal && g_race_qualifying)
2712                         {
2713                                 if(time > self.death_time)
2714                                 {
2715                                         self.death_time = time + 1; // only retry once a second
2716                                         respawn();
2717                                         self.impulse = 141;
2718                                 }
2719                         }
2720                         else
2721                         {
2722                                 if(frametime)
2723                                         player_anim();
2724                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2725                                 force_respawn = (g_lms || (g_ca) || autocvar_g_forced_respawn);
2726                                 if (self.deadflag == DEAD_DYING)
2727                                 {
2728                                         if(force_respawn)
2729                                                 self.deadflag = DEAD_RESPAWNING;
2730                                         else if(!button_pressed)
2731                                                 self.deadflag = DEAD_DEAD;
2732                                 }
2733                                 else if (self.deadflag == DEAD_DEAD)
2734                                 {
2735                                         if(button_pressed)
2736                                                 self.deadflag = DEAD_RESPAWNABLE;
2737                                 }
2738                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2739                                 {
2740                                         if(!button_pressed)
2741                                                 self.deadflag = DEAD_RESPAWNING;
2742                                 }
2743                                 else if (self.deadflag == DEAD_RESPAWNING)
2744                                 {
2745                                         if(time > self.death_time)
2746                                         {
2747                                                 self.death_time = time + 1; // only retry once a second
2748                                                 respawn();
2749                                         }
2750                                 }
2751                                 ShowRespawnCountdown();
2752                         }
2753                         return;
2754                 }
2755
2756                 if(g_touchexplode)
2757                 if(time > self.touchexplode_time)
2758                 if(self.classname == "player")
2759                 if(self.deadflag == DEAD_NO)
2760                 if not(IS_INDEPENDENT_PLAYER(self))
2761                 FOR_EACH_PLAYER(other) if(self != other)
2762                 {
2763                         if(time > other.touchexplode_time)
2764                         if(other.deadflag == DEAD_NO)
2765                         if not(IS_INDEPENDENT_PLAYER(other))
2766                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2767                         {
2768                                 PlayerTouchExplode(self, other);
2769                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2770                         }
2771                 }
2772
2773                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2774                 {
2775                         vector dist;
2776
2777                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2778                         dist = self.prevorigin - self.origin;
2779                         dist_z = 0;
2780                         self.lms_traveled_distance += fabs(vlen(dist));
2781
2782                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2783                         {
2784                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2785                                 self.lms_traveled_distance = 0;
2786                         }
2787
2788                         if(time > self.lms_nextcheck)
2789                         {
2790                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2791                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2792                                 {
2793                                         centerprint(self, autocvar_g_lms_campcheck_message);
2794                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2795                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2796                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2797                                 }
2798                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2799                                 self.lms_traveled_distance = 0;
2800                         }
2801                 }
2802
2803                 self.prevorigin = self.origin;
2804
2805                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2806                 {
2807                         if (!self.crouch)
2808                         {
2809                                 self.crouch = TRUE;
2810                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2811                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2812                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2813                         }
2814                 }
2815                 else
2816                 {
2817                         if (self.crouch)
2818                         {
2819                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2820                                 if (!trace_startsolid)
2821                                 {
2822                                         self.crouch = FALSE;
2823                                         self.view_ofs = PL_VIEW_OFS;
2824                                         setsize (self, PL_MIN, PL_MAX);
2825                                 }
2826                         }
2827                 }
2828
2829                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2830                 {
2831                         if(self.bloodloss_timer < time)
2832                         {
2833                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2834                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2835                         }
2836                 }
2837
2838                 FixPlayermodel();
2839
2840                 GrapplingHookFrame();
2841
2842                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2843                 //if(frametime)
2844                 {
2845                         self.items &~= self.items_added;
2846
2847                         W_WeaponFrame();
2848
2849                         self.items_added = 0;
2850                         if(self.items & IT_JETPACK)
2851                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2852                                         self.items_added |= IT_FUEL;
2853
2854                         self.items |= self.items_added;
2855                 }
2856
2857                 player_regen();
2858
2859                 // rot nex charge to the charge limit
2860                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2861                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2862
2863                 if(frametime)
2864                         player_anim();
2865
2866                 if (g_minstagib)
2867                         minstagib_ammocheck();
2868
2869                 if(g_ctf)
2870                         ctf_setstatus();
2871
2872                 if(g_nexball)
2873                         nexball_setstatus();
2874
2875                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2876
2877                 //self.angles_y=self.v_angle_y + 90;   // temp
2878         } else if(gameover) {
2879                 if (intermission_running)
2880                         IntermissionThink ();   // otherwise a button could be missed between
2881                 return;
2882         } else if(self.classname == "observer") {
2883                 ObserverThink();
2884         } else if(self.classname == "spectator") {
2885                 SpectatorThink();
2886         }
2887
2888         if(!zoomstate_set)
2889                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2890
2891         float oldspectatee_status;
2892         oldspectatee_status = self.spectatee_status;
2893         if(self.classname == "spectator")
2894                 self.spectatee_status = num_for_edict(self.enemy);
2895         else if(self.classname == "observer")
2896                 self.spectatee_status = num_for_edict(self);
2897         else
2898                 self.spectatee_status = 0;
2899         if(self.spectatee_status != oldspectatee_status)
2900         {
2901                 ClientData_Touch(self);
2902                 if(g_race || g_cts)
2903                         race_InitSpectator();
2904         }
2905
2906         if(self.teamkill_soundtime)
2907         if(time > self.teamkill_soundtime)
2908         {
2909                 self.teamkill_soundtime = 0;
2910
2911                 entity oldpusher, oldself;
2912
2913                 oldself = self; self = self.teamkill_soundsource;
2914                 oldpusher = self.pusher; self.pusher = oldself;
2915
2916                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2917
2918                 self.pusher = oldpusher;
2919                 self = oldself;
2920         }
2921
2922         if(self.taunt_soundtime)
2923         if(time > self.taunt_soundtime)
2924         {
2925                 self.taunt_soundtime = 0;
2926                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2927         }
2928
2929         target_voicescript_next(self);
2930 }
2931
2932 float isInvisibleString(string s)
2933 {
2934         float i, n, c;
2935         s = strdecolorize(s);
2936         for((i = 0), (n = strlen(s)); i < n; ++i)
2937         {
2938                 c = str2chr(s, i);
2939                 switch(c)
2940                 {
2941                         case 0:
2942                         case 32: // space
2943                                 break;
2944                         case 192: // charmap space
2945                                 if (!autocvar_utf8_enable)
2946                                         break;
2947                                 return FALSE;
2948                         case 160: // space in unicode fonts
2949                         case 0xE000 + 192: // utf8 charmap space
2950                                 if (autocvar_utf8_enable)
2951                                         break;
2952                         default:
2953                                 return FALSE;
2954                 }
2955         }
2956         return TRUE;
2957 }
2958
2959 /*
2960 =============
2961 PlayerPostThink
2962
2963 Called every frame for each client after the physics are run
2964 =============
2965 */
2966 .float idlekick_lasttimeleft;
2967 .entity showheadshotbbox;
2968 void showheadshotbbox_think()
2969 {
2970         if(self.owner.showheadshotbbox != self)
2971         {
2972                 remove(self);
2973                 return;
2974         }
2975         self.nextthink = time;
2976         setorigin(self, self.owner.origin);
2977         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2978 }
2979 void PlayerPostThink (void)
2980 {
2981         // Savage: Check for nameless players
2982         if (isInvisibleString(self.netname)) {
2983                 self.netname = "Player";
2984                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2985         }
2986
2987         if(sv_maxidle && frametime)
2988         {
2989                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2990                 float timeleft;
2991                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2992                 if(timeleft <= 0)
2993                 {
2994                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2995                         AnnounceTo(self, "terminated");
2996                         dropclient(self);
2997                         return;
2998                 }
2999                 else if(timeleft <= 10)
3000                 {
3001                         if(timeleft != self.idlekick_lasttimeleft)
3002                         {
3003                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3004                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3005                         }
3006                 }
3007                 else
3008                 {
3009                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3010                 }
3011                 self.idlekick_lasttimeleft = timeleft;
3012         }
3013
3014 #ifdef TETRIS
3015         if(self.impulse == 100)
3016                 ImpulseCommands();
3017         if (TetrisPostFrame())
3018                 return;
3019 #endif
3020
3021         CheatFrame();
3022
3023         if(self.classname == "player") {
3024                 CheckRules_Player();
3025                 UpdateChatBubble();
3026                 UpdateTeamBubble();
3027                 if (self.impulse)
3028                         ImpulseCommands();
3029                 if (intermission_running)
3030                         return;         // intermission or finale
3031                 GetPressedKeys();
3032         } else if (self.classname == "observer") {
3033                 //do nothing
3034         } else if (self.classname == "spectator") {
3035                 //do nothing
3036         }
3037
3038         /*
3039         float i;
3040         for(i = 0; i < 1000; ++i)
3041         {
3042                 vector end;
3043                 end = self.origin + '0 0 1024' + 512 * randomvec();
3044                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3045                 if(trace_fraction < 1)
3046                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3047                 {
3048                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3049                         break;