qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  54         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  55 }
  56
  57 bool ClientData_Send(entity this, entity to, int sf)
  58 {
  59         if(to != self.owner)
  60         {
  61                 error("wtf");
  62                 return false;
  63         }
  64
  65         entity e;
  66
  67         e = to;
  68         if(IS_SPEC(to))
  69                 e = to.enemy;
  70
  71         sf = 0;
  72
  73         if(e.race_completed)
  74                 sf |= 1; // forced scoreboard
  75         if(to.spectatee_status)
  76                 sf |= 2; // spectator ent number follows
  77         if(e.zoomstate)
  78                 sf |= 4; // zoomed
  79         if(e.porto_v_angle_held)
  80                 sf |= 8; // angles held
  81
  82         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  83         WriteByte(MSG_ENTITY, sf);
  84
  85         if(sf & 2)
  86                 WriteByte(MSG_ENTITY, to.spectatee_status);
  87
  88         if(sf & 8)
  89         {
  90                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  91                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  92         }
  93
  94         return true;
  95 }
  96
  97 void ClientData_Attach()
  98 {SELFPARAM();
  99         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
 100         self.clientdata.drawonlytoclient = self;
 101         self.clientdata.owner = self;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectatee(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178         UpdatePlayerSounds();
 179 }
 180
 181 /*
 182 =============
 183 PutObserverInServer
 184
 185 putting a client as observer in the server
 186 =============
 187 */
 188 void FixPlayermodel(entity player);
 189 void PutObserverInServer()
 190 {SELFPARAM();
 191         entity  spot;
 192     self.hud = HUD_NORMAL;
 193
 194         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 195
 196         spot = SelectSpawnPoint (true);
 197         if(!spot)
 198                 error("No spawnpoints for observers?!?\n");
 199         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 200
 201         if(IS_REAL_CLIENT(self))
 202         {
 203                 msg_entity = self;
 204                 WriteByte(MSG_ONE, SVC_SETVIEW);
 205                 WriteEntity(MSG_ONE, self);
 206         }
 207
 208         self.frags = FRAGS_SPECTATOR;
 209         self.bot_attack = false;
 210
 211         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 212
 213         Portal_ClearAll(self);
 214
 215         Unfreeze(self);
 216
 217         if(self.alivetime)
 218         {
 219                 if(!warmup_stage)
 220                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 221                 self.alivetime = 0;
 222         }
 223
 224         if(self.vehicle)
 225                 vehicles_exit(VHEF_RELEASE);
 226
 227         WaypointSprite_PlayerDead();
 228
 229         if(!mutator_returnvalue)  // mutator prevents resetting teams
 230                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 231
 232         if(self.killcount != FRAGS_SPECTATOR)
 233         {
 234                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 235                 if(!intermission_running)
 236                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 237                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 238
 239                 if(self.just_joined == false) {
 240                         LogTeamchange(self.playerid, -1, 4);
 241                 } else
 242                         self.just_joined = false;
 243         }
 244
 245         PlayerScore_Clear(self); // clear scores when needed
 246
 247         accuracy_resend(self);
 248
 249         self.spectatortime = time;
 250
 251         self.classname = STR_OBSERVER;
 252         self.iscreature = false;
 253         self.teleportable = TELEPORT_SIMPLE;
 254         self.damagedbycontents = false;
 255         self.health = FRAGS_SPECTATOR;
 256         self.takedamage = DAMAGE_NO;
 257         self.solid = SOLID_NOT;
 258         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 259         self.flags = FL_CLIENT | FL_NOTARGET;
 260         self.armorvalue = 666;
 261         self.effects = 0;
 262         self.armorvalue = autocvar_g_balance_armor_start;
 263         self.pauserotarmor_finished = 0;
 264         self.pauserothealth_finished = 0;
 265         self.pauseregen_finished = 0;
 266         self.damageforcescale = 0;
 267         self.death_time = 0;
 268         self.respawn_flags = 0;
 269         self.respawn_time = 0;
 270         self.stat_respawn_time = 0;
 271         self.alpha = 0;
 272         self.scale = 0;
 273         self.fade_time = 0;
 274         self.pain_frame = 0;
 275         self.pain_finished = 0;
 276         self.strength_finished = 0;
 277         self.invincible_finished = 0;
 278         self.superweapons_finished = 0;
 279         self.pushltime = 0;
 280         self.istypefrag = 0;
 281         self.think = func_null;
 282         self.nextthink = 0;
 283         self.hook_time = 0;
 284         self.deadflag = DEAD_NO;
 285         self.angles = spot.angles;
 286         self.angles_z = 0;
 287         self.fixangle = true;
 288         self.crouch = false;
 289         self.revival_time = 0;
 290
 291         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 292         self.prevorigin = self.origin;
 293         self.items = 0;
 294         self.weapons = '0 0 0';
 295         self.model = "";
 296         FixPlayermodel(self);
 297         setmodel(self, MDL_Null);
 298         self.drawonlytoclient = self;
 299
 300         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 301         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 302
 303         self.weapon = 0;
 304         self.weaponname = "";
 305         self.switchingweapon = 0;
 306         self.weaponmodel = "";
 307         self.weaponentity = world;
 308         self.exteriorweaponentity = world;
 309         self.killcount = FRAGS_SPECTATOR;
 310         self.velocity = '0 0 0';
 311         self.avelocity = '0 0 0';
 312         self.punchangle = '0 0 0';
 313         self.punchvector = '0 0 0';
 314         self.oldvelocity = self.velocity;
 315         self.fire_endtime = -1;
 316         self.event_damage = func_null;
 317 }
 318
 319 .float model_randomizer;
 320 void FixPlayermodel(entity player)
 321 {
 322         string defaultmodel = "";
 323         int defaultskin = 0;
 324         if(autocvar_sv_defaultcharacter)
 325         {
 326                 if(teamplay)
 327                 {
 328                         string s = Static_Team_ColorName_Lower(player.team);
 329                         if (s != "neutral")
 330                         {
 331                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 332                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 333                         }
 334                 }
 335
 336                 if(defaultmodel == "")
 337                 {
 338                         defaultmodel = autocvar_sv_defaultplayermodel;
 339                         defaultskin = autocvar_sv_defaultplayerskin;
 340                 }
 341
 342                 int n = tokenize_console(defaultmodel);
 343                 if(n > 0)
 344                 {
 345                         defaultmodel = argv(floor(n * player.model_randomizer));
 346                         // However, do NOT randomize if the player-selected model is in the list.
 347                         for (int i = 0; i < n; ++i)
 348                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 349                                         defaultmodel = argv(i);
 350                 }
 351
 352                 int i = strstrofs(defaultmodel, ":", 0);
 353                 if(i >= 0)
 354                 {
 355                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 356                         defaultmodel = substring(defaultmodel, 0, i);
 357                 }
 358         }
 359         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 360         defaultmodel = ret_string;
 361         defaultskin = ret_int;
 362
 363         bool chmdl = false;
 364         int oldskin;
 365         if(defaultmodel != "")
 366         {
 367                 if (defaultmodel != player.model)
 368                 {
 369                         vector m1 = player.mins;
 370                         vector m2 = player.maxs;
 371                         setplayermodel (player, defaultmodel);
 372                         setsize (player, m1, m2);
 373                         chmdl = true;
 374                 }
 375
 376                 oldskin = player.skin;
 377                 player.skin = defaultskin;
 378         } else {
 379                 if (player.playermodel != player.model || player.playermodel == "")
 380                 {
 381                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 382                         vector m1 = player.mins;
 383                         vector m2 = player.maxs;
 384                         setplayermodel (player, player.playermodel);
 385                         setsize (player, m1, m2);
 386                         chmdl = true;
 387                 }
 388
 389                 oldskin = player.skin;
 390                 player.skin = stof(player.playerskin);
 391         }
 392
 393         if(chmdl || oldskin != player.skin) // model or skin has changed
 394         {
 395                 player.species = player_getspecies(); // update species
 396                 UpdatePlayerSounds(); // update skin sounds
 397         }
 398
 399         if(!teamplay)
 400                 if(strlen(autocvar_sv_defaultplayercolors))
 401                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 402                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 403 }
 404
 405
 406 /** Called when a client spawns in the server */
 407 void PutClientInServer()
 408 {
 409         SELFPARAM();
 410         if (IS_BOT_CLIENT(this)) {
 411                 this.classname = STR_PLAYER;
 412         } else if (IS_REAL_CLIENT(this)) {
 413                 msg_entity = this;
 414                 WriteByte(MSG_ONE, SVC_SETVIEW);
 415                 WriteEntity(MSG_ONE, this);
 416         }
 417         if (gameover) {
 418                 this.classname = STR_OBSERVER;
 419         }
 420
 421         SetSpectatee(this, NULL);
 422
 423         // reset player keys
 424         this.itemkeys = 0;
 425
 426         MUTATOR_CALLHOOK(PutClientInServer, this);
 427
 428         if (IS_OBSERVER(this)) {
 429                 PutObserverInServer();
 430         } else if (IS_PLAYER(this)) {
 431                 accuracy_resend(this);
 432
 433                 if (this.team < 0)
 434                         JoinBestTeam(this, false, true);
 435
 436                 entity spot = SelectSpawnPoint(false);
 437                 if (!spot) {
 438                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 439                         return; // spawn failed
 440                 }
 441
 442                 this.classname = STR_PLAYER;
 443                 this.wasplayer = true;
 444                 this.iscreature = true;
 445                 this.teleportable = TELEPORT_NORMAL;
 446                 this.damagedbycontents = true;
 447                 this.movetype = MOVETYPE_WALK;
 448                 this.solid = SOLID_SLIDEBOX;
 449                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 450                 if (autocvar_g_playerclip_collisions)
 451                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 452                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 453                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 454                 this.frags = FRAGS_PLAYER;
 455                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 456                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 457                 if (autocvar__notarget)
 458                         this.flags |= FL_NOTARGET;
 459                 this.takedamage = DAMAGE_AIM;
 460                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 461                 this.dmg = 2; // WTF
 462
 463                 if (warmup_stage) {
 464                         this.ammo_shells = warmup_start_ammo_shells;
 465                         this.ammo_nails = warmup_start_ammo_nails;
 466                         this.ammo_rockets = warmup_start_ammo_rockets;
 467                         this.ammo_cells = warmup_start_ammo_cells;
 468                         this.ammo_plasma = warmup_start_ammo_plasma;
 469                         this.ammo_fuel = warmup_start_ammo_fuel;
 470                         this.health = warmup_start_health;
 471                         this.armorvalue = warmup_start_armorvalue;
 472                         this.weapons = WARMUP_START_WEAPONS;
 473                 } else {
 474                         this.ammo_shells = start_ammo_shells;
 475                         this.ammo_nails = start_ammo_nails;
 476                         this.ammo_rockets = start_ammo_rockets;
 477                         this.ammo_cells = start_ammo_cells;
 478                         this.ammo_plasma = start_ammo_plasma;
 479                         this.ammo_fuel = start_ammo_fuel;
 480                         this.health = start_health;
 481                         this.armorvalue = start_armorvalue;
 482                         this.weapons = start_weapons;
 483                 }
 484
 485                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 486
 487                 this.items = start_items;
 488
 489                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 490                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 491                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 492                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 493                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 494                 // extend the pause of rotting if client was reset at the beginning of the countdown
 495                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 496                         float f = game_starttime - time;
 497                         this.spawnshieldtime += f;
 498                         this.pauserotarmor_finished += f;
 499                         this.pauserothealth_finished += f;
 500                         this.pauseregen_finished += f;
 501                 }
 502                 this.damageforcescale = 2;
 503                 this.death_time = 0;
 504                 this.respawn_flags = 0;
 505                 this.respawn_time = 0;
 506                 this.stat_respawn_time = 0;
 507                 this.scale = autocvar_sv_player_scale;
 508                 this.fade_time = 0;
 509                 this.pain_frame = 0;
 510                 this.pain_finished = 0;
 511                 this.pushltime = 0;
 512                 this.think = func_null; // players have no think function
 513                 this.nextthink = 0;
 514                 this.dmg_team = 0;
 515                 this.ballistics_density = autocvar_g_ballistics_density_player;
 516
 517                 this.deadflag = DEAD_NO;
 518
 519                 this.angles = spot.angles;
 520                 this.angles_z = 0; // never spawn tilted even if the spot says to
 521                 if (IS_BOT_CLIENT(this))
 522                         this.v_angle = this.angles;
 523                 this.fixangle = true; // turn this way immediately
 524                 this.oldvelocity = this.velocity = '0 0 0';
 525                 this.avelocity = '0 0 0';
 526                 this.punchangle = '0 0 0';
 527                 this.punchvector = '0 0 0';
 528
 529                 this.strength_finished = 0;
 530                 this.invincible_finished = 0;
 531                 this.fire_endtime = -1;
 532                 this.revival_time = 0;
 533                 this.air_finished = time + 12;
 534
 535                 entity spawnevent = spawn();
 536                 spawnevent.owner = this;
 537                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 538
 539                 // Cut off any still running player sounds.
 540                 stopsound(this, CH_PLAYER_SINGLE);
 541
 542                 this.model = "";
 543                 FixPlayermodel(this);
 544                 this.drawonlytoclient = NULL;
 545
 546                 this.crouch = false;
 547                 this.view_ofs = PL_VIEW_OFS;
 548                 setsize(this, PL_MIN, PL_MAX);
 549                 this.spawnorigin = spot.origin;
 550                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 551                 // don't reset back to last position, even if new position is stuck in solid
 552                 this.oldorigin = this.origin;
 553                 this.prevorigin = this.origin;
 554                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 555         this.hud = HUD_NORMAL;
 556
 557                 this.event_damage = PlayerDamage;
 558
 559                 this.bot_attack = true;
 560                 this.monster_attack = true;
 561
 562                 this.spider_slowness = 0;
 563
 564                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = false;
 565
 566                 if (this.killcount == FRAGS_SPECTATOR) {
 567                         PlayerScore_Clear(this);
 568                         this.killcount = 0;
 569                 }
 570
 571                 CL_SpawnWeaponentity(this);
 572                 this.alpha = default_player_alpha;
 573                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 574                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 575
 576                 this.speedrunning = false;
 577
 578                 target_voicescript_clear(this);
 579
 580                 // reset fields the weapons may use
 581                 FOREACH(Weapons, true, LAMBDA(
 582                         it.wr_resetplayer(it);
 583                         // reload all reloadable weapons
 584                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 585                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 586                         }
 587                 ));
 588
 589                 {
 590                         string s = spot.target;
 591                         spot.target = string_null;
 592                         WITH(entity, activator, this, LAMBDA(
 593                                 WITH(entity, self, spot, SUB_UseTargets())
 594                         ));
 595                         spot.target = s;
 596                 }
 597
 598                 Unfreeze(this);
 599
 600                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 601
 602                 if (autocvar_spawn_debug)
 603                 {
 604                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 605                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 606                 }
 607
 608                 this.switchweapon = w_getbestweapon(this);
 609                 this.cnt = -1; // W_LastWeapon will not complain
 610                 this.weapon = 0;
 611                 this.weaponname = "";
 612                 this.switchingweapon = 0;
 613
 614                 if (!warmup_stage && !this.alivetime)
 615                         this.alivetime = time;
 616
 617                 antilag_clear(this);
 618         }
 619 }
 620
 621 .float ebouncefactor, ebouncestop; // electro's values
 622 // TODO do we need all these fields, or should we stop autodetecting runtime
 623 // changes and just have a console command to update this?
 624 bool ClientInit_SendEntity(entity this, entity to, int sf)
 625 {
 626         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 627         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 636
 637         if(sv_foginterval && world.fog != "")
 638                 WriteString(MSG_ENTITY, world.fog);
 639         else
 640                 WriteString(MSG_ENTITY, "");
 641         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 642         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 643         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 644         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 645         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 646         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 647         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 648         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 650         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 651         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 652         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 653         return true;
 654 }
 655
 656 void ClientInit_CheckUpdate()
 657 {SELFPARAM();
 658         self.nextthink = time;
 659         if(self.count != autocvar_g_balance_armor_blockpercent)
 660         {
 661                 self.count = autocvar_g_balance_armor_blockpercent;
 662                 self.SendFlags |= 1;
 663         }
 664         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 665         {
 666                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 667                 self.SendFlags |= 1;
 668         }
 669         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 670         {
 671                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 672                 self.SendFlags |= 1;
 673         }
 674         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 675         {
 676                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 677                 self.SendFlags |= 1;
 678         }
 679         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 680         {
 681                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 682                 self.SendFlags |= 1;
 683         }
 684 }
 685
 686 void ClientInit_Spawn()
 687 {SELFPARAM();
 688         entity e = spawn();
 689         e.classname = "clientinit";
 690         e.think = ClientInit_CheckUpdate;
 691         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 692
 693         WITH(entity, self, e, ClientInit_CheckUpdate());
 694 }
 695
 696 /*
 697 =============
 698 SetNewParms
 699 =============
 700 */
 701 void SetNewParms (void)
 702 {
 703         // initialize parms for a new player
 704         parm1 = -(86400 * 366);
 705
 706         MUTATOR_CALLHOOK(SetNewParms);
 707 }
 708
 709 /*
 710 =============
 711 SetChangeParms
 712 =============
 713 */
 714 void SetChangeParms (void)
 715 {SELFPARAM();
 716         // save parms for level change
 717         parm1 = self.parm_idlesince - time;
 718
 719         MUTATOR_CALLHOOK(SetChangeParms);
 720 }
 721
 722 /*
 723 =============
 724 DecodeLevelParms
 725 =============
 726 */
 727 void DecodeLevelParms (void)
 728 {SELFPARAM();
 729         // load parms
 730         self.parm_idlesince = parm1;
 731         if(self.parm_idlesince == -(86400 * 366))
 732                 self.parm_idlesince = time;
 733
 734         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 735         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 736
 737         MUTATOR_CALLHOOK(DecodeLevelParms);
 738 }
 739
 740 /*
 741 =============
 742 ClientKill
 743
 744 Called when a client types 'kill' in the console
 745 =============
 746 */
 747
 748 .float clientkill_nexttime;
 749 void ClientKill_Now_TeamChange()
 750 {SELFPARAM();
 751         if(self.killindicator_teamchange == -1)
 752         {
 753                 JoinBestTeam( self, false, true );
 754         }
 755         else if(self.killindicator_teamchange == -2)
 756         {
 757                 if(blockSpectators)
 758                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 759                 PutObserverInServer();
 760         }
 761         else
 762                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 763         self.killindicator_teamchange = 0;
 764 }
 765
 766 void ClientKill_Now()
 767 {SELFPARAM();
 768         if(self.vehicle)
 769         {
 770             vehicles_exit(VHEF_RELEASE);
 771             if(!self.killindicator_teamchange)
 772             {
 773             self.vehicle_health = -1;
 774             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 775             }
 776         }
 777
 778         if(self.killindicator && !wasfreed(self.killindicator))
 779                 remove(self.killindicator);
 780
 781         self.killindicator = world;
 782
 783         if(self.killindicator_teamchange)
 784                 ClientKill_Now_TeamChange();
 785
 786         if(IS_PLAYER(self))
 787                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 788
 789         // now I am sure the player IS dead
 790 }
 791 void KillIndicator_Think()
 792 {SELFPARAM();
 793         if (gameover)
 794         {
 795                 self.owner.killindicator = world;
 796                 remove(self);
 797                 return;
 798         }
 799
 800         if (self.owner.alpha < 0 && !self.owner.vehicle)
 801         {
 802                 self.owner.killindicator = world;
 803                 remove(self);
 804                 return;
 805         }
 806
 807         if(self.cnt <= 0)
 808         {
 809                 WITH(entity, self, self.owner, ClientKill_Now());
 810                 return;
 811         }
 812     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 813     {
 814         self.nextthink = time + 1;
 815         self.cnt -= 1;
 816     }
 817         else
 818         {
 819                 if(self.cnt <= 10)
 820                         setmodel(self, MDL_NUM(self.cnt));
 821                 if(IS_REAL_CLIENT(self.owner))
 822                 {
 823                         if(self.cnt <= 10)
 824                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 825                 }
 826                 self.nextthink = time + 1;
 827                 self.cnt -= 1;
 828         }
 829 }
 830
 831 float clientkilltime;
 832 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 833 {SELFPARAM();
 834         float killtime;
 835         float starttime;
 836         entity e;
 837
 838         if (gameover)
 839                 return;
 840
 841         killtime = autocvar_g_balance_kill_delay;
 842
 843         if(g_race_qualifying || g_cts)
 844                 killtime = 0;
 845
 846     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 847         return;
 848
 849         self.killindicator_teamchange = targetteam;
 850
 851     if(!self.killindicator)
 852         {
 853                 if(self.deadflag == DEAD_NO)
 854                 {
 855                         killtime = max(killtime, self.clientkill_nexttime - time);
 856                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 857                 }
 858
 859                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 860                 {
 861                         ClientKill_Now();
 862                 }
 863                 else
 864                 {
 865                         starttime = max(time, clientkilltime);
 866
 867                         self.killindicator = spawn();
 868                         self.killindicator.owner = self;
 869                         self.killindicator.scale = 0.5;
 870                         setattachment(self.killindicator, self, "");
 871                         setorigin(self.killindicator, '0 0 52');
 872                         self.killindicator.think = KillIndicator_Think;
 873                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 874                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 875                         self.killindicator.cnt = ceil(killtime);
 876                         self.killindicator.count = bound(0, ceil(killtime), 10);
 877                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 878
 879                         for(e = world; (e = find(e, classname, "body")) != world; )
 880                         {
 881                                 if(e.enemy != self)
 882                                         continue;
 883                                 e.killindicator = spawn();
 884                                 e.killindicator.owner = e;
 885                                 e.killindicator.scale = 0.5;
 886                                 setattachment(e.killindicator, e, "");
 887                                 setorigin(e.killindicator, '0 0 52');
 888                                 e.killindicator.think = KillIndicator_Think;
 889                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 890                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 891                                 e.killindicator.cnt = ceil(killtime);
 892                         }
 893                         self.lip = 0;
 894                 }
 895         }
 896         if(self.killindicator)
 897         {
 898                 if(targetteam == 0) // just die
 899                 {
 900                         self.killindicator.colormod = '0 0 0';
 901                         if(IS_REAL_CLIENT(self))
 902                         if(self.killindicator.cnt > 0)
 903                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 904                 }
 905                 else if(targetteam == -1) // auto
 906                 {
 907                         self.killindicator.colormod = '0 1 0';
 908                         if(IS_REAL_CLIENT(self))
 909                         if(self.killindicator.cnt > 0)
 910                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 911                 }
 912                 else if(targetteam == -2) // spectate
 913                 {
 914                         self.killindicator.colormod = '0.5 0.5 0.5';
 915                         if(IS_REAL_CLIENT(self))
 916                         if(self.killindicator.cnt > 0)
 917                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 918                 }
 919                 else
 920                 {
 921                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 922                         if(IS_REAL_CLIENT(self))
 923                         if(self.killindicator.cnt > 0)
 924                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 925                 }
 926         }
 927
 928 }
 929
 930 void ClientKill (void)
 931 {SELFPARAM();
 932         if(gameover) return;
 933         if(self.player_blocked) return;
 934         if(self.frozen) return;
 935
 936         ClientKill_TeamChange(0);
 937 }
 938
 939 void FixClientCvars(entity e)
 940 {
 941         // send prediction settings to the client
 942         stuffcmd(e, "\nin_bindmap 0 0\n");
 943         if(autocvar_g_antilag == 3) // client side hitscan
 944                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 945         if(autocvar_sv_gentle)
 946                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 947 }
 948
 949 float PlayerInIDList(entity p, string idlist)
 950 {
 951         float n, i;
 952         string s;
 953
 954         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 955         if (!p.crypto_idfp)
 956                 return 0;
 957
 958         // this function allows abbreviated player IDs too!
 959         n = tokenize_console(idlist);
 960         for(i = 0; i < n; ++i)
 961         {
 962                 s = argv(i);
 963                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 964                         return 1;
 965         }
 966
 967         return 0;
 968 }
 969
 970 #ifdef DP_EXT_PRECONNECT
 971 /*
 972 =============
 973 ClientPreConnect
 974
 975 Called once (not at each match start) when a client begins a connection to the server
 976 =============
 977 */
 978 void ClientPreConnect (void)
 979 {SELFPARAM();
 980         if(autocvar_sv_eventlog)
 981         {
 982                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 983                         self.playerid,
 984                         num_for_edict(self),
 985                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
 986                 ));
 987         }
 988 }
 989 #endif
 990
 991 /*
 992 =============
 993 ClientConnect
 994
 995 Called when a client connects to the server
 996 =============
 997 */
 998 void DecodeLevelParms (void);
 999 void ClientConnect (void)
