Merge remote branch 'origin/master' into fruitiex/gamemode_freezetag
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(cvar("spawn_debugview"))
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > cvar("g_spawn_furthest"))
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(cvar("spawn_debugview"))
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(cvar("spawn_debug"))
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(cvar("sv_servermodelsonly"))
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602         MUTATOR_CALLHOOK(MakePlayerObserver);
603
604         Portal_ClearAll(self);
605
606         if(self.alivetime)
607         {
608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
609                 self.alivetime = 0;
610         }
611
612         if(self.flagcarried)
613                 DropFlag(self.flagcarried, world, world);
614
615         if(self.ballcarried)
616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
617
618         WaypointSprite_PlayerDead();
619
620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
622
623         if(self.killcount != -666) {
624                 if(g_lms) {
625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
627                         else
628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
629                 } else
630                         bprint ("^4", self.netname, "^4 is spectating now\n");
631
632                 if(self.just_joined == FALSE) {
633                         LogTeamchange(self.playerid, -1, 4);
634                 } else
635                         self.just_joined = FALSE;
636         }
637
638         PlayerScore_Clear(self); // clear scores when needed
639
640         accuracy_resend(self);
641
642         self.spectatortime = time;
643
644         self.classname = "observer";
645         self.iscreature = FALSE;
646         self.health = -666;
647         self.takedamage = DAMAGE_NO;
648         self.solid = SOLID_NOT;
649         self.movetype = MOVETYPE_NOCLIP;
650         self.flags = FL_CLIENT | FL_NOTARGET;
651         self.armorvalue = 666;
652         self.effects = 0;
653         self.armorvalue = cvar("g_balance_armor_start");
654         self.pauserotarmor_finished = 0;
655         self.pauserothealth_finished = 0;
656         self.pauseregen_finished = 0;
657         self.damageforcescale = 0;
658         self.death_time = 0;
659         self.dead_frame = 0;
660         self.alpha = 0;
661         self.scale = 0;
662         self.fade_time = 0;
663         self.pain_frame = 0;
664         self.pain_finished = 0;
665         self.strength_finished = 0;
666         self.invincible_finished = 0;
667         self.pushltime = 0;
668         self.think = SUB_Null;
669         self.nextthink = 0;
670         self.hook_time = 0;
671         self.runes = 0;
672         self.deadflag = DEAD_NO;
673         self.angles = spot.angles;
674         self.angles_z = 0;
675         self.fixangle = TRUE;
676         self.crouch = FALSE;
677
678         self.view_ofs = PL_VIEW_OFS;
679         setorigin (self, spot.origin);
680         setsize (self, '0 0 0', '0 0 0');
681         self.prevorigin = self.origin;
682         self.items = 0;
683         self.weapons = 0;
684         self.model = "";
685         FixPlayermodel();
686         self.model = "";
687         self.modelindex = 0;
688         self.weapon = 0;
689         self.weaponmodel = "";
690         self.weaponentity = world;
691         self.exteriorweaponentity = world;
692         self.killcount = -666;
693         self.velocity = '0 0 0';
694         self.avelocity = '0 0 0';
695         self.punchangle = '0 0 0';
696         self.punchvector = '0 0 0';
697         self.oldvelocity = self.velocity;
698         self.fire_endtime = -1;
699
700         if(sv_loddistance1)
701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
702
703         if(g_arena)
704         {
705                 if(self.version_mismatch)
706                 {
707                         Spawnqueue_Unmark(self);
708                         Spawnqueue_Remove(self);
709                 }
710                 else
711                 {
712                         Spawnqueue_Insert(self);
713                 }
714         }
715         else if(g_lms)
716         {
717                 // Only if the player cannot play at all
718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
719                         self.frags = FRAGS_SPECTATOR;
720                 else
721                         self.frags = FRAGS_LMS_LOSER;
722         }
723         else
724                 self.frags = FRAGS_SPECTATOR;
725 }
726
727 float RestrictSkin(float s)
728 {
729         if(!teams_matter)
730                 return s;
731         if(s == 6)
732                 return 6;
733         return mod(s, 3);
734 }
735
736 void FixPlayermodel()
737 {
738         local string defaultmodel;
739         local float defaultskin, chmdl, oldskin;
740         local vector m1, m2;
741
742         defaultmodel = "";
743
744         if(cvar("sv_defaultcharacter") == 1) {
745                 defaultskin = 0;
746
747                 if(teams_matter)
748                 {
749                         string s;
750                         s = Team_ColorNameLowerCase(self.team);
751                         if(s != "neutral")
752                         {
753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
755                         }
756                 }
757
758                 if(defaultmodel == "")
759                 {
760                         defaultmodel = cvar_string("sv_defaultplayermodel");
761                         defaultskin = cvar("sv_defaultplayerskin");
762                 }
763         }
764
765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
766         {
767                 if(self.model != "")
768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
769                 self.model = ""; // force the != checks to return true
770         }
771
772         if(defaultmodel != "")
773         {
774                 if (defaultmodel != self.model)
775                 {
776                         m1 = self.mins;
777                         m2 = self.maxs;
778                         setmodel_lod (self, defaultmodel);
779                         setsize (self, m1, m2);
780                         chmdl = TRUE;
781                 }
782
783                 oldskin = self.skinindex;
784                 self.skinindex = defaultskin;
785         } else {
786                 if (self.playermodel != self.model || self.playermodel == "")
787                 {
788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
789                         m1 = self.mins;
790                         m2 = self.maxs;
791                         setmodel_lod (self, self.playermodel);
792                         setsize (self, m1, m2);
793                         chmdl = TRUE;
794                 }
795
796                 oldskin = self.skinindex;
797                 self.skinindex = RestrictSkin(stof(self.playerskin));
798         }
799
800         if(chmdl || oldskin != self.skinindex)
801                 self.species = player_getspecies(); // model or skin has changed
802
803         if(!teams_matter)
804                 if(strlen(cvar_string("sv_defaultplayercolors")))
805                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
806                                 setcolor(self, cvar("sv_defaultplayercolors"));
807 }
808
809 void PlayerTouchExplode(entity p1, entity p2)
810 {
811         vector org;
812         org = (p1.origin + p2.origin) * 0.5;
813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
814
815         te_explosion(org);
816
817         entity e;
818         e = spawn();
819         setorigin(e, org);
820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
821         remove(e);
822 }
823
824 /*
825 =============
826 PutClientInServer
827
828 Called when a client spawns in the server
829 =============
830 */
831 //void() ctf_playerchanged;
832 void PutClientInServer (void)
833 {
834         if(clienttype(self) == CLIENTTYPE_BOT)
835         {
836                 self.classname = "player";
837         }
838         else if(clienttype(self) == CLIENTTYPE_REAL)
839         {
840                 msg_entity = self;
841                 WriteByte(MSG_ONE, SVC_SETVIEW);
842                 WriteEntity(MSG_ONE, self);
843         }
844
845         // player is dead and becomes observer
846         // FIXME fix LMS scoring for new system
847         if(g_lms)
848         {
849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
850                         self.classname = "observer";
851         }
852
853         if(g_arena || (g_ca && !allowed_to_spawn))
854         if(!self.spawned)
855                 self.classname = "observer";
856
857         if(gameover)
858                 self.classname = "observer";
859
860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
861                 entity spot, oldself;
862                 float j;
863
864                 accuracy_resend(self);
865
866                 if(self.team < 0)
867                         JoinBestTeam(self, FALSE, TRUE);
868
869                 race_PreSpawn();
870
871                 spot = SelectSpawnPoint (FALSE);
872                 if(!spot)
873                 {
874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
875                         return; // spawn failed
876                 }
877
878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
879
880                 self.classname = "player";
881                 self.wasplayer = TRUE;
882                 self.iscreature = TRUE;
883                 self.movetype = MOVETYPE_WALK;
884                 self.solid = SOLID_SLIDEBOX;
885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
886                 if(cvar("g_playerclip_collisions"))
887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
888                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
890                 self.frags = FRAGS_PLAYER;
891                 if(independent_players)
892                         MAKE_INDEPENDENT_PLAYER(self);
893                 self.flags = FL_CLIENT;
894                 self.takedamage = DAMAGE_AIM;
895                 if(g_minstagib)
896                         self.effects = EF_FULLBRIGHT;
897                 else
898                         self.effects = 0;
899                 self.air_finished = time + 12;
900                 self.dmg = 2;
901                 if(cvar("g_balance_nex_charge"))
902                 {
903                         if(cvar("g_balance_nex_secondary_charge_pool"))
904                                 self.nex_charge_pool_ammo = 1;
905                         self.nex_charge = cvar("g_balance_nex_charge_start");
906                 }
907
908                 if(inWarmupStage)
909                 {
910                         self.ammo_shells = warmup_start_ammo_shells;
911                         self.ammo_nails = warmup_start_ammo_nails;
912                         self.ammo_rockets = warmup_start_ammo_rockets;
913                         self.ammo_cells = warmup_start_ammo_cells;
914                         self.ammo_fuel = warmup_start_ammo_fuel;
915                         self.health = warmup_start_health;
916                         self.armorvalue = warmup_start_armorvalue;
917                         self.weapons = warmup_start_weapons;
918                 }
919                 else
920                 {
921                         self.ammo_shells = start_ammo_shells;
922                         self.ammo_nails = start_ammo_nails;
923                         self.ammo_rockets = start_ammo_rockets;
924                         self.ammo_cells = start_ammo_cells;
925                         self.ammo_fuel = start_ammo_fuel;
926                         self.health = start_health;
927                         self.armorvalue = start_armorvalue;
928                         self.weapons = start_weapons;
929                 }
930
931                 if(g_weaponarena_random)
932                 {
933                         if(g_weaponarena_random_with_laser)
934                                 self.weapons &~= WEPBIT_LASER;
935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
936                         if(g_weaponarena_random_with_laser)
937                                 self.weapons |= WEPBIT_LASER;
938                 }
939
940                 self.items = start_items;
941                 self.jump_interval = time;
942
943                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
944                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
945                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
946                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
947                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
948                 //extend the pause of rotting if client was reset at the beginning of the countdown
949                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
950                         self.spawnshieldtime += game_starttime - time;
951                         self.pauserotarmor_finished += game_starttime - time;
952                         self.pauserothealth_finished += game_starttime - time;
953                         self.pauseregen_finished += game_starttime - time;
954                 }
955                 self.damageforcescale = 2;
956                 self.death_time = 0;
957                 self.dead_frame = 0;
958                 self.alpha = 0;
959                 self.scale = 0;
960                 self.fade_time = 0;
961                 self.pain_frame = 0;
962                 self.pain_finished = 0;
963                 self.strength_finished = 0;
964                 self.invincible_finished = 0;
965                 self.pushltime = 0;
966                 // players have no think function
967                 self.think = SUB_Null;
968                 self.nextthink = 0;
969                 self.hook_time = 0;
970                 self.dmg_team = 0;
971                 self.ballistics_density = cvar("g_ballistics_density_player");
972
973                 self.metertime = 0;
974
975                 self.runes = 0;
976
977                 self.deadflag = DEAD_NO;
978
979                 self.angles = spot.angles;
980
981                 self.angles_z = 0; // never spawn tilted even if the spot says to
982                 self.fixangle = TRUE; // turn this way immediately
983                 self.velocity = '0 0 0';
984                 self.avelocity = '0 0 0';
985                 self.punchangle = '0 0 0';
986                 self.punchvector = '0 0 0';
987                 self.oldvelocity = self.velocity;
988                 self.fire_endtime = -1;
989
990                 msg_entity = self;
991                 WRITESPECTATABLE_MSG_ONE({
992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
994                 });
995
996                 if(sv_loddistance1)
997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
998
999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(cvar("spawn_debug"))
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (cvar("g_spawnsound"))
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != cvar("g_balance_armor_blockpercent"))
1133         {
1134                 self.count = cvar("g_balance_armor_blockpercent");
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1138         {
1139                 self.cnt = cvar("g_balance_weaponswitchdelay");
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1143         {
1144                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1148         {
1149                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1153         {
1154                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1158         {
1159                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else
1233                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1234 }
1235
1236 void ClientKill_Now()
1237 {
1238         if(self.killindicator_teamchange)
1239                 ClientKill_Now_TeamChange();
1240
1241         // in any case:
1242         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1243
1244         if(self.killindicator)
1245         {
1246                 dprint("Cleaned up after a leaked kill indicator.\n");
1247                 remove(self.killindicator);
1248                 self.killindicator = world;
1249         }
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266         else
1267         {
1268                 if(self.cnt <= 10)
1269                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1270                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1271                 {
1272                         if(self.cnt <= 10)
1273                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1274                         if(self.owner.killindicator_teamchange)
1275                         {
1276                                 if(self.owner.killindicator_teamchange == -1)
1277                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1278                                 else
1279                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1280                         }
1281                         else
1282                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1283                 }
1284                 self.nextthink = time + 1;
1285                 self.cnt -= 1;
1286         }
1287 }
1288
1289 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1290 {
1291         float killtime;
1292         entity e;
1293         killtime = cvar("g_balance_kill_delay");
1294
1295         if(g_race_qualifying)
1296                 killtime = 0;
1297
1298         self.killindicator_teamchange = targetteam;
1299
1300         if(!self.killindicator)
1301         {
1302                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1303                 {
1304                         ClientKill_Now();
1305                 }
1306                 else
1307                 {
1308                         self.killindicator = spawn();
1309                         self.killindicator.owner = self;
1310                         self.killindicator.scale = 0.5;
1311                         setattachment(self.killindicator, self, "");
1312                         setorigin(self.killindicator, '0 0 52');
1313                         self.killindicator.think = KillIndicator_Think;
1314                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1315                         self.killindicator.cnt = ceil(killtime);
1316                         self.killindicator.count = bound(0, ceil(killtime), 10);
1317                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1318
1319                         for(e = world; (e = find(e, classname, "body")) != world; )
1320                         {
1321                                 if(e.enemy != self)
1322                                         continue;
1323                                 e.killindicator = spawn();
1324                                 e.killindicator.owner = e;
1325                                 e.killindicator.scale = 0.5;
1326                                 setattachment(e.killindicator, e, "");
1327                                 setorigin(e.killindicator, '0 0 52');
1328                                 e.killindicator.think = KillIndicator_Think;
1329                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1330                                 e.killindicator.cnt = ceil(killtime);
1331                         }
1332                         self.lip = 0;
1333                 }
1334         }
1335         if(self.killindicator)
1336         {
1337                 if(targetteam)
1338                         self.killindicator.colormod = TeamColor(targetteam);
1339                 else
1340                         self.killindicator.colormod = '0 0 0';
1341         }
1342 }
1343
1344 void ClientKill (void)
1345 {
1346         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1347         {
1348                 // do nothing
1349         }
1350     else if(g_freezetag && self.freezetag_frozen == 1)
1351     {
1352         // do nothing
1353     }
1354         else
1355                 ClientKill_TeamChange(0);
1356 }
1357
1358 void CTS_ClientKill_Think (void)
1359 {
1360         self = self.owner; // set self to the player to be killed
1361         sprint(self, "^1You were killed in order to prevent cheating!");
1362         ClientKill_Now();
1363 }
1364
1365 void CTS_ClientKill (float t) // silent version of ClientKill
1366 {
1367         entity e;
1368         e = spawn();
1369         e.owner = self;
1370         e.think = CTS_ClientKill_Think;
1371         e.nextthink = t;
1372 }
1373
1374 void DoTeamChange(float destteam)
1375 {
1376         float t, c0;
1377         if(!teams_matter)
1378         {
1379                 if(destteam >= 0)
1380                         SetPlayerColors(self, destteam);
1381                 return;
1382         }
1383         if(self.classname == "player")
1384         if(destteam == -1)
1385         {
1386                 CheckAllowedTeams(self);
1387                 t = FindSmallestTeam(self, TRUE);
1388                 switch(self.team)
1389                 {
1390                         case COLOR_TEAM1: c0 = c1; break;
1391                         case COLOR_TEAM2: c0 = c2; break;
1392                         case COLOR_TEAM3: c0 = c3; break;
1393                         case COLOR_TEAM4: c0 = c4; break;
1394                         default:          c0 = 999;
1395                 }
1396                 switch(t)
1397                 {
1398                         case 1:
1399                                 if(c0 > c1)
1400                                         destteam = COLOR_TEAM1;
1401                                 break;
1402                         case 2:
1403                                 if(c0 > c2)
1404                                         destteam = COLOR_TEAM2;
1405                                 break;
1406                         case 3:
1407                                 if(c0 > c3)
1408                                         destteam = COLOR_TEAM3;
1409                                 break;
1410                         case 4:
1411                                 if(c0 > c4)
1412                                         destteam = COLOR_TEAM4;
1413                                 break;
1414                 }
1415                 if(destteam == -1)
1416                         return;
1417         }
1418         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1419                 return;
1420         ClientKill_TeamChange(destteam);
1421 }
1422
1423 void FixClientCvars(entity e)
1424 {
1425         // send prediction settings to the client
1426         stuffcmd(e, "\nin_bindmap 0 0\n");
1427         if(g_race || g_cts)
1428                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1429         if(cvar("g_antilag") == 3) // client side hitscan
1430                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1431         if(sv_gentle)
1432                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1433         /*
1434          * we no longer need to stuff this. Remove this comment block if you feel
1435          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1436         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1437         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1438         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1439         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1440         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1441         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1442         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1443         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1444         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1445         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1446         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1447         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1448         stuffcmd(e, "cl_movement_edgefriction 1\n");
1449          */
1450 }
1451
1452 float PlayerInIDList(entity p, string idlist)
1453 {
1454         float n, i;
1455         string s;
1456
1457         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1458         if not(p.crypto_idfp)
1459                 return 0;
1460
1461         // this function allows abbreviated player IDs too!
1462         n = tokenize_console(idlist);
1463         for(i = 0; i < n; ++i)
1464         {
1465                 s = argv(i);
1466                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1467                         return 1;
1468         }
1469
1470         return 0;
1471 }
1472
1473 /*
1474 =============
1475 ClientConnect
1476
1477 Called when a client connects to the server
1478 =============
1479 */
1480 //void ctf_clientconnect();
1481 string ColoredTeamName(float t);
1482 void DecodeLevelParms (void);
1483 //void dom_player_join_team(entity pl);
1484 void ClientConnect (void)
1485 {
1486         float t;
1487
1488         if(self.flags & FL_CLIENT)
1489         {
1490                 print("Warning: ClientConnect, but already connected!\n");
1491                 return;
1492         }
1493
1494         if(Ban_MaybeEnforceBan(self))
1495                 return;
1496
1497         DecodeLevelParms();
1498
1499 #ifdef WATERMARK
1500         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1501 #endif
1502
1503         self.classname = "player_joining";
1504
1505         self.flags = FL_CLIENT;
1506         self.version_nagtime = time + 10 + random() * 10;
1507
1508         if(player_count<0)
1509         {
1510                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1511                 player_count = 0;
1512         }
1513
1514         PlayerScore_Attach(self);
1515         ClientData_Attach();
1516         accuracy_init(self);
1517
1518         bot_clientconnect();
1519
1520         playerdemo_init();
1521
1522         anticheat_init();
1523         
1524         race_PreSpawnObserver();
1525
1526         //if(g_domination)
1527         //      dom_player_join_team(self);
1528
1529         // identify the right forced team
1530         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1531                 self.team_forced = COLOR_TEAM1;
1532         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1533                 self.team_forced = COLOR_TEAM2;
1534         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1535                 self.team_forced = COLOR_TEAM3;
1536         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1537                 self.team_forced = COLOR_TEAM4;
1538         else if(cvar_string("g_forced_team_otherwise") == "red")
1539                 self.team_forced = COLOR_TEAM1;
1540         else if(cvar_string("g_forced_team_otherwise") == "blue")
1541                 self.team_forced = COLOR_TEAM2;
1542         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1543                 self.team_forced = COLOR_TEAM3;
1544         else if(cvar_string("g_forced_team_otherwise") == "pink")
1545                 self.team_forced = COLOR_TEAM4;
1546         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1547                 self.team_forced = -1;
1548         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1549                 self.team_forced = -1;
1550         else
1551                 self.team_forced = 0;
1552
1553         if(!teams_matter)
1554                 if(self.team_forced > 0)
1555                         self.team_forced = 0;
1556
1557         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1558
1559         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1560                 self.classname = "observer";
1561         } else {
1562                 if(teams_matter)
1563                 {
1564                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1565                         {
1566                                 self.classname = "player";
1567                                 campaign_bots_may_start = 1;
1568                         }
1569                         else
1570                         {
1571                                 self.classname = "observer"; // do it anyway
1572                         }
1573                 }
1574                 else
1575                 {
1576                         self.classname = "player";
1577                         campaign_bots_may_start = 1;
1578                 }
1579         }
1580
1581         self.playerid = (playerid_last = playerid_last + 1);
1582
1583         if(cvar("sv_eventlog"))
1584                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1585
1586         LogTeamchange(self.playerid, self.team, 1);
1587
1588         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1589
1590         self.netname_previous = strzone(self.netname);
1591
1592         bprint("^4", self.netname, "^4 connected");
1593
1594         if(self.classname != "observer" && (g_domination || g_ctf))
1595                 bprint(" and joined the ", ColoredTeamName(self.team));
1596
1597         bprint("\n");
1598
1599         self.welcomemessage_time = 0;
1600
1601         stuffcmd(self, strcat(clientstuff, "\n"));
1602         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1603         stuffcmd(self, "cl_particles_reloadeffects\n");
1604
1605         FixClientCvars(self);
1606
1607         // spawnfunc_waypoint sprites
1608         WaypointSprite_InitClient(self);
1609
1610         // Wazat's grappling hook
1611         SetGrappleHookBindings();
1612
1613         // get autoswitch state from player when he toggles it
1614         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1615
1616         // get version info from player
1617         stuffcmd(self, "cmd clientversion $gameversion\n");
1618
1619         // get other cvars from player
1620         GetCvars(0);
1621
1622         // set cvar for team scoreboard
1623         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1624
1625         // notify about available teams
1626         if(teams_matter)
1627         {
1628                 CheckAllowedTeams(self);
1629                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1630                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1631         }
1632         else
1633                 stuffcmd(self, "set _teams_available 0\n");
1634
1635         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1636
1637         if(g_arena || g_ca)
1638         {
1639                 self.classname = "observer";
1640                 if(g_arena)
1641                         Spawnqueue_Insert(self);
1642         }
1643         /*else if(g_ctf)
1644         {
1645                 ctf_clientconnect();
1646         }*/
1647
1648         if(teams_matter || radar_showennemies)
1649                 attach_entcs();
1650
1651         bot_relinkplayerlist();
1652
1653         self.spectatortime = time;
1654         if(blockSpectators)
1655         {
1656                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1657         }
1658
1659         self.jointime = time;
1660         self.allowedTimeouts = cvar("sv_timeout_number");
1661
1662         if(clienttype(self) == CLIENTTYPE_REAL)
1663         {
1664                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1665                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1666         }
1667
1668         if(g_lms)
1669         {
1670                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1671                 {
1672                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1673                         self.frags = FRAGS_SPECTATOR;
1674                 }
1675         }
1676
1677         if(!sv_foginterval && world.fog != "")
1678                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1679
1680         SoundEntity_Attach(self);
1681
1682         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1683         {
1684                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1685                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1686         }
1687         else
1688                 self.hitplotfh = -1;
1689
1690         if(g_race || g_cts) {
1691                 string rr;
1692                 if(g_cts)
1693                         rr = CTS_RECORD;
1694                 else
1695                         rr = RACE_RECORD;
1696                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1697
1698                 msg_entity = self;
1699                 race_send_recordtime(MSG_ONE);
1700                 race_send_speedaward(MSG_ONE);
1701
1702                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1703                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1704                 race_send_speedaward_alltimebest(MSG_ONE);
1705
1706                 float i;
1707                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1708                         race_SendRankings(i, 0, 0, MSG_ONE);
1709                 }
1710         }
1711         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1712                 send_CSQC_teamnagger();
1713
1714         send_CSQC_cr_maxbullets(self);
1715
1716         CheatInitClient();
1717
1718         PlayerStats_AddPlayer(self);
1719 }
1720
1721 /*
1722 =============
1723 ClientDisconnect
1724
1725 Called when a client disconnects from the server
1726 =============
1727 */
1728 .entity chatbubbleentity;
1729 .entity teambubbleentity;
1730 void ReadyCount();
1731 void ClientDisconnect (void)
1732 {
1733         if not(self.flags & FL_CLIENT)
1734         {
1735                 print("Warning: ClientDisconnect without ClientConnect\n");
1736                 return;
1737         }
1738
1739         PlayerStats_AddGlobalInfo(self);
1740
1741         CheatShutdownClient();
1742
1743         if(self.hitplotfh >= 0)
1744         {
1745                 fclose(self.hitplotfh);
1746                 self.hitplotfh = -1;
1747         }
1748
1749         anticheat_report();
1750         anticheat_shutdown();
1751
1752         playerdemo_shutdown();
1753
1754         bot_clientdisconnect();
1755
1756         if(self.entcs)
1757                 detach_entcs();
1758
1759         if(cvar("sv_eventlog"))
1760                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1761         bprint ("^4",self.netname);
1762         bprint ("^4 disconnected\n");
1763
1764         SoundEntity_Detach(self);
1765
1766         DropAllRunes(self);
1767         MUTATOR_CALLHOOK(ClientDisconnect);
1768
1769         Portal_ClearAll(self);
1770
1771         if(self.flagcarried)
1772                 DropFlag(self.flagcarried, world, world);
1773         if(self.ballcarried)
1774                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1775
1776         // Here, everything has been done that requires this player to be a client.
1777
1778         self.flags &~= FL_CLIENT;
1779
1780         if (self.chatbubbleentity)
1781                 remove (self.chatbubbleentity);
1782
1783         if (self.teambubbleentity)
1784                 remove (self.teambubbleentity);
1785
1786         if (self.killindicator)
1787                 remove (self.killindicator);
1788
1789         WaypointSprite_PlayerGone();
1790
1791         bot_relinkplayerlist();
1792
1793         if(g_arena)
1794         {
1795                 Spawnqueue_Unmark(self);
1796                 Spawnqueue_Remove(self);
1797         }
1798
1799         accuracy_free(self);
1800         ClientData_Detach();
1801         PlayerScore_Detach(self);
1802
1803         if(self.netname_previous)
1804                 strunzone(self.netname_previous);
1805         if(self.clientstatus)
1806                 strunzone(self.clientstatus);
1807         if(self.weaponorder_byimpulse)
1808                 strunzone(self.weaponorder_byimpulse);
1809
1810         ClearPlayerSounds();
1811
1812         if(self.personal)
1813                 remove(self.personal);
1814
1815         self.playerid = 0;
1816         ReadyCount();
1817
1818         // free cvars
1819         GetCvars(-1);
1820 }
1821
1822 .float BUTTON_CHAT;
1823 void ChatBubbleThink()
1824 {
1825         self.nextthink = time;
1826         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1827         {
1828                 if(self.owner) // but why can that ever be world?
1829                         self.owner.chatbubbleentity = world;
1830                 remove(self);
1831                 return;
1832         }
1833         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1834 #ifdef TETRIS
1835                 || self.owner.tetris_on
1836 #endif
1837         )
1838                 self.model = self.mdl;
1839         else
1840                 self.model = "";
1841 };
1842
1843 void UpdateChatBubble()
1844 {
1845         if (!self.modelindex)
1846                 return;
1847         // spawn a chatbubble entity if needed
1848         if (!self.chatbubbleentity)
1849         {
1850                 self.chatbubbleentity = spawn();
1851                 self.chatbubbleentity.owner = self;
1852                 self.chatbubbleentity.exteriormodeltoclient = self;
1853                 self.chatbubbleentity.think = ChatBubbleThink;
1854                 self.chatbubbleentity.nextthink = time;
1855                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1856                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1857                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1858                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1859                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1860                 self.chatbubbleentity.model = "";
1861                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1862         }
1863 }
1864
1865
1866 void TeamBubbleThink()
1867 {
1868         self.nextthink = time;
1869         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1870         {
1871                 if(self.owner) // but why can that ever be world?
1872                         self.owner.teambubbleentity = world;
1873                 remove(self);
1874                 return;
1875         }
1876 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1877         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1878                 self.model = "";
1879         else
1880                 self.model = self.mdl;
1881
1882 };
1883
1884 float TeamBubble_customizeentityforclient()
1885 {
1886         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1887 }
1888
1889 void UpdateTeamBubble()
1890 {
1891         if (!self.modelindex || !teams_matter)
1892                 return;
1893         // spawn a teambubble entity if needed
1894         if (!self.teambubbleentity && teams_matter)
1895         {
1896                 self.teambubbleentity = spawn();
1897                 self.teambubbleentity.owner = self;
1898                 self.teambubbleentity.exteriormodeltoclient = self;
1899                 self.teambubbleentity.think = TeamBubbleThink;
1900                 self.teambubbleentity.nextthink = time;
1901                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1902 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1903                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1904                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1905                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1906                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1907                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1908                 self.teambubbleentity.effects = EF_LOWPRECISION;
1909         }
1910 }
1911
1912 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1913 // added to the model skins
1914 /*void UpdateColorModHack()
1915 {
1916         local float c;
1917         c = self.clientcolors & 15;
1918         // LordHavoc: only bothering to support white, green, red, yellow, blue
1919              if (!teams_matter) self.colormod = '0 0 0';
1920         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1921         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1922         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1923         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1924         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1925         else self.colormod = '1 1 1';
1926 };*/
1927
1928 .float oldcolormap;
1929 void respawn(void)
1930 {
1931         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1932         {
1933                 self.solid = SOLID_NOT;
1934                 self.takedamage = DAMAGE_NO;
1935                 self.movetype = MOVETYPE_FLY;
1936                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1937                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1938                 self.effects |= EF_ADDITIVE;
1939                 self.oldcolormap = self.colormap;
1940                 self.colormap = 512;
1941                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1942                 if(cvar("g_respawn_ghosts_maxtime"))
1943                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1944         }
1945
1946         CopyBody(1);
1947         self.effects |= EF_NODRAW; // prevent another CopyBody
1948         if(self.oldcolormap)
1949         {
1950                 self.colormap = self.oldcolormap;
1951                 self.oldcolormap = 0;
1952         }
1953         PutClientInServer();
1954 }
1955
1956 void play_countdown(float finished, string samp)
1957 {
1958         if(clienttype(self) == CLIENTTYPE_REAL)
1959                 if(floor(finished - time - frametime) != floor(finished - time))
1960                         if(finished - time < 6)
1961                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1962 }
1963
1964 /**
1965  * When sv_timeout is used this function returs strings like
1966  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1967  * Called by centerprint functions
1968  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1969  */
1970 string getTimeoutText(float addOneSecond) {
1971         if (!cvar("sv_timeout") || !timeoutStatus)
1972                 return "";
1973
1974         local string retStr;
1975         if (timeoutStatus == 1) {
1976                 if (addOneSecond == 1) {
1977                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1978                 }
1979                 else {
1980                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1981                 }
1982                 return retStr;
1983         }
1984         else if (timeoutStatus == 2) {
1985                 if (addOneSecond) {
1986                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1987                         //don't show messages like "Timeout ends in 0 seconds"...
1988                         if ((remainingTimeoutTime + 1) > 0)
1989                                 return retStr;
1990                         else
1991                                 return "";
1992                 }
1993                 else {
1994                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1995                         //don't show messages like "Timeout ends in 0 seconds"...
1996                         if (remainingTimeoutTime > 0)
1997                                 return retStr;
1998                         else
1999                                 return "";
2000                 }
2001         }
2002         else return "";
2003 }
2004
2005 void player_powerups (void)
2006 {
2007         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2008         {
2009                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
2010                 self.modelflags |= MF_ROCKET;
2011         }
2012         else
2013         {
2014                 SoundEntity_StopSound(self, CHAN_PLAYER);
2015                 self.modelflags &~= MF_ROCKET;
2016         }
2017
2018         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2019
2020         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2021                 return;
2022         
2023         Fire_ApplyDamage(self);
2024         Fire_ApplyEffect(self);
2025
2026         if (g_minstagib)
2027         {
2028                 self.effects |= EF_FULLBRIGHT;
2029
2030                 if (self.items & IT_STRENGTH)
2031                 {
2032                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2033                         if (time > self.strength_finished)
2034                         {
2035                                 self.alpha = default_player_alpha;
2036                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2037                                 self.items &~= IT_STRENGTH;
2038                                 sprint(self, "^3Invisibility has worn off\n");
2039                         }
2040                 }
2041                 else
2042                 {
2043                         if (time < self.strength_finished)
2044                         {
2045                                 self.alpha = g_minstagib_invis_alpha;
2046                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2047                                 self.items |= IT_STRENGTH;
2048                                 sprint(self, "^3You are invisible\n");
2049                         }
2050                 }
2051
2052                 if (self.items & IT_INVINCIBLE)
2053                 {
2054                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2055                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2056                         {
2057                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2058                                 sprint(self, "^3Speed has worn off\n");
2059                         }
2060                 }
2061                 else
2062                 {
2063                         if (time < self.invincible_finished)
2064                         {
2065                                 self.items = self.items | IT_INVINCIBLE;
2066                                 sprint(self, "^3You are on speed\n");
2067                         }
2068                 }
2069                 return;
2070         }
2071
2072         if (self.items & IT_STRENGTH)
2073         {
2074                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2075                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2076                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2077                 {
2078                         self.items = self.items - (self.items & IT_STRENGTH);
2079                         sprint(self, "^3Strength has worn off\n");
2080                 }
2081         }
2082         else
2083         {
2084                 if (time < self.strength_finished)
2085                 {
2086                         self.items = self.items | IT_STRENGTH;
2087                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2088                 }
2089         }
2090         if (self.items & IT_INVINCIBLE)
2091         {
2092                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2093                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2094                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2095                 {
2096                         self.items = self.items - (self.items & IT_INVINCIBLE);
2097                         sprint(self, "^3Shield has worn off\n");
2098                 }
2099         }
2100         else
2101         {
2102                 if (time < self.invincible_finished)
2103                 {
2104                         self.items = self.items | IT_INVINCIBLE;
2105                         sprint(self, "^3Shield surrounds you\n");
2106                 }
2107         }
2108
2109         if(cvar("g_nodepthtestplayers"))
2110                 self.effects = self.effects | EF_NODEPTHTEST;
2111
2112         if(cvar("g_fullbrightplayers"))
2113                 self.effects = self.effects | EF_FULLBRIGHT;
2114
2115         // midair gamemode: damage only while in the air
2116         // if in midair mode, being on ground grants temporary invulnerability
2117         // (this is so that multishot weapon don't clear the ground flag on the
2118         // first damage in the frame, leaving the player vulnerable to the
2119         // remaining hits in the same frame)
2120         if (self.flags & FL_ONGROUND)
2121         if (g_midair)
2122                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2123
2124         if (time >= game_starttime)
2125         if (time < self.spawnshieldtime)
2126                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2127 }
2128
2129 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2130 {
2131         if(current > stable)
2132                 return current;
2133         else if(current > stable - 0.25) // when close enough, "snap"
2134                 return stable;
2135         else
2136                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2137 }
2138
2139 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2140 {
2141         if(current < stable)
2142                 return current;
2143         else if(current < stable + 0.25) // when close enough, "snap"
2144                 return stable;
2145         else
2146                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2147 }
2148
2149 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2150 {
2151         if(current > rotstable)
2152         {
2153                 if(rotframetime > 0)
2154                 {
2155                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2156                         current = max(rotstable, current - rotlinear * rotframetime);
2157                 }
2158         }
2159         else if(current < regenstable)
2160         {
2161                 if(regenframetime > 0)
2162                 {
2163                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2164                         current = min(regenstable, current + regenlinear * regenframetime);
2165                 }
2166         }
2167
2168         if(current > limit)
2169                 current = limit;
2170
2171         return current;
2172 }
2173
2174 void player_regen (void)
2175 {
2176         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2177         maxh = cvar("g_balance_health_rotstable");
2178         maxa = cvar("g_balance_armor_rotstable");
2179         maxf = cvar("g_balance_fuel_rotstable");
2180         minh = cvar("g_balance_health_regenstable");
2181         mina = cvar("g_balance_armor_regenstable");
2182         minf = cvar("g_balance_fuel_regenstable");
2183         limith = cvar("g_balance_health_limit");
2184         limita = cvar("g_balance_armor_limit");
2185         limitf = cvar("g_balance_fuel_limit");
2186
2187         max_mod = regen_mod = rot_mod = limit_mod = 1;
2188
2189         if (self.runes & RUNE_REGEN)
2190         {
2191                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2192                 {
2193                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2194                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2195                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2196                 }
2197                 else
2198                 {
2199                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2200                         max_mod = cvar("g_balance_rune_regen_hpmod");
2201                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2202                 }
2203         }
2204         else if (self.runes & CURSE_VENOM)
2205         {
2206                 max_mod = cvar("g_balance_curse_venom_hpmod");
2207                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2208                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2209                 else
2210                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2211                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2212                 //if (!self.runes & RUNE_REGEN)
2213                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2214         }
2215         maxh = maxh * max_mod;
2216         //maxa = maxa * max_mod;
2217         //maxf = maxf * max_mod;
2218         minh = minh * max_mod;
2219         //mina = mina * max_mod;
2220         //minf = minf * max_mod;
2221         limith = limith * limit_mod;
2222         limita = limita * limit_mod;
2223         //limitf = limitf * limit_mod;
2224
2225         if(g_lms && g_ca)
2226                 rot_mod = 0;
2227
2228         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2229         {
2230                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2231                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2232
2233                 // if player rotted to death...  die!
2234                 if(self.health < 1)
2235                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2236         }
2237
2238         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2239                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2240 }
2241
2242 float zoomstate_set;
2243 void SetZoomState(float z)
2244 {
2245         if(z != self.zoomstate)
2246         {
2247                 self.zoomstate = z;
2248                 ClientData_Touch(self);
2249         }
2250         zoomstate_set = 1;
2251 }
2252
2253 void GetPressedKeys(void) {
2254         MUTATOR_CALLHOOK(GetPressedKeys);
2255         if (self.movement_x > 0) // get if movement keys are pressed
2256         {       // forward key pressed
2257                 self.pressedkeys |= KEY_FORWARD;
2258                 self.pressedkeys &~= KEY_BACKWARD;
2259         }
2260         else if (self.movement_x < 0)
2261         {       // backward key pressed
2262                 self.pressedkeys |= KEY_BACKWARD;
2263                 self.pressedkeys &~= KEY_FORWARD;
2264         }
2265         else
2266         {       // no x input
2267                 self.pressedkeys &~= KEY_FORWARD;
2268                 self.pressedkeys &~= KEY_BACKWARD;
2269         }
2270
2271         if (self.movement_y > 0)
2272         {       // right key pressed
2273                 self.pressedkeys |= KEY_RIGHT;
2274                 self.pressedkeys &~= KEY_LEFT;
2275         }
2276         else if (self.movement_y < 0)
2277         {       // left key pressed
2278                 self.pressedkeys |= KEY_LEFT;
2279                 self.pressedkeys &~= KEY_RIGHT;
2280         }
2281         else
2282         {       // no y input
2283                 self.pressedkeys &~= KEY_RIGHT;
2284                 self.pressedkeys &~= KEY_LEFT;
2285         }
2286
2287         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2288                 self.pressedkeys |= KEY_JUMP;
2289         else
2290                 self.pressedkeys &~= KEY_JUMP;
2291         if (self.BUTTON_CROUCH)
2292                 self.pressedkeys |= KEY_CROUCH;
2293         else
2294                 self.pressedkeys &~= KEY_CROUCH;
2295 }
2296
2297 /*
2298 ======================
2299 spectate mode routines
2300 ======================
2301 */
2302
2303 void SpectateCopy(entity spectatee) {
2304         other = spectatee;
2305         MUTATOR_CALLHOOK(SpectateCopy);
2306         self.armortype = spectatee.armortype;
2307         self.armorvalue = spectatee.armorvalue;
2308         self.ammo_cells = spectatee.ammo_cells;
2309         self.ammo_shells = spectatee.ammo_shells;
2310         self.ammo_nails = spectatee.ammo_nails;
2311         self.ammo_rockets = spectatee.ammo_rockets;
2312         self.ammo_fuel = spectatee.ammo_fuel;
2313         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2314         self.health = spectatee.health;
2315         self.impulse = 0;
2316         self.items = spectatee.items;
2317         self.last_pickup = spectatee.last_pickup;
2318         self.metertime = spectatee.metertime;
2319         self.strength_finished = spectatee.strength_finished;
2320         self.invincible_finished = spectatee.invincible_finished;
2321         self.pressedkeys = spectatee.pressedkeys;
2322         self.weapons = spectatee.weapons;
2323         self.switchweapon = spectatee.switchweapon;
2324         self.weapon = spectatee.weapon;
2325         self.punchangle = spectatee.punchangle;
2326         self.view_ofs = spectatee.view_ofs;
2327         self.v_angle = spectatee.v_angle;
2328         self.velocity = spectatee.velocity;
2329         self.dmg_take = spectatee.dmg_take;
2330         self.dmg_save = spectatee.dmg_save;
2331         self.dmg_inflictor = spectatee.dmg_inflictor;
2332         self.angles = spectatee.v_angle;
2333         self.fixangle = TRUE;
2334         setorigin(self, spectatee.origin);
2335         setsize(self, spectatee.mins, spectatee.maxs);
2336         SetZoomState(spectatee.zoomstate);
2337
2338         anticheat_spectatecopy(spectatee);
2339 }
2340
2341 float SpectateUpdate() {
2342         if(!self.enemy)
2343                 return 0;
2344
2345         if (self == self.enemy)
2346                 return 0;
2347
2348         if(self.enemy.classname != "player")
2349                 return 0;
2350
2351         SpectateCopy(self.enemy);
2352
2353         return 1;
2354 }
2355
2356 float SpectateNext() {
2357         other = find(self.enemy, classname, "player");
2358
2359         if (!other)
2360                 other = find(other, classname, "player");
2361
2362         if (other)
2363                 self.enemy = other;
2364
2365         if(self.enemy.classname == "player") {
2366                 msg_entity = self;
2367                 WriteByte(MSG_ONE, SVC_SETVIEW);
2368                 WriteEntity(MSG_ONE, self.enemy);
2369                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2370                 self.movetype = MOVETYPE_NONE;
2371                 accuracy_resend(self);
2372
2373                 if(!SpectateUpdate())
2374                         PutObserverInServer();
2375
2376                 return 1;
2377         } else {
2378                 return 0;
2379         }
2380 }
2381
2382 /*
2383 =============
2384 ShowRespawnCountdown()
2385
2386 Update a respawn countdown display.
2387 =============
2388 */
2389 void ShowRespawnCountdown()
2390 {
2391         float number;
2392         if(self.deadflag == DEAD_NO) // just respawned?
2393                 return;
2394         else
2395         {
2396                 number = ceil(self.death_time - time);
2397                 if(number <= 0)
2398                         return;
2399                 if(number <= self.respawn_countdown)
2400                 {
2401                         self.respawn_countdown = number - 1;
2402                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2403                                 AnnounceTo(self, strcat(ftos(number), ""));
2404                 }
2405         }
2406 }
2407
2408 void LeaveSpectatorMode()
2409 {
2410         if(isJoinAllowed()) {
2411                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2412                         self.classname = "player";
2413
2414                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2415                                 JoinBestTeam(self, FALSE, TRUE);
2416
2417                         if(cvar("g_campaign"))
2418                                 campaign_bots_may_start = 1;
2419
2420                         PutClientInServer();
2421
2422                         if(self.classname == "player")
2423                                 bprint ("^4", self.netname, "^4 is playing now\n");
2424
2425                         if(!cvar("g_campaign"))
2426                                 centerprint(self,""); // clear MOTD
2427
2428                         return;
2429                 } else {
2430                         if (g_ca && self.caplayer) {
2431                         }       // do nothing
2432                         else
2433                                 stuffcmd(self,"menu_showteamselect\n");
2434                         return;
2435                 }
2436         }
2437         else {
2438                 //player may not join because of g_maxplayers is set
2439                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2440         }
2441 }
2442
2443 /**
2444  * Determines whether the player is allowed to join. This depends on cvar
2445  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2446  * it checks whether the number of currently playing players exceeds g_maxplayers.
2447  * @return bool TRUE if the player is allowed to join, false otherwise
2448  */
2449 float isJoinAllowed() {
2450         if(self.team_forced < 0)
2451                 return FALSE; // forced spectators can never join
2452
2453         if (!cvar("g_maxplayers"))
2454                 return TRUE;
2455
2456         local entity e;
2457         local float currentlyPlaying;
2458         FOR_EACH_REALPLAYER(e) {
2459                 if(e.classname == "player")
2460                         currentlyPlaying += 1;
2461         }
2462         if(currentlyPlaying < cvar("g_maxplayers"))
2463                 return TRUE;
2464
2465         return FALSE;
2466 }
2467
2468 /**
2469  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2470  * g_maxplayers_spectator_blocktime seconds
2471  */
2472 void checkSpectatorBlock() {
2473         if(self.classname == "spectator" || self.classname == "observer") {
2474                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2475                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2476                         dropclient(self);
2477                 }
2478         }
2479 }
2480
2481 void ObserverThink()
2482 {
2483         if (self.flags & FL_JUMPRELEASED) {
2484                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2485                         self.welcomemessage_time = 0;
2486                         self.flags &~= FL_JUMPRELEASED;
2487                         self.flags |= FL_SPAWNING;
2488                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2489                         self.welcomemessage_time = 0;
2490                         self.flags &~= FL_JUMPRELEASED;
2491                         if(SpectateNext() == 1) {
2492                                 self.classname = "spectator";
2493                         }
2494                 }
2495         } else {
2496                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2497                         self.flags |= FL_JUMPRELEASED;
2498                         if(self.flags & FL_SPAWNING)
2499                         {
2500                                 self.flags &~= FL_SPAWNING;
2501                                 LeaveSpectatorMode();
2502                                 return;
2503                         }
2504                 }
2505         }
2506         PrintWelcomeMessage(self);
2507 }
2508
2509 void SpectatorThink()
2510 {
2511         if (self.flags & FL_JUMPRELEASED) {
2512                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2513                         self.welcomemessage_time = 0;
2514                         self.flags &~= FL_JUMPRELEASED;
2515                         self.flags |= FL_SPAWNING;
2516                 } else if(self.BUTTON_ATCK) {
2517                         self.welcomemessage_time = 0;
2518                         self.flags &~= FL_JUMPRELEASED;
2519                         if(SpectateNext() == 1) {
2520                                 self.classname = "spectator";
2521                         } else {
2522                                 self.classname = "observer";
2523                                 PutClientInServer();
2524                         }
2525                 } else if (self.BUTTON_ATCK2) {
2526                         self.welcomemessage_time = 0;
2527                         self.flags &~= FL_JUMPRELEASED;
2528                         self.classname = "observer";
2529                         PutClientInServer();
2530                 } else {
2531                         if(!SpectateUpdate())
2532                                 PutObserverInServer();
2533                 }
2534         } else {
2535                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2536                         self.flags |= FL_JUMPRELEASED;
2537                         if(self.flags & FL_SPAWNING)
2538                         {
2539                                 self.flags &~= FL_SPAWNING;
2540                                 LeaveSpectatorMode();
2541                                 return;
2542                         }
2543                 }
2544         }
2545
2546         PrintWelcomeMessage(self);
2547         self.flags |= FL_CLIENT | FL_NOTARGET;
2548 }
2549
2550 .float touchexplode_time;
2551
2552 /*
2553 =============
2554 PlayerPreThink
2555
2556 Called every frame for each client before the physics are run
2557 =============
2558 */
2559 void() ctf_setstatus;
2560 void() nexball_setstatus;
2561 .float items_added;
2562 void PlayerPreThink (void)
2563 {
2564         self.stat_game_starttime = game_starttime;
2565         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2566         self.stat_leadlimit = cvar("leadlimit");
2567
2568         if(frametime)
2569         {
2570                 // physics frames: update anticheat stuff
2571                 anticheat_prethink();
2572         }
2573
2574         if(blockSpectators && frametime)
2575                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2576                 checkSpectatorBlock();
2577
2578         zoomstate_set = 0;
2579
2580         if(self.netname_previous != self.netname)
2581         {
2582                 if(cvar("sv_eventlog"))
2583                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2584                 if(self.netname_previous)
2585                         strunzone(self.netname_previous);
2586                 self.netname_previous = strzone(self.netname);
2587         }
2588
2589         // version nagging
2590         if(self.version_nagtime)
2591                 if(self.cvar_g_xonoticversion)
2592                         if(time > self.version_nagtime)
2593                         {
2594                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2595                                 {
2596                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2597                                         {
2598                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2599                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2600                                         }
2601                                         else
2602                                         {
2603                                                 float r;
2604                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2605                                                 if(r < 0)
2606                                                 {
2607                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2608                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2609                                                 }
2610                                                 else if(r > 0)
2611                                                 {
2612                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2613                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2614                                                 }
2615                                         }
2616                                 }
2617                                 self.version_nagtime = 0;
2618                         }
2619
2620         // GOD MODE info
2621         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2622         {
2623                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2624                 self.max_armorvalue = 0;
2625         }
2626
2627 #ifdef TETRIS
2628         if (TetrisPreFrame())
2629                 return;
2630 #endif
2631
2632         MUTATOR_CALLHOOK(PlayerPreThink);
2633
2634         if(self.classname == "player") {
2635 //              if(self.netname == "Wazat")
2636 //                      bprint(self.classname, "\n");
2637
2638                 CheckRules_Player();
2639
2640                 PrintWelcomeMessage(self);
2641
2642                 if (intermission_running)
2643                 {
2644                         IntermissionThink ();   // otherwise a button could be missed between
2645                         return;                                 // the think tics
2646                 }
2647
2648                 if(self.teleport_time)
2649                 if(time > self.teleport_time)
2650                 {
2651                         self.teleport_time = 0;
2652                         self.effects = self.effects - (self.effects & EF_NODRAW);
2653                 }
2654
2655                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2656                         UpdateSelectedPlayer();
2657
2658                 //don't allow the player to turn around while game is paused!
2659                 if(timeoutStatus == 2) {
2660                         self.v_angle = self.lastV_angle;
2661                         self.angles = self.lastV_angle;
2662                         self.fixangle = TRUE;
2663                 }
2664
2665                 if(frametime)
2666                 {
2667                         if(self.health <= 0 && cvar("g_deathglow"))
2668                         {
2669                                 if(self.glowmod_x > 0)
2670                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2671                                 else
2672                                         self.glowmod_x = -1;
2673                                 if(self.glowmod_y > 0)
2674                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2675                                 else
2676                                         self.glowmod_y = -1;
2677                                 if(self.glowmod_z > 0)
2678                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2679                                 else
2680                                         self.glowmod_z = -1;
2681                         }
2682                         else
2683                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2684                         player_powerups();
2685                 }
2686
2687                 if (self.deadflag != DEAD_NO)
2688                 {
2689                         float button_pressed, force_respawn;
2690                         if(self.personal && g_race_qualifying)
2691                         {
2692                                 if(time > self.death_time)
2693                                 {
2694                                         self.death_time = time + 1; // only retry once a second
2695                                         respawn();
2696                                         self.impulse = 141;
2697                                 }
2698                         }
2699                         else
2700                         {
2701                                 if(frametime)
2702                                         player_anim();
2703                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2704                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2705                                 if (self.deadflag == DEAD_DYING)
2706                                 {
2707                                         if(force_respawn)
2708                                                 self.deadflag = DEAD_RESPAWNING;
2709                                         else if(!button_pressed)
2710                                                 self.deadflag = DEAD_DEAD;
2711                                 }
2712                                 else if (self.deadflag == DEAD_DEAD)
2713                                 {
2714                                         if(button_pressed)
2715                                                 self.deadflag = DEAD_RESPAWNABLE;
2716                                 }
2717                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2718                                 {
2719                                         if(!button_pressed)
2720                                                 self.deadflag = DEAD_RESPAWNING;
2721                                 }
2722                                 else if (self.deadflag == DEAD_RESPAWNING)
2723                                 {
2724                                         if(time > self.death_time)
2725                                         {
2726                                                 self.death_time = time + 1; // only retry once a second
2727                                                 respawn();
2728                                         }
2729                                 }
2730                                 ShowRespawnCountdown();
2731                         }
2732                         return;
2733                 }
2734
2735                 if(g_touchexplode)
2736                 if(time > self.touchexplode_time)
2737                 if(self.classname == "player")
2738                 if(self.deadflag == DEAD_NO)
2739                 if not(IS_INDEPENDENT_PLAYER(self))
2740                 FOR_EACH_PLAYER(other) if(self != other)
2741                 {
2742                         if(time > other.touchexplode_time)
2743                         if(other.deadflag == DEAD_NO)
2744                         if not(IS_INDEPENDENT_PLAYER(other))
2745                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2746                         {
2747                                 PlayerTouchExplode(self, other);
2748                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2749                         }
2750                 }
2751
2752                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2753                 {
2754                         vector dist;
2755
2756                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2757                         dist = self.prevorigin - self.origin;
2758                         dist_z = 0;
2759                         self.lms_traveled_distance += fabs(vlen(dist));
2760
2761                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2762                         {
2763                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2764                                 self.lms_traveled_distance = 0;
2765                         }
2766
2767                         if(time > self.lms_nextcheck)
2768                         {
2769                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2770                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2771                                 {
2772                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2773                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2774                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2775                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2776                                 }
2777                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2778                                 self.lms_traveled_distance = 0;
2779                         }
2780                 }
2781
2782                 self.prevorigin = self.origin;
2783
2784                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2785                 {
2786                         if (!self.crouch)
2787                         {
2788                                 self.crouch = TRUE;
2789                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2790                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2791                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2792                         }
2793                 }
2794                 else
2795                 {
2796                         if (self.crouch)
2797                         {
2798                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2799                                 if (!trace_startsolid)
2800                                 {
2801                                         self.crouch = FALSE;
2802                                         self.view_ofs = PL_VIEW_OFS;
2803                                         setsize (self, PL_MIN, PL_MAX);
2804                                 }
2805                         }
2806                 }
2807
2808                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2809                 {
2810                         if(self.bloodloss_timer < time)
2811                         {
2812                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2813                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2814                         }
2815                 }
2816
2817                 FixPlayermodel();
2818
2819                 GrapplingHookFrame();
2820
2821                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2822                 //if(frametime)
2823                 {
2824                         self.items &~= self.items_added;
2825
2826                         W_WeaponFrame();
2827
2828                         self.items_added = 0;
2829                         if(self.items & IT_JETPACK)
2830                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2831                                         self.items_added |= IT_FUEL;
2832
2833                         self.items |= self.items_added;
2834                 }
2835
2836                 player_regen();
2837
2838                 // rot nex charge to the charge limit
2839                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2840                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2841
2842                 if(frametime)
2843                         player_anim();
2844
2845                 if (g_minstagib)
2846                         minstagib_ammocheck();
2847
2848                 if(g_ctf)
2849                         ctf_setstatus();
2850
2851                 if(g_nexball)
2852                         nexball_setstatus();
2853
2854                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2855
2856                 //self.angles_y=self.v_angle_y + 90;   // temp
2857         } else if(gameover) {
2858                 if (intermission_running)
2859                         IntermissionThink ();   // otherwise a button could be missed between
2860                 return;
2861         } else if(self.classname == "observer") {
2862                 ObserverThink();
2863         } else if(self.classname == "spectator") {
2864                 SpectatorThink();
2865         }
2866
2867         if(!zoomstate_set)
2868                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2869
2870         float oldspectatee_status;
2871         oldspectatee_status = self.spectatee_status;
2872         if(self.classname == "spectator")
2873                 self.spectatee_status = num_for_edict(self.enemy);
2874         else if(self.classname == "observer")
2875                 self.spectatee_status = num_for_edict(self);
2876         else
2877                 self.spectatee_status = 0;
2878         if(self.spectatee_status != oldspectatee_status)
2879         {
2880                 ClientData_Touch(self);
2881                 if(g_race || g_cts)
2882                         race_InitSpectator();
2883         }
2884
2885         if(self.teamkill_soundtime)
2886         if(time > self.teamkill_soundtime)
2887         {
2888                 self.teamkill_soundtime = 0;
2889
2890                 entity oldpusher, oldself;
2891
2892                 oldself = self; self = self.teamkill_soundsource;
2893                 oldpusher = self.pusher; self.pusher = oldself;
2894
2895                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2896
2897                 self.pusher = oldpusher;
2898                 self = oldself;
2899         }
2900
2901         if(self.taunt_soundtime)
2902         if(time > self.taunt_soundtime)
2903         {
2904                 self.taunt_soundtime = 0;
2905                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2906         }
2907
2908         target_voicescript_next(self);
2909 }
2910
2911 float isInvisibleString(string s)
2912 {
2913         float i, n, c;
2914         s = strdecolorize(s);
2915         for((i = 0), (n = strlen(s)); i < n; ++i)
2916         {
2917                 c = str2chr(s, i);
2918                 switch(c)
2919                 {
2920                         case 0:
2921                         case 32: // space
2922                                 break;
2923                         case 192: // charmap space
2924                                 if (!cvar("utf8_enable"))
2925                                         break;
2926                                 return FALSE;
2927                         case 160: // space in unicode fonts
2928                         case 0xE000 + 192: // utf8 charmap space
2929                                 if (cvar("utf8_enable"))
2930                                         break;
2931                         default:
2932                                 return FALSE;
2933                 }
2934         }
2935         return TRUE;
2936 }
2937
2938 /*
2939 =============
2940 PlayerPostThink
2941
2942 Called every frame for each client after the physics are run
2943 =============
2944 */
2945 .float idlekick_lasttimeleft;
2946 .entity showheadshotbbox;
2947 void showheadshotbbox_think()
2948 {
2949         if(self.owner.showheadshotbbox != self)
2950         {
2951                 remove(self);
2952                 return;
2953         }
2954         self.nextthink = time;
2955         setorigin(self, self.owner.origin);
2956         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2957 }
2958 void PlayerPostThink (void)
2959 {
2960         // Savage: Check for nameless players
2961         if (isInvisibleString(self.netname)) {
2962                 self.netname = "Player";
2963                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2964         }
2965
2966         if(sv_maxidle && frametime)
2967         {
2968                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2969                 float timeleft;
2970                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2971                 if(timeleft <= 0)
2972                 {
2973                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2974                         AnnounceTo(self, "terminated");
2975                         dropclient(self);
2976                         return;
2977                 }
2978                 else if(timeleft <= 10)
2979                 {
2980                         if(timeleft != self.idlekick_lasttimeleft)
2981                         {
2982                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2983                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2984                         }
2985                 }
2986                 else
2987                 {
2988                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2989                 }
2990                 self.idlekick_lasttimeleft = timeleft;
2991         }
2992
2993 #ifdef TETRIS
2994         if(self.impulse == 100)
2995                 ImpulseCommands();
2996         if (TetrisPostFrame())
2997                 return;
2998 #endif
2999
3000         CheatFrame();
3001
3002         if(self.classname == "player") {
3003                 CheckRules_Player();
3004                 UpdateChatBubble();
3005                 UpdateTeamBubble();
3006                 if (self.impulse)
3007                         ImpulseCommands();
3008                 if (intermission_running)
3009                         return;         // intermission or finale
3010                 GetPressedKeys();
3011         } else if (self.classname == "observer") {
3012                 //do nothing
3013         } else if (self.classname == "spectator") {
3014                 //do nothing
3015         }
3016
3017         /*
3018         float i;
3019         for(i = 0; i < 1000; ++i)
3020         {
3021                 vector end;
3022                 end = self.origin + '0 0 1024' + 512 * randomvec();
3023                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3024                 if(trace_fraction < 1)
3025                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3026                 {
3027                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3028                         break;
3029                 }
3030         }
3031         */
3032
3033         Arena_Warmup();
3034
3035         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3036
3037         if(self.waypointsprite_attachedforcarrier)
3038                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3039         
3040         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3041         {
3042                 if(!self.showheadshotbbox)
3043                 {
3044                         self.showheadshotbbox = spawn();
3045                         self.showheadshotbbox.classname = "headshotbbox";
3046                         self.showheadshotbbox.owner = self;
3047                         self.showheadshotbbox.think = showheadshotbbox_think;
3048                         self.showheadshotbbox.nextthink = time;
3049                         self = self.showheadshotbbox;
3050                         self.think();
3051                         self = self.owner;
3052                 }
3053         }
3054         else
3055         {