Oops, update one cvar because I forgot to change it
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck)
136         if(spot.team != teamcheck)
137                 return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(autocvar_spawn_debugview)
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         teamcheck = 0;
329
330         if(!anypoint && have_team_spawns > 0)
331                 teamcheck = self.team;
332
333         // get the list of players
334         playerlist = findchain(classname, "player");
335         // get the entire list of spots
336         firstspot = findchain(classname, "info_player_deathmatch");
337         // filter out the bad ones
338         // (note this returns the original list if none survived)
339         if(anypoint)
340         {
341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
342         }
343         else
344         {
345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
346                 if(!firstspot_new)
347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
348                 firstspot = firstspot_new;
349
350                 // there is 50/50 chance of choosing a random spot or the furthest spot
351                 // (this means that roughly every other spawn will be furthest, so you
352                 // usually won't get fragged at spawn twice in a row)
353                 if (arena_roundbased && !g_ca)
354                 {
355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
356                         if(firstspot_new)
357                                 firstspot = firstspot_new;
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 }
360                 else if (random() > autocvar_g_spawn_furthest)
361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362                 else
363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
364         }
365
366         if(autocvar_spawn_debugview)
367         {
368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
369
370                 entity e;
371                 if(teamcheck)
372                         for(e = firstspot; e; e = e.chain)
373                                 if(e.team != teamcheck)
374                                         error("invalid spawn found");
375         }
376
377         if (!spot)
378         {
379                 if(autocvar_spawn_debug)
380                         GotoNextMap();
381                 else
382                 {
383                         if(some_spawn_has_been_used)
384                                 return world; // team can't spawn any more, because of actions of other team
385                         else
386                                 error("Cannot find a spawn point - please fix the map!");
387                 }
388         }
389
390         return spot;
391 }
392
393 /*
394 =============
395 CheckPlayerModel
396
397 Checks if the argument string can be a valid playermodel.
398 Returns a valid one in doubt.
399 =============
400 */
401 string FallbackPlayerModel;
402 string CheckPlayerModel(string plyermodel) {
403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
404         {
405                 // note: we cannot summon Don Strunzone here, some player may
406                 // still have the model string set. In case anyone manages how
407                 // to change a cvar default, we'll have a small leak here.
408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
409         }
410         if(strlen(plyermodel) < 4)
411                 return FallbackPlayerModel;
412         if( substring(plyermodel,0,14) != "models/player/")
413                 return FallbackPlayerModel;
414         else if(autocvar_sv_servermodelsonly)
415         {
416                 if(substring(plyermodel,-4,4) != ".zym")
417                 if(substring(plyermodel,-4,4) != ".dpm")
418                 if(substring(plyermodel,-4,4) != ".iqm")
419                 if(substring(plyermodel,-4,4) != ".md3")
420                 if(substring(plyermodel,-4,4) != ".psk")
421                         return FallbackPlayerModel;
422                 // forbid the LOD models
423                 if(substring(plyermodel, -9,5) == "_lod1")
424                         return FallbackPlayerModel;
425                 if(substring(plyermodel, -9,5) == "_lod2")
426                         return FallbackPlayerModel;
427                 if(plyermodel != strtolower(plyermodel))
428                         return FallbackPlayerModel;
429                 if(!fexists(plyermodel))
430                         return FallbackPlayerModel;
431         }
432         return plyermodel;
433 }
434
435 /*
436 =============
437 Client_customizeentityforclient
438
439 LOD reduction
440 =============
441 */
442 void Client_uncustomizeentityforclient()
443 {
444         if(self.modelindex == 0) // no need to uncustomize then
445                 return;
446         self.modelindex = self.modelindex_lod0;
447         self.skin = self.skinindex;
448 }
449
450 float Client_customizeentityforclient()
451 {
452         entity modelsource;
453
454         if(self.modelindex == 0)
455                 return TRUE;
456
457         // forcemodel stuff
458
459 #ifdef PROFILING
460         float t0;
461         t0 = gettime(GETTIME_HIRES); // reference
462 #endif
463
464         modelsource = self;
465
466 #ifdef ALLOW_FORCEMODELS
467         if(other.cvar_cl_forceplayermodelsfromxonotic)
468                 if not(self.modelindex_lod0_from_xonotic)
469                         modelsource = other;
470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
471                 modelsource = other;
472 #endif
473
474         self.skin = modelsource.skinindex;
475
476 #if 0
477         if(modelsource == self)
478                 self.skin = modelsource.skinindex;
479         else
480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
481 #endif
482
483         // self: me
484         // other: the player viewing me
485         float distance;
486         float f;
487
488         if(other.cvar_cl_playerdetailreduction <= 0)
489         {
490                 if(other.cvar_cl_playerdetailreduction <= -2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(other.cvar_cl_playerdetailreduction <= -1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497         else
498         {
499                 distance = vlen(self.origin - other.origin);
500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
501                 if(f > sv_loddistance2)
502                         self.modelindex = modelsource.modelindex_lod2;
503                 else if(f > sv_loddistance1)
504                         self.modelindex = modelsource.modelindex_lod1;
505                 else
506                         self.modelindex = modelsource.modelindex_lod0;
507         }
508
509 #ifdef PROFILING
510         float t1;
511         t1 = gettime(GETTIME_HIRES); // reference
512         client_cefc_accumulator += (t1 - t0);
513 #endif
514
515         return TRUE;
516 }
517
518 void setmodel_lod(entity e, string modelname)
519 {
520         string s;
521
522         if(sv_loddistance1)
523         {
524                 // FIXME: this only supports 3-letter extensions
525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
526                 if(fexists(s))
527                 {
528                         setmodel(e, s); // players have high precision
529                         self.modelindex_lod1 = self.modelindex;
530                 }
531                 else
532                         self.modelindex_lod1 = -1;
533
534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
535                 if(fexists(s))
536                 {
537                         setmodel(e, s); // players have high precision
538                         self.modelindex_lod2 = self.modelindex;
539                 }
540                 else
541                         self.modelindex_lod2 = -1;
542
543                 precache_model(modelname);
544                 setmodel(e, modelname); // players have high precision
545                 self.modelindex_lod0 = self.modelindex;
546
547                 if(self.modelindex_lod1 < 0)
548                         self.modelindex_lod1 = self.modelindex;
549
550                 if(self.modelindex_lod2 < 0)
551                         self.modelindex_lod2 = self.modelindex;
552         }
553         else
554         {
555                 precache_model(modelname);
556                 setmodel(e, modelname); // players have high precision
557                 self.modelindex_lod0 = self.modelindex;
558                         // save it for possible player model forcing
559         }
560
561         s = whichpack(self.model);
562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
563
564         player_setupanimsformodel();
565         UpdatePlayerSounds();
566 }
567
568 /*
569 =============
570 PutObserverInServer
571
572 putting a client as observer in the server
573 =============
574 */
575 void FixPlayermodel();
576 void PutObserverInServer (void)
577 {
578         entity  spot;
579
580         race_PreSpawnObserver();
581
582         spot = SelectSpawnPoint (TRUE);
583         if(!spot)
584                 error("No spawnpoints for observers?!?\n");
585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
586
587         if(clienttype(self) == CLIENTTYPE_REAL)
588         {
589                 msg_entity = self;
590                 WriteByte(MSG_ONE, SVC_SETVIEW);
591                 WriteEntity(MSG_ONE, self);
592         }
593
594         DropAllRunes(self);
595         MUTATOR_CALLHOOK(MakePlayerObserver);
596
597         Portal_ClearAll(self);
598
599         if(self.alivetime)
600         {
601                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
602                 self.alivetime = 0;
603         }
604
605         if(self.flagcarried)
606                 DropFlag(self.flagcarried, world, world);
607
608         if(self.ballcarried && g_nexball)
609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
610
611         WaypointSprite_PlayerDead();
612
613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
615
616         if(self.killcount != -666) {
617                 if(g_lms) {
618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
620                         else
621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
622                 } else
623                         bprint ("^4", self.netname, "^4 is spectating now\n");
624
625                 if(self.just_joined == FALSE) {
626                         LogTeamchange(self.playerid, -1, 4);
627                 } else
628                         self.just_joined = FALSE;
629         }
630
631         PlayerScore_Clear(self); // clear scores when needed
632
633         accuracy_resend(self);
634
635         self.spectatortime = time;
636
637         self.classname = "observer";
638         self.iscreature = FALSE;
639         self.health = -666;
640         self.takedamage = DAMAGE_NO;
641         self.solid = SOLID_NOT;
642         self.movetype = MOVETYPE_NOCLIP;
643         self.flags = FL_CLIENT | FL_NOTARGET;
644         self.armorvalue = 666;
645         self.effects = 0;
646         self.armorvalue = autocvar_g_balance_armor_start;
647         self.pauserotarmor_finished = 0;
648         self.pauserothealth_finished = 0;
649         self.pauseregen_finished = 0;
650         self.damageforcescale = 0;
651         self.death_time = 0;
652         self.dead_frame = 0;
653         self.alpha = 0;
654         self.scale = 0;
655         self.fade_time = 0;
656         self.pain_frame = 0;
657         self.pain_finished = 0;
658         self.strength_finished = 0;
659         self.invincible_finished = 0;
660         self.pushltime = 0;
661         self.think = SUB_Null;
662         self.nextthink = 0;
663         self.hook_time = 0;
664         self.runes = 0;
665         self.deadflag = DEAD_NO;
666         self.angles = spot.angles;
667         self.angles_z = 0;
668         self.fixangle = TRUE;
669         self.crouch = FALSE;
670
671         self.view_ofs = PL_VIEW_OFS;
672         setorigin (self, spot.origin);
673         setsize (self, '0 0 0', '0 0 0');
674         self.prevorigin = self.origin;
675         self.items = 0;
676         self.weapons = 0;
677         self.model = "";
678         FixPlayermodel();
679         self.model = "";
680         self.modelindex = 0;
681         self.weapon = 0;
682         self.weaponmodel = "";
683         self.weaponentity = world;
684         self.exteriorweaponentity = world;
685         self.killcount = -666;
686         self.velocity = '0 0 0';
687         self.avelocity = '0 0 0';
688         self.punchangle = '0 0 0';
689         self.punchvector = '0 0 0';
690         self.oldvelocity = self.velocity;
691         self.fire_endtime = -1;
692
693         if(sv_loddistance1)
694                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
695
696         if(g_arena)
697         {
698                 if(self.version_mismatch)
699                 {
700                         Spawnqueue_Unmark(self);
701                         Spawnqueue_Remove(self);
702                 }
703                 else
704                 {
705                         Spawnqueue_Insert(self);
706                 }
707         }
708         else if(g_lms)
709         {
710                 // Only if the player cannot play at all
711                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
712                         self.frags = FRAGS_SPECTATOR;
713                 else
714                         self.frags = FRAGS_LMS_LOSER;
715         }
716         else
717                 self.frags = FRAGS_SPECTATOR;
718 }
719
720 void FixPlayermodel()
721 {
722         local string defaultmodel;
723         local float defaultskin, chmdl, oldskin;
724         local vector m1, m2;
725
726         defaultmodel = "";
727
728         if(autocvar_sv_defaultcharacter == 1) {
729                 defaultskin = 0;
730
731                 if(teams_matter)
732                 {
733                         string s;
734                         s = Team_ColorNameLowerCase(self.team);
735                         if(s != "neutral")
736                         {
737                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
738                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
739                         }
740                 }
741
742                 if(defaultmodel == "")
743                 {
744                         defaultmodel = autocvar_sv_defaultplayermodel;
745                         defaultskin = autocvar_sv_defaultplayerskin;
746                 }
747         }
748
749         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
750         {
751                 if(self.model != "")
752                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
753                 self.model = ""; // force the != checks to return true
754         }
755
756         if(defaultmodel != "")
757         {
758                 if (defaultmodel != self.model)
759                 {
760                         m1 = self.mins;
761                         m2 = self.maxs;
762                         setmodel_lod (self, defaultmodel);
763                         setsize (self, m1, m2);
764                         chmdl = TRUE;
765                 }
766
767                 oldskin = self.skinindex;
768                 self.skinindex = defaultskin;
769         } else {
770                 if (self.playermodel != self.model || self.playermodel == "")
771                 {
772                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
773                         m1 = self.mins;
774                         m2 = self.maxs;
775                         setmodel_lod (self, self.playermodel);
776                         setsize (self, m1, m2);
777                         chmdl = TRUE;
778                 }
779
780                 oldskin = self.skinindex;
781                 self.skinindex = stof(self.playerskin);
782         }
783
784         if(chmdl || oldskin != self.skinindex)
785                 self.species = player_getspecies(); // model or skin has changed
786
787         if(!teams_matter)
788                 if(strlen(autocvar_sv_defaultplayercolors))
789                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
790                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
791 }
792
793 void PlayerTouchExplode(entity p1, entity p2)
794 {
795         vector org;
796         org = (p1.origin + p2.origin) * 0.5;
797         org_z += (p1.mins_z + p2.mins_z) * 0.5;
798
799         te_explosion(org);
800
801         entity e;
802         e = spawn();
803         setorigin(e, org);
804         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
805         remove(e);
806 }
807
808 /*
809 =============
810 PutClientInServer
811
812 Called when a client spawns in the server
813 =============
814 */
815 //void() ctf_playerchanged;
816 void PutClientInServer (void)
817 {
818         if(clienttype(self) == CLIENTTYPE_BOT)
819         {
820                 self.classname = "player";
821         }
822         else if(clienttype(self) == CLIENTTYPE_REAL)
823         {
824                 msg_entity = self;
825                 WriteByte(MSG_ONE, SVC_SETVIEW);
826                 WriteEntity(MSG_ONE, self);
827         }
828
829         // player is dead and becomes observer
830         // FIXME fix LMS scoring for new system
831         if(g_lms)
832         {
833                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
834                         self.classname = "observer";
835         }
836
837         if(g_arena || (g_ca && !allowed_to_spawn))
838         if(!self.spawned)
839                 self.classname = "observer";
840
841         if(gameover)
842                 self.classname = "observer";
843
844         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
845                 entity spot, oldself;
846                 float j;
847
848                 accuracy_resend(self);
849
850                 if(self.team < 0)
851                         JoinBestTeam(self, FALSE, TRUE);
852
853                 race_PreSpawn();
854
855                 spot = SelectSpawnPoint (FALSE);
856                 if(!spot)
857                 {
858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
859                         return; // spawn failed
860                 }
861
862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
863
864                 self.classname = "player";
865                 self.wasplayer = TRUE;
866                 self.iscreature = TRUE;
867                 self.movetype = MOVETYPE_WALK;
868                 self.solid = SOLID_SLIDEBOX;
869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
870                 if(autocvar_g_playerclip_collisions)
871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
872                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
874                 self.frags = FRAGS_PLAYER;
875                 if(independent_players)
876                         MAKE_INDEPENDENT_PLAYER(self);
877                 self.flags = FL_CLIENT;
878                 self.takedamage = DAMAGE_AIM;
879                 if(g_minstagib)
880                         self.effects = EF_FULLBRIGHT;
881                 else
882                         self.effects = 0;
883                 self.air_finished = time + 12;
884                 self.dmg = 2;
885                 if(autocvar_g_balance_nex_charge)
886                 {
887                         if(autocvar_g_balance_nex_secondary_chargepool)
888                                 self.nex_chargepool_ammo = 1;
889                         self.nex_charge = autocvar_g_balance_nex_charge_start;
890                 }
891
892                 if(inWarmupStage)
893                 {
894                         self.ammo_shells = warmup_start_ammo_shells;
895                         self.ammo_nails = warmup_start_ammo_nails;
896                         self.ammo_rockets = warmup_start_ammo_rockets;
897                         self.ammo_cells = warmup_start_ammo_cells;
898                         self.ammo_fuel = warmup_start_ammo_fuel;
899                         self.health = warmup_start_health;
900                         self.armorvalue = warmup_start_armorvalue;
901                         self.weapons = warmup_start_weapons;
902                 }
903                 else
904                 {
905                         self.ammo_shells = start_ammo_shells;
906                         self.ammo_nails = start_ammo_nails;
907                         self.ammo_rockets = start_ammo_rockets;
908                         self.ammo_cells = start_ammo_cells;
909                         self.ammo_fuel = start_ammo_fuel;
910                         self.health = start_health;
911                         self.armorvalue = start_armorvalue;
912                         self.weapons = start_weapons;
913                 }
914
915                 if(g_weaponarena_random)
916                 {
917                         if(g_weaponarena_random_with_laser)
918                                 self.weapons &~= WEPBIT_LASER;
919                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
920                         if(g_weaponarena_random_with_laser)
921                                 self.weapons |= WEPBIT_LASER;
922                 }
923
924                 self.items = start_items;
925                 self.jump_interval = time;
926
927                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
928                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
929                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
930                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
931                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
932                 //extend the pause of rotting if client was reset at the beginning of the countdown
933                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
934                         self.spawnshieldtime += game_starttime - time;
935                         self.pauserotarmor_finished += game_starttime - time;
936                         self.pauserothealth_finished += game_starttime - time;
937                         self.pauseregen_finished += game_starttime - time;
938                 }
939                 self.damageforcescale = 2;
940                 self.death_time = 0;
941                 self.dead_frame = 0;
942                 self.alpha = 0;
943                 self.scale = 0;
944                 self.fade_time = 0;
945                 self.pain_frame = 0;
946                 self.pain_finished = 0;
947                 self.strength_finished = 0;
948                 self.invincible_finished = 0;
949                 self.pushltime = 0;
950                 // players have no think function
951                 self.think = SUB_Null;
952                 self.nextthink = 0;
953                 self.hook_time = 0;
954                 self.dmg_team = 0;
955                 self.ballistics_density = autocvar_g_ballistics_density_player;
956
957                 self.metertime = 0;
958
959                 self.runes = 0;
960
961                 self.deadflag = DEAD_NO;
962
963                 self.angles = spot.angles;
964
965                 self.angles_z = 0; // never spawn tilted even if the spot says to
966                 self.fixangle = TRUE; // turn this way immediately
967                 self.velocity = '0 0 0';
968                 self.avelocity = '0 0 0';
969                 self.punchangle = '0 0 0';
970                 self.punchvector = '0 0 0';
971                 self.oldvelocity = self.velocity;
972                 self.fire_endtime = -1;
973
974                 msg_entity = self;
975                 WRITESPECTATABLE_MSG_ONE({
976                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
977                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
978                 });
979
980                 if(sv_loddistance1)
981                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
982
983                 self.model = "";
984                 FixPlayermodel();
985
986                 self.crouch = FALSE;
987                 self.view_ofs = PL_VIEW_OFS;
988                 setsize (self, PL_MIN, PL_MAX);
989                 self.spawnorigin = spot.origin;
990                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
991                 // don't reset back to last position, even if new position is stuck in solid
992                 self.oldorigin = self.origin;
993                 self.prevorigin = self.origin;
994                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
995
996                 if(g_arena)
997                 {
998                         Spawnqueue_Remove(self);
999                         Spawnqueue_Mark(self);
1000                 }
1001
1002                 else if(g_ca)
1003                         self.caplayer = 1;
1004
1005                 self.event_damage = PlayerDamage;
1006
1007                 self.bot_attack = TRUE;
1008
1009                 self.statdraintime = time + 5;
1010                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1011
1012                 if(self.killcount == -666) {
1013                         PlayerScore_Clear(self);
1014                         self.killcount = 0;
1015                 }
1016
1017                 self.cnt = WEP_LASER;
1018
1019                 CL_SpawnWeaponentity();
1020                 self.alpha = default_player_alpha;
1021                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1022                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1023
1024                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1025                 self.lms_traveled_distance = 0;
1026                 self.speedrunning = FALSE;
1027
1028                 race_PostSpawn(spot);
1029
1030                 if(autocvar_spawn_debug)
1031                 {
1032                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1033                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1034                 }
1035
1036                 //stuffcmd(self, "chase_active 0");
1037                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1038
1039                 if (autocvar_g_spawnsound)
1040                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1041
1042                 if(g_assault) {
1043                         if(self.team == assault_attacker_team)
1044                                 centerprint(self, "You are attacking!");
1045                         else
1046                                 centerprint(self, "You are defending!");
1047                 }
1048
1049                 target_voicescript_clear(self);
1050
1051                 // reset fields the weapons may use
1052                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1053                         weapon_action(j, WR_RESETPLAYER);
1054
1055                 oldself = self;
1056                 self = spot;
1057                         activator = oldself;
1058                                 SUB_UseTargets();
1059                         activator = world;
1060                 self = oldself;
1061
1062                 MUTATOR_CALLHOOK(PlayerSpawn);
1063
1064                 self.switchweapon = w_getbestweapon(self);
1065                 self.cnt = self.switchweapon;
1066                 self.weapon = 0;
1067
1068                 if(!self.alivetime)
1069                         self.alivetime = time;
1070         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1071                 PutObserverInServer ();
1072         }
1073
1074         //if(g_ctf)
1075         //      ctf_playerchanged();
1076 }
1077
1078 .float ebouncefactor, ebouncestop; // electro's values
1079 // TODO do we need all these fields, or should we stop autodetecting runtime
1080 // changes and just have a console command to update this?
1081 float ClientInit_SendEntity(entity to, float sf)
1082 {
1083         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1084         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1097         if(sv_foginterval && world.fog != "")
1098                 WriteString(MSG_ENTITY, world.fog);
1099         else
1100                 WriteString(MSG_ENTITY, "");
1101         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1102         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1103         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1104         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1105         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1106         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1107         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1108         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1109         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1110         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_magazinecapacity); // rifle max bullets
1111         return TRUE;
1112 }
1113
1114 void ClientInit_CheckUpdate()
1115 {
1116         self.nextthink = time;
1117         if(self.count != autocvar_g_balance_armor_blockpercent)
1118         {
1119                 self.count = autocvar_g_balance_armor_blockpercent;
1120                 self.SendFlags |= 1;
1121         }
1122         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1123         {
1124                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1125                 self.SendFlags |= 1;
1126         }
1127         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1128         {
1129                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1130                 self.SendFlags |= 1;
1131         }
1132         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1133         {
1134                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1135                 self.SendFlags |= 1;
1136         }
1137         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1138         {
1139                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1140                 self.SendFlags |= 1;
1141         }
1142         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1143         {
1144                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1145                 self.SendFlags |= 1;
1146         }
1147 }
1148
1149 void ClientInit_Spawn()
1150 {
1151         entity o;
1152         entity e;
1153         e = spawn();
1154         e.classname = "clientinit";
1155         e.think = ClientInit_CheckUpdate;
1156         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1157
1158         o = self;
1159         self = e;
1160         ClientInit_CheckUpdate();
1161         self = o;
1162 }
1163
1164 /*
1165 =============
1166 SetNewParms
1167 =============
1168 */
1169 void SetNewParms (void)
1170 {
1171         // initialize parms for a new player
1172         parm1 = -(86400 * 366);
1173 }
1174
1175 /*
1176 =============
1177 SetChangeParms
1178 =============
1179 */
1180 void SetChangeParms (void)
1181 {
1182         // save parms for level change
1183         parm1 = self.parm_idlesince - time;
1184 }
1185
1186 /*
1187 =============
1188 DecodeLevelParms
1189 =============
1190 */
1191 void DecodeLevelParms (void)
1192 {
1193         // load parms
1194         self.parm_idlesince = parm1;
1195         if(self.parm_idlesince == -(86400 * 366))
1196                 self.parm_idlesince = time;
1197
1198         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1199         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1200 }
1201
1202 /*
1203 =============
1204 ClientKill
1205
1206 Called when a client types 'kill' in the console
1207 =============
1208 */
1209
1210 .float clientkill_nexttime;
1211 void ClientKill_Now_TeamChange()
1212 {
1213         if(self.killindicator_teamchange == -1)
1214         {
1215                 self.team = -1;
1216                 JoinBestTeam( self, FALSE, FALSE );
1217         }
1218         else if(self.killindicator_teamchange == -2)
1219         {
1220                 if(g_ca)
1221                         self.caplayer = 0;
1222                 if(blockSpectators)
1223                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1224                 PutObserverInServer();
1225         }
1226         else
1227                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1228 }
1229
1230 void ClientKill_Now()
1231 {
1232         remove(self.killindicator);
1233         self.killindicator = world;
1234
1235         if(self.killindicator_teamchange)
1236                 ClientKill_Now_TeamChange();
1237
1238         // in any case:
1239         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1240
1241         // now I am sure the player IS dead
1242 }
1243 void KillIndicator_Think()
1244 {
1245         if (!self.owner.modelindex)
1246         {
1247                 self.owner.killindicator = world;
1248                 remove(self);
1249                 return;
1250         }
1251
1252         if(self.cnt <= 0)
1253         {
1254                 self = self.owner;
1255                 ClientKill_Now(); // no oldself needed
1256                 return;
1257         }
1258     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1259     {
1260         self.nextthink = time + 1;
1261         self.cnt -= 1;
1262     }
1263         else
1264         {
1265                 if(self.cnt <= 10)
1266                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1267                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1268                 {
1269                         if(self.cnt <= 10)
1270                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1271                         if(self.owner.killindicator_teamchange)
1272                         {
1273                                 if(self.owner.killindicator_teamchange == -1)
1274                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1275                                 else if(self.owner.killindicator_teamchange == -2)
1276                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1277                                 else
1278                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1279                         }
1280                         else
1281                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1282                 }
1283                 self.nextthink = time + 1;
1284                 self.cnt -= 1;
1285         }
1286 }
1287
1288 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1289 {
1290         float killtime;
1291         entity e;
1292         killtime = autocvar_g_balance_kill_delay;
1293
1294         if(g_race_qualifying || g_cts)
1295                 killtime = 0;
1296
1297     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1298     {
1299                 remove(self.killindicator);
1300                 self.killindicator = world;
1301
1302         ClientKill_Now(); // allow instant kill in this case
1303         return;
1304     }
1305
1306         self.killindicator_teamchange = targetteam;
1307
1308     if(!self.killindicator)
1309         {
1310                 if(self.modelindex && self.deadflag == DEAD_NO)
1311                 {
1312                         killtime = max(killtime, self.clientkill_nexttime - time);
1313                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1314                 }
1315
1316                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1317                 {
1318                         ClientKill_Now();
1319                 }
1320                 else
1321                 {
1322                         self.killindicator = spawn();
1323                         self.killindicator.owner = self;
1324                         self.killindicator.scale = 0.5;
1325                         setattachment(self.killindicator, self, "");
1326                         setorigin(self.killindicator, '0 0 52');
1327                         self.killindicator.think = KillIndicator_Think;
1328                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1329                         self.killindicator.cnt = ceil(killtime);
1330                         self.killindicator.count = bound(0, ceil(killtime), 10);
1331                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1332
1333                         for(e = world; (e = find(e, classname, "body")) != world; )
1334                         {
1335                                 if(e.enemy != self)
1336                                         continue;
1337                                 e.killindicator = spawn();
1338                                 e.killindicator.owner = e;
1339                                 e.killindicator.scale = 0.5;
1340                                 setattachment(e.killindicator, e, "");
1341                                 setorigin(e.killindicator, '0 0 52');
1342                                 e.killindicator.think = KillIndicator_Think;
1343                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1344                                 e.killindicator.cnt = ceil(killtime);
1345                         }
1346                         self.lip = 0;
1347                 }
1348         }
1349         if(self.killindicator)
1350         {
1351                 if(targetteam == 0) // just die
1352                         self.killindicator.colormod = '0 0 0';
1353                 else if(targetteam == -1) // auto
1354                         self.killindicator.colormod = '0 1 0';
1355                 else if(targetteam == -2) // spectate
1356                         self.killindicator.colormod = '0.5 0.5 0.5';
1357                 else
1358                         self.killindicator.colormod = TeamColor(targetteam);
1359         }
1360 }
1361
1362 void ClientKill (void)
1363 {
1364         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1365         {
1366                 // do nothing
1367         }
1368     else if(g_freezetag && self.freezetag_frozen == 1)
1369     {
1370         // do nothing
1371     }
1372         else
1373                 ClientKill_TeamChange(0);
1374 }
1375
1376 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1377 {
1378     e.killindicator = spawn();
1379     e.killindicator.owner = e;
1380     e.killindicator.think = KillIndicator_Think;
1381     e.killindicator.nextthink = time + (e.lip) * 0.05;
1382     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1383     e.killindicator.health = 1; // this is used to indicate that it should be silent
1384     e.lip = 0;
1385 }
1386
1387 void DoTeamChange(float destteam)
1388 {
1389         float t, c0;
1390         if(!teams_matter)
1391         {
1392                 if(destteam >= 0)
1393                         SetPlayerColors(self, destteam);
1394                 return;
1395         }
1396         if(self.classname == "player")
1397         if(destteam == -1)
1398         {
1399                 CheckAllowedTeams(self);
1400                 t = FindSmallestTeam(self, TRUE);
1401                 switch(self.team)
1402                 {
1403                         case COLOR_TEAM1: c0 = c1; break;
1404                         case COLOR_TEAM2: c0 = c2; break;
1405                         case COLOR_TEAM3: c0 = c3; break;
1406                         case COLOR_TEAM4: c0 = c4; break;
1407                         default:          c0 = 999;
1408                 }
1409                 switch(t)
1410                 {
1411                         case 1:
1412                                 if(c0 > c1)
1413                                         destteam = COLOR_TEAM1;
1414                                 break;
1415                         case 2:
1416                                 if(c0 > c2)
1417                                         destteam = COLOR_TEAM2;
1418                                 break;
1419                         case 3:
1420                                 if(c0 > c3)
1421                                         destteam = COLOR_TEAM3;
1422                                 break;
1423                         case 4:
1424                                 if(c0 > c4)
1425                                         destteam = COLOR_TEAM4;
1426                                 break;
1427                 }
1428                 if(destteam == -1)
1429                         return;
1430         }
1431         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1432                 return;
1433         ClientKill_TeamChange(destteam);
1434 }
1435
1436 void FixClientCvars(entity e)
1437 {
1438         // send prediction settings to the client
1439         stuffcmd(e, "\nin_bindmap 0 0\n");
1440         if(g_race || g_cts)
1441                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1442         if(autocvar_g_antilag == 3) // client side hitscan
1443                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1444         if(sv_gentle)
1445                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1446         /*
1447          * we no longer need to stuff this. Remove this comment block if you feel
1448          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1449         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1450         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1451         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1452         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1453         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1454         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1455         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1456         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1457         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1458         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1459         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1460         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1461         stuffcmd(e, "cl_movement_edgefriction 1\n");
1462          */
1463 }
1464
1465 float PlayerInIDList(entity p, string idlist)
1466 {
1467         float n, i;
1468         string s;
1469
1470         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1471         if not(p.crypto_idfp)
1472                 return 0;
1473
1474         // this function allows abbreviated player IDs too!
1475         n = tokenize_console(idlist);
1476         for(i = 0; i < n; ++i)
1477         {
1478                 s = argv(i);
1479                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1480                         return 1;
1481         }
1482
1483         return 0;
1484 }
1485
1486 /*
1487 =============
1488 ClientConnect
1489
1490 Called when a client connects to the server
1491 =============
1492 */
1493 //void ctf_clientconnect();
1494 string ColoredTeamName(float t);
1495 void DecodeLevelParms (void);
1496 //void dom_player_join_team(entity pl);
1497 void ClientConnect (void)
1498 {
1499         float t;
1500
1501         if(self.flags & FL_CLIENT)
1502         {
1503                 print("Warning: ClientConnect, but already connected!\n");
1504                 return;
1505         }
1506
1507         if(Ban_MaybeEnforceBan(self))
1508                 return;
1509
1510         DecodeLevelParms();
1511
1512 #ifdef WATERMARK
1513         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1514 #endif
1515
1516         self.classname = "player_joining";
1517
1518         self.flags = FL_CLIENT;
1519         self.version_nagtime = time + 10 + random() * 10;
1520
1521         if(player_count<0)
1522         {
1523                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1524                 player_count = 0;
1525         }
1526
1527         PlayerScore_Attach(self);
1528         ClientData_Attach();
1529         accuracy_init(self);
1530
1531         bot_clientconnect();
1532
1533         playerdemo_init();
1534
1535         anticheat_init();
1536         
1537         race_PreSpawnObserver();
1538
1539         //if(g_domination)
1540         //      dom_player_join_team(self);
1541
1542         // identify the right forced team
1543         if(autocvar_g_campaign)
1544         {
1545                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1546                 {
1547                         switch(autocvar_g_campaign_forceteam)
1548                         {
1549                                 case 1: self.team_forced = COLOR_TEAM1; break;
1550                                 case 2: self.team_forced = COLOR_TEAM2; break;
1551                                 case 3: self.team_forced = COLOR_TEAM3; break;
1552                                 case 4: self.team_forced = COLOR_TEAM4; break;
1553                                 default: self.team_forced = 0;
1554                         }
1555                 }
1556         }
1557         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1558                 self.team_forced = COLOR_TEAM1;
1559         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1560                 self.team_forced = COLOR_TEAM2;
1561         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1562                 self.team_forced = COLOR_TEAM3;
1563         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1564                 self.team_forced = COLOR_TEAM4;
1565         else if(autocvar_g_forced_team_otherwise == "red")
1566                 self.team_forced = COLOR_TEAM1;
1567         else if(autocvar_g_forced_team_otherwise == "blue")
1568                 self.team_forced = COLOR_TEAM2;
1569         else if(autocvar_g_forced_team_otherwise == "yellow")
1570                 self.team_forced = COLOR_TEAM3;
1571         else if(autocvar_g_forced_team_otherwise == "pink")
1572                 self.team_forced = COLOR_TEAM4;
1573         else if(autocvar_g_forced_team_otherwise == "spectate")
1574                 self.team_forced = -1;
1575         else if(autocvar_g_forced_team_otherwise == "spectator")
1576                 self.team_forced = -1;
1577         else
1578                 self.team_forced = 0;
1579
1580         if(!teams_matter)
1581                 if(self.team_forced > 0)
1582                         self.team_forced = 0;
1583
1584         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1585
1586         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1587                 self.classname = "observer";
1588         } else {
1589                 if(teams_matter)
1590                 {
1591                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1592                         {
1593                                 self.classname = "player";
1594                                 campaign_bots_may_start = 1;
1595                         }
1596                         else
1597                         {
1598                                 self.classname = "observer"; // do it anyway
1599                         }
1600                 }
1601                 else
1602                 {
1603                         self.classname = "player";
1604                         campaign_bots_may_start = 1;
1605                 }
1606         }
1607
1608         self.playerid = (playerid_last = playerid_last + 1);
1609
1610         if(autocvar_sv_eventlog)
1611                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1612
1613         LogTeamchange(self.playerid, self.team, 1);
1614
1615         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1616
1617         self.netname_previous = strzone(self.netname);
1618
1619         bprint("^4", self.netname, "^4 connected");
1620
1621         if(self.classname != "observer" && (g_domination || g_ctf))
1622                 bprint(" and joined the ", ColoredTeamName(self.team));
1623
1624         bprint("\n");
1625
1626         self.welcomemessage_time = 0;
1627
1628         stuffcmd(self, strcat(clientstuff, "\n"));
1629         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1630         stuffcmd(self, "cl_particles_reloadeffects\n");
1631
1632         FixClientCvars(self);
1633
1634         // spawnfunc_waypoint sprites
1635         WaypointSprite_InitClient(self);
1636
1637         // Wazat's grappling hook
1638         SetGrappleHookBindings();
1639
1640         // get autoswitch state from player when he toggles it
1641         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1642
1643         // get version info from player
1644         stuffcmd(self, "cmd clientversion $gameversion\n");
1645
1646         // get other cvars from player
1647         GetCvars(0);
1648
1649         // notify about available teams
1650         if(teams_matter)
1651         {
1652                 CheckAllowedTeams(self);
1653                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1654                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1655         }
1656         else
1657                 stuffcmd(self, "set _teams_available 0\n");
1658
1659         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1660
1661         if(g_arena || g_ca)
1662         {
1663                 self.classname = "observer";
1664                 if(g_arena)
1665                         Spawnqueue_Insert(self);
1666         }
1667         /*else if(g_ctf)
1668         {
1669                 ctf_clientconnect();
1670         }*/
1671
1672         if(teams_matter || radar_showennemies)
1673                 attach_entcs();
1674
1675         bot_relinkplayerlist();
1676
1677         self.spectatortime = time;
1678         if(blockSpectators)
1679         {
1680                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1681         }
1682
1683         self.jointime = time;
1684         self.allowedTimeouts = autocvar_sv_timeout_number;
1685
1686         if(clienttype(self) == CLIENTTYPE_REAL)
1687         {
1688                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1689                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1690         }
1691
1692         if(g_lms)
1693         {
1694                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1695                 {
1696                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1697                         self.frags = FRAGS_SPECTATOR;
1698                 }
1699         }
1700
1701         if(!sv_foginterval && world.fog != "")
1702                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1703
1704         SoundEntity_Attach(self);
1705
1706         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1707         {
1708                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1709                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1710         }
1711         else
1712                 self.hitplotfh = -1;
1713
1714         if(g_race || g_cts) {
1715                 string rr;
1716                 if(g_cts)
1717                         rr = CTS_RECORD;
1718                 else
1719                         rr = RACE_RECORD;
1720                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1721
1722                 msg_entity = self;
1723                 race_send_recordtime(MSG_ONE);
1724                 race_send_speedaward(MSG_ONE);
1725
1726                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1727                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1728                 race_send_speedaward_alltimebest(MSG_ONE);
1729
1730                 float i;
1731                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1732                         race_SendRankings(i, 0, 0, MSG_ONE);
1733                 }
1734         }
1735         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1736                 send_CSQC_teamnagger();
1737
1738         CheatInitClient();
1739
1740         PlayerStats_AddPlayer(self);
1741 }
1742
1743 /*
1744 =============
1745 ClientDisconnect
1746
1747 Called when a client disconnects from the server
1748 =============
1749 */
1750 .entity chatbubbleentity;
1751 .entity teambubbleentity;
1752 void ReadyCount();
1753 void ClientDisconnect (void)
1754 {
1755         if not(self.flags & FL_CLIENT)
1756         {
1757                 print("Warning: ClientDisconnect without ClientConnect\n");
1758                 return;
1759         }
1760
1761         PlayerStats_AddGlobalInfo(self);
1762
1763         CheatShutdownClient();
1764
1765         if(self.hitplotfh >= 0)
1766         {
1767                 fclose(self.hitplotfh);
1768                 self.hitplotfh = -1;
1769         }
1770
1771         anticheat_report();
1772         anticheat_shutdown();
1773
1774         playerdemo_shutdown();
1775
1776         bot_clientdisconnect();
1777
1778         if(self.entcs)
1779                 detach_entcs();
1780
1781         if(autocvar_sv_eventlog)
1782                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1783         bprint ("^4",self.netname);
1784         bprint ("^4 disconnected\n");
1785
1786         SoundEntity_Detach(self);
1787
1788         DropAllRunes(self);
1789         MUTATOR_CALLHOOK(ClientDisconnect);
1790
1791         Portal_ClearAll(self);
1792
1793         if(self.flagcarried)
1794                 DropFlag(self.flagcarried, world, world);
1795         if(self.ballcarried && g_nexball)
1796                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1797
1798         // Here, everything has been done that requires this player to be a client.
1799
1800         self.flags &~= FL_CLIENT;
1801
1802         if (self.chatbubbleentity)
1803                 remove (self.chatbubbleentity);
1804
1805         if (self.teambubbleentity)
1806                 remove (self.teambubbleentity);
1807
1808         if (self.killindicator)
1809                 remove (self.killindicator);
1810
1811         WaypointSprite_PlayerGone();
1812
1813         bot_relinkplayerlist();
1814
1815         if(g_arena)
1816         {
1817                 Spawnqueue_Unmark(self);
1818                 Spawnqueue_Remove(self);
1819         }
1820
1821         accuracy_free(self);
1822         ClientData_Detach();
1823         PlayerScore_Detach(self);
1824
1825         if(self.netname_previous)
1826                 strunzone(self.netname_previous);
1827         if(self.clientstatus)
1828                 strunzone(self.clientstatus);
1829         if(self.weaponorder_byimpulse)
1830                 strunzone(self.weaponorder_byimpulse);
1831
1832         ClearPlayerSounds();
1833
1834         if(self.personal)
1835                 remove(self.personal);
1836
1837         self.playerid = 0;
1838         ReadyCount();
1839
1840         // free cvars
1841         GetCvars(-1);
1842 }
1843
1844 .float BUTTON_CHAT;
1845 void ChatBubbleThink()
1846 {
1847         self.nextthink = time;
1848         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1849         {
1850                 if(self.owner) // but why can that ever be world?
1851                         self.owner.chatbubbleentity = world;
1852                 remove(self);
1853                 return;
1854         }
1855         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1856 #ifdef TETRIS
1857                 || self.owner.tetris_on
1858 #endif
1859         )
1860                 self.model = self.mdl;
1861         else
1862                 self.model = "";
1863 };
1864
1865 void UpdateChatBubble()
1866 {
1867         if (!self.modelindex)
1868                 return;
1869         // spawn a chatbubble entity if needed
1870         if (!self.chatbubbleentity)
1871         {
1872                 self.chatbubbleentity = spawn();
1873                 self.chatbubbleentity.owner = self;
1874                 self.chatbubbleentity.exteriormodeltoclient = self;
1875                 self.chatbubbleentity.think = ChatBubbleThink;
1876                 self.chatbubbleentity.nextthink = time;
1877                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1878                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1879                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1880                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1881                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1882                 self.chatbubbleentity.model = "";
1883                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1884         }
1885 }
1886
1887
1888 void TeamBubbleThink()
1889 {
1890         self.nextthink = time;
1891         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1892         {
1893                 if(self.owner) // but why can that ever be world?
1894                         self.owner.teambubbleentity = world;
1895                 remove(self);
1896                 return;
1897         }
1898 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1899         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1900                 self.model = "";
1901         else
1902                 self.model = self.mdl;
1903
1904 };
1905
1906 float TeamBubble_customizeentityforclient()
1907 {
1908         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1909 }
1910
1911 void UpdateTeamBubble()
1912 {
1913         if (!self.modelindex || !teams_matter)
1914                 return;
1915         // spawn a teambubble entity if needed
1916         if (!self.teambubbleentity && teams_matter)
1917         {
1918                 self.teambubbleentity = spawn();
1919                 self.teambubbleentity.owner = self;
1920                 self.teambubbleentity.exteriormodeltoclient = self;
1921                 self.teambubbleentity.think = TeamBubbleThink;
1922                 self.teambubbleentity.nextthink = time;
1923                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1924 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1925                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1926                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1927                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1928                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1929                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1930                 self.teambubbleentity.effects = EF_LOWPRECISION;
1931         }
1932 }
1933
1934 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1935 // added to the model skins
1936 /*void UpdateColorModHack()
1937 {
1938         local float c;
1939         c = self.clientcolors & 15;
1940         // LordHavoc: only bothering to support white, green, red, yellow, blue
1941              if (!teams_matter) self.colormod = '0 0 0';
1942         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1943         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1944         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1945         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1946         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1947         else self.colormod = '1 1 1';
1948 };*/
1949
1950 .float oldcolormap;
1951 void respawn(void)
1952 {
1953         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1954         {
1955                 self.solid = SOLID_NOT;
1956                 self.takedamage = DAMAGE_NO;
1957                 self.movetype = MOVETYPE_FLY;
1958                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1959                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1960                 self.effects |= EF_ADDITIVE;
1961                 self.oldcolormap = self.colormap;
1962                 self.colormap = 512;
1963                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1964                 if(autocvar_g_respawn_ghosts_maxtime)
1965                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1966         }
1967
1968         CopyBody(1);
1969         self.effects |= EF_NODRAW; // prevent another CopyBody
1970         if(self.oldcolormap)
1971         {
1972                 self.colormap = self.oldcolormap;
1973                 self.oldcolormap = 0;
1974         }
1975         PutClientInServer();
1976 }
1977
1978 void play_countdown(float finished, string samp)
1979 {
1980         if(clienttype(self) == CLIENTTYPE_REAL)
1981                 if(floor(finished - time - frametime) != floor(finished - time))
1982                         if(finished - time < 6)
1983                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1984 }
1985
1986 /**
1987  * When sv_timeout is used this function returs strings like
1988  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1989  * Called by centerprint functions
1990  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1991  */
1992 string getTimeoutText(float addOneSecond) {
1993         if (!autocvar_sv_timeout || !timeoutStatus)
1994                 return "";
1995
1996         local string retStr;
1997         if (timeoutStatus == 1) {
1998                 if (addOneSecond == 1) {
1999                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2000                 }
2001                 else {
2002                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2003                 }
2004                 return retStr;
2005         }
2006         else if (timeoutStatus == 2) {
2007                 if (addOneSecond) {
2008                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2009                         //don't show messages like "Timeout ends in 0 seconds"...
2010                         if ((remainingTimeoutTime + 1) > 0)
2011                                 return retStr;
2012                         else
2013                                 return "";
2014                 }
2015                 else {
2016                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2017                         //don't show messages like "Timeout ends in 0 seconds"...
2018                         if (remainingTimeoutTime > 0)
2019                                 return retStr;
2020                         else
2021                                 return "";
2022                 }
2023         }
2024         else return "";
2025 }
2026
2027 void player_powerups (void)
2028 {
2029         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2030         olditems = self.items;
2031         
2032         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2033         {
2034                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2035                 self.modelflags |= MF_ROCKET;
2036         }
2037         else
2038         {
2039                 SoundEntity_StopSound(self, CHAN_PLAYER);
2040                 self.modelflags &~= MF_ROCKET;
2041         }
2042
2043         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2044
2045         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2046                 return;
2047         
2048         Fire_ApplyDamage(self);
2049         Fire_ApplyEffect(self);
2050
2051         if (g_minstagib)
2052         {
2053                 self.effects |= EF_FULLBRIGHT;
2054
2055                 if (self.items & IT_STRENGTH)
2056                 {
2057                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2058                         if (time > self.strength_finished)
2059                         {
2060                                 self.alpha = default_player_alpha;
2061                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2062                                 self.items &~= IT_STRENGTH;
2063                                 sprint(self, "^3Invisibility has worn off\n");
2064                         }
2065                 }
2066                 else
2067                 {
2068                         if (time < self.strength_finished)
2069                         {
2070                                 self.alpha = g_minstagib_invis_alpha;
2071                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2072                                 self.items |= IT_STRENGTH;
2073                                 sprint(self, "^3You are invisible\n");
2074                         }
2075                 }
2076
2077                 if (self.items & IT_INVINCIBLE)
2078                 {
2079                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2080                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2081                         {
2082                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2083                                 sprint(self, "^3Speed has worn off\n");
2084                         }
2085                 }
2086                 else
2087                 {
2088                         if (time < self.invincible_finished)
2089                         {
2090                                 self.items = self.items | IT_INVINCIBLE;
2091                                 sprint(self, "^3You are on speed\n");
2092                         }
2093                 }
2094         }
2095         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2096         {
2097                 if (self.items & IT_STRENGTH)
2098                 {
2099                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2100                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2101                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2102                         {
2103                                 self.items = self.items - (self.items & IT_STRENGTH);
2104                                 sprint(self, "^3Strength has worn off\n");
2105                         }
2106                 }
2107                 else
2108                 {
2109                         if (time < self.strength_finished)
2110                         {
2111                                 self.items = self.items | IT_STRENGTH;
2112                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2113                         }
2114                 }
2115                 if (self.items & IT_INVINCIBLE)
2116                 {
2117                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2118                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2119                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2120                         {
2121                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2122                                 sprint(self, "^3Shield has worn off\n");
2123                         }
2124                 }
2125                 else
2126                 {
2127                         if (time < self.invincible_finished)
2128                         {
2129                                 self.items = self.items | IT_INVINCIBLE;
2130                                 sprint(self, "^3Shield surrounds you\n");
2131                         }
2132                 }
2133
2134                 if(autocvar_g_nodepthtestplayers)
2135                         self.effects = self.effects | EF_NODEPTHTEST;
2136
2137                 if(autocvar_g_fullbrightplayers)
2138                         self.effects = self.effects | EF_FULLBRIGHT;
2139
2140                 // midair gamemode: damage only while in the air
2141                 // if in midair mode, being on ground grants temporary invulnerability
2142                 // (this is so that multishot weapon don't clear the ground flag on the
2143                 // first damage in the frame, leaving the player vulnerable to the
2144                 // remaining hits in the same frame)
2145                 if (self.flags & FL_ONGROUND)
2146                 if (g_midair)
2147                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2148
2149                 if (time >= game_starttime)
2150                 if (time < self.spawnshieldtime)
2151                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2152         }
2153         
2154         MUTATOR_CALLHOOK(PlayerPowerups);
2155 }
2156
2157 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2158 {
2159         if(current > stable)
2160                 return current;
2161         else if(current > stable - 0.25) // when close enough, "snap"
2162                 return stable;
2163         else
2164                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2165 }
2166
2167 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2168 {
2169         if(current < stable)
2170                 return current;
2171         else if(current < stable + 0.25) // when close enough, "snap"
2172                 return stable;
2173         else
2174                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2175 }
2176
2177 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2178 {
2179         if(current > rotstable)
2180         {
2181                 if(rotframetime > 0)
2182                 {
2183                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2184                         current = max(rotstable, current - rotlinear * rotframetime);
2185                 }
2186         }
2187         else if(current < regenstable)
2188         {
2189                 if(regenframetime > 0)
2190                 {
2191                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2192                         current = min(regenstable, current + regenlinear * regenframetime);
2193                 }
2194         }
2195
2196         if(current > limit)
2197                 current = limit;
2198
2199         return current;
2200 }
2201
2202 void player_regen (void)
2203 {
2204         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2205         maxh = autocvar_g_balance_health_rotstable;
2206         maxa = autocvar_g_balance_armor_rotstable;
2207         maxf = autocvar_g_balance_fuel_rotstable;
2208         minh = autocvar_g_balance_health_regenstable;
2209         mina = autocvar_g_balance_armor_regenstable;
2210         minf = autocvar_g_balance_fuel_regenstable;
2211         limith = autocvar_g_balance_health_limit;
2212         limita = autocvar_g_balance_armor_limit;
2213         limitf = autocvar_g_balance_fuel_limit;
2214
2215         max_mod = regen_mod = rot_mod = limit_mod = 1;
2216
2217         if (self.runes & RUNE_REGEN)
2218         {
2219                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2220                 {
2221                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2222                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2223                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2224                 }
2225                 else
2226                 {
2227                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2228                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2229                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2230                 }
2231         }
2232         else if (self.runes & CURSE_VENOM)
2233         {
2234                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2235                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2236                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2237                 else
2238                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2239                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2240                 //if (!self.runes & RUNE_REGEN)
2241                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2242         }
2243         maxh = maxh * max_mod;
2244         //maxa = maxa * max_mod;
2245         //maxf = maxf * max_mod;
2246         minh = minh * max_mod;
2247         //mina = mina * max_mod;
2248         //minf = minf * max_mod;
2249         limith = limith * limit_mod;
2250         limita = limita * limit_mod;
2251         //limitf = limitf * limit_mod;
2252
2253         if(g_lms && g_ca)
2254                 rot_mod = 0;
2255
2256         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2257         {
2258                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2259                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2260
2261                 // if player rotted to death...  die!
2262                 if(self.health < 1)
2263                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2264         }
2265
2266         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2267                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2268 }
2269
2270 float zoomstate_set;
2271 void SetZoomState(float z)
2272 {
2273         if(z != self.zoomstate)
2274         {
2275                 self.zoomstate = z;
2276                 ClientData_Touch(self);
2277         }
2278         zoomstate_set = 1;
2279 }
2280
2281 void GetPressedKeys(void) {
2282         MUTATOR_CALLHOOK(GetPressedKeys);
2283         if (self.movement_x > 0) // get if movement keys are pressed
2284         {       // forward key pressed
2285                 self.pressedkeys |= KEY_FORWARD;
2286                 self.pressedkeys &~= KEY_BACKWARD;
2287         }
2288         else if (self.movement_x < 0)
2289         {       // backward key pressed
2290                 self.pressedkeys |= KEY_BACKWARD;
2291                 self.pressedkeys &~= KEY_FORWARD;
2292         }
2293         else
2294         {       // no x input
2295                 self.pressedkeys &~= KEY_FORWARD;
2296                 self.pressedkeys &~= KEY_BACKWARD;
2297         }
2298
2299         if (self.movement_y > 0)
2300         {       // right key pressed
2301                 self.pressedkeys |= KEY_RIGHT;
2302                 self.pressedkeys &~= KEY_LEFT;
2303         }
2304         else if (self.movement_y < 0)
2305         {       // left key pressed
2306                 self.pressedkeys |= KEY_LEFT;
2307                 self.pressedkeys &~= KEY_RIGHT;
2308         }
2309         else
2310         {       // no y input
2311                 self.pressedkeys &~= KEY_RIGHT;
2312                 self.pressedkeys &~= KEY_LEFT;
2313         }
2314
2315         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2316                 self.pressedkeys |= KEY_JUMP;
2317         else
2318                 self.pressedkeys &~= KEY_JUMP;
2319         if (self.BUTTON_CROUCH)
2320                 self.pressedkeys |= KEY_CROUCH;
2321         else
2322                 self.pressedkeys &~= KEY_CROUCH;
2323 }
2324
2325 /*
2326 ======================
2327 spectate mode routines
2328 ======================
2329 */
2330
2331 void SpectateCopy(entity spectatee) {
2332         other = spectatee;
2333         MUTATOR_CALLHOOK(SpectateCopy);
2334         self.armortype = spectatee.armortype;
2335         self.armorvalue = spectatee.armorvalue;
2336         self.ammo_cells = spectatee.ammo_cells;
2337         self.ammo_shells = spectatee.ammo_shells;
2338         self.ammo_nails = spectatee.ammo_nails;
2339         self.ammo_rockets = spectatee.ammo_rockets;
2340         self.ammo_fuel = spectatee.ammo_fuel;
2341         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2342         self.health = spectatee.health;
2343         self.impulse = 0;
2344         self.items = spectatee.items;
2345         self.last_pickup = spectatee.last_pickup;
2346         self.metertime = spectatee.metertime;
2347         self.strength_finished = spectatee.strength_finished;
2348         self.invincible_finished = spectatee.invincible_finished;
2349         self.pressedkeys = spectatee.pressedkeys;
2350         self.weapons = spectatee.weapons;
2351         self.switchweapon = spectatee.switchweapon;
2352         self.weapon = spectatee.weapon;
2353         self.punchangle = spectatee.punchangle;
2354         self.view_ofs = spectatee.view_ofs;
2355         self.v_angle = spectatee.v_angle;
2356         self.velocity = spectatee.velocity;
2357         self.dmg_take = spectatee.dmg_take;
2358         self.dmg_save = spectatee.dmg_save;
2359         self.dmg_inflictor = spectatee.dmg_inflictor;
2360         self.angles = spectatee.v_angle;
2361         self.fixangle = TRUE;
2362         setorigin(self, spectatee.origin);
2363         setsize(self, spectatee.mins, spectatee.maxs);
2364         SetZoomState(spectatee.zoomstate);
2365
2366         anticheat_spectatecopy(spectatee);
2367 }
2368
2369 float SpectateUpdate() {
2370         if(!self.enemy)
2371                 return 0;
2372
2373         if (self == self.enemy)
2374                 return 0;
2375
2376         if(self.enemy.classname != "player")
2377                 return 0;
2378
2379         SpectateCopy(self.enemy);
2380
2381         return 1;
2382 }
2383
2384 float SpectateNext() {
2385         other = find(self.enemy, classname, "player");
2386
2387         if (!other)
2388                 other = find(other, classname, "player");
2389
2390         if (other)
2391                 self.enemy = other;
2392
2393         if(self.enemy.classname == "player") {
2394                 msg_entity = self;
2395                 WriteByte(MSG_ONE, SVC_SETVIEW);
2396                 WriteEntity(MSG_ONE, self.enemy);
2397                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2398                 self.movetype = MOVETYPE_NONE;
2399                 accuracy_resend(self);
2400
2401                 if(!SpectateUpdate())
2402                         PutObserverInServer();
2403
2404                 return 1;
2405         } else {
2406                 return 0;
2407         }
2408 }
2409
2410 /*
2411 =============
2412 ShowRespawnCountdown()
2413
2414 Update a respawn countdown display.
2415 =============
2416 */
2417 void ShowRespawnCountdown()
2418 {
2419         float number;
2420         if(self.deadflag == DEAD_NO) // just respawned?
2421                 return;
2422         else
2423         {
2424                 number = ceil(self.death_time - time);
2425                 if(number <= 0)
2426                         return;
2427                 if(number <= self.respawn_countdown)
2428                 {
2429                         self.respawn_countdown = number - 1;
2430                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2431                                 AnnounceTo(self, strcat(ftos(number), ""));
2432                 }
2433         }
2434 }
2435
2436 void LeaveSpectatorMode()
2437 {
2438         if(isJoinAllowed()) {
2439                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2440                         self.classname = "player";
2441
2442                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2443                                 JoinBestTeam(self, FALSE, TRUE);
2444
2445                         if(autocvar_g_campaign)
2446                                 campaign_bots_may_start = 1;
2447
2448                         PutClientInServer();
2449
2450                         if(self.classname == "player")
2451                                 bprint ("^4", self.netname, "^4 is playing now\n");
2452
2453                         if(!autocvar_g_campaign)
2454                                 centerprint(self,""); // clear MOTD
2455
2456                         return;
2457                 } else {
2458                         if (g_ca && self.caplayer) {
2459                         }       // do nothing
2460                         else
2461                                 stuffcmd(self,"menu_showteamselect\n");
2462                         return;
2463                 }
2464         }
2465         else {
2466                 //player may not join because of g_maxplayers is set
2467                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2468         }
2469 }
2470
2471 /**
2472  * Determines whether the player is allowed to join. This depends on cvar
2473  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2474  * it checks whether the number of currently playing players exceeds g_maxplayers.
2475  * @return bool TRUE if the player is allowed to join, false otherwise
2476  */
2477 float isJoinAllowed() {
2478         if(self.team_forced < 0)
2479                 return FALSE; // forced spectators can never join
2480
2481         if (!autocvar_g_maxplayers)
2482                 return TRUE;
2483
2484         local entity e;
2485         local float currentlyPlaying;
2486         FOR_EACH_REALPLAYER(e) {
2487                 if(e.classname == "player")
2488                         currentlyPlaying += 1;
2489         }
2490         if(currentlyPlaying < autocvar_g_maxplayers)
2491                 return TRUE;
2492
2493         return FALSE;
2494 }
2495
2496 /**
2497  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2498  * g_maxplayers_spectator_blocktime seconds
2499  */
2500 void checkSpectatorBlock() {
2501         if(self.classname == "spectator" || self.classname == "observer") {
2502                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2503                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2504                         dropclient(self);
2505                 }
2506         }
2507 }
2508
2509 void ObserverThink()
2510 {
2511         if (self.flags & FL_JUMPRELEASED) {
2512                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2513                         self.welcomemessage_time = 0;
2514                         self.flags &~= FL_JUMPRELEASED;
2515                         self.flags |= FL_SPAWNING;
2516                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2517                         self.welcomemessage_time = 0;
2518                         self.flags &~= FL_JUMPRELEASED;
2519                         if(SpectateNext() == 1) {
2520                                 self.classname = "spectator";
2521                         }
2522                 }
2523         } else {
2524                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2525                         self.flags |= FL_JUMPRELEASED;
2526                         if(self.flags & FL_SPAWNING)
2527                         {
2528                                 self.flags &~= FL_SPAWNING;
2529                                 LeaveSpectatorMode();
2530                                 return;
2531                         }
2532                 }
2533         }
2534         PrintWelcomeMessage(self);
2535 }
2536
2537 void SpectatorThink()
2538 {
2539         if (self.flags & FL_JUMPRELEASED) {
2540                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2541                         self.welcomemessage_time = 0;
2542                         self.flags &~= FL_JUMPRELEASED;
2543                         self.flags |= FL_SPAWNING;
2544                 } else if(self.BUTTON_ATCK) {
2545                         self.welcomemessage_time = 0;
2546                         self.flags &~= FL_JUMPRELEASED;
2547                         if(SpectateNext() == 1) {
2548                                 self.classname = "spectator";
2549                         } else {
2550                                 self.classname = "observer";
2551                                 PutClientInServer();
2552                         }
2553                 } else if (self.BUTTON_ATCK2) {
2554                         self.welcomemessage_time = 0;
2555                         self.flags &~= FL_JUMPRELEASED;
2556                         self.classname = "observer";
2557                         PutClientInServer();
2558                 } else {
2559                         if(!SpectateUpdate())
2560                                 PutObserverInServer();
2561                 }
2562         } else {
2563                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2564                         self.flags |= FL_JUMPRELEASED;
2565                         if(self.flags & FL_SPAWNING)
2566                         {
2567                                 self.flags &~= FL_SPAWNING;
2568                                 LeaveSpectatorMode();
2569                                 return;
2570                         }
2571                 }
2572         }
2573
2574         PrintWelcomeMessage(self);
2575         self.flags |= FL_CLIENT | FL_NOTARGET;
2576 }
2577
2578 .float touchexplode_time;
2579
2580 /*
2581 =============
2582 PlayerPreThink
2583
2584 Called every frame for each client before the physics are run
2585 =============
2586 */
2587 void() ctf_setstatus;
2588 void() nexball_setstatus;
2589 .float items_added;
2590 void PlayerPreThink (void)
2591 {
2592         self.stat_game_starttime = game_starttime;
2593         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2594         self.stat_leadlimit = autocvar_leadlimit;
2595
2596         if(frametime)
2597         {
2598                 // physics frames: update anticheat stuff
2599                 anticheat_prethink();
2600         }
2601
2602         if(blockSpectators && frametime)
2603                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2604                 checkSpectatorBlock();
2605
2606         zoomstate_set = 0;
2607
2608         if(self.netname_previous != self.netname)
2609         {
2610                 if(autocvar_sv_eventlog)
2611                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2612                 if(self.netname_previous)
2613                         strunzone(self.netname_previous);
2614                 self.netname_previous = strzone(self.netname);
2615         }
2616
2617         // version nagging
2618         if(self.version_nagtime)
2619                 if(self.cvar_g_xonoticversion)
2620                         if(time > self.version_nagtime)
2621                         {
2622                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2623                                 {
2624                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2625                                         {
2626                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2627                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2628                                         }
2629                                         else
2630                                         {
2631                                                 float r;
2632                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2633                                                 if(r < 0)
2634                                                 {
2635                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2636                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2637                                                 }
2638                                                 else if(r > 0)
2639                                                 {
2640                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2641                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2642                                                 }
2643                                         }
2644                                 }
2645                                 self.version_nagtime = 0;
2646                         }
2647
2648         // GOD MODE info
2649         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2650         {
2651                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2652                 self.max_armorvalue = 0;
2653         }
2654
2655 #ifdef TETRIS
2656         if (TetrisPreFrame())
2657                 return;
2658 #endif
2659
2660         MUTATOR_CALLHOOK(PlayerPreThink);
2661
2662         if(self.classname == "player") {
2663 //              if(self.netname == "Wazat")
2664 //                      bprint(self.classname, "\n");
2665
2666                 CheckRules_Player();
2667
2668                 PrintWelcomeMessage(self);
2669
2670                 if (intermission_running)
2671                 {
2672                         IntermissionThink ();   // otherwise a button could be missed between
2673                         return;                                 // the think tics
2674                 }
2675
2676                 if(self.teleport_time)
2677                 if(time > self.teleport_time)
2678                 {
2679                         self.teleport_time = 0;
2680                         self.effects = self.effects - (self.effects & EF_NODRAW);
2681                 }
2682
2683                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2684                         UpdateSelectedPlayer();
2685
2686                 //don't allow the player to turn around while game is paused!
2687                 if(timeoutStatus == 2) {
2688                         self.v_angle = self.lastV_angle;
2689                         self.angles = self.lastV_angle;
2690                         self.fixangle = TRUE;
2691                 }
2692
2693                 if(frametime)
2694                 {
2695                         if(self.health <= 0 && autocvar_g_deathglow)
2696                         {
2697                                 if(self.glowmod_x > 0)
2698                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2699                                 else
2700                                         self.glowmod_x = -1;
2701                                 if(self.glowmod_y > 0)
2702                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2703                                 else
2704                                         self.glowmod_y = -1;
2705                                 if(self.glowmod_z > 0)
2706                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2707                                 else
2708                                         self.glowmod_z = -1;
2709                         }
2710                         else
2711                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2712                         player_powerups();
2713                 }
2714
2715                 if (self.deadflag != DEAD_NO)
2716                 {
2717                         float button_pressed, force_respawn;
2718                         if(self.personal && g_race_qualifying)
2719                         {
2720                                 if(time > self.death_time)
2721                                 {
2722                                         self.death_time = time + 1; // only retry once a second
2723                                         respawn();
2724                                         self.impulse = 141;
2725                                 }
2726                         }
2727                         else
2728                         {
2729                                 if(frametime)
2730                                         player_anim();
2731                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2732                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2733                                 if (self.deadflag == DEAD_DYING)
2734                                 {
2735                                         if(force_respawn)
2736                                                 self.deadflag = DEAD_RESPAWNING;
2737                                         else if(!button_pressed)
2738                                                 self.deadflag = DEAD_DEAD;
2739                                 }
2740                                 else if (self.deadflag == DEAD_DEAD)
2741                                 {
2742                                         if(button_pressed)
2743                                                 self.deadflag = DEAD_RESPAWNABLE;
2744                                 }
2745                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2746                                 {
2747                                         if(!button_pressed)
2748                                                 self.deadflag = DEAD_RESPAWNING;
2749                                 }
2750                                 else if (self.deadflag == DEAD_RESPAWNING)
2751                                 {
2752                                         if(time > self.death_time)
2753                                         {
2754                                                 self.death_time = time + 1; // only retry once a second
2755                                                 respawn();
2756                                         }
2757                                 }
2758                                 ShowRespawnCountdown();
2759                         }
2760                         return;
2761                 }
2762
2763                 if(g_touchexplode)
2764                 if(time > self.touchexplode_time)
2765                 if(self.classname == "player")
2766                 if(self.deadflag == DEAD_NO)
2767                 if not(IS_INDEPENDENT_PLAYER(self))
2768                 FOR_EACH_PLAYER(other) if(self != other)
2769                 {
2770                         if(time > other.touchexplode_time)
2771                         if(other.deadflag == DEAD_NO)
2772                         if not(IS_INDEPENDENT_PLAYER(other))
2773                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2774                         {
2775                                 PlayerTouchExplode(self, other);
2776                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2777                         }
2778                 }
2779
2780                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2781                 {
2782                         vector dist;
2783
2784                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2785                         dist = self.prevorigin - self.origin;
2786                         dist_z = 0;
2787                         self.lms_traveled_distance += fabs(vlen(dist));
2788
2789                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2790                         {
2791                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2792                                 self.lms_traveled_distance = 0;
2793                         }
2794
2795                         if(time > self.lms_nextcheck)
2796                         {
2797                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2798                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2799                                 {
2800                                         centerprint(self, autocvar_g_lms_campcheck_message);
2801                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2802                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2803                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2804                                 }
2805                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2806                                 self.lms_traveled_distance = 0;
2807                         }
2808                 }
2809
2810                 self.prevorigin = self.origin;
2811
2812                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2813                 {
2814                         if (!self.crouch)
2815                         {
2816                                 self.crouch = TRUE;
2817                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2818                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2819                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2820                         }
2821                 }
2822                 else
2823                 {
2824                         if (self.crouch)
2825                         {
2826                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2827                                 if (!trace_startsolid)
2828                                 {
2829                                         self.crouch = FALSE;
2830                                         self.view_ofs = PL_VIEW_OFS;
2831                                         setsize (self, PL_MIN, PL_MAX);
2832                                 }
2833                         }
2834                 }
2835
2836                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2837                 {
2838                         if(self.bloodloss_timer < time)
2839                         {
2840                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2841                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2842                         }
2843                 }
2844
2845                 FixPlayermodel();
2846
2847                 GrapplingHookFrame();
2848
2849                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2850                 //if(frametime)
2851                 {
2852                         self.items &~= self.items_added;
2853
2854                         W_WeaponFrame();
2855
2856                         self.items_added = 0;
2857                         if(self.items & IT_JETPACK)
2858                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2859                                         self.items_added |= IT_FUEL;
2860
2861                         self.items |= self.items_added;
2862                 }
2863
2864                 player_regen();
2865
2866                 // rot nex charge to the charge limit
2867                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2868                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2869
2870                 if(frametime)
2871                         player_anim();
2872
2873                 if (g_minstagib)
2874                         minstagib_ammocheck();
2875
2876                 if(g_ctf)
2877                         ctf_setstatus();
2878
2879                 if(g_nexball)
2880                         nexball_setstatus();
2881
2882                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2883
2884                 //self.angles_y=self.v_angle_y + 90;   // temp
2885         } else if(gameover) {
2886                 if (intermission_running)
2887                         IntermissionThink ();   // otherwise a button could be missed between
2888                 return;
2889         } else if(self.classname == "observer") {
2890                 ObserverThink();
2891         } else if(self.classname == "spectator") {
2892                 SpectatorThink();
2893         }
2894
2895         if(!zoomstate_set)
2896                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2897
2898         float oldspectatee_status;
2899         oldspectatee_status = self.spectatee_status;
2900         if(self.classname == "spectator")
2901                 self.spectatee_status = num_for_edict(self.enemy);
2902         else if(self.classname == "observer")
2903                 self.spectatee_status = num_for_edict(self);
2904         else
2905                 self.spectatee_status = 0;
2906         if(self.spectatee_status != oldspectatee_status)
2907         {
2908                 ClientData_Touch(self);
2909                 if(g_race || g_cts)
2910                         race_InitSpectator();
2911         }
2912
2913         if(self.teamkill_soundtime)
2914         if(time > self.teamkill_soundtime)
2915         {
2916                 self.teamkill_soundtime = 0;
2917
2918                 entity oldpusher, oldself;
2919
2920                 oldself = self; self = self.teamkill_soundsource;
2921                 oldpusher = self.pusher; self.pusher = oldself;
2922
2923                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2924
2925                 self.pusher = oldpusher;
2926                 self = oldself;
2927         }
2928
2929         if(self.taunt_soundtime)
2930         if(time > self.taunt_soundtime)
2931         {
2932                 self.taunt_soundtime = 0;
2933                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2934         }
2935
2936         target_voicescript_next(self);
2937 }
2938
2939 float isInvisibleString(string s)
2940 {
2941         float i, n, c;
2942         s = strdecolorize(s);
2943         for((i = 0), (n = strlen(s)); i < n; ++i)
2944         {
2945                 c = str2chr(s, i);
2946                 switch(c)
2947                 {
2948                         case 0:
2949                         case 32: // space
2950                                 break;
2951                         case 192: // charmap space
2952                                 if (!autocvar_utf8_enable)
2953                                         break;
2954                                 return FALSE;
2955                         case 160: // space in unicode fonts
2956                         case 0xE000 + 192: // utf8 charmap space
2957                                 if (autocvar_utf8_enable)
2958                                         break;
2959                         default:
2960                                 return FALSE;
2961                 }
2962         }
2963         return TRUE;
2964 }
2965
2966 /*
2967 =============
2968 PlayerPostThink
2969
2970 Called every frame for each client after the physics are run
2971 =============
2972 */
2973 .float idlekick_lasttimeleft;
2974 .entity showheadshotbbox;
2975 void showheadshotbbox_think()
2976 {
2977         if(self.owner.showheadshotbbox != self)
2978         {
2979                 remove(self);
2980                 return;
2981         }
2982         self.nextthink = time;
2983         setorigin(self, self.owner.origin);
2984         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2985 }
2986 void PlayerPostThink (void)
2987 {
2988         // Savage: Check for nameless players
2989         if (isInvisibleString(self.netname)) {
2990                 self.netname = "Player";
2991                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2992         }
2993
2994         if(sv_maxidle && frametime)
2995         {
2996                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2997                 float timeleft;
2998                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2999                 if(timeleft <= 0)
3000                 {
3001                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3002                         AnnounceTo(self, "terminated");
3003                         dropclient(self);
3004                         return;
3005                 }
3006                 else if(timeleft <= 10)
3007                 {
3008                         if(timeleft != self.idlekick_lasttimeleft)
3009                         {
3010                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3011                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3012                         }
3013                 }
3014                 else
3015                 {
3016                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3017                 }
3018                 self.idlekick_lasttimeleft = timeleft;
3019         }
3020
3021 #ifdef TETRIS
3022         if(self.impulse == 100)
3023                 ImpulseCommands();
3024         if (TetrisPostFrame())
3025                 return;
3026 #endif
3027
3028         CheatFrame();
3029
3030         if(self.classname == "player") {
3031                 CheckRules_Player();
3032                 UpdateChatBubble();
3033                 UpdateTeamBubble();
3034                 if (self.impulse)
3035                         ImpulseCommands();
3036                 if (intermission_running)
3037                         return;         // intermission or finale
3038                 GetPressedKeys();
3039         } else if (self.classname == "observer") {
3040                 //do nothing
3041         } else if (self.classname == "spectator") {
3042                 //do nothing
3043         }
3044