qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 Item_ItemsTime_Get(self);
 400                 msg_entity = self;
 401                 WriteByte(MSG_ONE, SVC_SETVIEW);
 402                 WriteEntity(MSG_ONE, self);
 403         }
 404
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         minstagib_stop_countdown(self);
 408
 409         Portal_ClearAll(self);
 410
 411         if(self.alivetime)
 412         {
 413                 if(!inWarmupStage)
 414                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419                 vehicles_exit(VHEF_RELESE);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 424                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 425
 426         if(self.killcount != -666) {
 427                 if(g_lms) {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
 429                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
 430                         else
 431                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
 432                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
 433
 434                 if(self.just_joined == FALSE) {
 435                         LogTeamchange(self.playerid, -1, 4);
 436                 } else
 437                         self.just_joined = FALSE;
 438         }
 439
 440         PlayerScore_Clear(self); // clear scores when needed
 441
 442         accuracy_resend(self);
 443
 444         self.spectatortime = time;
 445
 446         self.classname = "observer";
 447         self.iscreature = FALSE;
 448         self.teleportable = TELEPORT_SIMPLE;
 449         self.damagedbycontents = FALSE;
 450         self.health = -666;
 451         self.takedamage = DAMAGE_NO;
 452         self.solid = SOLID_NOT;
 453         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 454         self.flags = FL_CLIENT | FL_NOTARGET;
 455         self.armorvalue = 666;
 456         self.effects = 0;
 457         self.armorvalue = autocvar_g_balance_armor_start;
 458         self.pauserotarmor_finished = 0;
 459         self.pauserothealth_finished = 0;
 460         self.pauseregen_finished = 0;
 461         self.damageforcescale = 0;
 462         self.death_time = 0;
 463         self.respawn_time = 0;
 464         self.alpha = 0;
 465         self.scale = 0;
 466         self.fade_time = 0;
 467         self.pain_frame = 0;
 468         self.pain_finished = 0;
 469         self.strength_finished = 0;
 470         self.invincible_finished = 0;
 471         self.superweapons_finished = 0;
 472         self.pushltime = 0;
 473         self.istypefrag = 0;
 474         self.think = func_null;
 475         self.nextthink = 0;
 476         self.hook_time = 0;
 477         self.deadflag = DEAD_NO;
 478         self.angles = spot.angles;
 479         self.angles_z = 0;
 480         self.fixangle = TRUE;
 481         self.crouch = FALSE;
 482
 483         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 484         self.prevorigin = self.origin;
 485         self.items = 0;
 486         WEPSET_CLEAR_E(self);
 487         self.model = "";
 488         FixPlayermodel();
 489         setmodel(self, "null");
 490         self.drawonlytoclient = self;
 491
 492         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 493         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 494
 495         self.weapon = 0;
 496         self.weaponname = "";
 497         self.switchingweapon = 0;
 498         self.weaponmodel = "";
 499         self.weaponentity = world;
 500         self.exteriorweaponentity = world;
 501         self.killcount = -666;
 502         self.velocity = '0 0 0';
 503         self.avelocity = '0 0 0';
 504         self.punchangle = '0 0 0';
 505         self.punchvector = '0 0 0';
 506         self.oldvelocity = self.velocity;
 507         self.fire_endtime = -1;
 508
 509         if(g_arena)
 510         {
 511                 if(self.version_mismatch)
 512                 {
 513                         self.frags = FRAGS_SPECTATOR;
 514                         Spawnqueue_Unmark(self);
 515                         Spawnqueue_Remove(self);
 516                 }
 517                 else
 518                 {
 519                         self.frags = FRAGS_LMS_LOSER;
 520                         Spawnqueue_Insert(self);
 521                 }
 522         }
 523         else if(g_lms)
 524         {
 525                 // Only if the player cannot play at all
 526                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 527                         self.frags = FRAGS_SPECTATOR;
 528                 else
 529                         self.frags = FRAGS_LMS_LOSER;
 530         }
 531         else if(g_ca)
 532         {
 533                 if(self.caplayer)
 534                         self.frags = FRAGS_LMS_LOSER;
 535                 else
 536                         self.frags = FRAGS_SPECTATOR;
 537         }
 538         else if((g_race && g_race_qualifying) || g_cts)
 539         {
 540                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 541                         self.frags = FRAGS_LMS_LOSER;
 542                 else
 543                         self.frags = FRAGS_SPECTATOR;
 544         }
 545         else
 546                 self.frags = FRAGS_SPECTATOR;
 547 }
 548
 549 .float model_randomizer;
 550 void FixPlayermodel()
 551 {
 552         string defaultmodel;
 553         float defaultskin, chmdl, oldskin, n, i;
 554         vector m1, m2;
 555
 556         defaultmodel = "";
 557         defaultskin = 0;
 558         chmdl = FALSE;
 559
 560         if(autocvar_sv_defaultcharacter == 1)
 561         {
 562                 if(teamplay)
 563                 {
 564                         string s;
 565                         s = Team_ColorName_Lower(self.team);
 566                         if(s != "neutral")
 567                         {
 568                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 569                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 570                         }
 571                 }
 572
 573                 if(defaultmodel == "")
 574                 {
 575                         defaultmodel = autocvar_sv_defaultplayermodel;
 576                         defaultskin = autocvar_sv_defaultplayerskin;
 577                 }
 578
 579                 n = tokenize_console(defaultmodel);
 580                 if(n > 0)
 581                         defaultmodel = argv(floor(n * self.model_randomizer));
 582
 583                 i = strstrofs(defaultmodel, ":", 0);
 584                 if(i >= 0)
 585                 {
 586                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 587                         defaultmodel = substring(defaultmodel, 0, i);
 588                 }
 589         }
 590
 591         if(defaultmodel != "")
 592         {
 593                 if (defaultmodel != self.model)
 594                 {
 595                         m1 = self.mins;
 596                         m2 = self.maxs;
 597                         setplayermodel (self, defaultmodel);
 598                         setsize (self, m1, m2);
 599                         chmdl = TRUE;
 600                 }
 601
 602                 oldskin = self.skin;
 603                 self.skin = defaultskin;
 604         } else {
 605                 if (self.playermodel != self.model || self.playermodel == "")
 606                 {
 607                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 608                         m1 = self.mins;
 609                         m2 = self.maxs;
 610                         setplayermodel (self, self.playermodel);
 611                         setsize (self, m1, m2);
 612                         chmdl = TRUE;
 613                 }
 614
 615                 oldskin = self.skin;
 616                 self.skin = stof(self.playerskin);
 617         }
 618
 619         if(chmdl || oldskin != self.skin) // model or skin has changed
 620         {
 621                 self.species = player_getspecies(); // update species
 622                 UpdatePlayerSounds(); // update skin sounds
 623         }
 624
 625         if(!teamplay)
 626                 if(strlen(autocvar_sv_defaultplayercolors))
 627                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 628                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 629 }
 630
 631 void PlayerTouchExplode(entity p1, entity p2)
 632 {
 633         vector org;
 634         org = (p1.origin + p2.origin) * 0.5;
 635         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 636
 637         te_explosion(org);
 638
 639         entity e;
 640         e = spawn();
 641         setorigin(e, org);
 642         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 643         remove(e);
 644 }
 645
 646 /*
 647 =============
 648 PutClientInServer
 649
 650 Called when a client spawns in the server
 651 =============
 652 */
 653
 654 void PutClientInServer (void)
 655 {
 656         if(clienttype(self) == CLIENTTYPE_BOT)
 657         {
 658                 self.classname = "player";
 659                 if(g_ca)
 660                         self.caplayer = 1;
 661         }
 662         else if(clienttype(self) == CLIENTTYPE_REAL)
 663         {
 664                 msg_entity = self;
 665                 WriteByte(MSG_ONE, SVC_SETVIEW);
 666                 WriteEntity(MSG_ONE, self);
 667         }
 668
 669         // reset player keys
 670         self.itemkeys = 0;
 671
 672         // player is dead and becomes observer
 673         // FIXME fix LMS scoring for new system
 674         if(g_lms)
 675         {
 676                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 677                         self.classname = "observer";
 678         }
 679
 680         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 681                 self.classname = "observer";
 682
 683         if(gameover)
 684                 self.classname = "observer";
 685
 686         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 687                 entity spot, oldself;
 688                 float j;
 689
 690                 accuracy_resend(self);
 691
 692                 if(self.team < 0)
 693                         JoinBestTeam(self, FALSE, TRUE);
 694
 695                 race_PreSpawn();
 696
 697                 spot = SelectSpawnPoint (FALSE);
 698                 if(!spot)
 699                 {
 700                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 701                         return; // spawn failed
 702                 }
 703
 704                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 705
 706                 self.classname = "player";
 707                 self.wasplayer = TRUE;
 708                 self.iscreature = TRUE;
 709                 self.teleportable = TELEPORT_NORMAL;
 710                 self.damagedbycontents = TRUE;
 711                 self.movetype = MOVETYPE_WALK;
 712                 self.solid = SOLID_SLIDEBOX;
 713                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 714                 if(autocvar_g_playerclip_collisions)
 715                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 716                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 717                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 718                 self.frags = FRAGS_PLAYER;
 719                 if(INDEPENDENT_PLAYERS)
 720                         MAKE_INDEPENDENT_PLAYER(self);
 721                 self.flags = FL_CLIENT;
 722                 if(autocvar__notarget)
 723                         self.flags |= FL_NOTARGET;
 724                 self.takedamage = DAMAGE_AIM;
 725                 if(g_minstagib)
 726                         self.effects = EF_FULLBRIGHT;
 727                 else
 728                         self.effects = 0;
 729                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 730                 self.air_finished = time + 12;
 731                 self.dmg = 2;
 732                 if(autocvar_g_balance_nex_charge)
 733                 {
 734                         if(autocvar_g_balance_nex_secondary_chargepool)
 735                                 self.nex_chargepool_ammo = 1;
 736                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 737                 }
 738
 739                 if(inWarmupStage)
 740                 {
 741                         self.ammo_shells = warmup_start_ammo_shells;
 742                         self.ammo_nails = warmup_start_ammo_nails;
 743                         self.ammo_rockets = warmup_start_ammo_rockets;
 744                         self.ammo_cells = warmup_start_ammo_cells;
 745                         self.ammo_fuel = warmup_start_ammo_fuel;
 746                         self.health = warmup_start_health;
 747                         self.armorvalue = warmup_start_armorvalue;
 748                         WEPSET_COPY_EA(self, warmup_start_weapons);
 749                 }
 750                 else
 751                 {
 752                         self.ammo_shells = start_ammo_shells;
 753                         self.ammo_nails = start_ammo_nails;
 754                         self.ammo_rockets = start_ammo_rockets;
 755                         self.ammo_cells = start_ammo_cells;
 756                         self.ammo_fuel = start_ammo_fuel;
 757                         self.health = start_health;
 758                         self.armorvalue = start_armorvalue;
 759                         WEPSET_COPY_EA(self, start_weapons);
 760                 }
 761
 762                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 763                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 764                 else
 765                         self.superweapons_finished = 0;
 766
 767                 if(!inWarmupStage)
 768                         Item_ItemsTime_ResetForPlayer(self);
 769
 770                 if(g_weaponarena_random)
 771                 {
 772                         if(g_weaponarena_random_with_laser)
 773                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 774                         W_RandomWeapons(self, g_weaponarena_random);
 775                         if(g_weaponarena_random_with_laser)
 776                                 WEPSET_OR_EW(self, WEP_LASER);
 777                 }
 778
 779                 self.items = start_items;
 780
 781                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 782                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 783                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 784                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 785                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 786                 //extend the pause of rotting if client was reset at the beginning of the countdown
 787                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 788                         self.spawnshieldtime += game_starttime - time;
 789                         self.pauserotarmor_finished += game_starttime - time;
 790                         self.pauserothealth_finished += game_starttime - time;
 791                         self.pauseregen_finished += game_starttime - time;
 792                 }
 793                 self.damageforcescale = 2;
 794                 self.death_time = 0;
 795                 self.respawn_time = 0;
 796                 self.scale = 0;
 797                 self.fade_time = 0;
 798                 self.pain_frame = 0;
 799                 self.pain_finished = 0;
 800                 self.strength_finished = 0;
 801                 self.invincible_finished = 0;
 802                 self.pushltime = 0;
 803                 // players have no think function
 804                 self.think = func_null;
 805                 self.nextthink = 0;
 806                 self.hook_time = 0;
 807                 self.dmg_team = 0;
 808                 self.ballistics_density = autocvar_g_ballistics_density_player;
 809
 810                 self.metertime = 0;
 811
 812                 self.deadflag = DEAD_NO;
 813
 814                 self.angles = spot.angles;
 815
 816                 self.angles_z = 0; // never spawn tilted even if the spot says to
 817                 self.fixangle = TRUE; // turn this way immediately
 818                 self.velocity = '0 0 0';
 819                 self.avelocity = '0 0 0';
 820                 self.punchangle = '0 0 0';
 821                 self.punchvector = '0 0 0';
 822                 self.oldvelocity = self.velocity;
 823                 self.fire_endtime = -1;
 824
 825                 msg_entity = self;
 826                 WRITESPECTATABLE_MSG_ONE({
 827                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 828                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 829                 });
 830
 831                 self.model = "";
 832                 FixPlayermodel();
 833                 self.drawonlytoclient = world;
 834
 835                 self.crouch = FALSE;
 836                 self.view_ofs = PL_VIEW_OFS;
 837                 setsize (self, PL_MIN, PL_MAX);
 838                 self.spawnorigin = spot.origin;
 839                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 840                 // don't reset back to last position, even if new position is stuck in solid
 841                 self.oldorigin = self.origin;
 842                 self.prevorigin = self.origin;
 843                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 844                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 845         self.hud = HUD_NORMAL;
 846
 847                 if(g_arena)
 848                 {
 849                         Spawnqueue_Remove(self);
 850                         Spawnqueue_Mark(self);
 851                 }
 852                 else if(g_ca)
 853                         self.caplayer = 1;
 854
 855                 self.event_damage = PlayerDamage;
 856
 857                 self.bot_attack = TRUE;
 858
 859                 self.statdraintime = time + 5;
 860                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 861
 862                 if(self.killcount == -666) {
 863                         PlayerScore_Clear(self);
 864                         self.killcount = 0;
 865                 }
 866
 867                 CL_SpawnWeaponentity();
 868                 self.alpha = default_player_alpha;
 869                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 870                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 871
 872                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 873                 self.lms_traveled_distance = 0;
 874                 self.speedrunning = FALSE;
 875
 876                 race_PostSpawn(spot);
 877
 878                 //stuffcmd(self, "chase_active 0");
 879                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 880
 881                 if(g_assault) {
 882                         if(self.team == assault_attacker_team)
 883                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 884                         else
 885                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 886                 }
 887
 888                 target_voicescript_clear(self);
 889
 890                 // reset fields the weapons may use
 891                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 892                 {
 893                         weapon_action(j, WR_RESETPLAYER);
 894
 895                         // all weapons must be fully loaded when we spawn
 896                         entity e;
 897                         e = get_weaponinfo(j);
 898                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 899                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 900                 }
 901
 902                 oldself = self;
 903                 self = spot;
 904                         activator = oldself;
 905                                 string s;
 906                                 s = self.target;
 907                                 self.target = string_null;
 908                                 SUB_UseTargets();
 909                                 self.target = s;
 910                         activator = world;
 911                 self = oldself;
 912
 913                 spawn_spot = spot;
 914                 MUTATOR_CALLHOOK(PlayerSpawn);
 915
 916                 if(autocvar_spawn_debug)
 917                 {
 918                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 919                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 920                 }
 921
 922                 self.switchweapon = w_getbestweapon(self);
 923                 self.cnt = -1; // W_LastWeapon will not complain
 924                 self.weapon = 0;
 925                 self.weaponname = "";
 926                 self.switchingweapon = 0;
 927
 928                 if(!inWarmupStage)
 929                         if(!self.alivetime)
 930                                 self.alivetime = time;
 931
 932                 antilag_clear(self);
 933
 934                 if (autocvar_g_spawnsound)
 935                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 936         } else if(self.classname == "observer") {
 937                 PutObserverInServer ();
 938         }
 939 }
 940
 941 .float ebouncefactor, ebouncestop; // electro's values
 942 // TODO do we need all these fields, or should we stop autodetecting runtime
 943 // changes and just have a console command to update this?
 944 float ClientInit_SendEntity(entity to, float sf)
 945 {
 946         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 947         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 950         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 951         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 952         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 953         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 954         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 955         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 956         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 957         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 958         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 959         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 960         if(sv_foginterval && world.fog != "")
 961                 WriteString(MSG_ENTITY, world.fog);
 962         else
 963                 WriteString(MSG_ENTITY, "");
 964         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 965         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 966         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 967         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 968         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 969         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 970         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 971         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 972         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 973         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 974         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 975         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 976         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 977         return TRUE;
 978 }
 979
 980 void ClientInit_CheckUpdate()
 981 {
 982         self.nextthink = time;
 983         if(self.count != autocvar_g_balance_armor_blockpercent)
 984         {
 985                 self.count = autocvar_g_balance_armor_blockpercent;
 986                 self.SendFlags |= 1;
 987         }
 988         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 989         {
 990                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 991                 self.SendFlags |= 1;
 992         }
 993         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 994         {
 995                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 996                 self.SendFlags |= 1;
 997         }
 998         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 999         {
1000                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1001                 self.SendFlags |= 1;
1002         }
1003         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1004         {
1005                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1006                 self.SendFlags |= 1;
1007         }
1008         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1009         {
1010                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1011                 self.SendFlags |= 1;
1012         }
1013 }
1014
1015 void ClientInit_Spawn()
1016 {
1017         entity o;
1018         entity e;
1019         e = spawn();
1020         e.classname = "clientinit";
1021         e.think = ClientInit_CheckUpdate;
1022         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1023
1024         o = self;
1025         self = e;
1026         ClientInit_CheckUpdate();
1027         self = o;
1028 }
1029
1030 /*
1031 =============
1032 SetNewParms
1033 =============
1034 */
1035 void SetNewParms (void)
1036 {
1037         // initialize parms for a new player
1038         parm1 = -(86400 * 366);
1039 }
1040
1041 /*
1042 =============
1043 SetChangeParms
1044 =============
1045 */
1046 void SetChangeParms (void)
1047 {
1048         // save parms for level change
1049         parm1 = self.parm_idlesince - time;
1050 }
1051
1052 /*
1053 =============
1054 DecodeLevelParms
1055 =============
1056 */
1057 void DecodeLevelParms (void)
1058 {
1059         // load parms
1060         self.parm_idlesince = parm1;
1061         if(self.parm_idlesince == -(86400 * 366))
1062                 self.parm_idlesince = time;
1063
1064         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1065         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1066 }
1067
1068 /*
1069 =============
1070 ClientKill
1071
1072 Called when a client types 'kill' in the console
1073 =============
1074 */
1075
1076 .float clientkill_nexttime;
1077 void ClientKill_Now_TeamChange()
1078 {
1079         if(self.killindicator_teamchange == -1)
1080         {
1081                 JoinBestTeam( self, FALSE, TRUE );
1082         }
1083         else if(self.killindicator_teamchange == -2)
1084         {
1085                 if(g_ca)
1086                         self.caplayer = 0;
1087                 if(blockSpectators)
1088                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1089                 PutObserverInServer();
1090         }
1091         else
1092                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1093 }
1094
1095 void ClientKill_Now()
1096 {
1097         if(self.vehicle)
1098         {
1099             vehicles_exit(VHEF_RELESE);
1100             if(!self.killindicator_teamchange)
1101             {
1102             self.vehicle_health = -1;
1103             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1104             }
1105         }
1106
1107         if(self.killindicator && !wasfreed(self.killindicator))
1108                 remove(self.killindicator);
1109
1110         self.killindicator = world;
1111
1112         if(self.killindicator_teamchange)
1113                 ClientKill_Now_TeamChange();
1114
1115         // in any case:
1116         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1117
1118         // now I am sure the player IS dead
1119 }
1120 void KillIndicator_Think()
1121 {
1122         if (gameover)
1123         {
1124                 self.owner.killindicator = world;
1125                 remove(self);
1126                 return;
1127         }
1128
1129         if (self.owner.alpha < 0 && !self.owner.vehicle)
1130         {
1131                 self.owner.killindicator = world;
1132                 remove(self);
1133                 return;
1134         }
1135
1136         if(self.cnt <= 0)
1137         {
1138                 self = self.owner;
1139                 ClientKill_Now(); // no oldself needed
1140                 return;
1141         }
1142     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1143     {
1144         self.nextthink = time + 1;
1145         self.cnt -= 1;
1146     }
1147         else
1148         {
1149                 if(self.cnt <= 10)
1150                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1151                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1152                 {
1153                         if(self.cnt <= 10)
1154                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1155                 }
1156                 self.nextthink = time + 1;
1157                 self.cnt -= 1;
1158         }
1159 }
1160
1161 float clientkilltime;
1162 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1163 {
1164         float killtime;
1165         float starttime;
1166         entity e;
1167
1168         if (gameover)
1169                 return;
1170
1171         killtime = autocvar_g_balance_kill_delay;
1172
1173         if(g_race_qualifying || g_cts)
1174                 killtime = 0;
1175
1176     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1177     {
1178                 remove(self.killindicator);
1179                 self.killindicator = world;
1180
1181         ClientKill_Now(); // allow instant kill in this case
1182         return;
1183     }
1184
1185         self.killindicator_teamchange = targetteam;
1186
1187     if(!self.killindicator)
1188         {
1189                 if(self.deadflag == DEAD_NO)
1190                 {
1191                         killtime = max(killtime, self.clientkill_nexttime - time);
1192                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1193                 }
1194
1195                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1196                 {
1197                         ClientKill_Now();
1198                 }
1199                 else
1200                 {
1201                         starttime = max(time, clientkilltime);
1202
1203                         self.killindicator = spawn();
1204                         self.killindicator.owner = self;
1205                         self.killindicator.scale = 0.5;
1206                         setattachment(self.killindicator, self, "");
1207                         setorigin(self.killindicator, '0 0 52');
1208                         self.killindicator.think = KillIndicator_Think;
1209                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1210                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1211                         self.killindicator.cnt = ceil(killtime);
1212                         self.killindicator.count = bound(0, ceil(killtime), 10);
1213                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1214
1215                         for(e = world; (e = find(e, classname, "body")) != world; )
1216                         {
1217                                 if(e.enemy != self)
1218                                         continue;
1219                                 e.killindicator = spawn();
1220                                 e.killindicator.owner = e;
1221                                 e.killindicator.scale = 0.5;
1222                                 setattachment(e.killindicator, e, "");
1223                                 setorigin(e.killindicator, '0 0 52');
1224                                 e.killindicator.think = KillIndicator_Think;
1225                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1226                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1227                                 e.killindicator.cnt = ceil(killtime);
1228                         }
1229                         self.lip = 0;
1230                 }
1231         }
1232         if(self.killindicator)
1233         {
1234                 if(targetteam == 0) // just die
1235                 {
1236                         self.killindicator.colormod = '0 0 0';
1237                         if(clienttype(self) == CLIENTTYPE_REAL)
1238                         if(self.killindicator.cnt > 0)
1239                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1240                 }
1241                 else if(targetteam == -1) // auto
1242                 {
1243                         self.killindicator.colormod = '0 1 0';
1244                         if(clienttype(self) == CLIENTTYPE_REAL)
1245                         if(self.killindicator.cnt > 0)
1246                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1247                 }
1248                 else if(targetteam == -2) // spectate
1249                 {
1250                         self.killindicator.colormod = '0.5 0.5 0.5';
1251                         if(clienttype(self) == CLIENTTYPE_REAL)
1252                         if(self.killindicator.cnt > 0)
1253                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1254                 }
1255                 else
1256                 {
1257                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1258                         if(clienttype(self) == CLIENTTYPE_REAL)
1259                         if(self.killindicator.cnt > 0)
1260                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1261                 }
1262         }
1263
1264 }
1265
1266 void ClientKill (void)
1267 {
1268         if (gameover)
1269                 return;
1270
1271         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1272         {
1273                 // do nothing
1274         }
1275     else if(self.freezetag_frozen)
1276     {
1277         // do nothing
1278     }
1279         else
1280                 ClientKill_TeamChange(0);
1281 }
1282
1283 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1284 {
1285     e.killindicator = spawn();
1286     e.killindicator.owner = e;
1287     e.killindicator.think = KillIndicator_Think;
1288     e.killindicator.nextthink = time + (e.lip) * 0.05;
1289     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1290     e.killindicator.health = 1; // this is used to indicate that it should be silent
1291     e.lip = 0;
1292 }
1293
1294 void FixClientCvars(entity e)
1295 {
1296         // send prediction settings to the client
1297         stuffcmd(e, "\nin_bindmap 0 0\n");
1298         if(g_race || g_cts)
1299                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1300         if(autocvar_g_antilag == 3) // client side hitscan
1301                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1302         if(autocvar_sv_gentle)
1303                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1304         /*
1305          * we no longer need to stuff this. Remove this comment block if you feel
1306          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1307         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1308         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1309         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1310         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1311         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1312         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1313         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1314         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1315         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1316         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1317         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1318         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1319         stuffcmd(e, "cl_movement_edgefriction 1\n");
1320          */
1321 }
1322
1323 float PlayerInIDList(entity p, string idlist)
1324 {
1325         float n, i;
1326         string s;
1327
1328         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1329         if not(p.crypto_idfp)
1330                 return 0;
1331
1332         // this function allows abbreviated player IDs too!
1333         n = tokenize_console(idlist);
1334         for(i = 0; i < n; ++i)
1335         {
1336                 s = argv(i);
1337                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1338                         return 1;
1339         }
1340
1341         return 0;
1342 }
1343
1344 /*
1345 =============
1346 ClientConnect
1347
1348 Called when a client connects to the server
1349 =============
1350 */
1351 void DecodeLevelParms (void);
1352 //void dom_player_join_team(entity pl);
1353 void set_dom_state(entity e);
1354 void ClientConnect (void)
1355 {
1356         float t;
1357
1358         if(self.flags & FL_CLIENT)
1359         {
1360                 print("Warning: ClientConnect, but already connected!\n");
1361                 return;
1362         }
1363
1364         if(Ban_MaybeEnforceBanOnce(self))
1365                 return;
1366
1367         DecodeLevelParms();
1368
1369 #ifdef WATERMARK
1370         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1371 #endif
1372
1373         self.classname = "player_joining";
1374
1375         self.flags = FL_CLIENT;
1376         self.version_nagtime = time + 10 + random() * 10;
1377
1378         if(player_count<0)
1379         {
1380                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1381                 player_count = 0;
1382         }
1383
1384         PlayerScore_Attach(self);
1385         ClientData_Attach();
1386         accuracy_init(self);
1387
1388         bot_clientconnect();
1389
1390         playerdemo_init();
1391
1392         anticheat_init();
1393
1394         race_PreSpawnObserver();
1395
1396         // identify the right forced team
1397         if(autocvar_g_campaign)
1398         {
1399                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1400                 {
1401                         switch(autocvar_g_campaign_forceteam)
1402                         {
1403                                 case 1: self.team_forced = NUM_TEAM_1; break;
1404                                 case 2: self.team_forced = NUM_TEAM_2; break;
1405                                 case 3: self.team_forced = NUM_TEAM_3; break;
1406                                 case 4: self.team_forced = NUM_TEAM_4; break;
1407                                 default: self.team_forced = 0;
1408                         }
1409                 }
1410         }
1411         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1412                 self.team_forced = NUM_TEAM_1;
1413         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1414                 self.team_forced = NUM_TEAM_2;
1415         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1416                 self.team_forced = NUM_TEAM_3;
1417         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1418                 self.team_forced = NUM_TEAM_4;
1419         else if(autocvar_g_forced_team_otherwise == "red")
1420                 self.team_forced = NUM_TEAM_1;
1421         else if(autocvar_g_forced_team_otherwise == "blue")
1422                 self.team_forced = NUM_TEAM_2;
1423         else if(autocvar_g_forced_team_otherwise == "yellow")
1424                 self.team_forced = NUM_TEAM_3;
1425         else if(autocvar_g_forced_team_otherwise == "pink")
1426                 self.team_forced = NUM_TEAM_4;
1427         else if(autocvar_g_forced_team_otherwise == "spectate")
1428                 self.team_forced = -1;
1429         else if(autocvar_g_forced_team_otherwise == "spectator")
1430                 self.team_forced = -1;
1431         else
1432                 self.team_forced = 0;
1433
1434         if(!teamplay)
1435                 if(self.team_forced > 0)
1436                         self.team_forced = 0;
1437
1438         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1439
1440         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1441                 self.classname = "observer";
1442         } else {
1443                 if(teamplay)
1444                 {
1445                         if(autocvar_g_balance_teams)
1446                         {
1447                                 self.classname = "player";
1448                                 campaign_bots_may_start = 1;
1449                         }
1450                         else
1451                         {
1452                                 self.classname = "observer"; // do it anyway
1453                         }
1454                 }
1455                 else
1456                 {
1457                         self.classname = "player";
1458                         campaign_bots_may_start = 1;
1459                 }
1460         }
1461
1462         self.playerid = (playerid_last = playerid_last + 1);
1463
1464         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1465
1466     if(clienttype(self) == CLIENTTYPE_BOT)
1467         PlayerStats_AddPlayer(self);
1468
1469         if(autocvar_sv_eventlog)
1470                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1471
1472         LogTeamchange(self.playerid, self.team, 1);
1473
1474         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1475
1476         self.netname_previous = strzone(self.netname);
1477
1478         if((self.classname == STR_PLAYER && teamplay))
1479                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1480         else
1481                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1482
1483         stuffcmd(self, strcat(clientstuff, "\n"));
1484         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1485
1486         FixClientCvars(self);
1487
1488         // spawnfunc_waypoint sprites
1489         WaypointSprite_InitClient(self);
1490
1491         // Wazat's grappling hook
1492         SetGrappleHookBindings();
1493
1494         // get version info from player
1495         stuffcmd(self, "cmd clientversion $gameversion\n");
1496
1497         // get other cvars from player
1498         GetCvars(0);
1499
1500         // notify about available teams
1501         if(teamplay)
1502         {
1503                 CheckAllowedTeams(self);
1504                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1505                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1506         }
1507         else
1508                 stuffcmd(self, "set _teams_available 0\n");
1509
1510         if(g_arena || g_ca)
1511         {
1512                 self.classname = "observer";
1513                 if(g_arena)
1514                         Spawnqueue_Insert(self);
1515         }
1516
1517         attach_entcs();
1518
1519         bot_relinkplayerlist();
1520
1521         self.spectatortime = time;
1522         if(blockSpectators)
1523         {
1524                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1525         }
1526
1527         self.jointime = time;
1528         self.allowed_timeouts = autocvar_sv_timeout_number;
1529
1530         if(clienttype(self) == CLIENTTYPE_REAL)
1531         {
1532                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1533                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1534         }
1535
1536         if(g_lms)
1537         {
1538                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1539                 {
1540                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1541                         self.frags = FRAGS_SPECTATOR;
1542                 }
1543         }
1544
1545         if(!sv_foginterval && world.fog != "")
1546                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1547
1548         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1549         {
1550                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1551                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1552         }
1553         else
1554                 self.hitplotfh = -1;
1555
1556         if(g_race || g_cts) {
1557                 string rr;
1558                 if(g_cts)
1559                         rr = CTS_RECORD;
1560                 else
1561                         rr = RACE_RECORD;
1562
1563                 msg_entity = self;
1564                 race_send_recordtime(MSG_ONE);
1565                 race_send_speedaward(MSG_ONE);
1566
1567                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1568                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1569                 race_send_speedaward_alltimebest(MSG_ONE);
1570
1571                 float i;
1572                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1573                         race_SendRankings(i, 0, 0, MSG_ONE);
1574                 }
1575         }
1576         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1577                 send_CSQC_teamnagger();
1578
1579         CheatInitClient();
1580
1581         if(!autocvar_g_campaign)
1582                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1583
1584         CSQCMODEL_AUTOINIT();
1585
1586         self.model_randomizer = random();
1587
1588     if(clienttype(self) != CLIENTTYPE_REAL)
1589         return;
1590
1591     sv_notice_join();
1592
1593     MUTATOR_CALLHOOK(ClientConnect);
1594 }
1595 /*
1596 =============
1597 ClientDisconnect
1598
1599 Called when a client disconnects from the server
1600 =============
1601 */
1602 .entity chatbubbleentity;
1603 void ReadyCount();
1604 void ClientDisconnect (void)
1605 {
1606         if(self.vehicle)
1607             vehicles_exit(VHEF_RELESE);
1608
1609         if not(self.flags & FL_CLIENT)
1610         {
1611                 print("Warning: ClientDisconnect without ClientConnect\n");
1612                 return;
1613         }
1614
1615         PlayerStats_AddGlobalInfo(self);
1616
1617         CheatShutdownClient();
1618
1619         if(self.hitplotfh >= 0)
1620         {
1621                 fclose(self.hitplotfh);
1622                 self.hitplotfh = -1;
1623         }
1624
1625         anticheat_report();
1626         anticheat_shutdown();
1627
1628         playerdemo_shutdown();
1629
1630         bot_clientdisconnect();
1631
1632         if(self.entcs)
1633                 detach_entcs();
1634
1635         if(autocvar_sv_eventlog)
1636                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1637
1638         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1639
1640         MUTATOR_CALLHOOK(ClientDisconnect);
1641
1642         Portal_ClearAll(self);
1643
1644         RemoveGrapplingHook(self);
1645
1646         // Here, everything has been done that requires this player to be a client.
1647
1648         self.flags &~= FL_CLIENT;
1649
1650         if (self.chatbubbleentity)
1651                 remove (self.chatbubbleentity);
1652
1653         if (self.killindicator)
1654                 remove (self.killindicator);
1655
1656         WaypointSprite_PlayerGone();
1657
1658         bot_relinkplayerlist();
1659
1660         if(g_arena)
1661         {
1662                 Spawnqueue_Unmark(self);
1663                 Spawnqueue_Remove(self);
1664         }
1665
1666         accuracy_free(self);
1667         ClientData_Detach();
1668         PlayerScore_Detach(self);
1669
1670         if(self.netname_previous)
1671                 strunzone(self.netname_previous);
1672         if(self.clientstatus)
1673                 strunzone(self.clientstatus);
1674         if(self.weaponorder_byimpulse)
1675                 strunzone(self.weaponorder_byimpulse);
1676
1677         ClearPlayerSounds();
1678
1679         if(self.personal)
1680                 remove(self.personal);
1681
1682         self.playerid = 0;
1683         ReadyCount();
1684
1685         // free cvars
1686         GetCvars(-1);
1687 }
1688
1689 .float BUTTON_CHAT;
1690 void ChatBubbleThink()
1691 {
1692         self.nextthink = time;
1693         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1694         {
1695                 if(self.owner) // but why can that ever be world?
1696                         self.owner.chatbubbleentity = world;
1697                 remove(self);
1698                 return;
1699         }
1700         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1701 #ifdef TETRIS
1702                 || self.owner.tetris_on
1703 #endif
1704         )
1705                 self.model = self.mdl;
1706         else
1707                 self.model = "";
1708 }
1709
1710 void UpdateChatBubble()
1711 {
1712         if (self.alpha < 0)
1713                 return;
1714         // spawn a chatbubble entity if needed
1715         if (!self.chatbubbleentity)
1716         {
1717                 self.chatbubbleentity = spawn();
1718                 self.chatbubbleentity.owner = self;
1719                 self.chatbubbleentity.exteriormodeltoclient = self;
1720                 self.chatbubbleentity.think = ChatBubbleThink;
1721                 self.chatbubbleentity.nextthink = time;
1722                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1723                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1724                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1725                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1726                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1727                 self.chatbubbleentity.model = "";
1728                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1729         }
1730 }
1731
1732
1733 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1734 // added to the model skins
1735 /*void UpdateColorModHack()
1736 {
1737         float c;
1738         c = self.clientcolors & 15;
1739         // LordHavoc: only bothering to support white, green, red, yellow, blue
1740              if (!teamplay) self.colormod = '0 0 0';
1741         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1742         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1743         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1744         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1745         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1746         else self.colormod = '1 1 1';
1747 }*/
1748
1749 void respawn(void)
1750 {
1751         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1752         {
1753                 self.solid = SOLID_NOT;
1754                 self.takedamage = DAMAGE_NO;
1755                 self.movetype = MOVETYPE_FLY;
1756                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1757                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1758                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1759                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1760                 if(autocvar_g_respawn_ghosts_maxtime)
1761                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1762         }
1763
1764         CopyBody(1);
1765
1766         self.effects |= EF_NODRAW; // prevent another CopyBody
1767         PutClientInServer();
1768 }
1769
1770 void play_countdown(float finished, string samp)
1771 {
1772         if(clienttype(self) == CLIENTTYPE_REAL)
1773                 if(floor(finished - time - frametime) != floor(finished - time))
1774                         if(finished - time < 6)
1775                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1776 }
1777
1778 void player_powerups (void)
1779 {
1780         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1781         olditems = self.items;
1782
1783         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1784                 self.modelflags |= MF_ROCKET;
1785         else
1786                 self.modelflags &~= MF_ROCKET;
1787
1788         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1789
1790         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1791                 return;
1792
1793         Fire_ApplyDamage(self);
1794         Fire_ApplyEffect(self);
1795
1796         if (g_minstagib)
1797         {
1798                 self.effects |= EF_FULLBRIGHT;
1799
1800                 if (self.items & IT_STRENGTH)
1801                 {
1802                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1803                         if (time > self.strength_finished)
1804                         {
1805                                 self.alpha = default_player_alpha;
1806                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1807                                 self.items &~= IT_STRENGTH;
1808                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1809                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1810                         }
1811                 }
1812                 else
1813                 {
1814                         if (time < self.strength_finished)
1815                         {
1816                                 self.alpha = g_minstagib_invis_alpha;
1817                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1818                                 self.items |= IT_STRENGTH;
1819                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1820                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1821                         }
1822                 }
1823
1824                 if (self.items & IT_INVINCIBLE)
1825                 {
1826                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1827                         if (time > self.invincible_finished)
1828                         {
1829                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1830                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1831                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1832                         }
1833                 }
1834                 else
1835                 {
1836                         if (time < self.invincible_finished)
1837                         {
1838                                 self.items = self.items | IT_INVINCIBLE;
1839                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1840                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1841                         }
1842                 }
1843         }
1844         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1845         {
1846                 if (self.items & IT_STRENGTH)
1847                 {
1848                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1849                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1850                         if (time > self.strength_finished)
1851                         {
1852                                 self.items = self.items - (self.items & IT_STRENGTH);
1853                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1854                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1855                         }
1856                 }
1857                 else
1858                 {
1859                         if (time < self.strength_finished)
1860                         {
1861                                 self.items = self.items | IT_STRENGTH;
1862                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1863                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1864                         }
1865                 }
1866                 if (self.items & IT_INVINCIBLE)
1867                 {
1868                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1869                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1870                         if (time > self.invincible_finished)
1871                         {
1872                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1873                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1874                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1875                         }
1876                 }
1877                 else
1878                 {
1879                         if (time < self.invincible_finished)
1880                         {
1881                                 self.items = self.items | IT_INVINCIBLE;
1882                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1883                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1884                         }
1885                 }
1886                 if (self.items & IT_SUPERWEAPON)
1887                 {
1888                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1889                         {
1890                                 self.superweapons_finished = 0;
1891                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1892                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1893                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1894                         }
1895                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1896                         {
1897                                 // don't let them run out
1898                         }
1899                         else
1900                         {
1901                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1902                                 if (time > self.superweapons_finished)
1903                                 {
1904                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1905                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1906                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1907                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1908                                 }
1909                         }
1910                 }
1911                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1912                 {
1913                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1914                         {
1915                                 self.items = self.items | IT_SUPERWEAPON;
1916                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1917                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1918                         }
1919                         else
1920                         {
1921                                 self.superweapons_finished = 0;
1922                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1923                         }
1924                 }
1925                 else
1926                 {
1927                         self.superweapons_finished = 0;
1928                 }
1929         }
1930
1931         if(autocvar_g_nodepthtestplayers)
1932                 self.effects = self.effects | EF_NODEPTHTEST;
1933
1934         if(autocvar_g_fullbrightplayers)
1935                 self.effects = self.effects | EF_FULLBRIGHT;
1936
1937         // midair gamemode: damage only while in the air
1938         // if in midair mode, being on ground grants temporary invulnerability
1939         // (this is so that multishot weapon don't clear the ground flag on the
1940         // first damage in the frame, leaving the player vulnerable to the
1941         // remaining hits in the same frame)
1942         if (self.flags & FL_ONGROUND)
1943         if (g_midair)
1944                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1945
1946         if (time >= game_starttime)
1947         if (time < self.spawnshieldtime)
1948                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1949
1950         MUTATOR_CALLHOOK(PlayerPowerups);
1951 }
1952
1953 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1954 {
1955         if(current > stable)
1956                 return current;
1957         else if(current > stable - 0.25) // when close enough, "snap"
1958                 return stable;
1959         else
1960                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1961 }
1962
1963 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1964 {
1965         if(current < stable)
1966                 return current;
1967         else if(current < stable + 0.25) // when close enough, "snap"
1968                 return stable;
1969         else
1970                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1971 }
1972
1973 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1974 {
1975         if(current > rotstable)
1976         {
1977                 if(rotframetime > 0)
1978                 {
1979                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1980                         current = max(rotstable, current - rotlinear * rotframetime);
1981                 }
1982         }
1983         else if(current < regenstable)
1984         {
1985                 if(regenframetime > 0)
1986                 {
1987                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1988                         current = min(regenstable, current + regenlinear * regenframetime);
1989                 }
1990         }
1991
1992         if(current > limit)
1993                 current = limit;
1994
1995         return current;
1996 }
1997
1998 void player_regen (void)
1999 {
2000         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2001         maxh = autocvar_g_balance_health_rotstable;
2002         maxa = autocvar_g_balance_armor_rotstable;
2003         maxf = autocvar_g_balance_fuel_rotstable;
2004         minh = autocvar_g_balance_health_regenstable;
2005         mina = autocvar_g_balance_armor_regenstable;
2006         minf = autocvar_g_balance_fuel_regenstable;
2007         limith = autocvar_g_balance_health_limit;
2008         limita = autocvar_g_balance_armor_limit;
2009         limitf = autocvar_g_balance_fuel_limit;
2010
2011         max_mod = regen_mod = rot_mod = limit_mod = 1;
2012
2013         maxh = maxh * max_mod;
2014         //maxa = maxa * max_mod;
2015         //maxf = maxf * max_mod;
2016         minh = minh * max_mod;
2017         //mina = mina * max_mod;
2018         //minf = minf * max_mod;
2019         limith = limith * limit_mod;
2020         limita = limita * limit_mod;
2021         //limitf = limitf * limit_mod;
2022
2023         if(g_lms && g_ca)
2024                 rot_mod = 0;
2025
2026         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2027         {
2028                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2029                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2030
2031                 // if player rotted to death...  die!
2032                 if(self.health < 1)
2033                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2034         }
2035
2036         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2037                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2038 }
2039
2040 float zoomstate_set;
2041 void SetZoomState(float z)
2042 {
2043         if(z != self.zoomstate)
2044         {
2045                 self.zoomstate = z;
2046                 ClientData_Touch(self);
2047         }
2048         zoomstate_set = 1;
2049 }
2050
2051 void GetPressedKeys(void) {
2052         MUTATOR_CALLHOOK(GetPressedKeys);
2053         if (self.movement_x > 0) // get if movement keys are pressed
2054         {       // forward key pressed
2055                 self.pressedkeys |= KEY_FORWARD;
2056                 self.pressedkeys &~= KEY_BACKWARD;
2057         }
2058         else if (self.movement_x < 0)
2059         {       // backward key pressed
2060                 self.pressedkeys |= KEY_BACKWARD;
2061                 self.pressedkeys &~= KEY_FORWARD;
2062         }
2063         else
2064         {       // no x input
2065                 self.pressedkeys &~= KEY_FORWARD;
2066                 self.pressedkeys &~= KEY_BACKWARD;
2067         }
2068
2069         if (self.movement_y > 0)
2070         {       // right key pressed
2071                 self.pressedkeys |= KEY_RIGHT;
2072                 self.pressedkeys &~= KEY_LEFT;
2073         }
2074         else if (self.movement_y < 0)
2075         {       // left key pressed
2076                 self.pressedkeys |= KEY_LEFT;
2077                 self.pressedkeys &~= KEY_RIGHT;
2078         }
2079         else
2080         {       // no y input
2081                 self.pressedkeys &~= KEY_RIGHT;
2082                 self.pressedkeys &~= KEY_LEFT;
2083         }
2084
2085         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2086                 self.pressedkeys |= KEY_JUMP;
2087         else
2088                 self.pressedkeys &~= KEY_JUMP;
2089         if (self.BUTTON_CROUCH)
2090                 self.pressedkeys |= KEY_CROUCH;
2091         else
2092                 self.pressedkeys &~= KEY_CROUCH;
2093
2094         if (self.BUTTON_ATCK)
2095                 self.pressedkeys |= KEY_ATCK;
2096         else
2097                 self.pressedkeys &~= KEY_ATCK;
2098         if (self.BUTTON_ATCK2)
2099                 self.pressedkeys |= KEY_ATCK2;
2100         else
2101                 self.pressedkeys &~= KEY_ATCK2;
2102 }
2103
2104 /*
2105 ======================
2106 spectate mode routines
2107 ======================
2108 */
2109
2110 void SpectateCopy(entity spectatee) {
2111         other = spectatee;
2112         MUTATOR_CALLHOOK(SpectateCopy);
2113         self.armortype = spectatee.armortype;
2114         self.armorvalue = spectatee.armorvalue;
2115         self.ammo_cells = spectatee.ammo_cells;
2116         self.ammo_shells = spectatee.ammo_shells;
2117         self.ammo_nails = spectatee.ammo_nails;
2118         self.ammo_rockets = spectatee.ammo_rockets;
2119         self.ammo_fuel = spectatee.ammo_fuel;
2120         self.clip_load = spectatee.clip_load;
2121         self.clip_size = spectatee.clip_size;
2122         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2123         self.health = spectatee.health;
2124         self.impulse = 0;
2125         self.items = spectatee.items;
2126         self.last_pickup = spectatee.last_pickup;
2127         self.hit_time = spectatee.hit_time;
2128         self.metertime = spectatee.metertime;
2129         self.strength_finished = spectatee.strength_finished;
2130         self.invincible_finished = spectatee.invincible_finished;
2131         self.pressedkeys = spectatee.pressedkeys;
2132         WEPSET_COPY_EE(self, spectatee);
2133         self.switchweapon = spectatee.switchweapon;
2134         self.switchingweapon = spectatee.switchingweapon;
2135         self.weapon = spectatee.weapon;
2136         self.nex_charge = spectatee.nex_charge;
2137         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2138         self.hagar_load = spectatee.hagar_load;
2139         self.minelayer_mines = spectatee.minelayer_mines;
2140         self.punchangle = spectatee.punchangle;
2141         self.view_ofs = spectatee.view_ofs;
2142         self.velocity = spectatee.velocity;
2143         self.dmg_take = spectatee.dmg_take;
2144         self.dmg_save = spectatee.dmg_save;
2145         self.dmg_inflictor = spectatee.dmg_inflictor;
2146         self.v_angle = spectatee.v_angle;
2147         self.angles = spectatee.v_angle;
2148         self.stat_respawn_time = spectatee.stat_respawn_time;
2149         if(!self.BUTTON_USE)
2150                 self.fixangle = TRUE;
2151         setorigin(self, spectatee.origin);
2152         setsize(self, spectatee.mins, spectatee.maxs);
2153         SetZoomState(spectatee.zoomstate);
2154
2155     anticheat_spectatecopy(spectatee);
2156         self.hud = spectatee.hud;
2157         if(spectatee.vehicle)
2158     {
2159         self.fixangle = FALSE;
2160         //self.velocity = spectatee.vehicle.velocity;
2161         self.vehicle_health = spectatee.vehicle_health;
2162         self.vehicle_shield = spectatee.vehicle_shield;
2163         self.vehicle_energy = spectatee.vehicle_energy;
2164         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2165         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2166         self.vehicle_reload1 = spectatee.vehicle_reload1;
2167         self.vehicle_reload2 = spectatee.vehicle_reload2;
2168
2169         msg_entity = self;
2170
2171         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2172             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2173             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2174             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2175
2176         //WriteByte (MSG_ONE, SVC_SETVIEW);
2177         //    WriteEntity(MSG_ONE, self);
2178         //makevectors(spectatee.v_angle);
2179         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2180     }
2181 }
2182
2183 float SpectateUpdate() {
2184         if(!self.enemy)
2185             return 0;
2186
2187         if (self == self.enemy)
2188                 return 0;
2189
2190         if(self.enemy.classname != "player")
2191                 return 0;
2192
2193         SpectateCopy(self.enemy);
2194
2195         return 1;
2196 }
2197
2198
2199 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2200 entity CA_SpectateNext(entity start) {
2201         if (start.team == self.team) {
2202                 return start;
2203         }
2204
2205         other = start;
2206         // continue from current player
2207         while(other && other.team != self.team) {
2208                 other = find(other, classname, "player");
2209         }
2210
2211         if (!other) {
2212                 // restart from begining
2213                 other = find(other, classname, "player");
2214                 while(other && other.team != self.team) {
2215                         other = find(other, classname, "player");
2216                 }
2217         }
2218
2219         return other;
2220 }
2221
2222 float SpectateNext(entity _prefer) {
2223
2224         if(_prefer)
2225                 other = _prefer;
2226         else
2227                 other = find(self.enemy, classname, "player");
2228
2229         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2230                 // CA and ca players when spectating enemies is forbidden
2231                 other = CA_SpectateNext(other);
2232         } else {
2233                 // other modes and ca spectators or spectating enemies is allowed
2234                 if (!other)
2235                         other = find(other, classname, "player");
2236         }
2237
2238         if (other)
2239                 self.enemy = other;
2240
2241         if(self.enemy.classname == "player") {
2242             /*if(self.enemy.vehicle)
2243             {
2244
2245             msg_entity = self;
2246             WriteByte(MSG_ONE, SVC_SETVIEW);
2247             WriteEntity(MSG_ONE, self.enemy);
2248             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2249
2250             self.movetype = MOVETYPE_NONE;
2251             accuracy_resend(self);
2252             }
2253             else
2254             {*/
2255             msg_entity = self;
2256             WriteByte(MSG_ONE, SVC_SETVIEW);
2257             WriteEntity(MSG_ONE, self.enemy);
2258             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2259             self.movetype = MOVETYPE_NONE;
2260             accuracy_resend(self);
2261
2262             if(!SpectateUpdate())
2263                 PutObserverInServer();
2264         //}
2265         return 1;
2266         } else {
2267                 return 0;
2268         }
2269 }
2270
2271 /*
2272 =============
2273 ShowRespawnCountdown()
2274
2275 Update a respawn countdown display.
2276 =============
2277 */
2278 void ShowRespawnCountdown()
2279 {
2280         float number;
2281         if(self.deadflag == DEAD_NO) // just respawned?
2282                 return;
2283         else
2284         {
2285                 number = ceil(self.respawn_time - time);
2286                 if(number <= 0)
2287                         return;
2288                 if(number <= self.respawn_countdown)
2289                 {
2290                         self.respawn_countdown = number - 1;
2291                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2292                                 AnnounceTo(self, strcat(ftos(number), ""));
2293                 }
2294         }
2295 }
2296
2297 void LeaveSpectatorMode()
2298 {
2299         if(nJoinAllowed(self))
2300         {
2301                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2302                 {
2303                         self.classname = "player";
2304
2305                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2306                                 { JoinBestTeam(self, FALSE, TRUE); }
2307
2308                         if(autocvar_g_campaign)
2309                                 { campaign_bots_may_start = 1; }
2310                         else
2311                                 { Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD); }
2312
2313                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2314
2315                         PutClientInServer();
2316
2317                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2318                 }
2319                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2320         }
2321         else
2322         {
2323                 // Player may not join because g_maxplayers is set
2324                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2325         }
2326 }
2327
2328 /**
2329  * Determines whether the player is allowed to join. This depends on cvar
2330  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2331  * it checks whether the number of currently playing players exceeds g_maxplayers.
2332  * @return int number of free slots for players, 0 if none
2333  */
2334 float nJoinAllowed(entity ignore) {
2335         if(!ignore)
2336         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2337         // so report 0 free slots if restricted
2338         {
2339                 if(autocvar_g_forced_team_otherwise == "spectate")
2340                         return 0;
2341                 if(autocvar_g_forced_team_otherwise == "spectator")
2342                         return 0;
2343         }
2344
2345         if(self.team_forced < 0)
2346                 return 0; // forced spectators can never join
2347
2348         // TODO simplify this
2349         entity e;
2350         float totalClients = 0;
2351         FOR_EACH_CLIENT(e)
2352                 if(e != ignore)
2353                         totalClients += 1;
2354
2355         if (!autocvar_g_maxplayers)
2356                 return maxclients - totalClients;
2357
2358         float currentlyPlaying = 0;
2359         FOR_EACH_REALPLAYER(e)
2360                 currentlyPlaying += 1;
2361
2362         if(currentlyPlaying < autocvar_g_maxplayers)
2363                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2364
2365         return 0;
2366 }
2367
2368 /**
2369  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2370  * g_maxplayers_spectator_blocktime seconds
2371  */
2372 void checkSpectatorBlock() {
2373         if(self.classname == "spectator" || self.classname == "observer") {
2374                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2375                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2376                         dropclient(self);
2377                 }
2378         }
2379 }
2380
2381 .float motd_actived_time; // used for both motd and campaign_message
2382 void PrintWelcomeMessage()
2383 {
2384         if (self.motd_actived_time == 0) { // is there already a message showing?
2385                 if (autocvar_g_campaign) {
2386                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2387                                 self.motd_actived_time = time;
2388                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2389                         }
2390                 } else {
2391                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2392                                 self.motd_actived_time = time;
2393                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2394                         }
2395                 }
2396         } else { // showing MOTD or campaign message
2397                 if (autocvar_g_campaign) {
2398                         if (self.BUTTON_INFO)
2399                                 self.motd_actived_time = time;
2400                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2401                                 self.motd_actived_time = 0;
2402                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2403                         }
2404                 } else {
2405                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2406                                 if (self.BUTTON_INFO)
2407                                         self.motd_actived_time = time;
2408                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2409                                         self.motd_actived_time = 0;
2410                                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2411                                 }
2412                         }
2413                 }
2414         }
2415 }
2416
2417 void ObserverThink()
2418 {
2419         float prefered_movetype;
2420         if (self.flags & FL_JUMPRELEASED) {
2421                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2422                         self.flags &~= FL_JUMPRELEASED;
2423                         self.flags |= FL_SPAWNING;
2424                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2425                         self.flags &~= FL_JUMPRELEASED;
2426                         if(SpectateNext(world) == 1) {
2427                                 self.classname = "spectator";
2428                         }
2429                 } else {
2430                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2431                         if (self.movetype != prefered_movetype)
2432                                 self.movetype = prefered_movetype;
2433                 }
2434         } else {
2435                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2436                         self.flags |= FL_JUMPRELEASED;
2437                         if(self.flags & FL_SPAWNING)
2438                         {
2439                                 self.flags &~= FL_SPAWNING;
2440                                 LeaveSpectatorMode();
2441                                 return;
2442                         }
2443                 }
2444         }
2445
2446         PrintWelcomeMessage();
2447 }
2448
2449 void SpectatorThink()
2450 {
2451         if (self.flags & FL_JUMPRELEASED) {
2452                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2453                         self.flags &~= FL_JUMPRELEASED;
2454                         self.flags |= FL_SPAWNING;
2455                 } else if(self.BUTTON_ATCK) {
2456                         self.flags &~= FL_JUMPRELEASED;
2457                         if(SpectateNext(world) == 1) {
2458                                 self.classname = "spectator";
2459                         } else {
2460                                 self.classname = "observer";
2461                                 PutClientInServer();
2462                         }
2463                 } else if (self.BUTTON_ATCK2) {
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         self.classname = "observer";
2466                         PutClientInServer();
2467                 } else {
2468                         if(!SpectateUpdate())
2469                                 PutObserverInServer();
2470                 }
2471         } else {
2472                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2473                         self.flags |= FL_JUMPRELEASED;
2474                         if(self.flags & FL_SPAWNING)
2475                         {
2476                                 self.flags &~= FL_SPAWNING;
2477                                 LeaveSpectatorMode();
2478                                 return;
2479                         }
2480                 }
2481                 if(!SpectateUpdate())
2482                         PutObserverInServer();
2483         }
2484
2485         PrintWelcomeMessage();
2486         self.flags |= FL_CLIENT | FL_NOTARGET;
2487 }
2488
2489 void PlayerUseKey()
2490 {
2491         if(self.classname != "player")
2492                 return;
2493
2494         if(self.vehicle)
2495         {
2496         vehicles_exit(VHEF_NORMAL);
2497         return;
2498         }
2499
2500         // a use key was pressed; call handlers
2501         MUTATOR_CALLHOOK(PlayerUseKey);
2502 }
2503
2504 .float touchexplode_time;
2505
2506 /*
2507 =============
2508 PlayerPreThink
2509
2510 Called every frame for each client before the physics are run
2511 =============
2512 */
2513 .float usekeypressed;
2514 void() nexball_setstatus;
2515 .float items_added;
2516 void PlayerPreThink (void)
2517 {
2518         WarpZone_PlayerPhysics_FixVAngle();
2519
2520         self.stat_game_starttime = game_starttime;
2521         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2522         self.stat_leadlimit = autocvar_leadlimit;
2523
2524         if(g_arena || (g_ca && !allowed_to_spawn))
2525                 self.stat_respawn_time = 0;
2526         else
2527                 self.stat_respawn_time = self.respawn_time;
2528
2529         if(frametime)
2530         {
2531                 // physics frames: update anticheat stuff
2532                 anticheat_prethink();
2533         }
2534
2535         if(blockSpectators && frametime)
2536                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2537                 checkSpectatorBlock();
2538
2539         zoomstate_set = 0;
2540
2541         if(self.netname_previous != self.netname)
2542         {
2543                 if(autocvar_sv_eventlog)
2544                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2545                 if(self.netname_previous)
2546                         strunzone(self.netname_previous);
2547                 self.netname_previous = strzone(self.netname);
2548         }
2549
2550         // version nagging
2551         if(self.version_nagtime)
2552                 if(self.cvar_g_xonoticversion)
2553                         if(time > self.version_nagtime)
2554                         {
2555                                 // don't notify git users
2556                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2557                                 {
2558                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2559                                         {
2560                                                 // notify release users if connecting to git
2561                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2562                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2563                                         }
2564                                         else
2565                                         {
2566                                                 float r;
2567                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2568                                                 if(r < 0)
2569                                                 {
2570                                                         // give users new version
2571                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2572                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2573                                                 }
2574                                                 else if(r > 0)
2575                                                 {
2576                                                         // notify users about old server version
2577                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2578                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2579                                                 }
2580                                         }
2581                                 }
2582                                 self.version_nagtime = 0;
2583                         }
2584
2585         // GOD MODE info
2586         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2587         {
2588                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2589                 self.max_armorvalue = 0;
2590         }
2591
2592 #ifdef TETRIS
2593         if (TetrisPreFrame())
2594                 return;
2595 #endif
2596
2597         MUTATOR_CALLHOOK(PlayerPreThink);
2598
2599         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2600         {
2601                 if(self.BUTTON_USE && !self.usekeypressed)
2602                         PlayerUseKey();
2603                 self.usekeypressed = self.BUTTON_USE;
2604         }
2605
2606         PrintWelcomeMessage();
2607
2608         if(self.classname == "player") {
2609 //              if(self.netname == "Wazat")
2610 //                      bprint(self.classname, "\n");
2611
2612                 CheckRules_Player();
2613
2614                 if (intermission_running)
2615                 {
2616                         IntermissionThink ();   // otherwise a button could be missed between
2617                         return;                                 // the think tics
2618                 }
2619
2620                 //don't allow the player to turn around while game is paused!
2621                 if(timeout_status == TIMEOUT_ACTIVE) {
2622                         // FIXME turn this into CSQC stuff
2623                         self.v_angle = self.lastV_angle;
2624                         self.angles = self.lastV_angle;
2625                         self.fixangle = TRUE;
2626                 }
2627
2628                 if(frametime)
2629                 {
2630                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2631                         {
2632                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2633                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2634                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2635
2636                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2637                                 {
2638                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2639                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2640                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2641                                 }
2642                         }
2643                         else
2644                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2645
2646                         player_powerups();
2647                 }
2648
2649                 if (g_minstagib)
2650                         minstagib_ammocheck();
2651
2652                 if (self.deadflag != DEAD_NO)
2653                 {
2654                         float button_pressed, force_respawn;
2655                         if(self.personal && g_race_qualifying)
2656                         {
2657                                 if(time > self.respawn_time)
2658                                 {
2659                                         self.respawn_time = time + 1; // only retry once a second
2660                                         respawn();
2661                                         self.impulse = 141;
2662                                 }
2663                         }
2664                         else
2665                         {
2666                                 if(frametime)
2667                                         player_anim();
2668                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2669                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2670                                 if (self.deadflag == DEAD_DYING)
2671                                 {
2672                                         if(force_respawn)
2673                                                 self.deadflag = DEAD_RESPAWNING;
2674                                         else if(!button_pressed)
2675                                                 self.deadflag = DEAD_DEAD;
2676                                 }
2677                                 else if (self.deadflag == DEAD_DEAD)
2678                                 {
2679                                         if(button_pressed)
2680                                                 self.deadflag = DEAD_RESPAWNABLE;
2681                                 }
2682                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2683                                 {
2684                                         if(!button_pressed)
2685                                                 self.deadflag = DEAD_RESPAWNING;
2686                                 }
2687                                 else if (self.deadflag == DEAD_RESPAWNING)
2688                                 {
2689                                         if(time > self.respawn_time)
2690                                         {
2691                                                 self.respawn_time = time + 1; // only retry once a second
2692                                                 respawn();
2693                                         }
2694                                 }
2695                                 ShowRespawnCountdown();
2696                         }
2697
2698                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2699                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2700                                 self.stat_respawn_time *= -1;
2701
2702                         return;
2703                 }
2704                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2705                 // so (self.deadflag == DEAD_NO) is always true in the code below
2706
2707                 if(g_touchexplode)
2708                 if(time > self.touchexplode_time)
2709                 if(self.classname == "player")
2710                 if(self.deadflag == DEAD_NO)
2711                 if not(IS_INDEPENDENT_PLAYER(self))
2712                 FOR_EACH_PLAYER(other) if(self != other)
2713                 {
2714                         if(time > other.touchexplode_time)
2715                         if(other.deadflag == DEAD_NO)
2716                         if not(IS_INDEPENDENT_PLAYER(other))
2717                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2718                         {
2719                                 PlayerTouchExplode(self, other);
2720                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2721                         }
2722                 }
2723
2724                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2725                 {
2726                         vector dist;
2727
2728                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2729                         dist = self.prevorigin - self.origin;
2730                         dist_z = 0;
2731                         self.lms_traveled_distance += fabs(vlen(dist));
2732
2733                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2734                         {
2735                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2736                                 self.lms_traveled_distance = 0;
2737                         }
2738
2739                         if(time > self.lms_nextcheck)
2740                         {
2741                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2742                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2743                                 {
2744                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2745                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2746                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2747                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2748                                 }
2749                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2750                                 self.lms_traveled_distance = 0;
2751                         }
2752                 }
2753
2754                 self.prevorigin = self.origin;
2755
2756                 float do_crouch = self.BUTTON_CROUCH;
2757                 if(self.hook.state)
2758                         do_crouch = 0;
2759                 if(self.health <= g_bloodloss)
2760                         do_crouch = 1;
2761                 if(self.vehicle)
2762                         do_crouch = 0;
2763                 if(self.freezetag_frozen)
2764                         do_crouch = 0;
2765                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2766                         do_crouch = 0;
2767
2768                 if (do_crouch)
2769                 {
2770                         if (!self.crouch)
2771                         {
2772                                 self.crouch = TRUE;
2773                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2774                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2775                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2776                         }
2777                 }
2778                 else
2779                 {
2780                         if (self.crouch)
2781                         {
2782                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2783                                 if (!trace_startsolid)
2784                                 {
2785                                         self.crouch = FALSE;
2786                                         self.view_ofs = PL_VIEW_OFS;
2787                                         setsize (self, PL_MIN, PL_MAX);
2788                                 }
2789                         }
2790                 }
2791
2792                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2793                 {
2794                         if(self.bloodloss_timer < time)
2795                         {
2796                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2797                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2798                         }
2799                 }
2800
2801                 FixPlayermodel();
2802
2803                 GrapplingHookFrame();
2804
2805                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2806                 //if(frametime)
2807                 {
2808                         self.items &~= self.items_added;
2809
2810                         W_WeaponFrame();
2811
2812                         self.items_added = 0;
2813                         if(self.items & IT_JETPACK)
2814                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2815                                         self.items_added |= IT_FUEL;
2816
2817                         self.items |= self.items_added;
2818                 }
2819
2820                 player_regen();
2821
2822                 // rot nex charge to the charge limit
2823                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2824                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2825
2826                 if(frametime)
2827                         player_anim();
2828
2829                 if(g_nexball)
2830                         nexball_setstatus();
2831
2832                 // secret status
2833                 secrets_setstatus();
2834
2835                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2836
2837                 //self.angles_y=self.v_angle_y + 90;   // temp
2838         } else if(gameover) {
2839                 if (intermission_running)
2840                         IntermissionThink ();   // otherwise a button could be missed between
2841                 return;
2842         } else if(self.classname == "observer") {
2843                 ObserverThink();
2844         } else if(self.classname == "spectator") {
2845                 SpectatorThink();
2846         }
2847
2848         if(!zoomstate_set)
2849                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2850
2851         float oldspectatee_status;
2852         oldspectatee_status = self.spectatee_status;
2853         if(self.classname == "spectator")
2854                 self.spectatee_status = num_for_edict(self.enemy);
2855         else if(self.classname == "observer")
2856                 self.spectatee_status = num_for_edict(self);
2857         else
2858                 self.spectatee_status = 0;
2859         if(self.spectatee_status != oldspectatee_status)
2860         {
2861                 ClientData_Touch(self);
2862                 if(g_race || g_cts)
2863                         race_InitSpectator();
2864         }
2865
2866         if(self.teamkill_soundtime)
2867         if(time > self.teamkill_soundtime)
2868         {
2869                 self.teamkill_soundtime = 0;
2870
2871                 entity oldpusher, oldself;
2872
2873                 oldself = self; self = self.teamkill_soundsource;
2874                 oldpusher = self.pusher; self.pusher = oldself;
2875
2876                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2877
2878                 self.pusher = oldpusher;
2879                 self = oldself;
2880         }
2881
2882         if(self.taunt_soundtime)
2883         if(time > self.taunt_soundtime)
2884         {
2885                 self.taunt_soundtime = 0;
2886                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2887         }
2888
2889         target_voicescript_next(self);
2890
2891         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2892         if(!self.weapon)
2893                 self.clip_load = self.clip_size = 0;
2894 }
2895
2896 float isInvisibleString(string s)
2897 {
2898         float i, n, c;
2899         s = strdecolorize(s);
2900         for((i = 0), (n = strlen(s)); i < n; ++i)
2901         {
2902                 c = str2chr(s, i);
2903                 switch(c)
2904                 {
2905                         case 0:
2906                         case 32: // space
2907                                 break;
2908                         case 192: // charmap space
2909                                 if (!autocvar_utf8_enable)
2910                                         break;
2911                                 return FALSE;
2912                         case 160: // space in unicode fonts
2913                         case 0xE000 + 192: // utf8 charmap space
2914                                 if (autocvar_utf8_enable)
2915                                         break;
2916                         default:
2917                                 return FALSE;
2918                 }
2919         }
2920         return TRUE;
2921 }
2922
2923 /*
2924 =============
2925 PlayerPostThink
2926
2927 Called every frame for each client after the physics are run
2928 =============
2929 */
2930 .float idlekick_lasttimeleft;
2931 void PlayerPostThink (void)
2932 {
2933         // Savage: Check for nameless players
2934         if (isInvisibleString(self.netname)) {
2935                 self.netname = "Player";
2936                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2937         }
2938
2939         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2940         {
2941                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2942                 {
2943                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2944                 }
2945                 else
2946                 {
2947                         float timeleft;
2948                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2949                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2950                         {
2951                                 if(!self.idlekick_lasttimeleft)
2952                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2953                         }
2954                         if(timeleft <= 0)
2955                         {
2956                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2957                                 dropclient(self);
2958                                 return;
2959                         }
2960                         else if(timeleft <= 10)
2961                         {
2962                                 if(timeleft != self.idlekick_lasttimeleft)
2963                                         AnnounceTo(self, ftos(timeleft));
2964                                 self.idlekick_lasttimeleft = timeleft;
2965                         }
2966                 }
2967         }
2968
2969 #ifdef TETRIS
2970         if(self.impulse == 100)
2971                 ImpulseCommands();
2972         if (!TetrisPostFrame())
2973         {
2974 #endif
2975
2976         CheatFrame();
2977
2978         //CheckPlayerJump();
2979
2980         if(self.classname == "player") {
2981                 CheckRules_Player();
2982                 UpdateChatBubble();
2983                 if (self.impulse)
2984                         ImpulseCommands();
2985                 if (intermission_running)
2986                         return;         // intermission or finale
2987                 GetPressedKeys();
2988         }
2989
2990 #ifdef TETRIS
2991         }
2992 #endif
2993
2994         /*
2995         float i;
2996         for(i = 0; i < 1000; ++i)
2997         {
2998                 vector end;
2999                 end = self.origin + '0 0 1024' + 512 * randomvec();
3000                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3001                 if(trace_fraction < 1)
3002                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3003                 {
3004                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3005                         break;
3006                 }
3007         }
3008         */
3009
3010         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3011
3012         if(self.waypointsprite_attachedforcarrier)
3013                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3014
3015         playerdemo_write();
3016
3017         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3018         {
3019                 if not(self.stored_netname)
3020                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3021                 if(self.stored_netname != self.netname)
3022                 {
3023                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3024                         strunzone(self.stored_netname);
3025                         self.stored_netname = strzone(self.netname);
3026                 }
3027         }
3028
3029         /*
3030         if(g_race)
3031                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3032         */
3033
3034         CSQCMODEL_AUTOUPDATE();
3035 }