4afd34e7ccef7cbde855f98d014be20db686cdad
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 #include "cl_client.qh"
2
3 #include "anticheat.qh"
4 #include "cl_impulse.qh"
5 #include "cl_player.qh"
6 #include "ent_cs.qh"
7 #include "ipban.qh"
8 #include "miscfunctions.qh"
9 #include "portals.qh"
10 #include "teamplay.qh"
11 #include "playerdemo.qh"
12 #include "spawnpoints.qh"
13 #include "g_damage.qh"
14 #include "g_hook.qh"
15 #include "command/common.qh"
16 #include "cheats.qh"
17 #include "g_world.qh"
18 #include "race.qh"
19 #include "antilag.qh"
20 #include "campaign.qh"
21 #include "command/common.qh"
22
23 #include "bot/bot.qh"
24 #include "bot/navigation.qh"
25
26 #include "../common/vehicles/all.qh"
27
28 #include "weapons/hitplot.qh"
29 #include "weapons/weaponsystem.qh"
30
31 #include "../common/net_notice.qh"
32 #include "../common/physics.qh"
33
34 #include "../common/items/all.qc"
35
36 #include "../common/mutators/mutator/waypoints/all.qh"
37
38 #include "../common/triggers/subs.qh"
39 #include "../common/triggers/triggers.qh"
40 #include "../common/triggers/trigger/secret.qh"
41
42 #include "../common/minigames/sv_minigames.qh"
43
44 #include "../common/items/inventory.qh"
45
46 #include "../common/monsters/sv_monsters.qh"
47
48 #include "../warpzonelib/server.qh"
49
50
51 void send_CSQC_teamnagger() {
52         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
53         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
54 }
55
56 float ClientData_Send(entity to, int sf)
57 {SELFPARAM();
58         if(to != self.owner)
59         {
60                 error("wtf");
61                 return false;
62         }
63
64         entity e;
65
66         e = to;
67         if(IS_SPEC(to))
68                 e = to.enemy;
69
70         sf = 0;
71
72         if(e.race_completed)
73                 sf |= 1; // forced scoreboard
74         if(to.spectatee_status)
75                 sf |= 2; // spectator ent number follows
76         if(e.zoomstate)
77                 sf |= 4; // zoomed
78         if(e.porto_v_angle_held)
79                 sf |= 8; // angles held
80
81         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
82         WriteByte(MSG_ENTITY, sf);
83
84         if(sf & 2)
85                 WriteByte(MSG_ENTITY, to.spectatee_status);
86
87         if(sf & 8)
88         {
89                 WriteAngle(MSG_ENTITY, e.v_angle.x);
90                 WriteAngle(MSG_ENTITY, e.v_angle.y);
91         }
92
93         return true;
94 }
95
96 void ClientData_Attach()
97 {SELFPARAM();
98         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
99         self.clientdata.drawonlytoclient = self;
100         self.clientdata.owner = self;
101 }
102
103 void ClientData_Detach()
104 {SELFPARAM();
105         remove(self.clientdata);
106         self.clientdata = world;
107 }
108
109 void ClientData_Touch(entity e)
110 {
111         e.clientdata.SendFlags = 1;
112
113         // make it spectatable
114         entity e2;
115         FOR_EACH_REALCLIENT(e2)
116         {
117                 if(e2 != e)
118                         if(IS_SPEC(e2))
119                                 if(e2.enemy == e)
120                                         e2.clientdata.SendFlags = 1;
121         }
122 }
123
124 .string netname_previous;
125
126 void SetSpectator(entity player, entity spectatee);
127
128
129 /*
130 =============
131 CheckPlayerModel
132
133 Checks if the argument string can be a valid playermodel.
134 Returns a valid one in doubt.
135 =============
136 */
137 string FallbackPlayerModel;
138 string CheckPlayerModel(string plyermodel) {
139         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
140         {
141                 // note: we cannot summon Don Strunzone here, some player may
142                 // still have the model string set. In case anyone manages how
143                 // to change a cvar default, we'll have a small leak here.
144                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
145         }
146         // only in right path
147         if( substring(plyermodel,0,14) != "models/player/")
148                 return FallbackPlayerModel;
149         // only good file extensions
150         if(substring(plyermodel,-4,4) != ".zym")
151         if(substring(plyermodel,-4,4) != ".dpm")
152         if(substring(plyermodel,-4,4) != ".iqm")
153         if(substring(plyermodel,-4,4) != ".md3")
154         if(substring(plyermodel,-4,4) != ".psk")
155                 return FallbackPlayerModel;
156         // forbid the LOD models
157         if(substring(plyermodel, -9,5) == "_lod1")
158                 return FallbackPlayerModel;
159         if(substring(plyermodel, -9,5) == "_lod2")
160                 return FallbackPlayerModel;
161         if(plyermodel != strtolower(plyermodel))
162                 return FallbackPlayerModel;
163         // also, restrict to server models
164         if(autocvar_sv_servermodelsonly)
165         {
166                 if(!fexists(plyermodel))
167                         return FallbackPlayerModel;
168         }
169         return plyermodel;
170 }
171
172 void setplayermodel(entity e, string modelname)
173 {
174         precache_model(modelname);
175         _setmodel(e, modelname);
176         player_setupanimsformodel();
177         UpdatePlayerSounds();
178 }
179
180 /*
181 =============
182 PutObserverInServer
183
184 putting a client as observer in the server
185 =============
186 */
187 void FixPlayermodel();
188 void PutObserverInServer (void)
189 {SELFPARAM();
190         entity  spot;
191     self.hud = HUD_NORMAL;
192
193         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
194
195         spot = SelectSpawnPoint (true);
196         if(!spot)
197                 error("No spawnpoints for observers?!?\n");
198         RemoveGrapplingHook(self); // Wazat's Grappling Hook
199
200         if(IS_REAL_CLIENT(self))
201         {
202                 msg_entity = self;
203                 WriteByte(MSG_ONE, SVC_SETVIEW);
204                 WriteEntity(MSG_ONE, self);
205         }
206
207         self.frags = FRAGS_SPECTATOR;
208
209         MUTATOR_CALLHOOK(MakePlayerObserver);
210
211         Portal_ClearAll(self);
212
213         Unfreeze(self);
214
215         if(self.alivetime)
216         {
217                 if(!warmup_stage)
218                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
219                 self.alivetime = 0;
220         }
221
222         if(self.vehicle)
223                 vehicles_exit(VHEF_RELEASE);
224
225         WaypointSprite_PlayerDead();
226
227         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
228                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
229
230         if(self.killcount != -666)
231         {
232                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
233                 if(!intermission_running)
234                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
235                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
236
237                 if(self.just_joined == false) {
238                         LogTeamchange(self.playerid, -1, 4);
239                 } else
240                         self.just_joined = false;
241         }
242
243         PlayerScore_Clear(self); // clear scores when needed
244
245         accuracy_resend(self);
246
247         self.spectatortime = time;
248
249         self.classname = "observer";
250         self.iscreature = false;
251         self.teleportable = TELEPORT_SIMPLE;
252         self.damagedbycontents = false;
253         self.health = -666;
254         self.takedamage = DAMAGE_NO;
255         self.solid = SOLID_NOT;
256         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
257         self.flags = FL_CLIENT | FL_NOTARGET;
258         self.armorvalue = 666;
259         self.effects = 0;
260         self.armorvalue = autocvar_g_balance_armor_start;
261         self.pauserotarmor_finished = 0;
262         self.pauserothealth_finished = 0;
263         self.pauseregen_finished = 0;
264         self.damageforcescale = 0;
265         self.death_time = 0;
266         self.respawn_flags = 0;
267         self.respawn_time = 0;
268         self.stat_respawn_time = 0;
269         self.alpha = 0;
270         self.scale = 0;
271         self.fade_time = 0;
272         self.pain_frame = 0;
273         self.pain_finished = 0;
274         self.strength_finished = 0;
275         self.invincible_finished = 0;
276         self.superweapons_finished = 0;
277         self.pushltime = 0;
278         self.istypefrag = 0;
279         self.think = func_null;
280         self.nextthink = 0;
281         self.hook_time = 0;
282         self.deadflag = DEAD_NO;
283         self.angles = spot.angles;
284         self.angles_z = 0;
285         self.fixangle = true;
286         self.crouch = false;
287         self.revival_time = 0;
288
289         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
290         self.prevorigin = self.origin;
291         self.items = 0;
292         self.weapons = '0 0 0';
293         self.model = "";
294         FixPlayermodel();
295         setmodel(self, MDL_Null);
296         self.drawonlytoclient = self;
297
298         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
299         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
300
301         self.weapon = 0;
302         self.weaponname = "";
303         self.switchingweapon = 0;
304         self.weaponmodel = "";
305         self.weaponentity = world;
306         self.exteriorweaponentity = world;
307         self.killcount = -666;
308         self.velocity = '0 0 0';
309         self.avelocity = '0 0 0';
310         self.punchangle = '0 0 0';
311         self.punchvector = '0 0 0';
312         self.oldvelocity = self.velocity;
313         self.fire_endtime = -1;
314         self.event_damage = func_null;
315 }
316
317 .float model_randomizer;
318 void FixPlayermodel()
319 {SELFPARAM();
320         string defaultmodel;
321         float defaultskin, chmdl, oldskin, n, i;
322         vector m1, m2;
323
324         defaultmodel = "";
325         defaultskin = 0;
326         chmdl = false;
327
328         if(autocvar_sv_defaultcharacter)
329         {
330                 if(teamplay)
331                 {
332                         string s = Static_Team_ColorName_Lower(self.team);
333                         if (s != "neutral")
334                         {
335                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
336                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
337                         }
338                 }
339
340                 if(defaultmodel == "")
341                 {
342                         defaultmodel = autocvar_sv_defaultplayermodel;
343                         defaultskin = autocvar_sv_defaultplayerskin;
344                 }
345
346                 n = tokenize_console(defaultmodel);
347                 if(n > 0)
348                 {
349                         defaultmodel = argv(floor(n * self.model_randomizer));
350                         // However, do NOT randomize if the player-selected model is in the list.
351                         for (i = 0; i < n; ++i)
352                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
353                                         defaultmodel = argv(i);
354                 }
355
356                 i = strstrofs(defaultmodel, ":", 0);
357                 if(i >= 0)
358                 {
359                         defaultskin = stof(substring(defaultmodel, i+1, -1));
360                         defaultmodel = substring(defaultmodel, 0, i);
361                 }
362         }
363
364         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
365         defaultmodel = ret_string;
366         defaultskin = ret_int;
367
368         if(defaultmodel != "")
369         {
370                 if (defaultmodel != self.model)
371                 {
372                         m1 = self.mins;
373                         m2 = self.maxs;
374                         setplayermodel (self, defaultmodel);
375                         setsize (self, m1, m2);
376                         chmdl = true;
377                 }
378
379                 oldskin = self.skin;
380                 self.skin = defaultskin;
381         } else {
382                 if (self.playermodel != self.model || self.playermodel == "")
383                 {
384                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
385                         m1 = self.mins;
386                         m2 = self.maxs;
387                         setplayermodel (self, self.playermodel);
388                         setsize (self, m1, m2);
389                         chmdl = true;
390                 }
391
392                 oldskin = self.skin;
393                 self.skin = stof(self.playerskin);
394         }
395
396         if(chmdl || oldskin != self.skin) // model or skin has changed
397         {
398                 self.species = player_getspecies(); // update species
399                 UpdatePlayerSounds(); // update skin sounds
400         }
401
402         if(!teamplay)
403                 if(strlen(autocvar_sv_defaultplayercolors))
404                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
405                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
406 }
407
408
409 /** Called when a client spawns in the server */
410 void PutClientInServer()
411 {
412         SELFPARAM();
413         if(IS_BOT_CLIENT(self))
414                 self.classname = "player";
415         else if(IS_REAL_CLIENT(self))
416         {
417                 msg_entity = self;
418                 WriteByte(MSG_ONE, SVC_SETVIEW);
419                 WriteEntity(MSG_ONE, self);
420         }
421
422         SetSpectator(self, world);
423
424         // reset player keys
425         self.itemkeys = 0;
426
427         MUTATOR_CALLHOOK(PutClientInServer, self);
428
429         if(gameover)
430                 self.classname = "observer";
431
432         if(IS_PLAYER(self))
433         {
434                 entity spot;
435
436                 accuracy_resend(self);
437
438                 if(self.team < 0)
439                         JoinBestTeam(self, false, true);
440
441                 spot = SelectSpawnPoint (false);
442                 if(!spot)
443                 {
444                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
445                         return; // spawn failed
446                 }
447
448                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
449
450                 self.classname = "player";
451                 self.wasplayer = true;
452                 self.iscreature = true;
453                 self.teleportable = TELEPORT_NORMAL;
454                 self.damagedbycontents = true;
455                 self.movetype = MOVETYPE_WALK;
456                 self.solid = SOLID_SLIDEBOX;
457                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
458                 if(autocvar_g_playerclip_collisions)
459                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
460                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
461                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
462                 self.frags = FRAGS_PLAYER;
463                 if(INDEPENDENT_PLAYERS)
464                         MAKE_INDEPENDENT_PLAYER(self);
465                 self.flags = FL_CLIENT | FL_PICKUPITEMS;
466                 if(autocvar__notarget)
467                         self.flags |= FL_NOTARGET;
468                 self.takedamage = DAMAGE_AIM;
469                 self.effects = 0;
470                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
471                 self.air_finished = time + 12;
472                 self.dmg = 2;
473                 if(WEP_CVAR(vortex, charge))
474                 {
475                         if(WEP_CVAR_SEC(vortex, chargepool))
476                                 self.vortex_chargepool_ammo = 1;
477                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
478                 }
479
480                 if(warmup_stage)
481                 {
482                         self.ammo_shells = warmup_start_ammo_shells;
483                         self.ammo_nails = warmup_start_ammo_nails;
484                         self.ammo_rockets = warmup_start_ammo_rockets;
485                         self.ammo_cells = warmup_start_ammo_cells;
486                         self.ammo_plasma = warmup_start_ammo_plasma;
487                         self.ammo_fuel = warmup_start_ammo_fuel;
488                         self.health = warmup_start_health;
489                         self.armorvalue = warmup_start_armorvalue;
490                         self.weapons = WARMUP_START_WEAPONS;
491                 }
492                 else
493                 {
494                         self.ammo_shells = start_ammo_shells;
495                         self.ammo_nails = start_ammo_nails;
496                         self.ammo_rockets = start_ammo_rockets;
497                         self.ammo_cells = start_ammo_cells;
498                         self.ammo_plasma = start_ammo_plasma;
499                         self.ammo_fuel = start_ammo_fuel;
500                         self.health = start_health;
501                         self.armorvalue = start_armorvalue;
502                         self.weapons = start_weapons;
503                 }
504
505                 if(self.weapons & WEPSET_SUPERWEAPONS)
506                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
507                 else
508                         self.superweapons_finished = 0;
509
510                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
511                 {
512                         if(g_weaponarena_random_with_blaster)
513                                 self.weapons &= ~WEPSET_BLASTER;
514                         W_RandomWeapons(self, g_weaponarena_random);
515                         if(g_weaponarena_random_with_blaster)
516                                 self.weapons |= WEPSET_BLASTER;
517                 }
518
519                 self.items = start_items;
520
521                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
522                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
523                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
524                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
525                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
526                 //extend the pause of rotting if client was reset at the beginning of the countdown
527                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
528                         self.spawnshieldtime += game_starttime - time;
529                         self.pauserotarmor_finished += game_starttime - time;
530                         self.pauserothealth_finished += game_starttime - time;
531                         self.pauseregen_finished += game_starttime - time;
532                 }
533                 self.damageforcescale = 2;
534                 self.death_time = 0;
535                 self.respawn_flags = 0;
536                 self.respawn_time = 0;
537                 self.stat_respawn_time = 0;
538                 self.scale = autocvar_sv_player_scale;
539                 self.fade_time = 0;
540                 self.pain_frame = 0;
541                 self.pain_finished = 0;
542                 self.strength_finished = 0;
543                 self.invincible_finished = 0;
544                 self.pushltime = 0;
545                 // players have no think function
546                 self.think = func_null;
547                 self.nextthink = 0;
548                 self.hook_time = 0;
549                 self.dmg_team = 0;
550                 self.ballistics_density = autocvar_g_ballistics_density_player;
551
552                 self.metertime = 0;
553
554                 self.deadflag = DEAD_NO;
555
556                 self.angles = spot.angles;
557
558                 self.angles_z = 0; // never spawn tilted even if the spot says to
559                 if(IS_BOT_CLIENT(self))
560                         self.v_angle = self.angles;
561                 self.fixangle = true; // turn this way immediately
562                 self.velocity = '0 0 0';
563                 self.avelocity = '0 0 0';
564                 self.punchangle = '0 0 0';
565                 self.punchvector = '0 0 0';
566                 self.oldvelocity = self.velocity;
567                 self.fire_endtime = -1;
568                 self.revival_time = 0;
569
570                 entity spawnevent = spawn();
571                 spawnevent.owner = self;
572                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
573
574                 // Cut off any still running player sounds.
575                 stopsound(self, CH_PLAYER_SINGLE);
576
577                 self.model = "";
578                 FixPlayermodel();
579                 self.drawonlytoclient = world;
580
581                 self.crouch = false;
582                 self.view_ofs = PL_VIEW_OFS;
583                 setsize (self, PL_MIN, PL_MAX);
584                 self.spawnorigin = spot.origin;
585                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
586                 // don't reset back to last position, even if new position is stuck in solid
587                 self.oldorigin = self.origin;
588                 self.prevorigin = self.origin;
589                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
590                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
591         self.hud = HUD_NORMAL;
592
593                 self.event_damage = PlayerDamage;
594
595                 self.bot_attack = true;
596                 self.monster_attack = true;
597
598                 self.spider_slowness = 0;
599
600                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
601
602                 if(self.killcount == -666) {
603                         PlayerScore_Clear(self);
604                         self.killcount = 0;
605                 }
606
607                 CL_SpawnWeaponentity(self);
608                 self.alpha = default_player_alpha;
609                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
610                 self.exteriorweaponentity.alpha = default_weapon_alpha;
611
612                 self.speedrunning = false;
613
614                 //stuffcmd(self, "chase_active 0");
615                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
616
617                 target_voicescript_clear(self);
618
619                 // reset fields the weapons may use
620                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
621                 {
622                         _WEP_ACTION(j, WR_RESETPLAYER);
623
624                         // all weapons must be fully loaded when we spawn
625                         entity e = get_weaponinfo(j);
626                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
627                                 self.(weapon_load[j]) = e.reloading_ammo;
628                 }
629
630                 string s = spot.target;
631                 spot.target = string_null;
632                 activator = self;
633                 WITH(entity, self, spot, SUB_UseTargets());
634                 activator = world;
635                 spot.target = s;
636
637                 Unfreeze(self);
638
639                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
640
641                 if(autocvar_spawn_debug)
642                 {
643                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
644                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
645                 }
646
647                 self.switchweapon = w_getbestweapon(self);
648                 self.cnt = -1; // W_LastWeapon will not complain
649                 self.weapon = 0;
650                 self.weaponname = "";
651                 self.switchingweapon = 0;
652
653                 if(!warmup_stage)
654                         if(!self.alivetime)
655                                 self.alivetime = time;
656
657                 antilag_clear(self);
658         }
659         else if(IS_OBSERVER(self))
660         {
661                 PutObserverInServer ();
662         }
663 }
664
665 .float ebouncefactor, ebouncestop; // electro's values
666 // TODO do we need all these fields, or should we stop autodetecting runtime
667 // changes and just have a console command to update this?
668 float ClientInit_SendEntity(entity to, int sf)
669 {SELFPARAM();
670         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
671         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
672         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
673         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
674         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
680
681         if(sv_foginterval && world.fog != "")
682                 WriteString(MSG_ENTITY, world.fog);
683         else
684                 WriteString(MSG_ENTITY, "");
685         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
686         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
687         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
688         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
689         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
690         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
691         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
692         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
693         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
694         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
695         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
696         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
697         return true;
698 }
699
700 void ClientInit_CheckUpdate()
701 {SELFPARAM();
702         self.nextthink = time;
703         if(self.count != autocvar_g_balance_armor_blockpercent)
704         {
705                 self.count = autocvar_g_balance_armor_blockpercent;
706                 self.SendFlags |= 1;
707         }
708         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
709         {
710                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
711                 self.SendFlags |= 1;
712         }
713         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
714         {
715                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
716                 self.SendFlags |= 1;
717         }
718         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
719         {
720                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
721                 self.SendFlags |= 1;
722         }
723         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
724         {
725                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
726                 self.SendFlags |= 1;
727         }
728 }
729
730 void ClientInit_Spawn()
731 {SELFPARAM();
732         entity e = spawn();
733         e.classname = "clientinit";
734         e.think = ClientInit_CheckUpdate;
735         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
736
737         WITH(entity, self, e, ClientInit_CheckUpdate());
738 }
739
740 /*
741 =============
742 SetNewParms
743 =============
744 */
745 void SetNewParms (void)
746 {
747         // initialize parms for a new player
748         parm1 = -(86400 * 366);
749 }
750
751 /*
752 =============
753 SetChangeParms
754 =============
755 */
756 void SetChangeParms (void)
757 {SELFPARAM();
758         // save parms for level change
759         parm1 = self.parm_idlesince - time;
760 }
761
762 /*
763 =============
764 DecodeLevelParms
765 =============
766 */
767 void DecodeLevelParms (void)
768 {SELFPARAM();
769         // load parms
770         self.parm_idlesince = parm1;
771         if(self.parm_idlesince == -(86400 * 366))
772                 self.parm_idlesince = time;
773
774         // whatever happens, allow 60 seconds of idling directly after connect for map loading
775         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
776 }
777
778 /*
779 =============
780 ClientKill
781
782 Called when a client types 'kill' in the console
783 =============
784 */
785
786 .float clientkill_nexttime;
787 void ClientKill_Now_TeamChange()
788 {SELFPARAM();
789         if(self.killindicator_teamchange == -1)
790         {
791                 JoinBestTeam( self, false, true );
792         }
793         else if(self.killindicator_teamchange == -2)
794         {
795                 if(blockSpectators)
796                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
797                 PutObserverInServer();
798         }
799         else
800                 SV_ChangeTeam(self.killindicator_teamchange - 1);
801         self.killindicator_teamchange = 0;
802 }
803
804 void ClientKill_Now()
805 {SELFPARAM();
806         if(self.vehicle)
807         {
808             vehicles_exit(VHEF_RELEASE);
809             if(!self.killindicator_teamchange)
810             {
811             self.vehicle_health = -1;
812             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
813             }
814         }
815
816         if(self.killindicator && !wasfreed(self.killindicator))
817                 remove(self.killindicator);
818
819         self.killindicator = world;
820
821         if(self.killindicator_teamchange)
822                 ClientKill_Now_TeamChange();
823
824         if(IS_PLAYER(self))
825                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
826
827         // now I am sure the player IS dead
828 }
829 void KillIndicator_Think()
830 {SELFPARAM();
831         if (gameover)
832         {
833                 self.owner.killindicator = world;
834                 remove(self);
835                 return;
836         }
837
838         if (self.owner.alpha < 0 && !self.owner.vehicle)
839         {
840                 self.owner.killindicator = world;
841                 remove(self);
842                 return;
843         }
844
845         if(self.cnt <= 0)
846         {
847                 WITH(entity, self, self.owner, ClientKill_Now());
848                 return;
849         }
850     else if(g_cts && self.health == 1) // health == 1 means that it's silent
851     {
852         self.nextthink = time + 1;
853         self.cnt -= 1;
854     }
855         else
856         {
857                 if(self.cnt <= 10)
858                         setmodel(self, MDL_NUM(self.cnt));
859                 if(IS_REAL_CLIENT(self.owner))
860                 {
861                         if(self.cnt <= 10)
862                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
863                 }
864                 self.nextthink = time + 1;
865                 self.cnt -= 1;
866         }
867 }
868
869 float clientkilltime;
870 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
871 {SELFPARAM();
872         float killtime;
873         float starttime;
874         entity e;
875
876         if (gameover)
877                 return;
878
879         killtime = autocvar_g_balance_kill_delay;
880
881         if(g_race_qualifying || g_cts)
882                 killtime = 0;
883
884     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
885     {
886                 remove(self.killindicator);
887                 self.killindicator = world;
888
889         ClientKill_Now(); // allow instant kill in this case
890         return;
891     }
892
893         self.killindicator_teamchange = targetteam;
894
895     if(!self.killindicator)
896         {
897                 if(self.deadflag == DEAD_NO)
898                 {
899                         killtime = max(killtime, self.clientkill_nexttime - time);
900                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
901                 }
902
903                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
904                 {
905                         ClientKill_Now();
906                 }
907                 else
908                 {
909                         starttime = max(time, clientkilltime);
910
911                         self.killindicator = spawn();
912                         self.killindicator.owner = self;
913                         self.killindicator.scale = 0.5;
914                         setattachment(self.killindicator, self, "");
915                         setorigin(self.killindicator, '0 0 52');
916                         self.killindicator.think = KillIndicator_Think;
917                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
918                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
919                         self.killindicator.cnt = ceil(killtime);
920                         self.killindicator.count = bound(0, ceil(killtime), 10);
921                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
922
923                         for(e = world; (e = find(e, classname, "body")) != world; )
924                         {
925                                 if(e.enemy != self)
926                                         continue;
927                                 e.killindicator = spawn();
928                                 e.killindicator.owner = e;
929                                 e.killindicator.scale = 0.5;
930                                 setattachment(e.killindicator, e, "");
931                                 setorigin(e.killindicator, '0 0 52');
932                                 e.killindicator.think = KillIndicator_Think;
933                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
934                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
935                                 e.killindicator.cnt = ceil(killtime);
936                         }
937                         self.lip = 0;
938                 }
939         }
940         if(self.killindicator)
941         {
942                 if(targetteam == 0) // just die
943                 {
944                         self.killindicator.colormod = '0 0 0';
945                         if(IS_REAL_CLIENT(self))
946                         if(self.killindicator.cnt > 0)
947                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
948                 }
949                 else if(targetteam == -1) // auto
950                 {
951                         self.killindicator.colormod = '0 1 0';
952                         if(IS_REAL_CLIENT(self))
953                         if(self.killindicator.cnt > 0)
954                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
955                 }
956                 else if(targetteam == -2) // spectate
957                 {
958                         self.killindicator.colormod = '0.5 0.5 0.5';
959                         if(IS_REAL_CLIENT(self))
960                         if(self.killindicator.cnt > 0)
961                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
962                 }
963                 else
964                 {
965                         self.killindicator.colormod = Team_ColorRGB(targetteam);
966                         if(IS_REAL_CLIENT(self))
967                         if(self.killindicator.cnt > 0)
968                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
969                 }
970         }
971
972 }
973
974 void ClientKill (void)
975 {SELFPARAM();
976         if(gameover) return;
977         if(self.player_blocked) return;
978         if(self.frozen) return;
979
980         ClientKill_TeamChange(0);
981 }
982
983 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
984 {
985     e.killindicator = spawn();
986     e.killindicator.owner = e;
987     e.killindicator.think = KillIndicator_Think;
988     e.killindicator.nextthink = time + (e.lip) * 0.05;
989     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
990     e.killindicator.health = 1; // this is used to indicate that it should be silent
991     e.lip = 0;
992 }
993
994 void FixClientCvars(entity e)
995 {
996         // send prediction settings to the client
997         stuffcmd(e, "\nin_bindmap 0 0\n");
998         if(g_race || g_cts)
999                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1000         if(autocvar_g_antilag == 3) // client side hitscan
1001                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1002         if(autocvar_sv_gentle)
1003                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1004 }
1005
1006 float PlayerInIDList(entity p, string idlist)
1007 {
1008         float n, i;
1009         string s;
1010
1011         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1012         if (!p.crypto_idfp)
1013                 return 0;
1014
1015         // this function allows abbreviated player IDs too!
1016         n = tokenize_console(idlist);
1017         for(i = 0; i < n; ++i)
1018         {
1019                 s = argv(i);
1020                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1021                         return 1;
1022         }
1023
1024         return 0;
1025 }
1026
1027 #ifdef DP_EXT_PRECONNECT
1028 /*
1029 =============
1030 ClientPreConnect
1031
1032 Called once (not at each match start) when a client begins a connection to the server
1033 =============
1034 */
1035 void ClientPreConnect (void)
1036 {SELFPARAM();
1037         if(autocvar_sv_eventlog)
1038         {
1039                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1040                         self.playerid,
1041                         num_for_edict(self),
1042                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1043                 ));
1044         }
1045 }
1046 #endif
1047
1048 /*
1049 =============
1050 ClientConnect
1051
1052 Called when a client connects to the server
1053 =============
1054 */
1055 void DecodeLevelParms (void);
1056 void ClientConnect (void)
1057 {SELFPARAM();
1058         float t;
1059
1060         if(IS_CLIENT(self))
1061         {
1062                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1063                 return;
1064         }
1065
1066         if(Ban_MaybeEnforceBanOnce(self))
1067                 return;
1068
1069         DecodeLevelParms();
1070
1071 #ifdef WATERMARK
1072         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1073 #endif
1074
1075         self.classname = "player_joining";
1076
1077         self.flags = FL_CLIENT;
1078         self.version_nagtime = time + 10 + random() * 10;
1079
1080         if(player_count<0)
1081         {
1082                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1083                 player_count = 0;
1084         }
1085
1086         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1087
1088         PlayerScore_Attach(self);
1089         ClientData_Attach();
1090         accuracy_init(self);
1091         Inventory_new(self);
1092
1093         bot_clientconnect();
1094
1095         playerdemo_init();
1096
1097         anticheat_init();
1098
1099         // identify the right forced team
1100         if(autocvar_g_campaign)
1101         {
1102                 if(IS_REAL_CLIENT(self)) // only players, not bots
1103                 {
1104                         switch(autocvar_g_campaign_forceteam)
1105                         {
1106                                 case 1: self.team_forced = NUM_TEAM_1; break;
1107                                 case 2: self.team_forced = NUM_TEAM_2; break;
1108                                 case 3: self.team_forced = NUM_TEAM_3; break;
1109                                 case 4: self.team_forced = NUM_TEAM_4; break;
1110                                 default: self.team_forced = 0;
1111                         }
1112                 }
1113         }
1114         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1115                 self.team_forced = NUM_TEAM_1;
1116         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1117                 self.team_forced = NUM_TEAM_2;
1118         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1119                 self.team_forced = NUM_TEAM_3;
1120         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1121                 self.team_forced = NUM_TEAM_4;
1122         else if(autocvar_g_forced_team_otherwise == "red")
1123                 self.team_forced = NUM_TEAM_1;
1124         else if(autocvar_g_forced_team_otherwise == "blue")
1125                 self.team_forced = NUM_TEAM_2;
1126         else if(autocvar_g_forced_team_otherwise == "yellow")
1127                 self.team_forced = NUM_TEAM_3;
1128         else if(autocvar_g_forced_team_otherwise == "pink")
1129                 self.team_forced = NUM_TEAM_4;
1130         else if(autocvar_g_forced_team_otherwise == "spectate")
1131                 self.team_forced = -1;
1132         else if(autocvar_g_forced_team_otherwise == "spectator")
1133                 self.team_forced = -1;
1134         else
1135                 self.team_forced = 0;
1136
1137         if(!teamplay)
1138                 if(self.team_forced > 0)
1139                         self.team_forced = 0;
1140
1141         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1142
1143         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1144                 self.classname = "observer";
1145         } else {
1146                 if(teamplay)
1147                 {
1148                         if(autocvar_g_balance_teams)
1149                         {
1150                                 self.classname = "player";
1151                                 campaign_bots_may_start = 1;
1152                         }
1153                         else
1154                         {
1155                                 self.classname = "observer"; // do it anyway
1156                         }
1157                 }
1158                 else
1159                 {
1160                         self.classname = "player";
1161                         campaign_bots_may_start = 1;
1162                 }
1163         }
1164
1165         self.playerid = (playerid_last = playerid_last + 1);
1166
1167         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1168
1169     if(IS_BOT_CLIENT(self))
1170         PlayerStats_GameReport_AddPlayer(self);
1171
1172         if(autocvar_sv_eventlog)
1173                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1174
1175         LogTeamchange(self.playerid, self.team, 1);
1176
1177         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1178
1179         self.netname_previous = strzone(self.netname);
1180
1181         if(IS_PLAYER(self) && teamplay)
1182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1183         else
1184                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1185
1186         stuffcmd(self, strcat(clientstuff, "\n"));
1187         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1188
1189         FixClientCvars(self);
1190
1191         // spawnfunc_waypoint sprites
1192         WaypointSprite_InitClient(self);
1193
1194         // Wazat's grappling hook
1195         SetGrappleHookBindings();
1196
1197         // Jetpack binds
1198         stuffcmd(self, "alias +jetpack +button10\n");
1199         stuffcmd(self, "alias -jetpack -button10\n");
1200
1201         // get version info from player
1202         stuffcmd(self, "cmd clientversion $gameversion\n");
1203
1204         // get other cvars from player
1205         GetCvars(0);
1206
1207         // notify about available teams
1208         if(teamplay)
1209         {
1210                 CheckAllowedTeams(self);
1211                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1212                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1213         }
1214         else
1215                 stuffcmd(self, "set _teams_available 0\n");
1216
1217         attach_entcs();
1218
1219         bot_relinkplayerlist();
1220
1221         self.spectatortime = time;
1222         if(blockSpectators)
1223         {
1224                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1225         }
1226
1227         self.jointime = time;
1228         self.allowed_timeouts = autocvar_sv_timeout_number;
1229
1230         if(IS_REAL_CLIENT(self))
1231         {
1232                 if(!autocvar_g_campaign)
1233                 {
1234                         self.motd_actived_time = -1;
1235                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1236                 }
1237
1238                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1239                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1240         }
1241
1242         if(!sv_foginterval && world.fog != "")
1243                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1244
1245         W_HitPlotOpen(self);
1246
1247         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1248                 send_CSQC_teamnagger();
1249
1250         CheatInitClient();
1251
1252         CSQCMODEL_AUTOINIT(self);
1253
1254         self.model_randomizer = random();
1255
1256         if(IS_REAL_CLIENT(self))
1257                 sv_notice_join();
1258
1259         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1260                 WITH(entity, self, e, e.init_for_player(this));
1261         }
1262
1263         MUTATOR_CALLHOOK(ClientConnect, self);
1264 }
1265 /*
1266 =============
1267 ClientDisconnect
1268
1269 Called when a client disconnects from the server
1270 =============
1271 */
1272 .entity chatbubbleentity;
1273 void ReadyCount();
1274 void ClientDisconnect (void)
1275 {SELFPARAM();
1276         if(self.vehicle)
1277             vehicles_exit(VHEF_RELEASE);
1278
1279         if (!IS_CLIENT(self))
1280         {
1281                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1282                 return;
1283         }
1284
1285         PlayerStats_GameReport_FinalizePlayer(self);
1286
1287         if ( self.active_minigame )
1288                 part_minigame(self);
1289
1290         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1291
1292         CheatShutdownClient();
1293
1294         W_HitPlotClose(self);
1295
1296         anticheat_report();
1297         anticheat_shutdown();
1298
1299         playerdemo_shutdown();
1300
1301         bot_clientdisconnect();
1302
1303         if(self.entcs)
1304                 detach_entcs();
1305
1306         if(autocvar_sv_eventlog)
1307                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1308
1309         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1310
1311         MUTATOR_CALLHOOK(ClientDisconnect);
1312
1313         Portal_ClearAll(self);
1314
1315         Unfreeze(self);
1316
1317         RemoveGrapplingHook(self);
1318
1319         // Here, everything has been done that requires this player to be a client.
1320
1321         self.flags &= ~FL_CLIENT;
1322
1323         if (self.chatbubbleentity)
1324                 remove (self.chatbubbleentity);
1325
1326         if (self.killindicator)
1327                 remove (self.killindicator);
1328
1329         WaypointSprite_PlayerGone();
1330
1331         bot_relinkplayerlist();
1332
1333         accuracy_free(self);
1334         Inventory_delete(self);
1335         ClientData_Detach();
1336         PlayerScore_Detach(self);
1337
1338         if(self.netname_previous)
1339                 strunzone(self.netname_previous);
1340         if(self.clientstatus)
1341                 strunzone(self.clientstatus);
1342         if(self.weaponorder_byimpulse)
1343                 strunzone(self.weaponorder_byimpulse);
1344
1345         ClearPlayerSounds();
1346
1347         if(self.personal)
1348                 remove(self.personal);
1349
1350         self.playerid = 0;
1351         ReadyCount();
1352
1353         // free cvars
1354         GetCvars(-1);
1355 }
1356
1357 .float BUTTON_CHAT;
1358 void ChatBubbleThink()
1359 {SELFPARAM();
1360         self.nextthink = time;
1361         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1362         {
1363                 if(self.owner) // but why can that ever be world?
1364                         self.owner.chatbubbleentity = world;
1365                 remove(self);
1366                 return;
1367         }
1368
1369         self.mdl = "";
1370
1371         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1372         {
1373                 if ( self.owner.active_minigame )
1374                         self.mdl = "models/sprites/minigame_busy.iqm";
1375                 else if ( self.owner.BUTTON_CHAT )
1376                         self.mdl = "models/misc/chatbubble.spr";
1377         }
1378
1379         if ( self.model != self.mdl )
1380                 _setmodel(self, self.mdl);
1381
1382 }
1383
1384 void UpdateChatBubble()
1385 {SELFPARAM();
1386         if (self.alpha < 0)
1387                 return;
1388         // spawn a chatbubble entity if needed
1389         if (!self.chatbubbleentity)
1390         {
1391                 self.chatbubbleentity = spawn();
1392                 self.chatbubbleentity.owner = self;
1393                 self.chatbubbleentity.exteriormodeltoclient = self;
1394                 self.chatbubbleentity.think = ChatBubbleThink;
1395                 self.chatbubbleentity.nextthink = time;
1396                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1397                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1398                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1399                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1400                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1401                 //self.chatbubbleentity.model = "";
1402                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1403         }
1404 }
1405
1406
1407 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1408 // added to the model skins
1409 /*void UpdateColorModHack()
1410 {
1411         float c;
1412         c = self.clientcolors & 15;
1413         // LordHavoc: only bothering to support white, green, red, yellow, blue
1414              if (!teamplay) self.colormod = '0 0 0';
1415         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1416         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1417         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1418         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1419         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1420         else self.colormod = '1 1 1';
1421 }*/
1422
1423 void respawn(void)
1424 {SELFPARAM();
1425         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1426         {
1427                 self.solid = SOLID_NOT;
1428                 self.takedamage = DAMAGE_NO;
1429                 self.movetype = MOVETYPE_FLY;
1430                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1431                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1432                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1433                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1434                 if(autocvar_g_respawn_ghosts_maxtime)
1435                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1436         }
1437
1438         CopyBody(1);
1439
1440         self.effects |= EF_NODRAW; // prevent another CopyBody
1441         PutClientInServer();
1442 }
1443
1444 void play_countdown(float finished, string samp)
1445 {SELFPARAM();
1446         if(IS_REAL_CLIENT(self))
1447                 if(floor(finished - time - frametime) != floor(finished - time))
1448                         if(finished - time < 6)
1449                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1450 }
1451
1452 void player_powerups (void)
1453 {SELFPARAM();
1454         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1455         int items_prev = self.items;
1456
1457         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1458                 self.modelflags |= MF_ROCKET;
1459         else
1460                 self.modelflags &= ~MF_ROCKET;
1461
1462         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1463
1464         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1465                 return;
1466
1467         Fire_ApplyDamage(self);
1468         Fire_ApplyEffect(self);
1469
1470         if (!g_instagib)
1471         {
1472                 if (self.items & ITEM_Strength.m_itemid)
1473                 {
1474                         play_countdown(self.strength_finished, SND(POWEROFF));
1475                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1476                         if (time > self.strength_finished)
1477                         {
1478                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1479                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1480                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1481                         }
1482                 }
1483                 else
1484                 {
1485                         if (time < self.strength_finished)
1486                         {
1487                                 self.items = self.items | ITEM_Strength.m_itemid;
1488                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1489                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1490                         }
1491                 }
1492                 if (self.items & ITEM_Shield.m_itemid)
1493                 {
1494                         play_countdown(self.invincible_finished, SND(POWEROFF));
1495                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1496                         if (time > self.invincible_finished)
1497                         {
1498                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1499                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1500                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1501                         }
1502                 }
1503                 else
1504                 {
1505                         if (time < self.invincible_finished)
1506                         {
1507                                 self.items = self.items | ITEM_Shield.m_itemid;
1508                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1509                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1510                         }
1511                 }
1512                 if (self.items & IT_SUPERWEAPON)
1513                 {
1514                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1515                         {
1516                                 self.superweapons_finished = 0;
1517                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1518                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1519                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1520                         }
1521                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1522                         {
1523                                 // don't let them run out
1524                         }
1525                         else
1526                         {
1527                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1528                                 if (time > self.superweapons_finished)
1529                                 {
1530                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1531                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1532                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1533                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1534                                 }
1535                         }
1536                 }
1537                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1538                 {
1539                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1540                         {
1541                                 self.items = self.items | IT_SUPERWEAPON;
1542                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1543                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1544                         }
1545                         else
1546                         {
1547                                 self.superweapons_finished = 0;
1548                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1549                         }
1550                 }
1551                 else
1552                 {
1553                         self.superweapons_finished = 0;
1554                 }
1555         }
1556
1557         if(autocvar_g_nodepthtestplayers)
1558                 self.effects = self.effects | EF_NODEPTHTEST;
1559
1560         if(autocvar_g_fullbrightplayers)
1561                 self.effects = self.effects | EF_FULLBRIGHT;
1562
1563         if (time >= game_starttime)
1564         if (time < self.spawnshieldtime)
1565                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1566
1567         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1568 }
1569
1570 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1571 {
1572         if(current > stable)
1573                 return current;
1574         else if(current > stable - 0.25) // when close enough, "snap"
1575                 return stable;
1576         else
1577                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1578 }
1579
1580 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1581 {
1582         if(current < stable)
1583                 return current;
1584         else if(current < stable + 0.25) // when close enough, "snap"
1585                 return stable;
1586         else
1587                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1588 }
1589
1590 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1591 {
1592         if(current > rotstable)
1593         {
1594                 if(rotframetime > 0)
1595                 {
1596                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1597                         current = max(rotstable, current - rotlinear * rotframetime);
1598                 }
1599         }
1600         else if(current < regenstable)
1601         {
1602                 if(regenframetime > 0)
1603                 {
1604                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1605                         current = min(regenstable, current + regenlinear * regenframetime);
1606                 }
1607         }
1608
1609         if(current > limit)
1610                 current = limit;
1611
1612         return current;
1613 }
1614
1615 void player_regen (void)
1616 {SELFPARAM();
1617         float max_mod, regen_mod, rot_mod, limit_mod;
1618         max_mod = regen_mod = rot_mod = limit_mod = 1;
1619         regen_mod_max = max_mod;
1620         regen_mod_regen = regen_mod;
1621         regen_mod_rot = rot_mod;
1622         regen_mod_limit = limit_mod;
1623
1624         regen_health = autocvar_g_balance_health_regen;
1625         regen_health_linear = autocvar_g_balance_health_regenlinear;
1626         regen_health_rot = autocvar_g_balance_health_rot;
1627         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1628         regen_health_stable = autocvar_g_balance_health_regenstable;
1629         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1630         if(!MUTATOR_CALLHOOK(PlayerRegen))
1631         if(!self.frozen)
1632         {
1633                 float mina, maxa, limith, limita;
1634                 maxa = autocvar_g_balance_armor_rotstable;
1635                 mina = autocvar_g_balance_armor_regenstable;
1636                 limith = autocvar_g_balance_health_limit;
1637                 limita = autocvar_g_balance_armor_limit;
1638
1639                 max_mod = regen_mod_max;
1640                 regen_mod = regen_mod_regen;
1641                 rot_mod = regen_mod_rot;
1642                 limit_mod = regen_mod_limit;
1643
1644                 regen_health_rotstable = regen_health_rotstable * max_mod;
1645                 regen_health_stable = regen_health_stable * max_mod;
1646                 limith = limith * limit_mod;
1647                 limita = limita * limit_mod;
1648
1649                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1650                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1651         }
1652
1653         // if player rotted to death...  die!
1654         // check this outside above checks, as player may still be able to rot to death
1655         if(self.health < 1)
1656         {
1657                 if(self.vehicle)
1658                         vehicles_exit(VHEF_RELEASE);
1659                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1660         }
1661
1662         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1663         {
1664                 float minf, maxf, limitf;
1665
1666                 maxf = autocvar_g_balance_fuel_rotstable;
1667                 minf = autocvar_g_balance_fuel_regenstable;
1668                 limitf = autocvar_g_balance_fuel_limit;
1669
1670                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1671         }
1672 }
1673
1674 float zoomstate_set;
1675 void SetZoomState(float z)
1676 {SELFPARAM();
1677         if(z != self.zoomstate)
1678         {
1679                 self.zoomstate = z;
1680                 ClientData_Touch(self);
1681         }
1682         zoomstate_set = 1;
1683 }
1684
1685 void GetPressedKeys()
1686 {SELFPARAM();
1687         MUTATOR_CALLHOOK(GetPressedKeys);
1688         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1689         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1690         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1691         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1692         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1693
1694         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1695         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1696         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1697         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1698         #undef X
1699 }
1700
1701 /*
1702 ======================
1703 spectate mode routines
1704 ======================
1705 */
1706
1707 void SpectateCopy(entity spectatee)
1708 {SELFPARAM();
1709         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1710         self.armortype = spectatee.armortype;
1711         self.armorvalue = spectatee.armorvalue;
1712         self.ammo_cells = spectatee.ammo_cells;
1713         self.ammo_plasma = spectatee.ammo_plasma;
1714         self.ammo_shells = spectatee.ammo_shells;
1715         self.ammo_nails = spectatee.ammo_nails;
1716         self.ammo_rockets = spectatee.ammo_rockets;
1717         self.ammo_fuel = spectatee.ammo_fuel;
1718         self.clip_load = spectatee.clip_load;
1719         self.clip_size = spectatee.clip_size;
1720         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1721         self.health = spectatee.health;
1722         self.impulse = 0;
1723         self.items = spectatee.items;
1724         self.last_pickup = spectatee.last_pickup;
1725         self.hit_time = spectatee.hit_time;
1726         self.metertime = spectatee.metertime;
1727         self.strength_finished = spectatee.strength_finished;
1728         self.invincible_finished = spectatee.invincible_finished;
1729         self.pressedkeys = spectatee.pressedkeys;
1730         self.weapons = spectatee.weapons;
1731         self.switchweapon = spectatee.switchweapon;
1732         self.switchingweapon = spectatee.switchingweapon;
1733         self.weapon = spectatee.weapon;
1734         self.vortex_charge = spectatee.vortex_charge;
1735         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1736         self.hagar_load = spectatee.hagar_load;
1737         self.arc_heat_percent = spectatee.arc_heat_percent;
1738         self.minelayer_mines = spectatee.minelayer_mines;
1739         self.punchangle = spectatee.punchangle;
1740         self.view_ofs = spectatee.view_ofs;
1741         self.velocity = spectatee.velocity;
1742         self.dmg_take = spectatee.dmg_take;
1743         self.dmg_save = spectatee.dmg_save;
1744         self.dmg_inflictor = spectatee.dmg_inflictor;
1745         self.v_angle = spectatee.v_angle;
1746         self.angles = spectatee.v_angle;
1747         self.frozen = spectatee.frozen;
1748         self.revive_progress = spectatee.revive_progress;
1749         if(!self.BUTTON_USE)
1750                 self.fixangle = true;
1751         setorigin(self, spectatee.origin);
1752         setsize(self, spectatee.mins, spectatee.maxs);
1753         SetZoomState(spectatee.zoomstate);
1754
1755     anticheat_spectatecopy(spectatee);
1756         self.hud = spectatee.hud;
1757         if(spectatee.vehicle)
1758     {
1759         self.fixangle = false;
1760         //self.velocity = spectatee.vehicle.velocity;
1761         self.vehicle_health = spectatee.vehicle_health;
1762         self.vehicle_shield = spectatee.vehicle_shield;
1763         self.vehicle_energy = spectatee.vehicle_energy;
1764         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1765         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1766         self.vehicle_reload1 = spectatee.vehicle_reload1;
1767         self.vehicle_reload2 = spectatee.vehicle_reload2;
1768
1769         msg_entity = self;
1770
1771         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1772             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1773             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1774             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1775
1776         //WriteByte (MSG_ONE, SVC_SETVIEW);
1777         //    WriteEntity(MSG_ONE, self);
1778         //makevectors(spectatee.v_angle);
1779         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1780     }
1781 }
1782
1783 bool SpectateUpdate()
1784 {SELFPARAM();
1785         if(!self.enemy)
1786             return false;
1787
1788         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1789         {
1790                 SetSpectator(self, world);
1791                 return false;
1792         }
1793
1794         SpectateCopy(self.enemy);
1795
1796         return true;
1797 }
1798
1799 bool SpectateSet()
1800 {SELFPARAM();
1801         if(!IS_PLAYER(self.enemy))
1802                 return false;
1803
1804         msg_entity = self;
1805         WriteByte(MSG_ONE, SVC_SETVIEW);
1806         WriteEntity(MSG_ONE, self.enemy);
1807         self.movetype = MOVETYPE_NONE;
1808         accuracy_resend(self);
1809
1810         if(!SpectateUpdate())
1811                 PutObserverInServer();
1812
1813         return true;
1814 }
1815
1816 void SetSpectator(entity player, entity spectatee)
1817 {
1818         entity old_spectatee = player.enemy;
1819
1820         player.enemy = spectatee;
1821
1822         // WEAPONTODO
1823         // these are required to fix the spectator bug with arc
1824         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1825         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1826 }
1827
1828 bool Spectate(entity pl)
1829 {SELFPARAM();
1830         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1831         if(DIFF_TEAM(pl, self))
1832                 return false;
1833
1834         SetSpectator(self, pl);
1835         return SpectateSet();
1836 }
1837
1838 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1839 entity CA_SpectateNext(entity start)
1840 {SELFPARAM();
1841         if(SAME_TEAM(start, self))
1842                 return start;
1843
1844         other = start;
1845         // continue from current player
1846         while(other && DIFF_TEAM(other, self))
1847                 other = find(other, classname, "player");
1848
1849         if (!other)
1850         {
1851                 // restart from begining
1852                 other = find(other, classname, "player");
1853                 while(other && DIFF_TEAM(other, self))
1854                         other = find(other, classname, "player");
1855         }
1856
1857         return other;
1858 }
1859
1860 bool SpectateNext()
1861 {SELFPARAM();
1862         other = find(self.enemy, classname, "player");
1863
1864         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1865                 // CA and ca players when spectating enemies is forbidden
1866                 other = CA_SpectateNext(other);
1867         else
1868         {
1869                 // other modes and ca spectators or spectating enemies is allowed
1870                 if (!other)
1871                         other = find(other, classname, "player");
1872         }
1873
1874         if(other) { SetSpectator(self, other); }
1875
1876         return SpectateSet();
1877 }
1878
1879 bool SpectatePrev()
1880 {SELFPARAM();
1881         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1882         other = findchain(classname, "player");
1883         if (!other) // no player
1884                 return false;
1885
1886         entity first = other;
1887         // skip players until current spectated player
1888         if(self.enemy)
1889         while(other && other != self.enemy)
1890                 other = other.chain;
1891
1892         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1893         {
1894                 do { other = other.chain; }
1895                 while(other && DIFF_TEAM(other, self));
1896
1897                 if (!other)
1898                 {
1899                         other = first;
1900                         while(other && DIFF_TEAM(other, self))
1901                                 other = other.chain;
1902                         if(other == self.enemy)
1903                                 return true;
1904                 }
1905         }
1906         else
1907         {
1908                 if(other.chain)
1909                         other = other.chain;
1910                 else
1911                         other = first;
1912         }
1913         SetSpectator(self, other);
1914         return SpectateSet();
1915 }
1916
1917 /*
1918 =============
1919 ShowRespawnCountdown()
1920
1921 Update a respawn countdown display.
1922 =============
1923 */
1924 void ShowRespawnCountdown()
1925 {SELFPARAM();
1926         float number;
1927         if(self.deadflag == DEAD_NO) // just respawned?
1928                 return;
1929         else
1930         {
1931                 number = ceil(self.respawn_time - time);
1932                 if(number <= 0)
1933                         return;
1934                 if(number <= self.respawn_countdown)
1935                 {
1936                         self.respawn_countdown = number - 1;
1937                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1938                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1939                 }
1940         }
1941 }
1942
1943 void LeaveSpectatorMode()
1944 {SELFPARAM();
1945         if(self.caplayer)
1946                 return;
1947         if(nJoinAllowed(self))
1948         {
1949                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1950                 {
1951                         self.classname = "player";
1952                         nades_RemoveBonus(self);
1953
1954                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1955                                 { JoinBestTeam(self, false, true); }
1956
1957                         if(autocvar_g_campaign)
1958                                 { campaign_bots_may_start = 1; }
1959
1960                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1961
1962                         PutClientInServer();
1963
1964                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1965                 }
1966                 else
1967                         stuffcmd(self, "menu_showteamselect\n");
1968         }
1969         else
1970         {
1971                 // Player may not join because g_maxplayers is set
1972                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1973         }
1974 }
1975
1976 /**
1977  * Determines whether the player is allowed to join. This depends on cvar
1978  * g_maxplayers, if it isn't used this function always return true, otherwise
1979  * it checks whether the number of currently playing players exceeds g_maxplayers.
1980  * @return int number of free slots for players, 0 if none
1981  */
1982 float nJoinAllowed(entity ignore)
1983 {SELFPARAM();
1984         if(!ignore)
1985         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1986         // so report 0 free slots if restricted
1987         {
1988                 if(autocvar_g_forced_team_otherwise == "spectate")
1989                         return 0;
1990                 if(autocvar_g_forced_team_otherwise == "spectator")
1991                         return 0;
1992         }
1993
1994         if(self.team_forced < 0)
1995                 return 0; // forced spectators can never join
1996
1997         // TODO simplify this
1998         entity e;
1999         float totalClients = 0;
2000         FOR_EACH_CLIENT(e)
2001                 if(e != ignore)
2002                         totalClients += 1;
2003
2004         if (!autocvar_g_maxplayers)
2005                 return maxclients - totalClients;
2006
2007         float currentlyPlaying = 0;
2008         FOR_EACH_REALCLIENT(e)
2009                 if(IS_PLAYER(e) || e.caplayer)
2010                         currentlyPlaying += 1;
2011
2012         if(currentlyPlaying < autocvar_g_maxplayers)
2013                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2014
2015         return 0;
2016 }
2017
2018 /**
2019  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2020  * g_maxplayers_spectator_blocktime seconds
2021  */
2022 void checkSpectatorBlock()
2023 {SELFPARAM();
2024         if(IS_SPEC(self) || IS_OBSERVER(self))
2025         if(!self.caplayer)
2026         if(IS_REAL_CLIENT(self))
2027         {
2028                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2029                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2030                         dropclient(self);
2031                 }
2032         }
2033 }
2034
2035 void PrintWelcomeMessage()
2036 {SELFPARAM();
2037         if(self.motd_actived_time == 0)
2038         {
2039                 if (autocvar_g_campaign) {
2040                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2041                                 self.motd_actived_time = time;
2042                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2043                         }
2044                 } else {
2045                         if (self.BUTTON_INFO) {
2046                                 self.motd_actived_time = time;
2047                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2048                         }
2049                 }
2050         }
2051         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2052         {
2053                 if (autocvar_g_campaign) {
2054                         if (self.BUTTON_INFO)
2055                                 self.motd_actived_time = time;
2056                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2057                                 self.motd_actived_time = 0;
2058                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2059                         }
2060                 } else {
2061                         if (self.BUTTON_INFO)
2062                                 self.motd_actived_time = time;
2063                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2064                                 self.motd_actived_time = 0;
2065                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2066                         }
2067                 }
2068         }
2069         else //if(self.motd_actived_time < 0) // just connected, motd is active
2070         {
2071                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2072                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2073                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2074                 {
2075                         // instanctly hide MOTD
2076                         self.motd_actived_time = 0;
2077                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2078                 }
2079         }
2080 }
2081
2082 void ObserverThink()
2083 {SELFPARAM();
2084         if ( self.impulse )
2085         {
2086                 MinigameImpulse(self.impulse);
2087                 self.impulse = 0;
2088         }
2089         float prefered_movetype;
2090         if (self.flags & FL_JUMPRELEASED) {
2091                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2092                         self.flags &= ~FL_JUMPRELEASED;
2093                         self.flags |= FL_SPAWNING;
2094                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         if(SpectateNext()) {
2097                                 self.classname = "spectator";
2098                         }
2099                 } else {
2100                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2101                         if (self.movetype != prefered_movetype)
2102                                 self.movetype = prefered_movetype;
2103                 }
2104         } else {
2105                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2106                         self.flags |= FL_JUMPRELEASED;
2107                         if(self.flags & FL_SPAWNING)
2108                         {
2109                                 self.flags &= ~FL_SPAWNING;
2110                                 LeaveSpectatorMode();
2111                                 return;
2112                         }
2113                 }
2114         }
2115 }
2116
2117 void SpectatorThink()
2118 {SELFPARAM();
2119         if ( self.impulse )
2120         {
2121                 if(MinigameImpulse(self.impulse))
2122                         self.impulse = 0;
2123         }
2124         if (self.flags & FL_JUMPRELEASED) {
2125                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2126                         self.flags &= ~FL_JUMPRELEASED;
2127                         self.flags |= FL_SPAWNING;
2128                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2129                         self.flags &= ~FL_JUMPRELEASED;
2130                         if(SpectateNext()) {
2131                                 self.classname = "spectator";
2132                         } else {
2133                                 self.classname = "observer";
2134                                 PutClientInServer();
2135                         }
2136                         self.impulse = 0;
2137                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2138                         self.flags &= ~FL_JUMPRELEASED;
2139                         if(SpectatePrev()) {
2140                                 self.classname = "spectator";
2141                         } else {
2142                                 self.classname = "observer";
2143                                 PutClientInServer();
2144                         }
2145                         self.impulse = 0;
2146                 } else if (self.BUTTON_ATCK2) {
2147                         self.flags &= ~FL_JUMPRELEASED;
2148                         self.classname = "observer";
2149                         PutClientInServer();
2150                 } else {
2151                         if(!SpectateUpdate())
2152                                 PutObserverInServer();
2153                 }
2154         } else {
2155                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2156                         self.flags |= FL_JUMPRELEASED;
2157                         if(self.flags & FL_SPAWNING)
2158                         {
2159                                 self.flags &= ~FL_SPAWNING;
2160                                 LeaveSpectatorMode();
2161                                 return;
2162                         }
2163                 }
2164                 if(!SpectateUpdate())
2165                         PutObserverInServer();
2166         }
2167
2168         self.flags |= FL_CLIENT | FL_NOTARGET;
2169 }
2170
2171 void vehicles_enter (entity pl, entity veh);
2172 void PlayerUseKey()
2173 {SELFPARAM();
2174         if (!IS_PLAYER(self))
2175                 return;
2176
2177         if(self.vehicle)
2178         {
2179                 if(!gameover)
2180                 {
2181                         vehicles_exit(VHEF_NORMAL);
2182                         return;
2183                 }
2184         }
2185         else if(autocvar_g_vehicles_enter)
2186         {
2187                 if(!self.frozen)
2188                 if(self.deadflag == DEAD_NO)
2189                 if(!gameover)
2190                 {
2191                         entity head, closest_target = world;
2192                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2193
2194                         while(head) // find the closest acceptable target to enter
2195                         {
2196                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2197                                 if(head.deadflag == DEAD_NO)
2198                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2199                                 if(head.takedamage != DAMAGE_NO)
2200                                 {
2201                                         if(closest_target)
2202                                         {
2203                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2204                                                 { closest_target = head; }
2205                                         }
2206                                         else { closest_target = head; }
2207                                 }
2208
2209                                 head = head.chain;
2210                         }
2211
2212                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2213                 }
2214         }
2215
2216         // a use key was pressed; call handlers
2217         MUTATOR_CALLHOOK(PlayerUseKey);
2218 }
2219
2220 float isInvisibleString(string s)
2221 {
2222         float i, n, c;
2223         s = strdecolorize(s);
2224         for((i = 0), (n = strlen(s)); i < n; ++i)
2225         {
2226                 c = str2chr(s, i);
2227                 switch(c)
2228                 {
2229                         case 0:
2230                         case 32: // space
2231                                 break;
2232                         case 192: // charmap space
2233                                 if (!autocvar_utf8_enable)
2234                                         break;
2235                                 return false;
2236                         case 160: // space in unicode fonts
2237                         case 0xE000 + 192: // utf8 charmap space
2238                                 if (autocvar_utf8_enable)
2239                                         break;
2240                         default:
2241                                 return false;
2242                 }
2243         }
2244         return true;
2245 }
2246
2247 /*
2248 =============
2249 PlayerPreThink
2250
2251 Called every frame for each client before the physics are run
2252 =============
2253 */
2254 .float usekeypressed;
2255 void() nexball_setstatus;
2256 .float last_vehiclecheck;
2257 .int items_added;
2258 void PlayerPreThink (void)
2259 {SELFPARAM();
2260         WarpZone_PlayerPhysics_FixVAngle();
2261
2262         self.stat_game_starttime = game_starttime;
2263         self.stat_round_starttime = round_starttime;
2264         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2265         self.stat_leadlimit = autocvar_leadlimit;
2266
2267         self.weaponsinmap = weaponsInMap;
2268
2269         if(frametime)
2270         {
2271                 // physics frames: update anticheat stuff
2272                 anticheat_prethink();
2273         }
2274
2275         if(blockSpectators && frametime)
2276                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2277                 checkSpectatorBlock();
2278
2279         zoomstate_set = 0;
2280
2281         // Savage: Check for nameless players
2282         if (isInvisibleString(self.netname)) {
2283                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2284                 if(autocvar_sv_eventlog)
2285                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2286                 if(self.netname_previous)
2287                         strunzone(self.netname_previous);
2288                 self.netname_previous = strzone(new_name);
2289                 self.netname = self.netname_previous;
2290                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2291         } else if(self.netname_previous != self.netname) {
2292                 if(autocvar_sv_eventlog)
2293                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2294                 if(self.netname_previous)
2295                         strunzone(self.netname_previous);
2296                 self.netname_previous = strzone(self.netname);
2297         }
2298
2299         // version nagging
2300         if(self.version_nagtime)
2301                 if(self.cvar_g_xonoticversion)
2302                         if(time > self.version_nagtime)
2303                         {
2304                                 // don't notify git users
2305                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2306                                 {
2307                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2308                                         {
2309                                                 // notify release users if connecting to git
2310                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2311                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2312                                         }
2313                                         else
2314                                         {
2315                                                 float r;
2316                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2317                                                 if(r < 0)
2318                                                 {
2319                                                         // give users new version
2320                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2321                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2322                                                 }
2323                                                 else if(r > 0)
2324                                                 {
2325                                                         // notify users about old server version
2326                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2327                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2328                                                 }
2329                                         }
2330                                 }
2331                                 self.version_nagtime = 0;
2332                         }
2333
2334         // GOD MODE info
2335         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2336         {
2337                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2338                 self.max_armorvalue = 0;
2339         }
2340
2341         if(self.frozen == 2)
2342         {
2343                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2344                 self.health = max(1, self.revive_progress * start_health);
2345                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2346
2347                 if(self.revive_progress >= 1)
2348                         Unfreeze(self);
2349         }
2350         else if(self.frozen == 3)
2351         {
2352                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2353                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2354
2355                 if(self.health < 1)
2356                 {
2357                         if(self.vehicle)
2358                                 vehicles_exit(VHEF_RELEASE);
2359                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2360                 }
2361                 else if ( self.revive_progress <= 0 )
2362                         Unfreeze(self);
2363         }
2364
2365         MUTATOR_CALLHOOK(PlayerPreThink);
2366
2367         if(autocvar_g_vehicles_enter)
2368         if(time > self.last_vehiclecheck)
2369         if(IS_PLAYER(self))
2370         if(!gameover)
2371         if(!self.frozen)
2372         if(!self.vehicle)
2373         if(self.deadflag == DEAD_NO)
2374         {
2375                 entity veh;
2376                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2377                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2378                 if(veh.deadflag == DEAD_NO)
2379                 if(veh.takedamage != DAMAGE_NO)
2380                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2381                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2382                 else if(!veh.owner)
2383                 if(!veh.team || SAME_TEAM(self, veh))
2384                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2385                 else if(autocvar_g_vehicles_steal)
2386                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2387
2388                 self.last_vehiclecheck = time + 1;
2389         }
2390
2391         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2392         {
2393                 if(self.BUTTON_USE && !self.usekeypressed)
2394                         PlayerUseKey();
2395                 self.usekeypressed = self.BUTTON_USE;
2396         }
2397
2398         if(IS_REAL_CLIENT(self))
2399                 PrintWelcomeMessage();
2400
2401         if(IS_PLAYER(self))
2402         {
2403
2404                 CheckRules_Player();
2405
2406                 if (intermission_running)
2407                 {
2408                         IntermissionThink ();   // otherwise a button could be missed between
2409                         return;                                 // the think tics
2410                 }
2411
2412                 //don't allow the player to turn around while game is paused!
2413                 if(timeout_status == TIMEOUT_ACTIVE) {
2414                         // FIXME turn this into CSQC stuff
2415                         self.v_angle = self.lastV_angle;
2416                         self.angles = self.lastV_angle;
2417                         self.fixangle = true;
2418                 }
2419
2420                 if(frametime)
2421                 {
2422                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2423                         {
2424                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2425                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2426                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2427
2428                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2429                                 {
2430                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2431                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2432                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2433                                 }
2434                         }
2435                         else
2436                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2437
2438                         player_powerups();
2439                 }
2440
2441                 if (self.deadflag != DEAD_NO)
2442                 {
2443                         if(self.personal && g_race_qualifying)
2444                         {
2445                                 if(time > self.respawn_time)
2446                                 {
2447                                         self.respawn_time = time + 1; // only retry once a second
2448                                         self.stat_respawn_time = self.respawn_time;
2449                                         respawn();
2450                                         self.impulse = 141;
2451                                 }
2452                         }
2453                         else
2454                         {
2455                                 float button_pressed;
2456                                 if(frametime)
2457                                         player_anim();
2458                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2459
2460                                 if (self.deadflag == DEAD_DYING)
2461                                 {
2462                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2463                                                 self.deadflag = DEAD_RESPAWNING;
2464                                         else if(!button_pressed)
2465                                                 self.deadflag = DEAD_DEAD;
2466                                 }
2467                                 else if (self.deadflag == DEAD_DEAD)
2468                                 {
2469                                         if(button_pressed)
2470                                                 self.deadflag = DEAD_RESPAWNABLE;
2471                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2472                                                 self.deadflag = DEAD_RESPAWNING;
2473                                 }
2474                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2475                                 {
2476                                         if(!button_pressed)
2477                                                 self.deadflag = DEAD_RESPAWNING;
2478                                 }
2479                                 else if (self.deadflag == DEAD_RESPAWNING)
2480                                 {
2481                                         if(time > self.respawn_time)
2482                                         {
2483                                                 self.respawn_time = time + 1; // only retry once a second
2484                                                 self.respawn_time_max = self.respawn_time;
2485                                                 respawn();
2486                                         }
2487                                 }
2488
2489                                 ShowRespawnCountdown();
2490
2491                                 if(self.respawn_flags & RESPAWN_SILENT)
2492                                         self.stat_respawn_time = 0;
2493                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2494                                         self.stat_respawn_time = self.respawn_time_max;
2495                                 else
2496                                         self.stat_respawn_time = self.respawn_time;
2497                         }
2498
2499                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2500                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2501                                 self.stat_respawn_time *= -1;
2502
2503                         return;
2504                 }
2505
2506                 self.prevorigin = self.origin;
2507
2508                 float do_crouch = self.BUTTON_CROUCH;
2509                 if(self.hook.state)
2510                         do_crouch = 0;
2511                 if(self.vehicle)
2512                         do_crouch = 0;
2513                 if(self.frozen)
2514                         do_crouch = 0;
2515
2516                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2517                 // It cannot be predicted by the engine!
2518                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2519                         do_crouch = 0;
2520
2521                 if (do_crouch)
2522                 {
2523                         if (!self.crouch)
2524                         {
2525                                 self.crouch = true;
2526                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2527                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2528                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2529                         }
2530                 }
2531                 else
2532                 {
2533                         if (self.crouch)
2534                         {
2535                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2536                                 if (!trace_startsolid)
2537                                 {
2538                                         self.crouch = false;
2539                                         self.view_ofs = self.stat_pl_view_ofs;
2540                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2541                                 }
2542                         }
2543                 }
2544
2545                 FixPlayermodel();
2546
2547                 GrapplingHookFrame();
2548
2549                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2550                 //if(frametime)
2551                 {
2552                         self.items &= ~self.items_added;
2553
2554                         W_WeaponFrame();
2555
2556                         self.items_added = 0;
2557                         if(self.items & ITEM_Jetpack.m_itemid)
2558                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2559                                         self.items_added |= IT_FUEL;
2560
2561                         self.items |= self.items_added;
2562                 }
2563
2564                 player_regen();
2565
2566                 // WEAPONTODO: Add a weapon request for this
2567                 // rot vortex charge to the charge limit
2568                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2569                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2570
2571                 if(frametime)
2572                         player_anim();
2573
2574                 // secret status
2575                 secrets_setstatus();
2576
2577                 // monsters status
2578                 monsters_setstatus();
2579
2580                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2581
2582                 //self.angles_y=self.v_angle_y + 90;   // temp
2583         } else if(gameover) {
2584                 if (intermission_running)
2585                         IntermissionThink ();   // otherwise a button could be missed between
2586                 return;
2587         } else if(IS_OBSERVER(self)) {
2588                 ObserverThink();
2589         } else if(IS_SPEC(self)) {
2590                 SpectatorThink();
2591         }
2592
2593         // WEAPONTODO: Add weapon request for this
2594         if(!zoomstate_set)
2595                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2596
2597         float oldspectatee_status;
2598         oldspectatee_status = self.spectatee_status;
2599         if(IS_SPEC(self))
2600                 self.spectatee_status = num_for_edict(self.enemy);
2601         else if(IS_OBSERVER(self))
2602                 self.spectatee_status = num_for_edict(self);
2603         else
2604                 self.spectatee_status = 0;
2605         if(self.spectatee_status != oldspectatee_status)
2606         {
2607                 ClientData_Touch(self);
2608         }
2609
2610         if(self.teamkill_soundtime)
2611         if(time > self.teamkill_soundtime)
2612         {
2613                 self.teamkill_soundtime = 0;
2614
2615                 setself(self.teamkill_soundsource);
2616                 entity oldpusher = self.pusher;
2617                 self.pusher = this;
2618
2619                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2620
2621                 self.pusher = oldpusher;
2622                 setself(this);
2623         }
2624
2625         if(self.taunt_soundtime)
2626         if(time > self.taunt_soundtime)
2627         {
2628                 self.taunt_soundtime = 0;
2629                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2630         }
2631
2632         target_voicescript_next(self);
2633
2634         // WEAPONTODO: Move into weaponsystem somehow
2635         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2636         if(!self.weapon)
2637                 self.clip_load = self.clip_size = 0;
2638 }
2639
2640 /*
2641 =============
2642 PlayerPostThink
2643
2644 Called every frame for each client after the physics are run
2645 =============
2646 */
2647 .float idlekick_lasttimeleft;
2648 void PlayerPostThink (void)
2649 {SELFPARAM();
2650         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2651         if(IS_REAL_CLIENT(self))
2652         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2653         {
2654                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2655                 {
2656                         if(self.idlekick_lasttimeleft)
2657                         {
2658                                 self.idlekick_lasttimeleft = 0;
2659                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2660                         }
2661                 }
2662                 else
2663                 {
2664                         float timeleft;
2665                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2666                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2667                         {
2668                                 if(!self.idlekick_lasttimeleft)
2669                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2670                         }
2671                         if(timeleft <= 0)
2672                         {
2673                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2674                                 dropclient(self);
2675                                 return;
2676                         }
2677                         else if(timeleft <= 10)
2678                         {
2679                                 if(timeleft != self.idlekick_lasttimeleft)
2680                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2681                                 self.idlekick_lasttimeleft = timeleft;
2682                         }
2683                 }
2684         }
2685
2686         CheatFrame();
2687
2688         //CheckPlayerJump();
2689
2690         if(IS_PLAYER(self)) {
2691                 CheckRules_Player();
2692                 UpdateChatBubble();
2693                 if (self.impulse)
2694                         ImpulseCommands();
2695                 if (intermission_running)
2696                         return;         // intermission or finale
2697                 GetPressedKeys();
2698         }
2699
2700         /*
2701         float i;
2702         for(i = 0; i < 1000; ++i)
2703         {
2704                 vector end;
2705                 end = self.origin + '0 0 1024' + 512 * randomvec();
2706                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2707                 if(trace_fraction < 1)
2708                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2709                 {
2710                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2711                         break;
2712                 }
2713         }
2714         */
2715
2716         if(self.waypointsprite_attachedforcarrier)
2717                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2718
2719         playerdemo_write();
2720
2721         CSQCMODEL_AUTOUPDATE(self);
2722 }