Merge remote branch 'origin/fruitiex/loadblackbg'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_nexvelocity(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_NEX_VELOCITY);
13         WriteByte(MSG_ONE, bound(0, fabs(cvar("g_balance_nex_velocitydependent_halflife")), 1));
14         WriteShort(MSG_ONE, cvar("g_balance_nex_velocitydependent_minspeed"));
15         WriteShort(MSG_ONE, cvar("g_balance_nex_velocitydependent_maxspeed"));
16         WriteByte(MSG_ONE, cvar("g_balance_nex_velocitydependent_falloff_rate"));
17         WriteByte(MSG_ONE, cvar("g_balance_nex_secondary_charge"));
18         WriteByte(MSG_ONE, cvar("g_balance_nex_secondary_charge_rate"));
19 }
20
21 void send_CSQC_cr_maxbullets(entity e) {
22         msg_entity = e;
23         WriteByte(MSG_ONE, SVC_TEMPENTITY);
24         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
25         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
26 }
27
28 void Announce(string snd) {
29         WriteByte(MSG_ALL, SVC_TEMPENTITY);
30         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
31         WriteString(MSG_ALL, snd);
32 }
33
34 void AnnounceTo(entity e, string snd) {
35         if (clienttype(e) == CLIENTTYPE_REAL)
36         {
37                 msg_entity = e;
38                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
39                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
40                 WriteString(MSG_ONE, snd);
41         }
42 }
43
44 float ClientData_Send(entity to, float sf)
45 {
46         if(to != self.owner)
47         {
48                 error("wtf");
49                 return FALSE;
50         }
51
52         entity e;
53
54         e = to;
55         if(to.classname == "spectator")
56                 e = to.enemy;
57
58         sf = 0;
59
60         if(e.race_completed)
61                 sf |= 1; // forced scoreboard
62         if(to.spectatee_status)
63                 sf |= 2; // spectator ent number follows
64         if(e.zoomstate)
65                 sf |= 4; // zoomed
66         if(e.porto_v_angle_held)
67                 sf |= 8; // angles held
68
69         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
70         WriteByte(MSG_ENTITY, sf);
71
72         if(sf & 2)
73                 WriteByte(MSG_ENTITY, to.spectatee_status);
74
75         if(sf & 8)
76         {
77                 WriteAngle(MSG_ENTITY, e.v_angle_x);
78                 WriteAngle(MSG_ENTITY, e.v_angle_y);
79         }
80
81         return TRUE;
82 }
83
84 void ClientData_Attach()
85 {
86         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
87         self.clientdata.drawonlytoclient = self;
88         self.clientdata.owner = self;
89 }
90
91 void ClientData_Detach()
92 {
93         remove(self.clientdata);
94         self.clientdata = world;
95 }
96
97 void ClientData_Touch(entity e)
98 {
99         e.clientdata.SendFlags = 1;
100
101         // make it spectatable
102         entity e2;
103         FOR_EACH_REALCLIENT(e2)
104         {
105                 if(e2 != e)
106                         if(e2.classname == "spectator")
107                                 if(e2.enemy == e)
108                                         e2.clientdata.SendFlags = 1;
109         }
110 }
111
112
113 .vector spawnpoint_score;
114 .string netname_previous;
115
116 void spawnfunc_info_player_survivor (void)
117 {
118         spawnfunc_info_player_deathmatch();
119 }
120
121 void spawnfunc_info_player_start (void)
122 {
123         spawnfunc_info_player_deathmatch();
124 }
125
126 void spawnfunc_info_player_deathmatch (void)
127 {
128         self.classname = "info_player_deathmatch";
129         relocate_spawnpoint();
130 }
131
132 void spawnpoint_use()
133 {
134         if(teams_matter)
135         if(have_team_spawns > 0)
136         {
137                 self.team = activator.team;
138                 some_spawn_has_been_used = 1;
139         }
140 };
141
142 // Returns:
143 //   _x: prio (-1 if unusable)
144 //   _y: weight
145 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
146 {
147         float shortest, thisdist;
148         float prio;
149         entity player;
150
151         prio = 0;
152
153         // filter out spots for the wrong team
154         if(teamcheck)
155         if(spot.team != teamcheck)
156                 return '-1 0 0';
157
158         if(race_spawns)
159                 if(spot.target == "")
160                         return '-1 0 0';
161
162         if(clienttype(self) == CLIENTTYPE_REAL)
163         {
164                 if(spot.restriction == 1)
165                         return '-1 0 0';
166         }
167         else
168         {
169                 if(spot.restriction == 2)
170                         return '-1 0 0';
171         }
172
173         // filter out spots for assault
174         if(spot.target != "") {
175                 local entity ent;
176                 float good, found;
177                 ent = find(world, targetname, spot.target);
178
179                 while(ent) {
180                         if(ent.classname == "target_objective")
181                         {
182                                 found = 1;
183                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
184                                         return '-1 0 0';
185                                 good = 1;
186                         }
187                         else if(ent.classname == "trigger_race_checkpoint")
188                         {
189                                 found = 1;
190                                 if(!anypoint) // spectators may spawn everywhere
191
192                                 {
193                                         if(g_race_qualifying)
194                                         {
195                                                 // spawn at first
196                                                 if(ent.race_checkpoint != 0)
197                                                         return '-1 0 0';
198                                                 if(spot.race_place != race_lowest_place_spawn)
199                                                         return '-1 0 0';
200                                         }
201                                         else
202                                         {
203                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
204                                                         return '-1 0 0';
205                                                 // try reusing the previous spawn
206                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
207                                                         prio += 1;
208                                                 if(ent.race_checkpoint == 0)
209                                                 {
210                                                         float pl;
211                                                         pl = self.race_place;
212                                                         if(pl > race_highest_place_spawn)
213                                                                 pl = 0;
214                                                         if(pl == 0 && !self.race_started)
215                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
216                                                         if(spot.race_place != pl)
217                                                                 return '-1 0 0';
218                                                 }
219                                         }
220                                 }
221                                 good = 1;
222                         }
223                         ent = find(ent, targetname, spot.target);
224                 }
225
226                 if(found && !good)
227                         return '-1 0 0';
228         }
229
230         player = playerlist;
231         shortest = vlen(world.maxs - world.mins);
232         for(player = playerlist; player; player = player.chain)
233                 if (player != self)
234                 {
235                         thisdist = vlen(player.origin - spot.origin);
236                         if (thisdist < shortest)
237                                 shortest = thisdist;
238                 }
239         return prio * '1 0 0' + shortest * '0 1 0';
240 }
241
242 float spawn_allbad;
243 float spawn_allgood;
244 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
245 {
246         local entity spot, spotlist, spotlistend;
247         spawn_allgood = TRUE;
248         spawn_allbad = TRUE;
249
250         spotlist = world;
251         spotlistend = world;
252
253         for(spot = firstspot; spot; spot = spot.chain)
254         {
255                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
256
257                 if(cvar("spawn_debugview"))
258                 {
259                         setmodel(spot, "models/runematch/rune.mdl");
260                         if(spot.spawnpoint_score_y < mindist)
261                         {
262                                 spot.colormod = '1 0 0';
263                                 spot.scale = 1;
264                         }
265                         else
266                         {
267                                 spot.colormod = '0 1 0';
268                                 spot.scale = spot.spawnpoint_score_y / mindist;
269                         }
270                 }
271
272                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
273                 {
274                         if(spot.spawnpoint_score_y < mindist)
275                         {
276                                 // too short distance
277                                 spawn_allgood = FALSE;
278                         }
279                         else
280                         {
281                                 // perfect
282                                 spawn_allbad = FALSE;
283
284                                 if(spotlistend)
285                                         spotlistend.chain = spot;
286                                 spotlistend = spot;
287                                 if(!spotlist)
288                                         spotlist = spot;
289
290                                 /*
291                                 if(teamcheck)
292                                 if(spot.team != teamcheck)
293                                         error("invalid spawn added");
294
295                                 print("added ", etos(spot), "\n");
296                                 */
297                         }
298                 }
299         }
300         if(spotlistend)
301                 spotlistend.chain = world;
302
303         /*
304                 entity e;
305                 if(teamcheck)
306                         for(e = spotlist; e; e = e.chain)
307                         {
308                                 print("seen ", etos(e), "\n");
309                                 if(e.team != teamcheck)
310                                         error("invalid spawn found");
311                         }
312         */
313
314         return spotlist;
315 }
316
317 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
318 {
319         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
320         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
321         local entity spot;
322
323         RandomSelection_Init();
324         for(spot = firstspot; spot; spot = spot.chain)
325                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
326
327         return RandomSelection_chosen_ent;
328 }
329
330 /*
331 =============
332 SelectSpawnPoint
333
334 Finds a point to respawn
335 =============
336 */
337 entity SelectSpawnPoint (float anypoint)
338 {
339         local float teamcheck;
340         local entity firstspot_new;
341         local entity spot, firstspot, playerlist;
342
343         spot = find (world, classname, "testplayerstart");
344         if (spot)
345                 return spot;
346
347         teamcheck = 0;
348
349         if(!anypoint && have_team_spawns > 0)
350                 teamcheck = self.team;
351
352         // get the list of players
353         playerlist = findchain(classname, "player");
354         // get the entire list of spots
355         firstspot = findchain(classname, "info_player_deathmatch");
356         // filter out the bad ones
357         // (note this returns the original list if none survived)
358         if(anypoint)
359         {
360                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
361         }
362         else
363         {
364                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
365                 if(!firstspot_new)
366                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
367                 firstspot = firstspot_new;
368
369                 // there is 50/50 chance of choosing a random spot or the furthest spot
370                 // (this means that roughly every other spawn will be furthest, so you
371                 // usually won't get fragged at spawn twice in a row)
372                 if (arena_roundbased && !g_ca)
373                 {
374                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
375                         if(firstspot_new)
376                                 firstspot = firstspot_new;
377                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
378                 }
379                 else if (random() > cvar("g_spawn_furthest"))
380                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
381                 else
382                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
383         }
384
385         if(cvar("spawn_debugview"))
386         {
387                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
388
389                 entity e;
390                 if(teamcheck)
391                         for(e = firstspot; e; e = e.chain)
392                                 if(e.team != teamcheck)
393                                         error("invalid spawn found");
394         }
395
396         if (!spot)
397         {
398                 if(cvar("spawn_debug"))
399                         GotoNextMap();
400                 else
401                 {
402                         if(some_spawn_has_been_used)
403                                 return world; // team can't spawn any more, because of actions of other team
404                         else
405                                 error("Cannot find a spawn point - please fix the map!");
406                 }
407         }
408
409         return spot;
410 }
411
412 /*
413 =============
414 CheckPlayerModel
415
416 Checks if the argument string can be a valid playermodel.
417 Returns a valid one in doubt.
418 =============
419 */
420 string FallbackPlayerModel;
421 string CheckPlayerModel(string plyermodel) {
422         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
423         {
424                 // note: we cannot summon Don Strunzone here, some player may
425                 // still have the model string set. In case anyone manages how
426                 // to change a cvar default, we'll have a small leak here.
427                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
428         }
429         if(strlen(plyermodel) < 4)
430                 return FallbackPlayerModel;
431         if( substring(plyermodel,0,14) != "models/player/")
432                 return FallbackPlayerModel;
433         else if(cvar("sv_servermodelsonly"))
434         {
435                 if(substring(plyermodel,-4,4) != ".zym")
436                 if(substring(plyermodel,-4,4) != ".dpm")
437                 if(substring(plyermodel,-4,4) != ".iqm")
438                 if(substring(plyermodel,-4,4) != ".md3")
439                 if(substring(plyermodel,-4,4) != ".psk")
440                         return FallbackPlayerModel;
441                 // forbid the LOD models
442                 if(substring(plyermodel, -9,5) == "_lod1")
443                         return FallbackPlayerModel;
444                 if(substring(plyermodel, -9,5) == "_lod2")
445                         return FallbackPlayerModel;
446                 if(plyermodel != strtolower(plyermodel))
447                         return FallbackPlayerModel;
448                 if(!fexists(plyermodel))
449                         return FallbackPlayerModel;
450         }
451         return plyermodel;
452 }
453
454 /*
455 =============
456 Client_customizeentityforclient
457
458 LOD reduction
459 =============
460 */
461 void Client_uncustomizeentityforclient()
462 {
463         if(self.modelindex == 0) // no need to uncustomize then
464                 return;
465         self.modelindex = self.modelindex_lod0;
466         self.skin = self.skinindex;
467 }
468
469 float Client_customizeentityforclient()
470 {
471         entity modelsource;
472
473         if(self.modelindex == 0)
474                 return TRUE;
475
476         // forcemodel stuff
477
478 #ifdef PROFILING
479         float t0;
480         t0 = gettime(GETTIME_HIRES); // reference
481 #endif
482
483         modelsource = self;
484
485 #ifdef ALLOW_FORCEMODELS
486         if(other.cvar_cl_forceplayermodelsfromxonotic)
487                 if not(self.modelindex_lod0_from_xonotic)
488                         modelsource = other;
489         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
490                 modelsource = other;
491 #endif
492
493         self.skin = modelsource.skinindex;
494
495 #if 0
496         if(modelsource == self)
497                 self.skin = modelsource.skinindex;
498         else
499                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
500 #endif
501
502         // self: me
503         // other: the player viewing me
504         float distance;
505         float f;
506
507         if(other.cvar_cl_playerdetailreduction <= 0)
508         {
509                 if(other.cvar_cl_playerdetailreduction <= -2)
510                         self.modelindex = modelsource.modelindex_lod2;
511                 else if(other.cvar_cl_playerdetailreduction <= -1)
512                         self.modelindex = modelsource.modelindex_lod1;
513                 else
514                         self.modelindex = modelsource.modelindex_lod0;
515         }
516         else
517         {
518                 distance = vlen(self.origin - other.origin);
519                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
520                 if(f > sv_loddistance2)
521                         self.modelindex = modelsource.modelindex_lod2;
522                 else if(f > sv_loddistance1)
523                         self.modelindex = modelsource.modelindex_lod1;
524                 else
525                         self.modelindex = modelsource.modelindex_lod0;
526         }
527
528 #ifdef PROFILING
529         float t1;
530         t1 = gettime(GETTIME_HIRES); // reference
531         client_cefc_accumulator += (t1 - t0);
532 #endif
533
534         return TRUE;
535 }
536
537 void setmodel_lod(entity e, string modelname)
538 {
539         string s;
540
541         if(sv_loddistance1)
542         {
543                 // FIXME: this only supports 3-letter extensions
544                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
545                 if(fexists(s))
546                 {
547                         setmodel(e, s); // players have high precision
548                         self.modelindex_lod1 = self.modelindex;
549                 }
550                 else
551                         self.modelindex_lod1 = -1;
552
553                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
554                 if(fexists(s))
555                 {
556                         setmodel(e, s); // players have high precision
557                         self.modelindex_lod2 = self.modelindex;
558                 }
559                 else
560                         self.modelindex_lod2 = -1;
561
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565
566                 if(self.modelindex_lod1 < 0)
567                         self.modelindex_lod1 = self.modelindex;
568
569                 if(self.modelindex_lod2 < 0)
570                         self.modelindex_lod2 = self.modelindex;
571         }
572         else
573         {
574                 precache_model(modelname);
575                 setmodel(e, modelname); // players have high precision
576                 self.modelindex_lod0 = self.modelindex;
577                         // save it for possible player model forcing
578         }
579
580         s = whichpack(self.model);
581         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
582
583         player_setupanimsformodel();
584         UpdatePlayerSounds();
585 }
586
587 /*
588 =============
589 PutObserverInServer
590
591 putting a client as observer in the server
592 =============
593 */
594 void FixPlayermodel();
595 void PutObserverInServer (void)
596 {
597         entity  spot;
598
599         race_PreSpawnObserver();
600
601         spot = SelectSpawnPoint (TRUE);
602         if(!spot)
603                 error("No spawnpoints for observers?!?\n");
604         RemoveGrapplingHook(self); // Wazat's Grappling Hook
605
606         if(clienttype(self) == CLIENTTYPE_REAL)
607         {
608                 msg_entity = self;
609                 WriteByte(MSG_ONE, SVC_SETVIEW);
610                 WriteEntity(MSG_ONE, self);
611         }
612
613         DropAllRunes(self);
614
615         Portal_ClearAll(self);
616
617         if(self.flagcarried)
618                 DropFlag(self.flagcarried, world, world);
619
620         if(self.ballcarried)
621                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
622
623         WaypointSprite_PlayerDead();
624
625         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
626                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
627
628         if(self.killcount != -666) {
629                 if(g_lms) {
630                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
631                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
632                         else
633                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
634                 } else
635                         bprint ("^4", self.netname, "^4 is spectating now\n");
636
637                 if(self.just_joined == FALSE) {
638                         LogTeamchange(self.playerid, -1, 4);
639                 } else
640                         self.just_joined = FALSE;
641         }
642
643         PlayerScore_Clear(self); // clear scores when needed
644
645         self.spectatortime = time;
646
647         self.classname = "observer";
648         self.iscreature = FALSE;
649         self.health = -666;
650         self.takedamage = DAMAGE_NO;
651         self.solid = SOLID_NOT;
652         self.movetype = MOVETYPE_NOCLIP;
653         self.flags = FL_CLIENT | FL_NOTARGET;
654         self.armorvalue = 666;
655         self.effects = 0;
656         self.armorvalue = cvar("g_balance_armor_start");
657         self.pauserotarmor_finished = 0;
658         self.pauserothealth_finished = 0;
659         self.pauseregen_finished = 0;
660         self.damageforcescale = 0;
661         self.death_time = 0;
662         self.dead_frame = 0;
663         self.alpha = 0;
664         self.scale = 0;
665         self.fade_time = 0;
666         self.pain_frame = 0;
667         self.pain_finished = 0;
668         self.strength_finished = 0;
669         self.invincible_finished = 0;
670         self.pushltime = 0;
671         self.think = SUB_Null;
672         self.nextthink = 0;
673         self.hook_time = 0;
674         self.runes = 0;
675         self.deadflag = DEAD_NO;
676         self.angles = spot.angles;
677         self.angles_z = 0;
678         self.fixangle = TRUE;
679         self.crouch = FALSE;
680
681         self.view_ofs = PL_VIEW_OFS;
682         setorigin (self, spot.origin);
683         setsize (self, '0 0 0', '0 0 0');
684         self.prevorigin = self.origin;
685         self.items = 0;
686         self.weapons = 0;
687         self.model = "";
688         FixPlayermodel();
689         self.model = "";
690         self.modelindex = 0;
691         self.weapon = 0;
692         self.weaponmodel = "";
693         self.weaponentity = world;
694         self.exteriorweaponentity = world;
695         self.killcount = -666;
696         self.velocity = '0 0 0';
697         self.avelocity = '0 0 0';
698         self.punchangle = '0 0 0';
699         self.punchvector = '0 0 0';
700         self.oldvelocity = self.velocity;
701         self.fire_endtime = -1;
702
703         if(sv_loddistance1)
704                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
705
706         if(g_arena)
707         {
708                 if(self.version_mismatch)
709                 {
710                         Spawnqueue_Unmark(self);
711                         Spawnqueue_Remove(self);
712                 }
713                 else
714                 {
715                         Spawnqueue_Insert(self);
716                 }
717         }
718         else if(g_lms)
719         {
720                 // Only if the player cannot play at all
721                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
722                         self.frags = FRAGS_SPECTATOR;
723                 else
724                         self.frags = FRAGS_LMS_LOSER;
725         }
726         else
727                 self.frags = FRAGS_SPECTATOR;
728
729         MUTATOR_CALLHOOK(MakePlayerObserver);
730 }
731
732 float RestrictSkin(float s)
733 {
734         if(!teams_matter)
735                 return s;
736         if(s == 6)
737                 return 6;
738         return mod(s, 3);
739 }
740
741 void FixPlayermodel()
742 {
743         local string defaultmodel;
744         local float defaultskin, chmdl, oldskin;
745         local vector m1, m2;
746
747         defaultmodel = "";
748
749         if(cvar("sv_defaultcharacter") == 1) {
750                 defaultskin = 0;
751
752                 if(teams_matter)
753                 {
754                         string s;
755                         s = Team_ColorNameLowerCase(self.team);
756                         if(s != "neutral")
757                         {
758                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
759                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
760                         }
761                 }
762
763                 if(defaultmodel == "")
764                 {
765                         defaultmodel = cvar_string("sv_defaultplayermodel");
766                         defaultskin = cvar("sv_defaultplayerskin");
767                 }
768         }
769
770         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
771         {
772                 if(self.model != "")
773                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
774                 self.model = ""; // force the != checks to return true
775         }
776
777         if(defaultmodel != "")
778         {
779                 if (defaultmodel != self.model)
780                 {
781                         m1 = self.mins;
782                         m2 = self.maxs;
783                         setmodel_lod (self, defaultmodel);
784                         setsize (self, m1, m2);
785                         chmdl = TRUE;
786                 }
787
788                 oldskin = self.skinindex;
789                 self.skinindex = defaultskin;
790         } else {
791                 if (self.playermodel != self.model || self.playermodel == "")
792                 {
793                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
794                         m1 = self.mins;
795                         m2 = self.maxs;
796                         setmodel_lod (self, self.playermodel);
797                         setsize (self, m1, m2);
798                         chmdl = TRUE;
799                 }
800
801                 oldskin = self.skinindex;
802                 self.skinindex = RestrictSkin(stof(self.playerskin));
803         }
804
805         if(chmdl || oldskin != self.skinindex)
806                 self.species = player_getspecies(); // model or skin has changed
807
808         if(!teams_matter)
809                 if(strlen(cvar_string("sv_defaultplayercolors")))
810                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
811                                 setcolor(self, cvar("sv_defaultplayercolors"));
812 }
813
814 void PlayerTouchExplode(entity p1, entity p2)
815 {
816         vector org;
817         org = (p1.origin + p2.origin) * 0.5;
818         org_z += (p1.mins_z + p2.mins_z) * 0.5;
819
820         te_explosion(org);
821
822         entity e;
823         e = spawn();
824         setorigin(e, org);
825         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
826         remove(e);
827 }
828
829 /*
830 =============
831 PutClientInServer
832
833 Called when a client spawns in the server
834 =============
835 */
836 //void() ctf_playerchanged;
837 void PutClientInServer (void)
838 {
839         if(clienttype(self) == CLIENTTYPE_BOT)
840         {
841                 self.classname = "player";
842         }
843         else if(clienttype(self) == CLIENTTYPE_REAL)
844         {
845                 msg_entity = self;
846                 WriteByte(MSG_ONE, SVC_SETVIEW);
847                 WriteEntity(MSG_ONE, self);
848         }
849
850         // player is dead and becomes observer
851         // FIXME fix LMS scoring for new system
852         if(g_lms)
853         {
854                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
855                         self.classname = "observer";
856         }
857
858         if(g_arena || (g_ca && !allowed_to_spawn))
859         if(!self.spawned)
860                 self.classname = "observer";
861
862         if(gameover)
863                 self.classname = "observer";
864
865         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
866                 entity spot, oldself;
867                 float j;
868
869                 if(self.team < 0)
870                         JoinBestTeam(self, FALSE, TRUE);
871
872                 race_PreSpawn();
873
874                 spot = SelectSpawnPoint (FALSE);
875                 if(!spot)
876                 {
877                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
878                         return; // spawn failed
879                 }
880
881                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
882
883                 self.classname = "player";
884                 self.wasplayer = TRUE;
885                 self.iscreature = TRUE;
886                 self.movetype = MOVETYPE_WALK;
887                 self.solid = SOLID_SLIDEBOX;
888                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
889                 if(cvar("g_playerclip_collisions"))
890                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
891                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
892                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
893                 self.frags = FRAGS_PLAYER;
894                 if(independent_players)
895                         MAKE_INDEPENDENT_PLAYER(self);
896                 self.flags = FL_CLIENT;
897                 self.takedamage = DAMAGE_AIM;
898                 if(g_minstagib)
899                         self.effects = EF_FULLBRIGHT;
900                 else
901                         self.effects = 0;
902                 self.air_finished = time + 12;
903                 self.dmg = 2;
904
905                 if(inWarmupStage)
906                 {
907                         self.ammo_shells = warmup_start_ammo_shells;
908                         self.ammo_nails = warmup_start_ammo_nails;
909                         self.ammo_rockets = warmup_start_ammo_rockets;
910                         self.ammo_cells = warmup_start_ammo_cells;
911                         self.ammo_fuel = warmup_start_ammo_fuel;
912                         self.health = warmup_start_health;
913                         self.armorvalue = warmup_start_armorvalue;
914                         self.weapons = warmup_start_weapons;
915                 }
916                 else
917                 {
918                         self.ammo_shells = start_ammo_shells;
919                         self.ammo_nails = start_ammo_nails;
920                         self.ammo_rockets = start_ammo_rockets;
921                         self.ammo_cells = start_ammo_cells;
922                         self.ammo_fuel = start_ammo_fuel;
923                         self.health = start_health;
924                         self.armorvalue = start_armorvalue;
925                         self.weapons = start_weapons;
926                 }
927
928                 if(g_weaponarena_random)
929                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
930
931                 self.items = start_items;
932                 self.jump_interval = time;
933
934                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
935                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
936                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
937                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
938                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
939                 //extend the pause of rotting if client was reset at the beginning of the countdown
940                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
941                         self.spawnshieldtime += game_starttime - time;
942                         self.pauserotarmor_finished += game_starttime - time;
943                         self.pauserothealth_finished += game_starttime - time;
944                         self.pauseregen_finished += game_starttime - time;
945                 }
946                 self.damageforcescale = 2;
947                 self.death_time = 0;
948                 self.dead_frame = 0;
949                 self.alpha = 0;
950                 self.scale = 0;
951                 self.fade_time = 0;
952                 self.pain_frame = 0;
953                 self.pain_finished = 0;
954                 self.strength_finished = 0;
955                 self.invincible_finished = 0;
956                 self.pushltime = 0;
957                 // players have no think function
958                 self.think = SUB_Null;
959                 self.nextthink = 0;
960                 self.hook_time = 0;
961                 self.dmg_team = 0;
962                 self.ballistics_density = cvar("g_ballistics_density_player");
963
964                 self.metertime = 0;
965
966                 self.runes = 0;
967
968                 self.deadflag = DEAD_NO;
969
970                 self.angles = spot.angles;
971
972                 self.angles_z = 0; // never spawn tilted even if the spot says to
973                 self.fixangle = TRUE; // turn this way immediately
974                 self.velocity = '0 0 0';
975                 self.avelocity = '0 0 0';
976                 self.punchangle = '0 0 0';
977                 self.punchvector = '0 0 0';
978                 self.oldvelocity = self.velocity;
979                 self.fire_endtime = -1;
980
981                 msg_entity = self;
982                 WRITESPECTATABLE_MSG_ONE({
983                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
984                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
985                 });
986
987                 if(sv_loddistance1)
988                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
989
990                 self.model = "";
991                 FixPlayermodel();
992
993                 self.crouch = FALSE;
994                 self.view_ofs = PL_VIEW_OFS;
995                 setsize (self, PL_MIN, PL_MAX);
996                 self.spawnorigin = spot.origin;
997                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
998                 // don't reset back to last position, even if new position is stuck in solid
999                 self.oldorigin = self.origin;
1000                 self.prevorigin = self.origin;
1001                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1002
1003                 if(g_arena)
1004                 {
1005                         Spawnqueue_Remove(self);
1006                         Spawnqueue_Mark(self);
1007                 }
1008
1009                 else if(g_ca)
1010                         self.caplayer = 1;
1011
1012                 self.event_damage = PlayerDamage;
1013
1014                 self.bot_attack = TRUE;
1015
1016                 self.statdraintime = time + 5;
1017                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1018
1019                 if(self.killcount == -666) {
1020                         PlayerScore_Clear(self);
1021                         self.killcount = 0;
1022                 }
1023
1024                 self.cnt = WEP_LASER;
1025
1026                 CL_SpawnWeaponentity();
1027                 self.alpha = default_player_alpha;
1028                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1029                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1030
1031                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1032                 self.lms_traveled_distance = 0;
1033                 self.speedrunning = FALSE;
1034
1035                 race_PostSpawn(spot);
1036
1037                 if(cvar("spawn_debug"))
1038                 {
1039                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1040                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1041                 }
1042
1043                 //stuffcmd(self, "chase_active 0");
1044                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1045
1046                 if (cvar("g_spawnsound"))
1047                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1048
1049                 if(g_assault) {
1050                         if(self.team == assault_attacker_team)
1051                                 centerprint(self, "You are attacking!");
1052                         else
1053                                 centerprint(self, "You are defending!");
1054                 }
1055
1056                 target_voicescript_clear(self);
1057
1058                 // reset fields the weapons may use
1059                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1060                         weapon_action(j, WR_RESETPLAYER);
1061
1062                 oldself = self;
1063                 self = spot;
1064                         activator = oldself;
1065                                 SUB_UseTargets();
1066                         activator = world;
1067                 self = oldself;
1068
1069                 MUTATOR_CALLHOOK(PlayerSpawn);
1070
1071                 self.switchweapon = w_getbestweapon(self);
1072                 self.cnt = self.switchweapon;
1073                 self.weapon = 0;
1074         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1075                 PutObserverInServer ();
1076         }
1077
1078         //if(g_ctf)
1079         //      ctf_playerchanged();
1080 }
1081
1082 float ClientInit_SendEntity(entity to, float sf)
1083 {
1084         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1085         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1098         if(sv_foginterval && world.fog != "")
1099                 WriteString(MSG_ENTITY, world.fog);
1100         else
1101                 WriteString(MSG_ENTITY, "");
1102         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1103         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1104         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1105         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1106         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1107         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1108         return TRUE;
1109 }
1110
1111 void ClientInit_CheckUpdate()
1112 {
1113         self.nextthink = time;
1114         if(self.count != cvar("g_balance_armor_blockpercent"))
1115         {
1116                 self.count = cvar("g_balance_armor_blockpercent");
1117                 self.SendFlags |= 1;
1118         }
1119         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1120         {
1121                 self.cnt = cvar("g_balance_weaponswitchdelay");
1122                 self.SendFlags |= 1;
1123         }
1124         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1125         {
1126                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1127                 self.SendFlags |= 1;
1128         }
1129         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1130         {
1131                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1132                 self.SendFlags |= 1;
1133         }
1134 }
1135
1136 void ClientInit_Spawn()
1137 {
1138         entity o;
1139         entity e;
1140         e = spawn();
1141         e.classname = "clientinit";
1142         e.think = ClientInit_CheckUpdate;
1143         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1144
1145         o = self;
1146         self = e;
1147         ClientInit_CheckUpdate();
1148         self = o;
1149 }
1150
1151 /*
1152 =============
1153 SetNewParms
1154 =============
1155 */
1156 void SetNewParms (void)
1157 {
1158         // initialize parms for a new player
1159         parm1 = -(86400 * 366);
1160 }
1161
1162 /*
1163 =============
1164 SetChangeParms
1165 =============
1166 */
1167 void SetChangeParms (void)
1168 {
1169         // save parms for level change
1170         parm1 = self.parm_idlesince - time;
1171 }
1172
1173 /*
1174 =============
1175 DecodeLevelParms
1176 =============
1177 */
1178 void DecodeLevelParms (void)
1179 {
1180         // load parms
1181         self.parm_idlesince = parm1;
1182         if(self.parm_idlesince == -(86400 * 366))
1183                 self.parm_idlesince = time;
1184
1185         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1186         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1187 }
1188
1189 /*
1190 =============
1191 ClientKill
1192
1193 Called when a client types 'kill' in the console
1194 =============
1195 */
1196
1197 void ClientKill_Now_TeamChange()
1198 {
1199         if(self.killindicator_teamchange == -1)
1200         {
1201                 self.team = -1;
1202                 JoinBestTeam( self, FALSE, FALSE );
1203         }
1204         else
1205                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1206 }
1207
1208 void ClientKill_Now()
1209 {
1210         if(self.killindicator_teamchange)
1211                 ClientKill_Now_TeamChange();
1212
1213         // in any case:
1214         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1215
1216         if(self.killindicator)
1217         {
1218                 dprint("Cleaned up after a leaked kill indicator.\n");
1219                 remove(self.killindicator);
1220                 self.killindicator = world;
1221         }
1222 }
1223 void KillIndicator_Think()
1224 {
1225         if (!self.owner.modelindex)
1226         {
1227                 self.owner.killindicator = world;
1228                 remove(self);
1229                 return;
1230         }
1231
1232         if(self.cnt <= 0)
1233         {
1234                 self = self.owner;
1235                 ClientKill_Now(); // no oldself needed
1236                 return;
1237         }
1238         else
1239         {
1240                 if(self.cnt <= 10)
1241                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1242                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1243                 {
1244                         if(self.cnt <= 10)
1245                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1246                         if(self.owner.killindicator_teamchange)
1247                         {
1248                                 if(self.owner.killindicator_teamchange == -1)
1249                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1250                                 else
1251                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1252                         }
1253                         else
1254                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1255                 }
1256                 self.nextthink = time + 1;
1257                 self.cnt -= 1;
1258         }
1259 }
1260
1261 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1262 {
1263         float killtime;
1264         entity e;
1265         killtime = cvar("g_balance_kill_delay");
1266
1267         if(g_race_qualifying)
1268                 killtime = 0;
1269
1270         self.killindicator_teamchange = targetteam;
1271
1272         if(!self.killindicator)
1273         {
1274                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1275                 {
1276                         ClientKill_Now();
1277                 }
1278                 else
1279                 {
1280                         self.killindicator = spawn();
1281                         self.killindicator.owner = self;
1282                         self.killindicator.scale = 0.5;
1283                         setattachment(self.killindicator, self, "");
1284                         setorigin(self.killindicator, '0 0 52');
1285                         self.killindicator.think = KillIndicator_Think;
1286                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1287                         self.killindicator.cnt = ceil(killtime);
1288                         self.killindicator.count = bound(0, ceil(killtime), 10);
1289                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1290
1291                         for(e = world; (e = find(e, classname, "body")) != world; )
1292                         {
1293                                 if(e.enemy != self)
1294                                         continue;
1295                                 e.killindicator = spawn();
1296                                 e.killindicator.owner = e;
1297                                 e.killindicator.scale = 0.5;
1298                                 setattachment(e.killindicator, e, "");
1299                                 setorigin(e.killindicator, '0 0 52');
1300                                 e.killindicator.think = KillIndicator_Think;
1301                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1302                                 e.killindicator.cnt = ceil(killtime);
1303                         }
1304                         self.lip = 0;
1305                 }
1306         }
1307         if(self.killindicator)
1308         {
1309                 if(targetteam)
1310                         self.killindicator.colormod = TeamColor(targetteam);
1311                 else
1312                         self.killindicator.colormod = '0 0 0';
1313         }
1314 }
1315
1316 void ClientKill (void)
1317 {
1318         ClientKill_TeamChange(0);
1319 }
1320
1321 void DoTeamChange(float destteam)
1322 {
1323         float t, c0;
1324         if(!teams_matter)
1325         {
1326                 if(destteam >= 0)
1327                         SetPlayerColors(self, destteam);
1328                 return;
1329         }
1330         if(self.classname == "player")
1331         if(destteam == -1)
1332         {
1333                 CheckAllowedTeams(self);
1334                 t = FindSmallestTeam(self, TRUE);
1335                 switch(self.team)
1336                 {
1337                         case COLOR_TEAM1: c0 = c1; break;
1338                         case COLOR_TEAM2: c0 = c2; break;
1339                         case COLOR_TEAM3: c0 = c3; break;
1340                         case COLOR_TEAM4: c0 = c4; break;
1341                         default:          c0 = 999;
1342                 }
1343                 switch(t)
1344                 {
1345                         case 1:
1346                                 if(c0 > c1)
1347                                         destteam = COLOR_TEAM1;
1348                                 break;
1349                         case 2:
1350                                 if(c0 > c2)
1351                                         destteam = COLOR_TEAM2;
1352                                 break;
1353                         case 3:
1354                                 if(c0 > c3)
1355                                         destteam = COLOR_TEAM3;
1356                                 break;
1357                         case 4:
1358                                 if(c0 > c4)
1359                                         destteam = COLOR_TEAM4;
1360                                 break;
1361                 }
1362                 if(destteam == -1)
1363                         return;
1364         }
1365         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1366                 return;
1367         ClientKill_TeamChange(destteam);
1368 }
1369
1370 void FixClientCvars(entity e)
1371 {
1372         // send prediction settings to the client
1373         stuffcmd(e, "\nin_bindmap 0 0\n");
1374         if(g_race || g_cts)
1375                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1376         if(cvar("g_antilag") == 3) // client side hitscan
1377                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1378         if(sv_gentle)
1379                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1380         /*
1381          * we no longer need to stuff this. Remove this comment block if you feel
1382          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1383         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1384         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1385         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1386         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1387         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1388         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1389         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1390         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1391         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1392         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1393         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1394         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1395         stuffcmd(e, "cl_movement_edgefriction 1\n");
1396          */
1397 }
1398
1399 /*
1400 =============
1401 ClientConnect
1402
1403 Called when a client connects to the server
1404 =============
1405 */
1406 //void ctf_clientconnect();
1407 string ColoredTeamName(float t);
1408 void DecodeLevelParms (void);
1409 //void dom_player_join_team(entity pl);
1410 #ifdef UID
1411 .float uid_kicktime;
1412 .string uid;
1413 #endif
1414 void ClientConnect (void)
1415 {
1416         float t;
1417
1418         if(self.flags & FL_CLIENT)
1419         {
1420                 print("Warning: ClientConnect, but already connected!\n");
1421                 return;
1422         }
1423
1424         if(Ban_MaybeEnforceBan(self))
1425                 return;
1426
1427         DecodeLevelParms();
1428
1429 #ifdef WATERMARK
1430         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1431 #endif
1432
1433         self.classname = "player_joining";
1434
1435         self.flags = FL_CLIENT;
1436         self.version_nagtime = time + 10 + random() * 10;
1437
1438         if(player_count<0)
1439         {
1440                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1441                 player_count = 0;
1442         }
1443
1444         PlayerScore_Attach(self);
1445         ClientData_Attach();
1446
1447         bot_clientconnect();
1448
1449         playerdemo_init();
1450
1451         anticheat_init();
1452         
1453         race_PreSpawnObserver();
1454
1455         //if(g_domination)
1456         //      dom_player_join_team(self);
1457
1458         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1459
1460         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1461                 self.classname = "observer";
1462         } else {
1463                 if(teams_matter)
1464                 {
1465                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1466                         {
1467                                 self.classname = "player";
1468                                 campaign_bots_may_start = 1;
1469                         }
1470                         else
1471                         {
1472                                 self.classname = "observer"; // do it anyway
1473                         }
1474                 }
1475                 else
1476                 {
1477                         self.classname = "player";
1478                         campaign_bots_may_start = 1;
1479                 }
1480         }
1481
1482         self.playerid = (playerid_last = playerid_last + 1);
1483
1484         if(cvar("sv_eventlog"))
1485                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1486
1487         LogTeamchange(self.playerid, self.team, 1);
1488
1489         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1490
1491         self.netname_previous = strzone(self.netname);
1492
1493         bprint("^4", self.netname, "^4 connected");
1494
1495         if(self.classname != "observer" && (g_domination || g_ctf))
1496                 bprint(" and joined the ", ColoredTeamName(self.team));
1497
1498         bprint("\n");
1499
1500         self.welcomemessage_time = 0;
1501
1502         stuffcmd(self, strcat(clientstuff, "\n"));
1503         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1504         stuffcmd(self, "cl_particles_reloadeffects\n");
1505
1506         FixClientCvars(self);
1507
1508         // spawnfunc_waypoint sprites
1509         WaypointSprite_InitClient(self);
1510
1511         // Wazat's grappling hook
1512         SetGrappleHookBindings();
1513
1514         // get autoswitch state from player when he toggles it
1515         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1516
1517         // get version info from player
1518         stuffcmd(self, "cmd clientversion $gameversion\n");
1519
1520         // get other cvars from player
1521         GetCvars(0);
1522
1523         // set cvar for team scoreboard
1524         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1525
1526         // notify about available teams
1527         if(teams_matter)
1528         {
1529                 CheckAllowedTeams(self);
1530                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1531                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1532         }
1533         else
1534                 stuffcmd(self, "set _teams_available 0\n");
1535
1536         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1537
1538         if(g_arena || g_ca)
1539         {
1540                 self.classname = "observer";
1541                 if(g_arena)
1542                         Spawnqueue_Insert(self);
1543         }
1544         /*else if(g_ctf)
1545         {
1546                 ctf_clientconnect();
1547         }*/
1548
1549         if(teams_matter || radar_showennemies)
1550                 attach_entcs();
1551
1552         bot_relinkplayerlist();
1553
1554         self.spectatortime = time;
1555         if(blockSpectators)
1556         {
1557                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1558         }
1559
1560         self.jointime = time;
1561         self.allowedTimeouts = cvar("sv_timeout_number");
1562
1563         if(clienttype(self) == CLIENTTYPE_REAL)
1564         {
1565                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1566                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1567         }
1568
1569         if(g_lms)
1570         {
1571                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1572                 {
1573                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1574                         self.frags = FRAGS_SPECTATOR;
1575                 }
1576         }
1577
1578         if(!sv_foginterval && world.fog != "")
1579                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1580
1581         SoundEntity_Attach(self);
1582
1583         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1584         {
1585                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1586                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1587         }
1588         else
1589                 self.hitplotfh = -1;
1590
1591 #ifdef UID
1592         if(clienttype(self) == CLIENTTYPE_REAL)
1593         if not(self.uid)
1594                 self.uid_kicktime = time + 60;
1595 #endif
1596
1597         if(g_race || g_cts) {
1598                 string rr;
1599                 if(g_cts)
1600                         rr = CTS_RECORD;
1601                 else
1602                         rr = RACE_RECORD;
1603                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1604
1605                 race_send_recordtime(MSG_ONE);
1606                 race_send_speedaward(MSG_ONE);
1607
1608                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1609                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1610                 race_send_speedaward_alltimebest(MSG_ONE);
1611
1612                 float i;
1613                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1614                         race_SendRankings(i, 0, 0, MSG_ONE);
1615                 }
1616         }
1617         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1618                 send_CSQC_teamnagger();
1619
1620         send_CSQC_nexvelocity(self);
1621         send_CSQC_cr_maxbullets(self);
1622
1623         CheatInitClient();
1624 }
1625
1626 /*
1627 =============
1628 ClientDisconnect
1629
1630 Called when a client disconnects from the server
1631 =============
1632 */
1633 .entity chatbubbleentity;
1634 .entity teambubbleentity;
1635 void ReadyCount();
1636 void ClientDisconnect (void)
1637 {
1638         if not(self.flags & FL_CLIENT)
1639         {
1640                 print("Warning: ClientDisconnect without ClientConnect\n");
1641                 return;
1642         }
1643
1644         CheatShutdownClient();
1645
1646         if(self.hitplotfh >= 0)
1647         {
1648                 fclose(self.hitplotfh);
1649                 self.hitplotfh = -1;
1650         }
1651
1652         anticheat_report();
1653         anticheat_shutdown();
1654
1655         playerdemo_shutdown();
1656
1657         bot_clientdisconnect();
1658
1659         if(self.entcs)
1660                 detach_entcs();
1661
1662         if(cvar("sv_eventlog"))
1663                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1664         bprint ("^4",self.netname);
1665         bprint ("^4 disconnected\n");
1666
1667         SoundEntity_Detach(self);
1668
1669         DropAllRunes(self);
1670         MUTATOR_CALLHOOK(ClientDisconnect);
1671
1672         Portal_ClearAll(self);
1673
1674         if(self.flagcarried)
1675                 DropFlag(self.flagcarried, world, world);
1676         if(self.ballcarried)
1677                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1678
1679         // Here, everything has been done that requires this player to be a client.
1680
1681         self.flags &~= FL_CLIENT;
1682
1683         if (self.chatbubbleentity)
1684                 remove (self.chatbubbleentity);
1685
1686         if (self.teambubbleentity)
1687                 remove (self.teambubbleentity);
1688
1689         if (self.killindicator)
1690                 remove (self.killindicator);
1691
1692         WaypointSprite_PlayerGone();
1693
1694         bot_relinkplayerlist();
1695
1696         // remove laserdot
1697         if(self.weaponentity)
1698                 if(self.weaponentity.lasertarget)
1699                         remove(self.weaponentity.lasertarget);
1700
1701         if(g_arena)
1702         {
1703                 Spawnqueue_Unmark(self);
1704                 Spawnqueue_Remove(self);
1705         }
1706
1707         ClientData_Detach();
1708         PlayerScore_Detach(self);
1709
1710         if(self.netname_previous)
1711                 strunzone(self.netname_previous);
1712         if(self.clientstatus)
1713                 strunzone(self.clientstatus);
1714
1715         ClearPlayerSounds();
1716
1717         if(self.personal)
1718                 remove(self.personal);
1719
1720         self.playerid = 0;
1721         ReadyCount();
1722
1723         // free cvars
1724         GetCvars(-1);
1725 }
1726
1727 .float BUTTON_CHAT;
1728 void ChatBubbleThink()
1729 {
1730         self.nextthink = time;
1731         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1732         {
1733                 if(self.owner) // but why can that ever be world?
1734                         self.owner.chatbubbleentity = world;
1735                 remove(self);
1736                 return;
1737         }
1738         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1739 #ifdef TETRIS
1740                 || self.owner.tetris_on
1741 #endif
1742         )
1743                 self.model = self.mdl;
1744         else
1745                 self.model = "";
1746 };
1747
1748 void UpdateChatBubble()
1749 {
1750         if (!self.modelindex)
1751                 return;
1752         // spawn a chatbubble entity if needed
1753         if (!self.chatbubbleentity)
1754         {
1755                 self.chatbubbleentity = spawn();
1756                 self.chatbubbleentity.owner = self;
1757                 self.chatbubbleentity.exteriormodeltoclient = self;
1758                 self.chatbubbleentity.think = ChatBubbleThink;
1759                 self.chatbubbleentity.nextthink = time;
1760                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1761                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1762                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1763                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1764                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1765                 self.chatbubbleentity.model = "";
1766                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1767         }
1768 }
1769
1770
1771 void TeamBubbleThink()
1772 {
1773         self.nextthink = time;
1774         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1775         {
1776                 if(self.owner) // but why can that ever be world?
1777                         self.owner.teambubbleentity = world;
1778                 remove(self);
1779                 return;
1780         }
1781 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1782         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1783                 self.model = "";
1784         else
1785                 self.model = self.mdl;
1786
1787 };
1788
1789 float TeamBubble_customizeentityforclient()
1790 {
1791         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1792 }
1793
1794 void UpdateTeamBubble()
1795 {
1796         if (!self.modelindex || !teams_matter)
1797                 return;
1798         // spawn a teambubble entity if needed
1799         if (!self.teambubbleentity && teams_matter)
1800         {
1801                 self.teambubbleentity = spawn();
1802                 self.teambubbleentity.owner = self;
1803                 self.teambubbleentity.exteriormodeltoclient = self;
1804                 self.teambubbleentity.think = TeamBubbleThink;
1805                 self.teambubbleentity.nextthink = time;
1806                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1807 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1808                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1809                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1810                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1811                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1812                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1813                 self.teambubbleentity.effects = EF_LOWPRECISION;
1814         }
1815 }
1816
1817 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1818 // added to the model skins
1819 /*void UpdateColorModHack()
1820 {
1821         local float c;
1822         c = self.clientcolors & 15;
1823         // LordHavoc: only bothering to support white, green, red, yellow, blue
1824              if (!teams_matter) self.colormod = '0 0 0';
1825         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1826         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1827         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1828         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1829         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1830         else self.colormod = '1 1 1';
1831 };*/
1832
1833 .float oldcolormap;
1834 void respawn(void)
1835 {
1836         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1837         {
1838                 self.solid = SOLID_NOT;
1839                 self.takedamage = DAMAGE_NO;
1840                 self.movetype = MOVETYPE_FLY;
1841                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1842                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1843                 self.effects |= EF_ADDITIVE;
1844                 self.oldcolormap = self.colormap;
1845                 self.colormap = 512;
1846                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1847                 if(cvar("g_respawn_ghosts_maxtime"))
1848                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1849         }
1850
1851         CopyBody(1);
1852         self.effects |= EF_NODRAW; // prevent another CopyBody
1853         if(self.oldcolormap)
1854         {
1855                 self.colormap = self.oldcolormap;
1856                 self.oldcolormap = 0;
1857         }
1858         PutClientInServer();
1859 }
1860
1861 void play_countdown(float finished, string samp)
1862 {
1863         if(clienttype(self) == CLIENTTYPE_REAL)
1864                 if(floor(finished - time - frametime) != floor(finished - time))
1865                         if(finished - time < 6)
1866                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1867 }
1868
1869 /**
1870  * When sv_timeout is used this function returs strings like
1871  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1872  * Called by centerprint functions
1873  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1874  */
1875 string getTimeoutText(float addOneSecond) {
1876         if (!cvar("sv_timeout") || !timeoutStatus)
1877                 return "";
1878
1879         local string retStr;
1880         if (timeoutStatus == 1) {
1881                 if (addOneSecond == 1) {
1882                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1883                 }
1884                 else {
1885                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1886                 }
1887                 return retStr;
1888         }
1889         else if (timeoutStatus == 2) {
1890                 if (addOneSecond) {
1891                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1892                         //don't show messages like "Timeout ends in 0 seconds"...
1893                         if ((remainingTimeoutTime + 1) > 0)
1894                                 return retStr;
1895                         else
1896                                 return "";
1897                 }
1898                 else {
1899                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1900                         //don't show messages like "Timeout ends in 0 seconds"...
1901                         if (remainingTimeoutTime > 0)
1902                                 return retStr;
1903                         else
1904                                 return "";
1905                 }
1906         }
1907         else return "";
1908 }
1909
1910 void player_powerups (void)
1911 {
1912         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1913         {
1914                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1915                 self.modelflags |= MF_ROCKET;
1916         }
1917         else
1918         {
1919                 SoundEntity_StopSound(self, CHAN_PLAYER);
1920                 self.modelflags &~= MF_ROCKET;
1921         }
1922
1923         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1924
1925         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1926                 return;
1927         
1928         Fire_ApplyDamage(self);
1929         Fire_ApplyEffect(self);
1930
1931         if (g_minstagib)
1932         {
1933                 self.effects |= EF_FULLBRIGHT;
1934
1935                 if (self.items & IT_STRENGTH)
1936                 {
1937                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1938                         if (time > self.strength_finished)
1939                         {
1940                                 self.alpha = default_player_alpha;
1941                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1942                                 self.items &~= IT_STRENGTH;
1943                                 sprint(self, "^3Invisibility has worn off\n");
1944                         }
1945                 }
1946                 else
1947                 {
1948                         if (time < self.strength_finished)
1949                         {
1950                                 self.alpha = g_minstagib_invis_alpha;
1951                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1952                                 self.items |= IT_STRENGTH;
1953                                 sprint(self, "^3You are invisible\n");
1954                         }
1955                 }
1956
1957                 if (self.items & IT_INVINCIBLE)
1958                 {
1959                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1960                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1961                         {
1962                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1963                                 sprint(self, "^3Speed has worn off\n");
1964                         }
1965                 }
1966                 else
1967                 {
1968                         if (time < self.invincible_finished)
1969                         {
1970                                 self.items = self.items | IT_INVINCIBLE;
1971                                 sprint(self, "^3You are on speed\n");
1972                         }
1973                 }
1974                 return;
1975         }
1976
1977         if (self.items & IT_STRENGTH)
1978         {
1979                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1980                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1981                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1982                 {
1983                         self.items = self.items - (self.items & IT_STRENGTH);
1984                         sprint(self, "^3Strength has worn off\n");
1985                 }
1986         }
1987         else
1988         {
1989                 if (time < self.strength_finished)
1990                 {
1991                         self.items = self.items | IT_STRENGTH;
1992                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1993                 }
1994         }
1995         if (self.items & IT_INVINCIBLE)
1996         {
1997                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1998                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1999                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2000                 {
2001                         self.items = self.items - (self.items & IT_INVINCIBLE);
2002                         sprint(self, "^3Shield has worn off\n");
2003                 }
2004         }
2005         else
2006         {
2007                 if (time < self.invincible_finished)
2008                 {
2009                         self.items = self.items | IT_INVINCIBLE;
2010                         sprint(self, "^3Shield surrounds you\n");
2011                 }
2012         }
2013
2014         if(cvar("g_nodepthtestplayers"))
2015                 self.effects = self.effects | EF_NODEPTHTEST;
2016
2017         if(cvar("g_fullbrightplayers"))
2018                 self.effects = self.effects | EF_FULLBRIGHT;
2019
2020         // midair gamemode: damage only while in the air
2021         // if in midair mode, being on ground grants temporary invulnerability
2022         // (this is so that multishot weapon don't clear the ground flag on the
2023         // first damage in the frame, leaving the player vulnerable to the
2024         // remaining hits in the same frame)
2025         if (self.flags & FL_ONGROUND)
2026         if (g_midair)
2027                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2028
2029         if (time >= game_starttime)
2030         if (time < self.spawnshieldtime)
2031                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2032 }
2033
2034 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2035 {
2036         if(current > stable)
2037                 return current;
2038         else if(current > stable - 0.25) // when close enough, "snap"
2039                 return stable;
2040         else
2041                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2042 }
2043
2044 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2045 {
2046         if(current < stable)
2047                 return current;
2048         else if(current < stable + 0.25) // when close enough, "snap"
2049                 return stable;
2050         else
2051                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2052 }
2053
2054 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2055 {
2056         if(current > rotstable)
2057         {
2058                 if(rotframetime > 0)
2059                 {
2060                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2061                         current = max(rotstable, current - rotlinear * rotframetime);
2062                 }
2063         }
2064         else if(current < regenstable)
2065         {
2066                 if(regenframetime > 0)
2067                 {
2068                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2069                         current = min(regenstable, current + regenlinear * regenframetime);
2070                 }
2071         }
2072
2073         if(current > limit)
2074                 current = limit;
2075
2076         return current;
2077 }
2078
2079 void player_regen (void)
2080 {
2081         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2082         maxh = cvar("g_balance_health_rotstable");
2083         maxa = cvar("g_balance_armor_rotstable");
2084         maxf = cvar("g_balance_fuel_rotstable");
2085         minh = cvar("g_balance_health_regenstable");
2086         mina = cvar("g_balance_armor_regenstable");
2087         minf = cvar("g_balance_fuel_regenstable");
2088         limith = cvar("g_balance_health_limit");
2089         limita = cvar("g_balance_armor_limit");
2090         limitf = cvar("g_balance_fuel_limit");
2091
2092         max_mod = regen_mod = rot_mod = limit_mod = 1;
2093
2094         if (self.runes & RUNE_REGEN)
2095         {
2096                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2097                 {
2098                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2099                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2100                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2101                 }
2102                 else
2103                 {
2104                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2105                         max_mod = cvar("g_balance_rune_regen_hpmod");
2106                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2107                 }
2108         }
2109         else if (self.runes & CURSE_VENOM)
2110         {
2111                 max_mod = cvar("g_balance_curse_venom_hpmod");
2112                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2113                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2114                 else
2115                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2116                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2117                 //if (!self.runes & RUNE_REGEN)
2118                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2119         }
2120         maxh = maxh * max_mod;
2121         //maxa = maxa * max_mod;
2122         //maxf = maxf * max_mod;
2123         minh = minh * max_mod;
2124         //mina = mina * max_mod;
2125         //minf = minf * max_mod;
2126         limith = limith * limit_mod;
2127         limita = limita * limit_mod;
2128         //limitf = limitf * limit_mod;
2129
2130         if(g_lms && g_ca)
2131                 rot_mod = 0;
2132
2133         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2134         {
2135                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2136                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2137
2138                 // if player rotted to death...  die!
2139                 if(self.health < 1)
2140                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2141         }
2142
2143         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2144                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2145 }
2146
2147 float zoomstate_set;
2148 void SetZoomState(float z)
2149 {
2150         if(z != self.zoomstate)
2151         {
2152                 self.zoomstate = z;
2153                 ClientData_Touch(self);
2154         }
2155         zoomstate_set = 1;
2156 }
2157
2158 void GetPressedKeys(void) {
2159         MUTATOR_CALLHOOK(GetPressedKeys);
2160         if (self.movement_x > 0) // get if movement keys are pressed
2161         {       // forward key pressed
2162                 self.pressedkeys |= KEY_FORWARD;
2163                 self.pressedkeys &~= KEY_BACKWARD;
2164         }
2165         else if (self.movement_x < 0)
2166         {       // backward key pressed
2167                 self.pressedkeys |= KEY_BACKWARD;
2168                 self.pressedkeys &~= KEY_FORWARD;
2169         }
2170         else
2171         {       // no x input
2172                 self.pressedkeys &~= KEY_FORWARD;
2173                 self.pressedkeys &~= KEY_BACKWARD;
2174         }
2175
2176         if (self.movement_y > 0)
2177         {       // right key pressed
2178                 self.pressedkeys |= KEY_RIGHT;
2179                 self.pressedkeys &~= KEY_LEFT;
2180         }
2181         else if (self.movement_y < 0)
2182         {       // left key pressed
2183                 self.pressedkeys |= KEY_LEFT;
2184                 self.pressedkeys &~= KEY_RIGHT;
2185         }
2186         else
2187         {       // no y input
2188                 self.pressedkeys &~= KEY_RIGHT;
2189                 self.pressedkeys &~= KEY_LEFT;
2190         }
2191
2192         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2193                 self.pressedkeys |= KEY_JUMP;
2194         else
2195                 self.pressedkeys &~= KEY_JUMP;
2196         if (self.BUTTON_CROUCH)
2197                 self.pressedkeys |= KEY_CROUCH;
2198         else
2199                 self.pressedkeys &~= KEY_CROUCH;
2200 }
2201
2202 void update_stats (float number, float hit, float fired) {
2203 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2204 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2205
2206         if(number) {
2207                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2208                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2209         } else {
2210                 self.stat_hit = hit * sv_accuracy_data_share;
2211                 self.stat_fired = fired * sv_accuracy_data_share;
2212         }
2213 }
2214
2215 /*
2216 ======================
2217 spectate mode routines
2218 ======================
2219 */
2220
2221 .float weapon_count;
2222 void SpectateCopy(entity spectatee) {
2223         if(spectatee.weapon_count < WEP_LAST) {
2224                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2225                 spectatee.weapon_count ++;
2226         } else
2227                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2228
2229         other = spectatee;
2230         MUTATOR_CALLHOOK(SpectateCopy);
2231         self.armortype = spectatee.armortype;
2232         self.armorvalue = spectatee.armorvalue;
2233         self.ammo_cells = spectatee.ammo_cells;
2234         self.ammo_shells = spectatee.ammo_shells;
2235         self.ammo_nails = spectatee.ammo_nails;
2236         self.ammo_rockets = spectatee.ammo_rockets;
2237         self.ammo_fuel = spectatee.ammo_fuel;
2238         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2239         self.health = spectatee.health;
2240         self.impulse = 0;
2241         self.items = spectatee.items;
2242         self.metertime = spectatee.metertime;
2243         self.strength_finished = spectatee.strength_finished;
2244         self.invincible_finished = spectatee.invincible_finished;
2245         self.pressedkeys = spectatee.pressedkeys;
2246         self.weapons = spectatee.weapons;
2247         self.switchweapon = spectatee.switchweapon;
2248         self.weapon = spectatee.weapon;
2249         self.punchangle = spectatee.punchangle;
2250         self.view_ofs = spectatee.view_ofs;
2251         self.v_angle = spectatee.v_angle;
2252         self.velocity = spectatee.velocity;
2253         self.dmg_take = spectatee.dmg_take;
2254         self.dmg_save = spectatee.dmg_save;
2255         self.dmg_inflictor = spectatee.dmg_inflictor;
2256         self.angles = spectatee.v_angle;
2257         self.fixangle = TRUE;
2258         setorigin(self, spectatee.origin);
2259         setsize(self, spectatee.mins, spectatee.maxs);
2260         SetZoomState(spectatee.zoomstate);
2261
2262         anticheat_spectatecopy(spectatee);
2263 }
2264
2265 float SpectateUpdate() {
2266         if(!self.enemy)
2267                 return 0;
2268
2269         if (self == self.enemy)
2270                 return 0;
2271
2272         if(self.enemy.classname != "player")
2273                 return 0;
2274
2275         SpectateCopy(self.enemy);
2276
2277         return 1;
2278 }
2279
2280 float SpectateNext() {
2281         other = find(self.enemy, classname, "player");
2282
2283         if (!other)
2284                 other = find(other, classname, "player");
2285
2286         if (other)
2287                 self.enemy = other;
2288
2289         if(self.enemy.classname == "player") {
2290                 msg_entity = self;
2291                 WriteByte(MSG_ONE, SVC_SETVIEW);
2292                 WriteEntity(MSG_ONE, self.enemy);
2293                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2294                 self.movetype = MOVETYPE_NONE;
2295
2296                 self.enemy.weapon_count = 0;
2297
2298                 if(!SpectateUpdate())
2299                         PutObserverInServer();
2300
2301                 return 1;
2302         } else {
2303                 return 0;
2304         }
2305 }
2306
2307 /*
2308 =============
2309 ShowRespawnCountdown()
2310
2311 Update a respawn countdown display.
2312 =============
2313 */
2314 void ShowRespawnCountdown()
2315 {
2316         float number;
2317         if(self.deadflag == DEAD_NO) // just respawned?
2318                 return;
2319         else
2320         {
2321                 number = ceil(self.death_time - time);
2322                 if(number <= 0)
2323                         return;
2324                 if(number <= self.respawn_countdown)
2325                 {
2326                         self.respawn_countdown = number - 1;
2327                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2328                                 AnnounceTo(self, strcat(ftos(number), ""));
2329                 }
2330         }
2331 }
2332
2333 void LeaveSpectatorMode()
2334 {
2335         if(isJoinAllowed()) {
2336                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2337                         self.classname = "player";
2338
2339                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2340                                 JoinBestTeam(self, FALSE, TRUE);
2341
2342                         if(cvar("g_campaign"))
2343                                 campaign_bots_may_start = 1;
2344
2345                         self.stat_count = WEP_LAST;
2346
2347                         PutClientInServer();
2348
2349                         if(self.classname == "player")
2350                                 bprint ("^4", self.netname, "^4 is playing now\n");
2351
2352                         if(!cvar("g_campaign"))
2353                                 centerprint(self,""); // clear MOTD
2354
2355                         return;
2356                 } else {
2357                         if (g_ca && self.caplayer) {
2358                         }       // do nothing
2359                         else
2360                                 stuffcmd(self,"menu_showteamselect\n");
2361                         return;
2362                 }
2363         }
2364         else {
2365                 //player may not join because of g_maxplayers is set
2366                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2367         }
2368 }
2369
2370 /**
2371  * Determines whether the player is allowed to join. This depends on cvar
2372  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2373  * it checks whether the number of currently playing players exceeds g_maxplayers.
2374  * @return bool TRUE if the player is allowed to join, false otherwise
2375  */
2376 float isJoinAllowed() {
2377         if (!cvar("g_maxplayers"))
2378                 return TRUE;
2379
2380         local entity e;
2381         local float currentlyPlaying;
2382         FOR_EACH_REALPLAYER(e) {
2383                 if(e.classname == "player")
2384                         currentlyPlaying += 1;
2385         }
2386         if(currentlyPlaying < cvar("g_maxplayers"))
2387                 return TRUE;
2388
2389         return FALSE;
2390 }
2391
2392 /**
2393  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2394  * g_maxplayers_spectator_blocktime seconds
2395  */
2396 void checkSpectatorBlock() {
2397         if(self.classname == "spectator" || self.classname == "observer") {
2398                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2399                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2400                         dropclient(self);
2401                 }
2402         }
2403 }
2404
2405 float vercmp_recursive(string v1, string v2)
2406 {
2407         float dot1, dot2;
2408         string s1, s2;
2409         float r;
2410
2411         dot1 = strstrofs(v1, ".", 0);
2412         dot2 = strstrofs(v2, ".", 0);
2413         if(dot1 == -1)
2414                 s1 = v1;
2415         else
2416                 s1 = substring(v1, 0, dot1);
2417         if(dot2 == -1)
2418                 s2 = v2;
2419         else
2420                 s2 = substring(v2, 0, dot2);
2421
2422         r = stof(s1) - stof(s2);
2423         if(r != 0)
2424                 return r;
2425
2426         r = strcasecmp(s1, s2);
2427         if(r != 0)
2428                 return r;
2429
2430         if(dot1 == -1)
2431                 if(dot2 == -1)
2432                         return 0;
2433                 else
2434                         return -1;
2435         else
2436                 if(dot2 == -1)
2437                         return 1;
2438                 else
2439                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2440 }
2441
2442 float vercmp(string v1, string v2)
2443 {
2444         if(strcasecmp(v1, v2) == 0) // early out check
2445                 return 0;
2446         return vercmp_recursive(v1, v2);
2447 }
2448
2449 void ObserverThink()
2450 {
2451         if (self.flags & FL_JUMPRELEASED) {
2452                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2453                         self.welcomemessage_time = 0;
2454                         self.flags &~= FL_JUMPRELEASED;
2455                         self.flags |= FL_SPAWNING;
2456                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2457                         self.welcomemessage_time = 0;
2458                         self.flags &~= FL_JUMPRELEASED;
2459                         if(SpectateNext() == 1) {
2460                                 self.classname = "spectator";
2461                         }
2462                 }
2463         } else {
2464                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2465                         self.flags |= FL_JUMPRELEASED;
2466                         if(self.flags & FL_SPAWNING)
2467                         {
2468                                 self.flags &~= FL_SPAWNING;
2469                                 LeaveSpectatorMode();
2470                                 return;
2471                         }
2472                 }
2473         }
2474         PrintWelcomeMessage(self);
2475 }
2476
2477 void SpectatorThink()
2478 {
2479         if (self.flags & FL_JUMPRELEASED) {
2480                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2481                         self.welcomemessage_time = 0;
2482                         self.flags &~= FL_JUMPRELEASED;
2483                         self.flags |= FL_SPAWNING;
2484                 } else if(self.BUTTON_ATCK) {
2485                         self.welcomemessage_time = 0;
2486                         self.flags &~= FL_JUMPRELEASED;
2487                         if(SpectateNext() == 1) {
2488                                 self.classname = "spectator";
2489                         } else {
2490                                 self.classname = "observer";
2491                                 self.stat_count = WEP_LAST;
2492                                 PutClientInServer();
2493                         }
2494                 } else if (self.BUTTON_ATCK2) {
2495                         self.welcomemessage_time = 0;
2496                         self.flags &~= FL_JUMPRELEASED;
2497                         self.classname = "observer";
2498                         self.stat_count = WEP_LAST;
2499                         PutClientInServer();
2500                 } else {
2501                         if(!SpectateUpdate())
2502                                 PutObserverInServer();
2503                 }
2504         } else {
2505                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2506                         self.flags |= FL_JUMPRELEASED;
2507                         if(self.flags & FL_SPAWNING)
2508                         {
2509                                 self.flags &~= FL_SPAWNING;
2510                                 LeaveSpectatorMode();
2511                                 return;
2512                         }
2513                 }
2514         }
2515
2516         PrintWelcomeMessage(self);
2517         self.flags |= FL_CLIENT | FL_NOTARGET;
2518 }
2519
2520 .float touchexplode_time;
2521
2522 /*
2523 =============
2524 PlayerPreThink
2525
2526 Called every frame for each client before the physics are run
2527 =============
2528 */
2529 void() ctf_setstatus;
2530 void() nexball_setstatus;
2531 .float items_added;
2532 void PlayerPreThink (void)
2533 {
2534         self.stat_game_starttime = game_starttime;
2535         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2536         self.stat_leadlimit = cvar("leadlimit");
2537
2538         if(frametime)
2539         {
2540                 // physics frames: update anticheat stuff
2541                 anticheat_prethink();
2542         }
2543
2544         if(blockSpectators && frametime)
2545                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2546                 checkSpectatorBlock();
2547
2548         zoomstate_set = 0;
2549
2550         if(self.netname_previous != self.netname)
2551         {
2552                 if(cvar("sv_eventlog"))
2553                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2554                 if(self.netname_previous)
2555                         strunzone(self.netname_previous);
2556                 self.netname_previous = strzone(self.netname);
2557         }
2558
2559         // version nagging
2560         if(self.version_nagtime)
2561                 if(self.cvar_g_xonoticversion)
2562                         if(time > self.version_nagtime)
2563                         {
2564                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2565                                 {
2566                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2567                                         {
2568                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2569                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2570                                         }
2571                                         else
2572                                         {
2573                                                 float r;
2574                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2575                                                 if(r < 0)
2576                                                 {
2577                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2578                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2579                                                 }
2580                                                 else if(r > 0)
2581                                                 {
2582                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2583                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2584                                                 }
2585                                         }
2586                                 }
2587                                 self.version_nagtime = 0;
2588                         }
2589
2590         // GOD MODE info
2591         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2592         {
2593                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2594                 self.max_armorvalue = 0;
2595         }
2596
2597 #ifdef TETRIS
2598         if (TetrisPreFrame())
2599                 return;
2600 #endif
2601
2602         MUTATOR_CALLHOOK(PlayerPreThink);
2603
2604         if(self.classname == "player") {
2605 //              if(self.netname == "Wazat")
2606 //                      bprint(self.classname, "\n");
2607
2608                 CheckRules_Player();
2609
2610                 PrintWelcomeMessage(self);
2611
2612                 if (intermission_running)
2613                 {
2614                         IntermissionThink ();   // otherwise a button could be missed between
2615                         return;                                 // the think tics
2616                 }
2617
2618                 if(self.teleport_time)
2619                 if(time > self.teleport_time)
2620                 {
2621                         self.teleport_time = 0;
2622                         self.effects = self.effects - (self.effects & EF_NODRAW);
2623                 }
2624
2625                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2626                         UpdateSelectedPlayer();
2627
2628                 //don't allow the player to turn around while game is paused!
2629                 if(timeoutStatus == 2) {
2630                         self.v_angle = self.lastV_angle;
2631                         self.angles = self.lastV_angle;
2632                         self.fixangle = TRUE;
2633                 }
2634
2635                 if(frametime)
2636                 {
2637                         if(self.health <= 0 && cvar("g_deathglow"))
2638                         {
2639                                 if(self.glowmod_x > 0)
2640                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2641                                 else
2642                                         self.glowmod_x = -1;
2643                                 if(self.glowmod_y > 0)
2644                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2645                                 else
2646                                         self.glowmod_y = -1;
2647                                 if(self.glowmod_z > 0)
2648                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2649                                 else
2650                                         self.glowmod_z = -1;
2651                         }
2652                         else
2653                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2654                         player_powerups();
2655                 }
2656
2657                 if (self.deadflag != DEAD_NO)
2658                 {
2659                         float button_pressed, force_respawn;
2660                         if(self.personal && g_race_qualifying)
2661                         {
2662                                 if(time > self.death_time)
2663                                 {
2664                                         self.death_time = time + 1; // only retry once a second
2665                                         respawn();
2666                                         self.impulse = 141;
2667                                 }
2668                         }
2669                         else
2670                         {
2671                                 if(frametime)
2672                                         player_anim();
2673                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2674                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2675                                 if (self.deadflag == DEAD_DYING)
2676                                 {
2677                                         if(force_respawn)
2678                                                 self.deadflag = DEAD_RESPAWNING;
2679                                         else if(!button_pressed)
2680                                                 self.deadflag = DEAD_DEAD;
2681                                 }
2682                                 else if (self.deadflag == DEAD_DEAD)
2683                                 {
2684                                         if(button_pressed)
2685                                                 self.deadflag = DEAD_RESPAWNABLE;
2686                                 }
2687                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2688                                 {
2689                                         if(!button_pressed)
2690                                                 self.deadflag = DEAD_RESPAWNING;
2691                                 }
2692                                 else if (self.deadflag == DEAD_RESPAWNING)
2693                                 {
2694                                         if(time > self.death_time)
2695                                         {
2696                                                 self.death_time = time + 1; // only retry once a second
2697                                                 respawn();
2698                                         }
2699                                 }
2700                                 ShowRespawnCountdown();
2701                         }
2702                         return;
2703                 }
2704
2705                 if(g_touchexplode)
2706                 if(time > self.touchexplode_time)
2707                 if(self.classname == "player")
2708                 if(self.deadflag == DEAD_NO)
2709                 if not(IS_INDEPENDENT_PLAYER(self))
2710                 FOR_EACH_PLAYER(other) if(self != other)
2711                 {
2712                         if(time > other.touchexplode_time)
2713                         if(other.deadflag == DEAD_NO)
2714                         if not(IS_INDEPENDENT_PLAYER(other))
2715                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2716                         {
2717                                 PlayerTouchExplode(self, other);
2718                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2719                         }
2720                 }
2721
2722                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2723                 {
2724                         vector dist;
2725
2726                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2727                         dist = self.prevorigin - self.origin;
2728                         dist_z = 0;
2729                         self.lms_traveled_distance += fabs(vlen(dist));
2730
2731                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2732                         {
2733                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2734                                 self.lms_traveled_distance = 0;
2735                         }
2736
2737                         if(time > self.lms_nextcheck)
2738                         {
2739                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2740                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2741                                 {
2742                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2743                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2744                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2745                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2746                                 }
2747                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2748                                 self.lms_traveled_distance = 0;
2749                         }
2750                 }
2751
2752                 self.prevorigin = self.origin;
2753
2754                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2755                 {
2756                         if (!self.crouch)
2757                         {
2758                                 self.crouch = TRUE;
2759                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2760                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2761                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2762                         }
2763                 }
2764                 else
2765                 {
2766                         if (self.crouch)
2767                         {
2768                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2769                                 if (!trace_startsolid)
2770                                 {
2771                                         self.crouch = FALSE;
2772                                         self.view_ofs = PL_VIEW_OFS;
2773                                         setsize (self, PL_MIN, PL_MAX);
2774                                 }
2775                         }
2776                 }
2777
2778                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2779                 {
2780                         if(self.bloodloss_timer < time)
2781                         {
2782                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2783                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2784                         }
2785                 }
2786
2787                 FixPlayermodel();
2788
2789                 GrapplingHookFrame();
2790
2791                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2792                 //if(frametime)
2793                 {
2794                         self.items &~= self.items_added;
2795
2796                         W_WeaponFrame();
2797
2798                         self.items_added = 0;
2799                         if(self.items & IT_JETPACK)
2800                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2801                                         self.items_added |= IT_FUEL;
2802
2803                         self.items |= self.items_added;
2804                 }
2805
2806                 player_regen();
2807                 if(frametime)
2808                         player_anim();
2809
2810                 if (g_minstagib)
2811                         minstagib_ammocheck();
2812
2813                 ctf_setstatus();
2814                 nexball_setstatus();
2815
2816                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2817
2818                 //self.angles_y=self.v_angle_y + 90;   // temp
2819         } else if(gameover) {
2820                 if (intermission_running)
2821                         IntermissionThink ();   // otherwise a button could be missed between
2822                 return;
2823         } else if(self.classname == "observer") {
2824                 ObserverThink();
2825         } else if(self.classname == "spectator") {
2826                 SpectatorThink();
2827         }
2828
2829         if(!zoomstate_set)
2830                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2831
2832         float oldspectatee_status;
2833         oldspectatee_status = self.spectatee_status;
2834         if(self.classname == "spectator")
2835                 self.spectatee_status = num_for_edict(self.enemy);
2836         else if(self.classname == "observer")
2837                 self.spectatee_status = num_for_edict(self);
2838         else
2839                 self.spectatee_status = 0;
2840         if(self.spectatee_status != oldspectatee_status)
2841         {
2842                 ClientData_Touch(self);
2843                 if(g_race || g_cts)
2844                         race_InitSpectator();
2845         }
2846
2847         if(self.teamkill_soundtime)
2848         if(time > self.teamkill_soundtime)
2849         {
2850                 self.teamkill_soundtime = 0;
2851
2852                 entity oldpusher, oldself;
2853
2854                 oldself = self; self = self.teamkill_soundsource;
2855                 oldpusher = self.pusher; self.pusher = oldself;
2856
2857                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2858
2859                 self.pusher = oldpusher;
2860                 self = oldself;
2861         }
2862
2863         if(self.taunt_soundtime)
2864         if(time > self.taunt_soundtime)
2865         {
2866                 self.taunt_soundtime = 0;
2867                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2868         }
2869
2870         target_voicescript_next(self);
2871 }
2872
2873 float isInvisibleString(string s)
2874 {
2875         float i, n, c;
2876         s = strdecolorize(s);
2877         for((i = 0), (n = strlen(s)); i < n; ++i)
2878         {
2879                 c = str2chr(s, i);
2880                 switch(c)
2881                 {
2882                         case 0:
2883                         case 32: // space
2884                                 break;
2885                         case 192: // charmap space
2886                                 if (!cvar("utf8_enable"))
2887                                         break;
2888                                 return FALSE;
2889                         case 160: // space in unicode fonts
2890                         case 0xE000 + 192: // utf8 charmap space
2891                                 if (cvar("utf8_enable"))
2892                                         break;
2893                         default:
2894                                 return FALSE;
2895                 }
2896         }
2897         return TRUE;
2898 }
2899
2900 /*
2901 =============
2902 PlayerPostThink
2903
2904 Called every frame for each client after the physics are run
2905 =============
2906 */
2907 .float idlekick_lasttimeleft;
2908 .entity showheadshotbbox;
2909 void showheadshotbbox_think()
2910 {
2911         if(self.owner.showheadshotbbox != self)
2912         {
2913                 remove(self);
2914                 return;
2915         }
2916         self.nextthink = time;
2917         setorigin(self, self.owner.origin);
2918         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2919 }
2920 void PlayerPostThink (void)
2921 {
2922         // Savage: Check for nameless players
2923         if (isInvisibleString(self.netname)) {
2924                 self.netname = "Player";
2925                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2926         }
2927
2928         // send the clients accuracy stats to the client
2929         if(self.stat_count > 0)
2930         if(frametime)
2931         {
2932                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2933                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2934                 self.stat_count -= 1;
2935         }
2936
2937 #ifdef UID
2938         if(self.uid_kicktime)
2939         if(time > self.uid_kicktime)
2940         {
2941                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2942                 dropclient(self);
2943                 return;
2944         }
2945 #endif
2946
2947         if(sv_maxidle && frametime)
2948         {
2949                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2950                 float timeleft;
2951                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2952                 if(timeleft <= 0)
2953                 {
2954                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2955                         AnnounceTo(self, "terminated");
2956                         dropclient(self);
2957                         return;
2958                 }
2959                 else if(timeleft <= 10)
2960                 {
2961                         if(timeleft != self.idlekick_lasttimeleft)
2962                         {
2963                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2964                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2965                         }
2966                 }
2967                 else
2968                 {
2969                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2970                 }
2971                 self.idlekick_lasttimeleft = timeleft;
2972         }
2973
2974 #ifdef TETRIS
2975         if(self.impulse == 100)
2976                 ImpulseCommands();
2977         if (TetrisPostFrame())
2978                 return;
2979 #endif
2980
2981         CheatFrame();
2982
2983         if(self.classname == "player") {
2984                 CheckRules_Player();
2985                 UpdateChatBubble();
2986                 UpdateTeamBubble();
2987                 if (self.impulse)
2988                         ImpulseCommands();
2989                 if (intermission_running)
2990                         return;         // intermission or finale
2991                 GetPressedKeys();
2992         } else if (self.classname == "observer") {
2993                 //do nothing
2994         } else if (self.classname == "spectator") {
2995                 //do nothing
2996         }
2997
2998         /*
2999         float i;
3000         for(i = 0; i < 1000; ++i)
3001         {
3002                 vector end;
3003                 end = self.origin + '0 0 1024' + 512 * randomvec();
3004                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3005                 if(trace_fraction < 1)
3006                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3007                 {
3008                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3009                         break;
3010                 }
3011         }
3012         */
3013
3014         Arena_Warmup();
3015
3016         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3017
3018         if(self.waypointsprite_attachedforcarrier)
3019                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3020         
3021         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3022         {
3023                 if(!self.showheadshotbbox)
3024                 {
3025                         self.showheadshotbbox = spawn();
3026                         self.showheadshotbbox.classname = "headshotbbox";
3027                         self.showheadshotbbox.owner = self;
3028                         self.showheadshotbbox.think = showheadshotbbox_think;
3029                         self.showheadshotbbox.nextthink = time;
3030                         self = self.showheadshotbbox;
3031                         self.think();
3032                         self = self.owner;
3033                 }
3034         }
3035         else
3036         {
3037                 if(self.showheadshotbbox)
3038                         remove(self.showheadshotbbox);
3039         }
3040
3041         playerdemo_write();
3042
3043         /*
3044         if(g_race)
3045                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3046         */
3047 }