Merge remote branch 'origin/fruitiex/fruit_vs_tzork-balance'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(cvar("spawn_debugview"))
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > cvar("g_spawn_furthest"))
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(cvar("spawn_debugview"))
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(cvar("spawn_debug"))
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(cvar("sv_servermodelsonly"))
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602         MUTATOR_CALLHOOK(MakePlayerObserver);
603
604         Portal_ClearAll(self);
605
606         if(self.flagcarried)
607                 DropFlag(self.flagcarried, world, world);
608
609         if(self.ballcarried)
610                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
611
612         WaypointSprite_PlayerDead();
613
614         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
615                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
616
617         if(self.killcount != -666) {
618                 if(g_lms) {
619                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
620                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
621                         else
622                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
623                 } else
624                         bprint ("^4", self.netname, "^4 is spectating now\n");
625
626                 if(self.just_joined == FALSE) {
627                         LogTeamchange(self.playerid, -1, 4);
628                 } else
629                         self.just_joined = FALSE;
630         }
631
632         PlayerScore_Clear(self); // clear scores when needed
633
634         self.spectatortime = time;
635
636         self.classname = "observer";
637         self.iscreature = FALSE;
638         self.health = -666;
639         self.takedamage = DAMAGE_NO;
640         self.solid = SOLID_NOT;
641         self.movetype = MOVETYPE_NOCLIP;
642         self.flags = FL_CLIENT | FL_NOTARGET;
643         self.armorvalue = 666;
644         self.effects = 0;
645         self.armorvalue = cvar("g_balance_armor_start");
646         self.pauserotarmor_finished = 0;
647         self.pauserothealth_finished = 0;
648         self.pauseregen_finished = 0;
649         self.damageforcescale = 0;
650         self.death_time = 0;
651         self.dead_frame = 0;
652         self.alpha = 0;
653         self.scale = 0;
654         self.fade_time = 0;
655         self.pain_frame = 0;
656         self.pain_finished = 0;
657         self.strength_finished = 0;
658         self.invincible_finished = 0;
659         self.pushltime = 0;
660         self.think = SUB_Null;
661         self.nextthink = 0;
662         self.hook_time = 0;
663         self.runes = 0;
664         self.deadflag = DEAD_NO;
665         self.angles = spot.angles;
666         self.angles_z = 0;
667         self.fixangle = TRUE;
668         self.crouch = FALSE;
669
670         self.view_ofs = PL_VIEW_OFS;
671         setorigin (self, spot.origin);
672         setsize (self, '0 0 0', '0 0 0');
673         self.prevorigin = self.origin;
674         self.items = 0;
675         self.weapons = 0;
676         self.model = "";
677         FixPlayermodel();
678         self.model = "";
679         self.modelindex = 0;
680         self.weapon = 0;
681         self.weaponmodel = "";
682         self.weaponentity = world;
683         self.exteriorweaponentity = world;
684         self.killcount = -666;
685         self.velocity = '0 0 0';
686         self.avelocity = '0 0 0';
687         self.punchangle = '0 0 0';
688         self.punchvector = '0 0 0';
689         self.oldvelocity = self.velocity;
690         self.fire_endtime = -1;
691
692         if(sv_loddistance1)
693                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
694
695         if(g_arena)
696         {
697                 if(self.version_mismatch)
698                 {
699                         Spawnqueue_Unmark(self);
700                         Spawnqueue_Remove(self);
701                 }
702                 else
703                 {
704                         Spawnqueue_Insert(self);
705                 }
706         }
707         else if(g_lms)
708         {
709                 // Only if the player cannot play at all
710                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
711                         self.frags = FRAGS_SPECTATOR;
712                 else
713                         self.frags = FRAGS_LMS_LOSER;
714         }
715         else
716                 self.frags = FRAGS_SPECTATOR;
717 }
718
719 float RestrictSkin(float s)
720 {
721         if(!teams_matter)
722                 return s;
723         if(s == 6)
724                 return 6;
725         return mod(s, 3);
726 }
727
728 void FixPlayermodel()
729 {
730         local string defaultmodel;
731         local float defaultskin, chmdl, oldskin;
732         local vector m1, m2;
733
734         defaultmodel = "";
735
736         if(cvar("sv_defaultcharacter") == 1) {
737                 defaultskin = 0;
738
739                 if(teams_matter)
740                 {
741                         string s;
742                         s = Team_ColorNameLowerCase(self.team);
743                         if(s != "neutral")
744                         {
745                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
746                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
747                         }
748                 }
749
750                 if(defaultmodel == "")
751                 {
752                         defaultmodel = cvar_string("sv_defaultplayermodel");
753                         defaultskin = cvar("sv_defaultplayerskin");
754                 }
755         }
756
757         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
758         {
759                 if(self.model != "")
760                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
761                 self.model = ""; // force the != checks to return true
762         }
763
764         if(defaultmodel != "")
765         {
766                 if (defaultmodel != self.model)
767                 {
768                         m1 = self.mins;
769                         m2 = self.maxs;
770                         setmodel_lod (self, defaultmodel);
771                         setsize (self, m1, m2);
772                         chmdl = TRUE;
773                 }
774
775                 oldskin = self.skinindex;
776                 self.skinindex = defaultskin;
777         } else {
778                 if (self.playermodel != self.model || self.playermodel == "")
779                 {
780                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
781                         m1 = self.mins;
782                         m2 = self.maxs;
783                         setmodel_lod (self, self.playermodel);
784                         setsize (self, m1, m2);
785                         chmdl = TRUE;
786                 }
787
788                 oldskin = self.skinindex;
789                 self.skinindex = RestrictSkin(stof(self.playerskin));
790         }
791
792         if(chmdl || oldskin != self.skinindex)
793                 self.species = player_getspecies(); // model or skin has changed
794
795         if(!teams_matter)
796                 if(strlen(cvar_string("sv_defaultplayercolors")))
797                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
798                                 setcolor(self, cvar("sv_defaultplayercolors"));
799 }
800
801 void PlayerTouchExplode(entity p1, entity p2)
802 {
803         vector org;
804         org = (p1.origin + p2.origin) * 0.5;
805         org_z += (p1.mins_z + p2.mins_z) * 0.5;
806
807         te_explosion(org);
808
809         entity e;
810         e = spawn();
811         setorigin(e, org);
812         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
813         remove(e);
814 }
815
816 /*
817 =============
818 PutClientInServer
819
820 Called when a client spawns in the server
821 =============
822 */
823 //void() ctf_playerchanged;
824 void PutClientInServer (void)
825 {
826         if(clienttype(self) == CLIENTTYPE_BOT)
827         {
828                 self.classname = "player";
829         }
830         else if(clienttype(self) == CLIENTTYPE_REAL)
831         {
832                 msg_entity = self;
833                 WriteByte(MSG_ONE, SVC_SETVIEW);
834                 WriteEntity(MSG_ONE, self);
835         }
836
837         // player is dead and becomes observer
838         // FIXME fix LMS scoring for new system
839         if(g_lms)
840         {
841                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
842                         self.classname = "observer";
843         }
844
845         if(g_arena || (g_ca && !allowed_to_spawn))
846         if(!self.spawned)
847                 self.classname = "observer";
848
849         if(gameover)
850                 self.classname = "observer";
851
852         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
853                 entity spot, oldself;
854                 float j;
855
856                 if(self.team < 0)
857                         JoinBestTeam(self, FALSE, TRUE);
858
859                 race_PreSpawn();
860
861                 spot = SelectSpawnPoint (FALSE);
862                 if(!spot)
863                 {
864                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
865                         return; // spawn failed
866                 }
867
868                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
869
870                 self.classname = "player";
871                 self.wasplayer = TRUE;
872                 self.iscreature = TRUE;
873                 self.movetype = MOVETYPE_WALK;
874                 self.solid = SOLID_SLIDEBOX;
875                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
876                 if(cvar("g_playerclip_collisions"))
877                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
878                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
879                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
880                 self.frags = FRAGS_PLAYER;
881                 if(independent_players)
882                         MAKE_INDEPENDENT_PLAYER(self);
883                 self.flags = FL_CLIENT;
884                 self.takedamage = DAMAGE_AIM;
885                 if(g_minstagib)
886                         self.effects = EF_FULLBRIGHT;
887                 else
888                         self.effects = 0;
889                 self.air_finished = time + 12;
890                 self.dmg = 2;
891                 if(cvar("g_balance_nex_charge"))
892                 {
893                         if(cvar("g_balance_nex_secondary_charge_pool"))
894                                 self.nex_charge_pool_ammo = 1;
895                         self.nex_charge = cvar("g_balance_nex_charge_start");
896                 }
897
898                 if(inWarmupStage)
899                 {
900                         self.ammo_shells = warmup_start_ammo_shells;
901                         self.ammo_nails = warmup_start_ammo_nails;
902                         self.ammo_rockets = warmup_start_ammo_rockets;
903                         self.ammo_cells = warmup_start_ammo_cells;
904                         self.ammo_fuel = warmup_start_ammo_fuel;
905                         self.health = warmup_start_health;
906                         self.armorvalue = warmup_start_armorvalue;
907                         self.weapons = warmup_start_weapons;
908                 }
909                 else
910                 {
911                         self.ammo_shells = start_ammo_shells;
912                         self.ammo_nails = start_ammo_nails;
913                         self.ammo_rockets = start_ammo_rockets;
914                         self.ammo_cells = start_ammo_cells;
915                         self.ammo_fuel = start_ammo_fuel;
916                         self.health = start_health;
917                         self.armorvalue = start_armorvalue;
918                         self.weapons = start_weapons;
919                 }
920
921                 if(g_weaponarena_random)
922                 {
923                         if(g_weaponarena_random_with_laser)
924                                 self.weapons &~= WEPBIT_LASER;
925                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
926                         if(g_weaponarena_random_with_laser)
927                                 self.weapons |= WEPBIT_LASER;
928                 }
929
930                 self.items = start_items;
931                 self.jump_interval = time;
932
933                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
934                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
935                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
936                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
937                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
938                 //extend the pause of rotting if client was reset at the beginning of the countdown
939                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
940                         self.spawnshieldtime += game_starttime - time;
941                         self.pauserotarmor_finished += game_starttime - time;
942                         self.pauserothealth_finished += game_starttime - time;
943                         self.pauseregen_finished += game_starttime - time;
944                 }
945                 self.damageforcescale = 2;
946                 self.death_time = 0;
947                 self.dead_frame = 0;
948                 self.alpha = 0;
949                 self.scale = 0;
950                 self.fade_time = 0;
951                 self.pain_frame = 0;
952                 self.pain_finished = 0;
953                 self.strength_finished = 0;
954                 self.invincible_finished = 0;
955                 self.pushltime = 0;
956                 // players have no think function
957                 self.think = SUB_Null;
958                 self.nextthink = 0;
959                 self.hook_time = 0;
960                 self.dmg_team = 0;
961                 self.ballistics_density = cvar("g_ballistics_density_player");
962
963                 self.metertime = 0;
964
965                 self.runes = 0;
966
967                 self.deadflag = DEAD_NO;
968
969                 self.angles = spot.angles;
970
971                 self.angles_z = 0; // never spawn tilted even if the spot says to
972                 self.fixangle = TRUE; // turn this way immediately
973                 self.velocity = '0 0 0';
974                 self.avelocity = '0 0 0';
975                 self.punchangle = '0 0 0';
976                 self.punchvector = '0 0 0';
977                 self.oldvelocity = self.velocity;
978                 self.fire_endtime = -1;
979
980                 msg_entity = self;
981                 WRITESPECTATABLE_MSG_ONE({
982                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
983                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
984                 });
985
986                 if(sv_loddistance1)
987                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
988
989                 self.model = "";
990                 FixPlayermodel();
991
992                 self.crouch = FALSE;
993                 self.view_ofs = PL_VIEW_OFS;
994                 setsize (self, PL_MIN, PL_MAX);
995                 self.spawnorigin = spot.origin;
996                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
997                 // don't reset back to last position, even if new position is stuck in solid
998                 self.oldorigin = self.origin;
999                 self.prevorigin = self.origin;
1000                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1001
1002                 if(g_arena)
1003                 {
1004                         Spawnqueue_Remove(self);
1005                         Spawnqueue_Mark(self);
1006                 }
1007
1008                 else if(g_ca)
1009                         self.caplayer = 1;
1010
1011                 self.event_damage = PlayerDamage;
1012
1013                 self.bot_attack = TRUE;
1014
1015                 self.statdraintime = time + 5;
1016                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1017
1018                 if(self.killcount == -666) {
1019                         PlayerScore_Clear(self);
1020                         self.killcount = 0;
1021                 }
1022
1023                 self.cnt = WEP_LASER;
1024
1025                 CL_SpawnWeaponentity();
1026                 self.alpha = default_player_alpha;
1027                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1028                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1029
1030                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1031                 self.lms_traveled_distance = 0;
1032                 self.speedrunning = FALSE;
1033
1034                 race_PostSpawn(spot);
1035
1036                 if(cvar("spawn_debug"))
1037                 {
1038                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1039                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1040                 }
1041
1042                 //stuffcmd(self, "chase_active 0");
1043                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1044
1045                 if (cvar("g_spawnsound"))
1046                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1047
1048                 if(g_assault) {
1049                         if(self.team == assault_attacker_team)
1050                                 centerprint(self, "You are attacking!");
1051                         else
1052                                 centerprint(self, "You are defending!");
1053                 }
1054
1055                 target_voicescript_clear(self);
1056
1057                 // reset fields the weapons may use
1058                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1059                         weapon_action(j, WR_RESETPLAYER);
1060
1061                 oldself = self;
1062                 self = spot;
1063                         activator = oldself;
1064                                 SUB_UseTargets();
1065                         activator = world;
1066                 self = oldself;
1067
1068                 MUTATOR_CALLHOOK(PlayerSpawn);
1069
1070                 self.switchweapon = w_getbestweapon(self);
1071                 self.cnt = self.switchweapon;
1072                 self.weapon = 0;
1073         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1074                 PutObserverInServer ();
1075         }
1076
1077         //if(g_ctf)
1078         //      ctf_playerchanged();
1079 }
1080
1081 .float ebouncefactor, ebouncestop; // electro's values
1082 // TODO do we need all these fields, or should we stop autodetecting runtime
1083 // changes and just have a console command to update this?
1084 float ClientInit_SendEntity(entity to, float sf)
1085 {
1086         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1087         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1100         if(sv_foginterval && world.fog != "")
1101                 WriteString(MSG_ENTITY, world.fog);
1102         else
1103                 WriteString(MSG_ENTITY, "");
1104         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1105         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1106         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1107         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1108         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1109         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1110         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1111         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1112         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1113         return TRUE;
1114 }
1115
1116 void ClientInit_CheckUpdate()
1117 {
1118         self.nextthink = time;
1119         if(self.count != cvar("g_balance_armor_blockpercent"))
1120         {
1121                 self.count = cvar("g_balance_armor_blockpercent");
1122                 self.SendFlags |= 1;
1123         }
1124         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1125         {
1126                 self.cnt = cvar("g_balance_weaponswitchdelay");
1127                 self.SendFlags |= 1;
1128         }
1129         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1130         {
1131                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1132                 self.SendFlags |= 1;
1133         }
1134         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1135         {
1136                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1137                 self.SendFlags |= 1;
1138         }
1139         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1140         {
1141                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1142                 self.SendFlags |= 1;
1143         }
1144         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1145         {
1146                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1147                 self.SendFlags |= 1;
1148         }
1149 }
1150
1151 void ClientInit_Spawn()
1152 {
1153         entity o;
1154         entity e;
1155         e = spawn();
1156         e.classname = "clientinit";
1157         e.think = ClientInit_CheckUpdate;
1158         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1159
1160         o = self;
1161         self = e;
1162         ClientInit_CheckUpdate();
1163         self = o;
1164 }
1165
1166 /*
1167 =============
1168 SetNewParms
1169 =============
1170 */
1171 void SetNewParms (void)
1172 {
1173         // initialize parms for a new player
1174         parm1 = -(86400 * 366);
1175 }
1176
1177 /*
1178 =============
1179 SetChangeParms
1180 =============
1181 */
1182 void SetChangeParms (void)
1183 {
1184         // save parms for level change
1185         parm1 = self.parm_idlesince - time;
1186 }
1187
1188 /*
1189 =============
1190 DecodeLevelParms
1191 =============
1192 */
1193 void DecodeLevelParms (void)
1194 {
1195         // load parms
1196         self.parm_idlesince = parm1;
1197         if(self.parm_idlesince == -(86400 * 366))
1198                 self.parm_idlesince = time;
1199
1200         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1201         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1202 }
1203
1204 /*
1205 =============
1206 ClientKill
1207
1208 Called when a client types 'kill' in the console
1209 =============
1210 */
1211
1212 void ClientKill_Now_TeamChange()
1213 {
1214         if(self.killindicator_teamchange == -1)
1215         {
1216                 self.team = -1;
1217                 JoinBestTeam( self, FALSE, FALSE );
1218         }
1219         else
1220                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1221 }
1222
1223 void ClientKill_Now()
1224 {
1225         if(self.killindicator_teamchange)
1226                 ClientKill_Now_TeamChange();
1227
1228         // in any case:
1229         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1230
1231         if(self.killindicator)
1232         {
1233                 dprint("Cleaned up after a leaked kill indicator.\n");
1234                 remove(self.killindicator);
1235                 self.killindicator = world;
1236         }
1237 }
1238 void KillIndicator_Think()
1239 {
1240         if (!self.owner.modelindex)
1241         {
1242                 self.owner.killindicator = world;
1243                 remove(self);
1244                 return;
1245         }
1246
1247         if(self.cnt <= 0)
1248         {
1249                 self = self.owner;
1250                 ClientKill_Now(); // no oldself needed
1251                 return;
1252         }
1253         else
1254         {
1255                 if(self.cnt <= 10)
1256                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1257                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1258                 {
1259                         if(self.cnt <= 10)
1260                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1261                         if(self.owner.killindicator_teamchange)
1262                         {
1263                                 if(self.owner.killindicator_teamchange == -1)
1264                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1265                                 else
1266                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1267                         }
1268                         else
1269                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1270                 }
1271                 self.nextthink = time + 1;
1272                 self.cnt -= 1;
1273         }
1274 }
1275
1276 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1277 {
1278         float killtime;
1279         entity e;
1280         killtime = cvar("g_balance_kill_delay");
1281
1282         if(g_race_qualifying)
1283                 killtime = 0;
1284
1285         self.killindicator_teamchange = targetteam;
1286
1287         if(!self.killindicator)
1288         {
1289                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1290                 {
1291                         ClientKill_Now();
1292                 }
1293                 else
1294                 {
1295                         self.killindicator = spawn();
1296                         self.killindicator.owner = self;
1297                         self.killindicator.scale = 0.5;
1298                         setattachment(self.killindicator, self, "");
1299                         setorigin(self.killindicator, '0 0 52');
1300                         self.killindicator.think = KillIndicator_Think;
1301                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1302                         self.killindicator.cnt = ceil(killtime);
1303                         self.killindicator.count = bound(0, ceil(killtime), 10);
1304                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1305
1306                         for(e = world; (e = find(e, classname, "body")) != world; )
1307                         {
1308                                 if(e.enemy != self)
1309                                         continue;
1310                                 e.killindicator = spawn();
1311                                 e.killindicator.owner = e;
1312                                 e.killindicator.scale = 0.5;
1313                                 setattachment(e.killindicator, e, "");
1314                                 setorigin(e.killindicator, '0 0 52');
1315                                 e.killindicator.think = KillIndicator_Think;
1316                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1317                                 e.killindicator.cnt = ceil(killtime);
1318                         }
1319                         self.lip = 0;
1320                 }
1321         }
1322         if(self.killindicator)
1323         {
1324                 if(targetteam)
1325                         self.killindicator.colormod = TeamColor(targetteam);
1326                 else
1327                         self.killindicator.colormod = '0 0 0';
1328         }
1329 }
1330
1331 void ClientKill (void)
1332 {
1333         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1334         {
1335                 // do nothing
1336         }
1337         else
1338                 ClientKill_TeamChange(0);
1339 }
1340
1341 void CTS_ClientKill_Think (void)
1342 {
1343         self = self.owner; // set self to the player to be killed
1344         sprint(self, "^1You were killed in order to prevent cheating!");
1345         ClientKill_Now();
1346 }
1347
1348 void CTS_ClientKill (float t) // silent version of ClientKill
1349 {
1350         entity e;
1351         e = spawn();
1352         e.owner = self;
1353         e.think = CTS_ClientKill_Think;
1354         e.nextthink = t;
1355 }
1356
1357 void DoTeamChange(float destteam)
1358 {
1359         float t, c0;
1360         if(!teams_matter)
1361         {
1362                 if(destteam >= 0)
1363                         SetPlayerColors(self, destteam);
1364                 return;
1365         }
1366         if(self.classname == "player")
1367         if(destteam == -1)
1368         {
1369                 CheckAllowedTeams(self);
1370                 t = FindSmallestTeam(self, TRUE);
1371                 switch(self.team)
1372                 {
1373                         case COLOR_TEAM1: c0 = c1; break;
1374                         case COLOR_TEAM2: c0 = c2; break;
1375                         case COLOR_TEAM3: c0 = c3; break;
1376                         case COLOR_TEAM4: c0 = c4; break;
1377                         default:          c0 = 999;
1378                 }
1379                 switch(t)
1380                 {
1381                         case 1:
1382                                 if(c0 > c1)
1383                                         destteam = COLOR_TEAM1;
1384                                 break;
1385                         case 2:
1386                                 if(c0 > c2)
1387                                         destteam = COLOR_TEAM2;
1388                                 break;
1389                         case 3:
1390                                 if(c0 > c3)
1391                                         destteam = COLOR_TEAM3;
1392                                 break;
1393                         case 4:
1394                                 if(c0 > c4)
1395                                         destteam = COLOR_TEAM4;
1396                                 break;
1397                 }
1398                 if(destteam == -1)
1399                         return;
1400         }
1401         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1402                 return;
1403         ClientKill_TeamChange(destteam);
1404 }
1405
1406 void FixClientCvars(entity e)
1407 {
1408         // send prediction settings to the client
1409         stuffcmd(e, "\nin_bindmap 0 0\n");
1410         if(g_race || g_cts)
1411                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1412         if(cvar("g_antilag") == 3) // client side hitscan
1413                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1414         if(sv_gentle)
1415                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1416         /*
1417          * we no longer need to stuff this. Remove this comment block if you feel
1418          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1419         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1420         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1421         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1422         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1423         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1424         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1425         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1426         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1427         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1428         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1429         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1430         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1431         stuffcmd(e, "cl_movement_edgefriction 1\n");
1432          */
1433 }
1434
1435 float PlayerInIDList(entity p, string idlist)
1436 {
1437         float n, i;
1438         string s;
1439
1440         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1441         if not(p.crypto_idfp)
1442                 return 0;
1443
1444         // this function allows abbreviated player IDs too!
1445         n = tokenize_console(idlist);
1446         for(i = 0; i < n; ++i)
1447         {
1448                 s = argv(i);
1449                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1450                         return 1;
1451         }
1452
1453         return 0;
1454 }
1455
1456 /*
1457 =============
1458 ClientConnect
1459
1460 Called when a client connects to the server
1461 =============
1462 */
1463 //void ctf_clientconnect();
1464 string ColoredTeamName(float t);
1465 void DecodeLevelParms (void);
1466 //void dom_player_join_team(entity pl);
1467 void ClientConnect (void)
1468 {
1469         float t;
1470
1471         if(self.flags & FL_CLIENT)
1472         {
1473                 print("Warning: ClientConnect, but already connected!\n");
1474                 return;
1475         }
1476
1477         if(Ban_MaybeEnforceBan(self))
1478                 return;
1479
1480         DecodeLevelParms();
1481
1482 #ifdef WATERMARK
1483         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1484 #endif
1485
1486         self.classname = "player_joining";
1487
1488         self.flags = FL_CLIENT;
1489         self.version_nagtime = time + 10 + random() * 10;
1490
1491         if(player_count<0)
1492         {
1493                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1494                 player_count = 0;
1495         }
1496
1497         PlayerScore_Attach(self);
1498         ClientData_Attach();
1499
1500         bot_clientconnect();
1501
1502         playerdemo_init();
1503
1504         anticheat_init();
1505         
1506         race_PreSpawnObserver();
1507
1508         //if(g_domination)
1509         //      dom_player_join_team(self);
1510
1511         // identify the right forced team
1512         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1513                 self.team_forced = COLOR_TEAM1;
1514         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1515                 self.team_forced = COLOR_TEAM2;
1516         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1517                 self.team_forced = COLOR_TEAM3;
1518         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1519                 self.team_forced = COLOR_TEAM4;
1520         else if(cvar_string("g_forced_team_otherwise") == "red")
1521                 self.team_forced = COLOR_TEAM1;
1522         else if(cvar_string("g_forced_team_otherwise") == "blue")
1523                 self.team_forced = COLOR_TEAM2;
1524         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1525                 self.team_forced = COLOR_TEAM3;
1526         else if(cvar_string("g_forced_team_otherwise") == "pink")
1527                 self.team_forced = COLOR_TEAM4;
1528         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1529                 self.team_forced = -1;
1530         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1531                 self.team_forced = -1;
1532         else
1533                 self.team_forced = 0;
1534
1535         if(!teams_matter)
1536                 if(self.team_forced > 0)
1537                         self.team_forced = 0;
1538
1539         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1540
1541         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1542                 self.classname = "observer";
1543         } else {
1544                 if(teams_matter)
1545                 {
1546                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1547                         {
1548                                 self.classname = "player";
1549                                 campaign_bots_may_start = 1;
1550                         }
1551                         else
1552                         {
1553                                 self.classname = "observer"; // do it anyway
1554                         }
1555                 }
1556                 else
1557                 {
1558                         self.classname = "player";
1559                         campaign_bots_may_start = 1;
1560                 }
1561         }
1562
1563         self.playerid = (playerid_last = playerid_last + 1);
1564
1565         if(cvar("sv_eventlog"))
1566                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1567
1568         LogTeamchange(self.playerid, self.team, 1);
1569
1570         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1571
1572         self.netname_previous = strzone(self.netname);
1573
1574         bprint("^4", self.netname, "^4 connected");
1575
1576         if(self.classname != "observer" && (g_domination || g_ctf))
1577                 bprint(" and joined the ", ColoredTeamName(self.team));
1578
1579         bprint("\n");
1580
1581         self.welcomemessage_time = 0;
1582
1583         stuffcmd(self, strcat(clientstuff, "\n"));
1584         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1585         stuffcmd(self, "cl_particles_reloadeffects\n");
1586
1587         FixClientCvars(self);
1588
1589         // spawnfunc_waypoint sprites
1590         WaypointSprite_InitClient(self);
1591
1592         // Wazat's grappling hook
1593         SetGrappleHookBindings();
1594
1595         // get autoswitch state from player when he toggles it
1596         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1597
1598         // get version info from player
1599         stuffcmd(self, "cmd clientversion $gameversion\n");
1600
1601         // get other cvars from player
1602         GetCvars(0);
1603
1604         // set cvar for team scoreboard
1605         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1606
1607         // notify about available teams
1608         if(teams_matter)
1609         {
1610                 CheckAllowedTeams(self);
1611                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1612                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1613         }
1614         else
1615                 stuffcmd(self, "set _teams_available 0\n");
1616
1617         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1618
1619         if(g_arena || g_ca)
1620         {
1621                 self.classname = "observer";
1622                 if(g_arena)
1623                         Spawnqueue_Insert(self);
1624         }
1625         /*else if(g_ctf)
1626         {
1627                 ctf_clientconnect();
1628         }*/
1629
1630         if(teams_matter || radar_showennemies)
1631                 attach_entcs();
1632
1633         bot_relinkplayerlist();
1634
1635         self.spectatortime = time;
1636         if(blockSpectators)
1637         {
1638                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1639         }
1640
1641         self.jointime = time;
1642         self.allowedTimeouts = cvar("sv_timeout_number");
1643
1644         if(clienttype(self) == CLIENTTYPE_REAL)
1645         {
1646                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1647                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1648         }
1649
1650         if(g_lms)
1651         {
1652                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1653                 {
1654                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1655                         self.frags = FRAGS_SPECTATOR;
1656                 }
1657         }
1658
1659         if(!sv_foginterval && world.fog != "")
1660                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1661
1662         SoundEntity_Attach(self);
1663
1664         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1665         {
1666                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1667                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1668         }
1669         else
1670                 self.hitplotfh = -1;
1671
1672         if(g_race || g_cts) {
1673                 string rr;
1674                 if(g_cts)
1675                         rr = CTS_RECORD;
1676                 else
1677                         rr = RACE_RECORD;
1678                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1679
1680                 msg_entity = self;
1681                 race_send_recordtime(MSG_ONE);
1682                 race_send_speedaward(MSG_ONE);
1683
1684                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1685                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1686                 race_send_speedaward_alltimebest(MSG_ONE);
1687
1688                 float i;
1689                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1690                         race_SendRankings(i, 0, 0, MSG_ONE);
1691                 }
1692         }
1693         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1694                 send_CSQC_teamnagger();
1695
1696         send_CSQC_cr_maxbullets(self);
1697
1698         CheatInitClient();
1699 }
1700
1701 /*
1702 =============
1703 ClientDisconnect
1704
1705 Called when a client disconnects from the server
1706 =============
1707 */
1708 .entity chatbubbleentity;
1709 .entity teambubbleentity;
1710 void ReadyCount();
1711 void ClientDisconnect (void)
1712 {
1713         if not(self.flags & FL_CLIENT)
1714         {
1715                 print("Warning: ClientDisconnect without ClientConnect\n");
1716                 return;
1717         }
1718
1719         CheatShutdownClient();
1720
1721         if(self.hitplotfh >= 0)
1722         {
1723                 fclose(self.hitplotfh);
1724                 self.hitplotfh = -1;
1725         }
1726
1727         anticheat_report();
1728         anticheat_shutdown();
1729
1730         playerdemo_shutdown();
1731
1732         bot_clientdisconnect();
1733
1734         if(self.entcs)
1735                 detach_entcs();
1736
1737         if(cvar("sv_eventlog"))
1738                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1739         bprint ("^4",self.netname);
1740         bprint ("^4 disconnected\n");
1741
1742         SoundEntity_Detach(self);
1743
1744         DropAllRunes(self);
1745         MUTATOR_CALLHOOK(ClientDisconnect);
1746
1747         Portal_ClearAll(self);
1748
1749         if(self.flagcarried)
1750                 DropFlag(self.flagcarried, world, world);
1751         if(self.ballcarried)
1752                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1753
1754         // Here, everything has been done that requires this player to be a client.
1755
1756         self.flags &~= FL_CLIENT;
1757
1758         if (self.chatbubbleentity)
1759                 remove (self.chatbubbleentity);
1760
1761         if (self.teambubbleentity)
1762                 remove (self.teambubbleentity);
1763
1764         if (self.killindicator)
1765                 remove (self.killindicator);
1766
1767         WaypointSprite_PlayerGone();
1768
1769         bot_relinkplayerlist();
1770
1771         if(g_arena)
1772         {
1773                 Spawnqueue_Unmark(self);
1774                 Spawnqueue_Remove(self);
1775         }
1776
1777         ClientData_Detach();
1778         PlayerScore_Detach(self);
1779
1780         if(self.netname_previous)
1781                 strunzone(self.netname_previous);
1782         if(self.clientstatus)
1783                 strunzone(self.clientstatus);
1784         if(self.weaponorder_byimpulse)
1785                 strunzone(self.weaponorder_byimpulse);
1786
1787         ClearPlayerSounds();
1788
1789         if(self.personal)
1790                 remove(self.personal);
1791
1792         self.playerid = 0;
1793         ReadyCount();
1794
1795         // free cvars
1796         GetCvars(-1);
1797 }
1798
1799 .float BUTTON_CHAT;
1800 void ChatBubbleThink()
1801 {
1802         self.nextthink = time;
1803         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1804         {
1805                 if(self.owner) // but why can that ever be world?
1806                         self.owner.chatbubbleentity = world;
1807                 remove(self);
1808                 return;
1809         }
1810         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1811 #ifdef TETRIS
1812                 || self.owner.tetris_on
1813 #endif
1814         )
1815                 self.model = self.mdl;
1816         else
1817                 self.model = "";
1818 };
1819
1820 void UpdateChatBubble()
1821 {
1822         if (!self.modelindex)
1823                 return;
1824         // spawn a chatbubble entity if needed
1825         if (!self.chatbubbleentity)
1826         {
1827                 self.chatbubbleentity = spawn();
1828                 self.chatbubbleentity.owner = self;
1829                 self.chatbubbleentity.exteriormodeltoclient = self;
1830                 self.chatbubbleentity.think = ChatBubbleThink;
1831                 self.chatbubbleentity.nextthink = time;
1832                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1833                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1834                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1835                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1836                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1837                 self.chatbubbleentity.model = "";
1838                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1839         }
1840 }
1841
1842
1843 void TeamBubbleThink()
1844 {
1845         self.nextthink = time;
1846         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1847         {
1848                 if(self.owner) // but why can that ever be world?
1849                         self.owner.teambubbleentity = world;
1850                 remove(self);
1851                 return;
1852         }
1853 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1854         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1855                 self.model = "";
1856         else
1857                 self.model = self.mdl;
1858
1859 };
1860
1861 float TeamBubble_customizeentityforclient()
1862 {
1863         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1864 }
1865
1866 void UpdateTeamBubble()
1867 {
1868         if (!self.modelindex || !teams_matter)
1869                 return;
1870         // spawn a teambubble entity if needed
1871         if (!self.teambubbleentity && teams_matter)
1872         {
1873                 self.teambubbleentity = spawn();
1874                 self.teambubbleentity.owner = self;
1875                 self.teambubbleentity.exteriormodeltoclient = self;
1876                 self.teambubbleentity.think = TeamBubbleThink;
1877                 self.teambubbleentity.nextthink = time;
1878                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1879 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1880                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1881                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1882                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1883                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1884                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1885                 self.teambubbleentity.effects = EF_LOWPRECISION;
1886         }
1887 }
1888
1889 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1890 // added to the model skins
1891 /*void UpdateColorModHack()
1892 {
1893         local float c;
1894         c = self.clientcolors & 15;
1895         // LordHavoc: only bothering to support white, green, red, yellow, blue
1896              if (!teams_matter) self.colormod = '0 0 0';
1897         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1898         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1899         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1900         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1901         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1902         else self.colormod = '1 1 1';
1903 };*/
1904
1905 .float oldcolormap;
1906 void respawn(void)
1907 {
1908         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1909         {
1910                 self.solid = SOLID_NOT;
1911                 self.takedamage = DAMAGE_NO;
1912                 self.movetype = MOVETYPE_FLY;
1913                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1914                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1915                 self.effects |= EF_ADDITIVE;
1916                 self.oldcolormap = self.colormap;
1917                 self.colormap = 512;
1918                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1919                 if(cvar("g_respawn_ghosts_maxtime"))
1920                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1921         }
1922
1923         CopyBody(1);
1924         self.effects |= EF_NODRAW; // prevent another CopyBody
1925         if(self.oldcolormap)
1926         {
1927                 self.colormap = self.oldcolormap;
1928                 self.oldcolormap = 0;
1929         }
1930         PutClientInServer();
1931 }
1932
1933 void play_countdown(float finished, string samp)
1934 {
1935         if(clienttype(self) == CLIENTTYPE_REAL)
1936                 if(floor(finished - time - frametime) != floor(finished - time))
1937                         if(finished - time < 6)
1938                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1939 }
1940
1941 /**
1942  * When sv_timeout is used this function returs strings like
1943  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1944  * Called by centerprint functions
1945  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1946  */
1947 string getTimeoutText(float addOneSecond) {
1948         if (!cvar("sv_timeout") || !timeoutStatus)
1949                 return "";
1950
1951         local string retStr;
1952         if (timeoutStatus == 1) {
1953                 if (addOneSecond == 1) {
1954                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1955                 }
1956                 else {
1957                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1958                 }
1959                 return retStr;
1960         }
1961         else if (timeoutStatus == 2) {
1962                 if (addOneSecond) {
1963                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1964                         //don't show messages like "Timeout ends in 0 seconds"...
1965                         if ((remainingTimeoutTime + 1) > 0)
1966                                 return retStr;
1967                         else
1968                                 return "";
1969                 }
1970                 else {
1971                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1972                         //don't show messages like "Timeout ends in 0 seconds"...
1973                         if (remainingTimeoutTime > 0)
1974                                 return retStr;
1975                         else
1976                                 return "";
1977                 }
1978         }
1979         else return "";
1980 }
1981
1982 void player_powerups (void)
1983 {
1984         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1985         {
1986                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1987                 self.modelflags |= MF_ROCKET;
1988         }
1989         else
1990         {
1991                 SoundEntity_StopSound(self, CHAN_PLAYER);
1992                 self.modelflags &~= MF_ROCKET;
1993         }
1994
1995         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1996
1997         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1998                 return;
1999         
2000         Fire_ApplyDamage(self);
2001         Fire_ApplyEffect(self);
2002
2003         if (g_minstagib)
2004         {
2005                 self.effects |= EF_FULLBRIGHT;
2006
2007                 if (self.items & IT_STRENGTH)
2008                 {
2009                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2010                         if (time > self.strength_finished)
2011                         {
2012                                 self.alpha = default_player_alpha;
2013                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2014                                 self.items &~= IT_STRENGTH;
2015                                 sprint(self, "^3Invisibility has worn off\n");
2016                         }
2017                 }
2018                 else
2019                 {
2020                         if (time < self.strength_finished)
2021                         {
2022                                 self.alpha = g_minstagib_invis_alpha;
2023                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2024                                 self.items |= IT_STRENGTH;
2025                                 sprint(self, "^3You are invisible\n");
2026                         }
2027                 }
2028
2029                 if (self.items & IT_INVINCIBLE)
2030                 {
2031                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2032                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2033                         {
2034                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2035                                 sprint(self, "^3Speed has worn off\n");
2036                         }
2037                 }
2038                 else
2039                 {
2040                         if (time < self.invincible_finished)
2041                         {
2042                                 self.items = self.items | IT_INVINCIBLE;
2043                                 sprint(self, "^3You are on speed\n");
2044                         }
2045                 }
2046                 return;
2047         }
2048
2049         if (self.items & IT_STRENGTH)
2050         {
2051                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2052                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2053                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2054                 {
2055                         self.items = self.items - (self.items & IT_STRENGTH);
2056                         sprint(self, "^3Strength has worn off\n");
2057                 }
2058         }
2059         else
2060         {
2061                 if (time < self.strength_finished)
2062                 {
2063                         self.items = self.items | IT_STRENGTH;
2064                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2065                 }
2066         }
2067         if (self.items & IT_INVINCIBLE)
2068         {
2069                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2070                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2071                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2072                 {
2073                         self.items = self.items - (self.items & IT_INVINCIBLE);
2074                         sprint(self, "^3Shield has worn off\n");
2075                 }
2076         }
2077         else
2078         {
2079                 if (time < self.invincible_finished)
2080                 {
2081                         self.items = self.items | IT_INVINCIBLE;
2082                         sprint(self, "^3Shield surrounds you\n");
2083                 }
2084         }
2085
2086         if(cvar("g_nodepthtestplayers"))
2087                 self.effects = self.effects | EF_NODEPTHTEST;
2088
2089         if(cvar("g_fullbrightplayers"))
2090                 self.effects = self.effects | EF_FULLBRIGHT;
2091
2092         // midair gamemode: damage only while in the air
2093         // if in midair mode, being on ground grants temporary invulnerability
2094         // (this is so that multishot weapon don't clear the ground flag on the
2095         // first damage in the frame, leaving the player vulnerable to the
2096         // remaining hits in the same frame)
2097         if (self.flags & FL_ONGROUND)
2098         if (g_midair)
2099                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2100
2101         if (time >= game_starttime)
2102         if (time < self.spawnshieldtime)
2103                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2104 }
2105
2106 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2107 {
2108         if(current > stable)
2109                 return current;
2110         else if(current > stable - 0.25) // when close enough, "snap"
2111                 return stable;
2112         else
2113                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2114 }
2115
2116 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2117 {
2118         if(current < stable)
2119                 return current;
2120         else if(current < stable + 0.25) // when close enough, "snap"
2121                 return stable;
2122         else
2123                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2124 }
2125
2126 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2127 {
2128         if(current > rotstable)
2129         {
2130                 if(rotframetime > 0)
2131                 {
2132                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2133                         current = max(rotstable, current - rotlinear * rotframetime);
2134                 }
2135         }
2136         else if(current < regenstable)
2137         {
2138                 if(regenframetime > 0)
2139                 {
2140                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2141                         current = min(regenstable, current + regenlinear * regenframetime);
2142                 }
2143         }
2144
2145         if(current > limit)
2146                 current = limit;
2147
2148         return current;
2149 }
2150
2151 void player_regen (void)
2152 {
2153         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2154         maxh = cvar("g_balance_health_rotstable");
2155         maxa = cvar("g_balance_armor_rotstable");
2156         maxf = cvar("g_balance_fuel_rotstable");
2157         minh = cvar("g_balance_health_regenstable");
2158         mina = cvar("g_balance_armor_regenstable");
2159         minf = cvar("g_balance_fuel_regenstable");
2160         limith = cvar("g_balance_health_limit");
2161         limita = cvar("g_balance_armor_limit");
2162         limitf = cvar("g_balance_fuel_limit");
2163
2164         max_mod = regen_mod = rot_mod = limit_mod = 1;
2165
2166         if (self.runes & RUNE_REGEN)
2167         {
2168                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2169                 {
2170                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2171                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2172                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2173                 }
2174                 else
2175                 {
2176                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2177                         max_mod = cvar("g_balance_rune_regen_hpmod");
2178                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2179                 }
2180         }
2181         else if (self.runes & CURSE_VENOM)
2182         {
2183                 max_mod = cvar("g_balance_curse_venom_hpmod");
2184                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2185                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2186                 else
2187                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2188                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2189                 //if (!self.runes & RUNE_REGEN)
2190                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2191         }
2192         maxh = maxh * max_mod;
2193         //maxa = maxa * max_mod;
2194         //maxf = maxf * max_mod;
2195         minh = minh * max_mod;
2196         //mina = mina * max_mod;
2197         //minf = minf * max_mod;
2198         limith = limith * limit_mod;
2199         limita = limita * limit_mod;
2200         //limitf = limitf * limit_mod;
2201
2202         if(g_lms && g_ca)
2203                 rot_mod = 0;
2204
2205         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2206         {
2207                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2208                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2209
2210                 // if player rotted to death...  die!
2211                 if(self.health < 1)
2212                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2213         }
2214
2215         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2216                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2217 }
2218
2219 float zoomstate_set;
2220 void SetZoomState(float z)
2221 {
2222         if(z != self.zoomstate)
2223         {
2224                 self.zoomstate = z;
2225                 ClientData_Touch(self);
2226         }
2227         zoomstate_set = 1;
2228 }
2229
2230 void GetPressedKeys(void) {
2231         MUTATOR_CALLHOOK(GetPressedKeys);
2232         if (self.movement_x > 0) // get if movement keys are pressed
2233         {       // forward key pressed
2234                 self.pressedkeys |= KEY_FORWARD;
2235                 self.pressedkeys &~= KEY_BACKWARD;
2236         }
2237         else if (self.movement_x < 0)
2238         {       // backward key pressed
2239                 self.pressedkeys |= KEY_BACKWARD;
2240                 self.pressedkeys &~= KEY_FORWARD;
2241         }
2242         else
2243         {       // no x input
2244                 self.pressedkeys &~= KEY_FORWARD;
2245                 self.pressedkeys &~= KEY_BACKWARD;
2246         }
2247
2248         if (self.movement_y > 0)
2249         {       // right key pressed
2250                 self.pressedkeys |= KEY_RIGHT;
2251                 self.pressedkeys &~= KEY_LEFT;
2252         }
2253         else if (self.movement_y < 0)
2254         {       // left key pressed
2255                 self.pressedkeys |= KEY_LEFT;
2256                 self.pressedkeys &~= KEY_RIGHT;
2257         }
2258         else
2259         {       // no y input
2260                 self.pressedkeys &~= KEY_RIGHT;
2261                 self.pressedkeys &~= KEY_LEFT;
2262         }
2263
2264         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2265                 self.pressedkeys |= KEY_JUMP;
2266         else
2267                 self.pressedkeys &~= KEY_JUMP;
2268         if (self.BUTTON_CROUCH)
2269                 self.pressedkeys |= KEY_CROUCH;
2270         else
2271                 self.pressedkeys &~= KEY_CROUCH;
2272 }
2273
2274 void update_stats (float number, float hit, float fired) {
2275 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2276 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2277
2278         if(number) {
2279                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2280                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2281         } else {
2282                 self.stat_hit = hit * sv_accuracy_data_share;
2283                 self.stat_fired = fired * sv_accuracy_data_share;
2284         }
2285 }
2286
2287 /*
2288 ======================
2289 spectate mode routines
2290 ======================
2291 */
2292
2293 .float weapon_count;
2294 void SpectateCopy(entity spectatee) {
2295         if(spectatee.weapon_count < WEP_LAST) {
2296                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2297                 spectatee.weapon_count ++;
2298         } else
2299                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2300
2301         other = spectatee;
2302         MUTATOR_CALLHOOK(SpectateCopy);
2303         self.armortype = spectatee.armortype;
2304         self.armorvalue = spectatee.armorvalue;
2305         self.ammo_cells = spectatee.ammo_cells;
2306         self.ammo_shells = spectatee.ammo_shells;
2307         self.ammo_nails = spectatee.ammo_nails;
2308         self.ammo_rockets = spectatee.ammo_rockets;
2309         self.ammo_fuel = spectatee.ammo_fuel;
2310         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2311         self.health = spectatee.health;
2312         self.impulse = 0;
2313         self.items = spectatee.items;
2314         self.last_pickup = spectatee.last_pickup;
2315         self.metertime = spectatee.metertime;
2316         self.strength_finished = spectatee.strength_finished;
2317         self.invincible_finished = spectatee.invincible_finished;
2318         self.pressedkeys = spectatee.pressedkeys;
2319         self.weapons = spectatee.weapons;
2320         self.switchweapon = spectatee.switchweapon;
2321         self.weapon = spectatee.weapon;
2322         self.punchangle = spectatee.punchangle;
2323         self.view_ofs = spectatee.view_ofs;
2324         self.v_angle = spectatee.v_angle;
2325         self.velocity = spectatee.velocity;
2326         self.dmg_take = spectatee.dmg_take;
2327         self.dmg_save = spectatee.dmg_save;
2328         self.dmg_inflictor = spectatee.dmg_inflictor;
2329         self.angles = spectatee.v_angle;
2330         self.fixangle = TRUE;
2331         setorigin(self, spectatee.origin);
2332         setsize(self, spectatee.mins, spectatee.maxs);
2333         SetZoomState(spectatee.zoomstate);
2334
2335         anticheat_spectatecopy(spectatee);
2336 }
2337
2338 float SpectateUpdate() {
2339         if(!self.enemy)
2340                 return 0;
2341
2342         if (self == self.enemy)
2343                 return 0;
2344
2345         if(self.enemy.classname != "player")
2346                 return 0;
2347
2348         SpectateCopy(self.enemy);
2349
2350         return 1;
2351 }
2352
2353 float SpectateNext() {
2354         other = find(self.enemy, classname, "player");
2355
2356         if (!other)
2357                 other = find(other, classname, "player");
2358
2359         if (other)
2360                 self.enemy = other;
2361
2362         if(self.enemy.classname == "player") {
2363                 msg_entity = self;
2364                 WriteByte(MSG_ONE, SVC_SETVIEW);
2365                 WriteEntity(MSG_ONE, self.enemy);
2366                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2367                 self.movetype = MOVETYPE_NONE;
2368
2369                 self.enemy.weapon_count = 0;
2370
2371                 if(!SpectateUpdate())
2372                         PutObserverInServer();
2373
2374                 return 1;
2375         } else {
2376                 return 0;
2377         }
2378 }
2379
2380 /*
2381 =============
2382 ShowRespawnCountdown()
2383
2384 Update a respawn countdown display.
2385 =============
2386 */
2387 void ShowRespawnCountdown()
2388 {
2389         float number;
2390         if(self.deadflag == DEAD_NO) // just respawned?
2391                 return;
2392         else
2393         {
2394                 number = ceil(self.death_time - time);
2395                 if(number <= 0)
2396                         return;
2397                 if(number <= self.respawn_countdown)
2398                 {
2399                         self.respawn_countdown = number - 1;
2400                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2401                                 AnnounceTo(self, strcat(ftos(number), ""));
2402                 }
2403         }
2404 }
2405
2406 void LeaveSpectatorMode()
2407 {
2408         if(isJoinAllowed()) {
2409                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2410                         self.classname = "player";
2411
2412                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2413                                 JoinBestTeam(self, FALSE, TRUE);
2414
2415                         if(cvar("g_campaign"))
2416                                 campaign_bots_may_start = 1;
2417
2418                         self.stat_count = WEP_LAST;
2419
2420                         PutClientInServer();
2421
2422                         if(self.classname == "player")
2423                                 bprint ("^4", self.netname, "^4 is playing now\n");
2424
2425                         if(!cvar("g_campaign"))
2426                                 centerprint(self,""); // clear MOTD
2427
2428                         return;
2429                 } else {
2430                         if (g_ca && self.caplayer) {
2431                         }       // do nothing
2432                         else
2433                                 stuffcmd(self,"menu_showteamselect\n");
2434                         return;
2435                 }
2436         }
2437         else {
2438                 //player may not join because of g_maxplayers is set
2439                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2440         }
2441 }
2442
2443 /**
2444  * Determines whether the player is allowed to join. This depends on cvar
2445  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2446  * it checks whether the number of currently playing players exceeds g_maxplayers.
2447  * @return bool TRUE if the player is allowed to join, false otherwise
2448  */
2449 float isJoinAllowed() {
2450         if(self.team_forced < 0)
2451                 return FALSE; // forced spectators can never join
2452
2453         if (!cvar("g_maxplayers"))
2454                 return TRUE;
2455
2456         local entity e;
2457         local float currentlyPlaying;
2458         FOR_EACH_REALPLAYER(e) {
2459                 if(e.classname == "player")
2460                         currentlyPlaying += 1;
2461         }
2462         if(currentlyPlaying < cvar("g_maxplayers"))
2463                 return TRUE;
2464
2465         return FALSE;
2466 }
2467
2468 /**
2469  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2470  * g_maxplayers_spectator_blocktime seconds
2471  */
2472 void checkSpectatorBlock() {
2473         if(self.classname == "spectator" || self.classname == "observer") {
2474                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2475                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2476                         dropclient(self);
2477                 }
2478         }
2479 }
2480
2481 void ObserverThink()
2482 {
2483         if (self.flags & FL_JUMPRELEASED) {
2484                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2485                         self.welcomemessage_time = 0;
2486                         self.flags &~= FL_JUMPRELEASED;
2487                         self.flags |= FL_SPAWNING;
2488                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2489                         self.welcomemessage_time = 0;
2490                         self.flags &~= FL_JUMPRELEASED;
2491                         if(SpectateNext() == 1) {
2492                                 self.classname = "spectator";
2493                         }
2494                 }
2495         } else {
2496                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2497                         self.flags |= FL_JUMPRELEASED;
2498                         if(self.flags & FL_SPAWNING)
2499                         {
2500                                 self.flags &~= FL_SPAWNING;
2501                                 LeaveSpectatorMode();
2502                                 return;
2503                         }
2504                 }
2505         }
2506         PrintWelcomeMessage(self);
2507 }
2508
2509 void SpectatorThink()
2510 {
2511         if (self.flags & FL_JUMPRELEASED) {
2512                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2513                         self.welcomemessage_time = 0;
2514                         self.flags &~= FL_JUMPRELEASED;
2515                         self.flags |= FL_SPAWNING;
2516                 } else if(self.BUTTON_ATCK) {
2517                         self.welcomemessage_time = 0;
2518                         self.flags &~= FL_JUMPRELEASED;
2519                         if(SpectateNext() == 1) {
2520                                 self.classname = "spectator";
2521                         } else {
2522                                 self.classname = "observer";
2523                                 self.stat_count = WEP_LAST;
2524                                 PutClientInServer();
2525                         }
2526                 } else if (self.BUTTON_ATCK2) {
2527                         self.welcomemessage_time = 0;
2528                         self.flags &~= FL_JUMPRELEASED;
2529                         self.classname = "observer";
2530                         self.stat_count = WEP_LAST;
2531                         PutClientInServer();
2532                 } else {
2533                         if(!SpectateUpdate())
2534                                 PutObserverInServer();
2535                 }
2536         } else {
2537                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2538                         self.flags |= FL_JUMPRELEASED;
2539                         if(self.flags & FL_SPAWNING)
2540                         {
2541                                 self.flags &~= FL_SPAWNING;
2542                                 LeaveSpectatorMode();
2543                                 return;
2544                         }
2545                 }
2546         }
2547
2548         PrintWelcomeMessage(self);
2549         self.flags |= FL_CLIENT | FL_NOTARGET;
2550 }
2551
2552 .float touchexplode_time;
2553
2554 /*
2555 =============
2556 PlayerPreThink
2557
2558 Called every frame for each client before the physics are run
2559 =============
2560 */
2561 void() ctf_setstatus;
2562 void() nexball_setstatus;
2563 .float items_added;
2564 void PlayerPreThink (void)
2565 {
2566         self.stat_game_starttime = game_starttime;
2567         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2568         self.stat_leadlimit = cvar("leadlimit");
2569
2570         if(frametime)
2571         {
2572                 // physics frames: update anticheat stuff
2573                 anticheat_prethink();
2574         }
2575
2576         if(blockSpectators && frametime)
2577                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2578                 checkSpectatorBlock();
2579
2580         zoomstate_set = 0;
2581
2582         if(self.netname_previous != self.netname)
2583         {
2584                 if(cvar("sv_eventlog"))
2585                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2586                 if(self.netname_previous)
2587                         strunzone(self.netname_previous);
2588                 self.netname_previous = strzone(self.netname);
2589         }
2590
2591         // version nagging
2592         if(self.version_nagtime)
2593                 if(self.cvar_g_xonoticversion)
2594                         if(time > self.version_nagtime)
2595                         {
2596                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2597                                 {
2598                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2599                                         {
2600                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2601                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2602                                         }
2603                                         else
2604                                         {
2605                                                 float r;
2606                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2607                                                 if(r < 0)
2608                                                 {
2609                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2610                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2611                                                 }
2612                                                 else if(r > 0)
2613                                                 {
2614                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2615                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2616                                                 }
2617                                         }
2618                                 }
2619                                 self.version_nagtime = 0;
2620                         }
2621
2622         // GOD MODE info
2623         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2624         {
2625                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2626                 self.max_armorvalue = 0;
2627         }
2628
2629 #ifdef TETRIS
2630         if (TetrisPreFrame())
2631                 return;
2632 #endif
2633
2634         MUTATOR_CALLHOOK(PlayerPreThink);
2635
2636         if(self.classname == "player") {
2637 //              if(self.netname == "Wazat")
2638 //                      bprint(self.classname, "\n");
2639
2640                 CheckRules_Player();
2641
2642                 PrintWelcomeMessage(self);
2643
2644                 if (intermission_running)
2645                 {
2646                         IntermissionThink ();   // otherwise a button could be missed between
2647                         return;                                 // the think tics
2648                 }
2649
2650                 if(self.teleport_time)
2651                 if(time > self.teleport_time)
2652                 {
2653                         self.teleport_time = 0;
2654                         self.effects = self.effects - (self.effects & EF_NODRAW);
2655                 }
2656
2657                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2658                         UpdateSelectedPlayer();
2659
2660                 //don't allow the player to turn around while game is paused!
2661                 if(timeoutStatus == 2) {
2662                         self.v_angle = self.lastV_angle;
2663                         self.angles = self.lastV_angle;
2664                         self.fixangle = TRUE;
2665                 }
2666
2667                 if(frametime)
2668                 {
2669                         if(self.health <= 0 && cvar("g_deathglow"))
2670                         {
2671                                 if(self.glowmod_x > 0)
2672                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2673                                 else
2674                                         self.glowmod_x = -1;
2675                                 if(self.glowmod_y > 0)
2676                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2677                                 else
2678                                         self.glowmod_y = -1;
2679                                 if(self.glowmod_z > 0)
2680                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2681                                 else
2682                                         self.glowmod_z = -1;
2683                         }
2684                         else
2685                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2686                         player_powerups();
2687                 }
2688
2689                 if (self.deadflag != DEAD_NO)
2690                 {
2691                         float button_pressed, force_respawn;
2692                         if(self.personal && g_race_qualifying)
2693                         {
2694                                 if(time > self.death_time)
2695                                 {
2696                                         self.death_time = time + 1; // only retry once a second
2697                                         respawn();
2698                                         self.impulse = 141;
2699                                 }
2700                         }
2701                         else
2702                         {
2703                                 if(frametime)
2704                                         player_anim();
2705                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2706                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2707                                 if (self.deadflag == DEAD_DYING)
2708                                 {
2709                                         if(force_respawn)
2710                                                 self.deadflag = DEAD_RESPAWNING;
2711                                         else if(!button_pressed)
2712                                                 self.deadflag = DEAD_DEAD;
2713                                 }
2714                                 else if (self.deadflag == DEAD_DEAD)
2715                                 {
2716                                         if(button_pressed)
2717                                                 self.deadflag = DEAD_RESPAWNABLE;
2718                                 }
2719                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2720                                 {
2721                                         if(!button_pressed)
2722                                                 self.deadflag = DEAD_RESPAWNING;
2723                                 }
2724                                 else if (self.deadflag == DEAD_RESPAWNING)
2725                                 {
2726                                         if(time > self.death_time)
2727                                         {
2728                                                 self.death_time = time + 1; // only retry once a second
2729                                                 respawn();
2730                                         }
2731                                 }
2732                                 ShowRespawnCountdown();
2733                         }
2734                         return;
2735                 }
2736
2737                 if(g_touchexplode)
2738                 if(time > self.touchexplode_time)
2739                 if(self.classname == "player")
2740                 if(self.deadflag == DEAD_NO)
2741                 if not(IS_INDEPENDENT_PLAYER(self))
2742                 FOR_EACH_PLAYER(other) if(self != other)
2743                 {
2744                         if(time > other.touchexplode_time)
2745                         if(other.deadflag == DEAD_NO)
2746                         if not(IS_INDEPENDENT_PLAYER(other))
2747                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2748                         {
2749                                 PlayerTouchExplode(self, other);
2750                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2751                         }
2752                 }
2753
2754                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2755                 {
2756                         vector dist;
2757
2758                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2759                         dist = self.prevorigin - self.origin;
2760                         dist_z = 0;
2761                         self.lms_traveled_distance += fabs(vlen(dist));
2762
2763                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2764                         {
2765                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2766                                 self.lms_traveled_distance = 0;
2767                         }
2768
2769                         if(time > self.lms_nextcheck)
2770                         {
2771                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2772                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2773                                 {
2774                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2775                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2776                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2777                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2778                                 }
2779                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2780                                 self.lms_traveled_distance = 0;
2781                         }
2782                 }
2783
2784                 self.prevorigin = self.origin;
2785
2786                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2787                 {
2788                         if (!self.crouch)
2789                         {
2790                                 self.crouch = TRUE;
2791                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2792                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2793                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2794                         }
2795                 }
2796                 else
2797                 {
2798                         if (self.crouch)
2799                         {
2800                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2801                                 if (!trace_startsolid)
2802                                 {
2803                                         self.crouch = FALSE;
2804                                         self.view_ofs = PL_VIEW_OFS;
2805                                         setsize (self, PL_MIN, PL_MAX);
2806                                 }
2807                         }
2808                 }
2809
2810                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2811                 {
2812                         if(self.bloodloss_timer < time)
2813                         {
2814                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2815                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2816                         }
2817                 }
2818
2819                 FixPlayermodel();
2820
2821                 GrapplingHookFrame();
2822
2823                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2824                 //if(frametime)
2825                 {
2826                         self.items &~= self.items_added;
2827
2828                         W_WeaponFrame();
2829
2830                         self.items_added = 0;
2831                         if(self.items & IT_JETPACK)
2832                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2833                                         self.items_added |= IT_FUEL;
2834
2835                         self.items |= self.items_added;
2836                 }
2837
2838                 player_regen();
2839
2840                 // rot nex charge to the charge limit
2841                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2842                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2843
2844                 if(frametime)
2845                         player_anim();
2846
2847                 if (g_minstagib)
2848                         minstagib_ammocheck();
2849
2850                 ctf_setstatus();
2851                 nexball_setstatus();
2852
2853                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2854
2855                 //self.angles_y=self.v_angle_y + 90;   // temp
2856         } else if(gameover) {
2857                 if (intermission_running)
2858                         IntermissionThink ();   // otherwise a button could be missed between
2859                 return;
2860         } else if(self.classname == "observer") {
2861                 ObserverThink();
2862         } else if(self.classname == "spectator") {
2863                 SpectatorThink();
2864         }
2865
2866         if(!zoomstate_set)
2867                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2868
2869         float oldspectatee_status;
2870         oldspectatee_status = self.spectatee_status;
2871         if(self.classname == "spectator")
2872                 self.spectatee_status = num_for_edict(self.enemy);
2873         else if(self.classname == "observer")
2874                 self.spectatee_status = num_for_edict(self);
2875         else
2876                 self.spectatee_status = 0;
2877         if(self.spectatee_status != oldspectatee_status)
2878         {
2879                 ClientData_Touch(self);
2880                 if(g_race || g_cts)
2881                         race_InitSpectator();
2882         }
2883
2884         if(self.teamkill_soundtime)
2885         if(time > self.teamkill_soundtime)
2886         {
2887                 self.teamkill_soundtime = 0;
2888
2889                 entity oldpusher, oldself;
2890
2891                 oldself = self; self = self.teamkill_soundsource;
2892                 oldpusher = self.pusher; self.pusher = oldself;
2893
2894                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2895
2896                 self.pusher = oldpusher;
2897                 self = oldself;
2898         }
2899
2900         if(self.taunt_soundtime)
2901         if(time > self.taunt_soundtime)
2902         {
2903                 self.taunt_soundtime = 0;
2904                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2905         }
2906
2907         target_voicescript_next(self);
2908 }
2909
2910 float isInvisibleString(string s)
2911 {
2912         float i, n, c;
2913         s = strdecolorize(s);
2914         for((i = 0), (n = strlen(s)); i < n; ++i)
2915         {
2916                 c = str2chr(s, i);
2917                 switch(c)
2918                 {
2919                         case 0:
2920                         case 32: // space
2921                                 break;
2922                         case 192: // charmap space
2923                                 if (!cvar("utf8_enable"))
2924                                         break;
2925                                 return FALSE;
2926                         case 160: // space in unicode fonts
2927                         case 0xE000 + 192: // utf8 charmap space
2928                                 if (cvar("utf8_enable"))
2929                                         break;
2930                         default:
2931                                 return FALSE;
2932                 }
2933         }
2934         return TRUE;
2935 }
2936
2937 /*
2938 =============
2939 PlayerPostThink
2940
2941 Called every frame for each client after the physics are run
2942 =============
2943 */
2944 .float idlekick_lasttimeleft;
2945 .entity showheadshotbbox;
2946 void showheadshotbbox_think()
2947 {
2948         if(self.owner.showheadshotbbox != self)
2949         {
2950                 remove(self);
2951                 return;
2952         }
2953         self.nextthink = time;
2954         setorigin(self, self.owner.origin);
2955         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2956 }
2957 void PlayerPostThink (void)
2958 {
2959         // Savage: Check for nameless players
2960         if (isInvisibleString(self.netname)) {
2961                 self.netname = "Player";
2962                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2963         }
2964
2965         // send the clients accuracy stats to the client
2966         if(self.stat_count > 0)
2967         if(frametime)
2968         {
2969                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2970                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2971                 self.stat_count -= 1;
2972         }
2973
2974         if(sv_maxidle && frametime)
2975         {
2976                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2977                 float timeleft;
2978                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2979                 if(timeleft <= 0)
2980                 {
2981                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2982                         AnnounceTo(self, "terminated");
2983                         dropclient(self);
2984                         return;
2985                 }
2986                 else if(timeleft <= 10)
2987                 {
2988                         if(timeleft != self.idlekick_lasttimeleft)
2989                         {
2990                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2991                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2992                         }
2993                 }
2994                 else
2995                 {
2996                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2997                 }
2998                 self.idlekick_lasttimeleft = timeleft;
2999         }
3000
3001 #ifdef TETRIS
3002         if(self.impulse == 100)
3003                 ImpulseCommands();
3004         if (TetrisPostFrame())
3005                 return;
3006 #endif
3007
3008         CheatFrame();
3009
3010         if(self.classname == "player") {
3011                 CheckRules_Player();
3012                 UpdateChatBubble();
3013                 UpdateTeamBubble();
3014                 if (self.impulse)
3015                         ImpulseCommands();
3016                 if (intermission_running)
3017                         return;         // intermission or finale
3018                 GetPressedKeys();
3019         } else if (self.classname == "observer") {
3020                 //do nothing
3021         } else if (self.classname == "spectator") {
3022                 //do nothing
3023         }
3024
3025         /*
3026         float i;
3027         for(i = 0; i < 1000; ++i)
3028         {
3029                 vector end;
3030                 end = self.origin + '0 0 1024' + 512 * randomvec();
3031                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3032                 if(trace_fraction < 1)
3033                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3034                 {
3035                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3036                         break;
3037                 }
3038         }
3039         */
3040
3041         Arena_Warmup();
3042
3043         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3044
3045         if(self.waypointsprite_attachedforcarrier)
3046                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3047         
3048         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3049         {
3050                 if(!self.showheadshotbbox)
3051                 {
3052                         self.showheadshotbbox = spawn();
3053                         self.showheadshotbbo