Merge branch 'master' into terencehill/vehicles_fixes
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 float ClientData_Send(entity to, float sf)
10 {
11         if(to != self.owner)
12         {
13                 error("wtf");
14                 return FALSE;
15         }
16
17         entity e;
18
19         e = to;
20         if(IS_SPEC(to))
21                 e = to.enemy;
22
23         sf = 0;
24
25         if(e.race_completed)
26                 sf |= 1; // forced scoreboard
27         if(to.spectatee_status)
28                 sf |= 2; // spectator ent number follows
29         if(e.zoomstate)
30                 sf |= 4; // zoomed
31         if(e.porto_v_angle_held)
32                 sf |= 8; // angles held
33
34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
35         WriteByte(MSG_ENTITY, sf);
36
37         if(sf & 2)
38                 WriteByte(MSG_ENTITY, to.spectatee_status);
39
40         if(sf & 8)
41         {
42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
44         }
45
46         return TRUE;
47 }
48
49 void ClientData_Attach()
50 {
51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
52         self.clientdata.drawonlytoclient = self;
53         self.clientdata.owner = self;
54 }
55
56 void ClientData_Detach()
57 {
58         remove(self.clientdata);
59         self.clientdata = world;
60 }
61
62 void ClientData_Touch(entity e)
63 {
64         e.clientdata.SendFlags = 1;
65
66         // make it spectatable
67         entity e2;
68         FOR_EACH_REALCLIENT(e2)
69         {
70                 if(e2 != e)
71                         if(IS_SPEC(e2))
72                                 if(e2.enemy == e)
73                                         e2.clientdata.SendFlags = 1;
74         }
75 }
76
77 .string netname_previous;
78
79
80 /*
81 =============
82 CheckPlayerModel
83
84 Checks if the argument string can be a valid playermodel.
85 Returns a valid one in doubt.
86 =============
87 */
88 string FallbackPlayerModel;
89 string CheckPlayerModel(string plyermodel) {
90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
91         {
92                 // note: we cannot summon Don Strunzone here, some player may
93                 // still have the model string set. In case anyone manages how
94                 // to change a cvar default, we'll have a small leak here.
95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
96         }
97         // only in right path
98         if( substring(plyermodel,0,14) != "models/player/")
99                 return FallbackPlayerModel;
100         // only good file extensions
101         if(substring(plyermodel,-4,4) != ".zym")
102         if(substring(plyermodel,-4,4) != ".dpm")
103         if(substring(plyermodel,-4,4) != ".iqm")
104         if(substring(plyermodel,-4,4) != ".md3")
105         if(substring(plyermodel,-4,4) != ".psk")
106                 return FallbackPlayerModel;
107         // forbid the LOD models
108         if(substring(plyermodel, -9,5) == "_lod1")
109                 return FallbackPlayerModel;
110         if(substring(plyermodel, -9,5) == "_lod2")
111                 return FallbackPlayerModel;
112         if(plyermodel != strtolower(plyermodel))
113                 return FallbackPlayerModel;
114         // also, restrict to server models
115         if(autocvar_sv_servermodelsonly)
116         {
117                 if(!fexists(plyermodel))
118                         return FallbackPlayerModel;
119         }
120         return plyermodel;
121 }
122
123 void setplayermodel(entity e, string modelname)
124 {
125         precache_model(modelname);
126         setmodel(e, modelname);
127         player_setupanimsformodel();
128         UpdatePlayerSounds();
129 }
130
131 /*
132 =============
133 PutObserverInServer
134
135 putting a client as observer in the server
136 =============
137 */
138 void FixPlayermodel();
139 void PutObserverInServer (void)
140 {
141         entity  spot;
142     self.hud = HUD_NORMAL;
143         race_PreSpawnObserver();
144
145         spot = SelectSpawnPoint (TRUE);
146         if(!spot)
147                 error("No spawnpoints for observers?!?\n");
148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
149
150         if(IS_REAL_CLIENT(self))
151         {
152                 msg_entity = self;
153                 WriteByte(MSG_ONE, SVC_SETVIEW);
154                 WriteEntity(MSG_ONE, self);
155         }
156
157         if((g_race && g_race_qualifying) || g_cts)
158         {
159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
160                         self.frags = FRAGS_LMS_LOSER;
161                 else
162                         self.frags = FRAGS_SPECTATOR;
163         }
164         else
165                 self.frags = FRAGS_SPECTATOR;
166
167         MUTATOR_CALLHOOK(MakePlayerObserver);
168
169         Portal_ClearAll(self);
170
171         if(self.alivetime)
172         {
173                 if(!warmup_stage)
174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
175                 self.alivetime = 0;
176         }
177
178         if(self.vehicle)
179                 vehicles_exit(VHEF_RELESE);
180
181         WaypointSprite_PlayerDead();
182
183         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
185
186         if(self.killcount != -666)
187         {
188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
189
190                 if(self.just_joined == FALSE) {
191                         LogTeamchange(self.playerid, -1, 4);
192                 } else
193                         self.just_joined = FALSE;
194         }
195
196         PlayerScore_Clear(self); // clear scores when needed
197
198         accuracy_resend(self);
199
200         self.spectatortime = time;
201
202         self.classname = "observer";
203         self.iscreature = FALSE;
204         self.teleportable = TELEPORT_SIMPLE;
205         self.damagedbycontents = FALSE;
206         self.health = -666;
207         self.takedamage = DAMAGE_NO;
208         self.solid = SOLID_NOT;
209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
210         self.flags = FL_CLIENT | FL_NOTARGET;
211         self.armorvalue = 666;
212         self.effects = 0;
213         self.armorvalue = autocvar_g_balance_armor_start;
214         self.pauserotarmor_finished = 0;
215         self.pauserothealth_finished = 0;
216         self.pauseregen_finished = 0;
217         self.damageforcescale = 0;
218         self.death_time = 0;
219         self.respawn_flags = 0;
220         self.respawn_time = 0;
221         self.stat_respawn_time = 0;
222         self.alpha = 0;
223         self.scale = 0;
224         self.fade_time = 0;
225         self.pain_frame = 0;
226         self.pain_finished = 0;
227         self.strength_finished = 0;
228         self.invincible_finished = 0;
229         self.superweapons_finished = 0;
230         self.pushltime = 0;
231         self.istypefrag = 0;
232         self.think = func_null;
233         self.nextthink = 0;
234         self.hook_time = 0;
235         self.deadflag = DEAD_NO;
236         self.angles = spot.angles;
237         self.angles_z = 0;
238         self.fixangle = TRUE;
239         self.crouch = FALSE;
240
241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
242         self.prevorigin = self.origin;
243         self.items = 0;
244         self.weapons = '0 0 0';
245         self.model = "";
246         FixPlayermodel();
247         setmodel(self, "null");
248         self.drawonlytoclient = self;
249
250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
252
253         self.weapon = 0;
254         self.weaponname = "";
255         self.switchingweapon = 0;
256         self.weaponmodel = "";
257         self.weaponentity = world;
258         self.exteriorweaponentity = world;
259         self.killcount = -666;
260         self.velocity = '0 0 0';
261         self.avelocity = '0 0 0';
262         self.punchangle = '0 0 0';
263         self.punchvector = '0 0 0';
264         self.oldvelocity = self.velocity;
265         self.fire_endtime = -1;
266 }
267
268 .float model_randomizer;
269 void FixPlayermodel()
270 {
271         string defaultmodel;
272         float defaultskin, chmdl, oldskin, n, i;
273         vector m1, m2;
274
275         defaultmodel = "";
276         defaultskin = 0;
277         chmdl = FALSE;
278
279         if(autocvar_sv_defaultcharacter == 1)
280         {
281                 if(teamplay)
282                 {
283                         string s;
284                         s = Team_ColorName_Lower(self.team);
285                         if(s != "neutral")
286                         {
287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
289                         }
290                 }
291
292                 if(defaultmodel == "")
293                 {
294                         defaultmodel = autocvar_sv_defaultplayermodel;
295                         defaultskin = autocvar_sv_defaultplayerskin;
296                 }
297
298                 n = tokenize_console(defaultmodel);
299                 if(n > 0)
300                 {
301                         defaultmodel = argv(floor(n * self.model_randomizer));
302                         // However, do NOT randomize if the player-selected model is in the list.
303                         for (i = 0; i < n; ++i)
304                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
305                                         defaultmodel = argv(i);
306                 }
307
308                 i = strstrofs(defaultmodel, ":", 0);
309                 if(i >= 0)
310                 {
311                         defaultskin = stof(substring(defaultmodel, i+1, -1));
312                         defaultmodel = substring(defaultmodel, 0, i);
313                 }
314         }
315
316         if(defaultmodel != "")
317         {
318                 if (defaultmodel != self.model)
319                 {
320                         m1 = self.mins;
321                         m2 = self.maxs;
322                         setplayermodel (self, defaultmodel);
323                         setsize (self, m1, m2);
324                         chmdl = TRUE;
325                 }
326
327                 oldskin = self.skin;
328                 self.skin = defaultskin;
329         } else {
330                 if (self.playermodel != self.model || self.playermodel == "")
331                 {
332                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
333                         m1 = self.mins;
334                         m2 = self.maxs;
335                         setplayermodel (self, self.playermodel);
336                         setsize (self, m1, m2);
337                         chmdl = TRUE;
338                 }
339
340                 oldskin = self.skin;
341                 self.skin = stof(self.playerskin);
342         }
343
344         if(chmdl || oldskin != self.skin) // model or skin has changed
345         {
346                 self.species = player_getspecies(); // update species
347                 UpdatePlayerSounds(); // update skin sounds
348         }
349
350         if(!teamplay)
351                 if(strlen(autocvar_sv_defaultplayercolors))
352                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
353                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
354 }
355
356 /*
357 =============
358 PutClientInServer
359
360 Called when a client spawns in the server
361 =============
362 */
363 void PutClientInServer (void)
364 {
365         if(IS_BOT_CLIENT(self))
366                 self.classname = "player";
367         else if(IS_REAL_CLIENT(self))
368         {
369                 msg_entity = self;
370                 WriteByte(MSG_ONE, SVC_SETVIEW);
371                 WriteEntity(MSG_ONE, self);
372         }
373
374         // reset player keys
375         self.itemkeys = 0;
376
377         MUTATOR_CALLHOOK(PutClientInServer);
378
379         if(gameover)
380                 self.classname = "observer";
381
382         if(IS_PLAYER(self))
383         {
384                 entity spot, oldself;
385                 float j;
386
387                 accuracy_resend(self);
388
389                 if(self.team < 0)
390                         JoinBestTeam(self, FALSE, TRUE);
391
392                 race_PreSpawn();
393
394                 spot = SelectSpawnPoint (FALSE);
395                 if(!spot)
396                 {
397                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
398                         return; // spawn failed
399                 }
400
401                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
402
403                 if(self.vehicle)
404                         vehicles_exit(VHEF_RELESE);
405
406                 self.classname = "player";
407                 self.wasplayer = TRUE;
408                 self.iscreature = TRUE;
409                 self.teleportable = TELEPORT_NORMAL;
410                 self.damagedbycontents = TRUE;
411                 self.movetype = MOVETYPE_WALK;
412                 self.solid = SOLID_SLIDEBOX;
413                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
414                 if(autocvar_g_playerclip_collisions)
415                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
416                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
417                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
418                 self.frags = FRAGS_PLAYER;
419                 if(INDEPENDENT_PLAYERS)
420                         MAKE_INDEPENDENT_PLAYER(self);
421                 self.flags = FL_CLIENT;
422                 if(autocvar__notarget)
423                         self.flags |= FL_NOTARGET;
424                 self.takedamage = DAMAGE_AIM;
425                 self.effects = 0;
426                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
427                 self.air_finished = time + 12;
428                 self.dmg = 2;
429                 if(autocvar_g_balance_nex_charge)
430                 {
431                         if(autocvar_g_balance_nex_secondary_chargepool)
432                                 self.nex_chargepool_ammo = 1;
433                         self.nex_charge = autocvar_g_balance_nex_charge_start;
434                 }
435
436                 if(warmup_stage)
437                 {
438                         self.ammo_shells = warmup_start_ammo_shells;
439                         self.ammo_nails = warmup_start_ammo_nails;
440                         self.ammo_rockets = warmup_start_ammo_rockets;
441                         self.ammo_cells = warmup_start_ammo_cells;
442                         self.ammo_fuel = warmup_start_ammo_fuel;
443                         self.health = warmup_start_health;
444                         self.armorvalue = warmup_start_armorvalue;
445                         self.weapons = WARMUP_START_WEAPONS;
446                 }
447                 else
448                 {
449                         self.ammo_shells = start_ammo_shells;
450                         self.ammo_nails = start_ammo_nails;
451                         self.ammo_rockets = start_ammo_rockets;
452                         self.ammo_cells = start_ammo_cells;
453                         self.ammo_fuel = start_ammo_fuel;
454                         self.health = start_health;
455                         self.armorvalue = start_armorvalue;
456                         self.weapons = start_weapons;
457                 }
458
459                 if(self.weapons & WEPSET_SUPERWEAPONS)
460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
461                 else
462                         self.superweapons_finished = 0;
463
464                 if(g_weaponarena_random)
465                 {
466                         if(g_weaponarena_random_with_laser)
467                                 self.weapons &= ~WEPSET_LASER;
468                         W_RandomWeapons(self, g_weaponarena_random);
469                         if(g_weaponarena_random_with_laser)
470                                 self.weapons |= WEPSET_LASER;
471                 }
472
473                 self.items = start_items;
474
475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
480                 //extend the pause of rotting if client was reset at the beginning of the countdown
481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
482                         self.spawnshieldtime += game_starttime - time;
483                         self.pauserotarmor_finished += game_starttime - time;
484                         self.pauserothealth_finished += game_starttime - time;
485                         self.pauseregen_finished += game_starttime - time;
486                 }
487                 self.damageforcescale = 2;
488                 self.death_time = 0;
489                 self.respawn_flags = 0;
490                 self.respawn_time = 0;
491                 self.stat_respawn_time = 0;
492                 self.scale = 0;
493                 self.fade_time = 0;
494                 self.pain_frame = 0;
495                 self.pain_finished = 0;
496                 self.strength_finished = 0;
497                 self.invincible_finished = 0;
498                 self.pushltime = 0;
499                 // players have no think function
500                 self.think = func_null;
501                 self.nextthink = 0;
502                 self.hook_time = 0;
503                 self.dmg_team = 0;
504                 self.ballistics_density = autocvar_g_ballistics_density_player;
505
506                 self.metertime = 0;
507
508                 self.deadflag = DEAD_NO;
509
510                 self.angles = spot.angles;
511
512                 self.angles_z = 0; // never spawn tilted even if the spot says to
513                 self.fixangle = TRUE; // turn this way immediately
514                 self.velocity = '0 0 0';
515                 self.avelocity = '0 0 0';
516                 self.punchangle = '0 0 0';
517                 self.punchvector = '0 0 0';
518                 self.oldvelocity = self.velocity;
519                 self.fire_endtime = -1;
520
521                 entity spawnevent = spawn();
522                 spawnevent.owner = self;
523                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
524
525                 self.model = "";
526                 FixPlayermodel();
527                 self.drawonlytoclient = world;
528
529                 self.crouch = FALSE;
530                 self.view_ofs = PL_VIEW_OFS;
531                 setsize (self, PL_MIN, PL_MAX);
532                 self.spawnorigin = spot.origin;
533                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
534                 // don't reset back to last position, even if new position is stuck in solid
535                 self.oldorigin = self.origin;
536                 self.prevorigin = self.origin;
537                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
538                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
539         self.hud = HUD_NORMAL;
540
541                 self.event_damage = PlayerDamage;
542
543                 self.bot_attack = TRUE;
544
545                 self.statdraintime = time + 5;
546                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
547
548                 if(self.killcount == -666) {
549                         PlayerScore_Clear(self);
550                         self.killcount = 0;
551                 }
552
553                 CL_SpawnWeaponentity();
554                 self.alpha = default_player_alpha;
555                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
556                 self.exteriorweaponentity.alpha = default_weapon_alpha;
557
558                 self.speedrunning = FALSE;
559
560                 race_PostSpawn(spot);
561
562                 //stuffcmd(self, "chase_active 0");
563                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
564
565                 target_voicescript_clear(self);
566
567                 // reset fields the weapons may use
568                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
569                 {
570                         weapon_action(j, WR_RESETPLAYER);
571
572                         // all weapons must be fully loaded when we spawn
573                         entity e;
574                         e = get_weaponinfo(j);
575                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
576                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
577                 }
578
579                 oldself = self;
580                 self = spot;
581                         activator = oldself;
582                                 string s;
583                                 s = self.target;
584                                 self.target = string_null;
585                                 SUB_UseTargets();
586                                 self.target = s;
587                         activator = world;
588                 self = oldself;
589
590                 spawn_spot = spot;
591                 MUTATOR_CALLHOOK(PlayerSpawn);
592
593                 if(autocvar_spawn_debug)
594                 {
595                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
596                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
597                 }
598
599                 self.switchweapon = w_getbestweapon(self);
600                 self.cnt = -1; // W_LastWeapon will not complain
601                 self.weapon = 0;
602                 self.weaponname = "";
603                 self.switchingweapon = 0;
604
605                 if(!warmup_stage)
606                         if(!self.alivetime)
607                                 self.alivetime = time;
608
609                 antilag_clear(self);
610         }
611         else if(IS_OBSERVER(self))
612         {
613                 PutObserverInServer ();
614         }
615 }
616
617 .float ebouncefactor, ebouncestop; // electro's values
618 // TODO do we need all these fields, or should we stop autodetecting runtime
619 // changes and just have a console command to update this?
620 float ClientInit_SendEntity(entity to, float sf)
621 {
622         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
623         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
636         if(sv_foginterval && world.fog != "")
637                 WriteString(MSG_ENTITY, world.fog);
638         else
639                 WriteString(MSG_ENTITY, "");
640         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
641         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
642         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
643         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
644         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
645         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
646         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
647         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
648         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
649         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
650         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
651         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
652         return TRUE;
653 }
654
655 void ClientInit_CheckUpdate()
656 {
657         self.nextthink = time;
658         if(self.count != autocvar_g_balance_armor_blockpercent)
659         {
660                 self.count = autocvar_g_balance_armor_blockpercent;
661                 self.SendFlags |= 1;
662         }
663         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
664         {
665                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
666                 self.SendFlags |= 1;
667         }
668         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
669         {
670                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
671                 self.SendFlags |= 1;
672         }
673         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
674         {
675                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
676                 self.SendFlags |= 1;
677         }
678         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
679         {
680                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
681                 self.SendFlags |= 1;
682         }
683 }
684
685 void ClientInit_Spawn()
686 {
687         entity o;
688         entity e;
689         e = spawn();
690         e.classname = "clientinit";
691         e.think = ClientInit_CheckUpdate;
692         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
693
694         o = self;
695         self = e;
696         ClientInit_CheckUpdate();
697         self = o;
698 }
699
700 /*
701 =============
702 SetNewParms
703 =============
704 */
705 void SetNewParms (void)
706 {
707         // initialize parms for a new player
708         parm1 = -(86400 * 366);
709 }
710
711 /*
712 =============
713 SetChangeParms
714 =============
715 */
716 void SetChangeParms (void)
717 {
718         // save parms for level change
719         parm1 = self.parm_idlesince - time;
720 }
721
722 /*
723 =============
724 DecodeLevelParms
725 =============
726 */
727 void DecodeLevelParms (void)
728 {
729         // load parms
730         self.parm_idlesince = parm1;
731         if(self.parm_idlesince == -(86400 * 366))
732                 self.parm_idlesince = time;
733
734         // whatever happens, allow 60 seconds of idling directly after connect for map loading
735         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
736 }
737
738 /*
739 =============
740 ClientKill
741
742 Called when a client types 'kill' in the console
743 =============
744 */
745
746 .float clientkill_nexttime;
747 void ClientKill_Now_TeamChange()
748 {
749         if(self.killindicator_teamchange == -1)
750         {
751                 JoinBestTeam( self, FALSE, TRUE );
752         }
753         else if(self.killindicator_teamchange == -2)
754         {
755                 if(blockSpectators)
756                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
757                 PutObserverInServer();
758         }
759         else
760                 SV_ChangeTeam(self.killindicator_teamchange - 1);
761         self.killindicator_teamchange = 0;
762 }
763
764 void ClientKill_Now()
765 {
766         if(self.vehicle)
767         {
768             vehicles_exit(VHEF_RELESE);
769             if(!self.killindicator_teamchange)
770             {
771             self.vehicle_health = -1;
772             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
773             }
774         }
775
776         if(self.killindicator && !wasfreed(self.killindicator))
777                 remove(self.killindicator);
778
779         self.killindicator = world;
780
781         if(self.killindicator_teamchange)
782                 ClientKill_Now_TeamChange();
783
784         // in any case:
785         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
786
787         // now I am sure the player IS dead
788 }
789 void KillIndicator_Think()
790 {
791         if (gameover)
792         {
793                 self.owner.killindicator = world;
794                 remove(self);
795                 return;
796         }
797
798         if (self.owner.alpha < 0 && !self.owner.vehicle)
799         {
800                 self.owner.killindicator = world;
801                 remove(self);
802                 return;
803         }
804
805         if(self.cnt <= 0)
806         {
807                 self = self.owner;
808                 ClientKill_Now(); // no oldself needed
809                 return;
810         }
811     else if(g_cts && self.health == 1) // health == 1 means that it's silent
812     {
813         self.nextthink = time + 1;
814         self.cnt -= 1;
815     }
816         else
817         {
818                 if(self.cnt <= 10)
819                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
820                 if(IS_REAL_CLIENT(self.owner))
821                 {
822                         if(self.cnt <= 10)
823                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
824                 }
825                 self.nextthink = time + 1;
826                 self.cnt -= 1;
827         }
828 }
829
830 float clientkilltime;
831 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
832 {
833         float killtime;
834         float starttime;
835         entity e;
836
837         if (gameover)
838                 return;
839
840         killtime = autocvar_g_balance_kill_delay;
841
842         if(g_race_qualifying || g_cts)
843                 killtime = 0;
844
845     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
846     {
847                 remove(self.killindicator);
848                 self.killindicator = world;
849
850         ClientKill_Now(); // allow instant kill in this case
851         return;
852     }
853
854         self.killindicator_teamchange = targetteam;
855
856     if(!self.killindicator)
857         {
858                 if(self.deadflag == DEAD_NO)
859                 {
860                         killtime = max(killtime, self.clientkill_nexttime - time);
861                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
862                 }
863
864                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
865                 {
866                         ClientKill_Now();
867                 }
868                 else
869                 {
870                         starttime = max(time, clientkilltime);
871
872                         self.killindicator = spawn();
873                         self.killindicator.owner = self;
874                         self.killindicator.scale = 0.5;
875                         setattachment(self.killindicator, self, "");
876                         setorigin(self.killindicator, '0 0 52');
877                         self.killindicator.think = KillIndicator_Think;
878                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
879                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
880                         self.killindicator.cnt = ceil(killtime);
881                         self.killindicator.count = bound(0, ceil(killtime), 10);
882                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
883
884                         for(e = world; (e = find(e, classname, "body")) != world; )
885                         {
886                                 if(e.enemy != self)
887                                         continue;
888                                 e.killindicator = spawn();
889                                 e.killindicator.owner = e;
890                                 e.killindicator.scale = 0.5;
891                                 setattachment(e.killindicator, e, "");
892                                 setorigin(e.killindicator, '0 0 52');
893                                 e.killindicator.think = KillIndicator_Think;
894                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
895                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
896                                 e.killindicator.cnt = ceil(killtime);
897                         }
898                         self.lip = 0;
899                 }
900         }
901         if(self.killindicator)
902         {
903                 if(targetteam == 0) // just die
904                 {
905                         self.killindicator.colormod = '0 0 0';
906                         if(IS_REAL_CLIENT(self))
907                         if(self.killindicator.cnt > 0)
908                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
909                 }
910                 else if(targetteam == -1) // auto
911                 {
912                         self.killindicator.colormod = '0 1 0';
913                         if(IS_REAL_CLIENT(self))
914                         if(self.killindicator.cnt > 0)
915                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
916                 }
917                 else if(targetteam == -2) // spectate
918                 {
919                         self.killindicator.colormod = '0.5 0.5 0.5';
920                         if(IS_REAL_CLIENT(self))
921                         if(self.killindicator.cnt > 0)
922                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
923                 }
924                 else
925                 {
926                         self.killindicator.colormod = Team_ColorRGB(targetteam);
927                         if(IS_REAL_CLIENT(self))
928                         if(self.killindicator.cnt > 0)
929                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
930                 }
931         }
932
933 }
934
935 void ClientKill (void)
936 {
937         if(gameover) return;
938         if(self.player_blocked) return;
939         if(self.freezetag_frozen) return;
940
941         ClientKill_TeamChange(0);
942 }
943
944 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
945 {
946     e.killindicator = spawn();
947     e.killindicator.owner = e;
948     e.killindicator.think = KillIndicator_Think;
949     e.killindicator.nextthink = time + (e.lip) * 0.05;
950     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
951     e.killindicator.health = 1; // this is used to indicate that it should be silent
952     e.lip = 0;
953 }
954
955 void FixClientCvars(entity e)
956 {
957         // send prediction settings to the client
958         stuffcmd(e, "\nin_bindmap 0 0\n");
959         if(g_race || g_cts)
960                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
961         if(autocvar_g_antilag == 3) // client side hitscan
962                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
963         if(autocvar_sv_gentle)
964                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
965         /*
966          * we no longer need to stuff this. Remove this comment block if you feel
967          * 2.3 and higher (or was it 2.2.3?) don't need these any more
968         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
969         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
970         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
971         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
972         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
973         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
974         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
975         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
976         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
977         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
978         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
979         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
980         stuffcmd(e, "cl_movement_edgefriction 1\n");
981          */
982 }
983
984 float PlayerInIDList(entity p, string idlist)
985 {
986         float n, i;
987         string s;
988
989         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
990         if (!p.crypto_idfp)
991                 return 0;
992
993         // this function allows abbreviated player IDs too!
994         n = tokenize_console(idlist);
995         for(i = 0; i < n; ++i)
996         {
997                 s = argv(i);
998                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
999                         return 1;
1000         }
1001
1002         return 0;
1003 }
1004
1005 /*
1006 =============
1007 ClientConnect
1008
1009 Called when a client connects to the server
1010 =============
1011 */
1012 void DecodeLevelParms (void);
1013 //void dom_player_join_team(entity pl);
1014 void set_dom_state(entity e);
1015 void ClientConnect (void)
1016 {
1017         float t;
1018
1019         if(IS_CLIENT(self))
1020         {
1021                 print("Warning: ClientConnect, but already connected!\n");
1022                 return;
1023         }
1024
1025         if(Ban_MaybeEnforceBanOnce(self))
1026                 return;
1027
1028         DecodeLevelParms();
1029
1030 #ifdef WATERMARK
1031         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1032 #endif
1033
1034         self.classname = "player_joining";
1035
1036         self.flags = FL_CLIENT;
1037         self.version_nagtime = time + 10 + random() * 10;
1038
1039         if(player_count<0)
1040         {
1041                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1042                 player_count = 0;
1043         }
1044
1045         PlayerScore_Attach(self);
1046         ClientData_Attach();
1047         accuracy_init(self);
1048
1049         bot_clientconnect();
1050
1051         playerdemo_init();
1052
1053         anticheat_init();
1054
1055         race_PreSpawnObserver();
1056
1057         // identify the right forced team
1058         if(autocvar_g_campaign)
1059         {
1060                 if(IS_REAL_CLIENT(self)) // only players, not bots
1061                 {
1062                         switch(autocvar_g_campaign_forceteam)
1063                         {
1064                                 case 1: self.team_forced = NUM_TEAM_1; break;
1065                                 case 2: self.team_forced = NUM_TEAM_2; break;
1066                                 case 3: self.team_forced = NUM_TEAM_3; break;
1067                                 case 4: self.team_forced = NUM_TEAM_4; break;
1068                                 default: self.team_forced = 0;
1069                         }
1070                 }
1071         }
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1073                 self.team_forced = NUM_TEAM_1;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1075                 self.team_forced = NUM_TEAM_2;
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1077                 self.team_forced = NUM_TEAM_3;
1078         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1079                 self.team_forced = NUM_TEAM_4;
1080         else if(autocvar_g_forced_team_otherwise == "red")
1081                 self.team_forced = NUM_TEAM_1;
1082         else if(autocvar_g_forced_team_otherwise == "blue")
1083                 self.team_forced = NUM_TEAM_2;
1084         else if(autocvar_g_forced_team_otherwise == "yellow")
1085                 self.team_forced = NUM_TEAM_3;
1086         else if(autocvar_g_forced_team_otherwise == "pink")
1087                 self.team_forced = NUM_TEAM_4;
1088         else if(autocvar_g_forced_team_otherwise == "spectate")
1089                 self.team_forced = -1;
1090         else if(autocvar_g_forced_team_otherwise == "spectator")
1091                 self.team_forced = -1;
1092         else
1093                 self.team_forced = 0;
1094
1095         if(!teamplay)
1096                 if(self.team_forced > 0)
1097                         self.team_forced = 0;
1098
1099         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1100
1101         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1102                 self.classname = "observer";
1103         } else {
1104                 if(teamplay)
1105                 {
1106                         if(autocvar_g_balance_teams)
1107                         {
1108                                 self.classname = "player";
1109                                 campaign_bots_may_start = 1;
1110                         }
1111                         else
1112                         {
1113                                 self.classname = "observer"; // do it anyway
1114                         }
1115                 }
1116                 else
1117                 {
1118                         self.classname = "player";
1119                         campaign_bots_may_start = 1;
1120                 }
1121         }
1122
1123         self.playerid = (playerid_last = playerid_last + 1);
1124
1125         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1126
1127     if(IS_BOT_CLIENT(self))
1128         PlayerStats_AddPlayer(self);
1129
1130         if(autocvar_sv_eventlog)
1131                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1132
1133         LogTeamchange(self.playerid, self.team, 1);
1134
1135         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1136
1137         self.netname_previous = strzone(self.netname);
1138
1139         if(IS_PLAYER(self) && teamplay)
1140                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1141         else
1142                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1143
1144         stuffcmd(self, strcat(clientstuff, "\n"));
1145         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1146
1147         FixClientCvars(self);
1148
1149         // spawnfunc_waypoint sprites
1150         WaypointSprite_InitClient(self);
1151
1152         // Wazat's grappling hook
1153         SetGrappleHookBindings();
1154
1155         // get version info from player
1156         stuffcmd(self, "cmd clientversion $gameversion\n");
1157
1158         // get other cvars from player
1159         GetCvars(0);
1160
1161         // notify about available teams
1162         if(teamplay)
1163         {
1164                 CheckAllowedTeams(self);
1165                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1166                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1167         }
1168         else
1169                 stuffcmd(self, "set _teams_available 0\n");
1170
1171         attach_entcs();
1172
1173         bot_relinkplayerlist();
1174
1175         self.spectatortime = time;
1176         if(blockSpectators)
1177         {
1178                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1179         }
1180
1181         self.jointime = time;
1182         self.allowed_timeouts = autocvar_sv_timeout_number;
1183
1184         if(IS_REAL_CLIENT(self))
1185         {
1186                 if(!autocvar_g_campaign)
1187                 {
1188                         self.motd_actived_time = -1;
1189                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1190                 }
1191
1192                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1193                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1194         }
1195
1196         if(!sv_foginterval && world.fog != "")
1197                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1198
1199         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1200         {
1201                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1202                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1203         }
1204         else
1205                 self.hitplotfh = -1;
1206
1207         if(g_race || g_cts) {
1208                 string rr;
1209                 if(g_cts)
1210                         rr = CTS_RECORD;
1211                 else
1212                         rr = RACE_RECORD;
1213
1214                 msg_entity = self;
1215                 race_send_recordtime(MSG_ONE);
1216                 race_send_speedaward(MSG_ONE);
1217
1218                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1219                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1220                 race_send_speedaward_alltimebest(MSG_ONE);
1221
1222                 float i;
1223                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1224                         race_SendRankings(i, 0, 0, MSG_ONE);
1225                 }
1226         }
1227         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1228                 send_CSQC_teamnagger();
1229
1230         CheatInitClient();
1231
1232         CSQCMODEL_AUTOINIT();
1233
1234         self.model_randomizer = random();
1235
1236         if(IS_REAL_CLIENT(self))
1237                 sv_notice_join();
1238
1239         MUTATOR_CALLHOOK(ClientConnect);
1240 }
1241 /*
1242 =============
1243 ClientDisconnect
1244
1245 Called when a client disconnects from the server
1246 =============
1247 */
1248 .entity chatbubbleentity;
1249 void ReadyCount();
1250 void ClientDisconnect (void)
1251 {
1252         if(self.vehicle)
1253             vehicles_exit(VHEF_RELESE);
1254
1255         if (!IS_CLIENT(self))
1256         {
1257                 print("Warning: ClientDisconnect without ClientConnect\n");
1258                 return;
1259         }
1260
1261         PlayerStats_AddGlobalInfo(self);
1262
1263         CheatShutdownClient();
1264
1265         if(self.hitplotfh >= 0)
1266         {
1267                 fclose(self.hitplotfh);
1268                 self.hitplotfh = -1;
1269         }
1270
1271         anticheat_report();
1272         anticheat_shutdown();
1273
1274         playerdemo_shutdown();
1275
1276         bot_clientdisconnect();
1277
1278         if(self.entcs)
1279                 detach_entcs();
1280
1281         if(autocvar_sv_eventlog)
1282                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1283
1284         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1285
1286         MUTATOR_CALLHOOK(ClientDisconnect);
1287
1288         Portal_ClearAll(self);
1289
1290         RemoveGrapplingHook(self);
1291
1292         // Here, everything has been done that requires this player to be a client.
1293
1294         self.flags &= ~FL_CLIENT;
1295
1296         if (self.chatbubbleentity)
1297                 remove (self.chatbubbleentity);
1298
1299         if (self.killindicator)
1300                 remove (self.killindicator);
1301
1302         WaypointSprite_PlayerGone();
1303
1304         bot_relinkplayerlist();
1305
1306         accuracy_free(self);
1307         ClientData_Detach();
1308         PlayerScore_Detach(self);
1309
1310         if(self.netname_previous)
1311                 strunzone(self.netname_previous);
1312         if(self.clientstatus)
1313                 strunzone(self.clientstatus);
1314         if(self.weaponorder_byimpulse)
1315                 strunzone(self.weaponorder_byimpulse);
1316
1317         ClearPlayerSounds();
1318
1319         if(self.personal)
1320                 remove(self.personal);
1321
1322         self.playerid = 0;
1323         ReadyCount();
1324
1325         // free cvars
1326         GetCvars(-1);
1327 }
1328
1329 .float BUTTON_CHAT;
1330 void ChatBubbleThink()
1331 {
1332         self.nextthink = time;
1333         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1334         {
1335                 if(self.owner) // but why can that ever be world?
1336                         self.owner.chatbubbleentity = world;
1337                 remove(self);
1338                 return;
1339         }
1340         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1341 #ifdef TETRIS
1342                 || self.owner.tetris_on
1343 #endif
1344         )
1345                 self.model = self.mdl;
1346         else
1347                 self.model = "";
1348 }
1349
1350 void UpdateChatBubble()
1351 {
1352         if (self.alpha < 0)
1353                 return;
1354         // spawn a chatbubble entity if needed
1355         if (!self.chatbubbleentity)
1356         {
1357                 self.chatbubbleentity = spawn();
1358                 self.chatbubbleentity.owner = self;
1359                 self.chatbubbleentity.exteriormodeltoclient = self;
1360                 self.chatbubbleentity.think = ChatBubbleThink;
1361                 self.chatbubbleentity.nextthink = time;
1362                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1363                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1364                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1365                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1366                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1367                 self.chatbubbleentity.model = "";
1368                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1369         }
1370 }
1371
1372
1373 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1374 // added to the model skins
1375 /*void UpdateColorModHack()
1376 {
1377         float c;
1378         c = self.clientcolors & 15;
1379         // LordHavoc: only bothering to support white, green, red, yellow, blue
1380              if (!teamplay) self.colormod = '0 0 0';
1381         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1382         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1383         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1384         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1385         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1386         else self.colormod = '1 1 1';
1387 }*/
1388
1389 void respawn(void)
1390 {
1391         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1392         {
1393                 self.solid = SOLID_NOT;
1394                 self.takedamage = DAMAGE_NO;
1395                 self.movetype = MOVETYPE_FLY;
1396                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1397                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1398                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1399                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1400                 if(autocvar_g_respawn_ghosts_maxtime)
1401                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1402         }
1403
1404         CopyBody(1);
1405
1406         self.effects |= EF_NODRAW; // prevent another CopyBody
1407         PutClientInServer();
1408 }
1409
1410 void play_countdown(float finished, string samp)
1411 {
1412         if(IS_REAL_CLIENT(self))
1413                 if(floor(finished - time - frametime) != floor(finished - time))
1414                         if(finished - time < 6)
1415                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1416 }
1417
1418 void player_powerups (void)
1419 {
1420         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1421         olditems = self.items;
1422
1423         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1424                 self.modelflags |= MF_ROCKET;
1425         else
1426                 self.modelflags &= ~MF_ROCKET;
1427
1428         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1429
1430         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1431                 return;
1432
1433         Fire_ApplyDamage(self);
1434         Fire_ApplyEffect(self);
1435
1436         if (!g_minstagib)
1437         {
1438                 if (self.items & IT_STRENGTH)
1439                 {
1440                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1441                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1442                         if (time > self.strength_finished)
1443                         {
1444                                 self.items = self.items - (self.items & IT_STRENGTH);
1445                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1446                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1447                         }
1448                 }
1449                 else
1450                 {
1451                         if (time < self.strength_finished)
1452                         {
1453                                 self.items = self.items | IT_STRENGTH;
1454                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1455                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1456                         }
1457                 }
1458                 if (self.items & IT_INVINCIBLE)
1459                 {
1460                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1461                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1462                         if (time > self.invincible_finished)
1463                         {
1464                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1465                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1466                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1467                         }
1468                 }
1469                 else
1470                 {
1471                         if (time < self.invincible_finished)
1472                         {
1473                                 self.items = self.items | IT_INVINCIBLE;
1474                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1475                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1476                         }
1477                 }
1478                 if (self.items & IT_SUPERWEAPON)
1479                 {
1480                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1481                         {
1482                                 self.superweapons_finished = 0;
1483                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1484                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1485                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1486                         }
1487                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1488                         {
1489                                 // don't let them run out
1490                         }
1491                         else
1492                         {
1493                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1494                                 if (time > self.superweapons_finished)
1495                                 {
1496                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1497                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1498                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1499                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1500                                 }
1501                         }
1502                 }
1503                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1504                 {
1505                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1506                         {
1507                                 self.items = self.items | IT_SUPERWEAPON;
1508                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1509                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1510                         }
1511                         else
1512                         {
1513                                 self.superweapons_finished = 0;
1514                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1515                         }
1516                 }
1517                 else
1518                 {
1519                         self.superweapons_finished = 0;
1520                 }
1521         }
1522
1523         if(autocvar_g_nodepthtestplayers)
1524                 self.effects = self.effects | EF_NODEPTHTEST;
1525
1526         if(autocvar_g_fullbrightplayers)
1527                 self.effects = self.effects | EF_FULLBRIGHT;
1528
1529         if (time >= game_starttime)
1530         if (time < self.spawnshieldtime)
1531                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1532
1533         MUTATOR_CALLHOOK(PlayerPowerups);
1534 }
1535
1536 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1537 {
1538         if(current > stable)
1539                 return current;
1540         else if(current > stable - 0.25) // when close enough, "snap"
1541                 return stable;
1542         else
1543                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1544 }
1545
1546 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1547 {
1548         if(current < stable)
1549                 return current;
1550         else if(current < stable + 0.25) // when close enough, "snap"
1551                 return stable;
1552         else
1553                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1554 }
1555
1556 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1557 {
1558         if(current > rotstable)
1559         {
1560                 if(rotframetime > 0)
1561                 {
1562                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1563                         current = max(rotstable, current - rotlinear * rotframetime);
1564                 }
1565         }
1566         else if(current < regenstable)
1567         {
1568                 if(regenframetime > 0)
1569                 {
1570                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1571                         current = min(regenstable, current + regenlinear * regenframetime);
1572                 }
1573         }
1574
1575         if(current > limit)
1576                 current = limit;
1577
1578         return current;
1579 }
1580
1581 void player_regen (void)
1582 {
1583         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1584         maxh = autocvar_g_balance_health_rotstable;
1585         maxa = autocvar_g_balance_armor_rotstable;
1586         maxf = autocvar_g_balance_fuel_rotstable;
1587         minh = autocvar_g_balance_health_regenstable;
1588         mina = autocvar_g_balance_armor_regenstable;
1589         minf = autocvar_g_balance_fuel_regenstable;
1590         limith = autocvar_g_balance_health_limit;
1591         limita = autocvar_g_balance_armor_limit;
1592         limitf = autocvar_g_balance_fuel_limit;
1593
1594         max_mod = regen_mod = rot_mod = limit_mod = 1;
1595
1596         maxh = maxh * max_mod;
1597         //maxa = maxa * max_mod;
1598         //maxf = maxf * max_mod;
1599         minh = minh * max_mod;
1600         //mina = mina * max_mod;
1601         //minf = minf * max_mod;
1602         limith = limith * limit_mod;
1603         limita = limita * limit_mod;
1604         //limitf = limitf * limit_mod;
1605
1606         if(g_ca)
1607                 rot_mod = 0;
1608
1609         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1610         {
1611                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1612                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1613
1614                 // if player rotted to death...  die!
1615                 if(self.health < 1)
1616                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1617         }
1618
1619         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1620                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1621 }
1622
1623 float zoomstate_set;
1624 void SetZoomState(float z)
1625 {
1626         if(z != self.zoomstate)
1627         {
1628                 self.zoomstate = z;
1629                 ClientData_Touch(self);
1630         }
1631         zoomstate_set = 1;
1632 }
1633
1634 void GetPressedKeys(void) {
1635         MUTATOR_CALLHOOK(GetPressedKeys);
1636         if (self.movement_x > 0) // get if movement keys are pressed
1637         {       // forward key pressed
1638                 self.pressedkeys |= KEY_FORWARD;
1639                 self.pressedkeys &= ~KEY_BACKWARD;
1640         }
1641         else if (self.movement_x < 0)
1642         {       // backward key pressed
1643                 self.pressedkeys |= KEY_BACKWARD;
1644                 self.pressedkeys &= ~KEY_FORWARD;
1645         }
1646         else
1647         {       // no x input
1648                 self.pressedkeys &= ~KEY_FORWARD;
1649                 self.pressedkeys &= ~KEY_BACKWARD;
1650         }
1651
1652         if (self.movement_y > 0)
1653         {       // right key pressed
1654                 self.pressedkeys |= KEY_RIGHT;
1655                 self.pressedkeys &= ~KEY_LEFT;
1656         }
1657         else if (self.movement_y < 0)
1658         {       // left key pressed
1659                 self.pressedkeys |= KEY_LEFT;
1660                 self.pressedkeys &= ~KEY_RIGHT;
1661         }
1662         else
1663         {       // no y input
1664                 self.pressedkeys &= ~KEY_RIGHT;
1665                 self.pressedkeys &= ~KEY_LEFT;
1666         }
1667
1668         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1669                 self.pressedkeys |= KEY_JUMP;
1670         else
1671                 self.pressedkeys &= ~KEY_JUMP;
1672         if (self.BUTTON_CROUCH)
1673                 self.pressedkeys |= KEY_CROUCH;
1674         else
1675                 self.pressedkeys &= ~KEY_CROUCH;
1676
1677         if (self.BUTTON_ATCK)
1678                 self.pressedkeys |= KEY_ATCK;
1679         else
1680                 self.pressedkeys &= ~KEY_ATCK;
1681         if (self.BUTTON_ATCK2)
1682                 self.pressedkeys |= KEY_ATCK2;
1683         else
1684                 self.pressedkeys &= ~KEY_ATCK2;
1685 }
1686
1687 /*
1688 ======================
1689 spectate mode routines
1690 ======================
1691 */
1692
1693 void SpectateCopy(entity spectatee) {
1694         other = spectatee;
1695         MUTATOR_CALLHOOK(SpectateCopy);
1696         self.armortype = spectatee.armortype;
1697         self.armorvalue = spectatee.armorvalue;
1698         self.ammo_cells = spectatee.ammo_cells;
1699         self.ammo_shells = spectatee.ammo_shells;
1700         self.ammo_nails = spectatee.ammo_nails;
1701         self.ammo_rockets = spectatee.ammo_rockets;
1702         self.ammo_fuel = spectatee.ammo_fuel;
1703         self.clip_load = spectatee.clip_load;
1704         self.clip_size = spectatee.clip_size;
1705         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1706         self.health = spectatee.health;
1707         self.impulse = 0;
1708         self.items = spectatee.items;
1709         self.last_pickup = spectatee.last_pickup;
1710         self.hit_time = spectatee.hit_time;
1711         self.metertime = spectatee.metertime;
1712         self.strength_finished = spectatee.strength_finished;
1713         self.invincible_finished = spectatee.invincible_finished;
1714         self.pressedkeys = spectatee.pressedkeys;
1715         self.weapons = spectatee.weapons;
1716         self.switchweapon = spectatee.switchweapon;
1717         self.switchingweapon = spectatee.switchingweapon;
1718         self.weapon = spectatee.weapon;
1719         self.nex_charge = spectatee.nex_charge;
1720         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1721         self.hagar_load = spectatee.hagar_load;
1722         self.minelayer_mines = spectatee.minelayer_mines;
1723         self.punchangle = spectatee.punchangle;
1724         self.view_ofs = spectatee.view_ofs;
1725         self.velocity = spectatee.velocity;
1726         self.dmg_take = spectatee.dmg_take;
1727         self.dmg_save = spectatee.dmg_save;
1728         self.dmg_inflictor = spectatee.dmg_inflictor;
1729         self.v_angle = spectatee.v_angle;
1730         self.angles = spectatee.v_angle;
1731         if(!self.BUTTON_USE)
1732                 self.fixangle = TRUE;
1733         setorigin(self, spectatee.origin);
1734         setsize(self, spectatee.mins, spectatee.maxs);
1735         SetZoomState(spectatee.zoomstate);
1736
1737     anticheat_spectatecopy(spectatee);
1738         self.hud = spectatee.hud;
1739         if(spectatee.vehicle)
1740     {
1741         self.fixangle = FALSE;
1742         //self.velocity = spectatee.vehicle.velocity;
1743         self.vehicle_health = spectatee.vehicle_health;
1744         self.vehicle_shield = spectatee.vehicle_shield;
1745         self.vehicle_energy = spectatee.vehicle_energy;
1746         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1747         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1748         self.vehicle_reload1 = spectatee.vehicle_reload1;
1749         self.vehicle_reload2 = spectatee.vehicle_reload2;
1750
1751         msg_entity = self;
1752
1753         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1754             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1755             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1756             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1757
1758         //WriteByte (MSG_ONE, SVC_SETVIEW);
1759         //    WriteEntity(MSG_ONE, self);
1760         //makevectors(spectatee.v_angle);
1761         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1762     }
1763 }
1764
1765 float SpectateUpdate() {
1766         if(!self.enemy)
1767             return 0;
1768
1769         if (self == self.enemy)
1770                 return 0;
1771
1772         if (!IS_PLAYER(self.enemy))
1773                 return 0;
1774
1775         SpectateCopy(self.enemy);
1776
1777         return 1;
1778 }
1779
1780
1781 float SpectateSet()
1782 {
1783         if(self.enemy.classname != "player")
1784                 return FALSE;
1785         /*if(self.enemy.vehicle)
1786         {
1787
1788                 msg_entity = self;
1789                 WriteByte(MSG_ONE, SVC_SETVIEW);
1790                 WriteEntity(MSG_ONE, self.enemy);
1791                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1792
1793                 self.movetype = MOVETYPE_NONE;
1794                 accuracy_resend(self);
1795         }
1796         else
1797         {*/
1798                 msg_entity = self;
1799                 WriteByte(MSG_ONE, SVC_SETVIEW);
1800                 WriteEntity(MSG_ONE, self.enemy);
1801                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1802                 self.movetype = MOVETYPE_NONE;
1803                 accuracy_resend(self);
1804
1805                 if(!SpectateUpdate())
1806                         PutObserverInServer();
1807         //}
1808         return TRUE;
1809 }
1810
1811 float Spectate(entity pl)
1812 {
1813         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1814         if(pl.team != self.team)
1815                 return 0;
1816
1817         self.enemy = pl;
1818         return SpectateSet();
1819 }
1820
1821 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1822 entity CA_SpectateNext(entity start) {
1823         if (start.team == self.team) {
1824                 return start;
1825         }
1826
1827         other = start;
1828         // continue from current player
1829         while(other && other.team != self.team) {
1830                 other = find(other, classname, "player");
1831         }
1832
1833         if (!other) {
1834                 // restart from begining
1835                 other = find(other, classname, "player");
1836                 while(other && other.team != self.team) {
1837                         other = find(other, classname, "player");
1838                 }
1839         }
1840
1841         return other;
1842 }
1843
1844 float SpectateNext()
1845 {
1846         other = find(self.enemy, classname, "player");
1847
1848         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1849                 // CA and ca players when spectating enemies is forbidden
1850                 other = CA_SpectateNext(other);
1851         } else {
1852                 // other modes and ca spectators or spectating enemies is allowed
1853                 if (!other)
1854                         other = find(other, classname, "player");
1855         }
1856
1857         if (other)
1858                 self.enemy = other;
1859
1860         return SpectateSet();
1861 }
1862
1863 float SpectatePrev()
1864 {
1865         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1866         other = findchain(classname, "player");
1867         if (!other) // no player
1868                 return FALSE;
1869
1870         entity first = other;
1871         // skip players until current spectated player
1872         if(self.enemy)
1873         while(other && other != self.enemy)
1874                 other = other.chain;
1875
1876         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1877         {
1878                 do { other = other.chain; }
1879                 while(other && other.team != self.team);
1880
1881                 if (!other)
1882                 {
1883                         other = first;
1884                         while(other.team != self.team)
1885                                 other = other.chain;
1886                         if(other == self.enemy)
1887                                 return TRUE;
1888                 }
1889         }
1890         else
1891         {
1892                 if(other.chain)
1893                         other = other.chain;
1894                 else
1895                         other = first;
1896         }
1897         self.enemy = other;
1898         return SpectateSet();
1899 }
1900
1901 /*
1902 =============
1903 ShowRespawnCountdown()
1904
1905 Update a respawn countdown display.
1906 =============
1907 */
1908 void ShowRespawnCountdown()
1909 {
1910         float number;
1911         if(self.deadflag == DEAD_NO) // just respawned?
1912                 return;
1913         else
1914         {
1915                 number = ceil(self.respawn_time - time);
1916                 if(number <= 0)
1917                         return;
1918                 if(number <= self.respawn_countdown)
1919                 {
1920                         self.respawn_countdown = number - 1;
1921                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1922                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1923                 }
1924         }
1925 }
1926
1927 void LeaveSpectatorMode()
1928 {
1929         if(self.caplayer)
1930                 return;
1931         if(nJoinAllowed(self))
1932         {
1933                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1934                 {
1935                         self.classname = "player";
1936
1937                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1938                                 { JoinBestTeam(self, FALSE, TRUE); }
1939
1940                         if(autocvar_g_campaign)
1941                                 { campaign_bots_may_start = 1; }
1942
1943                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1944
1945                         PutClientInServer();
1946
1947                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1948                 }
1949                 else
1950                         stuffcmd(self, "menu_showteamselect\n");
1951         }
1952         else
1953         {
1954                 // Player may not join because g_maxplayers is set
1955                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1956         }
1957 }
1958
1959 /**
1960  * Determines whether the player is allowed to join. This depends on cvar
1961  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1962  * it checks whether the number of currently playing players exceeds g_maxplayers.
1963  * @return int number of free slots for players, 0 if none
1964  */
1965 float nJoinAllowed(entity ignore) {
1966         if(!ignore)
1967         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1968         // so report 0 free slots if restricted
1969         {
1970                 if(autocvar_g_forced_team_otherwise == "spectate")
1971                         return 0;
1972                 if(autocvar_g_forced_team_otherwise == "spectator")
1973                         return 0;
1974         }
1975
1976         if(self.team_forced < 0)
1977                 return 0; // forced spectators can never join
1978
1979         // TODO simplify this
1980         entity e;
1981         float totalClients = 0;
1982         FOR_EACH_CLIENT(e)
1983                 if(e != ignore)
1984                         totalClients += 1;
1985
1986         if (!autocvar_g_maxplayers)
1987                 return maxclients - totalClients;
1988
1989         float currentlyPlaying = 0;
1990         FOR_EACH_REALCLIENT(e)
1991                 if(IS_PLAYER(e) || e.caplayer == 1)
1992                         currentlyPlaying += 1;
1993
1994         if(currentlyPlaying < autocvar_g_maxplayers)
1995                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1996
1997         return 0;
1998 }
1999
2000 /**
2001  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2002  * g_maxplayers_spectator_blocktime seconds
2003  */
2004 void checkSpectatorBlock() {
2005         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2006                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2007                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2008                         dropclient(self);
2009                 }
2010         }
2011 }
2012
2013 void PrintWelcomeMessage()
2014 {
2015         if(self.motd_actived_time == 0)
2016         {
2017                 if (autocvar_g_campaign) {
2018                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2019                                 self.motd_actived_time = time;
2020                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2021                         }
2022                 } else {
2023                         if (self.BUTTON_INFO) {
2024                                 self.motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2026                         }
2027                 }
2028         }
2029         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2030         {
2031                 if (autocvar_g_campaign) {
2032                         if (self.BUTTON_INFO)
2033                                 self.motd_actived_time = time;
2034                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2035                                 self.motd_actived_time = 0;
2036                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2037                         }
2038                 } else {
2039                         if (self.BUTTON_INFO)
2040                                 self.motd_actived_time = time;
2041                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2042                                 self.motd_actived_time = 0;
2043                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2044                         }
2045                 }
2046         }
2047         else //if(self.motd_actived_time < 0) // just connected, motd is active
2048         {
2049                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2050                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2051                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2052                 {
2053                         // instanctly hide MOTD
2054                         self.motd_actived_time = 0;
2055                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2056                 }
2057         }
2058 }
2059
2060 void ObserverThink()
2061 {
2062         float prefered_movetype;
2063         if (self.flags & FL_JUMPRELEASED) {
2064                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2065                         self.flags &= ~FL_JUMPRELEASED;
2066                         self.flags |= FL_SPAWNING;
2067                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2068                         self.flags &= ~FL_JUMPRELEASED;
2069                         if(SpectateNext()) {
2070                                 self.classname = "spectator";
2071                         }
2072                 } else {
2073                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2074                         if (self.movetype != prefered_movetype)
2075                                 self.movetype = prefered_movetype;
2076                 }
2077         } else {
2078                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2079                         self.flags |= FL_JUMPRELEASED;
2080                         if(self.flags & FL_SPAWNING)
2081                         {
2082                                 self.flags &= ~FL_SPAWNING;
2083                                 LeaveSpectatorMode();
2084                                 return;
2085                         }
2086                 }
2087         }
2088 }
2089
2090 void SpectatorThink()
2091 {
2092         if (self.flags & FL_JUMPRELEASED) {
2093                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2094                         self.flags &= ~FL_JUMPRELEASED;
2095                         self.flags |= FL_SPAWNING;
2096                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         if(SpectateNext()) {
2099                                 self.classname = "spectator";
2100                         } else {
2101                                 self.classname = "observer";
2102                                 PutClientInServer();
2103                         }
2104                         self.impulse = 0;
2105                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2106                         self.flags &= ~FL_JUMPRELEASED;
2107                         if(SpectatePrev()) {
2108                                 self.classname = "spectator";
2109                         } else {
2110                                 self.classname = "observer";
2111                                 PutClientInServer();
2112                         }
2113                         self.impulse = 0;
2114                 } else if (self.BUTTON_ATCK2) {
2115                         self.flags &= ~FL_JUMPRELEASED;
2116                         self.classname = "observer";
2117                         PutClientInServer();
2118                 } else {
2119                         if(!SpectateUpdate())
2120                                 PutObserverInServer();
2121                 }
2122         } else {
2123                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2124                         self.flags |= FL_JUMPRELEASED;
2125                         if(self.flags & FL_SPAWNING)
2126                         {
2127                                 self.flags &= ~FL_SPAWNING;
2128                                 LeaveSpectatorMode();
2129                                 return;
2130                         }
2131                 }
2132                 if(!SpectateUpdate())
2133                         PutObserverInServer();
2134         }
2135
2136         self.flags |= FL_CLIENT | FL_NOTARGET;
2137 }
2138
2139 void PlayerUseKey()
2140 {
2141         if (!IS_PLAYER(self))
2142                 return;
2143
2144         if(self.vehicle)
2145         {
2146         vehicles_exit(VHEF_NORMAL);
2147         return;
2148         }
2149
2150         // a use key was pressed; call handlers
2151         MUTATOR_CALLHOOK(PlayerUseKey);
2152 }
2153
2154 /*
2155 =============
2156 PlayerPreThink
2157
2158 Called every frame for each client before the physics are run
2159 =============
2160 */
2161 .float usekeypressed;
2162 void() nexball_setstatus;
2163 .float items_added;
2164 void PlayerPreThink (void)
2165 {
2166         WarpZone_PlayerPhysics_FixVAngle();
2167
2168         self.stat_game_starttime = game_starttime;
2169         self.stat_round_starttime = round_starttime;
2170         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2171         self.stat_leadlimit = autocvar_leadlimit;
2172
2173         if(frametime)
2174         {
2175                 // physics frames: update anticheat stuff
2176                 anticheat_prethink();
2177         }
2178
2179         if(blockSpectators && frametime)
2180                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2181                 checkSpectatorBlock();
2182
2183         zoomstate_set = 0;
2184
2185         if(self.netname_previous != self.netname)
2186         {
2187                 if(autocvar_sv_eventlog)
2188                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2189                 if(self.netname_previous)
2190                         strunzone(self.netname_previous);
2191                 self.netname_previous = strzone(self.netname);
2192         }
2193
2194         // version nagging
2195         if(self.version_nagtime)
2196                 if(self.cvar_g_xonoticversion)
2197                         if(time > self.version_nagtime)
2198                         {
2199                                 // don't notify git users
2200                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2201                                 {
2202                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2203                                         {
2204                                                 // notify release users if connecting to git
2205                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2206                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2207                                         }
2208                                         else
2209                                         {
2210                                                 float r;
2211                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2212                                                 if(r < 0)
2213                                                 {
2214                                                         // give users new version
2215                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2216                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2217                                                 }
2218                                                 else if(r > 0)
2219                                                 {
2220                                                         // notify users about old server version
2221                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2222                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2223                                                 }
2224                                         }
2225                                 }
2226                                 self.version_nagtime = 0;
2227                         }
2228
2229         // GOD MODE info
2230         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2231         {
2232                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2233                 self.max_armorvalue = 0;
2234         }
2235
2236 #ifdef TETRIS
2237         if (TetrisPreFrame())
2238                 return;
2239 #endif
2240
2241         MUTATOR_CALLHOOK(PlayerPreThink);
2242
2243         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2244         {
2245                 if(self.BUTTON_USE && !self.usekeypressed)
2246                         PlayerUseKey();
2247                 self.usekeypressed = self.BUTTON_USE;
2248         }
2249
2250         if(IS_REAL_CLIENT(self))
2251                 PrintWelcomeMessage();
2252
2253         if(IS_PLAYER(self))
2254         {
2255
2256                 CheckRules_Player();
2257
2258                 if (intermission_running)
2259                 {
2260                         IntermissionThink ();   // otherwise a button could be missed between
2261                         return;                                 // the think tics
2262                 }
2263
2264                 //don't allow the player to turn around while game is paused!
2265                 if(timeout_status == TIMEOUT_ACTIVE) {
2266                         // FIXME turn this into CSQC stuff
2267                         self.v_angle = self.lastV_angle;
2268                         self.angles = self.lastV_angle;
2269                         self.fixangle = TRUE;
2270                 }
2271
2272                 if(frametime)
2273                 {
2274                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2275                         {
2276                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2277                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2278                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2279
2280                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2281                                 {
2282                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2283                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2284                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2285                                 }
2286                         }
2287                         else
2288                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2289
2290                         player_powerups();
2291                 }
2292
2293                 if (self.deadflag != DEAD_NO)
2294                 {
2295                         if(self.personal && g_race_qualifying)
2296                         {
2297                                 if(time > self.respawn_time)
2298                                 {
2299                                         self.respawn_time = time + 1; // only retry once a second
2300                                         self.stat_respawn_time = self.respawn_time;
2301                                         respawn();
2302                                         self.impulse = 141;
2303                                 }
2304                         }
2305                         else
2306                         {
2307                                 float button_pressed;
2308                                 if(frametime)
2309                                         player_anim();
2310                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2311
2312                                 if (self.deadflag == DEAD_DYING)
2313                                 {
2314                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2315                                                 self.deadflag = DEAD_RESPAWNING;
2316                                         else if(!button_pressed)
2317                                                 self.deadflag = DEAD_DEAD;
2318                                 }
2319                                 else if (self.deadflag == DEAD_DEAD)
2320                                 {
2321                                         if(button_pressed)
2322                                                 self.deadflag = DEAD_RESPAWNABLE;
2323                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2324                                                 self.deadflag = DEAD_RESPAWNING;
2325                                 }
2326                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2327                                 {
2328                                         if(!button_pressed)
2329                                                 self.deadflag = DEAD_RESPAWNING;
2330                                 }
2331                                 else if (self.deadflag == DEAD_RESPAWNING)
2332                                 {
2333                                         if(time > self.respawn_time)
2334                                         {
2335                                                 self.respawn_time = time + 1; // only retry once a second
2336                                                 self.respawn_time_max = self.respawn_time;
2337                                                 respawn();
2338                                         }
2339                                 }
2340
2341                                 ShowRespawnCountdown();
2342
2343                                 if(self.respawn_flags & RESPAWN_SILENT)
2344                                         self.stat_respawn_time = 0;
2345                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2346                                         self.stat_respawn_time = self.respawn_time_max;
2347                                 else
2348                                         self.stat_respawn_time = self.respawn_time;
2349                         }
2350
2351                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2352                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2353                                 self.stat_respawn_time *= -1;
2354
2355                         return;
2356                 }
2357
2358                 self.prevorigin = self.origin;
2359
2360                 float do_crouch = self.BUTTON_CROUCH;
2361                 if(self.hook.state)
2362                         do_crouch = 0;
2363                 if(self.vehicle)
2364                         do_crouch = 0;
2365                 if(self.freezetag_frozen)
2366                         do_crouch = 0;
2367                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2368                         do_crouch = 0;
2369
2370                 if (do_crouch)
2371                 {
2372                         if (!self.crouch)
2373                         {
2374                                 self.crouch = TRUE;
2375                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2376                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2377                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2378                         }
2379                 }
2380                 else
2381                 {
2382                         if (self.crouch)
2383                         {
2384                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2385                                 if (!trace_startsolid)
2386                                 {
2387                                         self.crouch = FALSE;
2388                                         self.view_ofs = PL_VIEW_OFS;
2389                                         setsize (self, PL_MIN, PL_MAX);
2390                                 }
2391                         }
2392                 }
2393
2394                 FixPlayermodel();
2395
2396                 GrapplingHookFrame();
2397
2398                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2399                 //if(frametime)
2400                 {
2401                         self.items &= ~self.items_added;
2402
2403                         W_WeaponFrame();
2404
2405                         self.items_added = 0;
2406                         if(self.items & IT_JETPACK)
2407                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2408                                         self.items_added |= IT_FUEL;
2409
2410                         self.items |= self.items_added;
2411                 }
2412
2413                 player_regen();
2414
2415                 // rot nex charge to the charge limit
2416                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2417                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2418
2419                 if(frametime)
2420                         player_anim();
2421
2422                 // secret status
2423                 secrets_setstatus();
2424
2425                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2426
2427                 //self.angles_y=self.v_angle_y + 90;   // temp
2428         } else if(gameover) {
2429                 if (intermission_running)
2430                         IntermissionThink ();   // otherwise a button could be missed between
2431                 return;
2432         } else if(IS_OBSERVER(self)) {
2433                 ObserverThink();
2434         } else if(IS_SPEC(self)) {
2435                 SpectatorThink();
2436         }
2437
2438         if(!zoomstate_set)
2439                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2440
2441         float oldspectatee_status;
2442         oldspectatee_status = self.spectatee_status;
2443         if(IS_SPEC(self))
2444                 self.spectatee_status = num_for_edict(self.enemy);
2445         else if(IS_OBSERVER(self))
2446                 self.spectatee_status = num_for_edict(self);
2447         else
2448                 self.spectatee_status = 0;
2449         if(self.spectatee_status != oldspectatee_status)
2450         {
2451                 ClientData_Touch(self);
2452                 if(g_race || g_cts)
2453                         race_InitSpectator();
2454         }
2455
2456         if(self.teamkill_soundtime)
2457         if(time > self.teamkill_soundtime)
2458         {
2459                 self.teamkill_soundtime = 0;
2460
2461                 entity oldpusher, oldself;
2462
2463                 oldself = self; self = self.teamkill_soundsource;
2464                 oldpusher = self.pusher; self.pusher = oldself;
2465
2466                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2467
2468                 self.pusher = oldpusher;
2469                 self = oldself;
2470         }
2471
2472         if(self.taunt_soundtime)
2473         if(time > self.taunt_soundtime)
2474         {
2475                 self.taunt_soundtime = 0;
2476                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2477         }
2478
2479         target_voicescript_next(self);
2480
2481         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2482         if(!self.weapon)
2483                 self.clip_load = self.clip_size = 0;
2484 }
2485
2486 float isInvisibleString(string s)
2487 {
2488         float i, n, c;
2489         s = strdecolorize(s);
2490         for((i = 0), (n = strlen(s)); i < n; ++i)
2491         {
2492                 c = str2chr(s, i);
2493                 switch(c)
2494                 {
2495                         case 0:
2496                         case 32: // space
2497                                 break;
2498                         case 192: // charmap space
2499                                 if (!autocvar_utf8_enable)
2500                                         break;
2501                                 return FALSE;
2502                         case 160: // space in unicode fonts
2503                         case 0xE000 + 192: // utf8 charmap space
2504                                 if (autocvar_utf8_enable)
2505                                         break;
2506                         default:
2507                                 return FALSE;
2508                 }
2509         }
2510         return TRUE;
2511 }
2512
2513 /*
2514 =============
2515 PlayerPostThink
2516
2517 Called every frame for each client after the physics are run
2518 =============
2519 */
2520 .float idlekick_lasttimeleft;
2521 void PlayerPostThink (void)
2522 {
2523         // Savage: Check for nameless players
2524         if (isInvisibleString(self.netname)) {
2525                 self.netname = "Player";
2526                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2527         }
2528
2529         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2530         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2531         {
2532                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2533                 {
2534                         if(self.idlekick_lasttimeleft)
2535                         {
2536                                 self.idlekick_lasttimeleft = 0;
2537                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2538                         }
2539                 }
2540                 else
2541                 {
2542                         float timeleft;
2543                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2544                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2545                         {
2546                                 if(!self.idlekick_lasttimeleft)
2547                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2548                         }
2549                         if(timeleft <= 0)
2550                         {
2551                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2552                                 dropclient(self);
2553                                 return;
2554                         }
2555                         else if(timeleft <= 10)
2556                         {
2557                                 if(timeleft != self.idlekick_lasttimeleft)
2558                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2559                                 self.idlekick_lasttimeleft = timeleft;
2560                         }
2561                 }
2562         }
2563
2564 #ifdef TETRIS
2565         if(self.impulse == 100)
2566                 ImpulseCommands();
2567         if (!TetrisPostFrame())
2568         {
2569 #endif
2570
2571         CheatFrame();
2572
2573         //CheckPlayerJump();
2574
2575         if(IS_PLAYER(self)) {
2576                 CheckRules_Player();
2577                 UpdateChatBubble();
2578                 if (self.impulse)
2579                         ImpulseCommands();
2580                 if (intermission_running)
2581                         return;         // intermission or finale
2582                 GetPressedKeys();
2583         }
2584
2585 #ifdef TETRIS
2586         }
2587 #endif
2588
2589         /*
2590         float i;
2591         for(i = 0; i < 1000; ++i)
2592         {
2593                 vector end;
2594                 end = self.origin + '0 0 1024' + 512 * randomvec();
2595                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2596                 if(trace_fraction < 1)
2597                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2598                 {
2599                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2600                         break;
2601                 }
2602         }
2603         */
2604
2605         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2606
2607         if(self.waypointsprite_attachedforcarrier)
2608                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2609
2610         playerdemo_write();
2611
2612         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2613         {
2614                 if (!self.stored_netname)
2615                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2616                 if(self.stored_netname != self.netname)
2617                 {
2618                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2619                         strunzone(self.stored_netname);
2620                         self.stored_netname = strzone(self.netname);
2621                 }
2622         }
2623
2624         /*
2625         if(g_race)
2626                 dprintf("%f %.6f\n", time, race_GetFractionalLapCount(self));
2627         */
2628
2629         CSQCMODEL_AUTOUPDATE();
2630 }