qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9
  10 void AnnounceTo(entity e, string snd) {
  11         if (clienttype(e) == CLIENTTYPE_REAL)
  12         {
  13                 msg_entity = e;
  14                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  15                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  16                 WriteString(MSG_ONE, snd);
  17         }
  18 }
  19
  20 float ClientData_Send(entity to, float sf)
  21 {
  22         if(to != self.owner)
  23         {
  24                 error("wtf");
  25                 return FALSE;
  26         }
  27
  28         entity e;
  29
  30         e = to;
  31         if(to.classname == "spectator")
  32                 e = to.enemy;
  33
  34         sf = 0;
  35
  36         if(e.race_completed)
  37                 sf |= 1; // forced scoreboard
  38         if(to.spectatee_status)
  39                 sf |= 2; // spectator ent number follows
  40         if(e.zoomstate)
  41                 sf |= 4; // zoomed
  42         if(e.porto_v_angle_held)
  43                 sf |= 8; // angles held
  44
  45         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  46         WriteByte(MSG_ENTITY, sf);
  47
  48         if(sf & 2)
  49                 WriteByte(MSG_ENTITY, to.spectatee_status);
  50
  51         if(sf & 8)
  52         {
  53                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  54                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  55         }
  56
  57         return TRUE;
  58 }
  59
  60 void ClientData_Attach()
  61 {
  62         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  63         self.clientdata.drawonlytoclient = self;
  64         self.clientdata.owner = self;
  65 }
  66
  67 void ClientData_Detach()
  68 {
  69         remove(self.clientdata);
  70         self.clientdata = world;
  71 }
  72
  73 void ClientData_Touch(entity e)
  74 {
  75         e.clientdata.SendFlags = 1;
  76
  77         // make it spectatable
  78         entity e2;
  79         FOR_EACH_REALCLIENT(e2)
  80         {
  81                 if(e2 != e)
  82                         if(e2.classname == "spectator")
  83                                 if(e2.enemy == e)
  84                                         e2.clientdata.SendFlags = 1;
  85         }
  86 }
  87
  88
  89 .vector spawnpoint_score;
  90 .string netname_previous;
  91
  92 void spawnfunc_info_player_survivor (void)
  93 {
  94         spawnfunc_info_player_deathmatch();
  95 }
  96
  97 void spawnfunc_info_player_start (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_deathmatch (void)
 103 {
 104         self.classname = "info_player_deathmatch";
 105         relocate_spawnpoint();
 106 }
 107
 108 void spawnpoint_use()
 109 {
 110         if(teamplay)
 111         if(have_team_spawns > 0)
 112         {
 113                 self.team = activator.team;
 114                 some_spawn_has_been_used = 1;
 115         }
 116 }
 117
 118 // Returns:
 119 //   _x: prio (-1 if unusable)
 120 //   _y: weight
 121 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 122 {
 123         float shortest, thisdist;
 124         float prio;
 125         entity player;
 126
 127         prio = 0;
 128
 129         // filter out spots for the wrong team
 130         if(teamcheck >= 0)
 131                 if(spot.team != teamcheck)
 132                         return '-1 0 0';
 133
 134         if(race_spawns)
 135                 if(spot.target == "")
 136                         return '-1 0 0';
 137
 138         if(clienttype(self) == CLIENTTYPE_REAL)
 139         {
 140                 if(spot.restriction == 1)
 141                         return '-1 0 0';
 142         }
 143         else
 144         {
 145                 if(spot.restriction == 2)
 146                         return '-1 0 0';
 147         }
 148
 149         shortest = vlen(world.maxs - world.mins);
 150         FOR_EACH_PLAYER(player) if (player != self)
 151         {
 152                 thisdist = vlen(player.origin - spot.origin);
 153                 if (thisdist < shortest)
 154                         shortest = thisdist;
 155         }
 156         if(shortest > mindist)
 157                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 158
 159         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 160         spawn_spot = spot;
 161
 162         // filter out spots for assault
 163         if(spot.target != "") {
 164                 entity ent;
 165                 float found;
 166
 167                 found = 0;
 168                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 169                 {
 170                         ++found;
 171                         if(ent.spawn_evalfunc)
 172                         {
 173                                 entity oldself = self;
 174                                 self = ent;
 175                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 176                                 self = oldself;
 177                                 if(spawn_score_x < 0)
 178                                         return spawn_score;
 179                         }
 180                 }
 181
 182                 if(!found)
 183                 {
 184                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 185                         return '-1 0 0';
 186                 }
 187         }
 188
 189         MUTATOR_CALLHOOK(Spawn_Score);
 190         return spawn_score;
 191 }
 192
 193 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 194 {
 195         entity spot;
 196         for(spot = firstspot; spot; spot = spot.chain)
 197                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 198 }
 199
 200 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 201 {
 202         entity spot, spotlist, spotlistend;
 203
 204         spotlist = world;
 205         spotlistend = world;
 206
 207         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 208
 209         for(spot = firstspot; spot; spot = spot.chain)
 210         {
 211                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 212                 {
 213                         if(spotlistend)
 214                                 spotlistend.chain = spot;
 215                         spotlistend = spot;
 216                         if(!spotlist)
 217                                 spotlist = spot;
 218                 }
 219         }
 220         if(spotlistend)
 221                 spotlistend.chain = world;
 222
 223         return spotlist;
 224 }
 225
 226 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 227 {
 228         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 229         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 230         entity spot;
 231
 232         RandomSelection_Init();
 233         for(spot = firstspot; spot; spot = spot.chain)
 234                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 235
 236         return RandomSelection_chosen_ent;
 237 }
 238
 239 /*
 240 =============
 241 SelectSpawnPoint
 242
 243 Finds a point to respawn
 244 =============
 245 */
 246 entity SelectSpawnPoint (float anypoint)
 247 {
 248         float teamcheck;
 249         entity spot, firstspot;
 250
 251         spot = find (world, classname, "testplayerstart");
 252         if (spot)
 253                 return spot;
 254
 255         if(anypoint || autocvar_g_spawn_useallspawns)
 256                 teamcheck = -1;
 257         else if(have_team_spawns > 0)
 258         {
 259                 if(have_team_spawns_forteam[self.team] == 0)
 260                 {
 261                         // we request a spawn for a team, and we have team
 262                         // spawns, but that team has no spawns?
 263                         if(have_team_spawns_forteam[0])
 264                                 // try noteam spawns
 265                                 teamcheck = 0;
 266                         else
 267                                 // if not, any spawn has to do
 268                                 teamcheck = -1;
 269                 }
 270                 else
 271                         teamcheck = self.team; // MUST be team
 272         }
 273         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 274                 teamcheck = 0; // MUST be noteam
 275         else
 276                 teamcheck = -1;
 277                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 278
 279
 280         // get the entire list of spots
 281         firstspot = findchain(classname, "info_player_deathmatch");
 282         // filter out the bad ones
 283         // (note this returns the original list if none survived)
 284         if(anypoint)
 285         {
 286                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 287         }
 288         else
 289         {
 290                 float mindist;
 291                 if (arena_roundbased && !g_ca)
 292                         mindist = 800;
 293                 else
 294                         mindist = 100;
 295                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 296
 297                 // there is 50/50 chance of choosing a random spot or the furthest spot
 298                 // (this means that roughly every other spawn will be furthest, so you
 299                 // usually won't get fragged at spawn twice in a row)
 300                 if (random() > autocvar_g_spawn_furthest)
 301                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 302                 else
 303                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 304         }
 305
 306         if (!spot)
 307         {
 308                 if(autocvar_spawn_debug)
 309                         GotoNextMap(0);
 310                 else
 311                 {
 312                         if(some_spawn_has_been_used)
 313                                 return world; // team can't spawn any more, because of actions of other team
 314                         else
 315                                 error("Cannot find a spawn point - please fix the map!");
 316                 }
 317         }
 318
 319         return spot;
 320 }
 321
 322 /*
 323 =============
 324 CheckPlayerModel
 325
 326 Checks if the argument string can be a valid playermodel.
 327 Returns a valid one in doubt.
 328 =============
 329 */
 330 string FallbackPlayerModel;
 331 string CheckPlayerModel(string plyermodel) {
 332         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 333         {
 334                 // note: we cannot summon Don Strunzone here, some player may
 335                 // still have the model string set. In case anyone manages how
 336                 // to change a cvar default, we'll have a small leak here.
 337                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 338         }
 339         // only in right path
 340         if( substring(plyermodel,0,14) != "models/player/")
 341                 return FallbackPlayerModel;
 342         // only good file extensions
 343         if(substring(plyermodel,-4,4) != ".zym")
 344         if(substring(plyermodel,-4,4) != ".dpm")
 345         if(substring(plyermodel,-4,4) != ".iqm")
 346         if(substring(plyermodel,-4,4) != ".md3")
 347         if(substring(plyermodel,-4,4) != ".psk")
 348                 return FallbackPlayerModel;
 349         // forbid the LOD models
 350         if(substring(plyermodel, -9,5) == "_lod1")
 351                 return FallbackPlayerModel;
 352         if(substring(plyermodel, -9,5) == "_lod2")
 353                 return FallbackPlayerModel;
 354         if(plyermodel != strtolower(plyermodel))
 355                 return FallbackPlayerModel;
 356         // also, restrict to server models
 357         if(autocvar_sv_servermodelsonly)
 358         {
 359                 if(!fexists(plyermodel))
 360                         return FallbackPlayerModel;
 361         }
 362         return plyermodel;
 363 }
 364
 365 void setplayermodel(entity e, string modelname)
 366 {
 367         precache_model(modelname);
 368         setmodel(e, modelname);
 369         player_setupanimsformodel();
 370         UpdatePlayerSounds();
 371 }
 372
 373 /*
 374 =============
 375 PutObserverInServer
 376
 377 putting a client as observer in the server
 378 =============
 379 */
 380 void FixPlayermodel();
 381 void PutObserverInServer (void)
 382 {
 383         entity  spot;
 384     self.hud = HUD_NORMAL;
 385         race_PreSpawnObserver();
 386
 387         spot = SelectSpawnPoint (TRUE);
 388         if(!spot)
 389                 error("No spawnpoints for observers?!?\n");
 390         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 391
 392         if(clienttype(self) == CLIENTTYPE_REAL)
 393         {
 394                 msg_entity = self;
 395                 WriteByte(MSG_ONE, SVC_SETVIEW);
 396                 WriteEntity(MSG_ONE, self);
 397         }
 398
 399         MUTATOR_CALLHOOK(MakePlayerObserver);
 400
 401         minstagib_stop_countdown(self);
 402
 403         Portal_ClearAll(self);
 404
 405         if(self.alivetime)
 406         {
 407                 if(!inWarmupStage)
 408                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 409                 self.alivetime = 0;
 410         }
 411
 412         if(self.vehicle)
 413                 vehicles_exit(VHEF_RELESE);
 414
 415         WaypointSprite_PlayerDead();
 416
 417         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 418                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 419
 420         if(self.killcount != -666) {
 421                 if(g_lms) {
 422                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
 423                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
 424                         else
 425                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
 426                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
 427
 428                 if(self.just_joined == FALSE) {
 429                         LogTeamchange(self.playerid, -1, 4);
 430                 } else
 431                         self.just_joined = FALSE;
 432         }
 433
 434         PlayerScore_Clear(self); // clear scores when needed
 435
 436         accuracy_resend(self);
 437
 438         self.spectatortime = time;
 439
 440         self.classname = "observer";
 441         self.iscreature = FALSE;
 442         self.teleportable = TELEPORT_SIMPLE;
 443         self.damagedbycontents = FALSE;
 444         self.health = -666;
 445         self.takedamage = DAMAGE_NO;
 446         self.solid = SOLID_NOT;
 447         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 448         self.flags = FL_CLIENT | FL_NOTARGET;
 449         self.armorvalue = 666;
 450         self.effects = 0;
 451         self.armorvalue = autocvar_g_balance_armor_start;
 452         self.pauserotarmor_finished = 0;
 453         self.pauserothealth_finished = 0;
 454         self.pauseregen_finished = 0;
 455         self.damageforcescale = 0;
 456         self.death_time = 0;
 457         self.respawn_time = 0;
 458         self.alpha = 0;
 459         self.scale = 0;
 460         self.fade_time = 0;
 461         self.pain_frame = 0;
 462         self.pain_finished = 0;
 463         self.strength_finished = 0;
 464         self.invincible_finished = 0;
 465         self.superweapons_finished = 0;
 466         self.pushltime = 0;
 467         self.istypefrag = 0;
 468         self.think = func_null;
 469         self.nextthink = 0;
 470         self.hook_time = 0;
 471         self.deadflag = DEAD_NO;
 472         self.angles = spot.angles;
 473         self.angles_z = 0;
 474         self.fixangle = TRUE;
 475         self.crouch = FALSE;
 476
 477         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 478         self.prevorigin = self.origin;
 479         self.items = 0;
 480         WEPSET_CLEAR_E(self);
 481         self.model = "";
 482         FixPlayermodel();
 483         setmodel(self, "null");
 484         self.drawonlytoclient = self;
 485
 486         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 487         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 488
 489         self.weapon = 0;
 490         self.weaponname = "";
 491         self.switchingweapon = 0;
 492         self.weaponmodel = "";
 493         self.weaponentity = world;
 494         self.exteriorweaponentity = world;
 495         self.killcount = -666;
 496         self.velocity = '0 0 0';
 497         self.avelocity = '0 0 0';
 498         self.punchangle = '0 0 0';
 499         self.punchvector = '0 0 0';
 500         self.oldvelocity = self.velocity;
 501         self.fire_endtime = -1;
 502
 503         if(g_arena)
 504         {
 505                 if(self.version_mismatch)
 506                 {
 507                         self.frags = FRAGS_SPECTATOR;
 508                         Spawnqueue_Unmark(self);
 509                         Spawnqueue_Remove(self);
 510                 }
 511                 else
 512                 {
 513                         self.frags = FRAGS_LMS_LOSER;
 514                         Spawnqueue_Insert(self);
 515                 }
 516         }
 517         else if(g_lms)
 518         {
 519                 // Only if the player cannot play at all
 520                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 521                         self.frags = FRAGS_SPECTATOR;
 522                 else
 523                         self.frags = FRAGS_LMS_LOSER;
 524         }
 525         else if(g_ca)
 526         {
 527                 if(self.caplayer)
 528                         self.frags = FRAGS_LMS_LOSER;
 529                 else
 530                         self.frags = FRAGS_SPECTATOR;
 531         }
 532         else if((g_race && g_race_qualifying) || g_cts)
 533         {
 534                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 535                         self.frags = FRAGS_LMS_LOSER;
 536                 else
 537                         self.frags = FRAGS_SPECTATOR;
 538         }
 539         else
 540                 self.frags = FRAGS_SPECTATOR;
 541 }
 542
 543 .float model_randomizer;
 544 void FixPlayermodel()
 545 {
 546         string defaultmodel;
 547         float defaultskin, chmdl, oldskin, n, i;
 548         vector m1, m2;
 549
 550         defaultmodel = "";
 551         defaultskin = 0;
 552         chmdl = FALSE;
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 if(teamplay)
 557                 {
 558                         string s;
 559                         s = Team_ColorName_Lower(self.team);
 560                         if(s != "neutral")
 561                         {
 562                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 563                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 564                         }
 565                 }
 566
 567                 if(defaultmodel == "")
 568                 {
 569                         defaultmodel = autocvar_sv_defaultplayermodel;
 570                         defaultskin = autocvar_sv_defaultplayerskin;
 571                 }
 572
 573                 n = tokenize_console(defaultmodel);
 574                 if(n > 0)
 575                         defaultmodel = argv(floor(n * self.model_randomizer));
 576
 577                 i = strstrofs(defaultmodel, ":", 0);
 578                 if(i >= 0)
 579                 {
 580                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 581                         defaultmodel = substring(defaultmodel, 0, i);
 582                 }
 583         }
 584
 585         if(defaultmodel != "")
 586         {
 587                 if (defaultmodel != self.model)
 588                 {
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, defaultmodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = defaultskin;
 598         } else {
 599                 if (self.playermodel != self.model || self.playermodel == "")
 600                 {
 601                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 602                         m1 = self.mins;
 603                         m2 = self.maxs;
 604                         setplayermodel (self, self.playermodel);
 605                         setsize (self, m1, m2);
 606                         chmdl = TRUE;
 607                 }
 608
 609                 oldskin = self.skin;
 610                 self.skin = stof(self.playerskin);
 611         }
 612
 613         if(chmdl || oldskin != self.skin) // model or skin has changed
 614         {
 615                 self.species = player_getspecies(); // update species
 616                 UpdatePlayerSounds(); // update skin sounds
 617         }
 618
 619         if(!teamplay)
 620                 if(strlen(autocvar_sv_defaultplayercolors))
 621                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 622                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 623 }
 624
 625 void PlayerTouchExplode(entity p1, entity p2)
 626 {
 627         vector org;
 628         org = (p1.origin + p2.origin) * 0.5;
 629         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 630
 631         te_explosion(org);
 632
 633         entity e;
 634         e = spawn();
 635         setorigin(e, org);
 636         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 637         remove(e);
 638 }
 639
 640 /*
 641 =============
 642 PutClientInServer
 643
 644 Called when a client spawns in the server
 645 =============
 646 */
 647
 648 void PutClientInServer (void)
 649 {
 650         if(clienttype(self) == CLIENTTYPE_BOT)
 651         {
 652                 self.classname = "player";
 653                 if(g_ca)
 654                         self.caplayer = 1;
 655         }
 656         else if(clienttype(self) == CLIENTTYPE_REAL)
 657         {
 658                 msg_entity = self;
 659                 WriteByte(MSG_ONE, SVC_SETVIEW);
 660                 WriteEntity(MSG_ONE, self);
 661         }
 662
 663         // reset player keys
 664         self.itemkeys = 0;
 665
 666         // player is dead and becomes observer
 667         // FIXME fix LMS scoring for new system
 668         if(g_lms)
 669         {
 670                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 671                         self.classname = "observer";
 672         }
 673
 674         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 675                 self.classname = "observer";
 676
 677         if(gameover)
 678                 self.classname = "observer";
 679
 680         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 681                 entity spot, oldself;
 682                 float j;
 683
 684                 accuracy_resend(self);
 685
 686                 if(self.team < 0)
 687                         JoinBestTeam(self, FALSE, TRUE);
 688
 689                 race_PreSpawn();
 690
 691                 spot = SelectSpawnPoint (FALSE);
 692                 if(!spot)
 693                 {
 694                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 695                         return; // spawn failed
 696                 }
 697
 698                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 699
 700                 self.classname = "player";
 701                 self.wasplayer = TRUE;
 702                 self.iscreature = TRUE;
 703                 self.teleportable = TELEPORT_NORMAL;
 704                 self.damagedbycontents = TRUE;
 705                 self.movetype = MOVETYPE_WALK;
 706                 self.solid = SOLID_SLIDEBOX;
 707                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 708                 if(autocvar_g_playerclip_collisions)
 709                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 710                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 711                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 712                 self.frags = FRAGS_PLAYER;
 713                 if(INDEPENDENT_PLAYERS)
 714                         MAKE_INDEPENDENT_PLAYER(self);
 715                 self.flags = FL_CLIENT;
 716                 if(autocvar__notarget)
 717                         self.flags |= FL_NOTARGET;
 718                 self.takedamage = DAMAGE_AIM;
 719                 if(g_minstagib)
 720                         self.effects = EF_FULLBRIGHT;
 721                 else
 722                         self.effects = 0;
 723                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 724                 self.air_finished = time + 12;
 725                 self.dmg = 2;
 726                 if(autocvar_g_balance_nex_charge)
 727                 {
 728                         if(autocvar_g_balance_nex_secondary_chargepool)
 729                                 self.nex_chargepool_ammo = 1;
 730                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 731                 }
 732
 733                 if(inWarmupStage)
 734                 {
 735                         self.ammo_shells = warmup_start_ammo_shells;
 736                         self.ammo_nails = warmup_start_ammo_nails;
 737                         self.ammo_rockets = warmup_start_ammo_rockets;
 738                         self.ammo_cells = warmup_start_ammo_cells;
 739                         self.ammo_fuel = warmup_start_ammo_fuel;
 740                         self.health = warmup_start_health;
 741                         self.armorvalue = warmup_start_armorvalue;
 742                         WEPSET_COPY_EA(self, warmup_start_weapons);
 743                 }
 744                 else
 745                 {
 746                         self.ammo_shells = start_ammo_shells;
 747                         self.ammo_nails = start_ammo_nails;
 748                         self.ammo_rockets = start_ammo_rockets;
 749                         self.ammo_cells = start_ammo_cells;
 750                         self.ammo_fuel = start_ammo_fuel;
 751                         self.health = start_health;
 752                         self.armorvalue = start_armorvalue;
 753                         WEPSET_COPY_EA(self, start_weapons);
 754                 }
 755
 756                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 757                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 758                 else
 759                         self.superweapons_finished = 0;
 760
 761                 if(g_weaponarena_random)
 762                 {
 763                         if(g_weaponarena_random_with_laser)
 764                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 765                         W_RandomWeapons(self, g_weaponarena_random);
 766                         if(g_weaponarena_random_with_laser)
 767                                 WEPSET_OR_EW(self, WEP_LASER);
 768                 }
 769
 770                 self.items = start_items;
 771
 772                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 773                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 774                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 775                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 776                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 777                 //extend the pause of rotting if client was reset at the beginning of the countdown
 778                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 779                         self.spawnshieldtime += game_starttime - time;
 780                         self.pauserotarmor_finished += game_starttime - time;
 781                         self.pauserothealth_finished += game_starttime - time;
 782                         self.pauseregen_finished += game_starttime - time;
 783                 }
 784                 self.damageforcescale = 2;
 785                 self.death_time = 0;
 786                 self.respawn_time = 0;
 787                 self.scale = 0;
 788                 self.fade_time = 0;
 789                 self.pain_frame = 0;
 790                 self.pain_finished = 0;
 791                 self.strength_finished = 0;
 792                 self.invincible_finished = 0;
 793                 self.pushltime = 0;
 794                 // players have no think function
 795                 self.think = func_null;
 796                 self.nextthink = 0;
 797                 self.hook_time = 0;
 798                 self.dmg_team = 0;
 799                 self.ballistics_density = autocvar_g_ballistics_density_player;
 800
 801                 self.metertime = 0;
 802
 803                 self.deadflag = DEAD_NO;
 804
 805                 self.angles = spot.angles;
 806
 807                 self.angles_z = 0; // never spawn tilted even if the spot says to
 808                 self.fixangle = TRUE; // turn this way immediately
 809                 self.velocity = '0 0 0';
 810                 self.avelocity = '0 0 0';
 811                 self.punchangle = '0 0 0';
 812                 self.punchvector = '0 0 0';
 813                 self.oldvelocity = self.velocity;
 814                 self.fire_endtime = -1;
 815
 816                 msg_entity = self;
 817                 WRITESPECTATABLE_MSG_ONE({
 818                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 819                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 820                 });
 821
 822                 self.model = "";
 823                 FixPlayermodel();
 824                 self.drawonlytoclient = world;
 825
 826                 self.crouch = FALSE;
 827                 self.view_ofs = PL_VIEW_OFS;
 828                 setsize (self, PL_MIN, PL_MAX);
 829                 self.spawnorigin = spot.origin;
 830                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 831                 // don't reset back to last position, even if new position is stuck in solid
 832                 self.oldorigin = self.origin;
 833                 self.prevorigin = self.origin;
 834                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 835                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 836         self.hud = HUD_NORMAL;
 837
 838                 if(g_arena)
 839                 {
 840                         Spawnqueue_Remove(self);
 841                         Spawnqueue_Mark(self);
 842                 }
 843                 else if(g_ca)
 844                         self.caplayer = 1;
 845
 846                 self.event_damage = PlayerDamage;
 847
 848                 self.bot_attack = TRUE;
 849
 850                 self.statdraintime = time + 5;
 851                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 852
 853                 if(self.killcount == -666) {
 854                         PlayerScore_Clear(self);
 855                         self.killcount = 0;
 856                 }
 857
 858                 CL_SpawnWeaponentity();
 859                 self.alpha = default_player_alpha;
 860                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 861                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 862
 863                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 864                 self.lms_traveled_distance = 0;
 865                 self.speedrunning = FALSE;
 866
 867                 race_PostSpawn(spot);
 868
 869                 //stuffcmd(self, "chase_active 0");
 870                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 871
 872                 if(g_assault) {
 873                         if(self.team == assault_attacker_team)
 874                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 875                         else
 876                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 877                 }
 878
 879                 target_voicescript_clear(self);
 880
 881                 // reset fields the weapons may use
 882                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 883                 {
 884                         weapon_action(j, WR_RESETPLAYER);
 885
 886                         // all weapons must be fully loaded when we spawn
 887                         entity e;
 888                         e = get_weaponinfo(j);
 889                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 890                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 891                 }
 892
 893                 oldself = self;
 894                 self = spot;
 895                         activator = oldself;
 896                                 string s;
 897                                 s = self.target;
 898                                 self.target = string_null;
 899                                 SUB_UseTargets();
 900                                 self.target = s;
 901                         activator = world;
 902                 self = oldself;
 903
 904                 spawn_spot = spot;
 905                 MUTATOR_CALLHOOK(PlayerSpawn);
 906
 907                 if(autocvar_spawn_debug)
 908                 {
 909                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 910                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 911                 }
 912
 913                 self.switchweapon = w_getbestweapon(self);
 914                 self.cnt = -1; // W_LastWeapon will not complain
 915                 self.weapon = 0;
 916                 self.weaponname = "";
 917                 self.switchingweapon = 0;
 918
 919                 if(!inWarmupStage)
 920                         if(!self.alivetime)
 921                                 self.alivetime = time;
 922
 923                 antilag_clear(self);
 924
 925                 if (autocvar_g_spawnsound)
 926                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 927         } else if(self.classname == "observer") {
 928                 PutObserverInServer ();
 929         }
 930 }
 931
 932 .float ebouncefactor, ebouncestop; // electro's values
 933 // TODO do we need all these fields, or should we stop autodetecting runtime
 934 // changes and just have a console command to update this?
 935 float ClientInit_SendEntity(entity to, float sf)
 936 {
 937         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 938         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 951         if(sv_foginterval && world.fog != "")
 952                 WriteString(MSG_ENTITY, world.fog);
 953         else
 954                 WriteString(MSG_ENTITY, "");
 955         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 956         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 957         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 958         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 959         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 960         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 962         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 963         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 965         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 966         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 967         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 968         return TRUE;
 969 }
 970
 971 void ClientInit_CheckUpdate()
 972 {
 973         self.nextthink = time;
 974         if(self.count != autocvar_g_balance_armor_blockpercent)
 975         {
 976                 self.count = autocvar_g_balance_armor_blockpercent;
 977                 self.SendFlags |= 1;
 978         }
 979         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 980         {
 981                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 982                 self.SendFlags |= 1;
 983         }
 984         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 985         {
 986                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 987                 self.SendFlags |= 1;
 988         }
 989         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 990         {
 991                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 992                 self.SendFlags |= 1;
 993         }
 994         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 995         {
 996                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 997                 self.SendFlags |= 1;
 998         }
 999         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1000         {
1001                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1002                 self.SendFlags |= 1;
1003         }
1004 }
1005
1006 void ClientInit_Spawn()
1007 {
1008         entity o;
1009         entity e;
1010         e = spawn();
1011         e.classname = "clientinit";
1012         e.think = ClientInit_CheckUpdate;
1013         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1014
1015         o = self;
1016         self = e;
1017         ClientInit_CheckUpdate();
1018         self = o;
1019 }
1020
1021 /*
1022 =============
1023 SetNewParms
1024 =============
1025 */
1026 void SetNewParms (void)
1027 {
1028         // initialize parms for a new player
1029         parm1 = -(86400 * 366);
1030 }
1031
1032 /*
1033 =============
1034 SetChangeParms
1035 =============
1036 */
1037 void SetChangeParms (void)
1038 {
1039         // save parms for level change
1040         parm1 = self.parm_idlesince - time;
1041 }
1042
1043 /*
1044 =============
1045 DecodeLevelParms
1046 =============
1047 */
1048 void DecodeLevelParms (void)
1049 {
1050         // load parms
1051         self.parm_idlesince = parm1;
1052         if(self.parm_idlesince == -(86400 * 366))
1053                 self.parm_idlesince = time;
1054
1055         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1056         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1057 }
1058
1059 /*
1060 =============
1061 ClientKill
1062
1063 Called when a client types 'kill' in the console
1064 =============
1065 */
1066
1067 .float clientkill_nexttime;
1068 void ClientKill_Now_TeamChange()
1069 {
1070         if(self.killindicator_teamchange == -1)
1071         {
1072                 JoinBestTeam( self, FALSE, TRUE );
1073         }
1074         else if(self.killindicator_teamchange == -2)
1075         {
1076                 if(g_ca)
1077                         self.caplayer = 0;
1078                 if(blockSpectators)
1079                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1080                 PutObserverInServer();
1081         }
1082         else
1083                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1084 }
1085
1086 void ClientKill_Now()
1087 {
1088         if(self.vehicle)
1089         {
1090             vehicles_exit(VHEF_RELESE);
1091             if(!self.killindicator_teamchange)
1092             {
1093             self.vehicle_health = -1;
1094             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1095             }
1096         }
1097
1098         if(self.killindicator && !wasfreed(self.killindicator))
1099                 remove(self.killindicator);
1100
1101         self.killindicator = world;
1102
1103         if(self.killindicator_teamchange)
1104                 ClientKill_Now_TeamChange();
1105
1106         // in any case:
1107         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1108
1109         // now I am sure the player IS dead
1110 }
1111 void KillIndicator_Think()
1112 {
1113         if (gameover)
1114         {
1115                 self.owner.killindicator = world;
1116                 remove(self);
1117                 return;
1118         }
1119
1120         if (self.owner.alpha < 0 && !self.owner.vehicle)
1121         {
1122                 self.owner.killindicator = world;
1123                 remove(self);
1124                 return;
1125         }
1126
1127         if(self.cnt <= 0)
1128         {
1129                 self = self.owner;
1130                 ClientKill_Now(); // no oldself needed
1131                 return;
1132         }
1133     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1134     {
1135         self.nextthink = time + 1;
1136         self.cnt -= 1;
1137     }
1138         else
1139         {
1140                 if(self.cnt <= 10)
1141                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1142                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1143                 {
1144                         if(self.cnt <= 10)
1145                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1146                 }
1147                 self.nextthink = time + 1;
1148                 self.cnt -= 1;
1149         }
1150 }
1151
1152 float clientkilltime;
1153 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1154 {
1155         float killtime;
1156         float starttime;
1157         entity e;
1158
1159         if (gameover)
1160                 return;
1161
1162         killtime = autocvar_g_balance_kill_delay;
1163
1164         if(g_race_qualifying || g_cts)
1165                 killtime = 0;
1166
1167     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1168     {
1169                 remove(self.killindicator);
1170                 self.killindicator = world;
1171
1172         ClientKill_Now(); // allow instant kill in this case
1173         return;
1174     }
1175
1176         self.killindicator_teamchange = targetteam;
1177
1178     if(!self.killindicator)
1179         {
1180                 if(self.deadflag == DEAD_NO)
1181                 {
1182                         killtime = max(killtime, self.clientkill_nexttime - time);
1183                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1184                 }
1185
1186                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1187                 {
1188                         ClientKill_Now();
1189                 }
1190                 else
1191                 {
1192                         starttime = max(time, clientkilltime);
1193
1194                         self.killindicator = spawn();
1195                         self.killindicator.owner = self;
1196                         self.killindicator.scale = 0.5;
1197                         setattachment(self.killindicator, self, "");
1198                         setorigin(self.killindicator, '0 0 52');
1199                         self.killindicator.think = KillIndicator_Think;
1200                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1201                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1202                         self.killindicator.cnt = ceil(killtime);
1203                         self.killindicator.count = bound(0, ceil(killtime), 10);
1204                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1205
1206                         for(e = world; (e = find(e, classname, "body")) != world; )
1207                         {
1208                                 if(e.enemy != self)
1209                                         continue;
1210                                 e.killindicator = spawn();
1211                                 e.killindicator.owner = e;
1212                                 e.killindicator.scale = 0.5;
1213                                 setattachment(e.killindicator, e, "");
1214                                 setorigin(e.killindicator, '0 0 52');
1215                                 e.killindicator.think = KillIndicator_Think;
1216                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1217                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1218                                 e.killindicator.cnt = ceil(killtime);
1219                         }
1220                         self.lip = 0;
1221                 }
1222         }
1223         if(self.killindicator)
1224         {
1225                 if(targetteam == 0) // just die
1226                 {
1227                         self.killindicator.colormod = '0 0 0';
1228                         if(clienttype(self) == CLIENTTYPE_REAL)
1229                         if(self.killindicator.cnt > 0)
1230                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1231                 }
1232                 else if(targetteam == -1) // auto
1233                 {
1234                         self.killindicator.colormod = '0 1 0';
1235                         if(clienttype(self) == CLIENTTYPE_REAL)
1236                         if(self.killindicator.cnt > 0)
1237                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1238                 }
1239                 else if(targetteam == -2) // spectate
1240                 {
1241                         self.killindicator.colormod = '0.5 0.5 0.5';
1242                         if(clienttype(self) == CLIENTTYPE_REAL)
1243                         if(self.killindicator.cnt > 0)
1244                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1245                 }
1246                 else
1247                 {
1248                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1249                         if(clienttype(self) == CLIENTTYPE_REAL)
1250                         if(self.killindicator.cnt > 0)
1251                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1252                 }
1253         }
1254
1255 }
1256
1257 void ClientKill (void)
1258 {
1259         if (gameover)
1260                 return;
1261
1262         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1263         {
1264                 // do nothing
1265         }
1266     else if(self.freezetag_frozen)
1267     {
1268         // do nothing
1269     }
1270         else
1271                 ClientKill_TeamChange(0);
1272 }
1273
1274 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1275 {
1276     e.killindicator = spawn();
1277     e.killindicator.owner = e;
1278     e.killindicator.think = KillIndicator_Think;
1279     e.killindicator.nextthink = time + (e.lip) * 0.05;
1280     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1281     e.killindicator.health = 1; // this is used to indicate that it should be silent
1282     e.lip = 0;
1283 }
1284
1285 void FixClientCvars(entity e)
1286 {
1287         // send prediction settings to the client
1288         stuffcmd(e, "\nin_bindmap 0 0\n");
1289         if(g_race || g_cts)
1290                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1291         if(autocvar_g_antilag == 3) // client side hitscan
1292                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1293         if(autocvar_sv_gentle)
1294                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1295         /*
1296          * we no longer need to stuff this. Remove this comment block if you feel
1297          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1298         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1299         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1300         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1301         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1302         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1303         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1304         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1305         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1306         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1307         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1308         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1309         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1310         stuffcmd(e, "cl_movement_edgefriction 1\n");
1311          */
1312 }
1313
1314 float PlayerInIDList(entity p, string idlist)
1315 {
1316         float n, i;
1317         string s;
1318
1319         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1320         if not(p.crypto_idfp)
1321                 return 0;
1322
1323         // this function allows abbreviated player IDs too!
1324         n = tokenize_console(idlist);
1325         for(i = 0; i < n; ++i)
1326         {
1327                 s = argv(i);
1328                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1329                         return 1;
1330         }
1331
1332         return 0;
1333 }
1334
1335 /*
1336 =============
1337 ClientConnect
1338
1339 Called when a client connects to the server
1340 =============
1341 */
1342 void DecodeLevelParms (void);
1343 //void dom_player_join_team(entity pl);
1344 void set_dom_state(entity e);
1345 void ClientConnect (void)
1346 {
1347         float t;
1348
1349         if(self.flags & FL_CLIENT)
1350         {
1351                 print("Warning: ClientConnect, but already connected!\n");
1352                 return;
1353         }
1354
1355         if(Ban_MaybeEnforceBanOnce(self))
1356                 return;
1357
1358         DecodeLevelParms();
1359
1360 #ifdef WATERMARK
1361         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1362 #endif
1363
1364         self.classname = "player_joining";
1365
1366         self.flags = FL_CLIENT;
1367         self.version_nagtime = time + 10 + random() * 10;
1368
1369         if(player_count<0)
1370         {
1371                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1372                 player_count = 0;
1373         }
1374
1375         PlayerScore_Attach(self);
1376         ClientData_Attach();
1377         accuracy_init(self);
1378
1379         bot_clientconnect();
1380
1381         playerdemo_init();
1382
1383         anticheat_init();
1384
1385         race_PreSpawnObserver();
1386
1387         // identify the right forced team
1388         if(autocvar_g_campaign)
1389         {
1390                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1391                 {
1392                         switch(autocvar_g_campaign_forceteam)
1393                         {
1394                                 case 1: self.team_forced = NUM_TEAM_1; break;
1395                                 case 2: self.team_forced = NUM_TEAM_2; break;
1396                                 case 3: self.team_forced = NUM_TEAM_3; break;
1397                                 case 4: self.team_forced = NUM_TEAM_4; break;
1398                                 default: self.team_forced = 0;
1399                         }
1400                 }
1401         }
1402         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1403                 self.team_forced = NUM_TEAM_1;
1404         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1405                 self.team_forced = NUM_TEAM_2;
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1407                 self.team_forced = NUM_TEAM_3;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1409                 self.team_forced = NUM_TEAM_4;
1410         else if(autocvar_g_forced_team_otherwise == "red")
1411                 self.team_forced = NUM_TEAM_1;
1412         else if(autocvar_g_forced_team_otherwise == "blue")
1413                 self.team_forced = NUM_TEAM_2;
1414         else if(autocvar_g_forced_team_otherwise == "yellow")
1415                 self.team_forced = NUM_TEAM_3;
1416         else if(autocvar_g_forced_team_otherwise == "pink")
1417                 self.team_forced = NUM_TEAM_4;
1418         else if(autocvar_g_forced_team_otherwise == "spectate")
1419                 self.team_forced = -1;
1420         else if(autocvar_g_forced_team_otherwise == "spectator")
1421                 self.team_forced = -1;
1422         else
1423                 self.team_forced = 0;
1424
1425         if(!teamplay)
1426                 if(self.team_forced > 0)
1427                         self.team_forced = 0;
1428
1429         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1430
1431         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1432                 self.classname = "observer";
1433         } else {
1434                 if(teamplay)
1435                 {
1436                         if(autocvar_g_balance_teams)
1437                         {
1438                                 self.classname = "player";
1439                                 campaign_bots_may_start = 1;
1440                         }
1441                         else
1442                         {
1443                                 self.classname = "observer"; // do it anyway
1444                         }
1445                 }
1446                 else
1447                 {
1448                         self.classname = "player";
1449                         campaign_bots_may_start = 1;
1450                 }
1451         }
1452
1453         self.playerid = (playerid_last = playerid_last + 1);
1454
1455         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1456
1457     if(clienttype(self) == CLIENTTYPE_BOT)
1458         PlayerStats_AddPlayer(self);
1459
1460         if(autocvar_sv_eventlog)
1461                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1462
1463         LogTeamchange(self.playerid, self.team, 1);
1464
1465         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1466
1467         self.netname_previous = strzone(self.netname);
1468
1469         if((self.classname == STR_PLAYER && teamplay))
1470                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1471         else
1472                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1473
1474         stuffcmd(self, strcat(clientstuff, "\n"));
1475         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1476
1477         FixClientCvars(self);
1478
1479         // spawnfunc_waypoint sprites
1480         WaypointSprite_InitClient(self);
1481
1482         // Wazat's grappling hook
1483         SetGrappleHookBindings();
1484
1485         // get version info from player
1486         stuffcmd(self, "cmd clientversion $gameversion\n");
1487
1488         // get other cvars from player
1489         GetCvars(0);
1490
1491         // notify about available teams
1492         if(teamplay)
1493         {
1494                 CheckAllowedTeams(self);
1495                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1496                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1497         }
1498         else
1499                 stuffcmd(self, "set _teams_available 0\n");
1500
1501         if(g_arena || g_ca)
1502         {
1503                 self.classname = "observer";
1504                 if(g_arena)
1505                         Spawnqueue_Insert(self);
1506         }
1507
1508         attach_entcs();
1509
1510         bot_relinkplayerlist();
1511
1512         self.spectatortime = time;
1513         if(blockSpectators)
1514         {
1515                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1516         }
1517
1518         self.jointime = time;
1519         self.allowed_timeouts = autocvar_sv_timeout_number;
1520
1521         if(clienttype(self) == CLIENTTYPE_REAL)
1522         {
1523                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1524                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1525         }
1526
1527         if(g_lms)
1528         {
1529                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1530                 {
1531                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1532                         self.frags = FRAGS_SPECTATOR;
1533                 }
1534         }
1535
1536         if(!sv_foginterval && world.fog != "")
1537                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1538
1539         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1540         {
1541                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1542                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1543         }
1544         else
1545                 self.hitplotfh = -1;
1546
1547         if(g_race || g_cts) {
1548                 string rr;
1549                 if(g_cts)
1550                         rr = CTS_RECORD;
1551                 else
1552                         rr = RACE_RECORD;
1553
1554                 msg_entity = self;
1555                 race_send_recordtime(MSG_ONE);
1556                 race_send_speedaward(MSG_ONE);
1557
1558                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1559                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1560                 race_send_speedaward_alltimebest(MSG_ONE);
1561
1562                 float i;
1563                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1564                         race_SendRankings(i, 0, 0, MSG_ONE);
1565                 }
1566         }
1567         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1568                 send_CSQC_teamnagger();
1569
1570         CheatInitClient();
1571
1572         if(!autocvar_g_campaign)
1573                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1574
1575         CSQCMODEL_AUTOINIT();
1576
1577         self.model_randomizer = random();
1578
1579     if(clienttype(self) != CLIENTTYPE_REAL)
1580         return;
1581
1582     sv_notice_join();
1583
1584     MUTATOR_CALLHOOK(ClientConnect);
1585 }
1586 /*
1587 =============
1588 ClientDisconnect
1589
1590 Called when a client disconnects from the server
1591 =============
1592 */
1593 .entity chatbubbleentity;
1594 void ReadyCount();
1595 void ClientDisconnect (void)
1596 {
1597         if(self.vehicle)
1598             vehicles_exit(VHEF_RELESE);
1599
1600         if not(self.flags & FL_CLIENT)
1601         {
1602                 print("Warning: ClientDisconnect without ClientConnect\n");
1603                 return;
1604         }
1605
1606         PlayerStats_AddGlobalInfo(self);
1607
1608         CheatShutdownClient();
1609
1610         if(self.hitplotfh >= 0)
1611         {
1612                 fclose(self.hitplotfh);
1613                 self.hitplotfh = -1;
1614         }
1615
1616         anticheat_report();
1617         anticheat_shutdown();
1618
1619         playerdemo_shutdown();
1620
1621         bot_clientdisconnect();
1622
1623         if(self.entcs)
1624                 detach_entcs();
1625
1626         if(autocvar_sv_eventlog)
1627                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1628
1629         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1630
1631         MUTATOR_CALLHOOK(ClientDisconnect);
1632
1633         Portal_ClearAll(self);
1634
1635         RemoveGrapplingHook(self);
1636
1637         // Here, everything has been done that requires this player to be a client.
1638
1639         self.flags &~= FL_CLIENT;
1640
1641         if (self.chatbubbleentity)
1642                 remove (self.chatbubbleentity);
1643
1644         if (self.killindicator)
1645                 remove (self.killindicator);
1646
1647         WaypointSprite_PlayerGone();
1648
1649         bot_relinkplayerlist();
1650
1651         if(g_arena)
1652         {
1653                 Spawnqueue_Unmark(self);
1654                 Spawnqueue_Remove(self);
1655         }
1656
1657         accuracy_free(self);
1658         ClientData_Detach();
1659         PlayerScore_Detach(self);
1660
1661         if(self.netname_previous)
1662                 strunzone(self.netname_previous);
1663         if(self.clientstatus)
1664                 strunzone(self.clientstatus);
1665         if(self.weaponorder_byimpulse)
1666                 strunzone(self.weaponorder_byimpulse);
1667
1668         ClearPlayerSounds();
1669
1670         if(self.personal)
1671                 remove(self.personal);
1672
1673         self.playerid = 0;
1674         ReadyCount();
1675
1676         // free cvars
1677         GetCvars(-1);
1678 }
1679
1680 .float BUTTON_CHAT;
1681 void ChatBubbleThink()
1682 {
1683         self.nextthink = time;
1684         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1685         {
1686                 if(self.owner) // but why can that ever be world?
1687                         self.owner.chatbubbleentity = world;
1688                 remove(self);
1689                 return;
1690         }
1691         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1692 #ifdef TETRIS
1693                 || self.owner.tetris_on
1694 #endif
1695         )
1696                 self.model = self.mdl;
1697         else
1698                 self.model = "";
1699 }
1700
1701 void UpdateChatBubble()
1702 {
1703         if (self.alpha < 0)
1704                 return;
1705         // spawn a chatbubble entity if needed
1706         if (!self.chatbubbleentity)
1707         {
1708                 self.chatbubbleentity = spawn();
1709                 self.chatbubbleentity.owner = self;
1710                 self.chatbubbleentity.exteriormodeltoclient = self;
1711                 self.chatbubbleentity.think = ChatBubbleThink;
1712                 self.chatbubbleentity.nextthink = time;
1713                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1714                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1715                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1716                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1717                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1718                 self.chatbubbleentity.model = "";
1719                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1720         }
1721 }
1722
1723
1724 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1725 // added to the model skins
1726 /*void UpdateColorModHack()
1727 {
1728         float c;
1729         c = self.clientcolors & 15;
1730         // LordHavoc: only bothering to support white, green, red, yellow, blue
1731              if (!teamplay) self.colormod = '0 0 0';
1732         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1733         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1734         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1735         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1736         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1737         else self.colormod = '1 1 1';
1738 }*/
1739
1740 void respawn(void)
1741 {
1742         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1743         {
1744                 self.solid = SOLID_NOT;
1745                 self.takedamage = DAMAGE_NO;
1746                 self.movetype = MOVETYPE_FLY;
1747                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1748                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1749                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1750                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1751                 if(autocvar_g_respawn_ghosts_maxtime)
1752                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1753         }
1754
1755         CopyBody(1);
1756
1757         self.effects |= EF_NODRAW; // prevent another CopyBody
1758         PutClientInServer();
1759 }
1760
1761 void play_countdown(float finished, string samp)
1762 {
1763         if(clienttype(self) == CLIENTTYPE_REAL)
1764                 if(floor(finished - time - frametime) != floor(finished - time))
1765                         if(finished - time < 6)
1766                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1767 }
1768
1769 void player_powerups (void)
1770 {
1771         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1772         olditems = self.items;
1773
1774         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1775                 self.modelflags |= MF_ROCKET;
1776         else
1777                 self.modelflags &~= MF_ROCKET;
1778
1779         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1780
1781         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1782                 return;
1783
1784         Fire_ApplyDamage(self);
1785         Fire_ApplyEffect(self);
1786
1787         if (g_minstagib)
1788         {
1789                 self.effects |= EF_FULLBRIGHT;
1790
1791                 if (self.items & IT_STRENGTH)
1792                 {
1793                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1794                         if (time > self.strength_finished)
1795                         {
1796                                 self.alpha = default_player_alpha;
1797                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1798                                 self.items &~= IT_STRENGTH;
1799                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1800                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1801                         }
1802                 }
1803                 else
1804                 {
1805                         if (time < self.strength_finished)
1806                         {
1807                                 self.alpha = g_minstagib_invis_alpha;
1808                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1809                                 self.items |= IT_STRENGTH;
1810                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1811                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1812                         }
1813                 }
1814
1815                 if (self.items & IT_INVINCIBLE)
1816                 {
1817                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1818                         if (time > self.invincible_finished)
1819                         {
1820                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1821                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1822                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1823                         }
1824                 }
1825                 else
1826                 {
1827                         if (time < self.invincible_finished)
1828                         {
1829                                 self.items = self.items | IT_INVINCIBLE;
1830                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1831                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1832                         }
1833                 }
1834         }
1835         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1836         {
1837                 if (self.items & IT_STRENGTH)
1838                 {
1839                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1840                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1841                         if (time > self.strength_finished)
1842                         {
1843                                 self.items = self.items - (self.items & IT_STRENGTH);
1844                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1845                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1846                         }
1847                 }
1848                 else
1849                 {
1850                         if (time < self.strength_finished)
1851                         {
1852                                 self.items = self.items | IT_STRENGTH;
1853                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1854                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1855                         }
1856                 }
1857                 if (self.items & IT_INVINCIBLE)
1858                 {
1859                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1860                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1861                         if (time > self.invincible_finished)
1862                         {
1863                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1864                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1865                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1866                         }
1867                 }
1868                 else
1869                 {
1870                         if (time < self.invincible_finished)
1871                         {
1872                                 self.items = self.items | IT_INVINCIBLE;
1873                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1874                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1875                         }
1876                 }
1877                 if (self.items & IT_SUPERWEAPON)
1878                 {
1879                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1880                         {
1881                                 self.superweapons_finished = 0;
1882                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1883                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1884                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1885                         }
1886                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1887                         {
1888                                 // don't let them run out
1889                         }
1890                         else
1891                         {
1892                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1893                                 if (time > self.superweapons_finished)
1894                                 {
1895                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1896                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1897                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1898                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1899                                 }
1900                         }
1901                 }
1902                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1903                 {
1904                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1905                         {
1906                                 self.items = self.items | IT_SUPERWEAPON;
1907                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1908                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1909                         }
1910                         else
1911                         {
1912                                 self.superweapons_finished = 0;
1913                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1914                         }
1915                 }
1916                 else
1917                 {
1918                         self.superweapons_finished = 0;
1919                 }
1920         }
1921
1922         if(autocvar_g_nodepthtestplayers)
1923                 self.effects = self.effects | EF_NODEPTHTEST;
1924
1925         if(autocvar_g_fullbrightplayers)
1926                 self.effects = self.effects | EF_FULLBRIGHT;
1927
1928         // midair gamemode: damage only while in the air
1929         // if in midair mode, being on ground grants temporary invulnerability
1930         // (this is so that multishot weapon don't clear the ground flag on the
1931         // first damage in the frame, leaving the player vulnerable to the
1932         // remaining hits in the same frame)
1933         if (self.flags & FL_ONGROUND)
1934         if (g_midair)
1935                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1936
1937         if (time >= game_starttime)
1938         if (time < self.spawnshieldtime)
1939                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1940
1941         MUTATOR_CALLHOOK(PlayerPowerups);
1942 }
1943
1944 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1945 {
1946         if(current > stable)
1947                 return current;
1948         else if(current > stable - 0.25) // when close enough, "snap"
1949                 return stable;
1950         else
1951                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1952 }
1953
1954 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1955 {
1956         if(current < stable)
1957                 return current;
1958         else if(current < stable + 0.25) // when close enough, "snap"
1959                 return stable;
1960         else
1961                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1962 }
1963
1964 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1965 {
1966         if(current > rotstable)
1967         {
1968                 if(rotframetime > 0)
1969                 {
1970                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1971                         current = max(rotstable, current - rotlinear * rotframetime);
1972                 }
1973         }
1974         else if(current < regenstable)
1975         {
1976                 if(regenframetime > 0)
1977                 {
1978                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1979                         current = min(regenstable, current + regenlinear * regenframetime);
1980                 }
1981         }
1982
1983         if(current > limit)
1984                 current = limit;
1985
1986         return current;
1987 }
1988
1989 void player_regen (void)
1990 {
1991         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1992         maxh = autocvar_g_balance_health_rotstable;
1993         maxa = autocvar_g_balance_armor_rotstable;
1994         maxf = autocvar_g_balance_fuel_rotstable;
1995         minh = autocvar_g_balance_health_regenstable;
1996         mina = autocvar_g_balance_armor_regenstable;
1997         minf = autocvar_g_balance_fuel_regenstable;
1998         limith = autocvar_g_balance_health_limit;
1999         limita = autocvar_g_balance_armor_limit;
2000         limitf = autocvar_g_balance_fuel_limit;
2001
2002         max_mod = regen_mod = rot_mod = limit_mod = 1;
2003
2004         maxh = maxh * max_mod;
2005         //maxa = maxa * max_mod;
2006         //maxf = maxf * max_mod;
2007         minh = minh * max_mod;
2008         //mina = mina * max_mod;
2009         //minf = minf * max_mod;
2010         limith = limith * limit_mod;
2011         limita = limita * limit_mod;
2012         //limitf = limitf * limit_mod;
2013
2014         if(g_lms && g_ca)
2015                 rot_mod = 0;
2016
2017         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2018         {
2019                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2020                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2021
2022                 // if player rotted to death...  die!
2023                 if(self.health < 1)
2024                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2025         }
2026
2027         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2028                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2029 }
2030
2031 float zoomstate_set;
2032 void SetZoomState(float z)
2033 {
2034         if(z != self.zoomstate)
2035         {
2036                 self.zoomstate = z;
2037                 ClientData_Touch(self);
2038         }
2039         zoomstate_set = 1;
2040 }
2041
2042 void GetPressedKeys(void) {
2043         MUTATOR_CALLHOOK(GetPressedKeys);
2044         if (self.movement_x > 0) // get if movement keys are pressed
2045         {       // forward key pressed
2046                 self.pressedkeys |= KEY_FORWARD;
2047                 self.pressedkeys &~= KEY_BACKWARD;
2048         }
2049         else if (self.movement_x < 0)
2050         {       // backward key pressed
2051                 self.pressedkeys |= KEY_BACKWARD;
2052                 self.pressedkeys &~= KEY_FORWARD;
2053         }
2054         else
2055         {       // no x input
2056                 self.pressedkeys &~= KEY_FORWARD;
2057                 self.pressedkeys &~= KEY_BACKWARD;
2058         }
2059
2060         if (self.movement_y > 0)
2061         {       // right key pressed
2062                 self.pressedkeys |= KEY_RIGHT;
2063                 self.pressedkeys &~= KEY_LEFT;
2064         }
2065         else if (self.movement_y < 0)
2066         {       // left key pressed
2067                 self.pressedkeys |= KEY_LEFT;
2068                 self.pressedkeys &~= KEY_RIGHT;
2069         }
2070         else
2071         {       // no y input
2072                 self.pressedkeys &~= KEY_RIGHT;
2073                 self.pressedkeys &~= KEY_LEFT;
2074         }
2075
2076         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2077                 self.pressedkeys |= KEY_JUMP;
2078         else
2079                 self.pressedkeys &~= KEY_JUMP;
2080         if (self.BUTTON_CROUCH)
2081                 self.pressedkeys |= KEY_CROUCH;
2082         else
2083                 self.pressedkeys &~= KEY_CROUCH;
2084
2085         if (self.BUTTON_ATCK)
2086                 self.pressedkeys |= KEY_ATCK;
2087         else
2088                 self.pressedkeys &~= KEY_ATCK;
2089         if (self.BUTTON_ATCK2)
2090                 self.pressedkeys |= KEY_ATCK2;
2091         else
2092                 self.pressedkeys &~= KEY_ATCK2;
2093 }
2094
2095 /*
2096 ======================
2097 spectate mode routines
2098 ======================
2099 */
2100
2101 void SpectateCopy(entity spectatee) {
2102         other = spectatee;
2103         MUTATOR_CALLHOOK(SpectateCopy);
2104         self.armortype = spectatee.armortype;
2105         self.armorvalue = spectatee.armorvalue;
2106         self.ammo_cells = spectatee.ammo_cells;
2107         self.ammo_shells = spectatee.ammo_shells;
2108         self.ammo_nails = spectatee.ammo_nails;
2109         self.ammo_rockets = spectatee.ammo_rockets;
2110         self.ammo_fuel = spectatee.ammo_fuel;
2111         self.clip_load = spectatee.clip_load;
2112         self.clip_size = spectatee.clip_size;
2113         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2114         self.health = spectatee.health;
2115         self.impulse = 0;
2116         self.items = spectatee.items;
2117         self.last_pickup = spectatee.last_pickup;
2118         self.hit_time = spectatee.hit_time;
2119         self.metertime = spectatee.metertime;
2120         self.strength_finished = spectatee.strength_finished;
2121         self.invincible_finished = spectatee.invincible_finished;
2122         self.pressedkeys = spectatee.pressedkeys;
2123         WEPSET_COPY_EE(self, spectatee);
2124         self.switchweapon = spectatee.switchweapon;
2125         self.switchingweapon = spectatee.switchingweapon;
2126         self.weapon = spectatee.weapon;
2127         self.nex_charge = spectatee.nex_charge;
2128         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2129         self.hagar_load = spectatee.hagar_load;
2130         self.minelayer_mines = spectatee.minelayer_mines;
2131         self.punchangle = spectatee.punchangle;
2132         self.view_ofs = spectatee.view_ofs;
2133         self.velocity = spectatee.velocity;
2134         self.dmg_take = spectatee.dmg_take;
2135         self.dmg_save = spectatee.dmg_save;
2136         self.dmg_inflictor = spectatee.dmg_inflictor;
2137         self.v_angle = spectatee.v_angle;
2138         self.angles = spectatee.v_angle;
2139         self.stat_respawn_time = spectatee.stat_respawn_time;
2140         if(!self.BUTTON_USE)
2141                 self.fixangle = TRUE;
2142         setorigin(self, spectatee.origin);
2143         setsize(self, spectatee.mins, spectatee.maxs);
2144         SetZoomState(spectatee.zoomstate);
2145
2146     anticheat_spectatecopy(spectatee);
2147         self.hud = spectatee.hud;
2148         if(spectatee.vehicle)
2149     {
2150         self.fixangle = FALSE;
2151         //self.velocity = spectatee.vehicle.velocity;
2152         self.vehicle_health = spectatee.vehicle_health;
2153         self.vehicle_shield = spectatee.vehicle_shield;
2154         self.vehicle_energy = spectatee.vehicle_energy;
2155         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2156         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2157         self.vehicle_reload1 = spectatee.vehicle_reload1;
2158         self.vehicle_reload2 = spectatee.vehicle_reload2;
2159
2160         msg_entity = self;
2161
2162         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2163             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2164             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2165             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2166
2167         //WriteByte (MSG_ONE, SVC_SETVIEW);
2168         //    WriteEntity(MSG_ONE, self);
2169         //makevectors(spectatee.v_angle);
2170         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2171     }
2172 }
2173
2174 float SpectateUpdate() {
2175         if(!self.enemy)
2176             return 0;
2177
2178         if (self == self.enemy)
2179                 return 0;
2180
2181         if(self.enemy.classname != "player")
2182                 return 0;
2183
2184         SpectateCopy(self.enemy);
2185
2186         return 1;
2187 }
2188
2189
2190 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2191 entity CA_SpectateNext(entity start) {
2192         if (start.team == self.team) {
2193                 return start;
2194         }
2195
2196         other = start;
2197         // continue from current player
2198         while(other && other.team != self.team) {
2199                 other = find(other, classname, "player");
2200         }
2201
2202         if (!other) {
2203                 // restart from begining
2204                 other = find(other, classname, "player");
2205                 while(other && other.team != self.team) {
2206                         other = find(other, classname, "player");
2207                 }
2208         }
2209
2210         return other;
2211 }
2212
2213 float SpectateNext(entity _prefer) {
2214
2215         if(_prefer)
2216                 other = _prefer;
2217         else
2218                 other = find(self.enemy, classname, "player");
2219
2220         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2221                 // CA and ca players when spectating enemies is forbidden
2222                 other = CA_SpectateNext(other);
2223         } else {
2224                 // other modes and ca spectators or spectating enemies is allowed
2225                 if (!other)
2226                         other = find(other, classname, "player");
2227         }
2228
2229         if (other)
2230                 self.enemy = other;
2231
2232         if(self.enemy.classname == "player") {
2233             /*if(self.enemy.vehicle)
2234             {
2235
2236             msg_entity = self;
2237             WriteByte(MSG_ONE, SVC_SETVIEW);
2238             WriteEntity(MSG_ONE, self.enemy);
2239             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2240
2241             self.movetype = MOVETYPE_NONE;
2242             accuracy_resend(self);
2243             }
2244             else
2245             {*/
2246             msg_entity = self;
2247             WriteByte(MSG_ONE, SVC_SETVIEW);
2248             WriteEntity(MSG_ONE, self.enemy);
2249             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2250             self.movetype = MOVETYPE_NONE;
2251             accuracy_resend(self);
2252
2253             if(!SpectateUpdate())
2254                 PutObserverInServer();
2255         //}
2256         return 1;
2257         } else {
2258                 return 0;
2259         }
2260 }
2261
2262 /*
2263 =============
2264 ShowRespawnCountdown()
2265
2266 Update a respawn countdown display.
2267 =============
2268 */
2269 void ShowRespawnCountdown()
2270 {
2271         float number;
2272         if(self.deadflag == DEAD_NO) // just respawned?
2273                 return;
2274         else
2275         {
2276                 number = ceil(self.respawn_time - time);
2277                 if(number <= 0)
2278                         return;
2279                 if(number <= self.respawn_countdown)
2280                 {
2281                         self.respawn_countdown = number - 1;
2282                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2283                                 AnnounceTo(self, strcat(ftos(number), ""));
2284                 }
2285         }
2286 }
2287
2288 void LeaveSpectatorMode()
2289 {
2290         if(nJoinAllowed(self))
2291         {
2292                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2293                 {
2294                         self.classname = "player";
2295
2296                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2297                                 { JoinBestTeam(self, FALSE, TRUE); }
2298
2299                         if(autocvar_g_campaign)
2300                                 { campaign_bots_may_start = 1; }
2301                         else
2302                                 { Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD); }
2303
2304                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2305
2306                         PutClientInServer();
2307
2308                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2309                 }
2310                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2311         }
2312         else
2313         {
2314                 // Player may not join because g_maxplayers is set
2315                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2316         }
2317 }
2318
2319 /**
2320  * Determines whether the player is allowed to join. This depends on cvar
2321  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2322  * it checks whether the number of currently playing players exceeds g_maxplayers.
2323  * @return int number of free slots for players, 0 if none
2324  */
2325 float nJoinAllowed(entity ignore) {
2326         if(!ignore)
2327         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2328         // so report 0 free slots if restricted
2329         {
2330                 if(autocvar_g_forced_team_otherwise == "spectate")
2331                         return 0;
2332                 if(autocvar_g_forced_team_otherwise == "spectator")
2333                         return 0;
2334         }
2335
2336         if(self.team_forced < 0)
2337                 return 0; // forced spectators can never join
2338
2339         // TODO simplify this
2340         entity e;
2341         float totalClients = 0;
2342         FOR_EACH_CLIENT(e)
2343                 if(e != ignore)
2344                         totalClients += 1;
2345
2346         if (!autocvar_g_maxplayers)
2347                 return maxclients - totalClients;
2348
2349         float currentlyPlaying = 0;
2350         FOR_EACH_REALPLAYER(e)
2351                 currentlyPlaying += 1;
2352
2353         if(currentlyPlaying < autocvar_g_maxplayers)
2354                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2355
2356         return 0;
2357 }
2358
2359 /**
2360  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2361  * g_maxplayers_spectator_blocktime seconds
2362  */
2363 void checkSpectatorBlock() {
2364         if(self.classname == "spectator" || self.classname == "observer") {
2365                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2366                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2367                         dropclient(self);
2368                 }
2369         }
2370 }
2371
2372 .float motd_actived_time; // used for both motd and campaign_message
2373 void PrintWelcomeMessage()
2374 {
2375         if (self.motd_actived_time == 0) { // is there already a message showing?
2376                 if (autocvar_g_campaign) {
2377                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2378                                 self.motd_actived_time = time;
2379                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2380                         }
2381                 } else {
2382                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2383                                 self.motd_actived_time = time;
2384                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2385                         }
2386                 }
2387         } else { // showing MOTD or campaign message
2388                 if (autocvar_g_campaign) {
2389                         if (self.BUTTON_INFO)
2390                                 self.motd_actived_time = time;
2391                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2392                                 self.motd_actived_time = 0;
2393                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2394                         }
2395                 } else {
2396                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2397                                 if (self.BUTTON_INFO)
2398                                         self.motd_actived_time = time;
2399                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2400                                         self.motd_actived_time = 0;
2401                                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2402                                 }
2403                         }
2404                 }
2405         }
2406 }
2407
2408 void ObserverThink()
2409 {
2410         float prefered_movetype;
2411         if (self.flags & FL_JUMPRELEASED) {
2412                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2413                         self.flags &~= FL_JUMPRELEASED;
2414                         self.flags |= FL_SPAWNING;
2415                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2416                         self.flags &~= FL_JUMPRELEASED;
2417                         if(SpectateNext(world) == 1) {
2418                                 self.classname = "spectator";
2419                         }
2420                 } else {
2421                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2422                         if (self.movetype != prefered_movetype)
2423                                 self.movetype = prefered_movetype;
2424                 }
2425         } else {
2426                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2427                         self.flags |= FL_JUMPRELEASED;
2428                         if(self.flags & FL_SPAWNING)
2429                         {
2430                                 self.flags &~= FL_SPAWNING;
2431                                 LeaveSpectatorMode();
2432                                 return;
2433                         }
2434                 }
2435         }
2436
2437         PrintWelcomeMessage();
2438 }
2439
2440 void SpectatorThink()
2441 {
2442         if (self.flags & FL_JUMPRELEASED) {
2443                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2444                         self.flags &~= FL_JUMPRELEASED;
2445                         self.flags |= FL_SPAWNING;
2446                 } else if(self.BUTTON_ATCK) {
2447                         self.flags &~= FL_JUMPRELEASED;
2448                         if(SpectateNext(world) == 1) {
2449                                 self.classname = "spectator";
2450                         } else {
2451                                 self.classname = "observer";
2452                                 PutClientInServer();
2453                         }
2454                 } else if (self.BUTTON_ATCK2) {
2455                         self.flags &~= FL_JUMPRELEASED;
2456                         self.classname = "observer";
2457                         PutClientInServer();
2458                 } else {
2459                         if(!SpectateUpdate())
2460                                 PutObserverInServer();
2461                 }
2462         } else {
2463                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2464                         self.flags |= FL_JUMPRELEASED;
2465                         if(self.flags & FL_SPAWNING)
2466                         {
2467                                 self.flags &~= FL_SPAWNING;
2468                                 LeaveSpectatorMode();
2469                                 return;
2470                         }
2471                 }
2472                 if(!SpectateUpdate())
2473                         PutObserverInServer();
2474         }
2475
2476         PrintWelcomeMessage();
2477         self.flags |= FL_CLIENT | FL_NOTARGET;
2478 }
2479
2480 void PlayerUseKey()
2481 {
2482         if(self.classname != "player")
2483                 return;
2484
2485         if(self.vehicle)
2486         {
2487         vehicles_exit(VHEF_NORMAL);
2488         return;
2489         }
2490
2491         // a use key was pressed; call handlers
2492         MUTATOR_CALLHOOK(PlayerUseKey);
2493 }
2494
2495 .float touchexplode_time;
2496
2497 /*
2498 =============
2499 PlayerPreThink
2500
2501 Called every frame for each client before the physics are run
2502 =============
2503 */
2504 .float usekeypressed;
2505 void() nexball_setstatus;
2506 .float items_added;
2507 void PlayerPreThink (void)
2508 {
2509         WarpZone_PlayerPhysics_FixVAngle();
2510
2511         self.stat_game_starttime = game_starttime;
2512         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2513         self.stat_leadlimit = autocvar_leadlimit;
2514
2515         if(g_arena || (g_ca && !allowed_to_spawn))
2516                 self.stat_respawn_time = 0;
2517         else
2518                 self.stat_respawn_time = self.respawn_time;
2519
2520         if(frametime)
2521         {
2522                 // physics frames: update anticheat stuff
2523                 anticheat_prethink();
2524         }
2525
2526         if(blockSpectators && frametime)
2527                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2528                 checkSpectatorBlock();
2529
2530         zoomstate_set = 0;
2531
2532         if(self.netname_previous != self.netname)
2533         {
2534                 if(autocvar_sv_eventlog)
2535                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2536                 if(self.netname_previous)
2537                         strunzone(self.netname_previous);
2538                 self.netname_previous = strzone(self.netname);
2539         }
2540
2541         // version nagging
2542         if(self.version_nagtime)
2543                 if(self.cvar_g_xonoticversion)
2544                         if(time > self.version_nagtime)
2545                         {
2546                                 // don't notify git users
2547                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2548                                 {
2549                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2550                                         {
2551                                                 // notify release users if connecting to git
2552                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2553                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2554                                         }
2555                                         else
2556                                         {
2557                                                 float r;
2558                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2559                                                 if(r < 0)
2560                                                 {
2561                                                         // give users new version
2562                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2563                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2564                                                 }
2565                                                 else if(r > 0)
2566                                                 {
2567                                                         // notify users about old server version
2568                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2569                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2570                                                 }
2571                                         }
2572                                 }
2573                                 self.version_nagtime = 0;
2574                         }
2575
2576         // GOD MODE info
2577         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2578         {
2579                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2580                 self.max_armorvalue = 0;
2581         }
2582
2583 #ifdef TETRIS
2584         if (TetrisPreFrame())
2585                 return;
2586 #endif
2587
2588         MUTATOR_CALLHOOK(PlayerPreThink);
2589
2590         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2591         {
2592                 if(self.BUTTON_USE && !self.usekeypressed)
2593                         PlayerUseKey();
2594                 self.usekeypressed = self.BUTTON_USE;
2595         }
2596
2597         PrintWelcomeMessage();
2598
2599         if(self.classname == "player") {
2600 //              if(self.netname == "Wazat")
2601 //                      bprint(self.classname, "\n");
2602
2603                 CheckRules_Player();
2604
2605                 if (intermission_running)
2606                 {
2607                         IntermissionThink ();   // otherwise a button could be missed between
2608                         return;                                 // the think tics
2609                 }
2610
2611                 //don't allow the player to turn around while game is paused!
2612                 if(timeout_status == TIMEOUT_ACTIVE) {
2613                         // FIXME turn this into CSQC stuff
2614                         self.v_angle = self.lastV_angle;
2615                         self.angles = self.lastV_angle;
2616                         self.fixangle = TRUE;
2617                 }
2618
2619                 if(frametime)
2620                 {
2621                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2622                         {
2623                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2624                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2625                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2626
2627                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2628                                 {
2629                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2630                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2631                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2632                                 }
2633                         }
2634                         else
2635                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2636
2637                         player_powerups();
2638                 }
2639
2640                 if (g_minstagib)
2641                         minstagib_ammocheck();
2642
2643                 if (self.deadflag != DEAD_NO)
2644                 {
2645                         float button_pressed, force_respawn;
2646                         if(self.personal && g_race_qualifying)
2647                         {
2648                                 if(time > self.respawn_time)
2649                                 {
2650                                         self.respawn_time = time + 1; // only retry once a second
2651                                         respawn();
2652                                         self.impulse = 141;
2653                                 }
2654                         }
2655                         else
2656                         {
2657                                 if(frametime)
2658                                         player_anim();
2659                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2660                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2661                                 if (self.deadflag == DEAD_DYING)
2662                                 {
2663                                         if(force_respawn)
2664                                                 self.deadflag = DEAD_RESPAWNING;
2665                                         else if(!button_pressed)
2666                                                 self.deadflag = DEAD_DEAD;
2667                                 }
2668                                 else if (self.deadflag == DEAD_DEAD)
2669                                 {
2670                                         if(button_pressed)
2671                                                 self.deadflag = DEAD_RESPAWNABLE;
2672                                 }
2673                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2674                                 {
2675                                         if(!button_pressed)
2676                                                 self.deadflag = DEAD_RESPAWNING;
2677                                 }
2678                                 else if (self.deadflag == DEAD_RESPAWNING)
2679                                 {
2680                                         if(time > self.respawn_time)
2681                                         {
2682                                                 self.respawn_time = time + 1; // only retry once a second
2683                                                 respawn();
2684                                         }
2685                                 }
2686                                 ShowRespawnCountdown();
2687                         }
2688
2689                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2690                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2691                                 self.stat_respawn_time *= -1;
2692
2693                         return;
2694                 }
2695                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2696                 // so (self.deadflag == DEAD_NO) is always true in the code below
2697
2698                 if(g_touchexplode)
2699                 if(time > self.touchexplode_time)
2700                 if(self.classname == "player")
2701                 if(self.deadflag == DEAD_NO)
2702                 if not(IS_INDEPENDENT_PLAYER(self))
2703                 FOR_EACH_PLAYER(other) if(self != other)
2704                 {
2705                         if(time > other.touchexplode_time)
2706                         if(other.deadflag == DEAD_NO)
2707                         if not(IS_INDEPENDENT_PLAYER(other))
2708                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2709                         {
2710                                 PlayerTouchExplode(self, other);
2711                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2712                         }
2713                 }
2714
2715                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2716                 {
2717                         vector dist;
2718
2719                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2720                         dist = self.prevorigin - self.origin;
2721                         dist_z = 0;
2722                         self.lms_traveled_distance += fabs(vlen(dist));
2723
2724                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2725                         {
2726                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2727                                 self.lms_traveled_distance = 0;
2728                         }
2729
2730                         if(time > self.lms_nextcheck)
2731                         {
2732                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2733                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2734                                 {
2735                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2736                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2737                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2738                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2739                                 }
2740                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2741                                 self.lms_traveled_distance = 0;
2742                         }
2743                 }
2744
2745                 self.prevorigin = self.origin;
2746
2747                 float do_crouch = self.BUTTON_CROUCH;
2748                 if(self.hook.state)
2749                         do_crouch = 0;
2750                 if(self.health <= g_bloodloss)
2751                         do_crouch = 1;
2752                 if(self.vehicle)
2753                         do_crouch = 0;
2754                 if(self.freezetag_frozen)
2755                         do_crouch = 0;
2756                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2757                         do_crouch = 0;
2758
2759                 if (do_crouch)
2760                 {
2761                         if (!self.crouch)
2762                         {
2763                                 self.crouch = TRUE;
2764                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2765                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2766                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2767                         }
2768                 }
2769                 else
2770                 {
2771                         if (self.crouch)
2772                         {
2773                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2774                                 if (!trace_startsolid)
2775                                 {
2776                                         self.crouch = FALSE;
2777                                         self.view_ofs = PL_VIEW_OFS;
2778                                         setsize (self, PL_MIN, PL_MAX);
2779                                 }
2780                         }
2781                 }
2782
2783                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2784                 {
2785                         if(self.bloodloss_timer < time)
2786                         {
2787                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2788                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2789                         }
2790                 }
2791
2792                 FixPlayermodel();
2793
2794                 GrapplingHookFrame();
2795
2796                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2797                 //if(frametime)
2798                 {
2799                         self.items &~= self.items_added;
2800
2801                         W_WeaponFrame();
2802
2803                         self.items_added = 0;
2804                         if(self.items & IT_JETPACK)
2805                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2806                                         self.items_added |= IT_FUEL;
2807
2808                         self.items |= self.items_added;
2809                 }
2810
2811                 player_regen();
2812
2813                 // rot nex charge to the charge limit
2814                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2815                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2816
2817                 if(frametime)
2818                         player_anim();
2819
2820                 if(g_nexball)
2821                         nexball_setstatus();
2822
2823                 // secret status
2824                 secrets_setstatus();
2825
2826                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2827
2828                 //self.angles_y=self.v_angle_y + 90;   // temp
2829         } else if(gameover) {
2830                 if (intermission_running)
2831                         IntermissionThink ();   // otherwise a button could be missed between
2832                 return;
2833         } else if(self.classname == "observer") {
2834                 ObserverThink();
2835         } else if(self.classname == "spectator") {
2836                 SpectatorThink();
2837         }
2838
2839         if(!zoomstate_set)
2840                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2841
2842         float oldspectatee_status;
2843         oldspectatee_status = self.spectatee_status;
2844         if(self.classname == "spectator")
2845                 self.spectatee_status = num_for_edict(self.enemy);
2846         else if(self.classname == "observer")
2847                 self.spectatee_status = num_for_edict(self);
2848         else
2849                 self.spectatee_status = 0;
2850         if(self.spectatee_status != oldspectatee_status)
2851         {
2852                 ClientData_Touch(self);
2853                 if(g_race || g_cts)
2854                         race_InitSpectator();
2855         }
2856
2857         if(self.teamkill_soundtime)
2858         if(time > self.teamkill_soundtime)
2859         {
2860                 self.teamkill_soundtime = 0;
2861
2862                 entity oldpusher, oldself;
2863
2864                 oldself = self; self = self.teamkill_soundsource;
2865                 oldpusher = self.pusher; self.pusher = oldself;
2866
2867                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2868
2869                 self.pusher = oldpusher;
2870                 self = oldself;
2871         }
2872
2873         if(self.taunt_soundtime)
2874         if(time > self.taunt_soundtime)
2875         {
2876                 self.taunt_soundtime = 0;
2877                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2878         }
2879
2880         target_voicescript_next(self);
2881
2882         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2883         if(!self.weapon)
2884                 self.clip_load = self.clip_size = 0;
2885 }
2886
2887 float isInvisibleString(string s)
2888 {
2889         float i, n, c;
2890         s = strdecolorize(s);
2891         for((i = 0), (n = strlen(s)); i < n; ++i)
2892         {
2893                 c = str2chr(s, i);
2894                 switch(c)
2895                 {
2896                         case 0:
2897                         case 32: // space
2898                                 break;
2899                         case 192: // charmap space
2900                                 if (!autocvar_utf8_enable)
2901                                         break;
2902                                 return FALSE;
2903                         case 160: // space in unicode fonts
2904                         case 0xE000 + 192: // utf8 charmap space
2905                                 if (autocvar_utf8_enable)
2906                                         break;
2907                         default:
2908                                 return FALSE;
2909                 }
2910         }
2911         return TRUE;
2912 }
2913
2914 /*
2915 =============
2916 PlayerPostThink
2917
2918 Called every frame for each client after the physics are run
2919 =============
2920 */
2921 .float idlekick_lasttimeleft;
2922 void PlayerPostThink (void)
2923 {
2924         // Savage: Check for nameless players
2925         if (isInvisibleString(self.netname)) {
2926                 self.netname = "Player";
2927                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2928         }
2929
2930         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2931         {
2932                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2933                 {
2934                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2935                 }
2936                 else
2937                 {
2938                         float timeleft;
2939                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2940                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2941                         {
2942                                 if(!self.idlekick_lasttimeleft)
2943                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2944                         }
2945                         if(timeleft <= 0)
2946                         {
2947                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2948                                 dropclient(self);
2949                                 return;
2950                         }
2951                         else if(timeleft <= 10)
2952                         {
2953                                 if(timeleft != self.idlekick_lasttimeleft)
2954                                         AnnounceTo(self, ftos(timeleft));
2955                                 self.idlekick_lasttimeleft = timeleft;
2956                         }
2957                 }
2958         }
2959
2960 #ifdef TETRIS
2961         if(self.impulse == 100)
2962                 ImpulseCommands();
2963         if (!TetrisPostFrame())
2964         {
2965 #endif
2966
2967         CheatFrame();
2968
2969         //CheckPlayerJump();
2970
2971         if(self.classname == "player") {
2972                 CheckRules_Player();
2973                 UpdateChatBubble();
2974                 if (self.impulse)
2975                         ImpulseCommands();
2976                 if (intermission_running)
2977                         return;         // intermission or finale
2978                 GetPressedKeys();
2979         }
2980
2981 #ifdef TETRIS
2982         }
2983 #endif
2984
2985         /*
2986         float i;
2987         for(i = 0; i < 1000; ++i)
2988         {
2989                 vector end;
2990                 end = self.origin + '0 0 1024' + 512 * randomvec();
2991                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2992                 if(trace_fraction < 1)
2993                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2994                 {
2995                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2996                         break;
2997                 }
2998         }
2999         */
3000
3001         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3002
3003         if(self.waypointsprite_attachedforcarrier)
3004                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3005
3006         playerdemo_write();
3007
3008         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3009         {
3010                 if not(self.stored_netname)
3011                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3012                 if(self.stored_netname != self.netname)
3013                 {
3014                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3015                         strunzone(self.stored_netname);
3016                         self.stored_netname = strzone(self.netname);
3017                 }
3018         }
3019
3020         /*
3021         if(g_race)
3022                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3023         */
3024
3025         CSQCMODEL_AUTOUPDATE();
3026 }