Merge branch 'master' into Mario/buffs
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 float ClientData_Send(entity to, float sf)
10 {
11         if(to != self.owner)
12         {
13                 error("wtf");
14                 return FALSE;
15         }
16
17         entity e;
18
19         e = to;
20         if(IS_SPEC(to))
21                 e = to.enemy;
22
23         sf = 0;
24
25         if(e.race_completed)
26                 sf |= 1; // forced scoreboard
27         if(to.spectatee_status)
28                 sf |= 2; // spectator ent number follows
29         if(e.zoomstate)
30                 sf |= 4; // zoomed
31         if(e.porto_v_angle_held)
32                 sf |= 8; // angles held
33
34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
35         WriteByte(MSG_ENTITY, sf);
36
37         if(sf & 2)
38                 WriteByte(MSG_ENTITY, to.spectatee_status);
39
40         if(sf & 8)
41         {
42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
44         }
45
46         return TRUE;
47 }
48
49 void ClientData_Attach()
50 {
51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
52         self.clientdata.drawonlytoclient = self;
53         self.clientdata.owner = self;
54 }
55
56 void ClientData_Detach()
57 {
58         remove(self.clientdata);
59         self.clientdata = world;
60 }
61
62 void ClientData_Touch(entity e)
63 {
64         e.clientdata.SendFlags = 1;
65
66         // make it spectatable
67         entity e2;
68         FOR_EACH_REALCLIENT(e2)
69         {
70                 if(e2 != e)
71                         if(IS_SPEC(e2))
72                                 if(e2.enemy == e)
73                                         e2.clientdata.SendFlags = 1;
74         }
75 }
76
77 .string netname_previous;
78
79
80 /*
81 =============
82 CheckPlayerModel
83
84 Checks if the argument string can be a valid playermodel.
85 Returns a valid one in doubt.
86 =============
87 */
88 string FallbackPlayerModel;
89 string CheckPlayerModel(string plyermodel) {
90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
91         {
92                 // note: we cannot summon Don Strunzone here, some player may
93                 // still have the model string set. In case anyone manages how
94                 // to change a cvar default, we'll have a small leak here.
95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
96         }
97         // only in right path
98         if( substring(plyermodel,0,14) != "models/player/")
99                 return FallbackPlayerModel;
100         // only good file extensions
101         if(substring(plyermodel,-4,4) != ".zym")
102         if(substring(plyermodel,-4,4) != ".dpm")
103         if(substring(plyermodel,-4,4) != ".iqm")
104         if(substring(plyermodel,-4,4) != ".md3")
105         if(substring(plyermodel,-4,4) != ".psk")
106                 return FallbackPlayerModel;
107         // forbid the LOD models
108         if(substring(plyermodel, -9,5) == "_lod1")
109                 return FallbackPlayerModel;
110         if(substring(plyermodel, -9,5) == "_lod2")
111                 return FallbackPlayerModel;
112         if(plyermodel != strtolower(plyermodel))
113                 return FallbackPlayerModel;
114         // also, restrict to server models
115         if(autocvar_sv_servermodelsonly)
116         {
117                 if(!fexists(plyermodel))
118                         return FallbackPlayerModel;
119         }
120         return plyermodel;
121 }
122
123 void setplayermodel(entity e, string modelname)
124 {
125         precache_model(modelname);
126         setmodel(e, modelname);
127         player_setupanimsformodel();
128         UpdatePlayerSounds();
129 }
130
131 /*
132 =============
133 PutObserverInServer
134
135 putting a client as observer in the server
136 =============
137 */
138 void FixPlayermodel();
139 void PutObserverInServer (void)
140 {
141         entity  spot;
142     self.hud = HUD_NORMAL;
143         race_PreSpawnObserver();
144
145         spot = SelectSpawnPoint (TRUE);
146         if(!spot)
147                 error("No spawnpoints for observers?!?\n");
148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
149
150         if(IS_REAL_CLIENT(self))
151         {
152                 msg_entity = self;
153                 WriteByte(MSG_ONE, SVC_SETVIEW);
154                 WriteEntity(MSG_ONE, self);
155         }
156
157         if((g_race && g_race_qualifying) || g_cts)
158         {
159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
160                         self.frags = FRAGS_LMS_LOSER;
161                 else
162                         self.frags = FRAGS_SPECTATOR;
163         }
164         else
165                 self.frags = FRAGS_SPECTATOR;
166
167         MUTATOR_CALLHOOK(MakePlayerObserver);
168
169         Portal_ClearAll(self);
170
171         if(self.alivetime)
172         {
173                 if(!warmup_stage)
174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
175                 self.alivetime = 0;
176         }
177
178         if(self.vehicle)
179                 vehicles_exit(VHEF_RELESE);
180
181         WaypointSprite_PlayerDead();
182
183         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
185
186         if(self.killcount != -666)
187         {
188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
189                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
190                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
191
192                 if(self.just_joined == FALSE) {
193                         LogTeamchange(self.playerid, -1, 4);
194                 } else
195                         self.just_joined = FALSE;
196         }
197
198         PlayerScore_Clear(self); // clear scores when needed
199
200         accuracy_resend(self);
201
202         self.spectatortime = time;
203
204         self.classname = "observer";
205         self.iscreature = FALSE;
206         self.teleportable = TELEPORT_SIMPLE;
207         self.damagedbycontents = FALSE;
208         self.health = -666;
209         self.takedamage = DAMAGE_NO;
210         self.solid = SOLID_NOT;
211         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
212         self.flags = FL_CLIENT | FL_NOTARGET;
213         self.armorvalue = 666;
214         self.effects = 0;
215         self.armorvalue = autocvar_g_balance_armor_start;
216         self.pauserotarmor_finished = 0;
217         self.pauserothealth_finished = 0;
218         self.pauseregen_finished = 0;
219         self.damageforcescale = 0;
220         self.death_time = 0;
221         self.respawn_flags = 0;
222         self.respawn_time = 0;
223         self.stat_respawn_time = 0;
224         self.alpha = 0;
225         self.scale = 0;
226         self.fade_time = 0;
227         self.pain_frame = 0;
228         self.pain_finished = 0;
229         self.strength_finished = 0;
230         self.invincible_finished = 0;
231         self.superweapons_finished = 0;
232         self.pushltime = 0;
233         self.istypefrag = 0;
234         self.think = func_null;
235         self.nextthink = 0;
236         self.hook_time = 0;
237         self.deadflag = DEAD_NO;
238         self.angles = spot.angles;
239         self.angles_z = 0;
240         self.fixangle = TRUE;
241         self.crouch = FALSE;
242
243         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
244         self.prevorigin = self.origin;
245         self.items = 0;
246         self.weapons = '0 0 0';
247         self.model = "";
248         FixPlayermodel();
249         setmodel(self, "null");
250         self.drawonlytoclient = self;
251
252         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
253         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
254
255         self.weapon = 0;
256         self.weaponname = "";
257         self.switchingweapon = 0;
258         self.weaponmodel = "";
259         self.weaponentity = world;
260         self.exteriorweaponentity = world;
261         self.killcount = -666;
262         self.velocity = '0 0 0';
263         self.avelocity = '0 0 0';
264         self.punchangle = '0 0 0';
265         self.punchvector = '0 0 0';
266         self.oldvelocity = self.velocity;
267         self.fire_endtime = -1;
268 }
269
270 .float model_randomizer;
271 void FixPlayermodel()
272 {
273         string defaultmodel;
274         float defaultskin, chmdl, oldskin, n, i;
275         vector m1, m2;
276
277         defaultmodel = "";
278         defaultskin = 0;
279         chmdl = FALSE;
280
281         if(autocvar_sv_defaultcharacter == 1)
282         {
283                 if(teamplay)
284                 {
285                         string s;
286                         s = Static_Team_ColorName_Lower(self.team);
287                         if(s != "neutral")
288                         {
289                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
290                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
291                         }
292                 }
293
294                 if(defaultmodel == "")
295                 {
296                         defaultmodel = autocvar_sv_defaultplayermodel;
297                         defaultskin = autocvar_sv_defaultplayerskin;
298                 }
299
300                 n = tokenize_console(defaultmodel);
301                 if(n > 0)
302                 {
303                         defaultmodel = argv(floor(n * self.model_randomizer));
304                         // However, do NOT randomize if the player-selected model is in the list.
305                         for (i = 0; i < n; ++i)
306                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
307                                         defaultmodel = argv(i);
308                 }
309
310                 i = strstrofs(defaultmodel, ":", 0);
311                 if(i >= 0)
312                 {
313                         defaultskin = stof(substring(defaultmodel, i+1, -1));
314                         defaultmodel = substring(defaultmodel, 0, i);
315                 }
316         }
317
318         if(defaultmodel != "")
319         {
320                 if (defaultmodel != self.model)
321                 {
322                         m1 = self.mins;
323                         m2 = self.maxs;
324                         setplayermodel (self, defaultmodel);
325                         setsize (self, m1, m2);
326                         chmdl = TRUE;
327                 }
328
329                 oldskin = self.skin;
330                 self.skin = defaultskin;
331         } else {
332                 if (self.playermodel != self.model || self.playermodel == "")
333                 {
334                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
335                         m1 = self.mins;
336                         m2 = self.maxs;
337                         setplayermodel (self, self.playermodel);
338                         setsize (self, m1, m2);
339                         chmdl = TRUE;
340                 }
341
342                 oldskin = self.skin;
343                 self.skin = stof(self.playerskin);
344         }
345
346         if(chmdl || oldskin != self.skin) // model or skin has changed
347         {
348                 self.species = player_getspecies(); // update species
349                 UpdatePlayerSounds(); // update skin sounds
350         }
351
352         if(!teamplay)
353                 if(strlen(autocvar_sv_defaultplayercolors))
354                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
355                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
356 }
357
358 /*
359 =============
360 PutClientInServer
361
362 Called when a client spawns in the server
363 =============
364 */
365 void PutClientInServer (void)
366 {
367         if(IS_BOT_CLIENT(self))
368                 self.classname = "player";
369         else if(IS_REAL_CLIENT(self))
370         {
371                 msg_entity = self;
372                 WriteByte(MSG_ONE, SVC_SETVIEW);
373                 WriteEntity(MSG_ONE, self);
374         }
375
376         // reset player keys
377         self.itemkeys = 0;
378
379         MUTATOR_CALLHOOK(PutClientInServer);
380
381         if(gameover)
382                 self.classname = "observer";
383
384         if(IS_PLAYER(self))
385         {
386                 entity spot, oldself;
387                 float j;
388
389                 accuracy_resend(self);
390
391                 if(self.team < 0)
392                         JoinBestTeam(self, FALSE, TRUE);
393
394                 race_PreSpawn();
395
396                 spot = SelectSpawnPoint (FALSE);
397                 if(!spot)
398                 {
399                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
400                         return; // spawn failed
401                 }
402
403                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
404
405                 if(self.vehicle)
406                         vehicles_exit(VHEF_RELESE);
407
408                 self.classname = "player";
409                 self.wasplayer = TRUE;
410                 self.iscreature = TRUE;
411                 self.teleportable = TELEPORT_NORMAL;
412                 self.damagedbycontents = TRUE;
413                 self.movetype = MOVETYPE_WALK;
414                 self.solid = SOLID_SLIDEBOX;
415                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
416                 if(autocvar_g_playerclip_collisions)
417                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
418                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
419                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
420                 self.frags = FRAGS_PLAYER;
421                 if(INDEPENDENT_PLAYERS)
422                         MAKE_INDEPENDENT_PLAYER(self);
423                 self.flags = FL_CLIENT;
424                 if(autocvar__notarget)
425                         self.flags |= FL_NOTARGET;
426                 self.takedamage = DAMAGE_AIM;
427                 self.effects = 0;
428                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
429                 self.air_finished = time + 12;
430                 self.dmg = 2;
431                 if(autocvar_g_balance_nex_charge)
432                 {
433                         if(autocvar_g_balance_nex_secondary_chargepool)
434                                 self.nex_chargepool_ammo = 1;
435                         self.nex_charge = autocvar_g_balance_nex_charge_start;
436                 }
437
438                 if(warmup_stage)
439                 {
440                         self.ammo_shells = warmup_start_ammo_shells;
441                         self.ammo_nails = warmup_start_ammo_nails;
442                         self.ammo_rockets = warmup_start_ammo_rockets;
443                         self.ammo_cells = warmup_start_ammo_cells;
444                         self.ammo_fuel = warmup_start_ammo_fuel;
445                         self.health = warmup_start_health;
446                         self.armorvalue = warmup_start_armorvalue;
447                         self.weapons = WARMUP_START_WEAPONS;
448                 }
449                 else
450                 {
451                         self.ammo_shells = start_ammo_shells;
452                         self.ammo_nails = start_ammo_nails;
453                         self.ammo_rockets = start_ammo_rockets;
454                         self.ammo_cells = start_ammo_cells;
455                         self.ammo_fuel = start_ammo_fuel;
456                         self.health = start_health;
457                         self.armorvalue = start_armorvalue;
458                         self.weapons = start_weapons;
459                 }
460
461                 if(self.weapons & WEPSET_SUPERWEAPONS)
462                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
463                 else
464                         self.superweapons_finished = 0;
465
466                 if(g_weaponarena_random)
467                 {
468                         if(g_weaponarena_random_with_laser)
469                                 self.weapons &= ~WEPSET_LASER;
470                         W_RandomWeapons(self, g_weaponarena_random);
471                         if(g_weaponarena_random_with_laser)
472                                 self.weapons |= WEPSET_LASER;
473                 }
474
475                 self.items = start_items;
476
477                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
478                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
479                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
480                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
481                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
482                 //extend the pause of rotting if client was reset at the beginning of the countdown
483                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
484                         self.spawnshieldtime += game_starttime - time;
485                         self.pauserotarmor_finished += game_starttime - time;
486                         self.pauserothealth_finished += game_starttime - time;
487                         self.pauseregen_finished += game_starttime - time;
488                 }
489                 self.damageforcescale = 2;
490                 self.death_time = 0;
491                 self.respawn_flags = 0;
492                 self.respawn_time = 0;
493                 self.stat_respawn_time = 0;
494                 self.scale = 0;
495                 self.fade_time = 0;
496                 self.pain_frame = 0;
497                 self.pain_finished = 0;
498                 self.strength_finished = 0;
499                 self.invincible_finished = 0;
500                 self.pushltime = 0;
501                 // players have no think function
502                 self.think = func_null;
503                 self.nextthink = 0;
504                 self.hook_time = 0;
505                 self.dmg_team = 0;
506                 self.ballistics_density = autocvar_g_ballistics_density_player;
507
508                 self.metertime = 0;
509
510                 self.deadflag = DEAD_NO;
511
512                 self.angles = spot.angles;
513
514                 self.angles_z = 0; // never spawn tilted even if the spot says to
515                 self.fixangle = TRUE; // turn this way immediately
516                 self.velocity = '0 0 0';
517                 self.avelocity = '0 0 0';
518                 self.punchangle = '0 0 0';
519                 self.punchvector = '0 0 0';
520                 self.oldvelocity = self.velocity;
521                 self.fire_endtime = -1;
522
523                 entity spawnevent = spawn();
524                 spawnevent.owner = self;
525                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
526
527                 // Cut off any still running player sounds.
528                 stopsound(self, CH_PLAYER_SINGLE);
529
530                 self.model = "";
531                 FixPlayermodel();
532                 self.drawonlytoclient = world;
533
534                 self.crouch = FALSE;
535                 self.view_ofs = PL_VIEW_OFS;
536                 setsize (self, PL_MIN, PL_MAX);
537                 self.spawnorigin = spot.origin;
538                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
539                 // don't reset back to last position, even if new position is stuck in solid
540                 self.oldorigin = self.origin;
541                 self.prevorigin = self.origin;
542                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
543                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
544         self.hud = HUD_NORMAL;
545
546                 self.event_damage = PlayerDamage;
547
548                 self.bot_attack = TRUE;
549                 self.monster_attack = TRUE;
550                 
551                 self.spider_slowness = 0;
552
553                 self.statdraintime = time + 5;
554                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
555
556                 if(self.killcount == -666) {
557                         PlayerScore_Clear(self);
558                         self.killcount = 0;
559                 }
560
561                 CL_SpawnWeaponentity();
562                 self.alpha = default_player_alpha;
563                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
564                 self.exteriorweaponentity.alpha = default_weapon_alpha;
565
566                 self.speedrunning = FALSE;
567
568                 race_PostSpawn(spot);
569
570                 //stuffcmd(self, "chase_active 0");
571                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
572
573                 target_voicescript_clear(self);
574
575                 // reset fields the weapons may use
576                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
577                 {
578                         weapon_action(j, WR_RESETPLAYER);
579
580                         // all weapons must be fully loaded when we spawn
581                         entity e;
582                         e = get_weaponinfo(j);
583                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
584                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
585                 }
586
587                 oldself = self;
588                 self = spot;
589                         activator = oldself;
590                                 string s;
591                                 s = self.target;
592                                 self.target = string_null;
593                                 SUB_UseTargets();
594                                 self.target = s;
595                         activator = world;
596                 self = oldself;
597
598                 spawn_spot = spot;
599                 MUTATOR_CALLHOOK(PlayerSpawn);
600
601                 if(autocvar_spawn_debug)
602                 {
603                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
604                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
605                 }
606
607                 self.switchweapon = w_getbestweapon(self);
608                 self.cnt = -1; // W_LastWeapon will not complain
609                 self.weapon = 0;
610                 self.weaponname = "";
611                 self.switchingweapon = 0;
612
613                 if(!warmup_stage)
614                         if(!self.alivetime)
615                                 self.alivetime = time;
616
617                 antilag_clear(self);
618         }
619         else if(IS_OBSERVER(self))
620         {
621                 PutObserverInServer ();
622         }
623 }
624
625 .float ebouncefactor, ebouncestop; // electro's values
626 // TODO do we need all these fields, or should we stop autodetecting runtime
627 // changes and just have a console command to update this?
628 float ClientInit_SendEntity(entity to, float sf)
629 {
630         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
631         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
640         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
641         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
642         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
643         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
644         if(sv_foginterval && world.fog != "")
645                 WriteString(MSG_ENTITY, world.fog);
646         else
647                 WriteString(MSG_ENTITY, "");
648         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
649         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
650         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
651         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
652         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
653         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
654         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
655         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
656         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
657         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
658         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
659         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
660         return TRUE;
661 }
662
663 void ClientInit_CheckUpdate()
664 {
665         self.nextthink = time;
666         if(self.count != autocvar_g_balance_armor_blockpercent)
667         {
668                 self.count = autocvar_g_balance_armor_blockpercent;
669                 self.SendFlags |= 1;
670         }
671         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
672         {
673                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
674                 self.SendFlags |= 1;
675         }
676         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
677         {
678                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
679                 self.SendFlags |= 1;
680         }
681         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
682         {
683                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
684                 self.SendFlags |= 1;
685         }
686         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
687         {
688                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
689                 self.SendFlags |= 1;
690         }
691 }
692
693 void ClientInit_Spawn()
694 {
695         entity o;
696         entity e;
697         e = spawn();
698         e.classname = "clientinit";
699         e.think = ClientInit_CheckUpdate;
700         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
701
702         o = self;
703         self = e;
704         ClientInit_CheckUpdate();
705         self = o;
706 }
707
708 /*
709 =============
710 SetNewParms
711 =============
712 */
713 void SetNewParms (void)
714 {
715         // initialize parms for a new player
716         parm1 = -(86400 * 366);
717 }
718
719 /*
720 =============
721 SetChangeParms
722 =============
723 */
724 void SetChangeParms (void)
725 {
726         // save parms for level change
727         parm1 = self.parm_idlesince - time;
728 }
729
730 /*
731 =============
732 DecodeLevelParms
733 =============
734 */
735 void DecodeLevelParms (void)
736 {
737         // load parms
738         self.parm_idlesince = parm1;
739         if(self.parm_idlesince == -(86400 * 366))
740                 self.parm_idlesince = time;
741
742         // whatever happens, allow 60 seconds of idling directly after connect for map loading
743         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
744 }
745
746 /*
747 =============
748 ClientKill
749
750 Called when a client types 'kill' in the console
751 =============
752 */
753
754 .float clientkill_nexttime;
755 void ClientKill_Now_TeamChange()
756 {
757         if(self.killindicator_teamchange == -1)
758         {
759                 JoinBestTeam( self, FALSE, TRUE );
760         }
761         else if(self.killindicator_teamchange == -2)
762         {
763                 if(blockSpectators)
764                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
765                 PutObserverInServer();
766         }
767         else
768                 SV_ChangeTeam(self.killindicator_teamchange - 1);
769         self.killindicator_teamchange = 0;
770 }
771
772 void ClientKill_Now()
773 {
774         if(self.vehicle)
775         {
776             vehicles_exit(VHEF_RELESE);
777             if(!self.killindicator_teamchange)
778             {
779             self.vehicle_health = -1;
780             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
781             }
782         }
783
784         if(self.killindicator && !wasfreed(self.killindicator))
785                 remove(self.killindicator);
786
787         self.killindicator = world;
788
789         if(self.killindicator_teamchange)
790                 ClientKill_Now_TeamChange();
791
792         // in any case:
793         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
794
795         // now I am sure the player IS dead
796 }
797 void KillIndicator_Think()
798 {
799         if (gameover)
800         {
801                 self.owner.killindicator = world;
802                 remove(self);
803                 return;
804         }
805
806         if (self.owner.alpha < 0 && !self.owner.vehicle)
807         {
808                 self.owner.killindicator = world;
809                 remove(self);
810                 return;
811         }
812
813         if(self.cnt <= 0)
814         {
815                 self = self.owner;
816                 ClientKill_Now(); // no oldself needed
817                 return;
818         }
819     else if(g_cts && self.health == 1) // health == 1 means that it's silent
820     {
821         self.nextthink = time + 1;
822         self.cnt -= 1;
823     }
824         else
825         {
826                 if(self.cnt <= 10)
827                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
828                 if(IS_REAL_CLIENT(self.owner))
829                 {
830                         if(self.cnt <= 10)
831                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
832                 }
833                 self.nextthink = time + 1;
834                 self.cnt -= 1;
835         }
836 }
837
838 float clientkilltime;
839 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
840 {
841         float killtime;
842         float starttime;
843         entity e;
844
845         if (gameover)
846                 return;
847
848         killtime = autocvar_g_balance_kill_delay;
849
850         if(g_race_qualifying || g_cts)
851                 killtime = 0;
852
853     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
854     {
855                 remove(self.killindicator);
856                 self.killindicator = world;
857
858         ClientKill_Now(); // allow instant kill in this case
859         return;
860     }
861
862         self.killindicator_teamchange = targetteam;
863
864     if(!self.killindicator)
865         {
866                 if(self.deadflag == DEAD_NO)
867                 {
868                         killtime = max(killtime, self.clientkill_nexttime - time);
869                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
870                 }
871
872                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
873                 {
874                         ClientKill_Now();
875                 }
876                 else
877                 {
878                         starttime = max(time, clientkilltime);
879
880                         self.killindicator = spawn();
881                         self.killindicator.owner = self;
882                         self.killindicator.scale = 0.5;
883                         setattachment(self.killindicator, self, "");
884                         setorigin(self.killindicator, '0 0 52');
885                         self.killindicator.think = KillIndicator_Think;
886                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
887                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
888                         self.killindicator.cnt = ceil(killtime);
889                         self.killindicator.count = bound(0, ceil(killtime), 10);
890                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
891
892                         for(e = world; (e = find(e, classname, "body")) != world; )
893                         {
894                                 if(e.enemy != self)
895                                         continue;
896                                 e.killindicator = spawn();
897                                 e.killindicator.owner = e;
898                                 e.killindicator.scale = 0.5;
899                                 setattachment(e.killindicator, e, "");
900                                 setorigin(e.killindicator, '0 0 52');
901                                 e.killindicator.think = KillIndicator_Think;
902                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
903                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
904                                 e.killindicator.cnt = ceil(killtime);
905                         }
906                         self.lip = 0;
907                 }
908         }
909         if(self.killindicator)
910         {
911                 if(targetteam == 0) // just die
912                 {
913                         self.killindicator.colormod = '0 0 0';
914                         if(IS_REAL_CLIENT(self))
915                         if(self.killindicator.cnt > 0)
916                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
917                 }
918                 else if(targetteam == -1) // auto
919                 {
920                         self.killindicator.colormod = '0 1 0';
921                         if(IS_REAL_CLIENT(self))
922                         if(self.killindicator.cnt > 0)
923                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
924                 }
925                 else if(targetteam == -2) // spectate
926                 {
927                         self.killindicator.colormod = '0.5 0.5 0.5';
928                         if(IS_REAL_CLIENT(self))
929                         if(self.killindicator.cnt > 0)
930                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
931                 }
932                 else
933                 {
934                         self.killindicator.colormod = Team_ColorRGB(targetteam);
935                         if(IS_REAL_CLIENT(self))
936                         if(self.killindicator.cnt > 0)
937                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
938                 }
939         }
940
941 }
942
943 void ClientKill (void)
944 {
945         if(gameover) return;
946         if(self.player_blocked) return;
947         if(self.freezetag_frozen) return;
948
949         ClientKill_TeamChange(0);
950 }
951
952 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
953 {
954     e.killindicator = spawn();
955     e.killindicator.owner = e;
956     e.killindicator.think = KillIndicator_Think;
957     e.killindicator.nextthink = time + (e.lip) * 0.05;
958     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
959     e.killindicator.health = 1; // this is used to indicate that it should be silent
960     e.lip = 0;
961 }
962
963 void FixClientCvars(entity e)
964 {
965         // send prediction settings to the client
966         stuffcmd(e, "\nin_bindmap 0 0\n");
967         if(g_race || g_cts)
968                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
969         if(autocvar_g_antilag == 3) // client side hitscan
970                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
971         if(autocvar_sv_gentle)
972                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
973         /*
974          * we no longer need to stuff this. Remove this comment block if you feel
975          * 2.3 and higher (or was it 2.2.3?) don't need these any more
976         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
977         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
978         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
979         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
980         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
981         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
982         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
983         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
984         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
985         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
986         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
987         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
988         stuffcmd(e, "cl_movement_edgefriction 1\n");
989          */
990 }
991
992 float PlayerInIDList(entity p, string idlist)
993 {
994         float n, i;
995         string s;
996
997         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
998         if (!p.crypto_idfp)
999                 return 0;
1000
1001         // this function allows abbreviated player IDs too!
1002         n = tokenize_console(idlist);
1003         for(i = 0; i < n; ++i)
1004         {
1005                 s = argv(i);
1006                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1007                         return 1;
1008         }
1009
1010         return 0;
1011 }
1012
1013 /*
1014 =============
1015 ClientConnect
1016
1017 Called when a client connects to the server
1018 =============
1019 */
1020 void DecodeLevelParms (void);
1021 //void dom_player_join_team(entity pl);
1022 void set_dom_state(entity e);
1023 void ClientConnect (void)
1024 {
1025         float t;
1026
1027         if(IS_CLIENT(self))
1028         {
1029                 print("Warning: ClientConnect, but already connected!\n");
1030                 return;
1031         }
1032
1033         if(Ban_MaybeEnforceBanOnce(self))
1034                 return;
1035
1036         DecodeLevelParms();
1037
1038 #ifdef WATERMARK
1039         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1040 #endif
1041
1042         self.classname = "player_joining";
1043
1044         self.flags = FL_CLIENT;
1045         self.version_nagtime = time + 10 + random() * 10;
1046
1047         if(player_count<0)
1048         {
1049                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1050                 player_count = 0;
1051         }
1052
1053         PlayerScore_Attach(self);
1054         ClientData_Attach();
1055         accuracy_init(self);
1056
1057         bot_clientconnect();
1058
1059         playerdemo_init();
1060
1061         anticheat_init();
1062
1063         race_PreSpawnObserver();
1064
1065         // identify the right forced team
1066         if(autocvar_g_campaign)
1067         {
1068                 if(IS_REAL_CLIENT(self)) // only players, not bots
1069                 {
1070                         switch(autocvar_g_campaign_forceteam)
1071                         {
1072                                 case 1: self.team_forced = NUM_TEAM_1; break;
1073                                 case 2: self.team_forced = NUM_TEAM_2; break;
1074                                 case 3: self.team_forced = NUM_TEAM_3; break;
1075                                 case 4: self.team_forced = NUM_TEAM_4; break;
1076                                 default: self.team_forced = 0;
1077                         }
1078                 }
1079         }
1080         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1081                 self.team_forced = NUM_TEAM_1;
1082         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1083                 self.team_forced = NUM_TEAM_2;
1084         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1085                 self.team_forced = NUM_TEAM_3;
1086         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1087                 self.team_forced = NUM_TEAM_4;
1088         else if(autocvar_g_forced_team_otherwise == "red")
1089                 self.team_forced = NUM_TEAM_1;
1090         else if(autocvar_g_forced_team_otherwise == "blue")
1091                 self.team_forced = NUM_TEAM_2;
1092         else if(autocvar_g_forced_team_otherwise == "yellow")
1093                 self.team_forced = NUM_TEAM_3;
1094         else if(autocvar_g_forced_team_otherwise == "pink")
1095                 self.team_forced = NUM_TEAM_4;
1096         else if(autocvar_g_forced_team_otherwise == "spectate")
1097                 self.team_forced = -1;
1098         else if(autocvar_g_forced_team_otherwise == "spectator")
1099                 self.team_forced = -1;
1100         else
1101                 self.team_forced = 0;
1102
1103         if(!teamplay)
1104                 if(self.team_forced > 0)
1105                         self.team_forced = 0;
1106
1107         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1108
1109         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1110                 self.classname = "observer";
1111         } else {
1112                 if(teamplay)
1113                 {
1114                         if(autocvar_g_balance_teams)
1115                         {
1116                                 self.classname = "player";
1117                                 campaign_bots_may_start = 1;
1118                         }
1119                         else
1120                         {
1121                                 self.classname = "observer"; // do it anyway
1122                         }
1123                 }
1124                 else
1125                 {
1126                         self.classname = "player";
1127                         campaign_bots_may_start = 1;
1128                 }
1129         }
1130
1131         self.playerid = (playerid_last = playerid_last + 1);
1132
1133         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1134
1135     if(IS_BOT_CLIENT(self))
1136         PlayerStats_AddPlayer(self);
1137
1138         if(autocvar_sv_eventlog)
1139                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1140
1141         LogTeamchange(self.playerid, self.team, 1);
1142
1143         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1144
1145         self.netname_previous = strzone(self.netname);
1146
1147         if(IS_PLAYER(self) && teamplay)
1148                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1149         else
1150                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1151
1152         stuffcmd(self, strcat(clientstuff, "\n"));
1153         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1154
1155         FixClientCvars(self);
1156
1157         // spawnfunc_waypoint sprites
1158         WaypointSprite_InitClient(self);
1159
1160         // Wazat's grappling hook
1161         SetGrappleHookBindings();
1162
1163         // get version info from player
1164         stuffcmd(self, "cmd clientversion $gameversion\n");
1165
1166         // get other cvars from player
1167         GetCvars(0);
1168
1169         // notify about available teams
1170         if(teamplay)
1171         {
1172                 CheckAllowedTeams(self);
1173                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1174                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1175         }
1176         else
1177                 stuffcmd(self, "set _teams_available 0\n");
1178
1179         attach_entcs();
1180
1181         bot_relinkplayerlist();
1182
1183         self.spectatortime = time;
1184         if(blockSpectators)
1185         {
1186                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1187         }
1188
1189         self.jointime = time;
1190         self.allowed_timeouts = autocvar_sv_timeout_number;
1191
1192         if(IS_REAL_CLIENT(self))
1193         {
1194                 if(!autocvar_g_campaign)
1195                 {
1196                         self.motd_actived_time = -1;
1197                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1198                 }
1199
1200                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1201                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1202         }
1203
1204         if(!sv_foginterval && world.fog != "")
1205                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1206
1207         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1208         {
1209                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1210                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1211         }
1212         else
1213                 self.hitplotfh = -1;
1214
1215         if(g_race || g_cts) {
1216                 string rr;
1217                 if(g_cts)
1218                         rr = CTS_RECORD;
1219                 else
1220                         rr = RACE_RECORD;
1221
1222                 msg_entity = self;
1223                 race_send_recordtime(MSG_ONE);
1224                 race_send_speedaward(MSG_ONE);
1225
1226                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1227                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1228                 race_send_speedaward_alltimebest(MSG_ONE);
1229
1230                 float i;
1231                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1232                         race_SendRankings(i, 0, 0, MSG_ONE);
1233                 }
1234         }
1235         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1236                 send_CSQC_teamnagger();
1237
1238         CheatInitClient();
1239
1240         CSQCMODEL_AUTOINIT();
1241
1242         self.model_randomizer = random();
1243
1244         if(IS_REAL_CLIENT(self))
1245                 sv_notice_join();
1246
1247         MUTATOR_CALLHOOK(ClientConnect);
1248 }
1249 /*
1250 =============
1251 ClientDisconnect
1252
1253 Called when a client disconnects from the server
1254 =============
1255 */
1256 .entity chatbubbleentity;
1257 void ReadyCount();
1258 void ClientDisconnect (void)
1259 {
1260         if(self.vehicle)
1261             vehicles_exit(VHEF_RELESE);
1262
1263         if (!IS_CLIENT(self))
1264         {
1265                 print("Warning: ClientDisconnect without ClientConnect\n");
1266                 return;
1267         }
1268
1269         PlayerStats_AddGlobalInfo(self);
1270
1271         CheatShutdownClient();
1272
1273         if(self.hitplotfh >= 0)
1274         {
1275                 fclose(self.hitplotfh);
1276                 self.hitplotfh = -1;
1277         }
1278
1279         anticheat_report();
1280         anticheat_shutdown();
1281
1282         playerdemo_shutdown();
1283
1284         bot_clientdisconnect();
1285
1286         if(self.entcs)
1287                 detach_entcs();
1288
1289         if(autocvar_sv_eventlog)
1290                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1291
1292         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1293
1294         MUTATOR_CALLHOOK(ClientDisconnect);
1295
1296         Portal_ClearAll(self);
1297
1298         RemoveGrapplingHook(self);
1299
1300         // Here, everything has been done that requires this player to be a client.
1301
1302         self.flags &= ~FL_CLIENT;
1303
1304         if (self.chatbubbleentity)
1305                 remove (self.chatbubbleentity);
1306
1307         if (self.killindicator)
1308                 remove (self.killindicator);
1309
1310         WaypointSprite_PlayerGone();
1311
1312         bot_relinkplayerlist();
1313
1314         accuracy_free(self);
1315         ClientData_Detach();
1316         PlayerScore_Detach(self);
1317
1318         if(self.netname_previous)
1319                 strunzone(self.netname_previous);
1320         if(self.clientstatus)
1321                 strunzone(self.clientstatus);
1322         if(self.weaponorder_byimpulse)
1323                 strunzone(self.weaponorder_byimpulse);
1324
1325         ClearPlayerSounds();
1326
1327         if(self.personal)
1328                 remove(self.personal);
1329
1330         self.playerid = 0;
1331         ReadyCount();
1332
1333         // free cvars
1334         GetCvars(-1);
1335 }
1336
1337 .float BUTTON_CHAT;
1338 void ChatBubbleThink()
1339 {
1340         self.nextthink = time;
1341         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1342         {
1343                 if(self.owner) // but why can that ever be world?
1344                         self.owner.chatbubbleentity = world;
1345                 remove(self);
1346                 return;
1347         }
1348         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1349 #ifdef TETRIS
1350                 || self.owner.tetris_on
1351 #endif
1352         )
1353                 self.model = self.mdl;
1354         else
1355                 self.model = "";
1356 }
1357
1358 void UpdateChatBubble()
1359 {
1360         if (self.alpha < 0)
1361                 return;
1362         // spawn a chatbubble entity if needed
1363         if (!self.chatbubbleentity)
1364         {
1365                 self.chatbubbleentity = spawn();
1366                 self.chatbubbleentity.owner = self;
1367                 self.chatbubbleentity.exteriormodeltoclient = self;
1368                 self.chatbubbleentity.think = ChatBubbleThink;
1369                 self.chatbubbleentity.nextthink = time;
1370                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1371                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1372                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1373                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1374                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1375                 self.chatbubbleentity.model = "";
1376                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1377         }
1378 }
1379
1380
1381 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1382 // added to the model skins
1383 /*void UpdateColorModHack()
1384 {
1385         float c;
1386         c = self.clientcolors & 15;
1387         // LordHavoc: only bothering to support white, green, red, yellow, blue
1388              if (!teamplay) self.colormod = '0 0 0';
1389         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1390         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1391         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1392         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1393         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1394         else self.colormod = '1 1 1';
1395 }*/
1396
1397 void respawn(void)
1398 {
1399         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1400         {
1401                 self.solid = SOLID_NOT;
1402                 self.takedamage = DAMAGE_NO;
1403                 self.movetype = MOVETYPE_FLY;
1404                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1405                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1406                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1407                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1408                 if(autocvar_g_respawn_ghosts_maxtime)
1409                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1410         }
1411
1412         CopyBody(1);
1413
1414         self.effects |= EF_NODRAW; // prevent another CopyBody
1415         PutClientInServer();
1416 }
1417
1418 void play_countdown(float finished, string samp)
1419 {
1420         if(IS_REAL_CLIENT(self))
1421                 if(floor(finished - time - frametime) != floor(finished - time))
1422                         if(finished - time < 6)
1423                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1424 }
1425
1426 void player_powerups (void)
1427 {
1428         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1429         olditems = self.items;
1430
1431         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1432                 self.modelflags |= MF_ROCKET;
1433         else
1434                 self.modelflags &= ~MF_ROCKET;
1435
1436         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1437
1438         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1439                 return;
1440
1441         Fire_ApplyDamage(self);
1442         Fire_ApplyEffect(self);
1443
1444         if (!g_minstagib)
1445         {
1446                 if (self.items & IT_STRENGTH)
1447                 {
1448                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1449                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1450                         if (time > self.strength_finished)
1451                         {
1452                                 self.items = self.items - (self.items & IT_STRENGTH);
1453                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1454                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1455                         }
1456                 }
1457                 else
1458                 {
1459                         if (time < self.strength_finished)
1460                         {
1461                                 self.items = self.items | IT_STRENGTH;
1462                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1463                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1464                         }
1465                 }
1466                 if (self.items & IT_INVINCIBLE)
1467                 {
1468                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1469                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1470                         if (time > self.invincible_finished)
1471                         {
1472                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1473                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1474                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1475                         }
1476                 }
1477                 else
1478                 {
1479                         if (time < self.invincible_finished)
1480                         {
1481                                 self.items = self.items | IT_INVINCIBLE;
1482                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1483                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1484                         }
1485                 }
1486                 if (self.items & IT_SUPERWEAPON)
1487                 {
1488                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1489                         {
1490                                 self.superweapons_finished = 0;
1491                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1492                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1493                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1494                         }
1495                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1496                         {
1497                                 // don't let them run out
1498                         }
1499                         else
1500                         {
1501                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1502                                 if (time > self.superweapons_finished)
1503                                 {
1504                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1505                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1506                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1507                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1508                                 }
1509                         }
1510                 }
1511                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1512                 {
1513                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1514                         {
1515                                 self.items = self.items | IT_SUPERWEAPON;
1516                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1517                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1518                         }
1519                         else
1520                         {
1521                                 self.superweapons_finished = 0;
1522                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1523                         }
1524                 }
1525                 else
1526                 {
1527                         self.superweapons_finished = 0;
1528                 }
1529         }
1530
1531         if(autocvar_g_nodepthtestplayers)
1532                 self.effects = self.effects | EF_NODEPTHTEST;
1533
1534         if(autocvar_g_fullbrightplayers)
1535                 self.effects = self.effects | EF_FULLBRIGHT;
1536
1537         if (time >= game_starttime)
1538         if (time < self.spawnshieldtime)
1539                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1540
1541         MUTATOR_CALLHOOK(PlayerPowerups);
1542 }
1543
1544 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1545 {
1546         if(current > stable)
1547                 return current;
1548         else if(current > stable - 0.25) // when close enough, "snap"
1549                 return stable;
1550         else
1551                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1552 }
1553
1554 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1555 {
1556         if(current < stable)
1557                 return current;
1558         else if(current < stable + 0.25) // when close enough, "snap"
1559                 return stable;
1560         else
1561                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1562 }
1563
1564 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1565 {
1566         if(current > rotstable)
1567         {
1568                 if(rotframetime > 0)
1569                 {
1570                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1571                         current = max(rotstable, current - rotlinear * rotframetime);
1572                 }
1573         }
1574         else if(current < regenstable)
1575         {
1576                 if(regenframetime > 0)
1577                 {
1578                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1579                         current = min(regenstable, current + regenlinear * regenframetime);
1580                 }
1581         }
1582
1583         if(current > limit)
1584                 current = limit;
1585
1586         return current;
1587 }
1588
1589 void player_regen (void)
1590 {
1591         float max_mod, regen_mod, rot_mod, limit_mod;
1592         max_mod = regen_mod = rot_mod = limit_mod = 1;
1593         regen_mod_max = max_mod;
1594         regen_mod_regen = regen_mod;
1595         regen_mod_rot = rot_mod;
1596         regen_mod_limit = limit_mod;
1597         if(!MUTATOR_CALLHOOK(PlayerRegen))
1598         {
1599                 float minh, mina, maxh, maxa, limith, limita;
1600                 maxh = autocvar_g_balance_health_rotstable;
1601                 maxa = autocvar_g_balance_armor_rotstable;
1602                 minh = autocvar_g_balance_health_regenstable;
1603                 mina = autocvar_g_balance_armor_regenstable;
1604                 limith = autocvar_g_balance_health_limit;
1605                 limita = autocvar_g_balance_armor_limit;
1606                 
1607                 max_mod = regen_mod_max;
1608                 regen_mod = regen_mod_regen;
1609                 rot_mod = regen_mod_rot;
1610                 limit_mod = regen_mod_limit;
1611
1612                 maxh = maxh * max_mod;
1613                 minh = minh * max_mod;
1614                 limith = limith * limit_mod;
1615                 limita = limita * limit_mod;
1616
1617                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1618                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1619         }
1620
1621         // if player rotted to death...  die!
1622         // check this outside above checks, as player may still be able to rot to death
1623         if(self.health < 1)
1624                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1625
1626         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1627         {
1628                 float minf, maxf, limitf;
1629
1630                 maxf = autocvar_g_balance_fuel_rotstable;
1631                 minf = autocvar_g_balance_fuel_regenstable;
1632                 limitf = autocvar_g_balance_fuel_limit;
1633
1634                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1635         }
1636 }
1637
1638 float zoomstate_set;
1639 void SetZoomState(float z)
1640 {
1641         if(z != self.zoomstate)
1642         {
1643                 self.zoomstate = z;
1644                 ClientData_Touch(self);
1645         }
1646         zoomstate_set = 1;
1647 }
1648
1649 void GetPressedKeys(void) {
1650         MUTATOR_CALLHOOK(GetPressedKeys);
1651         if (self.movement_x > 0) // get if movement keys are pressed
1652         {       // forward key pressed
1653                 self.pressedkeys |= KEY_FORWARD;
1654                 self.pressedkeys &= ~KEY_BACKWARD;
1655         }
1656         else if (self.movement_x < 0)
1657         {       // backward key pressed
1658                 self.pressedkeys |= KEY_BACKWARD;
1659                 self.pressedkeys &= ~KEY_FORWARD;
1660         }
1661         else
1662         {       // no x input
1663                 self.pressedkeys &= ~KEY_FORWARD;
1664                 self.pressedkeys &= ~KEY_BACKWARD;
1665         }
1666
1667         if (self.movement_y > 0)
1668         {       // right key pressed
1669                 self.pressedkeys |= KEY_RIGHT;
1670                 self.pressedkeys &= ~KEY_LEFT;
1671         }
1672         else if (self.movement_y < 0)
1673         {       // left key pressed
1674                 self.pressedkeys |= KEY_LEFT;
1675                 self.pressedkeys &= ~KEY_RIGHT;
1676         }
1677         else
1678         {       // no y input
1679                 self.pressedkeys &= ~KEY_RIGHT;
1680                 self.pressedkeys &= ~KEY_LEFT;
1681         }
1682
1683         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1684                 self.pressedkeys |= KEY_JUMP;
1685         else
1686                 self.pressedkeys &= ~KEY_JUMP;
1687         if (self.BUTTON_CROUCH)
1688                 self.pressedkeys |= KEY_CROUCH;
1689         else
1690                 self.pressedkeys &= ~KEY_CROUCH;
1691
1692         if (self.BUTTON_ATCK)
1693                 self.pressedkeys |= KEY_ATCK;
1694         else
1695                 self.pressedkeys &= ~KEY_ATCK;
1696         if (self.BUTTON_ATCK2)
1697                 self.pressedkeys |= KEY_ATCK2;
1698         else
1699                 self.pressedkeys &= ~KEY_ATCK2;
1700 }
1701
1702 /*
1703 ======================
1704 spectate mode routines
1705 ======================
1706 */
1707
1708 void SpectateCopy(entity spectatee) {
1709         other = spectatee;
1710         MUTATOR_CALLHOOK(SpectateCopy);
1711         self.armortype = spectatee.armortype;
1712         self.armorvalue = spectatee.armorvalue;
1713         self.ammo_cells = spectatee.ammo_cells;
1714         self.ammo_shells = spectatee.ammo_shells;
1715         self.ammo_nails = spectatee.ammo_nails;
1716         self.ammo_rockets = spectatee.ammo_rockets;
1717         self.ammo_fuel = spectatee.ammo_fuel;
1718         self.clip_load = spectatee.clip_load;
1719         self.clip_size = spectatee.clip_size;
1720         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1721         self.health = spectatee.health;
1722         self.impulse = 0;
1723         self.items = spectatee.items;
1724         self.last_pickup = spectatee.last_pickup;
1725         self.hit_time = spectatee.hit_time;
1726         self.metertime = spectatee.metertime;
1727         self.strength_finished = spectatee.strength_finished;
1728         self.invincible_finished = spectatee.invincible_finished;
1729         self.pressedkeys = spectatee.pressedkeys;
1730         self.weapons = spectatee.weapons;
1731         self.switchweapon = spectatee.switchweapon;
1732         self.switchingweapon = spectatee.switchingweapon;
1733         self.weapon = spectatee.weapon;
1734         self.nex_charge = spectatee.nex_charge;
1735         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1736         self.hagar_load = spectatee.hagar_load;
1737         self.minelayer_mines = spectatee.minelayer_mines;
1738         self.punchangle = spectatee.punchangle;
1739         self.view_ofs = spectatee.view_ofs;
1740         self.velocity = spectatee.velocity;
1741         self.dmg_take = spectatee.dmg_take;
1742         self.dmg_save = spectatee.dmg_save;
1743         self.dmg_inflictor = spectatee.dmg_inflictor;
1744         self.v_angle = spectatee.v_angle;
1745         self.angles = spectatee.v_angle;
1746         if(!self.BUTTON_USE)
1747                 self.fixangle = TRUE;
1748         setorigin(self, spectatee.origin);
1749         setsize(self, spectatee.mins, spectatee.maxs);
1750         SetZoomState(spectatee.zoomstate);
1751
1752     anticheat_spectatecopy(spectatee);
1753         self.hud = spectatee.hud;
1754         if(spectatee.vehicle)
1755     {
1756         self.fixangle = FALSE;
1757         //self.velocity = spectatee.vehicle.velocity;
1758         self.vehicle_health = spectatee.vehicle_health;
1759         self.vehicle_shield = spectatee.vehicle_shield;
1760         self.vehicle_energy = spectatee.vehicle_energy;
1761         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1762         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1763         self.vehicle_reload1 = spectatee.vehicle_reload1;
1764         self.vehicle_reload2 = spectatee.vehicle_reload2;
1765
1766         msg_entity = self;
1767
1768         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1770             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1771             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1772
1773         //WriteByte (MSG_ONE, SVC_SETVIEW);
1774         //    WriteEntity(MSG_ONE, self);
1775         //makevectors(spectatee.v_angle);
1776         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1777     }
1778 }
1779
1780 float SpectateUpdate() {
1781         if(!self.enemy)
1782             return 0;
1783
1784         if (self == self.enemy)
1785                 return 0;
1786
1787         if (!IS_PLAYER(self.enemy))
1788                 return 0;
1789
1790         SpectateCopy(self.enemy);
1791
1792         return 1;
1793 }
1794
1795
1796 float SpectateSet()
1797 {
1798         if(self.enemy.classname != "player")
1799                 return FALSE;
1800         /*if(self.enemy.vehicle)
1801         {
1802
1803                 msg_entity = self;
1804                 WriteByte(MSG_ONE, SVC_SETVIEW);
1805                 WriteEntity(MSG_ONE, self.enemy);
1806                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1807
1808                 self.movetype = MOVETYPE_NONE;
1809                 accuracy_resend(self);
1810         }
1811         else
1812         {*/
1813                 msg_entity = self;
1814                 WriteByte(MSG_ONE, SVC_SETVIEW);
1815                 WriteEntity(MSG_ONE, self.enemy);
1816                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1817                 self.movetype = MOVETYPE_NONE;
1818                 accuracy_resend(self);
1819
1820                 if(!SpectateUpdate())
1821                         PutObserverInServer();
1822         //}
1823         return TRUE;
1824 }
1825
1826 float Spectate(entity pl)
1827 {
1828         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1829         if(pl.team != self.team)
1830                 return 0;
1831
1832         self.enemy = pl;
1833         return SpectateSet();
1834 }
1835
1836 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1837 entity CA_SpectateNext(entity start) {
1838         if (start.team == self.team) {
1839                 return start;
1840         }
1841
1842         other = start;
1843         // continue from current player
1844         while(other && other.team != self.team) {
1845                 other = find(other, classname, "player");
1846         }
1847
1848         if (!other) {
1849                 // restart from begining
1850                 other = find(other, classname, "player");
1851                 while(other && other.team != self.team) {
1852                         other = find(other, classname, "player");
1853                 }
1854         }
1855
1856         return other;
1857 }
1858
1859 float SpectateNext()
1860 {
1861         other = find(self.enemy, classname, "player");
1862
1863         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1864                 // CA and ca players when spectating enemies is forbidden
1865                 other = CA_SpectateNext(other);
1866         } else {
1867                 // other modes and ca spectators or spectating enemies is allowed
1868                 if (!other)
1869                         other = find(other, classname, "player");
1870         }
1871
1872         if (other)
1873                 self.enemy = other;
1874
1875         return SpectateSet();
1876 }
1877
1878 float SpectatePrev()
1879 {
1880         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1881         other = findchain(classname, "player");
1882         if (!other) // no player
1883                 return FALSE;
1884
1885         entity first = other;
1886         // skip players until current spectated player
1887         if(self.enemy)
1888         while(other && other != self.enemy)
1889                 other = other.chain;
1890
1891         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1892         {
1893                 do { other = other.chain; }
1894                 while(other && other.team != self.team);
1895
1896                 if (!other)
1897                 {
1898                         other = first;
1899                         while(other.team != self.team)
1900                                 other = other.chain;
1901                         if(other == self.enemy)
1902                                 return TRUE;
1903                 }
1904         }
1905         else
1906         {
1907                 if(other.chain)
1908                         other = other.chain;
1909                 else
1910                         other = first;
1911         }
1912         self.enemy = other;
1913         return SpectateSet();
1914 }
1915
1916 /*
1917 =============
1918 ShowRespawnCountdown()
1919
1920 Update a respawn countdown display.
1921 =============
1922 */
1923 void ShowRespawnCountdown()
1924 {
1925         float number;
1926         if(self.deadflag == DEAD_NO) // just respawned?
1927                 return;
1928         else
1929         {
1930                 number = ceil(self.respawn_time - time);
1931                 if(number <= 0)
1932                         return;
1933                 if(number <= self.respawn_countdown)
1934                 {
1935                         self.respawn_countdown = number - 1;
1936                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1937                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1938                 }
1939         }
1940 }
1941
1942 void LeaveSpectatorMode()
1943 {
1944         if(self.caplayer)
1945                 return;
1946         if(nJoinAllowed(self))
1947         {
1948                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1949                 {
1950                         self.classname = "player";
1951
1952                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1953                                 { JoinBestTeam(self, FALSE, TRUE); }
1954
1955                         if(autocvar_g_campaign)
1956                                 { campaign_bots_may_start = 1; }
1957
1958                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1959
1960                         PutClientInServer();
1961
1962                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1963                 }
1964                 else
1965                         stuffcmd(self, "menu_showteamselect\n");
1966         }
1967         else
1968         {
1969                 // Player may not join because g_maxplayers is set
1970                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1971         }
1972 }
1973
1974 /**
1975  * Determines whether the player is allowed to join. This depends on cvar
1976  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1977  * it checks whether the number of currently playing players exceeds g_maxplayers.
1978  * @return int number of free slots for players, 0 if none
1979  */
1980 float nJoinAllowed(entity ignore) {
1981         if(!ignore)
1982         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1983         // so report 0 free slots if restricted
1984         {
1985                 if(autocvar_g_forced_team_otherwise == "spectate")
1986                         return 0;
1987                 if(autocvar_g_forced_team_otherwise == "spectator")
1988                         return 0;
1989         }
1990
1991         if(self.team_forced < 0)
1992                 return 0; // forced spectators can never join
1993
1994         // TODO simplify this
1995         entity e;
1996         float totalClients = 0;
1997         FOR_EACH_CLIENT(e)
1998                 if(e != ignore)
1999                         totalClients += 1;
2000
2001         if (!autocvar_g_maxplayers)
2002                 return maxclients - totalClients;
2003
2004         float currentlyPlaying = 0;
2005         FOR_EACH_REALCLIENT(e)
2006                 if(IS_PLAYER(e) || e.caplayer == 1)
2007                         currentlyPlaying += 1;
2008
2009         if(currentlyPlaying < autocvar_g_maxplayers)
2010                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2011
2012         return 0;
2013 }
2014
2015 /**
2016  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2017  * g_maxplayers_spectator_blocktime seconds
2018  */
2019 void checkSpectatorBlock() {
2020         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2021                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2022                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2023                         dropclient(self);
2024                 }
2025         }
2026 }
2027
2028 void PrintWelcomeMessage()
2029 {
2030         if(self.motd_actived_time == 0)
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2034                                 self.motd_actived_time = time;
2035                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2036                         }
2037                 } else {
2038                         if (self.BUTTON_INFO) {
2039                                 self.motd_actived_time = time;
2040                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2041                         }
2042                 }
2043         }
2044         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2045         {
2046                 if (autocvar_g_campaign) {
2047                         if (self.BUTTON_INFO)
2048                                 self.motd_actived_time = time;
2049                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2050                                 self.motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2052                         }
2053                 } else {
2054                         if (self.BUTTON_INFO)
2055                                 self.motd_actived_time = time;
2056                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2057                                 self.motd_actived_time = 0;
2058                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2059                         }
2060                 }
2061         }
2062         else //if(self.motd_actived_time < 0) // just connected, motd is active
2063         {
2064                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2065                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2066                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2067                 {
2068                         // instanctly hide MOTD
2069                         self.motd_actived_time = 0;
2070                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2071                 }
2072         }
2073 }
2074
2075 void ObserverThink()
2076 {
2077         float prefered_movetype;
2078         if (self.flags & FL_JUMPRELEASED) {
2079                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2080                         self.flags &= ~FL_JUMPRELEASED;
2081                         self.flags |= FL_SPAWNING;
2082                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2083                         self.flags &= ~FL_JUMPRELEASED;
2084                         if(SpectateNext()) {
2085                                 self.classname = "spectator";
2086                         }
2087                 } else {
2088                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2089                         if (self.movetype != prefered_movetype)
2090                                 self.movetype = prefered_movetype;
2091                 }
2092         } else {
2093                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2094                         self.flags |= FL_JUMPRELEASED;
2095                         if(self.flags & FL_SPAWNING)
2096                         {
2097                                 self.flags &= ~FL_SPAWNING;
2098                                 LeaveSpectatorMode();
2099                                 return;
2100                         }
2101                 }
2102         }
2103 }
2104
2105 void SpectatorThink()
2106 {
2107         if (self.flags & FL_JUMPRELEASED) {
2108                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         self.flags |= FL_SPAWNING;
2111                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2112                         self.flags &= ~FL_JUMPRELEASED;
2113                         if(SpectateNext()) {
2114                                 self.classname = "spectator";
2115                         } else {
2116                                 self.classname = "observer";
2117                                 PutClientInServer();
2118                         }
2119                         self.impulse = 0;
2120                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2121                         self.flags &= ~FL_JUMPRELEASED;
2122                         if(SpectatePrev()) {
2123                                 self.classname = "spectator";
2124                         } else {
2125                                 self.classname = "observer";
2126                                 PutClientInServer();
2127                         }
2128                         self.impulse = 0;
2129                 } else if (self.BUTTON_ATCK2) {
2130                         self.flags &= ~FL_JUMPRELEASED;
2131                         self.classname = "observer";
2132                         PutClientInServer();
2133                 } else {
2134                         if(!SpectateUpdate())
2135                                 PutObserverInServer();
2136                 }
2137         } else {
2138                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2139                         self.flags |= FL_JUMPRELEASED;
2140                         if(self.flags & FL_SPAWNING)
2141                         {
2142                                 self.flags &= ~FL_SPAWNING;
2143                                 LeaveSpectatorMode();
2144                                 return;
2145                         }
2146                 }
2147                 if(!SpectateUpdate())
2148                         PutObserverInServer();
2149         }
2150
2151         self.flags |= FL_CLIENT | FL_NOTARGET;
2152 }
2153
2154 void PlayerUseKey()
2155 {
2156         if (!IS_PLAYER(self))
2157                 return;
2158
2159         if(self.vehicle)
2160         {
2161         vehicles_exit(VHEF_NORMAL);
2162         return;
2163         }
2164
2165         // a use key was pressed; call handlers
2166         MUTATOR_CALLHOOK(PlayerUseKey);
2167 }
2168
2169 /*
2170 =============
2171 PlayerPreThink
2172
2173 Called every frame for each client before the physics are run
2174 =============
2175 */
2176 .float usekeypressed;
2177 void() nexball_setstatus;
2178 .float items_added;
2179 void PlayerPreThink (void)
2180 {
2181         WarpZone_PlayerPhysics_FixVAngle();
2182
2183         self.stat_game_starttime = game_starttime;
2184         self.stat_round_starttime = round_starttime;
2185         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2186         self.stat_leadlimit = autocvar_leadlimit;
2187
2188         if(frametime)
2189         {
2190                 // physics frames: update anticheat stuff
2191                 anticheat_prethink();
2192         }
2193
2194         if(blockSpectators && frametime)
2195                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2196                 checkSpectatorBlock();
2197
2198         zoomstate_set = 0;
2199
2200         if(self.netname_previous != self.netname)
2201         {
2202                 if(autocvar_sv_eventlog)
2203                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2204                 if(self.netname_previous)
2205                         strunzone(self.netname_previous);
2206                 self.netname_previous = strzone(self.netname);
2207         }
2208
2209         // version nagging
2210         if(self.version_nagtime)
2211                 if(self.cvar_g_xonoticversion)
2212                         if(time > self.version_nagtime)
2213                         {
2214                                 // don't notify git users
2215                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2216                                 {
2217                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2218                                         {
2219                                                 // notify release users if connecting to git
2220                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2221                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2222                                         }
2223                                         else
2224                                         {
2225                                                 float r;
2226                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2227                                                 if(r < 0)
2228                                                 {
2229                                                         // give users new version
2230                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2231                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2232                                                 }
2233                                                 else if(r > 0)
2234                                                 {
2235                                                         // notify users about old server version
2236                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2237                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2238                                                 }
2239                                         }
2240                                 }
2241                                 self.version_nagtime = 0;
2242                         }
2243
2244         // GOD MODE info
2245         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2246         {
2247                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2248                 self.max_armorvalue = 0;
2249         }
2250
2251 #ifdef TETRIS
2252         if (TetrisPreFrame())
2253                 return;
2254 #endif
2255
2256         MUTATOR_CALLHOOK(PlayerPreThink);
2257
2258         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2259         {
2260                 if(self.BUTTON_USE && !self.usekeypressed)
2261                         PlayerUseKey();
2262                 self.usekeypressed = self.BUTTON_USE;
2263         }
2264
2265         if(IS_REAL_CLIENT(self))
2266                 PrintWelcomeMessage();
2267
2268         if(IS_PLAYER(self))
2269         {
2270
2271                 CheckRules_Player();
2272
2273                 if (intermission_running)
2274                 {
2275                         IntermissionThink ();   // otherwise a button could be missed between
2276                         return;                                 // the think tics
2277                 }
2278
2279                 //don't allow the player to turn around while game is paused!
2280                 if(timeout_status == TIMEOUT_ACTIVE) {
2281                         // FIXME turn this into CSQC stuff
2282                         self.v_angle = self.lastV_angle;
2283                         self.angles = self.lastV_angle;
2284                         self.fixangle = TRUE;
2285                 }
2286
2287                 if(frametime)
2288                 {
2289                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2290                         {
2291                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2292                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2293                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2294
2295                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2296                                 {
2297                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2298                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2299                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2300                                 }
2301                         }
2302                         else
2303                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2304
2305                         player_powerups();
2306                 }
2307
2308                 if (self.deadflag != DEAD_NO)
2309                 {
2310                         if(self.personal && g_race_qualifying)
2311                         {
2312                                 if(time > self.respawn_time)
2313                                 {
2314                                         self.respawn_time = time + 1; // only retry once a second
2315                                         self.stat_respawn_time = self.respawn_time;
2316                                         respawn();
2317                                         self.impulse = 141;
2318                                 }
2319                         }
2320                         else
2321                         {
2322                                 float button_pressed;
2323                                 if(frametime)
2324                                         player_anim();
2325                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2326
2327                                 if (self.deadflag == DEAD_DYING)
2328                                 {
2329                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2330                                                 self.deadflag = DEAD_RESPAWNING;
2331                                         else if(!button_pressed)
2332                                                 self.deadflag = DEAD_DEAD;
2333                                 }
2334                                 else if (self.deadflag == DEAD_DEAD)
2335                                 {
2336                                         if(button_pressed)
2337                                                 self.deadflag = DEAD_RESPAWNABLE;
2338                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2339                                                 self.deadflag = DEAD_RESPAWNING;
2340                                 }
2341                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2342                                 {
2343                                         if(!button_pressed)
2344                                                 self.deadflag = DEAD_RESPAWNING;
2345                                 }
2346                                 else if (self.deadflag == DEAD_RESPAWNING)
2347                                 {
2348                                         if(time > self.respawn_time)
2349                                         {
2350                                                 self.respawn_time = time + 1; // only retry once a second
2351                                                 self.respawn_time_max = self.respawn_time;
2352                                                 respawn();
2353                                         }
2354                                 }
2355
2356                                 ShowRespawnCountdown();
2357
2358                                 if(self.respawn_flags & RESPAWN_SILENT)
2359                                         self.stat_respawn_time = 0;
2360                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2361                                         self.stat_respawn_time = self.respawn_time_max;
2362                                 else
2363                                         self.stat_respawn_time = self.respawn_time;
2364                         }
2365
2366                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2367                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2368                                 self.stat_respawn_time *= -1;
2369
2370                         return;
2371                 }
2372
2373                 self.prevorigin = self.origin;
2374
2375                 float do_crouch = self.BUTTON_CROUCH;
2376                 if(self.hook.state)
2377                         do_crouch = 0;
2378                 if(self.vehicle)
2379                         do_crouch = 0;
2380                 if(self.freezetag_frozen)
2381                         do_crouch = 0;
2382                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2383                         do_crouch = 0;
2384
2385                 if (do_crouch)
2386                 {
2387                         if (!self.crouch)
2388                         {
2389                                 self.crouch = TRUE;
2390                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2391                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2392                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2393                         }
2394                 }
2395                 else
2396                 {
2397                         if (self.crouch)
2398                         {
2399                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2400                                 if (!trace_startsolid)
2401                                 {
2402                                         self.crouch = FALSE;
2403                                         self.view_ofs = PL_VIEW_OFS;
2404                                         setsize (self, PL_MIN, PL_MAX);
2405                                 }
2406                         }
2407                 }
2408
2409                 FixPlayermodel();
2410
2411                 GrapplingHookFrame();
2412
2413                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2414                 //if(frametime)
2415                 {
2416                         self.items &= ~self.items_added;
2417
2418                         W_WeaponFrame();
2419
2420                         self.items_added = 0;
2421                         if(self.items & IT_JETPACK)
2422                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2423                                         self.items_added |= IT_FUEL;
2424
2425                         self.items |= self.items_added;
2426                 }
2427
2428                 player_regen();
2429
2430                 // rot nex charge to the charge limit
2431                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2432                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2433
2434                 if(frametime)
2435                         player_anim();
2436
2437                 // secret status
2438                 secrets_setstatus();
2439
2440                 // monsters status
2441                 monsters_setstatus();
2442
2443                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2444
2445                 //self.angles_y=self.v_angle_y + 90;   // temp
2446         } else if(gameover) {
2447                 if (intermission_running)
2448                         IntermissionThink ();   // otherwise a button could be missed between
2449                 return;
2450         } else if(IS_OBSERVER(self)) {
2451                 ObserverThink();
2452         } else if(IS_SPEC(self)) {
2453                 SpectatorThink();
2454         }
2455
2456         if(!zoomstate_set)
2457                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2458
2459         float oldspectatee_status;
2460         oldspectatee_status = self.spectatee_status;
2461         if(IS_SPEC(self))
2462                 self.spectatee_status = num_for_edict(self.enemy);
2463         else if(IS_OBSERVER(self))
2464                 self.spectatee_status = num_for_edict(self);
2465         else
2466                 self.spectatee_status = 0;
2467         if(self.spectatee_status != oldspectatee_status)
2468         {
2469                 ClientData_Touch(self);
2470                 if(g_race || g_cts)
2471                         race_InitSpectator();
2472         }
2473
2474         if(self.teamkill_soundtime)
2475         if(time > self.teamkill_soundtime)
2476         {
2477                 self.teamkill_soundtime = 0;
2478
2479                 entity oldpusher, oldself;
2480
2481                 oldself = self; self = self.teamkill_soundsource;
2482                 oldpusher = self.pusher; self.pusher = oldself;
2483
2484                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2485
2486                 self.pusher = oldpusher;
2487                 self = oldself;
2488         }
2489
2490         if(self.taunt_soundtime)
2491         if(time > self.taunt_soundtime)
2492         {
2493                 self.taunt_soundtime = 0;
2494                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2495         }
2496
2497         target_voicescript_next(self);
2498
2499         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2500         if(!self.weapon)
2501                 self.clip_load = self.clip_size = 0;
2502 }
2503
2504 float isInvisibleString(string s)
2505 {
2506         float i, n, c;
2507         s = strdecolorize(s);
2508         for((i = 0), (n = strlen(s)); i < n; ++i)
2509         {
2510                 c = str2chr(s, i);
2511                 switch(c)
2512                 {
2513                         case 0:
2514                         case 32: // space
2515                                 break;
2516                         case 192: // charmap space
2517                                 if (!autocvar_utf8_enable)
2518                                         break;
2519                                 return FALSE;
2520                         case 160: // space in unicode fonts
2521                         case 0xE000 + 192: // utf8 charmap space
2522                                 if (autocvar_utf8_enable)
2523                                         break;
2524                         default:
2525                                 return FALSE;
2526                 }
2527         }
2528         return TRUE;
2529 }
2530
2531 /*
2532 =============
2533 PlayerPostThink
2534
2535 Called every frame for each client after the physics are run
2536 =============
2537 */
2538 .float idlekick_lasttimeleft;
2539 void PlayerPostThink (void)
2540 {
2541         // Savage: Check for nameless players
2542         if (isInvisibleString(self.netname)) {
2543                 self.netname = "Player";
2544                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2545         }
2546
2547         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2548         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2549         {
2550                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2551                 {
2552                         if(self.idlekick_lasttimeleft)
2553                         {
2554                                 self.idlekick_lasttimeleft = 0;
2555                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2556                         }
2557                 }
2558                 else
2559                 {
2560                         float timeleft;
2561                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2562                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2563                         {
2564                                 if(!self.idlekick_lasttimeleft)
2565                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2566                         }
2567                         if(timeleft <= 0)
2568                         {
2569                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2570                                 dropclient(self);
2571                                 return;
2572                         }
2573                         else if(timeleft <= 10)
2574                         {
2575                                 if(timeleft != self.idlekick_lasttimeleft)
2576                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2577                                 self.idlekick_lasttimeleft = timeleft;
2578                         }
2579                 }
2580         }
2581
2582 #ifdef TETRIS
2583         if(self.impulse == 100)
2584                 ImpulseCommands();
2585         if (!TetrisPostFrame())
2586         {
2587 #endif
2588
2589         CheatFrame();
2590
2591         //CheckPlayerJump();
2592
2593         if(IS_PLAYER(self)) {
2594                 CheckRules_Player();
2595                 UpdateChatBubble();
2596                 if (self.impulse)
2597                         ImpulseCommands();
2598                 if (intermission_running)
2599                         return;         // intermission or finale
2600                 GetPressedKeys();
2601         }
2602
2603 #ifdef TETRIS
2604         }
2605 #endif
2606
2607         /*
2608         float i;
2609         for(i = 0; i < 1000; ++i)
2610         {
2611                 vector end;
2612                 end = self.origin + '0 0 1024' + 512 * randomvec();
2613                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2614                 if(trace_fraction < 1)
2615                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2616                 {
2617                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2618                         break;
2619                 }
2620         }
2621         */
2622
2623         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2624
2625         if(self.waypointsprite_attachedforcarrier)
2626                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2627
2628         playerdemo_write();
2629
2630         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2631         {
2632                 if (!self.stored_netname)
2633                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2634                 if(self.stored_netname != self.netname)
2635                 {
2636                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2637                         strunzone(self.stored_netname);
2638                         self.stored_netname = strzone(self.netname);
2639                 }
2640         }
2641
2642         /*
2643         if(g_race)
2644                 dprintf("%f %.6f\n", time, race_GetFractionalLapCount(self));
2645         */
2646
2647         CSQCMODEL_AUTOUPDATE();
2648 }