qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/all.qc"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     ClientConnect(this);
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     PutClientInServer(this);
  63 }
  64
  65 void PutObserverInServer(entity this);
  66
  67 STATIC_METHOD(Client, Remove, void(Client this))
  68 {
  69     TRANSMUTE(Observer, this);
  70     PutClientInServer(this);
  71     ClientDisconnect(this);
  72 }
  73
  74 void send_CSQC_teamnagger() {
  75         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  76 }
  77
  78 int CountSpectators(entity player, entity to)
  79 {
  80         if(!player) { return 0; } // not sure how, but best to be safe
  81
  82         int spec_count = 0;
  83
  84         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  85         {
  86                 spec_count++;
  87         });
  88
  89         return spec_count;
  90 }
  91
  92 void WriteSpectators(entity player, entity to)
  93 {
  94         if(!player) { return; } // not sure how, but best to be safe
  95
  96         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  97         {
  98                 WriteByte(MSG_ENTITY, num_for_edict(it));
  99         });
 100 }
 101
 102 bool ClientData_Send(entity this, entity to, int sf)
 103 {
 104         assert(to == this.owner, return false);
 105
 106         entity e = to;
 107         if (IS_SPEC(e)) e = e.enemy;
 108
 109         sf = 0;
 110         if (e.race_completed)       sf |= 1; // forced scoreboard
 111         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 112         if (e.zoomstate)            sf |= 4; // zoomed
 113         if (e.porto_v_angle_held)   sf |= 8; // angles held
 114         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 115
 116         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 117         WriteByte(MSG_ENTITY, sf);
 118
 119         if (sf & 2)
 120         {
 121                 WriteByte(MSG_ENTITY, to.spectatee_status);
 122         }
 123         if (sf & 8)
 124         {
 125                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 126                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 127         }
 128
 129         if(sf & 16)
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         this.clientdata.drawonlytoclient = this;
 143         this.clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(this.clientdata);
 149         this.clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         e.clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 158 }
 159
 160 .string netname_previous;
 161
 162 void SetSpectatee(entity player, entity spectatee);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this) && this.health >= 1) {
 225         // despawn effect
 226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 227     }
 228
 229     {
 230         entity spot = SelectSpawnPoint(this, true);
 231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 232         this.angles = spot.angles;
 233         this.angles_z = 0;
 234         this.fixangle = true;
 235         // offset it so that the spectator spawns higher off the ground, looks better this way
 236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 237         this.prevorigin = this.origin;
 238         if (IS_REAL_CLIENT(this))
 239         {
 240             msg_entity = this;
 241             WriteByte(MSG_ONE, SVC_SETVIEW);
 242             WriteEntity(MSG_ONE, this);
 243         }
 244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 246         if(!autocvar_g_debug_globalsounds)
 247         {
 248                 // needed for player sounds
 249                 this.model = "";
 250                 FixPlayermodel(this);
 251         }
 252         setmodel(this, MDL_Null);
 253         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 254         this.view_ofs = '0 0 0';
 255     }
 256
 257     RemoveGrapplingHook(this);
 258         Portal_ClearAll(this);
 259         Unfreeze(this);
 260         SetSpectatee(this, NULL);
 261
 262         if (this.alivetime)
 263         {
 264                 if (!warmup_stage)
 265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 266                 this.alivetime = 0;
 267         }
 268
 269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 270
 271         WaypointSprite_PlayerDead(this);
 272
 273         if (mutator_returnvalue) {
 274             // mutator prevents resetting teams+score
 275         } else {
 276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 277         this.frags = FRAGS_SPECTATOR;
 278         PlayerScore_Clear(this);  // clear scores when needed
 279     }
 280
 281         if (this.killcount != FRAGS_SPECTATOR)
 282         {
 283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 284                 if(!intermission_running)
 285                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 287
 288                 if(this.just_joined == false) {
 289                         LogTeamchange(this.playerid, -1, 4);
 290                 } else
 291                         this.just_joined = false;
 292         }
 293
 294         accuracy_resend(this);
 295
 296         this.spectatortime = time;
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         this.damagedbycontents = false;
 303         this.health = FRAGS_SPECTATOR;
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.hook_time = 0;
 332         this.deadflag = DEAD_NO;
 333         this.crouch = false;
 334         this.revival_time = 0;
 335
 336         this.items = 0;
 337         this.weapons = '0 0 0';
 338         this.drawonlytoclient = this;
 339
 340         this.weaponname = "";
 341         this.weaponmodel = "";
 342         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 343         {
 344                 this.weaponentities[slot] = NULL;
 345         }
 346         this.exteriorweaponentity = NULL;
 347         this.killcount = FRAGS_SPECTATOR;
 348         this.velocity = '0 0 0';
 349         this.avelocity = '0 0 0';
 350         this.punchangle = '0 0 0';
 351         this.punchvector = '0 0 0';
 352         this.oldvelocity = this.velocity;
 353         this.fire_endtime = -1;
 354         this.event_damage = func_null;
 355 }
 356
 357 int player_getspecies(entity this)
 358 {
 359         get_model_parameters(this.model, this.skin);
 360         int s = get_model_parameters_species;
 361         get_model_parameters(string_null, 0);
 362         if (s < 0) return SPECIES_HUMAN;
 363         return s;
 364 }
 365
 366 .float model_randomizer;
 367 void FixPlayermodel(entity player)
 368 {
 369         string defaultmodel = "";
 370         int defaultskin = 0;
 371         if(autocvar_sv_defaultcharacter)
 372         {
 373                 if(teamplay)
 374                 {
 375                         string s = Static_Team_ColorName_Lower(player.team);
 376                         if (s != "neutral")
 377                         {
 378                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 379                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 380                         }
 381                 }
 382
 383                 if(defaultmodel == "")
 384                 {
 385                         defaultmodel = autocvar_sv_defaultplayermodel;
 386                         defaultskin = autocvar_sv_defaultplayerskin;
 387                 }
 388
 389                 int n = tokenize_console(defaultmodel);
 390                 if(n > 0)
 391                 {
 392                         defaultmodel = argv(floor(n * player.model_randomizer));
 393                         // However, do NOT randomize if the player-selected model is in the list.
 394                         for (int i = 0; i < n; ++i)
 395                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 396                                         defaultmodel = argv(i);
 397                 }
 398
 399                 int i = strstrofs(defaultmodel, ":", 0);
 400                 if(i >= 0)
 401                 {
 402                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 403                         defaultmodel = substring(defaultmodel, 0, i);
 404                 }
 405         }
 406         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 407         {
 408                 if(teamplay)
 409                 {
 410                         string s = Static_Team_ColorName_Lower(player.team);
 411                         if (s != "neutral")
 412                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 413                 }
 414
 415                 if(!defaultskin)
 416                         defaultskin = autocvar_sv_defaultplayerskin;
 417         }
 418
 419         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 420         defaultmodel = M_ARGV(0, string);
 421         defaultskin = M_ARGV(1, int);
 422
 423         bool chmdl = false;
 424         int oldskin;
 425         if(defaultmodel != "")
 426         {
 427                 if (defaultmodel != player.model)
 428                 {
 429                         vector m1 = player.mins;
 430                         vector m2 = player.maxs;
 431                         setplayermodel (player, defaultmodel);
 432                         setsize (player, m1, m2);
 433                         chmdl = true;
 434                 }
 435
 436                 oldskin = player.skin;
 437                 player.skin = defaultskin;
 438         } else {
 439                 if (player.playermodel != player.model || player.playermodel == "")
 440                 {
 441                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, player.playermodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 if(!autocvar_sv_defaultcharacterskin)
 450                 {
 451                         oldskin = player.skin;
 452                         player.skin = stof(player.playerskin);
 453                 }
 454                 else
 455                 {
 456                         oldskin = player.skin;
 457                         player.skin = defaultskin;
 458                 }
 459         }
 460
 461         if(chmdl || oldskin != player.skin) // model or skin has changed
 462         {
 463                 player.species = player_getspecies(player); // update species
 464                 if(!autocvar_g_debug_globalsounds)
 465                         UpdatePlayerSounds(player); // update skin sounds
 466         }
 467
 468         if(!teamplay)
 469                 if(strlen(autocvar_sv_defaultplayercolors))
 470                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 471                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 472 }
 473
 474
 475 /** Called when a client spawns in the server */
 476 void PutClientInServer(entity this)
 477 {
 478         if (IS_BOT_CLIENT(this)) {
 479                 TRANSMUTE(Player, this);
 480         } else if (IS_REAL_CLIENT(this)) {
 481                 msg_entity = this;
 482                 WriteByte(MSG_ONE, SVC_SETVIEW);
 483                 WriteEntity(MSG_ONE, this);
 484         }
 485         if (gameover) {
 486                 TRANSMUTE(Observer, this);
 487         }
 488
 489         SetSpectatee(this, NULL);
 490
 491         // reset player keys
 492         this.itemkeys = 0;
 493
 494         MUTATOR_CALLHOOK(PutClientInServer, this);
 495
 496         if (IS_OBSERVER(this)) {
 497                 PutObserverInServer(this);
 498         } else if (IS_PLAYER(this)) {
 499                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 500
 501                 PlayerState_attach(this);
 502                 accuracy_resend(this);
 503
 504                 if (this.team < 0)
 505                         JoinBestTeam(this, false, true);
 506
 507                 entity spot = SelectSpawnPoint(this, false);
 508                 if (!spot) {
 509                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 510                         return; // spawn failed
 511                 }
 512
 513                 TRANSMUTE(Player, this);
 514                 this.wasplayer = true;
 515                 this.iscreature = true;
 516                 this.teleportable = TELEPORT_NORMAL;
 517                 this.damagedbycontents = true;
 518                 set_movetype(this, MOVETYPE_WALK);
 519                 this.solid = SOLID_SLIDEBOX;
 520                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 521                 if (autocvar_g_playerclip_collisions)
 522                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 523                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 524                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 525                 this.frags = FRAGS_PLAYER;
 526                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 527                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 528                 if (autocvar__notarget)
 529                         this.flags |= FL_NOTARGET;
 530                 this.takedamage = DAMAGE_AIM;
 531                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 532                 this.dmg = 2; // WTF
 533
 534                 if (warmup_stage) {
 535                         this.ammo_shells = warmup_start_ammo_shells;
 536                         this.ammo_nails = warmup_start_ammo_nails;
 537                         this.ammo_rockets = warmup_start_ammo_rockets;
 538                         this.ammo_cells = warmup_start_ammo_cells;
 539                         this.ammo_plasma = warmup_start_ammo_plasma;
 540                         this.ammo_fuel = warmup_start_ammo_fuel;
 541                         this.health = warmup_start_health;
 542                         this.armorvalue = warmup_start_armorvalue;
 543                         this.weapons = WARMUP_START_WEAPONS;
 544                 } else {
 545                         this.ammo_shells = start_ammo_shells;
 546                         this.ammo_nails = start_ammo_nails;
 547                         this.ammo_rockets = start_ammo_rockets;
 548                         this.ammo_cells = start_ammo_cells;
 549                         this.ammo_plasma = start_ammo_plasma;
 550                         this.ammo_fuel = start_ammo_fuel;
 551                         this.health = start_health;
 552                         this.armorvalue = start_armorvalue;
 553                         this.weapons = start_weapons;
 554                 }
 555
 556                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 557
 558                 this.items = start_items;
 559
 560                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 561                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 562                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 563                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 564                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 565                 // extend the pause of rotting if client was reset at the beginning of the countdown
 566                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 567                         float f = game_starttime - time;
 568                         this.spawnshieldtime += f;
 569                         this.pauserotarmor_finished += f;
 570                         this.pauserothealth_finished += f;
 571                         this.pauseregen_finished += f;
 572                 }
 573                 this.damageforcescale = 2;
 574                 this.death_time = 0;
 575                 this.respawn_flags = 0;
 576                 this.respawn_time = 0;
 577                 this.stat_respawn_time = 0;
 578                 this.scale = autocvar_sv_player_scale;
 579                 this.fade_time = 0;
 580                 this.pain_frame = 0;
 581                 this.pain_finished = 0;
 582                 this.pushltime = 0;
 583                 setthink(this, func_null); // players have no think function
 584                 this.nextthink = 0;
 585                 this.dmg_team = 0;
 586                 this.ballistics_density = autocvar_g_ballistics_density_player;
 587
 588                 this.deadflag = DEAD_NO;
 589
 590                 this.angles = spot.angles;
 591                 this.angles_z = 0; // never spawn tilted even if the spot says to
 592                 if (IS_BOT_CLIENT(this))
 593                         this.v_angle = this.angles;
 594                 this.fixangle = true; // turn this way immediately
 595                 this.oldvelocity = this.velocity = '0 0 0';
 596                 this.avelocity = '0 0 0';
 597                 this.punchangle = '0 0 0';
 598                 this.punchvector = '0 0 0';
 599
 600                 this.strength_finished = 0;
 601                 this.invincible_finished = 0;
 602                 this.fire_endtime = -1;
 603                 this.revival_time = 0;
 604                 this.air_finished = time + 12;
 605
 606                 entity spawnevent = new_pure(spawnevent);
 607                 spawnevent.owner = this;
 608                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 609
 610                 // Cut off any still running player sounds.
 611                 stopsound(this, CH_PLAYER_SINGLE);
 612
 613                 this.model = "";
 614                 FixPlayermodel(this);
 615                 this.drawonlytoclient = NULL;
 616
 617                 this.crouch = false;
 618                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 619                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 620                 this.spawnorigin = spot.origin;
 621                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 622                 // don't reset back to last position, even if new position is stuck in solid
 623                 this.oldorigin = this.origin;
 624                 this.prevorigin = this.origin;
 625                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 626                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 627                 this.hud = HUD_NORMAL;
 628
 629                 this.event_damage = PlayerDamage;
 630
 631                 this.bot_attack = true;
 632                 this.monster_attack = true;
 633
 634                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 635
 636                 if (this.killcount == FRAGS_SPECTATOR) {
 637                         PlayerScore_Clear(this);
 638                         this.killcount = 0;
 639                 }
 640
 641                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 642                 {
 643                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 644                 }
 645                 this.alpha = default_player_alpha;
 646                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 647                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 648
 649                 this.speedrunning = false;
 650
 651                 target_voicescript_clear(this);
 652
 653                 // reset fields the weapons may use
 654                 FOREACH(Weapons, true, LAMBDA(
 655                         it.wr_resetplayer(it, this);
 656                         // reload all reloadable weapons
 657                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 658                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 659                         }
 660                 ));
 661
 662                 {
 663                         string s = spot.target;
 664                         spot.target = string_null;
 665                         SUB_UseTargets(spot, this, NULL);
 666                         spot.target = s;
 667                 }
 668
 669                 Unfreeze(this);
 670
 671                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 672
 673                 if (autocvar_spawn_debug)
 674                 {
 675                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 676                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 677                 }
 678
 679                 PS(this).m_switchweapon = w_getbestweapon(this);
 680                 this.cnt = -1; // W_LastWeapon will not complain
 681                 PS(this).m_weapon = WEP_Null;
 682                 this.weaponname = "";
 683                 PS(this).m_switchingweapon = WEP_Null;
 684
 685                 if (!warmup_stage && !this.alivetime)
 686                         this.alivetime = time;
 687
 688                 antilag_clear(this, CS(this));
 689         }
 690 }
 691
 692 void ClientInit_misc(entity this);
 693
 694 .float ebouncefactor, ebouncestop; // electro's values
 695 // TODO do we need all these fields, or should we stop autodetecting runtime
 696 // changes and just have a console command to update this?
 697 bool ClientInit_SendEntity(entity this, entity to, int sf)
 698 {
 699         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 700         return = true;
 701         msg_entity = to;
 702         // MSG_INIT replacement
 703         // TODO: make easier to use
 704         Registry_send_all();
 705         W_PROP_reload(MSG_ONE, to);
 706         ClientInit_misc(this);
 707         MUTATOR_CALLHOOK(Ent_Init);
 708 }
 709 void ClientInit_misc(entity this)
 710 {
 711         int channel = MSG_ONE;
 712         WriteHeader(channel, ENT_CLIENT_INIT);
 713         WriteByte(channel, g_nexball_meter_period * 32);
 714         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 715         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 716         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 717         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 718         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 719         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 720         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 721         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 722
 723         if(sv_foginterval && world.fog != "")
 724                 WriteString(channel, world.fog);
 725         else
 726                 WriteString(channel, "");
 727         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 728         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 729         WriteCoord(channel, autocvar_g_trueaim_minrange);
 730 }
 731
 732 void ClientInit_CheckUpdate(entity this)
 733 {
 734         this.nextthink = time;
 735         if(this.count != autocvar_g_balance_armor_blockpercent)
 736         {
 737                 this.count = autocvar_g_balance_armor_blockpercent;
 738                 this.SendFlags |= 1;
 739         }
 740 }
 741
 742 void ClientInit_Spawn()
 743 {
 744         entity e = new_pure(clientinit);
 745         setthink(e, ClientInit_CheckUpdate);
 746         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 747
 748         ClientInit_CheckUpdate(e);
 749 }
 750
 751 /*
 752 =============
 753 SetNewParms
 754 =============
 755 */
 756 void SetNewParms ()
 757 {
 758         // initialize parms for a new player
 759         parm1 = -(86400 * 366);
 760
 761         MUTATOR_CALLHOOK(SetNewParms);
 762 }
 763
 764 /*
 765 =============
 766 SetChangeParms
 767 =============
 768 */
 769 void SetChangeParms (entity this)
 770 {
 771         // save parms for level change
 772         parm1 = this.parm_idlesince - time;
 773
 774         MUTATOR_CALLHOOK(SetChangeParms);
 775 }
 776
 777 /*
 778 =============
 779 DecodeLevelParms
 780 =============
 781 */
 782 void DecodeLevelParms(entity this)
 783 {
 784         // load parms
 785         this.parm_idlesince = parm1;
 786         if (this.parm_idlesince == -(86400 * 366))
 787                 this.parm_idlesince = time;
 788
 789         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 790         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 791
 792         MUTATOR_CALLHOOK(DecodeLevelParms);
 793 }
 794
 795 /*
 796 =============
 797 ClientKill
 798
 799 Called when a client types 'kill' in the console
 800 =============
 801 */
 802
 803 .float clientkill_nexttime;
 804 void ClientKill_Now_TeamChange(entity this)
 805 {
 806         if(this.killindicator_teamchange == -1)
 807         {
 808                 JoinBestTeam( this, false, true );
 809         }
 810         else if(this.killindicator_teamchange == -2)
 811         {
 812                 if(blockSpectators)
 813                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 814                 PutObserverInServer(this);
 815         }
 816         else
 817                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 818         this.killindicator_teamchange = 0;
 819 }
 820
 821 void ClientKill_Now(entity this)
 822 {
 823         if(this.vehicle)
 824         {
 825             vehicles_exit(this.vehicle, VHEF_RELEASE);
 826             if(!this.killindicator_teamchange)
 827             {
 828             this.vehicle_health = -1;
 829             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 830             }
 831         }
 832
 833         if(this.killindicator && !wasfreed(this.killindicator))
 834                 delete(this.killindicator);
 835
 836         this.killindicator = NULL;
 837
 838         if(this.killindicator_teamchange)
 839                 ClientKill_Now_TeamChange(this);
 840
 841         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 842                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 843
 844         // now I am sure the player IS dead
 845 }
 846 void KillIndicator_Think(entity this)
 847 {
 848         if (gameover)
 849         {
 850                 this.owner.killindicator = NULL;
 851                 delete(this);
 852                 return;
 853         }
 854
 855         if (this.owner.alpha < 0 && !this.owner.vehicle)
 856         {
 857                 this.owner.killindicator = NULL;
 858                 delete(this);
 859                 return;
 860         }
 861
 862         if(this.cnt <= 0)
 863         {
 864                 ClientKill_Now(this.owner);
 865                 return;
 866         }
 867     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 868     {
 869         this.nextthink = time + 1;
 870         this.cnt -= 1;
 871     }
 872         else
 873         {
 874                 if(this.cnt <= 10)
 875                         setmodel(this, MDL_NUM(this.cnt));
 876                 if(IS_REAL_CLIENT(this.owner))
 877                 {
 878                         if(this.cnt <= 10)
 879                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 880                 }
 881                 this.nextthink = time + 1;
 882                 this.cnt -= 1;
 883         }
 884 }
 885
 886 float clientkilltime;
 887 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 888 {
 889         float killtime;
 890         float starttime;
 891
 892         if (gameover)
 893                 return;
 894
 895         killtime = autocvar_g_balance_kill_delay;
 896
 897         if(g_race_qualifying || g_cts)
 898                 killtime = 0;
 899
 900     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 901         return;
 902
 903         this.killindicator_teamchange = targetteam;
 904
 905     if(!this.killindicator)
 906         {
 907                 if(!IS_DEAD(this))
 908                 {
 909                         killtime = max(killtime, this.clientkill_nexttime - time);
 910                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 911                 }
 912
 913                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 914                 {
 915                         ClientKill_Now(this);
 916                 }
 917                 else
 918                 {
 919                         starttime = max(time, clientkilltime);
 920
 921                         this.killindicator = spawn();
 922                         this.killindicator.owner = this;
 923                         this.killindicator.scale = 0.5;
 924                         setattachment(this.killindicator, this, "");
 925                         setorigin(this.killindicator, '0 0 52');
 926                         setthink(this.killindicator, KillIndicator_Think);
 927                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 928                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 929                         this.killindicator.cnt = ceil(killtime);
 930                         this.killindicator.count = bound(0, ceil(killtime), 10);
 931                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 932
 933                         FOREACH_ENTITY_ENT(enemy, this,
 934                         {
 935                                 if(it.classname != "body")
 936                                         continue;
 937                                 it.killindicator = spawn();
 938                                 it.killindicator.owner = it;
 939                                 it.killindicator.scale = 0.5;
 940                                 setattachment(it.killindicator, it, "");
 941                                 setorigin(it.killindicator, '0 0 52');
 942                                 setthink(it.killindicator, KillIndicator_Think);
 943                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 944                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 945                                 it.killindicator.cnt = ceil(killtime);
 946                         });
 947                         this.lip = 0;
 948                 }
 949         }
 950         if(this.killindicator)
 951         {
 952                 if(targetteam == 0) // just die
 953                 {
 954                         this.killindicator.colormod = '0 0 0';
 955                         if(IS_REAL_CLIENT(this))
 956                         if(this.killindicator.cnt > 0)
 957                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 958                 }
 959                 else if(targetteam == -1) // auto
 960                 {
 961                         this.killindicator.colormod = '0 1 0';
 962                         if(IS_REAL_CLIENT(this))
 963                         if(this.killindicator.cnt > 0)
 964                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 965                 }
 966                 else if(targetteam == -2) // spectate
 967                 {
 968                         this.killindicator.colormod = '0.5 0.5 0.5';
 969                         if(IS_REAL_CLIENT(this))
 970                         if(this.killindicator.cnt > 0)
 971                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 972                 }
 973                 else
 974                 {
 975                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 976                         if(IS_REAL_CLIENT(this))
 977                         if(this.killindicator.cnt > 0)
 978                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 979                 }
 980         }
 981
 982 }
 983
 984 void ClientKill (entity this)
 985 {
 986         if(gameover) return;
 987         if(this.player_blocked) return;
 988         if(STAT(FROZEN, this)) return;
 989
 990         ClientKill_TeamChange(this, 0);
 991 }
 992
 993 void FixClientCvars(entity e)
 994 {
 995         // send prediction settings to the client
 996         stuffcmd(e, "\nin_bindmap 0 0\n");
 997         if(autocvar_g_antilag == 3) // client side hitscan
 998                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 999         if(autocvar_sv_gentle)
1000                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1001
1002         MUTATOR_CALLHOOK(FixClientCvars, e);
1003 }
1004
1005 float PlayerInIDList(entity p, string idlist)
1006 {
1007         float n, i;
1008         string s;
1009
1010         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1011         if (!p.crypto_idfp)
1012                 return 0;
1013
1014         // this function allows abbreviated player IDs too!
1015         n = tokenize_console(idlist);
1016         for(i = 0; i < n; ++i)
1017         {
1018                 s = argv(i);
1019                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1020                         return 1;
1021         }
1022
1023         return 0;
1024 }
1025
1026 #ifdef DP_EXT_PRECONNECT
1027 /*
1028 =============
1029 ClientPreConnect
1030
1031 Called once (not at each match start) when a client begins a connection to the server
1032 =============
1033 */
1034 void ClientPreConnect ()
1035 {ENGINE_EVENT();
1036         if(autocvar_sv_eventlog)
1037         {
1038                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1039                         this.playerid,
1040                         etof(this),
1041                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1042                 ));
1043         }
1044 }
1045 #endif
1046
1047 /**
1048 =============
1049 ClientConnect
1050
1051 Called when a client connects to the server
1052 =============
1053 */
1054 void ClientConnect(entity this)
1055 {
1056         if (Ban_MaybeEnforceBanOnce(this)) return;
1057         assert(!IS_CLIENT(this), return);
1058         this.flags |= FL_CLIENT;
1059         assert(player_count >= 0, player_count = 0);
1060
1061 #ifdef WATERMARK
1062         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1063 #endif
1064         this.version_nagtime = time + 10 + random() * 10;
1065         TRANSMUTE(Client, this);
1066
1067         // identify the right forced team
1068         if (autocvar_g_campaign)
1069         {
1070                 if (IS_REAL_CLIENT(this)) // only players, not bots
1071                 {
1072                         switch (autocvar_g_campaign_forceteam)
1073                         {
1074                                 case 1: this.team_forced = NUM_TEAM_1; break;
1075                                 case 2: this.team_forced = NUM_TEAM_2; break;
1076                                 case 3: this.team_forced = NUM_TEAM_3; break;
1077                                 case 4: this.team_forced = NUM_TEAM_4; break;
1078                                 default: this.team_forced = 0;
1079                         }
1080                 }
1081         }
1082         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1083         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1084         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1085         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1086         else switch (autocvar_g_forced_team_otherwise)
1087         {
1088                 default: this.team_forced = 0; break;
1089                 case "red": this.team_forced = NUM_TEAM_1; break;
1090                 case "blue": this.team_forced = NUM_TEAM_2; break;
1091                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1092                 case "pink": this.team_forced = NUM_TEAM_4; break;
1093                 case "spectate":
1094                 case "spectator":
1095                         this.team_forced = -1;
1096                         break;
1097         }
1098         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1099
1100     {
1101         int id = this.playerid;
1102         this.playerid = 0; // silent
1103             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1104             this.playerid = id;
1105     }
1106
1107         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1108                 TRANSMUTE(Observer, this);
1109         } else {
1110                 if (!teamplay || autocvar_g_balance_teams) {
1111                         TRANSMUTE(Player, this);
1112                         campaign_bots_may_start = true;
1113                 } else {
1114                         TRANSMUTE(Observer, this); // do it anyway
1115                 }
1116         }
1117
1118         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1119
1120         // always track bots, don't ask for cl_allow_uidtracking
1121     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1122
1123         if (autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1125
1126         LogTeamchange(this.playerid, this.team, 1);
1127
1128         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1129
1130         this.netname_previous = strzone(this.netname);
1131
1132         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1133
1134         stuffcmd(this, clientstuff, "\n");
1135         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1136
1137         FixClientCvars(this);
1138
1139         // get version info from player
1140         stuffcmd(this, "cmd clientversion $gameversion\n");
1141
1142         // notify about available teams
1143         if (teamplay)
1144         {
1145                 CheckAllowedTeams(this);
1146                 int t = 0;
1147                 if (c1 >= 0) t |= BIT(0);
1148                 if (c2 >= 0) t |= BIT(1);
1149                 if (c3 >= 0) t |= BIT(2);
1150                 if (c4 >= 0) t |= BIT(3);
1151                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1152         }
1153         else
1154         {
1155                 stuffcmd(this, "set _teams_available 0\n");
1156         }
1157
1158         bot_relinkplayerlist();
1159
1160         this.spectatortime = time;
1161         if (blockSpectators)
1162         {
1163                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1164         }
1165
1166         this.jointime = time;
1167         this.allowed_timeouts = autocvar_sv_timeout_number;
1168
1169         if (IS_REAL_CLIENT(this))
1170         {
1171                 if (!autocvar_g_campaign)
1172                 {
1173                         this.motd_actived_time = -1;
1174                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1175                 }
1176
1177                 if (g_weaponarena_weapons == WEPSET(TUBA))
1178                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1179         }
1180
1181         if (!sv_foginterval && world.fog != "")
1182                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1183
1184         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1185                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1186                         send_CSQC_teamnagger();
1187
1188         CSQCMODEL_AUTOINIT(this);
1189
1190         this.model_randomizer = random();
1191
1192         if (IS_REAL_CLIENT(this))
1193                 sv_notice_join(this);
1194
1195         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1196                 it.init_for_player(it, this);
1197         });
1198
1199         MUTATOR_CALLHOOK(ClientConnect, this);
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void ReadyCount();
1210 void ClientDisconnect(entity this)
1211 {
1212         assert(IS_CLIENT(this), return);
1213
1214         PlayerStats_GameReport_FinalizePlayer(this);
1215         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1216         if (this.active_minigame) part_minigame(this);
1217         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1218
1219         if (autocvar_sv_eventlog)
1220                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1221
1222         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1223
1224         SetSpectatee(this, NULL);
1225
1226     MUTATOR_CALLHOOK(ClientDisconnect, this);
1227
1228         ClientState_detach(this);
1229
1230         Portal_ClearAll(this);
1231
1232         Unfreeze(this);
1233
1234         RemoveGrapplingHook(this);
1235
1236         // Here, everything has been done that requires this player to be a client.
1237
1238         this.flags &= ~FL_CLIENT;
1239
1240         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1241         if (this.killindicator) delete(this.killindicator);
1242
1243         WaypointSprite_PlayerGone(this);
1244
1245         bot_relinkplayerlist();
1246
1247         if (this.netname_previous) strunzone(this.netname_previous);
1248         if (this.clientstatus) strunzone(this.clientstatus);
1249         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1250         if (this.personal) delete(this.personal);
1251
1252         this.playerid = 0;
1253         ReadyCount();
1254         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1255 }
1256
1257 void ChatBubbleThink(entity this)
1258 {
1259         this.nextthink = time;
1260         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1261         {
1262                 if(this.owner) // but why can that ever be NULL?
1263                         this.owner.chatbubbleentity = NULL;
1264                 delete(this);
1265                 return;
1266         }
1267
1268         this.mdl = "";
1269
1270         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1271         {
1272                 if ( this.owner.active_minigame )
1273                         this.mdl = "models/sprites/minigame_busy.iqm";
1274                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1275                         this.mdl = "models/misc/chatbubble.spr";
1276         }
1277
1278         if ( this.model != this.mdl )
1279                 _setmodel(this, this.mdl);
1280
1281 }
1282
1283 void UpdateChatBubble(entity this)
1284 {
1285         if (this.alpha < 0)
1286                 return;
1287         // spawn a chatbubble entity if needed
1288         if (!this.chatbubbleentity)
1289         {
1290                 this.chatbubbleentity = new(chatbubbleentity);
1291                 this.chatbubbleentity.owner = this;
1292                 this.chatbubbleentity.exteriormodeltoclient = this;
1293                 setthink(this.chatbubbleentity, ChatBubbleThink);
1294                 this.chatbubbleentity.nextthink = time;
1295                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1296                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1297                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1298                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1299                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1300                 //this.chatbubbleentity.model = "";
1301                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1302         }
1303 }
1304
1305
1306 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1307 // added to the model skins
1308 /*void UpdateColorModHack()
1309 {
1310         float c;
1311         c = this.clientcolors & 15;
1312         // LordHavoc: only bothering to support white, green, red, yellow, blue
1313              if (!teamplay) this.colormod = '0 0 0';
1314         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1315         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1316         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1317         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1318         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1319         else this.colormod = '1 1 1';
1320 }*/
1321
1322 void respawn(entity this)
1323 {
1324         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1325         {
1326                 this.solid = SOLID_NOT;
1327                 this.takedamage = DAMAGE_NO;
1328                 set_movetype(this, MOVETYPE_FLY);
1329                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1330                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1331                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1332                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1333                 if(autocvar_g_respawn_ghosts_maxtime)
1334                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1335         }
1336
1337         CopyBody(this, 1);
1338
1339         this.effects |= EF_NODRAW; // prevent another CopyBody
1340         PutClientInServer(this);
1341 }
1342
1343 void play_countdown(entity this, float finished, Sound samp)
1344 {
1345     TC(Sound, samp);
1346         if(IS_REAL_CLIENT(this))
1347                 if(floor(finished - time - frametime) != floor(finished - time))
1348                         if(finished - time < 6)
1349                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1350 }
1351
1352 void player_powerups(entity this)
1353 {
1354         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1355         int items_prev = this.items;
1356
1357         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1358                 this.modelflags |= MF_ROCKET;
1359         else
1360                 this.modelflags &= ~MF_ROCKET;
1361
1362         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1363
1364         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1365                 return;
1366
1367         Fire_ApplyDamage(this);
1368         Fire_ApplyEffect(this);
1369
1370         if (!g_instagib)
1371         {
1372                 if (this.items & ITEM_Strength.m_itemid)
1373                 {
1374                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1375                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1376                         if (time > this.strength_finished)
1377                         {
1378                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1379                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1380                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1381                         }
1382                 }
1383                 else
1384                 {
1385                         if (time < this.strength_finished)
1386                         {
1387                                 this.items = this.items | ITEM_Strength.m_itemid;
1388                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1389                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1390                         }
1391                 }
1392                 if (this.items & ITEM_Shield.m_itemid)
1393                 {
1394                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1395                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1396                         if (time > this.invincible_finished)
1397                         {
1398                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1399                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1400                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1401                         }
1402                 }
1403                 else
1404                 {
1405                         if (time < this.invincible_finished)
1406                         {
1407                                 this.items = this.items | ITEM_Shield.m_itemid;
1408                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1409                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1410                         }
1411                 }
1412                 if (this.items & IT_SUPERWEAPON)
1413                 {
1414                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1415                         {
1416                                 this.superweapons_finished = 0;
1417                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1418                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1419                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1420                         }
1421                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1422                         {
1423                                 // don't let them run out
1424                         }
1425                         else
1426                         {
1427                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1428                                 if (time > this.superweapons_finished)
1429                                 {
1430                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1431                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1432                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1433                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1434                                 }
1435                         }
1436                 }
1437                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1438                 {
1439                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1440                         {
1441                                 this.items = this.items | IT_SUPERWEAPON;
1442                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1444                         }
1445                         else
1446                         {
1447                                 this.superweapons_finished = 0;
1448                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1449                         }
1450                 }
1451                 else
1452                 {
1453                         this.superweapons_finished = 0;
1454                 }
1455         }
1456
1457         if(autocvar_g_nodepthtestplayers)
1458                 this.effects = this.effects | EF_NODEPTHTEST;
1459
1460         if(autocvar_g_fullbrightplayers)
1461                 this.effects = this.effects | EF_FULLBRIGHT;
1462
1463         if (time >= game_starttime)
1464         if (time < this.spawnshieldtime)
1465                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1466
1467         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1468 }
1469
1470 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1471 {
1472         if(current > stable)
1473                 return current;
1474         else if(current > stable - 0.25) // when close enough, "snap"
1475                 return stable;
1476         else
1477                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1478 }
1479
1480 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1481 {
1482         if(current < stable)
1483                 return current;
1484         else if(current < stable + 0.25) // when close enough, "snap"
1485                 return stable;
1486         else
1487                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1488 }
1489
1490 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1491 {
1492         if(current > rotstable)
1493         {
1494                 if(rotframetime > 0)
1495                 {
1496                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1497                         current = max(rotstable, current - rotlinear * rotframetime);
1498                 }
1499         }
1500         else if(current < regenstable)
1501         {
1502                 if(regenframetime > 0)
1503                 {
1504                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1505                         current = min(regenstable, current + regenlinear * regenframetime);
1506                 }
1507         }
1508
1509         if(current > limit)
1510                 current = limit;
1511
1512         return current;
1513 }
1514
1515 void player_regen(entity this)
1516 {
1517         float max_mod, regen_mod, rot_mod, limit_mod;
1518         max_mod = regen_mod = rot_mod = limit_mod = 1;
1519
1520         float regen_health = autocvar_g_balance_health_regen;
1521         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1522         float regen_health_rot = autocvar_g_balance_health_rot;
1523         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1524         float regen_health_stable = autocvar_g_balance_health_regenstable;
1525         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1526         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1527                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1528         max_mod = M_ARGV(1, float);
1529         regen_mod = M_ARGV(2, float);
1530         rot_mod = M_ARGV(3, float);
1531         limit_mod = M_ARGV(4, float);
1532         regen_health = M_ARGV(5, float);
1533         regen_health_linear = M_ARGV(6, float);
1534         regen_health_rot = M_ARGV(7, float);
1535         regen_health_rotlinear = M_ARGV(8, float);
1536         regen_health_stable = M_ARGV(9, float);
1537         regen_health_rotstable = M_ARGV(10, float);
1538
1539
1540         if(!mutator_returnvalue)
1541         if(!STAT(FROZEN, this))
1542         {
1543                 float mina, maxa, limith, limita;
1544                 maxa = autocvar_g_balance_armor_rotstable;
1545                 mina = autocvar_g_balance_armor_regenstable;
1546                 limith = autocvar_g_balance_health_limit;
1547                 limita = autocvar_g_balance_armor_limit;
1548
1549                 regen_health_rotstable = regen_health_rotstable * max_mod;
1550                 regen_health_stable = regen_health_stable * max_mod;
1551                 limith = limith * limit_mod;
1552                 limita = limita * limit_mod;
1553
1554                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1555                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1556         }
1557
1558         // if player rotted to death...  die!
1559         // check this outside above checks, as player may still be able to rot to death
1560         if(this.health < 1)
1561         {
1562                 if(this.vehicle)
1563                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1564                 if(this.event_damage)
1565                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1566         }
1567
1568         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1569         {
1570                 float minf, maxf, limitf;
1571
1572                 maxf = autocvar_g_balance_fuel_rotstable;
1573                 minf = autocvar_g_balance_fuel_regenstable;
1574                 limitf = autocvar_g_balance_fuel_limit;
1575
1576                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1577         }
1578 }
1579
1580 bool zoomstate_set;
1581 void SetZoomState(entity this, float z)
1582 {
1583         if(z != this.zoomstate)
1584         {
1585                 this.zoomstate = z;
1586                 ClientData_Touch(this);
1587         }
1588         zoomstate_set = true;
1589 }
1590
1591 void GetPressedKeys(entity this)
1592 {
1593         MUTATOR_CALLHOOK(GetPressedKeys, this);
1594         int keys = this.pressedkeys;
1595         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1596         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1597         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1598         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1599
1600         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1601         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1602         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1603         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1604         this.pressedkeys = keys;
1605 }
1606
1607 /*
1608 ======================
1609 spectate mode routines
1610 ======================
1611 */
1612
1613 void SpectateCopy(entity this, entity spectatee)
1614 {
1615     TC(Client, this); TC(Client, spectatee);
1616
1617         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1618         PS(this) = PS(spectatee);
1619         this.armortype = spectatee.armortype;
1620         this.armorvalue = spectatee.armorvalue;
1621         this.ammo_cells = spectatee.ammo_cells;
1622         this.ammo_plasma = spectatee.ammo_plasma;
1623         this.ammo_shells = spectatee.ammo_shells;
1624         this.ammo_nails = spectatee.ammo_nails;
1625         this.ammo_rockets = spectatee.ammo_rockets;
1626         this.ammo_fuel = spectatee.ammo_fuel;
1627         this.clip_load = spectatee.clip_load;
1628         this.clip_size = spectatee.clip_size;
1629         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1630         this.health = spectatee.health;
1631         this.impulse = 0;
1632         this.items = spectatee.items;
1633         this.last_pickup = spectatee.last_pickup;
1634         this.hit_time = spectatee.hit_time;
1635         this.strength_finished = spectatee.strength_finished;
1636         this.invincible_finished = spectatee.invincible_finished;
1637         this.pressedkeys = spectatee.pressedkeys;
1638         this.weapons = spectatee.weapons;
1639         this.vortex_charge = spectatee.vortex_charge;
1640         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1641         this.hagar_load = spectatee.hagar_load;
1642         this.arc_heat_percent = spectatee.arc_heat_percent;
1643         this.minelayer_mines = spectatee.minelayer_mines;
1644         this.punchangle = spectatee.punchangle;
1645         this.view_ofs = spectatee.view_ofs;
1646         this.velocity = spectatee.velocity;
1647         this.dmg_take = spectatee.dmg_take;
1648         this.dmg_save = spectatee.dmg_save;
1649         this.dmg_inflictor = spectatee.dmg_inflictor;
1650         this.v_angle = spectatee.v_angle;
1651         this.angles = spectatee.v_angle;
1652         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1653         this.revive_progress = spectatee.revive_progress;
1654         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1655                 this.fixangle = true;
1656         setorigin(this, spectatee.origin);
1657         setsize(this, spectatee.mins, spectatee.maxs);
1658         SetZoomState(this, spectatee.zoomstate);
1659
1660     anticheat_spectatecopy(this, spectatee);
1661         this.hud = spectatee.hud;
1662         if(spectatee.vehicle)
1663     {
1664         this.angles = spectatee.v_angle;
1665
1666         //this.fixangle = false;
1667         //this.velocity = spectatee.vehicle.velocity;
1668         this.vehicle_health = spectatee.vehicle_health;
1669         this.vehicle_shield = spectatee.vehicle_shield;
1670         this.vehicle_energy = spectatee.vehicle_energy;
1671         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1672         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1673         this.vehicle_reload1 = spectatee.vehicle_reload1;
1674         this.vehicle_reload2 = spectatee.vehicle_reload2;
1675
1676         //msg_entity = this;
1677
1678        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1679             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1680            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1681            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1682
1683         //WriteByte (MSG_ONE, SVC_SETVIEW);
1684         //    WriteEntity(MSG_ONE, this);
1685         //makevectors(spectatee.v_angle);
1686         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1687     }
1688 }
1689
1690 bool SpectateUpdate(entity this)
1691 {
1692         if(!this.enemy)
1693             return false;
1694
1695         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1696         {
1697                 SetSpectatee(this, NULL);
1698                 return false;
1699         }
1700
1701         SpectateCopy(this, this.enemy);
1702
1703         return true;
1704 }
1705
1706 bool SpectateSet(entity this)
1707 {
1708         if(!IS_PLAYER(this.enemy))
1709                 return false;
1710
1711         ClientData_Touch(this.enemy);
1712
1713         msg_entity = this;
1714         WriteByte(MSG_ONE, SVC_SETVIEW);
1715         WriteEntity(MSG_ONE, this.enemy);
1716         set_movetype(this, MOVETYPE_NONE);
1717         accuracy_resend(this);
1718
1719         if(!SpectateUpdate(this))
1720                 PutObserverInServer(this);
1721
1722         return true;
1723 }
1724
1725 void SetSpectatee(entity this, entity spectatee)
1726 {
1727         entity old_spectatee = this.enemy;
1728
1729         this.enemy = spectatee;
1730
1731         // WEAPONTODO
1732         // these are required to fix the spectator bug with arc
1733         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1734         if(this.enemy && this.enemy.arc_beam) { this.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1735
1736         // needed to update spectator list
1737         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1738 }
1739
1740 bool Spectate(entity this, entity pl)
1741 {
1742         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1743                 return false;
1744         pl = M_ARGV(1, entity);
1745
1746         SetSpectatee(this, pl);
1747         return SpectateSet(this);
1748 }
1749
1750 bool SpectateNext(entity this)
1751 {
1752         entity ent = find(this.enemy, classname, STR_PLAYER);
1753
1754         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1755                 ent = M_ARGV(1, entity);
1756         else if (!ent)
1757                 ent = find(ent, classname, STR_PLAYER);
1758
1759         if(ent) { SetSpectatee(this, ent); }
1760
1761         return SpectateSet(this);
1762 }
1763
1764 bool SpectatePrev(entity this)
1765 {
1766         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1767         entity ent = findchain(classname, STR_PLAYER);
1768         if (!ent) // no player
1769                 return false;
1770
1771         entity first = ent;
1772         // skip players until current spectated player
1773         if(this.enemy)
1774         while(ent && ent != this.enemy)
1775                 ent = ent.chain;
1776
1777         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1778         {
1779                 case MUT_SPECPREV_FOUND:
1780                     ent = M_ARGV(1, entity);
1781                     break;
1782                 case MUT_SPECPREV_RETURN:
1783                     return true;
1784                 case MUT_SPECPREV_CONTINUE:
1785                 default:
1786                 {
1787                         if(ent.chain)
1788                                 ent = ent.chain;
1789                         else
1790                                 ent = first;
1791                         break;
1792                 }
1793         }
1794
1795         SetSpectatee(this, ent);
1796         return SpectateSet(this);
1797 }
1798
1799 /*
1800 =============
1801 ShowRespawnCountdown()
1802
1803 Update a respawn countdown display.
1804 =============
1805 */
1806 void ShowRespawnCountdown(entity this)
1807 {
1808         float number;
1809         if(!IS_DEAD(this)) // just respawned?
1810                 return;
1811         else
1812         {
1813                 number = ceil(this.respawn_time - time);
1814                 if(number <= 0)
1815                         return;
1816                 if(number <= this.respawn_countdown)
1817                 {
1818                         this.respawn_countdown = number - 1;
1819                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1820                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1821                 }
1822         }
1823 }
1824
1825 void LeaveSpectatorMode(entity this)
1826 {
1827         if(this.caplayer)
1828                 return;
1829         if(nJoinAllowed(this, this))
1830         {
1831                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1832                 {
1833                         TRANSMUTE(Player, this);
1834
1835                         SetSpectatee(this, NULL);
1836
1837                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1838                                 { JoinBestTeam(this, false, true); }
1839
1840                         if(autocvar_g_campaign)
1841                                 { campaign_bots_may_start = true; }
1842
1843                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1844
1845                         PutClientInServer(this);
1846
1847                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1848                 }
1849                 else
1850                         stuffcmd(this, "menu_showteamselect\n");
1851         }
1852         else
1853         {
1854                 // Player may not join because g_maxplayers is set
1855                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1856         }
1857 }
1858
1859 /**
1860  * Determines whether the player is allowed to join. This depends on cvar
1861  * g_maxplayers, if it isn't used this function always return true, otherwise
1862  * it checks whether the number of currently playing players exceeds g_maxplayers.
1863  * @return int number of free slots for players, 0 if none
1864  */
1865 bool nJoinAllowed(entity this, entity ignore)
1866 {
1867         if(!ignore)
1868         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1869         // so report 0 free slots if restricted
1870         {
1871                 if(autocvar_g_forced_team_otherwise == "spectate")
1872                         return false;
1873                 if(autocvar_g_forced_team_otherwise == "spectator")
1874                         return false;
1875         }
1876
1877         if(this.team_forced < 0)
1878                 return false; // forced spectators can never join
1879
1880         // TODO simplify this
1881         int totalClients = 0;
1882         int currentlyPlaying = 0;
1883         FOREACH_CLIENT(true, LAMBDA(
1884                 if(it != ignore)
1885                         ++totalClients;
1886                 if(IS_REAL_CLIENT(it))
1887                 if(IS_PLAYER(it) || it.caplayer)
1888                         ++currentlyPlaying;
1889         ));
1890
1891         if (!autocvar_g_maxplayers)
1892                 return maxclients - totalClients;
1893
1894         if(currentlyPlaying < autocvar_g_maxplayers)
1895                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1896
1897         return false;
1898 }
1899
1900 /**
1901  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1902  * g_maxplayers_spectator_blocktime seconds
1903  */
1904 void checkSpectatorBlock(entity this)
1905 {
1906         if(IS_SPEC(this) || IS_OBSERVER(this))
1907         if(!this.caplayer)
1908         if(IS_REAL_CLIENT(this))
1909         {
1910                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1912                         dropclient(this);
1913                 }
1914         }
1915 }
1916
1917 void PrintWelcomeMessage(entity this)
1918 {
1919         if(this.motd_actived_time == 0)
1920         {
1921                 if (autocvar_g_campaign) {
1922                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1923                                 this.motd_actived_time = time;
1924                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1925                         }
1926                 } else {
1927                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1928                                 this.motd_actived_time = time;
1929                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1930                         }
1931                 }
1932         }
1933         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1934         {
1935                 if (autocvar_g_campaign) {
1936                         if (PHYS_INPUT_BUTTON_INFO(this))
1937                                 this.motd_actived_time = time;
1938                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1939                                 this.motd_actived_time = 0;
1940                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1941                         }
1942                 } else {
1943                         if (PHYS_INPUT_BUTTON_INFO(this))
1944                                 this.motd_actived_time = time;
1945                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1946                                 this.motd_actived_time = 0;
1947                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1948                         }
1949                 }
1950         }
1951         else //if(this.motd_actived_time < 0) // just connected, motd is active
1952         {
1953                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1954                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1955                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1956                 {
1957                         // instanctly hide MOTD
1958                         this.motd_actived_time = 0;
1959                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1960                 }
1961         }
1962 }
1963
1964 void ObserverThink(entity this)
1965 {
1966         if ( this.impulse )
1967         {
1968                 MinigameImpulse(this, this.impulse);
1969                 this.impulse = 0;
1970         }
1971         if (this.flags & FL_JUMPRELEASED) {
1972                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1973                         this.flags &= ~FL_JUMPRELEASED;
1974                         this.flags |= FL_SPAWNING;
1975                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1976                         this.flags &= ~FL_JUMPRELEASED;
1977                         if(SpectateNext(this)) {
1978                                 TRANSMUTE(Spectator, this);
1979                         }
1980                 } else {
1981                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
1982                         set_movetype(this, preferred_movetype);
1983                 }
1984         } else {
1985                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
1986                         this.flags |= FL_JUMPRELEASED;
1987                         if(this.flags & FL_SPAWNING)
1988                         {
1989                                 this.flags &= ~FL_SPAWNING;
1990                                 LeaveSpectatorMode(this);
1991                                 return;
1992                         }
1993                 }
1994         }
1995 }
1996
1997 void SpectatorThink(entity this)
1998 {
1999         if ( this.impulse )
2000         {
2001                 if(MinigameImpulse(this, this.impulse))
2002                         this.impulse = 0;
2003
2004                 if (this.impulse == IMP_weapon_drop.impulse)
2005                 {
2006                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2007                         this.impulse = 0;
2008                         return;
2009                 }
2010         }
2011         if (this.flags & FL_JUMPRELEASED) {
2012                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2013                         this.flags &= ~FL_JUMPRELEASED;
2014                         this.flags |= FL_SPAWNING;
2015                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2016                         this.flags &= ~FL_JUMPRELEASED;
2017                         if(SpectateNext(this)) {
2018                                 TRANSMUTE(Spectator, this);
2019                         } else {
2020                                 TRANSMUTE(Observer, this);
2021                                 PutClientInServer(this);
2022                         }
2023                         this.impulse = 0;
2024                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2025                         this.flags &= ~FL_JUMPRELEASED;
2026                         if(SpectatePrev(this)) {
2027                                 TRANSMUTE(Spectator, this);
2028                         } else {
2029                                 TRANSMUTE(Observer, this);
2030                                 PutClientInServer(this);
2031                         }
2032                         this.impulse = 0;
2033                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2034                         this.flags &= ~FL_JUMPRELEASED;
2035                         TRANSMUTE(Observer, this);
2036                         PutClientInServer(this);
2037                 } else {
2038                         if(!SpectateUpdate(this))
2039                                 PutObserverInServer(this);
2040                 }
2041         } else {
2042                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2043                         this.flags |= FL_JUMPRELEASED;
2044                         if(this.flags & FL_SPAWNING)
2045                         {
2046                                 this.flags &= ~FL_SPAWNING;
2047                                 LeaveSpectatorMode(this);
2048                                 return;
2049                         }
2050                 }
2051                 if(!SpectateUpdate(this))
2052                         PutObserverInServer(this);
2053         }
2054
2055         this.flags |= FL_CLIENT | FL_NOTARGET;
2056 }
2057
2058 void vehicles_enter (entity pl, entity veh);
2059 void PlayerUseKey(entity this)
2060 {
2061         if (!IS_PLAYER(this))
2062                 return;
2063
2064         if(this.vehicle)
2065         {
2066                 if(!gameover)
2067                 {
2068                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2069                         return;
2070                 }
2071         }
2072         else if(autocvar_g_vehicles_enter)
2073         {
2074                 if(!STAT(FROZEN, this))
2075                 if(!IS_DEAD(this))
2076                 if(!gameover)
2077                 {
2078                         entity head, closest_target = NULL;
2079                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2080
2081                         while(head) // find the closest acceptable target to enter
2082                         {
2083                                 if(IS_VEHICLE(head))
2084                                 if(!IS_DEAD(head))
2085                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2086                                 if(head.takedamage != DAMAGE_NO)
2087                                 {
2088                                         if(closest_target)
2089                                         {
2090                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2091                                                 { closest_target = head; }
2092                                         }
2093                                         else { closest_target = head; }
2094                                 }
2095
2096                                 head = head.chain;
2097                         }
2098
2099                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2100                 }
2101         }
2102
2103         // a use key was pressed; call handlers
2104         MUTATOR_CALLHOOK(PlayerUseKey, this);
2105 }
2106
2107
2108 /*
2109 =============
2110 PlayerPreThink
2111
2112 Called every frame for each client before the physics are run
2113 =============
2114 */
2115 .float usekeypressed;
2116 .float last_vehiclecheck;
2117 .int items_added;
2118 void PlayerPreThink (entity this)
2119 {
2120         WarpZone_PlayerPhysics_FixVAngle(this);
2121
2122     STAT(GAMESTARTTIME, this) = game_starttime;
2123         STAT(ROUNDSTARTTIME, this) = round_starttime;
2124         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2125         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2126
2127         STAT(WEAPONSINMAP, this) = weaponsInMap;
2128
2129         if (frametime) {
2130                 // physics frames: update anticheat stuff
2131                 anticheat_prethink(this);
2132         }
2133
2134         if (blockSpectators && frametime) {
2135                 // WORKAROUND: only use dropclient in server frames (frametime set).
2136                 // Never use it in cl_movement frames (frametime zero).
2137                 checkSpectatorBlock(this);
2138     }
2139
2140         zoomstate_set = false;
2141
2142         // Check for nameless players
2143         if (isInvisibleString(this.netname)) {
2144                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2145                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2146         }
2147         if (this.netname != this.netname_previous) {
2148                 if (autocvar_sv_eventlog) {
2149                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2150         }
2151                 if (this.netname_previous) strunzone(this.netname_previous);
2152                 this.netname_previous = strzone(this.netname);
2153         }
2154
2155         // version nagging
2156         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2157         this.version_nagtime = 0;
2158         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2159             // git client
2160         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2161             // git server
2162             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2163         } else {
2164             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2165             if (r < 0) { // old client
2166                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2167             } else if (r > 0) { // old server
2168                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2169             }
2170         }
2171     }
2172
2173         // GOD MODE info
2174         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2175         {
2176                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2177                 this.max_armorvalue = 0;
2178         }
2179
2180         if (STAT(FROZEN, this) == 2)
2181         {
2182                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2183                 this.health = max(1, this.revive_progress * start_health);
2184                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2185
2186                 if (this.revive_progress >= 1)
2187                         Unfreeze(this);
2188         }
2189         else if (STAT(FROZEN, this) == 3)
2190         {
2191                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2192                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2193
2194                 if (this.health < 1)
2195                 {
2196                         if (this.vehicle)
2197                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2198                         if(this.event_damage)
2199                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2200                 }
2201                 else if (this.revive_progress <= 0)
2202                         Unfreeze(this);
2203         }
2204
2205         MUTATOR_CALLHOOK(PlayerPreThink, this);
2206
2207         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2208         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2209         {
2210                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2211                 {
2212                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2213                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2214                         {
2215                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2216                         }
2217                         else if(!it.owner)
2218                         {
2219                                 if(!it.team || SAME_TEAM(this, it))
2220                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2221                                 else if(autocvar_g_vehicles_steal)
2222                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2223                         }
2224                 });
2225
2226                 this.last_vehiclecheck = time + 1;
2227         }
2228
2229         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2230         {
2231                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2232                         PlayerUseKey(this);
2233                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2234         }
2235
2236         if (IS_REAL_CLIENT(this))
2237                 PrintWelcomeMessage(this);
2238
2239         if (IS_PLAYER(this)) {
2240                 CheckRules_Player(this);
2241
2242                 if (intermission_running) {
2243                         IntermissionThink(this);
2244                         return;
2245                 }
2246
2247                 if (timeout_status == TIMEOUT_ACTIVE) {
2248             // don't allow the player to turn around while game is paused
2249                         // FIXME turn this into CSQC stuff
2250                         this.v_angle = this.lastV_angle;
2251                         this.angles = this.lastV_angle;
2252                         this.fixangle = true;
2253                 }
2254
2255                 if (frametime) player_powerups(this);
2256
2257                 if (IS_DEAD(this)) {
2258                         if (this.personal && g_race_qualifying) {
2259                                 if (time > this.respawn_time) {
2260                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2261                                         respawn(this);
2262                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2263                                 }
2264                         } else {
2265                                 if (frametime) player_anim(this);
2266                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2267
2268                                 switch(this.deadflag)
2269                                 {
2270                                         case DEAD_DYING:
2271                                         {
2272                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2273                                                         this.deadflag = DEAD_RESPAWNING;
2274                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2275                                                         this.deadflag = DEAD_DEAD;
2276                                                 break;
2277                                         }
2278                                         case DEAD_DEAD:
2279                                         {
2280                                                 if (button_pressed)
2281                                                         this.deadflag = DEAD_RESPAWNABLE;
2282                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2283                                                         this.deadflag = DEAD_RESPAWNING;
2284                                                 break;
2285                                         }
2286                                         case DEAD_RESPAWNABLE:
2287                                         {
2288                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2289                                                         this.deadflag = DEAD_RESPAWNING;
2290                                                 break;
2291                                         }
2292                                         case DEAD_RESPAWNING:
2293                                         {
2294                                                 if (time > this.respawn_time)
2295                                                 {
2296                                                         this.respawn_time = time + 1; // only retry once a second
2297                                                         this.respawn_time_max = this.respawn_time;
2298                                                         respawn(this);
2299                                                 }
2300                                                 break;
2301                                         }
2302                                 }
2303
2304                                 ShowRespawnCountdown(this);
2305
2306                                 if (this.respawn_flags & RESPAWN_SILENT)
2307                                         STAT(RESPAWN_TIME, this) = 0;
2308                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2309                                 {
2310                                         if (time < this.respawn_time)
2311                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2312                                         else if (this.deadflag != DEAD_RESPAWNING)
2313                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2314                                 }
2315                                 else
2316                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2317                         }
2318
2319                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2320                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2321                                 STAT(RESPAWN_TIME, this) *= -1;
2322
2323                         return;
2324                 }
2325
2326                 this.prevorigin = this.origin;
2327
2328                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2329         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2330                 if (this.hook.state) {
2331                         do_crouch = false;
2332                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2333                         do_crouch = false;
2334                 } else if (this.vehicle) {
2335                         do_crouch = false;
2336                 } else if (STAT(FROZEN, this)) {
2337                         do_crouch = false;
2338         } else if ((PS(this).m_weapon.spawnflags & WEP_TYPE_MELEE_PRI) && this.(weaponentity).wframe == WFRAME_FIRE1 && time < this.(weaponentity).weapon_nextthink) {
2339                         do_crouch = false;
2340         } else if ((PS(this).m_weapon.spawnflags & WEP_TYPE_MELEE_SEC) && this.(weaponentity).wframe == WFRAME_FIRE2 && time < this.(weaponentity).weapon_nextthink) {
2341                         do_crouch = false;
2342         }
2343
2344                 if (do_crouch) {
2345                         if (!this.crouch) {
2346                                 this.crouch = true;
2347                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2348                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2349                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2350                         }
2351                 } else if (this.crouch) {
2352             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2353             if (!trace_startsolid) {
2354                 this.crouch = false;
2355                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2356                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2357             }
2358                 }
2359
2360                 FixPlayermodel(this);
2361
2362                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2363                 //if(frametime)
2364                 {
2365                         this.items &= ~this.items_added;
2366
2367                         W_WeaponFrame(this);
2368
2369                         this.items_added = 0;
2370                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2371                 this.items_added |= IT_FUEL;
2372
2373                         this.items |= this.items_added;
2374                 }
2375
2376                 player_regen(this);
2377
2378                 // WEAPONTODO: Add a weapon request for this
2379                 // rot vortex charge to the charge limit
2380                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2381                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2382
2383                 if (frametime) player_anim(this);
2384
2385                 // secret status
2386                 secrets_setstatus(this);
2387
2388                 // monsters status
2389                 monsters_setstatus(this);
2390
2391                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2392         }
2393         else if (gameover) {
2394                 if (intermission_running) IntermissionThink(this);
2395                 return;
2396         }
2397         else if (IS_OBSERVER(this)) {
2398                 ObserverThink(this);
2399         }
2400         else if (IS_SPEC(this)) {
2401                 SpectatorThink(this);
2402         }
2403
2404         // WEAPONTODO: Add weapon request for this
2405         if (!zoomstate_set) {
2406                 SetZoomState(this,
2407                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2408                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2409                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2410                 );
2411     }
2412
2413         int oldspectatee_status = this.spectatee_status;
2414         if (IS_SPEC(this)) {
2415                 this.spectatee_status = etof(this.enemy);
2416         } else if (IS_OBSERVER(this)) {
2417                 this.spectatee_status = etof(this);
2418         } else {
2419                 this.spectatee_status = 0;
2420     }
2421         if (this.spectatee_status != oldspectatee_status) {
2422                 ClientData_Touch(this);
2423                 if (g_race || g_cts) race_InitSpectator();
2424         }
2425
2426         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2427         {
2428                 this.teamkill_soundtime = 0;
2429
2430                 entity e = this.teamkill_soundsource;
2431                 entity oldpusher = e.pusher;
2432                 e.pusher = this;
2433                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2434                 e.pusher = oldpusher;
2435         }
2436
2437         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2438                 this.taunt_soundtime = 0;
2439                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2440         }
2441
2442         target_voicescript_next(this);
2443
2444         // WEAPONTODO: Move into weaponsystem somehow
2445         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2446         if (PS(this).m_weapon == WEP_Null)
2447                 this.clip_load = this.clip_size = 0;
2448 }
2449
2450 void DrownPlayer(entity this)
2451 {
2452         if(IS_DEAD(this))
2453                 return;
2454
2455         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2456         {
2457                 if(this.air_finished < time)
2458                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2459                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2460                 this.dmg = 2;
2461         }
2462         else if (this.air_finished < time)
2463         {       // drown!
2464                 if (this.pain_finished < time)
2465                 {
2466                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2467                         this.pain_finished = time + 0.5;
2468                 }
2469         }
2470 }
2471
2472 void Player_Physics(entity this)
2473 {
2474         set_movetype(this, ((this.move_qcphysics) ? MOVETYPE_NONE : this.move_movetype));
2475
2476         if(!this.move_qcphysics)
2477                 return;
2478
2479         int mt = this.move_movetype;
2480
2481         if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2482         {
2483                 this.move_qcphysics = false;
2484                 set_movetype(this, mt);
2485                 return;
2486         }
2487
2488         if(!frametime && !this.pm_frametime)
2489                 return;
2490
2491         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2492
2493         this.pm_frametime = 0;
2494 }
2495
2496 /*
2497 =============
2498 PlayerPostThink
2499
2500 Called every frame for each client after the physics are run
2501 =============
2502 */
2503 .float idlekick_lasttimeleft;
2504 void PlayerPostThink (entity this)
2505 {
2506         Player_Physics(this);
2507
2508         if (sv_maxidle > 0)
2509         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2510         if (IS_REAL_CLIENT(this))
2511         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2512         {
2513                 int totalClients = 0;
2514                 if(sv_maxidle_slots > 0)
2515                 {
2516                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2517                         {
2518                                 ++totalClients;
2519                         });
2520                 }
2521
2522                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2523                 { /* do nothing */ }
2524                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2525                 {
2526                         if (this.idlekick_lasttimeleft)
2527                         {
2528                                 this.idlekick_lasttimeleft = 0;
2529                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2530                         }
2531                 }
2532                 else
2533                 {
2534                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2535                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2536                                 if (!this.idlekick_lasttimeleft)
2537                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2538                         }
2539                         if (timeleft <= 0) {
2540                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2541                                 dropclient(this);
2542                                 return;
2543                         }
2544                         else if (timeleft <= 10) {
2545                                 if (timeleft != this.idlekick_lasttimeleft) {
2546                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2547                 }
2548                                 this.idlekick_lasttimeleft = timeleft;
2549                         }
2550                 }
2551         }
2552
2553         CheatFrame(this);
2554
2555         //CheckPlayerJump();
2556
2557         if (IS_PLAYER(this)) {
2558                 DrownPlayer(this);
2559                 CheckRules_Player(this);
2560                 UpdateChatBubble(this);
2561                 if (this.impulse) ImpulseCommands(this);
2562                 if (intermission_running) return; // intermission or finale
2563                 GetPressedKeys(this);
2564         }
2565
2566         if (this.waypointsprite_attachedforcarrier) {
2567             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2568                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2569     }
2570
2571         playerdemo_write(this);
2572
2573         CSQCMODEL_AUTOUPDATE(this);
2574 }