qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  54         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  55 }
  56
  57 bool ClientData_Send(entity this, entity to, int sf)
  58 {
  59         if(to != self.owner)
  60         {
  61                 error("wtf");
  62                 return false;
  63         }
  64
  65         entity e;
  66
  67         e = to;
  68         if(IS_SPEC(to))
  69                 e = to.enemy;
  70
  71         sf = 0;
  72
  73         if(e.race_completed)
  74                 sf |= 1; // forced scoreboard
  75         if(to.spectatee_status)
  76                 sf |= 2; // spectator ent number follows
  77         if(e.zoomstate)
  78                 sf |= 4; // zoomed
  79         if(e.porto_v_angle_held)
  80                 sf |= 8; // angles held
  81
  82         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  83         WriteByte(MSG_ENTITY, sf);
  84
  85         if(sf & 2)
  86                 WriteByte(MSG_ENTITY, to.spectatee_status);
  87
  88         if(sf & 8)
  89         {
  90                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  91                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  92         }
  93
  94         return true;
  95 }
  96
  97 void ClientData_Attach()
  98 {SELFPARAM();
  99         Net_LinkEntity(this.clientdata = new(clientdata), false, 0, ClientData_Send);
 100         make_pure(this.clientdata);
 101         self.clientdata.drawonlytoclient = this;
 102         self.clientdata.owner = this;
 103 }
 104
 105 void ClientData_Detach()
 106 {SELFPARAM();
 107         remove(self.clientdata);
 108         self.clientdata = world;
 109 }
 110
 111 void ClientData_Touch(entity e)
 112 {
 113         e.clientdata.SendFlags = 1;
 114
 115         // make it spectatable
 116         entity e2;
 117         FOR_EACH_REALCLIENT(e2)
 118         {
 119                 if(e2 != e)
 120                         if(IS_SPEC(e2))
 121                                 if(e2.enemy == e)
 122                                         e2.clientdata.SendFlags = 1;
 123         }
 124 }
 125
 126 .string netname_previous;
 127
 128 void SetSpectatee(entity player, entity spectatee);
 129
 130
 131 /*
 132 =============
 133 CheckPlayerModel
 134
 135 Checks if the argument string can be a valid playermodel.
 136 Returns a valid one in doubt.
 137 =============
 138 */
 139 string FallbackPlayerModel;
 140 string CheckPlayerModel(string plyermodel) {
 141         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 142         {
 143                 // note: we cannot summon Don Strunzone here, some player may
 144                 // still have the model string set. In case anyone manages how
 145                 // to change a cvar default, we'll have a small leak here.
 146                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 147         }
 148         // only in right path
 149         if( substring(plyermodel,0,14) != "models/player/")
 150                 return FallbackPlayerModel;
 151         // only good file extensions
 152         if(substring(plyermodel,-4,4) != ".zym")
 153         if(substring(plyermodel,-4,4) != ".dpm")
 154         if(substring(plyermodel,-4,4) != ".iqm")
 155         if(substring(plyermodel,-4,4) != ".md3")
 156         if(substring(plyermodel,-4,4) != ".psk")
 157                 return FallbackPlayerModel;
 158         // forbid the LOD models
 159         if(substring(plyermodel, -9,5) == "_lod1")
 160                 return FallbackPlayerModel;
 161         if(substring(plyermodel, -9,5) == "_lod2")
 162                 return FallbackPlayerModel;
 163         if(plyermodel != strtolower(plyermodel))
 164                 return FallbackPlayerModel;
 165         // also, restrict to server models
 166         if(autocvar_sv_servermodelsonly)
 167         {
 168                 if(!fexists(plyermodel))
 169                         return FallbackPlayerModel;
 170         }
 171         return plyermodel;
 172 }
 173
 174 void setplayermodel(entity e, string modelname)
 175 {
 176         precache_model(modelname);
 177         _setmodel(e, modelname);
 178         player_setupanimsformodel();
 179         UpdatePlayerSounds();
 180 }
 181
 182 /*
 183 =============
 184 PutObserverInServer
 185
 186 putting a client as observer in the server
 187 =============
 188 */
 189 void FixPlayermodel(entity player);
 190 void PutObserverInServer()
 191 {SELFPARAM();
 192         entity  spot;
 193     self.hud = HUD_NORMAL;
 194
 195         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 196
 197         spot = SelectSpawnPoint (true);
 198         if(!spot)
 199                 error("No spawnpoints for observers?!?\n");
 200         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 201
 202         if(IS_REAL_CLIENT(self))
 203         {
 204                 msg_entity = self;
 205                 WriteByte(MSG_ONE, SVC_SETVIEW);
 206                 WriteEntity(MSG_ONE, self);
 207         }
 208
 209         self.frags = FRAGS_SPECTATOR;
 210         self.bot_attack = false;
 211
 212         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 213
 214         Portal_ClearAll(self);
 215
 216         Unfreeze(self);
 217
 218         if(self.alivetime)
 219         {
 220                 if(!warmup_stage)
 221                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 222                 self.alivetime = 0;
 223         }
 224
 225         if(self.vehicle)
 226                 vehicles_exit(VHEF_RELEASE);
 227
 228         WaypointSprite_PlayerDead();
 229
 230         if(!mutator_returnvalue)  // mutator prevents resetting teams
 231                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 232
 233         if(self.killcount != FRAGS_SPECTATOR)
 234         {
 235                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 236                 if(!intermission_running)
 237                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 238                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 239
 240                 if(self.just_joined == false) {
 241                         LogTeamchange(self.playerid, -1, 4);
 242                 } else
 243                         self.just_joined = false;
 244         }
 245
 246         PlayerScore_Clear(self); // clear scores when needed
 247
 248         accuracy_resend(self);
 249
 250         self.spectatortime = time;
 251
 252         self.classname = STR_OBSERVER;
 253         self.iscreature = false;
 254         self.teleportable = TELEPORT_SIMPLE;
 255         self.damagedbycontents = false;
 256         self.health = FRAGS_SPECTATOR;
 257         self.takedamage = DAMAGE_NO;
 258         self.solid = SOLID_NOT;
 259         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 260         self.flags = FL_CLIENT | FL_NOTARGET;
 261         self.armorvalue = 666;
 262         self.effects = 0;
 263         self.armorvalue = autocvar_g_balance_armor_start;
 264         self.pauserotarmor_finished = 0;
 265         self.pauserothealth_finished = 0;
 266         self.pauseregen_finished = 0;
 267         self.damageforcescale = 0;
 268         self.death_time = 0;
 269         self.respawn_flags = 0;
 270         self.respawn_time = 0;
 271         self.stat_respawn_time = 0;
 272         self.alpha = 0;
 273         self.scale = 0;
 274         self.fade_time = 0;
 275         self.pain_frame = 0;
 276         self.pain_finished = 0;
 277         self.strength_finished = 0;
 278         self.invincible_finished = 0;
 279         self.superweapons_finished = 0;
 280         self.pushltime = 0;
 281         self.istypefrag = 0;
 282         self.think = func_null;
 283         self.nextthink = 0;
 284         self.hook_time = 0;
 285         self.deadflag = DEAD_NO;
 286         self.angles = spot.angles;
 287         self.angles_z = 0;
 288         self.fixangle = true;
 289         self.crouch = false;
 290         self.revival_time = 0;
 291
 292         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 293         self.prevorigin = self.origin;
 294         self.items = 0;
 295         self.weapons = '0 0 0';
 296         self.model = "";
 297         FixPlayermodel(self);
 298         setmodel(self, MDL_Null);
 299         self.drawonlytoclient = self;
 300
 301         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 302         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 303
 304         self.weapon = 0;
 305         self.weaponname = "";
 306         self.switchingweapon = 0;
 307         self.weaponmodel = "";
 308         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 309         {
 310                 self.weaponentity[slot] = NULL;
 311         }
 312         self.exteriorweaponentity = world;
 313         self.killcount = FRAGS_SPECTATOR;
 314         self.velocity = '0 0 0';
 315         self.avelocity = '0 0 0';
 316         self.punchangle = '0 0 0';
 317         self.punchvector = '0 0 0';
 318         self.oldvelocity = self.velocity;
 319         self.fire_endtime = -1;
 320         self.event_damage = func_null;
 321 }
 322
 323 .float model_randomizer;
 324 void FixPlayermodel(entity player)
 325 {
 326         string defaultmodel = "";
 327         int defaultskin = 0;
 328         if(autocvar_sv_defaultcharacter)
 329         {
 330                 if(teamplay)
 331                 {
 332                         string s = Static_Team_ColorName_Lower(player.team);
 333                         if (s != "neutral")
 334                         {
 335                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 336                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 337                         }
 338                 }
 339
 340                 if(defaultmodel == "")
 341                 {
 342                         defaultmodel = autocvar_sv_defaultplayermodel;
 343                         defaultskin = autocvar_sv_defaultplayerskin;
 344                 }
 345
 346                 int n = tokenize_console(defaultmodel);
 347                 if(n > 0)
 348                 {
 349                         defaultmodel = argv(floor(n * player.model_randomizer));
 350                         // However, do NOT randomize if the player-selected model is in the list.
 351                         for (int i = 0; i < n; ++i)
 352                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 353                                         defaultmodel = argv(i);
 354                 }
 355
 356                 int i = strstrofs(defaultmodel, ":", 0);
 357                 if(i >= 0)
 358                 {
 359                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 360                         defaultmodel = substring(defaultmodel, 0, i);
 361                 }
 362         }
 363         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 364         defaultmodel = ret_string;
 365         defaultskin = ret_int;
 366
 367         bool chmdl = false;
 368         int oldskin;
 369         if(defaultmodel != "")
 370         {
 371                 if (defaultmodel != player.model)
 372                 {
 373                         vector m1 = player.mins;
 374                         vector m2 = player.maxs;
 375                         setplayermodel (player, defaultmodel);
 376                         setsize (player, m1, m2);
 377                         chmdl = true;
 378                 }
 379
 380                 oldskin = player.skin;
 381                 player.skin = defaultskin;
 382         } else {
 383                 if (player.playermodel != player.model || player.playermodel == "")
 384                 {
 385                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 386                         vector m1 = player.mins;
 387                         vector m2 = player.maxs;
 388                         setplayermodel (player, player.playermodel);
 389                         setsize (player, m1, m2);
 390                         chmdl = true;
 391                 }
 392
 393                 oldskin = player.skin;
 394                 player.skin = stof(player.playerskin);
 395         }
 396
 397         if(chmdl || oldskin != player.skin) // model or skin has changed
 398         {
 399                 player.species = player_getspecies(); // update species
 400                 UpdatePlayerSounds(); // update skin sounds
 401         }
 402
 403         if(!teamplay)
 404                 if(strlen(autocvar_sv_defaultplayercolors))
 405                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 406                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 407 }
 408
 409
 410 /** Called when a client spawns in the server */
 411 void PutClientInServer()
 412 {
 413         SELFPARAM();
 414         if (IS_BOT_CLIENT(this)) {
 415                 this.classname = STR_PLAYER;
 416         } else if (IS_REAL_CLIENT(this)) {
 417                 msg_entity = this;
 418                 WriteByte(MSG_ONE, SVC_SETVIEW);
 419                 WriteEntity(MSG_ONE, this);
 420         }
 421         if (gameover) {
 422                 this.classname = STR_OBSERVER;
 423         }
 424
 425         SetSpectatee(this, NULL);
 426
 427         // reset player keys
 428         this.itemkeys = 0;
 429
 430         MUTATOR_CALLHOOK(PutClientInServer, this);
 431
 432         if (IS_OBSERVER(this)) {
 433                 PutObserverInServer();
 434         } else if (IS_PLAYER(this)) {
 435                 accuracy_resend(this);
 436
 437                 if (this.team < 0)
 438                         JoinBestTeam(this, false, true);
 439
 440                 entity spot = SelectSpawnPoint(false);
 441                 if (!spot) {
 442                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 443                         return; // spawn failed
 444                 }
 445
 446                 this.classname = STR_PLAYER;
 447                 this.wasplayer = true;
 448                 this.iscreature = true;
 449                 this.teleportable = TELEPORT_NORMAL;
 450                 this.damagedbycontents = true;
 451                 this.movetype = MOVETYPE_WALK;
 452                 this.solid = SOLID_SLIDEBOX;
 453                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 454                 if (autocvar_g_playerclip_collisions)
 455                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 456                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 457                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 458                 this.frags = FRAGS_PLAYER;
 459                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 460                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 461                 if (autocvar__notarget)
 462                         this.flags |= FL_NOTARGET;
 463                 this.takedamage = DAMAGE_AIM;
 464                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 465                 this.dmg = 2; // WTF
 466
 467                 if (warmup_stage) {
 468                         this.ammo_shells = warmup_start_ammo_shells;
 469                         this.ammo_nails = warmup_start_ammo_nails;
 470                         this.ammo_rockets = warmup_start_ammo_rockets;
 471                         this.ammo_cells = warmup_start_ammo_cells;
 472                         this.ammo_plasma = warmup_start_ammo_plasma;
 473                         this.ammo_fuel = warmup_start_ammo_fuel;
 474                         this.health = warmup_start_health;
 475                         this.armorvalue = warmup_start_armorvalue;
 476                         this.weapons = WARMUP_START_WEAPONS;
 477                 } else {
 478                         this.ammo_shells = start_ammo_shells;
 479                         this.ammo_nails = start_ammo_nails;
 480                         this.ammo_rockets = start_ammo_rockets;
 481                         this.ammo_cells = start_ammo_cells;
 482                         this.ammo_plasma = start_ammo_plasma;
 483                         this.ammo_fuel = start_ammo_fuel;
 484                         this.health = start_health;
 485                         this.armorvalue = start_armorvalue;
 486                         this.weapons = start_weapons;
 487                 }
 488
 489                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 490
 491                 this.items = start_items;
 492
 493                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 494                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 495                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 496                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 497                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 498                 // extend the pause of rotting if client was reset at the beginning of the countdown
 499                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 500                         float f = game_starttime - time;
 501                         this.spawnshieldtime += f;
 502                         this.pauserotarmor_finished += f;
 503                         this.pauserothealth_finished += f;
 504                         this.pauseregen_finished += f;
 505                 }
 506                 this.damageforcescale = 2;
 507                 this.death_time = 0;
 508                 this.respawn_flags = 0;
 509                 this.respawn_time = 0;
 510                 this.stat_respawn_time = 0;
 511                 this.scale = autocvar_sv_player_scale;
 512                 this.fade_time = 0;
 513                 this.pain_frame = 0;
 514                 this.pain_finished = 0;
 515                 this.pushltime = 0;
 516                 this.think = func_null; // players have no think function
 517                 this.nextthink = 0;
 518                 this.dmg_team = 0;
 519                 this.ballistics_density = autocvar_g_ballistics_density_player;
 520
 521                 this.deadflag = DEAD_NO;
 522
 523                 this.angles = spot.angles;
 524                 this.angles_z = 0; // never spawn tilted even if the spot says to
 525                 if (IS_BOT_CLIENT(this))
 526                         this.v_angle = this.angles;
 527                 this.fixangle = true; // turn this way immediately
 528                 this.oldvelocity = this.velocity = '0 0 0';
 529                 this.avelocity = '0 0 0';
 530                 this.punchangle = '0 0 0';
 531                 this.punchvector = '0 0 0';
 532
 533                 this.strength_finished = 0;
 534                 this.invincible_finished = 0;
 535                 this.fire_endtime = -1;
 536                 this.revival_time = 0;
 537                 this.air_finished = time + 12;
 538
 539                 entity spawnevent = new(spawnevent);
 540                 make_pure(spawnevent);
 541                 spawnevent.owner = this;
 542                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 543
 544                 // Cut off any still running player sounds.
 545                 stopsound(this, CH_PLAYER_SINGLE);
 546
 547                 this.model = "";
 548                 FixPlayermodel(this);
 549                 this.drawonlytoclient = NULL;
 550
 551                 this.crouch = false;
 552                 this.view_ofs = PL_VIEW_OFS;
 553                 setsize(this, PL_MIN, PL_MAX);
 554                 this.spawnorigin = spot.origin;
 555                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 556                 // don't reset back to last position, even if new position is stuck in solid
 557                 this.oldorigin = this.origin;
 558                 this.prevorigin = this.origin;
 559                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 560         this.hud = HUD_NORMAL;
 561
 562                 this.event_damage = PlayerDamage;
 563
 564                 this.bot_attack = true;
 565                 this.monster_attack = true;
 566
 567                 this.spider_slowness = 0;
 568
 569                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = false;
 570
 571                 if (this.killcount == FRAGS_SPECTATOR) {
 572                         PlayerScore_Clear(this);
 573                         this.killcount = 0;
 574                 }
 575
 576                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 577                 {
 578                         CL_SpawnWeaponentity(this, slot);
 579                 }
 580                 this.alpha = default_player_alpha;
 581                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 582                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 583
 584                 this.speedrunning = false;
 585
 586                 target_voicescript_clear(this);
 587
 588                 // reset fields the weapons may use
 589                 FOREACH(Weapons, true, LAMBDA(
 590                         it.wr_resetplayer(it);
 591                         // reload all reloadable weapons
 592                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 593                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 594                         }
 595                 ));
 596
 597                 {
 598                         string s = spot.target;
 599                         spot.target = string_null;
 600                         WITH(entity, activator, this, LAMBDA(
 601                                 WITH(entity, self, spot, SUB_UseTargets())
 602                         ));
 603                         spot.target = s;
 604                 }
 605
 606                 Unfreeze(this);
 607
 608                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 609
 610                 if (autocvar_spawn_debug)
 611                 {
 612                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 613                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 614                 }
 615
 616                 this.switchweapon = w_getbestweapon(this);
 617                 this.cnt = -1; // W_LastWeapon will not complain
 618                 this.weapon = 0;
 619                 this.weaponname = "";
 620                 this.switchingweapon = 0;
 621
 622                 if (!warmup_stage && !this.alivetime)
 623                         this.alivetime = time;
 624
 625                 antilag_clear(this);
 626         }
 627 }
 628
 629 .float ebouncefactor, ebouncestop; // electro's values
 630 // TODO do we need all these fields, or should we stop autodetecting runtime
 631 // changes and just have a console command to update this?
 632 bool ClientInit_SendEntity(entity this, entity to, int sf)
 633 {
 634         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 635         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 640         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 641         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 642         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 643         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 644
 645         if(sv_foginterval && world.fog != "")
 646                 WriteString(MSG_ENTITY, world.fog);
 647         else
 648                 WriteString(MSG_ENTITY, "");
 649         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 650         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 651         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 652         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 653         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 654         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 655         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 656         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 657         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 658         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 659         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 660         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 661
 662         MUTATOR_CALLHOOK(Ent_Init);
 663         return true;
 664 }
 665
 666 void ClientInit_CheckUpdate()
 667 {SELFPARAM();
 668         self.nextthink = time;
 669         if(self.count != autocvar_g_balance_armor_blockpercent)
 670         {
 671                 self.count = autocvar_g_balance_armor_blockpercent;
 672                 self.SendFlags |= 1;
 673         }
 674         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 675         {
 676                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 677                 self.SendFlags |= 1;
 678         }
 679         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 680         {
 681                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 682                 self.SendFlags |= 1;
 683         }
 684         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 685         {
 686                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 687                 self.SendFlags |= 1;
 688         }
 689         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 690         {
 691                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 692                 self.SendFlags |= 1;
 693         }
 694 }
 695
 696 void ClientInit_Spawn()
 697 {SELFPARAM();
 698
 699         entity e = new(clientinit);
 700         make_pure(e);
 701         e.think = ClientInit_CheckUpdate;
 702         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 703
 704         WITH(entity, self, e, ClientInit_CheckUpdate());
 705 }
 706
 707 /*
 708 =============
 709 SetNewParms
 710 =============
 711 */
 712 void SetNewParms (void)
 713 {
 714         // initialize parms for a new player
 715         parm1 = -(86400 * 366);
 716
 717         MUTATOR_CALLHOOK(SetNewParms);
 718 }
 719
 720 /*
 721 =============
 722 SetChangeParms
 723 =============
 724 */
 725 void SetChangeParms (void)
 726 {SELFPARAM();
 727         // save parms for level change
 728         parm1 = self.parm_idlesince - time;
 729
 730         MUTATOR_CALLHOOK(SetChangeParms);
 731 }
 732
 733 /*
 734 =============
 735 DecodeLevelParms
 736 =============
 737 */
 738 void DecodeLevelParms (void)
 739 {SELFPARAM();
 740         // load parms
 741         self.parm_idlesince = parm1;
 742         if(self.parm_idlesince == -(86400 * 366))
 743                 self.parm_idlesince = time;
 744
 745         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 746         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 747
 748         MUTATOR_CALLHOOK(DecodeLevelParms);
 749 }
 750
 751 /*
 752 =============
 753 ClientKill
 754
 755 Called when a client types 'kill' in the console
 756 =============
 757 */
 758
 759 .float clientkill_nexttime;
 760 void ClientKill_Now_TeamChange()
 761 {SELFPARAM();
 762         if(self.killindicator_teamchange == -1)
 763         {
 764                 JoinBestTeam( self, false, true );
 765         }
 766         else if(self.killindicator_teamchange == -2)
 767         {
 768                 if(blockSpectators)
 769                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 770                 PutObserverInServer();
 771         }
 772         else
 773                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 774         self.killindicator_teamchange = 0;
 775 }
 776
 777 void ClientKill_Now()
 778 {SELFPARAM();
 779         if(self.vehicle)
 780         {
 781             vehicles_exit(VHEF_RELEASE);
 782             if(!self.killindicator_teamchange)
 783             {
 784             self.vehicle_health = -1;
 785             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 786             }
 787         }
 788
 789         if(self.killindicator && !wasfreed(self.killindicator))
 790                 remove(self.killindicator);
 791
 792         self.killindicator = world;
 793
 794         if(self.killindicator_teamchange)
 795                 ClientKill_Now_TeamChange();
 796
 797         if(IS_PLAYER(self))
 798                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 799
 800         // now I am sure the player IS dead
 801 }
 802 void KillIndicator_Think()
 803 {SELFPARAM();
 804         if (gameover)
 805         {
 806                 self.owner.killindicator = world;
 807                 remove(self);
 808                 return;
 809         }
 810
 811         if (self.owner.alpha < 0 && !self.owner.vehicle)
 812         {
 813                 self.owner.killindicator = world;
 814                 remove(self);
 815                 return;
 816         }
 817
 818         if(self.cnt <= 0)
 819         {
 820                 WITH(entity, self, self.owner, ClientKill_Now());
 821                 return;
 822         }
 823     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 824     {
 825         self.nextthink = time + 1;
 826         self.cnt -= 1;
 827     }
 828         else
 829         {
 830                 if(self.cnt <= 10)
 831                         setmodel(self, MDL_NUM(self.cnt));
 832                 if(IS_REAL_CLIENT(self.owner))
 833                 {
 834                         if(self.cnt <= 10)
 835                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 836                 }
 837                 self.nextthink = time + 1;
 838                 self.cnt -= 1;
 839         }
 840 }
 841
 842 float clientkilltime;
 843 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 844 {SELFPARAM();
 845         float killtime;
 846         float starttime;
 847         entity e;
 848
 849         if (gameover)
 850                 return;
 851
 852         killtime = autocvar_g_balance_kill_delay;
 853
 854         if(g_race_qualifying || g_cts)
 855                 killtime = 0;
 856
 857     if(MUTATOR_CALLHOOK(ClientKill, self, killtime))
 858         return;
 859
 860         self.killindicator_teamchange = targetteam;
 861
 862     if(!self.killindicator)
 863         {
 864                 if(self.deadflag == DEAD_NO)
 865                 {
 866                         killtime = max(killtime, self.clientkill_nexttime - time);
 867                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 868                 }
 869
 870                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 871                 {
 872                         ClientKill_Now();
 873                 }
 874                 else
 875                 {
 876                         starttime = max(time, clientkilltime);
 877
 878                         self.killindicator = spawn();
 879                         self.killindicator.owner = self;
 880                         self.killindicator.scale = 0.5;
 881                         setattachment(self.killindicator, self, "");
 882                         setorigin(self.killindicator, '0 0 52');
 883                         self.killindicator.think = KillIndicator_Think;
 884                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 885                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 886                         self.killindicator.cnt = ceil(killtime);
 887                         self.killindicator.count = bound(0, ceil(killtime), 10);
 888                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 889
 890                         for(e = world; (e = find(e, classname, "body")) != world; )
 891                         {
 892                                 if(e.enemy != self)
 893                                         continue;
 894                                 e.killindicator = spawn();
 895                                 e.killindicator.owner = e;
 896                                 e.killindicator.scale = 0.5;
 897                                 setattachment(e.killindicator, e, "");
 898                                 setorigin(e.killindicator, '0 0 52');
 899                                 e.killindicator.think = KillIndicator_Think;
 900                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 901                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 902                                 e.killindicator.cnt = ceil(killtime);
 903                         }
 904                         self.lip = 0;
 905                 }
 906         }
 907         if(self.killindicator)
 908         {
 909                 if(targetteam == 0) // just die
 910                 {
 911                         self.killindicator.colormod = '0 0 0';
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 915                 }
 916                 else if(targetteam == -1) // auto
 917                 {
 918                         self.killindicator.colormod = '0 1 0';
 919                         if(IS_REAL_CLIENT(self))
 920                         if(self.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 922                 }
 923                 else if(targetteam == -2) // spectate
 924                 {
 925                         self.killindicator.colormod = '0.5 0.5 0.5';
 926                         if(IS_REAL_CLIENT(self))
 927                         if(self.killindicator.cnt > 0)
 928                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 929                 }
 930                 else
 931                 {
 932                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 933                         if(IS_REAL_CLIENT(self))
 934                         if(self.killindicator.cnt > 0)
 935                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 936                 }
 937         }
 938
 939 }
 940
 941 void ClientKill (void)
 942 {SELFPARAM();
 943         if(gameover) return;
 944         if(self.player_blocked) return;
 945         if(self.frozen) return;
 946
 947         ClientKill_TeamChange(0);
 948 }
 949
 950 void FixClientCvars(entity e)
 951 {
 952         // send prediction settings to the client
 953         stuffcmd(e, "\nin_bindmap 0 0\n");
 954         if(autocvar_g_antilag == 3) // client side hitscan
 955                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 956         if(autocvar_sv_gentle)
 957                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 958 }
 959
 960 float PlayerInIDList(entity p, string idlist)
 961 {
 962         float n, i;
 963         string s;
 964
 965         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 966         if (!p.crypto_idfp)
 967                 return 0;
 968
 969         // this function allows abbreviated player IDs too!
 970         n = tokenize_console(idlist);
 971         for(i = 0; i < n; ++i)
 972         {
 973                 s = argv(i);
 974                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 975                         return 1;
 976         }
 977
 978         return 0;
 979 }
 980
 981 #ifdef DP_EXT_PRECONNECT
 982 /*
 983 =============
 984 ClientPreConnect
 985
 986 Called once (not at each match start) when a client begins a connection to the server
 987 =============
 988 */
 989 void ClientPreConnect (void)
 990 {SELFPARAM();
 991         if(autocvar_sv_eventlog)
 992         {
 993                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 994                         self.playerid,
 995                         num_for_edict(self),
 996                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
 997                 ));
 998         }
 999 }
