qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         if (g_minstagib)
 618                 minstagib_stop_countdown();
 619
 620         Portal_ClearAll(self);
 621
 622         if(self.alivetime)
 623         {
 624                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                 self.alivetime = 0;
 626         }
 627
 628         if(self.vehicle)
 629             vehicles_exit(VHEF_RELESE);
 630
 631         if(self.flagcarried)
 632                 DropFlag(self.flagcarried, world, world);
 633
 634         if(self.ballcarried && g_nexball)
 635                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 636
 637         WaypointSprite_PlayerDead();
 638
 639         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 640                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 641
 642         if(self.killcount != -666) {
 643                 if(g_lms) {
 644                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 645                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 646                         else
 647                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 648                 } else
 649                         bprint ("^4", self.netname, "^4 is spectating now\n");
 650
 651                 if(self.just_joined == FALSE) {
 652                         LogTeamchange(self.playerid, -1, 4);
 653                 } else
 654                         self.just_joined = FALSE;
 655         }
 656
 657         PlayerScore_Clear(self); // clear scores when needed
 658
 659         accuracy_resend(self);
 660
 661         self.spectatortime = time;
 662
 663         self.classname = "observer";
 664         self.iscreature = FALSE;
 665         self.health = -666;
 666         self.takedamage = DAMAGE_NO;
 667         self.solid = SOLID_NOT;
 668         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 669         self.flags = FL_CLIENT | FL_NOTARGET;
 670         self.armorvalue = 666;
 671         self.effects = 0;
 672         self.armorvalue = autocvar_g_balance_armor_start;
 673         self.pauserotarmor_finished = 0;
 674         self.pauserothealth_finished = 0;
 675         self.pauseregen_finished = 0;
 676         self.damageforcescale = 0;
 677         self.death_time = 0;
 678         self.dead_frame = 0;
 679         self.alpha = 0;
 680         self.scale = 0;
 681         self.fade_time = 0;
 682         self.pain_frame = 0;
 683         self.pain_finished = 0;
 684         self.strength_finished = 0;
 685         self.invincible_finished = 0;
 686         self.pushltime = 0;
 687         self.think = SUB_Null;
 688         self.nextthink = 0;
 689         self.hook_time = 0;
 690         self.runes = 0;
 691         self.deadflag = DEAD_NO;
 692         self.angles = spot.angles;
 693         self.angles_z = 0;
 694         self.fixangle = TRUE;
 695         self.crouch = FALSE;
 696
 697         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 698         setorigin (self, spot.origin);
 699         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 700         self.prevorigin = self.origin;
 701         self.items = 0;
 702         self.weapons = 0;
 703         self.model = "";
 704         FixPlayermodel();
 705         self.model = "";
 706         self.modelindex = 0;
 707         self.weapon = 0;
 708         self.switchingweapon = 0;
 709         self.weaponmodel = "";
 710         self.weaponentity = world;
 711         self.exteriorweaponentity = world;
 712         self.killcount = -666;
 713         self.velocity = '0 0 0';
 714         self.avelocity = '0 0 0';
 715         self.punchangle = '0 0 0';
 716         self.punchvector = '0 0 0';
 717         self.oldvelocity = self.velocity;
 718         self.fire_endtime = -1;
 719
 720         if(sv_loddistance1)
 721                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 722
 723         if(g_arena)
 724         {
 725                 if(self.version_mismatch)
 726                 {
 727                         Spawnqueue_Unmark(self);
 728                         Spawnqueue_Remove(self);
 729                 }
 730                 else
 731                 {
 732                         Spawnqueue_Insert(self);
 733                 }
 734         }
 735         else if(g_lms)
 736         {
 737                 // Only if the player cannot play at all
 738                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 739                         self.frags = FRAGS_SPECTATOR;
 740                 else
 741                         self.frags = FRAGS_LMS_LOSER;
 742         }
 743         else if(g_ca)
 744         {
 745                 if(self.caplayer)
 746                         self.frags = FRAGS_LMS_LOSER;
 747                 else
 748                         self.frags = FRAGS_SPECTATOR;
 749         }
 750         else
 751                 self.frags = FRAGS_SPECTATOR;
 752 }
 753
 754 void FixPlayermodel()
 755 {
 756         local string defaultmodel;
 757         local float defaultskin, chmdl, oldskin;
 758         local vector m1, m2;
 759
 760         defaultmodel = "";
 761
 762         if(autocvar_sv_defaultcharacter == 1) {
 763                 defaultskin = 0;
 764
 765                 if(teamplay)
 766                 {
 767                         string s;
 768                         s = Team_ColorNameLowerCase(self.team);
 769                         if(s != "neutral")
 770                         {
 771                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 772                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 773                         }
 774                 }
 775
 776                 if(defaultmodel == "")
 777                 {
 778                         defaultmodel = autocvar_sv_defaultplayermodel;
 779                         defaultskin = autocvar_sv_defaultplayerskin;
 780                 }
 781         }
 782
 783         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 784         {
 785                 if(self.model != "")
 786                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 787                 self.model = ""; // force the != checks to return true
 788         }
 789
 790         if(defaultmodel != "")
 791         {
 792                 if (defaultmodel != self.model)
 793                 {
 794                         m1 = self.mins;
 795                         m2 = self.maxs;
 796                         setmodel_lod (self, defaultmodel);
 797                         setsize (self, m1, m2);
 798                         chmdl = TRUE;
 799                 }
 800
 801                 oldskin = self.skinindex;
 802                 self.skinindex = defaultskin;
 803         } else {
 804                 if (self.playermodel != self.model || self.playermodel == "")
 805                 {
 806                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 807                         m1 = self.mins;
 808                         m2 = self.maxs;
 809                         setmodel_lod (self, self.playermodel);
 810                         setsize (self, m1, m2);
 811                         chmdl = TRUE;
 812                 }
 813
 814                 oldskin = self.skinindex;
 815                 self.skinindex = stof(self.playerskin);
 816         }
 817
 818         if(chmdl || oldskin != self.skinindex)
 819                 self.species = player_getspecies(); // model or skin has changed
 820
 821         if(!teamplay)
 822                 if(strlen(autocvar_sv_defaultplayercolors))
 823                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 824                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 825 }
 826
 827 void PlayerTouchExplode(entity p1, entity p2)
 828 {
 829         vector org;
 830         org = (p1.origin + p2.origin) * 0.5;
 831         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 832
 833         te_explosion(org);
 834
 835         entity e;
 836         e = spawn();
 837         setorigin(e, org);
 838         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 839         remove(e);
 840 }
 841
 842 /*
 843 =============
 844 PutClientInServer
 845
 846 Called when a client spawns in the server
 847 =============
 848 */
 849 //void() ctf_playerchanged;
 850 void PutClientInServer (void)
 851 {
 852         if(clienttype(self) == CLIENTTYPE_BOT)
 853         {
 854                 self.classname = "player";
 855         }
 856         else if(clienttype(self) == CLIENTTYPE_REAL)
 857         {
 858                 msg_entity = self;
 859                 WriteByte(MSG_ONE, SVC_SETVIEW);
 860                 WriteEntity(MSG_ONE, self);
 861         }
 862
 863         // player is dead and becomes observer
 864         // FIXME fix LMS scoring for new system
 865         if(g_lms)
 866         {
 867                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 868                         self.classname = "observer";
 869         }
 870
 871         if(g_arena || (g_ca && !allowed_to_spawn))
 872         if(!self.spawned)
 873                 self.classname = "observer";
 874
 875         if(gameover)
 876                 self.classname = "observer";
 877
 878         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 879                 entity spot, oldself;
 880                 float j;
 881
 882                 accuracy_resend(self);
 883
 884                 if(self.team < 0)
 885                         JoinBestTeam(self, FALSE, TRUE);
 886
 887                 race_PreSpawn();
 888
 889                 spot = SelectSpawnPoint (FALSE);
 890                 if(!spot)
 891                 {
 892                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 893                         return; // spawn failed
 894                 }
 895
 896                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 897
 898                 self.classname = "player";
 899                 self.wasplayer = TRUE;
 900                 self.iscreature = TRUE;
 901                 self.movetype = MOVETYPE_WALK;
 902                 self.solid = SOLID_SLIDEBOX;
 903                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 904                 if(autocvar_g_playerclip_collisions)
 905                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 906                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 907                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 908                 self.frags = FRAGS_PLAYER;
 909                 if(independent_players)
 910                         MAKE_INDEPENDENT_PLAYER(self);
 911                 self.flags = FL_CLIENT;
 912                 self.takedamage = DAMAGE_AIM;
 913                 if(g_minstagib)
 914                         self.effects = EF_FULLBRIGHT;
 915                 else
 916                         self.effects = 0;
 917                 self.air_finished = time + 12;
 918                 self.dmg = 2;
 919                 if(autocvar_g_balance_nex_charge)
 920                 {
 921                         if(autocvar_g_balance_nex_secondary_chargepool)
 922                                 self.nex_chargepool_ammo = 1;
 923                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 924                 }
 925
 926                 if(inWarmupStage)
 927                 {
 928                         self.ammo_shells = warmup_start_ammo_shells;
 929                         self.ammo_nails = warmup_start_ammo_nails;
 930                         self.ammo_rockets = warmup_start_ammo_rockets;
 931                         self.ammo_cells = warmup_start_ammo_cells;
 932                         self.ammo_fuel = warmup_start_ammo_fuel;
 933                         self.health = warmup_start_health;
 934                         self.armorvalue = warmup_start_armorvalue;
 935                         self.weapons = warmup_start_weapons;
 936                 }
 937                 else
 938                 {
 939                         self.ammo_shells = start_ammo_shells;
 940                         self.ammo_nails = start_ammo_nails;
 941                         self.ammo_rockets = start_ammo_rockets;
 942                         self.ammo_cells = start_ammo_cells;
 943                         self.ammo_fuel = start_ammo_fuel;
 944                         self.health = start_health;
 945                         self.armorvalue = start_armorvalue;
 946                         self.weapons = start_weapons;
 947                 }
 948
 949                 if(g_weaponarena_random)
 950                 {
 951                         if(g_weaponarena_random_with_laser)
 952                                 self.weapons &~= WEPBIT_LASER;
 953                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 954                         if(g_weaponarena_random_with_laser)
 955                                 self.weapons |= WEPBIT_LASER;
 956                 }
 957
 958                 self.items = start_items;
 959                 self.jump_interval = time;
 960
 961                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 962                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 963                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 964                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 965                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 966                 //extend the pause of rotting if client was reset at the beginning of the countdown
 967                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 968                         self.spawnshieldtime += game_starttime - time;
 969                         self.pauserotarmor_finished += game_starttime - time;
 970                         self.pauserothealth_finished += game_starttime - time;
 971                         self.pauseregen_finished += game_starttime - time;
 972                 }
 973                 self.damageforcescale = 2;
 974                 self.death_time = 0;
 975                 self.dead_frame = 0;
 976                 self.alpha = 0;
 977                 self.scale = 0;
 978                 self.fade_time = 0;
 979                 self.pain_frame = 0;
 980                 self.pain_finished = 0;
 981                 self.strength_finished = 0;
 982                 self.invincible_finished = 0;
 983                 self.pushltime = 0;
 984                 // players have no think function
 985                 self.think = SUB_Null;
 986                 self.nextthink = 0;
 987                 self.hook_time = 0;
 988                 self.dmg_team = 0;
 989                 self.ballistics_density = autocvar_g_ballistics_density_player;
 990
 991                 self.metertime = 0;
 992
 993                 self.runes = 0;
 994
 995                 self.deadflag = DEAD_NO;
 996
 997                 self.angles = spot.angles;
 998
 999                 self.angles_z = 0; // never spawn tilted even if the spot says to