1000 {SELFPARAM();
1001         float t;
1002
1003         if(IS_CLIENT(self))
1004         {
1005                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1006                 return;
1007         }
1008
1009         if(Ban_MaybeEnforceBanOnce(self))
1010                 return;
1011
1012         DecodeLevelParms();
1013
1014 #ifdef WATERMARK
1015         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1016 #endif
1017
1018         self.classname = "player_joining";
1019
1020         self.flags = FL_CLIENT;
1021         self.version_nagtime = time + 10 + random() * 10;
1022
1023         if(player_count<0)
1024         {
1025                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1026                 player_count = 0;
1027         }
1028
1029         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1030
1031         PlayerScore_Attach(self);
1032         ClientData_Attach();
1033         accuracy_init(self);
1034         Inventory_new(self);
1035
1036         bot_clientconnect();
1037
1038         playerdemo_init();
1039
1040         anticheat_init();
1041
1042         // identify the right forced team
1043         if(autocvar_g_campaign)
1044         {
1045                 if(IS_REAL_CLIENT(self)) // only players, not bots
1046                 {
1047                         switch(autocvar_g_campaign_forceteam)
1048                         {
1049                                 case 1: self.team_forced = NUM_TEAM_1; break;
1050                                 case 2: self.team_forced = NUM_TEAM_2; break;
1051                                 case 3: self.team_forced = NUM_TEAM_3; break;
1052                                 case 4: self.team_forced = NUM_TEAM_4; break;
1053                                 default: self.team_forced = 0;
1054                         }
1055                 }
1056         }
1057         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1058                 self.team_forced = NUM_TEAM_1;
1059         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1060                 self.team_forced = NUM_TEAM_2;
1061         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1062                 self.team_forced = NUM_TEAM_3;
1063         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1064                 self.team_forced = NUM_TEAM_4;
1065         else if(autocvar_g_forced_team_otherwise == "red")
1066                 self.team_forced = NUM_TEAM_1;
1067         else if(autocvar_g_forced_team_otherwise == "blue")
1068                 self.team_forced = NUM_TEAM_2;
1069         else if(autocvar_g_forced_team_otherwise == "yellow")
1070                 self.team_forced = NUM_TEAM_3;
1071         else if(autocvar_g_forced_team_otherwise == "pink")
1072                 self.team_forced = NUM_TEAM_4;
1073         else if(autocvar_g_forced_team_otherwise == "spectate")
1074                 self.team_forced = -1;
1075         else if(autocvar_g_forced_team_otherwise == "spectator")
1076                 self.team_forced = -1;
1077         else
1078                 self.team_forced = 0;
1079
1080         if(!teamplay)
1081                 if(self.team_forced > 0)
1082                         self.team_forced = 0;
1083
1084         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1085
1086         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1087                 self.classname = STR_OBSERVER;
1088         } else {
1089                 if(teamplay)
1090                 {
1091                         if(autocvar_g_balance_teams)
1092                         {
1093                                 self.classname = STR_PLAYER;
1094                                 campaign_bots_may_start = 1;
1095                         }
1096                         else
1097                         {
1098                                 self.classname = STR_OBSERVER; // do it anyway
1099                         }
1100                 }
1101                 else
1102                 {
1103                         self.classname = STR_PLAYER;
1104                         campaign_bots_may_start = 1;
1105                 }
1106         }
1107
1108         self.playerid = (playerid_last = playerid_last + 1);
1109
1110         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1111
1112     if(IS_BOT_CLIENT(self))
1113         PlayerStats_GameReport_AddPlayer(self);
1114
1115         if(autocvar_sv_eventlog)
1116                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1117
1118         LogTeamchange(self.playerid, self.team, 1);
1119
1120         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1121
1122         self.netname_previous = strzone(self.netname);
1123
1124         if(IS_PLAYER(self) && teamplay)
1125                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1126         else
1127                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1128
1129         stuffcmd(self, strcat(clientstuff, "\n"));
1130         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1131
1132         FixClientCvars(self);
1133
1134         // spawnfunc_waypoint sprites
1135         WaypointSprite_InitClient(self);
1136
1137         // Wazat's grappling hook
1138         SetGrappleHookBindings();
1139
1140         // Jetpack binds
1141         stuffcmd(self, "alias +jetpack +button10\n");
1142         stuffcmd(self, "alias -jetpack -button10\n");
1143
1144         // get version info from player
1145         stuffcmd(self, "cmd clientversion $gameversion\n");
1146
1147         // get other cvars from player
1148         GetCvars(0);
1149
1150         // notify about available teams
1151         if(teamplay)
1152         {
1153                 CheckAllowedTeams(self);
1154                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1155                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1156         }
1157         else
1158                 stuffcmd(self, "set _teams_available 0\n");
1159
1160         attach_entcs(self);
1161
1162         bot_relinkplayerlist();
1163
1164         self.spectatortime = time;
1165         if(blockSpectators)
1166         {
1167                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1168         }
1169
1170         self.jointime = time;
1171         self.allowed_timeouts = autocvar_sv_timeout_number;
1172
1173         if(IS_REAL_CLIENT(self))
1174         {
1175                 if(!autocvar_g_campaign)
1176                 {
1177                         self.motd_actived_time = -1;
1178                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1179                 }
1180
1181                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1182                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1183         }
1184
1185         if(!sv_foginterval && world.fog != "")
1186                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1187
1188         W_HitPlotOpen(self);
1189
1190         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1191                 send_CSQC_teamnagger();
1192
1193         CheatInitClient();
1194
1195         CSQCMODEL_AUTOINIT(self);
1196
1197         self.model_randomizer = random();
1198
1199         if(IS_REAL_CLIENT(self))
1200                 sv_notice_join();
1201
1202         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1203                 WITH(entity, self, e, e.init_for_player(this));
1204         }
1205
1206         MUTATOR_CALLHOOK(ClientConnect, self);
1207 }
1208 /*
1209 =============
1210 ClientDisconnect
1211
1212 Called when a client disconnects from the server
1213 =============
1214 */
1215 .entity chatbubbleentity;
1216 void ReadyCount();
1217 void ClientDisconnect (void)
1218 {SELFPARAM();
1219         if(self.vehicle)
1220             vehicles_exit(VHEF_RELEASE);
1221
1222         if (!IS_CLIENT(self))
1223         {
1224                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1225                 return;
1226         }
1227
1228         PlayerStats_GameReport_FinalizePlayer(self);
1229
1230         if ( self.active_minigame )
1231                 part_minigame(self);
1232
1233         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1234
1235         CheatShutdownClient();
1236
1237         W_HitPlotClose(self);
1238
1239         anticheat_report();
1240         anticheat_shutdown();
1241
1242         playerdemo_shutdown();
1243
1244         bot_clientdisconnect();
1245
1246         detach_entcs(self);
1247
1248         if(autocvar_sv_eventlog)
1249                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1250
1251         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1252
1253         MUTATOR_CALLHOOK(ClientDisconnect);
1254
1255         Portal_ClearAll(self);
1256
1257         Unfreeze(self);
1258
1259         RemoveGrapplingHook(self);
1260
1261         // Here, everything has been done that requires this player to be a client.
1262
1263         self.flags &= ~FL_CLIENT;
1264
1265         if (self.chatbubbleentity)
1266                 remove (self.chatbubbleentity);
1267
1268         if (self.killindicator)
1269                 remove (self.killindicator);
1270
1271         WaypointSprite_PlayerGone();
1272
1273         bot_relinkplayerlist();
1274
1275         accuracy_free(self);
1276         Inventory_delete(self);
1277         ClientData_Detach();
1278         PlayerScore_Detach(self);
1279
1280         if(self.netname_previous)
1281                 strunzone(self.netname_previous);
1282         if(self.clientstatus)
1283                 strunzone(self.clientstatus);
1284         if(self.weaponorder_byimpulse)
1285                 strunzone(self.weaponorder_byimpulse);
1286
1287         ClearPlayerSounds();
1288
1289         if(self.personal)
1290                 remove(self.personal);
1291
1292         self.playerid = 0;
1293         ReadyCount();
1294
1295         // free cvars
1296         GetCvars(-1);
1297 }
1298
1299 .float BUTTON_CHAT;
1300 void ChatBubbleThink()
1301 {SELFPARAM();
1302         self.nextthink = time;
1303         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1304         {
1305                 if(self.owner) // but why can that ever be world?
1306                         self.owner.chatbubbleentity = world;
1307                 remove(self);
1308                 return;
1309         }
1310
1311         self.mdl = "";
1312
1313         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1314         {
1315                 if ( self.owner.active_minigame )
1316                         self.mdl = "models/sprites/minigame_busy.iqm";
1317                 else if ( self.owner.BUTTON_CHAT )
1318                         self.mdl = "models/misc/chatbubble.spr";
1319         }
1320
1321         if ( self.model != self.mdl )
1322                 _setmodel(self, self.mdl);
1323
1324 }
1325
1326 void UpdateChatBubble()
1327 {SELFPARAM();
1328         if (self.alpha < 0)
1329                 return;
1330         // spawn a chatbubble entity if needed
1331         if (!self.chatbubbleentity)
1332         {
1333                 self.chatbubbleentity = spawn();
1334                 self.chatbubbleentity.owner = self;
1335                 self.chatbubbleentity.exteriormodeltoclient = self;
1336                 self.chatbubbleentity.think = ChatBubbleThink;
1337                 self.chatbubbleentity.nextthink = time;
1338                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1339                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1340                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1341                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1342                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1343                 //self.chatbubbleentity.model = "";
1344                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1345         }
1346 }
1347
1348
1349 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1350 // added to the model skins
1351 /*void UpdateColorModHack()
1352 {
1353         float c;
1354         c = self.clientcolors & 15;
1355         // LordHavoc: only bothering to support white, green, red, yellow, blue
1356              if (!teamplay) self.colormod = '0 0 0';
1357         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1358         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1359         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1360         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1361         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1362         else self.colormod = '1 1 1';
1363 }*/
1364
1365 void respawn(void)
1366 {SELFPARAM();
1367         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1368         {
1369                 self.solid = SOLID_NOT;
1370                 self.takedamage = DAMAGE_NO;
1371                 self.movetype = MOVETYPE_FLY;
1372                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1373                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1374                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1375                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1376                 if(autocvar_g_respawn_ghosts_maxtime)
1377                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1378         }
1379
1380         CopyBody(1);
1381
1382         self.effects |= EF_NODRAW; // prevent another CopyBody
1383         PutClientInServer();
1384 }
1385
1386 void play_countdown(float finished, string samp)
1387 {SELFPARAM();
1388         if(IS_REAL_CLIENT(self))
1389                 if(floor(finished - time - frametime) != floor(finished - time))
1390                         if(finished - time < 6)
1391                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1392 }
1393
1394 void player_powerups (void)
1395 {SELFPARAM();
1396         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1397         int items_prev = self.items;
1398
1399         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1400                 self.modelflags |= MF_ROCKET;
1401         else
1402                 self.modelflags &= ~MF_ROCKET;
1403
1404         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1405
1406         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1407                 return;
1408
1409         Fire_ApplyDamage(self);
1410         Fire_ApplyEffect(self);
1411
1412         if (!g_instagib)
1413         {
1414                 if (self.items & ITEM_Strength.m_itemid)
1415                 {
1416                         play_countdown(self.strength_finished, SND(POWEROFF));
1417                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1418                         if (time > self.strength_finished)
1419                         {
1420                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1421                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1422                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1423                         }
1424                 }
1425                 else
1426                 {
1427                         if (time < self.strength_finished)
1428                         {
1429                                 self.items = self.items | ITEM_Strength.m_itemid;
1430                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1431                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1432                         }
1433                 }
1434                 if (self.items & ITEM_Shield.m_itemid)
1435                 {
1436                         play_countdown(self.invincible_finished, SND(POWEROFF));
1437                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1438                         if (time > self.invincible_finished)
1439                         {
1440                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1441                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1442                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1443                         }
1444                 }
1445                 else
1446                 {
1447                         if (time < self.invincible_finished)
1448                         {
1449                                 self.items = self.items | ITEM_Shield.m_itemid;
1450                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1452                         }
1453                 }
1454                 if (self.items & IT_SUPERWEAPON)
1455                 {
1456                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1457                         {
1458                                 self.superweapons_finished = 0;
1459                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1460                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1461                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1462                         }
1463                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1464                         {
1465                                 // don't let them run out
1466                         }
1467                         else
1468                         {
1469                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1470                                 if (time > self.superweapons_finished)
1471                                 {
1472                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1473                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1474                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1475                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1476                                 }
1477                         }
1478                 }
1479                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1480                 {
1481                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1482                         {
1483                                 self.items = self.items | IT_SUPERWEAPON;
1484                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1485                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1486                         }
1487                         else
1488                         {
1489                                 self.superweapons_finished = 0;
1490                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1491                         }
1492                 }
1493                 else
1494                 {
1495                         self.superweapons_finished = 0;
1496                 }
1497         }
1498
1499         if(autocvar_g_nodepthtestplayers)
1500                 self.effects = self.effects | EF_NODEPTHTEST;
1501
1502         if(autocvar_g_fullbrightplayers)
1503                 self.effects = self.effects | EF_FULLBRIGHT;
1504
1505         if (time >= game_starttime)
1506         if (time < self.spawnshieldtime)
1507                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1508
1509         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1510 }
1511
1512 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1513 {
1514         if(current > stable)
1515                 return current;
1516         else if(current > stable - 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1520 }
1521
1522 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1523 {
1524         if(current < stable)
1525                 return current;
1526         else if(current < stable + 0.25) // when close enough, "snap"
1527                 return stable;
1528         else
1529                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1530 }
1531
1532 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1533 {
1534         if(current > rotstable)
1535         {
1536                 if(rotframetime > 0)
1537                 {
1538                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1539                         current = max(rotstable, current - rotlinear * rotframetime);
1540                 }
1541         }
1542         else if(current < regenstable)
1543         {
1544                 if(regenframetime > 0)
1545                 {
1546                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1547                         current = min(regenstable, current + regenlinear * regenframetime);
1548                 }
1549         }
1550
1551         if(current > limit)
1552                 current = limit;
1553
1554         return current;
1555 }
1556
1557 void player_regen (void)
1558 {SELFPARAM();
1559         float max_mod, regen_mod, rot_mod, limit_mod;
1560         max_mod = regen_mod = rot_mod = limit_mod = 1;
1561         regen_mod_max = max_mod;
1562         regen_mod_regen = regen_mod;
1563         regen_mod_rot = rot_mod;
1564         regen_mod_limit = limit_mod;
1565
1566         regen_health = autocvar_g_balance_health_regen;
1567         regen_health_linear = autocvar_g_balance_health_regenlinear;
1568         regen_health_rot = autocvar_g_balance_health_rot;
1569         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1570         regen_health_stable = autocvar_g_balance_health_regenstable;
1571         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1572         if(!MUTATOR_CALLHOOK(PlayerRegen))
1573         if(!self.frozen)
1574         {
1575                 float mina, maxa, limith, limita;
1576                 maxa = autocvar_g_balance_armor_rotstable;
1577                 mina = autocvar_g_balance_armor_regenstable;
1578                 limith = autocvar_g_balance_health_limit;
1579                 limita = autocvar_g_balance_armor_limit;
1580
1581                 max_mod = regen_mod_max;
1582                 regen_mod = regen_mod_regen;
1583                 rot_mod = regen_mod_rot;
1584                 limit_mod = regen_mod_limit;
1585
1586                 regen_health_rotstable = regen_health_rotstable * max_mod;
1587                 regen_health_stable = regen_health_stable * max_mod;
1588                 limith = limith * limit_mod;
1589                 limita = limita * limit_mod;
1590
1591                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1592                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1593         }
1594
1595         // if player rotted to death...  die!
1596         // check this outside above checks, as player may still be able to rot to death
1597         if(self.health < 1)
1598         {
1599                 if(self.vehicle)
1600                         vehicles_exit(VHEF_RELEASE);
1601                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1602         }
1603
1604         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1605         {
1606                 float minf, maxf, limitf;
1607
1608                 maxf = autocvar_g_balance_fuel_rotstable;
1609                 minf = autocvar_g_balance_fuel_regenstable;
1610                 limitf = autocvar_g_balance_fuel_limit;
1611
1612                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1613         }
1614 }
1615
1616 float zoomstate_set;
1617 void SetZoomState(float z)
1618 {SELFPARAM();
1619         if(z != self.zoomstate)
1620         {
1621                 self.zoomstate = z;
1622                 ClientData_Touch(self);
1623         }
1624         zoomstate_set = 1;
1625 }
1626
1627 void GetPressedKeys()
1628 {SELFPARAM();
1629         MUTATOR_CALLHOOK(GetPressedKeys);
1630         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1631         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1632         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1633         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1634         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1635
1636         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1637         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1638         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1639         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1640         #undef X
1641 }
1642
1643 /*
1644 ======================
1645 spectate mode routines
1646 ======================
1647 */
1648
1649 void SpectateCopy(entity spectatee)
1650 {SELFPARAM();
1651         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1652         self.armortype = spectatee.armortype;
1653         self.armorvalue = spectatee.armorvalue;
1654         self.ammo_cells = spectatee.ammo_cells;
1655         self.ammo_plasma = spectatee.ammo_plasma;
1656         self.ammo_shells = spectatee.ammo_shells;
1657         self.ammo_nails = spectatee.ammo_nails;
1658         self.ammo_rockets = spectatee.ammo_rockets;
1659         self.ammo_fuel = spectatee.ammo_fuel;
1660         self.clip_load = spectatee.clip_load;
1661         self.clip_size = spectatee.clip_size;
1662         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1663         self.health = spectatee.health;
1664         self.impulse = 0;
1665         self.items = spectatee.items;
1666         self.last_pickup = spectatee.last_pickup;
1667         self.hit_time = spectatee.hit_time;
1668         self.strength_finished = spectatee.strength_finished;
1669         self.invincible_finished = spectatee.invincible_finished;
1670         self.pressedkeys = spectatee.pressedkeys;
1671         self.weapons = spectatee.weapons;
1672         self.switchweapon = spectatee.switchweapon;
1673         self.switchingweapon = spectatee.switchingweapon;
1674         self.weapon = spectatee.weapon;
1675         self.vortex_charge = spectatee.vortex_charge;
1676         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1677         self.hagar_load = spectatee.hagar_load;
1678         self.arc_heat_percent = spectatee.arc_heat_percent;
1679         self.minelayer_mines = spectatee.minelayer_mines;
1680         self.punchangle = spectatee.punchangle;
1681         self.view_ofs = spectatee.view_ofs;
1682         self.velocity = spectatee.velocity;
1683         self.dmg_take = spectatee.dmg_take;
1684         self.dmg_save = spectatee.dmg_save;
1685         self.dmg_inflictor = spectatee.dmg_inflictor;
1686         self.v_angle = spectatee.v_angle;
1687         self.angles = spectatee.v_angle;
1688         self.frozen = spectatee.frozen;
1689         self.revive_progress = spectatee.revive_progress;
1690         if(!self.BUTTON_USE)
1691                 self.fixangle = true;
1692         setorigin(self, spectatee.origin);
1693         setsize(self, spectatee.mins, spectatee.maxs);
1694         SetZoomState(spectatee.zoomstate);
1695
1696     anticheat_spectatecopy(spectatee);
1697         self.hud = spectatee.hud;
1698         if(spectatee.vehicle)
1699     {
1700         self.fixangle = false;
1701         //self.velocity = spectatee.vehicle.velocity;
1702         self.vehicle_health = spectatee.vehicle_health;
1703         self.vehicle_shield = spectatee.vehicle_shield;
1704         self.vehicle_energy = spectatee.vehicle_energy;
1705         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1706         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1707         self.vehicle_reload1 = spectatee.vehicle_reload1;
1708         self.vehicle_reload2 = spectatee.vehicle_reload2;
1709
1710         msg_entity = self;
1711
1712         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1713             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1714             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1715             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1716
1717         //WriteByte (MSG_ONE, SVC_SETVIEW);
1718         //    WriteEntity(MSG_ONE, self);
1719         //makevectors(spectatee.v_angle);
1720         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1721     }
1722 }
1723
1724 bool SpectateUpdate()
1725 {SELFPARAM();
1726         if(!self.enemy)
1727             return false;
1728
1729         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1730         {
1731                 SetSpectatee(self, NULL);
1732                 return false;
1733         }
1734
1735         SpectateCopy(self.enemy);
1736
1737         return true;
1738 }
1739
1740 bool SpectateSet()
1741 {SELFPARAM();
1742         if(!IS_PLAYER(self.enemy))
1743                 return false;
1744
1745         msg_entity = self;
1746         WriteByte(MSG_ONE, SVC_SETVIEW);
1747         WriteEntity(MSG_ONE, self.enemy);
1748         self.movetype = MOVETYPE_NONE;
1749         accuracy_resend(self);
1750
1751         if(!SpectateUpdate())
1752                 PutObserverInServer();
1753
1754         return true;
1755 }
1756
1757 void SetSpectatee(entity player, entity spectatee)
1758 {
1759         entity old_spectatee = player.enemy;
1760
1761         player.enemy = spectatee;
1762
1763         // WEAPONTODO
1764         // these are required to fix the spectator bug with arc
1765         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1766         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1767 }
1768
1769 bool Spectate(entity pl)
1770 {SELFPARAM();
1771         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1772                 return false;
1773         pl = spec_player;
1774
1775         SetSpectatee(self, pl);
1776         return SpectateSet();
1777 }
1778
1779 bool SpectateNext()
1780 {SELFPARAM();
1781         other = find(self.enemy, classname, "player");
1782
1783         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1784                 other = spec_player;
1785         else if (!other)
1786                 other = find(other, classname, "player");
1787
1788         if(other) { SetSpectatee(self, other); }
1789
1790         return SpectateSet();
1791 }
1792
1793 bool SpectatePrev()
1794 {SELFPARAM();
1795         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1796         other = findchain(classname, "player");
1797         if (!other) // no player
1798                 return false;
1799
1800         entity first = other;
1801         // skip players until current spectated player
1802         if(self.enemy)
1803         while(other && other != self.enemy)
1804                 other = other.chain;
1805
1806         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1807         {
1808                 case MUT_SPECPREV_FOUND:
1809                     other = spec_player;
1810                     break;
1811                 case MUT_SPECPREV_RETURN:
1812                     other = spec_player;
1813                     return true;
1814                 case MUT_SPECPREV_CONTINUE:
1815                 default:
1816                 {
1817                         if(other.chain)
1818                                 other = other.chain;
1819                         else
1820                                 other = first;
1821                         break;
1822                 }
1823         }
1824
1825         SetSpectatee(self, other);
1826         return SpectateSet();
1827 }
1828
1829 /*
1830 =============
1831 ShowRespawnCountdown()
1832
1833 Update a respawn countdown display.
1834 =============
1835 */
1836 void ShowRespawnCountdown()
1837 {SELFPARAM();
1838         float number;
1839         if(self.deadflag == DEAD_NO) // just respawned?
1840                 return;
1841         else
1842         {
1843                 number = ceil(self.respawn_time - time);
1844                 if(number <= 0)
1845                         return;
1846                 if(number <= self.respawn_countdown)
1847                 {
1848                         self.respawn_countdown = number - 1;
1849                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1850                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1851                 }
1852         }
1853 }
1854
1855 void LeaveSpectatorMode()
1856 {SELFPARAM();
1857         if(self.caplayer)
1858                 return;
1859         if(nJoinAllowed(self))
1860         {
1861                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1862                 {
1863                         self.classname = STR_PLAYER;
1864                         nades_RemoveBonus(self);
1865
1866                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1867                                 { JoinBestTeam(self, false, true); }
1868
1869                         if(autocvar_g_campaign)
1870                                 { campaign_bots_may_start = 1; }
1871
1872                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1873
1874                         PutClientInServer();
1875
1876                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1877                 }
1878                 else
1879                         stuffcmd(self, "menu_showteamselect\n");
1880         }
1881         else
1882         {
1883                 // Player may not join because g_maxplayers is set
1884                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1885         }
1886 }
1887
1888 /**
1889  * Determines whether the player is allowed to join. This depends on cvar
1890  * g_maxplayers, if it isn't used this function always return true, otherwise
1891  * it checks whether the number of currently playing players exceeds g_maxplayers.
1892  * @return int number of free slots for players, 0 if none
1893  */
1894 float nJoinAllowed(entity ignore)
1895 {SELFPARAM();
1896         if(!ignore)
1897         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1898         // so report 0 free slots if restricted
1899         {
1900                 if(autocvar_g_forced_team_otherwise == "spectate")
1901                         return 0;
1902                 if(autocvar_g_forced_team_otherwise == "spectator")
1903                         return 0;
1904         }
1905
1906         if(self.team_forced < 0)
1907                 return 0; // forced spectators can never join
1908
1909         // TODO simplify this
1910         entity e;
1911         float totalClients = 0;
1912         FOR_EACH_CLIENT(e)
1913                 if(e != ignore)
1914                         totalClients += 1;
1915
1916         if (!autocvar_g_maxplayers)
1917                 return maxclients - totalClients;
1918
1919         float currentlyPlaying = 0;
1920         FOR_EACH_REALCLIENT(e)
1921                 if(IS_PLAYER(e) || e.caplayer)
1922                         currentlyPlaying += 1;
1923
1924         if(currentlyPlaying < autocvar_g_maxplayers)
1925                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1926
1927         return 0;
1928 }
1929
1930 /**
1931  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1932  * g_maxplayers_spectator_blocktime seconds
1933  */
1934 void checkSpectatorBlock()
1935 {SELFPARAM();
1936         if(IS_SPEC(self) || IS_OBSERVER(self))
1937         if(!self.caplayer)
1938         if(IS_REAL_CLIENT(self))
1939         {
1940                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1941                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1942                         dropclient(self);
1943                 }
1944         }
1945 }
1946
1947 void PrintWelcomeMessage()
1948 {SELFPARAM();
1949         if(self.motd_actived_time == 0)
1950         {
1951                 if (autocvar_g_campaign) {
1952                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1953                                 self.motd_actived_time = time;
1954                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1955                         }
1956                 } else {
1957                         if (self.BUTTON_INFO) {
1958                                 self.motd_actived_time = time;
1959                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1960                         }
1961                 }
1962         }
1963         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1964         {
1965                 if (autocvar_g_campaign) {
1966                         if (self.BUTTON_INFO)
1967                                 self.motd_actived_time = time;
1968                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1969                                 self.motd_actived_time = 0;
1970                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1971                         }
1972                 } else {
1973                         if (self.BUTTON_INFO)
1974                                 self.motd_actived_time = time;
1975                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1976                                 self.motd_actived_time = 0;
1977                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1978                         }
1979                 }
1980         }
1981         else //if(self.motd_actived_time < 0) // just connected, motd is active
1982         {
1983                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
1984                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1985                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || IS_SPEC(self))
1986                 {
1987                         // instanctly hide MOTD
1988                         self.motd_actived_time = 0;
1989                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1990                 }
1991         }
1992 }
1993
1994 void ObserverThink()
1995 {SELFPARAM();
1996         if ( self.impulse )
1997         {
1998                 MinigameImpulse(self.impulse);
1999                 self.impulse = 0;
2000         }
2001         float prefered_movetype;
2002         if (self.flags & FL_JUMPRELEASED) {
2003                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2004                         self.flags &= ~FL_JUMPRELEASED;
2005                         self.flags |= FL_SPAWNING;
2006                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2007                         self.flags &= ~FL_JUMPRELEASED;
2008                         if(SpectateNext()) {
2009                                 self.classname = STR_SPECTATOR;
2010                         }
2011                 } else {
2012                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2013                         if (self.movetype != prefered_movetype)
2014                                 self.movetype = prefered_movetype;
2015                 }
2016         } else {
2017                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2018                         self.flags |= FL_JUMPRELEASED;
2019                         if(self.flags & FL_SPAWNING)
2020                         {
2021                                 self.flags &= ~FL_SPAWNING;
2022                                 LeaveSpectatorMode();
2023                                 return;
2024                         }
2025                 }
2026         }
2027 }
2028
2029 void SpectatorThink()
2030 {SELFPARAM();
2031         if ( self.impulse )
2032         {
2033                 if(MinigameImpulse(self.impulse))
2034                         self.impulse = 0;
2035         }
2036         if (self.flags & FL_JUMPRELEASED) {
2037                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2038                         self.flags &= ~FL_JUMPRELEASED;
2039                         self.flags |= FL_SPAWNING;
2040                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2041                         self.flags &= ~FL_JUMPRELEASED;
2042                         if(SpectateNext()) {
2043                                 self.classname = STR_SPECTATOR;
2044                         } else {
2045                                 self.classname = STR_OBSERVER;
2046                                 PutClientInServer();
2047                         }
2048                         self.impulse = 0;
2049                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2050                         self.flags &= ~FL_JUMPRELEASED;
2051                         if(SpectatePrev()) {
2052                                 self.classname = STR_SPECTATOR;
2053                         } else {
2054                                 self.classname = STR_OBSERVER;
2055                                 PutClientInServer();
2056                         }
2057                         self.impulse = 0;
2058                 } else if (self.BUTTON_ATCK2) {
2059                         self.flags &= ~FL_JUMPRELEASED;
2060                         self.classname = STR_OBSERVER;
2061                         PutClientInServer();
2062                 } else {
2063                         if(!SpectateUpdate())
2064                                 PutObserverInServer();
2065                 }
2066         } else {
2067                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2068                         self.flags |= FL_JUMPRELEASED;
2069                         if(self.flags & FL_SPAWNING)
2070                         {
2071                                 self.flags &= ~FL_SPAWNING;
2072                                 LeaveSpectatorMode();
2073                                 return;
2074                         }
2075                 }
2076                 if(!SpectateUpdate())
2077                         PutObserverInServer();
2078         }
2079
2080         self.flags |= FL_CLIENT | FL_NOTARGET;
2081 }
2082
2083 void vehicles_enter (entity pl, entity veh);
2084 void PlayerUseKey()
2085 {SELFPARAM();
2086         if (!IS_PLAYER(self))
2087                 return;
2088
2089         if(self.vehicle)
2090         {
2091                 if(!gameover)
2092                 {
2093                         vehicles_exit(VHEF_NORMAL);
2094                         return;
2095                 }
2096         }
2097         else if(autocvar_g_vehicles_enter)
2098         {
2099                 if(!self.frozen)
2100                 if(self.deadflag == DEAD_NO)
2101                 if(!gameover)
2102                 {
2103                         entity head, closest_target = world;
2104                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2105
2106                         while(head) // find the closest acceptable target to enter
2107                         {
2108                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2109                                 if(head.deadflag == DEAD_NO)
2110                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2111                                 if(head.takedamage != DAMAGE_NO)
2112                                 {
2113                                         if(closest_target)
2114                                         {
2115                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2116                                                 { closest_target = head; }
2117                                         }
2118                                         else { closest_target = head; }
2119                                 }
2120
2121                                 head = head.chain;
2122                         }
2123
2124                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2125                 }
2126         }
2127
2128         // a use key was pressed; call handlers
2129         MUTATOR_CALLHOOK(PlayerUseKey);
2130 }
2131
2132 float isInvisibleString(string s)
2133 {
2134         float i, n, c;
2135         s = strdecolorize(s);
2136         for((i = 0), (n = strlen(s)); i < n; ++i)
2137         {
2138                 c = str2chr(s, i);
2139                 switch(c)
2140                 {
2141                         case 0:
2142                         case 32: // space
2143                                 break;
2144                         case 192: // charmap space
2145                                 if (!autocvar_utf8_enable)
2146                                         break;
2147                                 return false;
2148                         case 160: // space in unicode fonts
2149                         case 0xE000 + 192: // utf8 charmap space
2150                                 if (autocvar_utf8_enable)
2151                                         break;
2152                         default:
2153                                 return false;
2154                 }
2155         }
2156         return true;
2157 }
2158
2159 /*
2160 =============
2161 PlayerPreThink
2162
2163 Called every frame for each client before the physics are run
2164 =============
2165 */
2166 .float usekeypressed;
2167 void() nexball_setstatus;
2168 .float last_vehiclecheck;
2169 .int items_added;
2170 void PlayerPreThink (void)
2171 {SELFPARAM();
2172         WarpZone_PlayerPhysics_FixVAngle();
2173
2174         self.stat_game_starttime = game_starttime;
2175         self.stat_round_starttime = round_starttime;
2176         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2177         self.stat_leadlimit = autocvar_leadlimit;
2178
2179         self.weaponsinmap = weaponsInMap;
2180
2181         if(frametime)
2182         {
2183                 // physics frames: update anticheat stuff
2184                 anticheat_prethink();
2185         }
2186
2187         if(blockSpectators && frametime)
2188                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2189                 checkSpectatorBlock();
2190
2191         zoomstate_set = 0;
2192
2193         // Savage: Check for nameless players
2194         if (isInvisibleString(self.netname)) {
2195                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2196                 if(autocvar_sv_eventlog)
2197                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2198                 if(self.netname_previous)
2199                         strunzone(self.netname_previous);
2200                 self.netname_previous = strzone(new_name);
2201                 self.netname = self.netname_previous;
2202                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2203         } else if(self.netname_previous != self.netname) {
2204                 if(autocvar_sv_eventlog)
2205                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2206                 if(self.netname_previous)
2207                         strunzone(self.netname_previous);
2208                 self.netname_previous = strzone(self.netname);
2209         }
2210
2211         // version nagging
2212         if(self.version_nagtime)
2213                 if(self.cvar_g_xonoticversion)
2214                         if(time > self.version_nagtime)
2215                         {
2216                                 // don't notify git users
2217                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2218                                 {
2219                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2220                                         {
2221                                                 // notify release users if connecting to git
2222                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2223                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2224                                         }
2225                                         else
2226                                         {
2227                                                 float r;
2228                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2229                                                 if(r < 0)
2230                                                 {
2231                                                         // give users new version
2232                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2233                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2234                                                 }
2235                                                 else if(r > 0)
2236                                                 {
2237                                                         // notify users about old server version
2238                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2239                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2240                                                 }
2241                                         }
2242                                 }
2243                                 self.version_nagtime = 0;
2244                         }
2245
2246         // GOD MODE info
2247         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2248         {
2249                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2250                 self.max_armorvalue = 0;
2251         }
2252
2253         if(self.frozen == 2)
2254         {
2255                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2256                 self.health = max(1, self.revive_progress * start_health);
2257                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2258
2259                 if(self.revive_progress >= 1)
2260                         Unfreeze(self);
2261         }
2262         else if(self.frozen == 3)
2263         {
2264                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2265                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2266
2267                 if(self.health < 1)
2268                 {
2269                         if(self.vehicle)
2270                                 vehicles_exit(VHEF_RELEASE);
2271                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2272                 }
2273                 else if ( self.revive_progress <= 0 )
2274                         Unfreeze(self);
2275         }
2276
2277         MUTATOR_CALLHOOK(PlayerPreThink);
2278
2279         if(autocvar_g_vehicles_enter)
2280         if(time > self.last_vehiclecheck)
2281         if(IS_PLAYER(self))
2282         if(!gameover)
2283         if(!self.frozen)
2284         if(!self.vehicle)
2285         if(self.deadflag == DEAD_NO)
2286         {
2287                 entity veh;
2288                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2289                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2290                 if(veh.deadflag == DEAD_NO)
2291                 if(veh.takedamage != DAMAGE_NO)
2292                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2293                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2294                 else if(!veh.owner)
2295                 if(!veh.team || SAME_TEAM(self, veh))
2296                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2297                 else if(autocvar_g_vehicles_steal)
2298                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2299
2300                 self.last_vehiclecheck = time + 1;
2301         }
2302
2303         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2304         {
2305                 if(self.BUTTON_USE && !self.usekeypressed)
2306                         PlayerUseKey();
2307                 self.usekeypressed = self.BUTTON_USE;
2308         }
2309
2310         if(IS_REAL_CLIENT(self))
2311                 PrintWelcomeMessage();
2312
2313         if(IS_PLAYER(self))
2314         {
2315
2316                 CheckRules_Player();
2317
2318                 if (intermission_running)
2319                 {
2320                         IntermissionThink ();   // otherwise a button could be missed between
2321                         return;                                 // the think tics
2322                 }
2323
2324                 //don't allow the player to turn around while game is paused!
2325                 if(timeout_status == TIMEOUT_ACTIVE) {
2326                         // FIXME turn this into CSQC stuff
2327                         self.v_angle = self.lastV_angle;
2328                         self.angles = self.lastV_angle;
2329                         self.fixangle = true;
2330                 }
2331
2332                 if(frametime)
2333                 {
2334                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2335                         {
2336                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2337                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2338                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2339
2340                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2341                                 {
2342                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2343                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2344                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2345                                 }
2346                         }
2347                         else
2348                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2349
2350                         player_powerups();
2351                 }
2352
2353                 if (self.deadflag != DEAD_NO)
2354                 {
2355                         if(self.personal && g_race_qualifying)
2356                         {
2357                                 if(time > self.respawn_time)
2358                                 {
2359                                         self.respawn_time = time + 1; // only retry once a second
2360                                         self.stat_respawn_time = self.respawn_time;
2361                                         respawn();
2362                                         self.impulse = 141;
2363                                 }
2364                         }
2365                         else
2366                         {
2367                                 float button_pressed;
2368                                 if(frametime)
2369                                         player_anim();
2370                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2371
2372                                 if (self.deadflag == DEAD_DYING)
2373                                 {
2374                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2375                                                 self.deadflag = DEAD_RESPAWNING;
2376                                         else if(!button_pressed)
2377                                                 self.deadflag = DEAD_DEAD;
2378                                 }
2379                                 else if (self.deadflag == DEAD_DEAD)
2380                                 {
2381                                         if(button_pressed)
2382                                                 self.deadflag = DEAD_RESPAWNABLE;
2383                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2384                                                 self.deadflag = DEAD_RESPAWNING;
2385                                 }
2386                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2387                                 {
2388                                         if(!button_pressed)
2389                                                 self.deadflag = DEAD_RESPAWNING;
2390                                 }
2391                                 else if (self.deadflag == DEAD_RESPAWNING)
2392                                 {
2393                                         if(time > self.respawn_time)
2394                                         {
2395                                                 self.respawn_time = time + 1; // only retry once a second
2396                                                 self.respawn_time_max = self.respawn_time;
2397                                                 respawn();
2398                                         }
2399                                 }
2400
2401                                 ShowRespawnCountdown();
2402
2403                                 if(self.respawn_flags & RESPAWN_SILENT)
2404                                         self.stat_respawn_time = 0;
2405                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2406                                         self.stat_respawn_time = self.respawn_time_max;
2407                                 else
2408                                         self.stat_respawn_time = self.respawn_time;
2409                         }
2410
2411                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2412                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2413                                 self.stat_respawn_time *= -1;
2414
2415                         return;
2416                 }
2417
2418                 self.prevorigin = self.origin;
2419
2420                 float do_crouch = self.BUTTON_CROUCH;
2421                 if(self.hook.state)
2422                         do_crouch = 0;
2423                 if(self.vehicle)
2424                         do_crouch = 0;
2425                 if(self.frozen)
2426                         do_crouch = 0;
2427
2428                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2429                 // It cannot be predicted by the engine!
2430                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2431                         do_crouch = 0;
2432
2433                 if (do_crouch)
2434                 {
2435                         if (!self.crouch)
2436                         {
2437                                 self.crouch = true;
2438                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2439                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2440                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2441                         }
2442                 }
2443                 else
2444                 {
2445                         if (self.crouch)
2446                         {
2447                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2448                                 if (!trace_startsolid)
2449                                 {
2450                                         self.crouch = false;
2451                                         self.view_ofs = self.stat_pl_view_ofs;
2452                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2453                                 }
2454                         }
2455                 }
2456
2457                 FixPlayermodel(self);
2458
2459                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2460                 //if(frametime)
2461                 {
2462                         self.items &= ~self.items_added;
2463
2464                         W_WeaponFrame(self);
2465
2466                         self.items_added = 0;
2467                         if(self.items & ITEM_Jetpack.m_itemid)
2468                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2469                                         self.items_added |= IT_FUEL;
2470
2471                         self.items |= self.items_added;
2472                 }
2473
2474                 player_regen();
2475
2476                 // WEAPONTODO: Add a weapon request for this
2477                 // rot vortex charge to the charge limit
2478                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2479                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2480
2481                 if(frametime)
2482                         player_anim();
2483
2484                 // secret status
2485                 secrets_setstatus();
2486
2487                 // monsters status
2488                 monsters_setstatus();
2489
2490                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2491
2492                 //self.angles_y=self.v_angle_y + 90;   // temp
2493         } else if(gameover) {
2494                 if (intermission_running)
2495                         IntermissionThink ();   // otherwise a button could be missed between
2496                 return;
2497         } else if(IS_OBSERVER(self)) {
2498                 ObserverThink();
2499         } else if(IS_SPEC(self)) {
2500                 SpectatorThink();
2501         }
2502
2503         // WEAPONTODO: Add weapon request for this
2504         if(!zoomstate_set)
2505                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2506
2507         float oldspectatee_status;
2508         oldspectatee_status = self.spectatee_status;
2509         if(IS_SPEC(self))
2510                 self.spectatee_status = num_for_edict(self.enemy);
2511         else if(IS_OBSERVER(self))
2512                 self.spectatee_status = num_for_edict(self);
2513         else
2514                 self.spectatee_status = 0;
2515         if(self.spectatee_status != oldspectatee_status)
2516         {
2517                 ClientData_Touch(self);
2518         }
2519
2520         if(self.teamkill_soundtime)
2521         if(time > self.teamkill_soundtime)
2522         {
2523                 self.teamkill_soundtime = 0;
2524
2525                 setself(self.teamkill_soundsource);
2526                 entity oldpusher = self.pusher;
2527                 self.pusher = this;
2528
2529                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2530
2531                 self.pusher = oldpusher;
2532                 setself(this);
2533         }
2534
2535         if(self.taunt_soundtime)
2536         if(time > self.taunt_soundtime)
2537         {
2538                 self.taunt_soundtime = 0;
2539                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2540         }
2541
2542         target_voicescript_next(self);
2543
2544         // WEAPONTODO: Move into weaponsystem somehow
2545         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2546         if(!self.weapon)
2547                 self.clip_load = self.clip_size = 0;
2548 }
2549
2550 /*
2551 =============
2552 PlayerPostThink
2553
2554 Called every frame for each client after the physics are run
2555 =============
2556 */
2557 .float idlekick_lasttimeleft;
2558 void PlayerPostThink (void)
2559 {SELFPARAM();
2560         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2561         if(IS_REAL_CLIENT(self))
2562         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2563         {
2564                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2565                 {
2566                         if(self.idlekick_lasttimeleft)
2567                         {
2568                                 self.idlekick_lasttimeleft = 0;
2569                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2570                         }
2571                 }
2572                 else
2573                 {
2574                         float timeleft;
2575                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2576                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2577                         {
2578                                 if(!self.idlekick_lasttimeleft)
2579                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2580                         }
2581                         if(timeleft <= 0)
2582                         {
2583                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2584                                 dropclient(self);
2585                                 return;
2586                         }
2587                         else if(timeleft <= 10)
2588                         {
2589                                 if(timeleft != self.idlekick_lasttimeleft)
2590                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2591                                 self.idlekick_lasttimeleft = timeleft;
2592                         }
2593                 }
2594         }
2595
2596         CheatFrame();
2597
2598         //CheckPlayerJump();
2599
2600         if(IS_PLAYER(self)) {
2601                 CheckRules_Player();
2602                 UpdateChatBubble();
2603                 if (self.impulse)
2604                         ImpulseCommands();
2605                 if (intermission_running)
2606                         return;         // intermission or finale
2607                 GetPressedKeys();
2608         }
2609
2610         /*
2611         float i;
2612         for(i = 0; i < 1000; ++i)
2613         {
2614                 vector end;
2615                 end = self.origin + '0 0 1024' + 512 * randomvec();
2616                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2617                 if(trace_fraction < 1)
2618                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2619                 {
2620                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2621                         break;
2622                 }
2623         }
2624         */
2625
2626         if(self.waypointsprite_attachedforcarrier)
2627                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2628
2629         playerdemo_write();
2630
2631         CSQCMODEL_AUTOUPDATE(self);
2632 }