73c9169e5e6929341cca72c4f50377ec92c32125
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck)
136         if(spot.team != teamcheck)
137                 return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(cvar("spawn_debugview"))
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         teamcheck = 0;
329
330         if(!anypoint && have_team_spawns > 0)
331                 teamcheck = self.team;
332
333         // get the list of players
334         playerlist = findchain(classname, "player");
335         // get the entire list of spots
336         firstspot = findchain(classname, "info_player_deathmatch");
337         // filter out the bad ones
338         // (note this returns the original list if none survived)
339         if(anypoint)
340         {
341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
342         }
343         else
344         {
345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
346                 if(!firstspot_new)
347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
348                 firstspot = firstspot_new;
349
350                 // there is 50/50 chance of choosing a random spot or the furthest spot
351                 // (this means that roughly every other spawn will be furthest, so you
352                 // usually won't get fragged at spawn twice in a row)
353                 if (arena_roundbased && !g_ca)
354                 {
355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
356                         if(firstspot_new)
357                                 firstspot = firstspot_new;
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 }
360                 else if (random() > cvar("g_spawn_furthest"))
361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362                 else
363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
364         }
365
366         if(cvar("spawn_debugview"))
367         {
368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
369
370                 entity e;
371                 if(teamcheck)
372                         for(e = firstspot; e; e = e.chain)
373                                 if(e.team != teamcheck)
374                                         error("invalid spawn found");
375         }
376
377         if (!spot)
378         {
379                 if(cvar("spawn_debug"))
380                         GotoNextMap();
381                 else
382                 {
383                         if(some_spawn_has_been_used)
384                                 return world; // team can't spawn any more, because of actions of other team
385                         else
386                                 error("Cannot find a spawn point - please fix the map!");
387                 }
388         }
389
390         return spot;
391 }
392
393 /*
394 =============
395 CheckPlayerModel
396
397 Checks if the argument string can be a valid playermodel.
398 Returns a valid one in doubt.
399 =============
400 */
401 string FallbackPlayerModel;
402 string CheckPlayerModel(string plyermodel) {
403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
404         {
405                 // note: we cannot summon Don Strunzone here, some player may
406                 // still have the model string set. In case anyone manages how
407                 // to change a cvar default, we'll have a small leak here.
408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
409         }
410         if(strlen(plyermodel) < 4)
411                 return FallbackPlayerModel;
412         if( substring(plyermodel,0,14) != "models/player/")
413                 return FallbackPlayerModel;
414         else if(cvar("sv_servermodelsonly"))
415         {
416                 if(substring(plyermodel,-4,4) != ".zym")
417                 if(substring(plyermodel,-4,4) != ".dpm")
418                 if(substring(plyermodel,-4,4) != ".iqm")
419                 if(substring(plyermodel,-4,4) != ".md3")
420                 if(substring(plyermodel,-4,4) != ".psk")
421                         return FallbackPlayerModel;
422                 // forbid the LOD models
423                 if(substring(plyermodel, -9,5) == "_lod1")
424                         return FallbackPlayerModel;
425                 if(substring(plyermodel, -9,5) == "_lod2")
426                         return FallbackPlayerModel;
427                 if(plyermodel != strtolower(plyermodel))
428                         return FallbackPlayerModel;
429                 if(!fexists(plyermodel))
430                         return FallbackPlayerModel;
431         }
432         return plyermodel;
433 }
434
435 /*
436 =============
437 Client_customizeentityforclient
438
439 LOD reduction
440 =============
441 */
442 void Client_uncustomizeentityforclient()
443 {
444         if(self.modelindex == 0) // no need to uncustomize then
445                 return;
446         self.modelindex = self.modelindex_lod0;
447         self.skin = self.skinindex;
448 }
449
450 float Client_customizeentityforclient()
451 {
452         entity modelsource;
453
454         if(self.modelindex == 0)
455                 return TRUE;
456
457         // forcemodel stuff
458
459 #ifdef PROFILING
460         float t0;
461         t0 = gettime(GETTIME_HIRES); // reference
462 #endif
463
464         modelsource = self;
465
466 #ifdef ALLOW_FORCEMODELS
467         if(other.cvar_cl_forceplayermodelsfromxonotic)
468                 if not(self.modelindex_lod0_from_xonotic)
469                         modelsource = other;
470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
471                 modelsource = other;
472 #endif
473
474         self.skin = modelsource.skinindex;
475
476 #if 0
477         if(modelsource == self)
478                 self.skin = modelsource.skinindex;
479         else
480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
481 #endif
482
483         // self: me
484         // other: the player viewing me
485         float distance;
486         float f;
487
488         if(other.cvar_cl_playerdetailreduction <= 0)
489         {
490                 if(other.cvar_cl_playerdetailreduction <= -2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(other.cvar_cl_playerdetailreduction <= -1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497         else
498         {
499                 distance = vlen(self.origin - other.origin);
500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
501                 if(f > sv_loddistance2)
502                         self.modelindex = modelsource.modelindex_lod2;
503                 else if(f > sv_loddistance1)
504                         self.modelindex = modelsource.modelindex_lod1;
505                 else
506                         self.modelindex = modelsource.modelindex_lod0;
507         }
508
509 #ifdef PROFILING
510         float t1;
511         t1 = gettime(GETTIME_HIRES); // reference
512         client_cefc_accumulator += (t1 - t0);
513 #endif
514
515         return TRUE;
516 }
517
518 void setmodel_lod(entity e, string modelname)
519 {
520         string s;
521
522         if(sv_loddistance1)
523         {
524                 // FIXME: this only supports 3-letter extensions
525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
526                 if(fexists(s))
527                 {
528                         setmodel(e, s); // players have high precision
529                         self.modelindex_lod1 = self.modelindex;
530                 }
531                 else
532                         self.modelindex_lod1 = -1;
533
534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
535                 if(fexists(s))
536                 {
537                         setmodel(e, s); // players have high precision
538                         self.modelindex_lod2 = self.modelindex;
539                 }
540                 else
541                         self.modelindex_lod2 = -1;
542
543                 precache_model(modelname);
544                 setmodel(e, modelname); // players have high precision
545                 self.modelindex_lod0 = self.modelindex;
546
547                 if(self.modelindex_lod1 < 0)
548                         self.modelindex_lod1 = self.modelindex;
549
550                 if(self.modelindex_lod2 < 0)
551                         self.modelindex_lod2 = self.modelindex;
552         }
553         else
554         {
555                 precache_model(modelname);
556                 setmodel(e, modelname); // players have high precision
557                 self.modelindex_lod0 = self.modelindex;
558                         // save it for possible player model forcing
559         }
560
561         s = whichpack(self.model);
562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
563
564         player_setupanimsformodel();
565         UpdatePlayerSounds();
566 }
567
568 /*
569 =============
570 PutObserverInServer
571
572 putting a client as observer in the server
573 =============
574 */
575 void FixPlayermodel();
576 void PutObserverInServer (void)
577 {
578         entity  spot;
579
580         race_PreSpawnObserver();
581
582         spot = SelectSpawnPoint (TRUE);
583         if(!spot)
584                 error("No spawnpoints for observers?!?\n");
585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
586
587         if(clienttype(self) == CLIENTTYPE_REAL)
588         {
589                 msg_entity = self;
590                 WriteByte(MSG_ONE, SVC_SETVIEW);
591                 WriteEntity(MSG_ONE, self);
592         }
593
594         DropAllRunes(self);
595
596         Portal_ClearAll(self);
597
598         if(self.flagcarried)
599                 DropFlag(self.flagcarried, world, world);
600
601         if(self.ballcarried)
602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
603
604         WaypointSprite_PlayerDead();
605
606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
608
609         if(self.killcount != -666) {
610                 if(g_lms) {
611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
613                         else
614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
615                 } else
616                         bprint ("^4", self.netname, "^4 is spectating now\n");
617
618                 if(self.just_joined == FALSE) {
619                         LogTeamchange(self.playerid, -1, 4);
620                 } else
621                         self.just_joined = FALSE;
622         }
623
624         PlayerScore_Clear(self); // clear scores when needed
625
626         self.spectatortime = time;
627
628         self.classname = "observer";
629         self.iscreature = FALSE;
630         self.health = -666;
631         self.takedamage = DAMAGE_NO;
632         self.solid = SOLID_NOT;
633         self.movetype = MOVETYPE_NOCLIP;
634         self.flags = FL_CLIENT | FL_NOTARGET;
635         self.armorvalue = 666;
636         self.effects = 0;
637         self.armorvalue = cvar("g_balance_armor_start");
638         self.pauserotarmor_finished = 0;
639         self.pauserothealth_finished = 0;
640         self.pauseregen_finished = 0;
641         self.damageforcescale = 0;
642         self.death_time = 0;
643         self.dead_frame = 0;
644         self.alpha = 0;
645         self.scale = 0;
646         self.fade_time = 0;
647         self.pain_frame = 0;
648         self.pain_finished = 0;
649         self.strength_finished = 0;
650         self.invincible_finished = 0;
651         self.pushltime = 0;
652         self.think = SUB_Null;
653         self.nextthink = 0;
654         self.hook_time = 0;
655         self.runes = 0;
656         self.deadflag = DEAD_NO;
657         self.angles = spot.angles;
658         self.angles_z = 0;
659         self.fixangle = TRUE;
660         self.crouch = FALSE;
661
662         self.view_ofs = PL_VIEW_OFS;
663         setorigin (self, spot.origin);
664         setsize (self, '0 0 0', '0 0 0');
665         self.prevorigin = self.origin;
666         self.items = 0;
667         self.weapons = 0;
668         self.model = "";
669         FixPlayermodel();
670         self.model = "";
671         self.modelindex = 0;
672         self.weapon = 0;
673         self.weaponmodel = "";
674         self.weaponentity = world;
675         self.exteriorweaponentity = world;
676         self.killcount = -666;
677         self.velocity = '0 0 0';
678         self.avelocity = '0 0 0';
679         self.punchangle = '0 0 0';
680         self.punchvector = '0 0 0';
681         self.oldvelocity = self.velocity;
682         self.fire_endtime = -1;
683
684         if(sv_loddistance1)
685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
686
687         if(g_arena)
688         {
689                 if(self.version_mismatch)
690                 {
691                         Spawnqueue_Unmark(self);
692                         Spawnqueue_Remove(self);
693                 }
694                 else
695                 {
696                         Spawnqueue_Insert(self);
697                 }
698         }
699         else if(g_lms)
700         {
701                 // Only if the player cannot play at all
702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
703                         self.frags = FRAGS_SPECTATOR;
704                 else
705                         self.frags = FRAGS_LMS_LOSER;
706         }
707         else
708                 self.frags = FRAGS_SPECTATOR;
709
710         MUTATOR_CALLHOOK(MakePlayerObserver);
711 }
712
713 float RestrictSkin(float s)
714 {
715         if(!teams_matter)
716                 return s;
717         if(s == 6)
718                 return 6;
719         return mod(s, 3);
720 }
721
722 void FixPlayermodel()
723 {
724         local string defaultmodel;
725         local float defaultskin, chmdl, oldskin;
726         local vector m1, m2;
727
728         defaultmodel = "";
729
730         if(cvar("sv_defaultcharacter") == 1) {
731                 defaultskin = 0;
732
733                 if(teams_matter)
734                 {
735                         string s;
736                         s = Team_ColorNameLowerCase(self.team);
737                         if(s != "neutral")
738                         {
739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
741                         }
742                 }
743
744                 if(defaultmodel == "")
745                 {
746                         defaultmodel = cvar_string("sv_defaultplayermodel");
747                         defaultskin = cvar("sv_defaultplayerskin");
748                 }
749         }
750
751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
752         {
753                 if(self.model != "")
754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
755                 self.model = ""; // force the != checks to return true
756         }
757
758         if(defaultmodel != "")
759         {
760                 if (defaultmodel != self.model)
761                 {
762                         m1 = self.mins;
763                         m2 = self.maxs;
764                         setmodel_lod (self, defaultmodel);
765                         setsize (self, m1, m2);
766                         chmdl = TRUE;
767                 }
768
769                 oldskin = self.skinindex;
770                 self.skinindex = defaultskin;
771         } else {
772                 if (self.playermodel != self.model || self.playermodel == "")
773                 {
774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
775                         m1 = self.mins;
776                         m2 = self.maxs;
777                         setmodel_lod (self, self.playermodel);
778                         setsize (self, m1, m2);
779                         chmdl = TRUE;
780                 }
781
782                 oldskin = self.skinindex;
783                 self.skinindex = RestrictSkin(stof(self.playerskin));
784         }
785
786         if(chmdl || oldskin != self.skinindex)
787                 self.species = player_getspecies(); // model or skin has changed
788
789         if(!teams_matter)
790                 if(strlen(cvar_string("sv_defaultplayercolors")))
791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
792                                 setcolor(self, cvar("sv_defaultplayercolors"));
793 }
794
795 void PlayerTouchExplode(entity p1, entity p2)
796 {
797         vector org;
798         org = (p1.origin + p2.origin) * 0.5;
799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
800
801         te_explosion(org);
802
803         entity e;
804         e = spawn();
805         setorigin(e, org);
806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
807         remove(e);
808 }
809
810 /*
811 =============
812 PutClientInServer
813
814 Called when a client spawns in the server
815 =============
816 */
817 //void() ctf_playerchanged;
818 void PutClientInServer (void)
819 {
820         if(clienttype(self) == CLIENTTYPE_BOT)
821         {
822                 self.classname = "player";
823         }
824         else if(clienttype(self) == CLIENTTYPE_REAL)
825         {
826                 msg_entity = self;
827                 WriteByte(MSG_ONE, SVC_SETVIEW);
828                 WriteEntity(MSG_ONE, self);
829         }
830
831         // player is dead and becomes observer
832         // FIXME fix LMS scoring for new system
833         if(g_lms)
834         {
835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
836                         self.classname = "observer";
837         }
838
839         if(g_arena || (g_ca && !allowed_to_spawn))
840         if(!self.spawned)
841                 self.classname = "observer";
842
843         if(gameover)
844                 self.classname = "observer";
845
846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
847                 entity spot, oldself;
848                 float j;
849
850                 if(self.team < 0)
851                         JoinBestTeam(self, FALSE, TRUE);
852
853                 race_PreSpawn();
854
855                 spot = SelectSpawnPoint (FALSE);
856                 if(!spot)
857                 {
858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
859                         return; // spawn failed
860                 }
861
862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
863
864                 self.classname = "player";
865                 self.wasplayer = TRUE;
866                 self.iscreature = TRUE;
867                 self.movetype = MOVETYPE_WALK;
868                 self.solid = SOLID_SLIDEBOX;
869                 if(cvar("g_playerclip_collisions"))
870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
871                 else
872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
873                 self.frags = FRAGS_PLAYER;
874                 if(independent_players)
875                         MAKE_INDEPENDENT_PLAYER(self);
876                 self.flags = FL_CLIENT;
877                 self.takedamage = DAMAGE_AIM;
878                 if(g_minstagib)
879                         self.effects = EF_FULLBRIGHT;
880                 else
881                         self.effects = 0;
882                 self.air_finished = time + 12;
883                 self.dmg = 2;
884
885                 if(inWarmupStage)
886                 {
887                         self.ammo_shells = warmup_start_ammo_shells;
888                         self.ammo_nails = warmup_start_ammo_nails;
889                         self.ammo_rockets = warmup_start_ammo_rockets;
890                         self.ammo_cells = warmup_start_ammo_cells;
891                         self.ammo_fuel = warmup_start_ammo_fuel;
892                         self.health = warmup_start_health;
893                         self.armorvalue = warmup_start_armorvalue;
894                         self.weapons = warmup_start_weapons;
895                 }
896                 else
897                 {
898                         self.ammo_shells = start_ammo_shells;
899                         self.ammo_nails = start_ammo_nails;
900                         self.ammo_rockets = start_ammo_rockets;
901                         self.ammo_cells = start_ammo_cells;
902                         self.ammo_fuel = start_ammo_fuel;
903                         self.health = start_health;
904                         self.armorvalue = start_armorvalue;
905                         self.weapons = start_weapons;
906                 }
907
908                 if(g_weaponarena_random)
909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
910
911                 self.items = start_items;
912                 self.jump_interval = time;
913
914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
919                 //extend the pause of rotting if client was reset at the beginning of the countdown
920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
921                         self.spawnshieldtime += game_starttime - time;
922                         self.pauserotarmor_finished += game_starttime - time;
923                         self.pauserothealth_finished += game_starttime - time;
924                         self.pauseregen_finished += game_starttime - time;
925                 }
926                 self.damageforcescale = 2;
927                 self.death_time = 0;
928                 self.dead_frame = 0;
929                 self.alpha = 0;
930                 self.scale = 0;
931                 self.fade_time = 0;
932                 self.pain_frame = 0;
933                 self.pain_finished = 0;
934                 self.strength_finished = 0;
935                 self.invincible_finished = 0;
936                 self.pushltime = 0;
937                 // players have no think function
938                 self.think = SUB_Null;
939                 self.nextthink = 0;
940                 self.hook_time = 0;
941                 self.dmg_team = 0;
942                 self.ballistics_density = cvar("g_ballistics_density_player");
943
944                 self.metertime = 0;
945
946                 self.runes = 0;
947
948                 self.deadflag = DEAD_NO;
949
950                 self.angles = spot.angles;
951
952                 self.angles_z = 0; // never spawn tilted even if the spot says to
953                 self.fixangle = TRUE; // turn this way immediately
954                 self.velocity = '0 0 0';
955                 self.avelocity = '0 0 0';
956                 self.punchangle = '0 0 0';
957                 self.punchvector = '0 0 0';
958                 self.oldvelocity = self.velocity;
959                 self.fire_endtime = -1;
960
961                 msg_entity = self;
962                 WRITESPECTATABLE_MSG_ONE({
963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
965                 });
966
967                 if(sv_loddistance1)
968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
969
970                 self.model = "";
971                 FixPlayermodel();
972
973                 self.crouch = FALSE;
974                 self.view_ofs = PL_VIEW_OFS;
975                 setsize (self, PL_MIN, PL_MAX);
976                 self.spawnorigin = spot.origin;
977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
978                 // don't reset back to last position, even if new position is stuck in solid
979                 self.oldorigin = self.origin;
980                 self.prevorigin = self.origin;
981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
982
983                 if(g_arena)
984                 {
985                         Spawnqueue_Remove(self);
986                         Spawnqueue_Mark(self);
987                 }
988
989                 else if(g_ca)
990                         self.caplayer = 1;
991
992                 self.event_damage = PlayerDamage;
993
994                 self.bot_attack = TRUE;
995
996                 self.statdraintime = time + 5;
997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
998
999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1067         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1068         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1069         if(sv_foginterval && world.fog != "")
1070                 WriteString(MSG_ENTITY, world.fog);
1071         else
1072                 WriteString(MSG_ENTITY, "");
1073         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1074         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1075         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1076         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1077         return TRUE;
1078 }
1079
1080 void ClientInit_CheckUpdate()
1081 {
1082         self.nextthink = time;
1083         if(self.count != cvar("g_balance_armor_blockpercent"))
1084         {
1085                 self.count = cvar("g_balance_armor_blockpercent");
1086                 self.SendFlags |= 1;
1087         }
1088         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1089         {
1090                 self.cnt = cvar("g_balance_weaponswitchdelay");
1091                 self.SendFlags |= 1;
1092         }
1093         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1094         {
1095                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1096                 self.SendFlags |= 1;
1097         }
1098         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1099         {
1100                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1101                 self.SendFlags |= 1;
1102         }
1103 }
1104
1105 void ClientInit_Spawn()
1106 {
1107         entity o;
1108         entity e;
1109         e = spawn();
1110         e.classname = "clientinit";
1111         e.think = ClientInit_CheckUpdate;
1112         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1113
1114         o = self;
1115         self = e;
1116         ClientInit_CheckUpdate();
1117         self = o;
1118 }
1119
1120 /*
1121 =============
1122 SetNewParms
1123 =============
1124 */
1125 void SetNewParms (void)
1126 {
1127         // initialize parms for a new player
1128         parm1 = -(86400 * 366);
1129 }
1130
1131 /*
1132 =============
1133 SetChangeParms
1134 =============
1135 */
1136 void SetChangeParms (void)
1137 {
1138         // save parms for level change
1139         parm1 = self.parm_idlesince - time;
1140 }
1141
1142 /*
1143 =============
1144 DecodeLevelParms
1145 =============
1146 */
1147 void DecodeLevelParms (void)
1148 {
1149         // load parms
1150         self.parm_idlesince = parm1;
1151         if(self.parm_idlesince == -(86400 * 366))
1152                 self.parm_idlesince = time;
1153
1154         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1155         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1156 }
1157
1158 /*
1159 =============
1160 ClientKill
1161
1162 Called when a client types 'kill' in the console
1163 =============
1164 */
1165
1166 void ClientKill_Now_TeamChange()
1167 {
1168         if(self.killindicator_teamchange == -1)
1169         {
1170                 self.team = -1;
1171                 JoinBestTeam( self, FALSE, FALSE );
1172         }
1173         else
1174                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1175 }
1176
1177 void ClientKill_Now()
1178 {
1179         if(self.killindicator_teamchange)
1180                 ClientKill_Now_TeamChange();
1181
1182         // in any case:
1183         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1184
1185         if(self.killindicator)
1186         {
1187                 dprint("Cleaned up after a leaked kill indicator.\n");
1188                 remove(self.killindicator);
1189                 self.killindicator = world;
1190         }
1191 }
1192 void KillIndicator_Think()
1193 {
1194         if (!self.owner.modelindex)
1195         {
1196                 self.owner.killindicator = world;
1197                 remove(self);
1198                 return;
1199         }
1200
1201         if(self.cnt <= 0)
1202         {
1203                 self = self.owner;
1204                 ClientKill_Now(); // no oldself needed
1205                 return;
1206         }
1207         else
1208         {
1209                 if(self.cnt <= 10)
1210                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1211                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1212                 {
1213                         if(self.cnt <= 10)
1214                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1215                         if(self.owner.killindicator_teamchange)
1216                         {
1217                                 if(self.owner.killindicator_teamchange == -1)
1218                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1219                                 else
1220                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1221                         }
1222                         else
1223                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1224                 }
1225                 self.nextthink = time + 1;
1226                 self.cnt -= 1;
1227         }
1228 }
1229
1230 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1231 {
1232         float killtime;
1233         entity e;
1234         killtime = cvar("g_balance_kill_delay");
1235
1236         if(g_race_qualifying)
1237                 killtime = 0;
1238
1239         self.killindicator_teamchange = targetteam;
1240
1241         if(!self.killindicator)
1242         {
1243                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1244                 {
1245                         ClientKill_Now();
1246                 }
1247                 else
1248                 {
1249                         self.killindicator = spawn();
1250                         self.killindicator.owner = self;
1251                         self.killindicator.scale = 0.5;
1252                         setattachment(self.killindicator, self, "");
1253                         setorigin(self.killindicator, '0 0 52');
1254                         self.killindicator.think = KillIndicator_Think;
1255                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1256                         self.killindicator.cnt = ceil(killtime);
1257                         self.killindicator.count = bound(0, ceil(killtime), 10);
1258                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1259
1260                         for(e = world; (e = find(e, classname, "body")) != world; )
1261                         {
1262                                 if(e.enemy != self)
1263                                         continue;
1264                                 e.killindicator = spawn();
1265                                 e.killindicator.owner = e;
1266                                 e.killindicator.scale = 0.5;
1267                                 setattachment(e.killindicator, e, "");
1268                                 setorigin(e.killindicator, '0 0 52');
1269                                 e.killindicator.think = KillIndicator_Think;
1270                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1271                                 e.killindicator.cnt = ceil(killtime);
1272                         }
1273                         self.lip = 0;
1274                 }
1275         }
1276         if(self.killindicator)
1277         {
1278                 if(targetteam)
1279                         self.killindicator.colormod = TeamColor(targetteam);
1280                 else
1281                         self.killindicator.colormod = '0 0 0';
1282         }
1283 }
1284
1285 void ClientKill (void)
1286 {
1287         ClientKill_TeamChange(0);
1288 }
1289
1290 void DoTeamChange(float destteam)
1291 {
1292         float t, c0;
1293         if(!teams_matter)
1294         {
1295                 if(destteam >= 0)
1296                         SetPlayerColors(self, destteam);
1297                 return;
1298         }
1299         if(self.classname == "player")
1300         if(destteam == -1)
1301         {
1302                 CheckAllowedTeams(self);
1303                 t = FindSmallestTeam(self, TRUE);
1304                 switch(self.team)
1305                 {
1306                         case COLOR_TEAM1: c0 = c1; break;
1307                         case COLOR_TEAM2: c0 = c2; break;
1308                         case COLOR_TEAM3: c0 = c3; break;
1309                         case COLOR_TEAM4: c0 = c4; break;
1310                         default:          c0 = 999;
1311                 }
1312                 switch(t)
1313                 {
1314                         case 1:
1315                                 if(c0 > c1)
1316                                         destteam = COLOR_TEAM1;
1317                                 break;
1318                         case 2:
1319                                 if(c0 > c2)
1320                                         destteam = COLOR_TEAM2;
1321                                 break;
1322                         case 3:
1323                                 if(c0 > c3)
1324                                         destteam = COLOR_TEAM3;
1325                                 break;
1326                         case 4:
1327                                 if(c0 > c4)
1328                                         destteam = COLOR_TEAM4;
1329                                 break;
1330                 }
1331                 if(destteam == -1)
1332                         return;
1333         }
1334         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1335                 return;
1336         ClientKill_TeamChange(destteam);
1337 }
1338
1339 void FixClientCvars(entity e)
1340 {
1341         // send prediction settings to the client
1342         stuffcmd(e, "\nin_bindmap 0 0\n");
1343         if(g_race || g_cts)
1344                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1345         if(cvar("g_antilag") == 3) // client side hitscan
1346                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1347                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1348         /*
1349          * we no longer need to stuff this. Remove this comment block if you feel
1350          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1351         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1352         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1353         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1354         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1355         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1356         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1357         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1358         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1359         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1360         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1361         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1362         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1363         stuffcmd(e, "cl_movement_edgefriction 1\n");
1364          */
1365 }
1366
1367 /*
1368 =============
1369 ClientConnect
1370
1371 Called when a client connects to the server
1372 =============
1373 */
1374 //void ctf_clientconnect();
1375 string ColoredTeamName(float t);
1376 void DecodeLevelParms (void);
1377 //void dom_player_join_team(entity pl);
1378 #ifdef UID
1379 .float uid_kicktime;
1380 .string uid;
1381 #endif
1382 void ClientConnect (void)
1383 {
1384         float t;
1385
1386         if(self.flags & FL_CLIENT)
1387         {
1388                 print("Warning: ClientConnect, but already connected!\n");
1389                 return;
1390         }
1391
1392         if(Ban_MaybeEnforceBan(self))
1393                 return;
1394
1395         DecodeLevelParms();
1396
1397 #ifdef WATERMARK
1398         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1399 #endif
1400
1401         self.classname = "player_joining";
1402
1403         self.flags = FL_CLIENT;
1404         self.version_nagtime = time + 10 + random() * 10;
1405
1406         if(player_count<0)
1407         {
1408                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1409                 player_count = 0;
1410         }
1411
1412         PlayerScore_Attach(self);
1413         ClientData_Attach();
1414
1415         bot_clientconnect();
1416
1417         playerdemo_init();
1418
1419         anticheat_init();
1420         
1421         race_PreSpawnObserver();
1422
1423         //if(g_domination)
1424         //      dom_player_join_team(self);
1425
1426         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1427
1428         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1429                 self.classname = "observer";
1430         } else {
1431                 if(teams_matter)
1432                 {
1433                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1434                         {
1435                                 self.classname = "player";
1436                                 campaign_bots_may_start = 1;
1437                         }
1438                         else
1439                         {
1440                                 self.classname = "observer"; // do it anyway
1441                         }
1442                 }
1443                 else
1444                 {
1445                         self.classname = "player";
1446                         campaign_bots_may_start = 1;
1447                 }
1448         }
1449
1450         self.playerid = (playerid_last = playerid_last + 1);
1451
1452         if(cvar("sv_eventlog"))
1453                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1454
1455         LogTeamchange(self.playerid, self.team, 1);
1456
1457         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1458
1459         self.netname_previous = strzone(self.netname);
1460
1461         bprint("^4", self.netname, "^4 connected");
1462
1463         if(self.classname != "observer" && (g_domination || g_ctf))
1464                 bprint(" and joined the ", ColoredTeamName(self.team));
1465
1466         bprint("\n");
1467
1468         self.welcomemessage_time = 0;
1469
1470         stuffcmd(self, strcat(clientstuff, "\n"));
1471         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1472         stuffcmd(self, "cl_particles_reloadeffects\n");
1473
1474         FixClientCvars(self);
1475
1476         // spawnfunc_waypoint sprites
1477         WaypointSprite_InitClient(self);
1478
1479         // Wazat's grappling hook
1480         SetGrappleHookBindings();
1481
1482         // get autoswitch state from player when he toggles it
1483         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1484
1485         // get version info from player
1486         stuffcmd(self, "cmd clientversion $gameversion\n");
1487
1488         // get other cvars from player
1489         GetCvars(0);
1490
1491         // set cvar for team scoreboard
1492         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1493
1494         // notify about available teams
1495         if(teams_matter)
1496         {
1497                 CheckAllowedTeams(self);
1498                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1499                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1500         }
1501         else
1502                 stuffcmd(self, "set _teams_available 0\n");
1503
1504         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1505
1506         if(g_arena || g_ca)
1507         {
1508                 self.classname = "observer";
1509                 if(g_arena)
1510                         Spawnqueue_Insert(self);
1511         }
1512         /*else if(g_ctf)
1513         {
1514                 ctf_clientconnect();
1515         }*/
1516
1517         if(teams_matter || radar_showennemies)
1518                 attach_entcs();
1519
1520         bot_relinkplayerlist();
1521
1522         self.spectatortime = time;
1523         if(blockSpectators)
1524         {
1525                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1526         }
1527
1528         self.jointime = time;
1529         self.allowedTimeouts = cvar("sv_timeout_number");
1530
1531         if(clienttype(self) == CLIENTTYPE_REAL)
1532         {
1533                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1534                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1535         }
1536
1537         if(g_lms)
1538         {
1539                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1540                 {
1541                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1542                         self.frags = FRAGS_SPECTATOR;
1543                 }
1544         }
1545
1546         if(!sv_foginterval && world.fog != "")
1547                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1548
1549         SoundEntity_Attach(self);
1550
1551         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1552         {
1553                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1554                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1555         }
1556         else
1557                 self.hitplotfh = -1;
1558
1559 #ifdef UID
1560         if(clienttype(self) == CLIENTTYPE_REAL)
1561         if not(self.uid)
1562                 self.uid_kicktime = time + 60;
1563 #endif
1564
1565         if(g_race || g_cts) {
1566                 string rr;
1567                 if(g_cts)
1568                         rr = CTS_RECORD;
1569                 else
1570                         rr = RACE_RECORD;
1571                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1572
1573                 race_send_recordtime(MSG_ONE);
1574                 race_send_speedaward(MSG_ONE);
1575
1576                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1577                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1578                 race_send_speedaward_alltimebest(MSG_ONE);
1579
1580                 float i;
1581                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1582                         race_SendRankings(i, 0, 0, MSG_ONE);
1583                 }
1584         }
1585         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1586                 send_CSQC_teamnagger();
1587
1588         CheatInitClient();
1589 }
1590
1591 /*
1592 =============
1593 ClientDisconnect
1594
1595 Called when a client disconnects from the server
1596 =============
1597 */
1598 .entity chatbubbleentity;
1599 .entity teambubbleentity;
1600 void ReadyCount();
1601 void ClientDisconnect (void)
1602 {
1603         if not(self.flags & FL_CLIENT)
1604         {
1605                 print("Warning: ClientDisconnect without ClientConnect\n");
1606                 return;
1607         }
1608
1609         CheatShutdownClient();
1610
1611         if(self.hitplotfh >= 0)
1612         {
1613                 fclose(self.hitplotfh);
1614                 self.hitplotfh = -1;
1615         }
1616
1617         anticheat_report();
1618         anticheat_shutdown();
1619
1620         playerdemo_shutdown();
1621
1622         bot_clientdisconnect();
1623
1624         if(self.entcs)
1625                 detach_entcs();
1626
1627         if(cvar("sv_eventlog"))
1628                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1629         bprint ("^4",self.netname);
1630         bprint ("^4 disconnected\n");
1631
1632         SoundEntity_Detach(self);
1633
1634         DropAllRunes(self);
1635         MUTATOR_CALLHOOK(ClientDisconnect);
1636
1637         Portal_ClearAll(self);
1638
1639         if(self.flagcarried)
1640                 DropFlag(self.flagcarried, world, world);
1641         if(self.ballcarried)
1642                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1643
1644         // Here, everything has been done that requires this player to be a client.
1645
1646         self.flags &~= FL_CLIENT;
1647
1648         if (self.chatbubbleentity)
1649                 remove (self.chatbubbleentity);
1650
1651         if (self.teambubbleentity)
1652                 remove (self.teambubbleentity);
1653
1654         if (self.killindicator)
1655                 remove (self.killindicator);
1656
1657         WaypointSprite_PlayerGone();
1658
1659         bot_relinkplayerlist();
1660
1661         // remove laserdot
1662         if(self.weaponentity)
1663                 if(self.weaponentity.lasertarget)
1664                         remove(self.weaponentity.lasertarget);
1665
1666         if(g_arena)
1667         {
1668                 Spawnqueue_Unmark(self);
1669                 Spawnqueue_Remove(self);
1670         }
1671
1672         ClientData_Detach();
1673         PlayerScore_Detach(self);
1674
1675         if(self.netname_previous)
1676                 strunzone(self.netname_previous);
1677         if(self.clientstatus)
1678                 strunzone(self.clientstatus);
1679
1680         ClearPlayerSounds();
1681
1682         if(self.personal)
1683                 remove(self.personal);
1684
1685         self.playerid = 0;
1686         ReadyCount();
1687
1688         // free cvars
1689         GetCvars(-1);
1690 }
1691
1692 .float BUTTON_CHAT;
1693 void ChatBubbleThink()
1694 {
1695         self.nextthink = time;
1696         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1697         {
1698                 if(self.owner) // but why can that ever be world?
1699                         self.owner.chatbubbleentity = world;
1700                 remove(self);
1701                 return;
1702         }
1703         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1704 #ifdef TETRIS
1705                 || self.owner.tetris_on
1706 #endif
1707         )
1708                 self.model = self.mdl;
1709         else
1710                 self.model = "";
1711 };
1712
1713 void UpdateChatBubble()
1714 {
1715         if (!self.modelindex)
1716                 return;
1717         // spawn a chatbubble entity if needed
1718         if (!self.chatbubbleentity)
1719         {
1720                 self.chatbubbleentity = spawn();
1721                 self.chatbubbleentity.owner = self;
1722                 self.chatbubbleentity.exteriormodeltoclient = self;
1723                 self.chatbubbleentity.think = ChatBubbleThink;
1724                 self.chatbubbleentity.nextthink = time;
1725                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1726                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1727                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1728                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1729                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1730                 self.chatbubbleentity.model = "";
1731                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1732         }
1733 }
1734
1735
1736 void TeamBubbleThink()
1737 {
1738         self.nextthink = time;
1739         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1740         {
1741                 if(self.owner) // but why can that ever be world?
1742                         self.owner.teambubbleentity = world;
1743                 remove(self);
1744                 return;
1745         }
1746 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1747         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1748                 self.model = "";
1749         else
1750                 self.model = self.mdl;
1751
1752 };
1753
1754 float TeamBubble_customizeentityforclient()
1755 {
1756         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1757 }
1758
1759 void UpdateTeamBubble()
1760 {
1761         if (!self.modelindex || !teams_matter)
1762                 return;
1763         // spawn a teambubble entity if needed
1764         if (!self.teambubbleentity && teams_matter)
1765         {
1766                 self.teambubbleentity = spawn();
1767                 self.teambubbleentity.owner = self;
1768                 self.teambubbleentity.exteriormodeltoclient = self;
1769                 self.teambubbleentity.think = TeamBubbleThink;
1770                 self.teambubbleentity.nextthink = time;
1771                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1772 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1773                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1774                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1775                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1776                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1777                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1778                 self.teambubbleentity.effects = EF_LOWPRECISION;
1779         }
1780 }
1781
1782 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1783 // added to the model skins
1784 /*void UpdateColorModHack()
1785 {
1786         local float c;
1787         c = self.clientcolors & 15;
1788         // LordHavoc: only bothering to support white, green, red, yellow, blue
1789              if (!teams_matter) self.colormod = '0 0 0';
1790         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1791         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1792         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1793         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1794         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1795         else self.colormod = '1 1 1';
1796 };*/
1797
1798 .float oldcolormap;
1799 void respawn(void)
1800 {
1801         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1802         {
1803                 self.solid = SOLID_NOT;
1804                 self.takedamage = DAMAGE_NO;
1805                 self.movetype = MOVETYPE_FLY;
1806                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1807                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1808                 self.effects |= EF_ADDITIVE;
1809                 self.oldcolormap = self.colormap;
1810                 self.colormap = 512;
1811                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1812                 if(cvar("g_respawn_ghosts_maxtime"))
1813                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1814         }
1815
1816         CopyBody(1);
1817         self.effects |= EF_NODRAW; // prevent another CopyBody
1818         if(self.oldcolormap)
1819         {
1820                 self.colormap = self.oldcolormap;
1821                 self.oldcolormap = 0;
1822         }
1823         PutClientInServer();
1824 }
1825
1826 void play_countdown(float finished, string samp)
1827 {
1828         if(clienttype(self) == CLIENTTYPE_REAL)
1829                 if(floor(finished - time - frametime) != floor(finished - time))
1830                         if(finished - time < 6)
1831                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1832 }
1833
1834 /**
1835  * When sv_timeout is used this function returs strings like
1836  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1837  * Called by centerprint functions
1838  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1839  */
1840 string getTimeoutText(float addOneSecond) {
1841         if (!cvar("sv_timeout") || !timeoutStatus)
1842                 return "";
1843
1844         local string retStr;
1845         if (timeoutStatus == 1) {
1846                 if (addOneSecond == 1) {
1847                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1848                 }
1849                 else {
1850                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1851                 }
1852                 return retStr;
1853         }
1854         else if (timeoutStatus == 2) {
1855                 if (addOneSecond) {
1856                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1857                         //don't show messages like "Timeout ends in 0 seconds"...
1858                         if ((remainingTimeoutTime + 1) > 0)
1859                                 return retStr;
1860                         else
1861                                 return "";
1862                 }
1863                 else {
1864                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1865                         //don't show messages like "Timeout ends in 0 seconds"...
1866                         if (remainingTimeoutTime > 0)
1867                                 return retStr;
1868                         else
1869                                 return "";
1870                 }
1871         }
1872         else return "";
1873 }
1874
1875 void player_powerups (void)
1876 {
1877         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1878         {
1879                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1880                 self.modelflags |= MF_ROCKET;
1881         }
1882         else
1883         {
1884                 SoundEntity_StopSound(self, CHAN_PLAYER);
1885                 self.modelflags &~= MF_ROCKET;
1886         }
1887
1888         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1889
1890         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1891                 return;
1892         
1893         Fire_ApplyDamage(self);
1894         Fire_ApplyEffect(self);
1895
1896         if (g_minstagib)
1897         {
1898                 self.effects |= EF_FULLBRIGHT;
1899
1900                 if (self.items & IT_STRENGTH)
1901                 {
1902                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1903                         if (time > self.strength_finished)
1904                         {
1905                                 self.alpha = default_player_alpha;
1906                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1907                                 self.items &~= IT_STRENGTH;
1908                                 sprint(self, "^3Invisibility has worn off\n");
1909                         }
1910                 }
1911                 else
1912                 {
1913                         if (time < self.strength_finished)
1914                         {
1915                                 self.alpha = g_minstagib_invis_alpha;
1916                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1917                                 self.items |= IT_STRENGTH;
1918                                 sprint(self, "^3You are invisible\n");
1919                         }
1920                 }
1921
1922                 if (self.items & IT_INVINCIBLE)
1923                 {
1924                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1925                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1926                         {
1927                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1928                                 sprint(self, "^3Speed has worn off\n");
1929                         }
1930                 }
1931                 else
1932                 {
1933                         if (time < self.invincible_finished)
1934                         {
1935                                 self.items = self.items | IT_INVINCIBLE;
1936                                 sprint(self, "^3You are on speed\n");
1937                         }
1938                 }
1939                 return;
1940         }
1941
1942         if (self.items & IT_STRENGTH)
1943         {
1944                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1945                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1946                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1947                 {
1948                         self.items = self.items - (self.items & IT_STRENGTH);
1949                         sprint(self, "^3Strength has worn off\n");
1950                 }
1951         }
1952         else
1953         {
1954                 if (time < self.strength_finished)
1955                 {
1956                         self.items = self.items | IT_STRENGTH;
1957                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1958                 }
1959         }
1960         if (self.items & IT_INVINCIBLE)
1961         {
1962                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1963                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1964                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1965                 {
1966                         self.items = self.items - (self.items & IT_INVINCIBLE);
1967                         sprint(self, "^3Shield has worn off\n");
1968                 }
1969         }
1970         else
1971         {
1972                 if (time < self.invincible_finished)
1973                 {
1974                         self.items = self.items | IT_INVINCIBLE;
1975                         sprint(self, "^3Shield surrounds you\n");
1976                 }
1977         }
1978
1979         if(cvar("g_nodepthtestplayers"))
1980                 self.effects = self.effects | EF_NODEPTHTEST;
1981
1982         if(cvar("g_fullbrightplayers"))
1983                 self.effects = self.effects | EF_FULLBRIGHT;
1984
1985         // midair gamemode: damage only while in the air
1986         // if in midair mode, being on ground grants temporary invulnerability
1987         // (this is so that multishot weapon don't clear the ground flag on the
1988         // first damage in the frame, leaving the player vulnerable to the
1989         // remaining hits in the same frame)
1990         if (self.flags & FL_ONGROUND)
1991         if (g_midair)
1992                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1993
1994         if (time >= game_starttime)
1995         if (time < self.spawnshieldtime)
1996                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1997 }
1998
1999 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2000 {
2001         if(current > stable)
2002                 return current;
2003         else if(current > stable - 0.25) // when close enough, "snap"
2004                 return stable;
2005         else
2006                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2007 }
2008
2009 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2010 {
2011         if(current < stable)
2012                 return current;
2013         else if(current < stable + 0.25) // when close enough, "snap"
2014                 return stable;
2015         else
2016                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2017 }
2018
2019 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2020 {
2021         if(current > rotstable)
2022         {
2023                 if(rotframetime > 0)
2024                 {
2025                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2026                         current = max(rotstable, current - rotlinear * rotframetime);
2027                 }
2028         }
2029         else if(current < regenstable)
2030         {
2031                 if(regenframetime > 0)
2032                 {
2033                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2034                         current = min(regenstable, current + regenlinear * regenframetime);
2035                 }
2036         }
2037
2038         if(current > limit)
2039                 current = limit;
2040
2041         return current;
2042 }
2043
2044 void player_regen (void)
2045 {
2046         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2047         maxh = cvar("g_balance_health_rotstable");
2048         maxa = cvar("g_balance_armor_rotstable");
2049         maxf = cvar("g_balance_fuel_rotstable");
2050         minh = cvar("g_balance_health_regenstable");
2051         mina = cvar("g_balance_armor_regenstable");
2052         minf = cvar("g_balance_fuel_regenstable");
2053         limith = cvar("g_balance_health_limit");
2054         limita = cvar("g_balance_armor_limit");
2055         limitf = cvar("g_balance_fuel_limit");
2056
2057         max_mod = regen_mod = rot_mod = limit_mod = 1;
2058
2059         if (self.runes & RUNE_REGEN)
2060         {
2061                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2062                 {
2063                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2064                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2065                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2066                 }
2067                 else
2068                 {
2069                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2070                         max_mod = cvar("g_balance_rune_regen_hpmod");
2071                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2072                 }
2073         }
2074         else if (self.runes & CURSE_VENOM)
2075         {
2076                 max_mod = cvar("g_balance_curse_venom_hpmod");
2077                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2078                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2079                 else
2080                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2081                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2082                 //if (!self.runes & RUNE_REGEN)
2083                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2084         }
2085         maxh = maxh * max_mod;
2086         //maxa = maxa * max_mod;
2087         //maxf = maxf * max_mod;
2088         minh = minh * max_mod;
2089         //mina = mina * max_mod;
2090         //minf = minf * max_mod;
2091         limith = limith * limit_mod;
2092         limita = limita * limit_mod;
2093         //limitf = limitf * limit_mod;
2094
2095         if(g_lms && g_ca)
2096                 rot_mod = 0;
2097
2098         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2099         {
2100                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2101                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2102
2103                 // if player rotted to death...  die!
2104                 if(self.health < 1)
2105                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2106         }
2107
2108         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2109                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2110 }
2111
2112 float zoomstate_set;
2113 void SetZoomState(float z)
2114 {
2115         if(z != self.zoomstate)
2116         {
2117                 self.zoomstate = z;
2118                 ClientData_Touch(self);
2119         }
2120         zoomstate_set = 1;
2121 }
2122
2123 void GetPressedKeys(void) {
2124         MUTATOR_CALLHOOK(GetPressedKeys);
2125         if (self.movement_x > 0) // get if movement keys are pressed
2126         {       // forward key pressed
2127                 self.pressedkeys |= KEY_FORWARD;
2128                 self.pressedkeys &~= KEY_BACKWARD;
2129         }
2130         else if (self.movement_x < 0)
2131         {       // backward key pressed
2132                 self.pressedkeys |= KEY_BACKWARD;
2133                 self.pressedkeys &~= KEY_FORWARD;
2134         }
2135         else
2136         {       // no x input
2137                 self.pressedkeys &~= KEY_FORWARD;
2138                 self.pressedkeys &~= KEY_BACKWARD;
2139         }
2140
2141         if (self.movement_y > 0)
2142         {       // right key pressed
2143                 self.pressedkeys |= KEY_RIGHT;
2144                 self.pressedkeys &~= KEY_LEFT;
2145         }
2146         else if (self.movement_y < 0)
2147         {       // left key pressed
2148                 self.pressedkeys |= KEY_LEFT;
2149                 self.pressedkeys &~= KEY_RIGHT;
2150         }
2151         else
2152         {       // no y input
2153                 self.pressedkeys &~= KEY_RIGHT;
2154                 self.pressedkeys &~= KEY_LEFT;
2155         }
2156
2157         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2158                 self.pressedkeys |= KEY_JUMP;
2159         else
2160                 self.pressedkeys &~= KEY_JUMP;
2161         if (self.BUTTON_CROUCH)
2162                 self.pressedkeys |= KEY_CROUCH;
2163         else
2164                 self.pressedkeys &~= KEY_CROUCH;
2165 }
2166
2167 void update_stats (float number, float hit, float fired) {
2168 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2169 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2170
2171         if(number) {
2172                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2173                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2174         } else {
2175                 self.stat_hit = hit * sv_accuracy_data_share;
2176                 self.stat_fired = fired * sv_accuracy_data_share;
2177         }
2178 }
2179
2180 /*
2181 ======================
2182 spectate mode routines
2183 ======================
2184 */
2185
2186 .float weapon_count;
2187 void SpectateCopy(entity spectatee) {
2188         if(spectatee.weapon_count < WEP_LAST) {
2189                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2190                 spectatee.weapon_count ++;
2191         } else
2192                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2193
2194         other = spectatee;
2195         MUTATOR_CALLHOOK(SpectateCopy);
2196         self.armortype = spectatee.armortype;
2197         self.armorvalue = spectatee.armorvalue;
2198         self.ammo_cells = spectatee.ammo_cells;
2199         self.ammo_shells = spectatee.ammo_shells;
2200         self.ammo_nails = spectatee.ammo_nails;
2201         self.ammo_rockets = spectatee.ammo_rockets;
2202         self.ammo_fuel = spectatee.ammo_fuel;
2203         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2204         self.health = spectatee.health;
2205         self.impulse = 0;
2206         self.items = spectatee.items;
2207         self.metertime = spectatee.metertime;
2208         self.strength_finished = spectatee.strength_finished;
2209         self.invincible_finished = spectatee.invincible_finished;
2210         self.pressedkeys = spectatee.pressedkeys;
2211         self.weapons = spectatee.weapons;
2212         self.switchweapon = spectatee.switchweapon;
2213         self.weapon = spectatee.weapon;
2214         self.punchangle = spectatee.punchangle;
2215         self.view_ofs = spectatee.view_ofs;
2216         self.v_angle = spectatee.v_angle;
2217         self.velocity = spectatee.velocity;
2218         self.dmg_take = spectatee.dmg_take;
2219         self.dmg_save = spectatee.dmg_save;
2220         self.dmg_inflictor = spectatee.dmg_inflictor;
2221         self.angles = spectatee.v_angle;
2222         self.fixangle = TRUE;
2223         setorigin(self, spectatee.origin);
2224         setsize(self, spectatee.mins, spectatee.maxs);
2225         SetZoomState(spectatee.zoomstate);
2226
2227         anticheat_spectatecopy(spectatee);
2228 }
2229
2230 float SpectateUpdate() {
2231         if(!self.enemy)
2232                 return 0;
2233
2234         if (self == self.enemy)
2235                 return 0;
2236
2237         if(self.enemy.classname != "player")
2238                 return 0;
2239
2240         SpectateCopy(self.enemy);
2241
2242         return 1;
2243 }
2244
2245 float SpectateNext() {
2246         other = find(self.enemy, classname, "player");
2247
2248         if (!other)
2249                 other = find(other, classname, "player");
2250
2251         if (other)
2252                 self.enemy = other;
2253
2254         if(self.enemy.classname == "player") {
2255                 msg_entity = self;
2256                 WriteByte(MSG_ONE, SVC_SETVIEW);
2257                 WriteEntity(MSG_ONE, self.enemy);
2258                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2259                 self.movetype = MOVETYPE_NONE;
2260
2261                 self.enemy.weapon_count = 0;
2262
2263                 if(!SpectateUpdate())
2264                         PutObserverInServer();
2265
2266                 return 1;
2267         } else {
2268                 return 0;
2269         }
2270 }
2271
2272 /*
2273 =============
2274 ShowRespawnCountdown()
2275
2276 Update a respawn countdown display.
2277 =============
2278 */
2279 void ShowRespawnCountdown()
2280 {
2281         float number;
2282         if(self.deadflag == DEAD_NO) // just respawned?
2283                 return;
2284         else
2285         {
2286                 number = ceil(self.death_time - time);
2287                 if(number <= 0)
2288                         return;
2289                 if(number <= self.respawn_countdown)
2290                 {
2291                         self.respawn_countdown = number - 1;
2292                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2293                                 AnnounceTo(self, strcat(ftos(number), ""));
2294                 }
2295         }
2296 }
2297
2298 void LeaveSpectatorMode()
2299 {
2300         if(isJoinAllowed()) {
2301                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2302                         self.classname = "player";
2303
2304                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2305                                 JoinBestTeam(self, FALSE, TRUE);
2306
2307                         if(cvar("g_campaign"))
2308                                 campaign_bots_may_start = 1;
2309
2310                         self.stat_count = WEP_LAST;
2311
2312                         PutClientInServer();
2313
2314                         if(self.classname == "player")
2315                                 bprint ("^4", self.netname, "^4 is playing now\n");
2316
2317                         if(!cvar("g_campaign"))
2318                                 centerprint(self,""); // clear MOTD
2319
2320                         return;
2321                 } else {
2322                         if (g_ca && self.caplayer) {
2323                         }       // do nothing
2324                         else
2325                                 stuffcmd(self,"menu_showteamselect\n");
2326                         return;
2327                 }
2328         }
2329         else {
2330                 //player may not join because of g_maxplayers is set
2331                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2332         }
2333 }
2334
2335 /**
2336  * Determines whether the player is allowed to join. This depends on cvar
2337  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2338  * it checks whether the number of currently playing players exceeds g_maxplayers.
2339  * @return bool TRUE if the player is allowed to join, false otherwise
2340  */
2341 float isJoinAllowed() {
2342         if (!cvar("g_maxplayers"))
2343                 return TRUE;
2344
2345         local entity e;
2346         local float currentlyPlaying;
2347         FOR_EACH_REALPLAYER(e) {
2348                 if(e.classname == "player")
2349                         currentlyPlaying += 1;
2350         }
2351         if(currentlyPlaying < cvar("g_maxplayers"))
2352                 return TRUE;
2353
2354         return FALSE;
2355 }
2356
2357 /**
2358  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2359  * g_maxplayers_spectator_blocktime seconds
2360  */
2361 void checkSpectatorBlock() {
2362         if(self.classname == "spectator" || self.classname == "observer") {
2363                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2364                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2365                         dropclient(self);
2366                 }
2367         }
2368 }
2369
2370 float vercmp_recursive(string v1, string v2)
2371 {
2372         float dot1, dot2;
2373         string s1, s2;
2374         float r;
2375
2376         dot1 = strstrofs(v1, ".", 0);
2377         dot2 = strstrofs(v2, ".", 0);
2378         if(dot1 == -1)
2379                 s1 = v1;
2380         else
2381                 s1 = substring(v1, 0, dot1);
2382         if(dot2 == -1)
2383                 s2 = v2;
2384         else
2385                 s2 = substring(v2, 0, dot2);
2386
2387         r = stof(s1) - stof(s2);
2388         if(r != 0)
2389                 return r;
2390
2391         r = strcasecmp(s1, s2);
2392         if(r != 0)
2393                 return r;
2394
2395         if(dot1 == -1)
2396                 if(dot2 == -1)
2397                         return 0;
2398                 else
2399                         return -1;
2400         else
2401                 if(dot2 == -1)
2402                         return 1;
2403                 else
2404                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2405 }
2406
2407 float vercmp(string v1, string v2)
2408 {
2409         if(strcasecmp(v1, v2) == 0) // early out check
2410                 return 0;
2411         return vercmp_recursive(v1, v2);
2412 }
2413
2414 void ObserverThink()
2415 {
2416         if (self.flags & FL_JUMPRELEASED) {
2417                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2418                         self.welcomemessage_time = 0;
2419                         self.flags &~= FL_JUMPRELEASED;
2420                         self.flags |= FL_SPAWNING;
2421                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2422                         self.welcomemessage_time = 0;
2423                         self.flags &~= FL_JUMPRELEASED;
2424                         if(SpectateNext() == 1) {
2425                                 self.classname = "spectator";
2426                         }
2427                 }
2428         } else {
2429                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2430                         self.flags |= FL_JUMPRELEASED;
2431                         if(self.flags & FL_SPAWNING)
2432                         {
2433                                 self.flags &~= FL_SPAWNING;
2434                                 LeaveSpectatorMode();
2435                                 return;
2436                         }
2437                 }
2438         }
2439         PrintWelcomeMessage(self);
2440 }
2441
2442 void SpectatorThink()
2443 {
2444         if (self.flags & FL_JUMPRELEASED) {
2445                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2446                         self.welcomemessage_time = 0;
2447                         self.flags &~= FL_JUMPRELEASED;
2448                         self.flags |= FL_SPAWNING;
2449                 } else if(self.BUTTON_ATCK) {
2450                         self.welcomemessage_time = 0;
2451                         self.flags &~= FL_JUMPRELEASED;
2452                         if(SpectateNext() == 1) {
2453                                 self.classname = "spectator";
2454                         } else {
2455                                 self.classname = "observer";
2456                                 self.stat_count = WEP_LAST;
2457                                 PutClientInServer();
2458                         }
2459                 } else if (self.BUTTON_ATCK2) {
2460                         self.welcomemessage_time = 0;
2461                         self.flags &~= FL_JUMPRELEASED;
2462                         self.classname = "observer";
2463                         self.stat_count = WEP_LAST;
2464                         PutClientInServer();
2465                 } else {
2466                         if(!SpectateUpdate())
2467                                 PutObserverInServer();
2468                 }
2469         } else {
2470                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2471                         self.flags |= FL_JUMPRELEASED;
2472                         if(self.flags & FL_SPAWNING)
2473                         {
2474                                 self.flags &~= FL_SPAWNING;
2475                                 LeaveSpectatorMode();
2476                                 return;
2477                         }
2478                 }
2479         }
2480
2481         PrintWelcomeMessage(self);
2482         self.flags |= FL_CLIENT | FL_NOTARGET;
2483 }
2484
2485 .float touchexplode_time;
2486
2487 /*
2488 =============
2489 PlayerPreThink
2490
2491 Called every frame for each client before the physics are run
2492 =============
2493 */
2494 void() ctf_setstatus;
2495 void() nexball_setstatus;
2496 .float items_added;
2497 void PlayerPreThink (void)
2498 {
2499         self.stat_game_starttime = game_starttime;
2500         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2501         self.stat_leadlimit = cvar("leadlimit");
2502
2503         if(frametime)
2504         {
2505                 // physics frames: update anticheat stuff
2506                 anticheat_prethink();
2507         }
2508
2509         if(blockSpectators && frametime)
2510                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2511                 checkSpectatorBlock();
2512
2513         zoomstate_set = 0;
2514
2515         if(self.netname_previous != self.netname)
2516         {
2517                 if(cvar("sv_eventlog"))
2518                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2519                 if(self.netname_previous)
2520                         strunzone(self.netname_previous);
2521                 self.netname_previous = strzone(self.netname);
2522         }
2523
2524         // version nagging
2525         if(self.version_nagtime)
2526                 if(self.cvar_g_xonoticversion)
2527                         if(time > self.version_nagtime)
2528                         {
2529                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2530                                 {
2531                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2532                                         {
2533                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2534                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2535                                         }
2536                                         else
2537                                         {
2538                                                 float r;
2539                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2540                                                 if(r < 0)
2541                                                 {
2542                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2543                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2544                                                 }
2545                                                 else if(r > 0)
2546                                                 {
2547                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2548                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2549                                                 }
2550                                         }
2551                                 }
2552                                 self.version_nagtime = 0;
2553                         }
2554
2555         // GOD MODE info
2556         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2557         {
2558                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2559                 self.max_armorvalue = 0;
2560         }
2561
2562 #ifdef TETRIS
2563         if (TetrisPreFrame())
2564                 return;
2565 #endif
2566
2567         MUTATOR_CALLHOOK(PlayerPreThink);
2568
2569         if(self.classname == "player") {
2570 //              if(self.netname == "Wazat")
2571 //                      bprint(self.classname, "\n");
2572
2573                 CheckRules_Player();
2574
2575                 PrintWelcomeMessage(self);
2576
2577                 if (intermission_running)
2578                 {
2579                         IntermissionThink ();   // otherwise a button could be missed between
2580                         return;                                 // the think tics
2581                 }
2582
2583                 if(self.teleport_time)
2584                 if(time > self.teleport_time)
2585                 {
2586                         self.teleport_time = 0;
2587                         self.effects = self.effects - (self.effects & EF_NODRAW);
2588                 }
2589
2590                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2591                         UpdateSelectedPlayer();
2592
2593                 //don't allow the player to turn around while game is paused!
2594                 if(timeoutStatus == 2) {
2595                         self.v_angle = self.lastV_angle;
2596                         self.angles = self.lastV_angle;
2597                         self.fixangle = TRUE;
2598                 }
2599
2600                 if(frametime)
2601                 {
2602                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2603                         player_powerups();
2604                 }
2605
2606                 if (self.deadflag != DEAD_NO)
2607                 {
2608                         float button_pressed, force_respawn;
2609                         if(self.personal && g_race_qualifying)
2610                         {
2611                                 if(time > self.death_time)
2612                                 {
2613                                         self.death_time = time + 1; // only retry once a second
2614                                         respawn();
2615                                         self.impulse = 141;
2616                                 }
2617                         }
2618                         else
2619                         {
2620                                 if(frametime)
2621                                         player_anim();
2622                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2623                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2624                                 if (self.deadflag == DEAD_DYING)
2625                                 {
2626                                         if(force_respawn)
2627                                                 self.deadflag = DEAD_RESPAWNING;
2628                                         else if(!button_pressed)
2629                                                 self.deadflag = DEAD_DEAD;
2630                                 }
2631                                 else if (self.deadflag == DEAD_DEAD)
2632                                 {
2633                                         if(button_pressed)
2634                                                 self.deadflag = DEAD_RESPAWNABLE;
2635                                 }
2636                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2637                                 {
2638                                         if(!button_pressed)
2639                                                 self.deadflag = DEAD_RESPAWNING;
2640                                 }
2641                                 else if (self.deadflag == DEAD_RESPAWNING)
2642                                 {
2643                                         if(time > self.death_time)
2644                                         {
2645                                                 self.death_time = time + 1; // only retry once a second
2646                                                 respawn();
2647                                         }
2648                                 }
2649                                 ShowRespawnCountdown();
2650                         }
2651                         return;
2652                 }
2653
2654                 if(g_touchexplode)
2655                 if(time > self.touchexplode_time)
2656                 if(self.classname == "player")
2657                 if(self.deadflag == DEAD_NO)
2658                 if not(IS_INDEPENDENT_PLAYER(self))
2659                 FOR_EACH_PLAYER(other) if(self != other)
2660                 {
2661                         if(time > other.touchexplode_time)
2662                         if(other.classname == "player")
2663                         if(other.deadflag == DEAD_NO)
2664                         if not(IS_INDEPENDENT_PLAYER(other))
2665                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2666                         {
2667                                 PlayerTouchExplode(self, other);
2668                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2669                         }
2670                 }
2671
2672                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2673                 {
2674                         vector dist;
2675
2676                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2677                         dist = self.prevorigin - self.origin;
2678                         dist_z = 0;
2679                         self.lms_traveled_distance += fabs(vlen(dist));
2680
2681                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2682                         {
2683                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2684                                 self.lms_traveled_distance = 0;
2685                         }
2686
2687                         if(time > self.lms_nextcheck)
2688                         {
2689                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2690                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2691                                 {
2692                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2693                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2694                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2695                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2696                                 }
2697                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2698                                 self.lms_traveled_distance = 0;
2699                         }
2700                 }
2701
2702                 self.prevorigin = self.origin;
2703
2704                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2705                 {
2706                         if (!self.crouch)
2707                         {
2708                                 self.crouch = TRUE;
2709                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2710                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2711                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2712                         }
2713                 }
2714                 else
2715                 {
2716                         if (self.crouch)
2717                         {
2718                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2719                                 if (!trace_startsolid)
2720                                 {
2721                                         self.crouch = FALSE;
2722                                         self.view_ofs = PL_VIEW_OFS;
2723                                         setsize (self, PL_MIN, PL_MAX);
2724                                 }
2725                         }
2726                 }
2727
2728                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2729                 {
2730                         if(self.bloodloss_timer < time)
2731                         {
2732                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2733                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2734                         }
2735                 }
2736
2737                 FixPlayermodel();
2738
2739                 GrapplingHookFrame();
2740
2741                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2742                 //if(frametime)
2743                 {
2744                         self.items &~= self.items_added;
2745
2746                         W_WeaponFrame();
2747
2748                         self.items_added = 0;
2749                         if(self.items & IT_JETPACK)
2750                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2751                                         self.items_added |= IT_FUEL;
2752
2753                         self.items |= self.items_added;
2754                 }
2755
2756                 player_regen();
2757                 if(frametime)
2758                         player_anim();
2759
2760                 if (g_minstagib)
2761                         minstagib_ammocheck();
2762
2763                 ctf_setstatus();
2764                 nexball_setstatus();
2765
2766                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2767
2768                 //self.angles_y=self.v_angle_y + 90;   // temp
2769         } else if(gameover) {
2770                 if (intermission_running)
2771                         IntermissionThink ();   // otherwise a button could be missed between
2772                 return;
2773         } else if(self.classname == "observer") {
2774                 ObserverThink();
2775         } else if(self.classname == "spectator") {
2776                 SpectatorThink();
2777         }
2778
2779         if(!zoomstate_set)
2780                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2781
2782         float oldspectatee_status;
2783         oldspectatee_status = self.spectatee_status;
2784         if(self.classname == "spectator")
2785                 self.spectatee_status = num_for_edict(self.enemy);
2786         else if(self.classname == "observer")
2787                 self.spectatee_status = num_for_edict(self);
2788         else
2789                 self.spectatee_status = 0;
2790         if(self.spectatee_status != oldspectatee_status)
2791         {
2792                 ClientData_Touch(self);
2793                 if(g_race || g_cts)
2794                         race_InitSpectator();
2795         }
2796
2797         if(self.teamkill_soundtime)
2798         if(time > self.teamkill_soundtime)
2799         {
2800                 self.teamkill_soundtime = 0;
2801
2802                 entity oldpusher, oldself;
2803
2804                 oldself = self; self = self.teamkill_soundsource;
2805                 oldpusher = self.pusher; self.pusher = oldself;
2806
2807                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2808
2809                 self.pusher = oldpusher;
2810                 self = oldself;
2811         }
2812
2813         if(self.taunt_soundtime)
2814         if(time > self.taunt_soundtime)
2815         {
2816                 self.taunt_soundtime = 0;
2817                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2818         }
2819
2820         target_voicescript_next(self);
2821 }
2822
2823 float isInvisibleString(string s)
2824 {
2825         float i, n, c;
2826         s = strdecolorize(s);
2827         for((i = 0), (n = strlen(s)); i < n; ++i)
2828         {
2829                 c = str2chr(s, i);
2830                 switch(c)
2831                 {
2832                         case 0:
2833                         case 32:
2834                         case 160:
2835                                 break;
2836                         default:
2837                                 return FALSE;
2838                 }
2839         }
2840         return TRUE;
2841 }
2842
2843 /*
2844 =============
2845 PlayerPostThink
2846
2847 Called every frame for each client after the physics are run
2848 =============
2849 */
2850 .float idlekick_lasttimeleft;
2851 .entity showheadshotbbox;
2852 void showheadshotbbox_think()
2853 {
2854         if(self.owner.showheadshotbbox != self)
2855         {
2856                 remove(self);
2857                 return;
2858         }
2859         self.nextthink = time;
2860         setorigin(self, self.owner.origin);
2861         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2862 }
2863 void PlayerPostThink (void)
2864 {
2865         // Savage: Check for nameless players
2866         if (isInvisibleString(self.netname)) {
2867                 self.netname = "Player";
2868                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2869         }
2870
2871         // send the clients accuracy stats to the client
2872         if(self.stat_count > 0)
2873         if(frametime)
2874         {
2875                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2876                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2877                 self.stat_count -= 1;
2878         }
2879
2880 #ifdef UID
2881         if(self.uid_kicktime)
2882         if(time > self.uid_kicktime)
2883         {
2884                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2885                 dropclient(self);
2886                 return;
2887         }
2888 #endif
2889
2890         if(sv_maxidle && frametime)
2891         {
2892                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2893                 float timeleft;
2894                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2895                 if(timeleft <= 0)
2896                 {
2897                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2898                         AnnounceTo(self, "terminated");
2899                         dropclient(self);
2900                         return;
2901                 }
2902                 else if(timeleft <= 10)
2903                 {
2904                         if(timeleft != self.idlekick_lasttimeleft)
2905                         {
2906                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2907                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2908                         }
2909                 }
2910                 else
2911                 {
2912                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2913                 }
2914                 self.idlekick_lasttimeleft = timeleft;
2915         }
2916
2917 #ifdef TETRIS
2918         if(self.impulse == 100)
2919                 ImpulseCommands();
2920         if (TetrisPostFrame())
2921                 return;
2922 #endif
2923
2924         CheatFrame();
2925
2926         if(self.classname == "player") {
2927                 CheckRules_Player();
2928                 UpdateChatBubble();
2929                 UpdateTeamBubble();
2930                 if (self.impulse)
2931                         ImpulseCommands();
2932                 if (intermission_running)
2933                         return;         // intermission or finale
2934                 GetPressedKeys();
2935         } else if (self.classname == "observer") {
2936                 //do nothing
2937         } else if (self.classname == "spectator") {
2938                 //do nothing
2939         }
2940
2941         /*
2942         float i;
2943         for(i = 0; i < 1000; ++i)
2944         {
2945                 vector end;
2946                 end = self.origin + '0 0 1024' + 512 * randomvec();
2947                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2948                 if(trace_fraction < 1)
2949                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2950                 {
2951                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2952                         break;
2953                 }
2954         }
2955         */
2956
2957         Arena_Warmup();
2958
2959         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2960
2961         if(self.waypointsprite_attachedforcarrier)
2962                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2963         
2964         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2965         {
2966                 if(!self.showheadshotbbox)
2967                 {
2968                         self.showheadshotbbox = spawn();
2969                         self.showheadshotbbox.classname = "headshotbbox";
2970                         self.showheadshotbbox.owner = self;
2971                         self.showheadshotbbox.think = showheadshotbbox_think;
2972                         self.showheadshotbbox.nextthink = time;
2973                         self = self.showheadshotbbox;
2974                         self.think();
2975                         self = self.owner;
2976                 }
2977         }
2978         else
2979         {
2980                 if(self.showheadshotbbox)
2981                         remove(self.showheadshotbbox);
2982         }
2983
2984         playerdemo_write();
2985
2986         /*
2987         if(g_race)
2988                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2989         */
2990 }