qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (arena_roundbased && !g_ca)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         DropAllRunes(self);
 405         MUTATOR_CALLHOOK(MakePlayerObserver);
 406
 407         if (g_minstagib)
 408                 minstagib_stop_countdown();
 409
 410         Portal_ClearAll(self);
 411
 412         if(self.alivetime)
 413         {
 414                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 415                 self.alivetime = 0;
 416         }
 417
 418         if(self.vehicle)
 419             vehicles_exit(VHEF_RELESE);
 420
 421         if(self.flagcarried)
 422                 DropFlag(self.flagcarried, world, world);
 423
 424         if(self.ballcarried && g_nexball)
 425                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 426
 427         WaypointSprite_PlayerDead();
 428
 429         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 430                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 431
 432         if(self.killcount != -666) {
 433                 if(g_lms) {
 434                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 435                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 436                         else
 437                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 438                 } else
 439                         bprint ("^4", self.netname, "^4 is spectating now\n");
 440
 441                 if(self.just_joined == FALSE) {
 442                         LogTeamchange(self.playerid, -1, 4);
 443                 } else
 444                         self.just_joined = FALSE;
 445         }
 446
 447         PlayerScore_Clear(self); // clear scores when needed
 448
 449         accuracy_resend(self);
 450
 451         self.spectatortime = time;
 452
 453         self.classname = "observer";
 454         self.iscreature = FALSE;
 455         self.damagedbycontents = FALSE;
 456         self.health = -666;
 457         self.takedamage = DAMAGE_NO;
 458         self.solid = SOLID_NOT;
 459         self.movetype = MOVETYPE_FLY_WORLDONLY; //(self.cvar_cl_clippedspectating ? MOVETYPE_NOCLIP : MOVETYPE_FLY); // it's too early for this anyway, lets just set it in playerprethink
 460         self.flags = FL_CLIENT | FL_NOTARGET;
 461         self.armorvalue = 666;
 462         self.effects = 0;
 463         self.armorvalue = autocvar_g_balance_armor_start;
 464         self.pauserotarmor_finished = 0;
 465         self.pauserothealth_finished = 0;
 466         self.pauseregen_finished = 0;
 467         self.damageforcescale = 0;
 468         self.death_time = 0;
 469         self.dead_frame = 0;
 470         self.alpha = 0;
 471         self.scale = 0;
 472         self.fade_time = 0;
 473         self.pain_frame = 0;
 474         self.pain_finished = 0;
 475         self.strength_finished = 0;
 476         self.invincible_finished = 0;
 477         self.pushltime = 0;
 478         self.think = SUB_Null;
 479         self.nextthink = 0;
 480         self.hook_time = 0;
 481         self.runes = 0;
 482         self.deadflag = DEAD_NO;
 483         self.angles = spot.angles;
 484         self.angles_z = 0;
 485         self.fixangle = TRUE;
 486         self.crouch = FALSE;
 487
 488         setorigin (self, spot.origin);
 489         self.prevorigin = self.origin;
 490         self.items = 0;
 491         self.weapons = 0;
 492         self.model = "";
 493         FixPlayermodel();
 494         setmodel(self, "null");
 495         self.drawonlytoclient = self;
 496
 497         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 498         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 499
 500         self.weapon = 0;
 501         self.weaponname = "";
 502         self.switchingweapon = 0;
 503         self.weaponmodel = "";
 504         self.weaponentity = world;
 505         self.exteriorweaponentity = world;
 506         self.killcount = -666;
 507         self.velocity = '0 0 0';
 508         self.avelocity = '0 0 0';
 509         self.punchangle = '0 0 0';
 510         self.punchvector = '0 0 0';
 511         self.oldvelocity = self.velocity;
 512         self.fire_endtime = -1;
 513
 514         if(g_arena)
 515         {
 516                 if(self.version_mismatch)
 517                 {
 518                         Spawnqueue_Unmark(self);
 519                         Spawnqueue_Remove(self);
 520                 }
 521                 else
 522                 {
 523                         Spawnqueue_Insert(self);
 524                 }
 525         }
 526         else if(g_lms)
 527         {
 528                 // Only if the player cannot play at all
 529                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 530                         self.frags = FRAGS_SPECTATOR;
 531                 else
 532                         self.frags = FRAGS_LMS_LOSER;
 533         }
 534         else if(g_ca)
 535         {
 536                 if(self.caplayer)
 537                         self.frags = FRAGS_LMS_LOSER;
 538                 else
 539                         self.frags = FRAGS_SPECTATOR;
 540         }
 541         else
 542                 self.frags = FRAGS_SPECTATOR;
 543 }
 544
 545 .float model_randomizer;
 546 void FixPlayermodel()
 547 {
 548         string defaultmodel;
 549         float defaultskin, chmdl, oldskin, n, i;
 550         vector m1, m2;
 551
 552         defaultmodel = "";
 553
 554         if(autocvar_sv_defaultcharacter == 1)
 555         {
 556                 defaultskin = 0;
 557
 558                 if(teamplay)
 559                 {
 560                         string s;
 561                         s = Team_ColorNameLowerCase(self.team);
 562                         if(s != "neutral")
 563                         {
 564                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 565                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 566                         }
 567                 }
 568
 569                 if(defaultmodel == "")
 570                 {
 571                         defaultmodel = autocvar_sv_defaultplayermodel;
 572                         defaultskin = autocvar_sv_defaultplayerskin;
 573                 }
 574
 575                 n = tokenize_console(defaultmodel);
 576                 if(n > 0)
 577                         defaultmodel = argv(floor(n * self.model_randomizer));
 578
 579                 i = strstrofs(defaultmodel, ":", 0);
 580                 if(i >= 0)
 581                 {
 582                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 583                         defaultmodel = substring(defaultmodel, 0, i);
 584                 }
 585         }
 586
 587         if(defaultmodel != "")
 588         {
 589                 if (defaultmodel != self.model)
 590                 {
 591                         m1 = self.mins;
 592                         m2 = self.maxs;
 593                         setplayermodel (self, defaultmodel);
 594                         setsize (self, m1, m2);
 595                         chmdl = TRUE;
 596                 }
 597
 598                 oldskin = self.skin;
 599                 self.skin = defaultskin;
 600         } else {
 601                 if (self.playermodel != self.model || self.playermodel == "")
 602                 {
 603                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 604                         m1 = self.mins;
 605                         m2 = self.maxs;
 606                         setplayermodel (self, self.playermodel);
 607                         setsize (self, m1, m2);
 608                         chmdl = TRUE;
 609                 }
 610
 611                 oldskin = self.skin;
 612                 self.skin = stof(self.playerskin);
 613         }
 614
 615         if(chmdl || oldskin != self.skin)
 616                 self.species = player_getspecies(); // model or skin has changed
 617
 618         if(!teamplay)
 619                 if(strlen(autocvar_sv_defaultplayercolors))
 620                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 621                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 622 }
 623
 624 void PlayerTouchExplode(entity p1, entity p2)
 625 {
 626         vector org;
 627         org = (p1.origin + p2.origin) * 0.5;
 628         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 629
 630         te_explosion(org);
 631
 632         entity e;
 633         e = spawn();
 634         setorigin(e, org);
 635         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 636         remove(e);
 637 }
 638
 639 /*
 640 =============
 641 PutClientInServer
 642
 643 Called when a client spawns in the server
 644 =============
 645 */
 646 //void() ctf_playerchanged;
 647 void PutClientInServer (void)
 648 {
 649         if(clienttype(self) == CLIENTTYPE_BOT)
 650         {
 651                 self.classname = "player";
 652         }
 653         else if(clienttype(self) == CLIENTTYPE_REAL)
 654         {
 655                 msg_entity = self;
 656                 WriteByte(MSG_ONE, SVC_SETVIEW);
 657                 WriteEntity(MSG_ONE, self);
 658         }
 659
 660         // reset player keys
 661         self.itemkeys = 0;
 662
 663         // player is dead and becomes observer
 664         // FIXME fix LMS scoring for new system
 665         if(g_lms)
 666         {
 667                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 668                         self.classname = "observer";
 669         }
 670
 671         if(g_arena || (g_ca && !allowed_to_spawn))
 672         if(!self.spawned)
 673                 self.classname = "observer";
 674
 675         if(gameover)
 676                 self.classname = "observer";
 677
 678         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 679                 entity spot, oldself;
 680                 float j;
 681
 682                 accuracy_resend(self);
 683
 684                 if(self.team < 0)
 685                         JoinBestTeam(self, FALSE, TRUE);
 686
 687                 race_PreSpawn();
 688
 689                 spot = SelectSpawnPoint (FALSE);
 690                 if(!spot)
 691                 {
 692                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 693                         return; // spawn failed
 694                 }
 695
 696                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 697
 698                 self.classname = "player";
 699                 self.wasplayer = TRUE;
 700                 self.iscreature = TRUE;
 701                 self.damagedbycontents = TRUE;
 702                 self.movetype = MOVETYPE_WALK;
 703                 self.solid = SOLID_SLIDEBOX;
 704                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 705                 if(autocvar_g_playerclip_collisions)
 706                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 707                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 708                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 709                 self.frags = FRAGS_PLAYER;
 710                 if(INDEPENDENT_PLAYERS)
 711                         MAKE_INDEPENDENT_PLAYER(self);
 712                 self.flags = FL_CLIENT;
 713                 if(autocvar__notarget)
 714                         self.flags |= FL_NOTARGET;
 715                 self.takedamage = DAMAGE_AIM;
 716                 if(g_minstagib)
 717                         self.effects = EF_FULLBRIGHT;
 718                 else
 719                         self.effects = 0;
 720                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 721                 self.air_finished = time + 12;
 722                 self.dmg = 2;
 723                 if(autocvar_g_balance_nex_charge)
 724                 {
 725                         if(autocvar_g_balance_nex_secondary_chargepool)
 726                                 self.nex_chargepool_ammo = 1;
 727                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 728                 }
 729
 730                 if(inWarmupStage)
 731                 {
 732                         self.ammo_shells = warmup_start_ammo_shells;
 733                         self.ammo_nails = warmup_start_ammo_nails;
 734                         self.ammo_rockets = warmup_start_ammo_rockets;
 735                         self.ammo_cells = warmup_start_ammo_cells;
 736                         self.ammo_fuel = warmup_start_ammo_fuel;
 737                         self.health = warmup_start_health;
 738                         self.armorvalue = warmup_start_armorvalue;
 739                         self.weapons = warmup_start_weapons;
 740                 }
 741                 else
 742                 {
 743                         self.ammo_shells = start_ammo_shells;
 744                         self.ammo_nails = start_ammo_nails;
 745                         self.ammo_rockets = start_ammo_rockets;
 746                         self.ammo_cells = start_ammo_cells;
 747                         self.ammo_fuel = start_ammo_fuel;
 748                         self.health = start_health;
 749                         self.armorvalue = start_armorvalue;
 750                         self.weapons = start_weapons;
 751                 }
 752
 753                 if(g_weaponarena_random)
 754                 {
 755                         if(g_weaponarena_random_with_laser)
 756                                 self.weapons &~= WEPBIT_LASER;
 757                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 758                         if(g_weaponarena_random_with_laser)
 759                                 self.weapons |= WEPBIT_LASER;
 760                 }
 761
 762                 self.items = start_items;
 763                 self.jump_interval = time;
 764
 765                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 766                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 767                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 768                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 769                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 770                 //extend the pause of rotting if client was reset at the beginning of the countdown
 771                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 772                         self.spawnshieldtime += game_starttime - time;
 773                         self.pauserotarmor_finished += game_starttime - time;
 774                         self.pauserothealth_finished += game_starttime - time;
 775                         self.pauseregen_finished += game_starttime - time;
 776                 }
 777                 self.damageforcescale = 2;
 778                 self.death_time = 0;
 779                 self.dead_frame = 0;
 780                 self.alpha = 0;
 781                 self.scale = 0;
 782                 self.fade_time = 0;
 783                 self.pain_frame = 0;
 784                 self.pain_finished = 0;
 785                 self.strength_finished = 0;
 786                 self.invincible_finished = 0;
 787                 self.pushltime = 0;
 788                 // players have no think function
 789                 self.think = SUB_Null;
 790                 self.nextthink = 0;
 791                 self.hook_time = 0;
 792                 self.dmg_team = 0;
 793                 self.ballistics_density = autocvar_g_ballistics_density_player;
 794
 795                 self.metertime = 0;
 796
 797                 self.runes = 0;
 798
 799                 self.deadflag = DEAD_NO;
 800
 801                 self.angles = spot.angles;
 802
 803                 self.angles_z = 0; // never spawn tilted even if the spot says to
 804                 self.fixangle = TRUE; // turn this way immediately
 805                 self.velocity = '0 0 0';
 806                 self.avelocity = '0 0 0';
 807                 self.punchangle = '0 0 0';
 808                 self.punchvector = '0 0 0';
 809                 self.oldvelocity = self.velocity;
 810                 self.fire_endtime = -1;
 811
 812                 msg_entity = self;
 813                 WRITESPECTATABLE_MSG_ONE({
 814                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 815                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 816                 });
 817
 818                 self.model = "";
 819                 FixPlayermodel();
 820                 self.drawonlytoclient = world;
 821
 822                 self.crouch = FALSE;
 823                 self.view_ofs = PL_VIEW_OFS;
 824                 setsize (self, PL_MIN, PL_MAX);
 825                 self.spawnorigin = spot.origin;
 826                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 827                 // don't reset back to last position, even if new position is stuck in solid
 828                 self.oldorigin = self.origin;
 829                 self.prevorigin = self.origin;
 830                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 831                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 832         self.hud = HUD_NORMAL;
 833
 834                 if(g_arena)
 835                 {
 836                         Spawnqueue_Remove(self);
 837                         Spawnqueue_Mark(self);
 838                 }
 839
 840                 else if(g_ca)
 841                         self.caplayer = 1;
 842
 843                 self.event_damage = PlayerDamage;
 844
 845                 self.bot_attack = TRUE;
 846
 847                 self.statdraintime = time + 5;
 848                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 849
 850                 if(self.killcount == -666) {
 851                         PlayerScore_Clear(self);
 852                         self.killcount = 0;
 853                 }
 854
 855                 CL_SpawnWeaponentity();
 856                 self.alpha = default_player_alpha;
 857                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 858                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 859
 860                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 861                 self.lms_traveled_distance = 0;
 862                 self.speedrunning = FALSE;
 863
 864                 race_PostSpawn(spot);
 865
 866                 //stuffcmd(self, "chase_active 0");
 867                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 868
 869                 if (autocvar_g_spawnsound)
 870                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 871
 872                 if(g_assault) {
 873                         if(self.team == assault_attacker_team)
 874                                 centerprint(self, "You are attacking!");
 875                         else
 876                                 centerprint(self, "You are defending!");
 877                 }
 878
 879                 target_voicescript_clear(self);
 880
 881                 // reset fields the weapons may use
 882                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 883                 {
 884                         weapon_action(j, WR_RESETPLAYER);
 885
 886                         // all weapons must be fully loaded when we spawn
 887                         entity e;
 888                         e = get_weaponinfo(j);
 889                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 890                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 891                 }
 892
 893                 oldself = self;
 894                 self = spot;
 895                         activator = oldself;
 896                                 string s;
 897                                 s = self.target;
 898                                 self.target = string_null;
 899                                 SUB_UseTargets();
 900                                 self.target = s;
 901                         activator = world;
 902                 self = oldself;
 903
 904                 spawn_spot = spot;
 905                 MUTATOR_CALLHOOK(PlayerSpawn);
 906
 907                 if(autocvar_spawn_debug)
 908                 {
 909                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 910                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 911                 }
 912
 913                 self.switchweapon = w_getbestweapon(self);
 914                 self.cnt = -1; // W_LastWeapon will not complain
 915                 self.weapon = 0;
 916                 self.weaponname = "";
 917                 self.switchingweapon = 0;
 918
 919                 if(!self.alivetime)
 920                         self.alivetime = time;
 921
 922                 antilag_clear(self);
 923         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
 924                 PutObserverInServer ();
 925         }
 926
 927         //if(g_ctf)
 928         //      ctf_playerchanged();
 929 }
 930
 931 .float ebouncefactor, ebouncestop; // electro's values
 932 // TODO do we need all these fields, or should we stop autodetecting runtime
 933 // changes and just have a console command to update this?
 934 float ClientInit_SendEntity(entity to, float sf)
 935 {
 936         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 937         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 938         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 939         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 940         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 941         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 942         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 943         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 944         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 945         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 946         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 947         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 948         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 949         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 950         if(sv_foginterval && world.fog != "")
 951                 WriteString(MSG_ENTITY, world.fog);
 952         else
 953                 WriteString(MSG_ENTITY, "");
 954         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 955         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 956         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 957         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 958         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 959         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 960         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 961         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 962         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 963         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 964         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 965         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 966         return TRUE;
 967 }
 968
 969 void ClientInit_CheckUpdate()
 970 {
 971         self.nextthink = time;
 972         if(self.count != autocvar_g_balance_armor_blockpercent)
 973         {
 974                 self.count = autocvar_g_balance_armor_blockpercent;
 975                 self.SendFlags |= 1;
 976         }
 977         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 978         {
 979                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 980                 self.SendFlags |= 1;
 981         }
 982         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 983         {
 984                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 985                 self.SendFlags |= 1;
 986         }
 987         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 988         {
 989                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 990                 self.SendFlags |= 1;
 991         }
 992         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 993         {
 994                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 995                 self.SendFlags |= 1;
 996         }
 997         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 998         {
 999                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1000                 self.SendFlags |= 1;
1001         }
1002 }
1003
1004 void ClientInit_Spawn()
1005 {
1006         entity o;
1007         entity e;
1008         e = spawn();
1009         e.classname = "clientinit";
1010         e.think = ClientInit_CheckUpdate;
1011         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1012
1013         o = self;
1014         self = e;
1015         ClientInit_CheckUpdate();
1016         self = o;
1017 }
1018
1019 /*
1020 =============
1021 SetNewParms
1022 =============
1023 */
1024 void SetNewParms (void)
1025 {
1026         // initialize parms for a new player
1027         parm1 = -(86400 * 366);
1028 }
1029
1030 /*
1031 =============
1032 SetChangeParms
1033 =============
1034 */
1035 void SetChangeParms (void)
1036 {
1037         // save parms for level change
1038         parm1 = self.parm_idlesince - time;
1039 }
1040
1041 /*
1042 =============
1043 DecodeLevelParms
1044 =============
1045 */
1046 void DecodeLevelParms (void)
1047 {
1048         // load parms
1049         self.parm_idlesince = parm1;
1050         if(self.parm_idlesince == -(86400 * 366))
1051                 self.parm_idlesince = time;
1052
1053         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1054         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1055 }
1056
1057 /*
1058 =============
1059 ClientKill
1060
1061 Called when a client types 'kill' in the console
1062 =============
1063 */
1064
1065 .float clientkill_nexttime;
1066 void ClientKill_Now_TeamChange()
1067 {
1068         if(self.killindicator_teamchange == -1)
1069         {
1070                 self.team = -1;
1071                 JoinBestTeam( self, FALSE, FALSE );
1072         }
1073         else if(self.killindicator_teamchange == -2)
1074         {
1075                 if(g_ca)
1076                         self.caplayer = 0;
1077                 if(blockSpectators)
1078                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1079                 PutObserverInServer();
1080         }
1081         else
1082                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1083 }
1084
1085 void ClientKill_Now()
1086 {
1087         if(self.vehicle)
1088         {
1089             vehicles_exit(VHEF_RELESE);
1090             if(!self.killindicator_teamchange)
1091             {
1092             self.vehicle_health = -1;
1093             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1094             }
1095         }
1096
1097         if(self.killindicator && !wasfreed(self.killindicator))
1098                 remove(self.killindicator);
1099
1100         self.killindicator = world;
1101
1102         if(self.killindicator_teamchange)
1103                 ClientKill_Now_TeamChange();
1104
1105         // in any case:
1106         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1107
1108         // now I am sure the player IS dead
1109 }
1110 void KillIndicator_Think()
1111 {
1112         if (gameover)
1113         {
1114                 self.owner.killindicator = world;
1115                 remove(self);
1116                 return;
1117         }
1118
1119         if (self.owner.effects & CSQCMODEL_EF_INVISIBLE)
1120         {
1121                 self.owner.killindicator = world;
1122                 remove(self);
1123                 return;
1124         }
1125
1126         if(self.cnt <= 0)
1127         {
1128                 self = self.owner;
1129                 ClientKill_Now(); // no oldself needed
1130                 return;
1131         }
1132     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1133     {
1134         self.nextthink = time + 1;
1135         self.cnt -= 1;
1136     }
1137         else
1138         {
1139                 if(self.cnt <= 10)
1140                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1141                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1142                 {
1143                         if(self.cnt <= 10)
1144                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1145                 }
1146                 self.nextthink = time + 1;
1147                 self.cnt -= 1;
1148         }
1149 }
1150
1151 float clientkilltime;
1152 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1153 {
1154         float killtime;
1155         float starttime;
1156         entity e;
1157
1158         if (gameover)
1159                 return;
1160
1161         killtime = autocvar_g_balance_kill_delay;
1162
1163         if(g_race_qualifying || g_cts)
1164                 killtime = 0;
1165
1166     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1167     {
1168                 remove(self.killindicator);
1169                 self.killindicator = world;
1170
1171         ClientKill_Now(); // allow instant kill in this case
1172         return;
1173     }
1174
1175         self.killindicator_teamchange = targetteam;
1176
1177     if(!self.killindicator)
1178         {
1179                 if(self.deadflag == DEAD_NO)
1180                 {
1181                         killtime = max(killtime, self.clientkill_nexttime - time);
1182                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1183                 }
1184
1185                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1186                 {
1187                         ClientKill_Now();
1188                 }
1189                 else
1190                 {
1191                         starttime = max(time, clientkilltime);
1192
1193                         self.killindicator = spawn();
1194                         self.killindicator.owner = self;
1195                         self.killindicator.scale = 0.5;
1196                         setattachment(self.killindicator, self, "");
1197                         setorigin(self.killindicator, '0 0 52');
1198                         self.killindicator.think = KillIndicator_Think;
1199                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1200                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1201                         self.killindicator.cnt = ceil(killtime);
1202                         self.killindicator.count = bound(0, ceil(killtime), 10);
1203                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1204
1205                         for(e = world; (e = find(e, classname, "body")) != world; )
1206                         {
1207                                 if(e.enemy != self)
1208                                         continue;
1209                                 e.killindicator = spawn();
1210                                 e.killindicator.owner = e;
1211                                 e.killindicator.scale = 0.5;
1212                                 setattachment(e.killindicator, e, "");
1213                                 setorigin(e.killindicator, '0 0 52');
1214                                 e.killindicator.think = KillIndicator_Think;
1215                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1216                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1217                                 e.killindicator.cnt = ceil(killtime);
1218                         }
1219                         self.lip = 0;
1220                 }
1221         }
1222         if(self.killindicator)
1223         {
1224                 if(targetteam == 0) // just die
1225                 {
1226                         self.killindicator.colormod = '0 0 0';
1227                         if(clienttype(self) == CLIENTTYPE_REAL)
1228                         if(self.killindicator.cnt > 0)
1229                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1230                 }
1231                 else if(targetteam == -1) // auto
1232                 {
1233                         self.killindicator.colormod = '0 1 0';
1234                         if(clienttype(self) == CLIENTTYPE_REAL)
1235                         if(self.killindicator.cnt > 0)
1236                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1237                 }
1238                 else if(targetteam == -2) // spectate
1239                 {
1240                         self.killindicator.colormod = '0.5 0.5 0.5';
1241                         if(clienttype(self) == CLIENTTYPE_REAL)
1242                         if(self.killindicator.cnt > 0)
1243                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1244                 }
1245                 else
1246                 {
1247                         self.killindicator.colormod = TeamColor(targetteam);
1248                         if(clienttype(self) == CLIENTTYPE_REAL)
1249                         if(self.killindicator.cnt > 0)
1250                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1251                 }
1252         }
1253
1254 }
1255
1256 void ClientKill (void)
1257 {
1258         if (gameover)
1259                 return;
1260
1261         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1262         {
1263                 // do nothing
1264         }
1265     else if(self.freezetag_frozen)
1266     {
1267         // do nothing
1268     }
1269         else
1270                 ClientKill_TeamChange(0);
1271 }
1272
1273 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1274 {
1275     e.killindicator = spawn();
1276     e.killindicator.owner = e;
1277     e.killindicator.think = KillIndicator_Think;
1278     e.killindicator.nextthink = time + (e.lip) * 0.05;
1279     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1280     e.killindicator.health = 1; // this is used to indicate that it should be silent
1281     e.lip = 0;
1282 }
1283
1284 void FixClientCvars(entity e)
1285 {
1286         // send prediction settings to the client
1287         stuffcmd(e, "\nin_bindmap 0 0\n");
1288         if(g_race || g_cts)
1289                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1290         if(autocvar_g_antilag == 3) // client side hitscan
1291                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1292         if(sv_gentle)
1293                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1294         /*
1295          * we no longer need to stuff this. Remove this comment block if you feel
1296          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1297         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1298         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1299         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1300         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1301         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1302         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1303         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1304         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1305         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1306         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1307         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1308         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1309         stuffcmd(e, "cl_movement_edgefriction 1\n");
1310          */
1311 }
1312
1313 float PlayerInIDList(entity p, string idlist)
1314 {
1315         float n, i;
1316         string s;
1317
1318         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1319         if not(p.crypto_idfp)
1320                 return 0;
1321
1322         // this function allows abbreviated player IDs too!
1323         n = tokenize_console(idlist);
1324         for(i = 0; i < n; ++i)
1325         {
1326                 s = argv(i);
1327                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1328                         return 1;
1329         }
1330
1331         return 0;
1332 }
1333
1334 /*
1335 =============
1336 ClientConnect
1337
1338 Called when a client connects to the server
1339 =============
1340 */
1341 //void ctf_clientconnect();
1342 string ColoredTeamName(float t);
1343 void DecodeLevelParms (void);
1344 //void dom_player_join_team(entity pl);
1345 void set_dom_state(entity e);
1346 void ClientConnect (void)
1347 {
1348         float t;
1349
1350         if(self.flags & FL_CLIENT)
1351         {
1352                 print("Warning: ClientConnect, but already connected!\n");
1353                 return;
1354         }
1355
1356         if(Ban_MaybeEnforceBan(self))
1357                 return;
1358
1359         DecodeLevelParms();
1360
1361 #ifdef WATERMARK
1362         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1363 #endif
1364
1365         self.classname = "player_joining";
1366
1367         self.flags = FL_CLIENT;
1368         self.version_nagtime = time + 10 + random() * 10;
1369
1370         if(player_count<0)
1371         {
1372                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1373                 player_count = 0;
1374         }
1375
1376         PlayerScore_Attach(self);
1377         ClientData_Attach();
1378         accuracy_init(self);
1379
1380         bot_clientconnect();
1381
1382         playerdemo_init();
1383
1384         anticheat_init();
1385
1386         race_PreSpawnObserver();
1387
1388         //if(g_domination)
1389         //      dom_player_join_team(self);
1390
1391         // identify the right forced team
1392         if(autocvar_g_campaign)
1393         {
1394                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1395                 {
1396                         switch(autocvar_g_campaign_forceteam)
1397                         {
1398                                 case 1: self.team_forced = COLOR_TEAM1; break;
1399                                 case 2: self.team_forced = COLOR_TEAM2; break;
1400                                 case 3: self.team_forced = COLOR_TEAM3; break;
1401                                 case 4: self.team_forced = COLOR_TEAM4; break;
1402                                 default: self.team_forced = 0;
1403                         }
1404                 }
1405         }
1406         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1407                 self.team_forced = COLOR_TEAM1;
1408         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1409                 self.team_forced = COLOR_TEAM2;
1410         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1411                 self.team_forced = COLOR_TEAM3;
1412         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1413                 self.team_forced = COLOR_TEAM4;
1414         else if(autocvar_g_forced_team_otherwise == "red")
1415                 self.team_forced = COLOR_TEAM1;
1416         else if(autocvar_g_forced_team_otherwise == "blue")
1417                 self.team_forced = COLOR_TEAM2;
1418         else if(autocvar_g_forced_team_otherwise == "yellow")
1419                 self.team_forced = COLOR_TEAM3;
1420         else if(autocvar_g_forced_team_otherwise == "pink")
1421                 self.team_forced = COLOR_TEAM4;
1422         else if(autocvar_g_forced_team_otherwise == "spectate")
1423                 self.team_forced = -1;
1424         else if(autocvar_g_forced_team_otherwise == "spectator")
1425                 self.team_forced = -1;
1426         else
1427                 self.team_forced = 0;
1428
1429         if(!teamplay)
1430                 if(self.team_forced > 0)
1431                         self.team_forced = 0;
1432
1433         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1434
1435         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1436                 self.classname = "observer";
1437         } else {
1438                 if(teamplay)
1439                 {
1440                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1441                         {
1442                                 self.classname = "player";
1443                                 campaign_bots_may_start = 1;
1444                         }
1445                         else
1446                         {
1447                                 self.classname = "observer"; // do it anyway
1448                         }
1449                 }
1450                 else
1451                 {
1452                         self.classname = "player";
1453                         campaign_bots_may_start = 1;
1454                 }
1455         }
1456
1457         self.playerid = (playerid_last = playerid_last + 1);
1458
1459         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1460
1461     if(clienttype(self) == CLIENTTYPE_BOT)
1462         PlayerStats_AddPlayer(self);
1463
1464         if(autocvar_sv_eventlog)
1465                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1466
1467         LogTeamchange(self.playerid, self.team, 1);
1468
1469         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1470
1471         self.netname_previous = strzone(self.netname);
1472
1473         bprint("^4", self.netname, "^4 connected");
1474
1475         if(self.classname != "observer" && (g_domination || g_ctf))
1476                 bprint(" and joined the ", ColoredTeamName(self.team));
1477
1478         bprint("\n");
1479
1480         stuffcmd(self, strcat(clientstuff, "\n"));
1481         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1482
1483         FixClientCvars(self);
1484
1485         // spawnfunc_waypoint sprites
1486         WaypointSprite_InitClient(self);
1487
1488         // Wazat's grappling hook
1489         SetGrappleHookBindings();
1490
1491         // get version info from player
1492         stuffcmd(self, "cmd clientversion $gameversion\n");
1493
1494         // get other cvars from player
1495         GetCvars(0);
1496
1497         // notify about available teams
1498         if(teamplay)
1499         {
1500                 CheckAllowedTeams(self);
1501                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1502                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1503         }
1504         else
1505                 stuffcmd(self, "set _teams_available 0\n");
1506
1507         if(g_arena || g_ca)
1508         {
1509                 self.classname = "observer";
1510                 if(g_arena)
1511                         Spawnqueue_Insert(self);
1512         }
1513         /*else if(g_ctf)
1514         {
1515                 ctf_clientconnect();
1516         }*/
1517
1518         attach_entcs();
1519
1520         bot_relinkplayerlist();
1521
1522         self.spectatortime = time;
1523         if(blockSpectators)
1524         {
1525                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1526         }
1527
1528         self.jointime = time;
1529         self.allowedTimeouts = autocvar_sv_timeout_number;
1530
1531         if(clienttype(self) == CLIENTTYPE_REAL)
1532         {
1533                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1534                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1535         }
1536
1537         if(g_lms)
1538         {
1539                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1540                 {
1541                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1542                         self.frags = FRAGS_SPECTATOR;
1543                 }
1544         }
1545
1546         if(!sv_foginterval && world.fog != "")
1547                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1548
1549         SoundEntity_Attach(self);
1550
1551         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1552         {
1553                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1554                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1555         }
1556         else
1557                 self.hitplotfh = -1;
1558
1559         if(g_race || g_cts) {
1560                 string rr;
1561                 if(g_cts)
1562                         rr = CTS_RECORD;
1563                 else
1564                         rr = RACE_RECORD;
1565                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1566
1567                 msg_entity = self;
1568                 race_send_recordtime(MSG_ONE);
1569                 race_send_speedaward(MSG_ONE);
1570
1571                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1572                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1573                 race_send_speedaward_alltimebest(MSG_ONE);
1574
1575                 float i;
1576                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1577                         race_SendRankings(i, 0, 0, MSG_ONE);
1578                 }
1579         }
1580         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1581                 send_CSQC_teamnagger();
1582
1583         if (g_domination)
1584                 set_dom_state(self);
1585
1586         CheatInitClient();
1587
1588         if(!autocvar_g_campaign)
1589                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1590
1591         CSQCMODEL_AUTOINIT();
1592
1593         self.model_randomizer = random();
1594 }
1595
1596 /*
1597 =============
1598 ClientDisconnect
1599
1600 Called when a client disconnects from the server
1601 =============
1602 */
1603 .entity chatbubbleentity;
1604 void ReadyCount();
1605 void ClientDisconnect (void)
1606 {
1607         if(self.vehicle)
1608             vehicles_exit(VHEF_RELESE);
1609
1610         if not(self.flags & FL_CLIENT)
1611         {
1612                 print("Warning: ClientDisconnect without ClientConnect\n");
1613                 return;
1614         }
1615
1616         PlayerStats_AddGlobalInfo(self);
1617
1618         CheatShutdownClient();
1619
1620         if(self.hitplotfh >= 0)
1621         {
1622                 fclose(self.hitplotfh);
1623                 self.hitplotfh = -1;
1624         }
1625
1626         anticheat_report();
1627         anticheat_shutdown();
1628
1629         playerdemo_shutdown();
1630
1631         bot_clientdisconnect();
1632
1633         if(self.entcs)
1634                 detach_entcs();
1635
1636         if(autocvar_sv_eventlog)
1637                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1638         bprint ("^4",self.netname);
1639         bprint ("^4 disconnected\n");
1640
1641         SoundEntity_Detach(self);
1642
1643         DropAllRunes(self);
1644         MUTATOR_CALLHOOK(ClientDisconnect);
1645
1646         Portal_ClearAll(self);
1647
1648         RemoveGrapplingHook(self);
1649         if(self.flagcarried)
1650                 DropFlag(self.flagcarried, world, world);
1651         if(self.ballcarried && g_nexball)
1652                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1653
1654         // Here, everything has been done that requires this player to be a client.
1655
1656         self.flags &~= FL_CLIENT;
1657
1658         if (self.chatbubbleentity)
1659                 remove (self.chatbubbleentity);
1660
1661         if (self.killindicator)
1662                 remove (self.killindicator);
1663
1664         WaypointSprite_PlayerGone();
1665
1666         bot_relinkplayerlist();
1667
1668         if(g_arena)
1669         {
1670                 Spawnqueue_Unmark(self);
1671                 Spawnqueue_Remove(self);
1672         }
1673
1674         accuracy_free(self);
1675         ClientData_Detach();
1676         PlayerScore_Detach(self);
1677
1678         if(self.netname_previous)
1679                 strunzone(self.netname_previous);
1680         if(self.clientstatus)
1681                 strunzone(self.clientstatus);
1682         if(self.weaponorder_byimpulse)
1683                 strunzone(self.weaponorder_byimpulse);
1684
1685         ClearPlayerSounds();
1686
1687         if(self.personal)
1688                 remove(self.personal);
1689
1690         self.playerid = 0;
1691         ReadyCount();
1692
1693         // free cvars
1694         GetCvars(-1);
1695 }
1696
1697 .float BUTTON_CHAT;
1698 void ChatBubbleThink()
1699 {
1700         self.nextthink = time;
1701         if ((self.owner.effects & CSQCMODEL_EF_INVISIBLE) || self.owner.chatbubbleentity != self)
1702         {
1703                 if(self.owner) // but why can that ever be world?
1704                         self.owner.chatbubbleentity = world;
1705                 remove(self);
1706                 return;
1707         }
1708         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1709 #ifdef TETRIS
1710                 || self.owner.tetris_on
1711 #endif
1712         )
1713                 self.model = self.mdl;
1714         else
1715                 self.model = "";
1716 }
1717
1718 void UpdateChatBubble()
1719 {
1720         if (self.effects & CSQCMODEL_EF_INVISIBLE)
1721                 return;
1722         // spawn a chatbubble entity if needed
1723         if (!self.chatbubbleentity)
1724         {
1725                 self.chatbubbleentity = spawn();
1726                 self.chatbubbleentity.owner = self;
1727                 self.chatbubbleentity.exteriormodeltoclient = self;
1728                 self.chatbubbleentity.think = ChatBubbleThink;
1729                 self.chatbubbleentity.nextthink = time;
1730                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1731                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1732                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1733                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1734                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1735                 self.chatbubbleentity.model = "";
1736                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1737         }
1738 }
1739
1740
1741 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1742 // added to the model skins
1743 /*void UpdateColorModHack()
1744 {
1745         float c;
1746         c = self.clientcolors & 15;
1747         // LordHavoc: only bothering to support white, green, red, yellow, blue
1748              if (!teamplay) self.colormod = '0 0 0';
1749         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1750         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1751         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1752         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1753         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1754         else self.colormod = '1 1 1';
1755 }*/
1756
1757 .float oldcolormap;
1758 void respawn(void)
1759 {
1760         if(!(self.effects & CSQCMODEL_EF_INVISIBLE) && autocvar_g_respawn_ghosts)
1761         {
1762                 self.solid = SOLID_NOT;
1763                 self.takedamage = DAMAGE_NO;
1764                 self.movetype = MOVETYPE_FLY;
1765                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1766                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1767                 self.effects |= EF_ADDITIVE;
1768                 self.oldcolormap = self.colormap;
1769                 self.colormap = 0; // this originally was 512, but raises a warning in the engine, so get rid of it
1770                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1771                 if(autocvar_g_respawn_ghosts_maxtime)
1772                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1773         }
1774
1775         CopyBody(1);
1776         self.effects |= EF_NODRAW; // prevent another CopyBody
1777         if(self.oldcolormap)
1778         {
1779                 self.colormap = self.oldcolormap;
1780                 self.oldcolormap = 0;
1781         }
1782         PutClientInServer();
1783 }
1784
1785 void play_countdown(float finished, string samp)
1786 {
1787         if(clienttype(self) == CLIENTTYPE_REAL)
1788                 if(floor(finished - time - frametime) != floor(finished - time))
1789                         if(finished - time < 6)
1790                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1791 }
1792
1793 void player_powerups (void)
1794 {
1795         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1796         olditems = self.items;
1797
1798         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1799         {
1800                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
1801                 self.modelflags |= MF_ROCKET;
1802         }
1803         else
1804         {
1805                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
1806                 self.modelflags &~= MF_ROCKET;
1807         }
1808
1809         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1810
1811         if((self.effects & CSQCMODEL_EF_INVISIBLE) || self.deadflag) // don't apply the flags if the player is gibbed
1812                 return;
1813
1814         Fire_ApplyDamage(self);
1815         Fire_ApplyEffect(self);
1816
1817         if (g_minstagib)
1818         {
1819                 self.effects |= EF_FULLBRIGHT;
1820
1821                 if (self.items & IT_STRENGTH)
1822                 {
1823                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1824                         if (time > self.strength_finished)
1825                         {
1826                                 self.alpha = default_player_alpha;
1827                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1828                                 self.items &~= IT_STRENGTH;
1829                                 sprint(self, "^3Invisibility has worn off\n");
1830                         }
1831                 }
1832                 else
1833                 {
1834                         if (time < self.strength_finished)
1835                         {
1836                                 self.alpha = g_minstagib_invis_alpha;
1837                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1838                                 self.items |= IT_STRENGTH;
1839                                 sprint(self, "^3You are invisible\n");
1840                         }
1841                 }
1842
1843                 if (self.items & IT_INVINCIBLE)
1844                 {
1845                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1846                         if (time > self.invincible_finished)
1847                         {
1848                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1849                                 sprint(self, "^3Speed has worn off\n");
1850                         }
1851                 }
1852                 else
1853                 {
1854                         if (time < self.invincible_finished)
1855                         {
1856                                 self.items = self.items | IT_INVINCIBLE;
1857                                 sprint(self, "^3You are on speed\n");
1858                         }
1859                 }
1860         }
1861         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1862         {
1863                 if (self.items & IT_STRENGTH)
1864                 {
1865                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1866                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1867                         if (time > self.strength_finished)
1868                         {
1869                                 self.items = self.items - (self.items & IT_STRENGTH);
1870                                 sprint(self, "^3Strength has worn off\n");
1871                         }
1872                 }
1873                 else
1874                 {
1875                         if (time < self.strength_finished)
1876                         {
1877                                 self.items = self.items | IT_STRENGTH;
1878                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1879                         }
1880                 }
1881                 if (self.items & IT_INVINCIBLE)
1882                 {
1883                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1884                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1885                         if (time > self.invincible_finished)
1886                         {
1887                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1888                                 sprint(self, "^3Shield has worn off\n");
1889                         }
1890                 }
1891                 else
1892                 {
1893                         if (time < self.invincible_finished)
1894                         {
1895                                 self.items = self.items | IT_INVINCIBLE;
1896                                 sprint(self, "^3Shield surrounds you\n");
1897                         }
1898                 }
1899
1900                 if(autocvar_g_nodepthtestplayers)
1901                         self.effects = self.effects | EF_NODEPTHTEST;
1902
1903                 if(autocvar_g_fullbrightplayers)
1904                         self.effects = self.effects | EF_FULLBRIGHT;
1905
1906                 // midair gamemode: damage only while in the air
1907                 // if in midair mode, being on ground grants temporary invulnerability
1908                 // (this is so that multishot weapon don't clear the ground flag on the
1909                 // first damage in the frame, leaving the player vulnerable to the
1910                 // remaining hits in the same frame)
1911                 if (self.flags & FL_ONGROUND)
1912                 if (g_midair)
1913                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1914
1915                 if (time >= game_starttime)
1916                 if (time < self.spawnshieldtime)
1917                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1918         }
1919
1920         MUTATOR_CALLHOOK(PlayerPowerups);
1921 }
1922
1923 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1924 {
1925         if(current > stable)
1926                 return current;
1927         else if(current > stable - 0.25) // when close enough, "snap"
1928                 return stable;
1929         else
1930                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1931 }
1932
1933 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1934 {
1935         if(current < stable)
1936                 return current;
1937         else if(current < stable + 0.25) // when close enough, "snap"
1938                 return stable;
1939         else
1940                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1941 }
1942
1943 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1944 {
1945         if(current > rotstable)
1946         {
1947                 if(rotframetime > 0)
1948                 {
1949                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1950                         current = max(rotstable, current - rotlinear * rotframetime);
1951                 }
1952         }
1953         else if(current < regenstable)
1954         {
1955                 if(regenframetime > 0)
1956                 {
1957                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1958                         current = min(regenstable, current + regenlinear * regenframetime);
1959                 }
1960         }
1961
1962         if(current > limit)
1963                 current = limit;
1964
1965         return current;
1966 }
1967
1968 void player_regen (void)
1969 {
1970         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1971         maxh = autocvar_g_balance_health_rotstable;
1972         maxa = autocvar_g_balance_armor_rotstable;
1973         maxf = autocvar_g_balance_fuel_rotstable;
1974         minh = autocvar_g_balance_health_regenstable;
1975         mina = autocvar_g_balance_armor_regenstable;
1976         minf = autocvar_g_balance_fuel_regenstable;
1977         limith = autocvar_g_balance_health_limit;
1978         limita = autocvar_g_balance_armor_limit;
1979         limitf = autocvar_g_balance_fuel_limit;
1980
1981         max_mod = regen_mod = rot_mod = limit_mod = 1;
1982
1983         if (self.runes & RUNE_REGEN)
1984         {
1985                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1986                 {
1987                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1988                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1989                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1990                 }
1991                 else
1992                 {
1993                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1994                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1995                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1996                 }
1997         }
1998         else if (self.runes & CURSE_VENOM)
1999         {
2000                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2001                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2002                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2003                 else
2004                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2005                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2006                 //if (!self.runes & RUNE_REGEN)
2007                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2008         }
2009         maxh = maxh * max_mod;
2010         //maxa = maxa * max_mod;
2011         //maxf = maxf * max_mod;
2012         minh = minh * max_mod;
2013         //mina = mina * max_mod;
2014         //minf = minf * max_mod;
2015         limith = limith * limit_mod;
2016         limita = limita * limit_mod;
2017         //limitf = limitf * limit_mod;
2018
2019         if(g_lms && g_ca)
2020                 rot_mod = 0;
2021
2022         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2023         {
2024                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2025                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2026
2027                 // if player rotted to death...  die!
2028                 if(self.health < 1)
2029                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2030         }
2031
2032         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2033                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2034 }
2035
2036 float zoomstate_set;
2037 void SetZoomState(float z)
2038 {
2039         if(z != self.zoomstate)
2040         {
2041                 self.zoomstate = z;
2042                 ClientData_Touch(self);
2043         }
2044         zoomstate_set = 1;
2045 }
2046
2047 void GetPressedKeys(void) {
2048         MUTATOR_CALLHOOK(GetPressedKeys);
2049         if (self.movement_x > 0) // get if movement keys are pressed
2050         {       // forward key pressed
2051                 self.pressedkeys |= KEY_FORWARD;
2052                 self.pressedkeys &~= KEY_BACKWARD;
2053         }
2054         else if (self.movement_x < 0)
2055         {       // backward key pressed
2056                 self.pressedkeys |= KEY_BACKWARD;
2057                 self.pressedkeys &~= KEY_FORWARD;
2058         }
2059         else
2060         {       // no x input
2061                 self.pressedkeys &~= KEY_FORWARD;
2062                 self.pressedkeys &~= KEY_BACKWARD;
2063         }
2064
2065         if (self.movement_y > 0)
2066         {       // right key pressed
2067                 self.pressedkeys |= KEY_RIGHT;
2068                 self.pressedkeys &~= KEY_LEFT;
2069         }
2070         else if (self.movement_y < 0)
2071         {       // left key pressed
2072                 self.pressedkeys |= KEY_LEFT;
2073                 self.pressedkeys &~= KEY_RIGHT;
2074         }
2075         else
2076         {       // no y input
2077                 self.pressedkeys &~= KEY_RIGHT;
2078                 self.pressedkeys &~= KEY_LEFT;
2079         }
2080
2081         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2082                 self.pressedkeys |= KEY_JUMP;
2083         else
2084                 self.pressedkeys &~= KEY_JUMP;
2085         if (self.BUTTON_CROUCH)
2086                 self.pressedkeys |= KEY_CROUCH;
2087         else
2088                 self.pressedkeys &~= KEY_CROUCH;
2089 }
2090
2091 /*
2092 ======================
2093 spectate mode routines
2094 ======================
2095 */
2096
2097 void SpectateCopy(entity spectatee) {
2098         other = spectatee;
2099         MUTATOR_CALLHOOK(SpectateCopy);
2100         self.armortype = spectatee.armortype;
2101         self.armorvalue = spectatee.armorvalue;
2102         self.ammo_cells = spectatee.ammo_cells;
2103         self.ammo_shells = spectatee.ammo_shells;
2104         self.ammo_nails = spectatee.ammo_nails;
2105         self.ammo_rockets = spectatee.ammo_rockets;
2106         self.ammo_fuel = spectatee.ammo_fuel;
2107         self.clip_load = spectatee.clip_load;
2108         self.clip_size = spectatee.clip_size;
2109         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2110         self.health = spectatee.health;
2111         self.impulse = 0;
2112         self.items = spectatee.items;
2113         self.last_pickup = spectatee.last_pickup;
2114         self.hit_time = spectatee.hit_time;
2115         self.metertime = spectatee.metertime;
2116         self.strength_finished = spectatee.strength_finished;
2117         self.invincible_finished = spectatee.invincible_finished;
2118         self.pressedkeys = spectatee.pressedkeys;
2119         self.weapons = spectatee.weapons;
2120         self.switchweapon = spectatee.switchweapon;
2121         self.switchingweapon = spectatee.switchingweapon;
2122         self.weapon = spectatee.weapon;
2123         self.nex_charge = spectatee.nex_charge;
2124         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2125         self.hagar_load = spectatee.hagar_load;
2126         self.minelayer_mines = spectatee.minelayer_mines;
2127         self.punchangle = spectatee.punchangle;
2128         self.view_ofs = spectatee.view_ofs;
2129         self.v_angle = spectatee.v_angle;
2130         self.velocity = spectatee.velocity;
2131         self.dmg_take = spectatee.dmg_take;
2132         self.dmg_save = spectatee.dmg_save;
2133         self.dmg_inflictor = spectatee.dmg_inflictor;
2134         self.angles = spectatee.v_angle;
2135         if(!self.BUTTON_USE)
2136                 self.fixangle = TRUE;
2137         setorigin(self, spectatee.origin);
2138         setsize(self, spectatee.mins, spectatee.maxs);
2139         SetZoomState(spectatee.zoomstate);
2140
2141         anticheat_spectatecopy(spectatee);
2142
2143         //self.vehicle = spectatee.vehicle;
2144
2145         self.hud = spectatee.hud;
2146         if(spectatee.vehicle)
2147     {
2148         setorigin(self, spectatee.origin);
2149         self.velocity = spectatee.vehicle.velocity;
2150         self.v_angle += spectatee.vehicle.angles;
2151         //self.v_angle_x *= -1;
2152         self.vehicle_health = spectatee.vehicle_health;
2153         self.vehicle_shield = spectatee.vehicle_shield;
2154         self.vehicle_energy = spectatee.vehicle_energy;
2155         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2156         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2157         self.vehicle_reload1 = spectatee.vehicle_reload1;
2158         self.vehicle_reload2 = spectatee.vehicle_reload2;
2159
2160         msg_entity = self;
2161         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2162         WriteEntity(MSG_ONE, spectatee);
2163         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2164     }
2165 }
2166
2167 float SpectateUpdate() {
2168         if(!self.enemy)
2169             return 0;
2170
2171         if (self == self.enemy)
2172                 return 0;
2173
2174         if(self.enemy.classname != "player")
2175                 return 0;
2176
2177         SpectateCopy(self.enemy);
2178
2179         return 1;
2180 }
2181
2182
2183 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2184 entity CA_SpectateNext(entity start) {
2185         if (start.team == self.team) {
2186                 return start;
2187         }
2188
2189         other = start;
2190         // continue from current player
2191         while(other && other.team != self.team) {
2192                 other = find(other, classname, "player");
2193         }
2194
2195         if (!other) {
2196                 // restart from begining
2197                 other = find(other, classname, "player");
2198                 while(other && other.team != self.team) {
2199                         other = find(other, classname, "player");
2200                 }
2201         }
2202
2203         return other;
2204 }
2205
2206 float SpectateNext() {
2207         other = find(self.enemy, classname, "player");
2208         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2209                 // CA and ca players when spectating enemies is forbidden
2210                 other = CA_SpectateNext(other);
2211         } else {
2212                 // other modes and ca spectators or spectating enemies is allowed
2213                 if (!other)
2214                         other = find(other, classname, "player");
2215         }
2216
2217         if (other)
2218                 self.enemy = other;
2219
2220         if(self.enemy.classname == "player") {
2221             if(self.enemy.vehicle)
2222             {
2223             msg_entity = self;
2224             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2225             WriteEntity(MSG_ONE, self.enemy);
2226             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2227             self.movetype = MOVETYPE_NONE;
2228             accuracy_resend(self);
2229             }
2230             else
2231             {
2232             msg_entity = self;
2233             WriteByte(MSG_ONE, SVC_SETVIEW);
2234             WriteEntity(MSG_ONE, self.enemy);
2235             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2236             self.movetype = MOVETYPE_NONE;
2237             accuracy_resend(self);
2238
2239             if(!SpectateUpdate())
2240                 PutObserverInServer();
2241         }
2242         return 1;
2243         } else {
2244                 return 0;
2245         }
2246 }
2247
2248 /*
2249 =============
2250 ShowRespawnCountdown()
2251
2252 Update a respawn countdown display.
2253 =============
2254 */
2255 void ShowRespawnCountdown()
2256 {
2257         float number;
2258         if(self.deadflag == DEAD_NO) // just respawned?
2259                 return;
2260         else
2261         {
2262                 number = ceil(self.death_time - time);
2263                 if(number <= 0)
2264                         return;
2265                 if(number <= self.respawn_countdown)
2266                 {
2267                         self.respawn_countdown = number - 1;
2268                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2269                                 AnnounceTo(self, strcat(ftos(number), ""));
2270                 }
2271         }
2272 }
2273
2274 .float prevent_join_msgtime;
2275 void LeaveSpectatorMode()
2276 {
2277         if(nJoinAllowed(1)) {
2278                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2279                         self.classname = "player";
2280
2281                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2282                                 JoinBestTeam(self, FALSE, TRUE);
2283
2284                         if(autocvar_g_campaign)
2285                                 campaign_bots_may_start = 1;
2286
2287                         PutClientInServer();
2288
2289                         if(self.classname == "player")
2290                                 bprint ("^4", self.netname, "^4 is playing now\n");
2291
2292                         if(!autocvar_g_campaign)
2293                         if (time < self.jointime + autocvar_welcome_message_time)
2294                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2295
2296                         if (self.prevent_join_msgtime)
2297                         {
2298                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2299                                 self.prevent_join_msgtime = 0;
2300                         }
2301
2302                         return;
2303                 } else {
2304                         if (g_ca && self.caplayer) {
2305                         }       // do nothing
2306                         else
2307                                 stuffcmd(self,"menu_showteamselect\n");
2308                         return;
2309                 }
2310         }
2311         else {
2312                 //player may not join because of g_maxplayers is set
2313                 if (time - self.prevent_join_msgtime > 2)
2314                 {
2315                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2316                         self.prevent_join_msgtime = time;
2317                 }
2318         }
2319 }
2320
2321 /**
2322  * Determines whether the player is allowed to join. This depends on cvar
2323  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2324  * it checks whether the number of currently playing players exceeds g_maxplayers.
2325  * @return int number of free slots for players, 0 if none
2326  */
2327 float nJoinAllowed(float includeMe) {
2328         if(self.team_forced < 0)
2329                 return FALSE; // forced spectators can never join
2330
2331         // TODO simplify this
2332         entity e;
2333
2334         float totalClients;
2335         FOR_EACH_CLIENT(e)
2336                 totalClients += 1;
2337
2338         if (!autocvar_g_maxplayers)
2339                 return maxclients - totalClients + includeMe;
2340
2341         float currentlyPlaying;
2342         FOR_EACH_REALPLAYER(e)
2343                 currentlyPlaying += 1;
2344
2345         if(currentlyPlaying < autocvar_g_maxplayers)
2346                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2347
2348         return 0;
2349 }
2350
2351 /**
2352  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2353  * g_maxplayers_spectator_blocktime seconds
2354  */
2355 void checkSpectatorBlock() {
2356         if(self.classname == "spectator" || self.classname == "observer") {
2357                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2358                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2359                         dropclient(self);
2360                 }
2361         }
2362 }
2363
2364 .float motd_actived_time; // used for both motd and campaign_message
2365 void PrintWelcomeMessage()
2366 {
2367         if (self.motd_actived_time == 0) { // is there already a message showing?
2368                 if (autocvar_g_campaign) {
2369                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2370                                 self.motd_actived_time = time;
2371                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2372                         }
2373                 } else {
2374                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2375                                 self.motd_actived_time = time;
2376                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2377                         }
2378                 }
2379         } else { // showing MOTD or campaign message
2380                 if (autocvar_g_campaign) {
2381                         if (self.BUTTON_INFO)
2382                                 self.motd_actived_time = time;
2383                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2384                                 self.motd_actived_time = 0;
2385                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2386                         }
2387                 } else {
2388                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2389                                 if (self.BUTTON_INFO)
2390                                         self.motd_actived_time = time;
2391                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2392                                         self.motd_actived_time = 0;
2393                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2394                                 }
2395                         }
2396                 }
2397         }
2398 }
2399
2400 void ObserverThink()
2401 {
2402         float prefered_movetype;
2403         if (self.flags & FL_JUMPRELEASED) {
2404                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2405                         self.flags &~= FL_JUMPRELEASED;
2406                         self.flags |= FL_SPAWNING;
2407                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2408                         self.flags &~= FL_JUMPRELEASED;
2409                         if(SpectateNext() == 1) {
2410                                 self.classname = "spectator";
2411                         }
2412                 } else {
2413                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2414                         if (self.movetype != prefered_movetype)
2415                                 self.movetype = prefered_movetype;
2416                 }
2417         } else {
2418                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2419                         self.flags |= FL_JUMPRELEASED;
2420                         if(self.flags & FL_SPAWNING)
2421                         {
2422                                 self.flags &~= FL_SPAWNING;
2423                                 LeaveSpectatorMode();
2424                                 return;
2425                         }
2426                 }
2427         }
2428
2429         PrintWelcomeMessage();
2430 }
2431
2432 void SpectatorThink()
2433 {
2434         if (self.flags & FL_JUMPRELEASED) {
2435                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2436                         self.flags &~= FL_JUMPRELEASED;
2437                         self.flags |= FL_SPAWNING;
2438                 } else if(self.BUTTON_ATCK) {
2439                         self.flags &~= FL_JUMPRELEASED;
2440                         if(SpectateNext() == 1) {
2441                                 self.classname = "spectator";
2442                         } else {
2443                                 self.classname = "observer";
2444                                 PutClientInServer();
2445                         }
2446                 } else if (self.BUTTON_ATCK2) {
2447                         self.flags &~= FL_JUMPRELEASED;
2448                         self.classname = "observer";
2449                         PutClientInServer();
2450                 } else {
2451                         if(!SpectateUpdate())
2452                                 PutObserverInServer();
2453                 }
2454         } else {
2455                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2456                         self.flags |= FL_JUMPRELEASED;
2457                         if(self.flags & FL_SPAWNING)
2458                         {
2459                                 self.flags &~= FL_SPAWNING;
2460                                 LeaveSpectatorMode();
2461                                 return;
2462                         }
2463                 }
2464                 if(!SpectateUpdate())
2465                         PutObserverInServer();
2466         }
2467
2468         PrintWelcomeMessage();
2469         self.flags |= FL_CLIENT | FL_NOTARGET;
2470 }
2471
2472 float ctf_usekey();
2473 void PlayerUseKey()
2474 {
2475         if(self.classname != "player")
2476                 return;
2477
2478         if(self.vehicle)
2479         {
2480         vehicles_exit(VHEF_NORMAL);
2481         return;
2482         }
2483
2484         // a use key was pressed; call handlers
2485         if(ctf_usekey())
2486                 return;
2487
2488         MUTATOR_CALLHOOK(PlayerUseKey);
2489 }
2490
2491 .float touchexplode_time;
2492
2493 /*
2494 =============
2495 PlayerPreThink
2496
2497 Called every frame for each client before the physics are run
2498 =============
2499 */
2500 .float usekeypressed;
2501 void() ctf_setstatus;
2502 void() nexball_setstatus;
2503 .float items_added;
2504 void PlayerPreThink (void)
2505 {
2506         WarpZone_PlayerPhysics_FixVAngle();
2507
2508         self.stat_game_starttime = game_starttime;
2509         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2510         self.stat_leadlimit = autocvar_leadlimit;
2511
2512         if(frametime)
2513         {
2514                 // physics frames: update anticheat stuff
2515                 anticheat_prethink();
2516         }
2517
2518         if(blockSpectators && frametime)
2519                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2520                 checkSpectatorBlock();
2521
2522         zoomstate_set = 0;
2523
2524         if(self.netname_previous != self.netname)
2525         {
2526                 if(autocvar_sv_eventlog)
2527                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2528                 if(self.netname_previous)
2529                         strunzone(self.netname_previous);
2530                 self.netname_previous = strzone(self.netname);
2531         }
2532
2533         // version nagging
2534         if(self.version_nagtime)
2535                 if(self.cvar_g_xonoticversion)
2536                         if(time > self.version_nagtime)
2537                         {
2538                                 // don't notify git users
2539                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2540                                 {
2541                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2542                                         {
2543                                                 // notify release users if connecting to git
2544                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2545                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2546                                         }
2547                                         else
2548                                         {
2549                                                 float r;
2550                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2551                                                 if(r < 0)
2552                                                 {
2553                                                         // give users new version
2554                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2555                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2556                                                 }
2557                                                 else if(r > 0)
2558                                                 {
2559                                                         // notify users about old server version
2560                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2561                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2562                                                 }
2563                                         }
2564                                 }
2565                                 self.version_nagtime = 0;
2566                         }
2567
2568         // GOD MODE info
2569         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2570         {
2571                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2572                 self.max_armorvalue = 0;
2573         }
2574
2575 #ifdef TETRIS
2576         if (TetrisPreFrame())
2577                 return;
2578 #endif
2579
2580         MUTATOR_CALLHOOK(PlayerPreThink);
2581
2582         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2583         {
2584                 if(self.BUTTON_USE && !self.usekeypressed)
2585                         PlayerUseKey();
2586                 self.usekeypressed = self.BUTTON_USE;
2587         }
2588
2589         PrintWelcomeMessage();
2590
2591         if(self.classname == "player") {
2592 //              if(self.netname == "Wazat")
2593 //                      bprint(self.classname, "\n");
2594
2595                 CheckRules_Player();
2596
2597                 if (intermission_running)
2598                 {
2599                         IntermissionThink ();   // otherwise a button could be missed between
2600                         return;                                 // the think tics
2601                 }
2602
2603                 //don't allow the player to turn around while game is paused!
2604                 if(timeoutStatus == 2) {
2605                         // FIXME turn this into CSQC stuff
2606                         self.v_angle = self.lastV_angle;
2607                         self.angles = self.lastV_angle;
2608                         self.fixangle = TRUE;
2609                 }
2610
2611                 if(frametime)
2612                 {
2613 #ifndef NO_LEGACY_NETWORKING
2614                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2615 #endif
2616
2617                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2618                         {
2619                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2620                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2621                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2622
2623                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2624                                 {
2625                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2626                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2627                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2628                                 }
2629                         }
2630                         else
2631                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2632
2633                         player_powerups();
2634                 }
2635
2636                 if (g_minstagib)
2637                         minstagib_ammocheck();
2638
2639                 if (self.deadflag != DEAD_NO)
2640                 {
2641                         float button_pressed, force_respawn;
2642                         if(self.personal && g_race_qualifying)
2643                         {
2644                                 if(time > self.death_time)
2645                                 {
2646                                         self.death_time = time + 1; // only retry once a second
2647                                         respawn();
2648                                         self.impulse = 141;
2649                                 }
2650                         }
2651                         else
2652                         {
2653                                 if(frametime)
2654                                         player_anim();
2655                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2656                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2657                                 if (self.deadflag == DEAD_DYING)
2658                                 {
2659                                         if(force_respawn)
2660                                                 self.deadflag = DEAD_RESPAWNING;
2661                                         else if(!button_pressed)
2662                                                 self.deadflag = DEAD_DEAD;
2663                                 }
2664                                 else if (self.deadflag == DEAD_DEAD)
2665                                 {
2666                                         if(button_pressed)
2667                                                 self.deadflag = DEAD_RESPAWNABLE;
2668                                 }
2669                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2670                                 {
2671                                         if(!button_pressed)
2672                                                 self.deadflag = DEAD_RESPAWNING;
2673                                 }
2674                                 else if (self.deadflag == DEAD_RESPAWNING)
2675                                 {
2676                                         if(time > self.death_time)
2677                                         {
2678                                                 self.death_time = time + 1; // only retry once a second
2679                                                 respawn();
2680                                         }
2681                                 }
2682                                 ShowRespawnCountdown();
2683                         }
2684                         return;
2685                 }
2686                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2687                 // so (self.deadflag == DEAD_NO) is always true in the code below
2688
2689                 if(g_touchexplode)
2690                 if(time > self.touchexplode_time)
2691                 if(self.classname == "player")
2692                 if(self.deadflag == DEAD_NO)
2693                 if not(IS_INDEPENDENT_PLAYER(self))
2694                 FOR_EACH_PLAYER(other) if(self != other)
2695                 {
2696                         if(time > other.touchexplode_time)
2697                         if(other.deadflag == DEAD_NO)
2698                         if not(IS_INDEPENDENT_PLAYER(other))
2699                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2700                         {
2701                                 PlayerTouchExplode(self, other);
2702                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2703                         }
2704                 }
2705
2706                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2707                 {
2708                         vector dist;
2709
2710                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2711                         dist = self.prevorigin - self.origin;
2712                         dist_z = 0;
2713                         self.lms_traveled_distance += fabs(vlen(dist));
2714
2715                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2716                         {
2717                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2718                                 self.lms_traveled_distance = 0;
2719                         }
2720
2721                         if(time > self.lms_nextcheck)
2722                         {
2723                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2724                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2725                                 {
2726                                         centerprint(self, autocvar_g_lms_campcheck_message);
2727                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2728                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2729                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2730                                 }
2731                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2732                                 self.lms_traveled_distance = 0;
2733                         }
2734                 }
2735
2736                 self.prevorigin = self.origin;
2737
2738                 if (((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss) && self.animstate_startframe != self.anim_melee_x) // prevent crouching if using melee attack
2739                 {
2740                         if (!self.crouch)
2741                         {
2742                                 self.crouch = TRUE;
2743                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2744                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2745                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2746                         }
2747                 }
2748                 else
2749                 {
2750                         if (self.crouch)
2751                         {
2752                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2753                                 if (!trace_startsolid)
2754                                 {
2755                                         self.crouch = FALSE;
2756                                         self.view_ofs = PL_VIEW_OFS;
2757                                         setsize (self, PL_MIN, PL_MAX);
2758                                 }
2759                         }
2760                 }
2761
2762                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2763                 {
2764                         if(self.bloodloss_timer < time)
2765                         {
2766                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2767                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2768                         }
2769                 }
2770
2771                 FixPlayermodel();
2772
2773                 GrapplingHookFrame();
2774
2775                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2776                 //if(frametime)
2777                 {
2778                         self.items &~= self.items_added;
2779
2780                         W_WeaponFrame();
2781
2782                         self.items_added = 0;
2783                         if(self.items & IT_JETPACK)
2784                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2785                                         self.items_added |= IT_FUEL;
2786
2787                         self.items |= self.items_added;
2788                 }
2789
2790                 player_regen();
2791
2792                 // rot nex charge to the charge limit
2793                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2794                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2795
2796                 if(frametime)
2797                         player_anim();
2798
2799                 if(g_ctf)
2800                         ctf_setstatus();
2801
2802                 if(g_nexball)
2803                         nexball_setstatus();
2804
2805                 // secret status
2806                 secrets_setstatus();
2807
2808                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2809
2810                 //self.angles_y=self.v_angle_y + 90;   // temp
2811         } else if(gameover) {
2812                 if (intermission_running)
2813                         IntermissionThink ();   // otherwise a button could be missed between
2814                 return;
2815         } else if(self.classname == "observer") {
2816                 ObserverThink();
2817         } else if(self.classname == "spectator") {
2818                 SpectatorThink();
2819         }
2820
2821         if(!zoomstate_set)
2822                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2823
2824         float oldspectatee_status;
2825         oldspectatee_status = self.spectatee_status;
2826         if(self.classname == "spectator")
2827                 self.spectatee_status = num_for_edict(self.enemy);
2828         else if(self.classname == "observer")
2829                 self.spectatee_status = num_for_edict(self);
2830         else
2831                 self.spectatee_status = 0;
2832         if(self.spectatee_status != oldspectatee_status)
2833         {
2834                 ClientData_Touch(self);
2835                 if(g_race || g_cts)
2836                         race_InitSpectator();
2837         }
2838
2839         if(self.teamkill_soundtime)
2840         if(time > self.teamkill_soundtime)
2841         {
2842                 self.teamkill_soundtime = 0;
2843
2844                 entity oldpusher, oldself;
2845
2846                 oldself = self; self = self.teamkill_soundsource;
2847                 oldpusher = self.pusher; self.pusher = oldself;
2848
2849                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2850
2851                 self.pusher = oldpusher;
2852                 self = oldself;
2853         }
2854
2855         if(self.taunt_soundtime)
2856         if(time > self.taunt_soundtime)
2857         {
2858                 self.taunt_soundtime = 0;
2859                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2860         }
2861
2862         target_voicescript_next(self);
2863
2864         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2865         if(!self.weapon)
2866                 self.clip_load = self.clip_size = 0;
2867 }
2868
2869 float isInvisibleString(string s)
2870 {
2871         float i, n, c;
2872         s = strdecolorize(s);
2873         for((i = 0), (n = strlen(s)); i < n; ++i)
2874         {
2875                 c = str2chr(s, i);
2876                 switch(c)
2877                 {
2878                         case 0:
2879                         case 32: // space
2880                                 break;
2881                         case 192: // charmap space
2882                                 if (!autocvar_utf8_enable)
2883                                         break;
2884                                 return FALSE;
2885                         case 160: // space in unicode fonts
2886                         case 0xE000 + 192: // utf8 charmap space
2887                                 if (autocvar_utf8_enable)
2888                                         break;
2889                         default:
2890                                 return FALSE;
2891                 }
2892         }
2893         return TRUE;
2894 }
2895
2896 /*
2897 =============
2898 PlayerPostThink
2899
2900 Called every frame for each client after the physics are run
2901 =============
2902 */
2903 .float idlekick_lasttimeleft;
2904 .entity showheadshotbbox;
2905 void showheadshotbbox_think()
2906 {
2907         if(self.owner.showheadshotbbox != self)
2908         {
2909                 remove(self);
2910                 return;
2911         }
2912         self.nextthink = time;
2913         setorigin(self, self.owner.origin);
2914         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2915 }
2916 void PlayerPostThink (void)
2917 {
2918         // Savage: Check for nameless players
2919         if (isInvisibleString(self.netname)) {
2920                 self.netname = "Player";
2921                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2922         }
2923
2924         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2925         {
2926                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2927                 {
2928                         if(self.idlekick_lasttimeleft)
2929                         {
2930                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2931                                 self.idlekick_lasttimeleft = 0;
2932                         }
2933                 }
2934                 else
2935                 {
2936                         float timeleft;
2937                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2938                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2939                         {
2940                                 if(!self.idlekick_lasttimeleft)
2941                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2942                         }
2943                         if(timeleft <= 0)
2944                         {
2945                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2946                                 AnnounceTo(self, "terminated");
2947                                 dropclient(self);
2948                                 return;
2949                         }
2950                         else if(timeleft <= 10)
2951                         {
2952                                 if(timeleft != self.idlekick_lasttimeleft)
2953                                         AnnounceTo(self, ftos(timeleft));
2954                                 self.idlekick_lasttimeleft = timeleft;
2955                         }
2956                 }
2957         }
2958
2959 #ifdef TETRIS
2960         if(self.impulse == 100)
2961                 ImpulseCommands();
2962         if (!TetrisPostFrame())
2963         {
2964 #endif
2965
2966         CheatFrame();
2967
2968         //CheckPlayerJump();
2969
2970         if(self.classname == "player") {
2971                 CheckRules_Player();
2972                 UpdateChatBubble();
2973                 if (self.impulse)
2974                         ImpulseCommands();
2975                 if (intermission_running)
2976                         return;         // intermission or finale
2977                 GetPressedKeys();
2978         } else if (self.classname == "observer") {
2979                 //do nothing
2980         } else if (self.classname == "spectator") {
2981                 //do nothing
2982         }
2983
2984 #ifdef TETRIS
2985         }
2986 #endif
2987
2988         /*
2989         float i;
2990         for(i = 0; i < 1000; ++i)
2991         {
2992                 vector end;
2993                 end = self.origin + '0 0 1024' + 512 * randomvec();
2994                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2995                 if(trace_fraction < 1)
2996                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2997                 {
2998                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2999                         break;
3000                 }
3001         }
3002         */
3003
3004         Arena_Warmup();
3005
3006         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3007
3008         if(self.waypointsprite_attachedforcarrier)
3009                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3010
3011         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3012         {
3013                 if(!self.showheadshotbbox)
3014                 {
3015                         self.showheadshotbbox = spawn();
3016                         self.showheadshotbbox.classname = "headshotbbox";
3017                         self.showheadshotbbox.owner = self;
3018                         self.showheadshotbbox.think = showheadshotbbox_think;
3019                         self.showheadshotbbox.nextthink = time;
3020                         self = self.showheadshotbbox;
3021                         self.think();
3022                         self = self.owner;
3023                 }
3024         }
3025         else
3026         {
3027                 if(self.showheadshotbbox)
3028                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3029                 remove(self.showheadshotbbox);
3030         }
3031
3032         playerdemo_write();
3033
3034         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3035         {
3036                 if(!self.stored_netname)
3037                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3038                 if(self.stored_netname != self.netname)
3039                 {
3040                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
3041                         strunzone(self.stored_netname);
3042                         self.stored_netname = strzone(self.netname);
3043                 }
3044         }
3045
3046         /*
3047         if(g_race)
3048                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3049         */
3050
3051         CSQCMODEL_AUTOUPDATE();
3052 }