qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76 void SetSpectator(entity player, entity spectatee);
  77
  78
  79 /*
  80 =============
  81 CheckPlayerModel
  82
  83 Checks if the argument string can be a valid playermodel.
  84 Returns a valid one in doubt.
  85 =============
  86 */
  87 string FallbackPlayerModel;
  88 string CheckPlayerModel(string plyermodel) {
  89         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  90         {
  91                 // note: we cannot summon Don Strunzone here, some player may
  92                 // still have the model string set. In case anyone manages how
  93                 // to change a cvar default, we'll have a small leak here.
  94                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  95         }
  96         // only in right path
  97         if( substring(plyermodel,0,14) != "models/player/")
  98                 return FallbackPlayerModel;
  99         // only good file extensions
 100         if(substring(plyermodel,-4,4) != ".zym")
 101         if(substring(plyermodel,-4,4) != ".dpm")
 102         if(substring(plyermodel,-4,4) != ".iqm")
 103         if(substring(plyermodel,-4,4) != ".md3")
 104         if(substring(plyermodel,-4,4) != ".psk")
 105                 return FallbackPlayerModel;
 106         // forbid the LOD models
 107         if(substring(plyermodel, -9,5) == "_lod1")
 108                 return FallbackPlayerModel;
 109         if(substring(plyermodel, -9,5) == "_lod2")
 110                 return FallbackPlayerModel;
 111         if(plyermodel != strtolower(plyermodel))
 112                 return FallbackPlayerModel;
 113         // also, restrict to server models
 114         if(autocvar_sv_servermodelsonly)
 115         {
 116                 if(!fexists(plyermodel))
 117                         return FallbackPlayerModel;
 118         }
 119         return plyermodel;
 120 }
 121
 122 void setplayermodel(entity e, string modelname)
 123 {
 124         precache_model(modelname);
 125         setmodel(e, modelname);
 126         player_setupanimsformodel();
 127         UpdatePlayerSounds();
 128 }
 129
 130 /*
 131 =============
 132 PutObserverInServer
 133
 134 putting a client as observer in the server
 135 =============
 136 */
 137 void FixPlayermodel();
 138 void PutObserverInServer (void)
 139 {
 140         entity  spot;
 141     self.hud = HUD_NORMAL;
 142
 143         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         self.frags = FRAGS_SPECTATOR;
 158
 159         MUTATOR_CALLHOOK(MakePlayerObserver);
 160
 161         Portal_ClearAll(self);
 162
 163         Unfreeze(self);
 164
 165         if(self.alivetime)
 166         {
 167                 if(!warmup_stage)
 168                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 169                 self.alivetime = 0;
 170         }
 171
 172         if(self.vehicle)
 173                 vehicles_exit(VHEF_RELESE);
 174
 175         WaypointSprite_PlayerDead();
 176
 177         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 178                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 179
 180         if(self.killcount != -666)
 181         {
 182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 183                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 185
 186                 if(self.just_joined == FALSE) {
 187                         LogTeamchange(self.playerid, -1, 4);
 188                 } else
 189                         self.just_joined = FALSE;
 190         }
 191
 192         PlayerScore_Clear(self); // clear scores when needed
 193
 194         accuracy_resend(self);
 195
 196         self.spectatortime = time;
 197
 198         self.classname = "observer";
 199         self.iscreature = FALSE;
 200         self.teleportable = TELEPORT_SIMPLE;
 201         self.damagedbycontents = FALSE;
 202         self.health = -666;
 203         self.takedamage = DAMAGE_NO;
 204         self.solid = SOLID_NOT;
 205         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 206         self.flags = FL_CLIENT | FL_NOTARGET;
 207         self.armorvalue = 666;
 208         self.effects = 0;
 209         self.armorvalue = autocvar_g_balance_armor_start;
 210         self.pauserotarmor_finished = 0;
 211         self.pauserothealth_finished = 0;
 212         self.pauseregen_finished = 0;
 213         self.damageforcescale = 0;
 214         self.death_time = 0;
 215         self.respawn_flags = 0;
 216         self.respawn_time = 0;
 217         self.stat_respawn_time = 0;
 218         self.alpha = 0;
 219         self.scale = 0;
 220         self.fade_time = 0;
 221         self.pain_frame = 0;
 222         self.pain_finished = 0;
 223         self.strength_finished = 0;
 224         self.invincible_finished = 0;
 225         self.superweapons_finished = 0;
 226         self.pushltime = 0;
 227         self.istypefrag = 0;
 228         self.think = func_null;
 229         self.nextthink = 0;
 230         self.hook_time = 0;
 231         self.deadflag = DEAD_NO;
 232         self.angles = spot.angles;
 233         self.angles_z = 0;
 234         self.fixangle = TRUE;
 235         self.crouch = FALSE;
 236         self.revival_time = 0;
 237
 238         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 239         self.prevorigin = self.origin;
 240         self.items = 0;
 241         self.weapons = '0 0 0';
 242         self.model = "";
 243         FixPlayermodel();
 244         setmodel(self, "null");
 245         self.drawonlytoclient = self;
 246
 247         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249
 250         self.weapon = 0;
 251         self.weaponname = "";
 252         self.switchingweapon = 0;
 253         self.weaponmodel = "";
 254         self.weaponentity = world;
 255         self.exteriorweaponentity = world;
 256         self.killcount = -666;
 257         self.velocity = '0 0 0';
 258         self.avelocity = '0 0 0';
 259         self.punchangle = '0 0 0';
 260         self.punchvector = '0 0 0';
 261         self.oldvelocity = self.velocity;
 262         self.fire_endtime = -1;
 263         self.event_damage = func_null;
 264 }
 265
 266 .float model_randomizer;
 267 void FixPlayermodel()
 268 {
 269         string defaultmodel;
 270         float defaultskin, chmdl, oldskin, n, i;
 271         vector m1, m2;
 272
 273         defaultmodel = "";
 274         defaultskin = 0;
 275         chmdl = FALSE;
 276
 277         if(autocvar_sv_defaultcharacter == 1)
 278         {
 279                 if(teamplay)
 280                 {
 281                         string s;
 282                         s = Static_Team_ColorName_Lower(self.team);
 283                         if(s != "neutral")
 284                         {
 285                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 286                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 287                         }
 288                 }
 289
 290                 if(defaultmodel == "")
 291                 {
 292                         defaultmodel = autocvar_sv_defaultplayermodel;
 293                         defaultskin = autocvar_sv_defaultplayerskin;
 294                 }
 295
 296                 n = tokenize_console(defaultmodel);
 297                 if(n > 0)
 298                 {
 299                         defaultmodel = argv(floor(n * self.model_randomizer));
 300                         // However, do NOT randomize if the player-selected model is in the list.
 301                         for (i = 0; i < n; ++i)
 302                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 303                                         defaultmodel = argv(i);
 304                 }
 305
 306                 i = strstrofs(defaultmodel, ":", 0);
 307                 if(i >= 0)
 308                 {
 309                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 310                         defaultmodel = substring(defaultmodel, 0, i);
 311                 }
 312         }
 313
 314         if(defaultmodel != "")
 315         {
 316                 if (defaultmodel != self.model)
 317                 {
 318                         m1 = self.mins;
 319                         m2 = self.maxs;
 320                         setplayermodel (self, defaultmodel);
 321                         setsize (self, m1, m2);
 322                         chmdl = TRUE;
 323                 }
 324
 325                 oldskin = self.skin;
 326                 self.skin = defaultskin;
 327         } else {
 328                 if (self.playermodel != self.model || self.playermodel == "")
 329                 {
 330                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 331                         m1 = self.mins;
 332                         m2 = self.maxs;
 333                         setplayermodel (self, self.playermodel);
 334                         setsize (self, m1, m2);
 335                         chmdl = TRUE;
 336                 }
 337
 338                 oldskin = self.skin;
 339                 self.skin = stof(self.playerskin);
 340         }
 341
 342         if(chmdl || oldskin != self.skin) // model or skin has changed
 343         {
 344                 self.species = player_getspecies(); // update species
 345                 UpdatePlayerSounds(); // update skin sounds
 346         }
 347
 348         if(!teamplay)
 349                 if(strlen(autocvar_sv_defaultplayercolors))
 350                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 351                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 352 }
 353
 354 /*
 355 =============
 356 PutClientInServer
 357
 358 Called when a client spawns in the server
 359 =============
 360 */
 361 void PutClientInServer (void)
 362 {
 363         if(IS_BOT_CLIENT(self))
 364                 self.classname = "player";
 365         else if(IS_REAL_CLIENT(self))
 366         {
 367                 msg_entity = self;
 368                 WriteByte(MSG_ONE, SVC_SETVIEW);
 369                 WriteEntity(MSG_ONE, self);
 370         }
 371
 372         SetSpectator(self, world);
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 spot = SelectSpawnPoint (FALSE);
 393                 if(!spot)
 394                 {
 395                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 396                         return; // spawn failed
 397                 }
 398
 399                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 400
 401                 if(self.vehicle)
 402                         vehicles_exit(VHEF_RELESE);
 403
 404                 self.classname = "player";
 405                 self.wasplayer = TRUE;
 406                 self.iscreature = TRUE;
 407                 self.teleportable = TELEPORT_NORMAL;
 408                 self.damagedbycontents = TRUE;
 409                 self.movetype = MOVETYPE_WALK;
 410                 self.solid = SOLID_SLIDEBOX;
 411                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 412                 if(autocvar_g_playerclip_collisions)
 413                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 414                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 415                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 416                 self.frags = FRAGS_PLAYER;
 417                 if(INDEPENDENT_PLAYERS)
 418                         MAKE_INDEPENDENT_PLAYER(self);
 419                 self.flags = FL_CLIENT;
 420                 if(autocvar__notarget)
 421                         self.flags |= FL_NOTARGET;
 422                 self.takedamage = DAMAGE_AIM;
 423                 self.effects = 0;
 424                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 425                 self.air_finished = time + 12;
 426                 self.dmg = 2;
 427                 if(WEP_CVAR(vortex, charge))
 428                 {
 429                         if(WEP_CVAR_SEC(vortex, chargepool))
 430                                 self.vortex_chargepool_ammo = 1;
 431                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 432                 }
 433
 434                 if(warmup_stage)
 435                 {
 436                         self.ammo_shells = warmup_start_ammo_shells;
 437                         self.ammo_nails = warmup_start_ammo_nails;
 438                         self.ammo_rockets = warmup_start_ammo_rockets;
 439                         self.ammo_cells = warmup_start_ammo_cells;
 440                         self.ammo_plasma = warmup_start_ammo_plasma;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = WARMUP_START_WEAPONS;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_plasma = start_ammo_plasma;
 453                         self.ammo_fuel = start_ammo_fuel;
 454                         self.health = start_health;
 455                         self.armorvalue = start_armorvalue;
 456                         self.weapons = start_weapons;
 457                 }
 458
 459                 if(self.weapons & WEPSET_SUPERWEAPONS)
 460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 461                 else
 462                         self.superweapons_finished = 0;
 463
 464                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 465                 {
 466                         if(g_weaponarena_random_with_blaster)
 467                                 self.weapons &= ~WEPSET_BLASTER;
 468                         W_RandomWeapons(self, g_weaponarena_random);
 469                         if(g_weaponarena_random_with_blaster)
 470                                 self.weapons |= WEPSET_BLASTER;
 471                 }
 472
 473                 self.items = start_items;
 474
 475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 480                 //extend the pause of rotting if client was reset at the beginning of the countdown
 481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 482                         self.spawnshieldtime += game_starttime - time;
 483                         self.pauserotarmor_finished += game_starttime - time;
 484                         self.pauserothealth_finished += game_starttime - time;
 485                         self.pauseregen_finished += game_starttime - time;
 486                 }
 487                 self.damageforcescale = 2;
 488                 self.death_time = 0;
 489                 self.respawn_flags = 0;
 490                 self.respawn_time = 0;
 491                 self.stat_respawn_time = 0;
 492                 self.scale = 0;
 493                 self.fade_time = 0;
 494                 self.pain_frame = 0;
 495                 self.pain_finished = 0;
 496                 self.strength_finished = 0;
 497                 self.invincible_finished = 0;
 498                 self.pushltime = 0;
 499                 // players have no think function
 500                 self.think = func_null;
 501                 self.nextthink = 0;
 502                 self.hook_time = 0;
 503                 self.dmg_team = 0;
 504                 self.ballistics_density = autocvar_g_ballistics_density_player;
 505
 506                 self.metertime = 0;
 507
 508                 self.deadflag = DEAD_NO;
 509
 510                 self.angles = spot.angles;
 511
 512                 self.angles_z = 0; // never spawn tilted even if the spot says to
 513                 if(IS_BOT_CLIENT(self))
 514                         self.v_angle = self.angles;
 515                 self.fixangle = TRUE; // turn this way immediately
 516                 self.velocity = '0 0 0';
 517                 self.avelocity = '0 0 0';
 518                 self.punchangle = '0 0 0';
 519                 self.punchvector = '0 0 0';
 520                 self.oldvelocity = self.velocity;
 521                 self.fire_endtime = -1;
 522                 self.revival_time = 0;
 523
 524                 entity spawnevent = spawn();
 525                 spawnevent.owner = self;
 526                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 527
 528                 // Cut off any still running player sounds.
 529                 stopsound(self, CH_PLAYER_SINGLE);
 530
 531                 self.model = "";
 532                 FixPlayermodel();
 533                 self.drawonlytoclient = world;
 534
 535                 self.crouch = FALSE;
 536                 self.view_ofs = PL_VIEW_OFS;
 537                 setsize (self, PL_MIN, PL_MAX);
 538                 self.spawnorigin = spot.origin;
 539                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 540                 // don't reset back to last position, even if new position is stuck in solid
 541                 self.oldorigin = self.origin;
 542                 self.prevorigin = self.origin;
 543                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 544                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 545         self.hud = HUD_NORMAL;
 546
 547                 self.event_damage = PlayerDamage;
 548
 549                 self.bot_attack = TRUE;
 550                 self.monster_attack = TRUE;
 551
 552                 self.spider_slowness = 0;
 553
 554                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 555
 556                 if(self.killcount == -666) {
 557                         PlayerScore_Clear(self);
 558                         self.killcount = 0;
 559                 }
 560
 561                 CL_SpawnWeaponentity();
 562                 self.alpha = default_player_alpha;
 563                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 564                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 565
 566                 self.speedrunning = FALSE;
 567
 568                 //stuffcmd(self, "chase_active 0");
 569                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 570
 571                 target_voicescript_clear(self);
 572
 573                 // reset fields the weapons may use
 574                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 575                 {
 576                         WEP_ACTION(j, WR_RESETPLAYER);
 577
 578                         // all weapons must be fully loaded when we spawn
 579                         entity e;
 580                         e = get_weaponinfo(j);
 581                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 582                                 self.(weapon_load[j]) = e.reloading_ammo;
 583                 }
 584
 585                 oldself = self;
 586                 self = spot;
 587                         activator = oldself;
 588                                 string s;
 589                                 s = self.target;
 590                                 self.target = string_null;
 591                                 SUB_UseTargets();
 592                                 self.target = s;
 593                         activator = world;
 594                 self = oldself;
 595
 596                 Unfreeze(self);
 597
 598                 spawn_spot = spot;
 599                 MUTATOR_CALLHOOK(PlayerSpawn);
 600
 601                 if(autocvar_spawn_debug)
 602                 {
 603                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 604                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 605                 }
 606
 607                 self.switchweapon = w_getbestweapon(self);
 608                 self.cnt = -1; // W_LastWeapon will not complain
 609                 self.weapon = 0;
 610                 self.weaponname = "";
 611                 self.switchingweapon = 0;
 612
 613                 if(!warmup_stage)
 614                         if(!self.alivetime)
 615                                 self.alivetime = time;
 616
 617                 antilag_clear(self);
 618         }
 619         else if(IS_OBSERVER(self))
 620         {
 621                 PutObserverInServer ();
 622         }
 623 }
 624
 625 .float ebouncefactor, ebouncestop; // electro's values
 626 // TODO do we need all these fields, or should we stop autodetecting runtime
 627 // changes and just have a console command to update this?
 628 float ClientInit_SendEntity(entity to, float sf)
 629 {
 630         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 631         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 640
 641         if(sv_foginterval && world.fog != "")
 642                 WriteString(MSG_ENTITY, world.fog);
 643         else
 644                 WriteString(MSG_ENTITY, "");
 645         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 646         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 647         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 648         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 649         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 650         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 651         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 652         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 653         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 654         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 655         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 656         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 657         return TRUE;
 658 }
 659
 660 void ClientInit_CheckUpdate()
 661 {
 662         self.nextthink = time;
 663         if(self.count != autocvar_g_balance_armor_blockpercent)
 664         {
 665                 self.count = autocvar_g_balance_armor_blockpercent;
 666                 self.SendFlags |= 1;
 667         }
 668         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 669         {
 670                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 671                 self.SendFlags |= 1;
 672         }
 673         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 674         {
 675                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 676                 self.SendFlags |= 1;
 677         }
 678         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 679         {
 680                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 681                 self.SendFlags |= 1;
 682         }
 683         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 684         {
 685                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 686                 self.SendFlags |= 1;
 687         }
 688 }
 689
 690 void ClientInit_Spawn()
 691 {
 692         entity o;
 693         entity e;
 694         e = spawn();
 695         e.classname = "clientinit";
 696         e.think = ClientInit_CheckUpdate;
 697         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 698
 699         o = self;
 700         self = e;
 701         ClientInit_CheckUpdate();
 702         self = o;
 703 }
 704
 705 /*
 706 =============
 707 SetNewParms
 708 =============
 709 */
 710 void SetNewParms (void)
 711 {
 712         // initialize parms for a new player
 713         parm1 = -(86400 * 366);
 714 }
 715
 716 /*
 717 =============
 718 SetChangeParms
 719 =============
 720 */
 721 void SetChangeParms (void)
 722 {
 723         // save parms for level change
 724         parm1 = self.parm_idlesince - time;
 725 }
 726
 727 /*
 728 =============
 729 DecodeLevelParms
 730 =============
 731 */
 732 void DecodeLevelParms (void)
 733 {
 734         // load parms
 735         self.parm_idlesince = parm1;
 736         if(self.parm_idlesince == -(86400 * 366))
 737                 self.parm_idlesince = time;
 738
 739         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 740         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 741 }
 742
 743 /*
 744 =============
 745 ClientKill
 746
 747 Called when a client types 'kill' in the console
 748 =============
 749 */
 750
 751 .float clientkill_nexttime;
 752 void ClientKill_Now_TeamChange()
 753 {
 754         if(self.killindicator_teamchange == -1)
 755         {
 756                 JoinBestTeam( self, FALSE, TRUE );
 757         }
 758         else if(self.killindicator_teamchange == -2)
 759         {
 760                 if(blockSpectators)
 761                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 762                 PutObserverInServer();
 763         }
 764         else
 765                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 766         self.killindicator_teamchange = 0;
 767 }
 768
 769 void ClientKill_Now()
 770 {
 771         if(self.vehicle)
 772         {
 773             vehicles_exit(VHEF_RELESE);
 774             if(!self.killindicator_teamchange)
 775             {
 776             self.vehicle_health = -1;
 777             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 778             }
 779         }
 780
 781         if(self.killindicator && !wasfreed(self.killindicator))
 782                 remove(self.killindicator);
 783
 784         self.killindicator = world;
 785
 786         if(self.killindicator_teamchange)
 787                 ClientKill_Now_TeamChange();
 788
 789         if(IS_PLAYER(self))
 790                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 791
 792         // now I am sure the player IS dead
 793 }
 794 void KillIndicator_Think()
 795 {
 796         if (gameover)
 797         {
 798                 self.owner.killindicator = world;
 799                 remove(self);
 800                 return;
 801         }
 802
 803         if (self.owner.alpha < 0 && !self.owner.vehicle)
 804         {
 805                 self.owner.killindicator = world;
 806                 remove(self);
 807                 return;
 808         }
 809
 810         if(self.cnt <= 0)
 811         {
 812                 self = self.owner;
 813                 ClientKill_Now(); // no oldself needed
 814                 return;
 815         }
 816     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 817     {
 818         self.nextthink = time + 1;
 819         self.cnt -= 1;
 820     }
 821         else
 822         {
 823                 if(self.cnt <= 10)
 824                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 825                 if(IS_REAL_CLIENT(self.owner))
 826                 {
 827                         if(self.cnt <= 10)
 828                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 829                 }
 830                 self.nextthink = time + 1;
 831                 self.cnt -= 1;
 832         }
 833 }
 834
 835 float clientkilltime;
 836 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 837 {
 838         float killtime;
 839         float starttime;
 840         entity e;
 841
 842         if (gameover)
 843                 return;
 844
 845         killtime = autocvar_g_balance_kill_delay;
 846
 847         if(g_race_qualifying || g_cts)
 848                 killtime = 0;
 849
 850     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 851     {
 852                 remove(self.killindicator);
 853                 self.killindicator = world;
 854
 855         ClientKill_Now(); // allow instant kill in this case
 856         return;
 857     }
 858
 859         self.killindicator_teamchange = targetteam;
 860
 861     if(!self.killindicator)
 862         {
 863                 if(self.deadflag == DEAD_NO)
 864                 {
 865                         killtime = max(killtime, self.clientkill_nexttime - time);
 866                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 867                 }
 868
 869                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 870                 {
 871                         ClientKill_Now();
 872                 }
 873                 else
 874                 {
 875                         starttime = max(time, clientkilltime);
 876
 877                         self.killindicator = spawn();
 878                         self.killindicator.owner = self;
 879                         self.killindicator.scale = 0.5;
 880                         setattachment(self.killindicator, self, "");
 881                         setorigin(self.killindicator, '0 0 52');
 882                         self.killindicator.think = KillIndicator_Think;
 883                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 884                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 885                         self.killindicator.cnt = ceil(killtime);
 886                         self.killindicator.count = bound(0, ceil(killtime), 10);
 887                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 888
 889                         for(e = world; (e = find(e, classname, "body")) != world; )
 890                         {
 891                                 if(e.enemy != self)
 892                                         continue;
 893                                 e.killindicator = spawn();
 894                                 e.killindicator.owner = e;
 895                                 e.killindicator.scale = 0.5;
 896                                 setattachment(e.killindicator, e, "");
 897                                 setorigin(e.killindicator, '0 0 52');
 898                                 e.killindicator.think = KillIndicator_Think;
 899                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 900                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 901                                 e.killindicator.cnt = ceil(killtime);
 902                         }
 903                         self.lip = 0;
 904                 }
 905         }
 906         if(self.killindicator)
 907         {
 908                 if(targetteam == 0) // just die
 909                 {
 910                         self.killindicator.colormod = '0 0 0';
 911                         if(IS_REAL_CLIENT(self))
 912                         if(self.killindicator.cnt > 0)
 913                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 914                 }
 915                 else if(targetteam == -1) // auto
 916                 {
 917                         self.killindicator.colormod = '0 1 0';
 918                         if(IS_REAL_CLIENT(self))
 919                         if(self.killindicator.cnt > 0)
 920                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 921                 }
 922                 else if(targetteam == -2) // spectate
 923                 {
 924                         self.killindicator.colormod = '0.5 0.5 0.5';
 925                         if(IS_REAL_CLIENT(self))
 926                         if(self.killindicator.cnt > 0)
 927                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 928                 }
 929                 else
 930                 {
 931                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 932                         if(IS_REAL_CLIENT(self))
 933                         if(self.killindicator.cnt > 0)
 934                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 935                 }
 936         }
 937
 938 }
 939
 940 void ClientKill (void)
 941 {
 942         if(gameover) return;
 943         if(self.player_blocked) return;
 944         if(self.frozen) return;
 945
 946         ClientKill_TeamChange(0);
 947 }
 948
 949 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 950 {
 951     e.killindicator = spawn();
 952     e.killindicator.owner = e;
 953     e.killindicator.think = KillIndicator_Think;
 954     e.killindicator.nextthink = time + (e.lip) * 0.05;
 955     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 956     e.killindicator.health = 1; // this is used to indicate that it should be silent
 957     e.lip = 0;
 958 }
 959
 960 void FixClientCvars(entity e)
 961 {
 962         // send prediction settings to the client
 963         stuffcmd(e, "\nin_bindmap 0 0\n");
 964         if(g_race || g_cts)
 965                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970         /*
 971          * we no longer need to stuff this. Remove this comment block if you feel
 972          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 973         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 974         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 975         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 978         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 980         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 981         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 983         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 984         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 985         stuffcmd(e, "cl_movement_edgefriction 1\n");
 986          */
 987 }
 988
 989 float PlayerInIDList(entity p, string idlist)
 990 {
 991         float n, i;
 992         string s;
 993
 994         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 995         if (!p.crypto_idfp)
 996                 return 0;
 997
 998         // this function allows abbreviated player IDs too!
 999         n = tokenize_console(idlist);
1000         for(i = 0; i < n; ++i)
1001         {
1002                 s = argv(i);
1003                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1004                         return 1;
1005         }
1006
1007         return 0;
1008 }
1009
1010 /*
1011 =============
1012 ClientConnect
1013
1014 Called when a client connects to the server
1015 =============
1016 */
1017 void DecodeLevelParms (void);
1018 //void dom_player_join_team(entity pl);
1019 void set_dom_state(entity e);
1020 void ClientConnect (void)
1021 {
1022         float t;
1023
1024         if(IS_CLIENT(self))
1025         {
1026                 print("Warning: ClientConnect, but already connected!\n");
1027                 return;
1028         }
1029
1030         if(Ban_MaybeEnforceBanOnce(self))
1031                 return;
1032
1033         DecodeLevelParms();
1034
1035 #ifdef WATERMARK
1036         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1037 #endif
1038
1039         self.classname = "player_joining";
1040
1041         self.flags = FL_CLIENT;
1042         self.version_nagtime = time + 10 + random() * 10;
1043
1044         if(player_count<0)
1045         {
1046                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1047                 player_count = 0;
1048         }
1049
1050         PlayerScore_Attach(self);
1051         ClientData_Attach();
1052         accuracy_init(self);
1053
1054         bot_clientconnect();
1055
1056         playerdemo_init();
1057
1058         anticheat_init();
1059
1060         // identify the right forced team
1061         if(autocvar_g_campaign)
1062         {
1063                 if(IS_REAL_CLIENT(self)) // only players, not bots
1064                 {
1065                         switch(autocvar_g_campaign_forceteam)
1066                         {
1067                                 case 1: self.team_forced = NUM_TEAM_1; break;
1068                                 case 2: self.team_forced = NUM_TEAM_2; break;
1069                                 case 3: self.team_forced = NUM_TEAM_3; break;
1070                                 case 4: self.team_forced = NUM_TEAM_4; break;
1071                                 default: self.team_forced = 0;
1072                         }
1073                 }
1074         }
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1076                 self.team_forced = NUM_TEAM_1;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1078                 self.team_forced = NUM_TEAM_2;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1080                 self.team_forced = NUM_TEAM_3;
1081         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1082                 self.team_forced = NUM_TEAM_4;
1083         else if(autocvar_g_forced_team_otherwise == "red")
1084                 self.team_forced = NUM_TEAM_1;
1085         else if(autocvar_g_forced_team_otherwise == "blue")
1086                 self.team_forced = NUM_TEAM_2;
1087         else if(autocvar_g_forced_team_otherwise == "yellow")
1088                 self.team_forced = NUM_TEAM_3;
1089         else if(autocvar_g_forced_team_otherwise == "pink")
1090                 self.team_forced = NUM_TEAM_4;
1091         else if(autocvar_g_forced_team_otherwise == "spectate")
1092                 self.team_forced = -1;
1093         else if(autocvar_g_forced_team_otherwise == "spectator")
1094                 self.team_forced = -1;
1095         else
1096                 self.team_forced = 0;
1097
1098         if(!teamplay)
1099                 if(self.team_forced > 0)
1100                         self.team_forced = 0;
1101
1102         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1103
1104         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1105                 self.classname = "observer";
1106         } else {
1107                 if(teamplay)
1108                 {
1109                         if(autocvar_g_balance_teams)
1110                         {
1111                                 self.classname = "player";
1112                                 campaign_bots_may_start = 1;
1113                         }
1114                         else
1115                         {
1116                                 self.classname = "observer"; // do it anyway
1117                         }
1118                 }
1119                 else
1120                 {
1121                         self.classname = "player";
1122                         campaign_bots_may_start = 1;
1123                 }
1124         }
1125
1126         self.playerid = (playerid_last = playerid_last + 1);
1127
1128         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1129
1130     if(IS_BOT_CLIENT(self))
1131         PlayerStats_AddPlayer(self);
1132
1133         if(autocvar_sv_eventlog)
1134                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1135
1136         LogTeamchange(self.playerid, self.team, 1);
1137
1138         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1139
1140         self.netname_previous = strzone(self.netname);
1141
1142         if(IS_PLAYER(self) && teamplay)
1143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1144         else
1145                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1146
1147         stuffcmd(self, strcat(clientstuff, "\n"));
1148         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1149
1150         FixClientCvars(self);
1151
1152         // spawnfunc_waypoint sprites
1153         WaypointSprite_InitClient(self);
1154
1155         // Wazat's grappling hook
1156         SetGrappleHookBindings();
1157
1158         // get version info from player
1159         stuffcmd(self, "cmd clientversion $gameversion\n");
1160
1161         // get other cvars from player
1162         GetCvars(0);
1163
1164         // notify about available teams
1165         if(teamplay)
1166         {
1167                 CheckAllowedTeams(self);
1168                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1169                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1170         }
1171         else
1172                 stuffcmd(self, "set _teams_available 0\n");
1173
1174         attach_entcs();
1175
1176         bot_relinkplayerlist();
1177
1178         self.spectatortime = time;
1179         if(blockSpectators)
1180         {
1181                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1182         }
1183
1184         self.jointime = time;
1185         self.allowed_timeouts = autocvar_sv_timeout_number;
1186
1187         if(IS_REAL_CLIENT(self))
1188         {
1189                 if(!autocvar_g_campaign)
1190                 {
1191                         self.motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1193                 }
1194
1195                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1196                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1197         }
1198
1199         if(!sv_foginterval && world.fog != "")
1200                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1201
1202         W_HitPlotOpen(self);
1203
1204         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1205                 send_CSQC_teamnagger();
1206
1207         CheatInitClient();
1208
1209         CSQCMODEL_AUTOINIT();
1210
1211         self.model_randomizer = random();
1212
1213         if(IS_REAL_CLIENT(self))
1214                 sv_notice_join();
1215
1216         MUTATOR_CALLHOOK(ClientConnect);
1217 }
1218 /*
1219 =============
1220 ClientDisconnect
1221
1222 Called when a client disconnects from the server
1223 =============
1224 */
1225 .entity chatbubbleentity;
1226 void ReadyCount();
1227 void ClientDisconnect (void)
1228 {
1229         if(self.vehicle)
1230             vehicles_exit(VHEF_RELESE);
1231
1232         if (!IS_CLIENT(self))
1233         {
1234                 print("Warning: ClientDisconnect without ClientConnect\n");
1235                 return;
1236         }
1237
1238         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1239
1240         PlayerStats_AddGlobalInfo(self);
1241
1242         CheatShutdownClient();
1243
1244         W_HitPlotClose(self);
1245
1246         anticheat_report();
1247         anticheat_shutdown();
1248
1249         playerdemo_shutdown();
1250
1251         bot_clientdisconnect();
1252
1253         if(self.entcs)
1254                 detach_entcs();
1255
1256         if(autocvar_sv_eventlog)
1257                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1258
1259         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1260
1261         MUTATOR_CALLHOOK(ClientDisconnect);
1262
1263         Portal_ClearAll(self);
1264
1265         Unfreeze(self);
1266
1267         RemoveGrapplingHook(self);
1268
1269         // Here, everything has been done that requires this player to be a client.
1270
1271         self.flags &= ~FL_CLIENT;
1272
1273         if (self.chatbubbleentity)
1274                 remove (self.chatbubbleentity);
1275
1276         if (self.killindicator)
1277                 remove (self.killindicator);
1278
1279         WaypointSprite_PlayerGone();
1280
1281         bot_relinkplayerlist();
1282
1283         accuracy_free(self);
1284         ClientData_Detach();
1285         PlayerScore_Detach(self);
1286
1287         if(self.netname_previous)
1288                 strunzone(self.netname_previous);
1289         if(self.clientstatus)
1290                 strunzone(self.clientstatus);
1291         if(self.weaponorder_byimpulse)
1292                 strunzone(self.weaponorder_byimpulse);
1293
1294         ClearPlayerSounds();
1295
1296         if(self.personal)
1297                 remove(self.personal);
1298
1299         self.playerid = 0;
1300         ReadyCount();
1301
1302         // free cvars
1303         GetCvars(-1);
1304 }
1305
1306 .float BUTTON_CHAT;
1307 void ChatBubbleThink()
1308 {
1309         self.nextthink = time;
1310         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1311         {
1312                 if(self.owner) // but why can that ever be world?
1313                         self.owner.chatbubbleentity = world;
1314                 remove(self);
1315                 return;
1316         }
1317         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1318 #ifdef TETRIS
1319                 || self.owner.tetris_on
1320 #endif
1321         )
1322                 self.model = self.mdl;
1323         else
1324                 self.model = "";
1325 }
1326
1327 void UpdateChatBubble()
1328 {
1329         if (self.alpha < 0)
1330                 return;
1331         // spawn a chatbubble entity if needed
1332         if (!self.chatbubbleentity)
1333         {
1334                 self.chatbubbleentity = spawn();
1335                 self.chatbubbleentity.owner = self;
1336                 self.chatbubbleentity.exteriormodeltoclient = self;
1337                 self.chatbubbleentity.think = ChatBubbleThink;
1338                 self.chatbubbleentity.nextthink = time;
1339                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1340                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1341                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1342                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1343                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1344                 self.chatbubbleentity.model = "";
1345                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1346         }
1347 }
1348
1349
1350 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1351 // added to the model skins
1352 /*void UpdateColorModHack()
1353 {
1354         float c;
1355         c = self.clientcolors & 15;
1356         // LordHavoc: only bothering to support white, green, red, yellow, blue
1357              if (!teamplay) self.colormod = '0 0 0';
1358         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1359         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1360         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1361         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1362         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1363         else self.colormod = '1 1 1';
1364 }*/
1365
1366 void respawn(void)
1367 {
1368         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1369         {
1370                 self.solid = SOLID_NOT;
1371                 self.takedamage = DAMAGE_NO;
1372                 self.movetype = MOVETYPE_FLY;
1373                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1374                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1375                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1376                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1377                 if(autocvar_g_respawn_ghosts_maxtime)
1378                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1379         }
1380
1381         CopyBody(1);
1382
1383         self.effects |= EF_NODRAW; // prevent another CopyBody
1384         PutClientInServer();
1385 }
1386
1387 void play_countdown(float finished, string samp)
1388 {
1389         if(IS_REAL_CLIENT(self))
1390                 if(floor(finished - time - frametime) != floor(finished - time))
1391                         if(finished - time < 6)
1392                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1393 }
1394
1395 void player_powerups (void)
1396 {
1397         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1398         olditems = self.items;
1399
1400         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1401                 self.modelflags |= MF_ROCKET;
1402         else
1403                 self.modelflags &= ~MF_ROCKET;
1404
1405         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1406
1407         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1408                 return;
1409
1410         Fire_ApplyDamage(self);
1411         Fire_ApplyEffect(self);
1412
1413         if (!g_instagib)
1414         {
1415                 if (self.items & IT_STRENGTH)
1416                 {
1417                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1418                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1419                         if (time > self.strength_finished)
1420                         {
1421                                 self.items = self.items - (self.items & IT_STRENGTH);
1422                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1423                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1424                         }
1425                 }
1426                 else
1427                 {
1428                         if (time < self.strength_finished)
1429                         {
1430                                 self.items = self.items | IT_STRENGTH;
1431                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1432                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1433                         }
1434                 }
1435                 if (self.items & IT_INVINCIBLE)
1436                 {
1437                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1438                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1439                         if (time > self.invincible_finished)
1440                         {
1441                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1442                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1443                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1444                         }
1445                 }
1446                 else
1447                 {
1448                         if (time < self.invincible_finished)
1449                         {
1450                                 self.items = self.items | IT_INVINCIBLE;
1451                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1453                         }
1454                 }
1455                 if (self.items & IT_SUPERWEAPON)
1456                 {
1457                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1458                         {
1459                                 self.superweapons_finished = 0;
1460                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1461                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1462                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1463                         }
1464                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1465                         {
1466                                 // don't let them run out
1467                         }
1468                         else
1469                         {
1470                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1471                                 if (time > self.superweapons_finished)
1472                                 {
1473                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1474                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1475                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1476                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1477                                 }
1478                         }
1479                 }
1480                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1481                 {
1482                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1483                         {
1484                                 self.items = self.items | IT_SUPERWEAPON;
1485                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1486                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1487                         }
1488                         else
1489                         {
1490                                 self.superweapons_finished = 0;
1491                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1492                         }
1493                 }
1494                 else
1495                 {
1496                         self.superweapons_finished = 0;
1497                 }
1498         }
1499
1500         if(autocvar_g_nodepthtestplayers)
1501                 self.effects = self.effects | EF_NODEPTHTEST;
1502
1503         if(autocvar_g_fullbrightplayers)
1504                 self.effects = self.effects | EF_FULLBRIGHT;
1505
1506         if (time >= game_starttime)
1507         if (time < self.spawnshieldtime)
1508                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1509
1510         MUTATOR_CALLHOOK(PlayerPowerups);
1511 }
1512
1513 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1514 {
1515         if(current > stable)
1516                 return current;
1517         else if(current > stable - 0.25) // when close enough, "snap"
1518                 return stable;
1519         else
1520                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1521 }
1522
1523 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1524 {
1525         if(current < stable)
1526                 return current;
1527         else if(current < stable + 0.25) // when close enough, "snap"
1528                 return stable;
1529         else
1530                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1531 }
1532
1533 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1534 {
1535         if(current > rotstable)
1536         {
1537                 if(rotframetime > 0)
1538                 {
1539                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1540                         current = max(rotstable, current - rotlinear * rotframetime);
1541                 }
1542         }
1543         else if(current < regenstable)
1544         {
1545                 if(regenframetime > 0)
1546                 {
1547                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1548                         current = min(regenstable, current + regenlinear * regenframetime);
1549                 }
1550         }
1551
1552         if(current > limit)
1553                 current = limit;
1554
1555         return current;
1556 }
1557
1558 void player_regen (void)
1559 {
1560         float max_mod, regen_mod, rot_mod, limit_mod;
1561         max_mod = regen_mod = rot_mod = limit_mod = 1;
1562         regen_mod_max = max_mod;
1563         regen_mod_regen = regen_mod;
1564         regen_mod_rot = rot_mod;
1565         regen_mod_limit = limit_mod;
1566         if(!MUTATOR_CALLHOOK(PlayerRegen))
1567         if(!self.frozen)
1568         {
1569                 float minh, mina, maxh, maxa, limith, limita;
1570                 maxh = autocvar_g_balance_health_rotstable;
1571                 maxa = autocvar_g_balance_armor_rotstable;
1572                 minh = autocvar_g_balance_health_regenstable;
1573                 mina = autocvar_g_balance_armor_regenstable;
1574                 limith = autocvar_g_balance_health_limit;
1575                 limita = autocvar_g_balance_armor_limit;
1576
1577                 max_mod = regen_mod_max;
1578                 regen_mod = regen_mod_regen;
1579                 rot_mod = regen_mod_rot;
1580                 limit_mod = regen_mod_limit;
1581
1582                 maxh = maxh * max_mod;
1583                 minh = minh * max_mod;
1584                 limith = limith * limit_mod;
1585                 limita = limita * limit_mod;
1586
1587                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1588                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1589         }
1590
1591         // if player rotted to death...  die!
1592         // check this outside above checks, as player may still be able to rot to death
1593         if(self.health < 1)
1594                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1595
1596         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1597         {
1598                 float minf, maxf, limitf;
1599
1600                 maxf = autocvar_g_balance_fuel_rotstable;
1601                 minf = autocvar_g_balance_fuel_regenstable;
1602                 limitf = autocvar_g_balance_fuel_limit;
1603
1604                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1605         }
1606 }
1607
1608 float zoomstate_set;
1609 void SetZoomState(float z)
1610 {
1611         if(z != self.zoomstate)
1612         {
1613                 self.zoomstate = z;
1614                 ClientData_Touch(self);
1615         }
1616         zoomstate_set = 1;
1617 }
1618
1619 void GetPressedKeys(void) {
1620         MUTATOR_CALLHOOK(GetPressedKeys);
1621         if (self.movement_x > 0) // get if movement keys are pressed
1622         {       // forward key pressed
1623                 self.pressedkeys |= KEY_FORWARD;
1624                 self.pressedkeys &= ~KEY_BACKWARD;
1625         }
1626         else if (self.movement_x < 0)
1627         {       // backward key pressed
1628                 self.pressedkeys |= KEY_BACKWARD;
1629                 self.pressedkeys &= ~KEY_FORWARD;
1630         }
1631         else
1632         {       // no x input
1633                 self.pressedkeys &= ~KEY_FORWARD;
1634                 self.pressedkeys &= ~KEY_BACKWARD;
1635         }
1636
1637         if (self.movement_y > 0)
1638         {       // right key pressed
1639                 self.pressedkeys |= KEY_RIGHT;
1640                 self.pressedkeys &= ~KEY_LEFT;
1641         }
1642         else if (self.movement_y < 0)
1643         {       // left key pressed
1644                 self.pressedkeys |= KEY_LEFT;
1645                 self.pressedkeys &= ~KEY_RIGHT;
1646         }
1647         else
1648         {       // no y input
1649                 self.pressedkeys &= ~KEY_RIGHT;
1650                 self.pressedkeys &= ~KEY_LEFT;
1651         }
1652
1653         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1654                 self.pressedkeys |= KEY_JUMP;
1655         else
1656                 self.pressedkeys &= ~KEY_JUMP;
1657         if (self.BUTTON_CROUCH)
1658                 self.pressedkeys |= KEY_CROUCH;
1659         else
1660                 self.pressedkeys &= ~KEY_CROUCH;
1661
1662         if (self.BUTTON_ATCK)
1663                 self.pressedkeys |= KEY_ATCK;
1664         else
1665                 self.pressedkeys &= ~KEY_ATCK;
1666         if (self.BUTTON_ATCK2)
1667                 self.pressedkeys |= KEY_ATCK2;
1668         else
1669                 self.pressedkeys &= ~KEY_ATCK2;
1670 }
1671
1672 /*
1673 ======================
1674 spectate mode routines
1675 ======================
1676 */
1677
1678 void SpectateCopy(entity spectatee) {
1679         other = spectatee;
1680         MUTATOR_CALLHOOK(SpectateCopy);
1681         self.armortype = spectatee.armortype;
1682         self.armorvalue = spectatee.armorvalue;
1683         self.ammo_cells = spectatee.ammo_cells;
1684         self.ammo_plasma = spectatee.ammo_plasma;
1685         self.ammo_shells = spectatee.ammo_shells;
1686         self.ammo_nails = spectatee.ammo_nails;
1687         self.ammo_rockets = spectatee.ammo_rockets;
1688         self.ammo_fuel = spectatee.ammo_fuel;
1689         self.clip_load = spectatee.clip_load;
1690         self.clip_size = spectatee.clip_size;
1691         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1692         self.health = spectatee.health;
1693         self.impulse = 0;
1694         self.items = spectatee.items;
1695         self.last_pickup = spectatee.last_pickup;
1696         self.hit_time = spectatee.hit_time;
1697         self.metertime = spectatee.metertime;
1698         self.strength_finished = spectatee.strength_finished;
1699         self.invincible_finished = spectatee.invincible_finished;
1700         self.pressedkeys = spectatee.pressedkeys;
1701         self.weapons = spectatee.weapons;
1702         self.switchweapon = spectatee.switchweapon;
1703         self.switchingweapon = spectatee.switchingweapon;
1704         self.weapon = spectatee.weapon;
1705         self.vortex_charge = spectatee.vortex_charge;
1706         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1707         self.hagar_load = spectatee.hagar_load;
1708         self.arc_heat_percent = spectatee.arc_heat_percent;
1709         self.minelayer_mines = spectatee.minelayer_mines;
1710         self.punchangle = spectatee.punchangle;
1711         self.view_ofs = spectatee.view_ofs;
1712         self.velocity = spectatee.velocity;
1713         self.dmg_take = spectatee.dmg_take;
1714         self.dmg_save = spectatee.dmg_save;
1715         self.dmg_inflictor = spectatee.dmg_inflictor;
1716         self.v_angle = spectatee.v_angle;
1717         self.angles = spectatee.v_angle;
1718         self.frozen = spectatee.frozen;
1719         self.revive_progress = spectatee.revive_progress;
1720         if(!self.BUTTON_USE)
1721                 self.fixangle = TRUE;
1722         setorigin(self, spectatee.origin);
1723         setsize(self, spectatee.mins, spectatee.maxs);
1724         SetZoomState(spectatee.zoomstate);
1725
1726     anticheat_spectatecopy(spectatee);
1727         self.hud = spectatee.hud;
1728         if(spectatee.vehicle)
1729     {
1730         self.fixangle = FALSE;
1731         //self.velocity = spectatee.vehicle.velocity;
1732         self.vehicle_health = spectatee.vehicle_health;
1733         self.vehicle_shield = spectatee.vehicle_shield;
1734         self.vehicle_energy = spectatee.vehicle_energy;
1735         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1736         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1737         self.vehicle_reload1 = spectatee.vehicle_reload1;
1738         self.vehicle_reload2 = spectatee.vehicle_reload2;
1739
1740         msg_entity = self;
1741
1742         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1743             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1744             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1745             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1746
1747         //WriteByte (MSG_ONE, SVC_SETVIEW);
1748         //    WriteEntity(MSG_ONE, self);
1749         //makevectors(spectatee.v_angle);
1750         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1751     }
1752 }
1753
1754 float SpectateUpdate()
1755 {
1756         if(!self.enemy)
1757             return 0;
1758
1759         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1760         {
1761                 SetSpectator(self, world);
1762                 return 0;
1763         }
1764
1765         SpectateCopy(self.enemy);
1766
1767         return 1;
1768 }
1769
1770
1771 float SpectateSet()
1772 {
1773         if(self.enemy.classname != "player")
1774                 return FALSE;
1775         /*if(self.enemy.vehicle)
1776         {
1777
1778                 msg_entity = self;
1779                 WriteByte(MSG_ONE, SVC_SETVIEW);
1780                 WriteEntity(MSG_ONE, self.enemy);
1781                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1782
1783                 self.movetype = MOVETYPE_NONE;
1784                 accuracy_resend(self);
1785         }
1786         else
1787         {*/
1788                 msg_entity = self;
1789                 WriteByte(MSG_ONE, SVC_SETVIEW);
1790                 WriteEntity(MSG_ONE, self.enemy);
1791                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1792                 self.movetype = MOVETYPE_NONE;
1793                 accuracy_resend(self);
1794
1795                 if(!SpectateUpdate())
1796                         PutObserverInServer();
1797         //}
1798         return TRUE;
1799 }
1800
1801 void SetSpectator(entity player, entity spectatee)
1802 {
1803         entity old_spectatee = player.enemy;
1804
1805         player.enemy = spectatee;
1806
1807         // WEAPONTODO
1808         // these are required to fix the spectator bug with arc
1809         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1810         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1811 }
1812
1813 float Spectate(entity pl)
1814 {
1815         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1816         if(pl.team != self.team)
1817                 return 0;
1818
1819         SetSpectator(self, pl);
1820         return SpectateSet();
1821 }
1822
1823 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1824 entity CA_SpectateNext(entity start) {
1825         if (start.team == self.team) {
1826                 return start;
1827         }
1828
1829         other = start;
1830         // continue from current player
1831         while(other && other.team != self.team) {
1832                 other = find(other, classname, "player");
1833         }
1834
1835         if (!other) {
1836                 // restart from begining
1837                 other = find(other, classname, "player");
1838                 while(other && other.team != self.team) {
1839                         other = find(other, classname, "player");
1840                 }
1841         }
1842
1843         return other;
1844 }
1845
1846 float SpectateNext()
1847 {
1848         other = find(self.enemy, classname, "player");
1849
1850         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1851                 // CA and ca players when spectating enemies is forbidden
1852                 other = CA_SpectateNext(other);
1853         } else {
1854                 // other modes and ca spectators or spectating enemies is allowed
1855                 if (!other)
1856                         other = find(other, classname, "player");
1857         }
1858
1859         if(other) { SetSpectator(self, other); }
1860
1861         return SpectateSet();
1862 }
1863
1864 float SpectatePrev()
1865 {
1866         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1867         other = findchain(classname, "player");
1868         if (!other) // no player
1869                 return FALSE;
1870
1871         entity first = other;
1872         // skip players until current spectated player
1873         if(self.enemy)
1874         while(other && other != self.enemy)
1875                 other = other.chain;
1876
1877         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1878         {
1879                 do { other = other.chain; }
1880                 while(other && other.team != self.team);
1881
1882                 if (!other)
1883                 {
1884                         other = first;
1885                         while(other.team != self.team)
1886                                 other = other.chain;
1887                         if(other == self.enemy)
1888                                 return TRUE;
1889                 }
1890         }
1891         else
1892         {
1893                 if(other.chain)
1894                         other = other.chain;
1895                 else
1896                         other = first;
1897         }
1898         SetSpectator(self, other);
1899         return SpectateSet();
1900 }
1901
1902 /*
1903 =============
1904 ShowRespawnCountdown()
1905
1906 Update a respawn countdown display.
1907 =============
1908 */
1909 void ShowRespawnCountdown()
1910 {
1911         float number;
1912         if(self.deadflag == DEAD_NO) // just respawned?
1913                 return;
1914         else
1915         {
1916                 number = ceil(self.respawn_time - time);
1917                 if(number <= 0)
1918                         return;
1919                 if(number <= self.respawn_countdown)
1920                 {
1921                         self.respawn_countdown = number - 1;
1922                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1923                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1924                 }
1925         }
1926 }
1927
1928 void LeaveSpectatorMode()
1929 {
1930         if(self.caplayer)
1931                 return;
1932         if(nJoinAllowed(self))
1933         {
1934                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1935                 {
1936                         self.classname = "player";
1937                         nades_RemoveBonus(self);
1938
1939                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1940                                 { JoinBestTeam(self, FALSE, TRUE); }
1941
1942                         if(autocvar_g_campaign)
1943                                 { campaign_bots_may_start = 1; }
1944
1945                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1946
1947                         PutClientInServer();
1948
1949                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1950                 }
1951                 else
1952                         stuffcmd(self, "menu_showteamselect\n");
1953         }
1954         else
1955         {
1956                 // Player may not join because g_maxplayers is set
1957                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1958         }
1959 }
1960
1961 /**
1962  * Determines whether the player is allowed to join. This depends on cvar
1963  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1964  * it checks whether the number of currently playing players exceeds g_maxplayers.
1965  * @return int number of free slots for players, 0 if none
1966  */
1967 float nJoinAllowed(entity ignore) {
1968         if(!ignore)
1969         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1970         // so report 0 free slots if restricted
1971         {
1972                 if(autocvar_g_forced_team_otherwise == "spectate")
1973                         return 0;
1974                 if(autocvar_g_forced_team_otherwise == "spectator")
1975                         return 0;
1976         }
1977
1978         if(self.team_forced < 0)
1979                 return 0; // forced spectators can never join
1980
1981         // TODO simplify this
1982         entity e;
1983         float totalClients = 0;
1984         FOR_EACH_CLIENT(e)
1985                 if(e != ignore)
1986                         totalClients += 1;
1987
1988         if (!autocvar_g_maxplayers)
1989                 return maxclients - totalClients;
1990
1991         float currentlyPlaying = 0;
1992         FOR_EACH_REALCLIENT(e)
1993                 if(IS_PLAYER(e) || e.caplayer)
1994                         currentlyPlaying += 1;
1995
1996         if(currentlyPlaying < autocvar_g_maxplayers)
1997                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1998
1999         return 0;
2000 }
2001
2002 /**
2003  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2004  * g_maxplayers_spectator_blocktime seconds
2005  */
2006 void checkSpectatorBlock() {
2007         if(IS_SPEC(self) || IS_OBSERVER(self))
2008         if(!self.caplayer)
2009         if(IS_REAL_CLIENT(self))
2010         {
2011                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2012                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2013                         dropclient(self);
2014                 }
2015         }
2016 }
2017
2018 void PrintWelcomeMessage()
2019 {
2020         if(self.motd_actived_time == 0)
2021         {
2022                 if (autocvar_g_campaign) {
2023                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2024                                 self.motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2026                         }
2027                 } else {
2028                         if (self.BUTTON_INFO) {
2029                                 self.motd_actived_time = time;
2030                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2031                         }
2032                 }
2033         }
2034         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2035         {
2036                 if (autocvar_g_campaign) {
2037                         if (self.BUTTON_INFO)
2038                                 self.motd_actived_time = time;
2039                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2040                                 self.motd_actived_time = 0;
2041                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2042                         }
2043                 } else {
2044                         if (self.BUTTON_INFO)
2045                                 self.motd_actived_time = time;
2046                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2047                                 self.motd_actived_time = 0;
2048                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2049                         }
2050                 }
2051         }
2052         else //if(self.motd_actived_time < 0) // just connected, motd is active
2053         {
2054                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2055                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2056                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2057                 {
2058                         // instanctly hide MOTD
2059                         self.motd_actived_time = 0;
2060                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2061                 }
2062         }
2063 }
2064
2065 void ObserverThink()
2066 {
2067         float prefered_movetype;
2068         if (self.flags & FL_JUMPRELEASED) {
2069                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2070                         self.flags &= ~FL_JUMPRELEASED;
2071                         self.flags |= FL_SPAWNING;
2072                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2073                         self.flags &= ~FL_JUMPRELEASED;
2074                         if(SpectateNext()) {
2075                                 self.classname = "spectator";
2076                         }
2077                 } else {
2078                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2079                         if (self.movetype != prefered_movetype)
2080                                 self.movetype = prefered_movetype;
2081                 }
2082         } else {
2083                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2084                         self.flags |= FL_JUMPRELEASED;
2085                         if(self.flags & FL_SPAWNING)
2086                         {
2087                                 self.flags &= ~FL_SPAWNING;
2088                                 LeaveSpectatorMode();
2089                                 return;
2090                         }
2091                 }
2092         }
2093 }
2094
2095 void SpectatorThink()
2096 {
2097         if (self.flags & FL_JUMPRELEASED) {
2098                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2099                         self.flags &= ~FL_JUMPRELEASED;
2100                         self.flags |= FL_SPAWNING;
2101                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2102                         self.flags &= ~FL_JUMPRELEASED;
2103                         if(SpectateNext()) {
2104                                 self.classname = "spectator";
2105                         } else {
2106                                 self.classname = "observer";
2107                                 PutClientInServer();
2108                         }
2109                         self.impulse = 0;
2110                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2111                         self.flags &= ~FL_JUMPRELEASED;
2112                         if(SpectatePrev()) {
2113                                 self.classname = "spectator";
2114                         } else {
2115                                 self.classname = "observer";
2116                                 PutClientInServer();
2117                         }
2118                         self.impulse = 0;
2119                 } else if (self.BUTTON_ATCK2) {
2120                         self.flags &= ~FL_JUMPRELEASED;
2121                         self.classname = "observer";
2122                         PutClientInServer();
2123                 } else {
2124                         if(!SpectateUpdate())
2125                                 PutObserverInServer();
2126                 }
2127         } else {
2128                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2129                         self.flags |= FL_JUMPRELEASED;
2130                         if(self.flags & FL_SPAWNING)
2131                         {
2132                                 self.flags &= ~FL_SPAWNING;
2133                                 LeaveSpectatorMode();
2134                                 return;
2135                         }
2136                 }
2137                 if(!SpectateUpdate())
2138                         PutObserverInServer();
2139         }
2140
2141         self.flags |= FL_CLIENT | FL_NOTARGET;
2142 }
2143
2144 void PlayerUseKey()
2145 {
2146         if (!IS_PLAYER(self))
2147                 return;
2148
2149         if(self.vehicle)
2150         {
2151         vehicles_exit(VHEF_NORMAL);
2152         return;
2153         }
2154
2155         // a use key was pressed; call handlers
2156         MUTATOR_CALLHOOK(PlayerUseKey);
2157 }
2158
2159 /*
2160 =============
2161 PlayerPreThink
2162
2163 Called every frame for each client before the physics are run
2164 =============
2165 */
2166 .float usekeypressed;
2167 void() nexball_setstatus;
2168 .float items_added;
2169 void PlayerPreThink (void)
2170 {
2171         WarpZone_PlayerPhysics_FixVAngle();
2172
2173         self.stat_game_starttime = game_starttime;
2174         self.stat_round_starttime = round_starttime;
2175         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2176         self.stat_leadlimit = autocvar_leadlimit;
2177
2178         if(frametime)
2179         {
2180                 // physics frames: update anticheat stuff
2181                 anticheat_prethink();
2182         }
2183
2184         if(blockSpectators && frametime)
2185                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2186                 checkSpectatorBlock();
2187
2188         zoomstate_set = 0;
2189
2190         if(self.netname_previous != self.netname)
2191         {
2192                 if(autocvar_sv_eventlog)
2193                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2194                 if(self.netname_previous)
2195                         strunzone(self.netname_previous);
2196                 self.netname_previous = strzone(self.netname);
2197         }
2198
2199         // version nagging
2200         if(self.version_nagtime)
2201                 if(self.cvar_g_xonoticversion)
2202                         if(time > self.version_nagtime)
2203                         {
2204                                 // don't notify git users
2205                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2206                                 {
2207                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2208                                         {
2209                                                 // notify release users if connecting to git
2210                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2211                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2212                                         }
2213                                         else
2214                                         {
2215                                                 float r;
2216                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2217                                                 if(r < 0)
2218                                                 {
2219                                                         // give users new version
2220                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2221                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2222                                                 }
2223                                                 else if(r > 0)
2224                                                 {
2225                                                         // notify users about old server version
2226                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2227                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2228                                                 }
2229                                         }
2230                                 }
2231                                 self.version_nagtime = 0;
2232                         }
2233
2234         // GOD MODE info
2235         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2236         {
2237                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2238                 self.max_armorvalue = 0;
2239         }
2240
2241 #ifdef TETRIS
2242         if (TetrisPreFrame())
2243                 return;
2244 #endif
2245
2246         if(self.frozen == 2)
2247         {
2248                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2249                 self.health = max(1, self.revive_progress * start_health);
2250                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2251
2252                 if(self.revive_progress >= 1)
2253                         Unfreeze(self);
2254         }
2255         else if(self.frozen == 3)
2256         {
2257                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2258                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2259
2260                 if(self.health < 1)
2261                 {
2262                         if(self.vehicle)
2263                                 vehicles_exit(VHEF_RELESE);
2264                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2265                 }
2266                 else if ( self.revive_progress <= 0 )
2267                         Unfreeze(self);
2268         }
2269
2270         MUTATOR_CALLHOOK(PlayerPreThink);
2271
2272         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2273         {
2274                 if(self.BUTTON_USE && !self.usekeypressed)
2275                         PlayerUseKey();
2276                 self.usekeypressed = self.BUTTON_USE;
2277         }
2278
2279         if(IS_REAL_CLIENT(self))
2280                 PrintWelcomeMessage();
2281
2282         if(IS_PLAYER(self))
2283         {
2284
2285                 CheckRules_Player();
2286
2287                 if (intermission_running)
2288                 {
2289                         IntermissionThink ();   // otherwise a button could be missed between
2290                         return;                                 // the think tics
2291                 }
2292
2293                 //don't allow the player to turn around while game is paused!
2294                 if(timeout_status == TIMEOUT_ACTIVE) {
2295                         // FIXME turn this into CSQC stuff
2296                         self.v_angle = self.lastV_angle;
2297                         self.angles = self.lastV_angle;
2298                         self.fixangle = TRUE;
2299                 }
2300
2301                 if(frametime)
2302                 {
2303                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2304                         {
2305                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2306                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2307                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2308
2309                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2310                                 {
2311                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2312                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2313                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2314                                 }
2315                         }
2316                         else
2317                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2318
2319                         player_powerups();
2320                 }
2321
2322                 if (self.deadflag != DEAD_NO)
2323                 {
2324                         if(self.personal && g_race_qualifying)
2325                         {
2326                                 if(time > self.respawn_time)
2327                                 {
2328                                         self.respawn_time = time + 1; // only retry once a second
2329                                         self.stat_respawn_time = self.respawn_time;
2330                                         respawn();
2331                                         self.impulse = 141;
2332                                 }
2333                         }
2334                         else
2335                         {
2336                                 float button_pressed;
2337                                 if(frametime)
2338                                         player_anim();
2339                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2340
2341                                 if (self.deadflag == DEAD_DYING)
2342                                 {
2343                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2344                                                 self.deadflag = DEAD_RESPAWNING;
2345                                         else if(!button_pressed)
2346                                                 self.deadflag = DEAD_DEAD;
2347                                 }
2348                                 else if (self.deadflag == DEAD_DEAD)
2349                                 {
2350                                         if(button_pressed)
2351                                                 self.deadflag = DEAD_RESPAWNABLE;
2352                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2353                                                 self.deadflag = DEAD_RESPAWNING;
2354                                 }
2355                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2356                                 {
2357                                         if(!button_pressed)
2358                                                 self.deadflag = DEAD_RESPAWNING;
2359                                 }
2360                                 else if (self.deadflag == DEAD_RESPAWNING)
2361                                 {
2362                                         if(time > self.respawn_time)
2363                                         {
2364                                                 self.respawn_time = time + 1; // only retry once a second
2365                                                 self.respawn_time_max = self.respawn_time;
2366                                                 respawn();
2367                                         }
2368                                 }
2369
2370                                 ShowRespawnCountdown();
2371
2372                                 if(self.respawn_flags & RESPAWN_SILENT)
2373                                         self.stat_respawn_time = 0;
2374                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2375                                         self.stat_respawn_time = self.respawn_time_max;
2376                                 else
2377                                         self.stat_respawn_time = self.respawn_time;
2378                         }
2379
2380                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2381                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2382                                 self.stat_respawn_time *= -1;
2383
2384                         return;
2385                 }
2386
2387                 self.prevorigin = self.origin;
2388
2389                 float do_crouch = self.BUTTON_CROUCH;
2390                 if(self.hook.state)
2391                         do_crouch = 0;
2392                 if(self.vehicle)
2393                         do_crouch = 0;
2394                 if(self.frozen)
2395                         do_crouch = 0;
2396
2397                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2398                 // It cannot be predicted by the engine!
2399                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2400                         do_crouch = 0;
2401
2402                 if (do_crouch)
2403                 {
2404                         if (!self.crouch)
2405                         {
2406                                 self.crouch = TRUE;
2407                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2408                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2409                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2410                         }
2411                 }
2412                 else
2413                 {
2414                         if (self.crouch)
2415                         {
2416                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2417                                 if (!trace_startsolid)
2418                                 {
2419                                         self.crouch = FALSE;
2420                                         self.view_ofs = PL_VIEW_OFS;
2421                                         setsize (self, PL_MIN, PL_MAX);
2422                                 }
2423                         }
2424                 }
2425
2426                 FixPlayermodel();
2427
2428                 GrapplingHookFrame();
2429
2430                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2431                 //if(frametime)
2432                 {
2433                         self.items &= ~self.items_added;
2434
2435                         W_WeaponFrame();
2436
2437                         self.items_added = 0;
2438                         if(self.items & IT_JETPACK)
2439                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2440                                         self.items_added |= IT_FUEL;
2441
2442                         self.items |= self.items_added;
2443                 }
2444
2445                 player_regen();
2446
2447                 // WEAPONTODO: Add a weapon request for this
2448                 // rot vortex charge to the charge limit
2449                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2450                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2451
2452                 if(frametime)
2453                         player_anim();
2454
2455                 // secret status
2456                 secrets_setstatus();
2457
2458                 // monsters status
2459                 monsters_setstatus();
2460
2461                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2462
2463                 //self.angles_y=self.v_angle_y + 90;   // temp
2464         } else if(gameover) {
2465                 if (intermission_running)
2466                         IntermissionThink ();   // otherwise a button could be missed between
2467                 return;
2468         } else if(IS_OBSERVER(self)) {
2469                 ObserverThink();
2470         } else if(IS_SPEC(self)) {
2471                 SpectatorThink();
2472         }
2473
2474         // WEAPONTODO: Add weapon request for this
2475         if(!zoomstate_set)
2476                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2477
2478         float oldspectatee_status;
2479         oldspectatee_status = self.spectatee_status;
2480         if(IS_SPEC(self))
2481                 self.spectatee_status = num_for_edict(self.enemy);
2482         else if(IS_OBSERVER(self))
2483                 self.spectatee_status = num_for_edict(self);
2484         else
2485                 self.spectatee_status = 0;
2486         if(self.spectatee_status != oldspectatee_status)
2487         {
2488                 ClientData_Touch(self);
2489         }
2490
2491         if(self.teamkill_soundtime)
2492         if(time > self.teamkill_soundtime)
2493         {
2494                 self.teamkill_soundtime = 0;
2495
2496                 entity oldpusher, oldself;
2497
2498                 oldself = self; self = self.teamkill_soundsource;
2499                 oldpusher = self.pusher; self.pusher = oldself;
2500
2501                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2502
2503                 self.pusher = oldpusher;
2504                 self = oldself;
2505         }
2506
2507         if(self.taunt_soundtime)
2508         if(time > self.taunt_soundtime)
2509         {
2510                 self.taunt_soundtime = 0;
2511                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2512         }
2513
2514         target_voicescript_next(self);
2515
2516         // WEAPONTODO: Move into weaponsystem somehow
2517         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2518         if(!self.weapon)
2519                 self.clip_load = self.clip_size = 0;
2520 }
2521
2522 float isInvisibleString(string s)
2523 {
2524         float i, n, c;
2525         s = strdecolorize(s);
2526         for((i = 0), (n = strlen(s)); i < n; ++i)
2527         {
2528                 c = str2chr(s, i);
2529                 switch(c)
2530                 {
2531                         case 0:
2532                         case 32: // space
2533                                 break;
2534                         case 192: // charmap space
2535                                 if (!autocvar_utf8_enable)
2536                                         break;
2537                                 return FALSE;
2538                         case 160: // space in unicode fonts
2539                         case 0xE000 + 192: // utf8 charmap space
2540                                 if (autocvar_utf8_enable)
2541                                         break;
2542                         default:
2543                                 return FALSE;
2544                 }
2545         }
2546         return TRUE;
2547 }
2548
2549 /*
2550 =============
2551 PlayerPostThink
2552
2553 Called every frame for each client after the physics are run
2554 =============
2555 */
2556 .float idlekick_lasttimeleft;
2557 void PlayerPostThink (void)
2558 {
2559         // Savage: Check for nameless players
2560         if (isInvisibleString(self.netname)) {
2561                 self.netname = "Player";
2562                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2563         }
2564
2565         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2566         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2567         {
2568                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2569                 {
2570                         if(self.idlekick_lasttimeleft)
2571                         {
2572                                 self.idlekick_lasttimeleft = 0;
2573                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2574                         }
2575                 }
2576                 else
2577                 {
2578                         float timeleft;
2579                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2580                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2581                         {
2582                                 if(!self.idlekick_lasttimeleft)
2583                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2584                         }
2585                         if(timeleft <= 0)
2586                         {
2587                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2588                                 dropclient(self);
2589                                 return;
2590                         }
2591                         else if(timeleft <= 10)
2592                         {
2593                                 if(timeleft != self.idlekick_lasttimeleft)
2594                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2595                                 self.idlekick_lasttimeleft = timeleft;
2596                         }
2597                 }
2598         }
2599
2600 #ifdef TETRIS
2601         if(self.impulse == 100)
2602                 ImpulseCommands();
2603         if (!TetrisPostFrame())
2604         {
2605 #endif
2606
2607         CheatFrame();
2608
2609         //CheckPlayerJump();
2610
2611         if(IS_PLAYER(self)) {
2612                 CheckRules_Player();
2613                 UpdateChatBubble();
2614                 if (self.impulse)
2615                         ImpulseCommands();
2616                 if (intermission_running)
2617                         return;         // intermission or finale
2618                 GetPressedKeys();
2619         }
2620
2621 #ifdef TETRIS
2622         }
2623 #endif
2624
2625         /*
2626         float i;
2627         for(i = 0; i < 1000; ++i)
2628         {
2629                 vector end;
2630                 end = self.origin + '0 0 1024' + 512 * randomvec();
2631                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2632                 if(trace_fraction < 1)
2633                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2634                 {
2635                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2636                         break;
2637                 }
2638         }
2639         */
2640
2641         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2642
2643         if(self.waypointsprite_attachedforcarrier)
2644                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2645
2646         playerdemo_write();
2647
2648         CSQCMODEL_AUTOUPDATE();
2649 }