qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 if(cvar("g_playerclip_collisions"))
 870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 871                 else
 872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 873                 self.frags = FRAGS_PLAYER;
 874                 if(independent_players)
 875                         MAKE_INDEPENDENT_PLAYER(self);
 876                 self.flags = FL_CLIENT;
 877                 self.takedamage = DAMAGE_AIM;
 878                 if(g_minstagib)
 879                         self.effects = EF_FULLBRIGHT;
 880                 else
 881                         self.effects = 0;
 882                 self.air_finished = time + 12;
 883                 self.dmg = 2;
 884
 885                 if(inWarmupStage)
 886                 {
 887                         self.ammo_shells = warmup_start_ammo_shells;
 888                         self.ammo_nails = warmup_start_ammo_nails;
 889                         self.ammo_rockets = warmup_start_ammo_rockets;
 890                         self.ammo_cells = warmup_start_ammo_cells;
 891                         self.ammo_fuel = warmup_start_ammo_fuel;
 892                         self.health = warmup_start_health;
 893                         self.armorvalue = warmup_start_armorvalue;
 894                         self.weapons = warmup_start_weapons;
 895                 }
 896                 else
 897                 {
 898                         self.ammo_shells = start_ammo_shells;
 899                         self.ammo_nails = start_ammo_nails;
 900                         self.ammo_rockets = start_ammo_rockets;
 901                         self.ammo_cells = start_ammo_cells;
 902                         self.ammo_fuel = start_ammo_fuel;
 903                         self.health = start_health;
 904                         self.armorvalue = start_armorvalue;
 905                         self.weapons = start_weapons;
 906                 }
 907
 908                 if(g_weaponarena_random)
 909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 910
 911                 self.items = start_items;
 912                 self.jump_interval = time;
 913
 914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 919                 //extend the pause of rotting if client was reset at the beginning of the countdown
 920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 921                         self.spawnshieldtime += game_starttime - time;
 922                         self.pauserotarmor_finished += game_starttime - time;
 923                         self.pauserothealth_finished += game_starttime - time;
 924                         self.pauseregen_finished += game_starttime - time;
 925                 }
 926                 self.damageforcescale = 2;
 927                 self.death_time = 0;
 928                 self.dead_frame = 0;
 929                 self.alpha = 0;
 930                 self.scale = 0;
 931                 self.fade_time = 0;
 932                 self.pain_frame = 0;
 933                 self.pain_finished = 0;
 934                 self.strength_finished = 0;
 935                 self.invincible_finished = 0;
 936                 self.pushltime = 0;
 937                 // players have no think function
 938                 self.think = SUB_Null;
 939                 self.nextthink = 0;
 940                 self.hook_time = 0;
 941                 self.dmg_team = 0;
 942                 self.ballistics_density = cvar("g_ballistics_density_player");
 943
 944                 self.metertime = 0;
 945
 946                 self.runes = 0;
 947
 948                 self.deadflag = DEAD_NO;
 949
 950                 self.angles = spot.angles;
 951
 952                 self.angles_z = 0; // never spawn tilted even if the spot says to
 953                 self.fixangle = TRUE; // turn this way immediately
 954                 self.velocity = '0 0 0';
 955                 self.avelocity = '0 0 0';
 956                 self.punchangle = '0 0 0';
 957                 self.punchvector = '0 0 0';
 958                 self.oldvelocity = self.velocity;
 959                 self.fire_endtime = -1;
 960
 961                 msg_entity = self;
 962                 WRITESPECTATABLE_MSG_ONE({
 963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 965                 });
 966
 967                 if(sv_loddistance1)
 968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 969
 970                 self.model = "";
 971                 FixPlayermodel();
 972
 973                 self.crouch = FALSE;
 974                 self.view_ofs = PL_VIEW_OFS;
 975                 setsize (self, PL_MIN, PL_MAX);
 976                 self.spawnorigin = spot.origin;
 977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 978                 // don't reset back to last position, even if new position is stuck in solid
 979                 self.oldorigin = self.origin;
 980                 self.prevorigin = self.origin;
 981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 982
 983                 if(g_arena)
 984                 {
 985                         Spawnqueue_Remove(self);
 986                         Spawnqueue_Mark(self);
 987                 }
 988
 989                 else if(g_ca)
 990                         self.caplayer = 1;
 991
 992                 self.event_damage = PlayerDamage;
 993
 994                 self.bot_attack = TRUE;
 995
 996                 self.statdraintime = time + 5;
 997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 998
 999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1067         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1068         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1069         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1070         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1071         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1072         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1073         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1074         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1078         if(sv_foginterval && world.fog != "")
