Merge branch 'master' into mirceakitsune/per_character_sounds
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck)
136         if(spot.team != teamcheck)
137                 return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(cvar("spawn_debugview"))
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         teamcheck = 0;
329
330         if(!anypoint && have_team_spawns > 0)
331                 teamcheck = self.team;
332
333         // get the list of players
334         playerlist = findchain(classname, "player");
335         // get the entire list of spots
336         firstspot = findchain(classname, "info_player_deathmatch");
337         // filter out the bad ones
338         // (note this returns the original list if none survived)
339         if(anypoint)
340         {
341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
342         }
343         else
344         {
345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
346                 if(!firstspot_new)
347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
348                 firstspot = firstspot_new;
349
350                 // there is 50/50 chance of choosing a random spot or the furthest spot
351                 // (this means that roughly every other spawn will be furthest, so you
352                 // usually won't get fragged at spawn twice in a row)
353                 if (arena_roundbased && !g_ca)
354                 {
355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
356                         if(firstspot_new)
357                                 firstspot = firstspot_new;
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 }
360                 else if (random() > cvar("g_spawn_furthest"))
361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362                 else
363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
364         }
365
366         if(cvar("spawn_debugview"))
367         {
368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
369
370                 entity e;
371                 if(teamcheck)
372                         for(e = firstspot; e; e = e.chain)
373                                 if(e.team != teamcheck)
374                                         error("invalid spawn found");
375         }
376
377         if (!spot)
378         {
379                 if(cvar("spawn_debug"))
380                         GotoNextMap();
381                 else
382                 {
383                         if(some_spawn_has_been_used)
384                                 return world; // team can't spawn any more, because of actions of other team
385                         else
386                                 error("Cannot find a spawn point - please fix the map!");
387                 }
388         }
389
390         return spot;
391 }
392
393 /*
394 =============
395 CheckPlayerModel
396
397 Checks if the argument string can be a valid playermodel.
398 Returns a valid one in doubt.
399 =============
400 */
401 string FallbackPlayerModel = "models/player/marine.zym";
402 string CheckPlayerModel(string plyermodel) {
403         if(strlen(plyermodel) < 4)
404                 return FallbackPlayerModel;
405         if( substring(plyermodel,0,14) != "models/player/")
406                 return FallbackPlayerModel;
407         else if(cvar("sv_servermodelsonly"))
408         {
409                 if(substring(plyermodel,-4,4) != ".zym")
410                 if(substring(plyermodel,-4,4) != ".dpm")
411                 if(substring(plyermodel,-4,4) != ".iqm")
412                 if(substring(plyermodel,-4,4) != ".md3")
413                 if(substring(plyermodel,-4,4) != ".psk")
414                         return FallbackPlayerModel;
415                 // forbid the LOD models
416                 if(substring(plyermodel, -9,5) == "_lod1")
417                         return FallbackPlayerModel;
418                 if(substring(plyermodel, -9,5) == "_lod2")
419                         return FallbackPlayerModel;
420                 if(plyermodel != strtolower(plyermodel))
421                         return FallbackPlayerModel;
422                 if(!fexists(plyermodel))
423                         return FallbackPlayerModel;
424         }
425         return plyermodel;
426 }
427
428 /*
429 =============
430 Client_customizeentityforclient
431
432 LOD reduction
433 =============
434 */
435 void Client_uncustomizeentityforclient()
436 {
437         if(self.modelindex == 0) // no need to uncustomize then
438                 return;
439         self.modelindex = self.modelindex_lod0;
440         self.skin = self.skinindex;
441 }
442
443 float Client_customizeentityforclient()
444 {
445         entity modelsource;
446
447         if(self.modelindex == 0)
448                 return TRUE;
449
450         // forcemodel stuff
451
452 #ifdef PROFILING
453         float t0;
454         t0 = gettime(GETTIME_HIRES); // reference
455 #endif
456
457         modelsource = self;
458
459 #ifdef ALLOW_FORCEMODELS
460         if(other.cvar_cl_forceplayermodelsfromxonotic)
461                 if not(self.modelindex_lod0_from_xonotic)
462                         modelsource = other;
463         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
464                 modelsource = other;
465 #endif
466
467         self.skin = modelsource.skinindex;
468
469 #if 0
470         if(modelsource == self)
471                 self.skin = modelsource.skinindex;
472         else
473                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
474 #endif
475
476         // self: me
477         // other: the player viewing me
478         float distance;
479         float f;
480
481         if(other.cvar_cl_playerdetailreduction <= 0)
482         {
483                 if(other.cvar_cl_playerdetailreduction <= -2)
484                         self.modelindex = modelsource.modelindex_lod2;
485                 else if(other.cvar_cl_playerdetailreduction <= -1)
486                         self.modelindex = modelsource.modelindex_lod1;
487                 else
488                         self.modelindex = modelsource.modelindex_lod0;
489         }
490         else
491         {
492                 distance = vlen(self.origin - other.origin);
493                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
494                 if(f > sv_loddistance2)
495                         self.modelindex = modelsource.modelindex_lod2;
496                 else if(f > sv_loddistance1)
497                         self.modelindex = modelsource.modelindex_lod1;
498                 else
499                         self.modelindex = modelsource.modelindex_lod0;
500         }
501
502 #ifdef PROFILING
503         float t1;
504         t1 = gettime(GETTIME_HIRES); // reference
505         client_cefc_accumulator += (t1 - t0);
506 #endif
507
508         return TRUE;
509 }
510
511 void setmodel_lod(entity e, string modelname)
512 {
513         string s;
514
515         if(sv_loddistance1)
516         {
517                 // FIXME: this only supports 3-letter extensions
518                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
519                 if(fexists(s))
520                 {
521                         setmodel(e, s); // players have high precision
522                         self.modelindex_lod1 = self.modelindex;
523                 }
524                 else
525                         self.modelindex_lod1 = -1;
526
527                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
528                 if(fexists(s))
529                 {
530                         setmodel(e, s); // players have high precision
531                         self.modelindex_lod2 = self.modelindex;
532                 }
533                 else
534                         self.modelindex_lod2 = -1;
535
536                 precache_model(modelname);
537                 setmodel(e, modelname); // players have high precision
538                 self.modelindex_lod0 = self.modelindex;
539
540                 if(self.modelindex_lod1 < 0)
541                         self.modelindex_lod1 = self.modelindex;
542
543                 if(self.modelindex_lod2 < 0)
544                         self.modelindex_lod2 = self.modelindex;
545         }
546         else
547         {
548                 precache_model(modelname);
549                 setmodel(e, modelname); // players have high precision
550                 self.modelindex_lod0 = self.modelindex;
551                         // save it for possible player model forcing
552         }
553
554         s = whichpack(self.model);
555         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
556
557         player_setupanimsformodel();
558 }
559
560 /*
561 =============
562 PutObserverInServer
563
564 putting a client as observer in the server
565 =============
566 */
567 void FixPlayermodel();
568 void PutObserverInServer (void)
569 {
570         entity  spot;
571
572         race_PreSpawnObserver();
573
574         spot = SelectSpawnPoint (TRUE);
575         if(!spot)
576                 error("No spawnpoints for observers?!?\n");
577         RemoveGrapplingHook(self); // Wazat's Grappling Hook
578
579         if(clienttype(self) == CLIENTTYPE_REAL)
580         {
581                 msg_entity = self;
582                 WriteByte(MSG_ONE, SVC_SETVIEW);
583                 WriteEntity(MSG_ONE, self);
584         }
585
586         DropAllRunes(self);
587
588         Portal_ClearAll(self);
589
590         if(self.flagcarried)
591                 DropFlag(self.flagcarried, world, world);
592
593         if(self.ballcarried)
594                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
595
596         WaypointSprite_PlayerDead();
597
598         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
599                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
600
601         if(self.killcount != -666) {
602                 if(g_lms) {
603                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
604                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
605                         else
606                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
607                 } else
608                         bprint ("^4", self.netname, "^4 is spectating now\n");
609
610                 if(self.just_joined == FALSE) {
611                         LogTeamchange(self.playerid, -1, 4);
612                 } else
613                         self.just_joined = FALSE;
614         }
615
616         PlayerScore_Clear(self); // clear scores when needed
617
618         self.spectatortime = time;
619
620         self.classname = "observer";
621         self.iscreature = FALSE;
622         self.health = -666;
623         self.takedamage = DAMAGE_NO;
624         self.solid = SOLID_NOT;
625         self.movetype = MOVETYPE_NOCLIP;
626         self.flags = FL_CLIENT | FL_NOTARGET;
627         self.armorvalue = 666;
628         self.effects = 0;
629         self.armorvalue = cvar("g_balance_armor_start");
630         self.pauserotarmor_finished = 0;
631         self.pauserothealth_finished = 0;
632         self.pauseregen_finished = 0;
633         self.damageforcescale = 0;
634         self.death_time = 0;
635         self.dead_frame = 0;
636         self.alpha = 0;
637         self.scale = 0;
638         self.fade_time = 0;
639         self.pain_frame = 0;
640         self.pain_finished = 0;
641         self.strength_finished = 0;
642         self.invincible_finished = 0;
643         self.pushltime = 0;
644         self.think = SUB_Null;
645         self.nextthink = 0;
646         self.hook_time = 0;
647         self.runes = 0;
648         self.deadflag = DEAD_NO;
649         self.angles = spot.angles;
650         self.angles_z = 0;
651         self.fixangle = TRUE;
652         self.crouch = FALSE;
653
654         self.view_ofs = PL_VIEW_OFS;
655         setorigin (self, spot.origin);
656         setsize (self, '0 0 0', '0 0 0');
657         self.prevorigin = self.origin;
658         self.items = 0;
659         self.weapons = 0;
660         self.model = "";
661         FixPlayermodel();
662         self.model = "";
663         self.modelindex = 0;
664         self.weapon = 0;
665         self.weaponmodel = "";
666         self.weaponentity = world;
667         self.exteriorweaponentity = world;
668         self.killcount = -666;
669         self.velocity = '0 0 0';
670         self.avelocity = '0 0 0';
671         self.punchangle = '0 0 0';
672         self.punchvector = '0 0 0';
673         self.oldvelocity = self.velocity;
674         self.fire_endtime = -1;
675
676         if(sv_loddistance1)
677                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
678
679         if(g_arena)
680         {
681                 if(self.version_mismatch)
682                 {
683                         Spawnqueue_Unmark(self);
684                         Spawnqueue_Remove(self);
685                 }
686                 else
687                 {
688                         Spawnqueue_Insert(self);
689                 }
690         }
691         else if(g_lms)
692         {
693                 // Only if the player cannot play at all
694                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
695                         self.frags = FRAGS_SPECTATOR;
696                 else
697                         self.frags = FRAGS_LMS_LOSER;
698         }
699         else
700                 self.frags = FRAGS_SPECTATOR;
701
702         MUTATOR_CALLHOOK(MakePlayerObserver);
703 }
704
705 float RestrictSkin(float s)
706 {
707         if(!teams_matter)
708                 return s;
709         if(s == 6)
710                 return 6;
711         return mod(s, 3);
712 }
713
714 void FixPlayermodel()
715 {
716         local string defaultmodel;
717         local float defaultskin, chmdl, oldskin;
718         local vector m1, m2;
719
720         defaultmodel = "";
721
722         if(cvar("sv_defaultcharacter") == 1) {
723                 defaultskin = 0;
724
725                 if(teams_matter)
726                 {
727                         string s;
728                         s = Team_ColorNameLowerCase(self.team);
729                         if(s != "neutral")
730                         {
731                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
732                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
733                         }
734                 }
735
736                 if(defaultmodel == "")
737                 {
738                         defaultmodel = cvar_string("sv_defaultplayermodel");
739                         defaultskin = cvar("sv_defaultplayerskin");
740                 }
741         }
742
743         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
744         {
745                 if(self.model != "")
746                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
747                 self.model = ""; // force the != checks to return true
748         }
749
750         if(defaultmodel != "")
751         {
752                 if (defaultmodel != self.model)
753                 {
754                         m1 = self.mins;
755                         m2 = self.maxs;
756                         setmodel_lod (self, defaultmodel);
757                         setsize (self, m1, m2);
758                         chmdl = TRUE;
759                 }
760
761                 oldskin = self.skinindex;
762                 self.skinindex = defaultskin;
763         } else {
764                 if (self.playermodel != self.model || self.playermodel == "")
765                 {
766                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
767                         m1 = self.mins;
768                         m2 = self.maxs;
769                         setmodel_lod (self, self.playermodel);
770                         setsize (self, m1, m2);
771                         chmdl = TRUE;
772                 }
773
774                 oldskin = self.skinindex;
775                 self.skinindex = RestrictSkin(stof(self.playerskin));
776         }
777
778         if(chmdl || oldskin != self.skinindex)
779                 self.species = player_getspecies(); // model or skin has changed
780
781         if(!teams_matter)
782                 if(strlen(cvar_string("sv_defaultplayercolors")))
783                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
784                                 setcolor(self, cvar("sv_defaultplayercolors"));
785 }
786
787 void PlayerTouchExplode(entity p1, entity p2)
788 {
789         vector org;
790         org = (p1.origin + p2.origin) * 0.5;
791         org_z += (p1.mins_z + p2.mins_z) * 0.5;
792
793         te_explosion(org);
794
795         entity e;
796         e = spawn();
797         setorigin(e, org);
798         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
799         remove(e);
800 }
801
802 /*
803 =============
804 PutClientInServer
805
806 Called when a client spawns in the server
807 =============
808 */
809 //void() ctf_playerchanged;
810 void PutClientInServer (void)
811 {
812         if(clienttype(self) == CLIENTTYPE_BOT)
813         {
814                 self.classname = "player";
815         }
816         else if(clienttype(self) == CLIENTTYPE_REAL)
817         {
818                 msg_entity = self;
819                 WriteByte(MSG_ONE, SVC_SETVIEW);
820                 WriteEntity(MSG_ONE, self);
821         }
822
823         // player is dead and becomes observer
824         // FIXME fix LMS scoring for new system
825         if(g_lms)
826         {
827                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
828                         self.classname = "observer";
829         }
830
831         if(g_arena || (g_ca && !allowed_to_spawn))
832         if(!self.spawned)
833                 self.classname = "observer";
834
835         if(gameover)
836                 self.classname = "observer";
837
838         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
839                 entity spot, oldself;
840                 float j;
841
842                 if(self.team < 0)
843                         JoinBestTeam(self, FALSE, TRUE);
844
845                 race_PreSpawn();
846
847                 spot = SelectSpawnPoint (FALSE);
848                 if(!spot)
849                 {
850                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
851                         return; // spawn failed
852                 }
853
854                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
855
856                 self.classname = "player";
857                 self.wasplayer = TRUE;
858                 self.iscreature = TRUE;
859                 self.movetype = MOVETYPE_WALK;
860                 self.solid = SOLID_SLIDEBOX;
861                 if(cvar("g_playerclip_collisions"))
862                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
863                 else
864                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
865                 self.frags = FRAGS_PLAYER;
866                 if(independent_players)
867                         MAKE_INDEPENDENT_PLAYER(self);
868                 self.flags = FL_CLIENT;
869                 self.takedamage = DAMAGE_AIM;
870                 if(g_minstagib)
871                         self.effects = EF_FULLBRIGHT;
872                 else
873                         self.effects = 0;
874                 self.air_finished = time + 12;
875                 self.dmg = 2;
876
877                 if(inWarmupStage)
878                 {
879                         self.ammo_shells = warmup_start_ammo_shells;
880                         self.ammo_nails = warmup_start_ammo_nails;
881                         self.ammo_rockets = warmup_start_ammo_rockets;
882                         self.ammo_cells = warmup_start_ammo_cells;
883                         self.ammo_fuel = warmup_start_ammo_fuel;
884                         self.health = warmup_start_health;
885                         self.armorvalue = warmup_start_armorvalue;
886                         self.weapons = warmup_start_weapons;
887                 }
888                 else
889                 {
890                         self.ammo_shells = start_ammo_shells;
891                         self.ammo_nails = start_ammo_nails;
892                         self.ammo_rockets = start_ammo_rockets;
893                         self.ammo_cells = start_ammo_cells;
894                         self.ammo_fuel = start_ammo_fuel;
895                         self.health = start_health;
896                         self.armorvalue = start_armorvalue;
897                         self.weapons = start_weapons;
898                 }
899
900                 if(g_weaponarena_random)
901                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
902
903                 self.items = start_items;
904                 self.jump_interval = time;
905
906                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
907                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
908                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
909                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
910                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
911                 //extend the pause of rotting if client was reset at the beginning of the countdown
912                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
913                         self.spawnshieldtime += game_starttime - time;
914                         self.pauserotarmor_finished += game_starttime - time;
915                         self.pauserothealth_finished += game_starttime - time;
916                         self.pauseregen_finished += game_starttime - time;
917                 }
918                 self.damageforcescale = 2;
919                 self.death_time = 0;
920                 self.dead_frame = 0;
921                 self.alpha = 0;
922                 self.scale = 0;
923                 self.fade_time = 0;
924                 self.pain_frame = 0;
925                 self.pain_finished = 0;
926                 self.strength_finished = 0;
927                 self.invincible_finished = 0;
928                 self.pushltime = 0;
929                 // players have no think function
930                 self.think = SUB_Null;
931                 self.nextthink = 0;
932                 self.hook_time = 0;
933                 self.dmg_team = 0;
934
935                 self.metertime = 0;
936
937                 self.runes = 0;
938
939                 self.deadflag = DEAD_NO;
940
941                 self.angles = spot.angles;
942
943                 self.angles_z = 0; // never spawn tilted even if the spot says to
944                 self.fixangle = TRUE; // turn this way immediately
945                 self.velocity = '0 0 0';
946                 self.avelocity = '0 0 0';
947                 self.punchangle = '0 0 0';
948                 self.punchvector = '0 0 0';
949                 self.oldvelocity = self.velocity;
950                 self.fire_endtime = -1;
951
952                 msg_entity = self;
953                 WRITESPECTATABLE_MSG_ONE({
954                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
955                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
956                 });
957
958                 if(sv_loddistance1)
959                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
960
961                 self.model = "";
962                 FixPlayermodel();
963
964                 self.crouch = FALSE;
965                 self.view_ofs = PL_VIEW_OFS;
966                 setsize (self, PL_MIN, PL_MAX);
967                 self.spawnorigin = spot.origin;
968                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
969                 // don't reset back to last position, even if new position is stuck in solid
970                 self.oldorigin = self.origin;
971                 self.prevorigin = self.origin;
972                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
973
974                 if(g_arena)
975                 {
976                         Spawnqueue_Remove(self);
977                         Spawnqueue_Mark(self);
978                 }
979
980                 else if(g_ca)
981                         self.caplayer = 1;
982
983                 self.event_damage = PlayerDamage;
984
985                 self.bot_attack = TRUE;
986
987                 self.statdraintime = time + 5;
988                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
989
990                 if(self.killcount == -666) {
991                         PlayerScore_Clear(self);
992                         self.killcount = 0;
993                 }
994
995                 self.cnt = WEP_LASER;
996
997                 CL_SpawnWeaponentity();
998                 self.alpha = default_player_alpha;
999                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1000                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1001
1002                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1003                 self.lms_traveled_distance = 0;
1004                 self.speedrunning = FALSE;
1005
1006                 race_PostSpawn(spot);
1007
1008                 if(cvar("spawn_debug"))
1009                 {
1010                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1011                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1012                 }
1013
1014                 //stuffcmd(self, "chase_active 0");
1015                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1016
1017                 if (cvar("g_spawnsound"))
1018                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1019
1020                 if(g_assault) {
1021                         if(self.team == assault_attacker_team)
1022                                 centerprint(self, "You are attacking!");
1023                         else
1024                                 centerprint(self, "You are defending!");
1025                 }
1026
1027                 target_voicescript_clear(self);
1028
1029                 // reset fields the weapons may use
1030                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1031                         weapon_action(j, WR_RESETPLAYER);
1032
1033                 oldself = self;
1034                 self = spot;
1035                         activator = oldself;
1036                                 SUB_UseTargets();
1037                         activator = world;
1038                 self = oldself;
1039
1040                 MUTATOR_CALLHOOK(PlayerSpawn);
1041
1042                 self.switchweapon = w_getbestweapon(self);
1043                 self.cnt = self.switchweapon;
1044                 self.weapon = 0;
1045         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1046                 PutObserverInServer ();
1047         }
1048
1049         //if(g_ctf)
1050         //      ctf_playerchanged();
1051 }
1052
1053 float ClientInit_SendEntity(entity to, float sf)
1054 {
1055         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1056         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1057         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1058         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1059         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1060
1061         if(sv_foginterval && world.fog != "")
1062                 WriteString(MSG_ENTITY, world.fog);
1063         else
1064                 WriteString(MSG_ENTITY, "");
1065         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1066         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1067         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1068         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1069         return TRUE;
1070 }
1071
1072 void ClientInit_CheckUpdate()
1073 {
1074         self.nextthink = time;
1075         if(self.count != cvar("g_balance_armor_blockpercent"))
1076         {
1077                 self.count = cvar("g_balance_armor_blockpercent");
1078                 self.SendFlags |= 1;
1079         }
1080         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1081         {
1082                 self.cnt = cvar("g_balance_weaponswitchdelay");
1083                 self.SendFlags |= 1;
1084         }
1085         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1086         {
1087                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1088                 self.SendFlags |= 1;
1089         }
1090         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1091         {
1092                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1093                 self.SendFlags |= 1;
1094         }
1095 }
1096
1097 void ClientInit_Spawn()
1098 {
1099         entity o;
1100         entity e;
1101         e.classname = "clientinit";
1102         e.think = ClientInit_CheckUpdate;
1103         e.nextthink = time;
1104         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1105         o = self;
1106         self = e;
1107         ClientInit_CheckUpdate();
1108         self = o;
1109 }
1110
1111 /*
1112 =============
1113 SetNewParms
1114 =============
1115 */
1116 void SetNewParms (void)
1117 {
1118         // initialize parms for a new player
1119         parm1 = -(86400 * 366);
1120 }
1121
1122 /*
1123 =============
1124 SetChangeParms
1125 =============
1126 */
1127 void SetChangeParms (void)
1128 {
1129         // save parms for level change
1130         parm1 = self.parm_idlesince - time;
1131 }
1132
1133 /*
1134 =============
1135 DecodeLevelParms
1136 =============
1137 */
1138 void DecodeLevelParms (void)
1139 {
1140         // load parms
1141         self.parm_idlesince = parm1;
1142         if(self.parm_idlesince == -(86400 * 366))
1143                 self.parm_idlesince = time;
1144
1145         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1146         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1147 }
1148
1149 /*
1150 =============
1151 ClientKill
1152
1153 Called when a client types 'kill' in the console
1154 =============
1155 */
1156
1157 void ClientKill_Now_TeamChange()
1158 {
1159         if(self.killindicator_teamchange == -1)
1160         {
1161                 self.team = -1;
1162                 JoinBestTeam( self, FALSE, FALSE );
1163         }
1164         else
1165                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1166 }
1167
1168 void ClientKill_Now()
1169 {
1170         if(self.killindicator_teamchange)
1171                 ClientKill_Now_TeamChange();
1172
1173         // in any case:
1174         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1175
1176         if(self.killindicator)
1177         {
1178                 dprint("Cleaned up after a leaked kill indicator.\n");
1179                 remove(self.killindicator);
1180                 self.killindicator = world;
1181         }
1182 }
1183 void KillIndicator_Think()
1184 {
1185         if (!self.owner.modelindex)
1186         {
1187                 self.owner.killindicator = world;
1188                 remove(self);
1189                 return;
1190         }
1191
1192         if(self.cnt <= 0)
1193         {
1194                 self = self.owner;
1195                 ClientKill_Now(); // no oldself needed
1196                 return;
1197         }
1198         else
1199         {
1200                 if(self.cnt <= 10)
1201                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1202                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1203                 {
1204                         if(self.cnt <= 10)
1205                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1206                         if(self.owner.killindicator_teamchange)
1207                         {
1208                                 if(self.owner.killindicator_teamchange == -1)
1209                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1210                                 else
1211                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1212                         }
1213                         else
1214                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1215                 }
1216                 self.nextthink = time + 1;
1217                 self.cnt -= 1;
1218         }
1219 }
1220
1221 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1222 {
1223         float killtime;
1224         entity e;
1225         killtime = cvar("g_balance_kill_delay");
1226
1227         if(g_race_qualifying)
1228                 killtime = 0;
1229
1230         self.killindicator_teamchange = targetteam;
1231
1232         if(!self.killindicator)
1233         {
1234                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1235                 {
1236                         ClientKill_Now();
1237                 }
1238                 else
1239                 {
1240                         self.killindicator = spawn();
1241                         self.killindicator.owner = self;
1242                         self.killindicator.scale = 0.5;
1243                         setattachment(self.killindicator, self, "");
1244                         setorigin(self.killindicator, '0 0 52');
1245                         self.killindicator.think = KillIndicator_Think;
1246                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1247                         self.killindicator.cnt = ceil(killtime);
1248                         self.killindicator.count = bound(0, ceil(killtime), 10);
1249                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1250
1251                         for(e = world; (e = find(e, classname, "body")) != world; )
1252                         {
1253                                 if(e.enemy != self)
1254                                         continue;
1255                                 e.killindicator = spawn();
1256                                 e.killindicator.owner = e;
1257                                 e.killindicator.scale = 0.5;
1258                                 setattachment(e.killindicator, e, "");
1259                                 setorigin(e.killindicator, '0 0 52');
1260                                 e.killindicator.think = KillIndicator_Think;
1261                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1262                                 e.killindicator.cnt = ceil(killtime);
1263                         }
1264                         self.lip = 0;
1265                 }
1266         }
1267         if(self.killindicator)
1268         {
1269                 if(targetteam)
1270                         self.killindicator.colormod = TeamColor(targetteam);
1271                 else
1272                         self.killindicator.colormod = '0 0 0';
1273         }
1274 }
1275
1276 void ClientKill (void)
1277 {
1278         ClientKill_TeamChange(0);
1279 }
1280
1281 void DoTeamChange(float destteam)
1282 {
1283         float t, c0;
1284         if(!teams_matter)
1285         {
1286                 if(destteam >= 0)
1287                         SetPlayerColors(self, destteam);
1288                 return;
1289         }
1290         if(self.classname == "player")
1291         if(destteam == -1)
1292         {
1293                 CheckAllowedTeams(self);
1294                 t = FindSmallestTeam(self, TRUE);
1295                 switch(self.team)
1296                 {
1297                         case COLOR_TEAM1: c0 = c1; break;
1298                         case COLOR_TEAM2: c0 = c2; break;
1299                         case COLOR_TEAM3: c0 = c3; break;
1300                         case COLOR_TEAM4: c0 = c4; break;
1301                         default:          c0 = 999;
1302                 }
1303                 switch(t)
1304                 {
1305                         case 1:
1306                                 if(c0 > c1)
1307                                         destteam = COLOR_TEAM1;
1308                                 break;
1309                         case 2:
1310                                 if(c0 > c2)
1311                                         destteam = COLOR_TEAM2;
1312                                 break;
1313                         case 3:
1314                                 if(c0 > c3)
1315                                         destteam = COLOR_TEAM3;
1316                                 break;
1317                         case 4:
1318                                 if(c0 > c4)
1319                                         destteam = COLOR_TEAM4;
1320                                 break;
1321                 }
1322                 if(destteam == -1)
1323                         return;
1324         }
1325         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1326                 return;
1327         ClientKill_TeamChange(destteam);
1328 }
1329
1330 void FixClientCvars(entity e)
1331 {
1332         // send prediction settings to the client
1333         stuffcmd(e, "\nin_bindmap 0 0\n");
1334         if(g_race || g_cts)
1335                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1336         if(cvar("g_antilag") == 3) // client side hitscan
1337                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1338                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1339         /*
1340          * we no longer need to stuff this. Remove this comment block if you feel
1341          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1342         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1343         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1344         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1345         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1346         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1347         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1348         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1349         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1350         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1351         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1352         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1353         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1354         stuffcmd(e, "cl_movement_edgefriction 1\n");
1355          */
1356 }
1357
1358 /*
1359 =============
1360 ClientConnect
1361
1362 Called when a client connects to the server
1363 =============
1364 */
1365 //void ctf_clientconnect();
1366 string ColoredTeamName(float t);
1367 void DecodeLevelParms (void);
1368 //void dom_player_join_team(entity pl);
1369 #ifdef UID
1370 .float uid_kicktime;
1371 .string uid;
1372 #endif
1373 void ClientConnect (void)
1374 {
1375         float t;
1376
1377         if(self.flags & FL_CLIENT)
1378         {
1379                 print("Warning: ClientConnect, but already connected!\n");
1380                 return;
1381         }
1382
1383         if(Ban_MaybeEnforceBan(self))
1384                 return;
1385
1386         DecodeLevelParms();
1387
1388         self.classname = "player_joining";
1389
1390         self.flags = FL_CLIENT;
1391         self.version_nagtime = time + 10 + random() * 10;
1392
1393         if(player_count<0)
1394         {
1395                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1396                 player_count = 0;
1397         }
1398
1399         PlayerScore_Attach(self);
1400         ClientData_Attach();
1401
1402         bot_clientconnect();
1403
1404         playerdemo_init();
1405
1406         anticheat_init();
1407         
1408         race_PreSpawnObserver();
1409
1410         //if(g_domination)
1411         //      dom_player_join_team(self);
1412
1413         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1414
1415         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1416                 self.classname = "observer";
1417         } else {
1418                 if(teams_matter)
1419                 {
1420                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1421                         {
1422                                 self.classname = "player";
1423                                 campaign_bots_may_start = 1;
1424                         }
1425                         else
1426                         {
1427                                 self.classname = "observer"; // do it anyway
1428                         }
1429                 }
1430                 else
1431                 {
1432                         self.classname = "player";
1433                         campaign_bots_may_start = 1;
1434                 }
1435         }
1436
1437         self.playerid = (playerid_last = playerid_last + 1);
1438
1439         if(cvar("sv_eventlog"))
1440                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1441
1442         LogTeamchange(self.playerid, self.team, 1);
1443
1444         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1445
1446         self.netname_previous = strzone(self.netname);
1447
1448         bprint("^4", self.netname, "^4 connected");
1449
1450         if(self.classname != "observer" && (g_domination || g_ctf))
1451                 bprint(" and joined the ", ColoredTeamName(self.team));
1452
1453         bprint("\n");
1454
1455         self.welcomemessage_time = 0;
1456
1457         stuffcmd(self, strcat(clientstuff, "\n"));
1458         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1459         stuffcmd(self, "cl_particles_reloadeffects\n");
1460
1461         FixClientCvars(self);
1462
1463         // spawnfunc_waypoint sprites
1464         WaypointSprite_InitClient(self);
1465
1466         // Wazat's grappling hook
1467         SetGrappleHookBindings();
1468
1469         // get autoswitch state from player when he toggles it
1470         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1471
1472         // get version info from player
1473         stuffcmd(self, "cmd clientversion $gameversion\n");
1474
1475         // get other cvars from player
1476         GetCvars(0);
1477
1478         // set cvar for team scoreboard
1479         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1480
1481         // notify about available teams
1482         if(teams_matter)
1483         {
1484                 CheckAllowedTeams(self);
1485                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1486                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1487         }
1488         else
1489                 stuffcmd(self, "set _teams_available 0\n");
1490
1491         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1492
1493         if(g_arena || g_ca)
1494         {
1495                 self.classname = "observer";
1496                 if(g_arena)
1497                         Spawnqueue_Insert(self);
1498         }
1499         /*else if(g_ctf)
1500         {
1501                 ctf_clientconnect();
1502         }*/
1503
1504         if(teams_matter || radar_showennemies)
1505                 attach_entcs();
1506
1507         bot_relinkplayerlist();
1508
1509         self.spectatortime = time;
1510         if(blockSpectators)
1511         {
1512                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1513         }
1514
1515         self.jointime = time;
1516         self.allowedTimeouts = cvar("sv_timeout_number");
1517
1518         if(clienttype(self) == CLIENTTYPE_REAL)
1519         {
1520                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1521                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1522         }
1523
1524         if(g_lms)
1525         {
1526                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1527                 {
1528                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1529                         self.frags = FRAGS_SPECTATOR;
1530                 }
1531         }
1532
1533         if(!sv_foginterval && world.fog != "")
1534                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1535
1536         SoundEntity_Attach(self);
1537
1538         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1539         {
1540                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1541                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1542         }
1543         else
1544                 self.hitplotfh = -1;
1545
1546 #ifdef UID
1547         if(clienttype(self) == CLIENTTYPE_REAL)
1548         if not(self.uid)
1549                 self.uid_kicktime = time + 60;
1550 #endif
1551
1552         if(g_race || g_cts) {
1553                 string rr;
1554                 if(g_cts)
1555                         rr = CTS_RECORD;
1556                 else
1557                         rr = RACE_RECORD;
1558                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1559
1560                 race_send_recordtime(MSG_ONE);
1561                 race_send_speedaward(MSG_ONE);
1562
1563                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1564                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1565                 race_send_speedaward_alltimebest(MSG_ONE);
1566
1567                 float i;
1568                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1569                         race_SendRankings(i, 0, 0, MSG_ONE);
1570                 }
1571         }
1572         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1573                 send_CSQC_teamnagger();
1574
1575         CheatInitClient();
1576 }
1577
1578 /*
1579 =============
1580 ClientDisconnect
1581
1582 Called when a client disconnects from the server
1583 =============
1584 */
1585 .entity chatbubbleentity;
1586 .entity teambubbleentity;
1587 void ReadyCount();
1588 void ClientDisconnect (void)
1589 {
1590         if not(self.flags & FL_CLIENT)
1591         {
1592                 print("Warning: ClientDisconnect without ClientConnect\n");
1593                 return;
1594         }
1595
1596         CheatShutdownClient();
1597
1598         if(self.hitplotfh >= 0)
1599         {
1600                 fclose(self.hitplotfh);
1601                 self.hitplotfh = -1;
1602         }
1603
1604         anticheat_report();
1605         anticheat_shutdown();
1606
1607         playerdemo_shutdown();
1608
1609         bot_clientdisconnect();
1610
1611         if(self.entcs)
1612                 detach_entcs();
1613
1614         if(cvar("sv_eventlog"))
1615                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1616         bprint ("^4",self.netname);
1617         bprint ("^4 disconnected\n");
1618
1619         SoundEntity_Detach(self);
1620
1621         DropAllRunes(self);
1622         MUTATOR_CALLHOOK(ClientDisconnect);
1623
1624         Portal_ClearAll(self);
1625
1626         if(self.flagcarried)
1627                 DropFlag(self.flagcarried, world, world);
1628         if(self.ballcarried)
1629                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1630
1631         // Here, everything has been done that requires this player to be a client.
1632
1633         self.flags &~= FL_CLIENT;
1634
1635         if (self.chatbubbleentity)
1636                 remove (self.chatbubbleentity);
1637
1638         if (self.teambubbleentity)
1639                 remove (self.teambubbleentity);
1640
1641         if (self.killindicator)
1642                 remove (self.killindicator);
1643
1644         WaypointSprite_PlayerGone();
1645
1646         bot_relinkplayerlist();
1647
1648         // remove laserdot
1649         if(self.weaponentity)
1650                 if(self.weaponentity.lasertarget)
1651                         remove(self.weaponentity.lasertarget);
1652
1653         if(g_arena)
1654         {
1655                 Spawnqueue_Unmark(self);
1656                 Spawnqueue_Remove(self);
1657         }
1658
1659         ClientData_Detach();
1660         PlayerScore_Detach(self);
1661
1662         if(self.netname_previous)
1663                 strunzone(self.netname_previous);
1664         if(self.clientstatus)
1665                 strunzone(self.clientstatus);
1666
1667         ClearPlayerSounds();
1668
1669         if(self.personal)
1670                 remove(self.personal);
1671
1672         self.playerid = 0;
1673         ReadyCount();
1674
1675         // free cvars
1676         GetCvars(-1);
1677 }
1678
1679 .float BUTTON_CHAT;
1680 void ChatBubbleThink()
1681 {
1682         self.nextthink = time;
1683         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1684         {
1685                 if(self.owner) // but why can that ever be world?
1686                         self.owner.chatbubbleentity = world;
1687                 remove(self);
1688                 return;
1689         }
1690         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1691 #ifdef TETRIS
1692                 || self.owner.tetris_on
1693 #endif
1694         )
1695                 self.model = self.mdl;
1696         else
1697                 self.model = "";
1698 };
1699
1700 void UpdateChatBubble()
1701 {
1702         if (!self.modelindex)
1703                 return;
1704         // spawn a chatbubble entity if needed
1705         if (!self.chatbubbleentity)
1706         {
1707                 self.chatbubbleentity = spawn();
1708                 self.chatbubbleentity.owner = self;
1709                 self.chatbubbleentity.exteriormodeltoclient = self;
1710                 self.chatbubbleentity.think = ChatBubbleThink;
1711                 self.chatbubbleentity.nextthink = time;
1712                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1713                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1714                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1715                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1716                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1717                 self.chatbubbleentity.model = "";
1718                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1719         }
1720 }
1721
1722
1723 void TeamBubbleThink()
1724 {
1725         self.nextthink = time;
1726         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1727         {
1728                 if(self.owner) // but why can that ever be world?
1729                         self.owner.teambubbleentity = world;
1730                 remove(self);
1731                 return;
1732         }
1733 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1734         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1735                 self.model = "";
1736         else
1737                 self.model = self.mdl;
1738
1739 };
1740
1741 float TeamBubble_customizeentityforclient()
1742 {
1743         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1744 }
1745
1746 void UpdateTeamBubble()
1747 {
1748         if (!self.modelindex || !teams_matter)
1749                 return;
1750         // spawn a teambubble entity if needed
1751         if (!self.teambubbleentity && teams_matter)
1752         {
1753                 self.teambubbleentity = spawn();
1754                 self.teambubbleentity.owner = self;
1755                 self.teambubbleentity.exteriormodeltoclient = self;
1756                 self.teambubbleentity.think = TeamBubbleThink;
1757                 self.teambubbleentity.nextthink = time;
1758                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1759 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1760                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1761                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1762                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1763                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1764                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1765                 self.teambubbleentity.effects = EF_LOWPRECISION;
1766         }
1767 }
1768
1769 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1770 // added to the model skins
1771 /*void UpdateColorModHack()
1772 {
1773         local float c;
1774         c = self.clientcolors & 15;
1775         // LordHavoc: only bothering to support white, green, red, yellow, blue
1776              if (!teams_matter) self.colormod = '0 0 0';
1777         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1778         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1779         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1780         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1781         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1782         else self.colormod = '1 1 1';
1783 };*/
1784
1785 .float oldcolormap;
1786 void respawn(void)
1787 {
1788         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1789         {
1790                 self.solid = SOLID_NOT;
1791                 self.takedamage = DAMAGE_NO;
1792                 self.movetype = MOVETYPE_FLY;
1793                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1794                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1795                 self.effects |= EF_ADDITIVE;
1796                 self.oldcolormap = self.colormap;
1797                 self.colormap = 512;
1798                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1799                 if(cvar("g_respawn_ghosts_maxtime"))
1800                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1801         }
1802
1803         CopyBody(1);
1804         self.effects |= EF_NODRAW; // prevent another CopyBody
1805         if(self.oldcolormap)
1806         {
1807                 self.colormap = self.oldcolormap;
1808                 self.oldcolormap = 0;
1809         }
1810         PutClientInServer();
1811 }
1812
1813 void play_countdown(float finished, string samp)
1814 {
1815         if(clienttype(self) == CLIENTTYPE_REAL)
1816                 if(floor(finished - time - frametime) != floor(finished - time))
1817                         if(finished - time < 6)
1818                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1819 }
1820
1821 /**
1822  * When sv_timeout is used this function returs strings like
1823  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1824  * Called by centerprint functions
1825  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1826  */
1827 string getTimeoutText(float addOneSecond) {
1828         if (!cvar("sv_timeout") || !timeoutStatus)
1829                 return "";
1830
1831         local string retStr;
1832         if (timeoutStatus == 1) {
1833                 if (addOneSecond == 1) {
1834                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1835                 }
1836                 else {
1837                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1838                 }
1839                 return retStr;
1840         }
1841         else if (timeoutStatus == 2) {
1842                 if (addOneSecond) {
1843                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1844                         //don't show messages like "Timeout ends in 0 seconds"...
1845                         if ((remainingTimeoutTime + 1) > 0)
1846                                 return retStr;
1847                         else
1848                                 return "";
1849                 }
1850                 else {
1851                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1852                         //don't show messages like "Timeout ends in 0 seconds"...
1853                         if (remainingTimeoutTime > 0)
1854                                 return retStr;
1855                         else
1856                                 return "";
1857                 }
1858         }
1859         else return "";
1860 }
1861
1862 void player_powerups (void)
1863 {
1864         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1865         {
1866                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1867                 self.modelflags |= MF_ROCKET;
1868         }
1869         else
1870         {
1871                 SoundEntity_StopSound(self, CHAN_PLAYER);
1872                 self.modelflags &~= MF_ROCKET;
1873         }
1874
1875         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1876
1877         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1878                 return;
1879         
1880         Fire_ApplyDamage(self);
1881         Fire_ApplyEffect(self);
1882
1883         if (g_minstagib)
1884         {
1885                 self.effects |= EF_FULLBRIGHT;
1886
1887                 if (self.items & IT_STRENGTH)
1888                 {
1889                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1890                         if (time > self.strength_finished)
1891                         {
1892                                 self.alpha = default_player_alpha;
1893                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1894                                 self.items &~= IT_STRENGTH;
1895                                 sprint(self, "^3Invisibility has worn off\n");
1896                         }
1897                 }
1898                 else
1899                 {
1900                         if (time < self.strength_finished)
1901                         {
1902                                 self.alpha = g_minstagib_invis_alpha;
1903                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1904                                 self.items |= IT_STRENGTH;
1905                                 sprint(self, "^3You are invisible\n");
1906                         }
1907                 }
1908
1909                 if (self.items & IT_INVINCIBLE)
1910                 {
1911                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1912                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1913                         {
1914                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1915                                 sprint(self, "^3Speed has worn off\n");
1916                         }
1917                 }
1918                 else
1919                 {
1920                         if (time < self.invincible_finished)
1921                         {
1922                                 self.items = self.items | IT_INVINCIBLE;
1923                                 sprint(self, "^3You are on speed\n");
1924                         }
1925                 }
1926                 return;
1927         }
1928
1929         if (self.items & IT_STRENGTH)
1930         {
1931                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1932                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1933                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1934                 {
1935                         self.items = self.items - (self.items & IT_STRENGTH);
1936                         sprint(self, "^3Strength has worn off\n");
1937                 }
1938         }
1939         else
1940         {
1941                 if (time < self.strength_finished)
1942                 {
1943                         self.items = self.items | IT_STRENGTH;
1944                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1945                 }
1946         }
1947         if (self.items & IT_INVINCIBLE)
1948         {
1949                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1950                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1951                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1952                 {
1953                         self.items = self.items - (self.items & IT_INVINCIBLE);
1954                         sprint(self, "^3Shield has worn off\n");
1955                 }
1956         }
1957         else
1958         {
1959                 if (time < self.invincible_finished)
1960                 {
1961                         self.items = self.items | IT_INVINCIBLE;
1962                         sprint(self, "^3Shield surrounds you\n");
1963                 }
1964         }
1965
1966         if(cvar("g_nodepthtestplayers"))
1967                 self.effects = self.effects | EF_NODEPTHTEST;
1968
1969         if(cvar("g_fullbrightplayers"))
1970                 self.effects = self.effects | EF_FULLBRIGHT;
1971
1972         // midair gamemode: damage only while in the air
1973         // if in midair mode, being on ground grants temporary invulnerability
1974         // (this is so that multishot weapon don't clear the ground flag on the
1975         // first damage in the frame, leaving the player vulnerable to the
1976         // remaining hits in the same frame)
1977         if (self.flags & FL_ONGROUND)
1978         if (g_midair)
1979                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1980
1981         if (time >= game_starttime)
1982         if (time < self.spawnshieldtime)
1983                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1984 }
1985
1986 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1987 {
1988         if(current > stable)
1989                 return current;
1990         else if(current > stable - 0.25) // when close enough, "snap"
1991                 return stable;
1992         else
1993                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1994 }
1995
1996 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1997 {
1998         if(current < stable)
1999                 return current;
2000         else if(current < stable + 0.25) // when close enough, "snap"
2001                 return stable;
2002         else
2003                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2004 }
2005
2006 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2007 {
2008         if(current > rotstable)
2009         {
2010                 if(rotframetime > 0)
2011                 {
2012                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2013                         current = max(rotstable, current - rotlinear * rotframetime);
2014                 }
2015         }
2016         else if(current < regenstable)
2017         {
2018                 if(regenframetime > 0)
2019                 {
2020                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2021                         current = min(regenstable, current + regenlinear * regenframetime);
2022                 }
2023         }
2024
2025         if(current > limit)
2026                 current = limit;
2027
2028         return current;
2029 }
2030
2031 void player_regen (void)
2032 {
2033         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2034         maxh = cvar("g_balance_health_rotstable");
2035         maxa = cvar("g_balance_armor_rotstable");
2036         maxf = cvar("g_balance_fuel_rotstable");
2037         minh = cvar("g_balance_health_regenstable");
2038         mina = cvar("g_balance_armor_regenstable");
2039         minf = cvar("g_balance_fuel_regenstable");
2040         limith = cvar("g_balance_health_limit");
2041         limita = cvar("g_balance_armor_limit");
2042         limitf = cvar("g_balance_fuel_limit");
2043
2044         max_mod = regen_mod = rot_mod = limit_mod = 1;
2045
2046         if (self.runes & RUNE_REGEN)
2047         {
2048                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2049                 {
2050                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2051                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2052                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2053                 }
2054                 else
2055                 {
2056                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2057                         max_mod = cvar("g_balance_rune_regen_hpmod");
2058                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2059                 }
2060         }
2061         else if (self.runes & CURSE_VENOM)
2062         {
2063                 max_mod = cvar("g_balance_curse_venom_hpmod");
2064                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2065                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2066                 else
2067                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2068                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2069                 //if (!self.runes & RUNE_REGEN)
2070                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2071         }
2072         maxh = maxh * max_mod;
2073         //maxa = maxa * max_mod;
2074         //maxf = maxf * max_mod;
2075         minh = minh * max_mod;
2076         //mina = mina * max_mod;
2077         //minf = minf * max_mod;
2078         limith = limith * limit_mod;
2079         limita = limita * limit_mod;
2080         //limitf = limitf * limit_mod;
2081
2082         if(g_lms && g_ca)
2083                 rot_mod = 0;
2084
2085         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2086         {
2087                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2088                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2089
2090                 // if player rotted to death...  die!
2091                 if(self.health < 1)
2092                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2093         }
2094
2095         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2096                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2097 }
2098
2099 float zoomstate_set;
2100 void SetZoomState(float z)
2101 {
2102         if(z != self.zoomstate)
2103         {
2104                 self.zoomstate = z;
2105                 ClientData_Touch(self);
2106         }
2107         zoomstate_set = 1;
2108 }
2109
2110 void GetPressedKeys(void) {
2111         MUTATOR_CALLHOOK(GetPressedKeys);
2112         if (self.movement_x > 0) // get if movement keys are pressed
2113         {       // forward key pressed
2114                 self.pressedkeys |= KEY_FORWARD;
2115                 self.pressedkeys &~= KEY_BACKWARD;
2116         }
2117         else if (self.movement_x < 0)
2118         {       // backward key pressed
2119                 self.pressedkeys |= KEY_BACKWARD;
2120                 self.pressedkeys &~= KEY_FORWARD;
2121         }
2122         else
2123         {       // no x input
2124                 self.pressedkeys &~= KEY_FORWARD;
2125                 self.pressedkeys &~= KEY_BACKWARD;
2126         }
2127
2128         if (self.movement_y > 0)
2129         {       // right key pressed
2130                 self.pressedkeys |= KEY_RIGHT;
2131                 self.pressedkeys &~= KEY_LEFT;
2132         }
2133         else if (self.movement_y < 0)
2134         {       // left key pressed
2135                 self.pressedkeys |= KEY_LEFT;
2136                 self.pressedkeys &~= KEY_RIGHT;
2137         }
2138         else
2139         {       // no y input
2140                 self.pressedkeys &~= KEY_RIGHT;
2141                 self.pressedkeys &~= KEY_LEFT;
2142         }
2143
2144         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2145                 self.pressedkeys |= KEY_JUMP;
2146         else
2147                 self.pressedkeys &~= KEY_JUMP;
2148         if (self.BUTTON_CROUCH)
2149                 self.pressedkeys |= KEY_CROUCH;
2150         else
2151                 self.pressedkeys &~= KEY_CROUCH;
2152 }
2153
2154 void update_stats (float number, float hit, float fired) {
2155 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2156 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2157
2158         if(number) {
2159                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2160                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2161         } else {
2162                 self.stat_hit = hit * sv_accuracy_data_share;
2163                 self.stat_fired = fired * sv_accuracy_data_share;
2164         }
2165 }
2166
2167 /*
2168 ======================
2169 spectate mode routines
2170 ======================
2171 */
2172
2173 .float weapon_count;
2174 void SpectateCopy(entity spectatee) {
2175         if(spectatee.weapon_count < WEP_LAST) {
2176                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2177                 spectatee.weapon_count ++;
2178         } else
2179                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2180
2181         other = spectatee;
2182         MUTATOR_CALLHOOK(SpectateCopy);
2183         self.armortype = spectatee.armortype;
2184         self.armorvalue = spectatee.armorvalue;
2185         self.ammo_cells = spectatee.ammo_cells;
2186         self.ammo_shells = spectatee.ammo_shells;
2187         self.ammo_nails = spectatee.ammo_nails;
2188         self.ammo_rockets = spectatee.ammo_rockets;
2189         self.ammo_fuel = spectatee.ammo_fuel;
2190         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2191         self.health = spectatee.health;
2192         self.impulse = 0;
2193         self.items = spectatee.items;
2194         self.metertime = spectatee.metertime;
2195         self.strength_finished = spectatee.strength_finished;
2196         self.invincible_finished = spectatee.invincible_finished;
2197         self.pressedkeys = spectatee.pressedkeys;
2198         self.weapons = spectatee.weapons;
2199         self.switchweapon = spectatee.switchweapon;
2200         self.weapon = spectatee.weapon;
2201         self.punchangle = spectatee.punchangle;
2202         self.view_ofs = spectatee.view_ofs;
2203         self.v_angle = spectatee.v_angle;
2204         self.velocity = spectatee.velocity;
2205         self.dmg_take = spectatee.dmg_take;
2206         self.dmg_save = spectatee.dmg_save;
2207         self.dmg_inflictor = spectatee.dmg_inflictor;
2208         self.angles = spectatee.v_angle;
2209         self.fixangle = TRUE;
2210         setorigin(self, spectatee.origin);
2211         setsize(self, spectatee.mins, spectatee.maxs);
2212         SetZoomState(spectatee.zoomstate);
2213
2214         anticheat_spectatecopy(spectatee);
2215 }
2216
2217 float SpectateUpdate() {
2218         if(!self.enemy)
2219                 return 0;
2220
2221         if (self == self.enemy)
2222                 return 0;
2223
2224         if(self.enemy.classname != "player")
2225                 return 0;
2226
2227         SpectateCopy(self.enemy);
2228
2229         return 1;
2230 }
2231
2232 float SpectateNext() {
2233         other = find(self.enemy, classname, "player");
2234
2235         if (!other)
2236                 other = find(other, classname, "player");
2237
2238         if (other)
2239                 self.enemy = other;
2240
2241         if(self.enemy.classname == "player") {
2242                 msg_entity = self;
2243                 WriteByte(MSG_ONE, SVC_SETVIEW);
2244                 WriteEntity(MSG_ONE, self.enemy);
2245                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2246                 self.movetype = MOVETYPE_NONE;
2247
2248                 self.enemy.weapon_count = 0;
2249
2250                 if(!SpectateUpdate())
2251                         PutObserverInServer();
2252
2253                 return 1;
2254         } else {
2255                 return 0;
2256         }
2257 }
2258
2259 /*
2260 =============
2261 ShowRespawnCountdown()
2262
2263 Update a respawn countdown display.
2264 =============
2265 */
2266 void ShowRespawnCountdown()
2267 {
2268         float number;
2269         if(self.deadflag == DEAD_NO) // just respawned?
2270                 return;
2271         else
2272         {
2273                 number = ceil(self.death_time - time);
2274                 if(number <= 0)
2275                         return;
2276                 if(number <= self.respawn_countdown)
2277                 {
2278                         self.respawn_countdown = number - 1;
2279                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2280                                 AnnounceTo(self, strcat(ftos(number), ""));
2281                 }
2282         }
2283 }
2284
2285 void LeaveSpectatorMode()
2286 {
2287         if(isJoinAllowed()) {
2288                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2289                         self.classname = "player";
2290
2291                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2292                                 JoinBestTeam(self, FALSE, TRUE);
2293
2294                         if(cvar("g_campaign"))
2295                                 campaign_bots_may_start = 1;
2296
2297                         self.stat_count = WEP_LAST;
2298
2299                         PutClientInServer();
2300
2301                         if(self.classname == "player")
2302                                 bprint ("^4", self.netname, "^4 is playing now\n");
2303
2304                         if(!cvar("g_campaign"))
2305                                 centerprint(self,""); // clear MOTD
2306
2307                         return;
2308                 } else {
2309                         if (g_ca && self.caplayer) {
2310                         }       // do nothing
2311                         else
2312                                 stuffcmd(self,"menu_showteamselect\n");
2313                         return;
2314                 }
2315         }
2316         else {
2317                 //player may not join because of g_maxplayers is set
2318                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2319         }
2320 }
2321
2322 /**
2323  * Determines whether the player is allowed to join. This depends on cvar
2324  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2325  * it checks whether the number of currently playing players exceeds g_maxplayers.
2326  * @return bool TRUE if the player is allowed to join, false otherwise
2327  */
2328 float isJoinAllowed() {
2329         if (!cvar("g_maxplayers"))
2330                 return TRUE;
2331
2332         local entity e;
2333         local float currentlyPlaying;
2334         FOR_EACH_REALPLAYER(e) {
2335                 if(e.classname == "player")
2336                         currentlyPlaying += 1;
2337         }
2338         if(currentlyPlaying < cvar("g_maxplayers"))
2339                 return TRUE;
2340
2341         return FALSE;
2342 }
2343
2344 /**
2345  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2346  * g_maxplayers_spectator_blocktime seconds
2347  */
2348 void checkSpectatorBlock() {
2349         if(self.classname == "spectator" || self.classname == "observer") {
2350                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2351                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2352                         dropclient(self);
2353                 }
2354         }
2355 }
2356
2357 float vercmp_recursive(string v1, string v2)
2358 {
2359         float dot1, dot2;
2360         string s1, s2;
2361         float r;
2362
2363         dot1 = strstrofs(v1, ".", 0);
2364         dot2 = strstrofs(v2, ".", 0);
2365         if(dot1 == -1)
2366                 s1 = v1;
2367         else
2368                 s1 = substring(v1, 0, dot1);
2369         if(dot2 == -1)
2370                 s2 = v2;
2371         else
2372                 s2 = substring(v2, 0, dot2);
2373
2374         r = stof(s1) - stof(s2);
2375         if(r != 0)
2376                 return r;
2377
2378         r = strcasecmp(s1, s2);
2379         if(r != 0)
2380                 return r;
2381
2382         if(dot1 == -1)
2383                 if(dot2 == -1)
2384                         return 0;
2385                 else
2386                         return -1;
2387         else
2388                 if(dot2 == -1)
2389                         return 1;
2390                 else
2391                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2392 }
2393
2394 float vercmp(string v1, string v2)
2395 {
2396         if(strcasecmp(v1, v2) == 0) // early out check
2397                 return 0;
2398         return vercmp_recursive(v1, v2);
2399 }
2400
2401 void ObserverThink()
2402 {
2403         if (self.flags & FL_JUMPRELEASED) {
2404                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2405                         self.welcomemessage_time = 0;
2406                         self.flags &~= FL_JUMPRELEASED;
2407                         self.flags |= FL_SPAWNING;
2408                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2409                         self.welcomemessage_time = 0;
2410                         self.flags &~= FL_JUMPRELEASED;
2411                         if(SpectateNext() == 1) {
2412                                 self.classname = "spectator";
2413                         }
2414                 }
2415         } else {
2416                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2417                         self.flags |= FL_JUMPRELEASED;
2418                         if(self.flags & FL_SPAWNING)
2419                         {
2420                                 self.flags &~= FL_SPAWNING;
2421                                 LeaveSpectatorMode();
2422                                 return;
2423                         }
2424                 }
2425         }
2426         PrintWelcomeMessage(self);
2427 }
2428
2429 void SpectatorThink()
2430 {
2431         if (self.flags & FL_JUMPRELEASED) {
2432                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2433                         self.welcomemessage_time = 0;
2434                         self.flags &~= FL_JUMPRELEASED;
2435                         self.flags |= FL_SPAWNING;
2436                 } else if(self.BUTTON_ATCK) {
2437                         self.welcomemessage_time = 0;
2438                         self.flags &~= FL_JUMPRELEASED;
2439                         if(SpectateNext() == 1) {
2440                                 self.classname = "spectator";
2441                         } else {
2442                                 self.classname = "observer";
2443                                 self.stat_count = WEP_LAST;
2444                                 PutClientInServer();
2445                         }
2446                 } else if (self.BUTTON_ATCK2) {
2447                         self.welcomemessage_time = 0;
2448                         self.flags &~= FL_JUMPRELEASED;
2449                         self.classname = "observer";
2450                         self.stat_count = WEP_LAST;
2451                         PutClientInServer();
2452                 } else {
2453                         if(!SpectateUpdate())
2454                                 PutObserverInServer();
2455                 }
2456         } else {
2457                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2458                         self.flags |= FL_JUMPRELEASED;
2459                         if(self.flags & FL_SPAWNING)
2460                         {
2461                                 self.flags &~= FL_SPAWNING;
2462                                 LeaveSpectatorMode();
2463                                 return;
2464                         }
2465                 }
2466         }
2467
2468         PrintWelcomeMessage(self);
2469         self.flags |= FL_CLIENT | FL_NOTARGET;
2470 }
2471
2472 .float touchexplode_time;
2473
2474 /*
2475 =============
2476 PlayerPreThink
2477
2478 Called every frame for each client before the physics are run
2479 =============
2480 */
2481 void() ctf_setstatus;
2482 void() nexball_setstatus;
2483 .float items_added;
2484 void PlayerPreThink (void)
2485 {
2486         self.stat_game_starttime = game_starttime;
2487         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2488         self.stat_leadlimit = cvar("leadlimit");
2489
2490         if(frametime)
2491         {
2492                 // physics frames: update anticheat stuff
2493                 anticheat_prethink();
2494         }
2495
2496         if(blockSpectators && frametime)
2497                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2498                 checkSpectatorBlock();
2499
2500         zoomstate_set = 0;
2501
2502         if(self.netname_previous != self.netname)
2503         {
2504                 if(cvar("sv_eventlog"))
2505                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2506                 if(self.netname_previous)
2507                         strunzone(self.netname_previous);
2508                 self.netname_previous = strzone(self.netname);
2509         }
2510
2511         // version nagging
2512         if(self.version_nagtime)
2513                 if(self.cvar_g_xonoticversion)
2514                         if(time > self.version_nagtime)
2515                         {
2516                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2517                                 {
2518                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2519                                         {
2520                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2521                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2522                                         }
2523                                         else
2524                                         {
2525                                                 float r;
2526                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2527                                                 if(r < 0)
2528                                                 {
2529                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2530                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2531                                                 }
2532                                                 else if(r > 0)
2533                                                 {
2534                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2535                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2536                                                 }
2537                                         }
2538                                 }
2539                                 self.version_nagtime = 0;
2540                         }
2541
2542         // GOD MODE info
2543         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2544         {
2545                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2546                 self.max_armorvalue = 0;
2547         }
2548
2549 #ifdef TETRIS
2550         if (TetrisPreFrame())
2551                 return;
2552 #endif
2553
2554         MUTATOR_CALLHOOK(PlayerPreThink);
2555
2556         if(self.classname == "player") {
2557 //              if(self.netname == "Wazat")
2558 //                      bprint(self.classname, "\n");
2559
2560                 CheckRules_Player();
2561
2562                 PrintWelcomeMessage(self);
2563
2564                 if (intermission_running)
2565                 {
2566                         IntermissionThink ();   // otherwise a button could be missed between
2567                         return;                                 // the think tics
2568                 }
2569
2570                 if(self.teleport_time)
2571                 if(time > self.teleport_time)
2572                 {
2573                         self.teleport_time = 0;
2574                         self.effects = self.effects - (self.effects & EF_NODRAW);
2575                 }
2576
2577                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2578                         UpdateSelectedPlayer();
2579
2580                 //don't allow the player to turn around while game is paused!
2581                 if(timeoutStatus == 2) {
2582                         self.v_angle = self.lastV_angle;
2583                         self.angles = self.lastV_angle;
2584                         self.fixangle = TRUE;
2585                 }
2586
2587                 if(frametime)
2588                 {
2589                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2590                         player_powerups();
2591                 }
2592
2593                 if (self.deadflag != DEAD_NO)
2594                 {
2595                         float button_pressed, force_respawn;
2596                         if(self.personal && g_race_qualifying)
2597                         {
2598                                 if(time > self.death_time)
2599                                 {
2600                                         self.death_time = time + 1; // only retry once a second
2601                                         respawn();
2602                                         self.impulse = 141;
2603                                 }
2604                         }
2605                         else
2606                         {
2607                                 if(frametime)
2608                                         player_anim();
2609                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2610                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2611                                 if (self.deadflag == DEAD_DYING)
2612                                 {
2613                                         if(force_respawn)
2614                                                 self.deadflag = DEAD_RESPAWNING;
2615                                         else if(!button_pressed)
2616                                                 self.deadflag = DEAD_DEAD;
2617                                 }
2618                                 else if (self.deadflag == DEAD_DEAD)
2619                                 {
2620                                         if(button_pressed)
2621                                                 self.deadflag = DEAD_RESPAWNABLE;
2622                                 }
2623                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2624                                 {
2625                                         if(!button_pressed)
2626                                                 self.deadflag = DEAD_RESPAWNING;
2627                                 }
2628                                 else if (self.deadflag == DEAD_RESPAWNING)
2629                                 {
2630                                         if(time > self.death_time)
2631                                         {
2632                                                 self.death_time = time + 1; // only retry once a second
2633                                                 respawn();
2634                                         }
2635                                 }
2636                                 ShowRespawnCountdown();
2637                         }
2638                         return;
2639                 }
2640
2641                 if(g_touchexplode)
2642                 if(time > self.touchexplode_time)
2643                 if(self.classname == "player")
2644                 if(self.deadflag == DEAD_NO)
2645                 if not(IS_INDEPENDENT_PLAYER(self))
2646                 FOR_EACH_PLAYER(other) if(self != other)
2647                 {
2648                         if(time > other.touchexplode_time)
2649                         if(other.classname == "player")
2650                         if(other.deadflag == DEAD_NO)
2651                         if not(IS_INDEPENDENT_PLAYER(other))
2652                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2653                         {
2654                                 PlayerTouchExplode(self, other);
2655                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2656                         }
2657                 }
2658
2659                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2660                 {
2661                         vector dist;
2662
2663                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2664                         dist = self.prevorigin - self.origin;
2665                         dist_z = 0;
2666                         self.lms_traveled_distance += fabs(vlen(dist));
2667
2668                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2669                         {
2670                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2671                                 self.lms_traveled_distance = 0;
2672                         }
2673
2674                         if(time > self.lms_nextcheck)
2675                         {
2676                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2677                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2678                                 {
2679                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2680                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2681                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2682                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2683                                 }
2684                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2685                                 self.lms_traveled_distance = 0;
2686                         }
2687                 }
2688
2689                 self.prevorigin = self.origin;
2690
2691                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2692                 {
2693                         if (!self.crouch)
2694                         {
2695                                 self.crouch = TRUE;
2696                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2697                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2698                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2699                         }
2700                 }
2701                 else
2702                 {
2703                         if (self.crouch)
2704                         {
2705                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2706                                 if (!trace_startsolid)
2707                                 {
2708                                         self.crouch = FALSE;
2709                                         self.view_ofs = PL_VIEW_OFS;
2710                                         setsize (self, PL_MIN, PL_MAX);
2711                                 }
2712                         }
2713                 }
2714
2715                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2716                 {
2717                         if(self.bloodloss_timer < time)
2718                         {
2719                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2720                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2721                         }
2722                 }
2723
2724                 FixPlayermodel();
2725
2726                 GrapplingHookFrame();
2727
2728                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2729                 //if(frametime)
2730                 {
2731                         self.items &~= self.items_added;
2732
2733                         W_WeaponFrame();
2734
2735                         self.items_added = 0;
2736                         if(self.items & IT_JETPACK)
2737                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2738                                         self.items_added |= IT_FUEL;
2739
2740                         self.items |= self.items_added;
2741                 }
2742
2743                 player_regen();
2744                 if(frametime)
2745                         player_anim();
2746
2747                 if (g_minstagib)
2748                         minstagib_ammocheck();
2749
2750                 ctf_setstatus();
2751                 nexball_setstatus();
2752
2753                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2754
2755                 //self.angles_y=self.v_angle_y + 90;   // temp
2756         } else if(gameover) {
2757                 if (intermission_running)
2758                         IntermissionThink ();   // otherwise a button could be missed between
2759                 return;
2760         } else if(self.classname == "observer") {
2761                 ObserverThink();
2762         } else if(self.classname == "spectator") {
2763                 SpectatorThink();
2764         }
2765
2766         if(!zoomstate_set)
2767                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2768
2769         float oldspectatee_status;
2770         oldspectatee_status = self.spectatee_status;
2771         if(self.classname == "spectator")
2772                 self.spectatee_status = num_for_edict(self.enemy);
2773         else if(self.classname == "observer")
2774                 self.spectatee_status = num_for_edict(self);
2775         else
2776                 self.spectatee_status = 0;
2777         if(self.spectatee_status != oldspectatee_status)
2778         {
2779                 ClientData_Touch(self);
2780                 if(g_race || g_cts)
2781                         race_InitSpectator();
2782         }
2783
2784         if(self.teamkill_soundtime)
2785         if(time > self.teamkill_soundtime)
2786         {
2787                 self.teamkill_soundtime = 0;
2788
2789                 entity oldpusher, oldself;
2790
2791                 oldself = self; self = self.teamkill_soundsource;
2792                 oldpusher = self.pusher; self.pusher = oldself;
2793
2794                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2795
2796                 self.pusher = oldpusher;
2797                 self = oldself;
2798         }
2799
2800         if(self.taunt_soundtime)
2801         if(time > self.taunt_soundtime)
2802         {
2803                 self.taunt_soundtime = 0;
2804                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2805         }
2806
2807         target_voicescript_next(self);
2808 }
2809
2810 float isInvisibleString(string s)
2811 {
2812         float i, n, c;
2813         s = strdecolorize(s);
2814         for((i = 0), (n = strlen(s)); i < n; ++i)
2815         {
2816                 c = str2chr(s, i);
2817                 switch(c)
2818                 {
2819                         case 0:
2820                         case 32:
2821                         case 160:
2822                                 break;
2823                         default:
2824                                 return FALSE;
2825                 }
2826         }
2827         return TRUE;
2828 }
2829
2830 /*
2831 =============
2832 PlayerPostThink
2833
2834 Called every frame for each client after the physics are run
2835 =============
2836 */
2837 .float idlekick_lasttimeleft;
2838 void PlayerPostThink (void)
2839 {
2840         // Savage: Check for nameless players
2841         if (isInvisibleString(self.netname)) {
2842                 self.netname = "Player";
2843                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2844         }
2845
2846         // send the clients accuracy stats to the client
2847         if(self.stat_count > 0)
2848         if(frametime)
2849         {
2850                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2851                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2852                 self.stat_count -= 1;
2853         }
2854
2855 #ifdef UID
2856         if(self.uid_kicktime)
2857         if(time > self.uid_kicktime)
2858         {
2859                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2860                 dropclient(self);
2861                 return;
2862         }
2863 #endif
2864
2865         if(sv_maxidle && frametime)
2866         {
2867                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2868                 float timeleft;
2869                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2870                 if(timeleft <= 0)
2871                 {
2872                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2873                         AnnounceTo(self, "terminated");
2874                         dropclient(self);
2875                         return;
2876                 }
2877                 else if(timeleft <= 10)
2878                 {
2879                         if(timeleft != self.idlekick_lasttimeleft)
2880                         {
2881                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2882                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2883                         }
2884                 }
2885                 else
2886                 {
2887                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2888                 }
2889                 self.idlekick_lasttimeleft = timeleft;
2890         }
2891
2892 #ifdef TETRIS
2893         if(self.impulse == 100)
2894                 ImpulseCommands();
2895         if (TetrisPostFrame())
2896                 return;
2897 #endif
2898
2899         CheatFrame();
2900
2901         if(self.classname == "player") {
2902                 CheckRules_Player();
2903                 UpdateChatBubble();
2904                 UpdateTeamBubble();
2905                 if (self.impulse)
2906                         ImpulseCommands();
2907                 if (intermission_running)
2908                         return;         // intermission or finale
2909                 GetPressedKeys();
2910         } else if (self.classname == "observer") {
2911                 //do nothing
2912         } else if (self.classname == "spectator") {
2913                 //do nothing
2914         }
2915
2916         /*
2917         float i;
2918         for(i = 0; i < 1000; ++i)
2919         {
2920                 vector end;
2921                 end = self.origin + '0 0 1024' + 512 * randomvec();
2922                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2923                 if(trace_fraction < 1)
2924                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2925                 {
2926                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2927                         break;
2928                 }
2929         }
2930         */
2931
2932         Arena_Warmup();
2933
2934         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2935
2936         if(self.waypointsprite_attachedforcarrier)
2937                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2938         
2939         playerdemo_write();
2940
2941         /*
2942         if(g_race)
2943                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2944         */
2945 }