qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!inWarmupStage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         self.weapons = '0 0 0';
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                         defaultmodel = argv(floor(n * self.model_randomizer));
 301
 302                 i = strstrofs(defaultmodel, ":", 0);
 303                 if(i >= 0)
 304                 {
 305                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 306                         defaultmodel = substring(defaultmodel, 0, i);
 307                 }
 308         }
 309
 310         if(defaultmodel != "")
 311         {
 312                 if (defaultmodel != self.model)
 313                 {
 314                         m1 = self.mins;
 315                         m2 = self.maxs;
 316                         setplayermodel (self, defaultmodel);
 317                         setsize (self, m1, m2);
 318                         chmdl = TRUE;
 319                 }
 320
 321                 oldskin = self.skin;
 322                 self.skin = defaultskin;
 323         } else {
 324                 if (self.playermodel != self.model || self.playermodel == "")
 325                 {
 326                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 327                         m1 = self.mins;
 328                         m2 = self.maxs;
 329                         setplayermodel (self, self.playermodel);
 330                         setsize (self, m1, m2);
 331                         chmdl = TRUE;
 332                 }
 333
 334                 oldskin = self.skin;
 335                 self.skin = stof(self.playerskin);
 336         }
 337
 338         if(chmdl || oldskin != self.skin) // model or skin has changed
 339         {
 340                 self.species = player_getspecies(); // update species
 341                 UpdatePlayerSounds(); // update skin sounds
 342         }
 343
 344         if(!teamplay)
 345                 if(strlen(autocvar_sv_defaultplayercolors))
 346                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 347                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 348 }
 349
 350 /*
 351 =============
 352 PutClientInServer
 353
 354 Called when a client spawns in the server
 355 =============
 356 */
 357 void PutClientInServer (void)
 358 {
 359         if(IS_BOT_CLIENT(self))
 360                 self.classname = "player";
 361         else if(IS_REAL_CLIENT(self))
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         // reset player keys
 369         self.itemkeys = 0;
 370
 371         MUTATOR_CALLHOOK(PutClientInServer);
 372
 373         if(gameover)
 374                 self.classname = "observer";
 375
 376         if(IS_PLAYER(self))
 377         {
 378                 entity spot, oldself;
 379                 float j;
 380
 381                 accuracy_resend(self);
 382
 383                 if(self.team < 0)
 384                         JoinBestTeam(self, FALSE, TRUE);
 385
 386                 race_PreSpawn();
 387
 388                 spot = SelectSpawnPoint (FALSE);
 389                 if(!spot)
 390                 {
 391                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 392                         return; // spawn failed
 393                 }
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 if(self.vehicle)
 398                         vehicles_exit(VHEF_RELESE);
 399
 400                 self.classname = "player";
 401                 self.wasplayer = TRUE;
 402                 self.iscreature = TRUE;
 403                 self.teleportable = TELEPORT_NORMAL;
 404                 self.damagedbycontents = TRUE;
 405                 self.movetype = MOVETYPE_WALK;
 406                 self.solid = SOLID_SLIDEBOX;
 407                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 408                 if(autocvar_g_playerclip_collisions)
 409                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 410                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 411                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 412                 self.frags = FRAGS_PLAYER;
 413                 if(INDEPENDENT_PLAYERS)
 414                         MAKE_INDEPENDENT_PLAYER(self);
 415                 self.flags = FL_CLIENT;
 416                 if(autocvar__notarget)
 417                         self.flags |= FL_NOTARGET;
 418                 self.takedamage = DAMAGE_AIM;
 419                 self.effects = 0;
 420                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 421                 self.air_finished = time + 12;
 422                 self.dmg = 2;
 423                 if(autocvar_g_balance_nex_charge)
 424                 {
 425                         if(autocvar_g_balance_nex_secondary_chargepool)
 426                                 self.nex_chargepool_ammo = 1;
 427                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 428                 }
 429
 430                 if(inWarmupStage)
 431                 {
 432                         self.ammo_shells = warmup_start_ammo_shells;
 433                         self.ammo_nails = warmup_start_ammo_nails;
 434                         self.ammo_rockets = warmup_start_ammo_rockets;
 435                         self.ammo_cells = warmup_start_ammo_cells;
 436                         self.ammo_fuel = warmup_start_ammo_fuel;
 437                         self.health = warmup_start_health;
 438                         self.armorvalue = warmup_start_armorvalue;
 439                         self.weapons = warmup_start_weapons;
 440                 }
 441                 else
 442                 {
 443                         self.ammo_shells = start_ammo_shells;
 444                         self.ammo_nails = start_ammo_nails;
 445                         self.ammo_rockets = start_ammo_rockets;
 446                         self.ammo_cells = start_ammo_cells;
 447                         self.ammo_fuel = start_ammo_fuel;
 448                         self.health = start_health;
 449                         self.armorvalue = start_armorvalue;
 450                         self.weapons = start_weapons;
 451                 }
 452
 453                 if(self.weapons & WEPSET_SUPERWEAPONS)
 454                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 455                 else
 456                         self.superweapons_finished = 0;
 457
 458                 if(g_weaponarena_random)
 459                 {
 460                         if(g_weaponarena_random_with_laser)
 461                                 self.weapons &= ~WEPSET_LASER;
 462                         W_RandomWeapons(self, g_weaponarena_random);
 463                         if(g_weaponarena_random_with_laser)
 464                                 self.weapons |= WEPSET_LASER;
 465                 }
 466
 467                 self.items = start_items;
 468
 469                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 470                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 471                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 472                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 473                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 474                 //extend the pause of rotting if client was reset at the beginning of the countdown
 475                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 476                         self.spawnshieldtime += game_starttime - time;
 477                         self.pauserotarmor_finished += game_starttime - time;
 478                         self.pauserothealth_finished += game_starttime - time;
 479                         self.pauseregen_finished += game_starttime - time;
 480                 }
 481                 self.damageforcescale = 2;
 482                 self.death_time = 0;
 483                 self.respawn_flags = 0;
 484                 self.respawn_time = 0;
 485                 self.stat_respawn_time = 0;
 486                 self.scale = 0;
 487                 self.fade_time = 0;
 488                 self.pain_frame = 0;
 489                 self.pain_finished = 0;
 490                 self.strength_finished = 0;
 491                 self.invincible_finished = 0;
 492                 self.pushltime = 0;
 493                 // players have no think function
 494                 self.think = func_null;
 495                 self.nextthink = 0;
 496                 self.hook_time = 0;
 497                 self.dmg_team = 0;
 498                 self.ballistics_density = autocvar_g_ballistics_density_player;
 499
 500                 self.metertime = 0;
 501
 502                 self.deadflag = DEAD_NO;
 503
 504                 self.angles = spot.angles;
 505
 506                 self.angles_z = 0; // never spawn tilted even if the spot says to
 507                 self.fixangle = TRUE; // turn this way immediately
 508                 self.velocity = '0 0 0';
 509                 self.avelocity = '0 0 0';
 510                 self.punchangle = '0 0 0';
 511                 self.punchvector = '0 0 0';
 512                 self.oldvelocity = self.velocity;
 513                 self.fire_endtime = -1;
 514
 515                 entity spawnevent = spawn();
 516                 spawnevent.owner = self;
 517                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 518
 519                 self.model = "";
 520                 FixPlayermodel();
 521                 self.drawonlytoclient = world;
 522
 523                 self.crouch = FALSE;
 524                 self.view_ofs = PL_VIEW_OFS;
 525                 setsize (self, PL_MIN, PL_MAX);
 526                 self.spawnorigin = spot.origin;
 527                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 528                 // don't reset back to last position, even if new position is stuck in solid
 529                 self.oldorigin = self.origin;
 530                 self.prevorigin = self.origin;
 531                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 532                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 533         self.hud = HUD_NORMAL;
 534
 535                 self.event_damage = PlayerDamage;
 536
 537                 self.bot_attack = TRUE;
 538
 539                 self.statdraintime = time + 5;
 540                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 541
 542                 if(self.killcount == -666) {
 543                         PlayerScore_Clear(self);
 544                         self.killcount = 0;
 545                 }
 546
 547                 CL_SpawnWeaponentity();
 548                 self.alpha = default_player_alpha;
 549                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 550                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 551
 552                 self.speedrunning = FALSE;
 553
 554                 race_PostSpawn(spot);
 555
 556                 //stuffcmd(self, "chase_active 0");
 557                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 558
 559                 target_voicescript_clear(self);
 560
 561                 // reset fields the weapons may use
 562                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 563                 {
 564                         weapon_action(j, WR_RESETPLAYER);
 565
 566                         // all weapons must be fully loaded when we spawn
 567                         entity e;
 568                         e = get_weaponinfo(j);
 569                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 570                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 571                 }
 572
 573                 oldself = self;
 574                 self = spot;
 575                         activator = oldself;
 576                                 string s;
 577                                 s = self.target;
 578                                 self.target = string_null;
 579                                 SUB_UseTargets();
 580                                 self.target = s;
 581                         activator = world;
 582                 self = oldself;
 583
 584                 spawn_spot = spot;
 585                 MUTATOR_CALLHOOK(PlayerSpawn);
 586
 587                 if(autocvar_spawn_debug)
 588                 {
 589                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 590                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 591                 }
 592
 593                 self.switchweapon = w_getbestweapon(self);
 594                 self.cnt = -1; // W_LastWeapon will not complain
 595                 self.weapon = 0;
 596                 self.weaponname = "";
 597                 self.switchingweapon = 0;
 598
 599                 if(!inWarmupStage)
 600                         if(!self.alivetime)
 601                                 self.alivetime = time;
 602
 603                 antilag_clear(self);
 604         }
 605         else if(IS_OBSERVER(self))
 606         {
 607                 PutObserverInServer ();
 608         }
 609 }
 610
 611 .float ebouncefactor, ebouncestop; // electro's values
 612 // TODO do we need all these fields, or should we stop autodetecting runtime
 613 // changes and just have a console command to update this?
 614 float ClientInit_SendEntity(entity to, float sf)
 615 {
 616         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 617         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 630         if(sv_foginterval && world.fog != "")
 631                 WriteString(MSG_ENTITY, world.fog);
 632         else
 633                 WriteString(MSG_ENTITY, "");
 634         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 635         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 636         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 637         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 638         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 639         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 641         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 642         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 644         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 645         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 646         return TRUE;
 647 }
 648
 649 void ClientInit_CheckUpdate()
 650 {
 651         self.nextthink = time;
 652         if(self.count != autocvar_g_balance_armor_blockpercent)
 653         {
 654                 self.count = autocvar_g_balance_armor_blockpercent;
 655                 self.SendFlags |= 1;
 656         }
 657         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 658         {
 659                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 660                 self.SendFlags |= 1;
 661         }
 662         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 663         {
 664                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 665                 self.SendFlags |= 1;
 666         }
 667         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 668         {
 669                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 670                 self.SendFlags |= 1;
 671         }
 672         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 673         {
 674                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 675                 self.SendFlags |= 1;
 676         }
 677 }
 678
 679 void ClientInit_Spawn()
 680 {
 681         entity o;
 682         entity e;
 683         e = spawn();
 684         e.classname = "clientinit";
 685         e.think = ClientInit_CheckUpdate;
 686         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 687
 688         o = self;
 689         self = e;
 690         ClientInit_CheckUpdate();
 691         self = o;
 692 }
 693
 694 /*
 695 =============
 696 SetNewParms
 697 =============
 698 */
 699 void SetNewParms (void)
 700 {
 701         // initialize parms for a new player
 702         parm1 = -(86400 * 366);
 703 }
 704
 705 /*
 706 =============
 707 SetChangeParms
 708 =============
 709 */
 710 void SetChangeParms (void)
 711 {
 712         // save parms for level change
 713         parm1 = self.parm_idlesince - time;
 714 }
 715
 716 /*
 717 =============
 718 DecodeLevelParms
 719 =============
 720 */
 721 void DecodeLevelParms (void)
 722 {
 723         // load parms
 724         self.parm_idlesince = parm1;
 725         if(self.parm_idlesince == -(86400 * 366))
 726                 self.parm_idlesince = time;
 727
 728         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 729         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 730 }
 731
 732 /*
 733 =============
 734 ClientKill
 735
 736 Called when a client types 'kill' in the console
 737 =============
 738 */
 739
 740 .float clientkill_nexttime;
 741 void ClientKill_Now_TeamChange()
 742 {
 743         if(self.killindicator_teamchange == -1)
 744         {
 745                 JoinBestTeam( self, FALSE, TRUE );
 746         }
 747         else if(self.killindicator_teamchange == -2)
 748         {
 749                 if(blockSpectators)
 750                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 751                 PutObserverInServer();
 752         }
 753         else
 754                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 755         self.killindicator_teamchange = 0;
 756 }
 757
 758 void ClientKill_Now()
 759 {
 760         if(self.vehicle)
 761         {
 762             vehicles_exit(VHEF_RELESE);
 763             if(!self.killindicator_teamchange)
 764             {
 765             self.vehicle_health = -1;
 766             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 767             }
 768         }
 769
 770         if(self.killindicator && !wasfreed(self.killindicator))
 771                 remove(self.killindicator);
 772
 773         self.killindicator = world;
 774
 775         if(self.killindicator_teamchange)
 776                 ClientKill_Now_TeamChange();
 777
 778         // in any case:
 779         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 780
 781         // now I am sure the player IS dead
 782 }
 783 void KillIndicator_Think()
 784 {
 785         if (gameover)
 786         {
 787                 self.owner.killindicator = world;
 788                 remove(self);
 789                 return;
 790         }
 791
 792         if (self.owner.alpha < 0 && !self.owner.vehicle)
 793         {
 794                 self.owner.killindicator = world;
 795                 remove(self);
 796                 return;
 797         }
 798
 799         if(self.cnt <= 0)
 800         {
 801                 self = self.owner;
 802                 ClientKill_Now(); // no oldself needed
 803                 return;
 804         }
 805     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 806     {
 807         self.nextthink = time + 1;
 808         self.cnt -= 1;
 809     }
 810         else
 811         {
 812                 if(self.cnt <= 10)
 813                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 814                 if(IS_REAL_CLIENT(self.owner))
 815                 {
 816                         if(self.cnt <= 10)
 817                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 818                 }
 819                 self.nextthink = time + 1;
 820                 self.cnt -= 1;
 821         }
 822 }
 823
 824 float clientkilltime;
 825 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 826 {
 827         float killtime;
 828         float starttime;
 829         entity e;
 830
 831         if (gameover)
 832                 return;
 833
 834         killtime = autocvar_g_balance_kill_delay;
 835
 836         if(g_race_qualifying || g_cts)
 837                 killtime = 0;
 838
 839     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 840     {
 841                 remove(self.killindicator);
 842                 self.killindicator = world;
 843
 844         ClientKill_Now(); // allow instant kill in this case
 845         return;
 846     }
 847
 848         self.killindicator_teamchange = targetteam;
 849
 850     if(!self.killindicator)
 851         {
 852                 if(self.deadflag == DEAD_NO)
 853                 {
 854                         killtime = max(killtime, self.clientkill_nexttime - time);
 855                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 856                 }
 857
 858                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 859                 {
 860                         ClientKill_Now();
 861                 }
 862                 else
 863                 {
 864                         starttime = max(time, clientkilltime);
 865
 866                         self.killindicator = spawn();
 867                         self.killindicator.owner = self;
 868                         self.killindicator.scale = 0.5;
 869                         setattachment(self.killindicator, self, "");
 870                         setorigin(self.killindicator, '0 0 52');
 871                         self.killindicator.think = KillIndicator_Think;
 872                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 873                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 874                         self.killindicator.cnt = ceil(killtime);
 875                         self.killindicator.count = bound(0, ceil(killtime), 10);
 876                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 877
 878                         for(e = world; (e = find(e, classname, "body")) != world; )
 879                         {
 880                                 if(e.enemy != self)
 881                                         continue;
 882                                 e.killindicator = spawn();
 883                                 e.killindicator.owner = e;
 884                                 e.killindicator.scale = 0.5;
 885                                 setattachment(e.killindicator, e, "");
 886                                 setorigin(e.killindicator, '0 0 52');
 887                                 e.killindicator.think = KillIndicator_Think;
 888                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 889                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 890                                 e.killindicator.cnt = ceil(killtime);
 891                         }
 892                         self.lip = 0;
 893                 }
 894         }
 895         if(self.killindicator)
 896         {
 897                 if(targetteam == 0) // just die
 898                 {
 899                         self.killindicator.colormod = '0 0 0';
 900                         if(IS_REAL_CLIENT(self))
 901                         if(self.killindicator.cnt > 0)
 902                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 903                 }
 904                 else if(targetteam == -1) // auto
 905                 {
 906                         self.killindicator.colormod = '0 1 0';
 907                         if(IS_REAL_CLIENT(self))
 908                         if(self.killindicator.cnt > 0)
 909                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 910                 }
 911                 else if(targetteam == -2) // spectate
 912                 {
 913                         self.killindicator.colormod = '0.5 0.5 0.5';
 914                         if(IS_REAL_CLIENT(self))
 915                         if(self.killindicator.cnt > 0)
 916                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 917                 }
 918                 else
 919                 {
 920                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 921                         if(IS_REAL_CLIENT(self))
 922                         if(self.killindicator.cnt > 0)
 923                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 924                 }
 925         }
 926
 927 }
 928
 929 void ClientKill (void)
 930 {
 931         if(gameover) return;
 932         if(self.player_blocked) return;
 933         if(self.freezetag_frozen) return;
 934
 935         ClientKill_TeamChange(0);
 936 }
 937
 938 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 939 {
 940     e.killindicator = spawn();
 941     e.killindicator.owner = e;
 942     e.killindicator.think = KillIndicator_Think;
 943     e.killindicator.nextthink = time + (e.lip) * 0.05;
 944     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 945     e.killindicator.health = 1; // this is used to indicate that it should be silent
 946     e.lip = 0;
 947 }
 948
 949 void FixClientCvars(entity e)
 950 {
 951         // send prediction settings to the client
 952         stuffcmd(e, "\nin_bindmap 0 0\n");
 953         if(g_race || g_cts)
 954                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 955         if(autocvar_g_antilag == 3) // client side hitscan
 956                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 957         if(autocvar_sv_gentle)
 958                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 959         /*
 960          * we no longer need to stuff this. Remove this comment block if you feel
 961          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 962         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 963         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 964         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 966         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 967         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 969         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 970         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 972         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 973         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 974         stuffcmd(e, "cl_movement_edgefriction 1\n");
 975          */
 976 }
 977
 978 float PlayerInIDList(entity p, string idlist)
 979 {
 980         float n, i;
 981         string s;
 982
 983         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 984         if not(p.crypto_idfp)
 985                 return 0;
 986
 987         // this function allows abbreviated player IDs too!
 988         n = tokenize_console(idlist);
 989         for(i = 0; i < n; ++i)
 990         {
 991                 s = argv(i);
 992                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 993                         return 1;
 994         }
 995
 996         return 0;
 997 }
 998
 999 /*
1000 =============
1001 ClientConnect
1002
1003 Called when a client connects to the server
1004 =============
1005 */
1006 void DecodeLevelParms (void);
1007 //void dom_player_join_team(entity pl);
1008 void set_dom_state(entity e);
1009 void ClientConnect (void)
1010 {
1011         float t;
1012
1013         if(IS_CLIENT(self))
1014         {
1015                 print("Warning: ClientConnect, but already connected!\n");
1016                 return;
1017         }
1018
1019         if(Ban_MaybeEnforceBanOnce(self))
1020                 return;
1021
1022         DecodeLevelParms();
1023
1024 #ifdef WATERMARK
1025         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1026 #endif
1027
1028         self.classname = "player_joining";
1029
1030         self.flags = FL_CLIENT;
1031         self.version_nagtime = time + 10 + random() * 10;
1032
1033         if(player_count<0)
1034         {
1035                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1036                 player_count = 0;
1037         }
1038
1039         PlayerScore_Attach(self);
1040         ClientData_Attach();
1041         accuracy_init(self);
1042
1043         bot_clientconnect();
1044
1045         playerdemo_init();
1046
1047         anticheat_init();
1048
1049         race_PreSpawnObserver();
1050
1051         // identify the right forced team
1052         if(autocvar_g_campaign)
1053         {
1054                 if(IS_REAL_CLIENT(self)) // only players, not bots
1055                 {
1056                         switch(autocvar_g_campaign_forceteam)
1057                         {
1058                                 case 1: self.team_forced = NUM_TEAM_1; break;
1059                                 case 2: self.team_forced = NUM_TEAM_2; break;
1060                                 case 3: self.team_forced = NUM_TEAM_3; break;
1061                                 case 4: self.team_forced = NUM_TEAM_4; break;
1062                                 default: self.team_forced = 0;
1063                         }
1064                 }
1065         }
1066         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1067                 self.team_forced = NUM_TEAM_1;
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1069                 self.team_forced = NUM_TEAM_2;
1070         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1071                 self.team_forced = NUM_TEAM_3;
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1073                 self.team_forced = NUM_TEAM_4;
1074         else if(autocvar_g_forced_team_otherwise == "red")
1075                 self.team_forced = NUM_TEAM_1;
1076         else if(autocvar_g_forced_team_otherwise == "blue")
1077                 self.team_forced = NUM_TEAM_2;
1078         else if(autocvar_g_forced_team_otherwise == "yellow")
1079                 self.team_forced = NUM_TEAM_3;
1080         else if(autocvar_g_forced_team_otherwise == "pink")
1081                 self.team_forced = NUM_TEAM_4;
1082         else if(autocvar_g_forced_team_otherwise == "spectate")
1083                 self.team_forced = -1;
1084         else if(autocvar_g_forced_team_otherwise == "spectator")
1085                 self.team_forced = -1;
1086         else
1087                 self.team_forced = 0;
1088
1089         if(!teamplay)
1090                 if(self.team_forced > 0)
1091                         self.team_forced = 0;
1092
1093         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1094
1095         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1096                 self.classname = "observer";
1097         } else {
1098                 if(teamplay)
1099                 {
1100                         if(autocvar_g_balance_teams)
1101                         {
1102                                 self.classname = "player";
1103                                 campaign_bots_may_start = 1;
1104                         }
1105                         else
1106                         {
1107                                 self.classname = "observer"; // do it anyway
1108                         }
1109                 }
1110                 else
1111                 {
1112                         self.classname = "player";
1113                         campaign_bots_may_start = 1;
1114                 }
1115         }
1116
1117         self.playerid = (playerid_last = playerid_last + 1);
1118
1119         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1120
1121     if(IS_BOT_CLIENT(self))
1122         PlayerStats_AddPlayer(self);
1123
1124         if(autocvar_sv_eventlog)
1125                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1126
1127         LogTeamchange(self.playerid, self.team, 1);
1128
1129         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1130
1131         self.netname_previous = strzone(self.netname);
1132
1133         if(IS_PLAYER(self) && teamplay)
1134                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1135         else
1136                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1137
1138         stuffcmd(self, strcat(clientstuff, "\n"));
1139         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1140
1141         FixClientCvars(self);
1142
1143         // spawnfunc_waypoint sprites
1144         WaypointSprite_InitClient(self);
1145
1146         // Wazat's grappling hook
1147         SetGrappleHookBindings();
1148
1149         // get version info from player
1150         stuffcmd(self, "cmd clientversion $gameversion\n");
1151
1152         // get other cvars from player
1153         GetCvars(0);
1154
1155         // notify about available teams
1156         if(teamplay)
1157         {
1158                 CheckAllowedTeams(self);
1159                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1160                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1161         }
1162         else
1163                 stuffcmd(self, "set _teams_available 0\n");
1164
1165         attach_entcs();
1166
1167         bot_relinkplayerlist();
1168
1169         self.spectatortime = time;
1170         if(blockSpectators)
1171         {
1172                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1173         }
1174
1175         self.jointime = time;
1176         self.allowed_timeouts = autocvar_sv_timeout_number;
1177
1178         if(IS_REAL_CLIENT(self))
1179         {
1180                 if(!autocvar_g_campaign)
1181                 {
1182                         self.motd_actived_time = -1;
1183                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1184                 }
1185
1186                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1187                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1188         }
1189
1190         if(!sv_foginterval && world.fog != "")
1191                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1192
1193         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1194         {
1195                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1196                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1197         }
1198         else
1199                 self.hitplotfh = -1;
1200
1201         if(g_race || g_cts) {
1202                 string rr;
1203                 if(g_cts)
1204                         rr = CTS_RECORD;
1205                 else
1206                         rr = RACE_RECORD;
1207
1208                 msg_entity = self;
1209                 race_send_recordtime(MSG_ONE);
1210                 race_send_speedaward(MSG_ONE);
1211
1212                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1213                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1214                 race_send_speedaward_alltimebest(MSG_ONE);
1215
1216                 float i;
1217                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1218                         race_SendRankings(i, 0, 0, MSG_ONE);
1219                 }
1220         }
1221         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1222                 send_CSQC_teamnagger();
1223
1224         CheatInitClient();
1225
1226         CSQCMODEL_AUTOINIT();
1227
1228         self.model_randomizer = random();
1229
1230         if(IS_REAL_CLIENT(self))
1231                 sv_notice_join();
1232
1233         MUTATOR_CALLHOOK(ClientConnect);
1234 }
1235 /*
1236 =============
1237 ClientDisconnect
1238
1239 Called when a client disconnects from the server
1240 =============
1241 */
1242 .entity chatbubbleentity;
1243 void ReadyCount();
1244 void ClientDisconnect (void)
1245 {
1246         if(self.vehicle)
1247             vehicles_exit(VHEF_RELESE);
1248
1249         if not(IS_CLIENT(self))
1250         {
1251                 print("Warning: ClientDisconnect without ClientConnect\n");
1252                 return;
1253         }
1254
1255         PlayerStats_AddGlobalInfo(self);
1256
1257         CheatShutdownClient();
1258
1259         if(self.hitplotfh >= 0)
1260         {
1261                 fclose(self.hitplotfh);
1262                 self.hitplotfh = -1;
1263         }
1264
1265         anticheat_report();
1266         anticheat_shutdown();
1267
1268         playerdemo_shutdown();
1269
1270         bot_clientdisconnect();
1271
1272         if(self.entcs)
1273                 detach_entcs();
1274
1275         if(autocvar_sv_eventlog)
1276                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1277
1278         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1279
1280         MUTATOR_CALLHOOK(ClientDisconnect);
1281
1282         Portal_ClearAll(self);
1283
1284         RemoveGrapplingHook(self);
1285
1286         // Here, everything has been done that requires this player to be a client.
1287
1288         self.flags &= ~FL_CLIENT;
1289
1290         if (self.chatbubbleentity)
1291                 remove (self.chatbubbleentity);
1292
1293         if (self.killindicator)
1294                 remove (self.killindicator);
1295
1296         WaypointSprite_PlayerGone();
1297
1298         bot_relinkplayerlist();
1299
1300         accuracy_free(self);
1301         ClientData_Detach();
1302         PlayerScore_Detach(self);
1303
1304         if(self.netname_previous)
1305                 strunzone(self.netname_previous);
1306         if(self.clientstatus)
1307                 strunzone(self.clientstatus);
1308         if(self.weaponorder_byimpulse)
1309                 strunzone(self.weaponorder_byimpulse);
1310
1311         ClearPlayerSounds();
1312
1313         if(self.personal)
1314                 remove(self.personal);
1315
1316         self.playerid = 0;
1317         ReadyCount();
1318
1319         // free cvars
1320         GetCvars(-1);
1321 }
1322
1323 .float BUTTON_CHAT;
1324 void ChatBubbleThink()
1325 {
1326         self.nextthink = time;
1327         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1328         {
1329                 if(self.owner) // but why can that ever be world?
1330                         self.owner.chatbubbleentity = world;
1331                 remove(self);
1332                 return;
1333         }
1334         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1335 #ifdef TETRIS
1336                 || self.owner.tetris_on
1337 #endif
1338         )
1339                 self.model = self.mdl;
1340         else
1341                 self.model = "";
1342 }
1343
1344 void UpdateChatBubble()
1345 {
1346         if (self.alpha < 0)
1347                 return;
1348         // spawn a chatbubble entity if needed
1349         if (!self.chatbubbleentity)
1350         {
1351                 self.chatbubbleentity = spawn();
1352                 self.chatbubbleentity.owner = self;
1353                 self.chatbubbleentity.exteriormodeltoclient = self;
1354                 self.chatbubbleentity.think = ChatBubbleThink;
1355                 self.chatbubbleentity.nextthink = time;
1356                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1357                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1358                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1359                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1360                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1361                 self.chatbubbleentity.model = "";
1362                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1363         }
1364 }
1365
1366
1367 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1368 // added to the model skins
1369 /*void UpdateColorModHack()
1370 {
1371         float c;
1372         c = self.clientcolors & 15;
1373         // LordHavoc: only bothering to support white, green, red, yellow, blue
1374              if (!teamplay) self.colormod = '0 0 0';
1375         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1376         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1377         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1378         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1379         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1380         else self.colormod = '1 1 1';
1381 }*/
1382
1383 void respawn(void)
1384 {
1385         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1386         {
1387                 self.solid = SOLID_NOT;
1388                 self.takedamage = DAMAGE_NO;
1389                 self.movetype = MOVETYPE_FLY;
1390                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1391                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1392                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1393                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1394                 if(autocvar_g_respawn_ghosts_maxtime)
1395                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1396         }
1397
1398         CopyBody(1);
1399
1400         self.effects |= EF_NODRAW; // prevent another CopyBody
1401         PutClientInServer();
1402 }
1403
1404 void play_countdown(float finished, string samp)
1405 {
1406         if(IS_REAL_CLIENT(self))
1407                 if(floor(finished - time - frametime) != floor(finished - time))
1408                         if(finished - time < 6)
1409                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1410 }
1411
1412 void player_powerups (void)
1413 {
1414         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1415         olditems = self.items;
1416
1417         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1418                 self.modelflags |= MF_ROCKET;
1419         else
1420                 self.modelflags &= ~MF_ROCKET;
1421
1422         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1423
1424         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1425                 return;
1426
1427         Fire_ApplyDamage(self);
1428         Fire_ApplyEffect(self);
1429
1430         if not(g_minstagib)
1431         {
1432                 if (self.items & IT_STRENGTH)
1433                 {
1434                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1435                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1436                         if (time > self.strength_finished)
1437                         {
1438                                 self.items = self.items - (self.items & IT_STRENGTH);
1439                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1440                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1441                         }
1442                 }
1443                 else
1444                 {
1445                         if (time < self.strength_finished)
1446                         {
1447                                 self.items = self.items | IT_STRENGTH;
1448                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1449                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1450                         }
1451                 }
1452                 if (self.items & IT_INVINCIBLE)
1453                 {
1454                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1455                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1456                         if (time > self.invincible_finished)
1457                         {
1458                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1459                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1461                         }
1462                 }
1463                 else
1464                 {
1465                         if (time < self.invincible_finished)
1466                         {
1467                                 self.items = self.items | IT_INVINCIBLE;
1468                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1469                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1470                         }
1471                 }
1472                 if (self.items & IT_SUPERWEAPON)
1473                 {
1474                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1475                         {
1476                                 self.superweapons_finished = 0;
1477                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1478                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1480                         }
1481                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1482                         {
1483                                 // don't let them run out
1484                         }
1485                         else
1486                         {
1487                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1488                                 if (time > self.superweapons_finished)
1489                                 {
1490                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1491                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1492                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1493                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1494                                 }
1495                         }
1496                 }
1497                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1498                 {
1499                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1500                         {
1501                                 self.items = self.items | IT_SUPERWEAPON;
1502                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1503                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1504                         }
1505                         else
1506                         {
1507                                 self.superweapons_finished = 0;
1508                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1509                         }
1510                 }
1511                 else
1512                 {
1513                         self.superweapons_finished = 0;
1514                 }
1515         }
1516
1517         if(autocvar_g_nodepthtestplayers)
1518                 self.effects = self.effects | EF_NODEPTHTEST;
1519
1520         if(autocvar_g_fullbrightplayers)
1521                 self.effects = self.effects | EF_FULLBRIGHT;
1522
1523         if (time >= game_starttime)
1524         if (time < self.spawnshieldtime)
1525                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1526
1527         MUTATOR_CALLHOOK(PlayerPowerups);
1528 }
1529
1530 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1531 {
1532         if(current > stable)
1533                 return current;
1534         else if(current > stable - 0.25) // when close enough, "snap"
1535                 return stable;
1536         else
1537                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1538 }
1539
1540 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1541 {
1542         if(current < stable)
1543                 return current;
1544         else if(current < stable + 0.25) // when close enough, "snap"
1545                 return stable;
1546         else
1547                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1548 }
1549
1550 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1551 {
1552         if(current > rotstable)
1553         {
1554                 if(rotframetime > 0)
1555                 {
1556                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1557                         current = max(rotstable, current - rotlinear * rotframetime);
1558                 }
1559         }
1560         else if(current < regenstable)
1561         {
1562                 if(regenframetime > 0)
1563                 {
1564                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1565                         current = min(regenstable, current + regenlinear * regenframetime);
1566                 }
1567         }
1568
1569         if(current > limit)
1570                 current = limit;
1571
1572         return current;
1573 }
1574
1575 void player_regen (void)
1576 {
1577         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1578         maxh = autocvar_g_balance_health_rotstable;
1579         maxa = autocvar_g_balance_armor_rotstable;
1580         maxf = autocvar_g_balance_fuel_rotstable;
1581         minh = autocvar_g_balance_health_regenstable;
1582         mina = autocvar_g_balance_armor_regenstable;
1583         minf = autocvar_g_balance_fuel_regenstable;
1584         limith = autocvar_g_balance_health_limit;
1585         limita = autocvar_g_balance_armor_limit;
1586         limitf = autocvar_g_balance_fuel_limit;
1587
1588         max_mod = regen_mod = rot_mod = limit_mod = 1;
1589
1590         maxh = maxh * max_mod;
1591         //maxa = maxa * max_mod;
1592         //maxf = maxf * max_mod;
1593         minh = minh * max_mod;
1594         //mina = mina * max_mod;
1595         //minf = minf * max_mod;
1596         limith = limith * limit_mod;
1597         limita = limita * limit_mod;
1598         //limitf = limitf * limit_mod;
1599
1600         if(g_ca)
1601                 rot_mod = 0;
1602
1603         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1604         {
1605                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1606                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1607
1608                 // if player rotted to death...  die!
1609                 if(self.health < 1)
1610                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1611         }
1612
1613         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1614                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1615 }
1616
1617 float zoomstate_set;
1618 void SetZoomState(float z)
1619 {
1620         if(z != self.zoomstate)
1621         {
1622                 self.zoomstate = z;
1623                 ClientData_Touch(self);
1624         }
1625         zoomstate_set = 1;
1626 }
1627
1628 void GetPressedKeys(void) {
1629         MUTATOR_CALLHOOK(GetPressedKeys);
1630         if (self.movement_x > 0) // get if movement keys are pressed
1631         {       // forward key pressed
1632                 self.pressedkeys |= KEY_FORWARD;
1633                 self.pressedkeys &= ~KEY_BACKWARD;
1634         }
1635         else if (self.movement_x < 0)
1636         {       // backward key pressed
1637                 self.pressedkeys |= KEY_BACKWARD;
1638                 self.pressedkeys &= ~KEY_FORWARD;
1639         }
1640         else
1641         {       // no x input
1642                 self.pressedkeys &= ~KEY_FORWARD;
1643                 self.pressedkeys &= ~KEY_BACKWARD;
1644         }
1645
1646         if (self.movement_y > 0)
1647         {       // right key pressed
1648                 self.pressedkeys |= KEY_RIGHT;
1649                 self.pressedkeys &= ~KEY_LEFT;
1650         }
1651         else if (self.movement_y < 0)
1652         {       // left key pressed
1653                 self.pressedkeys |= KEY_LEFT;
1654                 self.pressedkeys &= ~KEY_RIGHT;
1655         }
1656         else
1657         {       // no y input
1658                 self.pressedkeys &= ~KEY_RIGHT;
1659                 self.pressedkeys &= ~KEY_LEFT;
1660         }
1661
1662         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1663                 self.pressedkeys |= KEY_JUMP;
1664         else
1665                 self.pressedkeys &= ~KEY_JUMP;
1666         if (self.BUTTON_CROUCH)
1667                 self.pressedkeys |= KEY_CROUCH;
1668         else
1669                 self.pressedkeys &= ~KEY_CROUCH;
1670
1671         if (self.BUTTON_ATCK)
1672                 self.pressedkeys |= KEY_ATCK;
1673         else
1674                 self.pressedkeys &= ~KEY_ATCK;
1675         if (self.BUTTON_ATCK2)
1676                 self.pressedkeys |= KEY_ATCK2;
1677         else
1678                 self.pressedkeys &= ~KEY_ATCK2;
1679 }
1680
1681 /*
1682 ======================
1683 spectate mode routines
1684 ======================
1685 */
1686
1687 void SpectateCopy(entity spectatee) {
1688         other = spectatee;
1689         MUTATOR_CALLHOOK(SpectateCopy);
1690         self.armortype = spectatee.armortype;
1691         self.armorvalue = spectatee.armorvalue;
1692         self.ammo_cells = spectatee.ammo_cells;
1693         self.ammo_shells = spectatee.ammo_shells;
1694         self.ammo_nails = spectatee.ammo_nails;
1695         self.ammo_rockets = spectatee.ammo_rockets;
1696         self.ammo_fuel = spectatee.ammo_fuel;
1697         self.clip_load = spectatee.clip_load;
1698         self.clip_size = spectatee.clip_size;
1699         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1700         self.health = spectatee.health;
1701         self.impulse = 0;
1702         self.items = spectatee.items;
1703         self.last_pickup = spectatee.last_pickup;
1704         self.hit_time = spectatee.hit_time;
1705         self.metertime = spectatee.metertime;
1706         self.strength_finished = spectatee.strength_finished;
1707         self.invincible_finished = spectatee.invincible_finished;
1708         self.pressedkeys = spectatee.pressedkeys;
1709         self.weapons = spectatee.weapons;
1710         self.switchweapon = spectatee.switchweapon;
1711         self.switchingweapon = spectatee.switchingweapon;
1712         self.weapon = spectatee.weapon;
1713         self.nex_charge = spectatee.nex_charge;
1714         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1715         self.hagar_load = spectatee.hagar_load;
1716         self.minelayer_mines = spectatee.minelayer_mines;
1717         self.punchangle = spectatee.punchangle;
1718         self.view_ofs = spectatee.view_ofs;
1719         self.velocity = spectatee.velocity;
1720         self.dmg_take = spectatee.dmg_take;
1721         self.dmg_save = spectatee.dmg_save;
1722         self.dmg_inflictor = spectatee.dmg_inflictor;
1723         self.v_angle = spectatee.v_angle;
1724         self.angles = spectatee.v_angle;
1725         if(!self.BUTTON_USE)
1726                 self.fixangle = TRUE;
1727         setorigin(self, spectatee.origin);
1728         setsize(self, spectatee.mins, spectatee.maxs);
1729         SetZoomState(spectatee.zoomstate);
1730
1731     anticheat_spectatecopy(spectatee);
1732         self.hud = spectatee.hud;
1733         if(spectatee.vehicle)
1734     {
1735         self.fixangle = FALSE;
1736         //self.velocity = spectatee.vehicle.velocity;
1737         self.vehicle_health = spectatee.vehicle_health;
1738         self.vehicle_shield = spectatee.vehicle_shield;
1739         self.vehicle_energy = spectatee.vehicle_energy;
1740         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1741         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1742         self.vehicle_reload1 = spectatee.vehicle_reload1;
1743         self.vehicle_reload2 = spectatee.vehicle_reload2;
1744
1745         msg_entity = self;
1746
1747         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1748             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1749             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1750             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1751
1752         //WriteByte (MSG_ONE, SVC_SETVIEW);
1753         //    WriteEntity(MSG_ONE, self);
1754         //makevectors(spectatee.v_angle);
1755         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1756     }
1757 }
1758
1759 float SpectateUpdate() {
1760         if(!self.enemy)
1761             return 0;
1762
1763         if (self == self.enemy)
1764                 return 0;
1765
1766         if not(IS_PLAYER(self.enemy))
1767                 return 0;
1768
1769         SpectateCopy(self.enemy);
1770
1771         return 1;
1772 }
1773
1774
1775 float SpectateSet()
1776 {
1777         if(self.enemy.classname != "player")
1778                 return FALSE;
1779         /*if(self.enemy.vehicle)
1780         {
1781
1782                 msg_entity = self;
1783                 WriteByte(MSG_ONE, SVC_SETVIEW);
1784                 WriteEntity(MSG_ONE, self.enemy);
1785                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1786
1787                 self.movetype = MOVETYPE_NONE;
1788                 accuracy_resend(self);
1789         }
1790         else
1791         {*/
1792                 msg_entity = self;
1793                 WriteByte(MSG_ONE, SVC_SETVIEW);
1794                 WriteEntity(MSG_ONE, self.enemy);
1795                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1796                 self.movetype = MOVETYPE_NONE;
1797                 accuracy_resend(self);
1798
1799                 if(!SpectateUpdate())
1800                         PutObserverInServer();
1801         //}
1802         return TRUE;
1803 }
1804
1805 float Spectate(entity pl)
1806 {
1807         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1808         if(pl.team != self.team)
1809                 return 0;
1810
1811         self.enemy = pl;
1812         return SpectateSet();
1813 }
1814
1815 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1816 entity CA_SpectateNext(entity start) {
1817         if (start.team == self.team) {
1818                 return start;
1819         }
1820
1821         other = start;
1822         // continue from current player
1823         while(other && other.team != self.team) {
1824                 other = find(other, classname, "player");
1825         }
1826
1827         if (!other) {
1828                 // restart from begining
1829                 other = find(other, classname, "player");
1830                 while(other && other.team != self.team) {
1831                         other = find(other, classname, "player");
1832                 }
1833         }
1834
1835         return other;
1836 }
1837
1838 float SpectateNext()
1839 {
1840         other = find(self.enemy, classname, "player");
1841
1842         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1843                 // CA and ca players when spectating enemies is forbidden
1844                 other = CA_SpectateNext(other);
1845         } else {
1846                 // other modes and ca spectators or spectating enemies is allowed
1847                 if (!other)
1848                         other = find(other, classname, "player");
1849         }
1850
1851         if (other)
1852                 self.enemy = other;
1853
1854         return SpectateSet();
1855 }
1856
1857 float SpectatePrev()
1858 {
1859         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1860         other = findchain(classname, "player");
1861         if not(other) // no player
1862                 return FALSE;
1863
1864         entity first = other;
1865         // skip players until current spectated player
1866         if(self.enemy)
1867         while(other && other != self.enemy)
1868                 other = other.chain;
1869
1870         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1871         {
1872                 do { other = other.chain; }
1873                 while(other && other.team != self.team);
1874
1875                 if not(other)
1876                 {
1877                         other = first;
1878                         while(other.team != self.team)
1879                                 other = other.chain;
1880                         if(other == self.enemy)
1881                                 return TRUE;
1882                 }
1883         }
1884         else
1885         {
1886                 if(other.chain)
1887                         other = other.chain;
1888                 else
1889                         other = first;
1890         }
1891         self.enemy = other;
1892         return SpectateSet();
1893 }
1894
1895 /*
1896 =============
1897 ShowRespawnCountdown()
1898
1899 Update a respawn countdown display.
1900 =============
1901 */
1902 void ShowRespawnCountdown()
1903 {
1904         float number;
1905         if(self.deadflag == DEAD_NO) // just respawned?
1906                 return;
1907         else
1908         {
1909                 number = ceil(self.respawn_time - time);
1910                 if(number <= 0)
1911                         return;
1912                 if(number <= self.respawn_countdown)
1913                 {
1914                         self.respawn_countdown = number - 1;
1915                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1916                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1917                 }
1918         }
1919 }
1920
1921 void LeaveSpectatorMode()
1922 {
1923         if(self.caplayer)
1924                 return;
1925         if(nJoinAllowed(self))
1926         {
1927                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1928                 {
1929                         self.classname = "player";
1930
1931                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1932                                 { JoinBestTeam(self, FALSE, TRUE); }
1933
1934                         if(autocvar_g_campaign)
1935                                 { campaign_bots_may_start = 1; }
1936
1937                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1938
1939                         PutClientInServer();
1940
1941                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1942                 }
1943                 else
1944                         stuffcmd(self, "menu_showteamselect\n");
1945         }
1946         else
1947         {
1948                 // Player may not join because g_maxplayers is set
1949                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1950         }
1951 }
1952
1953 /**
1954  * Determines whether the player is allowed to join. This depends on cvar
1955  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1956  * it checks whether the number of currently playing players exceeds g_maxplayers.
1957  * @return int number of free slots for players, 0 if none
1958  */
1959 float nJoinAllowed(entity ignore) {
1960         if(!ignore)
1961         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1962         // so report 0 free slots if restricted
1963         {
1964                 if(autocvar_g_forced_team_otherwise == "spectate")
1965                         return 0;
1966                 if(autocvar_g_forced_team_otherwise == "spectator")
1967                         return 0;
1968         }
1969
1970         if(self.team_forced < 0)
1971                 return 0; // forced spectators can never join
1972
1973         // TODO simplify this
1974         entity e;
1975         float totalClients = 0;
1976         FOR_EACH_CLIENT(e)
1977                 if(e != ignore)
1978                         totalClients += 1;
1979
1980         if (!autocvar_g_maxplayers)
1981                 return maxclients - totalClients;
1982
1983         float currentlyPlaying = 0;
1984         FOR_EACH_REALCLIENT(e)
1985                 if(IS_PLAYER(e) || e.caplayer == 1)
1986                         currentlyPlaying += 1;
1987
1988         if(currentlyPlaying < autocvar_g_maxplayers)
1989                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1990
1991         return 0;
1992 }
1993
1994 /**
1995  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1996  * g_maxplayers_spectator_blocktime seconds
1997  */
1998 void checkSpectatorBlock() {
1999         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2000                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2001                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2002                         dropclient(self);
2003                 }
2004         }
2005 }
2006
2007 void PrintWelcomeMessage()
2008 {
2009         if(self.motd_actived_time == 0)
2010         {
2011                 if (autocvar_g_campaign) {
2012                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2013                                 self.motd_actived_time = time;
2014                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2015                         }
2016                 } else {
2017                         if (self.BUTTON_INFO) {
2018                                 self.motd_actived_time = time;
2019                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2020                         }
2021                 }
2022         }
2023         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2024         {
2025                 if (autocvar_g_campaign) {
2026                         if (self.BUTTON_INFO)
2027                                 self.motd_actived_time = time;
2028                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2029                                 self.motd_actived_time = 0;
2030                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2031                         }
2032                 } else {
2033                         if (self.BUTTON_INFO)
2034                                 self.motd_actived_time = time;
2035                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2036                                 self.motd_actived_time = 0;
2037                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2038                         }
2039                 }
2040         }
2041         else //if(self.motd_actived_time < 0) // just connected, motd is active
2042         {
2043                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2044                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2045                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2046                 {
2047                         // instanctly hide MOTD
2048                         self.motd_actived_time = 0;
2049                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2050                 }
2051         }
2052 }
2053
2054 void ObserverThink()
2055 {
2056         float prefered_movetype;
2057         if (self.flags & FL_JUMPRELEASED) {
2058                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2059                         self.flags &= ~FL_JUMPRELEASED;
2060                         self.flags |= FL_SPAWNING;
2061                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2062                         self.flags &= ~FL_JUMPRELEASED;
2063                         if(SpectateNext()) {
2064                                 self.classname = "spectator";
2065                         }
2066                 } else {
2067                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2068                         if (self.movetype != prefered_movetype)
2069                                 self.movetype = prefered_movetype;
2070                 }
2071         } else {
2072                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2073                         self.flags |= FL_JUMPRELEASED;
2074                         if(self.flags & FL_SPAWNING)
2075                         {
2076                                 self.flags &= ~FL_SPAWNING;
2077                                 LeaveSpectatorMode();
2078                                 return;
2079                         }
2080                 }
2081         }
2082 }
2083
2084 void SpectatorThink()
2085 {
2086         if (self.flags & FL_JUMPRELEASED) {
2087                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2088                         self.flags &= ~FL_JUMPRELEASED;
2089                         self.flags |= FL_SPAWNING;
2090                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2091                         self.flags &= ~FL_JUMPRELEASED;
2092                         if(SpectateNext()) {
2093                                 self.classname = "spectator";
2094                         } else {
2095                                 self.classname = "observer";
2096                                 PutClientInServer();
2097                         }
2098                         self.impulse = 0;
2099                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectatePrev()) {
2102                                 self.classname = "spectator";
2103                         } else {
2104                                 self.classname = "observer";
2105                                 PutClientInServer();
2106                         }
2107                         self.impulse = 0;
2108                 } else if (self.BUTTON_ATCK2) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         self.classname = "observer";
2111                         PutClientInServer();
2112                 } else {
2113                         if(!SpectateUpdate())
2114                                 PutObserverInServer();
2115                 }
2116         } else {
2117                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2118                         self.flags |= FL_JUMPRELEASED;
2119                         if(self.flags & FL_SPAWNING)
2120                         {
2121                                 self.flags &= ~FL_SPAWNING;
2122                                 LeaveSpectatorMode();
2123                                 return;
2124                         }
2125                 }
2126                 if(!SpectateUpdate())
2127                         PutObserverInServer();
2128         }
2129
2130         self.flags |= FL_CLIENT | FL_NOTARGET;
2131 }
2132
2133 void PlayerUseKey()
2134 {
2135         if not(IS_PLAYER(self))
2136                 return;
2137
2138         if(self.vehicle)
2139         {
2140         vehicles_exit(VHEF_NORMAL);
2141         return;
2142         }
2143
2144         // a use key was pressed; call handlers
2145         MUTATOR_CALLHOOK(PlayerUseKey);
2146 }
2147
2148 /*
2149 =============
2150 PlayerPreThink
2151
2152 Called every frame for each client before the physics are run
2153 =============
2154 */
2155 .float usekeypressed;
2156 void() nexball_setstatus;
2157 .float items_added;
2158 void PlayerPreThink (void)
2159 {
2160         WarpZone_PlayerPhysics_FixVAngle();
2161
2162         self.stat_game_starttime = game_starttime;
2163         self.stat_round_starttime = round_starttime;
2164         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2165         self.stat_leadlimit = autocvar_leadlimit;
2166
2167         if(frametime)
2168         {
2169                 // physics frames: update anticheat stuff
2170                 anticheat_prethink();
2171         }
2172
2173         if(blockSpectators && frametime)
2174                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2175                 checkSpectatorBlock();
2176
2177         zoomstate_set = 0;
2178
2179         if(self.netname_previous != self.netname)
2180         {
2181                 if(autocvar_sv_eventlog)
2182                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2183                 if(self.netname_previous)
2184                         strunzone(self.netname_previous);
2185                 self.netname_previous = strzone(self.netname);
2186         }
2187
2188         // version nagging
2189         if(self.version_nagtime)
2190                 if(self.cvar_g_xonoticversion)
2191                         if(time > self.version_nagtime)
2192                         {
2193                                 // don't notify git users
2194                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2195                                 {
2196                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2197                                         {
2198                                                 // notify release users if connecting to git
2199                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2200                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2201                                         }
2202                                         else
2203                                         {
2204                                                 float r;
2205                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2206                                                 if(r < 0)
2207                                                 {
2208                                                         // give users new version
2209                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2210                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2211                                                 }
2212                                                 else if(r > 0)
2213                                                 {
2214                                                         // notify users about old server version
2215                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2216                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2217                                                 }
2218                                         }
2219                                 }
2220                                 self.version_nagtime = 0;
2221                         }
2222
2223         // GOD MODE info
2224         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2225         {
2226                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2227                 self.max_armorvalue = 0;
2228         }
2229
2230 #ifdef TETRIS
2231         if (TetrisPreFrame())
2232                 return;
2233 #endif
2234
2235         MUTATOR_CALLHOOK(PlayerPreThink);
2236
2237         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2238         {
2239                 if(self.BUTTON_USE && !self.usekeypressed)
2240                         PlayerUseKey();
2241                 self.usekeypressed = self.BUTTON_USE;
2242         }
2243
2244         if(IS_REAL_CLIENT(self))
2245                 PrintWelcomeMessage();
2246
2247         if(IS_PLAYER(self))
2248         {
2249
2250                 CheckRules_Player();
2251
2252                 if (intermission_running)
2253                 {
2254                         IntermissionThink ();   // otherwise a button could be missed between
2255                         return;                                 // the think tics
2256                 }
2257
2258                 //don't allow the player to turn around while game is paused!
2259                 if(timeout_status == TIMEOUT_ACTIVE) {
2260                         // FIXME turn this into CSQC stuff
2261                         self.v_angle = self.lastV_angle;
2262                         self.angles = self.lastV_angle;
2263                         self.fixangle = TRUE;
2264                 }
2265
2266                 if(frametime)
2267                 {
2268                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2269                         {
2270                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2271                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2272                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2273
2274                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2275                                 {
2276                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2277                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2278                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2279                                 }
2280                         }
2281                         else
2282                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2283
2284                         player_powerups();
2285                 }
2286
2287                 if (self.deadflag != DEAD_NO)
2288                 {
2289                         if(self.personal && g_race_qualifying)
2290                         {
2291                                 if(time > self.respawn_time)
2292                                 {
2293                                         self.respawn_time = time + 1; // only retry once a second
2294                                         self.stat_respawn_time = self.respawn_time;
2295                                         respawn();
2296                                         self.impulse = 141;
2297                                 }
2298                         }
2299                         else
2300                         {
2301                                 float button_pressed;
2302                                 if(frametime)
2303                                         player_anim();
2304                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2305
2306                                 if (self.deadflag == DEAD_DYING)
2307                                 {
2308                                         if(self.respawn_flags & RESPAWN_FORCE)
2309                                                 self.deadflag = DEAD_RESPAWNING;
2310                                         else if(!button_pressed)
2311                                                 self.deadflag = DEAD_DEAD;
2312                                 }
2313                                 else if (self.deadflag == DEAD_DEAD)
2314                                 {
2315                                         if(button_pressed)
2316                                                 self.deadflag = DEAD_RESPAWNABLE;
2317                                 }
2318                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2319                                 {
2320                                         if(!button_pressed)
2321                                                 self.deadflag = DEAD_RESPAWNING;
2322                                 }
2323                                 else if (self.deadflag == DEAD_RESPAWNING)
2324                                 {
2325                                         if(time > self.respawn_time)
2326                                         {
2327                                                 self.respawn_time = time + 1; // only retry once a second
2328                                                 respawn();
2329                                         }
2330                                 }
2331
2332                                 ShowRespawnCountdown();
2333
2334                                 if(self.respawn_flags & RESPAWN_SILENT)
2335                                         self.stat_respawn_time = 0;
2336                                 else
2337                                         self.stat_respawn_time = self.respawn_time;
2338                         }
2339
2340                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2341                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2342                                 self.stat_respawn_time *= -1;
2343
2344                         return;
2345                 }
2346
2347                 self.prevorigin = self.origin;
2348
2349                 float do_crouch = self.BUTTON_CROUCH;
2350                 if(self.hook.state)
2351                         do_crouch = 0;
2352                 if(self.vehicle)
2353                         do_crouch = 0;
2354                 if(self.freezetag_frozen)
2355                         do_crouch = 0;
2356                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2357                         do_crouch = 0;
2358
2359                 if (do_crouch)
2360                 {
2361                         if (!self.crouch)
2362                         {
2363                                 self.crouch = TRUE;
2364                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2365                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2366                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2367                         }
2368                 }
2369                 else
2370                 {
2371                         if (self.crouch)
2372                         {
2373                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2374                                 if (!trace_startsolid)
2375                                 {
2376                                         self.crouch = FALSE;
2377                                         self.view_ofs = PL_VIEW_OFS;
2378                                         setsize (self, PL_MIN, PL_MAX);
2379                                 }
2380                         }
2381                 }
2382
2383                 FixPlayermodel();
2384
2385                 GrapplingHookFrame();
2386
2387                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2388                 //if(frametime)
2389                 {
2390                         self.items &= ~self.items_added;
2391
2392                         W_WeaponFrame();
2393
2394                         self.items_added = 0;
2395                         if(self.items & IT_JETPACK)
2396                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2397                                         self.items_added |= IT_FUEL;
2398
2399                         self.items |= self.items_added;
2400                 }
2401
2402                 player_regen();
2403
2404                 // rot nex charge to the charge limit
2405                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2406                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2407
2408                 if(frametime)
2409                         player_anim();
2410
2411                 // secret status
2412                 secrets_setstatus();
2413
2414                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2415
2416                 //self.angles_y=self.v_angle_y + 90;   // temp
2417         } else if(gameover) {
2418                 if (intermission_running)
2419                         IntermissionThink ();   // otherwise a button could be missed between
2420                 return;
2421         } else if(IS_OBSERVER(self)) {
2422                 ObserverThink();
2423         } else if(IS_SPEC(self)) {
2424                 SpectatorThink();
2425         }
2426
2427         if(!zoomstate_set)
2428                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2429
2430         float oldspectatee_status;
2431         oldspectatee_status = self.spectatee_status;
2432         if(IS_SPEC(self))
2433                 self.spectatee_status = num_for_edict(self.enemy);
2434         else if(IS_OBSERVER(self))
2435                 self.spectatee_status = num_for_edict(self);
2436         else
2437                 self.spectatee_status = 0;
2438         if(self.spectatee_status != oldspectatee_status)
2439         {
2440                 ClientData_Touch(self);
2441                 if(g_race || g_cts)
2442                         race_InitSpectator();
2443         }
2444
2445         if(self.teamkill_soundtime)
2446         if(time > self.teamkill_soundtime)
2447         {
2448                 self.teamkill_soundtime = 0;
2449
2450                 entity oldpusher, oldself;
2451
2452                 oldself = self; self = self.teamkill_soundsource;
2453                 oldpusher = self.pusher; self.pusher = oldself;
2454
2455                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2456
2457                 self.pusher = oldpusher;
2458                 self = oldself;
2459         }
2460
2461         if(self.taunt_soundtime)
2462         if(time > self.taunt_soundtime)
2463         {
2464                 self.taunt_soundtime = 0;
2465                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2466         }
2467
2468         target_voicescript_next(self);
2469
2470         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2471         if(!self.weapon)
2472                 self.clip_load = self.clip_size = 0;
2473 }
2474
2475 float isInvisibleString(string s)
2476 {
2477         float i, n, c;
2478         s = strdecolorize(s);
2479         for((i = 0), (n = strlen(s)); i < n; ++i)
2480         {
2481                 c = str2chr(s, i);
2482                 switch(c)
2483                 {
2484                         case 0:
2485                         case 32: // space
2486                                 break;
2487                         case 192: // charmap space
2488                                 if (!autocvar_utf8_enable)
2489                                         break;
2490                                 return FALSE;
2491                         case 160: // space in unicode fonts
2492                         case 0xE000 + 192: // utf8 charmap space
2493                                 if (autocvar_utf8_enable)
2494                                         break;
2495                         default:
2496                                 return FALSE;
2497                 }
2498         }
2499         return TRUE;
2500 }
2501
2502 /*
2503 =============
2504 PlayerPostThink
2505
2506 Called every frame for each client after the physics are run
2507 =============
2508 */
2509 .float idlekick_lasttimeleft;
2510 void PlayerPostThink (void)
2511 {
2512         // Savage: Check for nameless players
2513         if (isInvisibleString(self.netname)) {
2514                 self.netname = "Player";
2515                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2516         }
2517
2518         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2519         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2520         {
2521                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2522                 {
2523                         if(self.idlekick_lasttimeleft)
2524                         {
2525                                 self.idlekick_lasttimeleft = 0;
2526                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2527                         }
2528                 }
2529                 else
2530                 {
2531                         float timeleft;
2532                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2533                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2534                         {
2535                                 if(!self.idlekick_lasttimeleft)
2536                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2537                         }
2538                         if(timeleft <= 0)
2539                         {
2540                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2541                                 dropclient(self);
2542                                 return;
2543                         }
2544                         else if(timeleft <= 10)
2545                         {
2546                                 if(timeleft != self.idlekick_lasttimeleft)
2547                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2548                                 self.idlekick_lasttimeleft = timeleft;
2549                         }
2550                 }
2551         }
2552
2553 #ifdef TETRIS
2554         if(self.impulse == 100)
2555                 ImpulseCommands();
2556         if (!TetrisPostFrame())
2557         {
2558 #endif
2559
2560         CheatFrame();
2561
2562         //CheckPlayerJump();
2563
2564         if(IS_PLAYER(self)) {
2565                 CheckRules_Player();
2566                 UpdateChatBubble();
2567                 if (self.impulse)
2568                         ImpulseCommands();
2569                 if (intermission_running)
2570                         return;         // intermission or finale
2571                 GetPressedKeys();
2572         }
2573
2574 #ifdef TETRIS
2575         }
2576 #endif
2577
2578         /*
2579         float i;
2580         for(i = 0; i < 1000; ++i)
2581         {
2582                 vector end;
2583                 end = self.origin + '0 0 1024' + 512 * randomvec();
2584                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2585                 if(trace_fraction < 1)
2586                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2587                 {
2588                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2589                         break;
2590                 }
2591         }
2592         */
2593
2594         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2595
2596         if(self.waypointsprite_attachedforcarrier)
2597                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2598
2599         playerdemo_write();
2600
2601         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2602         {
2603                 if not(self.stored_netname)
2604                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2605                 if(self.stored_netname != self.netname)
2606                 {
2607                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2608                         strunzone(self.stored_netname);
2609                         self.stored_netname = strzone(self.netname);
2610                 }
2611         }
2612
2613         /*
2614         if(g_race)
2615                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2616         */
2617
2618         CSQCMODEL_AUTOUPDATE();
2619 }