explicitly allow an instant kill after player finished a CTS run, add a comment
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, autocvar_g_balance_campingrifle_magazinecapacity);
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(autocvar_spawn_debugview)
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > autocvar_g_spawn_furthest)
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(autocvar_spawn_debugview)
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(autocvar_spawn_debug)
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(autocvar_sv_servermodelsonly)
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602         MUTATOR_CALLHOOK(MakePlayerObserver);
603
604         Portal_ClearAll(self);
605
606         if(self.alivetime)
607         {
608                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
609                 self.alivetime = 0;
610         }
611
612         if(self.flagcarried)
613                 DropFlag(self.flagcarried, world, world);
614
615         if(self.ballcarried && g_nexball)
616                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
617
618         WaypointSprite_PlayerDead();
619
620         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
621                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
622
623         if(self.killcount != -666) {
624                 if(g_lms) {
625                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
626                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
627                         else
628                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
629                 } else
630                         bprint ("^4", self.netname, "^4 is spectating now\n");
631
632                 if(self.just_joined == FALSE) {
633                         LogTeamchange(self.playerid, -1, 4);
634                 } else
635                         self.just_joined = FALSE;
636         }
637
638         PlayerScore_Clear(self); // clear scores when needed
639
640         accuracy_resend(self);
641
642         self.spectatortime = time;
643
644         self.classname = "observer";
645         self.iscreature = FALSE;
646         self.health = -666;
647         self.takedamage = DAMAGE_NO;
648         self.solid = SOLID_NOT;
649         self.movetype = MOVETYPE_NOCLIP;
650         self.flags = FL_CLIENT | FL_NOTARGET;
651         self.armorvalue = 666;
652         self.effects = 0;
653         self.armorvalue = autocvar_g_balance_armor_start;
654         self.pauserotarmor_finished = 0;
655         self.pauserothealth_finished = 0;
656         self.pauseregen_finished = 0;
657         self.damageforcescale = 0;
658         self.death_time = 0;
659         self.dead_frame = 0;
660         self.alpha = 0;
661         self.scale = 0;
662         self.fade_time = 0;
663         self.pain_frame = 0;
664         self.pain_finished = 0;
665         self.strength_finished = 0;
666         self.invincible_finished = 0;
667         self.pushltime = 0;
668         self.think = SUB_Null;
669         self.nextthink = 0;
670         self.hook_time = 0;
671         self.runes = 0;
672         self.deadflag = DEAD_NO;
673         self.angles = spot.angles;
674         self.angles_z = 0;
675         self.fixangle = TRUE;
676         self.crouch = FALSE;
677
678         self.view_ofs = PL_VIEW_OFS;
679         setorigin (self, spot.origin);
680         setsize (self, '0 0 0', '0 0 0');
681         self.prevorigin = self.origin;
682         self.items = 0;
683         self.weapons = 0;
684         self.model = "";
685         FixPlayermodel();
686         self.model = "";
687         self.modelindex = 0;
688         self.weapon = 0;
689         self.weaponmodel = "";
690         self.weaponentity = world;
691         self.exteriorweaponentity = world;
692         self.killcount = -666;
693         self.velocity = '0 0 0';
694         self.avelocity = '0 0 0';
695         self.punchangle = '0 0 0';
696         self.punchvector = '0 0 0';
697         self.oldvelocity = self.velocity;
698         self.fire_endtime = -1;
699
700         if(sv_loddistance1)
701                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
702
703         if(g_arena)
704         {
705                 if(self.version_mismatch)
706                 {
707                         Spawnqueue_Unmark(self);
708                         Spawnqueue_Remove(self);
709                 }
710                 else
711                 {
712                         Spawnqueue_Insert(self);
713                 }
714         }
715         else if(g_lms)
716         {
717                 // Only if the player cannot play at all
718                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
719                         self.frags = FRAGS_SPECTATOR;
720                 else
721                         self.frags = FRAGS_LMS_LOSER;
722         }
723         else
724                 self.frags = FRAGS_SPECTATOR;
725 }
726
727 float RestrictSkin(float s)
728 {
729         if(!teams_matter)
730                 return s;
731         if(s == 6)
732                 return 6;
733         return mod(s, 3);
734 }
735
736 void FixPlayermodel()
737 {
738         local string defaultmodel;
739         local float defaultskin, chmdl, oldskin;
740         local vector m1, m2;
741
742         defaultmodel = "";
743
744         if(autocvar_sv_defaultcharacter == 1) {
745                 defaultskin = 0;
746
747                 if(teams_matter)
748                 {
749                         string s;
750                         s = Team_ColorNameLowerCase(self.team);
751                         if(s != "neutral")
752                         {
753                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
754                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
755                         }
756                 }
757
758                 if(defaultmodel == "")
759                 {
760                         defaultmodel = autocvar_sv_defaultplayermodel;
761                         defaultskin = autocvar_sv_defaultplayerskin;
762                 }
763         }
764
765         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
766         {
767                 if(self.model != "")
768                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
769                 self.model = ""; // force the != checks to return true
770         }
771
772         if(defaultmodel != "")
773         {
774                 if (defaultmodel != self.model)
775                 {
776                         m1 = self.mins;
777                         m2 = self.maxs;
778                         setmodel_lod (self, defaultmodel);
779                         setsize (self, m1, m2);
780                         chmdl = TRUE;
781                 }
782
783                 oldskin = self.skinindex;
784                 self.skinindex = defaultskin;
785         } else {
786                 if (self.playermodel != self.model || self.playermodel == "")
787                 {
788                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
789                         m1 = self.mins;
790                         m2 = self.maxs;
791                         setmodel_lod (self, self.playermodel);
792                         setsize (self, m1, m2);
793                         chmdl = TRUE;
794                 }
795
796                 oldskin = self.skinindex;
797                 self.skinindex = RestrictSkin(stof(self.playerskin));
798         }
799
800         if(chmdl || oldskin != self.skinindex)
801                 self.species = player_getspecies(); // model or skin has changed
802
803         if(!teams_matter)
804                 if(strlen(autocvar_sv_defaultplayercolors))
805                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
806                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
807 }
808
809 void PlayerTouchExplode(entity p1, entity p2)
810 {
811         vector org;
812         org = (p1.origin + p2.origin) * 0.5;
813         org_z += (p1.mins_z + p2.mins_z) * 0.5;
814
815         te_explosion(org);
816
817         entity e;
818         e = spawn();
819         setorigin(e, org);
820         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
821         remove(e);
822 }
823
824 /*
825 =============
826 PutClientInServer
827
828 Called when a client spawns in the server
829 =============
830 */
831 //void() ctf_playerchanged;
832 void PutClientInServer (void)
833 {
834         if(clienttype(self) == CLIENTTYPE_BOT)
835         {
836                 self.classname = "player";
837         }
838         else if(clienttype(self) == CLIENTTYPE_REAL)
839         {
840                 msg_entity = self;
841                 WriteByte(MSG_ONE, SVC_SETVIEW);
842                 WriteEntity(MSG_ONE, self);
843         }
844
845         // player is dead and becomes observer
846         // FIXME fix LMS scoring for new system
847         if(g_lms)
848         {
849                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
850                         self.classname = "observer";
851         }
852
853         if(g_arena || (g_ca && !allowed_to_spawn))
854         if(!self.spawned)
855                 self.classname = "observer";
856
857         if(gameover)
858                 self.classname = "observer";
859
860         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
861                 entity spot, oldself;
862                 float j;
863
864                 accuracy_resend(self);
865
866                 if(self.team < 0)
867                         JoinBestTeam(self, FALSE, TRUE);
868
869                 race_PreSpawn();
870
871                 spot = SelectSpawnPoint (FALSE);
872                 if(!spot)
873                 {
874                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
875                         return; // spawn failed
876                 }
877
878                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
879
880                 self.classname = "player";
881                 self.wasplayer = TRUE;
882                 self.iscreature = TRUE;
883                 self.movetype = MOVETYPE_WALK;
884                 self.solid = SOLID_SLIDEBOX;
885                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
886                 if(autocvar_g_playerclip_collisions)
887                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
888                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
889                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
890                 self.frags = FRAGS_PLAYER;
891                 if(independent_players)
892                         MAKE_INDEPENDENT_PLAYER(self);
893                 self.flags = FL_CLIENT;
894                 self.takedamage = DAMAGE_AIM;
895                 if(g_minstagib)
896                         self.effects = EF_FULLBRIGHT;
897                 else
898                         self.effects = 0;
899                 self.air_finished = time + 12;
900                 self.dmg = 2;
901                 if(autocvar_g_balance_nex_charge)
902                 {
903                         if(autocvar_g_balance_nex_secondary_chargepool)
904                                 self.nex_chargepool_ammo = 1;
905                         self.nex_charge = autocvar_g_balance_nex_charge_start;
906                 }
907
908                 if(inWarmupStage)
909                 {
910                         self.ammo_shells = warmup_start_ammo_shells;
911                         self.ammo_nails = warmup_start_ammo_nails;
912                         self.ammo_rockets = warmup_start_ammo_rockets;
913                         self.ammo_cells = warmup_start_ammo_cells;
914                         self.ammo_fuel = warmup_start_ammo_fuel;
915                         self.health = warmup_start_health;
916                         self.armorvalue = warmup_start_armorvalue;
917                         self.weapons = warmup_start_weapons;
918                 }
919                 else
920                 {
921                         self.ammo_shells = start_ammo_shells;
922                         self.ammo_nails = start_ammo_nails;
923                         self.ammo_rockets = start_ammo_rockets;
924                         self.ammo_cells = start_ammo_cells;
925                         self.ammo_fuel = start_ammo_fuel;
926                         self.health = start_health;
927                         self.armorvalue = start_armorvalue;
928                         self.weapons = start_weapons;
929                 }
930
931                 if(g_weaponarena_random)
932                 {
933                         if(g_weaponarena_random_with_laser)
934                                 self.weapons &~= WEPBIT_LASER;
935                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
936                         if(g_weaponarena_random_with_laser)
937                                 self.weapons |= WEPBIT_LASER;
938                 }
939
940                 self.items = start_items;
941                 self.jump_interval = time;
942
943                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
944                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
945                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
946                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
947                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
948                 //extend the pause of rotting if client was reset at the beginning of the countdown
949                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
950                         self.spawnshieldtime += game_starttime - time;
951                         self.pauserotarmor_finished += game_starttime - time;
952                         self.pauserothealth_finished += game_starttime - time;
953                         self.pauseregen_finished += game_starttime - time;
954                 }
955                 self.damageforcescale = 2;
956                 self.death_time = 0;
957                 self.dead_frame = 0;
958                 self.alpha = 0;
959                 self.scale = 0;
960                 self.fade_time = 0;
961                 self.pain_frame = 0;
962                 self.pain_finished = 0;
963                 self.strength_finished = 0;
964                 self.invincible_finished = 0;
965                 self.pushltime = 0;
966                 // players have no think function
967                 self.think = SUB_Null;
968                 self.nextthink = 0;
969                 self.hook_time = 0;
970                 self.dmg_team = 0;
971                 self.ballistics_density = autocvar_g_ballistics_density_player;
972
973                 self.metertime = 0;
974
975                 self.runes = 0;
976
977                 self.deadflag = DEAD_NO;
978
979                 self.angles = spot.angles;
980
981                 self.angles_z = 0; // never spawn tilted even if the spot says to
982                 self.fixangle = TRUE; // turn this way immediately
983                 self.velocity = '0 0 0';
984                 self.avelocity = '0 0 0';
985                 self.punchangle = '0 0 0';
986                 self.punchvector = '0 0 0';
987                 self.oldvelocity = self.velocity;
988                 self.fire_endtime = -1;
989
990                 msg_entity = self;
991                 WRITESPECTATABLE_MSG_ONE({
992                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
993                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
994                 });
995
996                 if(sv_loddistance1)
997                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
998
999                 self.model = "";
1000                 FixPlayermodel();
1001
1002                 self.crouch = FALSE;
1003                 self.view_ofs = PL_VIEW_OFS;
1004                 setsize (self, PL_MIN, PL_MAX);
1005                 self.spawnorigin = spot.origin;
1006                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1007                 // don't reset back to last position, even if new position is stuck in solid
1008                 self.oldorigin = self.origin;
1009                 self.prevorigin = self.origin;
1010                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1011
1012                 if(g_arena)
1013                 {
1014                         Spawnqueue_Remove(self);
1015                         Spawnqueue_Mark(self);
1016                 }
1017
1018                 else if(g_ca)
1019                         self.caplayer = 1;
1020
1021                 self.event_damage = PlayerDamage;
1022
1023                 self.bot_attack = TRUE;
1024
1025                 self.statdraintime = time + 5;
1026                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1027
1028                 if(self.killcount == -666) {
1029                         PlayerScore_Clear(self);
1030                         self.killcount = 0;
1031                 }
1032
1033                 self.cnt = WEP_LASER;
1034
1035                 CL_SpawnWeaponentity();
1036                 self.alpha = default_player_alpha;
1037                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1038                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1039
1040                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1041                 self.lms_traveled_distance = 0;
1042                 self.speedrunning = FALSE;
1043
1044                 race_PostSpawn(spot);
1045
1046                 if(autocvar_spawn_debug)
1047                 {
1048                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1049                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1050                 }
1051
1052                 //stuffcmd(self, "chase_active 0");
1053                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1054
1055                 if (autocvar_g_spawnsound)
1056                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1057
1058                 if(g_assault) {
1059                         if(self.team == assault_attacker_team)
1060                                 centerprint(self, "You are attacking!");
1061                         else
1062                                 centerprint(self, "You are defending!");
1063                 }
1064
1065                 target_voicescript_clear(self);
1066
1067                 // reset fields the weapons may use
1068                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1069                         weapon_action(j, WR_RESETPLAYER);
1070
1071                 oldself = self;
1072                 self = spot;
1073                         activator = oldself;
1074                                 SUB_UseTargets();
1075                         activator = world;
1076                 self = oldself;
1077
1078                 MUTATOR_CALLHOOK(PlayerSpawn);
1079
1080                 self.switchweapon = w_getbestweapon(self);
1081                 self.cnt = self.switchweapon;
1082                 self.weapon = 0;
1083
1084                 if(!self.alivetime)
1085                         self.alivetime = time;
1086         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1087                 PutObserverInServer ();
1088         }
1089
1090         //if(g_ctf)
1091         //      ctf_playerchanged();
1092 }
1093
1094 .float ebouncefactor, ebouncestop; // electro's values
1095 // TODO do we need all these fields, or should we stop autodetecting runtime
1096 // changes and just have a console command to update this?
1097 float ClientInit_SendEntity(entity to, float sf)
1098 {
1099         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1100         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1110         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1111         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1112         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1113         if(sv_foginterval && world.fog != "")
1114                 WriteString(MSG_ENTITY, world.fog);
1115         else
1116                 WriteString(MSG_ENTITY, "");
1117         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1118         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1119         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1120         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1121         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1122         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1124         WriteByte(MSG_ENTITY, autocvar_g_balance_campingrifle_secondary); // client has to know if it should zoom or not
1125         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1126         return TRUE;
1127 }
1128
1129 void ClientInit_CheckUpdate()
1130 {
1131         self.nextthink = time;
1132         if(self.count != autocvar_g_balance_armor_blockpercent)
1133         {
1134                 self.count = autocvar_g_balance_armor_blockpercent;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1138         {
1139                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1143         {
1144                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1145                 self.SendFlags |= 1;
1146         }
1147         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1148         {
1149                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1150                 self.SendFlags |= 1;
1151         }
1152         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1153         {
1154                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1155                 self.SendFlags |= 1;
1156         }
1157         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1158         {
1159                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1160                 self.SendFlags |= 1;
1161         }
1162 }
1163
1164 void ClientInit_Spawn()
1165 {
1166         entity o;
1167         entity e;
1168         e = spawn();
1169         e.classname = "clientinit";
1170         e.think = ClientInit_CheckUpdate;
1171         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1172
1173         o = self;
1174         self = e;
1175         ClientInit_CheckUpdate();
1176         self = o;
1177 }
1178
1179 /*
1180 =============
1181 SetNewParms
1182 =============
1183 */
1184 void SetNewParms (void)
1185 {
1186         // initialize parms for a new player
1187         parm1 = -(86400 * 366);
1188 }
1189
1190 /*
1191 =============
1192 SetChangeParms
1193 =============
1194 */
1195 void SetChangeParms (void)
1196 {
1197         // save parms for level change
1198         parm1 = self.parm_idlesince - time;
1199 }
1200
1201 /*
1202 =============
1203 DecodeLevelParms
1204 =============
1205 */
1206 void DecodeLevelParms (void)
1207 {
1208         // load parms
1209         self.parm_idlesince = parm1;
1210         if(self.parm_idlesince == -(86400 * 366))
1211                 self.parm_idlesince = time;
1212
1213         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1214         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1215 }
1216
1217 /*
1218 =============
1219 ClientKill
1220
1221 Called when a client types 'kill' in the console
1222 =============
1223 */
1224
1225 .float clientkill_nexttime;
1226 void ClientKill_Now_TeamChange()
1227 {
1228         if(self.killindicator_teamchange == -1)
1229         {
1230                 self.team = -1;
1231                 JoinBestTeam( self, FALSE, FALSE );
1232         }
1233         else if(self.killindicator_teamchange == -2)
1234         {
1235                 if(g_ca)
1236                         self.caplayer = 0;
1237                 if(blockSpectators)
1238                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1239                 PutObserverInServer();
1240         }
1241         else
1242                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1243 }
1244
1245 void ClientKill_Now()
1246 {
1247         if(self.killindicator_teamchange)
1248                 ClientKill_Now_TeamChange();
1249
1250         // in any case:
1251         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1252
1253         if(self.killindicator)
1254         {
1255                 dprint("Cleaned up after a leaked kill indicator.\n");
1256                 remove(self.killindicator);
1257                 self.killindicator = world;
1258         }
1259 }
1260 void KillIndicator_Think()
1261 {
1262         if (!self.owner.modelindex)
1263         {
1264                 self.owner.killindicator = world;
1265                 remove(self);
1266                 return;
1267         }
1268
1269         if(self.cnt <= 0)
1270         {
1271                 self = self.owner;
1272                 ClientKill_Now(); // no oldself needed
1273                 return;
1274         }
1275     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1276     {
1277         self.nextthink = time + 1;
1278         self.cnt -= 1;
1279     }
1280         else
1281         {
1282                 if(self.cnt <= 10)
1283                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1284                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1285                 {
1286                         if(self.cnt <= 10)
1287                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1288                         if(self.owner.killindicator_teamchange)
1289                         {
1290                                 if(self.owner.killindicator_teamchange == -1)
1291                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1292                                 else if(self.owner.killindicator_teamchange == -2)
1293                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1294                                 else
1295                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1296                         }
1297                         else
1298                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1299                 }
1300                 self.nextthink = time + 1;
1301                 self.cnt -= 1;
1302         }
1303 }
1304
1305 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1306 {
1307         float killtime;
1308         entity e;
1309         killtime = autocvar_g_balance_kill_delay;
1310
1311         if(g_race_qualifying || g_cts)
1312                 killtime = 0;
1313
1314     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1315     {
1316                 remove(self.killindicator);
1317                 self.killindicator = world;
1318
1319         ClientKill_Now(); // allow instant kill in this case
1320         return;
1321     }
1322
1323         self.killindicator_teamchange = targetteam;
1324
1325     if(!self.killindicator)
1326         {
1327                 if(self.modelindex && self.deadflag == DEAD_NO)
1328                 {
1329                         killtime = max(killtime, self.clientkill_nexttime - time);
1330                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1331                 }
1332
1333                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1334                 {
1335                         ClientKill_Now();
1336                 }
1337                 else
1338                 {
1339                         self.killindicator = spawn();
1340                         self.killindicator.owner = self;
1341                         self.killindicator.scale = 0.5;
1342                         setattachment(self.killindicator, self, "");
1343                         setorigin(self.killindicator, '0 0 52');
1344                         self.killindicator.think = KillIndicator_Think;
1345                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1346                         self.killindicator.cnt = ceil(killtime);
1347                         self.killindicator.count = bound(0, ceil(killtime), 10);
1348                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1349
1350                         for(e = world; (e = find(e, classname, "body")) != world; )
1351                         {
1352                                 if(e.enemy != self)
1353                                         continue;
1354                                 e.killindicator = spawn();
1355                                 e.killindicator.owner = e;
1356                                 e.killindicator.scale = 0.5;
1357                                 setattachment(e.killindicator, e, "");
1358                                 setorigin(e.killindicator, '0 0 52');
1359                                 e.killindicator.think = KillIndicator_Think;
1360                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1361                                 e.killindicator.cnt = ceil(killtime);
1362                         }
1363                         self.lip = 0;
1364                 }
1365         }
1366         if(self.killindicator)
1367         {
1368                 if(targetteam == 0) // just die
1369                         self.killindicator.colormod = '0 0 0';
1370                 else if(targetteam == -1) // auto
1371                         self.killindicator.colormod = '0 1 0';
1372                 else if(targetteam == -2) // spectate
1373                         self.killindicator.colormod = '0.5 0.5 0.5';
1374                 else
1375                         self.killindicator.colormod = TeamColor(targetteam);
1376         }
1377 }
1378
1379 void ClientKill (void)
1380 {
1381         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1382         {
1383                 // do nothing
1384         }
1385     else if(g_freezetag && self.freezetag_frozen == 1)
1386     {
1387         // do nothing
1388     }
1389         else
1390                 ClientKill_TeamChange(0);
1391 }
1392
1393 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1394 {
1395     e.killindicator = spawn();
1396     e.killindicator.owner = e;
1397     e.killindicator.think = KillIndicator_Think;
1398     e.killindicator.nextthink = time + (e.lip) * 0.05;
1399     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1400     e.killindicator.health = 1; // this is used to indicate that it should be silent
1401     e.lip = 0;
1402 }
1403
1404 void DoTeamChange(float destteam)
1405 {
1406         float t, c0;
1407         if(!teams_matter)
1408         {
1409                 if(destteam >= 0)
1410                         SetPlayerColors(self, destteam);
1411                 return;
1412         }
1413         if(self.classname == "player")
1414         if(destteam == -1)
1415         {
1416                 CheckAllowedTeams(self);
1417                 t = FindSmallestTeam(self, TRUE);
1418                 switch(self.team)
1419                 {
1420                         case COLOR_TEAM1: c0 = c1; break;
1421                         case COLOR_TEAM2: c0 = c2; break;
1422                         case COLOR_TEAM3: c0 = c3; break;
1423                         case COLOR_TEAM4: c0 = c4; break;
1424                         default:          c0 = 999;
1425                 }
1426                 switch(t)
1427                 {
1428                         case 1:
1429                                 if(c0 > c1)
1430                                         destteam = COLOR_TEAM1;
1431                                 break;
1432                         case 2:
1433                                 if(c0 > c2)
1434                                         destteam = COLOR_TEAM2;
1435                                 break;
1436                         case 3:
1437                                 if(c0 > c3)
1438                                         destteam = COLOR_TEAM3;
1439                                 break;
1440                         case 4:
1441                                 if(c0 > c4)
1442                                         destteam = COLOR_TEAM4;
1443                                 break;
1444                 }
1445                 if(destteam == -1)
1446                         return;
1447         }
1448         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1449                 return;
1450         ClientKill_TeamChange(destteam);
1451 }
1452
1453 void FixClientCvars(entity e)
1454 {
1455         // send prediction settings to the client
1456         stuffcmd(e, "\nin_bindmap 0 0\n");
1457         if(g_race || g_cts)
1458                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1459         if(autocvar_g_antilag == 3) // client side hitscan
1460                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1461         if(sv_gentle)
1462                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1463         /*
1464          * we no longer need to stuff this. Remove this comment block if you feel
1465          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1466         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1467         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1468         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1469         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1470         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1471         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1472         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1473         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1474         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1475         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1476         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1477         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1478         stuffcmd(e, "cl_movement_edgefriction 1\n");
1479          */
1480 }
1481
1482 float PlayerInIDList(entity p, string idlist)
1483 {
1484         float n, i;
1485         string s;
1486
1487         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1488         if not(p.crypto_idfp)
1489                 return 0;
1490
1491         // this function allows abbreviated player IDs too!
1492         n = tokenize_console(idlist);
1493         for(i = 0; i < n; ++i)
1494         {
1495                 s = argv(i);
1496                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1497                         return 1;
1498         }
1499
1500         return 0;
1501 }
1502
1503 /*
1504 =============
1505 ClientConnect
1506
1507 Called when a client connects to the server
1508 =============
1509 */
1510 //void ctf_clientconnect();
1511 string ColoredTeamName(float t);
1512 void DecodeLevelParms (void);
1513 //void dom_player_join_team(entity pl);
1514 void ClientConnect (void)
1515 {
1516         float t;
1517
1518         if(self.flags & FL_CLIENT)
1519         {
1520                 print("Warning: ClientConnect, but already connected!\n");
1521                 return;
1522         }
1523
1524         if(Ban_MaybeEnforceBan(self))
1525                 return;
1526
1527         DecodeLevelParms();
1528
1529 #ifdef WATERMARK
1530         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1531 #endif
1532
1533         self.classname = "player_joining";
1534
1535         self.flags = FL_CLIENT;
1536         self.version_nagtime = time + 10 + random() * 10;
1537
1538         if(player_count<0)
1539         {
1540                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1541                 player_count = 0;
1542         }
1543
1544         PlayerScore_Attach(self);
1545         ClientData_Attach();
1546         accuracy_init(self);
1547
1548         bot_clientconnect();
1549
1550         playerdemo_init();
1551
1552         anticheat_init();
1553         
1554         race_PreSpawnObserver();
1555
1556         //if(g_domination)
1557         //      dom_player_join_team(self);
1558
1559         // identify the right forced team
1560         if(autocvar_g_campaign)
1561         {
1562                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1563                 {
1564                         switch(autocvar_g_campaign_forceteam)
1565                         {
1566                                 case 1: self.team_forced = COLOR_TEAM1; break;
1567                                 case 2: self.team_forced = COLOR_TEAM2; break;
1568                                 case 3: self.team_forced = COLOR_TEAM3; break;
1569                                 case 4: self.team_forced = COLOR_TEAM4; break;
1570                                 default: self.team_forced = 0;
1571                         }
1572                 }
1573         }
1574         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1575                 self.team_forced = COLOR_TEAM1;
1576         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1577                 self.team_forced = COLOR_TEAM2;
1578         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1579                 self.team_forced = COLOR_TEAM3;
1580         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1581                 self.team_forced = COLOR_TEAM4;
1582         else if(autocvar_g_forced_team_otherwise == "red")
1583                 self.team_forced = COLOR_TEAM1;
1584         else if(autocvar_g_forced_team_otherwise == "blue")
1585                 self.team_forced = COLOR_TEAM2;
1586         else if(autocvar_g_forced_team_otherwise == "yellow")
1587                 self.team_forced = COLOR_TEAM3;
1588         else if(autocvar_g_forced_team_otherwise == "pink")
1589                 self.team_forced = COLOR_TEAM4;
1590         else if(autocvar_g_forced_team_otherwise == "spectate")
1591                 self.team_forced = -1;
1592         else if(autocvar_g_forced_team_otherwise == "spectator")
1593                 self.team_forced = -1;
1594         else
1595                 self.team_forced = 0;
1596
1597         if(!teams_matter)
1598                 if(self.team_forced > 0)
1599                         self.team_forced = 0;
1600
1601         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1602
1603         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1604                 self.classname = "observer";
1605         } else {
1606                 if(teams_matter)
1607                 {
1608                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1609                         {
1610                                 self.classname = "player";
1611                                 campaign_bots_may_start = 1;
1612                         }
1613                         else
1614                         {
1615                                 self.classname = "observer"; // do it anyway
1616                         }
1617                 }
1618                 else
1619                 {
1620                         self.classname = "player";
1621                         campaign_bots_may_start = 1;
1622                 }
1623         }
1624
1625         self.playerid = (playerid_last = playerid_last + 1);
1626
1627         if(autocvar_sv_eventlog)
1628                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1629
1630         LogTeamchange(self.playerid, self.team, 1);
1631
1632         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1633
1634         self.netname_previous = strzone(self.netname);
1635
1636         bprint("^4", self.netname, "^4 connected");
1637
1638         if(self.classname != "observer" && (g_domination || g_ctf))
1639                 bprint(" and joined the ", ColoredTeamName(self.team));
1640
1641         bprint("\n");
1642
1643         self.welcomemessage_time = 0;
1644
1645         stuffcmd(self, strcat(clientstuff, "\n"));
1646         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1647         stuffcmd(self, "cl_particles_reloadeffects\n");
1648
1649         FixClientCvars(self);
1650
1651         // spawnfunc_waypoint sprites
1652         WaypointSprite_InitClient(self);
1653
1654         // Wazat's grappling hook
1655         SetGrappleHookBindings();
1656
1657         // get autoswitch state from player when he toggles it
1658         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1659
1660         // get version info from player
1661         stuffcmd(self, "cmd clientversion $gameversion\n");
1662
1663         // get other cvars from player
1664         GetCvars(0);
1665
1666         // notify about available teams
1667         if(teams_matter)
1668         {
1669                 CheckAllowedTeams(self);
1670                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1671                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1672         }
1673         else
1674                 stuffcmd(self, "set _teams_available 0\n");
1675
1676         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1677
1678         if(g_arena || g_ca)
1679         {
1680                 self.classname = "observer";
1681                 if(g_arena)
1682                         Spawnqueue_Insert(self);
1683         }
1684         /*else if(g_ctf)
1685         {
1686                 ctf_clientconnect();
1687         }*/
1688
1689         if(teams_matter || radar_showennemies)
1690                 attach_entcs();
1691
1692         bot_relinkplayerlist();
1693
1694         self.spectatortime = time;
1695         if(blockSpectators)
1696         {
1697                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1698         }
1699
1700         self.jointime = time;
1701         self.allowedTimeouts = autocvar_sv_timeout_number;
1702
1703         if(clienttype(self) == CLIENTTYPE_REAL)
1704         {
1705                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1706                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1707         }
1708
1709         if(g_lms)
1710         {
1711                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1712                 {
1713                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1714                         self.frags = FRAGS_SPECTATOR;
1715                 }
1716         }
1717
1718         if(!sv_foginterval && world.fog != "")
1719                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1720
1721         SoundEntity_Attach(self);
1722
1723         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1724         {
1725                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1726                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1727         }
1728         else
1729                 self.hitplotfh = -1;
1730
1731         if(g_race || g_cts) {
1732                 string rr;
1733                 if(g_cts)
1734                         rr = CTS_RECORD;
1735                 else
1736                         rr = RACE_RECORD;
1737                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1738
1739                 msg_entity = self;
1740                 race_send_recordtime(MSG_ONE);
1741                 race_send_speedaward(MSG_ONE);
1742
1743                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1744                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1745                 race_send_speedaward_alltimebest(MSG_ONE);
1746
1747                 float i;
1748                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1749                         race_SendRankings(i, 0, 0, MSG_ONE);
1750                 }
1751         }
1752         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1753                 send_CSQC_teamnagger();
1754
1755         send_CSQC_cr_maxbullets(self);
1756
1757         CheatInitClient();
1758
1759         PlayerStats_AddPlayer(self);
1760 }
1761
1762 /*
1763 =============
1764 ClientDisconnect
1765
1766 Called when a client disconnects from the server
1767 =============
1768 */
1769 .entity chatbubbleentity;
1770 .entity teambubbleentity;
1771 void ReadyCount();
1772 void ClientDisconnect (void)
1773 {
1774         if not(self.flags & FL_CLIENT)
1775         {
1776                 print("Warning: ClientDisconnect without ClientConnect\n");
1777                 return;
1778         }
1779
1780         PlayerStats_AddGlobalInfo(self);
1781
1782         CheatShutdownClient();
1783
1784         if(self.hitplotfh >= 0)
1785         {
1786                 fclose(self.hitplotfh);
1787                 self.hitplotfh = -1;
1788         }
1789
1790         anticheat_report();
1791         anticheat_shutdown();
1792
1793         playerdemo_shutdown();
1794
1795         bot_clientdisconnect();
1796
1797         if(self.entcs)
1798                 detach_entcs();
1799
1800         if(autocvar_sv_eventlog)
1801                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1802         bprint ("^4",self.netname);
1803         bprint ("^4 disconnected\n");
1804
1805         SoundEntity_Detach(self);
1806
1807         DropAllRunes(self);
1808         MUTATOR_CALLHOOK(ClientDisconnect);
1809
1810         Portal_ClearAll(self);
1811
1812         if(self.flagcarried)
1813                 DropFlag(self.flagcarried, world, world);
1814         if(self.ballcarried && g_nexball)
1815                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1816
1817         // Here, everything has been done that requires this player to be a client.
1818
1819         self.flags &~= FL_CLIENT;
1820
1821         if (self.chatbubbleentity)
1822                 remove (self.chatbubbleentity);
1823
1824         if (self.teambubbleentity)
1825                 remove (self.teambubbleentity);
1826
1827         if (self.killindicator)
1828                 remove (self.killindicator);
1829
1830         WaypointSprite_PlayerGone();
1831
1832         bot_relinkplayerlist();
1833
1834         if(g_arena)
1835         {
1836                 Spawnqueue_Unmark(self);
1837                 Spawnqueue_Remove(self);
1838         }
1839
1840         accuracy_free(self);
1841         ClientData_Detach();
1842         PlayerScore_Detach(self);
1843
1844         if(self.netname_previous)
1845                 strunzone(self.netname_previous);
1846         if(self.clientstatus)
1847                 strunzone(self.clientstatus);
1848         if(self.weaponorder_byimpulse)
1849                 strunzone(self.weaponorder_byimpulse);
1850
1851         ClearPlayerSounds();
1852
1853         if(self.personal)
1854                 remove(self.personal);
1855
1856         self.playerid = 0;
1857         ReadyCount();
1858
1859         // free cvars
1860         GetCvars(-1);
1861 }
1862
1863 .float BUTTON_CHAT;
1864 void ChatBubbleThink()
1865 {
1866         self.nextthink = time;
1867         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1868         {
1869                 if(self.owner) // but why can that ever be world?
1870                         self.owner.chatbubbleentity = world;
1871                 remove(self);
1872                 return;
1873         }
1874         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1875 #ifdef TETRIS
1876                 || self.owner.tetris_on
1877 #endif
1878         )
1879                 self.model = self.mdl;
1880         else
1881                 self.model = "";
1882 };
1883
1884 void UpdateChatBubble()
1885 {
1886         if (!self.modelindex)
1887                 return;
1888         // spawn a chatbubble entity if needed
1889         if (!self.chatbubbleentity)
1890         {
1891                 self.chatbubbleentity = spawn();
1892                 self.chatbubbleentity.owner = self;
1893                 self.chatbubbleentity.exteriormodeltoclient = self;
1894                 self.chatbubbleentity.think = ChatBubbleThink;
1895                 self.chatbubbleentity.nextthink = time;
1896                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1897                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1898                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1899                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1900                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1901                 self.chatbubbleentity.model = "";
1902                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1903         }
1904 }
1905
1906
1907 void TeamBubbleThink()
1908 {
1909         self.nextthink = time;
1910         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1911         {
1912                 if(self.owner) // but why can that ever be world?
1913                         self.owner.teambubbleentity = world;
1914                 remove(self);
1915                 return;
1916         }
1917 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1918         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1919                 self.model = "";
1920         else
1921                 self.model = self.mdl;
1922
1923 };
1924
1925 float TeamBubble_customizeentityforclient()
1926 {
1927         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1928 }
1929
1930 void UpdateTeamBubble()
1931 {
1932         if (!self.modelindex || !teams_matter)
1933                 return;
1934         // spawn a teambubble entity if needed
1935         if (!self.teambubbleentity && teams_matter)
1936         {
1937                 self.teambubbleentity = spawn();
1938                 self.teambubbleentity.owner = self;
1939                 self.teambubbleentity.exteriormodeltoclient = self;
1940                 self.teambubbleentity.think = TeamBubbleThink;
1941                 self.teambubbleentity.nextthink = time;
1942                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1943 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1944                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1945                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1946                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1947                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1948                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1949                 self.teambubbleentity.effects = EF_LOWPRECISION;
1950         }
1951 }
1952
1953 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1954 // added to the model skins
1955 /*void UpdateColorModHack()
1956 {
1957         local float c;
1958         c = self.clientcolors & 15;
1959         // LordHavoc: only bothering to support white, green, red, yellow, blue
1960              if (!teams_matter) self.colormod = '0 0 0';
1961         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1962         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1963         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1964         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1965         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1966         else self.colormod = '1 1 1';
1967 };*/
1968
1969 .float oldcolormap;
1970 void respawn(void)
1971 {
1972         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1973         {
1974                 self.solid = SOLID_NOT;
1975                 self.takedamage = DAMAGE_NO;
1976                 self.movetype = MOVETYPE_FLY;
1977                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1978                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1979                 self.effects |= EF_ADDITIVE;
1980                 self.oldcolormap = self.colormap;
1981                 self.colormap = 512;
1982                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1983                 if(autocvar_g_respawn_ghosts_maxtime)
1984                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1985         }
1986
1987         CopyBody(1);
1988         self.effects |= EF_NODRAW; // prevent another CopyBody
1989         if(self.oldcolormap)
1990         {
1991                 self.colormap = self.oldcolormap;
1992                 self.oldcolormap = 0;
1993         }
1994         PutClientInServer();
1995 }
1996
1997 void play_countdown(float finished, string samp)
1998 {
1999         if(clienttype(self) == CLIENTTYPE_REAL)
2000                 if(floor(finished - time - frametime) != floor(finished - time))
2001                         if(finished - time < 6)
2002                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
2003 }
2004
2005 /**
2006  * When sv_timeout is used this function returs strings like
2007  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2008  * Called by centerprint functions
2009  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2010  */
2011 string getTimeoutText(float addOneSecond) {
2012         if (!autocvar_sv_timeout || !timeoutStatus)
2013                 return "";
2014
2015         local string retStr;
2016         if (timeoutStatus == 1) {
2017                 if (addOneSecond == 1) {
2018                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2019                 }
2020                 else {
2021                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2022                 }
2023                 return retStr;
2024         }
2025         else if (timeoutStatus == 2) {
2026                 if (addOneSecond) {
2027                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2028                         //don't show messages like "Timeout ends in 0 seconds"...
2029                         if ((remainingTimeoutTime + 1) > 0)
2030                                 return retStr;
2031                         else
2032                                 return "";
2033                 }
2034                 else {
2035                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2036                         //don't show messages like "Timeout ends in 0 seconds"...
2037                         if (remainingTimeoutTime > 0)
2038                                 return retStr;
2039                         else
2040                                 return "";
2041                 }
2042         }
2043         else return "";
2044 }
2045
2046 void player_powerups (void)
2047 {
2048         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2049         olditems = self.items;
2050         
2051         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2052         {
2053                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2054                 self.modelflags |= MF_ROCKET;
2055         }
2056         else
2057         {
2058                 SoundEntity_StopSound(self, CHAN_PLAYER);
2059                 self.modelflags &~= MF_ROCKET;
2060         }
2061
2062         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2063
2064         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2065                 return;
2066         
2067         Fire_ApplyDamage(self);
2068         Fire_ApplyEffect(self);
2069
2070         if (g_minstagib)
2071         {
2072                 self.effects |= EF_FULLBRIGHT;
2073
2074                 if (self.items & IT_STRENGTH)
2075                 {
2076                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2077                         if (time > self.strength_finished)
2078                         {
2079                                 self.alpha = default_player_alpha;
2080                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2081                                 self.items &~= IT_STRENGTH;
2082                                 sprint(self, "^3Invisibility has worn off\n");
2083                         }
2084                 }
2085                 else
2086                 {
2087                         if (time < self.strength_finished)
2088                         {
2089                                 self.alpha = g_minstagib_invis_alpha;
2090                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2091                                 self.items |= IT_STRENGTH;
2092                                 sprint(self, "^3You are invisible\n");
2093                         }
2094                 }
2095
2096                 if (self.items & IT_INVINCIBLE)
2097                 {
2098                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2099                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2100                         {
2101                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2102                                 sprint(self, "^3Speed has worn off\n");
2103                         }
2104                 }
2105                 else
2106                 {
2107                         if (time < self.invincible_finished)
2108                         {
2109                                 self.items = self.items | IT_INVINCIBLE;
2110                                 sprint(self, "^3You are on speed\n");
2111                         }
2112                 }
2113         }
2114         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2115         {
2116                 if (self.items & IT_STRENGTH)
2117                 {
2118                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2119                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2120                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2121                         {
2122                                 self.items = self.items - (self.items & IT_STRENGTH);
2123                                 sprint(self, "^3Strength has worn off\n");
2124                         }
2125                 }
2126                 else
2127                 {
2128                         if (time < self.strength_finished)
2129                         {
2130                                 self.items = self.items | IT_STRENGTH;
2131                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2132                         }
2133                 }
2134                 if (self.items & IT_INVINCIBLE)
2135                 {
2136                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2137                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2138                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2139                         {
2140                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2141                                 sprint(self, "^3Shield has worn off\n");
2142                         }
2143                 }
2144                 else
2145                 {
2146                         if (time < self.invincible_finished)
2147                         {
2148                                 self.items = self.items | IT_INVINCIBLE;
2149                                 sprint(self, "^3Shield surrounds you\n");
2150                         }
2151                 }
2152
2153                 if(autocvar_g_nodepthtestplayers)
2154                         self.effects = self.effects | EF_NODEPTHTEST;
2155
2156                 if(autocvar_g_fullbrightplayers)
2157                         self.effects = self.effects | EF_FULLBRIGHT;
2158
2159                 // midair gamemode: damage only while in the air
2160                 // if in midair mode, being on ground grants temporary invulnerability
2161                 // (this is so that multishot weapon don't clear the ground flag on the
2162                 // first damage in the frame, leaving the player vulnerable to the
2163                 // remaining hits in the same frame)
2164                 if (self.flags & FL_ONGROUND)
2165                 if (g_midair)
2166                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2167
2168                 if (time >= game_starttime)
2169                 if (time < self.spawnshieldtime)
2170                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2171         }
2172         
2173         MUTATOR_CALLHOOK(PlayerPowerups);
2174 }
2175
2176 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2177 {
2178         if(current > stable)
2179                 return current;
2180         else if(current > stable - 0.25) // when close enough, "snap"
2181                 return stable;
2182         else
2183                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2184 }
2185
2186 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2187 {
2188         if(current < stable)
2189                 return current;
2190         else if(current < stable + 0.25) // when close enough, "snap"
2191                 return stable;
2192         else
2193                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2194 }
2195
2196 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2197 {
2198         if(current > rotstable)
2199         {
2200                 if(rotframetime > 0)
2201                 {
2202                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2203                         current = max(rotstable, current - rotlinear * rotframetime);
2204                 }
2205         }
2206         else if(current < regenstable)
2207         {
2208                 if(regenframetime > 0)
2209                 {
2210                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2211                         current = min(regenstable, current + regenlinear * regenframetime);
2212                 }
2213         }
2214
2215         if(current > limit)
2216                 current = limit;
2217
2218         return current;
2219 }
2220
2221 void player_regen (void)
2222 {
2223         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2224         maxh = autocvar_g_balance_health_rotstable;
2225         maxa = autocvar_g_balance_armor_rotstable;
2226         maxf = autocvar_g_balance_fuel_rotstable;
2227         minh = autocvar_g_balance_health_regenstable;
2228         mina = autocvar_g_balance_armor_regenstable;
2229         minf = autocvar_g_balance_fuel_regenstable;
2230         limith = autocvar_g_balance_health_limit;
2231         limita = autocvar_g_balance_armor_limit;
2232         limitf = autocvar_g_balance_fuel_limit;
2233
2234         max_mod = regen_mod = rot_mod = limit_mod = 1;
2235
2236         if (self.runes & RUNE_REGEN)
2237         {
2238                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2239                 {
2240                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2241                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2242                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2243                 }
2244                 else
2245                 {
2246                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2247                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2248                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2249                 }
2250         }
2251         else if (self.runes & CURSE_VENOM)
2252         {
2253                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2254                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2255                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2256                 else
2257                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2258                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2259                 //if (!self.runes & RUNE_REGEN)
2260                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2261         }
2262         maxh = maxh * max_mod;
2263         //maxa = maxa * max_mod;
2264         //maxf = maxf * max_mod;
2265         minh = minh * max_mod;
2266         //mina = mina * max_mod;
2267         //minf = minf * max_mod;
2268         limith = limith * limit_mod;
2269         limita = limita * limit_mod;
2270         //limitf = limitf * limit_mod;
2271
2272         if(g_lms && g_ca)
2273                 rot_mod = 0;
2274
2275         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2276         {
2277                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2278                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2279
2280                 // if player rotted to death...  die!
2281                 if(self.health < 1)
2282                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2283         }
2284
2285         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2286                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2287 }
2288
2289 float zoomstate_set;
2290 void SetZoomState(float z)
2291 {
2292         if(z != self.zoomstate)
2293         {
2294                 self.zoomstate = z;
2295                 ClientData_Touch(self);
2296         }
2297         zoomstate_set = 1;
2298 }
2299
2300 void GetPressedKeys(void) {
2301         MUTATOR_CALLHOOK(GetPressedKeys);
2302         if (self.movement_x > 0) // get if movement keys are pressed
2303         {       // forward key pressed
2304                 self.pressedkeys |= KEY_FORWARD;
2305                 self.pressedkeys &~= KEY_BACKWARD;
2306         }
2307         else if (self.movement_x < 0)
2308         {       // backward key pressed
2309                 self.pressedkeys |= KEY_BACKWARD;
2310                 self.pressedkeys &~= KEY_FORWARD;
2311         }
2312         else
2313         {       // no x input
2314                 self.pressedkeys &~= KEY_FORWARD;
2315                 self.pressedkeys &~= KEY_BACKWARD;
2316         }
2317
2318         if (self.movement_y > 0)
2319         {       // right key pressed
2320                 self.pressedkeys |= KEY_RIGHT;
2321                 self.pressedkeys &~= KEY_LEFT;
2322         }
2323         else if (self.movement_y < 0)
2324         {       // left key pressed
2325                 self.pressedkeys |= KEY_LEFT;
2326                 self.pressedkeys &~= KEY_RIGHT;
2327         }
2328         else
2329         {       // no y input
2330                 self.pressedkeys &~= KEY_RIGHT;
2331                 self.pressedkeys &~= KEY_LEFT;
2332         }
2333
2334         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2335                 self.pressedkeys |= KEY_JUMP;
2336         else
2337                 self.pressedkeys &~= KEY_JUMP;
2338         if (self.BUTTON_CROUCH)
2339                 self.pressedkeys |= KEY_CROUCH;
2340         else
2341                 self.pressedkeys &~= KEY_CROUCH;
2342 }
2343
2344 /*
2345 ======================
2346 spectate mode routines
2347 ======================
2348 */
2349
2350 void SpectateCopy(entity spectatee) {
2351         other = spectatee;
2352         MUTATOR_CALLHOOK(SpectateCopy);
2353         self.armortype = spectatee.armortype;
2354         self.armorvalue = spectatee.armorvalue;
2355         self.ammo_cells = spectatee.ammo_cells;
2356         self.ammo_shells = spectatee.ammo_shells;
2357         self.ammo_nails = spectatee.ammo_nails;
2358         self.ammo_rockets = spectatee.ammo_rockets;
2359         self.ammo_fuel = spectatee.ammo_fuel;
2360         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2361         self.health = spectatee.health;
2362         self.impulse = 0;
2363         self.items = spectatee.items;
2364         self.last_pickup = spectatee.last_pickup;
2365         self.metertime = spectatee.metertime;
2366         self.strength_finished = spectatee.strength_finished;
2367         self.invincible_finished = spectatee.invincible_finished;
2368         self.pressedkeys = spectatee.pressedkeys;
2369         self.weapons = spectatee.weapons;
2370         self.switchweapon = spectatee.switchweapon;
2371         self.weapon = spectatee.weapon;
2372         self.punchangle = spectatee.punchangle;
2373         self.view_ofs = spectatee.view_ofs;
2374         self.v_angle = spectatee.v_angle;
2375         self.velocity = spectatee.velocity;
2376         self.dmg_take = spectatee.dmg_take;
2377         self.dmg_save = spectatee.dmg_save;
2378         self.dmg_inflictor = spectatee.dmg_inflictor;
2379         self.angles = spectatee.v_angle;
2380         self.fixangle = TRUE;
2381         setorigin(self, spectatee.origin);
2382         setsize(self, spectatee.mins, spectatee.maxs);
2383         SetZoomState(spectatee.zoomstate);
2384
2385         anticheat_spectatecopy(spectatee);
2386 }
2387
2388 float SpectateUpdate() {
2389         if(!self.enemy)
2390                 return 0;
2391
2392         if (self == self.enemy)
2393                 return 0;
2394
2395         if(self.enemy.classname != "player")
2396                 return 0;
2397
2398         SpectateCopy(self.enemy);
2399
2400         return 1;
2401 }
2402
2403 float SpectateNext() {
2404         other = find(self.enemy, classname, "player");
2405
2406         if (!other)
2407                 other = find(other, classname, "player");
2408
2409         if (other)
2410                 self.enemy = other;
2411
2412         if(self.enemy.classname == "player") {
2413                 msg_entity = self;
2414                 WriteByte(MSG_ONE, SVC_SETVIEW);
2415                 WriteEntity(MSG_ONE, self.enemy);
2416                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2417                 self.movetype = MOVETYPE_NONE;
2418                 accuracy_resend(self);
2419
2420                 if(!SpectateUpdate())
2421                         PutObserverInServer();
2422
2423                 return 1;
2424         } else {
2425                 return 0;
2426         }
2427 }
2428
2429 /*
2430 =============
2431 ShowRespawnCountdown()
2432
2433 Update a respawn countdown display.
2434 =============
2435 */
2436 void ShowRespawnCountdown()
2437 {
2438         float number;
2439         if(self.deadflag == DEAD_NO) // just respawned?
2440                 return;
2441         else
2442         {
2443                 number = ceil(self.death_time - time);
2444                 if(number <= 0)
2445                         return;
2446                 if(number <= self.respawn_countdown)
2447                 {
2448                         self.respawn_countdown = number - 1;
2449                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2450                                 AnnounceTo(self, strcat(ftos(number), ""));
2451                 }
2452         }
2453 }
2454
2455 void LeaveSpectatorMode()
2456 {
2457         if(isJoinAllowed()) {
2458                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2459                         self.classname = "player";
2460
2461                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2462                                 JoinBestTeam(self, FALSE, TRUE);
2463
2464                         if(autocvar_g_campaign)
2465                                 campaign_bots_may_start = 1;
2466
2467                         PutClientInServer();
2468
2469                         if(self.classname == "player")
2470                                 bprint ("^4", self.netname, "^4 is playing now\n");
2471
2472                         if(!autocvar_g_campaign)
2473                                 centerprint(self,""); // clear MOTD
2474
2475                         return;
2476                 } else {
2477                         if (g_ca && self.caplayer) {
2478                         }       // do nothing
2479                         else
2480                                 stuffcmd(self,"menu_showteamselect\n");
2481                         return;
2482                 }
2483         }
2484         else {
2485                 //player may not join because of g_maxplayers is set
2486                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2487         }
2488 }
2489
2490 /**
2491  * Determines whether the player is allowed to join. This depends on cvar
2492  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2493  * it checks whether the number of currently playing players exceeds g_maxplayers.
2494  * @return bool TRUE if the player is allowed to join, false otherwise
2495  */
2496 float isJoinAllowed() {
2497         if(self.team_forced < 0)
2498                 return FALSE; // forced spectators can never join
2499
2500         if (!autocvar_g_maxplayers)
2501                 return TRUE;
2502
2503         local entity e;
2504         local float currentlyPlaying;
2505         FOR_EACH_REALPLAYER(e) {
2506                 if(e.classname == "player")
2507                         currentlyPlaying += 1;
2508         }
2509         if(currentlyPlaying < autocvar_g_maxplayers)
2510                 return TRUE;
2511
2512         return FALSE;
2513 }
2514
2515 /**
2516  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2517  * g_maxplayers_spectator_blocktime seconds
2518  */
2519 void checkSpectatorBlock() {
2520         if(self.classname == "spectator" || self.classname == "observer") {
2521                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2522                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2523                         dropclient(self);
2524                 }
2525         }
2526 }
2527
2528 void ObserverThink()
2529 {
2530         if (self.flags & FL_JUMPRELEASED) {
2531                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2532                         self.welcomemessage_time = 0;
2533                         self.flags &~= FL_JUMPRELEASED;
2534                         self.flags |= FL_SPAWNING;
2535                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2536                         self.welcomemessage_time = 0;
2537                         self.flags &~= FL_JUMPRELEASED;
2538                         if(SpectateNext() == 1) {
2539                                 self.classname = "spectator";
2540                         }
2541                 }
2542         } else {
2543                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2544                         self.flags |= FL_JUMPRELEASED;
2545                         if(self.flags & FL_SPAWNING)
2546                         {
2547                                 self.flags &~= FL_SPAWNING;
2548                                 LeaveSpectatorMode();
2549                                 return;
2550                         }
2551                 }
2552         }
2553         PrintWelcomeMessage(self);
2554 }
2555
2556 void SpectatorThink()
2557 {
2558         if (self.flags & FL_JUMPRELEASED) {
2559                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2560                         self.welcomemessage_time = 0;
2561                         self.flags &~= FL_JUMPRELEASED;
2562                         self.flags |= FL_SPAWNING;
2563                 } else if(self.BUTTON_ATCK) {
2564                         self.welcomemessage_time = 0;
2565                         self.flags &~= FL_JUMPRELEASED;
2566                         if(SpectateNext() == 1) {
2567                                 self.classname = "spectator";
2568                         } else {
2569                                 self.classname = "observer";
2570                                 PutClientInServer();
2571                         }
2572                 } else if (self.BUTTON_ATCK2) {
2573                         self.welcomemessage_time = 0;
2574                         self.flags &~= FL_JUMPRELEASED;
2575                         self.classname = "observer";
2576                         PutClientInServer();
2577                 } else {
2578                         if(!SpectateUpdate())
2579                                 PutObserverInServer();
2580                 }
2581         } else {
2582                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2583                         self.flags |= FL_JUMPRELEASED;
2584                         if(self.flags & FL_SPAWNING)
2585                         {
2586                                 self.flags &~= FL_SPAWNING;
2587                                 LeaveSpectatorMode();
2588                                 return;
2589                         }
2590                 }
2591         }
2592
2593         PrintWelcomeMessage(self);
2594         self.flags |= FL_CLIENT | FL_NOTARGET;
2595 }
2596
2597 .float touchexplode_time;
2598
2599 /*
2600 =============
2601 PlayerPreThink
2602
2603 Called every frame for each client before the physics are run
2604 =============
2605 */
2606 void() ctf_setstatus;
2607 void() nexball_setstatus;
2608 .float items_added;
2609 void PlayerPreThink (void)
2610 {
2611         self.stat_game_starttime = game_starttime;
2612         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2613         self.stat_leadlimit = autocvar_leadlimit;
2614
2615         if(frametime)
2616         {
2617                 // physics frames: update anticheat stuff
2618                 anticheat_prethink();
2619         }
2620
2621         if(blockSpectators && frametime)
2622                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2623                 checkSpectatorBlock();
2624
2625         zoomstate_set = 0;
2626
2627         if(self.netname_previous != self.netname)
2628         {
2629                 if(autocvar_sv_eventlog)
2630                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2631                 if(self.netname_previous)
2632                         strunzone(self.netname_previous);
2633                 self.netname_previous = strzone(self.netname);
2634         }
2635
2636         // version nagging
2637         if(self.version_nagtime)
2638                 if(self.cvar_g_xonoticversion)
2639                         if(time > self.version_nagtime)
2640                         {
2641                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2642                                 {
2643                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2644                                         {
2645                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2646                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2647                                         }
2648                                         else
2649                                         {
2650                                                 float r;
2651                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2652                                                 if(r < 0)
2653                                                 {
2654                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2655                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2656                                                 }
2657                                                 else if(r > 0)
2658                                                 {
2659                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2660                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2661                                                 }
2662                                         }
2663                                 }
2664                                 self.version_nagtime = 0;
2665                         }
2666
2667         // GOD MODE info
2668         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2669         {
2670                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2671                 self.max_armorvalue = 0;
2672         }
2673
2674 #ifdef TETRIS
2675         if (TetrisPreFrame())
2676                 return;
2677 #endif
2678
2679         MUTATOR_CALLHOOK(PlayerPreThink);
2680
2681         if(self.classname == "player") {
2682 //              if(self.netname == "Wazat")
2683 //                      bprint(self.classname, "\n");
2684
2685                 CheckRules_Player();
2686
2687                 PrintWelcomeMessage(self);
2688
2689                 if (intermission_running)
2690                 {
2691                         IntermissionThink ();   // otherwise a button could be missed between
2692                         return;                                 // the think tics
2693                 }
2694
2695                 if(self.teleport_time)
2696                 if(time > self.teleport_time)
2697                 {
2698                         self.teleport_time = 0;
2699                         self.effects = self.effects - (self.effects & EF_NODRAW);
2700                 }
2701
2702                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2703                         UpdateSelectedPlayer();
2704
2705                 //don't allow the player to turn around while game is paused!
2706                 if(timeoutStatus == 2) {
2707                         self.v_angle = self.lastV_angle;
2708                         self.angles = self.lastV_angle;
2709                         self.fixangle = TRUE;
2710                 }
2711
2712                 if(frametime)
2713                 {
2714                         if(self.health <= 0 && autocvar_g_deathglow)
2715                         {
2716                                 if(self.glowmod_x > 0)
2717                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2718                                 else
2719                                         self.glowmod_x = -1;
2720                                 if(self.glowmod_y > 0)
2721                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2722                                 else
2723                                         self.glowmod_y = -1;
2724                                 if(self.glowmod_z > 0)
2725                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2726                                 else
2727                                         self.glowmod_z = -1;
2728                         }
2729                         else
2730                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2731                         player_powerups();
2732                 }
2733
2734                 if (self.deadflag != DEAD_NO)
2735                 {
2736                         float button_pressed, force_respawn;
2737                         if(self.personal && g_race_qualifying)
2738                         {
2739                                 if(time > self.death_time)
2740                                 {
2741                                         self.death_time = time + 1; // only retry once a second
2742                                         respawn();
2743                                         self.impulse = 141;
2744                                 }
2745                         }
2746                         else
2747                         {
2748                                 if(frametime)
2749                                         player_anim();
2750                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2751                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2752                                 if (self.deadflag == DEAD_DYING)
2753                                 {
2754                                         if(force_respawn)
2755                                                 self.deadflag = DEAD_RESPAWNING;
2756                                         else if(!button_pressed)
2757                                                 self.deadflag = DEAD_DEAD;
2758                                 }
2759                                 else if (self.deadflag == DEAD_DEAD)
2760                                 {
2761                                         if(button_pressed)
2762                                                 self.deadflag = DEAD_RESPAWNABLE;
2763                                 }
2764                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2765                                 {
2766                                         if(!button_pressed)
2767                                                 self.deadflag = DEAD_RESPAWNING;
2768                                 }
2769                                 else if (self.deadflag == DEAD_RESPAWNING)
2770                                 {
2771                                         if(time > self.death_time)
2772                                         {
2773                                                 self.death_time = time + 1; // only retry once a second
2774                                                 respawn();
2775                                         }
2776                                 }
2777                                 ShowRespawnCountdown();
2778                         }
2779                         return;
2780                 }
2781
2782                 if(g_touchexplode)
2783                 if(time > self.touchexplode_time)
2784                 if(self.classname == "player")
2785                 if(self.deadflag == DEAD_NO)
2786                 if not(IS_INDEPENDENT_PLAYER(self))
2787                 FOR_EACH_PLAYER(other) if(self != other)
2788                 {
2789                         if(time > other.touchexplode_time)
2790                         if(other.deadflag == DEAD_NO)
2791                         if not(IS_INDEPENDENT_PLAYER(other))
2792                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2793                         {
2794                                 PlayerTouchExplode(self, other);
2795                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2796                         }
2797                 }
2798
2799                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2800                 {
2801                         vector dist;
2802
2803                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2804                         dist = self.prevorigin - self.origin;
2805                         dist_z = 0;
2806                         self.lms_traveled_distance += fabs(vlen(dist));
2807
2808                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2809                         {
2810                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2811                                 self.lms_traveled_distance = 0;
2812                         }
2813
2814                         if(time > self.lms_nextcheck)
2815                         {
2816                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2817                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2818                                 {
2819                                         centerprint(self, autocvar_g_lms_campcheck_message);
2820                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2821                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2822                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2823                                 }
2824                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2825                                 self.lms_traveled_distance = 0;
2826                         }
2827                 }
2828
2829                 self.prevorigin = self.origin;
2830
2831                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2832                 {
2833                         if (!self.crouch)
2834                         {
2835                                 self.crouch = TRUE;
2836                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2837                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2838                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2839                         }
2840                 }
2841                 else
2842                 {
2843                         if (self.crouch)
2844                         {
2845                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2846                                 if (!trace_startsolid)
2847                                 {
2848                                         self.crouch = FALSE;
2849                                         self.view_ofs = PL_VIEW_OFS;
2850                                         setsize (self, PL_MIN, PL_MAX);
2851                                 }
2852                         }
2853                 }
2854
2855                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2856                 {
2857                         if(self.bloodloss_timer < time)
2858                         {
2859                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2860                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2861                         }
2862                 }
2863
2864                 FixPlayermodel();
2865
2866                 GrapplingHookFrame();
2867
2868                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2869                 //if(frametime)
2870                 {
2871                         self.items &~= self.items_added;
2872
2873                         W_WeaponFrame();
2874
2875                         self.items_added = 0;
2876                         if(self.items & IT_JETPACK)
2877                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2878                                         self.items_added |= IT_FUEL;
2879
2880                         self.items |= self.items_added;
2881                 }
2882
2883                 player_regen();
2884
2885                 // rot nex charge to the charge limit
2886                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2887                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2888
2889                 if(frametime)
2890                         player_anim();
2891
2892                 if (g_minstagib)
2893                         minstagib_ammocheck();
2894
2895                 if(g_ctf)
2896                         ctf_setstatus();
2897
2898                 if(g_nexball)
2899                         nexball_setstatus();
2900
2901                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2902
2903                 //self.angles_y=self.v_angle_y + 90;   // temp
2904         } else if(gameover) {
2905                 if (intermission_running)
2906                         IntermissionThink ();   // otherwise a button could be missed between
2907                 return;
2908         } else if(self.classname == "observer") {
2909                 ObserverThink();
2910         } else if(self.classname == "spectator") {
2911                 SpectatorThink();
2912         }
2913
2914         if(!zoomstate_set)
2915                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && autocvar_g_balance_campingrifle_secondary == 0));
2916
2917         float oldspectatee_status;
2918         oldspectatee_status = self.spectatee_status;
2919         if(self.classname == "spectator")
2920                 self.spectatee_status = num_for_edict(self.enemy);
2921         else if(self.classname == "observer")
2922                 self.spectatee_status = num_for_edict(self);
2923         else
2924                 self.spectatee_status = 0;
2925         if(self.spectatee_status != oldspectatee_status)
2926         {
2927                 ClientData_Touch(self);
2928                 if(g_race || g_cts)
2929                         race_InitSpectator();
2930         }
2931
2932         if(self.teamkill_soundtime)
2933         if(time > self.teamkill_soundtime)
2934         {
2935                 self.teamkill_soundtime = 0;
2936
2937                 entity oldpusher, oldself;
2938
2939                 oldself = self; self = self.teamkill_soundsource;
2940                 oldpusher = self.pusher; self.pusher = oldself;
2941
2942                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2943
2944                 self.pusher = oldpusher;
2945                 self = oldself;
2946         }
2947
2948         if(self.taunt_soundtime)
2949         if(time > self.taunt_soundtime)
2950         {
2951                 self.taunt_soundtime = 0;
2952                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2953         }
2954
2955         target_voicescript_next(self);
2956 }
2957
2958 float isInvisibleString(string s)
2959 {
2960         float i, n, c;
2961         s = strdecolorize(s);
2962         for((i = 0), (n = strlen(s)); i < n; ++i)
2963         {
2964                 c = str2chr(s, i);
2965                 switch(c)
2966                 {
2967                         case 0:
2968                         case 32: // space
2969                                 break;
2970                         case 192: // charmap space
2971                                 if (!autocvar_utf8_enable)
2972                                         break;
2973                                 return FALSE;
2974                         case 160: // space in unicode fonts
2975                         case 0xE000 + 192: // utf8 charmap space
2976                                 if (autocvar_utf8_enable)
2977                                         break;
2978                         default:
2979                                 return FALSE;
2980                 }
2981         }
2982         return TRUE;
2983 }
2984
2985 /*
2986 =============
2987 PlayerPostThink
2988
2989 Called every frame for each client after the physics are run
2990 =============
2991 */
2992 .float idlekick_lasttimeleft;
2993 .entity showheadshotbbox;
2994 void showheadshotbbox_think()
2995 {
2996         if(self.owner.showheadshotbbox != self)
2997         {
2998                 remove(self);
2999                 return;
3000         }
3001         self.nextthink = time;
3002         setorigin(self, self.owner.origin);
3003         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3004 }
3005 void PlayerPostThink (void)
3006 {
3007         // Savage: Check for nameless players
3008         if (isInvisibleString(self.netname)) {
3009                 self.netname = "Player";
3010                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3011         }
3012
3013         if(sv_maxidle && frametime)
3014         {
3015                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3016                 float timeleft;
3017                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3018                 if(timeleft <= 0)
3019                 {
3020                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3021                         AnnounceTo(self, "terminated");
3022                         dropclient(self);
3023                         return;
3024                 }
3025                 else if(timeleft <= 10)
3026                 {
3027                         if(timeleft != self.idlekick_lasttimeleft)
3028                         {
3029                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3030                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3031                         }
3032                 }
3033                 else
3034                 {
3035                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3036                 }
3037                 self.idlekick_lasttimeleft = timeleft;
3038         }
3039
3040 #ifdef TETRIS
3041         if(self.impulse == 100)
3042                 ImpulseCommands();
3043         if (TetrisPostFrame())
3044                 return;
3045 #endif
3046
3047         CheatFrame();