Remove useless weaponarena check
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 float ClientData_Send(entity to, float sf)
10 {
11         if(to != self.owner)
12         {
13                 error("wtf");
14                 return FALSE;
15         }
16
17         entity e;
18
19         e = to;
20         if(to.classname == "spectator")
21                 e = to.enemy;
22
23         sf = 0;
24
25         if(e.race_completed)
26                 sf |= 1; // forced scoreboard
27         if(to.spectatee_status)
28                 sf |= 2; // spectator ent number follows
29         if(e.zoomstate)
30                 sf |= 4; // zoomed
31         if(e.porto_v_angle_held)
32                 sf |= 8; // angles held
33
34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
35         WriteByte(MSG_ENTITY, sf);
36
37         if(sf & 2)
38                 WriteByte(MSG_ENTITY, to.spectatee_status);
39
40         if(sf & 8)
41         {
42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
44         }
45
46         return TRUE;
47 }
48
49 void ClientData_Attach()
50 {
51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
52         self.clientdata.drawonlytoclient = self;
53         self.clientdata.owner = self;
54 }
55
56 void ClientData_Detach()
57 {
58         remove(self.clientdata);
59         self.clientdata = world;
60 }
61
62 void ClientData_Touch(entity e)
63 {
64         e.clientdata.SendFlags = 1;
65
66         // make it spectatable
67         entity e2;
68         FOR_EACH_REALCLIENT(e2)
69         {
70                 if(e2 != e)
71                         if(e2.classname == "spectator")
72                                 if(e2.enemy == e)
73                                         e2.clientdata.SendFlags = 1;
74         }
75 }
76
77
78 .vector spawnpoint_score;
79 .string netname_previous;
80
81 void spawnfunc_info_player_survivor (void)
82 {
83         spawnfunc_info_player_deathmatch();
84 }
85
86 void spawnfunc_info_player_start (void)
87 {
88         spawnfunc_info_player_deathmatch();
89 }
90
91 void spawnfunc_info_player_deathmatch (void)
92 {
93         self.classname = "info_player_deathmatch";
94         relocate_spawnpoint();
95 }
96
97 void spawnpoint_use()
98 {
99         if(teamplay)
100         if(have_team_spawns > 0)
101         {
102                 self.team = activator.team;
103                 some_spawn_has_been_used = 1;
104         }
105 }
106
107 // Returns:
108 //   _x: prio (-1 if unusable)
109 //   _y: weight
110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
111 {
112         float shortest, thisdist;
113         float prio;
114         entity player;
115
116         prio = 0;
117
118         // filter out spots for the wrong team
119         if(teamcheck >= 0)
120                 if(spot.team != teamcheck)
121                         return '-1 0 0';
122
123         if(race_spawns)
124                 if(spot.target == "")
125                         return '-1 0 0';
126
127         if(clienttype(self) == CLIENTTYPE_REAL)
128         {
129                 if(spot.restriction == 1)
130                         return '-1 0 0';
131         }
132         else
133         {
134                 if(spot.restriction == 2)
135                         return '-1 0 0';
136         }
137
138         shortest = vlen(world.maxs - world.mins);
139         FOR_EACH_PLAYER(player) if (player != self)
140         {
141                 thisdist = vlen(player.origin - spot.origin);
142                 if (thisdist < shortest)
143                         shortest = thisdist;
144         }
145         if(shortest > mindist)
146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
147
148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
149         spawn_spot = spot;
150
151         // filter out spots for assault
152         if(spot.target != "") {
153                 entity ent;
154                 float found;
155
156                 found = 0;
157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
158                 {
159                         ++found;
160                         if(ent.spawn_evalfunc)
161                         {
162                                 entity oldself = self;
163                                 self = ent;
164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
165                                 self = oldself;
166                                 if(spawn_score_x < 0)
167                                         return spawn_score;
168                         }
169                 }
170
171                 if(!found)
172                 {
173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
174                         return '-1 0 0';
175                 }
176         }
177
178         MUTATOR_CALLHOOK(Spawn_Score);
179         return spawn_score;
180 }
181
182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
183 {
184         entity spot;
185         for(spot = firstspot; spot; spot = spot.chain)
186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
187 }
188
189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
190 {
191         entity spot, spotlist, spotlistend;
192
193         spotlist = world;
194         spotlistend = world;
195
196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
197
198         for(spot = firstspot; spot; spot = spot.chain)
199         {
200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
201                 {
202                         if(spotlistend)
203                                 spotlistend.chain = spot;
204                         spotlistend = spot;
205                         if(!spotlist)
206                                 spotlist = spot;
207                 }
208         }
209         if(spotlistend)
210                 spotlistend.chain = world;
211
212         return spotlist;
213 }
214
215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
216 {
217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
219         entity spot;
220
221         RandomSelection_Init();
222         for(spot = firstspot; spot; spot = spot.chain)
223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
224
225         return RandomSelection_chosen_ent;
226 }
227
228 /*
229 =============
230 SelectSpawnPoint
231
232 Finds a point to respawn
233 =============
234 */
235 entity SelectSpawnPoint (float anypoint)
236 {
237         float teamcheck;
238         entity spot, firstspot;
239
240         spot = find (world, classname, "testplayerstart");
241         if (spot)
242                 return spot;
243
244         if(anypoint || autocvar_g_spawn_useallspawns)
245                 teamcheck = -1;
246         else if(have_team_spawns > 0)
247         {
248                 if(have_team_spawns_forteam[self.team] == 0)
249                 {
250                         // we request a spawn for a team, and we have team
251                         // spawns, but that team has no spawns?
252                         if(have_team_spawns_forteam[0])
253                                 // try noteam spawns
254                                 teamcheck = 0;
255                         else
256                                 // if not, any spawn has to do
257                                 teamcheck = -1;
258                 }
259                 else
260                         teamcheck = self.team; // MUST be team
261         }
262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
263                 teamcheck = 0; // MUST be noteam
264         else
265                 teamcheck = -1;
266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
267
268
269         // get the entire list of spots
270         firstspot = findchain(classname, "info_player_deathmatch");
271         // filter out the bad ones
272         // (note this returns the original list if none survived)
273         if(anypoint)
274         {
275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
276         }
277         else
278         {
279                 float mindist;
280                 if (arena_roundbased && !g_ca)
281                         mindist = 800;
282                 else
283                         mindist = 100;
284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
285
286                 // there is 50/50 chance of choosing a random spot or the furthest spot
287                 // (this means that roughly every other spawn will be furthest, so you
288                 // usually won't get fragged at spawn twice in a row)
289                 if (random() > autocvar_g_spawn_furthest)
290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
291                 else
292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
293         }
294
295         if (!spot)
296         {
297                 if(autocvar_spawn_debug)
298                         GotoNextMap(0);
299                 else
300                 {
301                         if(some_spawn_has_been_used)
302                                 return world; // team can't spawn any more, because of actions of other team
303                         else
304                                 error("Cannot find a spawn point - please fix the map!");
305                 }
306         }
307
308         return spot;
309 }
310
311 /*
312 =============
313 CheckPlayerModel
314
315 Checks if the argument string can be a valid playermodel.
316 Returns a valid one in doubt.
317 =============
318 */
319 string FallbackPlayerModel;
320 string CheckPlayerModel(string plyermodel) {
321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
322         {
323                 // note: we cannot summon Don Strunzone here, some player may
324                 // still have the model string set. In case anyone manages how
325                 // to change a cvar default, we'll have a small leak here.
326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
327         }
328         // only in right path
329         if( substring(plyermodel,0,14) != "models/player/")
330                 return FallbackPlayerModel;
331         // only good file extensions
332         if(substring(plyermodel,-4,4) != ".zym")
333         if(substring(plyermodel,-4,4) != ".dpm")
334         if(substring(plyermodel,-4,4) != ".iqm")
335         if(substring(plyermodel,-4,4) != ".md3")
336         if(substring(plyermodel,-4,4) != ".psk")
337                 return FallbackPlayerModel;
338         // forbid the LOD models
339         if(substring(plyermodel, -9,5) == "_lod1")
340                 return FallbackPlayerModel;
341         if(substring(plyermodel, -9,5) == "_lod2")
342                 return FallbackPlayerModel;
343         if(plyermodel != strtolower(plyermodel))
344                 return FallbackPlayerModel;
345         // also, restrict to server models
346         if(autocvar_sv_servermodelsonly)
347         {
348                 if(!fexists(plyermodel))
349                         return FallbackPlayerModel;
350         }
351         return plyermodel;
352 }
353
354 void setplayermodel(entity e, string modelname)
355 {
356         precache_model(modelname);
357         setmodel(e, modelname);
358         player_setupanimsformodel();
359         UpdatePlayerSounds();
360 }
361
362 /*
363 =============
364 PutObserverInServer
365
366 putting a client as observer in the server
367 =============
368 */
369 void FixPlayermodel();
370 void PutObserverInServer (void)
371 {
372         entity  spot;
373     self.hud = HUD_NORMAL;
374         race_PreSpawnObserver();
375
376         spot = SelectSpawnPoint (TRUE);
377         if(!spot)
378                 error("No spawnpoints for observers?!?\n");
379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
380
381         if(clienttype(self) == CLIENTTYPE_REAL)
382         {
383                 msg_entity = self;
384                 WriteByte(MSG_ONE, SVC_SETVIEW);
385                 WriteEntity(MSG_ONE, self);
386         }
387
388         MUTATOR_CALLHOOK(MakePlayerObserver);
389
390         minstagib_stop_countdown(self);
391
392         Portal_ClearAll(self);
393         
394         if(self.alivetime)
395         {
396                 if(!inWarmupStage)
397                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
398                 self.alivetime = 0;
399         }
400
401         if(self.vehicle)
402                 vehicles_exit(VHEF_RELESE);         
403
404         WaypointSprite_PlayerDead();
405
406         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
407                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
408
409         if(self.killcount != -666)
410         {
411                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
412
413                 if(self.just_joined == FALSE) {
414                         LogTeamchange(self.playerid, -1, 4);
415                 } else
416                         self.just_joined = FALSE;
417         }
418
419         PlayerScore_Clear(self); // clear scores when needed
420
421         accuracy_resend(self);
422
423         self.spectatortime = time;
424         
425         self.classname = "observer";
426         self.iscreature = FALSE;
427         self.teleportable = TELEPORT_SIMPLE;
428         self.damagedbycontents = FALSE;
429         self.health = -666;
430         self.takedamage = DAMAGE_NO;
431         self.solid = SOLID_NOT;
432         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
433         self.flags = FL_CLIENT | FL_NOTARGET;
434         self.armorvalue = 666;
435         self.effects = 0;
436         self.armorvalue = autocvar_g_balance_armor_start;
437         self.pauserotarmor_finished = 0;
438         self.pauserothealth_finished = 0;
439         self.pauseregen_finished = 0;
440         self.damageforcescale = 0;
441         self.death_time = 0;
442         self.respawn_time = 0;
443         self.alpha = 0;
444         self.scale = 0;
445         self.fade_time = 0;
446         self.pain_frame = 0;
447         self.pain_finished = 0;
448         self.strength_finished = 0;
449         self.invincible_finished = 0;
450         self.superweapons_finished = 0;
451         self.pushltime = 0;
452         self.istypefrag = 0;
453         self.think = func_null;
454         self.nextthink = 0;
455         self.hook_time = 0;
456         self.deadflag = DEAD_NO;
457         self.angles = spot.angles;
458         self.angles_z = 0;
459         self.fixangle = TRUE;
460         self.crouch = FALSE;
461
462         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
463         self.prevorigin = self.origin;
464         self.items = 0;
465         WEPSET_CLEAR_E(self);
466         self.model = "";
467         FixPlayermodel();
468         setmodel(self, "null");
469         self.drawonlytoclient = self;
470
471         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
472         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
473
474         self.weapon = 0;
475         self.weaponname = "";
476         self.switchingweapon = 0;
477         self.weaponmodel = "";
478         self.weaponentity = world;
479         self.exteriorweaponentity = world;
480         self.killcount = -666;
481         self.velocity = '0 0 0';
482         self.avelocity = '0 0 0';
483         self.punchangle = '0 0 0';
484         self.punchvector = '0 0 0';
485         self.oldvelocity = self.velocity;
486         self.fire_endtime = -1;
487
488         if(g_arena)
489         {
490                 if(self.version_mismatch)
491                 {
492                         self.frags = FRAGS_SPECTATOR;
493                         Spawnqueue_Unmark(self);
494                         Spawnqueue_Remove(self);
495                 }
496                 else
497                 {
498                         self.frags = FRAGS_LMS_LOSER;
499                         Spawnqueue_Insert(self);
500                 }
501         }
502         else if(g_ca)
503         {
504                 if(self.caplayer)
505                         self.frags = FRAGS_LMS_LOSER;
506                 else
507                         self.frags = FRAGS_SPECTATOR;
508         }
509         else if((g_race && g_race_qualifying) || g_cts)
510         {
511                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
512                         self.frags = FRAGS_LMS_LOSER;
513                 else
514                         self.frags = FRAGS_SPECTATOR;
515         }
516         else
517                 self.frags = FRAGS_SPECTATOR;
518 }
519
520 .float model_randomizer;
521 void FixPlayermodel()
522 {
523         string defaultmodel;
524         float defaultskin, chmdl, oldskin, n, i;
525         vector m1, m2;
526
527         defaultmodel = "";
528         defaultskin = 0;
529         chmdl = FALSE;
530
531         if(autocvar_sv_defaultcharacter == 1)
532         {
533                 if(teamplay)
534                 {
535                         string s;
536                         s = Team_ColorName_Lower(self.team);
537                         if(s != "neutral")
538                         {
539                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
540                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
541                         }
542                 }
543
544                 if(defaultmodel == "")
545                 {
546                         defaultmodel = autocvar_sv_defaultplayermodel;
547                         defaultskin = autocvar_sv_defaultplayerskin;
548                 }
549
550                 n = tokenize_console(defaultmodel);
551                 if(n > 0)
552                         defaultmodel = argv(floor(n * self.model_randomizer));
553
554                 i = strstrofs(defaultmodel, ":", 0);
555                 if(i >= 0)
556                 {
557                         defaultskin = stof(substring(defaultmodel, i+1, -1));
558                         defaultmodel = substring(defaultmodel, 0, i);
559                 }
560         }
561
562         if(defaultmodel != "")
563         {
564                 if (defaultmodel != self.model)
565                 {
566                         m1 = self.mins;
567                         m2 = self.maxs;
568                         setplayermodel (self, defaultmodel);
569                         setsize (self, m1, m2);
570                         chmdl = TRUE;
571                 }
572
573                 oldskin = self.skin;
574                 self.skin = defaultskin;
575         } else {
576                 if (self.playermodel != self.model || self.playermodel == "")
577                 {
578                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
579                         m1 = self.mins;
580                         m2 = self.maxs;
581                         setplayermodel (self, self.playermodel);
582                         setsize (self, m1, m2);
583                         chmdl = TRUE;
584                 }
585
586                 oldskin = self.skin;
587                 self.skin = stof(self.playerskin);
588         }
589
590         if(chmdl || oldskin != self.skin) // model or skin has changed
591         {
592                 self.species = player_getspecies(); // update species
593                 UpdatePlayerSounds(); // update skin sounds
594         }
595
596         if(!teamplay)
597                 if(strlen(autocvar_sv_defaultplayercolors))
598                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
599                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
600 }
601
602 /*
603 =============
604 PutClientInServer
605
606 Called when a client spawns in the server
607 =============
608 */
609
610 void PutClientInServer (void)
611 {
612         if(clienttype(self) == CLIENTTYPE_BOT)
613         {
614                 self.classname = "player";
615                 if(g_ca)
616                         self.caplayer = 1;
617         }
618         else if(clienttype(self) == CLIENTTYPE_REAL)
619         {
620                 msg_entity = self;
621                 WriteByte(MSG_ONE, SVC_SETVIEW);
622                 WriteEntity(MSG_ONE, self);
623         }
624
625         // reset player keys
626         self.itemkeys = 0;
627
628         // player is dead and becomes observer
629         // FIXME fix LMS scoring for new system
630         if(g_lms)
631         {
632                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
633                         self.classname = "observer";
634         }
635
636         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
637                 self.classname = "observer";
638
639         if(gameover)
640                 self.classname = "observer";
641
642         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
643                 entity spot, oldself;
644                 float j;
645
646                 accuracy_resend(self);
647
648                 if(self.team < 0)
649                         JoinBestTeam(self, FALSE, TRUE);
650
651                 race_PreSpawn();
652
653                 spot = SelectSpawnPoint (FALSE);
654                 if(!spot)
655                 {
656                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
657                         return; // spawn failed
658                 }
659
660                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
661
662                 self.classname = "player";
663                 self.wasplayer = TRUE;
664                 self.iscreature = TRUE;
665                 self.teleportable = TELEPORT_NORMAL;
666                 self.damagedbycontents = TRUE;
667                 self.movetype = MOVETYPE_WALK;
668                 self.solid = SOLID_SLIDEBOX;
669                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
670                 if(autocvar_g_playerclip_collisions)
671                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
672                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
673                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
674                 self.frags = FRAGS_PLAYER;
675                 if(INDEPENDENT_PLAYERS)
676                         MAKE_INDEPENDENT_PLAYER(self);
677                 self.flags = FL_CLIENT;
678                 if(autocvar__notarget)
679                         self.flags |= FL_NOTARGET;
680                 self.takedamage = DAMAGE_AIM;
681                 if(g_minstagib)
682                         self.effects = EF_FULLBRIGHT;
683                 else
684                         self.effects = 0;
685                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
686                 self.air_finished = time + 12;
687                 self.dmg = 2;
688                 if(autocvar_g_balance_nex_charge)
689                 {
690                         if(autocvar_g_balance_nex_secondary_chargepool)
691                                 self.nex_chargepool_ammo = 1;
692                         self.nex_charge = autocvar_g_balance_nex_charge_start;
693                 }
694
695                 if(inWarmupStage)
696                 {
697                         self.ammo_shells = warmup_start_ammo_shells;
698                         self.ammo_nails = warmup_start_ammo_nails;
699                         self.ammo_rockets = warmup_start_ammo_rockets;
700                         self.ammo_cells = warmup_start_ammo_cells;
701                         self.ammo_fuel = warmup_start_ammo_fuel;
702                         self.health = warmup_start_health;
703                         self.armorvalue = warmup_start_armorvalue;
704                         WEPSET_COPY_EA(self, warmup_start_weapons);
705                 }
706                 else
707                 {
708                         self.ammo_shells = start_ammo_shells;
709                         self.ammo_nails = start_ammo_nails;
710                         self.ammo_rockets = start_ammo_rockets;
711                         self.ammo_cells = start_ammo_cells;
712                         self.ammo_fuel = start_ammo_fuel;
713                         self.health = start_health;
714                         self.armorvalue = start_armorvalue;
715                         WEPSET_COPY_EA(self, start_weapons);
716                 }
717
718                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
719                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
720                 else
721                         self.superweapons_finished = 0;
722
723                 if(g_weaponarena_random)
724                 {
725                         if(g_weaponarena_random_with_laser)
726                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
727                         W_RandomWeapons(self, g_weaponarena_random);
728                         if(g_weaponarena_random_with_laser)
729                                 WEPSET_OR_EW(self, WEP_LASER);
730                 }
731
732                 self.items = start_items;
733
734                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
735                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
736                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
737                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
738                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
739                 //extend the pause of rotting if client was reset at the beginning of the countdown
740                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
741                         self.spawnshieldtime += game_starttime - time;
742                         self.pauserotarmor_finished += game_starttime - time;
743                         self.pauserothealth_finished += game_starttime - time;
744                         self.pauseregen_finished += game_starttime - time;
745                 }
746                 self.damageforcescale = 2;
747                 self.death_time = 0;
748                 self.respawn_time = 0;
749                 self.scale = 0;
750                 self.fade_time = 0;
751                 self.pain_frame = 0;
752                 self.pain_finished = 0;
753                 self.strength_finished = 0;
754                 self.invincible_finished = 0;
755                 self.pushltime = 0;
756                 // players have no think function
757                 self.think = func_null;
758                 self.nextthink = 0;
759                 self.hook_time = 0;
760                 self.dmg_team = 0;
761                 self.ballistics_density = autocvar_g_ballistics_density_player;
762
763                 self.metertime = 0;
764
765                 self.deadflag = DEAD_NO;
766
767                 self.angles = spot.angles;
768
769                 self.angles_z = 0; // never spawn tilted even if the spot says to
770                 self.fixangle = TRUE; // turn this way immediately
771                 self.velocity = '0 0 0';
772                 self.avelocity = '0 0 0';
773                 self.punchangle = '0 0 0';
774                 self.punchvector = '0 0 0';
775                 self.oldvelocity = self.velocity;
776                 self.fire_endtime = -1;
777
778                 msg_entity = self;
779                 WRITESPECTATABLE_MSG_ONE({
780                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
781                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
782                 });
783
784                 self.model = "";
785                 FixPlayermodel();
786                 self.drawonlytoclient = world;
787
788                 self.crouch = FALSE;
789                 self.view_ofs = PL_VIEW_OFS;
790                 setsize (self, PL_MIN, PL_MAX);
791                 self.spawnorigin = spot.origin;
792                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
793                 // don't reset back to last position, even if new position is stuck in solid
794                 self.oldorigin = self.origin;
795                 self.prevorigin = self.origin;
796                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
797                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
798         self.hud = HUD_NORMAL;
799
800                 if(g_arena)
801                 {
802                         Spawnqueue_Remove(self);
803                         Spawnqueue_Mark(self);
804                 }
805                 else if(g_ca)
806                         self.caplayer = 1;
807
808                 self.event_damage = PlayerDamage;
809
810                 self.bot_attack = TRUE;
811
812                 self.statdraintime = time + 5;
813                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
814
815                 if(self.killcount == -666) {
816                         PlayerScore_Clear(self);
817                         self.killcount = 0;
818                 }
819
820                 CL_SpawnWeaponentity();
821                 self.alpha = default_player_alpha;
822                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
823                 self.exteriorweaponentity.alpha = default_weapon_alpha;
824
825                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
826                 self.lms_traveled_distance = 0;
827                 self.speedrunning = FALSE;
828
829                 race_PostSpawn(spot);
830
831                 //stuffcmd(self, "chase_active 0");
832                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
833
834                 if(g_assault) {
835                         if(self.team == assault_attacker_team)
836                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
837                         else
838                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
839                 }
840
841                 target_voicescript_clear(self);
842
843                 // reset fields the weapons may use
844                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
845                 {
846                         weapon_action(j, WR_RESETPLAYER);
847
848                         // all weapons must be fully loaded when we spawn
849                         entity e;
850                         e = get_weaponinfo(j);
851                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
852                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
853                 }
854
855                 oldself = self;
856                 self = spot;
857                         activator = oldself;
858                                 string s;
859                                 s = self.target;
860                                 self.target = string_null;
861                                 SUB_UseTargets();
862                                 self.target = s;
863                         activator = world;
864                 self = oldself;
865
866                 spawn_spot = spot;
867                 MUTATOR_CALLHOOK(PlayerSpawn);
868
869                 if(autocvar_spawn_debug)
870                 {
871                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
872                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
873                 }
874
875                 self.switchweapon = w_getbestweapon(self);
876                 self.cnt = -1; // W_LastWeapon will not complain
877                 self.weapon = 0;
878                 self.weaponname = "";
879                 self.switchingweapon = 0;
880
881                 if(!inWarmupStage)
882                         if(!self.alivetime)
883                                 self.alivetime = time;
884
885                 antilag_clear(self);
886
887                 if (autocvar_g_spawnsound)
888                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
889         } else if(self.classname == "observer") {
890                 PutObserverInServer ();
891         }
892 }
893
894 .float ebouncefactor, ebouncestop; // electro's values
895 // TODO do we need all these fields, or should we stop autodetecting runtime
896 // changes and just have a console command to update this?
897 float ClientInit_SendEntity(entity to, float sf)
898 {
899         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
900         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
901         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
902         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
903         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
904         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
905         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
906         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
907         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
908         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
909         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
910         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
911         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
912         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
913         if(sv_foginterval && world.fog != "")
914                 WriteString(MSG_ENTITY, world.fog);
915         else
916                 WriteString(MSG_ENTITY, "");
917         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
918         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
919         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
920         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
921         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
922         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
923         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
924         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
925         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
926         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
927         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
928         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
929         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
930         return TRUE;
931 }
932
933 void ClientInit_CheckUpdate()
934 {
935         self.nextthink = time;
936         if(self.count != autocvar_g_balance_armor_blockpercent)
937         {
938                 self.count = autocvar_g_balance_armor_blockpercent;
939                 self.SendFlags |= 1;
940         }
941         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
942         {
943                 self.cnt = autocvar_g_balance_weaponswitchdelay;
944                 self.SendFlags |= 1;
945         }
946         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
947         {
948                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
949                 self.SendFlags |= 1;
950         }
951         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
952         {
953                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
954                 self.SendFlags |= 1;
955         }
956         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
957         {
958                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
959                 self.SendFlags |= 1;
960         }
961         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
962         {
963                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
964                 self.SendFlags |= 1;
965         }
966 }
967
968 void ClientInit_Spawn()
969 {
970         entity o;
971         entity e;
972         e = spawn();
973         e.classname = "clientinit";
974         e.think = ClientInit_CheckUpdate;
975         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
976
977         o = self;
978         self = e;
979         ClientInit_CheckUpdate();
980         self = o;
981 }
982
983 /*
984 =============
985 SetNewParms
986 =============
987 */
988 void SetNewParms (void)
989 {
990         // initialize parms for a new player
991         parm1 = -(86400 * 366);
992 }
993
994 /*
995 =============
996 SetChangeParms
997 =============
998 */
999 void SetChangeParms (void)
1000 {
1001         // save parms for level change
1002         parm1 = self.parm_idlesince - time;
1003 }
1004
1005 /*
1006 =============
1007 DecodeLevelParms
1008 =============
1009 */
1010 void DecodeLevelParms (void)
1011 {
1012         // load parms
1013         self.parm_idlesince = parm1;
1014         if(self.parm_idlesince == -(86400 * 366))
1015                 self.parm_idlesince = time;
1016
1017         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1018         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1019 }
1020
1021 /*
1022 =============
1023 ClientKill
1024
1025 Called when a client types 'kill' in the console
1026 =============
1027 */
1028
1029 .float clientkill_nexttime;
1030 void ClientKill_Now_TeamChange()
1031 {
1032         if(self.killindicator_teamchange == -1)
1033         {
1034                 JoinBestTeam( self, FALSE, TRUE );
1035         }
1036         else if(self.killindicator_teamchange == -2)
1037         {
1038                 if(g_ca)
1039                         self.caplayer = 0;
1040                 if(blockSpectators)
1041                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1042                 PutObserverInServer();
1043         }
1044         else
1045                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1046 }
1047
1048 void ClientKill_Now()
1049 {
1050         if(self.vehicle)
1051         {
1052             vehicles_exit(VHEF_RELESE);
1053             if(!self.killindicator_teamchange)
1054             {
1055             self.vehicle_health = -1;
1056             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');             
1057             }
1058         }
1059
1060         if(self.killindicator && !wasfreed(self.killindicator))
1061                 remove(self.killindicator);
1062
1063         self.killindicator = world;
1064
1065         if(self.killindicator_teamchange)
1066                 ClientKill_Now_TeamChange();
1067
1068         // in any case:
1069         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1070
1071         // now I am sure the player IS dead
1072 }
1073 void KillIndicator_Think()
1074 {
1075         if (gameover)
1076         {
1077                 self.owner.killindicator = world;
1078                 remove(self);
1079                 return;
1080         }
1081
1082         if (self.owner.alpha < 0 && !self.owner.vehicle)
1083         {
1084                 self.owner.killindicator = world;
1085                 remove(self);
1086                 return;
1087         }
1088
1089         if(self.cnt <= 0)
1090         {
1091                 self = self.owner;
1092                 ClientKill_Now(); // no oldself needed
1093                 return;
1094         }
1095     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1096     {
1097         self.nextthink = time + 1;
1098         self.cnt -= 1;
1099     }
1100         else
1101         {
1102                 if(self.cnt <= 10)
1103                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1104                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1105                 {
1106                         if(self.cnt <= 10)
1107                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1108                 }
1109                 self.nextthink = time + 1;
1110                 self.cnt -= 1;
1111         }
1112 }
1113
1114 float clientkilltime;
1115 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1116 {
1117         float killtime;
1118         float starttime;
1119         entity e;
1120
1121         if (gameover)
1122                 return;
1123
1124         killtime = autocvar_g_balance_kill_delay;
1125
1126         if(g_race_qualifying || g_cts)
1127                 killtime = 0;
1128
1129     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1130     {
1131                 remove(self.killindicator);
1132                 self.killindicator = world;
1133
1134         ClientKill_Now(); // allow instant kill in this case
1135         return;
1136     }
1137
1138         self.killindicator_teamchange = targetteam;
1139
1140     if(!self.killindicator)
1141         {
1142                 if(self.deadflag == DEAD_NO)
1143                 {
1144                         killtime = max(killtime, self.clientkill_nexttime - time);
1145                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1146                 }
1147
1148                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1149                 {
1150                         ClientKill_Now();
1151                 }
1152                 else
1153                 {
1154                         starttime = max(time, clientkilltime);
1155
1156                         self.killindicator = spawn();
1157                         self.killindicator.owner = self;
1158                         self.killindicator.scale = 0.5;
1159                         setattachment(self.killindicator, self, "");
1160                         setorigin(self.killindicator, '0 0 52');
1161                         self.killindicator.think = KillIndicator_Think;
1162                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1163                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1164                         self.killindicator.cnt = ceil(killtime);
1165                         self.killindicator.count = bound(0, ceil(killtime), 10);
1166                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1167
1168                         for(e = world; (e = find(e, classname, "body")) != world; )
1169                         {
1170                                 if(e.enemy != self)
1171                                         continue;
1172                                 e.killindicator = spawn();
1173                                 e.killindicator.owner = e;
1174                                 e.killindicator.scale = 0.5;
1175                                 setattachment(e.killindicator, e, "");
1176                                 setorigin(e.killindicator, '0 0 52');
1177                                 e.killindicator.think = KillIndicator_Think;
1178                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1179                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1180                                 e.killindicator.cnt = ceil(killtime);
1181                         }
1182                         self.lip = 0;
1183                 }
1184         }
1185         if(self.killindicator)
1186         {
1187                 if(targetteam == 0) // just die
1188                 {
1189                         self.killindicator.colormod = '0 0 0';
1190                         if(clienttype(self) == CLIENTTYPE_REAL)
1191                         if(self.killindicator.cnt > 0)
1192                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1193                 }
1194                 else if(targetteam == -1) // auto
1195                 {
1196                         self.killindicator.colormod = '0 1 0';
1197                         if(clienttype(self) == CLIENTTYPE_REAL)
1198                         if(self.killindicator.cnt > 0)
1199                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1200                 }
1201                 else if(targetteam == -2) // spectate
1202                 {
1203                         self.killindicator.colormod = '0.5 0.5 0.5';
1204                         if(clienttype(self) == CLIENTTYPE_REAL)
1205                         if(self.killindicator.cnt > 0)
1206                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1207                 }
1208                 else
1209                 {
1210                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1211                         if(clienttype(self) == CLIENTTYPE_REAL)
1212                         if(self.killindicator.cnt > 0)
1213                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1214                 }
1215         }
1216
1217 }
1218
1219 void ClientKill (void)
1220 {
1221         if (gameover)
1222                 return;
1223
1224         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1225         {
1226                 // do nothing
1227         }
1228     else if(self.freezetag_frozen)
1229     {
1230         // do nothing
1231     }
1232         else
1233                 ClientKill_TeamChange(0);
1234 }
1235
1236 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1237 {
1238     e.killindicator = spawn();
1239     e.killindicator.owner = e;
1240     e.killindicator.think = KillIndicator_Think;
1241     e.killindicator.nextthink = time + (e.lip) * 0.05;
1242     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1243     e.killindicator.health = 1; // this is used to indicate that it should be silent
1244     e.lip = 0;
1245 }
1246
1247 void FixClientCvars(entity e)
1248 {
1249         // send prediction settings to the client
1250         stuffcmd(e, "\nin_bindmap 0 0\n");
1251         if(g_race || g_cts)
1252                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1253         if(autocvar_g_antilag == 3) // client side hitscan
1254                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1255         if(autocvar_sv_gentle)
1256                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1257         /*
1258          * we no longer need to stuff this. Remove this comment block if you feel
1259          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1260         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1261         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1262         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1263         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1264         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1265         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1266         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1267         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1268         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1269         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1270         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1271         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1272         stuffcmd(e, "cl_movement_edgefriction 1\n");
1273          */
1274 }
1275
1276 float PlayerInIDList(entity p, string idlist)
1277 {
1278         float n, i;
1279         string s;
1280
1281         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1282         if not(p.crypto_idfp)
1283                 return 0;
1284
1285         // this function allows abbreviated player IDs too!
1286         n = tokenize_console(idlist);
1287         for(i = 0; i < n; ++i)
1288         {
1289                 s = argv(i);
1290                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1291                         return 1;
1292         }
1293
1294         return 0;
1295 }
1296
1297 /*
1298 =============
1299 ClientConnect
1300
1301 Called when a client connects to the server
1302 =============
1303 */
1304 void DecodeLevelParms (void);
1305 //void dom_player_join_team(entity pl);
1306 void set_dom_state(entity e);
1307 void ClientConnect (void)
1308 {
1309         float t;
1310
1311         if(self.flags & FL_CLIENT)
1312         {
1313                 print("Warning: ClientConnect, but already connected!\n");
1314                 return;
1315         }
1316
1317         if(Ban_MaybeEnforceBanOnce(self))
1318                 return;
1319
1320         DecodeLevelParms();
1321
1322 #ifdef WATERMARK
1323         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1324 #endif
1325
1326         self.classname = "player_joining";
1327
1328         self.flags = FL_CLIENT;
1329         self.version_nagtime = time + 10 + random() * 10;
1330
1331         if(player_count<0)
1332         {
1333                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1334                 player_count = 0;
1335         }
1336
1337         PlayerScore_Attach(self);
1338         ClientData_Attach();
1339         accuracy_init(self);
1340
1341         bot_clientconnect();
1342
1343         playerdemo_init();
1344
1345         anticheat_init();
1346
1347         race_PreSpawnObserver();
1348
1349         // identify the right forced team
1350         if(autocvar_g_campaign)
1351         {
1352                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1353                 {
1354                         switch(autocvar_g_campaign_forceteam)
1355                         {
1356                                 case 1: self.team_forced = NUM_TEAM_1; break;
1357                                 case 2: self.team_forced = NUM_TEAM_2; break;
1358                                 case 3: self.team_forced = NUM_TEAM_3; break;
1359                                 case 4: self.team_forced = NUM_TEAM_4; break;
1360                                 default: self.team_forced = 0;
1361                         }
1362                 }
1363         }
1364         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1365                 self.team_forced = NUM_TEAM_1;
1366         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1367                 self.team_forced = NUM_TEAM_2;
1368         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1369                 self.team_forced = NUM_TEAM_3;
1370         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1371                 self.team_forced = NUM_TEAM_4;
1372         else if(autocvar_g_forced_team_otherwise == "red")
1373                 self.team_forced = NUM_TEAM_1;
1374         else if(autocvar_g_forced_team_otherwise == "blue")
1375                 self.team_forced = NUM_TEAM_2;
1376         else if(autocvar_g_forced_team_otherwise == "yellow")
1377                 self.team_forced = NUM_TEAM_3;
1378         else if(autocvar_g_forced_team_otherwise == "pink")
1379                 self.team_forced = NUM_TEAM_4;
1380         else if(autocvar_g_forced_team_otherwise == "spectate")
1381                 self.team_forced = -1;
1382         else if(autocvar_g_forced_team_otherwise == "spectator")
1383                 self.team_forced = -1;
1384         else
1385                 self.team_forced = 0;
1386
1387         if(!teamplay)
1388                 if(self.team_forced > 0)
1389                         self.team_forced = 0;
1390
1391         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1392
1393         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1394                 self.classname = "observer";
1395         } else {
1396                 if(teamplay)
1397                 {
1398                         if(autocvar_g_balance_teams)
1399                         {
1400                                 self.classname = "player";
1401                                 campaign_bots_may_start = 1;
1402                         }
1403                         else
1404                         {
1405                                 self.classname = "observer"; // do it anyway
1406                         }
1407                 }
1408                 else
1409                 {
1410                         self.classname = "player";
1411                         campaign_bots_may_start = 1;
1412                 }
1413         }
1414
1415         self.playerid = (playerid_last = playerid_last + 1);
1416
1417         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1418
1419     if(clienttype(self) == CLIENTTYPE_BOT)
1420         PlayerStats_AddPlayer(self);
1421
1422         if(autocvar_sv_eventlog)
1423                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1424
1425         LogTeamchange(self.playerid, self.team, 1);
1426
1427         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1428
1429         self.netname_previous = strzone(self.netname);
1430
1431         if((self.classname == STR_PLAYER && teamplay))
1432                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1433         else
1434                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1435
1436         stuffcmd(self, strcat(clientstuff, "\n"));
1437         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1438
1439         FixClientCvars(self);
1440
1441         // spawnfunc_waypoint sprites
1442         WaypointSprite_InitClient(self);
1443
1444         // Wazat's grappling hook
1445         SetGrappleHookBindings();
1446
1447         // get version info from player
1448         stuffcmd(self, "cmd clientversion $gameversion\n");
1449
1450         // get other cvars from player
1451         GetCvars(0);
1452
1453         // notify about available teams
1454         if(teamplay)
1455         {
1456                 CheckAllowedTeams(self);
1457                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1458                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1459         }
1460         else
1461                 stuffcmd(self, "set _teams_available 0\n");
1462
1463         if(g_arena || g_ca)
1464         {
1465                 self.classname = "observer";
1466                 if(g_arena)
1467                         Spawnqueue_Insert(self);
1468         }
1469
1470         attach_entcs();
1471
1472         bot_relinkplayerlist();
1473
1474         self.spectatortime = time;
1475         if(blockSpectators)
1476         {
1477                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1478         }
1479
1480         self.jointime = time;
1481         self.allowed_timeouts = autocvar_sv_timeout_number;
1482
1483         if(clienttype(self) == CLIENTTYPE_REAL)
1484         {
1485                 if(!autocvar_g_campaign)
1486                 {
1487                         self.motd_actived_time = -1;
1488                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1489                 }
1490
1491                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1492                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1493         }
1494
1495         if(!sv_foginterval && world.fog != "")
1496                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1497
1498         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1499         {
1500                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1501                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1502         }
1503         else
1504                 self.hitplotfh = -1;
1505
1506         if(g_race || g_cts) {
1507                 string rr;
1508                 if(g_cts)
1509                         rr = CTS_RECORD;
1510                 else
1511                         rr = RACE_RECORD;
1512
1513                 msg_entity = self;
1514                 race_send_recordtime(MSG_ONE);
1515                 race_send_speedaward(MSG_ONE);
1516
1517                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1518                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1519                 race_send_speedaward_alltimebest(MSG_ONE);
1520
1521                 float i;
1522                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1523                         race_SendRankings(i, 0, 0, MSG_ONE);
1524                 }
1525         }
1526         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1527                 send_CSQC_teamnagger();
1528
1529         CheatInitClient();
1530
1531         CSQCMODEL_AUTOINIT();
1532
1533         self.model_randomizer = random();
1534     
1535     if(clienttype(self) != CLIENTTYPE_REAL)
1536         return;
1537         
1538     sv_notice_join();
1539     
1540     MUTATOR_CALLHOOK(ClientConnect);
1541 }
1542 /*
1543 =============
1544 ClientDisconnect
1545
1546 Called when a client disconnects from the server
1547 =============
1548 */
1549 .entity chatbubbleentity;
1550 void ReadyCount();
1551 void ClientDisconnect (void)
1552 {
1553         if(self.vehicle)
1554             vehicles_exit(VHEF_RELESE);
1555
1556         if not(self.flags & FL_CLIENT)
1557         {
1558                 print("Warning: ClientDisconnect without ClientConnect\n");
1559                 return;
1560         }
1561
1562         PlayerStats_AddGlobalInfo(self);
1563
1564         CheatShutdownClient();
1565
1566         if(self.hitplotfh >= 0)
1567         {
1568                 fclose(self.hitplotfh);
1569                 self.hitplotfh = -1;
1570         }
1571
1572         anticheat_report();
1573         anticheat_shutdown();
1574
1575         playerdemo_shutdown();
1576
1577         bot_clientdisconnect();
1578
1579         if(self.entcs)
1580                 detach_entcs();
1581
1582         if(autocvar_sv_eventlog)
1583                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1584                 
1585         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1586
1587         MUTATOR_CALLHOOK(ClientDisconnect);
1588
1589         Portal_ClearAll(self);
1590
1591         RemoveGrapplingHook(self);
1592
1593         // Here, everything has been done that requires this player to be a client.
1594
1595         self.flags &~= FL_CLIENT;
1596
1597         if (self.chatbubbleentity)
1598                 remove (self.chatbubbleentity);
1599
1600         if (self.killindicator)
1601                 remove (self.killindicator);
1602
1603         WaypointSprite_PlayerGone();
1604
1605         bot_relinkplayerlist();
1606
1607         if(g_arena)
1608         {
1609                 Spawnqueue_Unmark(self);
1610                 Spawnqueue_Remove(self);
1611         }
1612
1613         accuracy_free(self);
1614         ClientData_Detach();
1615         PlayerScore_Detach(self);
1616
1617         if(self.netname_previous)
1618                 strunzone(self.netname_previous);
1619         if(self.clientstatus)
1620                 strunzone(self.clientstatus);
1621         if(self.weaponorder_byimpulse)
1622                 strunzone(self.weaponorder_byimpulse);
1623
1624         ClearPlayerSounds();
1625
1626         if(self.personal)
1627                 remove(self.personal);
1628
1629         self.playerid = 0;
1630         ReadyCount();
1631
1632         // free cvars
1633         GetCvars(-1);
1634 }
1635
1636 .float BUTTON_CHAT;
1637 void ChatBubbleThink()
1638 {
1639         self.nextthink = time;
1640         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1641         {
1642                 if(self.owner) // but why can that ever be world?
1643                         self.owner.chatbubbleentity = world;
1644                 remove(self);
1645                 return;
1646         }
1647         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1648 #ifdef TETRIS
1649                 || self.owner.tetris_on
1650 #endif
1651         )
1652                 self.model = self.mdl;
1653         else
1654                 self.model = "";
1655 }
1656
1657 void UpdateChatBubble()
1658 {
1659         if (self.alpha < 0)
1660                 return;
1661         // spawn a chatbubble entity if needed
1662         if (!self.chatbubbleentity)
1663         {
1664                 self.chatbubbleentity = spawn();
1665                 self.chatbubbleentity.owner = self;
1666                 self.chatbubbleentity.exteriormodeltoclient = self;
1667                 self.chatbubbleentity.think = ChatBubbleThink;
1668                 self.chatbubbleentity.nextthink = time;
1669                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1670                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1671                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1672                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1673                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1674                 self.chatbubbleentity.model = "";
1675                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1676         }
1677 }
1678
1679
1680 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1681 // added to the model skins
1682 /*void UpdateColorModHack()
1683 {
1684         float c;
1685         c = self.clientcolors & 15;
1686         // LordHavoc: only bothering to support white, green, red, yellow, blue
1687              if (!teamplay) self.colormod = '0 0 0';
1688         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1689         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1690         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1691         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1692         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1693         else self.colormod = '1 1 1';
1694 }*/
1695
1696 void respawn(void)
1697 {
1698         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1699         {
1700                 self.solid = SOLID_NOT;
1701                 self.takedamage = DAMAGE_NO;
1702                 self.movetype = MOVETYPE_FLY;
1703                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1704                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1705                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1706                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1707                 if(autocvar_g_respawn_ghosts_maxtime)
1708                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1709         }
1710
1711         CopyBody(1);
1712
1713         self.effects |= EF_NODRAW; // prevent another CopyBody
1714         PutClientInServer();
1715 }
1716
1717 void play_countdown(float finished, string samp)
1718 {
1719         if(clienttype(self) == CLIENTTYPE_REAL)
1720                 if(floor(finished - time - frametime) != floor(finished - time))
1721                         if(finished - time < 6)
1722                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1723 }
1724
1725 void player_powerups (void)
1726 {
1727         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1728         olditems = self.items;
1729
1730         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1731                 self.modelflags |= MF_ROCKET;
1732         else
1733                 self.modelflags &~= MF_ROCKET;
1734
1735         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1736
1737         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1738                 return;
1739
1740         Fire_ApplyDamage(self);
1741         Fire_ApplyEffect(self);
1742
1743         if (g_minstagib)
1744         {
1745                 self.effects |= EF_FULLBRIGHT;
1746
1747                 if (self.items & IT_STRENGTH)
1748                 {
1749                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1750                         if (time > self.strength_finished)
1751                         {
1752                                 self.alpha = default_player_alpha;
1753                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1754                                 self.items &~= IT_STRENGTH;
1755                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1756                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1757                         }
1758                 }
1759                 else
1760                 {
1761                         if (time < self.strength_finished)
1762                         {
1763                                 self.alpha = g_minstagib_invis_alpha;
1764                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1765                                 self.items |= IT_STRENGTH;
1766                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1767                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1768                         }
1769                 }
1770
1771                 if (self.items & IT_INVINCIBLE)
1772                 {
1773                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1774                         if (time > self.invincible_finished)
1775                         {
1776                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1777                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1778                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1779                         }
1780                 }
1781                 else
1782                 {
1783                         if (time < self.invincible_finished)
1784                         {
1785                                 self.items = self.items | IT_INVINCIBLE;
1786                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1787                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1788                         }
1789                 }
1790         }
1791         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1792         {
1793                 if (self.items & IT_STRENGTH)
1794                 {
1795                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1796                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1797                         if (time > self.strength_finished)
1798                         {
1799                                 self.items = self.items - (self.items & IT_STRENGTH);
1800                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1801                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1802                         }
1803                 }
1804                 else
1805                 {
1806                         if (time < self.strength_finished)
1807                         {
1808                                 self.items = self.items | IT_STRENGTH;
1809                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1810                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1811                         }
1812                 }
1813                 if (self.items & IT_INVINCIBLE)
1814                 {
1815                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1816                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1817                         if (time > self.invincible_finished)
1818                         {
1819                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1820                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1821                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1822                         }
1823                 }
1824                 else
1825                 {
1826                         if (time < self.invincible_finished)
1827                         {
1828                                 self.items = self.items | IT_INVINCIBLE;
1829                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1830                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1831                         }
1832                 }
1833                 if (self.items & IT_SUPERWEAPON)
1834                 {
1835                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1836                         {
1837                                 self.superweapons_finished = 0;
1838                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1839                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1840                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1841                         }
1842                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1843                         {
1844                                 // don't let them run out
1845                         }
1846                         else
1847                         {
1848                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1849                                 if (time > self.superweapons_finished)
1850                                 {
1851                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1852                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1853                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1854                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1855                                 }
1856                         }
1857                 }
1858                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1859                 {
1860                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1861                         {
1862                                 self.items = self.items | IT_SUPERWEAPON;
1863                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1864                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1865                         }
1866                         else
1867                         {
1868                                 self.superweapons_finished = 0;
1869                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1870                         }
1871                 }
1872                 else
1873                 {
1874                         self.superweapons_finished = 0;
1875                 }
1876         }
1877         
1878         if(autocvar_g_nodepthtestplayers)
1879                 self.effects = self.effects | EF_NODEPTHTEST;
1880
1881         if(autocvar_g_fullbrightplayers)
1882                 self.effects = self.effects | EF_FULLBRIGHT;
1883
1884         // midair gamemode: damage only while in the air
1885         // if in midair mode, being on ground grants temporary invulnerability
1886         // (this is so that multishot weapon don't clear the ground flag on the
1887         // first damage in the frame, leaving the player vulnerable to the
1888         // remaining hits in the same frame)
1889         if (self.flags & FL_ONGROUND)
1890         if (g_midair)
1891                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1892
1893         if (time >= game_starttime)
1894         if (time < self.spawnshieldtime)
1895                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1896
1897         MUTATOR_CALLHOOK(PlayerPowerups);
1898 }
1899
1900 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1901 {
1902         if(current > stable)
1903                 return current;
1904         else if(current > stable - 0.25) // when close enough, "snap"
1905                 return stable;
1906         else
1907                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1908 }
1909
1910 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1911 {
1912         if(current < stable)
1913                 return current;
1914         else if(current < stable + 0.25) // when close enough, "snap"
1915                 return stable;
1916         else
1917                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1918 }
1919
1920 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1921 {
1922         if(current > rotstable)
1923         {
1924                 if(rotframetime > 0)
1925                 {
1926                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1927                         current = max(rotstable, current - rotlinear * rotframetime);
1928                 }
1929         }
1930         else if(current < regenstable)
1931         {
1932                 if(regenframetime > 0)
1933                 {
1934                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1935                         current = min(regenstable, current + regenlinear * regenframetime);
1936                 }
1937         }
1938
1939         if(current > limit)
1940                 current = limit;
1941
1942         return current;
1943 }
1944
1945 void player_regen (void)
1946 {
1947         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1948         maxh = autocvar_g_balance_health_rotstable;
1949         maxa = autocvar_g_balance_armor_rotstable;
1950         maxf = autocvar_g_balance_fuel_rotstable;
1951         minh = autocvar_g_balance_health_regenstable;
1952         mina = autocvar_g_balance_armor_regenstable;
1953         minf = autocvar_g_balance_fuel_regenstable;
1954         limith = autocvar_g_balance_health_limit;
1955         limita = autocvar_g_balance_armor_limit;
1956         limitf = autocvar_g_balance_fuel_limit;
1957
1958         max_mod = regen_mod = rot_mod = limit_mod = 1;
1959
1960         maxh = maxh * max_mod;
1961         //maxa = maxa * max_mod;
1962         //maxf = maxf * max_mod;
1963         minh = minh * max_mod;
1964         //mina = mina * max_mod;
1965         //minf = minf * max_mod;
1966         limith = limith * limit_mod;
1967         limita = limita * limit_mod;
1968         //limitf = limitf * limit_mod;
1969
1970         if(g_lms || g_ca)
1971                 rot_mod = 0;
1972
1973         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1974         {
1975                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1976                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1977
1978                 // if player rotted to death...  die!
1979                 if(self.health < 1)
1980                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1981         }
1982
1983         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1984                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1985 }
1986
1987 float zoomstate_set;
1988 void SetZoomState(float z)
1989 {
1990         if(z != self.zoomstate)
1991         {
1992                 self.zoomstate = z;
1993                 ClientData_Touch(self);
1994         }
1995         zoomstate_set = 1;
1996 }
1997
1998 void GetPressedKeys(void) {
1999         MUTATOR_CALLHOOK(GetPressedKeys);
2000         if (self.movement_x > 0) // get if movement keys are pressed
2001         {       // forward key pressed
2002                 self.pressedkeys |= KEY_FORWARD;
2003                 self.pressedkeys &~= KEY_BACKWARD;
2004         }
2005         else if (self.movement_x < 0)
2006         {       // backward key pressed
2007                 self.pressedkeys |= KEY_BACKWARD;
2008                 self.pressedkeys &~= KEY_FORWARD;
2009         }
2010         else
2011         {       // no x input
2012                 self.pressedkeys &~= KEY_FORWARD;
2013                 self.pressedkeys &~= KEY_BACKWARD;
2014         }
2015
2016         if (self.movement_y > 0)
2017         {       // right key pressed
2018                 self.pressedkeys |= KEY_RIGHT;
2019                 self.pressedkeys &~= KEY_LEFT;
2020         }
2021         else if (self.movement_y < 0)
2022         {       // left key pressed
2023                 self.pressedkeys |= KEY_LEFT;
2024                 self.pressedkeys &~= KEY_RIGHT;
2025         }
2026         else
2027         {       // no y input
2028                 self.pressedkeys &~= KEY_RIGHT;
2029                 self.pressedkeys &~= KEY_LEFT;
2030         }
2031
2032         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2033                 self.pressedkeys |= KEY_JUMP;
2034         else
2035                 self.pressedkeys &~= KEY_JUMP;
2036         if (self.BUTTON_CROUCH)
2037                 self.pressedkeys |= KEY_CROUCH;
2038         else
2039                 self.pressedkeys &~= KEY_CROUCH;
2040
2041         if (self.BUTTON_ATCK)
2042                 self.pressedkeys |= KEY_ATCK;
2043         else
2044                 self.pressedkeys &~= KEY_ATCK;
2045         if (self.BUTTON_ATCK2)
2046                 self.pressedkeys |= KEY_ATCK2;
2047         else
2048                 self.pressedkeys &~= KEY_ATCK2;
2049 }
2050
2051 /*
2052 ======================
2053 spectate mode routines
2054 ======================
2055 */
2056
2057 void SpectateCopy(entity spectatee) {
2058         other = spectatee;
2059         MUTATOR_CALLHOOK(SpectateCopy);
2060         self.armortype = spectatee.armortype;
2061         self.armorvalue = spectatee.armorvalue;
2062         self.ammo_cells = spectatee.ammo_cells;
2063         self.ammo_shells = spectatee.ammo_shells;
2064         self.ammo_nails = spectatee.ammo_nails;
2065         self.ammo_rockets = spectatee.ammo_rockets;
2066         self.ammo_fuel = spectatee.ammo_fuel;
2067         self.clip_load = spectatee.clip_load;
2068         self.clip_size = spectatee.clip_size;
2069         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2070         self.health = spectatee.health;
2071         self.impulse = 0;
2072         self.items = spectatee.items;
2073         self.last_pickup = spectatee.last_pickup;
2074         self.hit_time = spectatee.hit_time;
2075         self.metertime = spectatee.metertime;
2076         self.strength_finished = spectatee.strength_finished;
2077         self.invincible_finished = spectatee.invincible_finished;
2078         self.pressedkeys = spectatee.pressedkeys;
2079         WEPSET_COPY_EE(self, spectatee);
2080         self.switchweapon = spectatee.switchweapon;
2081         self.switchingweapon = spectatee.switchingweapon;
2082         self.weapon = spectatee.weapon;
2083         self.nex_charge = spectatee.nex_charge;
2084         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2085         self.hagar_load = spectatee.hagar_load;
2086         self.minelayer_mines = spectatee.minelayer_mines;
2087         self.punchangle = spectatee.punchangle;
2088         self.view_ofs = spectatee.view_ofs;
2089         self.velocity = spectatee.velocity;
2090         self.dmg_take = spectatee.dmg_take;
2091         self.dmg_save = spectatee.dmg_save;
2092         self.dmg_inflictor = spectatee.dmg_inflictor;
2093         self.v_angle = spectatee.v_angle;
2094         self.angles = spectatee.v_angle;
2095         self.stat_respawn_time = spectatee.stat_respawn_time;
2096         if(!self.BUTTON_USE)
2097                 self.fixangle = TRUE;
2098         setorigin(self, spectatee.origin);
2099         setsize(self, spectatee.mins, spectatee.maxs);
2100         SetZoomState(spectatee.zoomstate);
2101     
2102     anticheat_spectatecopy(spectatee);
2103         self.hud = spectatee.hud;
2104         if(spectatee.vehicle)
2105     {
2106         self.fixangle = FALSE;
2107         //self.velocity = spectatee.vehicle.velocity;
2108         self.vehicle_health = spectatee.vehicle_health;
2109         self.vehicle_shield = spectatee.vehicle_shield;
2110         self.vehicle_energy = spectatee.vehicle_energy;
2111         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2112         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2113         self.vehicle_reload1 = spectatee.vehicle_reload1;
2114         self.vehicle_reload2 = spectatee.vehicle_reload2;
2115
2116         msg_entity = self;
2117         
2118         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2119             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2120             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2121             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2122
2123         //WriteByte (MSG_ONE, SVC_SETVIEW);
2124         //    WriteEntity(MSG_ONE, self);            
2125         //makevectors(spectatee.v_angle);
2126         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/    
2127     }
2128 }
2129
2130 float SpectateUpdate() {
2131         if(!self.enemy)
2132             return 0;           
2133
2134         if (self == self.enemy)
2135                 return 0;
2136
2137         if(self.enemy.classname != "player")
2138                 return 0;
2139
2140         SpectateCopy(self.enemy);
2141
2142         return 1;
2143 }
2144
2145
2146 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2147 entity CA_SpectateNext(entity start) {
2148         if (start.team == self.team) {
2149                 return start;
2150         }
2151         
2152         other = start;
2153         // continue from current player
2154         while(other && other.team != self.team) {
2155                 other = find(other, classname, "player");
2156         }
2157         
2158         if (!other) {
2159                 // restart from begining
2160                 other = find(other, classname, "player");
2161                 while(other && other.team != self.team) {
2162                         other = find(other, classname, "player");
2163                 }
2164         }
2165         
2166         return other;
2167 }
2168
2169 float SpectateNext(entity _prefer) {
2170         
2171         if(_prefer)
2172                 other = _prefer;        
2173         else
2174                 other = find(self.enemy, classname, "player");
2175         
2176         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2177                 // CA and ca players when spectating enemies is forbidden
2178                 other = CA_SpectateNext(other);
2179         } else {
2180                 // other modes and ca spectators or spectating enemies is allowed
2181                 if (!other)
2182                         other = find(other, classname, "player");
2183         }
2184         
2185         if (other)
2186                 self.enemy = other;
2187
2188         if(self.enemy.classname == "player") {
2189             /*if(self.enemy.vehicle)
2190             {      
2191             
2192             msg_entity = self;
2193             WriteByte(MSG_ONE, SVC_SETVIEW);
2194             WriteEntity(MSG_ONE, self.enemy);
2195             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2196             
2197             self.movetype = MOVETYPE_NONE;
2198             accuracy_resend(self);
2199             }
2200             else 
2201             {*/         
2202             msg_entity = self;
2203             WriteByte(MSG_ONE, SVC_SETVIEW);
2204             WriteEntity(MSG_ONE, self.enemy);
2205             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2206             self.movetype = MOVETYPE_NONE;
2207             accuracy_resend(self);
2208
2209             if(!SpectateUpdate())
2210                 PutObserverInServer();
2211         //}
2212         return 1;
2213         } else {
2214                 return 0;
2215         }
2216 }
2217
2218 /*
2219 =============
2220 ShowRespawnCountdown()
2221
2222 Update a respawn countdown display.
2223 =============
2224 */
2225 void ShowRespawnCountdown()
2226 {
2227         float number;
2228         if(self.deadflag == DEAD_NO) // just respawned?
2229                 return;
2230         else
2231         {
2232                 number = ceil(self.respawn_time - time);
2233                 if(number <= 0)
2234                         return;
2235                 if(number <= self.respawn_countdown)
2236                 {
2237                         self.respawn_countdown = number - 1;
2238                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2239                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number)); 
2240                 }
2241         }
2242 }
2243
2244 void LeaveSpectatorMode()
2245 {
2246         if(nJoinAllowed(self))
2247         {
2248                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2249                 {
2250                         self.classname = "player";
2251
2252                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2253                                 { JoinBestTeam(self, FALSE, TRUE); }
2254
2255                         if(autocvar_g_campaign)
2256                                 { campaign_bots_may_start = 1; }
2257
2258                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2259
2260                         PutClientInServer();
2261
2262                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2263                 }
2264                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2265         }
2266         else
2267         {
2268                 // Player may not join because g_maxplayers is set
2269                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2270         }
2271 }
2272
2273 /**
2274  * Determines whether the player is allowed to join. This depends on cvar
2275  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2276  * it checks whether the number of currently playing players exceeds g_maxplayers.
2277  * @return int number of free slots for players, 0 if none
2278  */
2279 float nJoinAllowed(entity ignore) {
2280         if(!ignore)
2281         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2282         // so report 0 free slots if restricted
2283         {
2284                 if(autocvar_g_forced_team_otherwise == "spectate")
2285                         return 0;
2286                 if(autocvar_g_forced_team_otherwise == "spectator")
2287                         return 0;
2288         }
2289
2290         if(self.team_forced < 0)
2291                 return 0; // forced spectators can never join
2292
2293         // TODO simplify this
2294         entity e;
2295         float totalClients = 0;
2296         FOR_EACH_CLIENT(e)
2297                 if(e != ignore)
2298                         totalClients += 1;
2299
2300         if (!autocvar_g_maxplayers)
2301                 return maxclients - totalClients;
2302
2303         float currentlyPlaying = 0;
2304         FOR_EACH_REALPLAYER(e)
2305                 currentlyPlaying += 1;
2306
2307         if(currentlyPlaying < autocvar_g_maxplayers)
2308                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2309
2310         return 0;
2311 }
2312
2313 /**
2314  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2315  * g_maxplayers_spectator_blocktime seconds
2316  */
2317 void checkSpectatorBlock() {
2318         if(self.classname == "spectator" || self.classname == "observer") {
2319                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2320                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2321                         dropclient(self);
2322                 }
2323         }
2324 }
2325
2326 void PrintWelcomeMessage()
2327 {
2328         if(self.motd_actived_time == 0)
2329         {
2330                 if (autocvar_g_campaign) {
2331                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2332                                 self.motd_actived_time = time;
2333                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2334                         }
2335                 } else {
2336                         if (self.BUTTON_INFO) {
2337                                 self.motd_actived_time = time;
2338                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2339                         }
2340                 }
2341         }
2342         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2343         {
2344                 if (autocvar_g_campaign) {
2345                         if (self.BUTTON_INFO)
2346                                 self.motd_actived_time = time;
2347                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2348                                 self.motd_actived_time = 0;
2349                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2350                         }
2351                 } else {
2352                         if (self.BUTTON_INFO)
2353                                 self.motd_actived_time = time;
2354                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2355                                 self.motd_actived_time = 0;
2356                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2357                         }
2358                 }
2359         }
2360         else //if(self.motd_actived_time < 0) // just connected, motd is active
2361         {
2362                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2363                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2364                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2365                 {
2366                         // instanctly hide MOTD
2367                         self.motd_actived_time = 0;
2368                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2369                 }
2370         }
2371 }
2372
2373 void ObserverThink()
2374 {
2375         float prefered_movetype;
2376         if (self.flags & FL_JUMPRELEASED) {
2377                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2378                         self.flags &~= FL_JUMPRELEASED;
2379                         self.flags |= FL_SPAWNING;
2380                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2381                         self.flags &~= FL_JUMPRELEASED;
2382                         if(SpectateNext(world) == 1) {
2383                                 self.classname = "spectator";
2384                         }
2385                 } else {
2386                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2387                         if (self.movetype != prefered_movetype)
2388                                 self.movetype = prefered_movetype;
2389                 }
2390         } else {
2391                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2392                         self.flags |= FL_JUMPRELEASED;
2393                         if(self.flags & FL_SPAWNING)
2394                         {
2395                                 self.flags &~= FL_SPAWNING;
2396                                 LeaveSpectatorMode();
2397                                 return;
2398                         }
2399                 }
2400         }
2401 }
2402
2403 void SpectatorThink()
2404 {
2405         if (self.flags & FL_JUMPRELEASED) {
2406                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2407                         self.flags &~= FL_JUMPRELEASED;
2408                         self.flags |= FL_SPAWNING;
2409                 } else if(self.BUTTON_ATCK) {
2410                         self.flags &~= FL_JUMPRELEASED;
2411                         if(SpectateNext(world) == 1) {
2412                                 self.classname = "spectator";
2413                         } else {
2414                                 self.classname = "observer";
2415                                 PutClientInServer();
2416                         }
2417                 } else if (self.BUTTON_ATCK2) {
2418                         self.flags &~= FL_JUMPRELEASED;
2419                         self.classname = "observer";
2420                         PutClientInServer();
2421                 } else {
2422                         if(!SpectateUpdate())
2423                                 PutObserverInServer();
2424                 }
2425         } else {
2426                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2427                         self.flags |= FL_JUMPRELEASED;
2428                         if(self.flags & FL_SPAWNING)
2429                         {
2430                                 self.flags &~= FL_SPAWNING;
2431                                 LeaveSpectatorMode();
2432                                 return;
2433                         }
2434                 }
2435                 if(!SpectateUpdate())
2436                         PutObserverInServer();
2437         }
2438
2439         self.flags |= FL_CLIENT | FL_NOTARGET;
2440 }
2441
2442 void PlayerUseKey()
2443 {
2444         if(self.classname != "player")
2445                 return;
2446
2447         if(self.vehicle)
2448         {
2449         vehicles_exit(VHEF_NORMAL);
2450         return;
2451         }
2452         
2453         // a use key was pressed; call handlers
2454         MUTATOR_CALLHOOK(PlayerUseKey);
2455 }
2456
2457 /*
2458 =============
2459 PlayerPreThink
2460
2461 Called every frame for each client before the physics are run
2462 =============
2463 */
2464 .float usekeypressed;
2465 void() nexball_setstatus;
2466 .float items_added;
2467 void PlayerPreThink (void)
2468 {
2469         WarpZone_PlayerPhysics_FixVAngle();
2470
2471         self.stat_game_starttime = game_starttime;
2472         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2473         self.stat_leadlimit = autocvar_leadlimit;
2474
2475         if(g_arena || (g_ca && !allowed_to_spawn))
2476                 self.stat_respawn_time = 0;
2477         else
2478                 self.stat_respawn_time = self.respawn_time;
2479
2480         if(frametime)
2481         {
2482                 // physics frames: update anticheat stuff
2483                 anticheat_prethink();
2484         }
2485
2486         if(blockSpectators && frametime)
2487                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2488                 checkSpectatorBlock();
2489
2490         zoomstate_set = 0;
2491
2492         if(self.netname_previous != self.netname)
2493         {
2494                 if(autocvar_sv_eventlog)
2495                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2496                 if(self.netname_previous)
2497                         strunzone(self.netname_previous);
2498                 self.netname_previous = strzone(self.netname);
2499         }
2500
2501         // version nagging
2502         if(self.version_nagtime)
2503                 if(self.cvar_g_xonoticversion)
2504                         if(time > self.version_nagtime)
2505                         {
2506                                 // don't notify git users
2507                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2508                                 {
2509                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2510                                         {
2511                                                 // notify release users if connecting to git
2512                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2513                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2514                                         }
2515                                         else
2516                                         {
2517                                                 float r;
2518                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2519                                                 if(r < 0)
2520                                                 {
2521                                                         // give users new version
2522                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2523                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2524                                                 }
2525                                                 else if(r > 0)
2526                                                 {
2527                                                         // notify users about old server version
2528                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2529                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2530                                                 }
2531                                         }
2532                                 }
2533                                 self.version_nagtime = 0;
2534                         }
2535
2536         // GOD MODE info
2537         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2538         {
2539                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2540                 self.max_armorvalue = 0;
2541         }
2542
2543 #ifdef TETRIS
2544         if (TetrisPreFrame())
2545                 return;
2546 #endif
2547
2548         MUTATOR_CALLHOOK(PlayerPreThink);
2549
2550         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2551         {
2552                 if(self.BUTTON_USE && !self.usekeypressed)
2553                         PlayerUseKey();
2554                 self.usekeypressed = self.BUTTON_USE;
2555         }
2556
2557         if(clienttype(self) == CLIENTTYPE_REAL)
2558                 PrintWelcomeMessage();
2559
2560         if(self.classname == "player") {
2561
2562                 CheckRules_Player();
2563
2564                 if (intermission_running)
2565                 {
2566                         IntermissionThink ();   // otherwise a button could be missed between
2567                         return;                                 // the think tics
2568                 }
2569
2570                 //don't allow the player to turn around while game is paused!
2571                 if(timeout_status == TIMEOUT_ACTIVE) {
2572                         // FIXME turn this into CSQC stuff
2573                         self.v_angle = self.lastV_angle;
2574                         self.angles = self.lastV_angle;
2575                         self.fixangle = TRUE;
2576                 }
2577
2578                 if(frametime)
2579                 {
2580                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2581                         {
2582                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2583                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2584                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2585
2586                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2587                                 {
2588                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2589                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2590                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2591                                 }
2592                         }
2593                         else
2594                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2595
2596                         player_powerups();
2597                 }
2598
2599                 if (g_minstagib)
2600                         minstagib_ammocheck();
2601
2602                 if (self.deadflag != DEAD_NO)
2603                 {
2604                         float button_pressed, force_respawn;
2605                         if(self.personal && g_race_qualifying)
2606                         {
2607                                 if(time > self.respawn_time)
2608                                 {
2609                                         self.respawn_time = time + 1; // only retry once a second
2610                                         respawn();
2611                                         self.impulse = 141;
2612                                 }
2613                         }
2614                         else
2615                         {
2616                                 if(frametime)
2617                                         player_anim();
2618                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2619                                 force_respawn = (g_ca || g_cts || autocvar_g_forced_respawn);
2620                                 if (self.deadflag == DEAD_DYING)
2621                                 {
2622                                         if(force_respawn)
2623                                                 self.deadflag = DEAD_RESPAWNING;
2624                                         else if(!button_pressed)
2625                                                 self.deadflag = DEAD_DEAD;
2626                                 }
2627                                 else if (self.deadflag == DEAD_DEAD)
2628                                 {
2629                                         if(button_pressed)
2630                                                 self.deadflag = DEAD_RESPAWNABLE;
2631                                 }
2632                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2633                                 {
2634                                         if(!button_pressed)
2635                                                 self.deadflag = DEAD_RESPAWNING;
2636                                 }
2637                                 else if (self.deadflag == DEAD_RESPAWNING)
2638                                 {
2639                                         if(time > self.respawn_time)
2640                                         {
2641                                                 self.respawn_time = time + 1; // only retry once a second
2642                                                 respawn();
2643                                         }
2644                                 }
2645                                 ShowRespawnCountdown();
2646                         }
2647
2648                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2649                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2650                                 self.stat_respawn_time *= -1;
2651
2652                         return;
2653                 }
2654
2655                 self.prevorigin = self.origin;
2656
2657                 float do_crouch = self.BUTTON_CROUCH;
2658                 if(self.hook.state)
2659                         do_crouch = 0;
2660                 if(self.health <= g_bloodloss)
2661                         do_crouch = 1;
2662                 if(self.vehicle)
2663                         do_crouch = 0;
2664                 if(self.freezetag_frozen)
2665                         do_crouch = 0;
2666                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2667                         do_crouch = 0;
2668
2669                 if (do_crouch)
2670                 {
2671                         if (!self.crouch)
2672                         {
2673                                 self.crouch = TRUE;
2674                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2675                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2676                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2677                         }
2678                 }
2679                 else
2680                 {
2681                         if (self.crouch)
2682                         {
2683                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2684                                 if (!trace_startsolid)
2685                                 {
2686                                         self.crouch = FALSE;
2687                                         self.view_ofs = PL_VIEW_OFS;
2688                                         setsize (self, PL_MIN, PL_MAX);
2689                                 }
2690                         }
2691                 }
2692
2693                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2694                 {
2695                         if(self.bloodloss_timer < time)
2696                         {
2697                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2698                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2699                         }
2700                 }
2701
2702                 FixPlayermodel();
2703
2704                 GrapplingHookFrame();
2705
2706                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2707                 //if(frametime)
2708                 {
2709                         self.items &~= self.items_added;
2710
2711                         W_WeaponFrame();
2712
2713                         self.items_added = 0;
2714                         if(self.items & IT_JETPACK)
2715                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2716                                         self.items_added |= IT_FUEL;
2717
2718                         self.items |= self.items_added;
2719                 }
2720
2721                 player_regen();
2722
2723                 // rot nex charge to the charge limit
2724                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2725                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2726
2727                 if(frametime)
2728                         player_anim();
2729
2730                 if(g_nexball)
2731                         nexball_setstatus();
2732                 
2733                 // secret status
2734                 secrets_setstatus();
2735                 
2736                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2737
2738                 //self.angles_y=self.v_angle_y + 90;   // temp
2739         } else if(gameover) {
2740                 if (intermission_running)
2741                         IntermissionThink ();   // otherwise a button could be missed between
2742                 return;
2743         } else if(self.classname == "observer") {
2744                 ObserverThink();
2745         } else if(self.classname == "spectator") {
2746                 SpectatorThink();
2747         }
2748
2749         if(!zoomstate_set)
2750                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2751
2752         float oldspectatee_status;
2753         oldspectatee_status = self.spectatee_status;
2754         if(self.classname == "spectator")
2755                 self.spectatee_status = num_for_edict(self.enemy);
2756         else if(self.classname == "observer")
2757                 self.spectatee_status = num_for_edict(self);
2758         else
2759                 self.spectatee_status = 0;
2760         if(self.spectatee_status != oldspectatee_status)
2761         {
2762                 ClientData_Touch(self);
2763                 if(g_race || g_cts)
2764                         race_InitSpectator();
2765         }
2766
2767         if(self.teamkill_soundtime)
2768         if(time > self.teamkill_soundtime)
2769         {
2770                 self.teamkill_soundtime = 0;
2771
2772                 entity oldpusher, oldself;
2773
2774                 oldself = self; self = self.teamkill_soundsource;
2775                 oldpusher = self.pusher; self.pusher = oldself;
2776
2777                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2778
2779                 self.pusher = oldpusher;
2780                 self = oldself;
2781         }
2782
2783         if(self.taunt_soundtime)
2784         if(time > self.taunt_soundtime)
2785         {
2786                 self.taunt_soundtime = 0;
2787                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2788         }
2789
2790         target_voicescript_next(self);
2791
2792         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2793         if(!self.weapon)
2794                 self.clip_load = self.clip_size = 0;
2795 }
2796
2797 float isInvisibleString(string s)
2798 {
2799         float i, n, c;
2800         s = strdecolorize(s);
2801         for((i = 0), (n = strlen(s)); i < n; ++i)
2802         {
2803                 c = str2chr(s, i);
2804                 switch(c)
2805                 {
2806                         case 0:
2807                         case 32: // space
2808                                 break;
2809                         case 192: // charmap space
2810                                 if (!autocvar_utf8_enable)
2811                                         break;
2812                                 return FALSE;
2813                         case 160: // space in unicode fonts
2814                         case 0xE000 + 192: // utf8 charmap space
2815                                 if (autocvar_utf8_enable)
2816                                         break;
2817                         default:
2818                                 return FALSE;
2819                 }
2820         }
2821         return TRUE;
2822 }
2823
2824 /*
2825 =============
2826 PlayerPostThink
2827
2828 Called every frame for each client after the physics are run
2829 =============
2830 */
2831 .float idlekick_lasttimeleft;
2832 void PlayerPostThink (void)
2833 {
2834         // Savage: Check for nameless players
2835         if (isInvisibleString(self.netname)) {
2836                 self.netname = "Player";
2837                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2838         }
2839
2840         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2841         {
2842                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2843                 {
2844                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2845                 }
2846                 else
2847                 {
2848                         float timeleft;
2849                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2850                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2851                         {
2852                                 if(!self.idlekick_lasttimeleft)
2853                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2854                         }
2855                         if(timeleft <= 0)
2856                         {
2857                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2858                                 dropclient(self);
2859                                 return;
2860                         }
2861                         else if(timeleft <= 10)
2862                         {
2863                                 if(timeleft != self.idlekick_lasttimeleft)
2864                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2865                                 self.idlekick_lasttimeleft = timeleft;
2866                         }
2867                 }
2868         }
2869
2870 #ifdef TETRIS
2871         if(self.impulse == 100)
2872                 ImpulseCommands();
2873         if (!TetrisPostFrame())
2874         {
2875 #endif
2876
2877         CheatFrame();
2878
2879         //CheckPlayerJump();
2880
2881         if(self.classname == "player") {
2882                 CheckRules_Player();
2883                 UpdateChatBubble();
2884                 if (self.impulse)
2885                         ImpulseCommands();
2886                 if (intermission_running)
2887                         return;         // intermission or finale
2888                 GetPressedKeys();
2889         }
2890         
2891 #ifdef TETRIS
2892         }
2893 #endif
2894
2895         /*
2896         float i;
2897         for(i = 0; i < 1000; ++i)
2898         {
2899                 vector end;
2900                 end = self.origin + '0 0 1024' + 512 * randomvec();
2901                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2902                 if(trace_fraction < 1)
2903                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2904                 {
2905                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2906                         break;
2907                 }
2908         }
2909         */
2910
2911         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2912
2913         if(self.waypointsprite_attachedforcarrier)
2914                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2915
2916         playerdemo_write();
2917
2918         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2919         {
2920                 if not(self.stored_netname)
2921                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2922                 if(self.stored_netname != self.netname)
2923                 {
2924                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2925                         strunzone(self.stored_netname);
2926                         self.stored_netname = strzone(self.netname);
2927                 }
2928         }
2929
2930         /*
2931         if(g_race)
2932                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2933         */
2934
2935         CSQCMODEL_AUTOUPDATE();
2936 }