1000                 self.fixangle = TRUE; // turn this way immediately
1001                 self.velocity = '0 0 0';
1002                 self.avelocity = '0 0 0';
1003                 self.punchangle = '0 0 0';
1004                 self.punchvector = '0 0 0';
1005                 self.oldvelocity = self.velocity;
1006                 self.fire_endtime = -1;
1007
1008                 msg_entity = self;
1009                 WRITESPECTATABLE_MSG_ONE({
1010                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1011                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1012                 });
1013
1014                 if(sv_loddistance1)
1015                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1016
1017                 self.model = "";
1018                 FixPlayermodel();
1019
1020                 self.crouch = FALSE;
1021                 self.view_ofs = PL_VIEW_OFS;
1022                 setsize (self, PL_MIN, PL_MAX);
1023                 self.spawnorigin = spot.origin;
1024                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1025                 // don't reset back to last position, even if new position is stuck in solid
1026                 self.oldorigin = self.origin;
1027                 self.prevorigin = self.origin;
1028                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1029                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1030
1031                 if(g_arena)
1032                 {
1033                         Spawnqueue_Remove(self);
1034                         Spawnqueue_Mark(self);
1035                 }
1036
1037                 else if(g_ca)
1038                         self.caplayer = 1;
1039
1040                 self.event_damage = PlayerDamage;
1041
1042                 self.bot_attack = TRUE;
1043
1044                 self.statdraintime = time + 5;
1045                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1046
1047                 if(self.killcount == -666) {
1048                         PlayerScore_Clear(self);
1049                         self.killcount = 0;
1050                 }
1051
1052                 self.cnt = WEP_LASER;
1053
1054                 CL_SpawnWeaponentity();
1055                 self.alpha = default_player_alpha;
1056                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1057                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1058
1059                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1060                 self.lms_traveled_distance = 0;
1061                 self.speedrunning = FALSE;
1062
1063                 race_PostSpawn(spot);
1064
1065                 if(autocvar_spawn_debug)
1066                 {
1067                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1068                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1069                 }
1070
1071                 //stuffcmd(self, "chase_active 0");
1072                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1073
1074                 if (autocvar_g_spawnsound)
1075                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1076
1077                 if(g_assault) {
1078                         if(self.team == assault_attacker_team)
1079                                 centerprint(self, "You are attacking!");
1080                         else
1081                                 centerprint(self, "You are defending!");
1082                 }
1083
1084                 target_voicescript_clear(self);
1085
1086                 // reset fields the weapons may use
1087                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1088                 {
1089                         weapon_action(j, WR_RESETPLAYER);
1090
1091                         // all weapons must be fully loaded when we spawn
1092                         entity e;
1093                         e = get_weaponinfo(j);
1094                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1095                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1096                 }
1097
1098                 oldself = self;
1099                 self = spot;
1100                         activator = oldself;
1101                                 string s;
1102                                 s = self.target;
1103                                 self.target = string_null;
1104                                 SUB_UseTargets();
1105                                 self.target = s;
1106                         activator = world;
1107                 self = oldself;
1108
1109                 MUTATOR_CALLHOOK(PlayerSpawn);
1110
1111                 self.switchweapon = w_getbestweapon(self);
1112                 self.cnt = self.switchweapon;
1113                 self.weapon = 0;
1114                 self.switchingweapon = 0;
1115
1116                 if(!self.alivetime)
1117                         self.alivetime = time;
1118         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1119                 PutObserverInServer ();
1120         }
1121
1122         //if(g_ctf)
1123         //      ctf_playerchanged();
1124 }
1125
1126 .float ebouncefactor, ebouncestop; // electro's values
1127 // TODO do we need all these fields, or should we stop autodetecting runtime
1128 // changes and just have a console command to update this?
1129 float ClientInit_SendEntity(entity to, float sf)
1130 {
1131         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1132         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1134         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1135         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1136         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1137         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1138         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1139         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1140         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1141         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1142         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1143         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1144         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1145         if(sv_foginterval && world.fog != "")
1146                 WriteString(MSG_ENTITY, world.fog);
1147         else
1148                 WriteString(MSG_ENTITY, "");
1149         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1150         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1151         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1152         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1153         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1154         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1155         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1156         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1157         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1158         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1159         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1160         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1161         return TRUE;
1162 }
1163
1164 void ClientInit_CheckUpdate()
1165 {
1166         self.nextthink = time;
1167         if(self.count != autocvar_g_balance_armor_blockpercent)
1168         {
1169                 self.count = autocvar_g_balance_armor_blockpercent;
1170                 self.SendFlags |= 1;
1171         }
1172         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1173         {
1174                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1175                 self.SendFlags |= 1;
1176         }
1177         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1178         {
1179                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1180                 self.SendFlags |= 1;
1181         }
1182         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1183         {
1184                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1185                 self.SendFlags |= 1;
1186         }
1187         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1188         {
1189                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1190                 self.SendFlags |= 1;
1191         }
1192         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1193         {
1194                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1195                 self.SendFlags |= 1;
1196         }
1197 }
1198
1199 void ClientInit_Spawn()
1200 {
1201         entity o;
1202         entity e;
1203         e = spawn();
1204         e.classname = "clientinit";
1205         e.think = ClientInit_CheckUpdate;
1206         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1207
1208         o = self;
1209         self = e;
1210         ClientInit_CheckUpdate();
1211         self = o;
1212 }
1213
1214 /*
1215 =============
1216 SetNewParms
1217 =============
1218 */
1219 void SetNewParms (void)
1220 {
1221         // initialize parms for a new player
1222         parm1 = -(86400 * 366);
1223 }
1224
1225 /*
1226 =============
1227 SetChangeParms
1228 =============
1229 */
1230 void SetChangeParms (void)
1231 {
1232         // save parms for level change
1233         parm1 = self.parm_idlesince - time;
1234 }
1235
1236 /*
1237 =============
1238 DecodeLevelParms
1239 =============
1240 */
1241 void DecodeLevelParms (void)
1242 {
1243         // load parms
1244         self.parm_idlesince = parm1;
1245         if(self.parm_idlesince == -(86400 * 366))
1246                 self.parm_idlesince = time;
1247
1248         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1249         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1250 }
1251
1252 /*
1253 =============
1254 ClientKill
1255
1256 Called when a client types 'kill' in the console
1257 =============
1258 */
1259
1260 .float clientkill_nexttime;
1261 void ClientKill_Now_TeamChange()
1262 {
1263         if(self.killindicator_teamchange == -1)
1264         {
1265                 self.team = -1;
1266                 JoinBestTeam( self, FALSE, FALSE );
1267         }
1268         else if(self.killindicator_teamchange == -2)
1269         {
1270                 if(g_ca)
1271                         self.caplayer = 0;
1272                 if(blockSpectators)
1273                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1274                 PutObserverInServer();
1275         }
1276         else
1277                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1278 }
1279
1280 void ClientKill_Now()
1281 {
1282         if(self.vehicle)
1283         {
1284             vehicles_exit(VHEF_RELESE);
1285             if(!self.killindicator_teamchange)
1286             {
1287             self.vehicle_health = -1;
1288             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1289             }
1290         }
1291
1292         if(self.killindicator && !wasfreed(self.killindicator))
1293                 remove(self.killindicator);
1294
1295         self.killindicator = world;
1296
1297         if(self.killindicator_teamchange)
1298                 ClientKill_Now_TeamChange();
1299
1300         // in any case:
1301         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1302
1303         // now I am sure the player IS dead
1304 }
1305 void KillIndicator_Think()
1306 {
1307         if (gameover)
1308         {
1309                 self.owner.killindicator = world;
1310                 remove(self);
1311                 return;
1312         }
1313
1314         if (!self.owner.modelindex)
1315         {
1316                 self.owner.killindicator = world;
1317                 remove(self);
1318                 return;
1319         }
1320
1321         if(self.cnt <= 0)
1322         {
1323                 self = self.owner;
1324                 ClientKill_Now(); // no oldself needed
1325                 return;
1326         }
1327     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1328     {
1329         self.nextthink = time + 1;
1330         self.cnt -= 1;
1331     }
1332         else
1333         {
1334                 if(self.cnt <= 10)
1335                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1336                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1337                 {
1338                         if(self.cnt <= 10)
1339                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1340                 }
1341                 self.nextthink = time + 1;
1342                 self.cnt -= 1;
1343         }
1344 }
1345
1346 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1347 {
1348         float killtime;
1349         entity e;
1350
1351         if (gameover)
1352                 return;
1353
1354         killtime = autocvar_g_balance_kill_delay;
1355
1356         if(g_race_qualifying || g_cts)
1357                 killtime = 0;
1358
1359     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1360     {
1361                 remove(self.killindicator);
1362                 self.killindicator = world;
1363
1364         ClientKill_Now(); // allow instant kill in this case
1365         return;
1366     }
1367
1368         self.killindicator_teamchange = targetteam;
1369
1370     if(!self.killindicator)
1371         {
1372                 if(self.modelindex && self.deadflag == DEAD_NO)
1373                 {
1374                         killtime = max(killtime, self.clientkill_nexttime - time);
1375                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1376                 }
1377
1378                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1379                 {
1380                         ClientKill_Now();
1381                 }
1382                 else
1383                 {
1384                         self.killindicator = spawn();
1385                         self.killindicator.owner = self;
1386                         self.killindicator.scale = 0.5;
1387                         setattachment(self.killindicator, self, "");
1388                         setorigin(self.killindicator, '0 0 52');
1389                         self.killindicator.think = KillIndicator_Think;
1390                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1391                         self.killindicator.cnt = ceil(killtime);
1392                         self.killindicator.count = bound(0, ceil(killtime), 10);
1393                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1394
1395                         for(e = world; (e = find(e, classname, "body")) != world; )
1396                         {
1397                                 if(e.enemy != self)
1398                                         continue;
1399                                 e.killindicator = spawn();
1400                                 e.killindicator.owner = e;
1401                                 e.killindicator.scale = 0.5;
1402                                 setattachment(e.killindicator, e, "");
1403                                 setorigin(e.killindicator, '0 0 52');
1404                                 e.killindicator.think = KillIndicator_Think;
1405                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1406                                 e.killindicator.cnt = ceil(killtime);
1407                         }
1408                         self.lip = 0;
1409                 }
1410         }
1411         if(self.killindicator)
1412         {
1413                 if(targetteam == 0) // just die
1414                 {
1415                         self.killindicator.colormod = '0 0 0';
1416                         if(clienttype(self) == CLIENTTYPE_REAL)
1417                         if(self.killindicator.cnt > 0)
1418                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1419                 }
1420                 else if(targetteam == -1) // auto
1421                 {
1422                         self.killindicator.colormod = '0 1 0';
1423                         if(clienttype(self) == CLIENTTYPE_REAL)
1424                         if(self.killindicator.cnt > 0)
1425                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1426                 }
1427                 else if(targetteam == -2) // spectate
1428                 {
1429                         self.killindicator.colormod = '0.5 0.5 0.5';
1430                         if(clienttype(self) == CLIENTTYPE_REAL)
1431                         if(self.killindicator.cnt > 0)
1432                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1433                 }
1434                 else
1435                 {
1436                         self.killindicator.colormod = TeamColor(targetteam);
1437                         if(clienttype(self) == CLIENTTYPE_REAL)
1438                         if(self.killindicator.cnt > 0)
1439                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1440                 }
1441         }
1442
1443 }
1444
1445 void ClientKill (void)
1446 {
1447         if (gameover)
1448                 return;
1449
1450         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1451         {
1452                 // do nothing
1453         }
1454     else if(self.freezetag_frozen)
1455     {
1456         // do nothing
1457     }
1458         else
1459                 ClientKill_TeamChange(0);
1460 }
1461
1462 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1463 {
1464     e.killindicator = spawn();
1465     e.killindicator.owner = e;
1466     e.killindicator.think = KillIndicator_Think;
1467     e.killindicator.nextthink = time + (e.lip) * 0.05;
1468     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1469     e.killindicator.health = 1; // this is used to indicate that it should be silent
1470     e.lip = 0;
1471 }
1472
1473 void FixClientCvars(entity e)
1474 {
1475         // send prediction settings to the client
1476         stuffcmd(e, "\nin_bindmap 0 0\n");
1477         if(g_race || g_cts)
1478                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1479         if(autocvar_g_antilag == 3) // client side hitscan
1480                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1481         if(sv_gentle)
1482                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1483         /*
1484          * we no longer need to stuff this. Remove this comment block if you feel
1485          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1486         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1487         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1488         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1489         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1490         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1491         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1492         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1493         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1494         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1495         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1496         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1497         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1498         stuffcmd(e, "cl_movement_edgefriction 1\n");
1499          */
1500 }
1501
1502 float PlayerInIDList(entity p, string idlist)
1503 {
1504         float n, i;
1505         string s;
1506
1507         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1508         if not(p.crypto_idfp)
1509                 return 0;
1510
1511         // this function allows abbreviated player IDs too!
1512         n = tokenize_console(idlist);
1513         for(i = 0; i < n; ++i)
1514         {
1515                 s = argv(i);
1516                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1517                         return 1;
1518         }
1519
1520         return 0;
1521 }
1522
1523 /*
1524 =============
1525 ClientConnect
1526
1527 Called when a client connects to the server
1528 =============
1529 */
1530 //void ctf_clientconnect();
1531 string ColoredTeamName(float t);
1532 void DecodeLevelParms (void);
1533 //void dom_player_join_team(entity pl);
1534 void set_dom_state(entity e);
1535 void ClientConnect (void)
1536 {
1537         float t;
1538
1539         if(self.flags & FL_CLIENT)
1540         {
1541                 print("Warning: ClientConnect, but already connected!\n");
1542                 return;
1543         }
1544
1545         if(Ban_MaybeEnforceBan(self))
1546                 return;
1547
1548         DecodeLevelParms();
1549
1550 #ifdef WATERMARK
1551         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1552 #endif
1553
1554         self.classname = "player_joining";
1555
1556         self.flags = FL_CLIENT;
1557         self.version_nagtime = time + 10 + random() * 10;
1558
1559         if(player_count<0)
1560         {
1561                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1562                 player_count = 0;
1563         }
1564
1565         PlayerScore_Attach(self);
1566         ClientData_Attach();
1567         accuracy_init(self);
1568
1569         bot_clientconnect();
1570
1571         playerdemo_init();
1572
1573         anticheat_init();
1574
1575         race_PreSpawnObserver();
1576
1577         //if(g_domination)
1578         //      dom_player_join_team(self);
1579
1580         // identify the right forced team
1581         if(autocvar_g_campaign)
1582         {
1583                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1584                 {
1585                         switch(autocvar_g_campaign_forceteam)
1586                         {
1587                                 case 1: self.team_forced = COLOR_TEAM1; break;
1588                                 case 2: self.team_forced = COLOR_TEAM2; break;
1589                                 case 3: self.team_forced = COLOR_TEAM3; break;
1590                                 case 4: self.team_forced = COLOR_TEAM4; break;
1591                                 default: self.team_forced = 0;
1592                         }
1593                 }
1594         }
1595         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1596                 self.team_forced = COLOR_TEAM1;
1597         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1598                 self.team_forced = COLOR_TEAM2;
1599         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1600                 self.team_forced = COLOR_TEAM3;
1601         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1602                 self.team_forced = COLOR_TEAM4;
1603         else if(autocvar_g_forced_team_otherwise == "red")
1604                 self.team_forced = COLOR_TEAM1;
1605         else if(autocvar_g_forced_team_otherwise == "blue")
1606                 self.team_forced = COLOR_TEAM2;
1607         else if(autocvar_g_forced_team_otherwise == "yellow")
1608                 self.team_forced = COLOR_TEAM3;
1609         else if(autocvar_g_forced_team_otherwise == "pink")
1610                 self.team_forced = COLOR_TEAM4;
1611         else if(autocvar_g_forced_team_otherwise == "spectate")
1612                 self.team_forced = -1;
1613         else if(autocvar_g_forced_team_otherwise == "spectator")
1614                 self.team_forced = -1;
1615         else
1616                 self.team_forced = 0;
1617
1618         if(!teamplay)
1619                 if(self.team_forced > 0)
1620                         self.team_forced = 0;
1621
1622         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1623
1624         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1625                 self.classname = "observer";
1626         } else {
1627                 if(teamplay)
1628                 {
1629                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1630                         {
1631                                 self.classname = "player";
1632                                 campaign_bots_may_start = 1;
1633                         }
1634                         else
1635                         {
1636                                 self.classname = "observer"; // do it anyway
1637                         }
1638                 }
1639                 else
1640                 {
1641                         self.classname = "player";
1642                         campaign_bots_may_start = 1;
1643                 }
1644         }
1645
1646         self.playerid = (playerid_last = playerid_last + 1);
1647
1648         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1649
1650     if(clienttype(self) == CLIENTTYPE_BOT)
1651         PlayerStats_AddPlayer(self);
1652
1653         if(autocvar_sv_eventlog)
1654                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1655
1656         LogTeamchange(self.playerid, self.team, 1);
1657
1658         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1659
1660         self.netname_previous = strzone(self.netname);
1661
1662         bprint("^4", self.netname, "^4 connected");
1663
1664         if(self.classname != "observer" && (g_domination || g_ctf))
1665                 bprint(" and joined the ", ColoredTeamName(self.team));
1666
1667         bprint("\n");
1668
1669         stuffcmd(self, strcat(clientstuff, "\n"));
1670         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1671
1672         FixClientCvars(self);
1673
1674         // spawnfunc_waypoint sprites
1675         WaypointSprite_InitClient(self);
1676
1677         // Wazat's grappling hook
1678         SetGrappleHookBindings();
1679
1680         // get autoswitch state from player when he toggles it
1681         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1682
1683         // get version info from player
1684         stuffcmd(self, "cmd clientversion $gameversion\n");
1685
1686         // get other cvars from player
1687         GetCvars(0);
1688
1689         // notify about available teams
1690         if(teamplay)
1691         {
1692                 CheckAllowedTeams(self);
1693                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1694                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1695         }
1696         else
1697                 stuffcmd(self, "set _teams_available 0\n");
1698
1699         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1700
1701         if(g_arena || g_ca)
1702         {
1703                 self.classname = "observer";
1704                 if(g_arena)
1705                         Spawnqueue_Insert(self);
1706         }
1707         /*else if(g_ctf)
1708         {
1709                 ctf_clientconnect();
1710         }*/
1711
1712         attach_entcs();
1713
1714         bot_relinkplayerlist();
1715
1716         self.spectatortime = time;
1717         if(blockSpectators)
1718         {
1719                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1720         }
1721
1722         self.jointime = time;
1723         self.allowedTimeouts = autocvar_sv_timeout_number;
1724
1725         if(clienttype(self) == CLIENTTYPE_REAL)
1726         {
1727                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1728                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1729         }
1730
1731         if(g_lms)
1732         {
1733                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1734                 {
1735                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1736                         self.frags = FRAGS_SPECTATOR;
1737                 }
1738         }
1739
1740         if(!sv_foginterval && world.fog != "")
1741                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1742
1743         SoundEntity_Attach(self);
1744
1745         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1746         {
1747                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1748                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1749         }
1750         else
1751                 self.hitplotfh = -1;
1752
1753         if(g_race || g_cts) {
1754                 string rr;
1755                 if(g_cts)
1756                         rr = CTS_RECORD;
1757                 else
1758                         rr = RACE_RECORD;
1759                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1760
1761                 msg_entity = self;
1762                 race_send_recordtime(MSG_ONE);
1763                 race_send_speedaward(MSG_ONE);
1764
1765                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1766                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1767                 race_send_speedaward_alltimebest(MSG_ONE);
1768
1769                 float i;
1770                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1771                         race_SendRankings(i, 0, 0, MSG_ONE);
1772                 }
1773         }
1774         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1775                 send_CSQC_teamnagger();
1776
1777         if (g_domination)
1778                 set_dom_state(self);
1779
1780         CheatInitClient();
1781
1782         if(!autocvar_g_campaign)
1783                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1784 }
1785
1786 /*
1787 =============
1788 ClientDisconnect
1789
1790 Called when a client disconnects from the server
1791 =============
1792 */
1793 .entity chatbubbleentity;
1794 void ReadyCount();
1795 void ClientDisconnect (void)
1796 {
1797         if(self.vehicle)
1798             vehicles_exit(VHEF_RELESE);
1799
1800         if not(self.flags & FL_CLIENT)
1801         {
1802                 print("Warning: ClientDisconnect without ClientConnect\n");
1803                 return;
1804         }
1805
1806         PlayerStats_AddGlobalInfo(self);
1807
1808         CheatShutdownClient();
1809
1810         if(self.hitplotfh >= 0)
1811         {
1812                 fclose(self.hitplotfh);
1813                 self.hitplotfh = -1;
1814         }
1815
1816         anticheat_report();
1817         anticheat_shutdown();
1818
1819         playerdemo_shutdown();
1820
1821         bot_clientdisconnect();
1822
1823         if(self.entcs)
1824                 detach_entcs();
1825
1826         if(autocvar_sv_eventlog)
1827                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1828         bprint ("^4",self.netname);
1829         bprint ("^4 disconnected\n");
1830
1831         SoundEntity_Detach(self);
1832
1833         DropAllRunes(self);
1834         MUTATOR_CALLHOOK(ClientDisconnect);
1835
1836         Portal_ClearAll(self);
1837
1838         if(self.flagcarried)
1839                 DropFlag(self.flagcarried, world, world);
1840         if(self.ballcarried && g_nexball)
1841                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1842
1843         // Here, everything has been done that requires this player to be a client.
1844
1845         self.flags &~= FL_CLIENT;
1846
1847         if (self.chatbubbleentity)
1848                 remove (self.chatbubbleentity);
1849
1850         if (self.killindicator)
1851                 remove (self.killindicator);
1852
1853         WaypointSprite_PlayerGone();
1854
1855         bot_relinkplayerlist();
1856
1857         if(g_arena)
1858         {
1859                 Spawnqueue_Unmark(self);
1860                 Spawnqueue_Remove(self);
1861         }
1862
1863         accuracy_free(self);
1864         ClientData_Detach();
1865         PlayerScore_Detach(self);
1866
1867         if(self.netname_previous)
1868                 strunzone(self.netname_previous);
1869         if(self.clientstatus)
1870                 strunzone(self.clientstatus);
1871         if(self.weaponorder_byimpulse)
1872                 strunzone(self.weaponorder_byimpulse);
1873
1874         ClearPlayerSounds();
1875
1876         if(self.personal)
1877                 remove(self.personal);
1878
1879         self.playerid = 0;
1880         ReadyCount();
1881
1882         // free cvars
1883         GetCvars(-1);
1884 }
1885
1886 .float BUTTON_CHAT;
1887 void ChatBubbleThink()
1888 {
1889         self.nextthink = time;
1890         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1891         {
1892                 if(self.owner) // but why can that ever be world?
1893                         self.owner.chatbubbleentity = world;
1894                 remove(self);
1895                 return;
1896         }
1897         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1898 #ifdef TETRIS
1899                 || self.owner.tetris_on
1900 #endif
1901         )
1902                 self.model = self.mdl;
1903         else
1904                 self.model = "";
1905 };
1906
1907 void UpdateChatBubble()
1908 {
1909         if (!self.modelindex)
1910                 return;
1911         // spawn a chatbubble entity if needed
1912         if (!self.chatbubbleentity)
1913         {
1914                 self.chatbubbleentity = spawn();
1915                 self.chatbubbleentity.owner = self;
1916                 self.chatbubbleentity.exteriormodeltoclient = self;
1917                 self.chatbubbleentity.think = ChatBubbleThink;
1918                 self.chatbubbleentity.nextthink = time;
1919                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1920                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1921                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1922                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1923                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1924                 self.chatbubbleentity.model = "";
1925                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1926         }
1927 }
1928
1929
1930 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1931 // added to the model skins
1932 /*void UpdateColorModHack()
1933 {
1934         local float c;
1935         c = self.clientcolors & 15;
1936         // LordHavoc: only bothering to support white, green, red, yellow, blue
1937              if (!teamplay) self.colormod = '0 0 0';
1938         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1939         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1940         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1941         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1942         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1943         else self.colormod = '1 1 1';
1944 };*/
1945
1946 .float oldcolormap;
1947 void respawn(void)
1948 {
1949         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1950         {
1951                 self.solid = SOLID_NOT;
1952                 self.takedamage = DAMAGE_NO;
1953                 self.movetype = MOVETYPE_FLY;
1954                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1955                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1956                 self.effects |= EF_ADDITIVE;
1957                 self.oldcolormap = self.colormap;
1958                 self.colormap = 512;
1959                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1960                 if(autocvar_g_respawn_ghosts_maxtime)
1961                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1962         }
1963
1964         CopyBody(1);
1965         self.effects |= EF_NODRAW; // prevent another CopyBody
1966         if(self.oldcolormap)
1967         {
1968                 self.colormap = self.oldcolormap;
1969                 self.oldcolormap = 0;
1970         }
1971         PutClientInServer();
1972 }
1973
1974 void play_countdown(float finished, string samp)
1975 {
1976         if(clienttype(self) == CLIENTTYPE_REAL)
1977                 if(floor(finished - time - frametime) != floor(finished - time))
1978                         if(finished - time < 6)
1979                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1980 }
1981
1982 void player_powerups (void)
1983 {
1984         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1985         olditems = self.items;
1986
1987         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1988         {
1989                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1990                 self.modelflags |= MF_ROCKET;
1991         }
1992         else
1993         {
1994                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1995                 self.modelflags &~= MF_ROCKET;
1996         }
1997
1998         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1999
2000         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2001                 return;
2002
2003         Fire_ApplyDamage(self);
2004         Fire_ApplyEffect(self);
2005
2006         if (g_minstagib)
2007         {
2008                 self.effects |= EF_FULLBRIGHT;
2009
2010                 if (self.items & IT_STRENGTH)
2011                 {
2012                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2013                         if (time > self.strength_finished)
2014                         {
2015                                 self.alpha = default_player_alpha;
2016                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2017                                 self.items &~= IT_STRENGTH;
2018                                 sprint(self, "^3Invisibility has worn off\n");
2019                         }
2020                 }
2021                 else
2022                 {
2023                         if (time < self.strength_finished)
2024                         {
2025                                 self.alpha = g_minstagib_invis_alpha;
2026                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2027                                 self.items |= IT_STRENGTH;
2028                                 sprint(self, "^3You are invisible\n");
2029                         }
2030                 }
2031
2032                 if (self.items & IT_INVINCIBLE)
2033                 {
2034                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2035                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2036                         {
2037                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2038                                 sprint(self, "^3Speed has worn off\n");
2039                         }
2040                 }
2041                 else
2042                 {
2043                         if (time < self.invincible_finished)
2044                         {
2045                                 self.items = self.items | IT_INVINCIBLE;
2046                                 sprint(self, "^3You are on speed\n");
2047                         }
2048                 }
2049         }
2050         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2051         {
2052                 if (self.items & IT_STRENGTH)
2053                 {
2054                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2055                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2056                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2057                         {
2058                                 self.items = self.items - (self.items & IT_STRENGTH);
2059                                 sprint(self, "^3Strength has worn off\n");
2060                         }
2061                 }
2062                 else
2063                 {
2064                         if (time < self.strength_finished)
2065                         {
2066                                 self.items = self.items | IT_STRENGTH;
2067                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2068                         }
2069                 }
2070                 if (self.items & IT_INVINCIBLE)
2071                 {
2072                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2073                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2074                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2075                         {
2076                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2077                                 sprint(self, "^3Shield has worn off\n");
2078                         }
2079                 }
2080                 else
2081                 {
2082                         if (time < self.invincible_finished)
2083                         {
2084                                 self.items = self.items | IT_INVINCIBLE;
2085                                 sprint(self, "^3Shield surrounds you\n");
2086                         }
2087                 }
2088
2089                 if(autocvar_g_nodepthtestplayers)
2090                         self.effects = self.effects | EF_NODEPTHTEST;
2091
2092                 if(autocvar_g_fullbrightplayers)
2093                         self.effects = self.effects | EF_FULLBRIGHT;
2094
2095                 // midair gamemode: damage only while in the air
2096                 // if in midair mode, being on ground grants temporary invulnerability
2097                 // (this is so that multishot weapon don't clear the ground flag on the
2098                 // first damage in the frame, leaving the player vulnerable to the
2099                 // remaining hits in the same frame)
2100                 if (self.flags & FL_ONGROUND)
2101                 if (g_midair)
2102                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2103
2104                 if (time >= game_starttime)
2105                 if (time < self.spawnshieldtime)
2106                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2107         }
2108
2109         MUTATOR_CALLHOOK(PlayerPowerups);
2110 }
2111
2112 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2113 {
2114         if(current > stable)
2115                 return current;
2116         else if(current > stable - 0.25) // when close enough, "snap"
2117                 return stable;
2118         else
2119                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2120 }
2121
2122 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2123 {
2124         if(current < stable)
2125                 return current;
2126         else if(current < stable + 0.25) // when close enough, "snap"
2127                 return stable;
2128         else
2129                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2130 }
2131
2132 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2133 {
2134         if(current > rotstable)
2135         {
2136                 if(rotframetime > 0)
2137                 {
2138                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2139                         current = max(rotstable, current - rotlinear * rotframetime);
2140                 }
2141         }
2142         else if(current < regenstable)
2143         {
2144                 if(regenframetime > 0)
2145                 {
2146                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2147                         current = min(regenstable, current + regenlinear * regenframetime);
2148                 }
2149         }
2150
2151         if(current > limit)
2152                 current = limit;
2153
2154         return current;
2155 }
2156
2157 void player_regen (void)
2158 {
2159         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2160         maxh = autocvar_g_balance_health_rotstable;
2161         maxa = autocvar_g_balance_armor_rotstable;
2162         maxf = autocvar_g_balance_fuel_rotstable;
2163         minh = autocvar_g_balance_health_regenstable;
2164         mina = autocvar_g_balance_armor_regenstable;
2165         minf = autocvar_g_balance_fuel_regenstable;
2166         limith = autocvar_g_balance_health_limit;
2167         limita = autocvar_g_balance_armor_limit;
2168         limitf = autocvar_g_balance_fuel_limit;
2169
2170         max_mod = regen_mod = rot_mod = limit_mod = 1;
2171
2172         if (self.runes & RUNE_REGEN)
2173         {
2174                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2175                 {
2176                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2177                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2178                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2179                 }
2180                 else
2181                 {
2182                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2183                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2184                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2185                 }
2186         }
2187         else if (self.runes & CURSE_VENOM)
2188         {
2189                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2190                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2191                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2192                 else
2193                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2194                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2195                 //if (!self.runes & RUNE_REGEN)
2196                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2197         }
2198         maxh = maxh * max_mod;
2199         //maxa = maxa * max_mod;
2200         //maxf = maxf * max_mod;
2201         minh = minh * max_mod;
2202         //mina = mina * max_mod;
2203         //minf = minf * max_mod;
2204         limith = limith * limit_mod;
2205         limita = limita * limit_mod;
2206         //limitf = limitf * limit_mod;
2207
2208         if(g_lms && g_ca)
2209                 rot_mod = 0;
2210
2211         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2212         {
2213                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2214                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2215
2216                 // if player rotted to death...  die!
2217                 if(self.health < 1)
2218                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2219         }
2220
2221         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2222                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2223 }
2224
2225 float zoomstate_set;
2226 void SetZoomState(float z)
2227 {
2228         if(z != self.zoomstate)
2229         {
2230                 self.zoomstate = z;
2231                 ClientData_Touch(self);
2232         }
2233         zoomstate_set = 1;
2234 }
2235
2236 void GetPressedKeys(void) {
2237         MUTATOR_CALLHOOK(GetPressedKeys);
2238         if (self.movement_x > 0) // get if movement keys are pressed
2239         {       // forward key pressed
2240                 self.pressedkeys |= KEY_FORWARD;
2241                 self.pressedkeys &~= KEY_BACKWARD;
2242         }
2243         else if (self.movement_x < 0)
2244         {       // backward key pressed
2245                 self.pressedkeys |= KEY_BACKWARD;
2246                 self.pressedkeys &~= KEY_FORWARD;
2247         }
2248         else
2249         {       // no x input
2250                 self.pressedkeys &~= KEY_FORWARD;
2251                 self.pressedkeys &~= KEY_BACKWARD;
2252         }
2253
2254         if (self.movement_y > 0)
2255         {       // right key pressed
2256                 self.pressedkeys |= KEY_RIGHT;
2257                 self.pressedkeys &~= KEY_LEFT;
2258         }
2259         else if (self.movement_y < 0)
2260         {       // left key pressed
2261                 self.pressedkeys |= KEY_LEFT;
2262                 self.pressedkeys &~= KEY_RIGHT;
2263         }
2264         else
2265         {       // no y input
2266                 self.pressedkeys &~= KEY_RIGHT;
2267                 self.pressedkeys &~= KEY_LEFT;
2268         }
2269
2270         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2271                 self.pressedkeys |= KEY_JUMP;
2272         else
2273                 self.pressedkeys &~= KEY_JUMP;
2274         if (self.BUTTON_CROUCH)
2275                 self.pressedkeys |= KEY_CROUCH;
2276         else
2277                 self.pressedkeys &~= KEY_CROUCH;
2278 }
2279
2280 /*
2281 ======================
2282 spectate mode routines
2283 ======================
2284 */
2285
2286 void SpectateCopy(entity spectatee) {
2287         other = spectatee;
2288         MUTATOR_CALLHOOK(SpectateCopy);
2289         self.armortype = spectatee.armortype;
2290         self.armorvalue = spectatee.armorvalue;
2291         self.ammo_cells = spectatee.ammo_cells;
2292         self.ammo_shells = spectatee.ammo_shells;
2293         self.ammo_nails = spectatee.ammo_nails;
2294         self.ammo_rockets = spectatee.ammo_rockets;
2295         self.ammo_fuel = spectatee.ammo_fuel;
2296         self.clip_load = spectatee.clip_load;
2297         self.clip_size = spectatee.clip_size;
2298         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2299         self.health = spectatee.health;
2300         self.impulse = 0;
2301         self.items = spectatee.items;
2302         self.last_pickup = spectatee.last_pickup;
2303         self.hit_time = spectatee.hit_time;
2304         self.metertime = spectatee.metertime;
2305         self.strength_finished = spectatee.strength_finished;
2306         self.invincible_finished = spectatee.invincible_finished;
2307         self.pressedkeys = spectatee.pressedkeys;
2308         self.weapons = spectatee.weapons;
2309         self.switchweapon = spectatee.switchweapon;
2310         self.switchingweapon = spectatee.switchingweapon;
2311         self.weapon = spectatee.weapon;
2312         self.nex_charge = spectatee.nex_charge;
2313         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2314         self.hagar_load = spectatee.hagar_load;
2315         self.minelayer_mines = spectatee.minelayer_mines;
2316         self.punchangle = spectatee.punchangle;
2317         self.view_ofs = spectatee.view_ofs;
2318         self.v_angle = spectatee.v_angle;
2319         self.velocity = spectatee.velocity;
2320         self.dmg_take = spectatee.dmg_take;
2321         self.dmg_save = spectatee.dmg_save;
2322         self.dmg_inflictor = spectatee.dmg_inflictor;
2323         self.angles = spectatee.v_angle;
2324         if(!self.BUTTON_USE)
2325                 self.fixangle = TRUE;
2326         setorigin(self, spectatee.origin);
2327         setsize(self, spectatee.mins, spectatee.maxs);
2328         SetZoomState(spectatee.zoomstate);
2329
2330         anticheat_spectatecopy(spectatee);
2331
2332         //self.vehicle = spectatee.vehicle;
2333
2334         self.hud = spectatee.hud;
2335         if(spectatee.vehicle)
2336     {
2337         setorigin(self, spectatee.origin);
2338         self.velocity = spectatee.vehicle.velocity;
2339         self.v_angle += spectatee.vehicle.angles;
2340         //self.v_angle_x *= -1;
2341         self.vehicle_health = spectatee.vehicle_health;
2342         self.vehicle_shield = spectatee.vehicle_shield;
2343         self.vehicle_energy = spectatee.vehicle_energy;
2344         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2345         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2346         self.vehicle_reload1 = spectatee.vehicle_reload1;
2347         self.vehicle_reload2 = spectatee.vehicle_reload2;
2348
2349         msg_entity = self;
2350         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2351         WriteEntity(MSG_ONE, spectatee);
2352         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2353     }
2354 }
2355
2356 float SpectateUpdate() {
2357         if(!self.enemy)
2358             return 0;
2359
2360         if (self == self.enemy)
2361                 return 0;
2362
2363         if(self.enemy.classname != "player")
2364                 return 0;
2365
2366         SpectateCopy(self.enemy);
2367
2368         return 1;
2369 }
2370
2371
2372 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2373 entity CA_SpectateNext(entity start) {
2374         if (start.team == self.team) {
2375                 return start;
2376         }
2377
2378         other = start;
2379         // continue from current player
2380         while(other && other.team != self.team) {
2381                 other = find(other, classname, "player");
2382         }
2383
2384         if (!other) {
2385                 // restart from begining
2386                 other = find(other, classname, "player");
2387                 while(other && other.team != self.team) {
2388                         other = find(other, classname, "player");
2389                 }
2390         }
2391
2392         return other;
2393 }
2394
2395 float SpectateNext() {
2396         other = find(self.enemy, classname, "player");
2397         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2398                 // CA and ca players when spectating enemies is forbidden
2399                 other = CA_SpectateNext(other);
2400         } else {
2401                 // other modes and ca spectators or spectating enemies is allowed
2402                 if (!other)
2403                         other = find(other, classname, "player");
2404         }
2405
2406         if (other)
2407                 self.enemy = other;
2408
2409         if(self.enemy.classname == "player") {
2410             if(self.enemy.vehicle)
2411             {
2412             msg_entity = self;
2413             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2414             WriteEntity(MSG_ONE, self.enemy);
2415             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2416             self.movetype = MOVETYPE_NONE;
2417             accuracy_resend(self);
2418             }
2419             else
2420             {
2421             msg_entity = self;
2422             WriteByte(MSG_ONE, SVC_SETVIEW);
2423             WriteEntity(MSG_ONE, self.enemy);
2424             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2425             self.movetype = MOVETYPE_NONE;
2426             accuracy_resend(self);
2427
2428             if(!SpectateUpdate())
2429                 PutObserverInServer();
2430         }
2431         return 1;
2432         } else {
2433                 return 0;
2434         }
2435 }
2436
2437 /*
2438 =============
2439 ShowRespawnCountdown()
2440
2441 Update a respawn countdown display.
2442 =============
2443 */
2444 void ShowRespawnCountdown()
2445 {
2446         float number;
2447         if(self.deadflag == DEAD_NO) // just respawned?
2448                 return;
2449         else
2450         {
2451                 number = ceil(self.death_time - time);
2452                 if(number <= 0)
2453                         return;
2454                 if(number <= self.respawn_countdown)
2455                 {
2456                         self.respawn_countdown = number - 1;
2457                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2458                                 AnnounceTo(self, strcat(ftos(number), ""));
2459                 }
2460         }
2461 }
2462
2463 .float prevent_join_msgtime;
2464 void LeaveSpectatorMode()
2465 {
2466         if(nJoinAllowed(1)) {
2467                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2468                         self.classname = "player";
2469
2470                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2471                                 JoinBestTeam(self, FALSE, TRUE);
2472
2473                         if(autocvar_g_campaign)
2474                                 campaign_bots_may_start = 1;
2475
2476                         PutClientInServer();
2477
2478                         if(self.classname == "player")
2479                                 bprint ("^4", self.netname, "^4 is playing now\n");
2480
2481                         if(!autocvar_g_campaign)
2482                         if (time < self.jointime + autocvar_welcome_message_time)
2483                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2484
2485                         if (self.prevent_join_msgtime)
2486                         {
2487                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2488                                 self.prevent_join_msgtime = 0;
2489                         }
2490
2491                         return;
2492                 } else {
2493                         if (g_ca && self.caplayer) {
2494                         }       // do nothing
2495                         else
2496                                 stuffcmd(self,"menu_showteamselect\n");
2497                         return;
2498                 }
2499         }
2500         else {
2501                 //player may not join because of g_maxplayers is set
2502                 if (time - self.prevent_join_msgtime > 2)
2503                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2504                 self.prevent_join_msgtime = time;
2505         }
2506 }
2507
2508 /**
2509  * Determines whether the player is allowed to join. This depends on cvar
2510  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2511  * it checks whether the number of currently playing players exceeds g_maxplayers.
2512  * @return int number of free slots for players, 0 if none
2513  */
2514 float nJoinAllowed(float includeMe) {
2515         if(self.team_forced < 0)
2516                 return FALSE; // forced spectators can never join
2517
2518         // TODO simplify this
2519         local entity e;
2520
2521         local float totalClients;
2522         FOR_EACH_CLIENT(e)
2523                 totalClients += 1;
2524
2525         if (!autocvar_g_maxplayers)
2526                 return maxclients - totalClients + includeMe;
2527
2528         local float currentlyPlaying;
2529         FOR_EACH_REALPLAYER(e)
2530                 currentlyPlaying += 1;
2531
2532         if(currentlyPlaying < autocvar_g_maxplayers)
2533                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2534
2535         return 0;
2536 }
2537
2538 /**
2539  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2540  * g_maxplayers_spectator_blocktime seconds
2541  */
2542 void checkSpectatorBlock() {
2543         if(self.classname == "spectator" || self.classname == "observer") {
2544                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2545                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2546                         dropclient(self);
2547                 }
2548         }
2549 }
2550
2551 .float motd_actived_time; // used for both motd and campaign_message
2552 void PrintWelcomeMessage()
2553 {
2554         if (self.motd_actived_time == 0) { // is there already a message showing?
2555                 if (autocvar_g_campaign) {
2556                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2557                                 self.motd_actived_time = time;
2558                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2559                         }
2560                 } else {
2561                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2562                                 self.motd_actived_time = time;
2563                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2564                         }
2565                 }
2566         } else { // showing MOTD or campaign message
2567                 if (autocvar_g_campaign) {
2568                         if (self.BUTTON_INFO)
2569                                 self.motd_actived_time = time;
2570                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2571                                 self.motd_actived_time = 0;
2572                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2573                         }
2574                 } else {
2575                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2576                                 if (self.BUTTON_INFO)
2577                                         self.motd_actived_time = time;
2578                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2579                                         self.motd_actived_time = 0;
2580                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2581                                 }
2582                         }
2583                 }
2584         }
2585 }
2586
2587 void ObserverThink()
2588 {
2589         float prefered_movetype;
2590         if (self.flags & FL_JUMPRELEASED) {
2591                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2592                         self.flags &~= FL_JUMPRELEASED;
2593                         self.flags |= FL_SPAWNING;
2594                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2595                         self.flags &~= FL_JUMPRELEASED;
2596                         if(SpectateNext() == 1) {
2597                                 self.classname = "spectator";
2598                         }
2599                 } else {
2600                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2601                         if (self.movetype != prefered_movetype)
2602                                 self.movetype = prefered_movetype;
2603                 }
2604         } else {
2605                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2606                         self.flags |= FL_JUMPRELEASED;
2607                         if(self.flags & FL_SPAWNING)
2608                         {
2609                                 self.flags &~= FL_SPAWNING;
2610                                 LeaveSpectatorMode();
2611                                 return;
2612                         }
2613                 }
2614         }
2615
2616         PrintWelcomeMessage();
2617 }
2618
2619 void SpectatorThink()
2620 {
2621         if (self.flags & FL_JUMPRELEASED) {
2622                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2623                         self.flags &~= FL_JUMPRELEASED;
2624                         self.flags |= FL_SPAWNING;
2625                 } else if(self.BUTTON_ATCK) {
2626                         self.flags &~= FL_JUMPRELEASED;
2627                         if(SpectateNext() == 1) {
2628                                 self.classname = "spectator";
2629                         } else {
2630                                 self.classname = "observer";
2631                                 PutClientInServer();
2632                         }
2633                 } else if (self.BUTTON_ATCK2) {
2634                         self.flags &~= FL_JUMPRELEASED;
2635                         self.classname = "observer";
2636                         PutClientInServer();
2637                 } else {
2638                         if(!SpectateUpdate())
2639                                 PutObserverInServer();
2640                 }
2641         } else {
2642                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2643                         self.flags |= FL_JUMPRELEASED;
2644                         if(self.flags & FL_SPAWNING)
2645                         {
2646                                 self.flags &~= FL_SPAWNING;
2647                                 LeaveSpectatorMode();
2648                                 return;
2649                         }
2650                 }
2651                 if(!SpectateUpdate())
2652                         PutObserverInServer();
2653         }
2654
2655         PrintWelcomeMessage();
2656         self.flags |= FL_CLIENT | FL_NOTARGET;
2657 }
2658
2659 float ctf_usekey();
2660 void PlayerUseKey()
2661 {
2662         if(self.classname != "player")
2663                 return;
2664
2665         if(self.vehicle)
2666         {
2667         vehicles_exit(VHEF_NORMAL);
2668         return;
2669         }
2670
2671         // a use key was pressed; call handlers
2672         if(ctf_usekey())
2673                 return;
2674
2675         MUTATOR_CALLHOOK(PlayerUseKey);
2676 }
2677
2678 .float touchexplode_time;
2679
2680 /*
2681 =============
2682 PlayerPreThink
2683
2684 Called every frame for each client before the physics are run
2685 =============
2686 */
2687 .float usekeypressed;
2688 void() ctf_setstatus;
2689 void() nexball_setstatus;
2690 .float items_added;
2691 void PlayerPreThink (void)
2692 {
2693         WarpZone_PlayerPhysics_FixVAngle();
2694
2695         self.stat_game_starttime = game_starttime;
2696         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2697         self.stat_leadlimit = autocvar_leadlimit;
2698
2699         if(frametime)
2700         {
2701                 // physics frames: update anticheat stuff
2702                 anticheat_prethink();
2703         }
2704
2705         if(blockSpectators && frametime)
2706                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2707                 checkSpectatorBlock();
2708
2709         zoomstate_set = 0;
2710
2711         if(self.netname_previous != self.netname)
2712         {
2713                 if(autocvar_sv_eventlog)
2714                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2715                 if(self.netname_previous)
2716                         strunzone(self.netname_previous);
2717                 self.netname_previous = strzone(self.netname);
2718         }
2719
2720         // version nagging
2721         if(self.version_nagtime)
2722                 if(self.cvar_g_xonoticversion)
2723                         if(time > self.version_nagtime)
2724                         {
2725                                 // don't notify git users
2726                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2727                                 {
2728                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2729                                         {
2730                                                 // notify release users if connecting to git
2731                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2732                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2733                                         }
2734                                         else
2735                                         {
2736                                                 float r;
2737                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2738                                                 if(r < 0)
2739                                                 {
2740                                                         // give users new version
2741                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2742                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2743                                                 }
2744                                                 else if(r > 0)
2745                                                 {
2746                                                         // notify users about old server version
2747                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2748                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2749                                                 }
2750                                         }
2751                                 }
2752                                 self.version_nagtime = 0;
2753                         }
2754
2755         // GOD MODE info
2756         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2757         {
2758                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2759                 self.max_armorvalue = 0;
2760         }
2761
2762 #ifdef TETRIS
2763         if (TetrisPreFrame())
2764                 return;
2765 #endif
2766
2767         MUTATOR_CALLHOOK(PlayerPreThink);
2768
2769         if(self.BUTTON_USE && !self.usekeypressed)
2770                 PlayerUseKey();
2771         self.usekeypressed = self.BUTTON_USE;
2772
2773         PrintWelcomeMessage();
2774
2775         if(self.classname == "player") {
2776 //              if(self.netname == "Wazat")
2777 //                      bprint(self.classname, "\n");
2778
2779                 CheckRules_Player();
2780
2781                 if (intermission_running)
2782                 {
2783                         IntermissionThink ();   // otherwise a button could be missed between
2784                         return;                                 // the think tics
2785                 }
2786
2787                 //don't allow the player to turn around while game is paused!
2788                 if(timeoutStatus == 2) {
2789                         // FIXME turn this into CSQC stuff
2790                         self.v_angle = self.lastV_angle;
2791                         self.angles = self.lastV_angle;
2792                         self.fixangle = TRUE;
2793                 }
2794
2795                 if(frametime)
2796                 {
2797                         if(self.health <= 0 && autocvar_g_deathglow)
2798                         {
2799                                 if(self.glowmod_x > 0)
2800                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2801                                 else
2802                                         self.glowmod_x = -1;
2803                                 if(self.glowmod_y > 0)
2804                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2805                                 else
2806                                         self.glowmod_y = -1;
2807                                 if(self.glowmod_z > 0)
2808                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2809                                 else
2810                                         self.glowmod_z = -1;
2811                         }
2812                         else
2813                         {
2814                                 // set weapon and player glowmod
2815                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2816
2817                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2818                                 {
2819                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2820                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2821                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2822
2823                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2824                                         {
2825                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2826                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2827                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2828                                         }
2829                                 }
2830                                 else
2831                                         self.weaponentity_glowmod = self.glowmod;
2832                         }
2833                         player_powerups();
2834                 }
2835
2836                 if (g_minstagib)
2837                         minstagib_ammocheck();
2838
2839                 if (self.deadflag != DEAD_NO)
2840                 {
2841                         float button_pressed, force_respawn;
2842                         if(self.personal && g_race_qualifying)
2843                         {
2844                                 if(time > self.death_time)
2845                                 {
2846                                         self.death_time = time + 1; // only retry once a second
2847                                         respawn();
2848                                         self.impulse = 141;
2849                                 }
2850                         }
2851                         else
2852                         {
2853                                 if(frametime)
2854                                         player_anim();
2855                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2856                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2857                                 if (self.deadflag == DEAD_DYING)
2858                                 {
2859                                         if(force_respawn)
2860                                                 self.deadflag = DEAD_RESPAWNING;
2861                                         else if(!button_pressed)
2862                                                 self.deadflag = DEAD_DEAD;
2863                                 }
2864                                 else if (self.deadflag == DEAD_DEAD)
2865                                 {
2866                                         if(button_pressed)
2867                                                 self.deadflag = DEAD_RESPAWNABLE;
2868                                 }
2869                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2870                                 {
2871                                         if(!button_pressed)
2872                                                 self.deadflag = DEAD_RESPAWNING;
2873                                 }
2874                                 else if (self.deadflag == DEAD_RESPAWNING)
2875                                 {
2876                                         if(time > self.death_time)
2877                                         {
2878                                                 self.death_time = time + 1; // only retry once a second
2879                                                 respawn();
2880                                         }
2881                                 }
2882                                 ShowRespawnCountdown();
2883                         }
2884                         return;
2885                 }
2886                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2887                 // so (self.deadflag == DEAD_NO) is always true in the code below
2888
2889                 if(g_touchexplode)
2890                 if(time > self.touchexplode_time)
2891                 if(self.classname == "player")
2892                 if(self.deadflag == DEAD_NO)
2893                 if not(IS_INDEPENDENT_PLAYER(self))
2894                 FOR_EACH_PLAYER(other) if(self != other)
2895                 {
2896                         if(time > other.touchexplode_time)
2897                         if(other.deadflag == DEAD_NO)
2898                         if not(IS_INDEPENDENT_PLAYER(other))
2899                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2900                         {
2901                                 PlayerTouchExplode(self, other);
2902                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2903                         }
2904                 }
2905
2906                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2907                 {
2908                         vector dist;
2909
2910                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2911                         dist = self.prevorigin - self.origin;
2912                         dist_z = 0;
2913                         self.lms_traveled_distance += fabs(vlen(dist));
2914
2915                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2916                         {
2917                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2918                                 self.lms_traveled_distance = 0;
2919                         }
2920
2921                         if(time > self.lms_nextcheck)
2922                         {
2923                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2924                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2925                                 {
2926                                         centerprint(self, autocvar_g_lms_campcheck_message);
2927                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2928                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2929                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2930                                 }
2931                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2932                                 self.lms_traveled_distance = 0;
2933                         }
2934                 }
2935
2936                 self.prevorigin = self.origin;
2937
2938                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2939                 {
2940                         if (!self.crouch)
2941                         {
2942                                 self.crouch = TRUE;
2943                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2944                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2945                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2946                         }
2947                 }
2948                 else
2949                 {
2950                         if (self.crouch)
2951                         {
2952                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2953                                 if (!trace_startsolid)
2954                                 {
2955                                         self.crouch = FALSE;
2956                                         self.view_ofs = PL_VIEW_OFS;
2957                                         setsize (self, PL_MIN, PL_MAX);
2958                                 }
2959                         }
2960                 }
2961
2962                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2963                 {
2964                         if(self.bloodloss_timer < time)
2965                         {
2966                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2967                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2968                         }
2969                 }
2970
2971                 FixPlayermodel();
2972
2973                 GrapplingHookFrame();
2974
2975                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2976                 //if(frametime)
2977                 {
2978                         self.items &~= self.items_added;
2979
2980                         W_WeaponFrame();
2981
2982                         self.items_added = 0;
2983                         if(self.items & IT_JETPACK)
2984                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2985                                         self.items_added |= IT_FUEL;
2986
2987                         self.items |= self.items_added;
2988                 }
2989
2990                 player_regen();
2991
2992                 // rot nex charge to the charge limit
2993                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2994                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2995
2996                 if(frametime)
2997                         player_anim();
2998
2999                 if(g_ctf)
3000                         ctf_setstatus();
3001
3002                 if(g_nexball)
3003                         nexball_setstatus();
3004
3005                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3006
3007                 //self.angles_y=self.v_angle_y + 90;   // temp
3008         } else if(gameover) {
3009                 if (intermission_running)
3010                         IntermissionThink ();   // otherwise a button could be missed between
3011                 return;
3012         } else if(self.classname == "observer") {
3013                 ObserverThink();
3014         } else if(self.classname == "spectator") {
3015                 SpectatorThink();
3016         }
3017
3018         if(!zoomstate_set)
3019                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3020
3021         float oldspectatee_status;
3022         oldspectatee_status = self.spectatee_status;
3023         if(self.classname == "spectator")
3024                 self.spectatee_status = num_for_edict(self.enemy);
3025         else if(self.classname == "observer")
3026                 self.spectatee_status = num_for_edict(self);
3027         else
3028                 self.spectatee_status = 0;
3029         if(self.spectatee_status != oldspectatee_status)
3030         {
3031                 ClientData_Touch(self);
3032                 if(g_race || g_cts)
3033                         race_InitSpectator();
3034         }
3035
3036         if(self.teamkill_soundtime)
3037         if(time > self.teamkill_soundtime)
3038         {
3039                 self.teamkill_soundtime = 0;
3040
3041                 entity oldpusher, oldself;
3042
3043                 oldself = self; self = self.teamkill_soundsource;
3044                 oldpusher = self.pusher; self.pusher = oldself;
3045
3046                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3047
3048                 self.pusher = oldpusher;
3049                 self = oldself;
3050         }
3051
3052         if(self.taunt_soundtime)
3053         if(time > self.taunt_soundtime)
3054         {
3055                 self.taunt_soundtime = 0;
3056                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3057         }
3058
3059         target_voicescript_next(self);
3060
3061         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3062         if(!self.weapon)
3063                 self.clip_load = self.clip_size = 0;
3064 }
3065
3066 float isInvisibleString(string s)
3067 {
3068         float i, n, c;
3069         s = strdecolorize(s);
3070         for((i = 0), (n = strlen(s)); i < n; ++i)
3071         {
3072                 c = str2chr(s, i);
3073                 switch(c)
3074                 {
3075                         case 0:
3076                         case 32: // space
3077                                 break;
3078                         case 192: // charmap space
3079                                 if (!autocvar_utf8_enable)
3080                                         break;
3081                                 return FALSE;
3082                         case 160: // space in unicode fonts
3083                         case 0xE000 + 192: // utf8 charmap space
3084                                 if (autocvar_utf8_enable)
3085                                         break;
3086                         default:
3087                                 return FALSE;
3088                 }
3089         }
3090         return TRUE;
3091 }
3092
3093 /*
3094 =============
3095 PlayerPostThink
3096
3097 Called every frame for each client after the physics are run
3098 =============
3099 */
3100 .float idlekick_lasttimeleft;
3101 .entity showheadshotbbox;
3102 void showheadshotbbox_think()
3103 {
3104         if(self.owner.showheadshotbbox != self)
3105         {
3106                 remove(self);
3107                 return;
3108         }
3109         self.nextthink = time;
3110         setorigin(self, self.owner.origin);
3111         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3112 }
3113 void PlayerPostThink (void)
3114 {
3115         // Savage: Check for nameless players
3116         if (isInvisibleString(self.netname)) {
3117                 self.netname = "Player";
3118                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3119         }
3120
3121         if(sv_maxidle && frametime)
3122         {
3123                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3124                 float timeleft;
3125                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
3126                 {
3127                         if(self.idlekick_lasttimeleft)
3128                         {
3129                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
3130                                 self.idlekick_lasttimeleft = 0;
3131                         }
3132                         return;
3133                 }
3134                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3135                 if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
3136                 {
3137                         if(!self.idlekick_lasttimeleft)
3138                                 Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
3139                 }
3140                 if(timeleft <= 0)
3141                 {
3142                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3143                         AnnounceTo(self, "terminated");
3144                         dropclient(self);
3145                         return;
3146                 }
3147                 else if(timeleft <= 10)
3148                 {
3149                         if(timeleft != self.idlekick_lasttimeleft)
3150                                 AnnounceTo(self, ftos(timeleft));
3151                         self.idlekick_lasttimeleft = timeleft;
3152                 }
3153         }
3154
3155 #ifdef TETRIS
3156         if(self.impulse == 100)
3157                 ImpulseCommands();
3158         if (TetrisPostFrame())
3159                 return;
3160 #endif
3161
3162         CheatFrame();
3163
3164         CheckPlayerJump();
3165
3166         if(self.classname == "player") {
3167                 CheckRules_Player();
3168                 UpdateChatBubble();
3169                 if (self.impulse)
3170                         ImpulseCommands();
3171                 if (intermission_running)
3172                         return;         // intermission or finale
3173                 GetPressedKeys();
3174         } else if (self.classname == "observer") {
3175                 //do nothing
3176         } else if (self.classname == "spectator") {
3177                 //do nothing
3178         }
3179
3180         /*
3181         float i;
3182         for(i = 0; i < 1000; ++i)
3183         {
3184                 vector end;
3185                 end = self.origin + '0 0 1024' + 512 * randomvec();
3186                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3187                 if(trace_fraction < 1)
3188                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3189                 {
3190                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3191                         break;
3192                 }
3193         }
3194         */
3195
3196         Arena_Warmup();
3197
3198         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3199
3200         if(self.waypointsprite_attachedforcarrier)
3201                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3202
3203         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3204         {
3205                 if(!self.showheadshotbbox)
3206                 {
3207                         self.showheadshotbbox = spawn();
3208                         self.showheadshotbbox.classname = "headshotbbox";
3209                         self.showheadshotbbox.owner = self;
3210                         self.showheadshotbbox.think = showheadshotbbox_think;
3211                         self.showheadshotbbox.nextthink = time;
3212                         self = self.showheadshotbbox;
3213                         self.think();
3214                         self = self.owner;
3215                 }
3216         }
3217         else
3218         {
3219                 if(self.showheadshotbbox)
3220                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3221                 remove(self.showheadshotbbox);
3222         }
3223
3224         playerdemo_write();
3225
3226         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3227         {
3228                 if(!self.stored_netname)
3229                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3230                 if(self.stored_netname != self.netname)
3231                 {
3232                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3233                         strunzone(self.stored_netname);
3234                         self.stored_netname = strzone(self.netname);
3235                 }
3236         }
3237
3238         /*
3239         if(g_race)
3240                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3241         */
3242 }