1079                 WriteString(MSG_ENTITY, world.fog);
1080         else
1081                 WriteString(MSG_ENTITY, "");
1082         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1083         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1084         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1085         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1086         return TRUE;
1087 }
1088
1089 void ClientInit_CheckUpdate()
1090 {
1091         self.nextthink = time;
1092         if(self.count != cvar("g_balance_armor_blockpercent"))
1093         {
1094                 self.count = cvar("g_balance_armor_blockpercent");
1095                 self.SendFlags |= 1;
1096         }
1097         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1098         {
1099                 self.cnt = cvar("g_balance_weaponswitchdelay");
1100                 self.SendFlags |= 1;
1101         }
1102         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1103         {
1104                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1105                 self.SendFlags |= 1;
1106         }
1107         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1108         {
1109                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1110                 self.SendFlags |= 1;
1111         }
1112 }
1113
1114 void ClientInit_Spawn()
1115 {
1116         entity o;
1117         entity e;
1118         e = spawn();
1119         e.classname = "clientinit";
1120         e.think = ClientInit_CheckUpdate;
1121         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1122
1123         o = self;
1124         self = e;
1125         ClientInit_CheckUpdate();
1126         self = o;
1127 }
1128
1129 /*
1130 =============
1131 SetNewParms
1132 =============
1133 */
1134 void SetNewParms (void)
1135 {
1136         // initialize parms for a new player
1137         parm1 = -(86400 * 366);
1138 }
1139
1140 /*
1141 =============
1142 SetChangeParms
1143 =============
1144 */
1145 void SetChangeParms (void)
1146 {
1147         // save parms for level change
1148         parm1 = self.parm_idlesince - time;
1149 }
1150
1151 /*
1152 =============
1153 DecodeLevelParms
1154 =============
1155 */
1156 void DecodeLevelParms (void)
1157 {
1158         // load parms
1159         self.parm_idlesince = parm1;
1160         if(self.parm_idlesince == -(86400 * 366))
1161                 self.parm_idlesince = time;
1162
1163         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1164         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1165 }
1166
1167 /*
1168 =============
1169 ClientKill
1170
1171 Called when a client types 'kill' in the console
1172 =============
1173 */
1174
1175 void ClientKill_Now_TeamChange()
1176 {
1177         if(self.killindicator_teamchange == -1)
1178         {
1179                 self.team = -1;
1180                 JoinBestTeam( self, FALSE, FALSE );
1181         }
1182         else
1183                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1184 }
1185
1186 void ClientKill_Now()
1187 {
1188         if(self.killindicator_teamchange)
1189                 ClientKill_Now_TeamChange();
1190
1191         // in any case:
1192         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1193
1194         if(self.killindicator)
1195         {
1196                 dprint("Cleaned up after a leaked kill indicator.\n");
1197                 remove(self.killindicator);
1198                 self.killindicator = world;
1199         }
1200 }
1201 void KillIndicator_Think()
1202 {
1203         if (!self.owner.modelindex)
1204         {
1205                 self.owner.killindicator = world;
1206                 remove(self);
1207                 return;
1208         }
1209
1210         if(self.cnt <= 0)
1211         {
1212                 self = self.owner;
1213                 ClientKill_Now(); // no oldself needed
1214                 return;
1215         }
1216         else
1217         {
1218                 if(self.cnt <= 10)
1219                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1220                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1221                 {
1222                         if(self.cnt <= 10)
1223                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1224                         if(self.owner.killindicator_teamchange)
1225                         {
1226                                 if(self.owner.killindicator_teamchange == -1)
1227                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1228                                 else
1229                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1230                         }
1231                         else
1232                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1233                 }
1234                 self.nextthink = time + 1;
1235                 self.cnt -= 1;
1236         }
1237 }
1238
1239 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1240 {
1241         float killtime;
1242         entity e;
1243         killtime = cvar("g_balance_kill_delay");
1244
1245         if(g_race_qualifying)
1246                 killtime = 0;
1247
1248         self.killindicator_teamchange = targetteam;
1249
1250         if(!self.killindicator)
1251         {
1252                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1253                 {
1254                         ClientKill_Now();
1255                 }
1256                 else
1257                 {
1258                         self.killindicator = spawn();
1259                         self.killindicator.owner = self;
1260                         self.killindicator.scale = 0.5;
1261                         setattachment(self.killindicator, self, "");
1262                         setorigin(self.killindicator, '0 0 52');
1263                         self.killindicator.think = KillIndicator_Think;
1264                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1265                         self.killindicator.cnt = ceil(killtime);
1266                         self.killindicator.count = bound(0, ceil(killtime), 10);
1267                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1268
1269                         for(e = world; (e = find(e, classname, "body")) != world; )
1270                         {
1271                                 if(e.enemy != self)
1272                                         continue;
1273                                 e.killindicator = spawn();
1274                                 e.killindicator.owner = e;
1275                                 e.killindicator.scale = 0.5;
1276                                 setattachment(e.killindicator, e, "");
1277                                 setorigin(e.killindicator, '0 0 52');
1278                                 e.killindicator.think = KillIndicator_Think;
1279                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1280                                 e.killindicator.cnt = ceil(killtime);
1281                         }
1282                         self.lip = 0;
1283                 }
1284         }
1285         if(self.killindicator)
1286         {
1287                 if(targetteam)
1288                         self.killindicator.colormod = TeamColor(targetteam);
1289                 else
1290                         self.killindicator.colormod = '0 0 0';
1291         }
1292 }
1293
1294 void ClientKill (void)
1295 {
1296         ClientKill_TeamChange(0);
1297 }
1298
1299 void DoTeamChange(float destteam)
1300 {
1301         float t, c0;
1302         if(!teams_matter)
1303         {
1304                 if(destteam >= 0)
1305                         SetPlayerColors(self, destteam);
1306                 return;
1307         }
1308         if(self.classname == "player")
1309         if(destteam == -1)
1310         {
1311                 CheckAllowedTeams(self);
1312                 t = FindSmallestTeam(self, TRUE);
1313                 switch(self.team)
1314                 {
1315                         case COLOR_TEAM1: c0 = c1; break;
1316                         case COLOR_TEAM2: c0 = c2; break;
1317                         case COLOR_TEAM3: c0 = c3; break;
1318                         case COLOR_TEAM4: c0 = c4; break;
1319                         default:          c0 = 999;
1320                 }
1321                 switch(t)
1322                 {
1323                         case 1:
1324                                 if(c0 > c1)
1325                                         destteam = COLOR_TEAM1;
1326                                 break;
1327                         case 2:
1328                                 if(c0 > c2)
1329                                         destteam = COLOR_TEAM2;
1330                                 break;
1331                         case 3:
1332                                 if(c0 > c3)
1333                                         destteam = COLOR_TEAM3;
1334                                 break;
1335                         case 4:
1336                                 if(c0 > c4)
1337                                         destteam = COLOR_TEAM4;
1338                                 break;
1339                 }
1340                 if(destteam == -1)
1341                         return;
1342         }
1343         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1344                 return;
1345         ClientKill_TeamChange(destteam);
1346 }
1347
1348 void FixClientCvars(entity e)
1349 {
1350         // send prediction settings to the client
1351         stuffcmd(e, "\nin_bindmap 0 0\n");
1352         if(g_race || g_cts)
1353                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1354         if(cvar("g_antilag") == 3) // client side hitscan
1355                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1356                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1357         /*
1358          * we no longer need to stuff this. Remove this comment block if you feel
1359          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1360         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1361         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1362         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1363         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1364         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1365         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1366         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1367         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1368         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1369         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1370         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1371         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1372         stuffcmd(e, "cl_movement_edgefriction 1\n");
1373          */
1374 }
1375
1376 /*
1377 =============
1378 ClientConnect
1379
1380 Called when a client connects to the server
1381 =============
1382 */
1383 //void ctf_clientconnect();
1384 string ColoredTeamName(float t);
1385 void DecodeLevelParms (void);
1386 //void dom_player_join_team(entity pl);
1387 #ifdef UID
1388 .float uid_kicktime;
1389 .string uid;
1390 #endif
1391 void ClientConnect (void)
1392 {
1393         float t;
1394
1395         if(self.flags & FL_CLIENT)
1396         {
1397                 print("Warning: ClientConnect, but already connected!\n");
1398                 return;
1399         }
1400
1401         if(Ban_MaybeEnforceBan(self))
1402                 return;
1403
1404         DecodeLevelParms();
1405
1406 #ifdef WATERMARK
1407         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1408 #endif
1409
1410         self.classname = "player_joining";
1411
1412         self.flags = FL_CLIENT;
1413         self.version_nagtime = time + 10 + random() * 10;
1414
1415         if(player_count<0)
1416         {
1417                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1418                 player_count = 0;
1419         }
1420
1421         PlayerScore_Attach(self);
1422         ClientData_Attach();
1423
1424         bot_clientconnect();
1425
1426         playerdemo_init();
1427
1428         anticheat_init();
1429
1430         race_PreSpawnObserver();
1431
1432         //if(g_domination)
1433         //      dom_player_join_team(self);
1434
1435         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1436
1437         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1438                 self.classname = "observer";
1439         } else {
1440                 if(teams_matter)
1441                 {
1442                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1443                         {
1444                                 self.classname = "player";
1445                                 campaign_bots_may_start = 1;
1446                         }
1447                         else
1448                         {
1449                                 self.classname = "observer"; // do it anyway
1450                         }
1451                 }
1452                 else
1453                 {
1454                         self.classname = "player";
1455                         campaign_bots_may_start = 1;
1456                 }
1457         }
1458
1459         self.playerid = (playerid_last = playerid_last + 1);
1460
1461         if(cvar("sv_eventlog"))
1462                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1463
1464         LogTeamchange(self.playerid, self.team, 1);
1465
1466         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1467
1468         self.netname_previous = strzone(self.netname);
1469
1470         bprint("^4", self.netname, "^4 connected");
1471
1472         if(self.classname != "observer" && (g_domination || g_ctf))
1473                 bprint(" and joined the ", ColoredTeamName(self.team));
1474
1475         bprint("\n");
1476
1477         self.welcomemessage_time = 0;
1478
1479         stuffcmd(self, strcat(clientstuff, "\n"));
1480         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1481         stuffcmd(self, "cl_particles_reloadeffects\n");
1482
1483         FixClientCvars(self);
1484
1485         // spawnfunc_waypoint sprites
1486         WaypointSprite_InitClient(self);
1487
1488         // Wazat's grappling hook
1489         SetGrappleHookBindings();
1490
1491         // get autoswitch state from player when he toggles it
1492         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1493
1494         // get version info from player
1495         stuffcmd(self, "cmd clientversion $gameversion\n");
1496
1497         // get other cvars from player
1498         GetCvars(0);
1499
1500         // set cvar for team scoreboard
1501         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1502
1503         // notify about available teams
1504         if(teams_matter)
1505         {
1506                 CheckAllowedTeams(self);
1507                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1508                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1509         }
1510         else
1511                 stuffcmd(self, "set _teams_available 0\n");
1512
1513         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1514
1515         if(g_arena || g_ca)
1516         {
1517                 self.classname = "observer";
1518                 if(g_arena)
1519                         Spawnqueue_Insert(self);
1520         }
1521         /*else if(g_ctf)
1522         {
1523                 ctf_clientconnect();
1524         }*/
1525
1526         if(teams_matter || radar_showennemies)
1527                 attach_entcs();
1528
1529         bot_relinkplayerlist();
1530
1531         self.spectatortime = time;
1532         if(blockSpectators)
1533         {
1534                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1535         }
1536
1537         self.jointime = time;
1538         self.allowedTimeouts = cvar("sv_timeout_number");
1539
1540         if(clienttype(self) == CLIENTTYPE_REAL)
1541         {
1542                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1543                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1544         }
1545
1546         if(g_lms)
1547         {
1548                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1549                 {
1550                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1551                         self.frags = FRAGS_SPECTATOR;
1552                 }
1553         }
1554
1555         if(!sv_foginterval && world.fog != "")
1556                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1557
1558         SoundEntity_Attach(self);
1559
1560         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1561         {
1562                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1563                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1564         }
1565         else
1566                 self.hitplotfh = -1;
1567
1568 #ifdef UID
1569         if(clienttype(self) == CLIENTTYPE_REAL)
1570         if not(self.uid)
1571                 self.uid_kicktime = time + 60;
1572 #endif
1573
1574         if(g_race || g_cts) {
1575                 string rr;
1576                 if(g_cts)
1577                         rr = CTS_RECORD;
1578                 else
1579                         rr = RACE_RECORD;
1580                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1581
1582                 race_send_recordtime(MSG_ONE);
1583                 race_send_speedaward(MSG_ONE);
1584
1585                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1586                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1587                 race_send_speedaward_alltimebest(MSG_ONE);
1588
1589                 float i;
1590                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1591                         race_SendRankings(i, 0, 0, MSG_ONE);
1592                 }
1593         }
1594         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1595                 send_CSQC_teamnagger();
1596
1597         CheatInitClient();
1598 }
1599
1600 /*
1601 =============
1602 ClientDisconnect
1603
1604 Called when a client disconnects from the server
1605 =============
1606 */
1607 .entity chatbubbleentity;
1608 .entity teambubbleentity;
1609 void ReadyCount();
1610 void ClientDisconnect (void)
1611 {
1612         if not(self.flags & FL_CLIENT)
1613         {
1614                 print("Warning: ClientDisconnect without ClientConnect\n");
1615                 return;
1616         }
1617
1618         CheatShutdownClient();
1619
1620         if(self.hitplotfh >= 0)
1621         {
1622                 fclose(self.hitplotfh);
1623                 self.hitplotfh = -1;
1624         }
1625
1626         anticheat_report();
1627         anticheat_shutdown();
1628
1629         playerdemo_shutdown();
1630
1631         bot_clientdisconnect();
1632
1633         if(self.entcs)
1634                 detach_entcs();
1635
1636         if(cvar("sv_eventlog"))
1637                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1638         bprint ("^4",self.netname);
1639         bprint ("^4 disconnected\n");
1640
1641         SoundEntity_Detach(self);
1642
1643         DropAllRunes(self);
1644         MUTATOR_CALLHOOK(ClientDisconnect);
1645
1646         Portal_ClearAll(self);
1647
1648         if(self.flagcarried)
1649                 DropFlag(self.flagcarried, world, world);
1650         if(self.ballcarried)
1651                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1652
1653         // Here, everything has been done that requires this player to be a client.
1654
1655         self.flags &~= FL_CLIENT;
1656
1657         if (self.chatbubbleentity)
1658                 remove (self.chatbubbleentity);
1659
1660         if (self.teambubbleentity)
1661                 remove (self.teambubbleentity);
1662
1663         if (self.killindicator)
1664                 remove (self.killindicator);
1665
1666         WaypointSprite_PlayerGone();
1667
1668         bot_relinkplayerlist();
1669
1670         // remove laserdot
1671         if(self.weaponentity)
1672                 if(self.weaponentity.lasertarget)
1673                         remove(self.weaponentity.lasertarget);
1674
1675         if(g_arena)
1676         {
1677                 Spawnqueue_Unmark(self);
1678                 Spawnqueue_Remove(self);
1679         }
1680
1681         ClientData_Detach();
1682         PlayerScore_Detach(self);
1683
1684         if(self.netname_previous)
1685                 strunzone(self.netname_previous);
1686         if(self.clientstatus)
1687                 strunzone(self.clientstatus);
1688
1689         ClearPlayerSounds();
1690
1691         if(self.personal)
1692                 remove(self.personal);
1693
1694         self.playerid = 0;
1695         ReadyCount();
1696
1697         // free cvars
1698         GetCvars(-1);
1699 }
1700
1701 .float BUTTON_CHAT;
1702 void ChatBubbleThink()
1703 {
1704         self.nextthink = time;
1705         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1706         {
1707                 if(self.owner) // but why can that ever be world?
1708                         self.owner.chatbubbleentity = world;
1709                 remove(self);
1710                 return;
1711         }
1712         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1713 #ifdef TETRIS
1714                 || self.owner.tetris_on
1715 #endif
1716         )
1717                 self.model = self.mdl;
1718         else
1719                 self.model = "";
1720 };
1721
1722 void UpdateChatBubble()
1723 {
1724         if (!self.modelindex)
1725                 return;
1726         // spawn a chatbubble entity if needed
1727         if (!self.chatbubbleentity)
1728         {
1729                 self.chatbubbleentity = spawn();
1730                 self.chatbubbleentity.owner = self;
1731                 self.chatbubbleentity.exteriormodeltoclient = self;
1732                 self.chatbubbleentity.think = ChatBubbleThink;
1733                 self.chatbubbleentity.nextthink = time;
1734                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1735                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1736                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1737                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1738                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1739                 self.chatbubbleentity.model = "";
1740                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1741         }
1742 }
1743
1744
1745 void TeamBubbleThink()
1746 {
1747         self.nextthink = time;
1748         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1749         {
1750                 if(self.owner) // but why can that ever be world?
1751                         self.owner.teambubbleentity = world;
1752                 remove(self);
1753                 return;
1754         }
1755 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1756         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1757                 self.model = "";
1758         else
1759                 self.model = self.mdl;
1760
1761 };
1762
1763 float TeamBubble_customizeentityforclient()
1764 {
1765         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1766 }
1767
1768 void UpdateTeamBubble()
1769 {
1770         if (!self.modelindex || !teams_matter)
1771                 return;
1772         // spawn a teambubble entity if needed
1773         if (!self.teambubbleentity && teams_matter)
1774         {
1775                 self.teambubbleentity = spawn();
1776                 self.teambubbleentity.owner = self;
1777                 self.teambubbleentity.exteriormodeltoclient = self;
1778                 self.teambubbleentity.think = TeamBubbleThink;
1779                 self.teambubbleentity.nextthink = time;
1780                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1781 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1782                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1783                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1784                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1785                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1786                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1787                 self.teambubbleentity.effects = EF_LOWPRECISION;
1788         }
1789 }
1790
1791 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1792 // added to the model skins
1793 /*void UpdateColorModHack()
1794 {
1795         local float c;
1796         c = self.clientcolors & 15;
1797         // LordHavoc: only bothering to support white, green, red, yellow, blue
1798              if (!teams_matter) self.colormod = '0 0 0';
1799         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1800         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1801         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1802         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1803         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1804         else self.colormod = '1 1 1';
1805 };*/
1806
1807 .float oldcolormap;
1808 void respawn(void)
1809 {
1810         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1811         {
1812                 self.solid = SOLID_NOT;
1813                 self.takedamage = DAMAGE_NO;
1814                 self.movetype = MOVETYPE_FLY;
1815                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1816                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1817                 self.effects |= EF_ADDITIVE;
1818                 self.oldcolormap = self.colormap;
1819                 self.colormap = 512;
1820                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1821                 if(cvar("g_respawn_ghosts_maxtime"))
1822                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1823         }
1824
1825         CopyBody(1);
1826         self.effects |= EF_NODRAW; // prevent another CopyBody
1827         if(self.oldcolormap)
1828         {
1829                 self.colormap = self.oldcolormap;
1830                 self.oldcolormap = 0;
1831         }
1832         PutClientInServer();
1833 }
1834
1835 void play_countdown(float finished, string samp)
1836 {
1837         if(clienttype(self) == CLIENTTYPE_REAL)
1838                 if(floor(finished - time - frametime) != floor(finished - time))
1839                         if(finished - time < 6)
1840                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1841 }
1842
1843 /**
1844  * When sv_timeout is used this function returs strings like
1845  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1846  * Called by centerprint functions
1847  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1848  */
1849 string getTimeoutText(float addOneSecond) {
1850         if (!cvar("sv_timeout") || !timeoutStatus)
1851                 return "";
1852
1853         local string retStr;
1854         if (timeoutStatus == 1) {
1855                 if (addOneSecond == 1) {
1856                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1857                 }
1858                 else {
1859                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1860                 }
1861                 return retStr;
1862         }
1863         else if (timeoutStatus == 2) {
1864                 if (addOneSecond) {
1865                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1866                         //don't show messages like "Timeout ends in 0 seconds"...
1867                         if ((remainingTimeoutTime + 1) > 0)
1868                                 return retStr;
1869                         else
1870                                 return "";
1871                 }
1872                 else {
1873                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1874                         //don't show messages like "Timeout ends in 0 seconds"...
1875                         if (remainingTimeoutTime > 0)
1876                                 return retStr;
1877                         else
1878                                 return "";
1879                 }
1880         }
1881         else return "";
1882 }
1883
1884 void player_powerups (void)
1885 {
1886         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1887         {
1888                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1889                 self.modelflags |= MF_ROCKET;
1890         }
1891         else
1892         {
1893                 SoundEntity_StopSound(self, CHAN_PLAYER);
1894                 self.modelflags &~= MF_ROCKET;
1895         }
1896
1897         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1898
1899         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1900                 return;
1901
1902         Fire_ApplyDamage(self);
1903         Fire_ApplyEffect(self);
1904
1905         if (g_minstagib)
1906         {
1907                 self.effects |= EF_FULLBRIGHT;
1908
1909                 if (self.items & IT_STRENGTH)
1910                 {
1911                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1912                         if (time > self.strength_finished)
1913                         {
1914                                 self.alpha = default_player_alpha;
1915                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1916                                 self.items &~= IT_STRENGTH;
1917                                 sprint(self, "^3Invisibility has worn off\n");
1918                         }
1919                 }
1920                 else
1921                 {
1922                         if (time < self.strength_finished)
1923                         {
1924                                 self.alpha = g_minstagib_invis_alpha;
1925                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1926                                 self.items |= IT_STRENGTH;
1927                                 sprint(self, "^3You are invisible\n");
1928                         }
1929                 }
1930
1931                 if (self.items & IT_INVINCIBLE)
1932                 {
1933                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1934                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1935                         {
1936                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1937                                 sprint(self, "^3Speed has worn off\n");
1938                         }
1939                 }
1940                 else
1941                 {
1942                         if (time < self.invincible_finished)
1943                         {
1944                                 self.items = self.items | IT_INVINCIBLE;
1945                                 sprint(self, "^3You are on speed\n");
1946                         }
1947                 }
1948                 return;
1949         }
1950
1951         if (self.items & IT_STRENGTH)
1952         {
1953                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1954                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1955                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1956                 {
1957                         self.items = self.items - (self.items & IT_STRENGTH);
1958                         sprint(self, "^3Strength has worn off\n");
1959                 }
1960         }
1961         else
1962         {
1963                 if (time < self.strength_finished)
1964                 {
1965                         self.items = self.items | IT_STRENGTH;
1966                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1967                 }
1968         }
1969         if (self.items & IT_INVINCIBLE)
1970         {
1971                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1972                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1973                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1974                 {
1975                         self.items = self.items - (self.items & IT_INVINCIBLE);
1976                         sprint(self, "^3Shield has worn off\n");
1977                 }
1978         }
1979         else
1980         {
1981                 if (time < self.invincible_finished)
1982                 {
1983                         self.items = self.items | IT_INVINCIBLE;
1984                         sprint(self, "^3Shield surrounds you\n");
1985                 }
1986         }
1987
1988         if(cvar("g_nodepthtestplayers"))
1989                 self.effects = self.effects | EF_NODEPTHTEST;
1990
1991         if(cvar("g_fullbrightplayers"))
1992                 self.effects = self.effects | EF_FULLBRIGHT;
1993
1994         // midair gamemode: damage only while in the air
1995         // if in midair mode, being on ground grants temporary invulnerability
1996         // (this is so that multishot weapon don't clear the ground flag on the
1997         // first damage in the frame, leaving the player vulnerable to the
1998         // remaining hits in the same frame)
1999         if (self.flags & FL_ONGROUND)
2000         if (g_midair)
2001                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2002
2003         if (time >= game_starttime)
2004         if (time < self.spawnshieldtime)
2005                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2006 }
2007
2008 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2009 {
2010         if(current > stable)
2011                 return current;
2012         else if(current > stable - 0.25) // when close enough, "snap"
2013                 return stable;
2014         else
2015                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2016 }
2017
2018 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2019 {
2020         if(current < stable)
2021                 return current;
2022         else if(current < stable + 0.25) // when close enough, "snap"
2023                 return stable;
2024         else
2025                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2026 }
2027
2028 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2029 {
2030         if(current > rotstable)
2031         {
2032                 if(rotframetime > 0)
2033                 {
2034                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2035                         current = max(rotstable, current - rotlinear * rotframetime);
2036                 }
2037         }
2038         else if(current < regenstable)
2039         {
2040                 if(regenframetime > 0)
2041                 {
2042                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2043                         current = min(regenstable, current + regenlinear * regenframetime);
2044                 }
2045         }
2046
2047         if(current > limit)
2048                 current = limit;
2049
2050         return current;
2051 }
2052
2053 void player_regen (void)
2054 {
2055         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2056         maxh = cvar("g_balance_health_rotstable");
2057         maxa = cvar("g_balance_armor_rotstable");
2058         maxf = cvar("g_balance_fuel_rotstable");
2059         minh = cvar("g_balance_health_regenstable");
2060         mina = cvar("g_balance_armor_regenstable");
2061         minf = cvar("g_balance_fuel_regenstable");
2062         limith = cvar("g_balance_health_limit");
2063         limita = cvar("g_balance_armor_limit");
2064         limitf = cvar("g_balance_fuel_limit");
2065
2066         max_mod = regen_mod = rot_mod = limit_mod = 1;
2067
2068         if (self.runes & RUNE_REGEN)
2069         {
2070                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2071                 {
2072                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2073                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2074                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2075                 }
2076                 else
2077                 {
2078                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2079                         max_mod = cvar("g_balance_rune_regen_hpmod");
2080                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2081                 }
2082         }
2083         else if (self.runes & CURSE_VENOM)
2084         {
2085                 max_mod = cvar("g_balance_curse_venom_hpmod");
2086                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2087                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2088                 else
2089                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2090                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2091                 //if (!self.runes & RUNE_REGEN)
2092                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2093         }
2094         maxh = maxh * max_mod;
2095         //maxa = maxa * max_mod;
2096         //maxf = maxf * max_mod;
2097         minh = minh * max_mod;
2098         //mina = mina * max_mod;
2099         //minf = minf * max_mod;
2100         limith = limith * limit_mod;
2101         limita = limita * limit_mod;
2102         //limitf = limitf * limit_mod;
2103
2104         if(g_lms && g_ca)
2105                 rot_mod = 0;
2106
2107         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2108         {
2109                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2110                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2111
2112                 // if player rotted to death...  die!
2113                 if(self.health < 1)
2114                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2115         }
2116
2117         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2118                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2119 }
2120
2121 float zoomstate_set;
2122 void SetZoomState(float z)
2123 {
2124         if(z != self.zoomstate)
2125         {
2126                 self.zoomstate = z;
2127                 ClientData_Touch(self);
2128         }
2129         zoomstate_set = 1;
2130 }
2131
2132 void GetPressedKeys(void) {
2133         MUTATOR_CALLHOOK(GetPressedKeys);
2134         if (self.movement_x > 0) // get if movement keys are pressed
2135         {       // forward key pressed
2136                 self.pressedkeys |= KEY_FORWARD;
2137                 self.pressedkeys &~= KEY_BACKWARD;
2138         }
2139         else if (self.movement_x < 0)
2140         {       // backward key pressed
2141                 self.pressedkeys |= KEY_BACKWARD;
2142                 self.pressedkeys &~= KEY_FORWARD;
2143         }
2144         else
2145         {       // no x input
2146                 self.pressedkeys &~= KEY_FORWARD;
2147                 self.pressedkeys &~= KEY_BACKWARD;
2148         }
2149
2150         if (self.movement_y > 0)
2151         {       // right key pressed
2152                 self.pressedkeys |= KEY_RIGHT;
2153                 self.pressedkeys &~= KEY_LEFT;
2154         }
2155         else if (self.movement_y < 0)
2156         {       // left key pressed
2157                 self.pressedkeys |= KEY_LEFT;
2158                 self.pressedkeys &~= KEY_RIGHT;
2159         }
2160         else
2161         {       // no y input
2162                 self.pressedkeys &~= KEY_RIGHT;
2163                 self.pressedkeys &~= KEY_LEFT;
2164         }
2165
2166         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2167                 self.pressedkeys |= KEY_JUMP;
2168         else
2169                 self.pressedkeys &~= KEY_JUMP;
2170         if (self.BUTTON_CROUCH)
2171                 self.pressedkeys |= KEY_CROUCH;
2172         else
2173                 self.pressedkeys &~= KEY_CROUCH;
2174 }
2175
2176 void update_stats (float number, float hit, float fired) {
2177 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2178 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2179
2180         if(number) {
2181                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2182                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2183         } else {
2184                 self.stat_hit = hit * sv_accuracy_data_share;
2185                 self.stat_fired = fired * sv_accuracy_data_share;
2186         }
2187 }
2188
2189 /*
2190 ======================
2191 spectate mode routines
2192 ======================
2193 */
2194
2195 .float weapon_count;
2196 void SpectateCopy(entity spectatee) {
2197         if(spectatee.weapon_count < WEP_LAST) {
2198                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2199                 spectatee.weapon_count ++;
2200         } else
2201                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2202
2203         other = spectatee;
2204         MUTATOR_CALLHOOK(SpectateCopy);
2205         self.armortype = spectatee.armortype;
2206         self.armorvalue = spectatee.armorvalue;
2207         self.ammo_cells = spectatee.ammo_cells;
2208         self.ammo_shells = spectatee.ammo_shells;
2209         self.ammo_nails = spectatee.ammo_nails;
2210         self.ammo_rockets = spectatee.ammo_rockets;
2211         self.ammo_fuel = spectatee.ammo_fuel;
2212         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2213         self.health = spectatee.health;
2214         self.impulse = 0;
2215         self.items = spectatee.items;
2216         self.metertime = spectatee.metertime;
2217         self.strength_finished = spectatee.strength_finished;
2218         self.invincible_finished = spectatee.invincible_finished;
2219         self.pressedkeys = spectatee.pressedkeys;
2220         self.weapons = spectatee.weapons;
2221         self.switchweapon = spectatee.switchweapon;
2222         self.weapon = spectatee.weapon;
2223         self.punchangle = spectatee.punchangle;
2224         self.view_ofs = spectatee.view_ofs;
2225         self.v_angle = spectatee.v_angle;
2226         self.velocity = spectatee.velocity;
2227         self.dmg_take = spectatee.dmg_take;
2228         self.dmg_save = spectatee.dmg_save;
2229         self.dmg_inflictor = spectatee.dmg_inflictor;
2230         self.angles = spectatee.v_angle;
2231         self.fixangle = TRUE;
2232         setorigin(self, spectatee.origin);
2233         setsize(self, spectatee.mins, spectatee.maxs);
2234         SetZoomState(spectatee.zoomstate);
2235
2236         anticheat_spectatecopy(spectatee);
2237 }
2238
2239 float SpectateUpdate() {
2240         if(!self.enemy)
2241                 return 0;
2242
2243         if (self == self.enemy)
2244                 return 0;
2245
2246         if(self.enemy.classname != "player")
2247                 return 0;
2248
2249         SpectateCopy(self.enemy);
2250
2251         return 1;
2252 }
2253
2254 float SpectateNext() {
2255         other = find(self.enemy, classname, "player");
2256
2257         if (!other)
2258                 other = find(other, classname, "player");
2259
2260         if (other)
2261                 self.enemy = other;
2262
2263         if(self.enemy.classname == "player") {
2264                 msg_entity = self;
2265                 WriteByte(MSG_ONE, SVC_SETVIEW);
2266                 WriteEntity(MSG_ONE, self.enemy);
2267                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2268                 self.movetype = MOVETYPE_NONE;
2269
2270                 self.enemy.weapon_count = 0;
2271
2272                 if(!SpectateUpdate())
2273                         PutObserverInServer();
2274
2275                 return 1;
2276         } else {
2277                 return 0;
2278         }
2279 }
2280
2281 /*
2282 =============
2283 ShowRespawnCountdown()
2284
2285 Update a respawn countdown display.
2286 =============
2287 */
2288 void ShowRespawnCountdown()
2289 {
2290         float number;
2291         if(self.deadflag == DEAD_NO) // just respawned?
2292                 return;
2293         else
2294         {
2295                 number = ceil(self.death_time - time);
2296                 if(number <= 0)
2297                         return;
2298                 if(number <= self.respawn_countdown)
2299                 {
2300                         self.respawn_countdown = number - 1;
2301                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2302                                 AnnounceTo(self, strcat(ftos(number), ""));
2303                 }
2304         }
2305 }
2306
2307 void LeaveSpectatorMode()
2308 {
2309         if(isJoinAllowed()) {
2310                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2311                         self.classname = "player";
2312
2313                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2314                                 JoinBestTeam(self, FALSE, TRUE);
2315
2316                         if(cvar("g_campaign"))
2317                                 campaign_bots_may_start = 1;
2318
2319                         self.stat_count = WEP_LAST;
2320
2321                         PutClientInServer();
2322
2323                         if(self.classname == "player")
2324                                 bprint ("^4", self.netname, "^4 is playing now\n");
2325
2326                         if(!cvar("g_campaign"))
2327                                 centerprint(self,""); // clear MOTD
2328
2329                         return;
2330                 } else {
2331                         if (g_ca && self.caplayer) {
2332                         }       // do nothing
2333                         else
2334                                 stuffcmd(self,"menu_showteamselect\n");
2335                         return;
2336                 }
2337         }
2338         else {
2339                 //player may not join because of g_maxplayers is set
2340                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2341         }
2342 }
2343
2344 /**
2345  * Determines whether the player is allowed to join. This depends on cvar
2346  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2347  * it checks whether the number of currently playing players exceeds g_maxplayers.
2348  * @return bool TRUE if the player is allowed to join, false otherwise
2349  */
2350 float isJoinAllowed() {
2351         if (!cvar("g_maxplayers"))
2352                 return TRUE;
2353
2354         local entity e;
2355         local float currentlyPlaying;
2356         FOR_EACH_REALPLAYER(e) {
2357                 if(e.classname == "player")
2358                         currentlyPlaying += 1;
2359         }
2360         if(currentlyPlaying < cvar("g_maxplayers"))
2361                 return TRUE;
2362
2363         return FALSE;
2364 }
2365
2366 /**
2367  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2368  * g_maxplayers_spectator_blocktime seconds
2369  */
2370 void checkSpectatorBlock() {
2371         if(self.classname == "spectator" || self.classname == "observer") {
2372                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2373                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2374                         dropclient(self);
2375                 }
2376         }
2377 }
2378
2379 float vercmp_recursive(string v1, string v2)
2380 {
2381         float dot1, dot2;
2382         string s1, s2;
2383         float r;
2384
2385         dot1 = strstrofs(v1, ".", 0);
2386         dot2 = strstrofs(v2, ".", 0);
2387         if(dot1 == -1)
2388                 s1 = v1;
2389         else
2390                 s1 = substring(v1, 0, dot1);
2391         if(dot2 == -1)
2392                 s2 = v2;
2393         else
2394                 s2 = substring(v2, 0, dot2);
2395
2396         r = stof(s1) - stof(s2);
2397         if(r != 0)
2398                 return r;
2399
2400         r = strcasecmp(s1, s2);
2401         if(r != 0)
2402                 return r;
2403
2404         if(dot1 == -1)
2405                 if(dot2 == -1)
2406                         return 0;
2407                 else
2408                         return -1;
2409         else
2410                 if(dot2 == -1)
2411                         return 1;
2412                 else
2413                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2414 }
2415
2416 float vercmp(string v1, string v2)
2417 {
2418         if(strcasecmp(v1, v2) == 0) // early out check
2419                 return 0;
2420         return vercmp_recursive(v1, v2);
2421 }
2422
2423 void ObserverThink()
2424 {
2425         if (self.flags & FL_JUMPRELEASED) {
2426                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2427                         self.welcomemessage_time = 0;
2428                         self.flags &~= FL_JUMPRELEASED;
2429                         self.flags |= FL_SPAWNING;
2430                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2431                         self.welcomemessage_time = 0;
2432                         self.flags &~= FL_JUMPRELEASED;
2433                         if(SpectateNext() == 1) {
2434                                 self.classname = "spectator";
2435                         }
2436                 }
2437         } else {
2438                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2439                         self.flags |= FL_JUMPRELEASED;
2440                         if(self.flags & FL_SPAWNING)
2441                         {
2442                                 self.flags &~= FL_SPAWNING;
2443                                 LeaveSpectatorMode();
2444                                 return;
2445                         }
2446                 }
2447         }
2448         PrintWelcomeMessage(self);
2449 }
2450
2451 void SpectatorThink()
2452 {
2453         if (self.flags & FL_JUMPRELEASED) {
2454                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2455                         self.welcomemessage_time = 0;
2456                         self.flags &~= FL_JUMPRELEASED;
2457                         self.flags |= FL_SPAWNING;
2458                 } else if(self.BUTTON_ATCK) {
2459                         self.welcomemessage_time = 0;
2460                         self.flags &~= FL_JUMPRELEASED;
2461                         if(SpectateNext() == 1) {
2462                                 self.classname = "spectator";
2463                         } else {
2464                                 self.classname = "observer";
2465                                 self.stat_count = WEP_LAST;
2466                                 PutClientInServer();
2467                         }
2468                 } else if (self.BUTTON_ATCK2) {
2469                         self.welcomemessage_time = 0;
2470                         self.flags &~= FL_JUMPRELEASED;
2471                         self.classname = "observer";
2472                         self.stat_count = WEP_LAST;
2473                         PutClientInServer();
2474                 } else {
2475                         if(!SpectateUpdate())
2476                                 PutObserverInServer();
2477                 }
2478         } else {
2479                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2480                         self.flags |= FL_JUMPRELEASED;
2481                         if(self.flags & FL_SPAWNING)
2482                         {
2483                                 self.flags &~= FL_SPAWNING;
2484                                 LeaveSpectatorMode();
2485                                 return;
2486                         }
2487                 }
2488         }
2489
2490         PrintWelcomeMessage(self);
2491         self.flags |= FL_CLIENT | FL_NOTARGET;
2492 }
2493
2494 .float touchexplode_time;
2495
2496 /*
2497 =============
2498 PlayerPreThink
2499
2500 Called every frame for each client before the physics are run
2501 =============
2502 */
2503 void() ctf_setstatus;
2504 void() nexball_setstatus;
2505 .float items_added;
2506 void PlayerPreThink (void)
2507 {
2508         self.stat_game_starttime = game_starttime;
2509         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2510         self.stat_leadlimit = cvar("leadlimit");
2511
2512         if(frametime)
2513         {
2514                 // physics frames: update anticheat stuff
2515                 anticheat_prethink();
2516         }
2517
2518         if(blockSpectators && frametime)
2519                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2520                 checkSpectatorBlock();
2521
2522         zoomstate_set = 0;
2523
2524         if(self.netname_previous != self.netname)
2525         {
2526                 if(cvar("sv_eventlog"))
2527                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2528                 if(self.netname_previous)
2529                         strunzone(self.netname_previous);
2530                 self.netname_previous = strzone(self.netname);
2531         }
2532
2533         // version nagging
2534         if(self.version_nagtime)
2535                 if(self.cvar_g_xonoticversion)
2536                         if(time > self.version_nagtime)
2537                         {
2538                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2539                                 {
2540                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2541                                         {
2542                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2543                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2544                                         }
2545                                         else
2546                                         {
2547                                                 float r;
2548                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2549                                                 if(r < 0)
2550                                                 {
2551                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2552                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2553                                                 }
2554                                                 else if(r > 0)
2555                                                 {
2556                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2557                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2558                                                 }
2559                                         }
2560                                 }
2561                                 self.version_nagtime = 0;
2562                         }
2563
2564         // GOD MODE info
2565         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2566         {
2567                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2568                 self.max_armorvalue = 0;
2569         }
2570
2571 #ifdef TETRIS
2572         if (TetrisPreFrame())
2573                 return;
2574 #endif
2575
2576         MUTATOR_CALLHOOK(PlayerPreThink);
2577
2578         if(self.classname == "player") {
2579 //              if(self.netname == "Wazat")
2580 //                      bprint(self.classname, "\n");
2581
2582                 CheckRules_Player();
2583
2584                 PrintWelcomeMessage(self);
2585
2586                 if (intermission_running)
2587                 {
2588                         IntermissionThink ();   // otherwise a button could be missed between
2589                         return;                                 // the think tics
2590                 }
2591
2592                 if(self.teleport_time)
2593                 if(time > self.teleport_time)
2594                 {
2595                         self.teleport_time = 0;
2596                         self.effects = self.effects - (self.effects & EF_NODRAW);
2597                 }
2598
2599                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2600                         UpdateSelectedPlayer();
2601
2602                 //don't allow the player to turn around while game is paused!
2603                 if(timeoutStatus == 2) {
2604                         self.v_angle = self.lastV_angle;
2605                         self.angles = self.lastV_angle;
2606                         self.fixangle = TRUE;
2607                 }
2608
2609                 if(frametime)
2610                 {
2611                         if(self.health <= 0 && cvar("g_deathglow"))
2612                         {
2613                                 if(self.glowmod_x > 0)
2614                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2615                                 else
2616                                         self.glowmod_x = -1;
2617                                 if(self.glowmod_y > 0)
2618                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2619                                 else
2620                                         self.glowmod_y = -1;
2621                                 if(self.glowmod_z > 0)
2622                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2623                                 else
2624                                         self.glowmod_z = -1;
2625                         }
2626                         else
2627                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2628                         player_powerups();
2629                 }
2630
2631                 if (self.deadflag != DEAD_NO)
2632                 {
2633                         float button_pressed, force_respawn;
2634                         if(self.personal && g_race_qualifying)
2635                         {
2636                                 if(time > self.death_time)
2637                                 {
2638                                         self.death_time = time + 1; // only retry once a second
2639                                         respawn();
2640                                         self.impulse = 141;
2641                                 }
2642                         }
2643                         else
2644                         {
2645                                 if(frametime)
2646                                         player_anim();
2647                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2648                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2649                                 if (self.deadflag == DEAD_DYING)
2650                                 {
2651                                         if(force_respawn)
2652                                                 self.deadflag = DEAD_RESPAWNING;
2653                                         else if(!button_pressed)
2654                                                 self.deadflag = DEAD_DEAD;
2655                                 }
2656                                 else if (self.deadflag == DEAD_DEAD)
2657                                 {
2658                                         if(button_pressed)
2659                                                 self.deadflag = DEAD_RESPAWNABLE;
2660                                 }
2661                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2662                                 {
2663                                         if(!button_pressed)
2664                                                 self.deadflag = DEAD_RESPAWNING;
2665                                 }
2666                                 else if (self.deadflag == DEAD_RESPAWNING)
2667                                 {
2668                                         if(time > self.death_time)
2669                                         {
2670                                                 self.death_time = time + 1; // only retry once a second
2671                                                 respawn();
2672                                         }
2673                                 }
2674                                 ShowRespawnCountdown();
2675                         }
2676                         return;
2677                 }
2678
2679                 if(g_touchexplode)
2680                 if(time > self.touchexplode_time)
2681                 if(self.classname == "player")
2682                 if(self.deadflag == DEAD_NO)
2683                 if not(IS_INDEPENDENT_PLAYER(self))
2684                 FOR_EACH_PLAYER(other) if(self != other)
2685                 {
2686                         if(time > other.touchexplode_time)
2687                         if(other.deadflag == DEAD_NO)
2688                         if not(IS_INDEPENDENT_PLAYER(other))
2689                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2690                         {
2691                                 PlayerTouchExplode(self, other);
2692                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2693                         }
2694                 }
2695
2696                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2697                 {
2698                         vector dist;
2699
2700                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2701                         dist = self.prevorigin - self.origin;
2702                         dist_z = 0;
2703                         self.lms_traveled_distance += fabs(vlen(dist));
2704
2705                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2706                         {
2707                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2708                                 self.lms_traveled_distance = 0;
2709                         }
2710
2711                         if(time > self.lms_nextcheck)
2712                         {
2713                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2714                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2715                                 {
2716                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2717                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2718                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2719                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2720                                 }
2721                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2722                                 self.lms_traveled_distance = 0;
2723                         }
2724                 }
2725
2726                 self.prevorigin = self.origin;
2727
2728                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2729                 {
2730                         if (!self.crouch)
2731                         {
2732                                 self.crouch = TRUE;
2733                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2734                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2735                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2736                         }
2737                 }
2738                 else
2739                 {
2740                         if (self.crouch)
2741                         {
2742                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2743                                 if (!trace_startsolid)
2744                                 {
2745                                         self.crouch = FALSE;
2746                                         self.view_ofs = PL_VIEW_OFS;
2747                                         setsize (self, PL_MIN, PL_MAX);
2748                                 }
2749                         }
2750                 }
2751
2752                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2753                 {
2754                         if(self.bloodloss_timer < time)
2755                         {
2756                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2757                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2758                         }
2759                 }
2760
2761                 FixPlayermodel();
2762
2763                 GrapplingHookFrame();
2764
2765                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2766                 //if(frametime)
2767                 {
2768                         self.items &~= self.items_added;
2769
2770                         W_WeaponFrame();
2771
2772                         self.items_added = 0;
2773                         if(self.items & IT_JETPACK)
2774                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2775                                         self.items_added |= IT_FUEL;
2776
2777                         self.items |= self.items_added;
2778                 }
2779
2780                 player_regen();
2781                 if(frametime)
2782                         player_anim();
2783
2784                 if (g_minstagib)
2785                         minstagib_ammocheck();
2786
2787                 ctf_setstatus();
2788                 nexball_setstatus();
2789
2790                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2791
2792                 //self.angles_y=self.v_angle_y + 90;   // temp
2793         } else if(gameover) {
2794                 if (intermission_running)
2795                         IntermissionThink ();   // otherwise a button could be missed between
2796                 return;
2797         } else if(self.classname == "observer") {
2798                 ObserverThink();
2799         } else if(self.classname == "spectator") {
2800                 SpectatorThink();
2801         }
2802
2803         if(!zoomstate_set)
2804                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2805
2806         float oldspectatee_status;
2807         oldspectatee_status = self.spectatee_status;
2808         if(self.classname == "spectator")
2809                 self.spectatee_status = num_for_edict(self.enemy);
2810         else if(self.classname == "observer")
2811                 self.spectatee_status = num_for_edict(self);
2812         else
2813                 self.spectatee_status = 0;
2814         if(self.spectatee_status != oldspectatee_status)
2815         {
2816                 ClientData_Touch(self);
2817                 if(g_race || g_cts)
2818                         race_InitSpectator();
2819         }
2820
2821         if(self.teamkill_soundtime)
2822         if(time > self.teamkill_soundtime)
2823         {
2824                 self.teamkill_soundtime = 0;
2825
2826                 entity oldpusher, oldself;
2827
2828                 oldself = self; self = self.teamkill_soundsource;
2829                 oldpusher = self.pusher; self.pusher = oldself;
2830
2831                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2832
2833                 self.pusher = oldpusher;
2834                 self = oldself;
2835         }
2836
2837         if(self.taunt_soundtime)
2838         if(time > self.taunt_soundtime)
2839         {
2840                 self.taunt_soundtime = 0;
2841                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2842         }
2843
2844         target_voicescript_next(self);
2845 }
2846
2847 float isInvisibleString(string s)
2848 {
2849         float i, n, c;
2850         s = strdecolorize(s);
2851         for((i = 0), (n = strlen(s)); i < n; ++i)
2852         {
2853                 c = str2chr(s, i);
2854                 switch(c)
2855                 {
2856                         case 0:
2857                         case 32:
2858                         case 160:
2859                                 break;
2860                         default:
2861                                 return FALSE;
2862                 }
2863         }
2864         return TRUE;
2865 }
2866
2867 /*
2868 =============
2869 PlayerPostThink
2870
2871 Called every frame for each client after the physics are run
2872 =============
2873 */
2874 .float idlekick_lasttimeleft;
2875 .entity showheadshotbbox;
2876 void showheadshotbbox_think()
2877 {
2878         if(self.owner.showheadshotbbox != self)
2879         {
2880                 remove(self);
2881                 return;
2882         }
2883         self.nextthink = time;
2884         setorigin(self, self.owner.origin);
2885         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2886 }
2887 void PlayerPostThink (void)
2888 {
2889         // Savage: Check for nameless players
2890         if (isInvisibleString(self.netname)) {
2891                 self.netname = "Player";
2892                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2893         }
2894
2895         // send the clients accuracy stats to the client
2896         if(self.stat_count > 0)
2897         if(frametime)
2898         {
2899                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2900                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2901                 self.stat_count -= 1;
2902         }
2903
2904 #ifdef UID
2905         if(self.uid_kicktime)
2906         if(time > self.uid_kicktime)
2907         {
2908                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2909                 dropclient(self);
2910                 return;
2911         }
2912 #endif
2913
2914         if(sv_maxidle && frametime)
2915         {
2916                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2917                 float timeleft;
2918                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2919                 if(timeleft <= 0)
2920                 {
2921                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2922                         AnnounceTo(self, "terminated");
2923                         dropclient(self);
2924                         return;
2925                 }
2926                 else if(timeleft <= 10)
2927                 {
2928                         if(timeleft != self.idlekick_lasttimeleft)
2929                         {
2930                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2931                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2932                         }
2933                 }
2934                 else
2935                 {
2936                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2937                 }
2938                 self.idlekick_lasttimeleft = timeleft;
2939         }
2940
2941 #ifdef TETRIS
2942         if(self.impulse == 100)
2943                 ImpulseCommands();
2944         if (TetrisPostFrame())
2945                 return;
2946 #endif
2947
2948         CheatFrame();
2949
2950         if(self.classname == "player") {
2951                 CheckRules_Player();
2952                 UpdateChatBubble();
2953                 UpdateTeamBubble();
2954                 if (self.impulse)
2955                         ImpulseCommands();
2956                 if (intermission_running)
2957                         return;         // intermission or finale
2958                 GetPressedKeys();
2959         } else if (self.classname == "observer") {
2960                 //do nothing
2961         } else if (self.classname == "spectator") {
2962                 //do nothing
2963         }
2964
2965         /*
2966         float i;
2967         for(i = 0; i < 1000; ++i)
2968         {
2969                 vector end;
2970                 end = self.origin + '0 0 1024' + 512 * randomvec();
2971                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2972                 if(trace_fraction < 1)
2973                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2974                 {
2975                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2976                         break;
2977                 }
2978         }
2979         */
2980
2981         Arena_Warmup();
2982
2983         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2984
2985         if(self.waypointsprite_attachedforcarrier)
2986                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2987
2988         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2989         {
2990                 if(!self.showheadshotbbox)
2991                 {
2992                         self.showheadshotbbox = spawn();
2993                         self.showheadshotbbox.classname = "headshotbbox";
2994                         self.showheadshotbbox.owner = self;
2995                         self.showheadshotbbox.think = showheadshotbbox_think;
2996                         self.showheadshotbbox.nextthink = time;
2997                         self = self.showheadshotbbox;
2998                         self.think();
2999                         self = self.owner;
3000                 }
3001         }
3002         else
3003         {
3004                 if(self.showheadshotbbox)
3005                         remove(self.showheadshotbbox);
3006         }
3007
3008         playerdemo_write();
3009
3010         /*
3011         if(g_race)
3012                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3013         */
3014 }