Merge branch 'master' into mirceakitsune/universal_reload_system
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck)
136         if(spot.team != teamcheck)
137                 return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(autocvar_spawn_debugview)
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         teamcheck = 0;
329
330         if(!anypoint && have_team_spawns > 0)
331                 teamcheck = self.team;
332
333         // get the list of players
334         playerlist = findchain(classname, "player");
335         // get the entire list of spots
336         firstspot = findchain(classname, "info_player_deathmatch");
337         // filter out the bad ones
338         // (note this returns the original list if none survived)
339         if(anypoint)
340         {
341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
342         }
343         else
344         {
345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
346                 if(!firstspot_new)
347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
348                 firstspot = firstspot_new;
349
350                 // there is 50/50 chance of choosing a random spot or the furthest spot
351                 // (this means that roughly every other spawn will be furthest, so you
352                 // usually won't get fragged at spawn twice in a row)
353                 if (arena_roundbased && !g_ca)
354                 {
355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
356                         if(firstspot_new)
357                                 firstspot = firstspot_new;
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 }
360                 else if (random() > autocvar_g_spawn_furthest)
361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362                 else
363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
364         }
365
366         if(autocvar_spawn_debugview)
367         {
368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
369
370                 entity e;
371                 if(teamcheck)
372                         for(e = firstspot; e; e = e.chain)
373                                 if(e.team != teamcheck)
374                                         error("invalid spawn found");
375         }
376
377         if (!spot)
378         {
379                 if(autocvar_spawn_debug)
380                         GotoNextMap();
381                 else
382                 {
383                         if(some_spawn_has_been_used)
384                                 return world; // team can't spawn any more, because of actions of other team
385                         else
386                                 error("Cannot find a spawn point - please fix the map!");
387                 }
388         }
389
390         return spot;
391 }
392
393 /*
394 =============
395 CheckPlayerModel
396
397 Checks if the argument string can be a valid playermodel.
398 Returns a valid one in doubt.
399 =============
400 */
401 string FallbackPlayerModel;
402 string CheckPlayerModel(string plyermodel) {
403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
404         {
405                 // note: we cannot summon Don Strunzone here, some player may
406                 // still have the model string set. In case anyone manages how
407                 // to change a cvar default, we'll have a small leak here.
408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
409         }
410         if(strlen(plyermodel) < 4)
411                 return FallbackPlayerModel;
412         if( substring(plyermodel,0,14) != "models/player/")
413                 return FallbackPlayerModel;
414         else if(autocvar_sv_servermodelsonly)
415         {
416                 if(substring(plyermodel,-4,4) != ".zym")
417                 if(substring(plyermodel,-4,4) != ".dpm")
418                 if(substring(plyermodel,-4,4) != ".iqm")
419                 if(substring(plyermodel,-4,4) != ".md3")
420                 if(substring(plyermodel,-4,4) != ".psk")
421                         return FallbackPlayerModel;
422                 // forbid the LOD models
423                 if(substring(plyermodel, -9,5) == "_lod1")
424                         return FallbackPlayerModel;
425                 if(substring(plyermodel, -9,5) == "_lod2")
426                         return FallbackPlayerModel;
427                 if(plyermodel != strtolower(plyermodel))
428                         return FallbackPlayerModel;
429                 if(!fexists(plyermodel))
430                         return FallbackPlayerModel;
431         }
432         return plyermodel;
433 }
434
435 /*
436 =============
437 Client_customizeentityforclient
438
439 LOD reduction
440 =============
441 */
442 void Client_uncustomizeentityforclient()
443 {
444         if(self.modelindex == 0) // no need to uncustomize then
445                 return;
446         self.modelindex = self.modelindex_lod0;
447         self.skin = self.skinindex;
448 }
449
450 float Client_customizeentityforclient()
451 {
452         entity modelsource;
453
454         if(self.modelindex == 0)
455                 return TRUE;
456
457         // forcemodel stuff
458
459 #ifdef PROFILING
460         float t0;
461         t0 = gettime(GETTIME_HIRES); // reference
462 #endif
463
464         modelsource = self;
465
466 #ifdef ALLOW_FORCEMODELS
467         if(other.cvar_cl_forceplayermodelsfromxonotic)
468                 if not(self.modelindex_lod0_from_xonotic)
469                         modelsource = other;
470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
471                 modelsource = other;
472 #endif
473
474         self.skin = modelsource.skinindex;
475
476 #if 0
477         if(modelsource == self)
478                 self.skin = modelsource.skinindex;
479         else
480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
481 #endif
482
483         // self: me
484         // other: the player viewing me
485         float distance;
486         float f;
487
488         if(other.cvar_cl_playerdetailreduction <= 0)
489         {
490                 if(other.cvar_cl_playerdetailreduction <= -2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(other.cvar_cl_playerdetailreduction <= -1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497         else
498         {
499                 distance = vlen(self.origin - other.origin);
500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
501                 if(f > sv_loddistance2)
502                         self.modelindex = modelsource.modelindex_lod2;
503                 else if(f > sv_loddistance1)
504                         self.modelindex = modelsource.modelindex_lod1;
505                 else
506                         self.modelindex = modelsource.modelindex_lod0;
507         }
508
509 #ifdef PROFILING
510         float t1;
511         t1 = gettime(GETTIME_HIRES); // reference
512         client_cefc_accumulator += (t1 - t0);
513 #endif
514
515         return TRUE;
516 }
517
518 void setmodel_lod(entity e, string modelname)
519 {
520         string s;
521
522         if(sv_loddistance1)
523         {
524                 // FIXME: this only supports 3-letter extensions
525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
526                 if(fexists(s))
527                 {
528                         setmodel(e, s); // players have high precision
529                         self.modelindex_lod1 = self.modelindex;
530                 }
531                 else
532                         self.modelindex_lod1 = -1;
533
534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
535                 if(fexists(s))
536                 {
537                         setmodel(e, s); // players have high precision
538                         self.modelindex_lod2 = self.modelindex;
539                 }
540                 else
541                         self.modelindex_lod2 = -1;
542
543                 precache_model(modelname);
544                 setmodel(e, modelname); // players have high precision
545                 self.modelindex_lod0 = self.modelindex;
546
547                 if(self.modelindex_lod1 < 0)
548                         self.modelindex_lod1 = self.modelindex;
549
550                 if(self.modelindex_lod2 < 0)
551                         self.modelindex_lod2 = self.modelindex;
552         }
553         else
554         {
555                 precache_model(modelname);
556                 setmodel(e, modelname); // players have high precision
557                 self.modelindex_lod0 = self.modelindex;
558                         // save it for possible player model forcing
559         }
560
561         s = whichpack(self.model);
562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
563
564         player_setupanimsformodel();
565         UpdatePlayerSounds();
566 }
567
568 /*
569 =============
570 PutObserverInServer
571
572 putting a client as observer in the server
573 =============
574 */
575 void FixPlayermodel();
576 void PutObserverInServer (void)
577 {
578         entity  spot;
579
580         race_PreSpawnObserver();
581
582         spot = SelectSpawnPoint (TRUE);
583         if(!spot)
584                 error("No spawnpoints for observers?!?\n");
585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
586
587         if(clienttype(self) == CLIENTTYPE_REAL)
588         {
589                 msg_entity = self;
590                 WriteByte(MSG_ONE, SVC_SETVIEW);
591                 WriteEntity(MSG_ONE, self);
592         }
593
594         DropAllRunes(self);
595         MUTATOR_CALLHOOK(MakePlayerObserver);
596
597         Portal_ClearAll(self);
598
599         if(self.alivetime)
600         {
601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
602                 self.alivetime = 0;
603         }
604
605         if(self.flagcarried)
606                 DropFlag(self.flagcarried, world, world);
607
608         if(self.ballcarried && g_nexball)
609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
610
611         WaypointSprite_PlayerDead();
612
613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
615
616         if(self.killcount != -666) {
617                 if(g_lms) {
618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
620                         else
621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
622                 } else
623                         bprint ("^4", self.netname, "^4 is spectating now\n");
624
625                 if(self.just_joined == FALSE) {
626                         LogTeamchange(self.playerid, -1, 4);
627                 } else
628                         self.just_joined = FALSE;
629         }
630
631         PlayerScore_Clear(self); // clear scores when needed
632
633         accuracy_resend(self);
634
635         self.spectatortime = time;
636
637         self.classname = "observer";
638         self.iscreature = FALSE;
639         self.health = -666;
640         self.takedamage = DAMAGE_NO;
641         self.solid = SOLID_NOT;
642         self.movetype = MOVETYPE_NOCLIP;
643         self.flags = FL_CLIENT | FL_NOTARGET;
644         self.armorvalue = 666;
645         self.effects = 0;
646         self.armorvalue = autocvar_g_balance_armor_start;
647         self.pauserotarmor_finished = 0;
648         self.pauserothealth_finished = 0;
649         self.pauseregen_finished = 0;
650         self.damageforcescale = 0;
651         self.death_time = 0;
652         self.dead_frame = 0;
653         self.alpha = 0;
654         self.scale = 0;
655         self.fade_time = 0;
656         self.pain_frame = 0;
657         self.pain_finished = 0;
658         self.strength_finished = 0;
659         self.invincible_finished = 0;
660         self.pushltime = 0;
661         self.think = SUB_Null;
662         self.nextthink = 0;
663         self.hook_time = 0;
664         self.runes = 0;
665         self.deadflag = DEAD_NO;
666         self.angles = spot.angles;
667         self.angles_z = 0;
668         self.fixangle = TRUE;
669         self.crouch = FALSE;
670
671         self.view_ofs = PL_VIEW_OFS;
672         setorigin (self, spot.origin);
673         setsize (self, '0 0 0', '0 0 0');
674         self.prevorigin = self.origin;
675         self.items = 0;
676         self.weapons = 0;
677         self.model = "";
678         FixPlayermodel();
679         self.model = "";
680         self.modelindex = 0;
681         self.weapon = 0;
682         self.weaponmodel = "";
683         self.weaponentity = world;
684         self.exteriorweaponentity = world;
685         self.killcount = -666;
686         self.velocity = '0 0 0';
687         self.avelocity = '0 0 0';
688         self.punchangle = '0 0 0';
689         self.punchvector = '0 0 0';
690         self.oldvelocity = self.velocity;
691         self.fire_endtime = -1;
692
693         if(sv_loddistance1)
694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
695
696         if(g_arena)
697         {
698                 if(self.version_mismatch)
699                 {
700                         Spawnqueue_Unmark(self);
701                         Spawnqueue_Remove(self);
702                 }
703                 else
704                 {
705                         Spawnqueue_Insert(self);
706                 }
707         }
708         else if(g_lms)
709         {
710                 // Only if the player cannot play at all
711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
712                         self.frags = FRAGS_SPECTATOR;
713                 else
714                         self.frags = FRAGS_LMS_LOSER;
715         }
716         else
717                 self.frags = FRAGS_SPECTATOR;
718 }
719
720 void FixPlayermodel()
721 {
722         local string defaultmodel;
723         local float defaultskin, chmdl, oldskin;
724         local vector m1, m2;
725
726         defaultmodel = "";
727
728         if(autocvar_sv_defaultcharacter == 1) {
729                 defaultskin = 0;
730
731                 if(teams_matter)
732                 {
733                         string s;
734                         s = Team_ColorNameLowerCase(self.team);
735                         if(s != "neutral")
736                         {
737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
739                         }
740                 }
741
742                 if(defaultmodel == "")
743                 {
744                         defaultmodel = autocvar_sv_defaultplayermodel;
745                         defaultskin = autocvar_sv_defaultplayerskin;
746                 }
747         }
748
749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
750         {
751                 if(self.model != "")
752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
753                 self.model = ""; // force the != checks to return true
754         }
755
756         if(defaultmodel != "")
757         {
758                 if (defaultmodel != self.model)
759                 {
760                         m1 = self.mins;
761                         m2 = self.maxs;
762                         setmodel_lod (self, defaultmodel);
763                         setsize (self, m1, m2);
764                         chmdl = TRUE;
765                 }
766
767                 oldskin = self.skinindex;
768                 self.skinindex = defaultskin;
769         } else {
770                 if (self.playermodel != self.model || self.playermodel == "")
771                 {
772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
773                         m1 = self.mins;
774                         m2 = self.maxs;
775                         setmodel_lod (self, self.playermodel);
776                         setsize (self, m1, m2);
777                         chmdl = TRUE;
778                 }
779
780                 oldskin = self.skinindex;
781                 self.skinindex = stof(self.playerskin);
782         }
783
784         if(chmdl || oldskin != self.skinindex)
785                 self.species = player_getspecies(); // model or skin has changed
786
787         if(!teams_matter)
788                 if(strlen(autocvar_sv_defaultplayercolors))
789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
791 }
792
793 void PlayerTouchExplode(entity p1, entity p2)
794 {
795         vector org;
796         org = (p1.origin + p2.origin) * 0.5;
797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
798
799         te_explosion(org);
800
801         entity e;
802         e = spawn();
803         setorigin(e, org);
804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
805         remove(e);
806 }
807
808 /*
809 =============
810 PutClientInServer
811
812 Called when a client spawns in the server
813 =============
814 */
815 //void() ctf_playerchanged;
816 void PutClientInServer (void)
817 {
818         if(clienttype(self) == CLIENTTYPE_BOT)
819         {
820                 self.classname = "player";
821         }
822         else if(clienttype(self) == CLIENTTYPE_REAL)
823         {
824                 msg_entity = self;
825                 WriteByte(MSG_ONE, SVC_SETVIEW);
826                 WriteEntity(MSG_ONE, self);
827         }
828
829         // player is dead and becomes observer
830         // FIXME fix LMS scoring for new system
831         if(g_lms)
832         {
833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
834                         self.classname = "observer";
835         }
836
837         if(g_arena || (g_ca && !allowed_to_spawn))
838         if(!self.spawned)
839                 self.classname = "observer";
840
841         if(gameover)
842                 self.classname = "observer";
843
844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
845                 entity spot, oldself;
846                 float j;
847
848                 accuracy_resend(self);
849
850                 if(self.team < 0)
851                         JoinBestTeam(self, FALSE, TRUE);
852
853                 race_PreSpawn();
854
855                 spot = SelectSpawnPoint (FALSE);
856                 if(!spot)
857                 {
858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
859                         return; // spawn failed
860                 }
861
862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
863
864                 self.classname = "player";
865                 self.wasplayer = TRUE;
866                 self.iscreature = TRUE;
867                 self.movetype = MOVETYPE_WALK;
868                 self.solid = SOLID_SLIDEBOX;
869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
870                 if(autocvar_g_playerclip_collisions)
871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
874                 self.frags = FRAGS_PLAYER;
875                 if(independent_players)
876                         MAKE_INDEPENDENT_PLAYER(self);
877                 self.flags = FL_CLIENT;
878                 self.takedamage = DAMAGE_AIM;
879                 if(g_minstagib)
880                         self.effects = EF_FULLBRIGHT;
881                 else
882                         self.effects = 0;
883                 self.air_finished = time + 12;
884                 self.dmg = 2;
885                 if(autocvar_g_balance_nex_charge)
886                 {
887                         if(autocvar_g_balance_nex_secondary_chargepool)
888                                 self.nex_chargepool_ammo = 1;
889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
890                 }
891
892                 if(inWarmupStage)
893                 {
894                         self.ammo_shells = warmup_start_ammo_shells;
895                         self.ammo_nails = warmup_start_ammo_nails;
896                         self.ammo_rockets = warmup_start_ammo_rockets;
897                         self.ammo_cells = warmup_start_ammo_cells;
898                         self.ammo_fuel = warmup_start_ammo_fuel;
899                         self.health = warmup_start_health;
900                         self.armorvalue = warmup_start_armorvalue;
901                         self.weapons = warmup_start_weapons;
902                 }
903                 else
904                 {
905                         self.ammo_shells = start_ammo_shells;
906                         self.ammo_nails = start_ammo_nails;
907                         self.ammo_rockets = start_ammo_rockets;
908                         self.ammo_cells = start_ammo_cells;
909                         self.ammo_fuel = start_ammo_fuel;
910                         self.health = start_health;
911                         self.armorvalue = start_armorvalue;
912                         self.weapons = start_weapons;
913                 }
914
915                 if(g_weaponarena_random)
916                 {
917                         if(g_weaponarena_random_with_laser)
918                                 self.weapons &~= WEPBIT_LASER;
919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
920                         if(g_weaponarena_random_with_laser)
921                                 self.weapons |= WEPBIT_LASER;
922                 }
923
924                 self.items = start_items;
925                 self.jump_interval = time;
926
927                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
928                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
929                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
930                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
931                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
932                 //extend the pause of rotting if client was reset at the beginning of the countdown
933                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
934                         self.spawnshieldtime += game_starttime - time;
935                         self.pauserotarmor_finished += game_starttime - time;
936                         self.pauserothealth_finished += game_starttime - time;
937                         self.pauseregen_finished += game_starttime - time;
938                 }
939                 self.damageforcescale = 2;
940                 self.death_time = 0;
941                 self.dead_frame = 0;
942                 self.alpha = 0;
943                 self.scale = 0;
944                 self.fade_time = 0;
945                 self.pain_frame = 0;
946                 self.pain_finished = 0;
947                 self.strength_finished = 0;
948                 self.invincible_finished = 0;
949                 self.pushltime = 0;
950                 // players have no think function
951                 self.think = SUB_Null;
952                 self.nextthink = 0;
953                 self.hook_time = 0;
954                 self.dmg_team = 0;
955                 self.ballistics_density = autocvar_g_ballistics_density_player;
956
957                 self.metertime = 0;
958
959                 self.runes = 0;
960
961                 self.deadflag = DEAD_NO;
962
963                 self.angles = spot.angles;
964
965                 self.angles_z = 0; // never spawn tilted even if the spot says to
966                 self.fixangle = TRUE; // turn this way immediately
967                 self.velocity = '0 0 0';
968                 self.avelocity = '0 0 0';
969                 self.punchangle = '0 0 0';
970                 self.punchvector = '0 0 0';
971                 self.oldvelocity = self.velocity;
972                 self.fire_endtime = -1;
973
974                 msg_entity = self;
975                 WRITESPECTATABLE_MSG_ONE({
976                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
977                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
978                 });
979
980                 if(sv_loddistance1)
981                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
982
983                 self.model = "";
984                 FixPlayermodel();
985
986                 self.crouch = FALSE;
987                 self.view_ofs = PL_VIEW_OFS;
988                 setsize (self, PL_MIN, PL_MAX);
989                 self.spawnorigin = spot.origin;
990                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
991                 // don't reset back to last position, even if new position is stuck in solid
992                 self.oldorigin = self.origin;
993                 self.prevorigin = self.origin;
994                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
995
996                 if(g_arena)
997                 {
998                         Spawnqueue_Remove(self);
999                         Spawnqueue_Mark(self);
1000                 }
1001
1002                 else if(g_ca)
1003                         self.caplayer = 1;
1004
1005                 self.event_damage = PlayerDamage;
1006
1007                 self.bot_attack = TRUE;
1008
1009                 self.statdraintime = time + 5;
1010                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1011
1012                 if(self.killcount == -666) {
1013                         PlayerScore_Clear(self);
1014                         self.killcount = 0;
1015                 }
1016
1017                 self.cnt = WEP_LASER;
1018
1019                 CL_SpawnWeaponentity();
1020                 self.alpha = default_player_alpha;
1021                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1022                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1023
1024                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1025                 self.lms_traveled_distance = 0;
1026                 self.speedrunning = FALSE;
1027
1028                 race_PostSpawn(spot);
1029
1030                 if(autocvar_spawn_debug)
1031                 {
1032                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1033                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1034                 }
1035
1036                 //stuffcmd(self, "chase_active 0");
1037                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1038
1039                 if (autocvar_g_spawnsound)
1040                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1041
1042                 if(g_assault) {
1043                         if(self.team == assault_attacker_team)
1044                                 centerprint(self, "You are attacking!");
1045                         else
1046                                 centerprint(self, "You are defending!");
1047                 }
1048
1049                 target_voicescript_clear(self);
1050
1051                 // reset fields the weapons may use
1052                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1053                 {
1054                         weapon_action(j, WR_RESETPLAYER);
1055
1056                         // all weapons must be fully loaded when we spawn
1057                         entity e;
1058                         e = get_weaponinfo(j);
1059                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1060                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1061                 }
1062
1063                 oldself = self;
1064                 self = spot;
1065                         activator = oldself;
1066                                 SUB_UseTargets();
1067                         activator = world;
1068                 self = oldself;
1069
1070                 MUTATOR_CALLHOOK(PlayerSpawn);
1071
1072                 self.switchweapon = w_getbestweapon(self);
1073                 self.cnt = self.switchweapon;
1074                 self.weapon = 0;
1075
1076                 if(!self.alivetime)
1077                         self.alivetime = time;
1078         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1079                 PutObserverInServer ();
1080         }
1081
1082         //if(g_ctf)
1083         //      ctf_playerchanged();
1084 }
1085
1086 .float ebouncefactor, ebouncestop; // electro's values
1087 // TODO do we need all these fields, or should we stop autodetecting runtime
1088 // changes and just have a console command to update this?
1089 float ClientInit_SendEntity(entity to, float sf)
1090 {
1091         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1092         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1097         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1105         if(sv_foginterval && world.fog != "")
1106                 WriteString(MSG_ENTITY, world.fog);
1107         else
1108                 WriteString(MSG_ENTITY, "");
1109         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1110         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1111         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1112         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1113         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1114         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1115         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1116         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1117         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1118         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1119         return TRUE;
1120 }
1121
1122 void ClientInit_CheckUpdate()
1123 {
1124         self.nextthink = time;
1125         if(self.count != autocvar_g_balance_armor_blockpercent)
1126         {
1127                 self.count = autocvar_g_balance_armor_blockpercent;
1128                 self.SendFlags |= 1;
1129         }
1130         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1131         {
1132                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1133                 self.SendFlags |= 1;
1134         }
1135         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1136         {
1137                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1138                 self.SendFlags |= 1;
1139         }
1140         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1141         {
1142                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1143                 self.SendFlags |= 1;
1144         }
1145         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1146         {
1147                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1148                 self.SendFlags |= 1;
1149         }
1150         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1151         {
1152                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1153                 self.SendFlags |= 1;
1154         }
1155 }
1156
1157 void ClientInit_Spawn()
1158 {
1159         entity o;
1160         entity e;
1161         e = spawn();
1162         e.classname = "clientinit";
1163         e.think = ClientInit_CheckUpdate;
1164         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1165
1166         o = self;
1167         self = e;
1168         ClientInit_CheckUpdate();
1169         self = o;
1170 }
1171
1172 /*
1173 =============
1174 SetNewParms
1175 =============
1176 */
1177 void SetNewParms (void)
1178 {
1179         // initialize parms for a new player
1180         parm1 = -(86400 * 366);
1181 }
1182
1183 /*
1184 =============
1185 SetChangeParms
1186 =============
1187 */
1188 void SetChangeParms (void)
1189 {
1190         // save parms for level change
1191         parm1 = self.parm_idlesince - time;
1192 }
1193
1194 /*
1195 =============
1196 DecodeLevelParms
1197 =============
1198 */
1199 void DecodeLevelParms (void)
1200 {
1201         // load parms
1202         self.parm_idlesince = parm1;
1203         if(self.parm_idlesince == -(86400 * 366))
1204                 self.parm_idlesince = time;
1205
1206         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1207         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1208 }
1209
1210 /*
1211 =============
1212 ClientKill
1213
1214 Called when a client types 'kill' in the console
1215 =============
1216 */
1217
1218 .float clientkill_nexttime;
1219 void ClientKill_Now_TeamChange()
1220 {
1221         if(self.killindicator_teamchange == -1)
1222         {
1223                 self.team = -1;
1224                 JoinBestTeam( self, FALSE, FALSE );
1225         }
1226         else if(self.killindicator_teamchange == -2)
1227         {
1228                 if(g_ca)
1229                         self.caplayer = 0;
1230                 if(blockSpectators)
1231                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1232                 PutObserverInServer();
1233         }
1234         else
1235                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1236 }
1237
1238 void ClientKill_Now()
1239 {
1240         remove(self.killindicator);
1241         self.killindicator = world;
1242
1243         if(self.killindicator_teamchange)
1244                 ClientKill_Now_TeamChange();
1245
1246         // in any case:
1247         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1248
1249         // now I am sure the player IS dead
1250 }
1251 void KillIndicator_Think()
1252 {
1253         if (!self.owner.modelindex)
1254         {
1255                 self.owner.killindicator = world;
1256                 remove(self);
1257                 return;
1258         }
1259
1260         if(self.cnt <= 0)
1261         {
1262                 self = self.owner;
1263                 ClientKill_Now(); // no oldself needed
1264                 return;
1265         }
1266     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1267     {
1268         self.nextthink = time + 1;
1269         self.cnt -= 1;
1270     }
1271         else
1272         {
1273                 if(self.cnt <= 10)
1274                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1275                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1276                 {
1277                         if(self.cnt <= 10)
1278                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1279                         if(self.owner.killindicator_teamchange)
1280                         {
1281                                 if(self.owner.killindicator_teamchange == -1)
1282                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1283                                 else if(self.owner.killindicator_teamchange == -2)
1284                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1285                                 else
1286                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1287                         }
1288                         else
1289                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1290                 }
1291                 self.nextthink = time + 1;
1292                 self.cnt -= 1;
1293         }
1294 }
1295
1296 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1297 {
1298         float killtime;
1299         entity e;
1300         killtime = autocvar_g_balance_kill_delay;
1301
1302         if(g_race_qualifying || g_cts)
1303                 killtime = 0;
1304
1305     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1306     {
1307                 remove(self.killindicator);
1308                 self.killindicator = world;
1309
1310         ClientKill_Now(); // allow instant kill in this case
1311         return;
1312     }
1313
1314         self.killindicator_teamchange = targetteam;
1315
1316     if(!self.killindicator)
1317         {
1318                 if(self.modelindex && self.deadflag == DEAD_NO)
1319                 {
1320                         killtime = max(killtime, self.clientkill_nexttime - time);
1321                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1322                 }
1323
1324                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1325                 {
1326                         ClientKill_Now();
1327                 }
1328                 else
1329                 {
1330                         self.killindicator = spawn();
1331                         self.killindicator.owner = self;
1332                         self.killindicator.scale = 0.5;
1333                         setattachment(self.killindicator, self, "");
1334                         setorigin(self.killindicator, '0 0 52');
1335                         self.killindicator.think = KillIndicator_Think;
1336                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1337                         self.killindicator.cnt = ceil(killtime);
1338                         self.killindicator.count = bound(0, ceil(killtime), 10);
1339                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1340
1341                         for(e = world; (e = find(e, classname, "body")) != world; )
1342                         {
1343                                 if(e.enemy != self)
1344                                         continue;
1345                                 e.killindicator = spawn();
1346                                 e.killindicator.owner = e;
1347                                 e.killindicator.scale = 0.5;
1348                                 setattachment(e.killindicator, e, "");
1349                                 setorigin(e.killindicator, '0 0 52');
1350                                 e.killindicator.think = KillIndicator_Think;
1351                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1352                                 e.killindicator.cnt = ceil(killtime);
1353                         }
1354                         self.lip = 0;
1355                 }
1356         }
1357         if(self.killindicator)
1358         {
1359                 if(targetteam == 0) // just die
1360                         self.killindicator.colormod = '0 0 0';
1361                 else if(targetteam == -1) // auto
1362                         self.killindicator.colormod = '0 1 0';
1363                 else if(targetteam == -2) // spectate
1364                         self.killindicator.colormod = '0.5 0.5 0.5';
1365                 else
1366                         self.killindicator.colormod = TeamColor(targetteam);
1367         }
1368 }
1369
1370 void ClientKill (void)
1371 {
1372         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1373         {
1374                 // do nothing
1375         }
1376     else if(self.freezetag_frozen)
1377     {
1378         // do nothing
1379     }
1380         else
1381                 ClientKill_TeamChange(0);
1382 }
1383
1384 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1385 {
1386     e.killindicator = spawn();
1387     e.killindicator.owner = e;
1388     e.killindicator.think = KillIndicator_Think;
1389     e.killindicator.nextthink = time + (e.lip) * 0.05;
1390     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1391     e.killindicator.health = 1; // this is used to indicate that it should be silent
1392     e.lip = 0;
1393 }
1394
1395 void DoTeamChange(float destteam)
1396 {
1397         float t, c0;
1398         if(!teams_matter)
1399         {
1400                 if(destteam >= 0)
1401                         SetPlayerColors(self, destteam);
1402                 return;
1403         }
1404         if(self.classname == "player")
1405         if(destteam == -1)
1406         {
1407                 CheckAllowedTeams(self);
1408                 t = FindSmallestTeam(self, TRUE);
1409                 switch(self.team)
1410                 {
1411                         case COLOR_TEAM1: c0 = c1; break;
1412                         case COLOR_TEAM2: c0 = c2; break;
1413                         case COLOR_TEAM3: c0 = c3; break;
1414                         case COLOR_TEAM4: c0 = c4; break;
1415                         default:          c0 = 999;
1416                 }
1417                 switch(t)
1418                 {
1419                         case 1:
1420                                 if(c0 > c1)
1421                                         destteam = COLOR_TEAM1;
1422                                 break;
1423                         case 2:
1424                                 if(c0 > c2)
1425                                         destteam = COLOR_TEAM2;
1426                                 break;
1427                         case 3:
1428                                 if(c0 > c3)
1429                                         destteam = COLOR_TEAM3;
1430                                 break;
1431                         case 4:
1432                                 if(c0 > c4)
1433                                         destteam = COLOR_TEAM4;
1434                                 break;
1435                 }
1436                 if(destteam == -1)
1437                         return;
1438         }
1439         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1440                 return;
1441         ClientKill_TeamChange(destteam);
1442 }
1443
1444 void FixClientCvars(entity e)
1445 {
1446         // send prediction settings to the client
1447         stuffcmd(e, "\nin_bindmap 0 0\n");
1448         if(g_race || g_cts)
1449                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1450         if(autocvar_g_antilag == 3) // client side hitscan
1451                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1452         if(sv_gentle)
1453                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1454         /*
1455          * we no longer need to stuff this. Remove this comment block if you feel
1456          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1457         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1458         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1459         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1460         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1461         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1462         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1463         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1464         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1465         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1466         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1467         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1468         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1469         stuffcmd(e, "cl_movement_edgefriction 1\n");
1470          */
1471 }
1472
1473 float PlayerInIDList(entity p, string idlist)
1474 {
1475         float n, i;
1476         string s;
1477
1478         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1479         if not(p.crypto_idfp)
1480                 return 0;
1481
1482         // this function allows abbreviated player IDs too!
1483         n = tokenize_console(idlist);
1484         for(i = 0; i < n; ++i)
1485         {
1486                 s = argv(i);
1487                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1488                         return 1;
1489         }
1490
1491         return 0;
1492 }
1493
1494 /*
1495 =============
1496 ClientConnect
1497
1498 Called when a client connects to the server
1499 =============
1500 */
1501 //void ctf_clientconnect();
1502 string ColoredTeamName(float t);
1503 void DecodeLevelParms (void);
1504 //void dom_player_join_team(entity pl);
1505 void ClientConnect (void)
1506 {
1507         float t;
1508
1509         if(self.flags & FL_CLIENT)
1510         {
1511                 print("Warning: ClientConnect, but already connected!\n");
1512                 return;
1513         }
1514
1515         if(Ban_MaybeEnforceBan(self))
1516                 return;
1517
1518         DecodeLevelParms();
1519
1520 #ifdef WATERMARK
1521         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1522 #endif
1523
1524         self.classname = "player_joining";
1525
1526         self.flags = FL_CLIENT;
1527         self.version_nagtime = time + 10 + random() * 10;
1528
1529         if(player_count<0)
1530         {
1531                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1532                 player_count = 0;
1533         }
1534
1535         PlayerScore_Attach(self);
1536         ClientData_Attach();
1537         accuracy_init(self);
1538
1539         bot_clientconnect();
1540
1541         playerdemo_init();
1542
1543         anticheat_init();
1544         
1545         race_PreSpawnObserver();
1546
1547         //if(g_domination)
1548         //      dom_player_join_team(self);
1549
1550         // identify the right forced team
1551         if(autocvar_g_campaign)
1552         {
1553                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1554                 {
1555                         switch(autocvar_g_campaign_forceteam)
1556                         {
1557                                 case 1: self.team_forced = COLOR_TEAM1; break;
1558                                 case 2: self.team_forced = COLOR_TEAM2; break;
1559                                 case 3: self.team_forced = COLOR_TEAM3; break;
1560                                 case 4: self.team_forced = COLOR_TEAM4; break;
1561                                 default: self.team_forced = 0;
1562                         }
1563                 }
1564         }
1565         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1566                 self.team_forced = COLOR_TEAM1;
1567         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1568                 self.team_forced = COLOR_TEAM2;
1569         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1570                 self.team_forced = COLOR_TEAM3;
1571         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1572                 self.team_forced = COLOR_TEAM4;
1573         else if(autocvar_g_forced_team_otherwise == "red")
1574                 self.team_forced = COLOR_TEAM1;
1575         else if(autocvar_g_forced_team_otherwise == "blue")
1576                 self.team_forced = COLOR_TEAM2;
1577         else if(autocvar_g_forced_team_otherwise == "yellow")
1578                 self.team_forced = COLOR_TEAM3;
1579         else if(autocvar_g_forced_team_otherwise == "pink")
1580                 self.team_forced = COLOR_TEAM4;
1581         else if(autocvar_g_forced_team_otherwise == "spectate")
1582                 self.team_forced = -1;
1583         else if(autocvar_g_forced_team_otherwise == "spectator")
1584                 self.team_forced = -1;
1585         else
1586                 self.team_forced = 0;
1587
1588         if(!teams_matter)
1589                 if(self.team_forced > 0)
1590                         self.team_forced = 0;
1591
1592         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1593
1594         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1595                 self.classname = "observer";
1596         } else {
1597                 if(teams_matter)
1598                 {
1599                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1600                         {
1601                                 self.classname = "player";
1602                                 campaign_bots_may_start = 1;
1603                         }
1604                         else
1605                         {
1606                                 self.classname = "observer"; // do it anyway
1607                         }
1608                 }
1609                 else
1610                 {
1611                         self.classname = "player";
1612                         campaign_bots_may_start = 1;
1613                 }
1614         }
1615
1616         self.playerid = (playerid_last = playerid_last + 1);
1617
1618         if(autocvar_sv_eventlog)
1619                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1620
1621         LogTeamchange(self.playerid, self.team, 1);
1622
1623         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1624
1625         self.netname_previous = strzone(self.netname);
1626
1627         bprint("^4", self.netname, "^4 connected");
1628
1629         if(self.classname != "observer" && (g_domination || g_ctf))
1630                 bprint(" and joined the ", ColoredTeamName(self.team));
1631
1632         bprint("\n");
1633
1634         self.welcomemessage_time = 0;
1635
1636         stuffcmd(self, strcat(clientstuff, "\n"));
1637         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1638         stuffcmd(self, "cl_particles_reloadeffects\n");
1639
1640         FixClientCvars(self);
1641
1642         // spawnfunc_waypoint sprites
1643         WaypointSprite_InitClient(self);
1644
1645         // Wazat's grappling hook
1646         SetGrappleHookBindings();
1647
1648         // get autoswitch state from player when he toggles it
1649         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1650
1651         // get version info from player
1652         stuffcmd(self, "cmd clientversion $gameversion\n");
1653
1654         // get other cvars from player
1655         GetCvars(0);
1656
1657         // notify about available teams
1658         if(teams_matter)
1659         {
1660                 CheckAllowedTeams(self);
1661                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1662                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1663         }
1664         else
1665                 stuffcmd(self, "set _teams_available 0\n");
1666
1667         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1668
1669         if(g_arena || g_ca)
1670         {
1671                 self.classname = "observer";
1672                 if(g_arena)
1673                         Spawnqueue_Insert(self);
1674         }
1675         /*else if(g_ctf)
1676         {
1677                 ctf_clientconnect();
1678         }*/
1679
1680         if(teams_matter || radar_showennemies)
1681                 attach_entcs();
1682
1683         bot_relinkplayerlist();
1684
1685         self.spectatortime = time;
1686         if(blockSpectators)
1687         {
1688                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1689         }
1690
1691         self.jointime = time;
1692         self.allowedTimeouts = autocvar_sv_timeout_number;
1693
1694         if(clienttype(self) == CLIENTTYPE_REAL)
1695         {
1696                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1697                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1698         }
1699
1700         if(g_lms)
1701         {
1702                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1703                 {
1704                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1705                         self.frags = FRAGS_SPECTATOR;
1706                 }
1707         }
1708
1709         if(!sv_foginterval && world.fog != "")
1710                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1711
1712         SoundEntity_Attach(self);
1713
1714         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1715         {
1716                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1717                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1718         }
1719         else
1720                 self.hitplotfh = -1;
1721
1722         if(g_race || g_cts) {
1723                 string rr;
1724                 if(g_cts)
1725                         rr = CTS_RECORD;
1726                 else
1727                         rr = RACE_RECORD;
1728                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1729
1730                 msg_entity = self;
1731                 race_send_recordtime(MSG_ONE);
1732                 race_send_speedaward(MSG_ONE);
1733
1734                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1735                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1736                 race_send_speedaward_alltimebest(MSG_ONE);
1737
1738                 float i;
1739                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1740                         race_SendRankings(i, 0, 0, MSG_ONE);
1741                 }
1742         }
1743         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1744                 send_CSQC_teamnagger();
1745
1746         CheatInitClient();
1747
1748         PlayerStats_AddPlayer(self);
1749 }
1750
1751 /*
1752 =============
1753 ClientDisconnect
1754
1755 Called when a client disconnects from the server
1756 =============
1757 */
1758 .entity chatbubbleentity;
1759 .entity teambubbleentity;
1760 void ReadyCount();
1761 void ClientDisconnect (void)
1762 {
1763         if not(self.flags & FL_CLIENT)
1764         {
1765                 print("Warning: ClientDisconnect without ClientConnect\n");
1766                 return;
1767         }
1768
1769         PlayerStats_AddGlobalInfo(self);
1770
1771         CheatShutdownClient();
1772
1773         if(self.hitplotfh >= 0)
1774         {
1775                 fclose(self.hitplotfh);
1776                 self.hitplotfh = -1;
1777         }
1778
1779         anticheat_report();
1780         anticheat_shutdown();
1781
1782         playerdemo_shutdown();
1783
1784         bot_clientdisconnect();
1785
1786         if(self.entcs)
1787                 detach_entcs();
1788
1789         if(autocvar_sv_eventlog)
1790                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1791         bprint ("^4",self.netname);
1792         bprint ("^4 disconnected\n");
1793
1794         SoundEntity_Detach(self);
1795
1796         DropAllRunes(self);
1797         MUTATOR_CALLHOOK(ClientDisconnect);
1798
1799         Portal_ClearAll(self);
1800
1801         if(self.flagcarried)
1802                 DropFlag(self.flagcarried, world, world);
1803         if(self.ballcarried && g_nexball)
1804                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1805
1806         // Here, everything has been done that requires this player to be a client.
1807
1808         self.flags &~= FL_CLIENT;
1809
1810         if (self.chatbubbleentity)
1811                 remove (self.chatbubbleentity);
1812
1813         if (self.teambubbleentity)
1814                 remove (self.teambubbleentity);
1815
1816         if (self.killindicator)
1817                 remove (self.killindicator);
1818
1819         WaypointSprite_PlayerGone();
1820
1821         bot_relinkplayerlist();
1822
1823         if(g_arena)
1824         {
1825                 Spawnqueue_Unmark(self);
1826                 Spawnqueue_Remove(self);
1827         }
1828
1829         accuracy_free(self);
1830         ClientData_Detach();
1831         PlayerScore_Detach(self);
1832
1833         if(self.netname_previous)
1834                 strunzone(self.netname_previous);
1835         if(self.clientstatus)
1836                 strunzone(self.clientstatus);
1837         if(self.weaponorder_byimpulse)
1838                 strunzone(self.weaponorder_byimpulse);
1839
1840         ClearPlayerSounds();
1841
1842         if(self.personal)
1843                 remove(self.personal);
1844
1845         self.playerid = 0;
1846         ReadyCount();
1847
1848         // free cvars
1849         GetCvars(-1);
1850 }
1851
1852 .float BUTTON_CHAT;
1853 void ChatBubbleThink()
1854 {
1855         self.nextthink = time;
1856         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1857         {
1858                 if(self.owner) // but why can that ever be world?
1859                         self.owner.chatbubbleentity = world;
1860                 remove(self);
1861                 return;
1862         }
1863         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1864 #ifdef TETRIS
1865                 || self.owner.tetris_on
1866 #endif
1867         )
1868                 self.model = self.mdl;
1869         else
1870                 self.model = "";
1871 };
1872
1873 void UpdateChatBubble()
1874 {
1875         if (!self.modelindex)
1876                 return;
1877         // spawn a chatbubble entity if needed
1878         if (!self.chatbubbleentity)
1879         {
1880                 self.chatbubbleentity = spawn();
1881                 self.chatbubbleentity.owner = self;
1882                 self.chatbubbleentity.exteriormodeltoclient = self;
1883                 self.chatbubbleentity.think = ChatBubbleThink;
1884                 self.chatbubbleentity.nextthink = time;
1885                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1886                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1887                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1888                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1889                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1890                 self.chatbubbleentity.model = "";
1891                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1892         }
1893 }
1894
1895
1896 void TeamBubbleThink()
1897 {
1898         self.nextthink = time;
1899         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1900         {
1901                 if(self.owner) // but why can that ever be world?
1902                         self.owner.teambubbleentity = world;
1903                 remove(self);
1904                 return;
1905         }
1906 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1907         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1908                 self.model = "";
1909         else
1910                 self.model = self.mdl;
1911
1912 };
1913
1914 float TeamBubble_customizeentityforclient()
1915 {
1916         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1917 }
1918
1919 void UpdateTeamBubble()
1920 {
1921         if (!self.modelindex || !teams_matter)
1922                 return;
1923         // spawn a teambubble entity if needed
1924         if (!self.teambubbleentity && teams_matter)
1925         {
1926                 self.teambubbleentity = spawn();
1927                 self.teambubbleentity.owner = self;
1928                 self.teambubbleentity.exteriormodeltoclient = self;
1929                 self.teambubbleentity.think = TeamBubbleThink;
1930                 self.teambubbleentity.nextthink = time;
1931                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1932 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1933                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1934                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1935                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1936                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1937                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1938                 self.teambubbleentity.effects = EF_LOWPRECISION;
1939         }
1940 }
1941
1942 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1943 // added to the model skins
1944 /*void UpdateColorModHack()
1945 {
1946         local float c;
1947         c = self.clientcolors & 15;
1948         // LordHavoc: only bothering to support white, green, red, yellow, blue
1949              if (!teams_matter) self.colormod = '0 0 0';
1950         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1951         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1952         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1953         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1954         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1955         else self.colormod = '1 1 1';
1956 };*/
1957
1958 .float oldcolormap;
1959 void respawn(void)
1960 {
1961         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1962         {
1963                 self.solid = SOLID_NOT;
1964                 self.takedamage = DAMAGE_NO;
1965                 self.movetype = MOVETYPE_FLY;
1966                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1967                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1968                 self.effects |= EF_ADDITIVE;
1969                 self.oldcolormap = self.colormap;
1970                 self.colormap = 512;
1971                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1972                 if(autocvar_g_respawn_ghosts_maxtime)
1973                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1974         }
1975
1976         CopyBody(1);
1977         self.effects |= EF_NODRAW; // prevent another CopyBody
1978         if(self.oldcolormap)
1979         {
1980                 self.colormap = self.oldcolormap;
1981                 self.oldcolormap = 0;
1982         }
1983         PutClientInServer();
1984 }
1985
1986 void play_countdown(float finished, string samp)
1987 {
1988         if(clienttype(self) == CLIENTTYPE_REAL)
1989                 if(floor(finished - time - frametime) != floor(finished - time))
1990                         if(finished - time < 6)
1991                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1992 }
1993
1994 /**
1995  * When sv_timeout is used this function returs strings like
1996  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1997  * Called by centerprint functions
1998  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1999  */
2000 string getTimeoutText(float addOneSecond) {
2001         if (!autocvar_sv_timeout || !timeoutStatus)
2002                 return "";
2003
2004         local string retStr;
2005         if (timeoutStatus == 1) {
2006                 if (addOneSecond == 1) {
2007                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2008                 }
2009                 else {
2010                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2011                 }
2012                 return retStr;
2013         }
2014         else if (timeoutStatus == 2) {
2015                 if (addOneSecond) {
2016                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2017                         //don't show messages like "Timeout ends in 0 seconds"...
2018                         if ((remainingTimeoutTime + 1) > 0)
2019                                 return retStr;
2020                         else
2021                                 return "";
2022                 }
2023                 else {
2024                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2025                         //don't show messages like "Timeout ends in 0 seconds"...
2026                         if (remainingTimeoutTime > 0)
2027                                 return retStr;
2028                         else
2029                                 return "";
2030                 }
2031         }
2032         else return "";
2033 }
2034
2035 void player_powerups (void)
2036 {
2037         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2038         olditems = self.items;
2039         
2040         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2041         {
2042                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2043                 self.modelflags |= MF_ROCKET;
2044         }
2045         else
2046         {
2047                 SoundEntity_StopSound(self, CHAN_PLAYER);
2048                 self.modelflags &~= MF_ROCKET;
2049         }
2050
2051         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2052
2053         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2054                 return;
2055         
2056         Fire_ApplyDamage(self);
2057         Fire_ApplyEffect(self);
2058
2059         if (g_minstagib)
2060         {
2061                 self.effects |= EF_FULLBRIGHT;
2062
2063                 if (self.items & IT_STRENGTH)
2064                 {
2065                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2066                         if (time > self.strength_finished)
2067                         {
2068                                 self.alpha = default_player_alpha;
2069                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2070                                 self.items &~= IT_STRENGTH;
2071                                 sprint(self, "^3Invisibility has worn off\n");
2072                         }
2073                 }
2074                 else
2075                 {
2076                         if (time < self.strength_finished)
2077                         {
2078                                 self.alpha = g_minstagib_invis_alpha;
2079                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2080                                 self.items |= IT_STRENGTH;
2081                                 sprint(self, "^3You are invisible\n");
2082                         }
2083                 }
2084
2085                 if (self.items & IT_INVINCIBLE)
2086                 {
2087                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2088                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2089                         {
2090                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2091                                 sprint(self, "^3Speed has worn off\n");
2092                         }
2093                 }
2094                 else
2095                 {
2096                         if (time < self.invincible_finished)
2097                         {
2098                                 self.items = self.items | IT_INVINCIBLE;
2099                                 sprint(self, "^3You are on speed\n");
2100                         }
2101                 }
2102         }
2103         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2104         {
2105                 if (self.items & IT_STRENGTH)
2106                 {
2107                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2108                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2109                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2110                         {
2111                                 self.items = self.items - (self.items & IT_STRENGTH);
2112                                 sprint(self, "^3Strength has worn off\n");
2113                         }
2114                 }
2115                 else
2116                 {
2117                         if (time < self.strength_finished)
2118                         {
2119                                 self.items = self.items | IT_STRENGTH;
2120                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2121                         }
2122                 }
2123                 if (self.items & IT_INVINCIBLE)
2124                 {
2125                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2126                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2127                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2128                         {
2129                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2130                                 sprint(self, "^3Shield has worn off\n");
2131                         }
2132                 }
2133                 else
2134                 {
2135                         if (time < self.invincible_finished)
2136                         {
2137                                 self.items = self.items | IT_INVINCIBLE;
2138                                 sprint(self, "^3Shield surrounds you\n");
2139                         }
2140                 }
2141
2142                 if(autocvar_g_nodepthtestplayers)
2143                         self.effects = self.effects | EF_NODEPTHTEST;
2144
2145                 if(autocvar_g_fullbrightplayers)
2146                         self.effects = self.effects | EF_FULLBRIGHT;
2147
2148                 // midair gamemode: damage only while in the air
2149                 // if in midair mode, being on ground grants temporary invulnerability
2150                 // (this is so that multishot weapon don't clear the ground flag on the
2151                 // first damage in the frame, leaving the player vulnerable to the
2152                 // remaining hits in the same frame)
2153                 if (self.flags & FL_ONGROUND)
2154                 if (g_midair)
2155                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2156
2157                 if (time >= game_starttime)
2158                 if (time < self.spawnshieldtime)
2159                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2160         }
2161         
2162         MUTATOR_CALLHOOK(PlayerPowerups);
2163 }
2164
2165 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2166 {
2167         if(current > stable)
2168                 return current;
2169         else if(current > stable - 0.25) // when close enough, "snap"
2170                 return stable;
2171         else
2172                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2173 }
2174
2175 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2176 {
2177         if(current < stable)
2178                 return current;
2179         else if(current < stable + 0.25) // when close enough, "snap"
2180                 return stable;
2181         else
2182                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2183 }
2184
2185 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2186 {
2187         if(current > rotstable)
2188         {
2189                 if(rotframetime > 0)
2190                 {
2191                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2192                         current = max(rotstable, current - rotlinear * rotframetime);
2193                 }
2194         }
2195         else if(current < regenstable)
2196         {
2197                 if(regenframetime > 0)
2198                 {
2199                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2200                         current = min(regenstable, current + regenlinear * regenframetime);
2201                 }
2202         }
2203
2204         if(current > limit)
2205                 current = limit;
2206
2207         return current;
2208 }
2209
2210 void player_regen (void)
2211 {
2212         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2213         maxh = autocvar_g_balance_health_rotstable;
2214         maxa = autocvar_g_balance_armor_rotstable;
2215         maxf = autocvar_g_balance_fuel_rotstable;
2216         minh = autocvar_g_balance_health_regenstable;
2217         mina = autocvar_g_balance_armor_regenstable;
2218         minf = autocvar_g_balance_fuel_regenstable;
2219         limith = autocvar_g_balance_health_limit;
2220         limita = autocvar_g_balance_armor_limit;
2221         limitf = autocvar_g_balance_fuel_limit;
2222
2223         max_mod = regen_mod = rot_mod = limit_mod = 1;
2224
2225         if (self.runes & RUNE_REGEN)
2226         {
2227                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2228                 {
2229                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2230                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2231                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2232                 }
2233                 else
2234                 {
2235                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2236                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2237                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2238                 }
2239         }
2240         else if (self.runes & CURSE_VENOM)
2241         {
2242                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2243                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2244                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2245                 else
2246                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2247                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2248                 //if (!self.runes & RUNE_REGEN)
2249                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2250         }
2251         maxh = maxh * max_mod;
2252         //maxa = maxa * max_mod;
2253         //maxf = maxf * max_mod;
2254         minh = minh * max_mod;
2255         //mina = mina * max_mod;
2256         //minf = minf * max_mod;
2257         limith = limith * limit_mod;
2258         limita = limita * limit_mod;
2259         //limitf = limitf * limit_mod;
2260
2261         if(g_lms && g_ca)
2262                 rot_mod = 0;
2263
2264         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2265         {
2266                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2267                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2268
2269                 // if player rotted to death...  die!
2270                 if(self.health < 1)
2271                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2272         }
2273
2274         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2275                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2276 }
2277
2278 float zoomstate_set;
2279 void SetZoomState(float z)
2280 {
2281         if(z != self.zoomstate)
2282         {
2283                 self.zoomstate = z;
2284                 ClientData_Touch(self);
2285         }
2286         zoomstate_set = 1;
2287 }
2288
2289 void GetPressedKeys(void) {
2290         MUTATOR_CALLHOOK(GetPressedKeys);
2291         if (self.movement_x > 0) // get if movement keys are pressed
2292         {       // forward key pressed
2293                 self.pressedkeys |= KEY_FORWARD;
2294                 self.pressedkeys &~= KEY_BACKWARD;
2295         }
2296         else if (self.movement_x < 0)
2297         {       // backward key pressed
2298                 self.pressedkeys |= KEY_BACKWARD;
2299                 self.pressedkeys &~= KEY_FORWARD;
2300         }
2301         else
2302         {       // no x input
2303                 self.pressedkeys &~= KEY_FORWARD;
2304                 self.pressedkeys &~= KEY_BACKWARD;
2305         }
2306
2307         if (self.movement_y > 0)
2308         {       // right key pressed
2309                 self.pressedkeys |= KEY_RIGHT;
2310                 self.pressedkeys &~= KEY_LEFT;
2311         }
2312         else if (self.movement_y < 0)
2313         {       // left key pressed
2314                 self.pressedkeys |= KEY_LEFT;
2315                 self.pressedkeys &~= KEY_RIGHT;
2316         }
2317         else
2318         {       // no y input
2319                 self.pressedkeys &~= KEY_RIGHT;
2320                 self.pressedkeys &~= KEY_LEFT;
2321         }
2322
2323         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2324                 self.pressedkeys |= KEY_JUMP;
2325         else
2326                 self.pressedkeys &~= KEY_JUMP;
2327         if (self.BUTTON_CROUCH)
2328                 self.pressedkeys |= KEY_CROUCH;
2329         else
2330                 self.pressedkeys &~= KEY_CROUCH;
2331 }
2332
2333 /*
2334 ======================
2335 spectate mode routines
2336 ======================
2337 */
2338
2339 void SpectateCopy(entity spectatee) {
2340         other = spectatee;
2341         MUTATOR_CALLHOOK(SpectateCopy);
2342         self.armortype = spectatee.armortype;
2343         self.armorvalue = spectatee.armorvalue;
2344         self.ammo_cells = spectatee.ammo_cells;
2345         self.ammo_shells = spectatee.ammo_shells;
2346         self.ammo_nails = spectatee.ammo_nails;
2347         self.ammo_rockets = spectatee.ammo_rockets;
2348         self.ammo_fuel = spectatee.ammo_fuel;
2349         self.clip_load = spectatee.clip_load;
2350         self.clip_size = spectatee.clip_size;
2351         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2352         self.health = spectatee.health;
2353         self.impulse = 0;
2354         self.items = spectatee.items;
2355         self.last_pickup = spectatee.last_pickup;
2356         self.hit_time = spectatee.hit_time;
2357         self.metertime = spectatee.metertime;
2358         self.strength_finished = spectatee.strength_finished;
2359         self.invincible_finished = spectatee.invincible_finished;
2360         self.pressedkeys = spectatee.pressedkeys;
2361         self.weapons = spectatee.weapons;
2362         self.switchweapon = spectatee.switchweapon;
2363         self.weapon = spectatee.weapon;
2364         self.punchangle = spectatee.punchangle;
2365         self.view_ofs = spectatee.view_ofs;
2366         self.v_angle = spectatee.v_angle;
2367         self.velocity = spectatee.velocity;
2368         self.dmg_take = spectatee.dmg_take;
2369         self.dmg_save = spectatee.dmg_save;
2370         self.dmg_inflictor = spectatee.dmg_inflictor;
2371         self.angles = spectatee.v_angle;
2372         self.fixangle = TRUE;
2373         setorigin(self, spectatee.origin);
2374         setsize(self, spectatee.mins, spectatee.maxs);
2375         SetZoomState(spectatee.zoomstate);
2376
2377         anticheat_spectatecopy(spectatee);
2378 }
2379
2380 float SpectateUpdate() {
2381         if(!self.enemy)
2382                 return 0;
2383
2384         if (self == self.enemy)
2385                 return 0;
2386
2387         if(self.enemy.classname != "player")
2388                 return 0;
2389
2390         SpectateCopy(self.enemy);
2391
2392         return 1;
2393 }
2394
2395 float SpectateNext() {
2396         other = find(self.enemy, classname, "player");
2397
2398         if (!other)
2399                 other = find(other, classname, "player");
2400
2401         if (other)
2402                 self.enemy = other;
2403
2404         if(self.enemy.classname == "player") {
2405                 msg_entity = self;
2406                 WriteByte(MSG_ONE, SVC_SETVIEW);
2407                 WriteEntity(MSG_ONE, self.enemy);
2408                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2409                 self.movetype = MOVETYPE_NONE;
2410                 accuracy_resend(self);
2411
2412                 if(!SpectateUpdate())
2413                         PutObserverInServer();
2414
2415                 return 1;
2416         } else {
2417                 return 0;
2418         }
2419 }
2420
2421 /*
2422 =============
2423 ShowRespawnCountdown()
2424
2425 Update a respawn countdown display.
2426 =============
2427 */
2428 void ShowRespawnCountdown()
2429 {
2430         float number;
2431         if(self.deadflag == DEAD_NO) // just respawned?
2432                 return;
2433         else
2434         {
2435                 number = ceil(self.death_time - time);
2436                 if(number <= 0)
2437                         return;
2438                 if(number <= self.respawn_countdown)
2439                 {
2440                         self.respawn_countdown = number - 1;
2441                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2442                                 AnnounceTo(self, strcat(ftos(number), ""));
2443                 }
2444         }
2445 }
2446
2447 void LeaveSpectatorMode()
2448 {
2449         if(nJoinAllowed(1)) {
2450                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2451                         self.classname = "player";
2452
2453                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2454                                 JoinBestTeam(self, FALSE, TRUE);
2455
2456                         if(autocvar_g_campaign)
2457                                 campaign_bots_may_start = 1;
2458
2459                         PutClientInServer();
2460
2461                         if(self.classname == "player")
2462                                 bprint ("^4", self.netname, "^4 is playing now\n");
2463
2464                         if(!autocvar_g_campaign)
2465                                 centerprint(self,""); // clear MOTD
2466
2467                         return;
2468                 } else {
2469                         if (g_ca && self.caplayer) {
2470                         }       // do nothing
2471                         else
2472                                 stuffcmd(self,"menu_showteamselect\n");
2473                         return;
2474                 }
2475         }
2476         else {
2477                 //player may not join because of g_maxplayers is set
2478                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2479         }
2480 }
2481
2482 /**
2483  * Determines whether the player is allowed to join. This depends on cvar
2484  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2485  * it checks whether the number of currently playing players exceeds g_maxplayers.
2486  * @return int number of free slots for players, 0 if none
2487  */
2488 float nJoinAllowed(float includeMe) {
2489         if(self.team_forced < 0)
2490                 return FALSE; // forced spectators can never join
2491
2492         // TODO simplify this
2493         local entity e;
2494
2495         local float totalClients;
2496         FOR_EACH_CLIENT(e)
2497                 totalClients += 1;
2498
2499         if (!autocvar_g_maxplayers)
2500                 return maxclients - totalClients + includeMe;
2501
2502         local float currentlyPlaying;
2503         FOR_EACH_REALPLAYER(e)
2504                 currentlyPlaying += 1;
2505
2506         if(currentlyPlaying < autocvar_g_maxplayers)
2507                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2508
2509         return 0;
2510 }
2511
2512 /**
2513  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2514  * g_maxplayers_spectator_blocktime seconds
2515  */
2516 void checkSpectatorBlock() {
2517         if(self.classname == "spectator" || self.classname == "observer") {
2518                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2519                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2520                         dropclient(self);
2521                 }
2522         }
2523 }
2524
2525 void ObserverThink()
2526 {
2527         if (self.flags & FL_JUMPRELEASED) {
2528                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2529                         self.welcomemessage_time = 0;
2530                         self.flags &~= FL_JUMPRELEASED;
2531                         self.flags |= FL_SPAWNING;
2532                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2533                         self.welcomemessage_time = 0;
2534                         self.flags &~= FL_JUMPRELEASED;
2535                         if(SpectateNext() == 1) {
2536                                 self.classname = "spectator";
2537                         }
2538                 }
2539         } else {
2540                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2541                         self.flags |= FL_JUMPRELEASED;
2542                         if(self.flags & FL_SPAWNING)
2543                         {
2544                                 self.flags &~= FL_SPAWNING;
2545                                 LeaveSpectatorMode();
2546                                 return;
2547                         }
2548                 }
2549         }
2550         PrintWelcomeMessage(self);
2551 }
2552
2553 void SpectatorThink()
2554 {
2555         if (self.flags & FL_JUMPRELEASED) {
2556                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2557                         self.welcomemessage_time = 0;
2558                         self.flags &~= FL_JUMPRELEASED;
2559                         self.flags |= FL_SPAWNING;
2560                 } else if(self.BUTTON_ATCK) {
2561                         self.welcomemessage_time = 0;
2562                         self.flags &~= FL_JUMPRELEASED;
2563                         if(SpectateNext() == 1) {
2564                                 self.classname = "spectator";
2565                         } else {
2566                                 self.classname = "observer";
2567                                 PutClientInServer();
2568                         }
2569                 } else if (self.BUTTON_ATCK2) {
2570                         self.welcomemessage_time = 0;
2571                         self.flags &~= FL_JUMPRELEASED;
2572                         self.classname = "observer";
2573                         PutClientInServer();
2574                 } else {
2575                         if(!SpectateUpdate())
2576                                 PutObserverInServer();
2577                 }
2578         } else {
2579                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2580                         self.flags |= FL_JUMPRELEASED;
2581                         if(self.flags & FL_SPAWNING)
2582                         {
2583                                 self.flags &~= FL_SPAWNING;
2584                                 LeaveSpectatorMode();
2585                                 return;
2586                         }
2587                 }
2588         }
2589
2590         PrintWelcomeMessage(self);
2591         self.flags |= FL_CLIENT | FL_NOTARGET;
2592 }
2593
2594 .float touchexplode_time;
2595
2596 /*
2597 =============
2598 PlayerPreThink
2599
2600 Called every frame for each client before the physics are run
2601 =============
2602 */
2603 void() ctf_setstatus;
2604 void() nexball_setstatus;
2605 .float items_added;
2606 void PlayerPreThink (void)
2607 {
2608         self.stat_game_starttime = game_starttime;
2609         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2610         self.stat_leadlimit = autocvar_leadlimit;
2611
2612         if(frametime)
2613         {
2614                 // physics frames: update anticheat stuff
2615                 anticheat_prethink();
2616         }
2617
2618         if(blockSpectators && frametime)
2619                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2620                 checkSpectatorBlock();
2621
2622         zoomstate_set = 0;
2623
2624         if(self.netname_previous != self.netname)
2625         {
2626                 if(autocvar_sv_eventlog)
2627                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2628                 if(self.netname_previous)
2629                         strunzone(self.netname_previous);
2630                 self.netname_previous = strzone(self.netname);
2631         }
2632
2633         // version nagging
2634         if(self.version_nagtime)
2635                 if(self.cvar_g_xonoticversion)
2636                         if(time > self.version_nagtime)
2637                         {
2638                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2639                                 {
2640                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2641                                         {
2642                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2643                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2644                                         }
2645                                         else
2646                                         {
2647                                                 float r;
2648                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2649                                                 if(r < 0)
2650                                                 {
2651                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2652                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2653                                                 }
2654                                                 else if(r > 0)
2655                                                 {
2656                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2657                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2658                                                 }
2659                                         }
2660                                 }
2661                                 self.version_nagtime = 0;
2662                         }
2663
2664         // GOD MODE info
2665         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2666         {
2667                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2668                 self.max_armorvalue = 0;
2669         }
2670
2671 #ifdef TETRIS
2672         if (TetrisPreFrame())
2673                 return;
2674 #endif
2675
2676         MUTATOR_CALLHOOK(PlayerPreThink);
2677
2678         if(self.classname == "player") {
2679 //              if(self.netname == "Wazat")
2680 //                      bprint(self.classname, "\n");
2681
2682                 CheckRules_Player();
2683
2684                 PrintWelcomeMessage(self);
2685
2686                 if (intermission_running)
2687                 {
2688                         IntermissionThink ();   // otherwise a button could be missed between
2689                         return;                                 // the think tics
2690                 }
2691
2692                 if(self.teleport_time)
2693                 if(time > self.teleport_time)
2694                 {
2695                         self.teleport_time = 0;
2696                         self.effects = self.effects - (self.effects & EF_NODRAW);
2697                 }
2698
2699                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2700                         UpdateSelectedPlayer();
2701
2702                 //don't allow the player to turn around while game is paused!
2703                 if(timeoutStatus == 2) {
2704                         self.v_angle = self.lastV_angle;
2705                         self.angles = self.lastV_angle;
2706                         self.fixangle = TRUE;
2707                 }
2708
2709                 if(frametime)
2710                 {
2711                         if(self.health <= 0 && autocvar_g_deathglow)
2712                         {
2713                                 if(self.glowmod_x > 0)
2714                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2715                                 else
2716                                         self.glowmod_x = -1;
2717                                 if(self.glowmod_y > 0)
2718                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2719                                 else
2720                                         self.glowmod_y = -1;
2721                                 if(self.glowmod_z > 0)
2722                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2723                                 else
2724                                         self.glowmod_z = -1;
2725                         }
2726                         else
2727                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2728                         player_powerups();
2729                 }
2730
2731                 if (self.deadflag != DEAD_NO)
2732                 {
2733                         float button_pressed, force_respawn;
2734                         if(self.personal && g_race_qualifying)
2735                         {
2736                                 if(time > self.death_time)
2737                                 {
2738                                         self.death_time = time + 1; // only retry once a second
2739                                         respawn();
2740                                         self.impulse = 141;
2741                                 }
2742                         }
2743                         else
2744                         {
2745                                 if(frametime)
2746                                         player_anim();
2747                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2748                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2749                                 if (self.deadflag == DEAD_DYING)
2750                                 {
2751                                         if(force_respawn)
2752                                                 self.deadflag = DEAD_RESPAWNING;
2753                                         else if(!button_pressed)
2754                                                 self.deadflag = DEAD_DEAD;
2755                                 }
2756                                 else if (self.deadflag == DEAD_DEAD)
2757                                 {
2758                                         if(button_pressed)
2759                                                 self.deadflag = DEAD_RESPAWNABLE;
2760                                 }
2761                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2762                                 {
2763                                         if(!button_pressed)
2764                                                 self.deadflag = DEAD_RESPAWNING;
2765                                 }
2766                                 else if (self.deadflag == DEAD_RESPAWNING)
2767                                 {
2768                                         if(time > self.death_time)
2769                                         {
2770                                                 self.death_time = time + 1; // only retry once a second
2771                                                 respawn();
2772                                         }
2773                                 }
2774                                 ShowRespawnCountdown();
2775                         }
2776                         return;
2777                 }
2778
2779                 if(g_touchexplode)
2780                 if(time > self.touchexplode_time)
2781                 if(self.classname == "player")
2782                 if(self.deadflag == DEAD_NO)
2783                 if not(IS_INDEPENDENT_PLAYER(self))
2784                 FOR_EACH_PLAYER(other) if(self != other)
2785                 {
2786                         if(time > other.touchexplode_time)
2787                         if(other.deadflag == DEAD_NO)
2788                         if not(IS_INDEPENDENT_PLAYER(other))
2789                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2790                         {
2791                                 PlayerTouchExplode(self, other);
2792                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2793                         }
2794                 }
2795
2796                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2797                 {
2798                         vector dist;
2799
2800                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2801                         dist = self.prevorigin - self.origin;
2802                         dist_z = 0;
2803                         self.lms_traveled_distance += fabs(vlen(dist));
2804
2805                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2806                         {
2807                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2808                                 self.lms_traveled_distance = 0;
2809                         }
2810
2811                         if(time > self.lms_nextcheck)
2812                         {
2813                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2814                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2815                                 {
2816                                         centerprint(self, autocvar_g_lms_campcheck_message);
2817                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2818                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2819                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2820                                 }
2821                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2822                                 self.lms_traveled_distance = 0;
2823                         }
2824                 }
2825
2826                 self.prevorigin = self.origin;
2827
2828                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2829                 {
2830                         if (!self.crouch)
2831                         {
2832                                 self.crouch = TRUE;
2833                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2834                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2835                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2836                         }
2837                 }
2838                 else
2839                 {
2840                         if (self.crouch)
2841                         {
2842                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2843                                 if (!trace_startsolid)
2844                                 {
2845                                         self.crouch = FALSE;
2846                                         self.view_ofs = PL_VIEW_OFS;
2847                                         setsize (self, PL_MIN, PL_MAX);
2848                                 }
2849                         }
2850                 }
2851
2852                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2853                 {
2854                         if(self.bloodloss_timer < time)
2855                         {
2856                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2857                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2858                         }
2859                 }
2860
2861                 FixPlayermodel();
2862
2863                 GrapplingHookFrame();
2864
2865                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2866                 //if(frametime)
2867                 {
2868                         self.items &~= self.items_added;
2869
2870                         W_WeaponFrame();
2871
2872                         self.items_added = 0;
2873                         if(self.items & IT_JETPACK)
2874                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2875                                         self.items_added |= IT_FUEL;
2876
2877                         self.items |= self.items_added;
2878                 }
2879
2880                 player_regen();
2881
2882                 // rot nex charge to the charge limit
2883                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2884                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2885
2886                 if(frametime)
2887                         player_anim();
2888
2889                 if (g_minstagib)
2890                         minstagib_ammocheck();
2891
2892                 if(g_ctf)
2893                         ctf_setstatus();
2894
2895                 if(g_nexball)
2896                         nexball_setstatus();
2897
2898                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2899
2900                 //self.angles_y=self.v_angle_y + 90;   // temp
2901         } else if(gameover) {
2902                 if (intermission_running)
2903                         IntermissionThink ();   // otherwise a button could be missed between
2904                 return;
2905         } else if(self.classname == "observer") {
2906                 ObserverThink();
2907         } else if(self.classname == "spectator") {
2908                 SpectatorThink();
2909         }
2910
2911         if(!zoomstate_set)
2912                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2913
2914         float oldspectatee_status;
2915         oldspectatee_status = self.spectatee_status;
2916         if(self.classname == "spectator")
2917                 self.spectatee_status = num_for_edict(self.enemy);
2918         else if(self.classname == "observer")
2919                 self.spectatee_status = num_for_edict(self);
2920         else
2921                 self.spectatee_status = 0;
2922         if(self.spectatee_status != oldspectatee_status)
2923         {
2924                 ClientData_Touch(self);
2925                 if(g_race || g_cts)
2926                         race_InitSpectator();
2927         }
2928
2929         if(self.teamkill_soundtime)
2930         if(time > self.teamkill_soundtime)
2931         {
2932                 self.teamkill_soundtime = 0;
2933
2934                 entity oldpusher, oldself;
2935
2936                 oldself = self; self = self.teamkill_soundsource;
2937                 oldpusher = self.pusher; self.pusher = oldself;
2938
2939                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2940
2941                 self.pusher = oldpusher;
2942                 self = oldself;
2943         }
2944
2945         if(self.taunt_soundtime)
2946         if(time > self.taunt_soundtime)
2947         {
2948                 self.taunt_soundtime = 0;
2949                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2950         }
2951
2952         target_voicescript_next(self);
2953
2954         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2955         if(!self.weapon)
2956                 self.clip_load = self.clip_size = 0;
2957 }
2958
2959 float isInvisibleString(string s)
2960 {
2961         float i, n, c;
2962         s = strdecolorize(s);
2963         for((i = 0), (n = strlen(s)); i < n; ++i)
2964         {
2965                 c = str2chr(s, i);
2966                 switch(c)
2967                 {
2968                         case 0:
2969                         case 32: // space
2970                                 break;
2971                         case 192: // charmap space
2972                                 if (!autocvar_utf8_enable)
2973                                         break;
2974                                 return FALSE;
2975                         case 160: // space in unicode fonts
2976                         case 0xE000 + 192: // utf8 charmap space
2977                                 if (autocvar_utf8_enable)
2978                                         break;
2979                         default:
2980                                 return FALSE;
2981                 }
2982         }
2983         return TRUE;
2984 }
2985
2986 /*
2987 =============
2988 PlayerPostThink
2989
2990 Called every frame for each client after the physics are run
2991 =============
2992 */
2993 .float idlekick_lasttimeleft;
2994 .entity showheadshotbbox;
2995 void showheadshotbbox_think()
2996 {
2997         if(self.owner.showheadshotbbox != self)
2998         {
2999                 remove(self);
3000                 return;
3001         }
3002         self.nextthink = time;
3003         setorigin(self, self.owner.origin);
3004         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3005 }
3006 void PlayerPostThink (void)
3007 {
3008         // Savage: Check for nameless players
3009         if (isInvisibleString(self.netname)) {
3010                 self.netname = "Player";
3011                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3012         }
3013
3014         if(sv_maxidle && frametime)
3015         {
3016                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3017                 float timeleft;
3018                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3019                 if(timeleft <= 0)
3020                 {
3021                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3022                         AnnounceTo(self, "terminated");
3023                         dropclient(self);
3024                         return;
3025                 }
3026                 else if(timeleft <= 10)
3027                 {
3028                         if(timeleft != self.idlekick_lasttimeleft)
3029                         {
3030                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3031                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3032                         }
3033                 }
3034                 else
3035                 {
3036                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3037                 }
3038                 self.idlekick_lasttimeleft = timeleft;
3039         }
3040
3041 #ifdef TETRIS
3042         if(self.impulse == 100)
3043                 ImpulseCommands();