1000 #endif
1001
1002 /*
1003 =============
1004 ClientConnect
1005
1006 Called when a client connects to the server
1007 =============
1008 */
1009 void DecodeLevelParms (void);
1010 void ClientConnect (void)
1011 {SELFPARAM();
1012         float t;
1013
1014         if(IS_CLIENT(self))
1015         {
1016                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1017                 return;
1018         }
1019
1020         if(Ban_MaybeEnforceBanOnce(self))
1021                 return;
1022
1023         DecodeLevelParms();
1024
1025 #ifdef WATERMARK
1026         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1027 #endif
1028
1029         self.classname = "player_joining";
1030
1031         self.flags = FL_CLIENT;
1032         self.version_nagtime = time + 10 + random() * 10;
1033
1034         if(player_count<0)
1035         {
1036                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1037                 player_count = 0;
1038         }
1039
1040         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1041
1042         PlayerScore_Attach(self);
1043         ClientData_Attach();
1044         accuracy_init(self);
1045         Inventory_new(self);
1046
1047         bot_clientconnect();
1048
1049         playerdemo_init();
1050
1051         anticheat_init();
1052
1053         // identify the right forced team
1054         if(autocvar_g_campaign)
1055         {
1056                 if(IS_REAL_CLIENT(self)) // only players, not bots
1057                 {
1058                         switch(autocvar_g_campaign_forceteam)
1059                         {
1060                                 case 1: self.team_forced = NUM_TEAM_1; break;
1061                                 case 2: self.team_forced = NUM_TEAM_2; break;
1062                                 case 3: self.team_forced = NUM_TEAM_3; break;
1063                                 case 4: self.team_forced = NUM_TEAM_4; break;
1064                                 default: self.team_forced = 0;
1065                         }
1066                 }
1067         }
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1069                 self.team_forced = NUM_TEAM_1;
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1071                 self.team_forced = NUM_TEAM_2;
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1073                 self.team_forced = NUM_TEAM_3;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1075                 self.team_forced = NUM_TEAM_4;
1076         else if(autocvar_g_forced_team_otherwise == "red")
1077                 self.team_forced = NUM_TEAM_1;
1078         else if(autocvar_g_forced_team_otherwise == "blue")
1079                 self.team_forced = NUM_TEAM_2;
1080         else if(autocvar_g_forced_team_otherwise == "yellow")
1081                 self.team_forced = NUM_TEAM_3;
1082         else if(autocvar_g_forced_team_otherwise == "pink")
1083                 self.team_forced = NUM_TEAM_4;
1084         else if(autocvar_g_forced_team_otherwise == "spectate")
1085                 self.team_forced = -1;
1086         else if(autocvar_g_forced_team_otherwise == "spectator")
1087                 self.team_forced = -1;
1088         else
1089                 self.team_forced = 0;
1090
1091         if(!teamplay)
1092                 if(self.team_forced > 0)
1093                         self.team_forced = 0;
1094
1095         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1096
1097         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1098                 self.classname = STR_OBSERVER;
1099         } else {
1100                 if(teamplay)
1101                 {
1102                         if(autocvar_g_balance_teams)
1103                         {
1104                                 self.classname = STR_PLAYER;
1105                                 campaign_bots_may_start = 1;
1106                         }
1107                         else
1108                         {
1109                                 self.classname = STR_OBSERVER; // do it anyway
1110                         }
1111                 }
1112                 else
1113                 {
1114                         self.classname = STR_PLAYER;
1115                         campaign_bots_may_start = 1;
1116                 }
1117         }
1118
1119         self.playerid = (playerid_last = playerid_last + 1);
1120
1121         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1122
1123     if(IS_BOT_CLIENT(self))
1124         PlayerStats_GameReport_AddPlayer(self);
1125
1126         if(autocvar_sv_eventlog)
1127                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1128
1129         LogTeamchange(self.playerid, self.team, 1);
1130
1131         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1132
1133         self.netname_previous = strzone(self.netname);
1134
1135         if(IS_PLAYER(self) && teamplay)
1136                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1137         else
1138                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1139
1140         stuffcmd(self, strcat(clientstuff, "\n"));
1141         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1142
1143         FixClientCvars(self);
1144
1145         // spawnfunc_waypoint sprites
1146         WaypointSprite_InitClient(self);
1147
1148         // Wazat's grappling hook
1149         SetGrappleHookBindings();
1150
1151         // Jetpack binds
1152         stuffcmd(self, "alias +jetpack +button10\n");
1153         stuffcmd(self, "alias -jetpack -button10\n");
1154
1155         // get version info from player
1156         stuffcmd(self, "cmd clientversion $gameversion\n");
1157
1158         // get other cvars from player
1159         GetCvars(0);
1160
1161         // notify about available teams
1162         if(teamplay)
1163         {
1164                 CheckAllowedTeams(self);
1165                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1166                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1167         }
1168         else
1169                 stuffcmd(self, "set _teams_available 0\n");
1170
1171         attach_entcs(self);
1172
1173         bot_relinkplayerlist();
1174
1175         self.spectatortime = time;
1176         if(blockSpectators)
1177         {
1178                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1179         }
1180
1181         self.jointime = time;
1182         self.allowed_timeouts = autocvar_sv_timeout_number;
1183
1184         if(IS_REAL_CLIENT(self))
1185         {
1186                 if(!autocvar_g_campaign)
1187                 {
1188                         self.motd_actived_time = -1;
1189                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1190                 }
1191
1192                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1193                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1194         }
1195
1196         if(!sv_foginterval && world.fog != "")
1197                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1198
1199         W_HitPlotOpen(self);
1200
1201         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1202                 send_CSQC_teamnagger();
1203
1204         CheatInitClient();
1205
1206         CSQCMODEL_AUTOINIT(self);
1207
1208         self.model_randomizer = random();
1209
1210         if(IS_REAL_CLIENT(self))
1211                 sv_notice_join();
1212
1213         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1214                 WITH(entity, self, e, e.init_for_player(this));
1215         }
1216
1217         MUTATOR_CALLHOOK(ClientConnect, self);
1218 }
1219 /*
1220 =============
1221 ClientDisconnect
1222
1223 Called when a client disconnects from the server
1224 =============
1225 */
1226 .entity chatbubbleentity;
1227 void ReadyCount();
1228 void ClientDisconnect (void)
1229 {SELFPARAM();
1230         if(self.vehicle)
1231             vehicles_exit(VHEF_RELEASE);
1232
1233         if (!IS_CLIENT(self))
1234         {
1235                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1236                 return;
1237         }
1238
1239         PlayerStats_GameReport_FinalizePlayer(self);
1240
1241         if ( self.active_minigame )
1242                 part_minigame(self);
1243
1244         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1245
1246         CheatShutdownClient();
1247
1248         W_HitPlotClose(self);
1249
1250         anticheat_report();
1251         anticheat_shutdown();
1252
1253         playerdemo_shutdown();
1254
1255         bot_clientdisconnect();
1256
1257         detach_entcs(self);
1258
1259         if(autocvar_sv_eventlog)
1260                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1261
1262         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1263
1264         MUTATOR_CALLHOOK(ClientDisconnect);
1265
1266         Portal_ClearAll(self);
1267
1268         Unfreeze(self);
1269
1270         RemoveGrapplingHook(self);
1271
1272         // Here, everything has been done that requires this player to be a client.
1273
1274         self.flags &= ~FL_CLIENT;
1275
1276         if (self.chatbubbleentity)
1277                 remove (self.chatbubbleentity);
1278
1279         if (self.killindicator)
1280                 remove (self.killindicator);
1281
1282         WaypointSprite_PlayerGone();
1283
1284         bot_relinkplayerlist();
1285
1286         accuracy_free(self);
1287         Inventory_delete(self);
1288         ClientData_Detach();
1289         PlayerScore_Detach(self);
1290
1291         if(self.netname_previous)
1292                 strunzone(self.netname_previous);
1293         if(self.clientstatus)
1294                 strunzone(self.clientstatus);
1295         if(self.weaponorder_byimpulse)
1296                 strunzone(self.weaponorder_byimpulse);
1297
1298         ClearPlayerSounds();
1299
1300         if(self.personal)
1301                 remove(self.personal);
1302
1303         self.playerid = 0;
1304         ReadyCount();
1305
1306         // free cvars
1307         GetCvars(-1);
1308 }
1309
1310 .float BUTTON_CHAT;
1311 void ChatBubbleThink()
1312 {SELFPARAM();
1313         self.nextthink = time;
1314         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1315         {
1316                 if(self.owner) // but why can that ever be world?
1317                         self.owner.chatbubbleentity = world;
1318                 remove(self);
1319                 return;
1320         }
1321
1322         self.mdl = "";
1323
1324         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1325         {
1326                 if ( self.owner.active_minigame )
1327                         self.mdl = "models/sprites/minigame_busy.iqm";
1328                 else if ( self.owner.BUTTON_CHAT )
1329                         self.mdl = "models/misc/chatbubble.spr";
1330         }
1331
1332         if ( self.model != self.mdl )
1333                 _setmodel(self, self.mdl);
1334
1335 }
1336
1337 void UpdateChatBubble()
1338 {SELFPARAM();
1339         if (self.alpha < 0)
1340                 return;
1341         // spawn a chatbubble entity if needed
1342         if (!self.chatbubbleentity)
1343         {
1344                 self.chatbubbleentity = new(chatbubbleentity);
1345                 self.chatbubbleentity.owner = self;
1346                 self.chatbubbleentity.exteriormodeltoclient = self;
1347                 self.chatbubbleentity.think = ChatBubbleThink;
1348                 self.chatbubbleentity.nextthink = time;
1349                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1350                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1351                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1352                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1353                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1354                 //self.chatbubbleentity.model = "";
1355                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1356         }
1357 }
1358
1359
1360 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1361 // added to the model skins
1362 /*void UpdateColorModHack()
1363 {
1364         float c;
1365         c = self.clientcolors & 15;
1366         // LordHavoc: only bothering to support white, green, red, yellow, blue
1367              if (!teamplay) self.colormod = '0 0 0';
1368         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1369         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1370         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1371         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1372         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1373         else self.colormod = '1 1 1';
1374 }*/
1375
1376 void respawn(void)
1377 {SELFPARAM();
1378         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1379         {
1380                 self.solid = SOLID_NOT;
1381                 self.takedamage = DAMAGE_NO;
1382                 self.movetype = MOVETYPE_FLY;
1383                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1384                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1385                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1386                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1387                 if(autocvar_g_respawn_ghosts_maxtime)
1388                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1389         }
1390
1391         CopyBody(1);
1392
1393         self.effects |= EF_NODRAW; // prevent another CopyBody
1394         PutClientInServer();
1395 }
1396
1397 void play_countdown(float finished, string samp)
1398 {SELFPARAM();
1399         if(IS_REAL_CLIENT(self))
1400                 if(floor(finished - time - frametime) != floor(finished - time))
1401                         if(finished - time < 6)
1402                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1403 }
1404
1405 void player_powerups (void)
1406 {SELFPARAM();
1407         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1408         int items_prev = self.items;
1409
1410         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1411                 self.modelflags |= MF_ROCKET;
1412         else
1413                 self.modelflags &= ~MF_ROCKET;
1414
1415         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1416
1417         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1418                 return;
1419
1420         Fire_ApplyDamage(self);
1421         Fire_ApplyEffect(self);
1422
1423         if (!g_instagib)
1424         {
1425                 if (self.items & ITEM_Strength.m_itemid)
1426                 {
1427                         play_countdown(self.strength_finished, SND(POWEROFF));
1428                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1429                         if (time > self.strength_finished)
1430                         {
1431                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1432                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1433                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1434                         }
1435                 }
1436                 else
1437                 {
1438                         if (time < self.strength_finished)
1439                         {
1440                                 self.items = self.items | ITEM_Strength.m_itemid;
1441                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1442                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1443                         }
1444                 }
1445                 if (self.items & ITEM_Shield.m_itemid)
1446                 {
1447                         play_countdown(self.invincible_finished, SND(POWEROFF));
1448                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1449                         if (time > self.invincible_finished)
1450                         {
1451                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1452                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1453                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1454                         }
1455                 }
1456                 else
1457                 {
1458                         if (time < self.invincible_finished)
1459                         {
1460                                 self.items = self.items | ITEM_Shield.m_itemid;
1461                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1462                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1463                         }
1464                 }
1465                 if (self.items & IT_SUPERWEAPON)
1466                 {
1467                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1468                         {
1469                                 self.superweapons_finished = 0;
1470                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1471                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1472                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1473                         }
1474                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1475                         {
1476                                 // don't let them run out
1477                         }
1478                         else
1479                         {
1480                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1481                                 if (time > self.superweapons_finished)
1482                                 {
1483                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1484                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1485                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1486                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1487                                 }
1488                         }
1489                 }
1490                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1491                 {
1492                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1493                         {
1494                                 self.items = self.items | IT_SUPERWEAPON;
1495                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1496                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1497                         }
1498                         else
1499                         {
1500                                 self.superweapons_finished = 0;
1501                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1502                         }
1503                 }
1504                 else
1505                 {
1506                         self.superweapons_finished = 0;
1507                 }
1508         }
1509
1510         if(autocvar_g_nodepthtestplayers)
1511                 self.effects = self.effects | EF_NODEPTHTEST;
1512
1513         if(autocvar_g_fullbrightplayers)
1514                 self.effects = self.effects | EF_FULLBRIGHT;
1515
1516         if (time >= game_starttime)
1517         if (time < self.spawnshieldtime)
1518                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1519
1520         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1521 }
1522
1523 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1524 {
1525         if(current > stable)
1526                 return current;
1527         else if(current > stable - 0.25) // when close enough, "snap"
1528                 return stable;
1529         else
1530                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1531 }
1532
1533 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1534 {
1535         if(current < stable)
1536                 return current;
1537         else if(current < stable + 0.25) // when close enough, "snap"
1538                 return stable;
1539         else
1540                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1541 }
1542
1543 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1544 {
1545         if(current > rotstable)
1546         {
1547                 if(rotframetime > 0)
1548                 {
1549                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1550                         current = max(rotstable, current - rotlinear * rotframetime);
1551                 }
1552         }
1553         else if(current < regenstable)
1554         {
1555                 if(regenframetime > 0)
1556                 {
1557                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1558                         current = min(regenstable, current + regenlinear * regenframetime);
1559                 }
1560         }
1561
1562         if(current > limit)
1563                 current = limit;
1564
1565         return current;
1566 }
1567
1568 void player_regen (void)
1569 {SELFPARAM();
1570         float max_mod, regen_mod, rot_mod, limit_mod;
1571         max_mod = regen_mod = rot_mod = limit_mod = 1;
1572         regen_mod_max = max_mod;
1573         regen_mod_regen = regen_mod;
1574         regen_mod_rot = rot_mod;
1575         regen_mod_limit = limit_mod;
1576
1577         regen_health = autocvar_g_balance_health_regen;
1578         regen_health_linear = autocvar_g_balance_health_regenlinear;
1579         regen_health_rot = autocvar_g_balance_health_rot;
1580         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1581         regen_health_stable = autocvar_g_balance_health_regenstable;
1582         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1583         if(!MUTATOR_CALLHOOK(PlayerRegen))
1584         if(!self.frozen)
1585         {
1586                 float mina, maxa, limith, limita;
1587                 maxa = autocvar_g_balance_armor_rotstable;
1588                 mina = autocvar_g_balance_armor_regenstable;
1589                 limith = autocvar_g_balance_health_limit;
1590                 limita = autocvar_g_balance_armor_limit;
1591
1592                 max_mod = regen_mod_max;
1593                 regen_mod = regen_mod_regen;
1594                 rot_mod = regen_mod_rot;
1595                 limit_mod = regen_mod_limit;
1596
1597                 regen_health_rotstable = regen_health_rotstable * max_mod;
1598                 regen_health_stable = regen_health_stable * max_mod;
1599                 limith = limith * limit_mod;
1600                 limita = limita * limit_mod;
1601
1602                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1603                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1604         }
1605
1606         // if player rotted to death...  die!
1607         // check this outside above checks, as player may still be able to rot to death
1608         if(self.health < 1)
1609         {
1610                 if(self.vehicle)
1611                         vehicles_exit(VHEF_RELEASE);
1612                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1613         }
1614
1615         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1616         {
1617                 float minf, maxf, limitf;
1618
1619                 maxf = autocvar_g_balance_fuel_rotstable;
1620                 minf = autocvar_g_balance_fuel_regenstable;
1621                 limitf = autocvar_g_balance_fuel_limit;
1622
1623                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1624         }
1625 }
1626
1627 float zoomstate_set;
1628 void SetZoomState(float z)
1629 {SELFPARAM();
1630         if(z != self.zoomstate)
1631         {
1632                 self.zoomstate = z;
1633                 ClientData_Touch(self);
1634         }
1635         zoomstate_set = 1;
1636 }
1637
1638 void GetPressedKeys()
1639 {SELFPARAM();
1640         MUTATOR_CALLHOOK(GetPressedKeys);
1641         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1642         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1643         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1644         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1645         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1646
1647         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1648         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1649         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1650         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1651         #undef X
1652 }
1653
1654 /*
1655 ======================
1656 spectate mode routines
1657 ======================
1658 */
1659
1660 void SpectateCopy(entity spectatee)
1661 {SELFPARAM();
1662         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1663         self.armortype = spectatee.armortype;
1664         self.armorvalue = spectatee.armorvalue;
1665         self.ammo_cells = spectatee.ammo_cells;
1666         self.ammo_plasma = spectatee.ammo_plasma;
1667         self.ammo_shells = spectatee.ammo_shells;
1668         self.ammo_nails = spectatee.ammo_nails;
1669         self.ammo_rockets = spectatee.ammo_rockets;
1670         self.ammo_fuel = spectatee.ammo_fuel;
1671         self.clip_load = spectatee.clip_load;
1672         self.clip_size = spectatee.clip_size;
1673         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1674         self.health = spectatee.health;
1675         self.impulse = 0;
1676         self.items = spectatee.items;
1677         self.last_pickup = spectatee.last_pickup;
1678         self.hit_time = spectatee.hit_time;
1679         self.strength_finished = spectatee.strength_finished;
1680         self.invincible_finished = spectatee.invincible_finished;
1681         self.pressedkeys = spectatee.pressedkeys;
1682         self.weapons = spectatee.weapons;
1683         self.switchweapon = spectatee.switchweapon;
1684         self.switchingweapon = spectatee.switchingweapon;
1685         self.weapon = spectatee.weapon;
1686         self.vortex_charge = spectatee.vortex_charge;
1687         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1688         self.hagar_load = spectatee.hagar_load;
1689         self.arc_heat_percent = spectatee.arc_heat_percent;
1690         self.minelayer_mines = spectatee.minelayer_mines;
1691         self.punchangle = spectatee.punchangle;
1692         self.view_ofs = spectatee.view_ofs;
1693         self.velocity = spectatee.velocity;
1694         self.dmg_take = spectatee.dmg_take;
1695         self.dmg_save = spectatee.dmg_save;
1696         self.dmg_inflictor = spectatee.dmg_inflictor;
1697         self.v_angle = spectatee.v_angle;
1698         self.angles = spectatee.v_angle;
1699         self.frozen = spectatee.frozen;
1700         self.revive_progress = spectatee.revive_progress;
1701         if(!self.BUTTON_USE)
1702                 self.fixangle = true;
1703         setorigin(self, spectatee.origin);
1704         setsize(self, spectatee.mins, spectatee.maxs);
1705         SetZoomState(spectatee.zoomstate);
1706
1707     anticheat_spectatecopy(spectatee);
1708         self.hud = spectatee.hud;
1709         if(spectatee.vehicle)
1710     {
1711         self.fixangle = false;
1712         //self.velocity = spectatee.vehicle.velocity;
1713         self.vehicle_health = spectatee.vehicle_health;
1714         self.vehicle_shield = spectatee.vehicle_shield;
1715         self.vehicle_energy = spectatee.vehicle_energy;
1716         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1717         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1718         self.vehicle_reload1 = spectatee.vehicle_reload1;
1719         self.vehicle_reload2 = spectatee.vehicle_reload2;
1720
1721         msg_entity = self;
1722
1723         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1724             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1725             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1726             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1727
1728         //WriteByte (MSG_ONE, SVC_SETVIEW);
1729         //    WriteEntity(MSG_ONE, self);
1730         //makevectors(spectatee.v_angle);
1731         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1732     }
1733 }
1734
1735 bool SpectateUpdate()
1736 {SELFPARAM();
1737         if(!self.enemy)
1738             return false;
1739
1740         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1741         {
1742                 SetSpectatee(self, NULL);
1743                 return false;
1744         }
1745
1746         SpectateCopy(self.enemy);
1747
1748         return true;
1749 }
1750
1751 bool SpectateSet()
1752 {SELFPARAM();
1753         if(!IS_PLAYER(self.enemy))
1754                 return false;
1755
1756         msg_entity = self;
1757         WriteByte(MSG_ONE, SVC_SETVIEW);
1758         WriteEntity(MSG_ONE, self.enemy);
1759         self.movetype = MOVETYPE_NONE;
1760         accuracy_resend(self);
1761
1762         if(!SpectateUpdate())
1763                 PutObserverInServer();
1764
1765         return true;
1766 }
1767
1768 void SetSpectatee(entity player, entity spectatee)
1769 {
1770         entity old_spectatee = player.enemy;
1771
1772         player.enemy = spectatee;
1773
1774         // WEAPONTODO
1775         // these are required to fix the spectator bug with arc
1776         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1777         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1778 }
1779
1780 bool Spectate(entity pl)
1781 {SELFPARAM();
1782         if(MUTATOR_CALLHOOK(SpectateSet, self, pl))
1783                 return false;
1784         pl = spec_player;
1785
1786         SetSpectatee(self, pl);
1787         return SpectateSet();
1788 }
1789
1790 bool SpectateNext()
1791 {SELFPARAM();
1792         other = find(self.enemy, classname, "player");
1793
1794         if (MUTATOR_CALLHOOK(SpectateNext, self, other))
1795                 other = spec_player;
1796         else if (!other)
1797                 other = find(other, classname, "player");
1798
1799         if(other) { SetSpectatee(self, other); }
1800
1801         return SpectateSet();
1802 }
1803
1804 bool SpectatePrev()
1805 {SELFPARAM();
1806         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1807         other = findchain(classname, "player");
1808         if (!other) // no player
1809                 return false;
1810
1811         entity first = other;
1812         // skip players until current spectated player
1813         if(self.enemy)
1814         while(other && other != self.enemy)
1815                 other = other.chain;
1816
1817         switch (MUTATOR_CALLHOOK(SpectatePrev, self, other, first))
1818         {
1819                 case MUT_SPECPREV_FOUND:
1820                     other = spec_player;
1821                     break;
1822                 case MUT_SPECPREV_RETURN:
1823                     other = spec_player;
1824                     return true;
1825                 case MUT_SPECPREV_CONTINUE:
1826                 default:
1827                 {
1828                         if(other.chain)
1829                                 other = other.chain;
1830                         else
1831                                 other = first;
1832                         break;
1833                 }
1834         }
1835
1836         SetSpectatee(self, other);
1837         return SpectateSet();
1838 }
1839
1840 /*
1841 =============
1842 ShowRespawnCountdown()
1843
1844 Update a respawn countdown display.
1845 =============
1846 */
1847 void ShowRespawnCountdown()
1848 {SELFPARAM();
1849         float number;
1850         if(self.deadflag == DEAD_NO) // just respawned?
1851                 return;
1852         else
1853         {
1854                 number = ceil(self.respawn_time - time);
1855                 if(number <= 0)
1856                         return;
1857                 if(number <= self.respawn_countdown)
1858                 {
1859                         self.respawn_countdown = number - 1;
1860                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1861                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1862                 }
1863         }
1864 }
1865
1866 void LeaveSpectatorMode()
1867 {SELFPARAM();
1868         if(self.caplayer)
1869                 return;
1870         if(nJoinAllowed(self))
1871         {
1872                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1873                 {
1874                         self.classname = STR_PLAYER;
1875                         nades_RemoveBonus(self);
1876
1877                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1878                                 { JoinBestTeam(self, false, true); }
1879
1880                         if(autocvar_g_campaign)
1881                                 { campaign_bots_may_start = 1; }
1882
1883                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1884
1885                         PutClientInServer();
1886
1887                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1888                 }
1889                 else
1890                         stuffcmd(self, "menu_showteamselect\n");
1891         }
1892         else
1893         {
1894                 // Player may not join because g_maxplayers is set
1895                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1896         }
1897 }
1898
1899 /**
1900  * Determines whether the player is allowed to join. This depends on cvar
1901  * g_maxplayers, if it isn't used this function always return true, otherwise
1902  * it checks whether the number of currently playing players exceeds g_maxplayers.
1903  * @return int number of free slots for players, 0 if none
1904  */
1905 float nJoinAllowed(entity ignore)
1906 {SELFPARAM();
1907         if(!ignore)
1908         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1909         // so report 0 free slots if restricted
1910         {
1911                 if(autocvar_g_forced_team_otherwise == "spectate")
1912                         return 0;
1913                 if(autocvar_g_forced_team_otherwise == "spectator")
1914                         return 0;
1915         }
1916
1917         if(self.team_forced < 0)
1918                 return 0; // forced spectators can never join
1919
1920         // TODO simplify this
1921         entity e;
1922         float totalClients = 0;
1923         FOR_EACH_CLIENT(e)
1924                 if(e != ignore)
1925                         totalClients += 1;
1926
1927         if (!autocvar_g_maxplayers)
1928                 return maxclients - totalClients;
1929
1930         float currentlyPlaying = 0;
1931         FOR_EACH_REALCLIENT(e)
1932                 if(IS_PLAYER(e) || e.caplayer)
1933                         currentlyPlaying += 1;
1934
1935         if(currentlyPlaying < autocvar_g_maxplayers)
1936                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1937
1938         return 0;
1939 }
1940
1941 /**
1942  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1943  * g_maxplayers_spectator_blocktime seconds
1944  */
1945 void checkSpectatorBlock()
1946 {SELFPARAM();
1947         if(IS_SPEC(self) || IS_OBSERVER(self))
1948         if(!self.caplayer)
1949         if(IS_REAL_CLIENT(self))
1950         {
1951                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1952                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1953                         dropclient(self);
1954                 }
1955         }
1956 }
1957
1958 void PrintWelcomeMessage()
1959 {SELFPARAM();
1960         if(self.motd_actived_time == 0)
1961         {
1962                 if (autocvar_g_campaign) {
1963                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1964                                 self.motd_actived_time = time;
1965                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1966                         }
1967                 } else {
1968                         if (self.BUTTON_INFO) {
1969                                 self.motd_actived_time = time;
1970                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1971                         }
1972                 }
1973         }
1974         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1975         {
1976                 if (autocvar_g_campaign) {
1977                         if (self.BUTTON_INFO)
1978                                 self.motd_actived_time = time;
1979                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
1980                                 self.motd_actived_time = 0;
1981                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1982                         }
1983                 } else {
1984                         if (self.BUTTON_INFO)
1985                                 self.motd_actived_time = time;
1986                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1987                                 self.motd_actived_time = 0;
1988                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
1989                         }
1990                 }
1991         }
1992         else //if(self.motd_actived_time < 0) // just connected, motd is active
1993         {
1994                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
1995                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1996                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
1997                 {
1998                         // instanctly hide MOTD
1999                         self.motd_actived_time = 0;
2000                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2001                 }
2002         }
2003 }
2004
2005 void ObserverThink()
2006 {SELFPARAM();
2007         if ( self.impulse )
2008         {
2009                 MinigameImpulse(self.impulse);
2010                 self.impulse = 0;
2011         }
2012         float prefered_movetype;
2013         if (self.flags & FL_JUMPRELEASED) {
2014                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2015                         self.flags &= ~FL_JUMPRELEASED;
2016                         self.flags |= FL_SPAWNING;
2017                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2018                         self.flags &= ~FL_JUMPRELEASED;
2019                         if(SpectateNext()) {
2020                                 self.classname = STR_SPECTATOR;
2021                         }
2022                 } else {
2023                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2024                         if (self.movetype != prefered_movetype)
2025                                 self.movetype = prefered_movetype;
2026                 }
2027         } else {
2028                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2029                         self.flags |= FL_JUMPRELEASED;
2030                         if(self.flags & FL_SPAWNING)
2031                         {
2032                                 self.flags &= ~FL_SPAWNING;
2033                                 LeaveSpectatorMode();
2034                                 return;
2035                         }
2036                 }
2037         }
2038 }
2039
2040 void SpectatorThink()
2041 {SELFPARAM();
2042         if ( self.impulse )
2043         {
2044                 if(MinigameImpulse(self.impulse))
2045                         self.impulse = 0;
2046         }
2047         if (self.flags & FL_JUMPRELEASED) {
2048                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2049                         self.flags &= ~FL_JUMPRELEASED;
2050                         self.flags |= FL_SPAWNING;
2051                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2052                         self.flags &= ~FL_JUMPRELEASED;
2053                         if(SpectateNext()) {
2054                                 self.classname = STR_SPECTATOR;
2055                         } else {
2056                                 self.classname = STR_OBSERVER;
2057                                 PutClientInServer();
2058                         }
2059                         self.impulse = 0;
2060                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2061                         self.flags &= ~FL_JUMPRELEASED;
2062                         if(SpectatePrev()) {
2063                                 self.classname = STR_SPECTATOR;
2064                         } else {
2065                                 self.classname = STR_OBSERVER;
2066                                 PutClientInServer();
2067                         }
2068                         self.impulse = 0;
2069                 } else if (self.BUTTON_ATCK2) {
2070                         self.flags &= ~FL_JUMPRELEASED;
2071                         self.classname = STR_OBSERVER;
2072                         PutClientInServer();
2073                 } else {
2074                         if(!SpectateUpdate())
2075                                 PutObserverInServer();
2076                 }
2077         } else {
2078                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2079                         self.flags |= FL_JUMPRELEASED;
2080                         if(self.flags & FL_SPAWNING)
2081                         {
2082                                 self.flags &= ~FL_SPAWNING;
2083                                 LeaveSpectatorMode();
2084                                 return;
2085                         }
2086                 }
2087                 if(!SpectateUpdate())
2088                         PutObserverInServer();
2089         }
2090
2091         self.flags |= FL_CLIENT | FL_NOTARGET;
2092 }
2093
2094 void vehicles_enter (entity pl, entity veh);
2095 void PlayerUseKey()
2096 {SELFPARAM();
2097         if (!IS_PLAYER(self))
2098                 return;
2099
2100         if(self.vehicle)
2101         {
2102                 if(!gameover)
2103                 {
2104                         vehicles_exit(VHEF_NORMAL);
2105                         return;
2106                 }
2107         }
2108         else if(autocvar_g_vehicles_enter)
2109         {
2110                 if(!self.frozen)
2111                 if(self.deadflag == DEAD_NO)
2112                 if(!gameover)
2113                 {
2114                         entity head, closest_target = world;
2115                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2116
2117                         while(head) // find the closest acceptable target to enter
2118                         {
2119                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2120                                 if(head.deadflag == DEAD_NO)
2121                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2122                                 if(head.takedamage != DAMAGE_NO)
2123                                 {
2124                                         if(closest_target)
2125                                         {
2126                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2127                                                 { closest_target = head; }
2128                                         }
2129                                         else { closest_target = head; }
2130                                 }
2131
2132                                 head = head.chain;
2133                         }
2134
2135                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2136                 }
2137         }
2138
2139         // a use key was pressed; call handlers
2140         MUTATOR_CALLHOOK(PlayerUseKey);
2141 }
2142
2143 float isInvisibleString(string s)
2144 {
2145         float i, n, c;
2146         s = strdecolorize(s);
2147         for((i = 0), (n = strlen(s)); i < n; ++i)
2148         {
2149                 c = str2chr(s, i);
2150                 switch(c)
2151                 {
2152                         case 0:
2153                         case 32: // space
2154                                 break;
2155                         case 192: // charmap space
2156                                 if (!autocvar_utf8_enable)
2157                                         break;
2158                                 return false;
2159                         case 160: // space in unicode fonts
2160                         case 0xE000 + 192: // utf8 charmap space
2161                                 if (autocvar_utf8_enable)
2162                                         break;
2163                         default:
2164                                 return false;
2165                 }
2166         }
2167         return true;
2168 }
2169
2170 /*
2171 =============
2172 PlayerPreThink
2173
2174 Called every frame for each client before the physics are run
2175 =============
2176 */
2177 .float usekeypressed;
2178 void() nexball_setstatus;
2179 .float last_vehiclecheck;
2180 .int items_added;
2181 void PlayerPreThink (void)
2182 {SELFPARAM();
2183         WarpZone_PlayerPhysics_FixVAngle();
2184
2185         self.stat_game_starttime = game_starttime;
2186         self.stat_round_starttime = round_starttime;
2187         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2188         self.stat_leadlimit = autocvar_leadlimit;
2189
2190         self.weaponsinmap = weaponsInMap;
2191
2192         if(frametime)
2193         {
2194                 // physics frames: update anticheat stuff
2195                 anticheat_prethink();
2196         }
2197
2198         if(blockSpectators && frametime)
2199                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2200                 checkSpectatorBlock();
2201
2202         zoomstate_set = 0;
2203
2204         // Savage: Check for nameless players
2205         if (isInvisibleString(self.netname)) {
2206                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2207                 if(autocvar_sv_eventlog)
2208                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2209                 if(self.netname_previous)
2210                         strunzone(self.netname_previous);
2211                 self.netname_previous = strzone(new_name);
2212                 self.netname = self.netname_previous;
2213                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2214         } else if(self.netname_previous != self.netname) {
2215                 if(autocvar_sv_eventlog)
2216                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2217                 if(self.netname_previous)
2218                         strunzone(self.netname_previous);
2219                 self.netname_previous = strzone(self.netname);
2220         }
2221
2222         // version nagging
2223         if(self.version_nagtime)
2224                 if(self.cvar_g_xonoticversion)
2225                         if(time > self.version_nagtime)
2226                         {
2227                                 // don't notify git users
2228                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2229                                 {
2230                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2231                                         {
2232                                                 // notify release users if connecting to git
2233                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2234                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2235                                         }
2236                                         else
2237                                         {
2238                                                 float r;
2239                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2240                                                 if(r < 0)
2241                                                 {
2242                                                         // give users new version
2243                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2244                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2245                                                 }
2246                                                 else if(r > 0)
2247                                                 {
2248                                                         // notify users about old server version
2249                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2250                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2251                                                 }
2252                                         }
2253                                 }
2254                                 self.version_nagtime = 0;
2255                         }
2256
2257         // GOD MODE info
2258         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2259         {
2260                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2261                 self.max_armorvalue = 0;
2262         }
2263
2264         if(self.frozen == 2)
2265         {
2266                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2267                 self.health = max(1, self.revive_progress * start_health);
2268                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2269
2270                 if(self.revive_progress >= 1)
2271                         Unfreeze(self);
2272         }
2273         else if(self.frozen == 3)
2274         {
2275                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2276                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2277
2278                 if(self.health < 1)
2279                 {
2280                         if(self.vehicle)
2281                                 vehicles_exit(VHEF_RELEASE);
2282                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2283                 }
2284                 else if ( self.revive_progress <= 0 )
2285                         Unfreeze(self);
2286         }
2287
2288         MUTATOR_CALLHOOK(PlayerPreThink);
2289
2290         if(autocvar_g_vehicles_enter)
2291         if(time > self.last_vehiclecheck)
2292         if(IS_PLAYER(self))
2293         if(!gameover)
2294         if(!self.frozen)
2295         if(!self.vehicle)
2296         if(self.deadflag == DEAD_NO)
2297         {
2298                 entity veh;
2299                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2300                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2301                 if(veh.deadflag == DEAD_NO)
2302                 if(veh.takedamage != DAMAGE_NO)
2303                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2304                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2305                 else if(!veh.owner)
2306                 if(!veh.team || SAME_TEAM(self, veh))
2307                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2308                 else if(autocvar_g_vehicles_steal)
2309                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2310
2311                 self.last_vehiclecheck = time + 1;
2312         }
2313
2314         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2315         {
2316                 if(self.BUTTON_USE && !self.usekeypressed)
2317                         PlayerUseKey();
2318                 self.usekeypressed = self.BUTTON_USE;
2319         }
2320
2321         if(IS_REAL_CLIENT(self))
2322                 PrintWelcomeMessage();
2323
2324         if(IS_PLAYER(self))
2325         {
2326
2327                 CheckRules_Player();
2328
2329                 if (intermission_running)
2330                 {
2331                         IntermissionThink ();   // otherwise a button could be missed between
2332                         return;                                 // the think tics
2333                 }
2334
2335                 //don't allow the player to turn around while game is paused!
2336                 if(timeout_status == TIMEOUT_ACTIVE) {
2337                         // FIXME turn this into CSQC stuff
2338                         self.v_angle = self.lastV_angle;
2339                         self.angles = self.lastV_angle;
2340                         self.fixangle = true;
2341                 }
2342
2343                 if(frametime)
2344                 {
2345                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2346                         {
2347                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2348                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2349                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2350
2351                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2352                                 {
2353                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2354                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2355                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2356                                 }
2357                         }
2358                         else
2359                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2360
2361                         player_powerups();
2362                 }
2363
2364                 if (self.deadflag != DEAD_NO)
2365                 {
2366                         if(self.personal && g_race_qualifying)
2367                         {
2368                                 if(time > self.respawn_time)
2369                                 {
2370                                         self.respawn_time = time + 1; // only retry once a second
2371                                         self.stat_respawn_time = self.respawn_time;
2372                                         respawn();
2373                                         self.impulse = 141;
2374                                 }
2375                         }
2376                         else
2377                         {
2378                                 float button_pressed;
2379                                 if(frametime)
2380                                         player_anim();
2381                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2382
2383                                 if (self.deadflag == DEAD_DYING)
2384                                 {
2385                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2386                                                 self.deadflag = DEAD_RESPAWNING;
2387                                         else if(!button_pressed)
2388                                                 self.deadflag = DEAD_DEAD;
2389                                 }
2390                                 else if (self.deadflag == DEAD_DEAD)
2391                                 {
2392                                         if(button_pressed)
2393                                                 self.deadflag = DEAD_RESPAWNABLE;
2394                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2395                                                 self.deadflag = DEAD_RESPAWNING;
2396                                 }
2397                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2398                                 {
2399                                         if(!button_pressed)
2400                                                 self.deadflag = DEAD_RESPAWNING;
2401                                 }
2402                                 else if (self.deadflag == DEAD_RESPAWNING)
2403                                 {
2404                                         if(time > self.respawn_time)
2405                                         {
2406                                                 self.respawn_time = time + 1; // only retry once a second
2407                                                 self.respawn_time_max = self.respawn_time;
2408                                                 respawn();
2409                                         }
2410                                 }
2411
2412                                 ShowRespawnCountdown();
2413
2414                                 if(self.respawn_flags & RESPAWN_SILENT)
2415                                         self.stat_respawn_time = 0;
2416                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2417                                         self.stat_respawn_time = self.respawn_time_max;
2418                                 else
2419                                         self.stat_respawn_time = self.respawn_time;
2420                         }
2421
2422                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2423                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2424                                 self.stat_respawn_time *= -1;
2425
2426                         return;
2427                 }
2428
2429                 self.prevorigin = self.origin;
2430
2431                 float do_crouch = self.BUTTON_CROUCH;
2432                 if(self.hook.state)
2433                         do_crouch = 0;
2434                 if(self.vehicle)
2435                         do_crouch = 0;
2436                 if(self.frozen)
2437                         do_crouch = 0;
2438
2439                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2440                 // It cannot be predicted by the engine!
2441                 int slot = 0; // TODO: unhardcode
2442                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity[slot].wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2443                         do_crouch = 0;
2444
2445                 if (do_crouch)
2446                 {
2447                         if (!self.crouch)
2448                         {
2449                                 self.crouch = true;
2450                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2451                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2452                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2453                         }
2454                 }
2455                 else
2456                 {
2457                         if (self.crouch)
2458                         {
2459                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2460                                 if (!trace_startsolid)
2461                                 {
2462                                         self.crouch = false;
2463                                         self.view_ofs = self.stat_pl_view_ofs;
2464                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2465                                 }
2466                         }
2467                 }
2468
2469                 FixPlayermodel(self);
2470
2471                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2472                 //if(frametime)
2473                 {
2474                         self.items &= ~self.items_added;
2475
2476                         W_WeaponFrame(self);
2477
2478                         self.items_added = 0;
2479                         if(self.items & ITEM_Jetpack.m_itemid)
2480                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2481                                         self.items_added |= IT_FUEL;
2482
2483                         self.items |= self.items_added;
2484                 }
2485
2486                 player_regen();
2487
2488                 // WEAPONTODO: Add a weapon request for this
2489                 // rot vortex charge to the charge limit
2490                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2491                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2492
2493                 if(frametime)
2494                         player_anim();
2495
2496                 // secret status
2497                 secrets_setstatus();
2498
2499                 // monsters status
2500                 monsters_setstatus();
2501
2502                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2503
2504                 //self.angles_y=self.v_angle_y + 90;   // temp
2505         } else if(gameover) {
2506                 if (intermission_running)
2507                         IntermissionThink ();   // otherwise a button could be missed between
2508                 return;
2509         } else if(IS_OBSERVER(self)) {
2510                 ObserverThink();
2511         } else if(IS_SPEC(self)) {
2512                 SpectatorThink();
2513         }
2514
2515         // WEAPONTODO: Add weapon request for this
2516         if(!zoomstate_set)
2517                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2518
2519         float oldspectatee_status;
2520         oldspectatee_status = self.spectatee_status;
2521         if(IS_SPEC(self))
2522                 self.spectatee_status = num_for_edict(self.enemy);
2523         else if(IS_OBSERVER(self))
2524                 self.spectatee_status = num_for_edict(self);
2525         else
2526                 self.spectatee_status = 0;
2527         if(self.spectatee_status != oldspectatee_status)
2528         {
2529                 ClientData_Touch(self);
2530         }
2531
2532         if(self.teamkill_soundtime)
2533         if(time > self.teamkill_soundtime)
2534         {
2535                 self.teamkill_soundtime = 0;
2536
2537                 setself(self.teamkill_soundsource);
2538                 entity oldpusher = self.pusher;
2539                 self.pusher = this;
2540
2541                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2542
2543                 self.pusher = oldpusher;
2544                 setself(this);
2545         }
2546
2547         if(self.taunt_soundtime)
2548         if(time > self.taunt_soundtime)
2549         {
2550                 self.taunt_soundtime = 0;
2551                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2552         }
2553
2554         target_voicescript_next(self);
2555
2556         // WEAPONTODO: Move into weaponsystem somehow
2557         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2558         if(!self.weapon)
2559                 self.clip_load = self.clip_size = 0;
2560 }
2561
2562 /*
2563 =============
2564 PlayerPostThink
2565
2566 Called every frame for each client after the physics are run
2567 =============
2568 */
2569 .float idlekick_lasttimeleft;
2570 void PlayerPostThink (void)
2571 {SELFPARAM();
2572         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2573         if(IS_REAL_CLIENT(self))
2574         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2575         {
2576                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2577                 {
2578                         if(self.idlekick_lasttimeleft)
2579                         {
2580                                 self.idlekick_lasttimeleft = 0;
2581                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2582                         }
2583                 }
2584                 else
2585                 {
2586                         float timeleft;
2587                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2588                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2589                         {
2590                                 if(!self.idlekick_lasttimeleft)
2591                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2592                         }
2593                         if(timeleft <= 0)
2594                         {
2595                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2596                                 dropclient(self);
2597                                 return;
2598                         }
2599                         else if(timeleft <= 10)
2600                         {
2601                                 if(timeleft != self.idlekick_lasttimeleft)
2602                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2603                                 self.idlekick_lasttimeleft = timeleft;
2604                         }
2605                 }
2606         }
2607
2608         CheatFrame();
2609
2610         //CheckPlayerJump();
2611
2612         if(IS_PLAYER(self)) {
2613                 CheckRules_Player();
2614                 UpdateChatBubble();
2615                 if (self.impulse)
2616                         ImpulseCommands();
2617                 if (intermission_running)
2618                         return;         // intermission or finale
2619                 GetPressedKeys();
2620         }
2621
2622         /*
2623         float i;
2624         for(i = 0; i < 1000; ++i)
2625         {
2626                 vector end;
2627                 end = self.origin + '0 0 1024' + 512 * randomvec();
2628                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2629                 if(trace_fraction < 1)
2630                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2631                 {
2632                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2633                         break;
2634                 }
2635         }
2636         */
2637
2638         if(self.waypointsprite_attachedforcarrier)
2639                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2640
2641         playerdemo_write();
2642
2643         CSQCMODEL_AUTOUPDATE(self);
2644 }