qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 414                 self.alivetime = 0;
 415         }
 416
 417         if(self.vehicle)
 418                 vehicles_exit(VHEF_RELESE);
 419
 420         WaypointSprite_PlayerDead();
 421
 422         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 423                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 424
 425         if(self.killcount != -666) {
 426                 if(g_lms) {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 } else
 432                         bprint ("^4", self.netname, "^4 is spectating now\n");
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.istypefrag = 0;
 474         self.think = func_null;
 475         self.nextthink = 0;
 476         self.hook_time = 0;
 477         self.runes = 0;
 478         self.deadflag = DEAD_NO;
 479         self.angles = spot.angles;
 480         self.angles_z = 0;
 481         self.fixangle = TRUE;
 482         self.crouch = FALSE;
 483
 484         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 485         self.prevorigin = self.origin;
 486         self.items = 0;
 487         WEPSET_CLEAR_E(self);
 488         self.model = "";
 489         FixPlayermodel();
 490         setmodel(self, "null");
 491         self.drawonlytoclient = self;
 492
 493         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 494         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 495
 496         self.weapon = 0;
 497         self.weaponname = "";
 498         self.switchingweapon = 0;
 499         self.weaponmodel = "";
 500         self.weaponentity = world;
 501         self.exteriorweaponentity = world;
 502         self.killcount = -666;
 503         self.velocity = '0 0 0';
 504         self.avelocity = '0 0 0';
 505         self.punchangle = '0 0 0';
 506         self.punchvector = '0 0 0';
 507         self.oldvelocity = self.velocity;
 508         self.fire_endtime = -1;
 509
 510         if(g_arena)
 511         {
 512                 if(self.version_mismatch)
 513                 {
 514                         Spawnqueue_Unmark(self);
 515                         Spawnqueue_Remove(self);
 516                 }
 517                 else
 518                 {
 519                         Spawnqueue_Insert(self);
 520                 }
 521         }
 522         else if(g_lms)
 523         {
 524                 // Only if the player cannot play at all
 525                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 526                         self.frags = FRAGS_SPECTATOR;
 527                 else
 528                         self.frags = FRAGS_LMS_LOSER;
 529         }
 530         else if(g_ca)
 531         {
 532                 if(self.caplayer)
 533                         self.frags = FRAGS_LMS_LOSER;
 534                 else
 535                         self.frags = FRAGS_SPECTATOR;
 536         }
 537         else
 538                 self.frags = FRAGS_SPECTATOR;
 539 }
 540
 541 .float model_randomizer;
 542 void FixPlayermodel()
 543 {
 544         string defaultmodel;
 545         float defaultskin, chmdl, oldskin, n, i;
 546         vector m1, m2;
 547
 548         defaultmodel = "";
 549         defaultskin = 0;
 550         chmdl = FALSE;
 551
 552         if(autocvar_sv_defaultcharacter == 1)
 553         {
 554                 if(teamplay)
 555                 {
 556                         string s;
 557                         s = Team_ColorNameLowerCase(self.team);
 558                         if(s != "neutral")
 559                         {
 560                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 561                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 562                         }
 563                 }
 564
 565                 if(defaultmodel == "")
 566                 {
 567                         defaultmodel = autocvar_sv_defaultplayermodel;
 568                         defaultskin = autocvar_sv_defaultplayerskin;
 569                 }
 570
 571                 n = tokenize_console(defaultmodel);
 572                 if(n > 0)
 573                         defaultmodel = argv(floor(n * self.model_randomizer));
 574
 575                 i = strstrofs(defaultmodel, ":", 0);
 576                 if(i >= 0)
 577                 {
 578                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 579                         defaultmodel = substring(defaultmodel, 0, i);
 580                 }
 581         }
 582
 583         if(defaultmodel != "")
 584         {
 585                 if (defaultmodel != self.model)
 586                 {
 587                         m1 = self.mins;
 588                         m2 = self.maxs;
 589                         setplayermodel (self, defaultmodel);
 590                         setsize (self, m1, m2);
 591                         chmdl = TRUE;
 592                 }
 593
 594                 oldskin = self.skin;
 595                 self.skin = defaultskin;
 596         } else {
 597                 if (self.playermodel != self.model || self.playermodel == "")
 598                 {
 599                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 600                         m1 = self.mins;
 601                         m2 = self.maxs;
 602                         setplayermodel (self, self.playermodel);
 603                         setsize (self, m1, m2);
 604                         chmdl = TRUE;
 605                 }
 606
 607                 oldskin = self.skin;
 608                 self.skin = stof(self.playerskin);
 609         }
 610
 611         if(chmdl || oldskin != self.skin)
 612                 self.species = player_getspecies(); // model or skin has changed
 613
 614         if(!teamplay)
 615                 if(strlen(autocvar_sv_defaultplayercolors))
 616                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 617                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 618 }
 619
 620 void PlayerTouchExplode(entity p1, entity p2)
 621 {
 622         vector org;
 623         org = (p1.origin + p2.origin) * 0.5;
 624         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 625
 626         te_explosion(org);
 627
 628         entity e;
 629         e = spawn();
 630         setorigin(e, org);
 631         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 632         remove(e);
 633 }
 634
 635 /*
 636 =============
 637 PutClientInServer
 638
 639 Called when a client spawns in the server
 640 =============
 641 */
 642
 643 void PutClientInServer (void)
 644 {
 645         if(clienttype(self) == CLIENTTYPE_BOT)
 646         {
 647                 self.classname = "player";
 648                 if(g_ca)
 649                         self.caplayer = 1;
 650         }
 651         else if(clienttype(self) == CLIENTTYPE_REAL)
 652         {
 653                 msg_entity = self;
 654                 WriteByte(MSG_ONE, SVC_SETVIEW);
 655                 WriteEntity(MSG_ONE, self);
 656         }
 657
 658         // reset player keys
 659         self.itemkeys = 0;
 660
 661         // player is dead and becomes observer
 662         // FIXME fix LMS scoring for new system
 663         if(g_lms)
 664         {
 665                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 666                         self.classname = "observer";
 667         }
 668
 669         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 670                 self.classname = "observer";
 671
 672         if(gameover)
 673                 self.classname = "observer";
 674
 675         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 676                 entity spot, oldself;
 677                 float j;
 678
 679                 accuracy_resend(self);
 680
 681                 if(self.team < 0)
 682                         JoinBestTeam(self, FALSE, TRUE);
 683
 684                 race_PreSpawn();
 685
 686                 spot = SelectSpawnPoint (FALSE);
 687                 if(!spot)
 688                 {
 689                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 690                         return; // spawn failed
 691                 }
 692
 693                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 694
 695                 self.classname = "player";
 696                 self.wasplayer = TRUE;
 697                 self.iscreature = TRUE;
 698                 self.teleportable = TELEPORT_NORMAL;
 699                 self.damagedbycontents = TRUE;
 700                 self.movetype = MOVETYPE_WALK;
 701                 self.solid = SOLID_SLIDEBOX;
 702                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 703                 if(autocvar_g_playerclip_collisions)
 704                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 705                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 707                 self.frags = FRAGS_PLAYER;
 708                 if(INDEPENDENT_PLAYERS)
 709                         MAKE_INDEPENDENT_PLAYER(self);
 710                 self.flags = FL_CLIENT;
 711                 if(autocvar__notarget)
 712                         self.flags |= FL_NOTARGET;
 713                 self.takedamage = DAMAGE_AIM;
 714                 if(g_minstagib)
 715                         self.effects = EF_FULLBRIGHT;
 716                 else
 717                         self.effects = 0;
 718                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 719                 self.air_finished = time + 12;
 720                 self.dmg = 2;
 721                 if(autocvar_g_balance_nex_charge)
 722                 {
 723                         if(autocvar_g_balance_nex_secondary_chargepool)
 724                                 self.nex_chargepool_ammo = 1;
 725                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 726                 }
 727
 728                 if(inWarmupStage)
 729                 {
 730                         self.ammo_shells = warmup_start_ammo_shells;
 731                         self.ammo_nails = warmup_start_ammo_nails;
 732                         self.ammo_rockets = warmup_start_ammo_rockets;
 733                         self.ammo_cells = warmup_start_ammo_cells;
 734                         self.ammo_fuel = warmup_start_ammo_fuel;
 735                         self.health = warmup_start_health;
 736                         self.armorvalue = warmup_start_armorvalue;
 737                         WEPSET_COPY_EA(self, warmup_start_weapons);
 738                 }
 739                 else
 740                 {
 741                         self.ammo_shells = start_ammo_shells;
 742                         self.ammo_nails = start_ammo_nails;
 743                         self.ammo_rockets = start_ammo_rockets;
 744                         self.ammo_cells = start_ammo_cells;
 745                         self.ammo_fuel = start_ammo_fuel;
 746                         self.health = start_health;
 747                         self.armorvalue = start_armorvalue;
 748                         WEPSET_COPY_EA(self, start_weapons);
 749                 }
 750
 751                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 752                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 753                 else
 754                         self.superweapons_finished = 0;
 755
 756                 if(g_weaponarena_random)
 757                 {
 758                         if(g_weaponarena_random_with_laser)
 759                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 760                         W_RandomWeapons(self, g_weaponarena_random);
 761                         if(g_weaponarena_random_with_laser)
 762                                 WEPSET_OR_EW(self, WEP_LASER);
 763                 }
 764
 765                 self.items = start_items;
 766
 767                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 768                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 769                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 770                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 771                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 772                 //extend the pause of rotting if client was reset at the beginning of the countdown
 773                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 774                         self.spawnshieldtime += game_starttime - time;
 775                         self.pauserotarmor_finished += game_starttime - time;
 776                         self.pauserothealth_finished += game_starttime - time;
 777                         self.pauseregen_finished += game_starttime - time;
 778                 }
 779                 self.damageforcescale = 2;
 780                 self.death_time = 0;
 781                 self.respawn_time = 0;
 782                 self.scale = 0;
 783                 self.fade_time = 0;
 784                 self.pain_frame = 0;
 785                 self.pain_finished = 0;
 786                 self.strength_finished = 0;
 787                 self.invincible_finished = 0;
 788                 self.pushltime = 0;
 789                 // players have no think function
 790                 self.think = func_null;
 791                 self.nextthink = 0;
 792                 self.hook_time = 0;
 793                 self.dmg_team = 0;
 794                 self.ballistics_density = autocvar_g_ballistics_density_player;
 795
 796                 self.metertime = 0;
 797
 798                 self.runes = 0;
 799
 800                 self.deadflag = DEAD_NO;
 801
 802                 self.angles = spot.angles;
 803
 804                 self.angles_z = 0; // never spawn tilted even if the spot says to
 805                 self.fixangle = TRUE; // turn this way immediately
 806                 self.velocity = '0 0 0';
 807                 self.avelocity = '0 0 0';
 808                 self.punchangle = '0 0 0';
 809                 self.punchvector = '0 0 0';
 810                 self.oldvelocity = self.velocity;
 811                 self.fire_endtime = -1;
 812
 813                 msg_entity = self;
 814                 WRITESPECTATABLE_MSG_ONE({
 815                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 816                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 817                 });
 818
 819                 self.model = "";
 820                 FixPlayermodel();
 821                 self.drawonlytoclient = world;
 822
 823                 self.crouch = FALSE;
 824                 self.view_ofs = PL_VIEW_OFS;
 825                 setsize (self, PL_MIN, PL_MAX);
 826                 self.spawnorigin = spot.origin;
 827                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 828                 // don't reset back to last position, even if new position is stuck in solid
 829                 self.oldorigin = self.origin;
 830                 self.prevorigin = self.origin;
 831                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 832                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 833         self.hud = HUD_NORMAL;
 834
 835                 if(g_arena)
 836                 {
 837                         Spawnqueue_Remove(self);
 838                         Spawnqueue_Mark(self);
 839                 }
 840                 else if(g_ca)
 841                         self.caplayer = 1;
 842
 843                 self.event_damage = PlayerDamage;
 844
 845                 self.bot_attack = TRUE;
 846
 847                 self.statdraintime = time + 5;
 848                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 849
 850                 if(self.killcount == -666) {
 851                         PlayerScore_Clear(self);
 852                         self.killcount = 0;
 853                 }
 854
 855                 CL_SpawnWeaponentity();
 856                 self.alpha = default_player_alpha;
 857                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 858                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 859
 860                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 861                 self.lms_traveled_distance = 0;
 862                 self.speedrunning = FALSE;
 863
 864                 race_PostSpawn(spot);
 865
 866                 //stuffcmd(self, "chase_active 0");
 867                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 868
 869                 target_voicescript_clear(self);
 870
 871                 // reset fields the weapons may use
 872                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 873                 {
 874                         weapon_action(j, WR_RESETPLAYER);
 875
 876                         // all weapons must be fully loaded when we spawn
 877                         entity e;
 878                         e = get_weaponinfo(j);
 879                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 880                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 881                 }
 882
 883                 oldself = self;
 884                 self = spot;
 885                         activator = oldself;
 886                                 string s;
 887                                 s = self.target;
 888                                 self.target = string_null;
 889                                 SUB_UseTargets();
 890                                 self.target = s;
 891                         activator = world;
 892                 self = oldself;
 893
 894                 spawn_spot = spot;
 895                 MUTATOR_CALLHOOK(PlayerSpawn);
 896
 897                 if(autocvar_spawn_debug)
 898                 {
 899                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 900                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 901                 }
 902
 903                 self.switchweapon = w_getbestweapon(self);
 904                 self.cnt = -1; // W_LastWeapon will not complain
 905                 self.weapon = 0;
 906                 self.weaponname = "";
 907                 self.switchingweapon = 0;
 908
 909                 if(!self.alivetime)
 910                         self.alivetime = time;
 911
 912                 antilag_clear(self);
 913
 914                 if (autocvar_g_spawnsound)
 915                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 916         } else if(self.classname == "observer") {
 917                 PutObserverInServer ();
 918         }
 919 }
 920
 921 .float ebouncefactor, ebouncestop; // electro's values
 922 // TODO do we need all these fields, or should we stop autodetecting runtime
 923 // changes and just have a console command to update this?
 924 float ClientInit_SendEntity(entity to, float sf)
 925 {
 926         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 927         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 928         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 929         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 930         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 931         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 932         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 933         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 934         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 935         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 936         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 937         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 940         if(sv_foginterval && world.fog != "")
 941                 WriteString(MSG_ENTITY, world.fog);
 942         else
 943                 WriteString(MSG_ENTITY, "");
 944         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 945         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 946         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 947         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 948         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 949         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 950         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 951         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 952         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 953         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 954         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 955         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 956         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 957         return TRUE;
 958 }
 959
 960 void ClientInit_CheckUpdate()
 961 {
 962         self.nextthink = time;
 963         if(self.count != autocvar_g_balance_armor_blockpercent)
 964         {
 965                 self.count = autocvar_g_balance_armor_blockpercent;
 966                 self.SendFlags |= 1;
 967         }
 968         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 969         {
 970                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 971                 self.SendFlags |= 1;
 972         }
 973         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 974         {
 975                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 976                 self.SendFlags |= 1;
 977         }
 978         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 979         {
 980                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 981                 self.SendFlags |= 1;
 982         }
 983         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 984         {
 985                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 986                 self.SendFlags |= 1;
 987         }
 988         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 989         {
 990                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 991                 self.SendFlags |= 1;
 992         }
 993 }
 994
 995 void ClientInit_Spawn()
 996 {
 997         entity o;
 998         entity e;
 999         e = spawn();
1000         e.classname = "clientinit";
1001         e.think = ClientInit_CheckUpdate;
1002         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1003
1004         o = self;
1005         self = e;
1006         ClientInit_CheckUpdate();
1007         self = o;
1008 }
1009
1010 /*
1011 =============
1012 SetNewParms
1013 =============
1014 */
1015 void SetNewParms (void)
1016 {
1017         // initialize parms for a new player
1018         parm1 = -(86400 * 366);
1019 }
1020
1021 /*
1022 =============
1023 SetChangeParms
1024 =============
1025 */
1026 void SetChangeParms (void)
1027 {
1028         // save parms for level change
1029         parm1 = self.parm_idlesince - time;
1030 }
1031
1032 /*
1033 =============
1034 DecodeLevelParms
1035 =============
1036 */
1037 void DecodeLevelParms (void)
1038 {
1039         // load parms
1040         self.parm_idlesince = parm1;
1041         if(self.parm_idlesince == -(86400 * 366))
1042                 self.parm_idlesince = time;
1043
1044         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1045         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1046 }
1047
1048 /*
1049 =============
1050 ClientKill
1051
1052 Called when a client types 'kill' in the console
1053 =============
1054 */
1055
1056 .float clientkill_nexttime;
1057 void ClientKill_Now_TeamChange()
1058 {
1059         if(self.killindicator_teamchange == -1)
1060         {
1061                 JoinBestTeam( self, FALSE, TRUE );
1062         }
1063         else if(self.killindicator_teamchange == -2)
1064         {
1065                 if(g_ca)
1066                         self.caplayer = 0;
1067                 if(blockSpectators)
1068                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1069                 PutObserverInServer();
1070         }
1071         else
1072                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1073 }
1074
1075 void ClientKill_Now()
1076 {
1077         if(self.vehicle)
1078         {
1079             vehicles_exit(VHEF_RELESE);
1080             if(!self.killindicator_teamchange)
1081             {
1082             self.vehicle_health = -1;
1083             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1084             }
1085         }
1086
1087         if(self.killindicator && !wasfreed(self.killindicator))
1088                 remove(self.killindicator);
1089
1090         self.killindicator = world;
1091
1092         if(self.killindicator_teamchange)
1093                 ClientKill_Now_TeamChange();
1094
1095         // in any case:
1096         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1097
1098         // now I am sure the player IS dead
1099 }
1100 void KillIndicator_Think()
1101 {
1102         if (gameover)
1103         {
1104                 self.owner.killindicator = world;
1105                 remove(self);
1106                 return;
1107         }
1108
1109         if (self.owner.alpha < 0 && !self.owner.vehicle)
1110         {
1111                 self.owner.killindicator = world;
1112                 remove(self);
1113                 return;
1114         }
1115
1116         if(self.cnt <= 0)
1117         {
1118                 self = self.owner;
1119                 ClientKill_Now(); // no oldself needed
1120                 return;
1121         }
1122     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1123     {
1124         self.nextthink = time + 1;
1125         self.cnt -= 1;
1126     }
1127         else
1128         {
1129                 if(self.cnt <= 10)
1130                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1131                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1132                 {
1133                         if(self.cnt <= 10)
1134                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1135                 }
1136                 self.nextthink = time + 1;
1137                 self.cnt -= 1;
1138         }
1139 }
1140
1141 float clientkilltime;
1142 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1143 {
1144         float killtime;
1145         float starttime;
1146         entity e;
1147
1148         if (gameover)
1149                 return;
1150
1151         killtime = autocvar_g_balance_kill_delay;
1152
1153         if(g_race_qualifying || g_cts)
1154                 killtime = 0;
1155
1156     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1157     {
1158                 remove(self.killindicator);
1159                 self.killindicator = world;
1160
1161         ClientKill_Now(); // allow instant kill in this case
1162         return;
1163     }
1164
1165         self.killindicator_teamchange = targetteam;
1166
1167     if(!self.killindicator)
1168         {
1169                 if(self.deadflag == DEAD_NO)
1170                 {
1171                         killtime = max(killtime, self.clientkill_nexttime - time);
1172                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1173                 }
1174
1175                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1176                 {
1177                         ClientKill_Now();
1178                 }
1179                 else
1180                 {
1181                         starttime = max(time, clientkilltime);
1182
1183                         self.killindicator = spawn();
1184                         self.killindicator.owner = self;
1185                         self.killindicator.scale = 0.5;
1186                         setattachment(self.killindicator, self, "");
1187                         setorigin(self.killindicator, '0 0 52');
1188                         self.killindicator.think = KillIndicator_Think;
1189                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1190                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1191                         self.killindicator.cnt = ceil(killtime);
1192                         self.killindicator.count = bound(0, ceil(killtime), 10);
1193                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1194
1195                         for(e = world; (e = find(e, classname, "body")) != world; )
1196                         {
1197                                 if(e.enemy != self)
1198                                         continue;
1199                                 e.killindicator = spawn();
1200                                 e.killindicator.owner = e;
1201                                 e.killindicator.scale = 0.5;
1202                                 setattachment(e.killindicator, e, "");
1203                                 setorigin(e.killindicator, '0 0 52');
1204                                 e.killindicator.think = KillIndicator_Think;
1205                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1206                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1207                                 e.killindicator.cnt = ceil(killtime);
1208                         }
1209                         self.lip = 0;
1210                 }
1211         }
1212         if(self.killindicator)
1213         {
1214                 if(targetteam == 0) // just die
1215                 {
1216                         self.killindicator.colormod = '0 0 0';
1217                         if(clienttype(self) == CLIENTTYPE_REAL)
1218                         if(self.killindicator.cnt > 0)
1219                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1220                 }
1221                 else if(targetteam == -1) // auto
1222                 {
1223                         self.killindicator.colormod = '0 1 0';
1224                         if(clienttype(self) == CLIENTTYPE_REAL)
1225                         if(self.killindicator.cnt > 0)
1226                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1227                 }
1228                 else if(targetteam == -2) // spectate
1229                 {
1230                         self.killindicator.colormod = '0.5 0.5 0.5';
1231                         if(clienttype(self) == CLIENTTYPE_REAL)
1232                         if(self.killindicator.cnt > 0)
1233                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1234                 }
1235                 else
1236                 {
1237                         self.killindicator.colormod = TeamColor(targetteam);
1238                         if(clienttype(self) == CLIENTTYPE_REAL)
1239                         if(self.killindicator.cnt > 0)
1240                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1241                 }
1242         }
1243
1244 }
1245
1246 void ClientKill (void)
1247 {
1248         if (gameover)
1249                 return;
1250
1251         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1252         {
1253                 // do nothing
1254         }
1255     else if(self.freezetag_frozen)
1256     {
1257         // do nothing
1258     }
1259         else
1260                 ClientKill_TeamChange(0);
1261 }
1262
1263 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1264 {
1265     e.killindicator = spawn();
1266     e.killindicator.owner = e;
1267     e.killindicator.think = KillIndicator_Think;
1268     e.killindicator.nextthink = time + (e.lip) * 0.05;
1269     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1270     e.killindicator.health = 1; // this is used to indicate that it should be silent
1271     e.lip = 0;
1272 }
1273
1274 void FixClientCvars(entity e)
1275 {
1276         // send prediction settings to the client
1277         stuffcmd(e, "\nin_bindmap 0 0\n");
1278         if(g_race || g_cts)
1279                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1280         if(autocvar_g_antilag == 3) // client side hitscan
1281                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1282         if(sv_gentle)
1283                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1284         /*
1285          * we no longer need to stuff this. Remove this comment block if you feel
1286          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1287         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1288         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1289         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1290         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1291         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1292         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1293         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1294         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1295         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1296         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1297         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1298         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1299         stuffcmd(e, "cl_movement_edgefriction 1\n");
1300          */
1301 }
1302
1303 float PlayerInIDList(entity p, string idlist)
1304 {
1305         float n, i;
1306         string s;
1307
1308         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1309         if not(p.crypto_idfp)
1310                 return 0;
1311
1312         // this function allows abbreviated player IDs too!
1313         n = tokenize_console(idlist);
1314         for(i = 0; i < n; ++i)
1315         {
1316                 s = argv(i);
1317                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1318                         return 1;
1319         }
1320
1321         return 0;
1322 }
1323
1324 /*
1325 =============
1326 ClientConnect
1327
1328 Called when a client connects to the server
1329 =============
1330 */
1331 string ColoredTeamName(float t);
1332 void DecodeLevelParms (void);
1333 //void dom_player_join_team(entity pl);
1334 void set_dom_state(entity e);
1335 void ClientConnect (void)
1336 {
1337         float t;
1338
1339         if(self.flags & FL_CLIENT)
1340         {
1341                 print("Warning: ClientConnect, but already connected!\n");
1342                 return;
1343         }
1344
1345         if(Ban_MaybeEnforceBanOnce(self))
1346                 return;
1347
1348         DecodeLevelParms();
1349
1350 #ifdef WATERMARK
1351         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1352 #endif
1353
1354         self.classname = "player_joining";
1355
1356         self.flags = FL_CLIENT;
1357         self.version_nagtime = time + 10 + random() * 10;
1358
1359         if(player_count<0)
1360         {
1361                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1362                 player_count = 0;
1363         }
1364
1365         PlayerScore_Attach(self);
1366         ClientData_Attach();
1367         accuracy_init(self);
1368
1369         bot_clientconnect();
1370
1371         playerdemo_init();
1372
1373         anticheat_init();
1374
1375         race_PreSpawnObserver();
1376
1377         //if(g_domination)
1378         //      dom_player_join_team(self);
1379
1380         // identify the right forced team
1381         if(autocvar_g_campaign)
1382         {
1383                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1384                 {
1385                         switch(autocvar_g_campaign_forceteam)
1386                         {
1387                                 case 1: self.team_forced = COLOR_TEAM1; break;
1388                                 case 2: self.team_forced = COLOR_TEAM2; break;
1389                                 case 3: self.team_forced = COLOR_TEAM3; break;
1390                                 case 4: self.team_forced = COLOR_TEAM4; break;
1391                                 default: self.team_forced = 0;
1392                         }
1393                 }
1394         }
1395         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1396                 self.team_forced = COLOR_TEAM1;
1397         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1398                 self.team_forced = COLOR_TEAM2;
1399         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1400                 self.team_forced = COLOR_TEAM3;
1401         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1402                 self.team_forced = COLOR_TEAM4;
1403         else if(autocvar_g_forced_team_otherwise == "red")
1404                 self.team_forced = COLOR_TEAM1;
1405         else if(autocvar_g_forced_team_otherwise == "blue")
1406                 self.team_forced = COLOR_TEAM2;
1407         else if(autocvar_g_forced_team_otherwise == "yellow")
1408                 self.team_forced = COLOR_TEAM3;
1409         else if(autocvar_g_forced_team_otherwise == "pink")
1410                 self.team_forced = COLOR_TEAM4;
1411         else if(autocvar_g_forced_team_otherwise == "spectate")
1412                 self.team_forced = -1;
1413         else if(autocvar_g_forced_team_otherwise == "spectator")
1414                 self.team_forced = -1;
1415         else
1416                 self.team_forced = 0;
1417
1418         if(!teamplay)
1419                 if(self.team_forced > 0)
1420                         self.team_forced = 0;
1421
1422         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1423
1424         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1425                 self.classname = "observer";
1426         } else {
1427                 if(teamplay)
1428                 {
1429                         if(autocvar_g_balance_teams)
1430                         {
1431                                 self.classname = "player";
1432                                 campaign_bots_may_start = 1;
1433                         }
1434                         else
1435                         {
1436                                 self.classname = "observer"; // do it anyway
1437                         }
1438                 }
1439                 else
1440                 {
1441                         self.classname = "player";
1442                         campaign_bots_may_start = 1;
1443                 }
1444         }
1445
1446         self.playerid = (playerid_last = playerid_last + 1);
1447
1448         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1449
1450     if(clienttype(self) == CLIENTTYPE_BOT)
1451         PlayerStats_AddPlayer(self);
1452
1453         if(autocvar_sv_eventlog)
1454                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1455
1456         LogTeamchange(self.playerid, self.team, 1);
1457
1458         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1459
1460         self.netname_previous = strzone(self.netname);
1461
1462         bprint("^4", self.netname, "^4 connected");
1463
1464         if(self.classname != "observer" && (g_domination || g_ctf))
1465                 bprint(" and joined the ", ColoredTeamName(self.team));
1466
1467         bprint("\n");
1468
1469         stuffcmd(self, strcat(clientstuff, "\n"));
1470         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1471
1472         FixClientCvars(self);
1473
1474         // spawnfunc_waypoint sprites
1475         WaypointSprite_InitClient(self);
1476
1477         // Wazat's grappling hook
1478         SetGrappleHookBindings();
1479
1480         // get version info from player
1481         stuffcmd(self, "cmd clientversion $gameversion\n");
1482
1483         // get other cvars from player
1484         GetCvars(0);
1485
1486         // notify about available teams
1487         if(teamplay)
1488         {
1489                 CheckAllowedTeams(self);
1490                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1491                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1492         }
1493         else
1494                 stuffcmd(self, "set _teams_available 0\n");
1495
1496         if(g_arena || g_ca)
1497         {
1498                 self.classname = "observer";
1499                 if(g_arena)
1500                         Spawnqueue_Insert(self);
1501         }
1502
1503         attach_entcs();
1504
1505         bot_relinkplayerlist();
1506
1507         self.spectatortime = time;
1508         if(blockSpectators)
1509         {
1510                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1511         }
1512
1513         self.jointime = time;
1514         self.allowed_timeouts = autocvar_sv_timeout_number;
1515
1516         if(clienttype(self) == CLIENTTYPE_REAL)
1517         {
1518                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1519                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1520         }
1521
1522         if(g_lms)
1523         {
1524                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1525                 {
1526                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1527                         self.frags = FRAGS_SPECTATOR;
1528                 }
1529         }
1530
1531         if(!sv_foginterval && world.fog != "")
1532                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1533
1534         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1535         {
1536                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1537                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1538         }
1539         else
1540                 self.hitplotfh = -1;
1541
1542         if(g_race || g_cts) {
1543                 string rr;
1544                 if(g_cts)
1545                         rr = CTS_RECORD;
1546                 else
1547                         rr = RACE_RECORD;
1548
1549                 msg_entity = self;
1550                 race_send_recordtime(MSG_ONE);
1551                 race_send_speedaward(MSG_ONE);
1552
1553                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1554                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1555                 race_send_speedaward_alltimebest(MSG_ONE);
1556
1557                 float i;
1558                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1559                         race_SendRankings(i, 0, 0, MSG_ONE);
1560                 }
1561         }
1562         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1563                 send_CSQC_teamnagger();
1564
1565         if (g_domination)
1566                 set_dom_state(self);
1567
1568         CheatInitClient();
1569
1570         if(!autocvar_g_campaign)
1571                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1572
1573         CSQCMODEL_AUTOINIT();
1574
1575         self.model_randomizer = random();
1576
1577     if(clienttype(self) != CLIENTTYPE_REAL)
1578         return;
1579
1580     sv_notice_join();
1581
1582     MUTATOR_CALLHOOK(ClientConnect);
1583 }
1584 /*
1585 =============
1586 ClientDisconnect
1587
1588 Called when a client disconnects from the server
1589 =============
1590 */
1591 .entity chatbubbleentity;
1592 void ReadyCount();
1593 void ClientDisconnect (void)
1594 {
1595         if(self.vehicle)
1596             vehicles_exit(VHEF_RELESE);
1597
1598         if not(self.flags & FL_CLIENT)
1599         {
1600                 print("Warning: ClientDisconnect without ClientConnect\n");
1601                 return;
1602         }
1603
1604         PlayerStats_AddGlobalInfo(self);
1605
1606         CheatShutdownClient();
1607
1608         if(self.hitplotfh >= 0)
1609         {
1610                 fclose(self.hitplotfh);
1611                 self.hitplotfh = -1;
1612         }
1613
1614         anticheat_report();
1615         anticheat_shutdown();
1616
1617         playerdemo_shutdown();
1618
1619         bot_clientdisconnect();
1620
1621         if(self.entcs)
1622                 detach_entcs();
1623
1624         if(autocvar_sv_eventlog)
1625                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1626         bprint ("^4",self.netname);
1627         bprint ("^4 disconnected\n");
1628
1629         DropAllRunes(self);
1630         MUTATOR_CALLHOOK(ClientDisconnect);
1631
1632         Portal_ClearAll(self);
1633
1634         RemoveGrapplingHook(self);
1635
1636         // Here, everything has been done that requires this player to be a client.
1637
1638         self.flags &~= FL_CLIENT;
1639
1640         if (self.chatbubbleentity)
1641                 remove (self.chatbubbleentity);
1642
1643         if (self.killindicator)
1644                 remove (self.killindicator);
1645
1646         WaypointSprite_PlayerGone();
1647
1648         bot_relinkplayerlist();
1649
1650         if(g_arena)
1651         {
1652                 Spawnqueue_Unmark(self);
1653                 Spawnqueue_Remove(self);
1654         }
1655
1656         accuracy_free(self);
1657         ClientData_Detach();
1658         PlayerScore_Detach(self);
1659
1660         if(self.netname_previous)
1661                 strunzone(self.netname_previous);
1662         if(self.clientstatus)
1663                 strunzone(self.clientstatus);
1664         if(self.weaponorder_byimpulse)
1665                 strunzone(self.weaponorder_byimpulse);
1666
1667         ClearPlayerSounds();
1668
1669         if(self.personal)
1670                 remove(self.personal);
1671
1672         self.playerid = 0;
1673         ReadyCount();
1674
1675         // free cvars
1676         GetCvars(-1);
1677 }
1678
1679 .float BUTTON_CHAT;
1680 void ChatBubbleThink()
1681 {
1682         self.nextthink = time;
1683         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1684         {
1685                 if(self.owner) // but why can that ever be world?
1686                         self.owner.chatbubbleentity = world;
1687                 remove(self);
1688                 return;
1689         }
1690         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1691 #ifdef TETRIS
1692                 || self.owner.tetris_on
1693 #endif
1694         )
1695                 self.model = self.mdl;
1696         else
1697                 self.model = "";
1698 }
1699
1700 void UpdateChatBubble()
1701 {
1702         if (self.alpha < 0)
1703                 return;
1704         // spawn a chatbubble entity if needed
1705         if (!self.chatbubbleentity)
1706         {
1707                 self.chatbubbleentity = spawn();
1708                 self.chatbubbleentity.owner = self;
1709                 self.chatbubbleentity.exteriormodeltoclient = self;
1710                 self.chatbubbleentity.think = ChatBubbleThink;
1711                 self.chatbubbleentity.nextthink = time;
1712                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1713                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1714                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1715                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1716                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1717                 self.chatbubbleentity.model = "";
1718                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1719         }
1720 }
1721
1722
1723 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1724 // added to the model skins
1725 /*void UpdateColorModHack()
1726 {
1727         float c;
1728         c = self.clientcolors & 15;
1729         // LordHavoc: only bothering to support white, green, red, yellow, blue
1730              if (!teamplay) self.colormod = '0 0 0';
1731         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1732         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1733         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1734         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1735         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1736         else self.colormod = '1 1 1';
1737 }*/
1738
1739 void respawn(void)
1740 {
1741         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1742         {
1743                 self.solid = SOLID_NOT;
1744                 self.takedamage = DAMAGE_NO;
1745                 self.movetype = MOVETYPE_FLY;
1746                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1747                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1748                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1749                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1750                 if(autocvar_g_respawn_ghosts_maxtime)
1751                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1752         }
1753
1754         CopyBody(1);
1755
1756         self.effects |= EF_NODRAW; // prevent another CopyBody
1757         PutClientInServer();
1758 }
1759
1760 void play_countdown(float finished, string samp)
1761 {
1762         if(clienttype(self) == CLIENTTYPE_REAL)
1763                 if(floor(finished - time - frametime) != floor(finished - time))
1764                         if(finished - time < 6)
1765                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1766 }
1767
1768 void player_powerups (void)
1769 {
1770         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1771         olditems = self.items;
1772
1773         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1774                 self.modelflags |= MF_ROCKET;
1775         else
1776                 self.modelflags &~= MF_ROCKET;
1777
1778         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1779
1780         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1781                 return;
1782
1783         Fire_ApplyDamage(self);
1784         Fire_ApplyEffect(self);
1785
1786         if (g_minstagib)
1787         {
1788                 self.effects |= EF_FULLBRIGHT;
1789
1790                 if (self.items & IT_STRENGTH)
1791                 {
1792                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1793                         if (time > self.strength_finished)
1794                         {
1795                                 self.alpha = default_player_alpha;
1796                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1797                                 self.items &~= IT_STRENGTH;
1798                                 sprint(self, "^3Invisibility has worn off\n");
1799                         }
1800                 }
1801                 else
1802                 {
1803                         if (time < self.strength_finished)
1804                         {
1805                                 self.alpha = g_minstagib_invis_alpha;
1806                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1807                                 self.items |= IT_STRENGTH;
1808                                 sprint(self, "^3You are invisible\n");
1809                         }
1810                 }
1811
1812                 if (self.items & IT_INVINCIBLE)
1813                 {
1814                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1815                         if (time > self.invincible_finished)
1816                         {
1817                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1818                                 sprint(self, "^3Speed has worn off\n");
1819                         }
1820                 }
1821                 else
1822                 {
1823                         if (time < self.invincible_finished)
1824                         {
1825                                 self.items = self.items | IT_INVINCIBLE;
1826                                 sprint(self, "^3You are on speed\n");
1827                         }
1828                 }
1829         }
1830         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1831         {
1832                 if (self.items & IT_STRENGTH)
1833                 {
1834                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1835                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1836                         if (time > self.strength_finished)
1837                         {
1838                                 self.items = self.items - (self.items & IT_STRENGTH);
1839                                 sprint(self, "^3Strength has worn off\n");
1840                         }
1841                 }
1842                 else
1843                 {
1844                         if (time < self.strength_finished)
1845                         {
1846                                 self.items = self.items | IT_STRENGTH;
1847                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1848                         }
1849                 }
1850                 if (self.items & IT_INVINCIBLE)
1851                 {
1852                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1853                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1854                         if (time > self.invincible_finished)
1855                         {
1856                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1857                                 sprint(self, "^3Shield has worn off\n");
1858                         }
1859                 }
1860                 else
1861                 {
1862                         if (time < self.invincible_finished)
1863                         {
1864                                 self.items = self.items | IT_INVINCIBLE;
1865                                 sprint(self, "^3Shield surrounds you\n");
1866                         }
1867                 }
1868                 if (self.items & IT_SUPERWEAPON)
1869                 {
1870                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1871                         {
1872                                 self.superweapons_finished = 0;
1873                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1874                                 sprint(self, "^3Superweapons have been lost\n");
1875                         }
1876                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1877                         {
1878                                 // don't let them run out
1879                         }
1880                         else
1881                         {
1882                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1883                                 if (time > self.superweapons_finished)
1884                                 {
1885                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1886                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1887                                         sprint(self, "^3Superweapons have broken down\n");
1888                                 }
1889                         }
1890                 }
1891                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1892                 {
1893                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1894                         {
1895                                 self.items = self.items | IT_SUPERWEAPON;
1896                                 sprint(self, "^3You now have a superweapon\n");
1897                         }
1898                         else
1899                         {
1900                                 self.superweapons_finished = 0;
1901                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1902                         }
1903                 }
1904                 else
1905                 {
1906                         self.superweapons_finished = 0;
1907                 }
1908         }
1909
1910         if(autocvar_g_nodepthtestplayers)
1911                 self.effects = self.effects | EF_NODEPTHTEST;
1912
1913         if(autocvar_g_fullbrightplayers)
1914                 self.effects = self.effects | EF_FULLBRIGHT;
1915
1916         // midair gamemode: damage only while in the air
1917         // if in midair mode, being on ground grants temporary invulnerability
1918         // (this is so that multishot weapon don't clear the ground flag on the
1919         // first damage in the frame, leaving the player vulnerable to the
1920         // remaining hits in the same frame)
1921         if (self.flags & FL_ONGROUND)
1922         if (g_midair)
1923                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1924
1925         if (time >= game_starttime)
1926         if (time < self.spawnshieldtime)
1927                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1928
1929         MUTATOR_CALLHOOK(PlayerPowerups);
1930 }
1931
1932 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1933 {
1934         if(current > stable)
1935                 return current;
1936         else if(current > stable - 0.25) // when close enough, "snap"
1937                 return stable;
1938         else
1939                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1940 }
1941
1942 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1943 {
1944         if(current < stable)
1945                 return current;
1946         else if(current < stable + 0.25) // when close enough, "snap"
1947                 return stable;
1948         else
1949                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1950 }
1951
1952 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1953 {
1954         if(current > rotstable)
1955         {
1956                 if(rotframetime > 0)
1957                 {
1958                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1959                         current = max(rotstable, current - rotlinear * rotframetime);
1960                 }
1961         }
1962         else if(current < regenstable)
1963         {
1964                 if(regenframetime > 0)
1965                 {
1966                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1967                         current = min(regenstable, current + regenlinear * regenframetime);
1968                 }
1969         }
1970
1971         if(current > limit)
1972                 current = limit;
1973
1974         return current;
1975 }
1976
1977 void player_regen (void)
1978 {
1979         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1980         maxh = autocvar_g_balance_health_rotstable;
1981         maxa = autocvar_g_balance_armor_rotstable;
1982         maxf = autocvar_g_balance_fuel_rotstable;
1983         minh = autocvar_g_balance_health_regenstable;
1984         mina = autocvar_g_balance_armor_regenstable;
1985         minf = autocvar_g_balance_fuel_regenstable;
1986         limith = autocvar_g_balance_health_limit;
1987         limita = autocvar_g_balance_armor_limit;
1988         limitf = autocvar_g_balance_fuel_limit;
1989
1990         max_mod = regen_mod = rot_mod = limit_mod = 1;
1991
1992         if (self.runes & RUNE_REGEN)
1993         {
1994                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1995                 {
1996                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1997                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1998                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1999                 }
2000                 else
2001                 {
2002                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2003                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2004                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2005                 }
2006         }
2007         else if (self.runes & CURSE_VENOM)
2008         {
2009                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2010                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2011                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2012                 else
2013                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2014                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2015                 //if (!self.runes & RUNE_REGEN)
2016                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2017         }
2018         maxh = maxh * max_mod;
2019         //maxa = maxa * max_mod;
2020         //maxf = maxf * max_mod;
2021         minh = minh * max_mod;
2022         //mina = mina * max_mod;
2023         //minf = minf * max_mod;
2024         limith = limith * limit_mod;
2025         limita = limita * limit_mod;
2026         //limitf = limitf * limit_mod;
2027
2028         if(g_lms && g_ca)
2029                 rot_mod = 0;
2030
2031         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2032         {
2033                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2034                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2035
2036                 // if player rotted to death...  die!
2037                 if(self.health < 1)
2038                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2039         }
2040
2041         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2042                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2043 }
2044
2045 float zoomstate_set;
2046 void SetZoomState(float z)
2047 {
2048         if(z != self.zoomstate)
2049         {
2050                 self.zoomstate = z;
2051                 ClientData_Touch(self);
2052         }
2053         zoomstate_set = 1;
2054 }
2055
2056 void GetPressedKeys(void) {
2057         MUTATOR_CALLHOOK(GetPressedKeys);
2058         if (self.movement_x > 0) // get if movement keys are pressed
2059         {       // forward key pressed
2060                 self.pressedkeys |= KEY_FORWARD;
2061                 self.pressedkeys &~= KEY_BACKWARD;
2062         }
2063         else if (self.movement_x < 0)
2064         {       // backward key pressed
2065                 self.pressedkeys |= KEY_BACKWARD;
2066                 self.pressedkeys &~= KEY_FORWARD;
2067         }
2068         else
2069         {       // no x input
2070                 self.pressedkeys &~= KEY_FORWARD;
2071                 self.pressedkeys &~= KEY_BACKWARD;
2072         }
2073
2074         if (self.movement_y > 0)
2075         {       // right key pressed
2076                 self.pressedkeys |= KEY_RIGHT;
2077                 self.pressedkeys &~= KEY_LEFT;
2078         }
2079         else if (self.movement_y < 0)
2080         {       // left key pressed
2081                 self.pressedkeys |= KEY_LEFT;
2082                 self.pressedkeys &~= KEY_RIGHT;
2083         }
2084         else
2085         {       // no y input
2086                 self.pressedkeys &~= KEY_RIGHT;
2087                 self.pressedkeys &~= KEY_LEFT;
2088         }
2089
2090         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2091                 self.pressedkeys |= KEY_JUMP;
2092         else
2093                 self.pressedkeys &~= KEY_JUMP;
2094         if (self.BUTTON_CROUCH)
2095                 self.pressedkeys |= KEY_CROUCH;
2096         else
2097                 self.pressedkeys &~= KEY_CROUCH;
2098
2099         if (self.BUTTON_ATCK)
2100                 self.pressedkeys |= KEY_ATCK;
2101         else
2102                 self.pressedkeys &~= KEY_ATCK;
2103         if (self.BUTTON_ATCK2)
2104                 self.pressedkeys |= KEY_ATCK2;
2105         else
2106                 self.pressedkeys &~= KEY_ATCK2;
2107 }
2108
2109 /*
2110 ======================
2111 spectate mode routines
2112 ======================
2113 */
2114
2115 void SpectateCopy(entity spectatee) {
2116         other = spectatee;
2117         MUTATOR_CALLHOOK(SpectateCopy);
2118         self.armortype = spectatee.armortype;
2119         self.armorvalue = spectatee.armorvalue;
2120         self.ammo_cells = spectatee.ammo_cells;
2121         self.ammo_shells = spectatee.ammo_shells;
2122         self.ammo_nails = spectatee.ammo_nails;
2123         self.ammo_rockets = spectatee.ammo_rockets;
2124         self.ammo_fuel = spectatee.ammo_fuel;
2125         self.clip_load = spectatee.clip_load;
2126         self.clip_size = spectatee.clip_size;
2127         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2128         self.health = spectatee.health;
2129         self.impulse = 0;
2130         self.items = spectatee.items;
2131         self.last_pickup = spectatee.last_pickup;
2132         self.hit_time = spectatee.hit_time;
2133         self.metertime = spectatee.metertime;
2134         self.strength_finished = spectatee.strength_finished;
2135         self.invincible_finished = spectatee.invincible_finished;
2136         self.pressedkeys = spectatee.pressedkeys;
2137         WEPSET_COPY_EE(self, spectatee);
2138         self.switchweapon = spectatee.switchweapon;
2139         self.switchingweapon = spectatee.switchingweapon;
2140         self.weapon = spectatee.weapon;
2141         self.nex_charge = spectatee.nex_charge;
2142         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2143         self.hagar_load = spectatee.hagar_load;
2144         self.minelayer_mines = spectatee.minelayer_mines;
2145         self.punchangle = spectatee.punchangle;
2146         self.view_ofs = spectatee.view_ofs;
2147         self.velocity = spectatee.velocity;
2148         self.dmg_take = spectatee.dmg_take;
2149         self.dmg_save = spectatee.dmg_save;
2150         self.dmg_inflictor = spectatee.dmg_inflictor;
2151         self.v_angle = spectatee.v_angle;
2152         self.angles = spectatee.v_angle;
2153         self.stat_respawn_time = spectatee.stat_respawn_time;
2154         if(!self.BUTTON_USE)
2155                 self.fixangle = TRUE;
2156         setorigin(self, spectatee.origin);
2157         setsize(self, spectatee.mins, spectatee.maxs);
2158         SetZoomState(spectatee.zoomstate);
2159
2160     anticheat_spectatecopy(spectatee);
2161         self.hud = spectatee.hud;
2162         if(spectatee.vehicle)
2163     {
2164         self.fixangle = FALSE;
2165         //self.velocity = spectatee.vehicle.velocity;
2166         self.vehicle_health = spectatee.vehicle_health;
2167         self.vehicle_shield = spectatee.vehicle_shield;
2168         self.vehicle_energy = spectatee.vehicle_energy;
2169         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2170         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2171         self.vehicle_reload1 = spectatee.vehicle_reload1;
2172         self.vehicle_reload2 = spectatee.vehicle_reload2;
2173
2174         msg_entity = self;
2175
2176         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2177             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2178             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2179             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2180
2181         //WriteByte (MSG_ONE, SVC_SETVIEW);
2182         //    WriteEntity(MSG_ONE, self);
2183         //makevectors(spectatee.v_angle);
2184         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2185     }
2186 }
2187
2188 float SpectateUpdate() {
2189         if(!self.enemy)
2190             return 0;
2191
2192         if (self == self.enemy)
2193                 return 0;
2194
2195         if(self.enemy.classname != "player")
2196                 return 0;
2197
2198         SpectateCopy(self.enemy);
2199
2200         return 1;
2201 }
2202
2203
2204 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2205 entity CA_SpectateNext(entity start) {
2206         if (start.team == self.team) {
2207                 return start;
2208         }
2209
2210         other = start;
2211         // continue from current player
2212         while(other && other.team != self.team) {
2213                 other = find(other, classname, "player");
2214         }
2215
2216         if (!other) {
2217                 // restart from begining
2218                 other = find(other, classname, "player");
2219                 while(other && other.team != self.team) {
2220                         other = find(other, classname, "player");
2221                 }
2222         }
2223
2224         return other;
2225 }
2226
2227 float SpectateNext(entity _prefer) {
2228
2229         if(_prefer)
2230                 other = _prefer;
2231         else
2232                 other = find(self.enemy, classname, "player");
2233
2234         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2235                 // CA and ca players when spectating enemies is forbidden
2236                 other = CA_SpectateNext(other);
2237         } else {
2238                 // other modes and ca spectators or spectating enemies is allowed
2239                 if (!other)
2240                         other = find(other, classname, "player");
2241         }
2242
2243         if (other)
2244                 self.enemy = other;
2245
2246         if(self.enemy.classname == "player") {
2247             /*if(self.enemy.vehicle)
2248             {
2249
2250             msg_entity = self;
2251             WriteByte(MSG_ONE, SVC_SETVIEW);
2252             WriteEntity(MSG_ONE, self.enemy);
2253             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2254
2255             self.movetype = MOVETYPE_NONE;
2256             accuracy_resend(self);
2257             }
2258             else
2259             {*/
2260             msg_entity = self;
2261             WriteByte(MSG_ONE, SVC_SETVIEW);
2262             WriteEntity(MSG_ONE, self.enemy);
2263             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2264             self.movetype = MOVETYPE_NONE;
2265             accuracy_resend(self);
2266
2267             if(!SpectateUpdate())
2268                 PutObserverInServer();
2269         //}
2270         return 1;
2271         } else {
2272                 return 0;
2273         }
2274 }
2275
2276 /*
2277 =============
2278 ShowRespawnCountdown()
2279
2280 Update a respawn countdown display.
2281 =============
2282 */
2283 void ShowRespawnCountdown()
2284 {
2285         float number;
2286         if(self.deadflag == DEAD_NO) // just respawned?
2287                 return;
2288         else
2289         {
2290                 number = ceil(self.respawn_time - time);
2291                 if(number <= 0)
2292                         return;
2293                 if(number <= self.respawn_countdown)
2294                 {
2295                         self.respawn_countdown = number - 1;
2296                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2297                                 AnnounceTo(self, strcat(ftos(number), ""));
2298                 }
2299         }
2300 }
2301
2302 .float prevent_join_msgtime;
2303 void LeaveSpectatorMode()
2304 {
2305         if(nJoinAllowed(self)) {
2306                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2307                         self.classname = "player";
2308
2309                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2310                                 JoinBestTeam(self, FALSE, TRUE);
2311
2312                         if(autocvar_g_campaign)
2313                                 campaign_bots_may_start = 1;
2314
2315                         PutClientInServer();
2316
2317                         if(self.classname == "player")
2318                                 bprint ("^4", self.netname, "^4 is playing now\n");
2319
2320                         if(!autocvar_g_campaign)
2321                         if (time < self.jointime + autocvar_welcome_message_time)
2322                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2323
2324                         if (self.prevent_join_msgtime)
2325                         {
2326                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2327                                 self.prevent_join_msgtime = 0;
2328                         }
2329
2330                         return;
2331                 } else {
2332                         if (g_ca && self.caplayer) {
2333                         }       // do nothing
2334                         else
2335                                 stuffcmd(self,"menu_showteamselect\n");
2336                         return;
2337                 }
2338         }
2339         else {
2340                 //player may not join because of g_maxplayers is set
2341                 if (time - self.prevent_join_msgtime > 2)
2342                 {
2343                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2344                         self.prevent_join_msgtime = time;
2345                 }
2346         }
2347 }
2348
2349 /**
2350  * Determines whether the player is allowed to join. This depends on cvar
2351  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2352  * it checks whether the number of currently playing players exceeds g_maxplayers.
2353  * @return int number of free slots for players, 0 if none
2354  */
2355 float nJoinAllowed(entity ignore) {
2356         if(!ignore)
2357         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2358         // so report 0 free slots if restricted
2359         {
2360                 if(autocvar_g_forced_team_otherwise == "spectate")
2361                         return 0;
2362                 if(autocvar_g_forced_team_otherwise == "spectator")
2363                         return 0;
2364         }
2365
2366         if(self.team_forced < 0)
2367                 return 0; // forced spectators can never join
2368
2369         // TODO simplify this
2370         entity e;
2371         float totalClients = 0;
2372         FOR_EACH_CLIENT(e)
2373                 if(e != ignore)
2374                         totalClients += 1;
2375
2376         if (!autocvar_g_maxplayers)
2377                 return maxclients - totalClients;
2378
2379         float currentlyPlaying = 0;
2380         FOR_EACH_REALPLAYER(e)
2381                 currentlyPlaying += 1;
2382
2383         if(currentlyPlaying < autocvar_g_maxplayers)
2384                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2385
2386         return 0;
2387 }
2388
2389 /**
2390  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2391  * g_maxplayers_spectator_blocktime seconds
2392  */
2393 void checkSpectatorBlock() {
2394         if(self.classname == "spectator" || self.classname == "observer") {
2395                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2396                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2397                         dropclient(self);
2398                 }
2399         }
2400 }
2401
2402 .float motd_actived_time; // used for both motd and campaign_message
2403 void PrintWelcomeMessage()
2404 {
2405         if (self.motd_actived_time == 0) { // is there already a message showing?
2406                 if (autocvar_g_campaign) {
2407                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2408                                 self.motd_actived_time = time;
2409                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2410                         }
2411                 } else {
2412                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2413                                 self.motd_actived_time = time;
2414                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2415                         }
2416                 }
2417         } else { // showing MOTD or campaign message
2418                 if (autocvar_g_campaign) {
2419                         if (self.BUTTON_INFO)
2420                                 self.motd_actived_time = time;
2421                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2422                                 self.motd_actived_time = 0;
2423                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2424                         }
2425                 } else {
2426                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2427                                 if (self.BUTTON_INFO)
2428                                         self.motd_actived_time = time;
2429                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2430                                         self.motd_actived_time = 0;
2431                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2432                                 }
2433                         }
2434                 }
2435         }
2436 }
2437
2438 void ObserverThink()
2439 {
2440         float prefered_movetype;
2441         if (self.flags & FL_JUMPRELEASED) {
2442                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2443                         self.flags &~= FL_JUMPRELEASED;
2444                         self.flags |= FL_SPAWNING;
2445                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2446                         self.flags &~= FL_JUMPRELEASED;
2447                         if(SpectateNext(world) == 1) {
2448                                 self.classname = "spectator";
2449                         }
2450                 } else {
2451                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2452                         if (self.movetype != prefered_movetype)
2453                                 self.movetype = prefered_movetype;
2454                 }
2455         } else {
2456                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2457                         self.flags |= FL_JUMPRELEASED;
2458                         if(self.flags & FL_SPAWNING)
2459                         {
2460                                 self.flags &~= FL_SPAWNING;
2461                                 LeaveSpectatorMode();
2462                                 return;
2463                         }
2464                 }
2465         }
2466
2467         PrintWelcomeMessage();
2468 }
2469
2470 void SpectatorThink()
2471 {
2472         if (self.flags & FL_JUMPRELEASED) {
2473                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2474                         self.flags &~= FL_JUMPRELEASED;
2475                         self.flags |= FL_SPAWNING;
2476                 } else if(self.BUTTON_ATCK) {
2477                         self.flags &~= FL_JUMPRELEASED;
2478                         if(SpectateNext(world) == 1) {
2479                                 self.classname = "spectator";
2480                         } else {
2481                                 self.classname = "observer";
2482                                 PutClientInServer();
2483                         }
2484                 } else if (self.BUTTON_ATCK2) {
2485                         self.flags &~= FL_JUMPRELEASED;
2486                         self.classname = "observer";
2487                         PutClientInServer();
2488                 } else {
2489                         if(!SpectateUpdate())
2490                                 PutObserverInServer();
2491                 }
2492         } else {
2493                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2494                         self.flags |= FL_JUMPRELEASED;
2495                         if(self.flags & FL_SPAWNING)
2496                         {
2497                                 self.flags &~= FL_SPAWNING;
2498                                 LeaveSpectatorMode();
2499                                 return;
2500                         }
2501                 }
2502                 if(!SpectateUpdate())
2503                         PutObserverInServer();
2504         }
2505
2506         PrintWelcomeMessage();
2507         self.flags |= FL_CLIENT | FL_NOTARGET;
2508 }
2509
2510 void PlayerUseKey()
2511 {
2512         if(self.classname != "player")
2513                 return;
2514
2515         if(self.vehicle)
2516         {
2517         vehicles_exit(VHEF_NORMAL);
2518         return;
2519         }
2520
2521         // a use key was pressed; call handlers
2522         MUTATOR_CALLHOOK(PlayerUseKey);
2523 }
2524
2525 .float touchexplode_time;
2526
2527 /*
2528 =============
2529 PlayerPreThink
2530
2531 Called every frame for each client before the physics are run
2532 =============
2533 */
2534 .float usekeypressed;
2535 void() nexball_setstatus;
2536 .float items_added;
2537 void PlayerPreThink (void)
2538 {
2539         WarpZone_PlayerPhysics_FixVAngle();
2540
2541         self.stat_game_starttime = game_starttime;
2542         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2543         self.stat_leadlimit = autocvar_leadlimit;
2544
2545         if(g_arena || (g_ca && !allowed_to_spawn))
2546                 self.stat_respawn_time = 0;
2547         else
2548                 self.stat_respawn_time = self.respawn_time;
2549
2550         if(frametime)
2551         {
2552                 // physics frames: update anticheat stuff
2553                 anticheat_prethink();
2554         }
2555
2556         if(blockSpectators && frametime)
2557                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2558                 checkSpectatorBlock();
2559
2560         zoomstate_set = 0;
2561
2562         if(self.netname_previous != self.netname)
2563         {
2564                 if(autocvar_sv_eventlog)
2565                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2566                 if(self.netname_previous)
2567                         strunzone(self.netname_previous);
2568                 self.netname_previous = strzone(self.netname);
2569         }
2570
2571         // version nagging
2572         if(self.version_nagtime)
2573                 if(self.cvar_g_xonoticversion)
2574                         if(time > self.version_nagtime)
2575                         {
2576                                 // don't notify git users
2577                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2578                                 {
2579                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2580                                         {
2581                                                 // notify release users if connecting to git
2582                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2583                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2584                                         }
2585                                         else
2586                                         {
2587                                                 float r;
2588                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2589                                                 if(r < 0)
2590                                                 {
2591                                                         // give users new version
2592                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2593                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2594                                                 }
2595                                                 else if(r > 0)
2596                                                 {
2597                                                         // notify users about old server version
2598                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2599                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2600                                                 }
2601                                         }
2602                                 }
2603                                 self.version_nagtime = 0;
2604                         }
2605
2606         // GOD MODE info
2607         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2608         {
2609                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2610                 self.max_armorvalue = 0;
2611         }
2612
2613 #ifdef TETRIS
2614         if (TetrisPreFrame())
2615                 return;
2616 #endif
2617
2618         MUTATOR_CALLHOOK(PlayerPreThink);
2619
2620         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2621         {
2622                 if(self.BUTTON_USE && !self.usekeypressed)
2623                         PlayerUseKey();
2624                 self.usekeypressed = self.BUTTON_USE;
2625         }
2626
2627         PrintWelcomeMessage();
2628
2629         if(self.classname == "player") {
2630 //              if(self.netname == "Wazat")
2631 //                      bprint(self.classname, "\n");
2632
2633                 CheckRules_Player();
2634
2635                 if (intermission_running)
2636                 {
2637                         IntermissionThink ();   // otherwise a button could be missed between
2638                         return;                                 // the think tics
2639                 }
2640
2641                 //don't allow the player to turn around while game is paused!
2642                 if(timeout_status == TIMEOUT_ACTIVE) {
2643                         // FIXME turn this into CSQC stuff
2644                         self.v_angle = self.lastV_angle;
2645                         self.angles = self.lastV_angle;
2646                         self.fixangle = TRUE;
2647                 }
2648
2649                 if(frametime)
2650                 {
2651 #ifndef NO_LEGACY_NETWORKING
2652                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2653 #endif
2654
2655                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2656                         {
2657                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2658                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2659                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2660
2661                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2662                                 {
2663                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2664                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2665                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2666                                 }
2667                         }
2668                         else
2669                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2670
2671                         player_powerups();
2672                 }
2673
2674                 if (g_minstagib)
2675                         minstagib_ammocheck();
2676
2677                 if (self.deadflag != DEAD_NO)
2678                 {
2679                         float button_pressed, force_respawn;
2680                         if(self.personal && g_race_qualifying)
2681                         {
2682                                 if(time > self.respawn_time)
2683                                 {
2684                                         self.respawn_time = time + 1; // only retry once a second
2685                                         respawn();
2686                                         self.impulse = 141;
2687                                 }
2688                         }
2689                         else
2690                         {
2691                                 if(frametime)
2692                                         player_anim();
2693                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2694                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2695                                 if (self.deadflag == DEAD_DYING)
2696                                 {
2697                                         if(force_respawn)
2698                                                 self.deadflag = DEAD_RESPAWNING;
2699                                         else if(!button_pressed)
2700                                                 self.deadflag = DEAD_DEAD;
2701                                 }
2702                                 else if (self.deadflag == DEAD_DEAD)
2703                                 {
2704                                         if(button_pressed)
2705                                                 self.deadflag = DEAD_RESPAWNABLE;
2706                                 }
2707                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2708                                 {
2709                                         if(!button_pressed)
2710                                                 self.deadflag = DEAD_RESPAWNING;
2711                                 }
2712                                 else if (self.deadflag == DEAD_RESPAWNING)
2713                                 {
2714                                         if(time > self.respawn_time)
2715                                         {
2716                                                 self.respawn_time = time + 1; // only retry once a second
2717                                                 respawn();
2718                                         }
2719                                 }
2720                                 ShowRespawnCountdown();
2721                         }
2722
2723                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2724                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2725                                 self.stat_respawn_time *= -1;
2726
2727                         return;
2728                 }
2729                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2730                 // so (self.deadflag == DEAD_NO) is always true in the code below
2731
2732                 if(g_touchexplode)
2733                 if(time > self.touchexplode_time)
2734                 if(self.classname == "player")
2735                 if(self.deadflag == DEAD_NO)
2736                 if not(IS_INDEPENDENT_PLAYER(self))
2737                 FOR_EACH_PLAYER(other) if(self != other)
2738                 {
2739                         if(time > other.touchexplode_time)
2740                         if(other.deadflag == DEAD_NO)
2741                         if not(IS_INDEPENDENT_PLAYER(other))
2742                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2743                         {
2744                                 PlayerTouchExplode(self, other);
2745                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2746                         }
2747                 }
2748
2749                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2750                 {
2751                         vector dist;
2752
2753                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2754                         dist = self.prevorigin - self.origin;
2755                         dist_z = 0;
2756                         self.lms_traveled_distance += fabs(vlen(dist));
2757
2758                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2759                         {
2760                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2761                                 self.lms_traveled_distance = 0;
2762                         }
2763
2764                         if(time > self.lms_nextcheck)
2765                         {
2766                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2767                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2768                                 {
2769                                         centerprint(self, autocvar_g_lms_campcheck_message);
2770                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2771                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2772                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2773                                 }
2774                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2775                                 self.lms_traveled_distance = 0;
2776                         }
2777                 }
2778
2779                 self.prevorigin = self.origin;
2780
2781                 if (!self.vehicle)
2782                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x && !self.freezetag_frozen) // prevent crouching if using melee attack
2783                 {
2784                         if (!self.crouch)
2785                         {
2786                                 self.crouch = TRUE;
2787                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2788                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2789                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2790                         }
2791                 }
2792                 else
2793                 {
2794                         if (self.crouch)
2795                         {
2796                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2797                                 if (!trace_startsolid)
2798                                 {
2799                                         self.crouch = FALSE;
2800                                         self.view_ofs = PL_VIEW_OFS;
2801                                         setsize (self, PL_MIN, PL_MAX);
2802                                 }
2803                         }
2804                 }
2805
2806                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2807                 {
2808                         if(self.bloodloss_timer < time)
2809                         {
2810                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2811                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2812                         }
2813                 }
2814
2815                 FixPlayermodel();
2816
2817                 GrapplingHookFrame();
2818
2819                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2820                 //if(frametime)
2821                 {
2822                         self.items &~= self.items_added;
2823
2824                         W_WeaponFrame();
2825
2826                         self.items_added = 0;
2827                         if(self.items & IT_JETPACK)
2828                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2829                                         self.items_added |= IT_FUEL;
2830
2831                         self.items |= self.items_added;
2832                 }
2833
2834                 player_regen();
2835
2836                 // rot nex charge to the charge limit
2837                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2838                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2839
2840                 if(frametime)
2841                         player_anim();
2842
2843                 if(g_nexball)
2844                         nexball_setstatus();
2845
2846                 // secret status
2847                 secrets_setstatus();
2848
2849                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2850
2851                 //self.angles_y=self.v_angle_y + 90;   // temp
2852         } else if(gameover) {
2853                 if (intermission_running)
2854                         IntermissionThink ();   // otherwise a button could be missed between
2855                 return;
2856         } else if(self.classname == "observer") {
2857                 ObserverThink();
2858         } else if(self.classname == "spectator") {
2859                 SpectatorThink();
2860         }
2861
2862         if(!zoomstate_set)
2863                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2864
2865         float oldspectatee_status;
2866         oldspectatee_status = self.spectatee_status;
2867         if(self.classname == "spectator")
2868                 self.spectatee_status = num_for_edict(self.enemy);
2869         else if(self.classname == "observer")
2870                 self.spectatee_status = num_for_edict(self);
2871         else
2872                 self.spectatee_status = 0;
2873         if(self.spectatee_status != oldspectatee_status)
2874         {
2875                 ClientData_Touch(self);
2876                 if(g_race || g_cts)
2877                         race_InitSpectator();
2878         }
2879
2880         if(self.teamkill_soundtime)
2881         if(time > self.teamkill_soundtime)
2882         {
2883                 self.teamkill_soundtime = 0;
2884
2885                 entity oldpusher, oldself;
2886
2887                 oldself = self; self = self.teamkill_soundsource;
2888                 oldpusher = self.pusher; self.pusher = oldself;
2889
2890                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2891
2892                 self.pusher = oldpusher;
2893                 self = oldself;
2894         }
2895
2896         if(self.taunt_soundtime)
2897         if(time > self.taunt_soundtime)
2898         {
2899                 self.taunt_soundtime = 0;
2900                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2901         }
2902
2903         target_voicescript_next(self);
2904
2905         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2906         if(!self.weapon)
2907                 self.clip_load = self.clip_size = 0;
2908 }
2909
2910 float isInvisibleString(string s)
2911 {
2912         float i, n, c;
2913         s = strdecolorize(s);
2914         for((i = 0), (n = strlen(s)); i < n; ++i)
2915         {
2916                 c = str2chr(s, i);
2917                 switch(c)
2918                 {
2919                         case 0:
2920                         case 32: // space
2921                                 break;
2922                         case 192: // charmap space
2923                                 if (!autocvar_utf8_enable)
2924                                         break;
2925                                 return FALSE;
2926                         case 160: // space in unicode fonts
2927                         case 0xE000 + 192: // utf8 charmap space
2928                                 if (autocvar_utf8_enable)
2929                                         break;
2930                         default:
2931                                 return FALSE;
2932                 }
2933         }
2934         return TRUE;
2935 }
2936
2937 /*
2938 =============
2939 PlayerPostThink
2940
2941 Called every frame for each client after the physics are run
2942 =============
2943 */
2944 .float idlekick_lasttimeleft;
2945 .entity showheadshotbbox;
2946 void showheadshotbbox_think()
2947 {
2948         if(self.owner.showheadshotbbox != self)
2949         {
2950                 remove(self);
2951                 return;
2952         }
2953         self.nextthink = time;
2954         setorigin(self, self.owner.origin);
2955         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2956 }
2957 void PlayerPostThink (void)
2958 {
2959         // Savage: Check for nameless players
2960         if (isInvisibleString(self.netname)) {
2961                 self.netname = "Player";
2962                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2963         }
2964
2965         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2966         {
2967                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2968                 {
2969                         if(self.idlekick_lasttimeleft)
2970                         {
2971                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2972                                 self.idlekick_lasttimeleft = 0;
2973                         }
2974                 }
2975                 else
2976                 {
2977                         float timeleft;
2978                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2979                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2980                         {
2981                                 if(!self.idlekick_lasttimeleft)
2982                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2983                         }
2984                         if(timeleft <= 0)
2985                         {
2986                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2987                                 AnnounceTo(self, "terminated");
2988                                 dropclient(self);
2989                                 return;
2990                         }
2991                         else if(timeleft <= 10)
2992                         {
2993                                 if(timeleft != self.idlekick_lasttimeleft)
2994                                         AnnounceTo(self, ftos(timeleft));
2995                                 self.idlekick_lasttimeleft = timeleft;
2996                         }
2997                 }
2998         }
2999
3000 #ifdef TETRIS
3001         if(self.impulse == 100)
3002                 ImpulseCommands();
3003         if (!TetrisPostFrame())
3004         {
3005 #endif
3006
3007         CheatFrame();
3008
3009         //CheckPlayerJump();
3010
3011         if(self.classname == "player") {
3012                 CheckRules_Player();
3013                 UpdateChatBubble();
3014                 if (self.impulse)
3015                         ImpulseCommands();
3016                 if (intermission_running)
3017                         return;         // intermission or finale
3018                 GetPressedKeys();
3019         }
3020
3021 #ifdef TETRIS
3022         }
3023 #endif
3024
3025         /*
3026         float i;
3027         for(i = 0; i < 1000; ++i)
3028         {
3029                 vector end;
3030                 end = self.origin + '0 0 1024' + 512 * randomvec();
3031                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3032                 if(trace_fraction < 1)
3033                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3034                 {
3035                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3036                         break;
3037                 }
3038         }
3039         */
3040
3041         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3042
3043         if(self.waypointsprite_attachedforcarrier)
3044                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3045
3046         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3047         {
3048                 if(!self.showheadshotbbox)
3049                 {
3050                         self.showheadshotbbox = spawn();
3051                         self.showheadshotbbox.classname = "headshotbbox";
3052                         self.showheadshotbbox.owner = self;
3053                         self.showheadshotbbox.think = showheadshotbbox_think;
3054                         self.showheadshotbbox.nextthink = time;
3055                         self = self.showheadshotbbox;
3056                         self.think();
3057                         self = self.owner;
3058                 }
3059         }
3060         else
3061         {
3062                 if(self.showheadshotbbox)
3063                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3064                 remove(self.showheadshotbbox);
3065         }
3066
3067         playerdemo_write();
3068
3069         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3070         {
3071                 if not(self.stored_netname)
3072                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3073                 if(self.stored_netname != self.netname)
3074                 {
3075                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3076                         strunzone(self.stored_netname);
3077                         self.stored_netname = strzone(self.netname);
3078                 }
3079         }
3080
3081         /*
3082         if(g_race)
3083                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3084         */
3085
3086         CSQCMODEL_AUTOUPDATE();
3087 }