qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  54 }
  55
  56 bool ClientData_Send(entity this, entity to, int sf)
  57 {
  58         if(to != self.owner)
  59         {
  60                 error("wtf");
  61                 return false;
  62         }
  63
  64         entity e;
  65
  66         e = to;
  67         if(IS_SPEC(to))
  68                 e = to.enemy;
  69
  70         sf = 0;
  71
  72         if(e.race_completed)
  73                 sf |= 1; // forced scoreboard
  74         if(to.spectatee_status)
  75                 sf |= 2; // spectator ent number follows
  76         if(e.zoomstate)
  77                 sf |= 4; // zoomed
  78         if(e.porto_v_angle_held)
  79                 sf |= 8; // angles held
  80
  81         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  82         WriteByte(MSG_ENTITY, sf);
  83
  84         if(sf & 2)
  85                 WriteByte(MSG_ENTITY, to.spectatee_status);
  86
  87         if(sf & 8)
  88         {
  89                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  90                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  91         }
  92
  93         return true;
  94 }
  95
  96 void ClientData_Attach()
  97 {SELFPARAM();
  98         Net_LinkEntity(this.clientdata = new(clientdata), false, 0, ClientData_Send);
  99         make_pure(this.clientdata);
 100         self.clientdata.drawonlytoclient = this;
 101         self.clientdata.owner = this;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectatee(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178         UpdatePlayerSounds(e);
 179 }
 180
 181 /*
 182 =============
 183 PutObserverInServer
 184
 185 putting a client as observer in the server
 186 =============
 187 */
 188 void FixPlayermodel(entity player);
 189 void PutObserverInServer()
 190 {SELFPARAM();
 191         entity  spot;
 192     self.hud = HUD_NORMAL;
 193
 194         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 195
 196         spot = SelectSpawnPoint (true);
 197         if(!spot)
 198                 error("No spawnpoints for observers?!?\n");
 199         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 200
 201         if(IS_REAL_CLIENT(self))
 202         {
 203                 msg_entity = self;
 204                 WriteByte(MSG_ONE, SVC_SETVIEW);
 205                 WriteEntity(MSG_ONE, self);
 206         }
 207
 208         self.frags = FRAGS_SPECTATOR;
 209         self.bot_attack = false;
 210
 211         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 212
 213         Portal_ClearAll(self);
 214
 215         Unfreeze(self);
 216
 217         if(self.alivetime)
 218         {
 219                 if(!warmup_stage)
 220                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 221                 self.alivetime = 0;
 222         }
 223
 224         if(self.vehicle)
 225                 vehicles_exit(VHEF_RELEASE);
 226
 227         WaypointSprite_PlayerDead();
 228
 229         if(!mutator_returnvalue)  // mutator prevents resetting teams
 230                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 231
 232         if(self.killcount != FRAGS_SPECTATOR)
 233         {
 234                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 235                 if(!intermission_running)
 236                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 237                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 238
 239                 if(self.just_joined == false) {
 240                         LogTeamchange(self.playerid, -1, 4);
 241                 } else
 242                         self.just_joined = false;
 243         }
 244
 245         PlayerScore_Clear(self); // clear scores when needed
 246
 247         accuracy_resend(self);
 248
 249         self.spectatortime = time;
 250
 251         self.classname = STR_OBSERVER;
 252         self.iscreature = false;
 253         self.teleportable = TELEPORT_SIMPLE;
 254         self.damagedbycontents = false;
 255         self.health = FRAGS_SPECTATOR;
 256         self.takedamage = DAMAGE_NO;
 257         self.solid = SOLID_NOT;
 258         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 259         self.flags = FL_CLIENT | FL_NOTARGET;
 260         self.armorvalue = 666;
 261         self.effects = 0;
 262         self.armorvalue = autocvar_g_balance_armor_start;
 263         self.pauserotarmor_finished = 0;
 264         self.pauserothealth_finished = 0;
 265         self.pauseregen_finished = 0;
 266         self.damageforcescale = 0;
 267         self.death_time = 0;
 268         self.respawn_flags = 0;
 269         self.respawn_time = 0;
 270         self.stat_respawn_time = 0;
 271         self.alpha = 0;
 272         self.scale = 0;
 273         self.fade_time = 0;
 274         self.pain_frame = 0;
 275         self.pain_finished = 0;
 276         self.strength_finished = 0;
 277         self.invincible_finished = 0;
 278         self.superweapons_finished = 0;
 279         self.pushltime = 0;
 280         self.istypefrag = 0;
 281         self.think = func_null;
 282         self.nextthink = 0;
 283         self.hook_time = 0;
 284         self.deadflag = DEAD_NO;
 285         self.angles = spot.angles;
 286         self.angles_z = 0;
 287         self.fixangle = true;
 288         self.crouch = false;
 289         self.revival_time = 0;
 290
 291         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 292         self.prevorigin = self.origin;
 293         self.items = 0;
 294         self.weapons = '0 0 0';
 295         self.model = "";
 296         FixPlayermodel(self);
 297         setmodel(self, MDL_Null);
 298         self.drawonlytoclient = self;
 299
 300         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 301         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 302
 303         self.weapon = 0;
 304         self.weaponname = "";
 305         self.switchingweapon = 0;
 306         self.weaponmodel = "";
 307         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 308         {
 309                 self.weaponentities[slot] = NULL;
 310         }
 311         self.exteriorweaponentity = world;
 312         self.killcount = FRAGS_SPECTATOR;
 313         self.velocity = '0 0 0';
 314         self.avelocity = '0 0 0';
 315         self.punchangle = '0 0 0';
 316         self.punchvector = '0 0 0';
 317         self.oldvelocity = self.velocity;
 318         self.fire_endtime = -1;
 319         self.event_damage = func_null;
 320 }
 321
 322 int player_getspecies(entity this)
 323 {
 324         get_model_parameters(this.model, this.skin);
 325         int s = get_model_parameters_species;
 326         get_model_parameters(string_null, 0);
 327         if (s < 0) return SPECIES_HUMAN;
 328         return s;
 329 }
 330
 331 .float model_randomizer;
 332 void FixPlayermodel(entity player)
 333 {
 334         string defaultmodel = "";
 335         int defaultskin = 0;
 336         if(autocvar_sv_defaultcharacter)
 337         {
 338                 if(teamplay)
 339                 {
 340                         string s = Static_Team_ColorName_Lower(player.team);
 341                         if (s != "neutral")
 342                         {
 343                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 344                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 345                         }
 346                 }
 347
 348                 if(defaultmodel == "")
 349                 {
 350                         defaultmodel = autocvar_sv_defaultplayermodel;
 351                         defaultskin = autocvar_sv_defaultplayerskin;
 352                 }
 353
 354                 int n = tokenize_console(defaultmodel);
 355                 if(n > 0)
 356                 {
 357                         defaultmodel = argv(floor(n * player.model_randomizer));
 358                         // However, do NOT randomize if the player-selected model is in the list.
 359                         for (int i = 0; i < n; ++i)
 360                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 361                                         defaultmodel = argv(i);
 362                 }
 363
 364                 int i = strstrofs(defaultmodel, ":", 0);
 365                 if(i >= 0)
 366                 {
 367                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 368                         defaultmodel = substring(defaultmodel, 0, i);
 369                 }
 370         }
 371         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 372         defaultmodel = ret_string;
 373         defaultskin = ret_int;
 374
 375         bool chmdl = false;
 376         int oldskin;
 377         if(defaultmodel != "")
 378         {
 379                 if (defaultmodel != player.model)
 380                 {
 381                         vector m1 = player.mins;
 382                         vector m2 = player.maxs;
 383                         setplayermodel (player, defaultmodel);
 384                         setsize (player, m1, m2);
 385                         chmdl = true;
 386                 }
 387
 388                 oldskin = player.skin;
 389                 player.skin = defaultskin;
 390         } else {
 391                 if (player.playermodel != player.model || player.playermodel == "")
 392                 {
 393                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 394                         vector m1 = player.mins;
 395                         vector m2 = player.maxs;
 396                         setplayermodel (player, player.playermodel);
 397                         setsize (player, m1, m2);
 398                         chmdl = true;
 399                 }
 400
 401                 oldskin = player.skin;
 402                 player.skin = stof(player.playerskin);
 403         }
 404
 405         if(chmdl || oldskin != player.skin) // model or skin has changed
 406         {
 407                 player.species = player_getspecies(player); // update species
 408                 UpdatePlayerSounds(player); // update skin sounds
 409         }
 410
 411         if(!teamplay)
 412                 if(strlen(autocvar_sv_defaultplayercolors))
 413                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 414                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 415 }
 416
 417
 418 /** Called when a client spawns in the server */
 419 void PutClientInServer()
 420 {
 421         SELFPARAM();
 422         if (IS_BOT_CLIENT(this)) {
 423                 this.classname = STR_PLAYER;
 424         } else if (IS_REAL_CLIENT(this)) {
 425                 msg_entity = this;
 426                 WriteByte(MSG_ONE, SVC_SETVIEW);
 427                 WriteEntity(MSG_ONE, this);
 428         }
 429         if (gameover) {
 430                 this.classname = STR_OBSERVER;
 431         }
 432
 433         SetSpectatee(this, NULL);
 434
 435         // reset player keys
 436         this.itemkeys = 0;
 437
 438         MUTATOR_CALLHOOK(PutClientInServer, this);
 439
 440         if (IS_OBSERVER(this)) {
 441                 PutObserverInServer();
 442         } else if (IS_PLAYER(this)) {
 443                 accuracy_resend(this);
 444
 445                 if (this.team < 0)
 446                         JoinBestTeam(this, false, true);
 447
 448                 entity spot = SelectSpawnPoint(false);
 449                 if (!spot) {
 450                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 451                         return; // spawn failed
 452                 }
 453
 454                 this.classname = STR_PLAYER;
 455                 this.wasplayer = true;
 456                 this.iscreature = true;
 457                 this.teleportable = TELEPORT_NORMAL;
 458                 this.damagedbycontents = true;
 459                 this.movetype = MOVETYPE_WALK;
 460                 this.solid = SOLID_SLIDEBOX;
 461                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 462                 if (autocvar_g_playerclip_collisions)
 463                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 464                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 465                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 466                 this.frags = FRAGS_PLAYER;
 467                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 468                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 469                 if (autocvar__notarget)
 470                         this.flags |= FL_NOTARGET;
 471                 this.takedamage = DAMAGE_AIM;
 472                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 473                 this.dmg = 2; // WTF
 474
 475                 if (warmup_stage) {
 476                         this.ammo_shells = warmup_start_ammo_shells;
 477                         this.ammo_nails = warmup_start_ammo_nails;
 478                         this.ammo_rockets = warmup_start_ammo_rockets;
 479                         this.ammo_cells = warmup_start_ammo_cells;
 480                         this.ammo_plasma = warmup_start_ammo_plasma;
 481                         this.ammo_fuel = warmup_start_ammo_fuel;
 482                         this.health = warmup_start_health;
 483                         this.armorvalue = warmup_start_armorvalue;
 484                         this.weapons = WARMUP_START_WEAPONS;
 485                 } else {
 486                         this.ammo_shells = start_ammo_shells;
 487                         this.ammo_nails = start_ammo_nails;
 488                         this.ammo_rockets = start_ammo_rockets;
 489                         this.ammo_cells = start_ammo_cells;
 490                         this.ammo_plasma = start_ammo_plasma;
 491                         this.ammo_fuel = start_ammo_fuel;
 492                         this.health = start_health;
 493                         this.armorvalue = start_armorvalue;
 494                         this.weapons = start_weapons;
 495                 }
 496
 497                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 498
 499                 this.items = start_items;
 500
 501                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 502                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 503                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 504                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 505                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 506                 // extend the pause of rotting if client was reset at the beginning of the countdown
 507                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 508                         float f = game_starttime - time;
 509                         this.spawnshieldtime += f;
 510                         this.pauserotarmor_finished += f;
 511                         this.pauserothealth_finished += f;
 512                         this.pauseregen_finished += f;
 513                 }
 514                 this.damageforcescale = 2;
 515                 this.death_time = 0;
 516                 this.respawn_flags = 0;
 517                 this.respawn_time = 0;
 518                 this.stat_respawn_time = 0;
 519                 this.scale = autocvar_sv_player_scale;
 520                 this.fade_time = 0;
 521                 this.pain_frame = 0;
 522                 this.pain_finished = 0;
 523                 this.pushltime = 0;
 524                 this.think = func_null; // players have no think function
 525                 this.nextthink = 0;
 526                 this.dmg_team = 0;
 527                 this.ballistics_density = autocvar_g_ballistics_density_player;
 528
 529                 this.deadflag = DEAD_NO;
 530
 531                 this.angles = spot.angles;
 532                 this.angles_z = 0; // never spawn tilted even if the spot says to
 533                 if (IS_BOT_CLIENT(this))
 534                         this.v_angle = this.angles;
 535                 this.fixangle = true; // turn this way immediately
 536                 this.oldvelocity = this.velocity = '0 0 0';
 537                 this.avelocity = '0 0 0';
 538                 this.punchangle = '0 0 0';
 539                 this.punchvector = '0 0 0';
 540
 541                 this.strength_finished = 0;
 542                 this.invincible_finished = 0;
 543                 this.fire_endtime = -1;
 544                 this.revival_time = 0;
 545                 this.air_finished = time + 12;
 546
 547                 entity spawnevent = new(spawnevent);
 548                 make_pure(spawnevent);
 549                 spawnevent.owner = this;
 550                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 551
 552                 // Cut off any still running player sounds.
 553                 stopsound(this, CH_PLAYER_SINGLE);
 554
 555                 this.model = "";
 556                 FixPlayermodel(this);
 557                 this.drawonlytoclient = NULL;
 558
 559                 this.crouch = false;
 560                 this.view_ofs = PL_VIEW_OFS;
 561                 setsize(this, PL_MIN, PL_MAX);
 562                 this.spawnorigin = spot.origin;
 563                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 564                 // don't reset back to last position, even if new position is stuck in solid
 565                 this.oldorigin = this.origin;
 566                 this.prevorigin = this.origin;
 567                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 568         this.hud = HUD_NORMAL;
 569
 570                 this.event_damage = PlayerDamage;
 571
 572                 this.bot_attack = true;
 573                 this.monster_attack = true;
 574
 575                 this.spider_slowness = 0;
 576
 577                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = false;
 578
 579                 if (this.killcount == FRAGS_SPECTATOR) {
 580                         PlayerScore_Clear(this);
 581                         this.killcount = 0;
 582                 }
 583
 584                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 585                 {
 586                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 587                 }
 588                 this.alpha = default_player_alpha;
 589                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 590                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 591
 592                 this.speedrunning = false;
 593
 594                 target_voicescript_clear(this);
 595
 596                 // reset fields the weapons may use
 597                 FOREACH(Weapons, true, LAMBDA(
 598                         it.wr_resetplayer(it);
 599                         // reload all reloadable weapons
 600                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 601                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 602                         }
 603                 ));
 604
 605                 {
 606                         string s = spot.target;
 607                         spot.target = string_null;
 608                         WITH(entity, activator, this, LAMBDA(
 609                                 WITH(entity, self, spot, SUB_UseTargets())
 610                         ));
 611                         spot.target = s;
 612                 }
 613
 614                 Unfreeze(this);
 615
 616                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 617
 618                 if (autocvar_spawn_debug)
 619                 {
 620                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 621                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 622                 }
 623
 624                 this.switchweapon = w_getbestweapon(this);
 625                 this.cnt = -1; // W_LastWeapon will not complain
 626                 this.weapon = 0;
 627                 this.weaponname = "";
 628                 this.switchingweapon = 0;
 629
 630                 if (!warmup_stage && !this.alivetime)
 631                         this.alivetime = time;
 632
 633                 antilag_clear(this);
 634         }
 635 }
 636
 637 .float ebouncefactor, ebouncestop; // electro's values
 638 // TODO do we need all these fields, or should we stop autodetecting runtime
 639 // changes and just have a console command to update this?
 640 bool ClientInit_SendEntity(entity this, entity to, int sf)
 641 {
 642         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 643         return = true;
 644         msg_entity = to;
 645         Registry_send_all();
 646         int channel = MSG_ONE;
 647         WriteHeader(channel, ENT_CLIENT_INIT);
 648         WriteByte(channel, g_nexball_meter_period * 32);
 649         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 650         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 651         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 652         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 653         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 654         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 655         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 656         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 657
 658         if(sv_foginterval && world.fog != "")
 659                 WriteString(channel, world.fog);
 660         else
 661                 WriteString(channel, "");
 662         WriteByte(channel, self.count * 255.0); // g_balance_armor_blockpercent
 663         WriteCoord(channel, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 664         WriteCoord(channel, self.bouncestop); // g_balance_mortar_bouncestop
 665         WriteCoord(channel, self.ebouncefactor); // g_balance_mortar_bouncefactor
 666         WriteCoord(channel, self.ebouncestop); // g_balance_mortar_bouncestop
 667         WriteByte(channel, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 668         WriteByte(channel, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 669         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 670         WriteByte(channel, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 671         WriteByte(channel, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 672         WriteCoord(channel, autocvar_g_trueaim_minrange);
 673         WriteByte(channel, WEP_CVAR(porto, secondary)); // WEAPONTODO
 674
 675         MUTATOR_CALLHOOK(Ent_Init);
 676 }
 677
 678 void ClientInit_CheckUpdate()
 679 {SELFPARAM();
 680         self.nextthink = time;
 681         if(self.count != autocvar_g_balance_armor_blockpercent)
 682         {
 683                 self.count = autocvar_g_balance_armor_blockpercent;
 684                 self.SendFlags |= 1;
 685         }
 686         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 687         {
 688                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 689                 self.SendFlags |= 1;
 690         }
 691         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 692         {
 693                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 694                 self.SendFlags |= 1;
 695         }
 696         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 697         {
 698                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 699                 self.SendFlags |= 1;
 700         }
 701         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 702         {
 703                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 704                 self.SendFlags |= 1;
 705         }
 706 }
 707
 708 void ClientInit_Spawn()
 709 {SELFPARAM();
 710
 711         entity e = new(clientinit);
 712         make_pure(e);
 713         e.think = ClientInit_CheckUpdate;
 714         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 715
 716         WITH(entity, self, e, ClientInit_CheckUpdate());
 717 }
 718
 719 /*
 720 =============
 721 SetNewParms
 722 =============
 723 */
 724 void SetNewParms ()
 725 {
 726         // initialize parms for a new player
 727         parm1 = -(86400 * 366);
 728
 729         MUTATOR_CALLHOOK(SetNewParms);
 730 }
 731
 732 /*
 733 =============
 734 SetChangeParms
 735 =============
 736 */
 737 void SetChangeParms ()
 738 {SELFPARAM();
 739         // save parms for level change
 740         parm1 = self.parm_idlesince - time;
 741
 742         MUTATOR_CALLHOOK(SetChangeParms);
 743 }
 744
 745 /*
 746 =============
 747 DecodeLevelParms
 748 =============
 749 */
 750 void DecodeLevelParms ()
 751 {SELFPARAM();
 752         // load parms
 753         self.parm_idlesince = parm1;
 754         if(self.parm_idlesince == -(86400 * 366))
 755                 self.parm_idlesince = time;
 756
 757         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 758         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 759
 760         MUTATOR_CALLHOOK(DecodeLevelParms);
 761 }
 762
 763 /*
 764 =============
 765 ClientKill
 766
 767 Called when a client types 'kill' in the console
 768 =============
 769 */
 770
 771 .float clientkill_nexttime;
 772 void ClientKill_Now_TeamChange()
 773 {SELFPARAM();
 774         if(self.killindicator_teamchange == -1)
 775         {
 776                 JoinBestTeam( self, false, true );
 777         }
 778         else if(self.killindicator_teamchange == -2)
 779         {
 780                 if(blockSpectators)
 781                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 782                 PutObserverInServer();
 783         }
 784         else
 785                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 786         self.killindicator_teamchange = 0;
 787 }
 788
 789 void ClientKill_Now()
 790 {SELFPARAM();
 791         if(self.vehicle)
 792         {
 793             vehicles_exit(VHEF_RELEASE);
 794             if(!self.killindicator_teamchange)
 795             {
 796             self.vehicle_health = -1;
 797             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 798             }
 799         }
 800
 801         if(self.killindicator && !wasfreed(self.killindicator))
 802                 remove(self.killindicator);
 803
 804         self.killindicator = world;
 805
 806         if(self.killindicator_teamchange)
 807                 ClientKill_Now_TeamChange();
 808
 809         if(IS_PLAYER(self))
 810                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 811
 812         // now I am sure the player IS dead
 813 }
 814 void KillIndicator_Think()
 815 {SELFPARAM();
 816         if (gameover)
 817         {
 818                 self.owner.killindicator = world;
 819                 remove(self);
 820                 return;
 821         }
 822
 823         if (self.owner.alpha < 0 && !self.owner.vehicle)
 824         {
 825                 self.owner.killindicator = world;
 826                 remove(self);
 827                 return;
 828         }
 829
 830         if(self.cnt <= 0)
 831         {
 832                 WITH(entity, self, self.owner, ClientKill_Now());
 833                 return;
 834         }
 835     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 836     {
 837         self.nextthink = time + 1;
 838         self.cnt -= 1;
 839     }
 840         else
 841         {
 842                 if(self.cnt <= 10)
 843                         setmodel(self, MDL_NUM(self.cnt));
 844                 if(IS_REAL_CLIENT(self.owner))
 845                 {
 846                         if(self.cnt <= 10)
 847                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 848                 }
 849                 self.nextthink = time + 1;
 850                 self.cnt -= 1;
 851         }
 852 }
 853
 854 float clientkilltime;
 855 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 856 {SELFPARAM();
 857         float killtime;
 858         float starttime;
 859         entity e;
 860
 861         if (gameover)
 862                 return;
 863
 864         killtime = autocvar_g_balance_kill_delay;
 865
 866         if(g_race_qualifying || g_cts)
 867                 killtime = 0;
 868
 869     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 870         return;
 871
 872         self.killindicator_teamchange = targetteam;
 873
 874     if(!self.killindicator)
 875         {
 876                 if(self.deadflag == DEAD_NO)
 877                 {
 878                         killtime = max(killtime, self.clientkill_nexttime - time);
 879                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 880                 }
 881
 882                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 883                 {
 884                         ClientKill_Now();
 885                 }
 886                 else
 887                 {
 888                         starttime = max(time, clientkilltime);
 889
 890                         self.killindicator = spawn();
 891                         self.killindicator.owner = self;
 892                         self.killindicator.scale = 0.5;
 893                         setattachment(self.killindicator, self, "");
 894                         setorigin(self.killindicator, '0 0 52');
 895                         self.killindicator.think = KillIndicator_Think;
 896                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 897                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 898                         self.killindicator.cnt = ceil(killtime);
 899                         self.killindicator.count = bound(0, ceil(killtime), 10);
 900                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 901
 902                         for(e = world; (e = find(e, classname, "body")) != world; )
 903                         {
 904                                 if(e.enemy != self)
 905                                         continue;
 906                                 e.killindicator = spawn();
 907                                 e.killindicator.owner = e;
 908                                 e.killindicator.scale = 0.5;
 909                                 setattachment(e.killindicator, e, "");
 910                                 setorigin(e.killindicator, '0 0 52');
 911                                 e.killindicator.think = KillIndicator_Think;
 912                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 913                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 914                                 e.killindicator.cnt = ceil(killtime);
 915                         }
 916                         self.lip = 0;
 917                 }
 918         }
 919         if(self.killindicator)
 920         {
 921                 if(targetteam == 0) // just die
 922                 {
 923                         self.killindicator.colormod = '0 0 0';
 924                         if(IS_REAL_CLIENT(self))
 925                         if(self.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 927                 }
 928                 else if(targetteam == -1) // auto
 929                 {
 930                         self.killindicator.colormod = '0 1 0';
 931                         if(IS_REAL_CLIENT(self))
 932                         if(self.killindicator.cnt > 0)
 933                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 934                 }
 935                 else if(targetteam == -2) // spectate
 936                 {
 937                         self.killindicator.colormod = '0.5 0.5 0.5';
 938                         if(IS_REAL_CLIENT(self))
 939                         if(self.killindicator.cnt > 0)
 940                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 941                 }
 942                 else
 943                 {
 944                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 945                         if(IS_REAL_CLIENT(self))
 946                         if(self.killindicator.cnt > 0)
 947                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 948                 }
 949         }
 950
 951 }
 952
 953 void ClientKill ()
 954 {SELFPARAM();
 955         if(gameover) return;
 956         if(self.player_blocked) return;
 957         if(self.frozen) return;
 958
 959         ClientKill_TeamChange(0);
 960 }
 961
 962 void FixClientCvars(entity e)
 963 {
 964         // send prediction settings to the client
 965         stuffcmd(e, "\nin_bindmap 0 0\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970 }
 971
 972 float PlayerInIDList(entity p, string idlist)
 973 {
 974         float n, i;
 975         string s;
 976
 977         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 978         if (!p.crypto_idfp)
 979                 return 0;
 980
 981         // this function allows abbreviated player IDs too!
 982         n = tokenize_console(idlist);
 983         for(i = 0; i < n; ++i)
 984         {
 985                 s = argv(i);
 986                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 987                         return 1;
 988         }
 989
 990         return 0;
 991 }
 992
 993 #ifdef DP_EXT_PRECONNECT
 994 /*
 995 =============
 996 ClientPreConnect
 997
 998 Called once (not at each match start) when a client begins a connection to the server
 999 =============
1000 */
1001 void ClientPreConnect ()
1002 {SELFPARAM();
1003         if(autocvar_sv_eventlog)
1004         {
1005                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1006                         self.playerid,
1007                         num_for_edict(self),
1008                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1009                 ));
1010         }
1011 }
1012 #endif
1013
1014 /*
1015 =============
1016 ClientConnect
1017
1018 Called when a client connects to the server
1019 =============
1020 */
1021 void DecodeLevelParms ();
1022 void ClientConnect ()
1023 {SELFPARAM();
1024         float t;
1025
1026         if(IS_CLIENT(self))
1027         {
1028                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1029                 return;
1030         }
1031
1032         if(Ban_MaybeEnforceBanOnce(self))
1033                 return;
1034
1035         DecodeLevelParms();
1036
1037 #ifdef WATERMARK
1038         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1039 #endif
1040
1041         self.classname = "player_joining";
1042
1043         self.flags = FL_CLIENT;
1044         self.version_nagtime = time + 10 + random() * 10;
1045
1046         if(player_count<0)
1047         {
1048                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1049                 player_count = 0;
1050         }
1051
1052         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1053
1054         PlayerScore_Attach(self);
1055         ClientData_Attach();
1056         accuracy_init(self);
1057         Inventory_new(self);
1058
1059         bot_clientconnect();
1060
1061         playerdemo_init();
1062
1063         anticheat_init();
1064
1065         // identify the right forced team
1066         if(autocvar_g_campaign)
1067         {
1068                 if(IS_REAL_CLIENT(self)) // only players, not bots
1069                 {
1070                         switch(autocvar_g_campaign_forceteam)
1071                         {
1072                                 case 1: self.team_forced = NUM_TEAM_1; break;
1073                                 case 2: self.team_forced = NUM_TEAM_2; break;
1074                                 case 3: self.team_forced = NUM_TEAM_3; break;
1075                                 case 4: self.team_forced = NUM_TEAM_4; break;
1076                                 default: self.team_forced = 0;
1077                         }
1078                 }
1079         }
1080         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1081                 self.team_forced = NUM_TEAM_1;
1082         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1083                 self.team_forced = NUM_TEAM_2;
1084         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1085                 self.team_forced = NUM_TEAM_3;
1086         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1087                 self.team_forced = NUM_TEAM_4;
1088         else if(autocvar_g_forced_team_otherwise == "red")
1089                 self.team_forced = NUM_TEAM_1;
1090         else if(autocvar_g_forced_team_otherwise == "blue")
1091                 self.team_forced = NUM_TEAM_2;
1092         else if(autocvar_g_forced_team_otherwise == "yellow")
1093                 self.team_forced = NUM_TEAM_3;
1094         else if(autocvar_g_forced_team_otherwise == "pink")
1095                 self.team_forced = NUM_TEAM_4;
1096         else if(autocvar_g_forced_team_otherwise == "spectate")
1097                 self.team_forced = -1;
1098         else if(autocvar_g_forced_team_otherwise == "spectator")
1099                 self.team_forced = -1;
1100         else
1101                 self.team_forced = 0;
1102
1103         if(!teamplay)
1104                 if(self.team_forced > 0)
1105                         self.team_forced = 0;
1106
1107         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1108
1109         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1110                 self.classname = STR_OBSERVER;
1111         } else {
1112                 if(teamplay)
1113                 {
1114                         if(autocvar_g_balance_teams)
1115                         {
1116                                 self.classname = STR_PLAYER;
1117                                 campaign_bots_may_start = 1;
1118                         }
1119                         else
1120                         {
1121                                 self.classname = STR_OBSERVER; // do it anyway
1122                         }
1123                 }
1124                 else
1125                 {
1126                         self.classname = STR_PLAYER;
1127                         campaign_bots_may_start = 1;
1128                 }
1129         }
1130
1131         self.playerid = (playerid_last = playerid_last + 1);
1132
1133         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1134
1135     if(IS_BOT_CLIENT(self))
1136         PlayerStats_GameReport_AddPlayer(self);
1137
1138         if(autocvar_sv_eventlog)
1139                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1140
1141         LogTeamchange(self.playerid, self.team, 1);
1142
1143         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1144
1145         self.netname_previous = strzone(self.netname);
1146
1147         if(IS_PLAYER(self) && teamplay)
1148                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1149         else
1150                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1151
1152         stuffcmd(self, strcat(clientstuff, "\n"));
1153         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1154
1155         FixClientCvars(self);
1156
1157         // spawnfunc_waypoint sprites
1158         WaypointSprite_InitClient(self);
1159
1160         // Wazat's grappling hook
1161         SetGrappleHookBindings();
1162
1163         // Jetpack binds
1164         stuffcmd(self, "alias +jetpack +button10\n");
1165         stuffcmd(self, "alias -jetpack -button10\n");
1166
1167         // get version info from player
1168         stuffcmd(self, "cmd clientversion $gameversion\n");
1169
1170         // get other cvars from player
1171         GetCvars(0);
1172
1173         // notify about available teams
1174         if(teamplay)
1175         {
1176                 CheckAllowedTeams(self);
1177                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1178                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1179         }
1180         else
1181                 stuffcmd(self, "set _teams_available 0\n");
1182
1183         attach_entcs(self);
1184
1185         bot_relinkplayerlist();
1186
1187         self.spectatortime = time;
1188         if(blockSpectators)
1189         {
1190                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1191         }
1192
1193         self.jointime = time;
1194         self.allowed_timeouts = autocvar_sv_timeout_number;
1195
1196         if(IS_REAL_CLIENT(self))
1197         {
1198                 if(!autocvar_g_campaign)
1199                 {
1200                         self.motd_actived_time = -1;
1201                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1202                 }
1203
1204                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1205                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1206         }
1207
1208         if(!sv_foginterval && world.fog != "")
1209                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1210
1211         W_HitPlotOpen(self);
1212
1213         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1214                 send_CSQC_teamnagger();
1215
1216         CheatInitClient();
1217
1218         CSQCMODEL_AUTOINIT(self);
1219
1220         self.model_randomizer = random();
1221
1222         if(IS_REAL_CLIENT(self))
1223                 sv_notice_join();
1224
1225         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1226                 WITH(entity, self, e, e.init_for_player(this));
1227         }
1228
1229         MUTATOR_CALLHOOK(ClientConnect, self);
1230 }
1231 /*
1232 =============
1233 ClientDisconnect
1234
1235 Called when a client disconnects from the server
1236 =============
1237 */
1238 .entity chatbubbleentity;
1239 void ReadyCount();
1240 void ClientDisconnect ()
1241 {SELFPARAM();
1242         if(self.vehicle)
1243             vehicles_exit(VHEF_RELEASE);
1244
1245         if (!IS_CLIENT(self))
1246         {
1247                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1248                 return;
1249         }
1250
1251         PlayerStats_GameReport_FinalizePlayer(self);
1252
1253         if ( self.active_minigame )
1254                 part_minigame(self);
1255
1256         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1257
1258         CheatShutdownClient();
1259
1260         W_HitPlotClose(self);
1261
1262         anticheat_report();
1263         anticheat_shutdown();
1264
1265         playerdemo_shutdown();
1266
1267         bot_clientdisconnect();
1268
1269         detach_entcs(self);
1270
1271         if(autocvar_sv_eventlog)
1272                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1273
1274         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1275
1276         MUTATOR_CALLHOOK(ClientDisconnect);
1277
1278         Portal_ClearAll(self);
1279
1280         Unfreeze(self);
1281
1282         RemoveGrapplingHook(self);
1283
1284         // Here, everything has been done that requires this player to be a client.
1285
1286         self.flags &= ~FL_CLIENT;
1287
1288         if (self.chatbubbleentity)
1289                 remove (self.chatbubbleentity);
1290
1291         if (self.killindicator)
1292                 remove (self.killindicator);
1293
1294         WaypointSprite_PlayerGone();
1295
1296         bot_relinkplayerlist();
1297
1298         accuracy_free(self);
1299         Inventory_delete(self);
1300         ClientData_Detach();
1301         PlayerScore_Detach(self);
1302
1303         if(self.netname_previous)
1304                 strunzone(self.netname_previous);
1305         if(self.clientstatus)
1306                 strunzone(self.clientstatus);
1307         if(self.weaponorder_byimpulse)
1308                 strunzone(self.weaponorder_byimpulse);
1309
1310         ClearPlayerSounds(self);
1311
1312         if(self.personal)
1313                 remove(self.personal);
1314
1315         self.playerid = 0;
1316         ReadyCount();
1317
1318         // free cvars
1319         GetCvars(-1);
1320 }
1321
1322 .float BUTTON_CHAT;
1323 void ChatBubbleThink()
1324 {SELFPARAM();
1325         self.nextthink = time;
1326         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1327         {
1328                 if(self.owner) // but why can that ever be world?
1329                         self.owner.chatbubbleentity = world;
1330                 remove(self);
1331                 return;
1332         }
1333
1334         self.mdl = "";
1335
1336         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1337         {
1338                 if ( self.owner.active_minigame )
1339                         self.mdl = "models/sprites/minigame_busy.iqm";
1340                 else if ( self.owner.BUTTON_CHAT )
1341                         self.mdl = "models/misc/chatbubble.spr";
1342         }
1343
1344         if ( self.model != self.mdl )
1345                 _setmodel(self, self.mdl);
1346
1347 }
1348
1349 void UpdateChatBubble()
1350 {SELFPARAM();
1351         if (self.alpha < 0)
1352                 return;
1353         // spawn a chatbubble entity if needed
1354         if (!self.chatbubbleentity)
1355         {
1356                 self.chatbubbleentity = new(chatbubbleentity);
1357                 self.chatbubbleentity.owner = self;
1358                 self.chatbubbleentity.exteriormodeltoclient = self;
1359                 self.chatbubbleentity.think = ChatBubbleThink;
1360                 self.chatbubbleentity.nextthink = time;
1361                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1362                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1363                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1364                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1365                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1366                 //self.chatbubbleentity.model = "";
1367                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1368         }
1369 }
1370
1371
1372 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1373 // added to the model skins
1374 /*void UpdateColorModHack()
1375 {
1376         float c;
1377         c = self.clientcolors & 15;
1378         // LordHavoc: only bothering to support white, green, red, yellow, blue
1379              if (!teamplay) self.colormod = '0 0 0';
1380         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1381         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1382         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1383         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1384         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1385         else self.colormod = '1 1 1';
1386 }*/
1387
1388 void respawn()
1389 {SELFPARAM();
1390         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1391         {
1392                 self.solid = SOLID_NOT;
1393                 self.takedamage = DAMAGE_NO;
1394                 self.movetype = MOVETYPE_FLY;
1395                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1396                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1397                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1398                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1399                 if(autocvar_g_respawn_ghosts_maxtime)
1400                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1401         }
1402
1403         CopyBody(1);
1404
1405         self.effects |= EF_NODRAW; // prevent another CopyBody
1406         PutClientInServer();
1407 }
1408
1409 void play_countdown(float finished, string samp)
1410 {SELFPARAM();
1411         if(IS_REAL_CLIENT(self))
1412                 if(floor(finished - time - frametime) != floor(finished - time))
1413                         if(finished - time < 6)
1414                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1415 }
1416
1417 void player_powerups ()
1418 {SELFPARAM();
1419         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1420         int items_prev = self.items;
1421
1422         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1423                 self.modelflags |= MF_ROCKET;
1424         else
1425                 self.modelflags &= ~MF_ROCKET;
1426
1427         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1428
1429         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1430                 return;
1431
1432         Fire_ApplyDamage(self);
1433         Fire_ApplyEffect(self);
1434
1435         if (!g_instagib)
1436         {
1437                 if (self.items & ITEM_Strength.m_itemid)
1438                 {
1439                         play_countdown(self.strength_finished, SND(POWEROFF));
1440                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1441                         if (time > self.strength_finished)
1442                         {
1443                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1444                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1445                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1446                         }
1447                 }
1448                 else
1449                 {
1450                         if (time < self.strength_finished)
1451                         {
1452                                 self.items = self.items | ITEM_Strength.m_itemid;
1453                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1454                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1455                         }
1456                 }
1457                 if (self.items & ITEM_Shield.m_itemid)
1458                 {
1459                         play_countdown(self.invincible_finished, SND(POWEROFF));
1460                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1461                         if (time > self.invincible_finished)
1462                         {
1463                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1464                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1465                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1466                         }
1467                 }
1468                 else
1469                 {
1470                         if (time < self.invincible_finished)
1471                         {
1472                                 self.items = self.items | ITEM_Shield.m_itemid;
1473                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1474                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1475                         }
1476                 }
1477                 if (self.items & IT_SUPERWEAPON)
1478                 {
1479                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1480                         {
1481                                 self.superweapons_finished = 0;
1482                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1483                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1484                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1485                         }
1486                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1487                         {
1488                                 // don't let them run out
1489                         }
1490                         else
1491                         {
1492                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1493                                 if (time > self.superweapons_finished)
1494                                 {
1495                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1496                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1497                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1498                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1499                                 }
1500                         }
1501                 }
1502                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1503                 {
1504                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1505                         {
1506                                 self.items = self.items | IT_SUPERWEAPON;
1507                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1508                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1509                         }
1510                         else
1511                         {
1512                                 self.superweapons_finished = 0;
1513                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1514                         }
1515                 }
1516                 else
1517                 {
1518                         self.superweapons_finished = 0;
1519                 }
1520         }
1521
1522         if(autocvar_g_nodepthtestplayers)
1523                 self.effects = self.effects | EF_NODEPTHTEST;
1524
1525         if(autocvar_g_fullbrightplayers)
1526                 self.effects = self.effects | EF_FULLBRIGHT;
1527
1528         if (time >= game_starttime)
1529         if (time < self.spawnshieldtime)
1530                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1531
1532         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1533 }
1534
1535 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1536 {
1537         if(current > stable)
1538                 return current;
1539         else if(current > stable - 0.25) // when close enough, "snap"
1540                 return stable;
1541         else
1542                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1543 }
1544
1545 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1546 {
1547         if(current < stable)
1548                 return current;
1549         else if(current < stable + 0.25) // when close enough, "snap"
1550                 return stable;
1551         else
1552                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1553 }
1554
1555 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1556 {
1557         if(current > rotstable)
1558         {
1559                 if(rotframetime > 0)
1560                 {
1561                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1562                         current = max(rotstable, current - rotlinear * rotframetime);
1563                 }
1564         }
1565         else if(current < regenstable)
1566         {
1567                 if(regenframetime > 0)
1568                 {
1569                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1570                         current = min(regenstable, current + regenlinear * regenframetime);
1571                 }
1572         }
1573
1574         if(current > limit)
1575                 current = limit;
1576
1577         return current;
1578 }
1579
1580 void player_regen ()
1581 {SELFPARAM();
1582         float max_mod, regen_mod, rot_mod, limit_mod;
1583         max_mod = regen_mod = rot_mod = limit_mod = 1;
1584         regen_mod_max = max_mod;
1585         regen_mod_regen = regen_mod;
1586         regen_mod_rot = rot_mod;
1587         regen_mod_limit = limit_mod;
1588
1589         regen_health = autocvar_g_balance_health_regen;
1590         regen_health_linear = autocvar_g_balance_health_regenlinear;
1591         regen_health_rot = autocvar_g_balance_health_rot;
1592         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1593         regen_health_stable = autocvar_g_balance_health_regenstable;
1594         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1595         if(!MUTATOR_CALLHOOK(PlayerRegen))
1596         if(!self.frozen)
1597         {
1598                 float mina, maxa, limith, limita;
1599                 maxa = autocvar_g_balance_armor_rotstable;
1600                 mina = autocvar_g_balance_armor_regenstable;
1601                 limith = autocvar_g_balance_health_limit;
1602                 limita = autocvar_g_balance_armor_limit;
1603
1604                 max_mod = regen_mod_max;
1605                 regen_mod = regen_mod_regen;
1606                 rot_mod = regen_mod_rot;
1607                 limit_mod = regen_mod_limit;
1608
1609                 regen_health_rotstable = regen_health_rotstable * max_mod;
1610                 regen_health_stable = regen_health_stable * max_mod;
1611                 limith = limith * limit_mod;
1612                 limita = limita * limit_mod;
1613
1614                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1615                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1616         }
1617
1618         // if player rotted to death...  die!
1619         // check this outside above checks, as player may still be able to rot to death
1620         if(self.health < 1)
1621         {
1622                 if(self.vehicle)
1623                         vehicles_exit(VHEF_RELEASE);
1624                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1625         }
1626
1627         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1628         {
1629                 float minf, maxf, limitf;
1630
1631                 maxf = autocvar_g_balance_fuel_rotstable;
1632                 minf = autocvar_g_balance_fuel_regenstable;
1633                 limitf = autocvar_g_balance_fuel_limit;
1634
1635                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1636         }
1637 }
1638
1639 float zoomstate_set;
1640 void SetZoomState(float z)
1641 {SELFPARAM();
1642         if(z != self.zoomstate)
1643         {
1644                 self.zoomstate = z;
1645                 ClientData_Touch(self);
1646         }
1647         zoomstate_set = 1;
1648 }
1649
1650 void GetPressedKeys()
1651 {
1652         SELFPARAM();
1653         MUTATOR_CALLHOOK(GetPressedKeys);
1654         int keys = this.pressedkeys;
1655         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1656         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1657         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1658         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1659
1660         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1661         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1662         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1663         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1664         this.pressedkeys = keys;
1665 }
1666
1667 /*
1668 ======================
1669 spectate mode routines
1670 ======================
1671 */
1672
1673 void SpectateCopy(entity spectatee)
1674 {SELFPARAM();
1675         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1676         self.armortype = spectatee.armortype;
1677         self.armorvalue = spectatee.armorvalue;
1678         self.ammo_cells = spectatee.ammo_cells;
1679         self.ammo_plasma = spectatee.ammo_plasma;
1680         self.ammo_shells = spectatee.ammo_shells;
1681         self.ammo_nails = spectatee.ammo_nails;
1682         self.ammo_rockets = spectatee.ammo_rockets;
1683         self.ammo_fuel = spectatee.ammo_fuel;
1684         self.clip_load = spectatee.clip_load;
1685         self.clip_size = spectatee.clip_size;
1686         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1687         self.health = spectatee.health;
1688         self.impulse = 0;
1689         self.items = spectatee.items;
1690         self.last_pickup = spectatee.last_pickup;
1691         self.hit_time = spectatee.hit_time;
1692         self.strength_finished = spectatee.strength_finished;
1693         self.invincible_finished = spectatee.invincible_finished;
1694         self.pressedkeys = spectatee.pressedkeys;
1695         self.weapons = spectatee.weapons;
1696         self.switchweapon = spectatee.switchweapon;
1697         self.switchingweapon = spectatee.switchingweapon;
1698         self.weapon = spectatee.weapon;
1699         self.vortex_charge = spectatee.vortex_charge;
1700         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1701         self.hagar_load = spectatee.hagar_load;
1702         self.arc_heat_percent = spectatee.arc_heat_percent;
1703         self.minelayer_mines = spectatee.minelayer_mines;
1704         self.punchangle = spectatee.punchangle;
1705         self.view_ofs = spectatee.view_ofs;
1706         self.velocity = spectatee.velocity;
1707         self.dmg_take = spectatee.dmg_take;
1708         self.dmg_save = spectatee.dmg_save;
1709         self.dmg_inflictor = spectatee.dmg_inflictor;
1710         self.v_angle = spectatee.v_angle;
1711         self.angles = spectatee.v_angle;
1712         self.frozen = spectatee.frozen;
1713         self.revive_progress = spectatee.revive_progress;
1714         if(!self.BUTTON_USE)
1715                 self.fixangle = true;
1716         setorigin(self, spectatee.origin);
1717         setsize(self, spectatee.mins, spectatee.maxs);
1718         SetZoomState(spectatee.zoomstate);
1719
1720     anticheat_spectatecopy(spectatee);
1721         self.hud = spectatee.hud;
1722         if(spectatee.vehicle)
1723     {
1724         self.fixangle = false;
1725         //self.velocity = spectatee.vehicle.velocity;
1726         self.vehicle_health = spectatee.vehicle_health;
1727         self.vehicle_shield = spectatee.vehicle_shield;
1728         self.vehicle_energy = spectatee.vehicle_energy;
1729         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1730         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1731         self.vehicle_reload1 = spectatee.vehicle_reload1;
1732         self.vehicle_reload2 = spectatee.vehicle_reload2;
1733
1734         msg_entity = self;
1735
1736         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1737             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1738             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1739             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1740
1741         //WriteByte (MSG_ONE, SVC_SETVIEW);
1742         //    WriteEntity(MSG_ONE, self);
1743         //makevectors(spectatee.v_angle);
1744         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1745     }
1746 }
1747
1748 bool SpectateUpdate()
1749 {SELFPARAM();
1750         if(!self.enemy)
1751             return false;
1752
1753         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1754         {
1755                 SetSpectatee(self, NULL);
1756                 return false;
1757         }
1758
1759         SpectateCopy(self.enemy);
1760
1761         return true;
1762 }
1763
1764 bool SpectateSet()
1765 {SELFPARAM();
1766         if(!IS_PLAYER(self.enemy))
1767                 return false;
1768
1769         msg_entity = self;
1770         WriteByte(MSG_ONE, SVC_SETVIEW);
1771         WriteEntity(MSG_ONE, self.enemy);
1772         self.movetype = MOVETYPE_NONE;
1773         accuracy_resend(self);
1774
1775         if(!SpectateUpdate())
1776                 PutObserverInServer();
1777
1778         return true;
1779 }
1780
1781 void SetSpectatee(entity player, entity spectatee)
1782 {
1783         entity old_spectatee = player.enemy;
1784
1785         player.enemy = spectatee;
1786
1787         // WEAPONTODO
1788         // these are required to fix the spectator bug with arc
1789         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1790         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1791 }
1792
1793 bool Spectate(entity pl)
1794 {SELFPARAM();
1795         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1796                 return false;
1797         pl = spec_player;
1798
1799         SetSpectatee(self, pl);
1800         return SpectateSet();
1801 }
1802
1803 bool SpectateNext()
1804 {SELFPARAM();
1805         other = find(self.enemy, classname, "player");
1806
1807         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1808                 other = spec_player;
1809         else if (!other)
1810                 other = find(other, classname, "player");
1811
1812         if(other) { SetSpectatee(self, other); }
1813
1814         return SpectateSet();
1815 }
1816
1817 bool SpectatePrev()
1818 {SELFPARAM();
1819         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1820         other = findchain(classname, "player");
1821         if (!other) // no player
1822                 return false;
1823
1824         entity first = other;
1825         // skip players until current spectated player
1826         if(self.enemy)
1827         while(other && other != self.enemy)
1828                 other = other.chain;
1829
1830         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1831         {
1832                 case MUT_SPECPREV_FOUND:
1833                     other = spec_player;
1834                     break;
1835                 case MUT_SPECPREV_RETURN:
1836                     other = spec_player;
1837                     return true;
1838                 case MUT_SPECPREV_CONTINUE:
1839                 default:
1840                 {
1841                         if(other.chain)
1842                                 other = other.chain;
1843                         else
1844                                 other = first;
1845                         break;
1846                 }
1847         }
1848
1849         SetSpectatee(self, other);
1850         return SpectateSet();
1851 }
1852
1853 /*
1854 =============
1855 ShowRespawnCountdown()
1856
1857 Update a respawn countdown display.
1858 =============
1859 */
1860 void ShowRespawnCountdown()
1861 {SELFPARAM();
1862         float number;
1863         if(self.deadflag == DEAD_NO) // just respawned?
1864                 return;
1865         else
1866         {
1867                 number = ceil(self.respawn_time - time);
1868                 if(number <= 0)
1869                         return;
1870                 if(number <= self.respawn_countdown)
1871                 {
1872                         self.respawn_countdown = number - 1;
1873                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1874                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1875                 }
1876         }
1877 }
1878
1879 void LeaveSpectatorMode()
1880 {SELFPARAM();
1881         if(self.caplayer)
1882                 return;
1883         if(nJoinAllowed(self))
1884         {
1885                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1886                 {
1887                         self.classname = STR_PLAYER;
1888
1889                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1890                                 { JoinBestTeam(self, false, true); }
1891
1892                         if(autocvar_g_campaign)
1893                                 { campaign_bots_may_start = 1; }
1894
1895                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1896
1897                         PutClientInServer();
1898
1899                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1900                 }
1901                 else
1902                         stuffcmd(self, "menu_showteamselect\n");
1903         }
1904         else
1905         {
1906                 // Player may not join because g_maxplayers is set
1907                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1908         }
1909 }
1910
1911 /**
1912  * Determines whether the player is allowed to join. This depends on cvar
1913  * g_maxplayers, if it isn't used this function always return true, otherwise
1914  * it checks whether the number of currently playing players exceeds g_maxplayers.
1915  * @return int number of free slots for players, 0 if none
1916  */
1917 float nJoinAllowed(entity ignore)
1918 {SELFPARAM();
1919         if(!ignore)
1920         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1921         // so report 0 free slots if restricted
1922         {
1923                 if(autocvar_g_forced_team_otherwise == "spectate")
1924                         return 0;
1925                 if(autocvar_g_forced_team_otherwise == "spectator")
1926                         return 0;
1927         }
1928
1929         if(self.team_forced < 0)
1930                 return 0; // forced spectators can never join
1931
1932         // TODO simplify this
1933         entity e;
1934         float totalClients = 0;
1935         FOR_EACH_CLIENT(e)
1936                 if(e != ignore)
1937                         totalClients += 1;
1938
1939         if (!autocvar_g_maxplayers)
1940                 return maxclients - totalClients;
1941
1942         float currentlyPlaying = 0;
1943         FOR_EACH_REALCLIENT(e)
1944                 if(IS_PLAYER(e) || e.caplayer)
1945                         currentlyPlaying += 1;
1946
1947         if(currentlyPlaying < autocvar_g_maxplayers)
1948                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1949
1950         return 0;
1951 }
1952
1953 /**
1954  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1955  * g_maxplayers_spectator_blocktime seconds
1956  */
1957 void checkSpectatorBlock()
1958 {SELFPARAM();
1959         if(IS_SPEC(self) || IS_OBSERVER(self))
1960         if(!self.caplayer)
1961         if(IS_REAL_CLIENT(self))
1962         {
1963                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1964                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1965                         dropclient(self);
1966                 }
1967         }
1968 }
1969
1970 void PrintWelcomeMessage()
1971 {SELFPARAM();
1972         if(self.motd_actived_time == 0)
1973         {
1974                 if (autocvar_g_campaign) {
1975                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1976                                 self.motd_actived_time = time;
1977                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1978                         }
1979                 } else {
1980                         if (self.BUTTON_INFO) {
1981                                 self.motd_actived_time = time;
1982                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1983                         }
1984                 }
1985         }
1986         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1987         {
1988                 if (autocvar_g_campaign) {
1989                         if (self.BUTTON_INFO)
1990                                 self.motd_actived_time = time;
1991                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1992                                 self.motd_actived_time = 0;
1993                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1994                         }
1995                 } else {
1996                         if (self.BUTTON_INFO)
1997                                 self.motd_actived_time = time;
1998                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1999                                 self.motd_actived_time = 0;
2000                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2001                         }
2002                 }
2003         }
2004         else //if(self.motd_actived_time < 0) // just connected, motd is active
2005         {
2006                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2007                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2008                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || IS_SPEC(self))
2009                 {
2010                         // instanctly hide MOTD
2011                         self.motd_actived_time = 0;
2012                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2013                 }
2014         }
2015 }
2016
2017 void ObserverThink()
2018 {SELFPARAM();
2019         if ( self.impulse )
2020         {
2021                 MinigameImpulse(self.impulse);
2022                 self.impulse = 0;
2023         }
2024         float prefered_movetype;
2025         if (self.flags & FL_JUMPRELEASED) {
2026                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2027                         self.flags &= ~FL_JUMPRELEASED;
2028                         self.flags |= FL_SPAWNING;
2029                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2030                         self.flags &= ~FL_JUMPRELEASED;
2031                         if(SpectateNext()) {
2032                                 self.classname = STR_SPECTATOR;
2033                         }
2034                 } else {
2035                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2036                         if (self.movetype != prefered_movetype)
2037                                 self.movetype = prefered_movetype;
2038                 }
2039         } else {
2040                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2041                         self.flags |= FL_JUMPRELEASED;
2042                         if(self.flags & FL_SPAWNING)
2043                         {
2044                                 self.flags &= ~FL_SPAWNING;
2045                                 LeaveSpectatorMode();
2046                                 return;
2047                         }
2048                 }
2049         }
2050 }
2051
2052 void SpectatorThink()
2053 {SELFPARAM();
2054         if ( self.impulse )
2055         {
2056                 if(MinigameImpulse(self.impulse))
2057                         self.impulse = 0;
2058         }
2059         if (self.flags & FL_JUMPRELEASED) {
2060                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2061                         self.flags &= ~FL_JUMPRELEASED;
2062                         self.flags |= FL_SPAWNING;
2063                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2064                         self.flags &= ~FL_JUMPRELEASED;
2065                         if(SpectateNext()) {
2066                                 self.classname = STR_SPECTATOR;
2067                         } else {
2068                                 self.classname = STR_OBSERVER;
2069                                 PutClientInServer();
2070                         }
2071                         self.impulse = 0;
2072                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2073                         self.flags &= ~FL_JUMPRELEASED;
2074                         if(SpectatePrev()) {
2075                                 self.classname = STR_SPECTATOR;
2076                         } else {
2077                                 self.classname = STR_OBSERVER;
2078                                 PutClientInServer();
2079                         }
2080                         self.impulse = 0;
2081                 } else if (self.BUTTON_ATCK2) {
2082                         self.flags &= ~FL_JUMPRELEASED;
2083                         self.classname = STR_OBSERVER;
2084                         PutClientInServer();
2085                 } else {
2086                         if(!SpectateUpdate())
2087                                 PutObserverInServer();
2088                 }
2089         } else {
2090                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2091                         self.flags |= FL_JUMPRELEASED;
2092                         if(self.flags & FL_SPAWNING)
2093                         {
2094                                 self.flags &= ~FL_SPAWNING;
2095                                 LeaveSpectatorMode();
2096                                 return;
2097                         }
2098                 }
2099                 if(!SpectateUpdate())
2100                         PutObserverInServer();
2101         }
2102
2103         self.flags |= FL_CLIENT | FL_NOTARGET;
2104 }
2105
2106 void vehicles_enter (entity pl, entity veh);
2107 void PlayerUseKey()
2108 {SELFPARAM();
2109         if (!IS_PLAYER(self))
2110                 return;
2111
2112         if(self.vehicle)
2113         {
2114                 if(!gameover)
2115                 {
2116                         vehicles_exit(VHEF_NORMAL);
2117                         return;
2118                 }
2119         }
2120         else if(autocvar_g_vehicles_enter)
2121         {
2122                 if(!self.frozen)
2123                 if(self.deadflag == DEAD_NO)
2124                 if(!gameover)
2125                 {
2126                         entity head, closest_target = world;
2127                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2128
2129                         while(head) // find the closest acceptable target to enter
2130                         {
2131                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2132                                 if(head.deadflag == DEAD_NO)
2133                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2134                                 if(head.takedamage != DAMAGE_NO)
2135                                 {
2136                                         if(closest_target)
2137                                         {
2138                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2139                                                 { closest_target = head; }
2140                                         }
2141                                         else { closest_target = head; }
2142                                 }
2143
2144                                 head = head.chain;
2145                         }
2146
2147                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2148                 }
2149         }
2150
2151         // a use key was pressed; call handlers
2152         MUTATOR_CALLHOOK(PlayerUseKey);
2153 }
2154
2155
2156 /*
2157 =============
2158 PlayerPreThink
2159
2160 Called every frame for each client before the physics are run
2161 =============
2162 */
2163 .float usekeypressed;
2164 void() nexball_setstatus;
2165 .float last_vehiclecheck;
2166 .int items_added;
2167 void PlayerPreThink ()
2168 {SELFPARAM();
2169         WarpZone_PlayerPhysics_FixVAngle();
2170
2171         self.stat_game_starttime = game_starttime;
2172         self.stat_round_starttime = round_starttime;
2173         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2174         self.stat_leadlimit = autocvar_leadlimit;
2175
2176         self.weaponsinmap = weaponsInMap;
2177
2178         if(frametime)
2179         {
2180                 // physics frames: update anticheat stuff
2181                 anticheat_prethink();
2182         }
2183
2184         if(blockSpectators && frametime)
2185                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2186                 checkSpectatorBlock();
2187
2188         zoomstate_set = 0;
2189
2190         // Savage: Check for nameless players
2191         if (isInvisibleString(self.netname)) {
2192                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2193                 if(autocvar_sv_eventlog)
2194                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2195                 if(self.netname_previous)
2196                         strunzone(self.netname_previous);
2197                 self.netname_previous = strzone(new_name);
2198                 self.netname = self.netname_previous;
2199                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2200         } else if(self.netname_previous != self.netname) {
2201                 if(autocvar_sv_eventlog)
2202                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2203                 if(self.netname_previous)
2204                         strunzone(self.netname_previous);
2205                 self.netname_previous = strzone(self.netname);
2206         }
2207
2208         // version nagging
2209         if(self.version_nagtime)
2210                 if(self.cvar_g_xonoticversion)
2211                         if(time > self.version_nagtime)
2212                         {
2213                                 // don't notify git users
2214                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2215                                 {
2216                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2217                                         {
2218                                                 // notify release users if connecting to git
2219                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2220                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2221                                         }
2222                                         else
2223                                         {
2224                                                 float r;
2225                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2226                                                 if(r < 0)
2227                                                 {
2228                                                         // give users new version
2229                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2230                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2231                                                 }
2232                                                 else if(r > 0)
2233                                                 {
2234                                                         // notify users about old server version
2235                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2236                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2237                                                 }
2238                                         }
2239                                 }
2240                                 self.version_nagtime = 0;
2241                         }
2242
2243         // GOD MODE info
2244         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2245         {
2246                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2247                 self.max_armorvalue = 0;
2248         }
2249
2250         if(self.frozen == 2)
2251         {
2252                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2253                 self.health = max(1, self.revive_progress * start_health);
2254                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2255
2256                 if(self.revive_progress >= 1)
2257                         Unfreeze(self);
2258         }
2259         else if(self.frozen == 3)
2260         {
2261                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2262                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2263
2264                 if(self.health < 1)
2265                 {
2266                         if(self.vehicle)
2267                                 vehicles_exit(VHEF_RELEASE);
2268                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2269                 }
2270                 else if ( self.revive_progress <= 0 )
2271                         Unfreeze(self);
2272         }
2273
2274         MUTATOR_CALLHOOK(PlayerPreThink);
2275
2276         if(autocvar_g_vehicles_enter)
2277         if(time > self.last_vehiclecheck)
2278         if(IS_PLAYER(self))
2279         if(!gameover)
2280         if(!self.frozen)
2281         if(!self.vehicle)
2282         if(self.deadflag == DEAD_NO)
2283         {
2284                 entity veh;
2285                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2286                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2287                 if(veh.deadflag == DEAD_NO)
2288                 if(veh.takedamage != DAMAGE_NO)
2289                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2290                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2291                 else if(!veh.owner)
2292                 if(!veh.team || SAME_TEAM(self, veh))
2293                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2294                 else if(autocvar_g_vehicles_steal)
2295                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2296
2297                 self.last_vehiclecheck = time + 1;
2298         }
2299
2300         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2301         {
2302                 if(self.BUTTON_USE && !self.usekeypressed)
2303                         PlayerUseKey();
2304                 self.usekeypressed = self.BUTTON_USE;
2305         }
2306
2307         if(IS_REAL_CLIENT(self))
2308                 PrintWelcomeMessage();
2309
2310         if(IS_PLAYER(self))
2311         {
2312
2313                 CheckRules_Player();
2314
2315                 if (intermission_running)
2316                 {
2317                         IntermissionThink ();   // otherwise a button could be missed between
2318                         return;                                 // the think tics
2319                 }
2320
2321                 //don't allow the player to turn around while game is paused!
2322                 if(timeout_status == TIMEOUT_ACTIVE) {
2323                         // FIXME turn this into CSQC stuff
2324                         self.v_angle = self.lastV_angle;
2325                         self.angles = self.lastV_angle;
2326                         self.fixangle = true;
2327                 }
2328
2329                 if(frametime)
2330                 {
2331                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2332                         {
2333                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2334                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2335                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2336
2337                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2338                                 {
2339                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2340                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2341                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2342                                 }
2343                         }
2344                         else
2345                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2346
2347                         player_powerups();
2348                 }
2349
2350                 if (self.deadflag != DEAD_NO)
2351                 {
2352                         if(self.personal && g_race_qualifying)
2353                         {
2354                                 if(time > self.respawn_time)
2355                                 {
2356                                         self.respawn_time = time + 1; // only retry once a second
2357                                         self.stat_respawn_time = self.respawn_time;
2358                                         respawn();
2359                                         self.impulse = 141;
2360                                 }
2361                         }
2362                         else
2363                         {
2364                                 float button_pressed;
2365                                 if(frametime)
2366                                         player_anim();
2367                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2368
2369                                 if (self.deadflag == DEAD_DYING)
2370                                 {
2371                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2372                                                 self.deadflag = DEAD_RESPAWNING;
2373                                         else if(!button_pressed)
2374                                                 self.deadflag = DEAD_DEAD;
2375                                 }
2376                                 else if (self.deadflag == DEAD_DEAD)
2377                                 {
2378                                         if(button_pressed)
2379                                                 self.deadflag = DEAD_RESPAWNABLE;
2380                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2381                                                 self.deadflag = DEAD_RESPAWNING;
2382                                 }
2383                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2384                                 {
2385                                         if(!button_pressed)
2386                                                 self.deadflag = DEAD_RESPAWNING;
2387                                 }
2388                                 else if (self.deadflag == DEAD_RESPAWNING)
2389                                 {
2390                                         if(time > self.respawn_time)
2391                                         {
2392                                                 self.respawn_time = time + 1; // only retry once a second
2393                                                 self.respawn_time_max = self.respawn_time;
2394                                                 respawn();
2395                                         }
2396                                 }
2397
2398                                 ShowRespawnCountdown();
2399
2400                                 if(self.respawn_flags & RESPAWN_SILENT)
2401                                         self.stat_respawn_time = 0;
2402                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2403                                         self.stat_respawn_time = self.respawn_time_max;
2404                                 else
2405                                         self.stat_respawn_time = self.respawn_time;
2406                         }
2407
2408                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2409                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2410                                 self.stat_respawn_time *= -1;
2411
2412                         return;
2413                 }
2414
2415                 self.prevorigin = self.origin;
2416
2417                 float do_crouch = self.BUTTON_CROUCH;
2418                 if(self.hook.state)
2419                         do_crouch = 0;
2420                 if(self.vehicle)
2421                         do_crouch = 0;
2422                 if(self.frozen)
2423                         do_crouch = 0;
2424
2425                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2426                 // It cannot be predicted by the engine!
2427                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2428                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.(weaponentity).wframe == WFRAME_FIRE2 && time < self.(weaponentity).weapon_nextthink)
2429                         do_crouch = 0;
2430
2431                 if (do_crouch)
2432                 {
2433                         if (!self.crouch)
2434                         {
2435                                 self.crouch = true;
2436                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2437                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2438                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2439                         }
2440                 }
2441                 else
2442                 {
2443                         if (self.crouch)
2444                         {
2445                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2446                                 if (!trace_startsolid)
2447                                 {
2448                                         self.crouch = false;
2449                                         self.view_ofs = self.stat_pl_view_ofs;
2450                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2451                                 }
2452                         }
2453                 }
2454
2455                 FixPlayermodel(self);
2456
2457                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2458                 //if(frametime)
2459                 {
2460                         self.items &= ~self.items_added;
2461
2462                         W_WeaponFrame(self);
2463
2464                         self.items_added = 0;
2465                         if(self.items & ITEM_Jetpack.m_itemid)
2466                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2467                                         self.items_added |= IT_FUEL;
2468
2469                         self.items |= self.items_added;
2470                 }
2471
2472                 player_regen();
2473
2474                 // WEAPONTODO: Add a weapon request for this
2475                 // rot vortex charge to the charge limit
2476                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2477                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2478
2479                 if(frametime)
2480                         player_anim();
2481
2482                 // secret status
2483                 secrets_setstatus();
2484
2485                 // monsters status
2486                 monsters_setstatus();
2487
2488                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2489
2490                 //self.angles_y=self.v_angle_y + 90;   // temp
2491         } else if(gameover) {
2492                 if (intermission_running)
2493                         IntermissionThink ();   // otherwise a button could be missed between
2494                 return;
2495         } else if(IS_OBSERVER(self)) {
2496                 ObserverThink();
2497         } else if(IS_SPEC(self)) {
2498                 SpectatorThink();
2499         }
2500
2501         // WEAPONTODO: Add weapon request for this
2502         if(!zoomstate_set)
2503                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2504
2505         float oldspectatee_status;
2506         oldspectatee_status = self.spectatee_status;
2507         if(IS_SPEC(self))
2508                 self.spectatee_status = num_for_edict(self.enemy);
2509         else if(IS_OBSERVER(self))
2510                 self.spectatee_status = num_for_edict(self);
2511         else
2512                 self.spectatee_status = 0;
2513         if(self.spectatee_status != oldspectatee_status)
2514         {
2515                 ClientData_Touch(self);
2516         }
2517
2518         if(self.teamkill_soundtime)
2519         if(time > self.teamkill_soundtime)
2520         {
2521                 self.teamkill_soundtime = 0;
2522
2523                 setself(self.teamkill_soundsource);
2524                 entity oldpusher = self.pusher;
2525                 self.pusher = this;
2526
2527                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2528
2529                 self.pusher = oldpusher;
2530                 setself(this);
2531         }
2532
2533         if(self.taunt_soundtime)
2534         if(time > self.taunt_soundtime)
2535         {
2536                 self.taunt_soundtime = 0;
2537                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2538         }
2539
2540         target_voicescript_next(self);
2541
2542         // WEAPONTODO: Move into weaponsystem somehow
2543         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2544         if(!self.weapon)
2545                 self.clip_load = self.clip_size = 0;
2546 }
2547
2548 /*
2549 =============
2550 PlayerPostThink
2551
2552 Called every frame for each client after the physics are run
2553 =============
2554 */
2555 .float idlekick_lasttimeleft;
2556 void PlayerPostThink ()
2557 {SELFPARAM();
2558         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2559         if(IS_REAL_CLIENT(self))
2560         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2561         {
2562                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2563                 {
2564                         if(self.idlekick_lasttimeleft)
2565                         {
2566                                 self.idlekick_lasttimeleft = 0;
2567                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2568                         }
2569                 }
2570                 else
2571                 {
2572                         float timeleft;
2573                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2574                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2575                         {
2576                                 if(!self.idlekick_lasttimeleft)
2577                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2578                         }
2579                         if(timeleft <= 0)
2580                         {
2581                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2582                                 dropclient(self);
2583                                 return;
2584                         }
2585                         else if(timeleft <= 10)
2586                         {
2587                                 if(timeleft != self.idlekick_lasttimeleft)
2588                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2589                                 self.idlekick_lasttimeleft = timeleft;
2590                         }
2591                 }
2592         }
2593
2594         CheatFrame();
2595
2596         //CheckPlayerJump();
2597
2598         if(IS_PLAYER(self)) {
2599                 CheckRules_Player();
2600                 UpdateChatBubble();
2601                 if (self.impulse)
2602                         ImpulseCommands();
2603                 if (intermission_running)
2604                         return;         // intermission or finale
2605                 GetPressedKeys();
2606         }
2607
2608         /*
2609         float i;
2610         for(i = 0; i < 1000; ++i)
2611         {
2612                 vector end;
2613                 end = self.origin + '0 0 1024' + 512 * randomvec();
2614                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2615                 if(trace_fraction < 1)
2616                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2617                 {
2618                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2619                         break;
2620                 }
2621         }
2622         */
2623
2624         if(self.waypointsprite_attachedforcarrier)
2625                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2626
2627         playerdemo_write();
2628
2629         CSQCMODEL_AUTOUPDATE(self);
2630 }