Remove some more g_lms checks & add a use for mega health (disabled by default)
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 float ClientData_Send(entity to, float sf)
10 {
11         if(to != self.owner)
12         {
13                 error("wtf");
14                 return FALSE;
15         }
16
17         entity e;
18
19         e = to;
20         if(to.classname == "spectator")
21                 e = to.enemy;
22
23         sf = 0;
24
25         if(e.race_completed)
26                 sf |= 1; // forced scoreboard
27         if(to.spectatee_status)
28                 sf |= 2; // spectator ent number follows
29         if(e.zoomstate)
30                 sf |= 4; // zoomed
31         if(e.porto_v_angle_held)
32                 sf |= 8; // angles held
33
34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
35         WriteByte(MSG_ENTITY, sf);
36
37         if(sf & 2)
38                 WriteByte(MSG_ENTITY, to.spectatee_status);
39
40         if(sf & 8)
41         {
42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
44         }
45
46         return TRUE;
47 }
48
49 void ClientData_Attach()
50 {
51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
52         self.clientdata.drawonlytoclient = self;
53         self.clientdata.owner = self;
54 }
55
56 void ClientData_Detach()
57 {
58         remove(self.clientdata);
59         self.clientdata = world;
60 }
61
62 void ClientData_Touch(entity e)
63 {
64         e.clientdata.SendFlags = 1;
65
66         // make it spectatable
67         entity e2;
68         FOR_EACH_REALCLIENT(e2)
69         {
70                 if(e2 != e)
71                         if(e2.classname == "spectator")
72                                 if(e2.enemy == e)
73                                         e2.clientdata.SendFlags = 1;
74         }
75 }
76
77
78 .vector spawnpoint_score;
79 .string netname_previous;
80
81 void spawnfunc_info_player_survivor (void)
82 {
83         spawnfunc_info_player_deathmatch();
84 }
85
86 void spawnfunc_info_player_start (void)
87 {
88         spawnfunc_info_player_deathmatch();
89 }
90
91 void spawnfunc_info_player_deathmatch (void)
92 {
93         self.classname = "info_player_deathmatch";
94         relocate_spawnpoint();
95 }
96
97 void spawnpoint_use()
98 {
99         if(teamplay)
100         if(have_team_spawns > 0)
101         {
102                 self.team = activator.team;
103                 some_spawn_has_been_used = 1;
104         }
105 }
106
107 // Returns:
108 //   _x: prio (-1 if unusable)
109 //   _y: weight
110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
111 {
112         float shortest, thisdist;
113         float prio;
114         entity player;
115
116         prio = 0;
117
118         // filter out spots for the wrong team
119         if(teamcheck >= 0)
120                 if(spot.team != teamcheck)
121                         return '-1 0 0';
122
123         if(race_spawns)
124                 if(spot.target == "")
125                         return '-1 0 0';
126
127         if(clienttype(self) == CLIENTTYPE_REAL)
128         {
129                 if(spot.restriction == 1)
130                         return '-1 0 0';
131         }
132         else
133         {
134                 if(spot.restriction == 2)
135                         return '-1 0 0';
136         }
137
138         shortest = vlen(world.maxs - world.mins);
139         FOR_EACH_PLAYER(player) if (player != self)
140         {
141                 thisdist = vlen(player.origin - spot.origin);
142                 if (thisdist < shortest)
143                         shortest = thisdist;
144         }
145         if(shortest > mindist)
146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
147
148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
149         spawn_spot = spot;
150
151         // filter out spots for assault
152         if(spot.target != "") {
153                 entity ent;
154                 float found;
155
156                 found = 0;
157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
158                 {
159                         ++found;
160                         if(ent.spawn_evalfunc)
161                         {
162                                 entity oldself = self;
163                                 self = ent;
164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
165                                 self = oldself;
166                                 if(spawn_score_x < 0)
167                                         return spawn_score;
168                         }
169                 }
170
171                 if(!found)
172                 {
173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
174                         return '-1 0 0';
175                 }
176         }
177
178         MUTATOR_CALLHOOK(Spawn_Score);
179         return spawn_score;
180 }
181
182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
183 {
184         entity spot;
185         for(spot = firstspot; spot; spot = spot.chain)
186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
187 }
188
189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
190 {
191         entity spot, spotlist, spotlistend;
192
193         spotlist = world;
194         spotlistend = world;
195
196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
197
198         for(spot = firstspot; spot; spot = spot.chain)
199         {
200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
201                 {
202                         if(spotlistend)
203                                 spotlistend.chain = spot;
204                         spotlistend = spot;
205                         if(!spotlist)
206                                 spotlist = spot;
207                 }
208         }
209         if(spotlistend)
210                 spotlistend.chain = world;
211
212         return spotlist;
213 }
214
215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
216 {
217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
219         entity spot;
220
221         RandomSelection_Init();
222         for(spot = firstspot; spot; spot = spot.chain)
223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
224
225         return RandomSelection_chosen_ent;
226 }
227
228 /*
229 =============
230 SelectSpawnPoint
231
232 Finds a point to respawn
233 =============
234 */
235 entity SelectSpawnPoint (float anypoint)
236 {
237         float teamcheck;
238         entity spot, firstspot;
239
240         spot = find (world, classname, "testplayerstart");
241         if (spot)
242                 return spot;
243
244         if(anypoint || autocvar_g_spawn_useallspawns)
245                 teamcheck = -1;
246         else if(have_team_spawns > 0)
247         {
248                 if(have_team_spawns_forteam[self.team] == 0)
249                 {
250                         // we request a spawn for a team, and we have team
251                         // spawns, but that team has no spawns?
252                         if(have_team_spawns_forteam[0])
253                                 // try noteam spawns
254                                 teamcheck = 0;
255                         else
256                                 // if not, any spawn has to do
257                                 teamcheck = -1;
258                 }
259                 else
260                         teamcheck = self.team; // MUST be team
261         }
262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
263                 teamcheck = 0; // MUST be noteam
264         else
265                 teamcheck = -1;
266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
267
268
269         // get the entire list of spots
270         firstspot = findchain(classname, "info_player_deathmatch");
271         // filter out the bad ones
272         // (note this returns the original list if none survived)
273         if(anypoint)
274         {
275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
276         }
277         else
278         {
279                 float mindist;
280                 if (arena_roundbased && !g_ca)
281                         mindist = 800;
282                 else
283                         mindist = 100;
284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
285
286                 // there is 50/50 chance of choosing a random spot or the furthest spot
287                 // (this means that roughly every other spawn will be furthest, so you
288                 // usually won't get fragged at spawn twice in a row)
289                 if (random() > autocvar_g_spawn_furthest)
290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
291                 else
292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
293         }
294
295         if (!spot)
296         {
297                 if(autocvar_spawn_debug)
298                         GotoNextMap(0);
299                 else
300                 {
301                         if(some_spawn_has_been_used)
302                                 return world; // team can't spawn any more, because of actions of other team
303                         else
304                                 error("Cannot find a spawn point - please fix the map!");
305                 }
306         }
307
308         return spot;
309 }
310
311 /*
312 =============
313 CheckPlayerModel
314
315 Checks if the argument string can be a valid playermodel.
316 Returns a valid one in doubt.
317 =============
318 */
319 string FallbackPlayerModel;
320 string CheckPlayerModel(string plyermodel) {
321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
322         {
323                 // note: we cannot summon Don Strunzone here, some player may
324                 // still have the model string set. In case anyone manages how
325                 // to change a cvar default, we'll have a small leak here.
326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
327         }
328         // only in right path
329         if( substring(plyermodel,0,14) != "models/player/")
330                 return FallbackPlayerModel;
331         // only good file extensions
332         if(substring(plyermodel,-4,4) != ".zym")
333         if(substring(plyermodel,-4,4) != ".dpm")
334         if(substring(plyermodel,-4,4) != ".iqm")
335         if(substring(plyermodel,-4,4) != ".md3")
336         if(substring(plyermodel,-4,4) != ".psk")
337                 return FallbackPlayerModel;
338         // forbid the LOD models
339         if(substring(plyermodel, -9,5) == "_lod1")
340                 return FallbackPlayerModel;
341         if(substring(plyermodel, -9,5) == "_lod2")
342                 return FallbackPlayerModel;
343         if(plyermodel != strtolower(plyermodel))
344                 return FallbackPlayerModel;
345         // also, restrict to server models
346         if(autocvar_sv_servermodelsonly)
347         {
348                 if(!fexists(plyermodel))
349                         return FallbackPlayerModel;
350         }
351         return plyermodel;
352 }
353
354 void setplayermodel(entity e, string modelname)
355 {
356         precache_model(modelname);
357         setmodel(e, modelname);
358         player_setupanimsformodel();
359         UpdatePlayerSounds();
360 }
361
362 /*
363 =============
364 PutObserverInServer
365
366 putting a client as observer in the server
367 =============
368 */
369 void FixPlayermodel();
370 void PutObserverInServer (void)
371 {
372         entity  spot;
373     self.hud = HUD_NORMAL;
374         race_PreSpawnObserver();
375
376         spot = SelectSpawnPoint (TRUE);
377         if(!spot)
378                 error("No spawnpoints for observers?!?\n");
379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
380
381         if(clienttype(self) == CLIENTTYPE_REAL)
382         {
383                 msg_entity = self;
384                 WriteByte(MSG_ONE, SVC_SETVIEW);
385                 WriteEntity(MSG_ONE, self);
386         }
387
388         MUTATOR_CALLHOOK(MakePlayerObserver);
389
390         minstagib_stop_countdown(self);
391
392         Portal_ClearAll(self);
393         
394         if(self.alivetime)
395         {
396                 if(!inWarmupStage)
397                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
398                 self.alivetime = 0;
399         }
400
401         if(self.vehicle)
402                 vehicles_exit(VHEF_RELESE);         
403
404         WaypointSprite_PlayerDead();
405
406         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
407                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
408
409         if(self.killcount != -666)
410         {
411                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
412
413                 if(self.just_joined == FALSE) {
414                         LogTeamchange(self.playerid, -1, 4);
415                 } else
416                         self.just_joined = FALSE;
417         }
418
419         PlayerScore_Clear(self); // clear scores when needed
420
421         accuracy_resend(self);
422
423         self.spectatortime = time;
424         
425         self.classname = "observer";
426         self.iscreature = FALSE;
427         self.teleportable = TELEPORT_SIMPLE;
428         self.damagedbycontents = FALSE;
429         self.health = -666;
430         self.takedamage = DAMAGE_NO;
431         self.solid = SOLID_NOT;
432         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
433         self.flags = FL_CLIENT | FL_NOTARGET;
434         self.armorvalue = 666;
435         self.effects = 0;
436         self.armorvalue = autocvar_g_balance_armor_start;
437         self.pauserotarmor_finished = 0;
438         self.pauserothealth_finished = 0;
439         self.pauseregen_finished = 0;
440         self.damageforcescale = 0;
441         self.death_time = 0;
442         self.respawn_time = 0;
443         self.alpha = 0;
444         self.scale = 0;
445         self.fade_time = 0;
446         self.pain_frame = 0;
447         self.pain_finished = 0;
448         self.strength_finished = 0;
449         self.invincible_finished = 0;
450         self.superweapons_finished = 0;
451         self.pushltime = 0;
452         self.istypefrag = 0;
453         self.think = func_null;
454         self.nextthink = 0;
455         self.hook_time = 0;
456         self.deadflag = DEAD_NO;
457         self.angles = spot.angles;
458         self.angles_z = 0;
459         self.fixangle = TRUE;
460         self.crouch = FALSE;
461
462         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
463         self.prevorigin = self.origin;
464         self.items = 0;
465         WEPSET_CLEAR_E(self);
466         self.model = "";
467         FixPlayermodel();
468         setmodel(self, "null");
469         self.drawonlytoclient = self;
470
471         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
472         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
473
474         self.weapon = 0;
475         self.weaponname = "";
476         self.switchingweapon = 0;
477         self.weaponmodel = "";
478         self.weaponentity = world;
479         self.exteriorweaponentity = world;
480         self.killcount = -666;
481         self.velocity = '0 0 0';
482         self.avelocity = '0 0 0';
483         self.punchangle = '0 0 0';
484         self.punchvector = '0 0 0';
485         self.oldvelocity = self.velocity;
486         self.fire_endtime = -1;
487
488         if(g_arena)
489         {
490                 if(self.version_mismatch)
491                 {
492                         self.frags = FRAGS_SPECTATOR;
493                         Spawnqueue_Unmark(self);
494                         Spawnqueue_Remove(self);
495                 }
496                 else
497                 {
498                         self.frags = FRAGS_LMS_LOSER;
499                         Spawnqueue_Insert(self);
500                 }
501         }
502         else if(g_ca)
503         {
504                 if(self.caplayer)
505                         self.frags = FRAGS_LMS_LOSER;
506                 else
507                         self.frags = FRAGS_SPECTATOR;
508         }
509         else if((g_race && g_race_qualifying) || g_cts)
510         {
511                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
512                         self.frags = FRAGS_LMS_LOSER;
513                 else
514                         self.frags = FRAGS_SPECTATOR;
515         }
516         else
517                 self.frags = FRAGS_SPECTATOR;
518 }
519
520 .float model_randomizer;
521 void FixPlayermodel()
522 {
523         string defaultmodel;
524         float defaultskin, chmdl, oldskin, n, i;
525         vector m1, m2;
526
527         defaultmodel = "";
528         defaultskin = 0;
529         chmdl = FALSE;
530
531         if(autocvar_sv_defaultcharacter == 1)
532         {
533                 if(teamplay)
534                 {
535                         string s;
536                         s = Team_ColorName_Lower(self.team);
537                         if(s != "neutral")
538                         {
539                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
540                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
541                         }
542                 }
543
544                 if(defaultmodel == "")
545                 {
546                         defaultmodel = autocvar_sv_defaultplayermodel;
547                         defaultskin = autocvar_sv_defaultplayerskin;
548                 }
549
550                 n = tokenize_console(defaultmodel);
551                 if(n > 0)
552                         defaultmodel = argv(floor(n * self.model_randomizer));
553
554                 i = strstrofs(defaultmodel, ":", 0);
555                 if(i >= 0)
556                 {
557                         defaultskin = stof(substring(defaultmodel, i+1, -1));
558                         defaultmodel = substring(defaultmodel, 0, i);
559                 }
560         }
561
562         if(defaultmodel != "")
563         {
564                 if (defaultmodel != self.model)
565                 {
566                         m1 = self.mins;
567                         m2 = self.maxs;
568                         setplayermodel (self, defaultmodel);
569                         setsize (self, m1, m2);
570                         chmdl = TRUE;
571                 }
572
573                 oldskin = self.skin;
574                 self.skin = defaultskin;
575         } else {
576                 if (self.playermodel != self.model || self.playermodel == "")
577                 {
578                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
579                         m1 = self.mins;
580                         m2 = self.maxs;
581                         setplayermodel (self, self.playermodel);
582                         setsize (self, m1, m2);
583                         chmdl = TRUE;
584                 }
585
586                 oldskin = self.skin;
587                 self.skin = stof(self.playerskin);
588         }
589
590         if(chmdl || oldskin != self.skin) // model or skin has changed
591         {
592                 self.species = player_getspecies(); // update species
593                 UpdatePlayerSounds(); // update skin sounds
594         }
595
596         if(!teamplay)
597                 if(strlen(autocvar_sv_defaultplayercolors))
598                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
599                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
600 }
601
602 /*
603 =============
604 PutClientInServer
605
606 Called when a client spawns in the server
607 =============
608 */
609
610 void PutClientInServer (void)
611 {
612         if(clienttype(self) == CLIENTTYPE_BOT)
613         {
614                 self.classname = "player";
615                 if(g_ca)
616                         self.caplayer = 1;
617         }
618         else if(clienttype(self) == CLIENTTYPE_REAL)
619         {
620                 msg_entity = self;
621                 WriteByte(MSG_ONE, SVC_SETVIEW);
622                 WriteEntity(MSG_ONE, self);
623         }
624
625         // reset player keys
626         self.itemkeys = 0;
627
628         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
629                 self.classname = "observer";
630                 
631         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
632                 self.classname = "observer";
633
634         if(gameover)
635                 self.classname = "observer";
636
637         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
638                 entity spot, oldself;
639                 float j;
640
641                 accuracy_resend(self);
642
643                 if(self.team < 0)
644                         JoinBestTeam(self, FALSE, TRUE);
645
646                 race_PreSpawn();
647
648                 spot = SelectSpawnPoint (FALSE);
649                 if(!spot)
650                 {
651                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
652                         return; // spawn failed
653                 }
654
655                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
656
657                 self.classname = "player";
658                 self.wasplayer = TRUE;
659                 self.iscreature = TRUE;
660                 self.teleportable = TELEPORT_NORMAL;
661                 self.damagedbycontents = TRUE;
662                 self.movetype = MOVETYPE_WALK;
663                 self.solid = SOLID_SLIDEBOX;
664                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
665                 if(autocvar_g_playerclip_collisions)
666                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
667                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
668                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
669                 self.frags = FRAGS_PLAYER;
670                 if(INDEPENDENT_PLAYERS)
671                         MAKE_INDEPENDENT_PLAYER(self);
672                 self.flags = FL_CLIENT;
673                 if(autocvar__notarget)
674                         self.flags |= FL_NOTARGET;
675                 self.takedamage = DAMAGE_AIM;
676                 if(g_minstagib)
677                         self.effects = EF_FULLBRIGHT;
678                 else
679                         self.effects = 0;
680                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
681                 self.air_finished = time + 12;
682                 self.dmg = 2;
683                 if(autocvar_g_balance_nex_charge)
684                 {
685                         if(autocvar_g_balance_nex_secondary_chargepool)
686                                 self.nex_chargepool_ammo = 1;
687                         self.nex_charge = autocvar_g_balance_nex_charge_start;
688                 }
689
690                 if(inWarmupStage)
691                 {
692                         self.ammo_shells = warmup_start_ammo_shells;
693                         self.ammo_nails = warmup_start_ammo_nails;
694                         self.ammo_rockets = warmup_start_ammo_rockets;
695                         self.ammo_cells = warmup_start_ammo_cells;
696                         self.ammo_fuel = warmup_start_ammo_fuel;
697                         self.health = warmup_start_health;
698                         self.armorvalue = warmup_start_armorvalue;
699                         WEPSET_COPY_EA(self, warmup_start_weapons);
700                 }
701                 else
702                 {
703                         self.ammo_shells = start_ammo_shells;
704                         self.ammo_nails = start_ammo_nails;
705                         self.ammo_rockets = start_ammo_rockets;
706                         self.ammo_cells = start_ammo_cells;
707                         self.ammo_fuel = start_ammo_fuel;
708                         self.health = start_health;
709                         self.armorvalue = start_armorvalue;
710                         WEPSET_COPY_EA(self, start_weapons);
711                 }
712
713                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
714                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
715                 else
716                         self.superweapons_finished = 0;
717
718                 if(g_weaponarena_random)
719                 {
720                         if(g_weaponarena_random_with_laser)
721                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
722                         W_RandomWeapons(self, g_weaponarena_random);
723                         if(g_weaponarena_random_with_laser)
724                                 WEPSET_OR_EW(self, WEP_LASER);
725                 }
726
727                 self.items = start_items;
728
729                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
730                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
731                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
732                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
733                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
734                 //extend the pause of rotting if client was reset at the beginning of the countdown
735                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
736                         self.spawnshieldtime += game_starttime - time;
737                         self.pauserotarmor_finished += game_starttime - time;
738                         self.pauserothealth_finished += game_starttime - time;
739                         self.pauseregen_finished += game_starttime - time;
740                 }
741                 self.damageforcescale = 2;
742                 self.death_time = 0;
743                 self.respawn_time = 0;
744                 self.scale = 0;
745                 self.fade_time = 0;
746                 self.pain_frame = 0;
747                 self.pain_finished = 0;
748                 self.strength_finished = 0;
749                 self.invincible_finished = 0;
750                 self.pushltime = 0;
751                 // players have no think function
752                 self.think = func_null;
753                 self.nextthink = 0;
754                 self.hook_time = 0;
755                 self.dmg_team = 0;
756                 self.ballistics_density = autocvar_g_ballistics_density_player;
757
758                 self.metertime = 0;
759
760                 self.deadflag = DEAD_NO;
761
762                 self.angles = spot.angles;
763
764                 self.angles_z = 0; // never spawn tilted even if the spot says to
765                 self.fixangle = TRUE; // turn this way immediately
766                 self.velocity = '0 0 0';
767                 self.avelocity = '0 0 0';
768                 self.punchangle = '0 0 0';
769                 self.punchvector = '0 0 0';
770                 self.oldvelocity = self.velocity;
771                 self.fire_endtime = -1;
772
773                 msg_entity = self;
774                 WRITESPECTATABLE_MSG_ONE({
775                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
776                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
777                 });
778
779                 self.model = "";
780                 FixPlayermodel();
781                 self.drawonlytoclient = world;
782
783                 self.crouch = FALSE;
784                 self.view_ofs = PL_VIEW_OFS;
785                 setsize (self, PL_MIN, PL_MAX);
786                 self.spawnorigin = spot.origin;
787                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
788                 // don't reset back to last position, even if new position is stuck in solid
789                 self.oldorigin = self.origin;
790                 self.prevorigin = self.origin;
791                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
792                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
793         self.hud = HUD_NORMAL;
794
795                 if(g_arena)
796                 {
797                         Spawnqueue_Remove(self);
798                         Spawnqueue_Mark(self);
799                 }
800                 else if(g_ca)
801                         self.caplayer = 1;
802
803                 self.event_damage = PlayerDamage;
804
805                 self.bot_attack = TRUE;
806
807                 self.statdraintime = time + 5;
808                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
809
810                 if(self.killcount == -666) {
811                         PlayerScore_Clear(self);
812                         self.killcount = 0;
813                 }
814
815                 CL_SpawnWeaponentity();
816                 self.alpha = default_player_alpha;
817                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
818                 self.exteriorweaponentity.alpha = default_weapon_alpha;
819
820                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
821                 self.lms_traveled_distance = 0;
822                 self.speedrunning = FALSE;
823
824                 race_PostSpawn(spot);
825
826                 //stuffcmd(self, "chase_active 0");
827                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
828
829                 if(g_assault) {
830                         if(self.team == assault_attacker_team)
831                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
832                         else
833                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
834                 }
835
836                 target_voicescript_clear(self);
837
838                 // reset fields the weapons may use
839                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
840                 {
841                         weapon_action(j, WR_RESETPLAYER);
842
843                         // all weapons must be fully loaded when we spawn
844                         entity e;
845                         e = get_weaponinfo(j);
846                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
847                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
848                 }
849
850                 oldself = self;
851                 self = spot;
852                         activator = oldself;
853                                 string s;
854                                 s = self.target;
855                                 self.target = string_null;
856                                 SUB_UseTargets();
857                                 self.target = s;
858                         activator = world;
859                 self = oldself;
860
861                 spawn_spot = spot;
862                 MUTATOR_CALLHOOK(PlayerSpawn);
863
864                 if(autocvar_spawn_debug)
865                 {
866                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
867                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
868                 }
869
870                 self.switchweapon = w_getbestweapon(self);
871                 self.cnt = -1; // W_LastWeapon will not complain
872                 self.weapon = 0;
873                 self.weaponname = "";
874                 self.switchingweapon = 0;
875
876                 if(!inWarmupStage)
877                         if(!self.alivetime)
878                                 self.alivetime = time;
879
880                 antilag_clear(self);
881
882                 if (autocvar_g_spawnsound)
883                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
884         } else if(self.classname == "observer") {
885                 PutObserverInServer ();
886         }
887 }
888
889 .float ebouncefactor, ebouncestop; // electro's values
890 // TODO do we need all these fields, or should we stop autodetecting runtime
891 // changes and just have a console command to update this?
892 float ClientInit_SendEntity(entity to, float sf)
893 {
894         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
895         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
896         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
897         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
898         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
899         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
900         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
901         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
902         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
903         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
904         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
905         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
906         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
907         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
908         if(sv_foginterval && world.fog != "")
909                 WriteString(MSG_ENTITY, world.fog);
910         else
911                 WriteString(MSG_ENTITY, "");
912         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
913         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
914         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
915         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
916         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
917         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
918         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
919         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
920         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
921         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
922         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
923         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
924         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
925         return TRUE;
926 }
927
928 void ClientInit_CheckUpdate()
929 {
930         self.nextthink = time;
931         if(self.count != autocvar_g_balance_armor_blockpercent)
932         {
933                 self.count = autocvar_g_balance_armor_blockpercent;
934                 self.SendFlags |= 1;
935         }
936         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
937         {
938                 self.cnt = autocvar_g_balance_weaponswitchdelay;
939                 self.SendFlags |= 1;
940         }
941         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
942         {
943                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
944                 self.SendFlags |= 1;
945         }
946         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
947         {
948                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
949                 self.SendFlags |= 1;
950         }
951         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
952         {
953                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
954                 self.SendFlags |= 1;
955         }
956         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
957         {
958                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
959                 self.SendFlags |= 1;
960         }
961 }
962
963 void ClientInit_Spawn()
964 {
965         entity o;
966         entity e;
967         e = spawn();
968         e.classname = "clientinit";
969         e.think = ClientInit_CheckUpdate;
970         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
971
972         o = self;
973         self = e;
974         ClientInit_CheckUpdate();
975         self = o;
976 }
977
978 /*
979 =============
980 SetNewParms
981 =============
982 */
983 void SetNewParms (void)
984 {
985         // initialize parms for a new player
986         parm1 = -(86400 * 366);
987 }
988
989 /*
990 =============
991 SetChangeParms
992 =============
993 */
994 void SetChangeParms (void)
995 {
996         // save parms for level change
997         parm1 = self.parm_idlesince - time;
998 }
999
1000 /*
1001 =============
1002 DecodeLevelParms
1003 =============
1004 */
1005 void DecodeLevelParms (void)
1006 {
1007         // load parms
1008         self.parm_idlesince = parm1;
1009         if(self.parm_idlesince == -(86400 * 366))
1010                 self.parm_idlesince = time;
1011
1012         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1013         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1014 }
1015
1016 /*
1017 =============
1018 ClientKill
1019
1020 Called when a client types 'kill' in the console
1021 =============
1022 */
1023
1024 .float clientkill_nexttime;
1025 void ClientKill_Now_TeamChange()
1026 {
1027         if(self.killindicator_teamchange == -1)
1028         {
1029                 JoinBestTeam( self, FALSE, TRUE );
1030         }
1031         else if(self.killindicator_teamchange == -2)
1032         {
1033                 if(g_ca)
1034                         self.caplayer = 0;
1035                 if(blockSpectators)
1036                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1037                 PutObserverInServer();
1038         }
1039         else
1040                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1041 }
1042
1043 void ClientKill_Now()
1044 {
1045         if(self.vehicle)
1046         {
1047             vehicles_exit(VHEF_RELESE);
1048             if(!self.killindicator_teamchange)
1049             {
1050             self.vehicle_health = -1;
1051             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');             
1052             }
1053         }
1054
1055         if(self.killindicator && !wasfreed(self.killindicator))
1056                 remove(self.killindicator);
1057
1058         self.killindicator = world;
1059
1060         if(self.killindicator_teamchange)
1061                 ClientKill_Now_TeamChange();
1062
1063         // in any case:
1064         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1065
1066         // now I am sure the player IS dead
1067 }
1068 void KillIndicator_Think()
1069 {
1070         if (gameover)
1071         {
1072                 self.owner.killindicator = world;
1073                 remove(self);
1074                 return;
1075         }
1076
1077         if (self.owner.alpha < 0 && !self.owner.vehicle)
1078         {
1079                 self.owner.killindicator = world;
1080                 remove(self);
1081                 return;
1082         }
1083
1084         if(self.cnt <= 0)
1085         {
1086                 self = self.owner;
1087                 ClientKill_Now(); // no oldself needed
1088                 return;
1089         }
1090     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1091     {
1092         self.nextthink = time + 1;
1093         self.cnt -= 1;
1094     }
1095         else
1096         {
1097                 if(self.cnt <= 10)
1098                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1099                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1100                 {
1101                         if(self.cnt <= 10)
1102                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1103                 }
1104                 self.nextthink = time + 1;
1105                 self.cnt -= 1;
1106         }
1107 }
1108
1109 float clientkilltime;
1110 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1111 {
1112         float killtime;
1113         float starttime;
1114         entity e;
1115
1116         if (gameover)
1117                 return;
1118
1119         killtime = autocvar_g_balance_kill_delay;
1120
1121         if(g_race_qualifying || g_cts)
1122                 killtime = 0;
1123
1124     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1125     {
1126                 remove(self.killindicator);
1127                 self.killindicator = world;
1128
1129         ClientKill_Now(); // allow instant kill in this case
1130         return;
1131     }
1132
1133         self.killindicator_teamchange = targetteam;
1134
1135     if(!self.killindicator)
1136         {
1137                 if(self.deadflag == DEAD_NO)
1138                 {
1139                         killtime = max(killtime, self.clientkill_nexttime - time);
1140                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1141                 }
1142
1143                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1144                 {
1145                         ClientKill_Now();
1146                 }
1147                 else
1148                 {
1149                         starttime = max(time, clientkilltime);
1150
1151                         self.killindicator = spawn();
1152                         self.killindicator.owner = self;
1153                         self.killindicator.scale = 0.5;
1154                         setattachment(self.killindicator, self, "");
1155                         setorigin(self.killindicator, '0 0 52');
1156                         self.killindicator.think = KillIndicator_Think;
1157                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1158                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1159                         self.killindicator.cnt = ceil(killtime);
1160                         self.killindicator.count = bound(0, ceil(killtime), 10);
1161                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1162
1163                         for(e = world; (e = find(e, classname, "body")) != world; )
1164                         {
1165                                 if(e.enemy != self)
1166                                         continue;
1167                                 e.killindicator = spawn();
1168                                 e.killindicator.owner = e;
1169                                 e.killindicator.scale = 0.5;
1170                                 setattachment(e.killindicator, e, "");
1171                                 setorigin(e.killindicator, '0 0 52');
1172                                 e.killindicator.think = KillIndicator_Think;
1173                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1174                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1175                                 e.killindicator.cnt = ceil(killtime);
1176                         }
1177                         self.lip = 0;
1178                 }
1179         }
1180         if(self.killindicator)
1181         {
1182                 if(targetteam == 0) // just die
1183                 {
1184                         self.killindicator.colormod = '0 0 0';
1185                         if(clienttype(self) == CLIENTTYPE_REAL)
1186                         if(self.killindicator.cnt > 0)
1187                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1188                 }
1189                 else if(targetteam == -1) // auto
1190                 {
1191                         self.killindicator.colormod = '0 1 0';
1192                         if(clienttype(self) == CLIENTTYPE_REAL)
1193                         if(self.killindicator.cnt > 0)
1194                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1195                 }
1196                 else if(targetteam == -2) // spectate
1197                 {
1198                         self.killindicator.colormod = '0.5 0.5 0.5';
1199                         if(clienttype(self) == CLIENTTYPE_REAL)
1200                         if(self.killindicator.cnt > 0)
1201                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1202                 }
1203                 else
1204                 {
1205                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1206                         if(clienttype(self) == CLIENTTYPE_REAL)
1207                         if(self.killindicator.cnt > 0)
1208                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1209                 }
1210         }
1211
1212 }
1213
1214 void ClientKill (void)
1215 {
1216         if (gameover)
1217                 return;
1218
1219         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1220         {
1221                 // do nothing
1222         }
1223     else if(self.freezetag_frozen)
1224     {
1225         // do nothing
1226     }
1227         else
1228                 ClientKill_TeamChange(0);
1229 }
1230
1231 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1232 {
1233     e.killindicator = spawn();
1234     e.killindicator.owner = e;
1235     e.killindicator.think = KillIndicator_Think;
1236     e.killindicator.nextthink = time + (e.lip) * 0.05;
1237     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1238     e.killindicator.health = 1; // this is used to indicate that it should be silent
1239     e.lip = 0;
1240 }
1241
1242 void FixClientCvars(entity e)
1243 {
1244         // send prediction settings to the client
1245         stuffcmd(e, "\nin_bindmap 0 0\n");
1246         if(g_race || g_cts)
1247                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1248         if(autocvar_g_antilag == 3) // client side hitscan
1249                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1250         if(autocvar_sv_gentle)
1251                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1252         /*
1253          * we no longer need to stuff this. Remove this comment block if you feel
1254          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1255         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1256         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1257         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1258         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1259         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1260         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1261         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1262         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1263         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1264         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1265         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1266         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1267         stuffcmd(e, "cl_movement_edgefriction 1\n");
1268          */
1269 }
1270
1271 float PlayerInIDList(entity p, string idlist)
1272 {
1273         float n, i;
1274         string s;
1275
1276         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1277         if not(p.crypto_idfp)
1278                 return 0;
1279
1280         // this function allows abbreviated player IDs too!
1281         n = tokenize_console(idlist);
1282         for(i = 0; i < n; ++i)
1283         {
1284                 s = argv(i);
1285                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1286                         return 1;
1287         }
1288
1289         return 0;
1290 }
1291
1292 /*
1293 =============
1294 ClientConnect
1295
1296 Called when a client connects to the server
1297 =============
1298 */
1299 void DecodeLevelParms (void);
1300 //void dom_player_join_team(entity pl);
1301 void set_dom_state(entity e);
1302 void ClientConnect (void)
1303 {
1304         float t;
1305
1306         if(self.flags & FL_CLIENT)
1307         {
1308                 print("Warning: ClientConnect, but already connected!\n");
1309                 return;
1310         }
1311
1312         if(Ban_MaybeEnforceBanOnce(self))
1313                 return;
1314
1315         DecodeLevelParms();
1316
1317 #ifdef WATERMARK
1318         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1319 #endif
1320
1321         self.classname = "player_joining";
1322
1323         self.flags = FL_CLIENT;
1324         self.version_nagtime = time + 10 + random() * 10;
1325
1326         if(player_count<0)
1327         {
1328                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1329                 player_count = 0;
1330         }
1331
1332         PlayerScore_Attach(self);
1333         ClientData_Attach();
1334         accuracy_init(self);
1335
1336         bot_clientconnect();
1337
1338         playerdemo_init();
1339
1340         anticheat_init();
1341
1342         race_PreSpawnObserver();
1343
1344         // identify the right forced team
1345         if(autocvar_g_campaign)
1346         {
1347                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1348                 {
1349                         switch(autocvar_g_campaign_forceteam)
1350                         {
1351                                 case 1: self.team_forced = NUM_TEAM_1; break;
1352                                 case 2: self.team_forced = NUM_TEAM_2; break;
1353                                 case 3: self.team_forced = NUM_TEAM_3; break;
1354                                 case 4: self.team_forced = NUM_TEAM_4; break;
1355                                 default: self.team_forced = 0;
1356                         }
1357                 }
1358         }
1359         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1360                 self.team_forced = NUM_TEAM_1;
1361         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1362                 self.team_forced = NUM_TEAM_2;
1363         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1364                 self.team_forced = NUM_TEAM_3;
1365         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1366                 self.team_forced = NUM_TEAM_4;
1367         else if(autocvar_g_forced_team_otherwise == "red")
1368                 self.team_forced = NUM_TEAM_1;
1369         else if(autocvar_g_forced_team_otherwise == "blue")
1370                 self.team_forced = NUM_TEAM_2;
1371         else if(autocvar_g_forced_team_otherwise == "yellow")
1372                 self.team_forced = NUM_TEAM_3;
1373         else if(autocvar_g_forced_team_otherwise == "pink")
1374                 self.team_forced = NUM_TEAM_4;
1375         else if(autocvar_g_forced_team_otherwise == "spectate")
1376                 self.team_forced = -1;
1377         else if(autocvar_g_forced_team_otherwise == "spectator")
1378                 self.team_forced = -1;
1379         else
1380                 self.team_forced = 0;
1381
1382         if(!teamplay)
1383                 if(self.team_forced > 0)
1384                         self.team_forced = 0;
1385
1386         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1387
1388         if(autocvar_g_campaign || self.team_forced < 0) {
1389                 self.classname = "observer";
1390         } else {
1391                 if(teamplay)
1392                 {
1393                         if(autocvar_g_balance_teams)
1394                         {
1395                                 self.classname = "player";
1396                                 campaign_bots_may_start = 1;
1397                         }
1398                         else
1399                         {
1400                                 self.classname = "observer"; // do it anyway
1401                         }
1402                 }
1403                 else
1404                 {
1405                         self.classname = "player";
1406                         campaign_bots_may_start = 1;
1407                 }
1408         }
1409
1410         self.playerid = (playerid_last = playerid_last + 1);
1411
1412         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1413
1414     if(clienttype(self) == CLIENTTYPE_BOT)
1415         PlayerStats_AddPlayer(self);
1416
1417         if(autocvar_sv_eventlog)
1418                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1419
1420         LogTeamchange(self.playerid, self.team, 1);
1421
1422         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1423
1424         self.netname_previous = strzone(self.netname);
1425
1426         if((self.classname == STR_PLAYER && teamplay))
1427                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1428         else
1429                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1430
1431         stuffcmd(self, strcat(clientstuff, "\n"));
1432         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1433
1434         FixClientCvars(self);
1435
1436         // spawnfunc_waypoint sprites
1437         WaypointSprite_InitClient(self);
1438
1439         // Wazat's grappling hook
1440         SetGrappleHookBindings();
1441
1442         // get version info from player
1443         stuffcmd(self, "cmd clientversion $gameversion\n");
1444
1445         // get other cvars from player
1446         GetCvars(0);
1447
1448         // notify about available teams
1449         if(teamplay)
1450         {
1451                 CheckAllowedTeams(self);
1452                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1453                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1454         }
1455         else
1456                 stuffcmd(self, "set _teams_available 0\n");
1457
1458         if(g_arena || g_ca)
1459         {
1460                 self.classname = "observer";
1461                 if(g_arena)
1462                         Spawnqueue_Insert(self);
1463         }
1464
1465         attach_entcs();
1466
1467         bot_relinkplayerlist();
1468
1469         self.spectatortime = time;
1470         if(blockSpectators)
1471         {
1472                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1473         }
1474
1475         self.jointime = time;
1476         self.allowed_timeouts = autocvar_sv_timeout_number;
1477
1478         if(clienttype(self) == CLIENTTYPE_REAL)
1479         {
1480                 if(!autocvar_g_campaign)
1481                 {
1482                         self.motd_actived_time = -1;
1483                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1484                 }
1485
1486                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1487                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1488         }
1489
1490         if(!sv_foginterval && world.fog != "")
1491                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1492
1493         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1494         {
1495                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1496                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1497         }
1498         else
1499                 self.hitplotfh = -1;
1500
1501         if(g_race || g_cts) {
1502                 string rr;
1503                 if(g_cts)
1504                         rr = CTS_RECORD;
1505                 else
1506                         rr = RACE_RECORD;
1507
1508                 msg_entity = self;
1509                 race_send_recordtime(MSG_ONE);
1510                 race_send_speedaward(MSG_ONE);
1511
1512                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1513                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1514                 race_send_speedaward_alltimebest(MSG_ONE);
1515
1516                 float i;
1517                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1518                         race_SendRankings(i, 0, 0, MSG_ONE);
1519                 }
1520         }
1521         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1522                 send_CSQC_teamnagger();
1523
1524         CheatInitClient();
1525
1526         CSQCMODEL_AUTOINIT();
1527
1528         self.model_randomizer = random();
1529     
1530     if(clienttype(self) != CLIENTTYPE_REAL)
1531         return;
1532         
1533     sv_notice_join();
1534     
1535     MUTATOR_CALLHOOK(ClientConnect);
1536 }
1537 /*
1538 =============
1539 ClientDisconnect
1540
1541 Called when a client disconnects from the server
1542 =============
1543 */
1544 .entity chatbubbleentity;
1545 void ReadyCount();
1546 void ClientDisconnect (void)
1547 {
1548         if(self.vehicle)
1549             vehicles_exit(VHEF_RELESE);
1550
1551         if not(self.flags & FL_CLIENT)
1552         {
1553                 print("Warning: ClientDisconnect without ClientConnect\n");
1554                 return;
1555         }
1556
1557         PlayerStats_AddGlobalInfo(self);
1558
1559         CheatShutdownClient();
1560
1561         if(self.hitplotfh >= 0)
1562         {
1563                 fclose(self.hitplotfh);
1564                 self.hitplotfh = -1;
1565         }
1566
1567         anticheat_report();
1568         anticheat_shutdown();
1569
1570         playerdemo_shutdown();
1571
1572         bot_clientdisconnect();
1573
1574         if(self.entcs)
1575                 detach_entcs();
1576
1577         if(autocvar_sv_eventlog)
1578                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1579                 
1580         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1581
1582         MUTATOR_CALLHOOK(ClientDisconnect);
1583
1584         Portal_ClearAll(self);
1585
1586         RemoveGrapplingHook(self);
1587
1588         // Here, everything has been done that requires this player to be a client.
1589
1590         self.flags &~= FL_CLIENT;
1591
1592         if (self.chatbubbleentity)
1593                 remove (self.chatbubbleentity);
1594
1595         if (self.killindicator)
1596                 remove (self.killindicator);
1597
1598         WaypointSprite_PlayerGone();
1599
1600         bot_relinkplayerlist();
1601
1602         if(g_arena)
1603         {
1604                 Spawnqueue_Unmark(self);
1605                 Spawnqueue_Remove(self);
1606         }
1607
1608         accuracy_free(self);
1609         ClientData_Detach();
1610         PlayerScore_Detach(self);
1611
1612         if(self.netname_previous)
1613                 strunzone(self.netname_previous);
1614         if(self.clientstatus)
1615                 strunzone(self.clientstatus);
1616         if(self.weaponorder_byimpulse)
1617                 strunzone(self.weaponorder_byimpulse);
1618
1619         ClearPlayerSounds();
1620
1621         if(self.personal)
1622                 remove(self.personal);
1623
1624         self.playerid = 0;
1625         ReadyCount();
1626
1627         // free cvars
1628         GetCvars(-1);
1629 }
1630
1631 .float BUTTON_CHAT;
1632 void ChatBubbleThink()
1633 {
1634         self.nextthink = time;
1635         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1636         {
1637                 if(self.owner) // but why can that ever be world?
1638                         self.owner.chatbubbleentity = world;
1639                 remove(self);
1640                 return;
1641         }
1642         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1643 #ifdef TETRIS
1644                 || self.owner.tetris_on
1645 #endif
1646         )
1647                 self.model = self.mdl;
1648         else
1649                 self.model = "";
1650 }
1651
1652 void UpdateChatBubble()
1653 {
1654         if (self.alpha < 0)
1655                 return;
1656         // spawn a chatbubble entity if needed
1657         if (!self.chatbubbleentity)
1658         {
1659                 self.chatbubbleentity = spawn();
1660                 self.chatbubbleentity.owner = self;
1661                 self.chatbubbleentity.exteriormodeltoclient = self;
1662                 self.chatbubbleentity.think = ChatBubbleThink;
1663                 self.chatbubbleentity.nextthink = time;
1664                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1665                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1666                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1667                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1668                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1669                 self.chatbubbleentity.model = "";
1670                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1671         }
1672 }
1673
1674
1675 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1676 // added to the model skins
1677 /*void UpdateColorModHack()
1678 {
1679         float c;
1680         c = self.clientcolors & 15;
1681         // LordHavoc: only bothering to support white, green, red, yellow, blue
1682              if (!teamplay) self.colormod = '0 0 0';
1683         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1684         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1685         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1686         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1687         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1688         else self.colormod = '1 1 1';
1689 }*/
1690
1691 void respawn(void)
1692 {
1693         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1694         {
1695                 self.solid = SOLID_NOT;
1696                 self.takedamage = DAMAGE_NO;
1697                 self.movetype = MOVETYPE_FLY;
1698                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1699                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1700                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1701                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1702                 if(autocvar_g_respawn_ghosts_maxtime)
1703                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1704         }
1705
1706         CopyBody(1);
1707
1708         self.effects |= EF_NODRAW; // prevent another CopyBody
1709         PutClientInServer();
1710 }
1711
1712 void play_countdown(float finished, string samp)
1713 {
1714         if(clienttype(self) == CLIENTTYPE_REAL)
1715                 if(floor(finished - time - frametime) != floor(finished - time))
1716                         if(finished - time < 6)
1717                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1718 }
1719
1720 void player_powerups (void)
1721 {
1722         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1723         olditems = self.items;
1724
1725         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1726                 self.modelflags |= MF_ROCKET;
1727         else
1728                 self.modelflags &~= MF_ROCKET;
1729
1730         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1731
1732         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1733                 return;
1734
1735         Fire_ApplyDamage(self);
1736         Fire_ApplyEffect(self);
1737
1738         if (g_minstagib)
1739         {
1740                 self.effects |= EF_FULLBRIGHT;
1741
1742                 if (self.items & IT_STRENGTH)
1743                 {
1744                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1745                         if (time > self.strength_finished)
1746                         {
1747                                 self.alpha = default_player_alpha;
1748                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1749                                 self.items &~= IT_STRENGTH;
1750                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1751                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1752                         }
1753                 }
1754                 else
1755                 {
1756                         if (time < self.strength_finished)
1757                         {
1758                                 self.alpha = g_minstagib_invis_alpha;
1759                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1760                                 self.items |= IT_STRENGTH;
1761                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1762                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1763                         }
1764                 }
1765
1766                 if (self.items & IT_INVINCIBLE)
1767                 {
1768                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1769                         if (time > self.invincible_finished)
1770                         {
1771                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1772                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1773                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1774                         }
1775                 }
1776                 else
1777                 {
1778                         if (time < self.invincible_finished)
1779                         {
1780                                 self.items = self.items | IT_INVINCIBLE;
1781                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1782                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1783                         }
1784                 }
1785         }
1786         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1787         {
1788                 if (self.items & IT_STRENGTH)
1789                 {
1790                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1791                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1792                         if (time > self.strength_finished)
1793                         {
1794                                 self.items = self.items - (self.items & IT_STRENGTH);
1795                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1796                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1797                         }
1798                 }
1799                 else
1800                 {
1801                         if (time < self.strength_finished)
1802                         {
1803                                 self.items = self.items | IT_STRENGTH;
1804                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1805                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1806                         }
1807                 }
1808                 if (self.items & IT_INVINCIBLE)
1809                 {
1810                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1811                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1812                         if (time > self.invincible_finished)
1813                         {
1814                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1815                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1816                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1817                         }
1818                 }
1819                 else
1820                 {
1821                         if (time < self.invincible_finished)
1822                         {
1823                                 self.items = self.items | IT_INVINCIBLE;
1824                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1825                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1826                         }
1827                 }
1828                 if (self.items & IT_SUPERWEAPON)
1829                 {
1830                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1831                         {
1832                                 self.superweapons_finished = 0;
1833                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1834                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1835                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1836                         }
1837                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1838                         {
1839                                 // don't let them run out
1840                         }
1841                         else
1842                         {
1843                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1844                                 if (time > self.superweapons_finished)
1845                                 {
1846                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1847                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1848                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1849                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1850                                 }
1851                         }
1852                 }
1853                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1854                 {
1855                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1856                         {
1857                                 self.items = self.items | IT_SUPERWEAPON;
1858                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1859                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1860                         }
1861                         else
1862                         {
1863                                 self.superweapons_finished = 0;
1864                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1865                         }
1866                 }
1867                 else
1868                 {
1869                         self.superweapons_finished = 0;
1870                 }
1871         }
1872         
1873         if(autocvar_g_nodepthtestplayers)
1874                 self.effects = self.effects | EF_NODEPTHTEST;
1875
1876         if(autocvar_g_fullbrightplayers)
1877                 self.effects = self.effects | EF_FULLBRIGHT;
1878
1879         // midair gamemode: damage only while in the air
1880         // if in midair mode, being on ground grants temporary invulnerability
1881         // (this is so that multishot weapon don't clear the ground flag on the
1882         // first damage in the frame, leaving the player vulnerable to the
1883         // remaining hits in the same frame)
1884         if (self.flags & FL_ONGROUND)
1885         if (g_midair)
1886                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1887
1888         if (time >= game_starttime)
1889         if (time < self.spawnshieldtime)
1890                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1891
1892         MUTATOR_CALLHOOK(PlayerPowerups);
1893 }
1894
1895 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1896 {
1897         if(current > stable)
1898                 return current;
1899         else if(current > stable - 0.25) // when close enough, "snap"
1900                 return stable;
1901         else
1902                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1903 }
1904
1905 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1906 {
1907         if(current < stable)
1908                 return current;
1909         else if(current < stable + 0.25) // when close enough, "snap"
1910                 return stable;
1911         else
1912                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1913 }
1914
1915 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1916 {
1917         if(current > rotstable)
1918         {
1919                 if(rotframetime > 0)
1920                 {
1921                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1922                         current = max(rotstable, current - rotlinear * rotframetime);
1923                 }
1924         }
1925         else if(current < regenstable)
1926         {
1927                 if(regenframetime > 0)
1928                 {
1929                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1930                         current = min(regenstable, current + regenlinear * regenframetime);
1931                 }
1932         }
1933
1934         if(current > limit)
1935                 current = limit;
1936
1937         return current;
1938 }
1939
1940 void player_regen (void)
1941 {
1942         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1943         maxh = autocvar_g_balance_health_rotstable;
1944         maxa = autocvar_g_balance_armor_rotstable;
1945         maxf = autocvar_g_balance_fuel_rotstable;
1946         minh = autocvar_g_balance_health_regenstable;
1947         mina = autocvar_g_balance_armor_regenstable;
1948         minf = autocvar_g_balance_fuel_regenstable;
1949         limith = autocvar_g_balance_health_limit;
1950         limita = autocvar_g_balance_armor_limit;
1951         limitf = autocvar_g_balance_fuel_limit;
1952
1953         max_mod = regen_mod = rot_mod = limit_mod = 1;
1954
1955         maxh = maxh * max_mod;
1956         //maxa = maxa * max_mod;
1957         //maxf = maxf * max_mod;
1958         minh = minh * max_mod;
1959         //mina = mina * max_mod;
1960         //minf = minf * max_mod;
1961         limith = limith * limit_mod;
1962         limita = limita * limit_mod;
1963         //limitf = limitf * limit_mod;
1964
1965         if(g_lms || g_ca)
1966                 rot_mod = 0;
1967
1968         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1969         {
1970                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1971                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1972
1973                 // if player rotted to death...  die!
1974                 if(self.health < 1)
1975                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1976         }
1977
1978         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1979                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1980 }
1981
1982 float zoomstate_set;
1983 void SetZoomState(float z)
1984 {
1985         if(z != self.zoomstate)
1986         {
1987                 self.zoomstate = z;
1988                 ClientData_Touch(self);
1989         }
1990         zoomstate_set = 1;
1991 }
1992
1993 void GetPressedKeys(void) {
1994         MUTATOR_CALLHOOK(GetPressedKeys);
1995         if (self.movement_x > 0) // get if movement keys are pressed
1996         {       // forward key pressed
1997                 self.pressedkeys |= KEY_FORWARD;
1998                 self.pressedkeys &~= KEY_BACKWARD;
1999         }
2000         else if (self.movement_x < 0)
2001         {       // backward key pressed
2002                 self.pressedkeys |= KEY_BACKWARD;
2003                 self.pressedkeys &~= KEY_FORWARD;
2004         }
2005         else
2006         {       // no x input
2007                 self.pressedkeys &~= KEY_FORWARD;
2008                 self.pressedkeys &~= KEY_BACKWARD;
2009         }
2010
2011         if (self.movement_y > 0)
2012         {       // right key pressed
2013                 self.pressedkeys |= KEY_RIGHT;
2014                 self.pressedkeys &~= KEY_LEFT;
2015         }
2016         else if (self.movement_y < 0)
2017         {       // left key pressed
2018                 self.pressedkeys |= KEY_LEFT;
2019                 self.pressedkeys &~= KEY_RIGHT;
2020         }
2021         else
2022         {       // no y input
2023                 self.pressedkeys &~= KEY_RIGHT;
2024                 self.pressedkeys &~= KEY_LEFT;
2025         }
2026
2027         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2028                 self.pressedkeys |= KEY_JUMP;
2029         else
2030                 self.pressedkeys &~= KEY_JUMP;
2031         if (self.BUTTON_CROUCH)
2032                 self.pressedkeys |= KEY_CROUCH;
2033         else
2034                 self.pressedkeys &~= KEY_CROUCH;
2035
2036         if (self.BUTTON_ATCK)
2037                 self.pressedkeys |= KEY_ATCK;
2038         else
2039                 self.pressedkeys &~= KEY_ATCK;
2040         if (self.BUTTON_ATCK2)
2041                 self.pressedkeys |= KEY_ATCK2;
2042         else
2043                 self.pressedkeys &~= KEY_ATCK2;
2044 }
2045
2046 /*
2047 ======================
2048 spectate mode routines
2049 ======================
2050 */
2051
2052 void SpectateCopy(entity spectatee) {
2053         other = spectatee;
2054         MUTATOR_CALLHOOK(SpectateCopy);
2055         self.armortype = spectatee.armortype;
2056         self.armorvalue = spectatee.armorvalue;
2057         self.ammo_cells = spectatee.ammo_cells;
2058         self.ammo_shells = spectatee.ammo_shells;
2059         self.ammo_nails = spectatee.ammo_nails;
2060         self.ammo_rockets = spectatee.ammo_rockets;
2061         self.ammo_fuel = spectatee.ammo_fuel;
2062         self.clip_load = spectatee.clip_load;
2063         self.clip_size = spectatee.clip_size;
2064         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2065         self.health = spectatee.health;
2066         self.impulse = 0;
2067         self.items = spectatee.items;
2068         self.last_pickup = spectatee.last_pickup;
2069         self.hit_time = spectatee.hit_time;
2070         self.metertime = spectatee.metertime;
2071         self.strength_finished = spectatee.strength_finished;
2072         self.invincible_finished = spectatee.invincible_finished;
2073         self.pressedkeys = spectatee.pressedkeys;
2074         WEPSET_COPY_EE(self, spectatee);
2075         self.switchweapon = spectatee.switchweapon;
2076         self.switchingweapon = spectatee.switchingweapon;
2077         self.weapon = spectatee.weapon;
2078         self.nex_charge = spectatee.nex_charge;
2079         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2080         self.hagar_load = spectatee.hagar_load;
2081         self.minelayer_mines = spectatee.minelayer_mines;
2082         self.punchangle = spectatee.punchangle;
2083         self.view_ofs = spectatee.view_ofs;
2084         self.velocity = spectatee.velocity;
2085         self.dmg_take = spectatee.dmg_take;
2086         self.dmg_save = spectatee.dmg_save;
2087         self.dmg_inflictor = spectatee.dmg_inflictor;
2088         self.v_angle = spectatee.v_angle;
2089         self.angles = spectatee.v_angle;
2090         self.stat_respawn_time = spectatee.stat_respawn_time;
2091         if(!self.BUTTON_USE)
2092                 self.fixangle = TRUE;
2093         setorigin(self, spectatee.origin);
2094         setsize(self, spectatee.mins, spectatee.maxs);
2095         SetZoomState(spectatee.zoomstate);
2096     
2097     anticheat_spectatecopy(spectatee);
2098         self.hud = spectatee.hud;
2099         if(spectatee.vehicle)
2100     {
2101         self.fixangle = FALSE;
2102         //self.velocity = spectatee.vehicle.velocity;
2103         self.vehicle_health = spectatee.vehicle_health;
2104         self.vehicle_shield = spectatee.vehicle_shield;
2105         self.vehicle_energy = spectatee.vehicle_energy;
2106         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2107         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2108         self.vehicle_reload1 = spectatee.vehicle_reload1;
2109         self.vehicle_reload2 = spectatee.vehicle_reload2;
2110
2111         msg_entity = self;
2112         
2113         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2114             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2115             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2116             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2117
2118         //WriteByte (MSG_ONE, SVC_SETVIEW);
2119         //    WriteEntity(MSG_ONE, self);            
2120         //makevectors(spectatee.v_angle);
2121         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/    
2122     }
2123 }
2124
2125 float SpectateUpdate() {
2126         if(!self.enemy)
2127             return 0;           
2128
2129         if (self == self.enemy)
2130                 return 0;
2131
2132         if(self.enemy.classname != "player")
2133                 return 0;
2134
2135         SpectateCopy(self.enemy);
2136
2137         return 1;
2138 }
2139
2140
2141 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2142 entity CA_SpectateNext(entity start) {
2143         if (start.team == self.team) {
2144                 return start;
2145         }
2146         
2147         other = start;
2148         // continue from current player
2149         while(other && other.team != self.team) {
2150                 other = find(other, classname, "player");
2151         }
2152         
2153         if (!other) {
2154                 // restart from begining
2155                 other = find(other, classname, "player");
2156                 while(other && other.team != self.team) {
2157                         other = find(other, classname, "player");
2158                 }
2159         }
2160         
2161         return other;
2162 }
2163
2164 float SpectateNext(entity _prefer) {
2165         
2166         if(_prefer)
2167                 other = _prefer;        
2168         else
2169                 other = find(self.enemy, classname, "player");
2170         
2171         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2172                 // CA and ca players when spectating enemies is forbidden
2173                 other = CA_SpectateNext(other);
2174         } else {
2175                 // other modes and ca spectators or spectating enemies is allowed
2176                 if (!other)
2177                         other = find(other, classname, "player");
2178         }
2179         
2180         if (other)
2181                 self.enemy = other;
2182
2183         if(self.enemy.classname == "player") {
2184             /*if(self.enemy.vehicle)
2185             {      
2186             
2187             msg_entity = self;
2188             WriteByte(MSG_ONE, SVC_SETVIEW);
2189             WriteEntity(MSG_ONE, self.enemy);
2190             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2191             
2192             self.movetype = MOVETYPE_NONE;
2193             accuracy_resend(self);
2194             }
2195             else 
2196             {*/         
2197             msg_entity = self;
2198             WriteByte(MSG_ONE, SVC_SETVIEW);
2199             WriteEntity(MSG_ONE, self.enemy);
2200             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2201             self.movetype = MOVETYPE_NONE;
2202             accuracy_resend(self);
2203
2204             if(!SpectateUpdate())
2205                 PutObserverInServer();
2206         //}
2207         return 1;
2208         } else {
2209                 return 0;
2210         }
2211 }
2212
2213 /*
2214 =============
2215 ShowRespawnCountdown()
2216
2217 Update a respawn countdown display.
2218 =============
2219 */
2220 void ShowRespawnCountdown()
2221 {
2222         float number;
2223         if(self.deadflag == DEAD_NO) // just respawned?
2224                 return;
2225         else
2226         {
2227                 number = ceil(self.respawn_time - time);
2228                 if(number <= 0)
2229                         return;
2230                 if(number <= self.respawn_countdown)
2231                 {
2232                         self.respawn_countdown = number - 1;
2233                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2234                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number)); 
2235                 }
2236         }
2237 }
2238
2239 void LeaveSpectatorMode()
2240 {
2241         if(nJoinAllowed(self))
2242         {
2243                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2244                 {
2245                         self.classname = "player";
2246
2247                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2248                                 { JoinBestTeam(self, FALSE, TRUE); }
2249
2250                         if(autocvar_g_campaign)
2251                                 { campaign_bots_may_start = 1; }
2252
2253                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2254
2255                         PutClientInServer();
2256
2257                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2258                 }
2259                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2260         }
2261         else
2262         {
2263                 // Player may not join because g_maxplayers is set
2264                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2265         }
2266 }
2267
2268 /**
2269  * Determines whether the player is allowed to join. This depends on cvar
2270  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2271  * it checks whether the number of currently playing players exceeds g_maxplayers.
2272  * @return int number of free slots for players, 0 if none
2273  */
2274 float nJoinAllowed(entity ignore) {
2275         if(!ignore)
2276         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2277         // so report 0 free slots if restricted
2278         {
2279                 if(autocvar_g_forced_team_otherwise == "spectate")
2280                         return 0;
2281                 if(autocvar_g_forced_team_otherwise == "spectator")
2282                         return 0;
2283         }
2284
2285         if(self.team_forced < 0)
2286                 return 0; // forced spectators can never join
2287
2288         // TODO simplify this
2289         entity e;
2290         float totalClients = 0;
2291         FOR_EACH_CLIENT(e)
2292                 if(e != ignore)
2293                         totalClients += 1;
2294
2295         if (!autocvar_g_maxplayers)
2296                 return maxclients - totalClients;
2297
2298         float currentlyPlaying = 0;
2299         FOR_EACH_REALPLAYER(e)
2300                 currentlyPlaying += 1;
2301
2302         if(currentlyPlaying < autocvar_g_maxplayers)
2303                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2304
2305         return 0;
2306 }
2307
2308 /**
2309  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2310  * g_maxplayers_spectator_blocktime seconds
2311  */
2312 void checkSpectatorBlock() {
2313         if(self.classname == "spectator" || self.classname == "observer") {
2314                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2315                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2316                         dropclient(self);
2317                 }
2318         }
2319 }
2320
2321 void PrintWelcomeMessage()
2322 {
2323         if(self.motd_actived_time == 0)
2324         {
2325                 if (autocvar_g_campaign) {
2326                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2327                                 self.motd_actived_time = time;
2328                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2329                         }
2330                 } else {
2331                         if (self.BUTTON_INFO) {
2332                                 self.motd_actived_time = time;
2333                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2334                         }
2335                 }
2336         }
2337         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2338         {
2339                 if (autocvar_g_campaign) {
2340                         if (self.BUTTON_INFO)
2341                                 self.motd_actived_time = time;
2342                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2343                                 self.motd_actived_time = 0;
2344                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2345                         }
2346                 } else {
2347                         if (self.BUTTON_INFO)
2348                                 self.motd_actived_time = time;
2349                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2350                                 self.motd_actived_time = 0;
2351                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2352                         }
2353                 }
2354         }
2355         else //if(self.motd_actived_time < 0) // just connected, motd is active
2356         {
2357                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2358                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2359                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2360                 {
2361                         // instanctly hide MOTD
2362                         self.motd_actived_time = 0;
2363                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2364                 }
2365         }
2366 }
2367
2368 void ObserverThink()
2369 {
2370         float prefered_movetype;
2371         if (self.flags & FL_JUMPRELEASED) {
2372                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2373                         self.flags &~= FL_JUMPRELEASED;
2374                         self.flags |= FL_SPAWNING;
2375                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2376                         self.flags &~= FL_JUMPRELEASED;
2377                         if(SpectateNext(world) == 1) {
2378                                 self.classname = "spectator";
2379                         }
2380                 } else {
2381                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2382                         if (self.movetype != prefered_movetype)
2383                                 self.movetype = prefered_movetype;
2384                 }
2385         } else {
2386                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2387                         self.flags |= FL_JUMPRELEASED;
2388                         if(self.flags & FL_SPAWNING)
2389                         {
2390                                 self.flags &~= FL_SPAWNING;
2391                                 LeaveSpectatorMode();
2392                                 return;
2393                         }
2394                 }
2395         }
2396 }
2397
2398 void SpectatorThink()
2399 {
2400         if (self.flags & FL_JUMPRELEASED) {
2401                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2402                         self.flags &~= FL_JUMPRELEASED;
2403                         self.flags |= FL_SPAWNING;
2404                 } else if(self.BUTTON_ATCK) {
2405                         self.flags &~= FL_JUMPRELEASED;
2406                         if(SpectateNext(world) == 1) {
2407                                 self.classname = "spectator";
2408                         } else {
2409                                 self.classname = "observer";
2410                                 PutClientInServer();
2411                         }
2412                 } else if (self.BUTTON_ATCK2) {
2413                         self.flags &~= FL_JUMPRELEASED;
2414                         self.classname = "observer";
2415                         PutClientInServer();
2416                 } else {
2417                         if(!SpectateUpdate())
2418                                 PutObserverInServer();
2419                 }
2420         } else {
2421                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2422                         self.flags |= FL_JUMPRELEASED;
2423                         if(self.flags & FL_SPAWNING)
2424                         {
2425                                 self.flags &~= FL_SPAWNING;
2426                                 LeaveSpectatorMode();
2427                                 return;
2428                         }
2429                 }
2430                 if(!SpectateUpdate())
2431                         PutObserverInServer();
2432         }
2433
2434         self.flags |= FL_CLIENT | FL_NOTARGET;
2435 }
2436
2437 void PlayerUseKey()
2438 {
2439         if(self.classname != "player")
2440                 return;
2441
2442         if(self.vehicle)
2443         {
2444         vehicles_exit(VHEF_NORMAL);
2445         return;
2446         }
2447         
2448         // a use key was pressed; call handlers
2449         MUTATOR_CALLHOOK(PlayerUseKey);
2450 }
2451
2452 /*
2453 =============
2454 PlayerPreThink
2455
2456 Called every frame for each client before the physics are run
2457 =============
2458 */
2459 .float usekeypressed;
2460 void() nexball_setstatus;
2461 .float items_added;
2462 void PlayerPreThink (void)
2463 {
2464         WarpZone_PlayerPhysics_FixVAngle();
2465
2466         self.stat_game_starttime = game_starttime;
2467         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2468         self.stat_leadlimit = autocvar_leadlimit;
2469
2470         if(g_arena || (g_ca && !allowed_to_spawn))
2471                 self.stat_respawn_time = 0;
2472         else
2473                 self.stat_respawn_time = self.respawn_time;
2474
2475         if(frametime)
2476         {
2477                 // physics frames: update anticheat stuff
2478                 anticheat_prethink();
2479         }
2480
2481         if(blockSpectators && frametime)
2482                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2483                 checkSpectatorBlock();
2484
2485         zoomstate_set = 0;
2486
2487         if(self.netname_previous != self.netname)
2488         {
2489                 if(autocvar_sv_eventlog)
2490                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2491                 if(self.netname_previous)
2492                         strunzone(self.netname_previous);
2493                 self.netname_previous = strzone(self.netname);
2494         }
2495
2496         // version nagging
2497         if(self.version_nagtime)
2498                 if(self.cvar_g_xonoticversion)
2499                         if(time > self.version_nagtime)
2500                         {
2501                                 // don't notify git users
2502                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2503                                 {
2504                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2505                                         {
2506                                                 // notify release users if connecting to git
2507                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2508                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2509                                         }
2510                                         else
2511                                         {
2512                                                 float r;
2513                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2514                                                 if(r < 0)
2515                                                 {
2516                                                         // give users new version
2517                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2518                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2519                                                 }
2520                                                 else if(r > 0)
2521                                                 {
2522                                                         // notify users about old server version
2523                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2524                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2525                                                 }
2526                                         }
2527                                 }
2528                                 self.version_nagtime = 0;
2529                         }
2530
2531         // GOD MODE info
2532         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2533         {
2534                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2535                 self.max_armorvalue = 0;
2536         }
2537
2538 #ifdef TETRIS
2539         if (TetrisPreFrame())
2540                 return;
2541 #endif
2542
2543         MUTATOR_CALLHOOK(PlayerPreThink);
2544
2545         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2546         {
2547                 if(self.BUTTON_USE && !self.usekeypressed)
2548                         PlayerUseKey();
2549                 self.usekeypressed = self.BUTTON_USE;
2550         }
2551
2552         if(clienttype(self) == CLIENTTYPE_REAL)
2553                 PrintWelcomeMessage();
2554
2555         if(self.classname == "player") {
2556
2557                 CheckRules_Player();
2558
2559                 if (intermission_running)
2560                 {
2561                         IntermissionThink ();   // otherwise a button could be missed between
2562                         return;                                 // the think tics
2563                 }
2564
2565                 //don't allow the player to turn around while game is paused!
2566                 if(timeout_status == TIMEOUT_ACTIVE) {
2567                         // FIXME turn this into CSQC stuff
2568                         self.v_angle = self.lastV_angle;
2569                         self.angles = self.lastV_angle;
2570                         self.fixangle = TRUE;
2571                 }
2572
2573                 if(frametime)
2574                 {
2575                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2576                         {
2577                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2578                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2579                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2580
2581                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2582                                 {
2583                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2584                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2585                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2586                                 }
2587                         }
2588                         else
2589                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2590
2591                         player_powerups();
2592                 }
2593
2594                 if (g_minstagib)
2595                         minstagib_ammocheck();
2596
2597                 if (self.deadflag != DEAD_NO)
2598                 {
2599                         float button_pressed, force_respawn;
2600                         if(self.personal && g_race_qualifying)
2601                         {
2602                                 if(time > self.respawn_time)
2603                                 {
2604                                         self.respawn_time = time + 1; // only retry once a second
2605                                         respawn();
2606                                         self.impulse = 141;
2607                                 }
2608                         }
2609                         else
2610                         {
2611                                 if(frametime)
2612                                         player_anim();
2613                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2614                                 force_respawn = (g_ca || g_cts || autocvar_g_forced_respawn);
2615                                 if (self.deadflag == DEAD_DYING)
2616                                 {
2617                                         if(force_respawn)
2618                                                 self.deadflag = DEAD_RESPAWNING;
2619                                         else if(!button_pressed)
2620                                                 self.deadflag = DEAD_DEAD;
2621                                 }
2622                                 else if (self.deadflag == DEAD_DEAD)
2623                                 {
2624                                         if(button_pressed)
2625                                                 self.deadflag = DEAD_RESPAWNABLE;
2626                                 }
2627                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2628                                 {
2629                                         if(!button_pressed)
2630                                                 self.deadflag = DEAD_RESPAWNING;
2631                                 }
2632                                 else if (self.deadflag == DEAD_RESPAWNING)
2633                                 {
2634                                         if(time > self.respawn_time)
2635                                         {
2636                                                 self.respawn_time = time + 1; // only retry once a second
2637                                                 respawn();
2638                                         }
2639                                 }
2640                                 ShowRespawnCountdown();
2641                         }
2642
2643                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2644                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2645                                 self.stat_respawn_time *= -1;
2646
2647                         return;
2648                 }
2649
2650                 self.prevorigin = self.origin;
2651
2652                 float do_crouch = self.BUTTON_CROUCH;
2653                 if(self.hook.state)
2654                         do_crouch = 0;
2655                 if(self.health <= g_bloodloss)
2656                         do_crouch = 1;
2657                 if(self.vehicle)
2658                         do_crouch = 0;
2659                 if(self.freezetag_frozen)
2660                         do_crouch = 0;
2661                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2662                         do_crouch = 0;
2663
2664                 if (do_crouch)
2665                 {
2666                         if (!self.crouch)
2667                         {
2668                                 self.crouch = TRUE;
2669                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2670                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2671                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2672                         }
2673                 }
2674                 else
2675                 {
2676                         if (self.crouch)
2677                         {
2678                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2679                                 if (!trace_startsolid)
2680                                 {
2681                                         self.crouch = FALSE;
2682                                         self.view_ofs = PL_VIEW_OFS;
2683                                         setsize (self, PL_MIN, PL_MAX);
2684                                 }
2685                         }
2686                 }
2687
2688                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2689                 {
2690                         if(self.bloodloss_timer < time)
2691                         {
2692                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2693                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2694                         }
2695                 }
2696
2697                 FixPlayermodel();
2698
2699                 GrapplingHookFrame();
2700
2701                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2702                 //if(frametime)
2703                 {
2704                         self.items &~= self.items_added;
2705
2706                         W_WeaponFrame();
2707
2708                         self.items_added = 0;
2709                         if(self.items & IT_JETPACK)
2710                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2711                                         self.items_added |= IT_FUEL;
2712
2713                         self.items |= self.items_added;
2714                 }
2715
2716                 player_regen();
2717
2718                 // rot nex charge to the charge limit
2719                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2720                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2721
2722                 if(frametime)
2723                         player_anim();
2724
2725                 if(g_nexball)
2726                         nexball_setstatus();
2727                 
2728                 // secret status
2729                 secrets_setstatus();
2730                 
2731                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2732
2733                 //self.angles_y=self.v_angle_y + 90;   // temp
2734         } else if(gameover) {
2735                 if (intermission_running)
2736                         IntermissionThink ();   // otherwise a button could be missed between
2737                 return;
2738         } else if(self.classname == "observer") {
2739                 ObserverThink();
2740         } else if(self.classname == "spectator") {
2741                 SpectatorThink();
2742         }
2743
2744         if(!zoomstate_set)
2745                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2746
2747         float oldspectatee_status;
2748         oldspectatee_status = self.spectatee_status;
2749         if(self.classname == "spectator")
2750                 self.spectatee_status = num_for_edict(self.enemy);
2751         else if(self.classname == "observer")
2752                 self.spectatee_status = num_for_edict(self);
2753         else
2754                 self.spectatee_status = 0;
2755         if(self.spectatee_status != oldspectatee_status)
2756         {
2757                 ClientData_Touch(self);
2758                 if(g_race || g_cts)
2759                         race_InitSpectator();
2760         }
2761
2762         if(self.teamkill_soundtime)
2763         if(time > self.teamkill_soundtime)
2764         {
2765                 self.teamkill_soundtime = 0;
2766
2767                 entity oldpusher, oldself;
2768
2769                 oldself = self; self = self.teamkill_soundsource;
2770                 oldpusher = self.pusher; self.pusher = oldself;
2771
2772                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2773
2774                 self.pusher = oldpusher;
2775                 self = oldself;
2776         }
2777
2778         if(self.taunt_soundtime)
2779         if(time > self.taunt_soundtime)
2780         {
2781                 self.taunt_soundtime = 0;
2782                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2783         }
2784
2785         target_voicescript_next(self);
2786
2787         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2788         if(!self.weapon)
2789                 self.clip_load = self.clip_size = 0;
2790 }
2791
2792 float isInvisibleString(string s)
2793 {
2794         float i, n, c;
2795         s = strdecolorize(s);
2796         for((i = 0), (n = strlen(s)); i < n; ++i)
2797         {
2798                 c = str2chr(s, i);
2799                 switch(c)
2800                 {
2801                         case 0:
2802                         case 32: // space
2803                                 break;
2804                         case 192: // charmap space
2805                                 if (!autocvar_utf8_enable)
2806                                         break;
2807                                 return FALSE;
2808                         case 160: // space in unicode fonts
2809                         case 0xE000 + 192: // utf8 charmap space
2810                                 if (autocvar_utf8_enable)
2811                                         break;
2812                         default:
2813                                 return FALSE;
2814                 }
2815         }
2816         return TRUE;
2817 }
2818
2819 /*
2820 =============
2821 PlayerPostThink
2822
2823 Called every frame for each client after the physics are run
2824 =============
2825 */
2826 .float idlekick_lasttimeleft;
2827 void PlayerPostThink (void)
2828 {
2829         // Savage: Check for nameless players
2830         if (isInvisibleString(self.netname)) {
2831                 self.netname = "Player";
2832                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2833         }
2834
2835         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2836         {
2837                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2838                 {
2839                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2840                 }
2841                 else
2842                 {
2843                         float timeleft;
2844                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2845                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2846                         {
2847                                 if(!self.idlekick_lasttimeleft)
2848                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2849                         }
2850                         if(timeleft <= 0)
2851                         {
2852                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2853                                 dropclient(self);
2854                                 return;
2855                         }
2856                         else if(timeleft <= 10)
2857                         {
2858                                 if(timeleft != self.idlekick_lasttimeleft)
2859                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2860                                 self.idlekick_lasttimeleft = timeleft;
2861                         }
2862                 }
2863         }
2864
2865 #ifdef TETRIS
2866         if(self.impulse == 100)
2867                 ImpulseCommands();
2868         if (!TetrisPostFrame())
2869         {
2870 #endif
2871
2872         CheatFrame();
2873
2874         //CheckPlayerJump();
2875
2876         if(self.classname == "player") {
2877                 CheckRules_Player();
2878                 UpdateChatBubble();
2879                 if (self.impulse)
2880                         ImpulseCommands();
2881                 if (intermission_running)
2882                         return;         // intermission or finale
2883                 GetPressedKeys();
2884         }
2885         
2886 #ifdef TETRIS
2887         }
2888 #endif
2889
2890         /*
2891         float i;
2892         for(i = 0; i < 1000; ++i)
2893         {
2894                 vector end;
2895                 end = self.origin + '0 0 1024' + 512 * randomvec();
2896                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2897                 if(trace_fraction < 1)
2898                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2899                 {
2900                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2901                         break;
2902                 }
2903         }
2904         */
2905
2906         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2907
2908         if(self.waypointsprite_attachedforcarrier)
2909                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2910
2911         playerdemo_write();
2912
2913         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2914         {
2915                 if not(self.stored_netname)
2916                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2917                 if(self.stored_netname != self.netname)
2918                 {
2919                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2920                         strunzone(self.stored_netname);
2921                         self.stored_netname = strzone(self.netname);
2922                 }
2923         }
2924
2925         /*
2926         if(g_race)
2927                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2928         */
2929
2930         CSQCMODEL_AUTOUPDATE();
2931 }