Merge remote branch 'origin/master' into samual/flyingspectators
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck >= 0)
136                 if(spot.team != teamcheck)
137                         return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(autocvar_spawn_debugview)
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck >= 0)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck >= 0)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         if(anypoint)
329                 teamcheck = -1;
330         else if(have_team_spawns > 0)
331                 teamcheck = self.team; // MUST be team
332         else if(have_team_spawns == 0 && have_noteam_spawns)
333                 teamcheck = 0; // MUST be noteam
334         else
335                 teamcheck = -1;
336                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
337
338         // get the list of players
339         playerlist = findchain(classname, "player");
340         // get the entire list of spots
341         firstspot = findchain(classname, "info_player_deathmatch");
342         // filter out the bad ones
343         // (note this returns the original list if none survived)
344         if(anypoint)
345         {
346                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
347         }
348         else
349         {
350                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
351                 if(!firstspot_new)
352                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
353                 firstspot = firstspot_new;
354
355                 // there is 50/50 chance of choosing a random spot or the furthest spot
356                 // (this means that roughly every other spawn will be furthest, so you
357                 // usually won't get fragged at spawn twice in a row)
358                 if (arena_roundbased && !g_ca)
359                 {
360                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
361                         if(firstspot_new)
362                                 firstspot = firstspot_new;
363                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
364                 }
365                 else if (random() > autocvar_g_spawn_furthest)
366                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
367                 else
368                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
369         }
370
371         if(autocvar_spawn_debugview)
372         {
373                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
374
375                 entity e;
376                 if(teamcheck >= 0)
377                         for(e = firstspot; e; e = e.chain)
378                                 if(e.team != teamcheck)
379                                         error("invalid spawn found");
380         }
381
382         if (!spot)
383         {
384                 if(autocvar_spawn_debug)
385                         GotoNextMap();
386                 else
387                 {
388                         if(some_spawn_has_been_used)
389                                 return world; // team can't spawn any more, because of actions of other team
390                         else
391                                 error("Cannot find a spawn point - please fix the map!");
392                 }
393         }
394
395         return spot;
396 }
397
398 /*
399 =============
400 CheckPlayerModel
401
402 Checks if the argument string can be a valid playermodel.
403 Returns a valid one in doubt.
404 =============
405 */
406 string FallbackPlayerModel;
407 string CheckPlayerModel(string plyermodel) {
408         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
409         {
410                 // note: we cannot summon Don Strunzone here, some player may
411                 // still have the model string set. In case anyone manages how
412                 // to change a cvar default, we'll have a small leak here.
413                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
414         }
415         if(strlen(plyermodel) < 4)
416                 return FallbackPlayerModel;
417         if( substring(plyermodel,0,14) != "models/player/")
418                 return FallbackPlayerModel;
419         else if(autocvar_sv_servermodelsonly)
420         {
421                 if(substring(plyermodel,-4,4) != ".zym")
422                 if(substring(plyermodel,-4,4) != ".dpm")
423                 if(substring(plyermodel,-4,4) != ".iqm")
424                 if(substring(plyermodel,-4,4) != ".md3")
425                 if(substring(plyermodel,-4,4) != ".psk")
426                         return FallbackPlayerModel;
427                 // forbid the LOD models
428                 if(substring(plyermodel, -9,5) == "_lod1")
429                         return FallbackPlayerModel;
430                 if(substring(plyermodel, -9,5) == "_lod2")
431                         return FallbackPlayerModel;
432                 if(plyermodel != strtolower(plyermodel))
433                         return FallbackPlayerModel;
434                 if(!fexists(plyermodel))
435                         return FallbackPlayerModel;
436         }
437         return plyermodel;
438 }
439
440 /*
441 =============
442 Client_customizeentityforclient
443
444 LOD reduction
445 =============
446 */
447 void Client_uncustomizeentityforclient()
448 {
449         if(self.modelindex == 0) // no need to uncustomize then
450                 return;
451         self.modelindex = self.modelindex_lod0;
452         self.skin = self.skinindex;
453 }
454
455 float Client_customizeentityforclient()
456 {
457         entity modelsource;
458
459         if(self.modelindex == 0)
460                 return TRUE;
461
462         // forcemodel stuff
463
464 #ifdef PROFILING
465         float t0;
466         t0 = gettime(GETTIME_HIRES); // reference
467 #endif
468
469         modelsource = self;
470
471 #ifdef ALLOW_FORCEMODELS
472         if(other.cvar_cl_forceplayermodelsfromxonotic)
473                 if not(self.modelindex_lod0_from_xonotic)
474                         modelsource = other;
475         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
476                 modelsource = other;
477 #endif
478
479         self.skin = modelsource.skinindex;
480
481 #if 0
482         if(modelsource == self)
483                 self.skin = modelsource.skinindex;
484         else
485                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
486 #endif
487
488         // self: me
489         // other: the player viewing me
490         float distance;
491         float f;
492
493         if(other.cvar_cl_playerdetailreduction <= 0)
494         {
495                 if(other.cvar_cl_playerdetailreduction <= -2)
496                         self.modelindex = modelsource.modelindex_lod2;
497                 else if(other.cvar_cl_playerdetailreduction <= -1)
498                         self.modelindex = modelsource.modelindex_lod1;
499                 else
500                         self.modelindex = modelsource.modelindex_lod0;
501         }
502         else
503         {
504                 distance = vlen(self.origin - other.origin);
505                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
506                 if(f > sv_loddistance2)
507                         self.modelindex = modelsource.modelindex_lod2;
508                 else if(f > sv_loddistance1)
509                         self.modelindex = modelsource.modelindex_lod1;
510                 else
511                         self.modelindex = modelsource.modelindex_lod0;
512         }
513
514 #ifdef PROFILING
515         float t1;
516         t1 = gettime(GETTIME_HIRES); // reference
517         client_cefc_accumulator += (t1 - t0);
518 #endif
519
520         return TRUE;
521 }
522
523 void setmodel_lod(entity e, string modelname)
524 {
525         string s;
526
527         if(sv_loddistance1)
528         {
529                 // FIXME: this only supports 3-letter extensions
530                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
531                 if(fexists(s))
532                 {
533                         setmodel(e, s); // players have high precision
534                         self.modelindex_lod1 = self.modelindex;
535                 }
536                 else
537                         self.modelindex_lod1 = -1;
538
539                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
540                 if(fexists(s))
541                 {
542                         setmodel(e, s); // players have high precision
543                         self.modelindex_lod2 = self.modelindex;
544                 }
545                 else
546                         self.modelindex_lod2 = -1;
547
548                 precache_model(modelname);
549                 setmodel(e, modelname); // players have high precision
550                 self.modelindex_lod0 = self.modelindex;
551
552                 if(self.modelindex_lod1 < 0)
553                         self.modelindex_lod1 = self.modelindex;
554
555                 if(self.modelindex_lod2 < 0)
556                         self.modelindex_lod2 = self.modelindex;
557         }
558         else
559         {
560                 precache_model(modelname);
561                 setmodel(e, modelname); // players have high precision
562                 self.modelindex_lod0 = self.modelindex;
563                         // save it for possible player model forcing
564         }
565
566         s = whichpack(self.model);
567         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
568
569         player_setupanimsformodel();
570         UpdatePlayerSounds();
571 }
572
573 /*
574 =============
575 PutObserverInServer
576
577 putting a client as observer in the server
578 =============
579 */
580 void FixPlayermodel();
581 void PutObserverInServer (void)
582 {
583         entity  spot;
584
585         race_PreSpawnObserver();
586
587         spot = SelectSpawnPoint (TRUE);
588         if(!spot)
589                 error("No spawnpoints for observers?!?\n");
590         RemoveGrapplingHook(self); // Wazat's Grappling Hook
591
592         if(clienttype(self) == CLIENTTYPE_REAL)
593         {
594                 msg_entity = self;
595                 WriteByte(MSG_ONE, SVC_SETVIEW);
596                 WriteEntity(MSG_ONE, self);
597         }
598
599         DropAllRunes(self);
600         MUTATOR_CALLHOOK(MakePlayerObserver);
601
602         Portal_ClearAll(self);
603
604         if(self.alivetime)
605         {
606                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
607                 self.alivetime = 0;
608         }
609
610         if(self.flagcarried)
611                 DropFlag(self.flagcarried, world, world);
612
613         if(self.ballcarried && g_nexball)
614                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
615
616         WaypointSprite_PlayerDead();
617
618         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
619                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
620
621         if(self.killcount != -666) {
622                 if(g_lms) {
623                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
624                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
625                         else
626                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
627                 } else
628                         bprint ("^4", self.netname, "^4 is spectating now\n");
629
630                 if(self.just_joined == FALSE) {
631                         LogTeamchange(self.playerid, -1, 4);
632                 } else
633                         self.just_joined = FALSE;
634         }
635
636         PlayerScore_Clear(self); // clear scores when needed
637
638         accuracy_resend(self);
639
640         self.spectatortime = time;
641
642         self.classname = "observer";
643         self.iscreature = FALSE;
644         self.health = -666;
645         self.takedamage = DAMAGE_NO;
646         self.solid = SOLID_TRIGGER; // FIXME: SOLID_TRIGGER doesn't work for doors, and SOLID_NOT doesn't work for teleporters... can we do what warpzones do to fix this?
647         self.movetype = MOVETYPE_FLY;
648         self.flags = FL_CLIENT | FL_NOTARGET;
649         self.armorvalue = 666;
650         self.effects = 0;
651         self.armorvalue = autocvar_g_balance_armor_start;
652         self.pauserotarmor_finished = 0;
653         self.pauserothealth_finished = 0;
654         self.pauseregen_finished = 0;
655         self.damageforcescale = 0;
656         self.death_time = 0;
657         self.dead_frame = 0;
658         self.alpha = 0;
659         self.scale = 0;
660         self.fade_time = 0;
661         self.pain_frame = 0;
662         self.pain_finished = 0;
663         self.strength_finished = 0;
664         self.invincible_finished = 0;
665         self.pushltime = 0;
666         self.think = SUB_Null;
667         self.nextthink = 0;
668         self.hook_time = 0;
669         self.runes = 0;
670         self.deadflag = DEAD_NO;
671         self.angles = spot.angles;
672         self.angles_z = 0;
673         self.fixangle = TRUE;
674         self.crouch = FALSE;
675
676         self.view_ofs = '0 0 0'; // so that you can't go inside walls with MOVETYPE_FLY, previously "PL_VIEW_OFS" - for some reason this is diff from normal players
677         setorigin (self, spot.origin);
678         setsize (self, '-16 -16 -24', '16 16 24'); // so that you can't go inside walls with MOVETYPE_FLY
679         self.prevorigin = self.origin;
680         self.items = 0;
681         self.weapons = 0;
682         self.model = "";
683         FixPlayermodel();
684         self.model = "";
685         self.modelindex = 0;
686         self.weapon = 0;
687         self.weaponmodel = "";
688         self.weaponentity = world;
689         self.exteriorweaponentity = world;
690         self.killcount = -666;
691         self.velocity = '0 0 0';
692         self.avelocity = '0 0 0';
693         self.punchangle = '0 0 0';
694         self.punchvector = '0 0 0';
695         self.oldvelocity = self.velocity;
696         self.fire_endtime = -1;
697
698         if(sv_loddistance1)
699                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
700
701         if(g_arena)
702         {
703                 if(self.version_mismatch)
704                 {
705                         Spawnqueue_Unmark(self);
706                         Spawnqueue_Remove(self);
707                 }
708                 else
709                 {
710                         Spawnqueue_Insert(self);
711                 }
712         }
713         else if(g_lms)
714         {
715                 // Only if the player cannot play at all
716                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
717                         self.frags = FRAGS_SPECTATOR;
718                 else
719                         self.frags = FRAGS_LMS_LOSER;
720         }
721         else
722                 self.frags = FRAGS_SPECTATOR;
723 }
724
725 void FixPlayermodel()
726 {
727         local string defaultmodel;
728         local float defaultskin, chmdl, oldskin;
729         local vector m1, m2;
730
731         defaultmodel = "";
732
733         if(autocvar_sv_defaultcharacter == 1) {
734                 defaultskin = 0;
735
736                 if(teams_matter)
737                 {
738                         string s;
739                         s = Team_ColorNameLowerCase(self.team);
740                         if(s != "neutral")
741                         {
742                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
743                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
744                         }
745                 }
746
747                 if(defaultmodel == "")
748                 {
749                         defaultmodel = autocvar_sv_defaultplayermodel;
750                         defaultskin = autocvar_sv_defaultplayerskin;
751                 }
752         }
753
754         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
755         {
756                 if(self.model != "")
757                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
758                 self.model = ""; // force the != checks to return true
759         }
760
761         if(defaultmodel != "")
762         {
763                 if (defaultmodel != self.model)
764                 {
765                         m1 = self.mins;
766                         m2 = self.maxs;
767                         setmodel_lod (self, defaultmodel);
768                         setsize (self, m1, m2);
769                         chmdl = TRUE;
770                 }
771
772                 oldskin = self.skinindex;
773                 self.skinindex = defaultskin;
774         } else {
775                 if (self.playermodel != self.model || self.playermodel == "")
776                 {
777                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
778                         m1 = self.mins;
779                         m2 = self.maxs;
780                         setmodel_lod (self, self.playermodel);
781                         setsize (self, m1, m2);
782                         chmdl = TRUE;
783                 }
784
785                 oldskin = self.skinindex;
786                 self.skinindex = stof(self.playerskin);
787         }
788
789         if(chmdl || oldskin != self.skinindex)
790                 self.species = player_getspecies(); // model or skin has changed
791
792         if(!teams_matter)
793                 if(strlen(autocvar_sv_defaultplayercolors))
794                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
795                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
796 }
797
798 void PlayerTouchExplode(entity p1, entity p2)
799 {
800         vector org;
801         org = (p1.origin + p2.origin) * 0.5;
802         org_z += (p1.mins_z + p2.mins_z) * 0.5;
803
804         te_explosion(org);
805
806         entity e;
807         e = spawn();
808         setorigin(e, org);
809         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
810         remove(e);
811 }
812
813 /*
814 =============
815 PutClientInServer
816
817 Called when a client spawns in the server
818 =============
819 */
820 //void() ctf_playerchanged;
821 void PutClientInServer (void)
822 {
823         if(clienttype(self) == CLIENTTYPE_BOT)
824         {
825                 self.classname = "player";
826         }
827         else if(clienttype(self) == CLIENTTYPE_REAL)
828         {
829                 msg_entity = self;
830                 WriteByte(MSG_ONE, SVC_SETVIEW);
831                 WriteEntity(MSG_ONE, self);
832         }
833
834         // player is dead and becomes observer
835         // FIXME fix LMS scoring for new system
836         if(g_lms)
837         {
838                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
839                         self.classname = "observer";
840         }
841
842         if(g_arena || (g_ca && !allowed_to_spawn))
843         if(!self.spawned)
844                 self.classname = "observer";
845
846         if(gameover)
847                 self.classname = "observer";
848
849         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
850                 entity spot, oldself;
851                 float j;
852
853                 accuracy_resend(self);
854
855                 if(self.team < 0)
856                         JoinBestTeam(self, FALSE, TRUE);
857
858                 race_PreSpawn();
859
860                 spot = SelectSpawnPoint (FALSE);
861                 if(!spot)
862                 {
863                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
864                         return; // spawn failed
865                 }
866
867                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
868
869                 self.classname = "player";
870                 self.wasplayer = TRUE;
871                 self.iscreature = TRUE;
872                 self.movetype = MOVETYPE_WALK;
873                 self.solid = SOLID_SLIDEBOX;
874                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
875                 if(autocvar_g_playerclip_collisions)
876                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
877                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
878                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
879                 self.frags = FRAGS_PLAYER;
880                 if(independent_players)
881                         MAKE_INDEPENDENT_PLAYER(self);
882                 self.flags = FL_CLIENT;
883                 self.takedamage = DAMAGE_AIM;
884                 if(g_minstagib)
885                         self.effects = EF_FULLBRIGHT;
886                 else
887                         self.effects = 0;
888                 self.air_finished = time + 12;
889                 self.dmg = 2;
890                 if(autocvar_g_balance_nex_charge)
891                 {
892                         if(autocvar_g_balance_nex_secondary_chargepool)
893                                 self.nex_chargepool_ammo = 1;
894                         self.nex_charge = autocvar_g_balance_nex_charge_start;
895                 }
896
897                 if(inWarmupStage)
898                 {
899                         self.ammo_shells = warmup_start_ammo_shells;
900                         self.ammo_nails = warmup_start_ammo_nails;
901                         self.ammo_rockets = warmup_start_ammo_rockets;
902                         self.ammo_cells = warmup_start_ammo_cells;
903                         self.ammo_fuel = warmup_start_ammo_fuel;
904                         self.health = warmup_start_health;
905                         self.armorvalue = warmup_start_armorvalue;
906                         self.weapons = warmup_start_weapons;
907                 }
908                 else
909                 {
910                         self.ammo_shells = start_ammo_shells;
911                         self.ammo_nails = start_ammo_nails;
912                         self.ammo_rockets = start_ammo_rockets;
913                         self.ammo_cells = start_ammo_cells;
914                         self.ammo_fuel = start_ammo_fuel;
915                         self.health = start_health;
916                         self.armorvalue = start_armorvalue;
917                         self.weapons = start_weapons;
918                 }
919
920                 if(g_weaponarena_random)
921                 {
922                         if(g_weaponarena_random_with_laser)
923                                 self.weapons &~= WEPBIT_LASER;
924                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
925                         if(g_weaponarena_random_with_laser)
926                                 self.weapons |= WEPBIT_LASER;
927                 }
928
929                 self.items = start_items;
930                 self.jump_interval = time;
931
932                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
933                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
934                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
935                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
936                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
937                 //extend the pause of rotting if client was reset at the beginning of the countdown
938                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
939                         self.spawnshieldtime += game_starttime - time;
940                         self.pauserotarmor_finished += game_starttime - time;
941                         self.pauserothealth_finished += game_starttime - time;
942                         self.pauseregen_finished += game_starttime - time;
943                 }
944                 self.damageforcescale = 2;
945                 self.death_time = 0;
946                 self.dead_frame = 0;
947                 self.alpha = 0;
948                 self.scale = 0;
949                 self.fade_time = 0;
950                 self.pain_frame = 0;
951                 self.pain_finished = 0;
952                 self.strength_finished = 0;
953                 self.invincible_finished = 0;
954                 self.pushltime = 0;
955                 // players have no think function
956                 self.think = SUB_Null;
957                 self.nextthink = 0;
958                 self.hook_time = 0;
959                 self.dmg_team = 0;
960                 self.ballistics_density = autocvar_g_ballistics_density_player;
961
962                 self.metertime = 0;
963
964                 self.runes = 0;
965
966                 self.deadflag = DEAD_NO;
967
968                 self.angles = spot.angles;
969
970                 self.angles_z = 0; // never spawn tilted even if the spot says to
971                 self.fixangle = TRUE; // turn this way immediately
972                 self.velocity = '0 0 0';
973                 self.avelocity = '0 0 0';
974                 self.punchangle = '0 0 0';
975                 self.punchvector = '0 0 0';
976                 self.oldvelocity = self.velocity;
977                 self.fire_endtime = -1;
978
979                 msg_entity = self;
980                 WRITESPECTATABLE_MSG_ONE({
981                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
982                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
983                 });
984
985                 if(sv_loddistance1)
986                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
987
988                 self.model = "";
989                 FixPlayermodel();
990
991                 self.crouch = FALSE;
992                 self.view_ofs = PL_VIEW_OFS;
993                 setsize (self, PL_MIN, PL_MAX);
994                 self.spawnorigin = spot.origin;
995                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
996                 // don't reset back to last position, even if new position is stuck in solid
997                 self.oldorigin = self.origin;
998                 self.prevorigin = self.origin;
999                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1000
1001                 if(g_arena)
1002                 {
1003                         Spawnqueue_Remove(self);
1004                         Spawnqueue_Mark(self);
1005                 }
1006
1007                 else if(g_ca)
1008                         self.caplayer = 1;
1009
1010                 self.event_damage = PlayerDamage;
1011
1012                 self.bot_attack = TRUE;
1013
1014                 self.statdraintime = time + 5;
1015                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1016
1017                 if(self.killcount == -666) {
1018                         PlayerScore_Clear(self);
1019                         self.killcount = 0;
1020                 }
1021
1022                 self.cnt = WEP_LASER;
1023
1024                 CL_SpawnWeaponentity();
1025                 self.alpha = default_player_alpha;
1026                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1027                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1028
1029                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1030                 self.lms_traveled_distance = 0;
1031                 self.speedrunning = FALSE;
1032
1033                 race_PostSpawn(spot);
1034
1035                 if(autocvar_spawn_debug)
1036                 {
1037                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1038                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1039                 }
1040
1041                 //stuffcmd(self, "chase_active 0");
1042                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1043
1044                 if (autocvar_g_spawnsound)
1045                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1046
1047                 if(g_assault) {
1048                         if(self.team == assault_attacker_team)
1049                                 centerprint(self, "You are attacking!");
1050                         else
1051                                 centerprint(self, "You are defending!");
1052                 }
1053
1054                 target_voicescript_clear(self);
1055
1056                 // reset fields the weapons may use
1057                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1058                 {
1059                         weapon_action(j, WR_RESETPLAYER);
1060
1061                         // all weapons must be fully loaded when we spawn
1062                         entity e;
1063                         e = get_weaponinfo(j);
1064                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1065                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1066                 }
1067
1068                 oldself = self;
1069                 self = spot;
1070                         activator = oldself;
1071                                 SUB_UseTargets();
1072                         activator = world;
1073                 self = oldself;
1074
1075                 MUTATOR_CALLHOOK(PlayerSpawn);
1076
1077                 self.switchweapon = w_getbestweapon(self);
1078                 self.cnt = self.switchweapon;
1079                 self.weapon = 0;
1080
1081                 if(!self.alivetime)
1082                         self.alivetime = time;
1083         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1084                 PutObserverInServer ();
1085         }
1086
1087         //if(g_ctf)
1088         //      ctf_playerchanged();
1089 }
1090
1091 .float ebouncefactor, ebouncestop; // electro's values
1092 // TODO do we need all these fields, or should we stop autodetecting runtime
1093 // changes and just have a console command to update this?
1094 float ClientInit_SendEntity(entity to, float sf)
1095 {
1096         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1097         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1098         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1099         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1100         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1101         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1102         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1103         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1104         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1105         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1106         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1107         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1108         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1109         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1110         if(sv_foginterval && world.fog != "")
1111                 WriteString(MSG_ENTITY, world.fog);
1112         else
1113                 WriteString(MSG_ENTITY, "");
1114         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1115         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1116         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1117         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1118         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1119         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1120         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1121         WriteByte(MSG_ENTITY, autocvar_g_balance_sniperrifle_secondary); // client has to know if it should zoom or not
1122         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1123         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1124         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1125         return TRUE;
1126 }
1127
1128 void ClientInit_CheckUpdate()
1129 {
1130         self.nextthink = time;
1131         if(self.count != autocvar_g_balance_armor_blockpercent)
1132         {
1133                 self.count = autocvar_g_balance_armor_blockpercent;
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1137         {
1138                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1142         {
1143                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1144                 self.SendFlags |= 1;
1145         }
1146         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1147         {
1148                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1149                 self.SendFlags |= 1;
1150         }
1151         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1152         {
1153                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1154                 self.SendFlags |= 1;
1155         }
1156         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1157         {
1158                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1159                 self.SendFlags |= 1;
1160         }
1161 }
1162
1163 void ClientInit_Spawn()
1164 {
1165         entity o;
1166         entity e;
1167         e = spawn();
1168         e.classname = "clientinit";
1169         e.think = ClientInit_CheckUpdate;
1170         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1171
1172         o = self;
1173         self = e;
1174         ClientInit_CheckUpdate();
1175         self = o;
1176 }
1177
1178 /*
1179 =============
1180 SetNewParms
1181 =============
1182 */
1183 void SetNewParms (void)
1184 {
1185         // initialize parms for a new player
1186         parm1 = -(86400 * 366);
1187 }
1188
1189 /*
1190 =============
1191 SetChangeParms
1192 =============
1193 */
1194 void SetChangeParms (void)
1195 {
1196         // save parms for level change
1197         parm1 = self.parm_idlesince - time;
1198 }
1199
1200 /*
1201 =============
1202 DecodeLevelParms
1203 =============
1204 */
1205 void DecodeLevelParms (void)
1206 {
1207         // load parms
1208         self.parm_idlesince = parm1;
1209         if(self.parm_idlesince == -(86400 * 366))
1210                 self.parm_idlesince = time;
1211
1212         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1213         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1214 }
1215
1216 /*
1217 =============
1218 ClientKill
1219
1220 Called when a client types 'kill' in the console
1221 =============
1222 */
1223
1224 .float clientkill_nexttime;
1225 void ClientKill_Now_TeamChange()
1226 {
1227         if(self.killindicator_teamchange == -1)
1228         {
1229                 self.team = -1;
1230                 JoinBestTeam( self, FALSE, FALSE );
1231         }
1232         else if(self.killindicator_teamchange == -2)
1233         {
1234                 if(g_ca)
1235                         self.caplayer = 0;
1236                 if(blockSpectators)
1237                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1238                 PutObserverInServer();
1239         }
1240         else
1241                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1242 }
1243
1244 void ClientKill_Now()
1245 {
1246         remove(self.killindicator);
1247         self.killindicator = world;
1248
1249         if(self.killindicator_teamchange)
1250                 ClientKill_Now_TeamChange();
1251
1252         // in any case:
1253         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1254
1255         // now I am sure the player IS dead
1256 }
1257 void KillIndicator_Think()
1258 {
1259         if (!self.owner.modelindex)
1260         {
1261                 self.owner.killindicator = world;
1262                 remove(self);
1263                 return;
1264         }
1265
1266         if(self.cnt <= 0)
1267         {
1268                 self = self.owner;
1269                 ClientKill_Now(); // no oldself needed
1270                 return;
1271         }
1272     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1273     {
1274         self.nextthink = time + 1;
1275         self.cnt -= 1;
1276     }
1277         else
1278         {
1279                 if(self.cnt <= 10)
1280                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1281                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1282                 {
1283                         if(self.cnt <= 10)
1284                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1285                         if(self.owner.killindicator_teamchange)
1286                         {
1287                                 if(self.owner.killindicator_teamchange == -1)
1288                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1289                                 else if(self.owner.killindicator_teamchange == -2)
1290                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1291                                 else
1292                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1293                         }
1294                         else
1295                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1296                 }
1297                 self.nextthink = time + 1;
1298                 self.cnt -= 1;
1299         }
1300 }
1301
1302 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1303 {
1304         float killtime;
1305         entity e;
1306         killtime = autocvar_g_balance_kill_delay;
1307
1308         if(g_race_qualifying || g_cts)
1309                 killtime = 0;
1310
1311     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1312     {
1313                 remove(self.killindicator);
1314                 self.killindicator = world;
1315
1316         ClientKill_Now(); // allow instant kill in this case
1317         return;
1318     }
1319
1320         self.killindicator_teamchange = targetteam;
1321
1322     if(!self.killindicator)
1323         {
1324                 if(self.modelindex && self.deadflag == DEAD_NO)
1325                 {
1326                         killtime = max(killtime, self.clientkill_nexttime - time);
1327                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1328                 }
1329
1330                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1331                 {
1332                         ClientKill_Now();
1333                 }
1334                 else
1335                 {
1336                         self.killindicator = spawn();
1337                         self.killindicator.owner = self;
1338                         self.killindicator.scale = 0.5;
1339                         setattachment(self.killindicator, self, "");
1340                         setorigin(self.killindicator, '0 0 52');
1341                         self.killindicator.think = KillIndicator_Think;
1342                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1343                         self.killindicator.cnt = ceil(killtime);
1344                         self.killindicator.count = bound(0, ceil(killtime), 10);
1345                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1346
1347                         for(e = world; (e = find(e, classname, "body")) != world; )
1348                         {
1349                                 if(e.enemy != self)
1350                                         continue;
1351                                 e.killindicator = spawn();
1352                                 e.killindicator.owner = e;
1353                                 e.killindicator.scale = 0.5;
1354                                 setattachment(e.killindicator, e, "");
1355                                 setorigin(e.killindicator, '0 0 52');
1356                                 e.killindicator.think = KillIndicator_Think;
1357                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1358                                 e.killindicator.cnt = ceil(killtime);
1359                         }
1360                         self.lip = 0;
1361                 }
1362         }
1363         if(self.killindicator)
1364         {
1365                 if(targetteam == 0) // just die
1366                         self.killindicator.colormod = '0 0 0';
1367                 else if(targetteam == -1) // auto
1368                         self.killindicator.colormod = '0 1 0';
1369                 else if(targetteam == -2) // spectate
1370                         self.killindicator.colormod = '0.5 0.5 0.5';
1371                 else
1372                         self.killindicator.colormod = TeamColor(targetteam);
1373         }
1374 }
1375
1376 void ClientKill (void)
1377 {
1378         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1379         {
1380                 // do nothing
1381         }
1382     else if(self.freezetag_frozen)
1383     {
1384         // do nothing
1385     }
1386         else
1387                 ClientKill_TeamChange(0);
1388 }
1389
1390 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1391 {
1392     e.killindicator = spawn();
1393     e.killindicator.owner = e;
1394     e.killindicator.think = KillIndicator_Think;
1395     e.killindicator.nextthink = time + (e.lip) * 0.05;
1396     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1397     e.killindicator.health = 1; // this is used to indicate that it should be silent
1398     e.lip = 0;
1399 }
1400
1401 void DoTeamChange(float destteam)
1402 {
1403         float t, c0;
1404         if(!teams_matter)
1405         {
1406                 if(destteam >= 0)
1407                         SetPlayerColors(self, destteam);
1408                 return;
1409         }
1410         if(self.classname == "player")
1411         if(destteam == -1)
1412         {
1413                 CheckAllowedTeams(self);
1414                 t = FindSmallestTeam(self, TRUE);
1415                 switch(self.team)
1416                 {
1417                         case COLOR_TEAM1: c0 = c1; break;
1418                         case COLOR_TEAM2: c0 = c2; break;
1419                         case COLOR_TEAM3: c0 = c3; break;
1420                         case COLOR_TEAM4: c0 = c4; break;
1421                         default:          c0 = 999;
1422                 }
1423                 switch(t)
1424                 {
1425                         case 1:
1426                                 if(c0 > c1)
1427                                         destteam = COLOR_TEAM1;
1428                                 break;
1429                         case 2:
1430                                 if(c0 > c2)
1431                                         destteam = COLOR_TEAM2;
1432                                 break;
1433                         case 3:
1434                                 if(c0 > c3)
1435                                         destteam = COLOR_TEAM3;
1436                                 break;
1437                         case 4:
1438                                 if(c0 > c4)
1439                                         destteam = COLOR_TEAM4;
1440                                 break;
1441                 }
1442                 if(destteam == -1)
1443                         return;
1444         }
1445         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1446                 return;
1447         ClientKill_TeamChange(destteam);
1448 }
1449
1450 void FixClientCvars(entity e)
1451 {
1452         // send prediction settings to the client
1453         stuffcmd(e, "\nin_bindmap 0 0\n");
1454         if(g_race || g_cts)
1455                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1456         if(autocvar_g_antilag == 3) // client side hitscan
1457                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1458         if(sv_gentle)
1459                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1460         /*
1461          * we no longer need to stuff this. Remove this comment block if you feel
1462          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1463         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1464         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1465         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1466         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1467         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1468         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1469         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1470         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1471         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1472         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1473         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1474         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1475         stuffcmd(e, "cl_movement_edgefriction 1\n");
1476          */
1477 }
1478
1479 float PlayerInIDList(entity p, string idlist)
1480 {
1481         float n, i;
1482         string s;
1483
1484         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1485         if not(p.crypto_idfp)
1486                 return 0;
1487
1488         // this function allows abbreviated player IDs too!
1489         n = tokenize_console(idlist);
1490         for(i = 0; i < n; ++i)
1491         {
1492                 s = argv(i);
1493                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1494                         return 1;
1495         }
1496
1497         return 0;
1498 }
1499
1500 /*
1501 =============
1502 ClientConnect
1503
1504 Called when a client connects to the server
1505 =============
1506 */
1507 //void ctf_clientconnect();
1508 string ColoredTeamName(float t);
1509 void DecodeLevelParms (void);
1510 //void dom_player_join_team(entity pl);
1511 void ClientConnect (void)
1512 {
1513         float t;
1514
1515         if(self.flags & FL_CLIENT)
1516         {
1517                 print("Warning: ClientConnect, but already connected!\n");
1518                 return;
1519         }
1520
1521         if(Ban_MaybeEnforceBan(self))
1522                 return;
1523
1524         DecodeLevelParms();
1525
1526 #ifdef WATERMARK
1527         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1528 #endif
1529
1530         self.classname = "player_joining";
1531
1532         self.flags = FL_CLIENT;
1533         self.version_nagtime = time + 10 + random() * 10;
1534
1535         if(player_count<0)
1536         {
1537                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1538                 player_count = 0;
1539         }
1540
1541         PlayerScore_Attach(self);
1542         ClientData_Attach();
1543         accuracy_init(self);
1544
1545         bot_clientconnect();
1546
1547         playerdemo_init();
1548
1549         anticheat_init();
1550         
1551         race_PreSpawnObserver();
1552
1553         //if(g_domination)
1554         //      dom_player_join_team(self);
1555
1556         // identify the right forced team
1557         if(autocvar_g_campaign)
1558         {
1559                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1560                 {
1561                         switch(autocvar_g_campaign_forceteam)
1562                         {
1563                                 case 1: self.team_forced = COLOR_TEAM1; break;
1564                                 case 2: self.team_forced = COLOR_TEAM2; break;
1565                                 case 3: self.team_forced = COLOR_TEAM3; break;
1566                                 case 4: self.team_forced = COLOR_TEAM4; break;
1567                                 default: self.team_forced = 0;
1568                         }
1569                 }
1570         }
1571         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1572                 self.team_forced = COLOR_TEAM1;
1573         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1574                 self.team_forced = COLOR_TEAM2;
1575         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1576                 self.team_forced = COLOR_TEAM3;
1577         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1578                 self.team_forced = COLOR_TEAM4;
1579         else if(autocvar_g_forced_team_otherwise == "red")
1580                 self.team_forced = COLOR_TEAM1;
1581         else if(autocvar_g_forced_team_otherwise == "blue")
1582                 self.team_forced = COLOR_TEAM2;
1583         else if(autocvar_g_forced_team_otherwise == "yellow")
1584                 self.team_forced = COLOR_TEAM3;
1585         else if(autocvar_g_forced_team_otherwise == "pink")
1586                 self.team_forced = COLOR_TEAM4;
1587         else if(autocvar_g_forced_team_otherwise == "spectate")
1588                 self.team_forced = -1;
1589         else if(autocvar_g_forced_team_otherwise == "spectator")
1590                 self.team_forced = -1;
1591         else
1592                 self.team_forced = 0;
1593
1594         if(!teams_matter)
1595                 if(self.team_forced > 0)
1596                         self.team_forced = 0;
1597
1598         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1599
1600         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1601                 self.classname = "observer";
1602         } else {
1603                 if(teams_matter)
1604                 {
1605                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1606                         {
1607                                 self.classname = "player";
1608                                 campaign_bots_may_start = 1;
1609                         }
1610                         else
1611                         {
1612                                 self.classname = "observer"; // do it anyway
1613                         }
1614                 }
1615                 else
1616                 {
1617                         self.classname = "player";
1618                         campaign_bots_may_start = 1;
1619                 }
1620         }
1621
1622         self.playerid = (playerid_last = playerid_last + 1);
1623
1624         if(autocvar_sv_eventlog)
1625                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1626
1627         LogTeamchange(self.playerid, self.team, 1);
1628
1629         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1630
1631         self.netname_previous = strzone(self.netname);
1632
1633         bprint("^4", self.netname, "^4 connected");
1634
1635         if(self.classname != "observer" && (g_domination || g_ctf))
1636                 bprint(" and joined the ", ColoredTeamName(self.team));
1637
1638         bprint("\n");
1639
1640         self.welcomemessage_time = 0;
1641
1642         stuffcmd(self, strcat(clientstuff, "\n"));
1643         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1644         stuffcmd(self, "cl_particles_reloadeffects\n");
1645
1646         FixClientCvars(self);
1647
1648         // spawnfunc_waypoint sprites
1649         WaypointSprite_InitClient(self);
1650
1651         // Wazat's grappling hook
1652         SetGrappleHookBindings();
1653
1654         // get autoswitch state from player when he toggles it
1655         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1656
1657         // get version info from player
1658         stuffcmd(self, "cmd clientversion $gameversion\n");
1659
1660         // get other cvars from player
1661         GetCvars(0);
1662
1663         // notify about available teams
1664         if(teams_matter)
1665         {
1666                 CheckAllowedTeams(self);
1667                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1668                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1669         }
1670         else
1671                 stuffcmd(self, "set _teams_available 0\n");
1672
1673         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1674
1675         if(g_arena || g_ca)
1676         {
1677                 self.classname = "observer";
1678                 if(g_arena)
1679                         Spawnqueue_Insert(self);
1680         }
1681         /*else if(g_ctf)
1682         {
1683                 ctf_clientconnect();
1684         }*/
1685
1686         if(teams_matter || radar_showennemies)
1687                 attach_entcs();
1688
1689         bot_relinkplayerlist();
1690
1691         self.spectatortime = time;
1692         if(blockSpectators)
1693         {
1694                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1695         }
1696
1697         self.jointime = time;
1698         self.allowedTimeouts = autocvar_sv_timeout_number;
1699
1700         if(clienttype(self) == CLIENTTYPE_REAL)
1701         {
1702                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1703                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1704         }
1705
1706         if(g_lms)
1707         {
1708                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1709                 {
1710                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1711                         self.frags = FRAGS_SPECTATOR;
1712                 }
1713         }
1714
1715         if(!sv_foginterval && world.fog != "")
1716                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1717
1718         SoundEntity_Attach(self);
1719
1720         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1721         {
1722                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1723                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1724         }
1725         else
1726                 self.hitplotfh = -1;
1727
1728         if(g_race || g_cts) {
1729                 string rr;
1730                 if(g_cts)
1731                         rr = CTS_RECORD;
1732                 else
1733                         rr = RACE_RECORD;
1734                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1735
1736                 msg_entity = self;
1737                 race_send_recordtime(MSG_ONE);
1738                 race_send_speedaward(MSG_ONE);
1739
1740                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1741                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1742                 race_send_speedaward_alltimebest(MSG_ONE);
1743
1744                 float i;
1745                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1746                         race_SendRankings(i, 0, 0, MSG_ONE);
1747                 }
1748         }
1749         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1750                 send_CSQC_teamnagger();
1751
1752         CheatInitClient();
1753
1754         PlayerStats_AddPlayer(self);
1755 }
1756
1757 /*
1758 =============
1759 ClientDisconnect
1760
1761 Called when a client disconnects from the server
1762 =============
1763 */
1764 .entity chatbubbleentity;
1765 .entity teambubbleentity;
1766 void ReadyCount();
1767 void ClientDisconnect (void)
1768 {
1769         if not(self.flags & FL_CLIENT)
1770         {
1771                 print("Warning: ClientDisconnect without ClientConnect\n");
1772                 return;
1773         }
1774
1775         PlayerStats_AddGlobalInfo(self);
1776
1777         CheatShutdownClient();
1778
1779         if(self.hitplotfh >= 0)
1780         {
1781                 fclose(self.hitplotfh);
1782                 self.hitplotfh = -1;
1783         }
1784
1785         anticheat_report();
1786         anticheat_shutdown();
1787
1788         playerdemo_shutdown();
1789
1790         bot_clientdisconnect();
1791
1792         if(self.entcs)
1793                 detach_entcs();
1794
1795         if(autocvar_sv_eventlog)
1796                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1797         bprint ("^4",self.netname);
1798         bprint ("^4 disconnected\n");
1799
1800         SoundEntity_Detach(self);
1801
1802         DropAllRunes(self);
1803         MUTATOR_CALLHOOK(ClientDisconnect);
1804
1805         Portal_ClearAll(self);
1806
1807         if(self.flagcarried)
1808                 DropFlag(self.flagcarried, world, world);
1809         if(self.ballcarried && g_nexball)
1810                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1811
1812         // Here, everything has been done that requires this player to be a client.
1813
1814         self.flags &~= FL_CLIENT;
1815
1816         if (self.chatbubbleentity)
1817                 remove (self.chatbubbleentity);
1818
1819         if (self.teambubbleentity)
1820                 remove (self.teambubbleentity);
1821
1822         if (self.killindicator)
1823                 remove (self.killindicator);
1824
1825         WaypointSprite_PlayerGone();
1826
1827         bot_relinkplayerlist();
1828
1829         if(g_arena)
1830         {
1831                 Spawnqueue_Unmark(self);
1832                 Spawnqueue_Remove(self);
1833         }
1834
1835         accuracy_free(self);
1836         ClientData_Detach();
1837         PlayerScore_Detach(self);
1838
1839         if(self.netname_previous)
1840                 strunzone(self.netname_previous);
1841         if(self.clientstatus)
1842                 strunzone(self.clientstatus);
1843         if(self.weaponorder_byimpulse)
1844                 strunzone(self.weaponorder_byimpulse);
1845
1846         ClearPlayerSounds();
1847
1848         if(self.personal)
1849                 remove(self.personal);
1850
1851         self.playerid = 0;
1852         ReadyCount();
1853
1854         // free cvars
1855         GetCvars(-1);
1856 }
1857
1858 .float BUTTON_CHAT;
1859 void ChatBubbleThink()
1860 {
1861         self.nextthink = time;
1862         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1863         {
1864                 if(self.owner) // but why can that ever be world?
1865                         self.owner.chatbubbleentity = world;
1866                 remove(self);
1867                 return;
1868         }
1869         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1870 #ifdef TETRIS
1871                 || self.owner.tetris_on
1872 #endif
1873         )
1874                 self.model = self.mdl;
1875         else
1876                 self.model = "";
1877 };
1878
1879 void UpdateChatBubble()
1880 {
1881         if (!self.modelindex)
1882                 return;
1883         // spawn a chatbubble entity if needed
1884         if (!self.chatbubbleentity)
1885         {
1886                 self.chatbubbleentity = spawn();
1887                 self.chatbubbleentity.owner = self;
1888                 self.chatbubbleentity.exteriormodeltoclient = self;
1889                 self.chatbubbleentity.think = ChatBubbleThink;
1890                 self.chatbubbleentity.nextthink = time;
1891                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1892                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1893                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1894                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1895                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1896                 self.chatbubbleentity.model = "";
1897                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1898         }
1899 }
1900
1901
1902 void TeamBubbleThink()
1903 {
1904         self.nextthink = time;
1905         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1906         {
1907                 if(self.owner) // but why can that ever be world?
1908                         self.owner.teambubbleentity = world;
1909                 remove(self);
1910                 return;
1911         }
1912 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1913         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1914                 self.model = "";
1915         else
1916                 self.model = self.mdl;
1917
1918 };
1919
1920 float TeamBubble_customizeentityforclient()
1921 {
1922         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1923 }
1924
1925 void UpdateTeamBubble()
1926 {
1927         if (!self.modelindex || !teams_matter)
1928                 return;
1929         // spawn a teambubble entity if needed
1930         if (!self.teambubbleentity && teams_matter)
1931         {
1932                 self.teambubbleentity = spawn();
1933                 self.teambubbleentity.owner = self;
1934                 self.teambubbleentity.exteriormodeltoclient = self;
1935                 self.teambubbleentity.think = TeamBubbleThink;
1936                 self.teambubbleentity.nextthink = time;
1937                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1938 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1939                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1940                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1941                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1942                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1943                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1944                 self.teambubbleentity.effects = EF_LOWPRECISION;
1945         }
1946 }
1947
1948 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1949 // added to the model skins
1950 /*void UpdateColorModHack()
1951 {
1952         local float c;
1953         c = self.clientcolors & 15;
1954         // LordHavoc: only bothering to support white, green, red, yellow, blue
1955              if (!teams_matter) self.colormod = '0 0 0';
1956         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1957         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1958         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1959         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1960         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1961         else self.colormod = '1 1 1';
1962 };*/
1963
1964 .float oldcolormap;
1965 void respawn(void)
1966 {
1967         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1968         {
1969                 self.solid = SOLID_NOT;
1970                 self.takedamage = DAMAGE_NO;
1971                 self.movetype = MOVETYPE_FLY;
1972                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1973                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1974                 self.effects |= EF_ADDITIVE;
1975                 self.oldcolormap = self.colormap;
1976                 self.colormap = 512;
1977                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1978                 if(autocvar_g_respawn_ghosts_maxtime)
1979                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1980         }
1981
1982         CopyBody(1);
1983         self.effects |= EF_NODRAW; // prevent another CopyBody
1984         if(self.oldcolormap)
1985         {
1986                 self.colormap = self.oldcolormap;
1987                 self.oldcolormap = 0;
1988         }
1989         PutClientInServer();
1990 }
1991
1992 void play_countdown(float finished, string samp)
1993 {
1994         if(clienttype(self) == CLIENTTYPE_REAL)
1995                 if(floor(finished - time - frametime) != floor(finished - time))
1996                         if(finished - time < 6)
1997                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1998 }
1999
2000 /**
2001  * When sv_timeout is used this function returs strings like
2002  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2003  * Called by centerprint functions
2004  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2005  */
2006 string getTimeoutText(float addOneSecond) {
2007         if (!autocvar_sv_timeout || !timeoutStatus)
2008                 return "";
2009
2010         local string retStr;
2011         if (timeoutStatus == 1) {
2012                 if (addOneSecond == 1) {
2013                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2014                 }
2015                 else {
2016                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2017                 }
2018                 return retStr;
2019         }
2020         else if (timeoutStatus == 2) {
2021                 if (addOneSecond) {
2022                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2023                         //don't show messages like "Timeout ends in 0 seconds"...
2024                         if ((remainingTimeoutTime + 1) > 0)
2025                                 return retStr;
2026                         else
2027                                 return "";
2028                 }
2029                 else {
2030                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2031                         //don't show messages like "Timeout ends in 0 seconds"...
2032                         if (remainingTimeoutTime > 0)
2033                                 return retStr;
2034                         else
2035                                 return "";
2036                 }
2037         }
2038         else return "";
2039 }
2040
2041 void player_powerups (void)
2042 {
2043         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2044         olditems = self.items;
2045         
2046         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2047         {
2048                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2049                 self.modelflags |= MF_ROCKET;
2050         }
2051         else
2052         {
2053                 SoundEntity_StopSound(self, CHAN_PLAYER);
2054                 self.modelflags &~= MF_ROCKET;
2055         }
2056
2057         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2058
2059         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2060                 return;
2061         
2062         Fire_ApplyDamage(self);
2063         Fire_ApplyEffect(self);
2064
2065         if (g_minstagib)
2066         {
2067                 self.effects |= EF_FULLBRIGHT;
2068
2069                 if (self.items & IT_STRENGTH)
2070                 {
2071                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2072                         if (time > self.strength_finished)
2073                         {
2074                                 self.alpha = default_player_alpha;
2075                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2076                                 self.items &~= IT_STRENGTH;
2077                                 sprint(self, "^3Invisibility has worn off\n");
2078                         }
2079                 }
2080                 else
2081                 {
2082                         if (time < self.strength_finished)
2083                         {
2084                                 self.alpha = g_minstagib_invis_alpha;
2085                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2086                                 self.items |= IT_STRENGTH;
2087                                 sprint(self, "^3You are invisible\n");
2088                         }
2089                 }
2090
2091                 if (self.items & IT_INVINCIBLE)
2092                 {
2093                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2094                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2095                         {
2096                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2097                                 sprint(self, "^3Speed has worn off\n");
2098                         }
2099                 }
2100                 else
2101                 {
2102                         if (time < self.invincible_finished)
2103                         {
2104                                 self.items = self.items | IT_INVINCIBLE;
2105                                 sprint(self, "^3You are on speed\n");
2106                         }
2107                 }
2108         }
2109         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2110         {
2111                 if (self.items & IT_STRENGTH)
2112                 {
2113                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2114                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2115                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2116                         {
2117                                 self.items = self.items - (self.items & IT_STRENGTH);
2118                                 sprint(self, "^3Strength has worn off\n");
2119                         }
2120                 }
2121                 else
2122                 {
2123                         if (time < self.strength_finished)
2124                         {
2125                                 self.items = self.items | IT_STRENGTH;
2126                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2127                         }
2128                 }
2129                 if (self.items & IT_INVINCIBLE)
2130                 {
2131                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2132                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2133                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2134                         {
2135                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2136                                 sprint(self, "^3Shield has worn off\n");
2137                         }
2138                 }
2139                 else
2140                 {
2141                         if (time < self.invincible_finished)
2142                         {
2143                                 self.items = self.items | IT_INVINCIBLE;
2144                                 sprint(self, "^3Shield surrounds you\n");
2145                         }
2146                 }
2147
2148                 if(autocvar_g_nodepthtestplayers)
2149                         self.effects = self.effects | EF_NODEPTHTEST;
2150
2151                 if(autocvar_g_fullbrightplayers)
2152                         self.effects = self.effects | EF_FULLBRIGHT;
2153
2154                 // midair gamemode: damage only while in the air
2155                 // if in midair mode, being on ground grants temporary invulnerability
2156                 // (this is so that multishot weapon don't clear the ground flag on the
2157                 // first damage in the frame, leaving the player vulnerable to the
2158                 // remaining hits in the same frame)
2159                 if (self.flags & FL_ONGROUND)
2160                 if (g_midair)
2161                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2162
2163                 if (time >= game_starttime)
2164                 if (time < self.spawnshieldtime)
2165                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2166         }
2167         
2168         MUTATOR_CALLHOOK(PlayerPowerups);
2169 }
2170
2171 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2172 {
2173         if(current > stable)
2174                 return current;
2175         else if(current > stable - 0.25) // when close enough, "snap"
2176                 return stable;
2177         else
2178                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2179 }
2180
2181 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2182 {
2183         if(current < stable)
2184                 return current;
2185         else if(current < stable + 0.25) // when close enough, "snap"
2186                 return stable;
2187         else
2188                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2189 }
2190
2191 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2192 {
2193         if(current > rotstable)
2194         {
2195                 if(rotframetime > 0)
2196                 {
2197                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2198                         current = max(rotstable, current - rotlinear * rotframetime);
2199                 }
2200         }
2201         else if(current < regenstable)
2202         {
2203                 if(regenframetime > 0)
2204                 {
2205                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2206                         current = min(regenstable, current + regenlinear * regenframetime);
2207                 }
2208         }
2209
2210         if(current > limit)
2211                 current = limit;
2212
2213         return current;
2214 }
2215
2216 void player_regen (void)
2217 {
2218         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2219         maxh = autocvar_g_balance_health_rotstable;
2220         maxa = autocvar_g_balance_armor_rotstable;
2221         maxf = autocvar_g_balance_fuel_rotstable;
2222         minh = autocvar_g_balance_health_regenstable;
2223         mina = autocvar_g_balance_armor_regenstable;
2224         minf = autocvar_g_balance_fuel_regenstable;
2225         limith = autocvar_g_balance_health_limit;
2226         limita = autocvar_g_balance_armor_limit;
2227         limitf = autocvar_g_balance_fuel_limit;
2228
2229         max_mod = regen_mod = rot_mod = limit_mod = 1;
2230
2231         if (self.runes & RUNE_REGEN)
2232         {
2233                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2234                 {
2235                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2236                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2237                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2238                 }
2239                 else
2240                 {
2241                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2242                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2243                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2244                 }
2245         }
2246         else if (self.runes & CURSE_VENOM)
2247         {
2248                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2249                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2250                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2251                 else
2252                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2253                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2254                 //if (!self.runes & RUNE_REGEN)
2255                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2256         }
2257         maxh = maxh * max_mod;
2258         //maxa = maxa * max_mod;
2259         //maxf = maxf * max_mod;
2260         minh = minh * max_mod;
2261         //mina = mina * max_mod;
2262         //minf = minf * max_mod;
2263         limith = limith * limit_mod;
2264         limita = limita * limit_mod;
2265         //limitf = limitf * limit_mod;
2266
2267         if(g_lms && g_ca)
2268                 rot_mod = 0;
2269
2270         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2271         {
2272                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2273                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2274
2275                 // if player rotted to death...  die!
2276                 if(self.health < 1)
2277                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2278         }
2279
2280         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2281                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2282 }
2283
2284 float zoomstate_set;
2285 void SetZoomState(float z)
2286 {
2287         if(z != self.zoomstate)
2288         {
2289                 self.zoomstate = z;
2290                 ClientData_Touch(self);
2291         }
2292         zoomstate_set = 1;
2293 }
2294
2295 void GetPressedKeys(void) {
2296         MUTATOR_CALLHOOK(GetPressedKeys);
2297         if (self.movement_x > 0) // get if movement keys are pressed
2298         {       // forward key pressed
2299                 self.pressedkeys |= KEY_FORWARD;
2300                 self.pressedkeys &~= KEY_BACKWARD;
2301         }
2302         else if (self.movement_x < 0)
2303         {       // backward key pressed
2304                 self.pressedkeys |= KEY_BACKWARD;
2305                 self.pressedkeys &~= KEY_FORWARD;
2306         }
2307         else
2308         {       // no x input
2309                 self.pressedkeys &~= KEY_FORWARD;
2310                 self.pressedkeys &~= KEY_BACKWARD;
2311         }
2312
2313         if (self.movement_y > 0)
2314         {       // right key pressed
2315                 self.pressedkeys |= KEY_RIGHT;
2316                 self.pressedkeys &~= KEY_LEFT;
2317         }
2318         else if (self.movement_y < 0)
2319         {       // left key pressed
2320                 self.pressedkeys |= KEY_LEFT;
2321                 self.pressedkeys &~= KEY_RIGHT;
2322         }
2323         else
2324         {       // no y input
2325                 self.pressedkeys &~= KEY_RIGHT;
2326                 self.pressedkeys &~= KEY_LEFT;
2327         }
2328
2329         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2330                 self.pressedkeys |= KEY_JUMP;
2331         else
2332                 self.pressedkeys &~= KEY_JUMP;
2333         if (self.BUTTON_CROUCH)
2334                 self.pressedkeys |= KEY_CROUCH;
2335         else
2336                 self.pressedkeys &~= KEY_CROUCH;
2337 }
2338
2339 /*
2340 ======================
2341 spectate mode routines
2342 ======================
2343 */
2344
2345 void SpectateCopy(entity spectatee) {
2346         other = spectatee;
2347         MUTATOR_CALLHOOK(SpectateCopy);
2348         self.armortype = spectatee.armortype;
2349         self.armorvalue = spectatee.armorvalue;
2350         self.ammo_cells = spectatee.ammo_cells;
2351         self.ammo_shells = spectatee.ammo_shells;
2352         self.ammo_nails = spectatee.ammo_nails;
2353         self.ammo_rockets = spectatee.ammo_rockets;
2354         self.ammo_fuel = spectatee.ammo_fuel;
2355         self.clip_load = spectatee.clip_load;
2356         self.clip_size = spectatee.clip_size;
2357         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2358         self.health = spectatee.health;
2359         self.impulse = 0;
2360         self.items = spectatee.items;
2361         self.last_pickup = spectatee.last_pickup;
2362         self.hit_time = spectatee.hit_time;
2363         self.metertime = spectatee.metertime;
2364         self.strength_finished = spectatee.strength_finished;
2365         self.invincible_finished = spectatee.invincible_finished;
2366         self.pressedkeys = spectatee.pressedkeys;
2367         self.weapons = spectatee.weapons;
2368         self.switchweapon = spectatee.switchweapon;
2369         self.weapon = spectatee.weapon;
2370         self.nex_charge = spectatee.nex_charge;
2371         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2372         self.minelayer_mines = spectatee.minelayer_mines;
2373         self.punchangle = spectatee.punchangle;
2374         self.view_ofs = spectatee.view_ofs;
2375         self.v_angle = spectatee.v_angle;
2376         self.velocity = spectatee.velocity;
2377         self.dmg_take = spectatee.dmg_take;
2378         self.dmg_save = spectatee.dmg_save;
2379         self.dmg_inflictor = spectatee.dmg_inflictor;
2380         self.angles = spectatee.v_angle;
2381         self.fixangle = TRUE;
2382         setorigin(self, spectatee.origin);
2383         setsize(self, spectatee.mins, spectatee.maxs);
2384         SetZoomState(spectatee.zoomstate);
2385
2386         anticheat_spectatecopy(spectatee);
2387 }
2388
2389 float SpectateUpdate() {
2390         if(!self.enemy)
2391                 return 0;
2392
2393         if (self == self.enemy)
2394                 return 0;
2395
2396         if(self.enemy.classname != "player")
2397                 return 0;
2398
2399         SpectateCopy(self.enemy);
2400
2401         return 1;
2402 }
2403
2404 float SpectateNext() {
2405         other = find(self.enemy, classname, "player");
2406
2407         if (!other)
2408                 other = find(other, classname, "player");
2409
2410         if (other)
2411                 self.enemy = other;
2412
2413         if(self.enemy.classname == "player") {
2414                 msg_entity = self;
2415                 WriteByte(MSG_ONE, SVC_SETVIEW);
2416                 WriteEntity(MSG_ONE, self.enemy);
2417                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2418                 self.movetype = MOVETYPE_NONE;
2419                 accuracy_resend(self);
2420
2421                 if(!SpectateUpdate())
2422                         PutObserverInServer();
2423
2424                 return 1;
2425         } else {
2426                 return 0;
2427         }
2428 }
2429
2430 /*
2431 =============
2432 ShowRespawnCountdown()
2433
2434 Update a respawn countdown display.
2435 =============
2436 */
2437 void ShowRespawnCountdown()
2438 {
2439         float number;
2440         if(self.deadflag == DEAD_NO) // just respawned?
2441                 return;
2442         else
2443         {
2444                 number = ceil(self.death_time - time);
2445                 if(number <= 0)
2446                         return;
2447                 if(number <= self.respawn_countdown)
2448                 {
2449                         self.respawn_countdown = number - 1;
2450                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2451                                 AnnounceTo(self, strcat(ftos(number), ""));
2452                 }
2453         }
2454 }
2455
2456 void LeaveSpectatorMode()
2457 {
2458         if(nJoinAllowed(1)) {
2459                 if(!teams_matter || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2460                         self.classname = "player";
2461
2462                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2463                                 JoinBestTeam(self, FALSE, TRUE);
2464
2465                         if(autocvar_g_campaign)
2466                                 campaign_bots_may_start = 1;
2467
2468                         PutClientInServer();
2469
2470                         if(self.classname == "player")
2471                                 bprint ("^4", self.netname, "^4 is playing now\n");
2472
2473                         if(!autocvar_g_campaign)
2474                                 centerprint(self,""); // clear MOTD
2475
2476                         return;
2477                 } else {
2478                         if (g_ca && self.caplayer) {
2479                         }       // do nothing
2480                         else
2481                                 stuffcmd(self,"menu_showteamselect\n");
2482                         return;
2483                 }
2484         }
2485         else {
2486                 //player may not join because of g_maxplayers is set
2487                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2488         }
2489 }
2490
2491 /**
2492  * Determines whether the player is allowed to join. This depends on cvar
2493  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2494  * it checks whether the number of currently playing players exceeds g_maxplayers.
2495  * @return int number of free slots for players, 0 if none
2496  */
2497 float nJoinAllowed(float includeMe) {
2498         if(self.team_forced < 0)
2499                 return FALSE; // forced spectators can never join
2500
2501         // TODO simplify this
2502         local entity e;
2503
2504         local float totalClients;
2505         FOR_EACH_CLIENT(e)
2506                 totalClients += 1;
2507
2508         if (!autocvar_g_maxplayers)
2509                 return maxclients - totalClients + includeMe;
2510
2511         local float currentlyPlaying;
2512         FOR_EACH_REALPLAYER(e)
2513                 currentlyPlaying += 1;
2514
2515         if(currentlyPlaying < autocvar_g_maxplayers)
2516                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2517
2518         return 0;
2519 }
2520
2521 /**
2522  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2523  * g_maxplayers_spectator_blocktime seconds
2524  */
2525 void checkSpectatorBlock() {
2526         if(self.classname == "spectator" || self.classname == "observer") {
2527                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2528                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2529                         dropclient(self);
2530                 }
2531         }
2532 }
2533
2534 void ObserverThink()
2535 {
2536         if (self.flags & FL_JUMPRELEASED) {
2537                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2538                         self.welcomemessage_time = 0;
2539                         self.flags &~= FL_JUMPRELEASED;
2540                         self.flags |= FL_SPAWNING;
2541                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2542                         self.welcomemessage_time = 0;
2543                         self.flags &~= FL_JUMPRELEASED;
2544                         if(SpectateNext() == 1) {
2545                                 self.classname = "spectator";
2546                         }
2547                 }
2548         } else {
2549                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2550                         self.flags |= FL_JUMPRELEASED;
2551                         if(self.flags & FL_SPAWNING)
2552                         {
2553                                 self.flags &~= FL_SPAWNING;
2554                                 LeaveSpectatorMode();
2555                                 return;
2556                         }
2557                 }
2558         }
2559         PrintWelcomeMessage(self);
2560 }
2561
2562 void SpectatorThink()
2563 {
2564         if (self.flags & FL_JUMPRELEASED) {
2565                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2566                         self.welcomemessage_time = 0;
2567                         self.flags &~= FL_JUMPRELEASED;
2568                         self.flags |= FL_SPAWNING;
2569                 } else if(self.BUTTON_ATCK) {
2570                         self.welcomemessage_time = 0;
2571                         self.flags &~= FL_JUMPRELEASED;
2572                         if(SpectateNext() == 1) {
2573                                 self.classname = "spectator";
2574                         } else {
2575                                 self.classname = "observer";
2576                                 PutClientInServer();
2577                         }
2578                 } else if (self.BUTTON_ATCK2) {
2579                         self.welcomemessage_time = 0;
2580                         self.flags &~= FL_JUMPRELEASED;
2581                         self.classname = "observer";
2582                         PutClientInServer();
2583                 } else {
2584                         if(!SpectateUpdate())
2585                                 PutObserverInServer();
2586                 }
2587         } else {
2588                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2589                         self.flags |= FL_JUMPRELEASED;
2590                         if(self.flags & FL_SPAWNING)
2591                         {
2592                                 self.flags &~= FL_SPAWNING;
2593                                 LeaveSpectatorMode();
2594                                 return;
2595                         }
2596                 }
2597         }
2598
2599         PrintWelcomeMessage(self);
2600         self.flags |= FL_CLIENT | FL_NOTARGET;
2601 }
2602
2603 .float touchexplode_time;
2604
2605 /*
2606 =============
2607 PlayerPreThink
2608
2609 Called every frame for each client before the physics are run
2610 =============
2611 */
2612 void() ctf_setstatus;
2613 void() nexball_setstatus;
2614 .float items_added;
2615 void PlayerPreThink (void)
2616 {
2617         self.stat_game_starttime = game_starttime;
2618         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2619         self.stat_leadlimit = autocvar_leadlimit;
2620
2621         if(frametime)
2622         {
2623                 // physics frames: update anticheat stuff
2624                 anticheat_prethink();
2625         }
2626
2627         if(blockSpectators && frametime)
2628                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2629                 checkSpectatorBlock();
2630
2631         zoomstate_set = 0;
2632
2633         if(self.netname_previous != self.netname)
2634         {
2635                 if(autocvar_sv_eventlog)
2636                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2637                 if(self.netname_previous)
2638                         strunzone(self.netname_previous);
2639                 self.netname_previous = strzone(self.netname);
2640         }
2641
2642         // version nagging
2643         if(self.version_nagtime)
2644                 if(self.cvar_g_xonoticversion)
2645                         if(time > self.version_nagtime)
2646                         {
2647                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2648                                 {
2649                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2650                                         {
2651                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2652                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2653                                         }
2654                                         else
2655                                         {
2656                                                 float r;
2657                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2658                                                 if(r < 0)
2659                                                 {
2660                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2661                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2662                                                 }
2663                                                 else if(r > 0)
2664                                                 {
2665                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2666                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2667                                                 }
2668                                         }
2669                                 }
2670                                 self.version_nagtime = 0;
2671                         }
2672
2673         // GOD MODE info
2674         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2675         {
2676                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2677                 self.max_armorvalue = 0;
2678         }
2679
2680 #ifdef TETRIS
2681         if (TetrisPreFrame())
2682                 return;
2683 #endif
2684
2685         MUTATOR_CALLHOOK(PlayerPreThink);
2686
2687         if(self.classname == "player") {
2688 //              if(self.netname == "Wazat")
2689 //                      bprint(self.classname, "\n");
2690
2691                 CheckRules_Player();
2692
2693                 PrintWelcomeMessage(self);
2694
2695                 if (intermission_running)
2696                 {
2697                         IntermissionThink ();   // otherwise a button could be missed between
2698                         return;                                 // the think tics
2699                 }
2700
2701                 if(self.teleport_time)
2702                 if(time > self.teleport_time)
2703                 {
2704                         self.teleport_time = 0;
2705                         self.effects = self.effects - (self.effects & EF_NODRAW);
2706                 }
2707
2708                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2709                         UpdateSelectedPlayer();
2710
2711                 //don't allow the player to turn around while game is paused!
2712                 if(timeoutStatus == 2) {
2713                         self.v_angle = self.lastV_angle;
2714                         self.angles = self.lastV_angle;
2715                         self.fixangle = TRUE;
2716                 }
2717
2718                 if(frametime)
2719                 {
2720                         if(self.health <= 0 && autocvar_g_deathglow)
2721                         {
2722                                 if(self.glowmod_x > 0)
2723                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2724                                 else
2725                                         self.glowmod_x = -1;
2726                                 if(self.glowmod_y > 0)
2727                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2728                                 else
2729                                         self.glowmod_y = -1;
2730                                 if(self.glowmod_z > 0)
2731                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2732                                 else
2733                                         self.glowmod_z = -1;
2734                         }
2735                         else
2736                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2737                         player_powerups();
2738                 }
2739
2740                 if (self.deadflag != DEAD_NO)
2741                 {
2742                         float button_pressed, force_respawn;
2743                         if(self.personal && g_race_qualifying)
2744                         {
2745                                 if(time > self.death_time)
2746                                 {
2747                                         self.death_time = time + 1; // only retry once a second
2748                                         respawn();
2749                                         self.impulse = 141;
2750                                 }
2751                         }
2752                         else
2753                         {
2754                                 if(frametime)
2755                                         player_anim();
2756                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2757                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2758                                 if (self.deadflag == DEAD_DYING)
2759                                 {
2760                                         if(force_respawn)
2761                                                 self.deadflag = DEAD_RESPAWNING;
2762                                         else if(!button_pressed)
2763                                                 self.deadflag = DEAD_DEAD;
2764                                 }
2765                                 else if (self.deadflag == DEAD_DEAD)
2766                                 {
2767                                         if(button_pressed)
2768                                                 self.deadflag = DEAD_RESPAWNABLE;
2769                                 }
2770                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2771                                 {
2772                                         if(!button_pressed)
2773                                                 self.deadflag = DEAD_RESPAWNING;
2774                                 }
2775                                 else if (self.deadflag == DEAD_RESPAWNING)
2776                                 {
2777                                         if(time > self.death_time)
2778                                         {
2779                                                 self.death_time = time + 1; // only retry once a second
2780                                                 respawn();
2781                                         }
2782                                 }
2783                                 ShowRespawnCountdown();
2784                         }
2785                         return;
2786                 }
2787
2788                 if(g_touchexplode)
2789                 if(time > self.touchexplode_time)
2790                 if(self.classname == "player")
2791                 if(self.deadflag == DEAD_NO)
2792                 if not(IS_INDEPENDENT_PLAYER(self))
2793                 FOR_EACH_PLAYER(other) if(self != other)
2794                 {
2795                         if(time > other.touchexplode_time)
2796                         if(other.deadflag == DEAD_NO)
2797                         if not(IS_INDEPENDENT_PLAYER(other))
2798                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2799                         {
2800                                 PlayerTouchExplode(self, other);
2801                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2802                         }
2803                 }
2804
2805                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2806                 {
2807                         vector dist;
2808
2809                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2810                         dist = self.prevorigin - self.origin;
2811                         dist_z = 0;
2812                         self.lms_traveled_distance += fabs(vlen(dist));
2813
2814                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2815                         {
2816                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2817                                 self.lms_traveled_distance = 0;
2818                         }
2819
2820                         if(time > self.lms_nextcheck)
2821                         {
2822                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2823                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2824                                 {
2825                                         centerprint(self, autocvar_g_lms_campcheck_message);
2826                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2827                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2828                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2829                                 }
2830                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2831                                 self.lms_traveled_distance = 0;
2832                         }
2833                 }
2834
2835                 self.prevorigin = self.origin;
2836
2837                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2838                 {
2839                         if (!self.crouch)
2840                         {
2841                                 self.crouch = TRUE;
2842                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2843                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2844                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2845                         }
2846                 }
2847                 else
2848                 {
2849                         if (self.crouch)
2850                         {
2851                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2852                                 if (!trace_startsolid)
2853                                 {
2854                                         self.crouch = FALSE;
2855                                         self.view_ofs = PL_VIEW_OFS;
2856                                         setsize (self, PL_MIN, PL_MAX);
2857                                 }
2858                         }
2859                 }
2860
2861                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2862                 {
2863                         if(self.bloodloss_timer < time)
2864                         {
2865                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2866                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2867                         }
2868                 }
2869
2870                 FixPlayermodel();
2871
2872                 GrapplingHookFrame();
2873
2874                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2875                 //if(frametime)
2876                 {
2877                         self.items &~= self.items_added;
2878
2879                         W_WeaponFrame();
2880
2881                         self.items_added = 0;
2882                         if(self.items & IT_JETPACK)
2883                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2884                                         self.items_added |= IT_FUEL;
2885
2886                         self.items |= self.items_added;
2887                 }
2888
2889                 player_regen();
2890
2891                 // rot nex charge to the charge limit
2892                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2893                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2894
2895                 if(frametime)
2896                         player_anim();
2897
2898                 if (g_minstagib)
2899                         minstagib_ammocheck();
2900
2901                 if(g_ctf)
2902                         ctf_setstatus();
2903
2904                 if(g_nexball)
2905                         nexball_setstatus();
2906
2907                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2908
2909                 //self.angles_y=self.v_angle_y + 90;   // temp
2910         } else if(gameover) {
2911                 if (intermission_running)
2912                         IntermissionThink ();   // otherwise a button could be missed between
2913                 return;
2914         } else if(self.classname == "observer") {
2915                 ObserverThink();
2916         } else if(self.classname == "spectator") {
2917                 SpectatorThink();
2918         }
2919
2920         if(!zoomstate_set)
2921                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_SNIPERRIFLE && autocvar_g_balance_sniperrifle_secondary == 0));
2922
2923         float oldspectatee_status;
2924         oldspectatee_status = self.spectatee_status;
2925         if(self.classname == "spectator")
2926                 self.spectatee_status = num_for_edict(self.enemy);
2927         else if(self.classname == "observer")
2928                 self.spectatee_status = num_for_edict(self);
2929         else
2930                 self.spectatee_status = 0;
2931         if(self.spectatee_status != oldspectatee_status)
2932         {
2933                 ClientData_Touch(self);
2934                 if(g_race || g_cts)
2935                         race_InitSpectator();
2936         }
2937
2938         if(self.teamkill_soundtime)
2939         if(time > self.teamkill_soundtime)
2940         {
2941                 self.teamkill_soundtime = 0;
2942
2943                 entity oldpusher, oldself;
2944
2945                 oldself = self; self = self.teamkill_soundsource;
2946                 oldpusher = self.pusher; self.pusher = oldself;
2947
2948                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2949
2950                 self.pusher = oldpusher;
2951                 self = oldself;
2952         }
2953
2954         if(self.taunt_soundtime)
2955         if(time > self.taunt_soundtime)
2956         {
2957                 self.taunt_soundtime = 0;
2958                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2959         }
2960
2961         target_voicescript_next(self);
2962
2963         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2964         if(!self.weapon)
2965                 self.clip_load = self.clip_size = 0;
2966 }
2967
2968 float isInvisibleString(string s)
2969 {
2970         float i, n, c;
2971         s = strdecolorize(s);
2972         for((i = 0), (n = strlen(s)); i < n; ++i)
2973         {
2974                 c = str2chr(s, i);
2975                 switch(c)
2976                 {
2977                         case 0:
2978                         case 32: // space
2979                                 break;
2980                         case 192: // charmap space
2981                                 if (!autocvar_utf8_enable)
2982                                         break;
2983                                 return FALSE;
2984                         case 160: // space in unicode fonts
2985                         case 0xE000 + 192: // utf8 charmap space
2986                                 if (autocvar_utf8_enable)
2987                                         break;
2988                         default:
2989                                 return FALSE;
2990                 }
2991         }
2992         return TRUE;
2993 }
2994
2995 /*
2996 =============
2997 PlayerPostThink
2998
2999 Called every frame for each client after the physics are run
3000 =============
3001 */
3002 .float idlekick_lasttimeleft;
3003 .entity showheadshotbbox;
3004 void showheadshotbbox_think()
3005 {
3006         if(self.owner.showheadshotbbox != self)
3007         {
3008                 remove(self);
3009                 return;
3010         }
3011         self.nextthink = time;
3012         setorigin(self, self.owner.origin);
3013         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3014 }
3015 void PlayerPostThink (void)
3016 {
3017         // Savage: Check for nameless players
3018         if (isInvisibleString(self.netname)) {
3019                 self.netname = "Player";
3020                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3021         }
3022
3023         if(sv_maxidle && frametime)
3024         {
3025                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3026                 float timeleft;
3027                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3028                 if(timeleft <= 0)
3029                 {
3030                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3031                         AnnounceTo(self, "terminated");
3032                         dropclient(self);
3033                         return;
3034                 }
3035                 else if(timeleft <= 10)
3036                 {
3037                         if(timeleft != self.idlekick_lasttimeleft)
3038                         {
3039                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));