qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void send_CSQC_cr_maxbullets(entity e) {
  10         msg_entity = e;
  11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
  13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
  14 }
  15
  16 void Announce(string snd) {
  17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  19         WriteString(MSG_ALL, snd);
  20 }
  21
  22 void AnnounceTo(entity e, string snd) {
  23         if (clienttype(e) == CLIENTTYPE_REAL)
  24         {
  25                 msg_entity = e;
  26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  28                 WriteString(MSG_ONE, snd);
  29         }
  30 }
  31
  32 float ClientData_Send(entity to, float sf)
  33 {
  34         if(to != self.owner)
  35         {
  36                 error("wtf");
  37                 return FALSE;
  38         }
  39
  40         entity e;
  41
  42         e = to;
  43         if(to.classname == "spectator")
  44                 e = to.enemy;
  45
  46         sf = 0;
  47
  48         if(e.race_completed)
  49                 sf |= 1; // forced scoreboard
  50         if(to.spectatee_status)
  51                 sf |= 2; // spectator ent number follows
  52         if(e.zoomstate)
  53                 sf |= 4; // zoomed
  54         if(e.porto_v_angle_held)
  55                 sf |= 8; // angles held
  56
  57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  58         WriteByte(MSG_ENTITY, sf);
  59
  60         if(sf & 2)
  61                 WriteByte(MSG_ENTITY, to.spectatee_status);
  62
  63         if(sf & 8)
  64         {
  65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  67         }
  68
  69         return TRUE;
  70 }
  71
  72 void ClientData_Attach()
  73 {
  74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  75         self.clientdata.drawonlytoclient = self;
  76         self.clientdata.owner = self;
  77 }
  78
  79 void ClientData_Detach()
  80 {
  81         remove(self.clientdata);
  82         self.clientdata = world;
  83 }
  84
  85 void ClientData_Touch(entity e)
  86 {
  87         e.clientdata.SendFlags = 1;
  88
  89         // make it spectatable
  90         entity e2;
  91         FOR_EACH_REALCLIENT(e2)
  92         {
  93                 if(e2 != e)
  94                         if(e2.classname == "spectator")
  95                                 if(e2.enemy == e)
  96                                         e2.clientdata.SendFlags = 1;
  97         }
  98 }
  99
 100
 101 .vector spawnpoint_score;
 102 .string netname_previous;
 103
 104 void spawnfunc_info_player_survivor (void)
 105 {
 106         spawnfunc_info_player_deathmatch();
 107 }
 108
 109 void spawnfunc_info_player_start (void)
 110 {
 111         spawnfunc_info_player_deathmatch();
 112 }
 113
 114 void spawnfunc_info_player_deathmatch (void)
 115 {
 116         self.classname = "info_player_deathmatch";
 117         relocate_spawnpoint();
 118 }
 119
 120 void spawnpoint_use()
 121 {
 122         if(teams_matter)
 123         if(have_team_spawns > 0)
 124         {
 125                 self.team = activator.team;
 126                 some_spawn_has_been_used = 1;
 127         }
 128 };
 129
 130 // Returns:
 131 //   _x: prio (-1 if unusable)
 132 //   _y: weight
 133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 134 {
 135         float shortest, thisdist;
 136         float prio;
 137         entity player;
 138
 139         prio = 0;
 140
 141         // filter out spots for the wrong team
 142         if(teamcheck)
 143         if(spot.team != teamcheck)
 144                 return '-1 0 0';
 145
 146         if(race_spawns)
 147                 if(spot.target == "")
 148                         return '-1 0 0';
 149
 150         if(clienttype(self) == CLIENTTYPE_REAL)
 151         {
 152                 if(spot.restriction == 1)
 153                         return '-1 0 0';
 154         }
 155         else
 156         {
 157                 if(spot.restriction == 2)
 158                         return '-1 0 0';
 159         }
 160
 161         // filter out spots for assault
 162         if(spot.target != "") {
 163                 local entity ent;
 164                 float good, found;
 165                 ent = find(world, targetname, spot.target);
 166
 167                 while(ent) {
 168                         if(ent.classname == "target_objective")
 169                         {
 170                                 found = 1;
 171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 172                                         return '-1 0 0';
 173                                 good = 1;
 174                         }
 175                         else if(ent.classname == "trigger_race_checkpoint")
 176                         {
 177                                 found = 1;
 178                                 if(!anypoint) // spectators may spawn everywhere
 179
 180                                 {
 181                                         if(g_race_qualifying)
 182                                         {
 183                                                 // spawn at first
 184                                                 if(ent.race_checkpoint != 0)
 185                                                         return '-1 0 0';
 186                                                 if(spot.race_place != race_lowest_place_spawn)
 187                                                         return '-1 0 0';
 188                                         }
 189                                         else
 190                                         {
 191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 192                                                         return '-1 0 0';
 193                                                 // try reusing the previous spawn
 194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 195                                                         prio += 1;
 196                                                 if(ent.race_checkpoint == 0)
 197                                                 {
 198                                                         float pl;
 199                                                         pl = self.race_place;
 200                                                         if(pl > race_highest_place_spawn)
 201                                                                 pl = 0;
 202                                                         if(pl == 0 && !self.race_started)
 203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 204                                                         if(spot.race_place != pl)
 205                                                                 return '-1 0 0';
 206                                                 }
 207                                         }
 208                                 }
 209                                 good = 1;
 210                         }
 211                         ent = find(ent, targetname, spot.target);
 212                 }
 213
 214                 if(found && !good)
 215                         return '-1 0 0';
 216         }
 217
 218         player = playerlist;
 219         shortest = vlen(world.maxs - world.mins);
 220         for(player = playerlist; player; player = player.chain)
 221                 if (player != self)
 222                 {
 223                         thisdist = vlen(player.origin - spot.origin);
 224                         if (thisdist < shortest)
 225                                 shortest = thisdist;
 226                 }
 227         return prio * '1 0 0' + shortest * '0 1 0';
 228 }
 229
 230 float spawn_allbad;
 231 float spawn_allgood;
 232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 233 {
 234         local entity spot, spotlist, spotlistend;
 235         spawn_allgood = TRUE;
 236         spawn_allbad = TRUE;
 237
 238         spotlist = world;
 239         spotlistend = world;
 240
 241         for(spot = firstspot; spot; spot = spot.chain)
 242         {
 243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 244
 245                 if(cvar("spawn_debugview"))
 246                 {
 247                         setmodel(spot, "models/runematch/rune.mdl");
 248                         if(spot.spawnpoint_score_y < mindist)
 249                         {
 250                                 spot.colormod = '1 0 0';
 251                                 spot.scale = 1;
 252                         }
 253                         else
 254                         {
 255                                 spot.colormod = '0 1 0';
 256                                 spot.scale = spot.spawnpoint_score_y / mindist;
 257                         }
 258                 }
 259
 260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 261                 {
 262                         if(spot.spawnpoint_score_y < mindist)
 263                         {
 264                                 // too short distance
 265                                 spawn_allgood = FALSE;
 266                         }
 267                         else
 268                         {
 269                                 // perfect
 270                                 spawn_allbad = FALSE;
 271
 272                                 if(spotlistend)
 273                                         spotlistend.chain = spot;
 274                                 spotlistend = spot;
 275                                 if(!spotlist)
 276                                         spotlist = spot;
 277
 278                                 /*
 279                                 if(teamcheck)
 280                                 if(spot.team != teamcheck)
 281                                         error("invalid spawn added");
 282
 283                                 print("added ", etos(spot), "\n");
 284                                 */
 285                         }
 286                 }
 287         }
 288         if(spotlistend)
 289                 spotlistend.chain = world;
 290
 291         /*
 292                 entity e;
 293                 if(teamcheck)
 294                         for(e = spotlist; e; e = e.chain)
 295                         {
 296                                 print("seen ", etos(e), "\n");
 297                                 if(e.team != teamcheck)
 298                                         error("invalid spawn found");
 299                         }
 300         */
 301
 302         return spotlist;
 303 }
 304
 305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 306 {
 307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 309         local entity spot;
 310
 311         RandomSelection_Init();
 312         for(spot = firstspot; spot; spot = spot.chain)
 313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 314
 315         return RandomSelection_chosen_ent;
 316 }
 317
 318 /*
 319 =============
 320 SelectSpawnPoint
 321
 322 Finds a point to respawn
 323 =============
 324 */
 325 entity SelectSpawnPoint (float anypoint)
 326 {
 327         local float teamcheck;
 328         local entity firstspot_new;
 329         local entity spot, firstspot, playerlist;
 330
 331         spot = find (world, classname, "testplayerstart");
 332         if (spot)
 333                 return spot;
 334
 335         teamcheck = 0;
 336
 337         if(!anypoint && have_team_spawns > 0)
 338                 teamcheck = self.team;
 339
 340         // get the list of players
 341         playerlist = findchain(classname, "player");
 342         // get the entire list of spots
 343         firstspot = findchain(classname, "info_player_deathmatch");
 344         // filter out the bad ones
 345         // (note this returns the original list if none survived)
 346         if(anypoint)
 347         {
 348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 349         }
 350         else
 351         {
 352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 353                 if(!firstspot_new)
 354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 355                 firstspot = firstspot_new;
 356
 357                 // there is 50/50 chance of choosing a random spot or the furthest spot
 358                 // (this means that roughly every other spawn will be furthest, so you
 359                 // usually won't get fragged at spawn twice in a row)
 360                 if (arena_roundbased && !g_ca)
 361                 {
 362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 363                         if(firstspot_new)
 364                                 firstspot = firstspot_new;
 365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 366                 }
 367                 else if (random() > cvar("g_spawn_furthest"))
 368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 369                 else
 370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 371         }
 372
 373         if(cvar("spawn_debugview"))
 374         {
 375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 376
 377                 entity e;
 378                 if(teamcheck)
 379                         for(e = firstspot; e; e = e.chain)
 380                                 if(e.team != teamcheck)
 381                                         error("invalid spawn found");
 382         }
 383
 384         if (!spot)
 385         {
 386                 if(cvar("spawn_debug"))
 387                         GotoNextMap();
 388                 else
 389                 {
 390                         if(some_spawn_has_been_used)
 391                                 return world; // team can't spawn any more, because of actions of other team
 392                         else
 393                                 error("Cannot find a spawn point - please fix the map!");
 394                 }
 395         }
 396
 397         return spot;
 398 }
 399
 400 /*
 401 =============
 402 CheckPlayerModel
 403
 404 Checks if the argument string can be a valid playermodel.
 405 Returns a valid one in doubt.
 406 =============
 407 */
 408 string FallbackPlayerModel;
 409 string CheckPlayerModel(string plyermodel) {
 410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 411         {
 412                 // note: we cannot summon Don Strunzone here, some player may
 413                 // still have the model string set. In case anyone manages how
 414                 // to change a cvar default, we'll have a small leak here.
 415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 416         }
 417         if(strlen(plyermodel) < 4)
 418                 return FallbackPlayerModel;
 419         if( substring(plyermodel,0,14) != "models/player/")
 420                 return FallbackPlayerModel;
 421         else if(cvar("sv_servermodelsonly"))
 422         {
 423                 if(substring(plyermodel,-4,4) != ".zym")
 424                 if(substring(plyermodel,-4,4) != ".dpm")
 425                 if(substring(plyermodel,-4,4) != ".iqm")
 426                 if(substring(plyermodel,-4,4) != ".md3")
 427                 if(substring(plyermodel,-4,4) != ".psk")
 428                         return FallbackPlayerModel;
 429                 // forbid the LOD models
 430                 if(substring(plyermodel, -9,5) == "_lod1")
 431                         return FallbackPlayerModel;
 432                 if(substring(plyermodel, -9,5) == "_lod2")
 433                         return FallbackPlayerModel;
 434                 if(plyermodel != strtolower(plyermodel))
 435                         return FallbackPlayerModel;
 436                 if(!fexists(plyermodel))
 437                         return FallbackPlayerModel;
 438         }
 439         return plyermodel;
 440 }
 441
 442 /*
 443 =============
 444 Client_customizeentityforclient
 445
 446 LOD reduction
 447 =============
 448 */
 449 void Client_uncustomizeentityforclient()
 450 {
 451         if(self.modelindex == 0) // no need to uncustomize then
 452                 return;
 453         self.modelindex = self.modelindex_lod0;
 454         self.skin = self.skinindex;
 455 }
 456
 457 float Client_customizeentityforclient()
 458 {
 459         entity modelsource;
 460
 461         if(self.modelindex == 0)
 462                 return TRUE;
 463
 464         // forcemodel stuff
 465
 466 #ifdef PROFILING
 467         float t0;
 468         t0 = gettime(GETTIME_HIRES); // reference
 469 #endif
 470
 471         modelsource = self;
 472
 473 #ifdef ALLOW_FORCEMODELS
 474         if(other.cvar_cl_forceplayermodelsfromxonotic)
 475                 if not(self.modelindex_lod0_from_xonotic)
 476                         modelsource = other;
 477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 478                 modelsource = other;
 479 #endif
 480
 481         self.skin = modelsource.skinindex;
 482
 483 #if 0
 484         if(modelsource == self)
 485                 self.skin = modelsource.skinindex;
 486         else
 487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 488 #endif
 489
 490         // self: me
 491         // other: the player viewing me
 492         float distance;
 493         float f;
 494
 495         if(other.cvar_cl_playerdetailreduction <= 0)
 496         {
 497                 if(other.cvar_cl_playerdetailreduction <= -2)
 498                         self.modelindex = modelsource.modelindex_lod2;
 499                 else if(other.cvar_cl_playerdetailreduction <= -1)
 500                         self.modelindex = modelsource.modelindex_lod1;
 501                 else
 502                         self.modelindex = modelsource.modelindex_lod0;
 503         }
 504         else
 505         {
 506                 distance = vlen(self.origin - other.origin);
 507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 508                 if(f > sv_loddistance2)
 509                         self.modelindex = modelsource.modelindex_lod2;
 510                 else if(f > sv_loddistance1)
 511                         self.modelindex = modelsource.modelindex_lod1;
 512                 else
 513                         self.modelindex = modelsource.modelindex_lod0;
 514         }
 515
 516 #ifdef PROFILING
 517         float t1;
 518         t1 = gettime(GETTIME_HIRES); // reference
 519         client_cefc_accumulator += (t1 - t0);
 520 #endif
 521
 522         return TRUE;
 523 }
 524
 525 void setmodel_lod(entity e, string modelname)
 526 {
 527         string s;
 528
 529         if(sv_loddistance1)
 530         {
 531                 // FIXME: this only supports 3-letter extensions
 532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 533                 if(fexists(s))
 534                 {
 535                         setmodel(e, s); // players have high precision
 536                         self.modelindex_lod1 = self.modelindex;
 537                 }
 538                 else
 539                         self.modelindex_lod1 = -1;
 540
 541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 542                 if(fexists(s))
 543                 {
 544                         setmodel(e, s); // players have high precision
 545                         self.modelindex_lod2 = self.modelindex;
 546                 }
 547                 else
 548                         self.modelindex_lod2 = -1;
 549
 550                 precache_model(modelname);
 551                 setmodel(e, modelname); // players have high precision
 552                 self.modelindex_lod0 = self.modelindex;
 553
 554                 if(self.modelindex_lod1 < 0)
 555                         self.modelindex_lod1 = self.modelindex;
 556
 557                 if(self.modelindex_lod2 < 0)
 558                         self.modelindex_lod2 = self.modelindex;
 559         }
 560         else
 561         {
 562                 precache_model(modelname);
 563                 setmodel(e, modelname); // players have high precision
 564                 self.modelindex_lod0 = self.modelindex;
 565                         // save it for possible player model forcing
 566         }
 567
 568         s = whichpack(self.model);
 569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 570
 571         player_setupanimsformodel();
 572         UpdatePlayerSounds();
 573 }
 574
 575 /*
 576 =============
 577 PutObserverInServer
 578
 579 putting a client as observer in the server
 580 =============
 581 */
 582 void FixPlayermodel();
 583 void PutObserverInServer (void)
 584 {
 585         entity  spot;
 586
 587         race_PreSpawnObserver();
 588
 589         spot = SelectSpawnPoint (TRUE);
 590         if(!spot)
 591                 error("No spawnpoints for observers?!?\n");
 592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 593
 594         if(clienttype(self) == CLIENTTYPE_REAL)
 595         {
 596                 msg_entity = self;
 597                 WriteByte(MSG_ONE, SVC_SETVIEW);
 598                 WriteEntity(MSG_ONE, self);
 599         }
 600
 601         DropAllRunes(self);
 602         MUTATOR_CALLHOOK(MakePlayerObserver);
 603
 604         Portal_ClearAll(self);
 605
 606         if(self.flagcarried)
 607                 DropFlag(self.flagcarried, world, world);
 608
 609         if(self.ballcarried)
 610                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 611
 612         WaypointSprite_PlayerDead();
 613
 614         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 615                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 616
 617         if(self.killcount != -666) {
 618                 if(g_lms) {
 619                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 620                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 621                         else
 622                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 623                 } else
 624                         bprint ("^4", self.netname, "^4 is spectating now\n");
 625
 626                 if(self.just_joined == FALSE) {
 627                         LogTeamchange(self.playerid, -1, 4);
 628                 } else
 629                         self.just_joined = FALSE;
 630         }
 631
 632         PlayerScore_Clear(self); // clear scores when needed
 633
 634         accuracy_resend(self);
 635
 636         self.spectatortime = time;
 637
 638         self.classname = "observer";
 639         self.iscreature = FALSE;
 640         self.health = -666;
 641         self.takedamage = DAMAGE_NO;
 642         self.solid = SOLID_NOT;
 643         self.movetype = MOVETYPE_NOCLIP;
 644         self.flags = FL_CLIENT | FL_NOTARGET;
 645         self.armorvalue = 666;
 646         self.effects = 0;
 647         self.armorvalue = cvar("g_balance_armor_start");
 648         self.pauserotarmor_finished = 0;
 649         self.pauserothealth_finished = 0;
 650         self.pauseregen_finished = 0;
 651         self.damageforcescale = 0;
 652         self.death_time = 0;
 653         self.dead_frame = 0;
 654         self.alpha = 0;
 655         self.scale = 0;
 656         self.fade_time = 0;
 657         self.pain_frame = 0;
 658         self.pain_finished = 0;
 659         self.strength_finished = 0;
 660         self.invincible_finished = 0;
 661         self.pushltime = 0;
 662         self.think = SUB_Null;
 663         self.nextthink = 0;
 664         self.hook_time = 0;
 665         self.runes = 0;
 666         self.deadflag = DEAD_NO;
 667         self.angles = spot.angles;
 668         self.angles_z = 0;
 669         self.fixangle = TRUE;
 670         self.crouch = FALSE;
 671
 672         self.view_ofs = PL_VIEW_OFS;
 673         setorigin (self, spot.origin);
 674         setsize (self, '0 0 0', '0 0 0');
 675         self.prevorigin = self.origin;
 676         self.items = 0;
 677         self.weapons = 0;
 678         self.model = "";
 679         FixPlayermodel();
 680         self.model = "";
 681         self.modelindex = 0;
 682         self.weapon = 0;
 683         self.weaponmodel = "";
 684         self.weaponentity = world;
 685         self.exteriorweaponentity = world;
 686         self.killcount = -666;
 687         self.velocity = '0 0 0';
 688         self.avelocity = '0 0 0';
 689         self.punchangle = '0 0 0';
 690         self.punchvector = '0 0 0';
 691         self.oldvelocity = self.velocity;
 692         self.fire_endtime = -1;
 693
 694         if(sv_loddistance1)
 695                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 696
 697         if(g_arena)
 698         {
 699                 if(self.version_mismatch)
 700                 {
 701                         Spawnqueue_Unmark(self);
 702                         Spawnqueue_Remove(self);
 703                 }
 704                 else
 705                 {
 706                         Spawnqueue_Insert(self);
 707                 }
 708         }
 709         else if(g_lms)
 710         {
 711                 // Only if the player cannot play at all
 712                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 713                         self.frags = FRAGS_SPECTATOR;
 714                 else
 715                         self.frags = FRAGS_LMS_LOSER;
 716         }
 717         else
 718                 self.frags = FRAGS_SPECTATOR;
 719 }
 720
 721 float RestrictSkin(float s)
 722 {
 723         if(!teams_matter)
 724                 return s;
 725         if(s == 6)
 726                 return 6;
 727         return mod(s, 3);
 728 }
 729
 730 void FixPlayermodel()
 731 {
 732         local string defaultmodel;
 733         local float defaultskin, chmdl, oldskin;
 734         local vector m1, m2;
 735
 736         defaultmodel = "";
 737
 738         if(cvar("sv_defaultcharacter") == 1) {
 739                 defaultskin = 0;
 740
 741                 if(teams_matter)
 742                 {
 743                         string s;
 744                         s = Team_ColorNameLowerCase(self.team);
 745                         if(s != "neutral")
 746                         {
 747                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 748                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 749                         }
 750                 }
 751
 752                 if(defaultmodel == "")
 753                 {
 754                         defaultmodel = cvar_string("sv_defaultplayermodel");
 755                         defaultskin = cvar("sv_defaultplayerskin");
 756                 }
 757         }
 758
 759         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 760         {
 761                 if(self.model != "")
 762                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 763                 self.model = ""; // force the != checks to return true
 764         }
 765
 766         if(defaultmodel != "")
 767         {
 768                 if (defaultmodel != self.model)
 769                 {
 770                         m1 = self.mins;
 771                         m2 = self.maxs;
 772                         setmodel_lod (self, defaultmodel);
 773                         setsize (self, m1, m2);
 774                         chmdl = TRUE;
 775                 }
 776
 777                 oldskin = self.skinindex;
 778                 self.skinindex = defaultskin;
 779         } else {
 780                 if (self.playermodel != self.model || self.playermodel == "")
 781                 {
 782                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, self.playermodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = RestrictSkin(stof(self.playerskin));
 792         }
 793
 794         if(chmdl || oldskin != self.skinindex)
 795                 self.species = player_getspecies(); // model or skin has changed
 796
 797         if(!teams_matter)
 798                 if(strlen(cvar_string("sv_defaultplayercolors")))
 799                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 800                                 setcolor(self, cvar("sv_defaultplayercolors"));
 801 }
 802
 803 void PlayerTouchExplode(entity p1, entity p2)
 804 {
 805         vector org;
 806         org = (p1.origin + p2.origin) * 0.5;
 807         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 808
 809         te_explosion(org);
 810
 811         entity e;
 812         e = spawn();
 813         setorigin(e, org);
 814         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 815         remove(e);
 816 }
 817
 818 /*
 819 =============
 820 PutClientInServer
 821
 822 Called when a client spawns in the server
 823 =============
 824 */
 825 //void() ctf_playerchanged;
 826 void PutClientInServer (void)
 827 {
 828         if(clienttype(self) == CLIENTTYPE_BOT)
 829         {
 830                 self.classname = "player";
 831         }
 832         else if(clienttype(self) == CLIENTTYPE_REAL)
 833         {
 834                 msg_entity = self;
 835                 WriteByte(MSG_ONE, SVC_SETVIEW);
 836                 WriteEntity(MSG_ONE, self);
 837         }
 838
 839         // player is dead and becomes observer
 840         // FIXME fix LMS scoring for new system
 841         if(g_lms)
 842         {
 843                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 844                         self.classname = "observer";
 845         }
 846
 847         if(g_arena || (g_ca && !allowed_to_spawn))
 848         if(!self.spawned)
 849                 self.classname = "observer";
 850
 851         if(gameover)
 852                 self.classname = "observer";
 853
 854         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 855                 entity spot, oldself;
 856                 float j;
 857
 858                 accuracy_resend(self);
 859
 860                 if(self.team < 0)
 861                         JoinBestTeam(self, FALSE, TRUE);
 862
 863                 race_PreSpawn();
 864
 865                 spot = SelectSpawnPoint (FALSE);
 866                 if(!spot)
 867                 {
 868                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 869                         return; // spawn failed
 870                 }
 871
 872                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 873
 874                 self.classname = "player";
 875                 self.wasplayer = TRUE;
 876                 self.iscreature = TRUE;
 877                 self.movetype = MOVETYPE_WALK;
 878                 self.solid = SOLID_SLIDEBOX;
 879                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 880                 if(cvar("g_playerclip_collisions"))
 881                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 882                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 883                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 884                 self.frags = FRAGS_PLAYER;
 885                 if(independent_players)
 886                         MAKE_INDEPENDENT_PLAYER(self);
 887                 self.flags = FL_CLIENT;
 888                 self.takedamage = DAMAGE_AIM;
 889                 if(g_minstagib)
 890                         self.effects = EF_FULLBRIGHT;
 891                 else
 892                         self.effects = 0;
 893                 self.air_finished = time + 12;
 894                 self.dmg = 2;
 895                 if(cvar("g_balance_nex_charge"))
 896                 {
 897                         if(cvar("g_balance_nex_secondary_charge_pool"))
 898                                 self.nex_charge_pool_ammo = 1;
 899                         self.nex_charge = cvar("g_balance_nex_charge_start");
 900                 }
 901
 902                 if(inWarmupStage)
 903                 {
 904                         self.ammo_shells = warmup_start_ammo_shells;
 905                         self.ammo_nails = warmup_start_ammo_nails;
 906                         self.ammo_rockets = warmup_start_ammo_rockets;
 907                         self.ammo_cells = warmup_start_ammo_cells;
 908                         self.ammo_fuel = warmup_start_ammo_fuel;
 909                         self.health = warmup_start_health;
 910                         self.armorvalue = warmup_start_armorvalue;
 911                         self.weapons = warmup_start_weapons;
 912                 }
 913                 else
 914                 {
 915                         self.ammo_shells = start_ammo_shells;
 916                         self.ammo_nails = start_ammo_nails;
 917                         self.ammo_rockets = start_ammo_rockets;
 918                         self.ammo_cells = start_ammo_cells;
 919                         self.ammo_fuel = start_ammo_fuel;
 920                         self.health = start_health;
 921                         self.armorvalue = start_armorvalue;
 922                         self.weapons = start_weapons;
 923                 }
 924
 925                 if(g_weaponarena_random)
 926                 {
 927                         if(g_weaponarena_random_with_laser)
 928                                 self.weapons &~= WEPBIT_LASER;
 929                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 930                         if(g_weaponarena_random_with_laser)
 931                                 self.weapons |= WEPBIT_LASER;
 932                 }
 933
 934                 self.items = start_items;
 935                 self.jump_interval = time;
 936
 937                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 938                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 939                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 940                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 941                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 942                 //extend the pause of rotting if client was reset at the beginning of the countdown
 943                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 944                         self.spawnshieldtime += game_starttime - time;
 945                         self.pauserotarmor_finished += game_starttime - time;
 946                         self.pauserothealth_finished += game_starttime - time;
 947                         self.pauseregen_finished += game_starttime - time;
 948                 }
 949                 self.damageforcescale = 2;
 950                 self.death_time = 0;
 951                 self.dead_frame = 0;
 952                 self.alpha = 0;
 953                 self.scale = 0;
 954                 self.fade_time = 0;
 955                 self.pain_frame = 0;
 956                 self.pain_finished = 0;
 957                 self.strength_finished = 0;
 958                 self.invincible_finished = 0;
 959                 self.pushltime = 0;
 960                 // players have no think function
 961                 self.think = SUB_Null;
 962                 self.nextthink = 0;
 963                 self.hook_time = 0;
 964                 self.dmg_team = 0;
 965                 self.ballistics_density = cvar("g_ballistics_density_player");
 966
 967                 self.metertime = 0;
 968
 969                 self.runes = 0;
 970
 971                 self.deadflag = DEAD_NO;
 972
 973                 self.angles = spot.angles;
 974
 975                 self.angles_z = 0; // never spawn tilted even if the spot says to
 976                 self.fixangle = TRUE; // turn this way immediately
 977                 self.velocity = '0 0 0';
 978                 self.avelocity = '0 0 0';
 979                 self.punchangle = '0 0 0';
 980                 self.punchvector = '0 0 0';
 981                 self.oldvelocity = self.velocity;
 982                 self.fire_endtime = -1;
 983
 984                 msg_entity = self;
 985                 WRITESPECTATABLE_MSG_ONE({
 986                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 987                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 988                 });
 989
 990                 if(sv_loddistance1)
 991                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 992
 993                 self.model = "";
 994                 FixPlayermodel();
 995
 996                 self.crouch = FALSE;
 997                 self.view_ofs = PL_VIEW_OFS;
 998                 setsize (self, PL_MIN, PL_MAX);
 999                 self.spawnorigin = spot.origin;
1000                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1001                 // don't reset back to last position, even if new position is stuck in solid
1002                 self.oldorigin = self.origin;
1003                 self.prevorigin = self.origin;
1004                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1005
1006                 if(g_arena)
1007                 {
1008                         Spawnqueue_Remove(self);
1009                         Spawnqueue_Mark(self);
1010                 }
1011
1012                 else if(g_ca)
1013                         self.caplayer = 1;
1014
1015                 self.event_damage = PlayerDamage;
1016
1017                 self.bot_attack = TRUE;
1018
1019                 self.statdraintime = time + 5;
1020                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1021
1022                 if(self.killcount == -666) {
1023                         PlayerScore_Clear(self);
1024                         self.killcount = 0;
1025                 }
1026
1027                 self.cnt = WEP_LASER;
1028
1029                 CL_SpawnWeaponentity();
1030                 self.alpha = default_player_alpha;
1031                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1032                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1033
1034                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1035                 self.lms_traveled_distance = 0;
1036                 self.speedrunning = FALSE;
1037
1038                 race_PostSpawn(spot);
1039
1040                 if(cvar("spawn_debug"))
1041                 {
1042                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1043                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1044                 }
1045
1046                 //stuffcmd(self, "chase_active 0");
1047                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1048
1049                 if (cvar("g_spawnsound"))
1050                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1051
1052                 if(g_assault) {
1053                         if(self.team == assault_attacker_team)
1054                                 centerprint(self, "You are attacking!");
1055                         else
1056                                 centerprint(self, "You are defending!");
1057                 }
1058
1059                 target_voicescript_clear(self);
1060
1061                 // reset fields the weapons may use
1062                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1063                         weapon_action(j, WR_RESETPLAYER);
1064
1065                 oldself = self;
1066                 self = spot;
1067                         activator = oldself;
1068                                 SUB_UseTargets();
1069                         activator = world;
1070                 self = oldself;
1071
1072                 MUTATOR_CALLHOOK(PlayerSpawn);
1073
1074                 self.switchweapon = w_getbestweapon(self);
1075                 self.cnt = self.switchweapon;
1076                 self.weapon = 0;
1077         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1078                 PutObserverInServer ();
1079         }
1080
1081         //if(g_ctf)
1082         //      ctf_playerchanged();
1083 }
1084
1085 .float ebouncefactor, ebouncestop; // electro's values
1086 // TODO do we need all these fields, or should we stop autodetecting runtime
1087 // changes and just have a console command to update this?
1088 float ClientInit_SendEntity(entity to, float sf)
1089 {
1090         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1091         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1104         if(sv_foginterval && world.fog != "")
1105                 WriteString(MSG_ENTITY, world.fog);
1106         else
1107                 WriteString(MSG_ENTITY, "");
1108         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1109         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1110         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1111         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1112         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1113         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1114         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1115         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1116         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1117         return TRUE;
1118 }
1119
1120 void ClientInit_CheckUpdate()
1121 {
1122         self.nextthink = time;
1123         if(self.count != cvar("g_balance_armor_blockpercent"))
1124         {
1125                 self.count = cvar("g_balance_armor_blockpercent");
1126                 self.SendFlags |= 1;
1127         }
1128         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1129         {
1130                 self.cnt = cvar("g_balance_weaponswitchdelay");
1131                 self.SendFlags |= 1;
1132         }
1133         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1134         {
1135                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1136                 self.SendFlags |= 1;
1137         }
1138         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1139         {
1140                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1141                 self.SendFlags |= 1;
1142         }
1143         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1144         {
1145                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1146                 self.SendFlags |= 1;
1147         }
1148         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1149         {
1150                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1151                 self.SendFlags |= 1;
1152         }
1153 }
1154
1155 void ClientInit_Spawn()
1156 {
1157         entity o;
1158         entity e;
1159         e = spawn();
1160         e.classname = "clientinit";
1161         e.think = ClientInit_CheckUpdate;
1162         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1163
1164         o = self;
1165         self = e;
1166         ClientInit_CheckUpdate();
1167         self = o;
1168 }
1169
1170 /*
1171 =============
1172 SetNewParms
1173 =============
1174 */
1175 void SetNewParms (void)
1176 {
1177         // initialize parms for a new player
1178         parm1 = -(86400 * 366);
1179 }
1180
1181 /*
1182 =============
1183 SetChangeParms
1184 =============
1185 */
1186 void SetChangeParms (void)
1187 {
1188         // save parms for level change
1189         parm1 = self.parm_idlesince - time;
1190 }
1191
1192 /*
1193 =============
1194 DecodeLevelParms
1195 =============
1196 */
1197 void DecodeLevelParms (void)
1198 {
1199         // load parms
1200         self.parm_idlesince = parm1;
1201         if(self.parm_idlesince == -(86400 * 366))
1202                 self.parm_idlesince = time;
1203
1204         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1205         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1206 }
1207
1208 /*
1209 =============
1210 ClientKill
1211
1212 Called when a client types 'kill' in the console
1213 =============
1214 */
1215
1216 void ClientKill_Now_TeamChange()
1217 {
1218         if(self.killindicator_teamchange == -1)
1219         {
1220                 self.team = -1;
1221                 JoinBestTeam( self, FALSE, FALSE );
1222         }
1223         else
1224                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1225 }
1226
1227 void ClientKill_Now()
1228 {
1229         if(self.killindicator_teamchange)
1230                 ClientKill_Now_TeamChange();
1231
1232         // in any case:
1233         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1234
1235         if(self.killindicator)
1236         {
1237                 dprint("Cleaned up after a leaked kill indicator.\n");
1238                 remove(self.killindicator);
1239                 self.killindicator = world;
1240         }
1241 }
1242 void KillIndicator_Think()
1243 {
1244         if (!self.owner.modelindex)
1245         {
1246                 self.owner.killindicator = world;
1247                 remove(self);
1248                 return;
1249         }
1250
1251         if(self.cnt <= 0)
1252         {
1253                 self = self.owner;
1254                 ClientKill_Now(); // no oldself needed
1255                 return;
1256         }
1257         else
1258         {
1259                 if(self.cnt <= 10)
1260                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1261                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1262                 {
1263                         if(self.cnt <= 10)
1264                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1265                         if(self.owner.killindicator_teamchange)
1266                         {
1267                                 if(self.owner.killindicator_teamchange == -1)
1268                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1269                                 else
1270                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1271                         }
1272                         else
1273                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1274                 }
1275                 self.nextthink = time + 1;
1276                 self.cnt -= 1;
1277         }
1278 }
1279
1280 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1281 {
1282         float killtime;
1283         entity e;
1284         killtime = cvar("g_balance_kill_delay");
1285
1286         if(g_race_qualifying)
1287                 killtime = 0;
1288
1289         self.killindicator_teamchange = targetteam;
1290
1291         if(!self.killindicator)
1292         {
1293                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1294                 {
1295                         ClientKill_Now();
1296                 }
1297                 else
1298                 {
1299                         self.killindicator = spawn();
1300                         self.killindicator.owner = self;
1301                         self.killindicator.scale = 0.5;
1302                         setattachment(self.killindicator, self, "");
1303                         setorigin(self.killindicator, '0 0 52');
1304                         self.killindicator.think = KillIndicator_Think;
1305                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1306                         self.killindicator.cnt = ceil(killtime);
1307                         self.killindicator.count = bound(0, ceil(killtime), 10);
1308                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1309
1310                         for(e = world; (e = find(e, classname, "body")) != world; )
1311                         {
1312                                 if(e.enemy != self)
1313                                         continue;
1314                                 e.killindicator = spawn();
1315                                 e.killindicator.owner = e;
1316                                 e.killindicator.scale = 0.5;
1317                                 setattachment(e.killindicator, e, "");
1318                                 setorigin(e.killindicator, '0 0 52');
1319                                 e.killindicator.think = KillIndicator_Think;
1320                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1321                                 e.killindicator.cnt = ceil(killtime);
1322                         }
1323                         self.lip = 0;
1324                 }
1325         }
1326         if(self.killindicator)
1327         {
1328                 if(targetteam)
1329                         self.killindicator.colormod = TeamColor(targetteam);
1330                 else
1331                         self.killindicator.colormod = '0 0 0';
1332         }
1333 }
1334
1335 void ClientKill (void)
1336 {
1337         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1338         {
1339                 // do nothing
1340         }
1341     else if(g_freezetag && self.freezetag_frozen == 1)
1342     {
1343         // do nothing
1344     }
1345         else
1346                 ClientKill_TeamChange(0);
1347 }
1348
1349 void CTS_ClientKill_Think (void)
1350 {
1351         self = self.owner; // set self to the player to be killed
1352         sprint(self, "^1You were killed in order to prevent cheating!");
1353         ClientKill_Now();
1354 }
1355
1356 void CTS_ClientKill (float t) // silent version of ClientKill
1357 {
1358         entity e;
1359         e = spawn();
1360         e.owner = self;
1361         e.think = CTS_ClientKill_Think;
1362         e.nextthink = t;
1363 }
1364
1365 void DoTeamChange(float destteam)
1366 {
1367         float t, c0;
1368         if(!teams_matter)
1369         {
1370                 if(destteam >= 0)
1371                         SetPlayerColors(self, destteam);
1372                 return;
1373         }
1374         if(self.classname == "player")
1375         if(destteam == -1)
1376         {
1377                 CheckAllowedTeams(self);
1378                 t = FindSmallestTeam(self, TRUE);
1379                 switch(self.team)
1380                 {
1381                         case COLOR_TEAM1: c0 = c1; break;
1382                         case COLOR_TEAM2: c0 = c2; break;
1383                         case COLOR_TEAM3: c0 = c3; break;
1384                         case COLOR_TEAM4: c0 = c4; break;
1385                         default:          c0 = 999;
1386                 }
1387                 switch(t)
1388                 {
1389                         case 1:
1390                                 if(c0 > c1)
1391                                         destteam = COLOR_TEAM1;
1392                                 break;
1393                         case 2:
1394                                 if(c0 > c2)
1395                                         destteam = COLOR_TEAM2;
1396                                 break;
1397                         case 3:
1398                                 if(c0 > c3)
1399                                         destteam = COLOR_TEAM3;
1400                                 break;
1401                         case 4:
1402                                 if(c0 > c4)
1403                                         destteam = COLOR_TEAM4;
1404                                 break;
1405                 }
1406                 if(destteam == -1)
1407                         return;
1408         }
1409         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1410                 return;
1411         ClientKill_TeamChange(destteam);
1412 }
1413
1414 void FixClientCvars(entity e)
1415 {
1416         // send prediction settings to the client
1417         stuffcmd(e, "\nin_bindmap 0 0\n");
1418         if(g_race || g_cts)
1419                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1420         if(cvar("g_antilag") == 3) // client side hitscan
1421                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1422         if(sv_gentle)
1423                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1424         /*
1425          * we no longer need to stuff this. Remove this comment block if you feel
1426          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1427         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1428         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1429         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1430         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1431         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1432         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1433         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1434         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1435         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1436         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1437         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1438         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1439         stuffcmd(e, "cl_movement_edgefriction 1\n");
1440          */
1441 }
1442
1443 float PlayerInIDList(entity p, string idlist)
1444 {
1445         float n, i;
1446         string s;
1447
1448         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1449         if not(p.crypto_idfp)
1450                 return 0;
1451
1452         // this function allows abbreviated player IDs too!
1453         n = tokenize_console(idlist);
1454         for(i = 0; i < n; ++i)
1455         {
1456                 s = argv(i);
1457                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1458                         return 1;
1459         }
1460
1461         return 0;
1462 }
1463
1464 /*
1465 =============
1466 ClientConnect
1467
1468 Called when a client connects to the server
1469 =============
1470 */
1471 //void ctf_clientconnect();
1472 string ColoredTeamName(float t);
1473 void DecodeLevelParms (void);
1474 //void dom_player_join_team(entity pl);
1475 void ClientConnect (void)
1476 {
1477         float t;
1478
1479         if(self.flags & FL_CLIENT)
1480         {
1481                 print("Warning: ClientConnect, but already connected!\n");
1482                 return;
1483         }
1484
1485         if(Ban_MaybeEnforceBan(self))
1486                 return;
1487
1488         DecodeLevelParms();
1489
1490 #ifdef WATERMARK
1491         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1492 #endif
1493
1494         self.classname = "player_joining";
1495
1496         self.flags = FL_CLIENT;
1497         self.version_nagtime = time + 10 + random() * 10;
1498
1499         if(player_count<0)
1500         {
1501                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1502                 player_count = 0;
1503         }
1504
1505         PlayerScore_Attach(self);
1506         ClientData_Attach();
1507         accuracy_init(self);
1508
1509         bot_clientconnect();
1510
1511         playerdemo_init();
1512
1513         anticheat_init();
1514
1515         race_PreSpawnObserver();
1516
1517         //if(g_domination)
1518         //      dom_player_join_team(self);
1519
1520         // identify the right forced team
1521         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1522                 self.team_forced = COLOR_TEAM1;
1523         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1524                 self.team_forced = COLOR_TEAM2;
1525         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1526                 self.team_forced = COLOR_TEAM3;
1527         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1528                 self.team_forced = COLOR_TEAM4;
1529         else if(cvar_string("g_forced_team_otherwise") == "red")
1530                 self.team_forced = COLOR_TEAM1;
1531         else if(cvar_string("g_forced_team_otherwise") == "blue")
1532                 self.team_forced = COLOR_TEAM2;
1533         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1534                 self.team_forced = COLOR_TEAM3;
1535         else if(cvar_string("g_forced_team_otherwise") == "pink")
1536                 self.team_forced = COLOR_TEAM4;
1537         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1538                 self.team_forced = -1;
1539         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1540                 self.team_forced = -1;
1541         else
1542                 self.team_forced = 0;
1543
1544         if(!teams_matter)
1545                 if(self.team_forced > 0)
1546                         self.team_forced = 0;
1547
1548         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1549
1550         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1551                 self.classname = "observer";
1552         } else {
1553                 if(teams_matter)
1554                 {
1555                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1556                         {
1557                                 self.classname = "player";
1558                                 campaign_bots_may_start = 1;
1559                         }
1560                         else
1561                         {
1562                                 self.classname = "observer"; // do it anyway
1563                         }
1564                 }
1565                 else
1566                 {
1567                         self.classname = "player";
1568                         campaign_bots_may_start = 1;
1569                 }
1570         }
1571
1572         self.playerid = (playerid_last = playerid_last + 1);
1573
1574         if(cvar("sv_eventlog"))
1575                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1576
1577         LogTeamchange(self.playerid, self.team, 1);
1578
1579         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1580
1581         self.netname_previous = strzone(self.netname);
1582
1583         bprint("^4", self.netname, "^4 connected");
1584
1585         if(self.classname != "observer" && (g_domination || g_ctf))
1586                 bprint(" and joined the ", ColoredTeamName(self.team));
1587
1588         bprint("\n");
1589
1590         self.welcomemessage_time = 0;
1591
1592         stuffcmd(self, strcat(clientstuff, "\n"));
1593         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1594         stuffcmd(self, "cl_particles_reloadeffects\n");
1595
1596         FixClientCvars(self);
1597
1598         // spawnfunc_waypoint sprites
1599         WaypointSprite_InitClient(self);
1600
1601         // Wazat's grappling hook
1602         SetGrappleHookBindings();
1603
1604         // get autoswitch state from player when he toggles it
1605         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1606
1607         // get version info from player
1608         stuffcmd(self, "cmd clientversion $gameversion\n");
1609
1610         // get other cvars from player
1611         GetCvars(0);
1612
1613         // set cvar for team scoreboard
1614         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1615
1616         // notify about available teams
1617         if(teams_matter)
1618         {
1619                 CheckAllowedTeams(self);
1620                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1621                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1622         }
1623         else
1624                 stuffcmd(self, "set _teams_available 0\n");
1625
1626         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1627
1628         if(g_arena || g_ca)
1629         {
1630                 self.classname = "observer";
1631                 if(g_arena)
1632                         Spawnqueue_Insert(self);
1633         }
1634         /*else if(g_ctf)
1635         {
1636                 ctf_clientconnect();
1637         }*/
1638
1639         if(teams_matter || radar_showennemies)
1640                 attach_entcs();
1641
1642         bot_relinkplayerlist();
1643
1644         self.spectatortime = time;
1645         if(blockSpectators)
1646         {
1647                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1648         }
1649
1650         self.jointime = time;
1651         self.allowedTimeouts = cvar("sv_timeout_number");
1652
1653         if(clienttype(self) == CLIENTTYPE_REAL)
1654         {
1655                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1656                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1657         }
1658
1659         if(g_lms)
1660         {
1661                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1662                 {
1663                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1664                         self.frags = FRAGS_SPECTATOR;
1665                 }
1666         }
1667
1668         if(!sv_foginterval && world.fog != "")
1669                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1670
1671         SoundEntity_Attach(self);
1672
1673         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1674         {
1675                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1676                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1677         }
1678         else
1679                 self.hitplotfh = -1;
1680
1681         if(g_race || g_cts) {
1682                 string rr;
1683                 if(g_cts)
1684                         rr = CTS_RECORD;
1685                 else
1686                         rr = RACE_RECORD;
1687                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1688
1689                 msg_entity = self;
1690                 race_send_recordtime(MSG_ONE);
1691                 race_send_speedaward(MSG_ONE);
1692
1693                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1694                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1695                 race_send_speedaward_alltimebest(MSG_ONE);
1696
1697                 float i;
1698                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1699                         race_SendRankings(i, 0, 0, MSG_ONE);
1700                 }
1701         }
1702         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1703                 send_CSQC_teamnagger();
1704
1705         send_CSQC_cr_maxbullets(self);
1706
1707         CheatInitClient();
1708 }
1709
1710 /*
1711 =============
1712 ClientDisconnect
1713
1714 Called when a client disconnects from the server
1715 =============
1716 */
1717 .entity chatbubbleentity;
1718 .entity teambubbleentity;
1719 void ReadyCount();
1720 void ClientDisconnect (void)
1721 {
1722         if not(self.flags & FL_CLIENT)
1723         {
1724                 print("Warning: ClientDisconnect without ClientConnect\n");
1725                 return;
1726         }
1727
1728         CheatShutdownClient();
1729
1730         if(self.hitplotfh >= 0)
1731         {
1732                 fclose(self.hitplotfh);
1733                 self.hitplotfh = -1;
1734         }
1735
1736         anticheat_report();
1737         anticheat_shutdown();
1738
1739         playerdemo_shutdown();
1740
1741         bot_clientdisconnect();
1742
1743         if(self.entcs)
1744                 detach_entcs();
1745
1746         if(cvar("sv_eventlog"))
1747                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1748         bprint ("^4",self.netname);
1749         bprint ("^4 disconnected\n");
1750
1751         SoundEntity_Detach(self);
1752
1753         DropAllRunes(self);
1754         MUTATOR_CALLHOOK(ClientDisconnect);
1755
1756         Portal_ClearAll(self);
1757
1758         if(self.flagcarried)
1759                 DropFlag(self.flagcarried, world, world);
1760         if(self.ballcarried)
1761                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1762
1763         // Here, everything has been done that requires this player to be a client.
1764
1765         self.flags &~= FL_CLIENT;
1766
1767         if (self.chatbubbleentity)
1768                 remove (self.chatbubbleentity);
1769
1770         if (self.teambubbleentity)
1771                 remove (self.teambubbleentity);
1772
1773         if (self.killindicator)
1774                 remove (self.killindicator);
1775
1776         WaypointSprite_PlayerGone();
1777
1778         bot_relinkplayerlist();
1779
1780         if(g_arena)
1781         {
1782                 Spawnqueue_Unmark(self);
1783                 Spawnqueue_Remove(self);
1784         }
1785
1786         accuracy_free(self);
1787         ClientData_Detach();
1788         PlayerScore_Detach(self);
1789
1790         if(self.netname_previous)
1791                 strunzone(self.netname_previous);
1792         if(self.clientstatus)
1793                 strunzone(self.clientstatus);
1794         if(self.weaponorder_byimpulse)
1795                 strunzone(self.weaponorder_byimpulse);
1796
1797         ClearPlayerSounds();
1798
1799         if(self.personal)
1800                 remove(self.personal);
1801
1802         self.playerid = 0;
1803         ReadyCount();
1804
1805         // free cvars
1806         GetCvars(-1);
1807 }
1808
1809 .float BUTTON_CHAT;
1810 void ChatBubbleThink()
1811 {
1812         self.nextthink = time;
1813         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1814         {
1815                 if(self.owner) // but why can that ever be world?
1816                         self.owner.chatbubbleentity = world;
1817                 remove(self);
1818                 return;
1819         }
1820         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1821 #ifdef TETRIS
1822                 || self.owner.tetris_on
1823 #endif
1824         )
1825                 self.model = self.mdl;
1826         else
1827                 self.model = "";
1828 };
1829
1830 void UpdateChatBubble()
1831 {
1832         if (!self.modelindex)
1833                 return;
1834         // spawn a chatbubble entity if needed
1835         if (!self.chatbubbleentity)
1836         {
1837                 self.chatbubbleentity = spawn();
1838                 self.chatbubbleentity.owner = self;
1839                 self.chatbubbleentity.exteriormodeltoclient = self;
1840                 self.chatbubbleentity.think = ChatBubbleThink;
1841                 self.chatbubbleentity.nextthink = time;
1842                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1843                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1844                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1845                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1846                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1847                 self.chatbubbleentity.model = "";
1848                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1849         }
1850 }
1851
1852
1853 void TeamBubbleThink()
1854 {
1855         self.nextthink = time;
1856         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1857         {
1858                 if(self.owner) // but why can that ever be world?
1859                         self.owner.teambubbleentity = world;
1860                 remove(self);
1861                 return;
1862         }
1863 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1864         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1865                 self.model = "";
1866         else
1867                 self.model = self.mdl;
1868
1869 };
1870
1871 float TeamBubble_customizeentityforclient()
1872 {
1873         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1874 }
1875
1876 void UpdateTeamBubble()
1877 {
1878         if (!self.modelindex || !teams_matter)
1879                 return;
1880         // spawn a teambubble entity if needed
1881         if (!self.teambubbleentity && teams_matter)
1882         {
1883                 self.teambubbleentity = spawn();
1884                 self.teambubbleentity.owner = self;
1885                 self.teambubbleentity.exteriormodeltoclient = self;
1886                 self.teambubbleentity.think = TeamBubbleThink;
1887                 self.teambubbleentity.nextthink = time;
1888                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1889 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1890                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1891                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1892                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1893                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1894                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1895                 self.teambubbleentity.effects = EF_LOWPRECISION;
1896         }
1897 }
1898
1899 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1900 // added to the model skins
1901 /*void UpdateColorModHack()
1902 {
1903         local float c;
1904         c = self.clientcolors & 15;
1905         // LordHavoc: only bothering to support white, green, red, yellow, blue
1906              if (!teams_matter) self.colormod = '0 0 0';
1907         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1908         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1909         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1910         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1911         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1912         else self.colormod = '1 1 1';
1913 };*/
1914
1915 .float oldcolormap;
1916 void respawn(void)
1917 {
1918         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1919         {
1920                 self.solid = SOLID_NOT;
1921                 self.takedamage = DAMAGE_NO;
1922                 self.movetype = MOVETYPE_FLY;
1923                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1924                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1925                 self.effects |= EF_ADDITIVE;
1926                 self.oldcolormap = self.colormap;
1927                 self.colormap = 512;
1928                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1929                 if(cvar("g_respawn_ghosts_maxtime"))
1930                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1931         }
1932
1933         CopyBody(1);
1934         self.effects |= EF_NODRAW; // prevent another CopyBody
1935         if(self.oldcolormap)
1936         {
1937                 self.colormap = self.oldcolormap;
1938                 self.oldcolormap = 0;
1939         }
1940         PutClientInServer();
1941 }
1942
1943 void play_countdown(float finished, string samp)
1944 {
1945         if(clienttype(self) == CLIENTTYPE_REAL)
1946                 if(floor(finished - time - frametime) != floor(finished - time))
1947                         if(finished - time < 6)
1948                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1949 }
1950
1951 /**
1952  * When sv_timeout is used this function returs strings like
1953  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1954  * Called by centerprint functions
1955  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1956  */
1957 string getTimeoutText(float addOneSecond) {
1958         if (!cvar("sv_timeout") || !timeoutStatus)
1959                 return "";
1960
1961         local string retStr;
1962         if (timeoutStatus == 1) {
1963                 if (addOneSecond == 1) {
1964                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1965                 }
1966                 else {
1967                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1968                 }
1969                 return retStr;
1970         }
1971         else if (timeoutStatus == 2) {
1972                 if (addOneSecond) {
1973                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1974                         //don't show messages like "Timeout ends in 0 seconds"...
1975                         if ((remainingTimeoutTime + 1) > 0)
1976                                 return retStr;
1977                         else
1978                                 return "";
1979                 }
1980                 else {
1981                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1982                         //don't show messages like "Timeout ends in 0 seconds"...
1983                         if (remainingTimeoutTime > 0)
1984                                 return retStr;
1985                         else
1986                                 return "";
1987                 }
1988         }
1989         else return "";
1990 }
1991
1992 void player_powerups (void)
1993 {
1994         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1995         {
1996                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1997                 self.modelflags |= MF_ROCKET;
1998         }
1999         else
2000         {
2001                 SoundEntity_StopSound(self, CHAN_PLAYER);
2002                 self.modelflags &~= MF_ROCKET;
2003         }
2004
2005         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2006
2007         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2008                 return;
2009
2010         Fire_ApplyDamage(self);
2011         Fire_ApplyEffect(self);
2012
2013         if (g_minstagib)
2014         {
2015                 self.effects |= EF_FULLBRIGHT;
2016
2017                 if (self.items & IT_STRENGTH)
2018                 {
2019                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2020                         if (time > self.strength_finished)
2021                         {
2022                                 self.alpha = default_player_alpha;
2023                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2024                                 self.items &~= IT_STRENGTH;
2025                                 sprint(self, "^3Invisibility has worn off\n");
2026                         }
2027                 }
2028                 else
2029                 {
2030                         if (time < self.strength_finished)
2031                         {
2032                                 self.alpha = g_minstagib_invis_alpha;
2033                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2034                                 self.items |= IT_STRENGTH;
2035                                 sprint(self, "^3You are invisible\n");
2036                         }
2037                 }
2038
2039                 if (self.items & IT_INVINCIBLE)
2040                 {
2041                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2042                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2043                         {
2044                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2045                                 sprint(self, "^3Speed has worn off\n");
2046                         }
2047                 }
2048                 else
2049                 {
2050                         if (time < self.invincible_finished)
2051                         {
2052                                 self.items = self.items | IT_INVINCIBLE;
2053                                 sprint(self, "^3You are on speed\n");
2054                         }
2055                 }
2056                 return;
2057         }
2058
2059         if (self.items & IT_STRENGTH)
2060         {
2061                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2062                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2063                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2064                 {
2065                         self.items = self.items - (self.items & IT_STRENGTH);
2066                         sprint(self, "^3Strength has worn off\n");
2067                 }
2068         }
2069         else
2070         {
2071                 if (time < self.strength_finished)
2072                 {
2073                         self.items = self.items | IT_STRENGTH;
2074                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2075                 }
2076         }
2077         if (self.items & IT_INVINCIBLE)
2078         {
2079                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2080                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2081                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2082                 {
2083                         self.items = self.items - (self.items & IT_INVINCIBLE);
2084                         sprint(self, "^3Shield has worn off\n");
2085                 }
2086         }
2087         else
2088         {
2089                 if (time < self.invincible_finished)
2090                 {
2091                         self.items = self.items | IT_INVINCIBLE;
2092                         sprint(self, "^3Shield surrounds you\n");
2093                 }
2094         }
2095
2096         if(cvar("g_nodepthtestplayers"))
2097                 self.effects = self.effects | EF_NODEPTHTEST;
2098
2099         if(cvar("g_fullbrightplayers"))
2100                 self.effects = self.effects | EF_FULLBRIGHT;
2101
2102         // midair gamemode: damage only while in the air
2103         // if in midair mode, being on ground grants temporary invulnerability
2104         // (this is so that multishot weapon don't clear the ground flag on the
2105         // first damage in the frame, leaving the player vulnerable to the
2106         // remaining hits in the same frame)
2107         if (self.flags & FL_ONGROUND)
2108         if (g_midair)
2109                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2110
2111         if (time >= game_starttime)
2112         if (time < self.spawnshieldtime)
2113                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2114 }
2115
2116 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2117 {
2118         if(current > stable)
2119                 return current;
2120         else if(current > stable - 0.25) // when close enough, "snap"
2121                 return stable;
2122         else
2123                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2124 }
2125
2126 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2127 {
2128         if(current < stable)
2129                 return current;
2130         else if(current < stable + 0.25) // when close enough, "snap"
2131                 return stable;
2132         else
2133                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2134 }
2135
2136 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2137 {
2138         if(current > rotstable)
2139         {
2140                 if(rotframetime > 0)
2141                 {
2142                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2143                         current = max(rotstable, current - rotlinear * rotframetime);
2144                 }
2145         }
2146         else if(current < regenstable)
2147         {
2148                 if(regenframetime > 0)
2149                 {
2150                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2151                         current = min(regenstable, current + regenlinear * regenframetime);
2152                 }
2153         }
2154
2155         if(current > limit)
2156                 current = limit;
2157
2158         return current;
2159 }
2160
2161 void player_regen (void)
2162 {
2163         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2164         maxh = cvar("g_balance_health_rotstable");
2165         maxa = cvar("g_balance_armor_rotstable");
2166         maxf = cvar("g_balance_fuel_rotstable");
2167         minh = cvar("g_balance_health_regenstable");
2168         mina = cvar("g_balance_armor_regenstable");
2169         minf = cvar("g_balance_fuel_regenstable");
2170         limith = cvar("g_balance_health_limit");
2171         limita = cvar("g_balance_armor_limit");
2172         limitf = cvar("g_balance_fuel_limit");
2173
2174         max_mod = regen_mod = rot_mod = limit_mod = 1;
2175
2176         if (self.runes & RUNE_REGEN)
2177         {
2178                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2179                 {
2180                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2181                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2182                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2183                 }
2184                 else
2185                 {
2186                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2187                         max_mod = cvar("g_balance_rune_regen_hpmod");
2188                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2189                 }
2190         }
2191         else if (self.runes & CURSE_VENOM)
2192         {
2193                 max_mod = cvar("g_balance_curse_venom_hpmod");
2194                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2195                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2196                 else
2197                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2198                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2199                 //if (!self.runes & RUNE_REGEN)
2200                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2201         }
2202         maxh = maxh * max_mod;
2203         //maxa = maxa * max_mod;
2204         //maxf = maxf * max_mod;
2205         minh = minh * max_mod;
2206         //mina = mina * max_mod;
2207         //minf = minf * max_mod;
2208         limith = limith * limit_mod;
2209         limita = limita * limit_mod;
2210         //limitf = limitf * limit_mod;
2211
2212         if(g_lms && g_ca)
2213                 rot_mod = 0;
2214
2215         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2216         {
2217                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2218                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2219
2220                 // if player rotted to death...  die!
2221                 if(self.health < 1)
2222                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2223         }
2224
2225         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2226                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2227 }
2228
2229 float zoomstate_set;
2230 void SetZoomState(float z)
2231 {
2232         if(z != self.zoomstate)
2233         {
2234                 self.zoomstate = z;
2235                 ClientData_Touch(self);
2236         }
2237         zoomstate_set = 1;
2238 }
2239
2240 void GetPressedKeys(void) {
2241         MUTATOR_CALLHOOK(GetPressedKeys);
2242         if (self.movement_x > 0) // get if movement keys are pressed
2243         {       // forward key pressed
2244                 self.pressedkeys |= KEY_FORWARD;
2245                 self.pressedkeys &~= KEY_BACKWARD;
2246         }
2247         else if (self.movement_x < 0)
2248         {       // backward key pressed
2249                 self.pressedkeys |= KEY_BACKWARD;
2250                 self.pressedkeys &~= KEY_FORWARD;
2251         }
2252         else
2253         {       // no x input
2254                 self.pressedkeys &~= KEY_FORWARD;
2255                 self.pressedkeys &~= KEY_BACKWARD;
2256         }
2257
2258         if (self.movement_y > 0)
2259         {       // right key pressed
2260                 self.pressedkeys |= KEY_RIGHT;
2261                 self.pressedkeys &~= KEY_LEFT;
2262         }
2263         else if (self.movement_y < 0)
2264         {       // left key pressed
2265                 self.pressedkeys |= KEY_LEFT;
2266                 self.pressedkeys &~= KEY_RIGHT;
2267         }
2268         else
2269         {       // no y input
2270                 self.pressedkeys &~= KEY_RIGHT;
2271                 self.pressedkeys &~= KEY_LEFT;
2272         }
2273
2274         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2275                 self.pressedkeys |= KEY_JUMP;
2276         else
2277                 self.pressedkeys &~= KEY_JUMP;
2278         if (self.BUTTON_CROUCH)
2279                 self.pressedkeys |= KEY_CROUCH;
2280         else
2281                 self.pressedkeys &~= KEY_CROUCH;
2282 }
2283
2284 /*
2285 ======================
2286 spectate mode routines
2287 ======================
2288 */
2289
2290 void SpectateCopy(entity spectatee) {
2291         other = spectatee;
2292         MUTATOR_CALLHOOK(SpectateCopy);
2293         self.armortype = spectatee.armortype;
2294         self.armorvalue = spectatee.armorvalue;
2295         self.ammo_cells = spectatee.ammo_cells;
2296         self.ammo_shells = spectatee.ammo_shells;
2297         self.ammo_nails = spectatee.ammo_nails;
2298         self.ammo_rockets = spectatee.ammo_rockets;
2299         self.ammo_fuel = spectatee.ammo_fuel;
2300         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2301         self.health = spectatee.health;
2302         self.impulse = 0;
2303         self.items = spectatee.items;
2304         self.last_pickup = spectatee.last_pickup;
2305         self.metertime = spectatee.metertime;
2306         self.strength_finished = spectatee.strength_finished;
2307         self.invincible_finished = spectatee.invincible_finished;
2308         self.pressedkeys = spectatee.pressedkeys;
2309         self.weapons = spectatee.weapons;
2310         self.switchweapon = spectatee.switchweapon;
2311         self.weapon = spectatee.weapon;
2312         self.punchangle = spectatee.punchangle;
2313         self.view_ofs = spectatee.view_ofs;
2314         self.v_angle = spectatee.v_angle;
2315         self.velocity = spectatee.velocity;
2316         self.dmg_take = spectatee.dmg_take;
2317         self.dmg_save = spectatee.dmg_save;
2318         self.dmg_inflictor = spectatee.dmg_inflictor;
2319         self.angles = spectatee.v_angle;
2320         self.fixangle = TRUE;
2321         setorigin(self, spectatee.origin);
2322         setsize(self, spectatee.mins, spectatee.maxs);
2323         SetZoomState(spectatee.zoomstate);
2324
2325         anticheat_spectatecopy(spectatee);
2326 }
2327
2328 float SpectateUpdate() {
2329         if(!self.enemy)
2330                 return 0;
2331
2332         if (self == self.enemy)
2333                 return 0;
2334
2335         if(self.enemy.classname != "player")
2336                 return 0;
2337
2338         SpectateCopy(self.enemy);
2339
2340         return 1;
2341 }
2342
2343 float SpectateNext() {
2344         other = find(self.enemy, classname, "player");
2345
2346         if (!other)
2347                 other = find(other, classname, "player");
2348
2349         if (other)
2350                 self.enemy = other;
2351
2352         if(self.enemy.classname == "player") {
2353                 msg_entity = self;
2354                 WriteByte(MSG_ONE, SVC_SETVIEW);
2355                 WriteEntity(MSG_ONE, self.enemy);
2356                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2357                 self.movetype = MOVETYPE_NONE;
2358                 accuracy_resend(self);
2359
2360                 if(!SpectateUpdate())
2361                         PutObserverInServer();
2362
2363                 return 1;
2364         } else {
2365                 return 0;
2366         }
2367 }
2368
2369 /*
2370 =============
2371 ShowRespawnCountdown()
2372
2373 Update a respawn countdown display.
2374 =============
2375 */
2376 void ShowRespawnCountdown()
2377 {
2378         float number;
2379         if(self.deadflag == DEAD_NO) // just respawned?
2380                 return;
2381         else
2382         {
2383                 number = ceil(self.death_time - time);
2384                 if(number <= 0)
2385                         return;
2386                 if(number <= self.respawn_countdown)
2387                 {
2388                         self.respawn_countdown = number - 1;
2389                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2390                                 AnnounceTo(self, strcat(ftos(number), ""));
2391                 }
2392         }
2393 }
2394
2395 void LeaveSpectatorMode()
2396 {
2397         if(isJoinAllowed()) {
2398                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2399                         self.classname = "player";
2400
2401                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2402                                 JoinBestTeam(self, FALSE, TRUE);
2403
2404                         if(cvar("g_campaign"))
2405                                 campaign_bots_may_start = 1;
2406
2407                         PutClientInServer();
2408
2409                         if(self.classname == "player")
2410                                 bprint ("^4", self.netname, "^4 is playing now\n");
2411
2412                         if(!cvar("g_campaign"))
2413                                 centerprint(self,""); // clear MOTD
2414
2415                         return;
2416                 } else {
2417                         if (g_ca && self.caplayer) {
2418                         }       // do nothing
2419                         else
2420                                 stuffcmd(self,"menu_showteamselect\n");
2421                         return;
2422                 }
2423         }
2424         else {
2425                 //player may not join because of g_maxplayers is set
2426                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2427         }
2428 }
2429
2430 /**
2431  * Determines whether the player is allowed to join. This depends on cvar
2432  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2433  * it checks whether the number of currently playing players exceeds g_maxplayers.
2434  * @return bool TRUE if the player is allowed to join, false otherwise
2435  */
2436 float isJoinAllowed() {
2437         if(self.team_forced < 0)
2438                 return FALSE; // forced spectators can never join
2439
2440         if (!cvar("g_maxplayers"))
2441                 return TRUE;
2442
2443         local entity e;
2444         local float currentlyPlaying;
2445         FOR_EACH_REALPLAYER(e) {
2446                 if(e.classname == "player")
2447                         currentlyPlaying += 1;
2448         }
2449         if(currentlyPlaying < cvar("g_maxplayers"))
2450                 return TRUE;
2451
2452         return FALSE;
2453 }
2454
2455 /**
2456  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2457  * g_maxplayers_spectator_blocktime seconds
2458  */
2459 void checkSpectatorBlock() {
2460         if(self.classname == "spectator" || self.classname == "observer") {
2461                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2462                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2463                         dropclient(self);
2464                 }
2465         }
2466 }
2467
2468 void ObserverThink()
2469 {
2470         if (self.flags & FL_JUMPRELEASED) {
2471                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2472                         self.welcomemessage_time = 0;
2473                         self.flags &~= FL_JUMPRELEASED;
2474                         self.flags |= FL_SPAWNING;
2475                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2476                         self.welcomemessage_time = 0;
2477                         self.flags &~= FL_JUMPRELEASED;
2478                         if(SpectateNext() == 1) {
2479                                 self.classname = "spectator";
2480                         }
2481                 }
2482         } else {
2483                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2484                         self.flags |= FL_JUMPRELEASED;
2485                         if(self.flags & FL_SPAWNING)
2486                         {
2487                                 self.flags &~= FL_SPAWNING;
2488                                 LeaveSpectatorMode();
2489                                 return;
2490                         }
2491                 }
2492         }
2493         PrintWelcomeMessage(self);
2494 }
2495
2496 void SpectatorThink()
2497 {
2498         if (self.flags & FL_JUMPRELEASED) {
2499                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2500                         self.welcomemessage_time = 0;
2501                         self.flags &~= FL_JUMPRELEASED;
2502                         self.flags |= FL_SPAWNING;
2503                 } else if(self.BUTTON_ATCK) {
2504                         self.welcomemessage_time = 0;
2505                         self.flags &~= FL_JUMPRELEASED;
2506                         if(SpectateNext() == 1) {
2507                                 self.classname = "spectator";
2508                         } else {
2509                                 self.classname = "observer";
2510                                 PutClientInServer();
2511                         }
2512                 } else if (self.BUTTON_ATCK2) {
2513                         self.welcomemessage_time = 0;
2514                         self.flags &~= FL_JUMPRELEASED;
2515                         self.classname = "observer";
2516                         PutClientInServer();
2517                 } else {
2518                         if(!SpectateUpdate())
2519                                 PutObserverInServer();
2520                 }
2521         } else {
2522                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2523                         self.flags |= FL_JUMPRELEASED;
2524                         if(self.flags & FL_SPAWNING)
2525                         {
2526                                 self.flags &~= FL_SPAWNING;
2527                                 LeaveSpectatorMode();
2528                                 return;
2529                         }
2530                 }
2531         }
2532
2533         PrintWelcomeMessage(self);
2534         self.flags |= FL_CLIENT | FL_NOTARGET;
2535 }
2536
2537 .float touchexplode_time;
2538
2539 /*
2540 =============
2541 PlayerPreThink
2542
2543 Called every frame for each client before the physics are run
2544 =============
2545 */
2546 void() ctf_setstatus;
2547 void() nexball_setstatus;
2548 .float items_added;
2549 void PlayerPreThink (void)
2550 {
2551         self.stat_game_starttime = game_starttime;
2552         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2553         self.stat_leadlimit = cvar("leadlimit");
2554
2555         if(frametime)
2556         {
2557                 // physics frames: update anticheat stuff
2558                 anticheat_prethink();
2559         }
2560
2561         if(blockSpectators && frametime)
2562                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2563                 checkSpectatorBlock();
2564
2565         zoomstate_set = 0;
2566
2567         if(self.netname_previous != self.netname)
2568         {
2569                 if(cvar("sv_eventlog"))
2570                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2571                 if(self.netname_previous)
2572                         strunzone(self.netname_previous);
2573                 self.netname_previous = strzone(self.netname);
2574         }
2575
2576         // version nagging
2577         if(self.version_nagtime)
2578                 if(self.cvar_g_xonoticversion)
2579                         if(time > self.version_nagtime)
2580                         {
2581                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2582                                 {
2583                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2584                                         {
2585                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2586                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2587                                         }
2588                                         else
2589                                         {
2590                                                 float r;
2591                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2592                                                 if(r < 0)
2593                                                 {
2594                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2595                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2596                                                 }
2597                                                 else if(r > 0)
2598                                                 {
2599                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2600                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2601                                                 }
2602                                         }
2603                                 }
2604                                 self.version_nagtime = 0;
2605                         }
2606
2607         // GOD MODE info
2608         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2609         {
2610                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2611                 self.max_armorvalue = 0;
2612         }
2613
2614 #ifdef TETRIS
2615         if (TetrisPreFrame())
2616                 return;
2617 #endif
2618
2619         MUTATOR_CALLHOOK(PlayerPreThink);
2620
2621         if(self.classname == "player") {
2622 //              if(self.netname == "Wazat")
2623 //                      bprint(self.classname, "\n");
2624
2625                 CheckRules_Player();
2626
2627                 PrintWelcomeMessage(self);
2628
2629                 if (intermission_running)
2630                 {
2631                         IntermissionThink ();   // otherwise a button could be missed between
2632                         return;                                 // the think tics
2633                 }
2634
2635                 if(self.teleport_time)
2636                 if(time > self.teleport_time)
2637                 {
2638                         self.teleport_time = 0;
2639                         self.effects = self.effects - (self.effects & EF_NODRAW);
2640                 }
2641
2642                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2643                         UpdateSelectedPlayer();
2644
2645                 //don't allow the player to turn around while game is paused!
2646                 if(timeoutStatus == 2) {
2647                         self.v_angle = self.lastV_angle;
2648                         self.angles = self.lastV_angle;
2649                         self.fixangle = TRUE;
2650                 }
2651
2652                 if(frametime)
2653                 {
2654                         if(self.health <= 0 && cvar("g_deathglow"))
2655                         {
2656                                 if(self.glowmod_x > 0)
2657                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2658                                 else
2659                                         self.glowmod_x = -1;
2660                                 if(self.glowmod_y > 0)
2661                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2662                                 else
2663                                         self.glowmod_y = -1;
2664                                 if(self.glowmod_z > 0)
2665                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2666                                 else
2667                                         self.glowmod_z = -1;
2668                         }
2669                         else
2670                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2671                         player_powerups();
2672                 }
2673
2674                 if (self.deadflag != DEAD_NO)
2675                 {
2676                         float button_pressed, force_respawn;
2677                         if(self.personal && g_race_qualifying)
2678                         {
2679                                 if(time > self.death_time)
2680                                 {
2681                                         self.death_time = time + 1; // only retry once a second
2682                                         respawn();
2683                                         self.impulse = 141;
2684                                 }
2685                         }
2686                         else
2687                         {
2688                                 if(frametime)
2689                                         player_anim();
2690                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2691                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2692                                 if (self.deadflag == DEAD_DYING)
2693                                 {
2694                                         if(force_respawn)
2695                                                 self.deadflag = DEAD_RESPAWNING;
2696                                         else if(!button_pressed)
2697                                                 self.deadflag = DEAD_DEAD;
2698                                 }
2699                                 else if (self.deadflag == DEAD_DEAD)
2700                                 {
2701                                         if(button_pressed)
2702                                                 self.deadflag = DEAD_RESPAWNABLE;
2703                                 }
2704                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2705                                 {
2706                                         if(!button_pressed)
2707                                                 self.deadflag = DEAD_RESPAWNING;
2708                                 }
2709                                 else if (self.deadflag == DEAD_RESPAWNING)
2710                                 {
2711                                         if(time > self.death_time)
2712                                         {
2713                                                 self.death_time = time + 1; // only retry once a second
2714                                                 respawn();
2715                                         }
2716                                 }
2717                                 ShowRespawnCountdown();
2718                         }
2719                         return;
2720                 }
2721
2722                 if(g_touchexplode)
2723                 if(time > self.touchexplode_time)
2724                 if(self.classname == "player")
2725                 if(self.deadflag == DEAD_NO)
2726                 if not(IS_INDEPENDENT_PLAYER(self))
2727                 FOR_EACH_PLAYER(other) if(self != other)
2728                 {
2729                         if(time > other.touchexplode_time)
2730                         if(other.deadflag == DEAD_NO)
2731                         if not(IS_INDEPENDENT_PLAYER(other))
2732                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2733                         {
2734                                 PlayerTouchExplode(self, other);
2735                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2736                         }
2737                 }
2738
2739                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2740                 {
2741                         vector dist;
2742
2743                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2744                         dist = self.prevorigin - self.origin;
2745                         dist_z = 0;
2746                         self.lms_traveled_distance += fabs(vlen(dist));
2747
2748                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2749                         {
2750                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2751                                 self.lms_traveled_distance = 0;
2752                         }
2753
2754                         if(time > self.lms_nextcheck)
2755                         {
2756                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2757                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2758                                 {
2759                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2760                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2761                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2762                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2763                                 }
2764                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2765                                 self.lms_traveled_distance = 0;
2766                         }
2767                 }
2768
2769                 self.prevorigin = self.origin;
2770
2771                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2772                 {
2773                         if (!self.crouch)
2774                         {
2775                                 self.crouch = TRUE;
2776                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2777                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2778                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2779                         }
2780                 }
2781                 else
2782                 {
2783                         if (self.crouch)
2784                         {
2785                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2786                                 if (!trace_startsolid)
2787                                 {
2788                                         self.crouch = FALSE;
2789                                         self.view_ofs = PL_VIEW_OFS;
2790                                         setsize (self, PL_MIN, PL_MAX);
2791                                 }
2792                         }
2793                 }
2794
2795                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2796                 {
2797                         if(self.bloodloss_timer < time)
2798                         {
2799                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2800                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2801                         }
2802                 }
2803
2804                 FixPlayermodel();
2805
2806                 GrapplingHookFrame();
2807
2808                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2809                 //if(frametime)
2810                 {
2811                         self.items &~= self.items_added;
2812
2813                         W_WeaponFrame();
2814
2815                         self.items_added = 0;
2816                         if(self.items & IT_JETPACK)
2817                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2818                                         self.items_added |= IT_FUEL;
2819
2820                         self.items |= self.items_added;
2821                 }
2822
2823                 player_regen();
2824
2825                 // rot nex charge to the charge limit
2826                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2827                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2828
2829                 if(frametime)
2830                         player_anim();
2831
2832                 if (g_minstagib)
2833                         minstagib_ammocheck();
2834
2835                 if(g_ctf)
2836                         ctf_setstatus();
2837
2838                 if(g_nexball)
2839                         nexball_setstatus();
2840
2841                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2842
2843                 //self.angles_y=self.v_angle_y + 90;   // temp
2844         } else if(gameover) {
2845                 if (intermission_running)
2846                         IntermissionThink ();   // otherwise a button could be missed between
2847                 return;
2848         } else if(self.classname == "observer") {
2849                 ObserverThink();
2850         } else if(self.classname == "spectator") {
2851                 SpectatorThink();
2852         }
2853
2854         if(!zoomstate_set)
2855                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2856
2857         float oldspectatee_status;
2858         oldspectatee_status = self.spectatee_status;
2859         if(self.classname == "spectator")
2860                 self.spectatee_status = num_for_edict(self.enemy);
2861         else if(self.classname == "observer")
2862                 self.spectatee_status = num_for_edict(self);
2863         else
2864                 self.spectatee_status = 0;
2865         if(self.spectatee_status != oldspectatee_status)
2866         {
2867                 ClientData_Touch(self);
2868                 if(g_race || g_cts)
2869                         race_InitSpectator();
2870         }
2871
2872         if(self.teamkill_soundtime)
2873         if(time > self.teamkill_soundtime)
2874         {
2875                 self.teamkill_soundtime = 0;
2876
2877                 entity oldpusher, oldself;
2878
2879                 oldself = self; self = self.teamkill_soundsource;
2880                 oldpusher = self.pusher; self.pusher = oldself;
2881
2882                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2883
2884                 self.pusher = oldpusher;
2885                 self = oldself;
2886         }
2887
2888         if(self.taunt_soundtime)
2889         if(time > self.taunt_soundtime)
2890         {
2891                 self.taunt_soundtime = 0;
2892                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2893         }
2894
2895         target_voicescript_next(self);
2896 }
2897
2898 float isInvisibleString(string s)
2899 {
2900         float i, n, c;
2901         s = strdecolorize(s);
2902         for((i = 0), (n = strlen(s)); i < n; ++i)
2903         {
2904                 c = str2chr(s, i);
2905                 switch(c)
2906                 {
2907                         case 0:
2908                         case 32: // space
2909                                 break;
2910                         case 192: // charmap space
2911                                 if (!cvar("utf8_enable"))
2912                                         break;
2913                                 return FALSE;
2914                         case 160: // space in unicode fonts
2915                         case 0xE000 + 192: // utf8 charmap space
2916                                 if (cvar("utf8_enable"))
2917                                         break;
2918                         default:
2919                                 return FALSE;
2920                 }
2921         }
2922         return TRUE;
2923 }
2924
2925 /*
2926 =============
2927 PlayerPostThink
2928
2929 Called every frame for each client after the physics are run
2930 =============
2931 */
2932 .float idlekick_lasttimeleft;
2933 .entity showheadshotbbox;
2934 void showheadshotbbox_think()
2935 {
2936         if(self.owner.showheadshotbbox != self)
2937         {
2938                 remove(self);
2939                 return;
2940         }
2941         self.nextthink = time;
2942         setorigin(self, self.owner.origin);
2943         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2944 }
2945 void PlayerPostThink (void)
2946 {
2947         // Savage: Check for nameless players
2948         if (isInvisibleString(self.netname)) {
2949                 self.netname = "Player";
2950                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2951         }
2952
2953         if(sv_maxidle && frametime)
2954         {
2955                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2956                 float timeleft;
2957                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2958                 if(timeleft <= 0)
2959                 {
2960                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2961                         AnnounceTo(self, "terminated");
2962                         dropclient(self);
2963                         return;
2964                 }
2965                 else if(timeleft <= 10)
2966                 {
2967                         if(timeleft != self.idlekick_lasttimeleft)
2968                         {
2969                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2970                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2971                         }
2972                 }
2973                 else
2974                 {
2975                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2976                 }
2977                 self.idlekick_lasttimeleft = timeleft;
2978         }
2979
2980 #ifdef TETRIS
2981         if(self.impulse == 100)
2982                 ImpulseCommands();
2983         if (TetrisPostFrame())
2984                 return;
2985 #endif
2986
2987         CheatFrame();
2988
2989         if(self.classname == "player") {
2990                 CheckRules_Player();
2991                 UpdateChatBubble();
2992                 UpdateTeamBubble();
2993                 if (self.impulse)
2994                         ImpulseCommands();
2995                 if (intermission_running)
2996                         return;         // intermission or finale
2997                 GetPressedKeys();
2998         } else if (self.classname == "observer") {
2999                 //do nothing
3000         } else if (self.classname == "spectator") {
3001                 //do nothing
3002         }
3003
3004         /*
3005         float i;
3006         for(i = 0; i < 1000; ++i)
3007         {
3008                 vector end;
3009                 end = self.origin + '0 0 1024' + 512 * randomvec();
3010                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3011                 if(trace_fraction < 1)
3012                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3013                 {
3014                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3015                         break;
3016                 }
3017         }
3018         */
3019
3020         Arena_Warmup();
3021
3022         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3023
3024         if(self.waypointsprite_attachedforcarrier)
3025                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3026
3027         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3028         {
3029                 if(!self.showheadshotbbox)
3030                 {
3031                         self.showheadshotbbox = spawn();
3032                         self.showheadshotbbox.classname = "headshotbbox";
3033                         self.showheadshotbbox.owner = self;
3034                         self.showheadshotbbox.think = showheadshotbbox_think;
3035                         self.showheadshotbbox.nextthink = time;
3036                         self = self.showheadshotbbox;
3037                         self.think();
3038                         self = self.owner;
3039                 }
3040         }
3041         else
3042         {
3043                 if(self.showheadshotbbox)
3044                         remove(self.showheadshotbbox);
3045         }
3046
3047         playerdemo_write();
3048
3049         if((g_cts || g_race) && self.cvar_cl_allow_uid2name)
3050         {
3051                 if(!self.stored_netname)
3052                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3053                 if(self.stored_netname != self.netname)
3054                 {
3055                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3056                         strunzone(self.stored_netname);
3057                         self.stored_netname = strzone(self.netname);
3058                 }
3059         }
3060
3061         /*
3062         if(g_race)
3063                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3064         */
3065 }