Merge remote-tracking branch 'origin/master' into terencehill/hud_code_restructure
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 float ClientData_Send(entity to, float sf)
10 {
11         if(to != self.owner)
12         {
13                 error("wtf");
14                 return FALSE;
15         }
16
17         entity e;
18
19         e = to;
20         if(to.classname == "spectator")
21                 e = to.enemy;
22
23         sf = 0;
24
25         if(e.race_completed)
26                 sf |= 1; // forced scoreboard
27         if(to.spectatee_status)
28                 sf |= 2; // spectator ent number follows
29         if(e.zoomstate)
30                 sf |= 4; // zoomed
31         if(e.porto_v_angle_held)
32                 sf |= 8; // angles held
33
34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
35         WriteByte(MSG_ENTITY, sf);
36
37         if(sf & 2)
38                 WriteByte(MSG_ENTITY, to.spectatee_status);
39
40         if(sf & 8)
41         {
42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
44         }
45
46         return TRUE;
47 }
48
49 void ClientData_Attach()
50 {
51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
52         self.clientdata.drawonlytoclient = self;
53         self.clientdata.owner = self;
54 }
55
56 void ClientData_Detach()
57 {
58         remove(self.clientdata);
59         self.clientdata = world;
60 }
61
62 void ClientData_Touch(entity e)
63 {
64         e.clientdata.SendFlags = 1;
65
66         // make it spectatable
67         entity e2;
68         FOR_EACH_REALCLIENT(e2)
69         {
70                 if(e2 != e)
71                         if(e2.classname == "spectator")
72                                 if(e2.enemy == e)
73                                         e2.clientdata.SendFlags = 1;
74         }
75 }
76
77
78 .vector spawnpoint_score;
79 .string netname_previous;
80
81 void spawnfunc_info_player_survivor (void)
82 {
83         spawnfunc_info_player_deathmatch();
84 }
85
86 void spawnfunc_info_player_start (void)
87 {
88         spawnfunc_info_player_deathmatch();
89 }
90
91 void spawnfunc_info_player_deathmatch (void)
92 {
93         self.classname = "info_player_deathmatch";
94         relocate_spawnpoint();
95 }
96
97 void spawnpoint_use()
98 {
99         if(teamplay)
100         if(have_team_spawns > 0)
101         {
102                 self.team = activator.team;
103                 some_spawn_has_been_used = 1;
104         }
105 }
106
107 // Returns:
108 //   _x: prio (-1 if unusable)
109 //   _y: weight
110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
111 {
112         float shortest, thisdist;
113         float prio;
114         entity player;
115
116         prio = 0;
117
118         // filter out spots for the wrong team
119         if(teamcheck >= 0)
120                 if(spot.team != teamcheck)
121                         return '-1 0 0';
122
123         if(race_spawns)
124                 if(spot.target == "")
125                         return '-1 0 0';
126
127         if(clienttype(self) == CLIENTTYPE_REAL)
128         {
129                 if(spot.restriction == 1)
130                         return '-1 0 0';
131         }
132         else
133         {
134                 if(spot.restriction == 2)
135                         return '-1 0 0';
136         }
137
138         shortest = vlen(world.maxs - world.mins);
139         FOR_EACH_PLAYER(player) if (player != self)
140         {
141                 thisdist = vlen(player.origin - spot.origin);
142                 if (thisdist < shortest)
143                         shortest = thisdist;
144         }
145         if(shortest > mindist)
146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
147
148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
149         spawn_spot = spot;
150
151         // filter out spots for assault
152         if(spot.target != "") {
153                 entity ent;
154                 float found;
155
156                 found = 0;
157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
158                 {
159                         ++found;
160                         if(ent.spawn_evalfunc)
161                         {
162                                 entity oldself = self;
163                                 self = ent;
164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
165                                 self = oldself;
166                                 if(spawn_score_x < 0)
167                                         return spawn_score;
168                         }
169                 }
170
171                 if(!found)
172                 {
173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
174                         return '-1 0 0';
175                 }
176         }
177
178         MUTATOR_CALLHOOK(Spawn_Score);
179         return spawn_score;
180 }
181
182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
183 {
184         entity spot;
185         for(spot = firstspot; spot; spot = spot.chain)
186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
187 }
188
189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
190 {
191         entity spot, spotlist, spotlistend;
192
193         spotlist = world;
194         spotlistend = world;
195
196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
197
198         for(spot = firstspot; spot; spot = spot.chain)
199         {
200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
201                 {
202                         if(spotlistend)
203                                 spotlistend.chain = spot;
204                         spotlistend = spot;
205                         if(!spotlist)
206                                 spotlist = spot;
207                 }
208         }
209         if(spotlistend)
210                 spotlistend.chain = world;
211
212         return spotlist;
213 }
214
215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
216 {
217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
219         entity spot;
220
221         RandomSelection_Init();
222         for(spot = firstspot; spot; spot = spot.chain)
223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
224
225         return RandomSelection_chosen_ent;
226 }
227
228 /*
229 =============
230 SelectSpawnPoint
231
232 Finds a point to respawn
233 =============
234 */
235 entity SelectSpawnPoint (float anypoint)
236 {
237         float teamcheck;
238         entity spot, firstspot;
239
240         spot = find (world, classname, "testplayerstart");
241         if (spot)
242                 return spot;
243
244         if(anypoint || autocvar_g_spawn_useallspawns)
245                 teamcheck = -1;
246         else if(have_team_spawns > 0)
247         {
248                 if(have_team_spawns_forteam[self.team] == 0)
249                 {
250                         // we request a spawn for a team, and we have team
251                         // spawns, but that team has no spawns?
252                         if(have_team_spawns_forteam[0])
253                                 // try noteam spawns
254                                 teamcheck = 0;
255                         else
256                                 // if not, any spawn has to do
257                                 teamcheck = -1;
258                 }
259                 else
260                         teamcheck = self.team; // MUST be team
261         }
262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
263                 teamcheck = 0; // MUST be noteam
264         else
265                 teamcheck = -1;
266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
267
268
269         // get the entire list of spots
270         firstspot = findchain(classname, "info_player_deathmatch");
271         // filter out the bad ones
272         // (note this returns the original list if none survived)
273         if(anypoint)
274         {
275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
276         }
277         else
278         {
279                 float mindist;
280                 if (arena_roundbased && !g_ca)
281                         mindist = 800;
282                 else
283                         mindist = 100;
284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
285
286                 // there is 50/50 chance of choosing a random spot or the furthest spot
287                 // (this means that roughly every other spawn will be furthest, so you
288                 // usually won't get fragged at spawn twice in a row)
289                 if (random() > autocvar_g_spawn_furthest)
290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
291                 else
292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
293         }
294
295         if (!spot)
296         {
297                 if(autocvar_spawn_debug)
298                         GotoNextMap(0);
299                 else
300                 {
301                         if(some_spawn_has_been_used)
302                                 return world; // team can't spawn any more, because of actions of other team
303                         else
304                                 error("Cannot find a spawn point - please fix the map!");
305                 }
306         }
307
308         return spot;
309 }
310
311 /*
312 =============
313 CheckPlayerModel
314
315 Checks if the argument string can be a valid playermodel.
316 Returns a valid one in doubt.
317 =============
318 */
319 string FallbackPlayerModel;
320 string CheckPlayerModel(string plyermodel) {
321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
322         {
323                 // note: we cannot summon Don Strunzone here, some player may
324                 // still have the model string set. In case anyone manages how
325                 // to change a cvar default, we'll have a small leak here.
326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
327         }
328         // only in right path
329         if( substring(plyermodel,0,14) != "models/player/")
330                 return FallbackPlayerModel;
331         // only good file extensions
332         if(substring(plyermodel,-4,4) != ".zym")
333         if(substring(plyermodel,-4,4) != ".dpm")
334         if(substring(plyermodel,-4,4) != ".iqm")
335         if(substring(plyermodel,-4,4) != ".md3")
336         if(substring(plyermodel,-4,4) != ".psk")
337                 return FallbackPlayerModel;
338         // forbid the LOD models
339         if(substring(plyermodel, -9,5) == "_lod1")
340                 return FallbackPlayerModel;
341         if(substring(plyermodel, -9,5) == "_lod2")
342                 return FallbackPlayerModel;
343         if(plyermodel != strtolower(plyermodel))
344                 return FallbackPlayerModel;
345         // also, restrict to server models
346         if(autocvar_sv_servermodelsonly)
347         {
348                 if(!fexists(plyermodel))
349                         return FallbackPlayerModel;
350         }
351         return plyermodel;
352 }
353
354 void setplayermodel(entity e, string modelname)
355 {
356         precache_model(modelname);
357         setmodel(e, modelname);
358         player_setupanimsformodel();
359         UpdatePlayerSounds();
360 }
361
362 /*
363 =============
364 PutObserverInServer
365
366 putting a client as observer in the server
367 =============
368 */
369 void FixPlayermodel();
370 void PutObserverInServer (void)
371 {
372         entity  spot;
373     self.hud = HUD_NORMAL;
374         race_PreSpawnObserver();
375
376         spot = SelectSpawnPoint (TRUE);
377         if(!spot)
378                 error("No spawnpoints for observers?!?\n");
379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
380
381         if(clienttype(self) == CLIENTTYPE_REAL)
382         {
383                 msg_entity = self;
384                 WriteByte(MSG_ONE, SVC_SETVIEW);
385                 WriteEntity(MSG_ONE, self);
386         }
387
388         MUTATOR_CALLHOOK(MakePlayerObserver);
389
390         minstagib_stop_countdown(self);
391
392         Portal_ClearAll(self);
393         
394         if(self.alivetime)
395         {
396                 if(!inWarmupStage)
397                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
398                 self.alivetime = 0;
399         }
400
401         if(self.vehicle)
402                 vehicles_exit(VHEF_RELESE);         
403
404         WaypointSprite_PlayerDead();
405
406         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
407                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
408
409         if(self.killcount != -666) {
410                 if(g_lms) {
411                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
412                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
413                         else
414                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
415                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
416
417                 if(self.just_joined == FALSE) {
418                         LogTeamchange(self.playerid, -1, 4);
419                 } else
420                         self.just_joined = FALSE;
421         }
422
423         PlayerScore_Clear(self); // clear scores when needed
424
425         accuracy_resend(self);
426
427         self.spectatortime = time;
428         
429         self.classname = "observer";
430         self.iscreature = FALSE;
431         self.teleportable = TELEPORT_SIMPLE;
432         self.damagedbycontents = FALSE;
433         self.health = -666;
434         self.takedamage = DAMAGE_NO;
435         self.solid = SOLID_NOT;
436         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
437         self.flags = FL_CLIENT | FL_NOTARGET;
438         self.armorvalue = 666;
439         self.effects = 0;
440         self.armorvalue = autocvar_g_balance_armor_start;
441         self.pauserotarmor_finished = 0;
442         self.pauserothealth_finished = 0;
443         self.pauseregen_finished = 0;
444         self.damageforcescale = 0;
445         self.death_time = 0;
446         self.respawn_time = 0;
447         self.alpha = 0;
448         self.scale = 0;
449         self.fade_time = 0;
450         self.pain_frame = 0;
451         self.pain_finished = 0;
452         self.strength_finished = 0;
453         self.invincible_finished = 0;
454         self.superweapons_finished = 0;
455         self.pushltime = 0;
456         self.istypefrag = 0;
457         self.think = func_null;
458         self.nextthink = 0;
459         self.hook_time = 0;
460         self.deadflag = DEAD_NO;
461         self.angles = spot.angles;
462         self.angles_z = 0;
463         self.fixangle = TRUE;
464         self.crouch = FALSE;
465
466         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
467         self.prevorigin = self.origin;
468         self.items = 0;
469         WEPSET_CLEAR_E(self);
470         self.model = "";
471         FixPlayermodel();
472         setmodel(self, "null");
473         self.drawonlytoclient = self;
474
475         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
476         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
477
478         self.weapon = 0;
479         self.weaponname = "";
480         self.switchingweapon = 0;
481         self.weaponmodel = "";
482         self.weaponentity = world;
483         self.exteriorweaponentity = world;
484         self.killcount = -666;
485         self.velocity = '0 0 0';
486         self.avelocity = '0 0 0';
487         self.punchangle = '0 0 0';
488         self.punchvector = '0 0 0';
489         self.oldvelocity = self.velocity;
490         self.fire_endtime = -1;
491
492         if(g_arena)
493         {
494                 if(self.version_mismatch)
495                 {
496                         self.frags = FRAGS_SPECTATOR;
497                         Spawnqueue_Unmark(self);
498                         Spawnqueue_Remove(self);
499                 }
500                 else
501                 {
502                         self.frags = FRAGS_LMS_LOSER;
503                         Spawnqueue_Insert(self);
504                 }
505         }
506         else if(g_lms)
507         {
508                 // Only if the player cannot play at all
509                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
510                         self.frags = FRAGS_SPECTATOR;
511                 else
512                         self.frags = FRAGS_LMS_LOSER;
513         }
514         else if(g_ca)
515         {
516                 if(self.caplayer)
517                         self.frags = FRAGS_LMS_LOSER;
518                 else
519                         self.frags = FRAGS_SPECTATOR;
520         }
521         else if((g_race && g_race_qualifying) || g_cts)
522         {
523                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
524                         self.frags = FRAGS_LMS_LOSER;
525                 else
526                         self.frags = FRAGS_SPECTATOR;
527         }
528         else
529                 self.frags = FRAGS_SPECTATOR;
530 }
531
532 .float model_randomizer;
533 void FixPlayermodel()
534 {
535         string defaultmodel;
536         float defaultskin, chmdl, oldskin, n, i;
537         vector m1, m2;
538
539         defaultmodel = "";
540         defaultskin = 0;
541         chmdl = FALSE;
542
543         if(autocvar_sv_defaultcharacter == 1)
544         {
545                 if(teamplay)
546                 {
547                         string s;
548                         s = Team_ColorName_Lower(self.team);
549                         if(s != "neutral")
550                         {
551                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
552                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
553                         }
554                 }
555
556                 if(defaultmodel == "")
557                 {
558                         defaultmodel = autocvar_sv_defaultplayermodel;
559                         defaultskin = autocvar_sv_defaultplayerskin;
560                 }
561
562                 n = tokenize_console(defaultmodel);
563                 if(n > 0)
564                         defaultmodel = argv(floor(n * self.model_randomizer));
565
566                 i = strstrofs(defaultmodel, ":", 0);
567                 if(i >= 0)
568                 {
569                         defaultskin = stof(substring(defaultmodel, i+1, -1));
570                         defaultmodel = substring(defaultmodel, 0, i);
571                 }
572         }
573
574         if(defaultmodel != "")
575         {
576                 if (defaultmodel != self.model)
577                 {
578                         m1 = self.mins;
579                         m2 = self.maxs;
580                         setplayermodel (self, defaultmodel);
581                         setsize (self, m1, m2);
582                         chmdl = TRUE;
583                 }
584
585                 oldskin = self.skin;
586                 self.skin = defaultskin;
587         } else {
588                 if (self.playermodel != self.model || self.playermodel == "")
589                 {
590                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
591                         m1 = self.mins;
592                         m2 = self.maxs;
593                         setplayermodel (self, self.playermodel);
594                         setsize (self, m1, m2);
595                         chmdl = TRUE;
596                 }
597
598                 oldskin = self.skin;
599                 self.skin = stof(self.playerskin);
600         }
601
602         if(chmdl || oldskin != self.skin) // model or skin has changed
603         {
604                 self.species = player_getspecies(); // update species
605                 UpdatePlayerSounds(); // update skin sounds
606         }
607
608         if(!teamplay)
609                 if(strlen(autocvar_sv_defaultplayercolors))
610                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
611                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
612 }
613
614 /*
615 =============
616 PutClientInServer
617
618 Called when a client spawns in the server
619 =============
620 */
621
622 void PutClientInServer (void)
623 {
624         if(clienttype(self) == CLIENTTYPE_BOT)
625         {
626                 self.classname = "player";
627                 if(g_ca)
628                         self.caplayer = 1;
629         }
630         else if(clienttype(self) == CLIENTTYPE_REAL)
631         {
632                 msg_entity = self;
633                 WriteByte(MSG_ONE, SVC_SETVIEW);
634                 WriteEntity(MSG_ONE, self);
635         }
636
637         // reset player keys
638         self.itemkeys = 0;
639
640         // player is dead and becomes observer
641         // FIXME fix LMS scoring for new system
642         if(g_lms)
643         {
644                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
645                         self.classname = "observer";
646         }
647
648         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
649                 self.classname = "observer";
650
651         if(gameover)
652                 self.classname = "observer";
653
654         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
655                 entity spot, oldself;
656                 float j;
657
658                 accuracy_resend(self);
659
660                 if(self.team < 0)
661                         JoinBestTeam(self, FALSE, TRUE);
662
663                 race_PreSpawn();
664
665                 spot = SelectSpawnPoint (FALSE);
666                 if(!spot)
667                 {
668                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
669                         return; // spawn failed
670                 }
671
672                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
673
674                 self.classname = "player";
675                 self.wasplayer = TRUE;
676                 self.iscreature = TRUE;
677                 self.teleportable = TELEPORT_NORMAL;
678                 self.damagedbycontents = TRUE;
679                 self.movetype = MOVETYPE_WALK;
680                 self.solid = SOLID_SLIDEBOX;
681                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
682                 if(autocvar_g_playerclip_collisions)
683                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
684                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
685                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
686                 self.frags = FRAGS_PLAYER;
687                 if(INDEPENDENT_PLAYERS)
688                         MAKE_INDEPENDENT_PLAYER(self);
689                 self.flags = FL_CLIENT;
690                 if(autocvar__notarget)
691                         self.flags |= FL_NOTARGET;
692                 self.takedamage = DAMAGE_AIM;
693                 if(g_minstagib)
694                         self.effects = EF_FULLBRIGHT;
695                 else
696                         self.effects = 0;
697                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
698                 self.air_finished = time + 12;
699                 self.dmg = 2;
700                 if(autocvar_g_balance_nex_charge)
701                 {
702                         if(autocvar_g_balance_nex_secondary_chargepool)
703                                 self.nex_chargepool_ammo = 1;
704                         self.nex_charge = autocvar_g_balance_nex_charge_start;
705                 }
706
707                 if(inWarmupStage)
708                 {
709                         self.ammo_shells = warmup_start_ammo_shells;
710                         self.ammo_nails = warmup_start_ammo_nails;
711                         self.ammo_rockets = warmup_start_ammo_rockets;
712                         self.ammo_cells = warmup_start_ammo_cells;
713                         self.ammo_fuel = warmup_start_ammo_fuel;
714                         self.health = warmup_start_health;
715                         self.armorvalue = warmup_start_armorvalue;
716                         WEPSET_COPY_EA(self, warmup_start_weapons);
717                 }
718                 else
719                 {
720                         self.ammo_shells = start_ammo_shells;
721                         self.ammo_nails = start_ammo_nails;
722                         self.ammo_rockets = start_ammo_rockets;
723                         self.ammo_cells = start_ammo_cells;
724                         self.ammo_fuel = start_ammo_fuel;
725                         self.health = start_health;
726                         self.armorvalue = start_armorvalue;
727                         WEPSET_COPY_EA(self, start_weapons);
728                 }
729
730                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
731                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
732                 else
733                         self.superweapons_finished = 0;
734
735                 if(g_weaponarena_random)
736                 {
737                         if(g_weaponarena_random_with_laser)
738                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
739                         W_RandomWeapons(self, g_weaponarena_random);
740                         if(g_weaponarena_random_with_laser)
741                                 WEPSET_OR_EW(self, WEP_LASER);
742                 }
743
744                 self.items = start_items;
745
746                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
747                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
748                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
749                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
750                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
751                 //extend the pause of rotting if client was reset at the beginning of the countdown
752                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
753                         self.spawnshieldtime += game_starttime - time;
754                         self.pauserotarmor_finished += game_starttime - time;
755                         self.pauserothealth_finished += game_starttime - time;
756                         self.pauseregen_finished += game_starttime - time;
757                 }
758                 self.damageforcescale = 2;
759                 self.death_time = 0;
760                 self.respawn_time = 0;
761                 self.scale = 0;
762                 self.fade_time = 0;
763                 self.pain_frame = 0;
764                 self.pain_finished = 0;
765                 self.strength_finished = 0;
766                 self.invincible_finished = 0;
767                 self.pushltime = 0;
768                 // players have no think function
769                 self.think = func_null;
770                 self.nextthink = 0;
771                 self.hook_time = 0;
772                 self.dmg_team = 0;
773                 self.ballistics_density = autocvar_g_ballistics_density_player;
774
775                 self.metertime = 0;
776
777                 self.deadflag = DEAD_NO;
778
779                 self.angles = spot.angles;
780
781                 self.angles_z = 0; // never spawn tilted even if the spot says to
782                 self.fixangle = TRUE; // turn this way immediately
783                 self.velocity = '0 0 0';
784                 self.avelocity = '0 0 0';
785                 self.punchangle = '0 0 0';
786                 self.punchvector = '0 0 0';
787                 self.oldvelocity = self.velocity;
788                 self.fire_endtime = -1;
789
790                 msg_entity = self;
791                 WRITESPECTATABLE_MSG_ONE({
792                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
793                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
794                 });
795
796                 self.model = "";
797                 FixPlayermodel();
798                 self.drawonlytoclient = world;
799
800                 self.crouch = FALSE;
801                 self.view_ofs = PL_VIEW_OFS;
802                 setsize (self, PL_MIN, PL_MAX);
803                 self.spawnorigin = spot.origin;
804                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
805                 // don't reset back to last position, even if new position is stuck in solid
806                 self.oldorigin = self.origin;
807                 self.prevorigin = self.origin;
808                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
809                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
810         self.hud = HUD_NORMAL;
811
812                 if(g_arena)
813                 {
814                         Spawnqueue_Remove(self);
815                         Spawnqueue_Mark(self);
816                 }
817                 else if(g_ca)
818                         self.caplayer = 1;
819
820                 self.event_damage = PlayerDamage;
821
822                 self.bot_attack = TRUE;
823
824                 self.statdraintime = time + 5;
825                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
826
827                 if(self.killcount == -666) {
828                         PlayerScore_Clear(self);
829                         self.killcount = 0;
830                 }
831
832                 CL_SpawnWeaponentity();
833                 self.alpha = default_player_alpha;
834                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
835                 self.exteriorweaponentity.alpha = default_weapon_alpha;
836
837                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
838                 self.lms_traveled_distance = 0;
839                 self.speedrunning = FALSE;
840
841                 race_PostSpawn(spot);
842
843                 //stuffcmd(self, "chase_active 0");
844                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
845
846                 if(g_assault) {
847                         if(self.team == assault_attacker_team)
848                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
849                         else
850                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
851                 }
852
853                 target_voicescript_clear(self);
854
855                 // reset fields the weapons may use
856                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
857                 {
858                         weapon_action(j, WR_RESETPLAYER);
859
860                         // all weapons must be fully loaded when we spawn
861                         entity e;
862                         e = get_weaponinfo(j);
863                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
864                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
865                 }
866
867                 oldself = self;
868                 self = spot;
869                         activator = oldself;
870                                 string s;
871                                 s = self.target;
872                                 self.target = string_null;
873                                 SUB_UseTargets();
874                                 self.target = s;
875                         activator = world;
876                 self = oldself;
877
878                 spawn_spot = spot;
879                 MUTATOR_CALLHOOK(PlayerSpawn);
880
881                 if(autocvar_spawn_debug)
882                 {
883                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
884                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
885                 }
886
887                 self.switchweapon = w_getbestweapon(self);
888                 self.cnt = -1; // W_LastWeapon will not complain
889                 self.weapon = 0;
890                 self.weaponname = "";
891                 self.switchingweapon = 0;
892
893                 if(!inWarmupStage)
894                         if(!self.alivetime)
895                                 self.alivetime = time;
896
897                 antilag_clear(self);
898
899                 if (autocvar_g_spawnsound)
900                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
901         } else if(self.classname == "observer") {
902                 PutObserverInServer ();
903         }
904 }
905
906 .float ebouncefactor, ebouncestop; // electro's values
907 // TODO do we need all these fields, or should we stop autodetecting runtime
908 // changes and just have a console command to update this?
909 float ClientInit_SendEntity(entity to, float sf)
910 {
911         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
912         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
913         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
914         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
915         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
916         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
917         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
918         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
919         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
920         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
921         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
922         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
923         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
924         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
925         if(sv_foginterval && world.fog != "")
926                 WriteString(MSG_ENTITY, world.fog);
927         else
928                 WriteString(MSG_ENTITY, "");
929         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
930         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
931         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
932         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
933         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
934         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
935         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
936         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
937         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
938         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
939         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
940         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
941         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
942         return TRUE;
943 }
944
945 void ClientInit_CheckUpdate()
946 {
947         self.nextthink = time;
948         if(self.count != autocvar_g_balance_armor_blockpercent)
949         {
950                 self.count = autocvar_g_balance_armor_blockpercent;
951                 self.SendFlags |= 1;
952         }
953         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
954         {
955                 self.cnt = autocvar_g_balance_weaponswitchdelay;
956                 self.SendFlags |= 1;
957         }
958         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
959         {
960                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
961                 self.SendFlags |= 1;
962         }
963         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
964         {
965                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
966                 self.SendFlags |= 1;
967         }
968         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
969         {
970                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
971                 self.SendFlags |= 1;
972         }
973         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
974         {
975                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
976                 self.SendFlags |= 1;
977         }
978 }
979
980 void ClientInit_Spawn()
981 {
982         entity o;
983         entity e;
984         e = spawn();
985         e.classname = "clientinit";
986         e.think = ClientInit_CheckUpdate;
987         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
988
989         o = self;
990         self = e;
991         ClientInit_CheckUpdate();
992         self = o;
993 }
994
995 /*
996 =============
997 SetNewParms
998 =============
999 */
1000 void SetNewParms (void)
1001 {
1002         // initialize parms for a new player
1003         parm1 = -(86400 * 366);
1004 }
1005
1006 /*
1007 =============
1008 SetChangeParms
1009 =============
1010 */
1011 void SetChangeParms (void)
1012 {
1013         // save parms for level change
1014         parm1 = self.parm_idlesince - time;
1015 }
1016
1017 /*
1018 =============
1019 DecodeLevelParms
1020 =============
1021 */
1022 void DecodeLevelParms (void)
1023 {
1024         // load parms
1025         self.parm_idlesince = parm1;
1026         if(self.parm_idlesince == -(86400 * 366))
1027                 self.parm_idlesince = time;
1028
1029         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1030         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1031 }
1032
1033 /*
1034 =============
1035 ClientKill
1036
1037 Called when a client types 'kill' in the console
1038 =============
1039 */
1040
1041 .float clientkill_nexttime;
1042 void ClientKill_Now_TeamChange()
1043 {
1044         if(self.killindicator_teamchange == -1)
1045         {
1046                 JoinBestTeam( self, FALSE, TRUE );
1047         }
1048         else if(self.killindicator_teamchange == -2)
1049         {
1050                 if(g_ca)
1051                         self.caplayer = 0;
1052                 if(blockSpectators)
1053                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1054                 PutObserverInServer();
1055         }
1056         else
1057                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1058 }
1059
1060 void ClientKill_Now()
1061 {
1062         if(self.vehicle)
1063         {
1064             vehicles_exit(VHEF_RELESE);
1065             if(!self.killindicator_teamchange)
1066             {
1067             self.vehicle_health = -1;
1068             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');             
1069             }
1070         }
1071
1072         if(self.killindicator && !wasfreed(self.killindicator))
1073                 remove(self.killindicator);
1074
1075         self.killindicator = world;
1076
1077         if(self.killindicator_teamchange)
1078                 ClientKill_Now_TeamChange();
1079
1080         // in any case:
1081         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1082
1083         // now I am sure the player IS dead
1084 }
1085 void KillIndicator_Think()
1086 {
1087         if (gameover)
1088         {
1089                 self.owner.killindicator = world;
1090                 remove(self);
1091                 return;
1092         }
1093
1094         if (self.owner.alpha < 0 && !self.owner.vehicle)
1095         {
1096                 self.owner.killindicator = world;
1097                 remove(self);
1098                 return;
1099         }
1100
1101         if(self.cnt <= 0)
1102         {
1103                 self = self.owner;
1104                 ClientKill_Now(); // no oldself needed
1105                 return;
1106         }
1107     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1108     {
1109         self.nextthink = time + 1;
1110         self.cnt -= 1;
1111     }
1112         else
1113         {
1114                 if(self.cnt <= 10)
1115                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1116                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1117                 {
1118                         if(self.cnt <= 10)
1119                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1120                 }
1121                 self.nextthink = time + 1;
1122                 self.cnt -= 1;
1123         }
1124 }
1125
1126 float clientkilltime;
1127 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1128 {
1129         float killtime;
1130         float starttime;
1131         entity e;
1132
1133         if (gameover)
1134                 return;
1135
1136         killtime = autocvar_g_balance_kill_delay;
1137
1138         if(g_race_qualifying || g_cts)
1139                 killtime = 0;
1140
1141     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1142     {
1143                 remove(self.killindicator);
1144                 self.killindicator = world;
1145
1146         ClientKill_Now(); // allow instant kill in this case
1147         return;
1148     }
1149
1150         self.killindicator_teamchange = targetteam;
1151
1152     if(!self.killindicator)
1153         {
1154                 if(self.deadflag == DEAD_NO)
1155                 {
1156                         killtime = max(killtime, self.clientkill_nexttime - time);
1157                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1158                 }
1159
1160                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1161                 {
1162                         ClientKill_Now();
1163                 }
1164                 else
1165                 {
1166                         starttime = max(time, clientkilltime);
1167
1168                         self.killindicator = spawn();
1169                         self.killindicator.owner = self;
1170                         self.killindicator.scale = 0.5;
1171                         setattachment(self.killindicator, self, "");
1172                         setorigin(self.killindicator, '0 0 52');
1173                         self.killindicator.think = KillIndicator_Think;
1174                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1175                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1176                         self.killindicator.cnt = ceil(killtime);
1177                         self.killindicator.count = bound(0, ceil(killtime), 10);
1178                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1179
1180                         for(e = world; (e = find(e, classname, "body")) != world; )
1181                         {
1182                                 if(e.enemy != self)
1183                                         continue;
1184                                 e.killindicator = spawn();
1185                                 e.killindicator.owner = e;
1186                                 e.killindicator.scale = 0.5;
1187                                 setattachment(e.killindicator, e, "");
1188                                 setorigin(e.killindicator, '0 0 52');
1189                                 e.killindicator.think = KillIndicator_Think;
1190                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1191                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1192                                 e.killindicator.cnt = ceil(killtime);
1193                         }
1194                         self.lip = 0;
1195                 }
1196         }
1197         if(self.killindicator)
1198         {
1199                 if(targetteam == 0) // just die
1200                 {
1201                         self.killindicator.colormod = '0 0 0';
1202                         if(clienttype(self) == CLIENTTYPE_REAL)
1203                         if(self.killindicator.cnt > 0)
1204                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1205                 }
1206                 else if(targetteam == -1) // auto
1207                 {
1208                         self.killindicator.colormod = '0 1 0';
1209                         if(clienttype(self) == CLIENTTYPE_REAL)
1210                         if(self.killindicator.cnt > 0)
1211                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1212                 }
1213                 else if(targetteam == -2) // spectate
1214                 {
1215                         self.killindicator.colormod = '0.5 0.5 0.5';
1216                         if(clienttype(self) == CLIENTTYPE_REAL)
1217                         if(self.killindicator.cnt > 0)
1218                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1219                 }
1220                 else
1221                 {
1222                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1223                         if(clienttype(self) == CLIENTTYPE_REAL)
1224                         if(self.killindicator.cnt > 0)
1225                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1226                 }
1227         }
1228
1229 }
1230
1231 void ClientKill (void)
1232 {
1233         if (gameover)
1234                 return;
1235
1236         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1237         {
1238                 // do nothing
1239         }
1240     else if(self.freezetag_frozen)
1241     {
1242         // do nothing
1243     }
1244         else
1245                 ClientKill_TeamChange(0);
1246 }
1247
1248 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1249 {
1250     e.killindicator = spawn();
1251     e.killindicator.owner = e;
1252     e.killindicator.think = KillIndicator_Think;
1253     e.killindicator.nextthink = time + (e.lip) * 0.05;
1254     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1255     e.killindicator.health = 1; // this is used to indicate that it should be silent
1256     e.lip = 0;
1257 }
1258
1259 void FixClientCvars(entity e)
1260 {
1261         // send prediction settings to the client
1262         stuffcmd(e, "\nin_bindmap 0 0\n");
1263         if(g_race || g_cts)
1264                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1265         if(autocvar_g_antilag == 3) // client side hitscan
1266                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1267         if(autocvar_sv_gentle)
1268                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1269         /*
1270          * we no longer need to stuff this. Remove this comment block if you feel
1271          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1272         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1273         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1274         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1275         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1276         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1277         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1278         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1279         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1280         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1281         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1282         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1283         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1284         stuffcmd(e, "cl_movement_edgefriction 1\n");
1285          */
1286 }
1287
1288 float PlayerInIDList(entity p, string idlist)
1289 {
1290         float n, i;
1291         string s;
1292
1293         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1294         if not(p.crypto_idfp)
1295                 return 0;
1296
1297         // this function allows abbreviated player IDs too!
1298         n = tokenize_console(idlist);
1299         for(i = 0; i < n; ++i)
1300         {
1301                 s = argv(i);
1302                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1303                         return 1;
1304         }
1305
1306         return 0;
1307 }
1308
1309 /*
1310 =============
1311 ClientConnect
1312
1313 Called when a client connects to the server
1314 =============
1315 */
1316 void DecodeLevelParms (void);
1317 //void dom_player_join_team(entity pl);
1318 void set_dom_state(entity e);
1319 void ClientConnect (void)
1320 {
1321         float t;
1322
1323         if(self.flags & FL_CLIENT)
1324         {
1325                 print("Warning: ClientConnect, but already connected!\n");
1326                 return;
1327         }
1328
1329         if(Ban_MaybeEnforceBanOnce(self))
1330                 return;
1331
1332         DecodeLevelParms();
1333
1334 #ifdef WATERMARK
1335         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1336 #endif
1337
1338         self.classname = "player_joining";
1339
1340         self.flags = FL_CLIENT;
1341         self.version_nagtime = time + 10 + random() * 10;
1342
1343         if(player_count<0)
1344         {
1345                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1346                 player_count = 0;
1347         }
1348
1349         PlayerScore_Attach(self);
1350         ClientData_Attach();
1351         accuracy_init(self);
1352
1353         bot_clientconnect();
1354
1355         playerdemo_init();
1356
1357         anticheat_init();
1358
1359         race_PreSpawnObserver();
1360
1361         // identify the right forced team
1362         if(autocvar_g_campaign)
1363         {
1364                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1365                 {
1366                         switch(autocvar_g_campaign_forceteam)
1367                         {
1368                                 case 1: self.team_forced = NUM_TEAM_1; break;
1369                                 case 2: self.team_forced = NUM_TEAM_2; break;
1370                                 case 3: self.team_forced = NUM_TEAM_3; break;
1371                                 case 4: self.team_forced = NUM_TEAM_4; break;
1372                                 default: self.team_forced = 0;
1373                         }
1374                 }
1375         }
1376         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1377                 self.team_forced = NUM_TEAM_1;
1378         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1379                 self.team_forced = NUM_TEAM_2;
1380         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1381                 self.team_forced = NUM_TEAM_3;
1382         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1383                 self.team_forced = NUM_TEAM_4;
1384         else if(autocvar_g_forced_team_otherwise == "red")
1385                 self.team_forced = NUM_TEAM_1;
1386         else if(autocvar_g_forced_team_otherwise == "blue")
1387                 self.team_forced = NUM_TEAM_2;
1388         else if(autocvar_g_forced_team_otherwise == "yellow")
1389                 self.team_forced = NUM_TEAM_3;
1390         else if(autocvar_g_forced_team_otherwise == "pink")
1391                 self.team_forced = NUM_TEAM_4;
1392         else if(autocvar_g_forced_team_otherwise == "spectate")
1393                 self.team_forced = -1;
1394         else if(autocvar_g_forced_team_otherwise == "spectator")
1395                 self.team_forced = -1;
1396         else
1397                 self.team_forced = 0;
1398
1399         if(!teamplay)
1400                 if(self.team_forced > 0)
1401                         self.team_forced = 0;
1402
1403         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1404
1405         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1406                 self.classname = "observer";
1407         } else {
1408                 if(teamplay)
1409                 {
1410                         if(autocvar_g_balance_teams)
1411                         {
1412                                 self.classname = "player";
1413                                 campaign_bots_may_start = 1;
1414                         }
1415                         else
1416                         {
1417                                 self.classname = "observer"; // do it anyway
1418                         }
1419                 }
1420                 else
1421                 {
1422                         self.classname = "player";
1423                         campaign_bots_may_start = 1;
1424                 }
1425         }
1426
1427         self.playerid = (playerid_last = playerid_last + 1);
1428
1429         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1430
1431     if(clienttype(self) == CLIENTTYPE_BOT)
1432         PlayerStats_AddPlayer(self);
1433
1434         if(autocvar_sv_eventlog)
1435                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1436
1437         LogTeamchange(self.playerid, self.team, 1);
1438
1439         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1440
1441         self.netname_previous = strzone(self.netname);
1442
1443         if((self.classname == STR_PLAYER && teamplay))
1444                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1445         else
1446                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1447
1448         stuffcmd(self, strcat(clientstuff, "\n"));
1449         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1450
1451         FixClientCvars(self);
1452
1453         // spawnfunc_waypoint sprites
1454         WaypointSprite_InitClient(self);
1455
1456         // Wazat's grappling hook
1457         SetGrappleHookBindings();
1458
1459         // get version info from player
1460         stuffcmd(self, "cmd clientversion $gameversion\n");
1461
1462         // get other cvars from player
1463         GetCvars(0);
1464
1465         // notify about available teams
1466         if(teamplay)
1467         {
1468                 CheckAllowedTeams(self);
1469                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1470                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1471         }
1472         else
1473                 stuffcmd(self, "set _teams_available 0\n");
1474
1475         if(g_arena || g_ca)
1476         {
1477                 self.classname = "observer";
1478                 if(g_arena)
1479                         Spawnqueue_Insert(self);
1480         }
1481
1482         attach_entcs();
1483
1484         bot_relinkplayerlist();
1485
1486         self.spectatortime = time;
1487         if(blockSpectators)
1488         {
1489                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1490         }
1491
1492         self.jointime = time;
1493         self.allowed_timeouts = autocvar_sv_timeout_number;
1494
1495         if(clienttype(self) == CLIENTTYPE_REAL)
1496         {
1497                 if(!autocvar_g_campaign)
1498                 {
1499                         self.motd_actived_time = -1;
1500                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1501                 }
1502
1503                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1504                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1505         }
1506
1507         if(g_lms)
1508         {
1509                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1510                 {
1511                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1512                         self.frags = FRAGS_SPECTATOR;
1513                 }
1514         }
1515
1516         if(!sv_foginterval && world.fog != "")
1517                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1518
1519         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1520         {
1521                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1522                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1523         }
1524         else
1525                 self.hitplotfh = -1;
1526
1527         if(g_race || g_cts) {
1528                 string rr;
1529                 if(g_cts)
1530                         rr = CTS_RECORD;
1531                 else
1532                         rr = RACE_RECORD;
1533
1534                 msg_entity = self;
1535                 race_send_recordtime(MSG_ONE);
1536                 race_send_speedaward(MSG_ONE);
1537
1538                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1539                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1540                 race_send_speedaward_alltimebest(MSG_ONE);
1541
1542                 float i;
1543                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1544                         race_SendRankings(i, 0, 0, MSG_ONE);
1545                 }
1546         }
1547         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1548                 send_CSQC_teamnagger();
1549
1550         CheatInitClient();
1551
1552         CSQCMODEL_AUTOINIT();
1553
1554         self.model_randomizer = random();
1555     
1556     if(clienttype(self) != CLIENTTYPE_REAL)
1557         return;
1558         
1559     sv_notice_join();
1560     
1561     MUTATOR_CALLHOOK(ClientConnect);
1562 }
1563 /*
1564 =============
1565 ClientDisconnect
1566
1567 Called when a client disconnects from the server
1568 =============
1569 */
1570 .entity chatbubbleentity;
1571 void ReadyCount();
1572 void ClientDisconnect (void)
1573 {
1574         if(self.vehicle)
1575             vehicles_exit(VHEF_RELESE);
1576
1577         if not(self.flags & FL_CLIENT)
1578         {
1579                 print("Warning: ClientDisconnect without ClientConnect\n");
1580                 return;
1581         }
1582
1583         PlayerStats_AddGlobalInfo(self);
1584
1585         CheatShutdownClient();
1586
1587         if(self.hitplotfh >= 0)
1588         {
1589                 fclose(self.hitplotfh);
1590                 self.hitplotfh = -1;
1591         }
1592
1593         anticheat_report();
1594         anticheat_shutdown();
1595
1596         playerdemo_shutdown();
1597
1598         bot_clientdisconnect();
1599
1600         if(self.entcs)
1601                 detach_entcs();
1602
1603         if(autocvar_sv_eventlog)
1604                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1605                 
1606         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1607
1608         MUTATOR_CALLHOOK(ClientDisconnect);
1609
1610         Portal_ClearAll(self);
1611
1612         RemoveGrapplingHook(self);
1613
1614         // Here, everything has been done that requires this player to be a client.
1615
1616         self.flags &~= FL_CLIENT;
1617
1618         if (self.chatbubbleentity)
1619                 remove (self.chatbubbleentity);
1620
1621         if (self.killindicator)
1622                 remove (self.killindicator);
1623
1624         WaypointSprite_PlayerGone();
1625
1626         bot_relinkplayerlist();
1627
1628         if(g_arena)
1629         {
1630                 Spawnqueue_Unmark(self);
1631                 Spawnqueue_Remove(self);
1632         }
1633
1634         accuracy_free(self);
1635         ClientData_Detach();
1636         PlayerScore_Detach(self);
1637
1638         if(self.netname_previous)
1639                 strunzone(self.netname_previous);
1640         if(self.clientstatus)
1641                 strunzone(self.clientstatus);
1642         if(self.weaponorder_byimpulse)
1643                 strunzone(self.weaponorder_byimpulse);
1644
1645         ClearPlayerSounds();
1646
1647         if(self.personal)
1648                 remove(self.personal);
1649
1650         self.playerid = 0;
1651         ReadyCount();
1652
1653         // free cvars
1654         GetCvars(-1);
1655 }
1656
1657 .float BUTTON_CHAT;
1658 void ChatBubbleThink()
1659 {
1660         self.nextthink = time;
1661         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1662         {
1663                 if(self.owner) // but why can that ever be world?
1664                         self.owner.chatbubbleentity = world;
1665                 remove(self);
1666                 return;
1667         }
1668         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1669 #ifdef TETRIS
1670                 || self.owner.tetris_on
1671 #endif
1672         )
1673                 self.model = self.mdl;
1674         else
1675                 self.model = "";
1676 }
1677
1678 void UpdateChatBubble()
1679 {
1680         if (self.alpha < 0)
1681                 return;
1682         // spawn a chatbubble entity if needed
1683         if (!self.chatbubbleentity)
1684         {
1685                 self.chatbubbleentity = spawn();
1686                 self.chatbubbleentity.owner = self;
1687                 self.chatbubbleentity.exteriormodeltoclient = self;
1688                 self.chatbubbleentity.think = ChatBubbleThink;
1689                 self.chatbubbleentity.nextthink = time;
1690                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1691                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1692                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1693                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1694                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1695                 self.chatbubbleentity.model = "";
1696                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1697         }
1698 }
1699
1700
1701 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1702 // added to the model skins
1703 /*void UpdateColorModHack()
1704 {
1705         float c;
1706         c = self.clientcolors & 15;
1707         // LordHavoc: only bothering to support white, green, red, yellow, blue
1708              if (!teamplay) self.colormod = '0 0 0';
1709         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1710         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1711         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1712         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1713         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1714         else self.colormod = '1 1 1';
1715 }*/
1716
1717 void respawn(void)
1718 {
1719         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1720         {
1721                 self.solid = SOLID_NOT;
1722                 self.takedamage = DAMAGE_NO;
1723                 self.movetype = MOVETYPE_FLY;
1724                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1725                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1726                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1727                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1728                 if(autocvar_g_respawn_ghosts_maxtime)
1729                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1730         }
1731
1732         CopyBody(1);
1733
1734         self.effects |= EF_NODRAW; // prevent another CopyBody
1735         PutClientInServer();
1736 }
1737
1738 void play_countdown(float finished, string samp)
1739 {
1740         if(clienttype(self) == CLIENTTYPE_REAL)
1741                 if(floor(finished - time - frametime) != floor(finished - time))
1742                         if(finished - time < 6)
1743                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1744 }
1745
1746 void player_powerups (void)
1747 {
1748         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1749         olditems = self.items;
1750
1751         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1752                 self.modelflags |= MF_ROCKET;
1753         else
1754                 self.modelflags &~= MF_ROCKET;
1755
1756         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1757
1758         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1759                 return;
1760
1761         Fire_ApplyDamage(self);
1762         Fire_ApplyEffect(self);
1763
1764         if (g_minstagib)
1765         {
1766                 self.effects |= EF_FULLBRIGHT;
1767
1768                 if (self.items & IT_STRENGTH)
1769                 {
1770                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1771                         if (time > self.strength_finished)
1772                         {
1773                                 self.alpha = default_player_alpha;
1774                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1775                                 self.items &~= IT_STRENGTH;
1776                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1777                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1778                         }
1779                 }
1780                 else
1781                 {
1782                         if (time < self.strength_finished)
1783                         {
1784                                 self.alpha = g_minstagib_invis_alpha;
1785                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1786                                 self.items |= IT_STRENGTH;
1787                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1788                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1789                         }
1790                 }
1791
1792                 if (self.items & IT_INVINCIBLE)
1793                 {
1794                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1795                         if (time > self.invincible_finished)
1796                         {
1797                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1798                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1799                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1800                         }
1801                 }
1802                 else
1803                 {
1804                         if (time < self.invincible_finished)
1805                         {
1806                                 self.items = self.items | IT_INVINCIBLE;
1807                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1808                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1809                         }
1810                 }
1811         }
1812         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1813         {
1814                 if (self.items & IT_STRENGTH)
1815                 {
1816                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1817                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1818                         if (time > self.strength_finished)
1819                         {
1820                                 self.items = self.items - (self.items & IT_STRENGTH);
1821                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1822                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1823                         }
1824                 }
1825                 else
1826                 {
1827                         if (time < self.strength_finished)
1828                         {
1829                                 self.items = self.items | IT_STRENGTH;
1830                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1831                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1832                         }
1833                 }
1834                 if (self.items & IT_INVINCIBLE)
1835                 {
1836                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1837                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1838                         if (time > self.invincible_finished)
1839                         {
1840                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1841                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1842                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1843                         }
1844                 }
1845                 else
1846                 {
1847                         if (time < self.invincible_finished)
1848                         {
1849                                 self.items = self.items | IT_INVINCIBLE;
1850                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1851                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1852                         }
1853                 }
1854                 if (self.items & IT_SUPERWEAPON)
1855                 {
1856                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1857                         {
1858                                 self.superweapons_finished = 0;
1859                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1860                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1861                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1862                         }
1863                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1864                         {
1865                                 // don't let them run out
1866                         }
1867                         else
1868                         {
1869                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1870                                 if (time > self.superweapons_finished)
1871                                 {
1872                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1873                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1874                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1875                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1876                                 }
1877                         }
1878                 }
1879                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1880                 {
1881                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1882                         {
1883                                 self.items = self.items | IT_SUPERWEAPON;
1884                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1885                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1886                         }
1887                         else
1888                         {
1889                                 self.superweapons_finished = 0;
1890                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1891                         }
1892                 }
1893                 else
1894                 {
1895                         self.superweapons_finished = 0;
1896                 }
1897         }
1898         
1899         if(autocvar_g_nodepthtestplayers)
1900                 self.effects = self.effects | EF_NODEPTHTEST;
1901
1902         if(autocvar_g_fullbrightplayers)
1903                 self.effects = self.effects | EF_FULLBRIGHT;
1904
1905         // midair gamemode: damage only while in the air
1906         // if in midair mode, being on ground grants temporary invulnerability
1907         // (this is so that multishot weapon don't clear the ground flag on the
1908         // first damage in the frame, leaving the player vulnerable to the
1909         // remaining hits in the same frame)
1910         if (self.flags & FL_ONGROUND)
1911         if (g_midair)
1912                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1913
1914         if (time >= game_starttime)
1915         if (time < self.spawnshieldtime)
1916                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1917
1918         MUTATOR_CALLHOOK(PlayerPowerups);
1919 }
1920
1921 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1922 {
1923         if(current > stable)
1924                 return current;
1925         else if(current > stable - 0.25) // when close enough, "snap"
1926                 return stable;
1927         else
1928                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1929 }
1930
1931 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1932 {
1933         if(current < stable)
1934                 return current;
1935         else if(current < stable + 0.25) // when close enough, "snap"
1936                 return stable;
1937         else
1938                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1939 }
1940
1941 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1942 {
1943         if(current > rotstable)
1944         {
1945                 if(rotframetime > 0)
1946                 {
1947                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1948                         current = max(rotstable, current - rotlinear * rotframetime);
1949                 }
1950         }
1951         else if(current < regenstable)
1952         {
1953                 if(regenframetime > 0)
1954                 {
1955                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1956                         current = min(regenstable, current + regenlinear * regenframetime);
1957                 }
1958         }
1959
1960         if(current > limit)
1961                 current = limit;
1962
1963         return current;
1964 }
1965
1966 void player_regen (void)
1967 {
1968         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1969         maxh = autocvar_g_balance_health_rotstable;
1970         maxa = autocvar_g_balance_armor_rotstable;
1971         maxf = autocvar_g_balance_fuel_rotstable;
1972         minh = autocvar_g_balance_health_regenstable;
1973         mina = autocvar_g_balance_armor_regenstable;
1974         minf = autocvar_g_balance_fuel_regenstable;
1975         limith = autocvar_g_balance_health_limit;
1976         limita = autocvar_g_balance_armor_limit;
1977         limitf = autocvar_g_balance_fuel_limit;
1978
1979         max_mod = regen_mod = rot_mod = limit_mod = 1;
1980
1981         maxh = maxh * max_mod;
1982         //maxa = maxa * max_mod;
1983         //maxf = maxf * max_mod;
1984         minh = minh * max_mod;
1985         //mina = mina * max_mod;
1986         //minf = minf * max_mod;
1987         limith = limith * limit_mod;
1988         limita = limita * limit_mod;
1989         //limitf = limitf * limit_mod;
1990
1991         if(g_lms && g_ca)
1992                 rot_mod = 0;
1993
1994         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1995         {
1996                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1997                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1998
1999                 // if player rotted to death...  die!
2000                 if(self.health < 1)
2001                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2002         }
2003
2004         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2005                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2006 }
2007
2008 float zoomstate_set;
2009 void SetZoomState(float z)
2010 {
2011         if(z != self.zoomstate)
2012         {
2013                 self.zoomstate = z;
2014                 ClientData_Touch(self);
2015         }
2016         zoomstate_set = 1;
2017 }
2018
2019 void GetPressedKeys(void) {
2020         MUTATOR_CALLHOOK(GetPressedKeys);
2021         if (self.movement_x > 0) // get if movement keys are pressed
2022         {       // forward key pressed
2023                 self.pressedkeys |= KEY_FORWARD;
2024                 self.pressedkeys &~= KEY_BACKWARD;
2025         }
2026         else if (self.movement_x < 0)
2027         {       // backward key pressed
2028                 self.pressedkeys |= KEY_BACKWARD;
2029                 self.pressedkeys &~= KEY_FORWARD;
2030         }
2031         else
2032         {       // no x input
2033                 self.pressedkeys &~= KEY_FORWARD;
2034                 self.pressedkeys &~= KEY_BACKWARD;
2035         }
2036
2037         if (self.movement_y > 0)
2038         {       // right key pressed
2039                 self.pressedkeys |= KEY_RIGHT;
2040                 self.pressedkeys &~= KEY_LEFT;
2041         }
2042         else if (self.movement_y < 0)
2043         {       // left key pressed
2044                 self.pressedkeys |= KEY_LEFT;
2045                 self.pressedkeys &~= KEY_RIGHT;
2046         }
2047         else
2048         {       // no y input
2049                 self.pressedkeys &~= KEY_RIGHT;
2050                 self.pressedkeys &~= KEY_LEFT;
2051         }
2052
2053         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2054                 self.pressedkeys |= KEY_JUMP;
2055         else
2056                 self.pressedkeys &~= KEY_JUMP;
2057         if (self.BUTTON_CROUCH)
2058                 self.pressedkeys |= KEY_CROUCH;
2059         else
2060                 self.pressedkeys &~= KEY_CROUCH;
2061
2062         if (self.BUTTON_ATCK)
2063                 self.pressedkeys |= KEY_ATCK;
2064         else
2065                 self.pressedkeys &~= KEY_ATCK;
2066         if (self.BUTTON_ATCK2)
2067                 self.pressedkeys |= KEY_ATCK2;
2068         else
2069                 self.pressedkeys &~= KEY_ATCK2;
2070 }
2071
2072 /*
2073 ======================
2074 spectate mode routines
2075 ======================
2076 */
2077
2078 void SpectateCopy(entity spectatee) {
2079         other = spectatee;
2080         MUTATOR_CALLHOOK(SpectateCopy);
2081         self.armortype = spectatee.armortype;
2082         self.armorvalue = spectatee.armorvalue;
2083         self.ammo_cells = spectatee.ammo_cells;
2084         self.ammo_shells = spectatee.ammo_shells;
2085         self.ammo_nails = spectatee.ammo_nails;
2086         self.ammo_rockets = spectatee.ammo_rockets;
2087         self.ammo_fuel = spectatee.ammo_fuel;
2088         self.clip_load = spectatee.clip_load;
2089         self.clip_size = spectatee.clip_size;
2090         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2091         self.health = spectatee.health;
2092         self.impulse = 0;
2093         self.items = spectatee.items;
2094         self.last_pickup = spectatee.last_pickup;
2095         self.hit_time = spectatee.hit_time;
2096         self.metertime = spectatee.metertime;
2097         self.strength_finished = spectatee.strength_finished;
2098         self.invincible_finished = spectatee.invincible_finished;
2099         self.pressedkeys = spectatee.pressedkeys;
2100         WEPSET_COPY_EE(self, spectatee);
2101         self.switchweapon = spectatee.switchweapon;
2102         self.switchingweapon = spectatee.switchingweapon;
2103         self.weapon = spectatee.weapon;
2104         self.nex_charge = spectatee.nex_charge;
2105         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2106         self.hagar_load = spectatee.hagar_load;
2107         self.minelayer_mines = spectatee.minelayer_mines;
2108         self.punchangle = spectatee.punchangle;
2109         self.view_ofs = spectatee.view_ofs;
2110         self.velocity = spectatee.velocity;
2111         self.dmg_take = spectatee.dmg_take;
2112         self.dmg_save = spectatee.dmg_save;
2113         self.dmg_inflictor = spectatee.dmg_inflictor;
2114         self.v_angle = spectatee.v_angle;
2115         self.angles = spectatee.v_angle;
2116         self.stat_respawn_time = spectatee.stat_respawn_time;
2117         if(!self.BUTTON_USE)
2118                 self.fixangle = TRUE;
2119         setorigin(self, spectatee.origin);
2120         setsize(self, spectatee.mins, spectatee.maxs);
2121         SetZoomState(spectatee.zoomstate);
2122     
2123     anticheat_spectatecopy(spectatee);
2124         self.hud = spectatee.hud;
2125         if(spectatee.vehicle)
2126     {
2127         self.fixangle = FALSE;
2128         //self.velocity = spectatee.vehicle.velocity;
2129         self.vehicle_health = spectatee.vehicle_health;
2130         self.vehicle_shield = spectatee.vehicle_shield;
2131         self.vehicle_energy = spectatee.vehicle_energy;
2132         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2133         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2134         self.vehicle_reload1 = spectatee.vehicle_reload1;
2135         self.vehicle_reload2 = spectatee.vehicle_reload2;
2136
2137         msg_entity = self;
2138         
2139         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2140             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2141             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2142             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2143
2144         //WriteByte (MSG_ONE, SVC_SETVIEW);
2145         //    WriteEntity(MSG_ONE, self);            
2146         //makevectors(spectatee.v_angle);
2147         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/    
2148     }
2149 }
2150
2151 float SpectateUpdate() {
2152         if(!self.enemy)
2153             return 0;           
2154
2155         if (self == self.enemy)
2156                 return 0;
2157
2158         if(self.enemy.classname != "player")
2159                 return 0;
2160
2161         SpectateCopy(self.enemy);
2162
2163         return 1;
2164 }
2165
2166
2167 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2168 entity CA_SpectateNext(entity start) {
2169         if (start.team == self.team) {
2170                 return start;
2171         }
2172         
2173         other = start;
2174         // continue from current player
2175         while(other && other.team != self.team) {
2176                 other = find(other, classname, "player");
2177         }
2178         
2179         if (!other) {
2180                 // restart from begining
2181                 other = find(other, classname, "player");
2182                 while(other && other.team != self.team) {
2183                         other = find(other, classname, "player");
2184                 }
2185         }
2186         
2187         return other;
2188 }
2189
2190 float SpectateNext(entity _prefer) {
2191         
2192         if(_prefer)
2193                 other = _prefer;        
2194         else
2195                 other = find(self.enemy, classname, "player");
2196         
2197         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2198                 // CA and ca players when spectating enemies is forbidden
2199                 other = CA_SpectateNext(other);
2200         } else {
2201                 // other modes and ca spectators or spectating enemies is allowed
2202                 if (!other)
2203                         other = find(other, classname, "player");
2204         }
2205         
2206         if (other)
2207                 self.enemy = other;
2208
2209         if(self.enemy.classname == "player") {
2210             /*if(self.enemy.vehicle)
2211             {      
2212             
2213             msg_entity = self;
2214             WriteByte(MSG_ONE, SVC_SETVIEW);
2215             WriteEntity(MSG_ONE, self.enemy);
2216             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2217             
2218             self.movetype = MOVETYPE_NONE;
2219             accuracy_resend(self);
2220             }
2221             else 
2222             {*/         
2223             msg_entity = self;
2224             WriteByte(MSG_ONE, SVC_SETVIEW);
2225             WriteEntity(MSG_ONE, self.enemy);
2226             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2227             self.movetype = MOVETYPE_NONE;
2228             accuracy_resend(self);
2229
2230             if(!SpectateUpdate())
2231                 PutObserverInServer();
2232         //}
2233         return 1;
2234         } else {
2235                 return 0;
2236         }
2237 }
2238
2239 /*
2240 =============
2241 ShowRespawnCountdown()
2242
2243 Update a respawn countdown display.
2244 =============
2245 */
2246 void ShowRespawnCountdown()
2247 {
2248         float number;
2249         if(self.deadflag == DEAD_NO) // just respawned?
2250                 return;
2251         else
2252         {
2253                 number = ceil(self.respawn_time - time);
2254                 if(number <= 0)
2255                         return;
2256                 if(number <= self.respawn_countdown)
2257                 {
2258                         self.respawn_countdown = number - 1;
2259                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2260                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number)); 
2261                 }
2262         }
2263 }
2264
2265 void LeaveSpectatorMode()
2266 {
2267         if(nJoinAllowed(self))
2268         {
2269                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2270                 {
2271                         self.classname = "player";
2272
2273                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2274                                 { JoinBestTeam(self, FALSE, TRUE); }
2275
2276                         if(autocvar_g_campaign)
2277                                 { campaign_bots_may_start = 1; }
2278
2279                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2280
2281                         PutClientInServer();
2282
2283                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2284                 }
2285                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2286         }
2287         else
2288         {
2289                 // Player may not join because g_maxplayers is set
2290                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2291         }
2292 }
2293
2294 /**
2295  * Determines whether the player is allowed to join. This depends on cvar
2296  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2297  * it checks whether the number of currently playing players exceeds g_maxplayers.
2298  * @return int number of free slots for players, 0 if none
2299  */
2300 float nJoinAllowed(entity ignore) {
2301         if(!ignore)
2302         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2303         // so report 0 free slots if restricted
2304         {
2305                 if(autocvar_g_forced_team_otherwise == "spectate")
2306                         return 0;
2307                 if(autocvar_g_forced_team_otherwise == "spectator")
2308                         return 0;
2309         }
2310
2311         if(self.team_forced < 0)
2312                 return 0; // forced spectators can never join
2313
2314         // TODO simplify this
2315         entity e;
2316         float totalClients = 0;
2317         FOR_EACH_CLIENT(e)
2318                 if(e != ignore)
2319                         totalClients += 1;
2320
2321         if (!autocvar_g_maxplayers)
2322                 return maxclients - totalClients;
2323
2324         float currentlyPlaying = 0;
2325         FOR_EACH_REALPLAYER(e)
2326                 currentlyPlaying += 1;
2327
2328         if(currentlyPlaying < autocvar_g_maxplayers)
2329                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2330
2331         return 0;
2332 }
2333
2334 /**
2335  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2336  * g_maxplayers_spectator_blocktime seconds
2337  */
2338 void checkSpectatorBlock() {
2339         if(self.classname == "spectator" || self.classname == "observer") {
2340                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2341                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2342                         dropclient(self);
2343                 }
2344         }
2345 }
2346
2347 void PrintWelcomeMessage()
2348 {
2349         if(self.motd_actived_time == 0)
2350         {
2351                 if (autocvar_g_campaign) {
2352                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2353                                 self.motd_actived_time = time;
2354                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2355                         }
2356                 } else {
2357                         if (self.BUTTON_INFO) {
2358                                 self.motd_actived_time = time;
2359                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2360                         }
2361                 }
2362         }
2363         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2364         {
2365                 if (autocvar_g_campaign) {
2366                         if (self.BUTTON_INFO)
2367                                 self.motd_actived_time = time;
2368                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2369                                 self.motd_actived_time = 0;
2370                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2371                         }
2372                 } else {
2373                         if (self.BUTTON_INFO)
2374                                 self.motd_actived_time = time;
2375                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2376                                 self.motd_actived_time = 0;
2377                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2378                         }
2379                 }
2380         }
2381         else //if(self.motd_actived_time < 0) // just connected, motd is active
2382         {
2383                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2384                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2385                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2386                 {
2387                         // instanctly hide MOTD
2388                         self.motd_actived_time = 0;
2389                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2390                 }
2391         }
2392 }
2393
2394 void ObserverThink()
2395 {
2396         float prefered_movetype;
2397         if (self.flags & FL_JUMPRELEASED) {
2398                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2399                         self.flags &~= FL_JUMPRELEASED;
2400                         self.flags |= FL_SPAWNING;
2401                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2402                         self.flags &~= FL_JUMPRELEASED;
2403                         if(SpectateNext(world) == 1) {
2404                                 self.classname = "spectator";
2405                         }
2406                 } else {
2407                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2408                         if (self.movetype != prefered_movetype)
2409                                 self.movetype = prefered_movetype;
2410                 }
2411         } else {
2412                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2413                         self.flags |= FL_JUMPRELEASED;
2414                         if(self.flags & FL_SPAWNING)
2415                         {
2416                                 self.flags &~= FL_SPAWNING;
2417                                 LeaveSpectatorMode();
2418                                 return;
2419                         }
2420                 }
2421         }
2422 }
2423
2424 void SpectatorThink()
2425 {
2426         if (self.flags & FL_JUMPRELEASED) {
2427                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2428                         self.flags &~= FL_JUMPRELEASED;
2429                         self.flags |= FL_SPAWNING;
2430                 } else if(self.BUTTON_ATCK) {
2431                         self.flags &~= FL_JUMPRELEASED;
2432                         if(SpectateNext(world) == 1) {
2433                                 self.classname = "spectator";
2434                         } else {
2435                                 self.classname = "observer";
2436                                 PutClientInServer();
2437                         }
2438                 } else if (self.BUTTON_ATCK2) {
2439                         self.flags &~= FL_JUMPRELEASED;
2440                         self.classname = "observer";
2441                         PutClientInServer();
2442                 } else {
2443                         if(!SpectateUpdate())
2444                                 PutObserverInServer();
2445                 }
2446         } else {
2447                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2448                         self.flags |= FL_JUMPRELEASED;
2449                         if(self.flags & FL_SPAWNING)
2450                         {
2451                                 self.flags &~= FL_SPAWNING;
2452                                 LeaveSpectatorMode();
2453                                 return;
2454                         }
2455                 }
2456                 if(!SpectateUpdate())
2457                         PutObserverInServer();
2458         }
2459
2460         self.flags |= FL_CLIENT | FL_NOTARGET;
2461 }
2462
2463 void PlayerUseKey()
2464 {
2465         if(self.classname != "player")
2466                 return;
2467
2468         if(self.vehicle)
2469         {
2470         vehicles_exit(VHEF_NORMAL);
2471         return;
2472         }
2473         
2474         // a use key was pressed; call handlers
2475         MUTATOR_CALLHOOK(PlayerUseKey);
2476 }
2477
2478 /*
2479 =============
2480 PlayerPreThink
2481
2482 Called every frame for each client before the physics are run
2483 =============
2484 */
2485 .float usekeypressed;
2486 void() nexball_setstatus;
2487 .float items_added;
2488 void PlayerPreThink (void)
2489 {
2490         WarpZone_PlayerPhysics_FixVAngle();
2491
2492         self.stat_game_starttime = game_starttime;
2493         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2494         self.stat_leadlimit = autocvar_leadlimit;
2495
2496         if(g_arena || (g_ca && !allowed_to_spawn))
2497                 self.stat_respawn_time = 0;
2498         else
2499                 self.stat_respawn_time = self.respawn_time;
2500
2501         if(frametime)
2502         {
2503                 // physics frames: update anticheat stuff
2504                 anticheat_prethink();
2505         }
2506
2507         if(blockSpectators && frametime)
2508                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2509                 checkSpectatorBlock();
2510
2511         zoomstate_set = 0;
2512
2513         if(self.netname_previous != self.netname)
2514         {
2515                 if(autocvar_sv_eventlog)
2516                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2517                 if(self.netname_previous)
2518                         strunzone(self.netname_previous);
2519                 self.netname_previous = strzone(self.netname);
2520         }
2521
2522         // version nagging
2523         if(self.version_nagtime)
2524                 if(self.cvar_g_xonoticversion)
2525                         if(time > self.version_nagtime)
2526                         {
2527                                 // don't notify git users
2528                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2529                                 {
2530                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2531                                         {
2532                                                 // notify release users if connecting to git
2533                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2534                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2535                                         }
2536                                         else
2537                                         {
2538                                                 float r;
2539                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2540                                                 if(r < 0)
2541                                                 {
2542                                                         // give users new version
2543                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2544                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2545                                                 }
2546                                                 else if(r > 0)
2547                                                 {
2548                                                         // notify users about old server version
2549                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2550                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2551                                                 }
2552                                         }
2553                                 }
2554                                 self.version_nagtime = 0;
2555                         }
2556
2557         // GOD MODE info
2558         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2559         {
2560                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2561                 self.max_armorvalue = 0;
2562         }
2563
2564 #ifdef TETRIS
2565         if (TetrisPreFrame())
2566                 return;
2567 #endif
2568
2569         MUTATOR_CALLHOOK(PlayerPreThink);
2570
2571         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2572         {
2573                 if(self.BUTTON_USE && !self.usekeypressed)
2574                         PlayerUseKey();
2575                 self.usekeypressed = self.BUTTON_USE;
2576         }
2577
2578         if(clienttype(self) == CLIENTTYPE_REAL)
2579                 PrintWelcomeMessage();
2580
2581         if(self.classname == "player") {
2582
2583                 CheckRules_Player();
2584
2585                 if (intermission_running)
2586                 {
2587                         IntermissionThink ();   // otherwise a button could be missed between
2588                         return;                                 // the think tics
2589                 }
2590
2591                 //don't allow the player to turn around while game is paused!
2592                 if(timeout_status == TIMEOUT_ACTIVE) {
2593                         // FIXME turn this into CSQC stuff
2594                         self.v_angle = self.lastV_angle;
2595                         self.angles = self.lastV_angle;
2596                         self.fixangle = TRUE;
2597                 }
2598
2599                 if(frametime)
2600                 {
2601                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2602                         {
2603                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2604                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2605                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2606
2607                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2608                                 {
2609                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2610                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2611                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2612                                 }
2613                         }
2614                         else
2615                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2616
2617                         player_powerups();
2618                 }
2619
2620                 if (g_minstagib)
2621                         minstagib_ammocheck();
2622
2623                 if (self.deadflag != DEAD_NO)
2624                 {
2625                         float button_pressed, force_respawn;
2626                         if(self.personal && g_race_qualifying)
2627                         {
2628                                 if(time > self.respawn_time)
2629                                 {
2630                                         self.respawn_time = time + 1; // only retry once a second
2631                                         respawn();
2632                                         self.impulse = 141;
2633                                 }
2634                         }
2635                         else
2636                         {
2637                                 if(frametime)
2638                                         player_anim();
2639                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2640                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2641                                 if (self.deadflag == DEAD_DYING)
2642                                 {
2643                                         if(force_respawn)
2644                                                 self.deadflag = DEAD_RESPAWNING;
2645                                         else if(!button_pressed)
2646                                                 self.deadflag = DEAD_DEAD;
2647                                 }
2648                                 else if (self.deadflag == DEAD_DEAD)
2649                                 {
2650                                         if(button_pressed)
2651                                                 self.deadflag = DEAD_RESPAWNABLE;
2652                                 }
2653                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2654                                 {
2655                                         if(!button_pressed)
2656                                                 self.deadflag = DEAD_RESPAWNING;
2657                                 }
2658                                 else if (self.deadflag == DEAD_RESPAWNING)
2659                                 {
2660                                         if(time > self.respawn_time)
2661                                         {
2662                                                 self.respawn_time = time + 1; // only retry once a second
2663                                                 respawn();
2664                                         }
2665                                 }
2666                                 ShowRespawnCountdown();
2667                         }
2668
2669                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2670                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2671                                 self.stat_respawn_time *= -1;
2672
2673                         return;
2674                 }
2675
2676                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2677                 {
2678                         vector dist;
2679
2680                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2681                         dist = self.prevorigin - self.origin;
2682                         dist_z = 0;
2683                         self.lms_traveled_distance += fabs(vlen(dist));
2684
2685                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2686                         {
2687                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2688                                 self.lms_traveled_distance = 0;
2689                         }
2690
2691                         if(time > self.lms_nextcheck)
2692                         {
2693                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2694                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2695                                 {
2696                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2697                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2698                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2699                                         if(self.vehicle)
2700                                                 Damage(self.vehicle, self, self, autocvar_g_lms_campcheck_damage * 2, DEATH_CAMP, self.vehicle.origin, '0 0 0');
2701                                         else
2702                                                 Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2703                                 }
2704                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2705                                 self.lms_traveled_distance = 0;
2706                         }
2707                 }
2708
2709                 self.prevorigin = self.origin;
2710
2711                 float do_crouch = self.BUTTON_CROUCH;
2712                 if(self.hook.state)
2713                         do_crouch = 0;
2714                 if(self.health <= g_bloodloss)
2715                         do_crouch = 1;
2716                 if(self.vehicle)
2717                         do_crouch = 0;
2718                 if(self.freezetag_frozen)
2719                         do_crouch = 0;
2720                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2721                         do_crouch = 0;
2722
2723                 if (do_crouch)
2724                 {
2725                         if (!self.crouch)
2726                         {
2727                                 self.crouch = TRUE;
2728                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2729                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2730                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2731                         }
2732                 }
2733                 else
2734                 {
2735                         if (self.crouch)
2736                         {
2737                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2738                                 if (!trace_startsolid)
2739                                 {
2740                                         self.crouch = FALSE;
2741                                         self.view_ofs = PL_VIEW_OFS;
2742                                         setsize (self, PL_MIN, PL_MAX);
2743                                 }
2744                         }
2745                 }
2746
2747                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2748                 {
2749                         if(self.bloodloss_timer < time)
2750                         {
2751                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2752                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2753                         }
2754                 }
2755
2756                 FixPlayermodel();
2757
2758                 GrapplingHookFrame();
2759
2760                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2761                 //if(frametime)
2762                 {
2763                         self.items &~= self.items_added;
2764
2765                         W_WeaponFrame();
2766
2767                         self.items_added = 0;
2768                         if(self.items & IT_JETPACK)
2769                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2770                                         self.items_added |= IT_FUEL;
2771
2772                         self.items |= self.items_added;
2773                 }
2774
2775                 player_regen();
2776
2777                 // rot nex charge to the charge limit
2778                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2779                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2780
2781                 if(frametime)
2782                         player_anim();
2783
2784                 if(g_nexball)
2785                         nexball_setstatus();
2786                 
2787                 // secret status
2788                 secrets_setstatus();
2789                 
2790                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2791
2792                 //self.angles_y=self.v_angle_y + 90;   // temp
2793         } else if(gameover) {
2794                 if (intermission_running)
2795                         IntermissionThink ();   // otherwise a button could be missed between
2796                 return;
2797         } else if(self.classname == "observer") {
2798                 ObserverThink();
2799         } else if(self.classname == "spectator") {
2800                 SpectatorThink();
2801         }
2802
2803         if(!zoomstate_set)
2804                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2805
2806         float oldspectatee_status;
2807         oldspectatee_status = self.spectatee_status;
2808         if(self.classname == "spectator")
2809                 self.spectatee_status = num_for_edict(self.enemy);
2810         else if(self.classname == "observer")
2811                 self.spectatee_status = num_for_edict(self);
2812         else
2813                 self.spectatee_status = 0;
2814         if(self.spectatee_status != oldspectatee_status)
2815         {
2816                 ClientData_Touch(self);
2817                 if(g_race || g_cts)
2818                         race_InitSpectator();
2819         }
2820
2821         if(self.teamkill_soundtime)
2822         if(time > self.teamkill_soundtime)
2823         {
2824                 self.teamkill_soundtime = 0;
2825
2826                 entity oldpusher, oldself;
2827
2828                 oldself = self; self = self.teamkill_soundsource;
2829                 oldpusher = self.pusher; self.pusher = oldself;
2830
2831                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2832
2833                 self.pusher = oldpusher;
2834                 self = oldself;
2835         }
2836
2837         if(self.taunt_soundtime)
2838         if(time > self.taunt_soundtime)
2839         {
2840                 self.taunt_soundtime = 0;
2841                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2842         }
2843
2844         target_voicescript_next(self);
2845
2846         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2847         if(!self.weapon)
2848                 self.clip_load = self.clip_size = 0;
2849 }
2850
2851 float isInvisibleString(string s)
2852 {
2853         float i, n, c;
2854         s = strdecolorize(s);
2855         for((i = 0), (n = strlen(s)); i < n; ++i)
2856         {
2857                 c = str2chr(s, i);
2858                 switch(c)
2859                 {
2860                         case 0:
2861                         case 32: // space
2862                                 break;
2863                         case 192: // charmap space
2864                                 if (!autocvar_utf8_enable)
2865                                         break;
2866                                 return FALSE;
2867                         case 160: // space in unicode fonts
2868                         case 0xE000 + 192: // utf8 charmap space
2869                                 if (autocvar_utf8_enable)
2870                                         break;
2871                         default:
2872                                 return FALSE;
2873                 }
2874         }
2875         return TRUE;
2876 }
2877
2878 /*
2879 =============
2880 PlayerPostThink
2881
2882 Called every frame for each client after the physics are run
2883 =============
2884 */
2885 .float idlekick_lasttimeleft;
2886 void PlayerPostThink (void)
2887 {
2888         // Savage: Check for nameless players
2889         if (isInvisibleString(self.netname)) {
2890                 self.netname = "Player";
2891                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2892         }
2893
2894         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2895         {
2896                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2897                 {
2898                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2899                 }
2900                 else
2901                 {
2902                         float timeleft;
2903                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2904                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2905                         {
2906                                 if(!self.idlekick_lasttimeleft)
2907                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2908                         }
2909                         if(timeleft <= 0)
2910                         {
2911                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2912                                 dropclient(self);
2913                                 return;
2914                         }
2915                         else if(timeleft <= 10)
2916                         {
2917                                 if(timeleft != self.idlekick_lasttimeleft)
2918                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2919                                 self.idlekick_lasttimeleft = timeleft;
2920                         }
2921                 }
2922         }
2923
2924 #ifdef TETRIS
2925         if(self.impulse == 100)
2926                 ImpulseCommands();
2927         if (!TetrisPostFrame())
2928         {
2929 #endif
2930
2931         CheatFrame();
2932
2933         //CheckPlayerJump();
2934
2935         if(self.classname == "player") {
2936                 CheckRules_Player();
2937                 UpdateChatBubble();
2938                 if (self.impulse)
2939                         ImpulseCommands();
2940                 if (intermission_running)
2941                         return;         // intermission or finale
2942                 GetPressedKeys();
2943         }
2944         
2945 #ifdef TETRIS
2946         }
2947 #endif
2948
2949         /*
2950         float i;
2951         for(i = 0; i < 1000; ++i)
2952         {
2953                 vector end;
2954                 end = self.origin + '0 0 1024' + 512 * randomvec();
2955                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2956                 if(trace_fraction < 1)
2957                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2958                 {
2959                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2960                         break;
2961                 }
2962         }
2963         */
2964
2965         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2966
2967         if(self.waypointsprite_attachedforcarrier)
2968                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2969
2970         playerdemo_write();
2971
2972         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2973         {
2974                 if not(self.stored_netname)
2975                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2976                 if(self.stored_netname != self.netname)
2977                 {
2978                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2979                         strunzone(self.stored_netname);
2980                         self.stored_netname = strzone(self.netname);
2981                 }
2982         }
2983
2984         /*
2985         if(g_race)
2986                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2987         */
2988
2989         CSQCMODEL_AUTOUPDATE();
2990 }