qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24
  25 #include "bot/bot.qh"
  26 #include "bot/navigation.qh"
  27
  28 #include "../common/vehicles/sv_vehicles.qh"
  29
  30 #include "weapons/hitplot.qh"
  31 #include "weapons/weaponsystem.qh"
  32
  33 #include "../common/net_notice.qh"
  34 #include "../common/physics.qh"
  35
  36 #include "../common/triggers/subs.qh"
  37 #include "../common/triggers/triggers.qh"
  38 #include "../common/triggers/trigger/secret.qh"
  39
  40 #include "../common/items/inventory.qh"
  41
  42 #include "../common/monsters/sv_monsters.qh"
  43
  44 #include "../warpzonelib/server.qh"
  45
  46
  47 void send_CSQC_teamnagger() {
  48         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  49         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  50 }
  51
  52 float ClientData_Send(entity to, int sf)
  53 {
  54         if(to != self.owner)
  55         {
  56                 error("wtf");
  57                 return false;
  58         }
  59
  60         entity e;
  61
  62         e = to;
  63         if(IS_SPEC(to))
  64                 e = to.enemy;
  65
  66         sf = 0;
  67
  68         if(e.race_completed)
  69                 sf |= 1; // forced scoreboard
  70         if(to.spectatee_status)
  71                 sf |= 2; // spectator ent number follows
  72         if(e.zoomstate)
  73                 sf |= 4; // zoomed
  74         if(e.porto_v_angle_held)
  75                 sf |= 8; // angles held
  76
  77         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  78         WriteByte(MSG_ENTITY, sf);
  79
  80         if(sf & 2)
  81                 WriteByte(MSG_ENTITY, to.spectatee_status);
  82
  83         if(sf & 8)
  84         {
  85                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  86                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  87         }
  88
  89         return true;
  90 }
  91
  92 void ClientData_Attach()
  93 {
  94         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  95         self.clientdata.drawonlytoclient = self;
  96         self.clientdata.owner = self;
  97 }
  98
  99 void ClientData_Detach()
 100 {
 101         remove(self.clientdata);
 102         self.clientdata = world;
 103 }
 104
 105 void ClientData_Touch(entity e)
 106 {
 107         e.clientdata.SendFlags = 1;
 108
 109         // make it spectatable
 110         entity e2;
 111         FOR_EACH_REALCLIENT(e2)
 112         {
 113                 if(e2 != e)
 114                         if(IS_SPEC(e2))
 115                                 if(e2.enemy == e)
 116                                         e2.clientdata.SendFlags = 1;
 117         }
 118 }
 119
 120 .string netname_previous;
 121
 122 void SetSpectator(entity player, entity spectatee);
 123
 124
 125 /*
 126 =============
 127 CheckPlayerModel
 128
 129 Checks if the argument string can be a valid playermodel.
 130 Returns a valid one in doubt.
 131 =============
 132 */
 133 string FallbackPlayerModel;
 134 string CheckPlayerModel(string plyermodel) {
 135         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 136         {
 137                 // note: we cannot summon Don Strunzone here, some player may
 138                 // still have the model string set. In case anyone manages how
 139                 // to change a cvar default, we'll have a small leak here.
 140                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 141         }
 142         // only in right path
 143         if( substring(plyermodel,0,14) != "models/player/")
 144                 return FallbackPlayerModel;
 145         // only good file extensions
 146         if(substring(plyermodel,-4,4) != ".zym")
 147         if(substring(plyermodel,-4,4) != ".dpm")
 148         if(substring(plyermodel,-4,4) != ".iqm")
 149         if(substring(plyermodel,-4,4) != ".md3")
 150         if(substring(plyermodel,-4,4) != ".psk")
 151                 return FallbackPlayerModel;
 152         // forbid the LOD models
 153         if(substring(plyermodel, -9,5) == "_lod1")
 154                 return FallbackPlayerModel;
 155         if(substring(plyermodel, -9,5) == "_lod2")
 156                 return FallbackPlayerModel;
 157         if(plyermodel != strtolower(plyermodel))
 158                 return FallbackPlayerModel;
 159         // also, restrict to server models
 160         if(autocvar_sv_servermodelsonly)
 161         {
 162                 if(!fexists(plyermodel))
 163                         return FallbackPlayerModel;
 164         }
 165         return plyermodel;
 166 }
 167
 168 void setplayermodel(entity e, string modelname)
 169 {
 170         precache_model(modelname);
 171         setmodel(e, modelname);
 172         player_setupanimsformodel();
 173         UpdatePlayerSounds();
 174 }
 175
 176 /*
 177 =============
 178 PutObserverInServer
 179
 180 putting a client as observer in the server
 181 =============
 182 */
 183 void FixPlayermodel();
 184 void PutObserverInServer (void)
 185 {
 186         entity  spot;
 187     self.hud = HUD_NORMAL;
 188
 189         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 190
 191         spot = SelectSpawnPoint (true);
 192         if(!spot)
 193                 error("No spawnpoints for observers?!?\n");
 194         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 195
 196         if(IS_REAL_CLIENT(self))
 197         {
 198                 msg_entity = self;
 199                 WriteByte(MSG_ONE, SVC_SETVIEW);
 200                 WriteEntity(MSG_ONE, self);
 201         }
 202
 203         self.frags = FRAGS_SPECTATOR;
 204
 205         MUTATOR_CALLHOOK(MakePlayerObserver);
 206
 207         Portal_ClearAll(self);
 208
 209         Unfreeze(self);
 210
 211         if(self.alivetime)
 212         {
 213                 if(!warmup_stage)
 214                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 215                 self.alivetime = 0;
 216         }
 217
 218         if(self.vehicle)
 219                 vehicles_exit(VHEF_RELEASE);
 220
 221         WaypointSprite_PlayerDead();
 222
 223         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 224                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 225
 226         if(self.killcount != -666)
 227         {
 228                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 229                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 230                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 231
 232                 if(self.just_joined == false) {
 233                         LogTeamchange(self.playerid, -1, 4);
 234                 } else
 235                         self.just_joined = false;
 236         }
 237
 238         PlayerScore_Clear(self); // clear scores when needed
 239
 240         accuracy_resend(self);
 241
 242         self.spectatortime = time;
 243
 244         self.classname = "observer";
 245         self.iscreature = false;
 246         self.teleportable = TELEPORT_SIMPLE;
 247         self.damagedbycontents = false;
 248         self.health = -666;
 249         self.takedamage = DAMAGE_NO;
 250         self.solid = SOLID_NOT;
 251         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 252         self.flags = FL_CLIENT | FL_NOTARGET;
 253         self.armorvalue = 666;
 254         self.effects = 0;
 255         self.armorvalue = autocvar_g_balance_armor_start;
 256         self.pauserotarmor_finished = 0;
 257         self.pauserothealth_finished = 0;
 258         self.pauseregen_finished = 0;
 259         self.damageforcescale = 0;
 260         self.death_time = 0;
 261         self.respawn_flags = 0;
 262         self.respawn_time = 0;
 263         self.stat_respawn_time = 0;
 264         self.alpha = 0;
 265         self.scale = 0;
 266         self.fade_time = 0;
 267         self.pain_frame = 0;
 268         self.pain_finished = 0;
 269         self.strength_finished = 0;
 270         self.invincible_finished = 0;
 271         self.superweapons_finished = 0;
 272         self.pushltime = 0;
 273         self.istypefrag = 0;
 274         self.think = func_null;
 275         self.nextthink = 0;
 276         self.hook_time = 0;
 277         self.deadflag = DEAD_NO;
 278         self.angles = spot.angles;
 279         self.angles_z = 0;
 280         self.fixangle = true;
 281         self.crouch = false;
 282         self.revival_time = 0;
 283
 284         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 285         self.prevorigin = self.origin;
 286         self.items = 0;
 287         self.weapons = '0 0 0';
 288         self.model = "";
 289         FixPlayermodel();
 290         setmodel(self, "null");
 291         self.drawonlytoclient = self;
 292
 293         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 294         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 295
 296         self.weapon = 0;
 297         self.weaponname = "";
 298         self.switchingweapon = 0;
 299         self.weaponmodel = "";
 300         self.weaponentity = world;
 301         self.exteriorweaponentity = world;
 302         self.killcount = -666;
 303         self.velocity = '0 0 0';
 304         self.avelocity = '0 0 0';
 305         self.punchangle = '0 0 0';
 306         self.punchvector = '0 0 0';
 307         self.oldvelocity = self.velocity;
 308         self.fire_endtime = -1;
 309         self.event_damage = func_null;
 310 }
 311
 312 .float model_randomizer;
 313 void FixPlayermodel()
 314 {
 315         string defaultmodel;
 316         float defaultskin, chmdl, oldskin, n, i;
 317         vector m1, m2;
 318
 319         defaultmodel = "";
 320         defaultskin = 0;
 321         chmdl = false;
 322
 323         if(autocvar_sv_defaultcharacter)
 324         {
 325                 if(teamplay)
 326                 {
 327                         string s;
 328                         s = Static_Team_ColorName_Lower(self.team);
 329                         if(s != "neutral")
 330                         {
 331                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 332                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 333                         }
 334                 }
 335
 336                 if(defaultmodel == "")
 337                 {
 338                         defaultmodel = autocvar_sv_defaultplayermodel;
 339                         defaultskin = autocvar_sv_defaultplayerskin;
 340                 }
 341
 342                 n = tokenize_console(defaultmodel);
 343                 if(n > 0)
 344                 {
 345                         defaultmodel = argv(floor(n * self.model_randomizer));
 346                         // However, do NOT randomize if the player-selected model is in the list.
 347                         for (i = 0; i < n; ++i)
 348                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 349                                         defaultmodel = argv(i);
 350                 }
 351
 352                 i = strstrofs(defaultmodel, ":", 0);
 353                 if(i >= 0)
 354                 {
 355                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 356                         defaultmodel = substring(defaultmodel, 0, i);
 357                 }
 358         }
 359
 360         if(defaultmodel != "")
 361         {
 362                 if (defaultmodel != self.model)
 363                 {
 364                         m1 = self.mins;
 365                         m2 = self.maxs;
 366                         setplayermodel (self, defaultmodel);
 367                         setsize (self, m1, m2);
 368                         chmdl = true;
 369                 }
 370
 371                 oldskin = self.skin;
 372                 self.skin = defaultskin;
 373         } else {
 374                 if (self.playermodel != self.model || self.playermodel == "")
 375                 {
 376                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 377                         m1 = self.mins;
 378                         m2 = self.maxs;
 379                         setplayermodel (self, self.playermodel);
 380                         setsize (self, m1, m2);
 381                         chmdl = true;
 382                 }
 383
 384                 oldskin = self.skin;
 385                 self.skin = stof(self.playerskin);
 386         }
 387
 388         if(chmdl || oldskin != self.skin) // model or skin has changed
 389         {
 390                 self.species = player_getspecies(); // update species
 391                 UpdatePlayerSounds(); // update skin sounds
 392         }
 393
 394         if(!teamplay)
 395                 if(strlen(autocvar_sv_defaultplayercolors))
 396                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 397                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 398 }
 399
 400 /*
 401 =============
 402 PutClientInServer
 403
 404 Called when a client spawns in the server
 405 =============
 406 */
 407 void PutClientInServer (void)
 408 {
 409         if(IS_BOT_CLIENT(self))
 410                 self.classname = "player";
 411         else if(IS_REAL_CLIENT(self))
 412         {
 413                 msg_entity = self;
 414                 WriteByte(MSG_ONE, SVC_SETVIEW);
 415                 WriteEntity(MSG_ONE, self);
 416         }
 417
 418         SetSpectator(self, world);
 419
 420         // reset player keys
 421         self.itemkeys = 0;
 422
 423         MUTATOR_CALLHOOK(PutClientInServer);
 424
 425         if(gameover)
 426                 self.classname = "observer";
 427
 428         if(IS_PLAYER(self))
 429         {
 430                 entity spot, oldself;
 431
 432                 accuracy_resend(self);
 433
 434                 if(self.team < 0)
 435                         JoinBestTeam(self, false, true);
 436
 437                 spot = SelectSpawnPoint (false);
 438                 if(!spot)
 439                 {
 440                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 441                         return; // spawn failed
 442                 }
 443
 444                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 445
 446                 self.classname = "player";
 447                 self.wasplayer = true;
 448                 self.iscreature = true;
 449                 self.teleportable = TELEPORT_NORMAL;
 450                 self.damagedbycontents = true;
 451                 self.movetype = MOVETYPE_WALK;
 452                 self.solid = SOLID_SLIDEBOX;
 453                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 454                 if(autocvar_g_playerclip_collisions)
 455                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 456                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 457                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 458                 self.frags = FRAGS_PLAYER;
 459                 if(INDEPENDENT_PLAYERS)
 460                         MAKE_INDEPENDENT_PLAYER(self);
 461                 self.flags = FL_CLIENT;
 462                 if(autocvar__notarget)
 463                         self.flags |= FL_NOTARGET;
 464                 self.takedamage = DAMAGE_AIM;
 465                 self.effects = 0;
 466                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 467                 self.air_finished = time + 12;
 468                 self.dmg = 2;
 469                 if(WEP_CVAR(vortex, charge))
 470                 {
 471                         if(WEP_CVAR_SEC(vortex, chargepool))
 472                                 self.vortex_chargepool_ammo = 1;
 473                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 474                 }
 475
 476                 if(warmup_stage)
 477                 {
 478                         self.ammo_shells = warmup_start_ammo_shells;
 479                         self.ammo_nails = warmup_start_ammo_nails;
 480                         self.ammo_rockets = warmup_start_ammo_rockets;
 481                         self.ammo_cells = warmup_start_ammo_cells;
 482                         self.ammo_plasma = warmup_start_ammo_plasma;
 483                         self.ammo_fuel = warmup_start_ammo_fuel;
 484                         self.health = warmup_start_health;
 485                         self.armorvalue = warmup_start_armorvalue;
 486                         self.weapons = WARMUP_START_WEAPONS;
 487                 }
 488                 else
 489                 {
 490                         self.ammo_shells = start_ammo_shells;
 491                         self.ammo_nails = start_ammo_nails;
 492                         self.ammo_rockets = start_ammo_rockets;
 493                         self.ammo_cells = start_ammo_cells;
 494                         self.ammo_plasma = start_ammo_plasma;
 495                         self.ammo_fuel = start_ammo_fuel;
 496                         self.health = start_health;
 497                         self.armorvalue = start_armorvalue;
 498                         self.weapons = start_weapons;
 499                 }
 500
 501                 if(self.weapons & WEPSET_SUPERWEAPONS)
 502                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 503                 else
 504                         self.superweapons_finished = 0;
 505
 506                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 507                 {
 508                         if(g_weaponarena_random_with_blaster)
 509                                 self.weapons &= ~WEPSET_BLASTER;
 510                         W_RandomWeapons(self, g_weaponarena_random);
 511                         if(g_weaponarena_random_with_blaster)
 512                                 self.weapons |= WEPSET_BLASTER;
 513                 }
 514
 515                 self.items = start_items;
 516
 517                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 518                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 519                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 520                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 521                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 522                 //extend the pause of rotting if client was reset at the beginning of the countdown
 523                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 524                         self.spawnshieldtime += game_starttime - time;
 525                         self.pauserotarmor_finished += game_starttime - time;
 526                         self.pauserothealth_finished += game_starttime - time;
 527                         self.pauseregen_finished += game_starttime - time;
 528                 }
 529                 self.damageforcescale = 2;
 530                 self.death_time = 0;
 531                 self.respawn_flags = 0;
 532                 self.respawn_time = 0;
 533                 self.stat_respawn_time = 0;
 534                 self.scale = autocvar_sv_player_scale;
 535                 self.fade_time = 0;
 536                 self.pain_frame = 0;
 537                 self.pain_finished = 0;
 538                 self.strength_finished = 0;
 539                 self.invincible_finished = 0;
 540                 self.pushltime = 0;
 541                 // players have no think function
 542                 self.think = func_null;
 543                 self.nextthink = 0;
 544                 self.hook_time = 0;
 545                 self.dmg_team = 0;
 546                 self.ballistics_density = autocvar_g_ballistics_density_player;
 547
 548                 self.metertime = 0;
 549
 550                 self.deadflag = DEAD_NO;
 551
 552                 self.angles = spot.angles;
 553
 554                 self.angles_z = 0; // never spawn tilted even if the spot says to
 555                 if(IS_BOT_CLIENT(self))
 556                         self.v_angle = self.angles;
 557                 self.fixangle = true; // turn this way immediately
 558                 self.velocity = '0 0 0';
 559                 self.avelocity = '0 0 0';
 560                 self.punchangle = '0 0 0';
 561                 self.punchvector = '0 0 0';
 562                 self.oldvelocity = self.velocity;
 563                 self.fire_endtime = -1;
 564                 self.revival_time = 0;
 565
 566                 entity spawnevent = spawn();
 567                 spawnevent.owner = self;
 568                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 569
 570                 // Cut off any still running player sounds.
 571                 stopsound(self, CH_PLAYER_SINGLE);
 572
 573                 self.model = "";
 574                 FixPlayermodel();
 575                 self.drawonlytoclient = world;
 576
 577                 self.crouch = false;
 578                 self.view_ofs = PL_VIEW_OFS;
 579                 setsize (self, PL_MIN, PL_MAX);
 580                 self.spawnorigin = spot.origin;
 581                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 582                 // don't reset back to last position, even if new position is stuck in solid
 583                 self.oldorigin = self.origin;
 584                 self.prevorigin = self.origin;
 585                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 586                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 587         self.hud = HUD_NORMAL;
 588
 589                 self.event_damage = PlayerDamage;
 590
 591                 self.bot_attack = true;
 592                 self.monster_attack = true;
 593
 594                 self.spider_slowness = 0;
 595
 596                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 597
 598                 if(self.killcount == -666) {
 599                         PlayerScore_Clear(self);
 600                         self.killcount = 0;
 601                 }
 602
 603                 CL_SpawnWeaponentity();
 604                 self.alpha = default_player_alpha;
 605                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 606                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 607
 608                 self.speedrunning = false;
 609
 610                 //stuffcmd(self, "chase_active 0");
 611                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 612
 613                 target_voicescript_clear(self);
 614
 615                 // reset fields the weapons may use
 616                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 617                 {
 618                         WEP_ACTION(j, WR_RESETPLAYER);
 619
 620                         // all weapons must be fully loaded when we spawn
 621                         entity e = get_weaponinfo(j);
 622                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 623                                 self.(weapon_load[j]) = e.reloading_ammo;
 624                 }
 625
 626                 oldself = self;
 627                 self = spot;
 628                         activator = oldself;
 629                                 string s;
 630                                 s = self.target;
 631                                 self.target = string_null;
 632                                 SUB_UseTargets();
 633                                 self.target = s;
 634                         activator = world;
 635                 self = oldself;
 636
 637                 Unfreeze(self);
 638
 639                 spawn_spot = spot;
 640                 MUTATOR_CALLHOOK(PlayerSpawn);
 641
 642                 if(autocvar_spawn_debug)
 643                 {
 644                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 645                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 646                 }
 647
 648                 self.switchweapon = w_getbestweapon(self);
 649                 self.cnt = -1; // W_LastWeapon will not complain
 650                 self.weapon = 0;
 651                 self.weaponname = "";
 652                 self.switchingweapon = 0;
 653
 654                 if(!warmup_stage)
 655                         if(!self.alivetime)
 656                                 self.alivetime = time;
 657
 658                 antilag_clear(self);
 659         }
 660         else if(IS_OBSERVER(self))
 661         {
 662                 PutObserverInServer ();
 663         }
 664 }
 665
 666 .float ebouncefactor, ebouncestop; // electro's values
 667 // TODO do we need all these fields, or should we stop autodetecting runtime
 668 // changes and just have a console command to update this?
 669 float ClientInit_SendEntity(entity to, int sf)
 670 {
 671         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 672         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 673         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 674         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 681
 682         if(sv_foginterval && world.fog != "")
 683                 WriteString(MSG_ENTITY, world.fog);
 684         else
 685                 WriteString(MSG_ENTITY, "");
 686         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 687         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 688         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 689         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 690         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 691         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 692         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 693         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 694         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 695         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 696         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 697         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 698         return true;
 699 }
 700
 701 void ClientInit_CheckUpdate()
 702 {
 703         self.nextthink = time;
 704         if(self.count != autocvar_g_balance_armor_blockpercent)
 705         {
 706                 self.count = autocvar_g_balance_armor_blockpercent;
 707                 self.SendFlags |= 1;
 708         }
 709         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 710         {
 711                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 712                 self.SendFlags |= 1;
 713         }
 714         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 715         {
 716                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 717                 self.SendFlags |= 1;
 718         }
 719         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 720         {
 721                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 722                 self.SendFlags |= 1;
 723         }
 724         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 725         {
 726                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 727                 self.SendFlags |= 1;
 728         }
 729 }
 730
 731 void ClientInit_Spawn()
 732 {
 733         entity o;
 734         entity e;
 735         e = spawn();
 736         e.classname = "clientinit";
 737         e.think = ClientInit_CheckUpdate;
 738         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 739
 740         o = self;
 741         self = e;
 742         ClientInit_CheckUpdate();
 743         self = o;
 744 }
 745
 746 /*
 747 =============
 748 SetNewParms
 749 =============
 750 */
 751 void SetNewParms (void)
 752 {
 753         // initialize parms for a new player
 754         parm1 = -(86400 * 366);
 755 }
 756
 757 /*
 758 =============
 759 SetChangeParms
 760 =============
 761 */
 762 void SetChangeParms (void)
 763 {
 764         // save parms for level change
 765         parm1 = self.parm_idlesince - time;
 766 }
 767
 768 /*
 769 =============
 770 DecodeLevelParms
 771 =============
 772 */
 773 void DecodeLevelParms (void)
 774 {
 775         // load parms
 776         self.parm_idlesince = parm1;
 777         if(self.parm_idlesince == -(86400 * 366))
 778                 self.parm_idlesince = time;
 779
 780         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 781         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 782 }
 783
 784 /*
 785 =============
 786 ClientKill
 787
 788 Called when a client types 'kill' in the console
 789 =============
 790 */
 791
 792 .float clientkill_nexttime;
 793 void ClientKill_Now_TeamChange()
 794 {
 795         if(self.killindicator_teamchange == -1)
 796         {
 797                 JoinBestTeam( self, false, true );
 798         }
 799         else if(self.killindicator_teamchange == -2)
 800         {
 801                 if(blockSpectators)
 802                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 803                 PutObserverInServer();
 804         }
 805         else
 806                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 807         self.killindicator_teamchange = 0;
 808 }
 809
 810 void ClientKill_Now()
 811 {
 812         if(self.vehicle)
 813         {
 814             vehicles_exit(VHEF_RELEASE);
 815             if(!self.killindicator_teamchange)
 816             {
 817             self.vehicle_health = -1;
 818             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 819             }
 820         }
 821
 822         if(self.killindicator && !wasfreed(self.killindicator))
 823                 remove(self.killindicator);
 824
 825         self.killindicator = world;
 826
 827         if(self.killindicator_teamchange)
 828                 ClientKill_Now_TeamChange();
 829
 830         if(IS_PLAYER(self))
 831                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 832
 833         // now I am sure the player IS dead
 834 }
 835 void KillIndicator_Think()
 836 {
 837         if (gameover)
 838         {
 839                 self.owner.killindicator = world;
 840                 remove(self);
 841                 return;
 842         }
 843
 844         if (self.owner.alpha < 0 && !self.owner.vehicle)
 845         {
 846                 self.owner.killindicator = world;
 847                 remove(self);
 848                 return;
 849         }
 850
 851         if(self.cnt <= 0)
 852         {
 853                 self = self.owner;
 854                 ClientKill_Now(); // no oldself needed
 855                 return;
 856         }
 857     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 858     {
 859         self.nextthink = time + 1;
 860         self.cnt -= 1;
 861     }
 862         else
 863         {
 864                 if(self.cnt <= 10)
 865                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 866                 if(IS_REAL_CLIENT(self.owner))
 867                 {
 868                         if(self.cnt <= 10)
 869                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 870                 }
 871                 self.nextthink = time + 1;
 872                 self.cnt -= 1;
 873         }
 874 }
 875
 876 float clientkilltime;
 877 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 878 {
 879         float killtime;
 880         float starttime;
 881         entity e;
 882
 883         if (gameover)
 884                 return;
 885
 886         killtime = autocvar_g_balance_kill_delay;
 887
 888         if(g_race_qualifying || g_cts)
 889                 killtime = 0;
 890
 891     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 892     {
 893                 remove(self.killindicator);
 894                 self.killindicator = world;
 895
 896         ClientKill_Now(); // allow instant kill in this case
 897         return;
 898     }
 899
 900         self.killindicator_teamchange = targetteam;
 901
 902     if(!self.killindicator)
 903         {
 904                 if(self.deadflag == DEAD_NO)
 905                 {
 906                         killtime = max(killtime, self.clientkill_nexttime - time);
 907                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 908                 }
 909
 910                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 911                 {
 912                         ClientKill_Now();
 913                 }
 914                 else
 915                 {
 916                         starttime = max(time, clientkilltime);
 917
 918                         self.killindicator = spawn();
 919                         self.killindicator.owner = self;
 920                         self.killindicator.scale = 0.5;
 921                         setattachment(self.killindicator, self, "");
 922                         setorigin(self.killindicator, '0 0 52');
 923                         self.killindicator.think = KillIndicator_Think;
 924                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 925                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 926                         self.killindicator.cnt = ceil(killtime);
 927                         self.killindicator.count = bound(0, ceil(killtime), 10);
 928                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 929
 930                         for(e = world; (e = find(e, classname, "body")) != world; )
 931                         {
 932                                 if(e.enemy != self)
 933                                         continue;
 934                                 e.killindicator = spawn();
 935                                 e.killindicator.owner = e;
 936                                 e.killindicator.scale = 0.5;
 937                                 setattachment(e.killindicator, e, "");
 938                                 setorigin(e.killindicator, '0 0 52');
 939                                 e.killindicator.think = KillIndicator_Think;
 940                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 941                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 942                                 e.killindicator.cnt = ceil(killtime);
 943                         }
 944                         self.lip = 0;
 945                 }
 946         }
 947         if(self.killindicator)
 948         {
 949                 if(targetteam == 0) // just die
 950                 {
 951                         self.killindicator.colormod = '0 0 0';
 952                         if(IS_REAL_CLIENT(self))
 953                         if(self.killindicator.cnt > 0)
 954                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 955                 }
 956                 else if(targetteam == -1) // auto
 957                 {
 958                         self.killindicator.colormod = '0 1 0';
 959                         if(IS_REAL_CLIENT(self))
 960                         if(self.killindicator.cnt > 0)
 961                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 962                 }
 963                 else if(targetteam == -2) // spectate
 964                 {
 965                         self.killindicator.colormod = '0.5 0.5 0.5';
 966                         if(IS_REAL_CLIENT(self))
 967                         if(self.killindicator.cnt > 0)
 968                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 969                 }
 970                 else
 971                 {
 972                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 973                         if(IS_REAL_CLIENT(self))
 974                         if(self.killindicator.cnt > 0)
 975                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 976                 }
 977         }
 978
 979 }
 980
 981 void ClientKill (void)
 982 {
 983         if(gameover) return;
 984         if(self.player_blocked) return;
 985         if(self.frozen) return;
 986
 987         ClientKill_TeamChange(0);
 988 }
 989
 990 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 991 {
 992     e.killindicator = spawn();
 993     e.killindicator.owner = e;
 994     e.killindicator.think = KillIndicator_Think;
 995     e.killindicator.nextthink = time + (e.lip) * 0.05;
 996     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 997     e.killindicator.health = 1; // this is used to indicate that it should be silent
 998     e.lip = 0;
 999 }
1000
1001 void FixClientCvars(entity e)
1002 {
1003         // send prediction settings to the client
1004         stuffcmd(e, "\nin_bindmap 0 0\n");
1005         if(g_race || g_cts)
1006                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1007         if(autocvar_g_antilag == 3) // client side hitscan
1008                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1009         if(autocvar_sv_gentle)
1010                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1011 }
1012
1013 float PlayerInIDList(entity p, string idlist)
1014 {
1015         float n, i;
1016         string s;
1017
1018         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1019         if (!p.crypto_idfp)
1020                 return 0;
1021
1022         // this function allows abbreviated player IDs too!
1023         n = tokenize_console(idlist);
1024         for(i = 0; i < n; ++i)
1025         {
1026                 s = argv(i);
1027                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1028                         return 1;
1029         }
1030
1031         return 0;
1032 }
1033
1034 #ifdef DP_EXT_PRECONNECT
1035 /*
1036 =============
1037 ClientPreConnect
1038
1039 Called once (not at each match start) when a client begins a connection to the server
1040 =============
1041 */
1042 void ClientPreConnect (void)
1043 {
1044         if(autocvar_sv_eventlog)
1045         {
1046                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1047                         self.playerid,
1048                         num_for_edict(self),
1049                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1050                 ));
1051         }
1052 }
1053 #endif
1054
1055 /*
1056 =============
1057 ClientConnect
1058
1059 Called when a client connects to the server
1060 =============
1061 */
1062 void DecodeLevelParms (void);
1063 //void dom_player_join_team(entity pl);
1064 void set_dom_state(entity e);
1065 void ClientConnect (void)
1066 {
1067         float t;
1068
1069         if(IS_CLIENT(self))
1070         {
1071                 print("Warning: ClientConnect, but already connected!\n");
1072                 return;
1073         }
1074
1075         if(Ban_MaybeEnforceBanOnce(self))
1076                 return;
1077
1078         DecodeLevelParms();
1079
1080 #ifdef WATERMARK
1081         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1082 #endif
1083
1084         self.classname = "player_joining";
1085
1086         self.flags = FL_CLIENT;
1087         self.version_nagtime = time + 10 + random() * 10;
1088
1089         if(player_count<0)
1090         {
1091                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1092                 player_count = 0;
1093         }
1094
1095         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1096
1097         PlayerScore_Attach(self);
1098         ClientData_Attach();
1099         accuracy_init(self);
1100         Inventory_new(self);
1101
1102         bot_clientconnect();
1103
1104         playerdemo_init();
1105
1106         anticheat_init();
1107
1108         // identify the right forced team
1109         if(autocvar_g_campaign)
1110         {
1111                 if(IS_REAL_CLIENT(self)) // only players, not bots
1112                 {
1113                         switch(autocvar_g_campaign_forceteam)
1114                         {
1115                                 case 1: self.team_forced = NUM_TEAM_1; break;
1116                                 case 2: self.team_forced = NUM_TEAM_2; break;
1117                                 case 3: self.team_forced = NUM_TEAM_3; break;
1118                                 case 4: self.team_forced = NUM_TEAM_4; break;
1119                                 default: self.team_forced = 0;
1120                         }
1121                 }
1122         }
1123         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1124                 self.team_forced = NUM_TEAM_1;
1125         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1126                 self.team_forced = NUM_TEAM_2;
1127         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1128                 self.team_forced = NUM_TEAM_3;
1129         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1130                 self.team_forced = NUM_TEAM_4;
1131         else if(autocvar_g_forced_team_otherwise == "red")
1132                 self.team_forced = NUM_TEAM_1;
1133         else if(autocvar_g_forced_team_otherwise == "blue")
1134                 self.team_forced = NUM_TEAM_2;
1135         else if(autocvar_g_forced_team_otherwise == "yellow")
1136                 self.team_forced = NUM_TEAM_3;
1137         else if(autocvar_g_forced_team_otherwise == "pink")
1138                 self.team_forced = NUM_TEAM_4;
1139         else if(autocvar_g_forced_team_otherwise == "spectate")
1140                 self.team_forced = -1;
1141         else if(autocvar_g_forced_team_otherwise == "spectator")
1142                 self.team_forced = -1;
1143         else
1144                 self.team_forced = 0;
1145
1146         if(!teamplay)
1147                 if(self.team_forced > 0)
1148                         self.team_forced = 0;
1149
1150         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1151
1152         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1153                 self.classname = "observer";
1154         } else {
1155                 if(teamplay)
1156                 {
1157                         if(autocvar_g_balance_teams)
1158                         {
1159                                 self.classname = "player";
1160                                 campaign_bots_may_start = 1;
1161                         }
1162                         else
1163                         {
1164                                 self.classname = "observer"; // do it anyway
1165                         }
1166                 }
1167                 else
1168                 {
1169                         self.classname = "player";
1170                         campaign_bots_may_start = 1;
1171                 }
1172         }
1173
1174         self.playerid = (playerid_last = playerid_last + 1);
1175
1176         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1177
1178     if(IS_BOT_CLIENT(self))
1179         PlayerStats_GameReport_AddPlayer(self);
1180
1181         if(autocvar_sv_eventlog)
1182                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1183
1184         LogTeamchange(self.playerid, self.team, 1);
1185
1186         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1187
1188         self.netname_previous = strzone(self.netname);
1189
1190         if(IS_PLAYER(self) && teamplay)
1191                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1192         else
1193                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1194
1195         stuffcmd(self, strcat(clientstuff, "\n"));
1196         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1197
1198         FixClientCvars(self);
1199
1200         // spawnfunc_waypoint sprites
1201         WaypointSprite_InitClient(self);
1202
1203         // Wazat's grappling hook
1204         SetGrappleHookBindings();
1205
1206         // Jetpack binds
1207         stuffcmd(self, "alias +jetpack +button10\n");
1208         stuffcmd(self, "alias -jetpack -button10\n");
1209
1210         // get version info from player
1211         stuffcmd(self, "cmd clientversion $gameversion\n");
1212
1213         // get other cvars from player
1214         GetCvars(0);
1215
1216         // notify about available teams
1217         if(teamplay)
1218         {
1219                 CheckAllowedTeams(self);
1220                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1221                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1222         }
1223         else
1224                 stuffcmd(self, "set _teams_available 0\n");
1225
1226         attach_entcs();
1227
1228         bot_relinkplayerlist();
1229
1230         self.spectatortime = time;
1231         if(blockSpectators)
1232         {
1233                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1234         }
1235
1236         self.jointime = time;
1237         self.allowed_timeouts = autocvar_sv_timeout_number;
1238
1239         if(IS_REAL_CLIENT(self))
1240         {
1241                 if(!autocvar_g_campaign)
1242                 {
1243                         self.motd_actived_time = -1;
1244                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1245                 }
1246
1247                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1248                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1249         }
1250
1251         if(!sv_foginterval && world.fog != "")
1252                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1253
1254         W_HitPlotOpen(self);
1255
1256         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1257                 send_CSQC_teamnagger();
1258
1259         CheatInitClient();
1260
1261         CSQCMODEL_AUTOINIT();
1262
1263         self.model_randomizer = random();
1264
1265         if(IS_REAL_CLIENT(self))
1266                 sv_notice_join();
1267
1268         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1269                 entity oldself = self;
1270                 self = e;
1271                 e.init_for_player(oldself);
1272                 self = oldself;
1273         }
1274
1275         MUTATOR_CALLHOOK(ClientConnect);
1276 }
1277 /*
1278 =============
1279 ClientDisconnect
1280
1281 Called when a client disconnects from the server
1282 =============
1283 */
1284 .entity chatbubbleentity;
1285 void ReadyCount();
1286 void ClientDisconnect (void)
1287 {
1288         if(self.vehicle)
1289             vehicles_exit(VHEF_RELEASE);
1290
1291         if (!IS_CLIENT(self))
1292         {
1293                 print("Warning: ClientDisconnect without ClientConnect\n");
1294                 return;
1295         }
1296
1297         PlayerStats_GameReport_FinalizePlayer(self);
1298
1299         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1300
1301         CheatShutdownClient();
1302
1303         W_HitPlotClose(self);
1304
1305         anticheat_report();
1306         anticheat_shutdown();
1307
1308         playerdemo_shutdown();
1309
1310         bot_clientdisconnect();
1311
1312         if(self.entcs)
1313                 detach_entcs();
1314
1315         if(autocvar_sv_eventlog)
1316                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1317
1318         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1319
1320         MUTATOR_CALLHOOK(ClientDisconnect);
1321
1322         Portal_ClearAll(self);
1323
1324         Unfreeze(self);
1325
1326         RemoveGrapplingHook(self);
1327
1328         // Here, everything has been done that requires this player to be a client.
1329
1330         self.flags &= ~FL_CLIENT;
1331
1332         if (self.chatbubbleentity)
1333                 remove (self.chatbubbleentity);
1334
1335         if (self.killindicator)
1336                 remove (self.killindicator);
1337
1338         WaypointSprite_PlayerGone();
1339
1340         bot_relinkplayerlist();
1341
1342         accuracy_free(self);
1343         Inventory_delete(self);
1344         ClientData_Detach();
1345         PlayerScore_Detach(self);
1346
1347         if(self.netname_previous)
1348                 strunzone(self.netname_previous);
1349         if(self.clientstatus)
1350                 strunzone(self.clientstatus);
1351         if(self.weaponorder_byimpulse)
1352                 strunzone(self.weaponorder_byimpulse);
1353
1354         ClearPlayerSounds();
1355
1356         if(self.personal)
1357                 remove(self.personal);
1358
1359         self.playerid = 0;
1360         ReadyCount();
1361
1362         // free cvars
1363         GetCvars(-1);
1364 }
1365
1366 .float BUTTON_CHAT;
1367 void ChatBubbleThink()
1368 {
1369         self.nextthink = time;
1370         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1371         {
1372                 if(self.owner) // but why can that ever be world?
1373                         self.owner.chatbubbleentity = world;
1374                 remove(self);
1375                 return;
1376         }
1377         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1378 #ifdef TETRIS
1379                 || self.owner.tetris_on
1380 #endif
1381         )
1382                 self.model = self.mdl;
1383         else
1384                 self.model = "";
1385 }
1386
1387 void UpdateChatBubble()
1388 {
1389         if (self.alpha < 0)
1390                 return;
1391         // spawn a chatbubble entity if needed
1392         if (!self.chatbubbleentity)
1393         {
1394                 self.chatbubbleentity = spawn();
1395                 self.chatbubbleentity.owner = self;
1396                 self.chatbubbleentity.exteriormodeltoclient = self;
1397                 self.chatbubbleentity.think = ChatBubbleThink;
1398                 self.chatbubbleentity.nextthink = time;
1399                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1400                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1401                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1402                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1403                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1404                 self.chatbubbleentity.model = "";
1405                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1406         }
1407 }
1408
1409
1410 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1411 // added to the model skins
1412 /*void UpdateColorModHack()
1413 {
1414         float c;
1415         c = self.clientcolors & 15;
1416         // LordHavoc: only bothering to support white, green, red, yellow, blue
1417              if (!teamplay) self.colormod = '0 0 0';
1418         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1419         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1420         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1421         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1422         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1423         else self.colormod = '1 1 1';
1424 }*/
1425
1426 void respawn(void)
1427 {
1428         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1429         {
1430                 self.solid = SOLID_NOT;
1431                 self.takedamage = DAMAGE_NO;
1432                 self.movetype = MOVETYPE_FLY;
1433                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1434                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1435                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1436                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1437                 if(autocvar_g_respawn_ghosts_maxtime)
1438                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1439         }
1440
1441         CopyBody(1);
1442
1443         self.effects |= EF_NODRAW; // prevent another CopyBody
1444         PutClientInServer();
1445 }
1446
1447 void play_countdown(float finished, string samp)
1448 {
1449         if(IS_REAL_CLIENT(self))
1450                 if(floor(finished - time - frametime) != floor(finished - time))
1451                         if(finished - time < 6)
1452                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1453 }
1454
1455 void player_powerups (void)
1456 {
1457         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1458         olditems = self.items;
1459
1460         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1461                 self.modelflags |= MF_ROCKET;
1462         else
1463                 self.modelflags &= ~MF_ROCKET;
1464
1465         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1466
1467         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1468                 return;
1469
1470         Fire_ApplyDamage(self);
1471         Fire_ApplyEffect(self);
1472
1473         if (!g_instagib)
1474         {
1475                 if (self.items & IT_STRENGTH)
1476                 {
1477                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1478                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1479                         if (time > self.strength_finished)
1480                         {
1481                                 self.items = self.items - (self.items & IT_STRENGTH);
1482                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1483                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1484                         }
1485                 }
1486                 else
1487                 {
1488                         if (time < self.strength_finished)
1489                         {
1490                                 self.items = self.items | IT_STRENGTH;
1491                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1492                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1493                         }
1494                 }
1495                 if (self.items & IT_INVINCIBLE)
1496                 {
1497                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1498                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1499                         if (time > self.invincible_finished)
1500                         {
1501                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1502                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1503                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1504                         }
1505                 }
1506                 else
1507                 {
1508                         if (time < self.invincible_finished)
1509                         {
1510                                 self.items = self.items | IT_INVINCIBLE;
1511                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1512                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1513                         }
1514                 }
1515                 if (self.items & IT_SUPERWEAPON)
1516                 {
1517                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1518                         {
1519                                 self.superweapons_finished = 0;
1520                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1521                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1522                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1523                         }
1524                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1525                         {
1526                                 // don't let them run out
1527                         }
1528                         else
1529                         {
1530                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1531                                 if (time > self.superweapons_finished)
1532                                 {
1533                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1534                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1535                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1536                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1537                                 }
1538                         }
1539                 }
1540                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1541                 {
1542                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1543                         {
1544                                 self.items = self.items | IT_SUPERWEAPON;
1545                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1546                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1547                         }
1548                         else
1549                         {
1550                                 self.superweapons_finished = 0;
1551                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1552                         }
1553                 }
1554                 else
1555                 {
1556                         self.superweapons_finished = 0;
1557                 }
1558         }
1559
1560         if(autocvar_g_nodepthtestplayers)
1561                 self.effects = self.effects | EF_NODEPTHTEST;
1562
1563         if(autocvar_g_fullbrightplayers)
1564                 self.effects = self.effects | EF_FULLBRIGHT;
1565
1566         if (time >= game_starttime)
1567         if (time < self.spawnshieldtime)
1568                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1569
1570         MUTATOR_CALLHOOK(PlayerPowerups);
1571 }
1572
1573 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1574 {
1575         if(current > stable)
1576                 return current;
1577         else if(current > stable - 0.25) // when close enough, "snap"
1578                 return stable;
1579         else
1580                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1581 }
1582
1583 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1584 {
1585         if(current < stable)
1586                 return current;
1587         else if(current < stable + 0.25) // when close enough, "snap"
1588                 return stable;
1589         else
1590                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1591 }
1592
1593 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1594 {
1595         if(current > rotstable)
1596         {
1597                 if(rotframetime > 0)
1598                 {
1599                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1600                         current = max(rotstable, current - rotlinear * rotframetime);
1601                 }
1602         }
1603         else if(current < regenstable)
1604         {
1605                 if(regenframetime > 0)
1606                 {
1607                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1608                         current = min(regenstable, current + regenlinear * regenframetime);
1609                 }
1610         }
1611
1612         if(current > limit)
1613                 current = limit;
1614
1615         return current;
1616 }
1617
1618 void player_regen (void)
1619 {
1620         float max_mod, regen_mod, rot_mod, limit_mod;
1621         max_mod = regen_mod = rot_mod = limit_mod = 1;
1622         regen_mod_max = max_mod;
1623         regen_mod_regen = regen_mod;
1624         regen_mod_rot = rot_mod;
1625         regen_mod_limit = limit_mod;
1626         if(!MUTATOR_CALLHOOK(PlayerRegen))
1627         if(!self.frozen)
1628         {
1629                 float minh, mina, maxh, maxa, limith, limita;
1630                 maxh = autocvar_g_balance_health_rotstable;
1631                 maxa = autocvar_g_balance_armor_rotstable;
1632                 minh = autocvar_g_balance_health_regenstable;
1633                 mina = autocvar_g_balance_armor_regenstable;
1634                 limith = autocvar_g_balance_health_limit;
1635                 limita = autocvar_g_balance_armor_limit;
1636
1637                 max_mod = regen_mod_max;
1638                 regen_mod = regen_mod_regen;
1639                 rot_mod = regen_mod_rot;
1640                 limit_mod = regen_mod_limit;
1641
1642                 maxh = maxh * max_mod;
1643                 minh = minh * max_mod;
1644                 limith = limith * limit_mod;
1645                 limita = limita * limit_mod;
1646
1647                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1648                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1649         }
1650
1651         // if player rotted to death...  die!
1652         // check this outside above checks, as player may still be able to rot to death
1653         if(self.health < 1)
1654         {
1655                 if(self.vehicle)
1656                         vehicles_exit(VHEF_RELEASE);
1657                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1658         }
1659
1660         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1661         {
1662                 float minf, maxf, limitf;
1663
1664                 maxf = autocvar_g_balance_fuel_rotstable;
1665                 minf = autocvar_g_balance_fuel_regenstable;
1666                 limitf = autocvar_g_balance_fuel_limit;
1667
1668                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1669         }
1670 }
1671
1672 float zoomstate_set;
1673 void SetZoomState(float z)
1674 {
1675         if(z != self.zoomstate)
1676         {
1677                 self.zoomstate = z;
1678                 ClientData_Touch(self);
1679         }
1680         zoomstate_set = 1;
1681 }
1682
1683 void GetPressedKeys(void) {
1684         MUTATOR_CALLHOOK(GetPressedKeys);
1685         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1686         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1687         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1688         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1689         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1690
1691         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1692         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1693         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1694         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1695         #undef X
1696 }
1697
1698 /*
1699 ======================
1700 spectate mode routines
1701 ======================
1702 */
1703
1704 void SpectateCopy(entity spectatee) {
1705         other = spectatee;
1706         MUTATOR_CALLHOOK(SpectateCopy);
1707         self.armortype = spectatee.armortype;
1708         self.armorvalue = spectatee.armorvalue;
1709         self.ammo_cells = spectatee.ammo_cells;
1710         self.ammo_plasma = spectatee.ammo_plasma;
1711         self.ammo_shells = spectatee.ammo_shells;
1712         self.ammo_nails = spectatee.ammo_nails;
1713         self.ammo_rockets = spectatee.ammo_rockets;
1714         self.ammo_fuel = spectatee.ammo_fuel;
1715         self.clip_load = spectatee.clip_load;
1716         self.clip_size = spectatee.clip_size;
1717         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1718         self.health = spectatee.health;
1719         self.impulse = 0;
1720         self.items = spectatee.items;
1721         self.last_pickup = spectatee.last_pickup;
1722         self.hit_time = spectatee.hit_time;
1723         self.metertime = spectatee.metertime;
1724         self.strength_finished = spectatee.strength_finished;
1725         self.invincible_finished = spectatee.invincible_finished;
1726         self.pressedkeys = spectatee.pressedkeys;
1727         self.weapons = spectatee.weapons;
1728         self.switchweapon = spectatee.switchweapon;
1729         self.switchingweapon = spectatee.switchingweapon;
1730         self.weapon = spectatee.weapon;
1731         self.vortex_charge = spectatee.vortex_charge;
1732         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1733         self.hagar_load = spectatee.hagar_load;
1734         self.arc_heat_percent = spectatee.arc_heat_percent;
1735         self.minelayer_mines = spectatee.minelayer_mines;
1736         self.punchangle = spectatee.punchangle;
1737         self.view_ofs = spectatee.view_ofs;
1738         self.velocity = spectatee.velocity;
1739         self.dmg_take = spectatee.dmg_take;
1740         self.dmg_save = spectatee.dmg_save;
1741         self.dmg_inflictor = spectatee.dmg_inflictor;
1742         self.v_angle = spectatee.v_angle;
1743         self.angles = spectatee.v_angle;
1744         self.frozen = spectatee.frozen;
1745         self.revive_progress = spectatee.revive_progress;
1746         if(!self.BUTTON_USE)
1747                 self.fixangle = true;
1748         setorigin(self, spectatee.origin);
1749         setsize(self, spectatee.mins, spectatee.maxs);
1750         SetZoomState(spectatee.zoomstate);
1751
1752     anticheat_spectatecopy(spectatee);
1753         self.hud = spectatee.hud;
1754         if(spectatee.vehicle)
1755     {
1756         self.fixangle = false;
1757         //self.velocity = spectatee.vehicle.velocity;
1758         self.vehicle_health = spectatee.vehicle_health;
1759         self.vehicle_shield = spectatee.vehicle_shield;
1760         self.vehicle_energy = spectatee.vehicle_energy;
1761         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1762         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1763         self.vehicle_reload1 = spectatee.vehicle_reload1;
1764         self.vehicle_reload2 = spectatee.vehicle_reload2;
1765
1766         msg_entity = self;
1767
1768         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1770             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1771             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1772
1773         //WriteByte (MSG_ONE, SVC_SETVIEW);
1774         //    WriteEntity(MSG_ONE, self);
1775         //makevectors(spectatee.v_angle);
1776         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1777     }
1778 }
1779
1780 float SpectateUpdate()
1781 {
1782         if(!self.enemy)
1783             return 0;
1784
1785         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1786         {
1787                 SetSpectator(self, world);
1788                 return 0;
1789         }
1790
1791         SpectateCopy(self.enemy);
1792
1793         return 1;
1794 }
1795
1796 float SpectateSet()
1797 {
1798         if(self.enemy.classname != "player")
1799                 return false;
1800         /*if(self.enemy.vehicle)
1801         {
1802
1803                 msg_entity = self;
1804                 WriteByte(MSG_ONE, SVC_SETVIEW);
1805                 WriteEntity(MSG_ONE, self.enemy);
1806                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1807
1808                 self.movetype = MOVETYPE_NONE;
1809                 accuracy_resend(self);
1810         }
1811         else
1812         {*/
1813                 msg_entity = self;
1814                 WriteByte(MSG_ONE, SVC_SETVIEW);
1815                 WriteEntity(MSG_ONE, self.enemy);
1816                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1817                 self.movetype = MOVETYPE_NONE;
1818                 accuracy_resend(self);
1819
1820                 if(!SpectateUpdate())
1821                         PutObserverInServer();
1822         //}
1823         return true;
1824 }
1825
1826 void SetSpectator(entity player, entity spectatee)
1827 {
1828         entity old_spectatee = player.enemy;
1829
1830         player.enemy = spectatee;
1831
1832         // WEAPONTODO
1833         // these are required to fix the spectator bug with arc
1834         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1835         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1836 }
1837
1838 float Spectate(entity pl)
1839 {
1840         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1841         if(pl.team != self.team)
1842                 return 0;
1843
1844         SetSpectator(self, pl);
1845         return SpectateSet();
1846 }
1847
1848 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1849 entity CA_SpectateNext(entity start) {
1850         if (start.team == self.team) {
1851                 return start;
1852         }
1853
1854         other = start;
1855         // continue from current player
1856         while(other && other.team != self.team) {
1857                 other = find(other, classname, "player");
1858         }
1859
1860         if (!other) {
1861                 // restart from begining
1862                 other = find(other, classname, "player");
1863                 while(other && other.team != self.team) {
1864                         other = find(other, classname, "player");
1865                 }
1866         }
1867
1868         return other;
1869 }
1870
1871 float SpectateNext()
1872 {
1873         other = find(self.enemy, classname, "player");
1874
1875         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1876                 // CA and ca players when spectating enemies is forbidden
1877                 other = CA_SpectateNext(other);
1878         } else {
1879                 // other modes and ca spectators or spectating enemies is allowed
1880                 if (!other)
1881                         other = find(other, classname, "player");
1882         }
1883
1884         if(other) { SetSpectator(self, other); }
1885
1886         return SpectateSet();
1887 }
1888
1889 float SpectatePrev()
1890 {
1891         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1892         other = findchain(classname, "player");
1893         if (!other) // no player
1894                 return false;
1895
1896         entity first = other;
1897         // skip players until current spectated player
1898         if(self.enemy)
1899         while(other && other != self.enemy)
1900                 other = other.chain;
1901
1902         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1903         {
1904                 do { other = other.chain; }
1905                 while(other && other.team != self.team);
1906
1907                 if (!other)
1908                 {
1909                         other = first;
1910                         while(other.team != self.team)
1911                                 other = other.chain;
1912                         if(other == self.enemy)
1913                                 return true;
1914                 }
1915         }
1916         else
1917         {
1918                 if(other.chain)
1919                         other = other.chain;
1920                 else
1921                         other = first;
1922         }
1923         SetSpectator(self, other);
1924         return SpectateSet();
1925 }
1926
1927 /*
1928 =============
1929 ShowRespawnCountdown()
1930
1931 Update a respawn countdown display.
1932 =============
1933 */
1934 void ShowRespawnCountdown()
1935 {
1936         float number;
1937         if(self.deadflag == DEAD_NO) // just respawned?
1938                 return;
1939         else
1940         {
1941                 number = ceil(self.respawn_time - time);
1942                 if(number <= 0)
1943                         return;
1944                 if(number <= self.respawn_countdown)
1945                 {
1946                         self.respawn_countdown = number - 1;
1947                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1948                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1949                 }
1950         }
1951 }
1952
1953 void LeaveSpectatorMode()
1954 {
1955         if(self.caplayer)
1956                 return;
1957         if(nJoinAllowed(self))
1958         {
1959                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1960                 {
1961                         self.classname = "player";
1962                         nades_RemoveBonus(self);
1963
1964                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1965                                 { JoinBestTeam(self, false, true); }
1966
1967                         if(autocvar_g_campaign)
1968                                 { campaign_bots_may_start = 1; }
1969
1970                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1971
1972                         PutClientInServer();
1973
1974                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1975                 }
1976                 else
1977                         stuffcmd(self, "menu_showteamselect\n");
1978         }
1979         else
1980         {
1981                 // Player may not join because g_maxplayers is set
1982                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1983         }
1984 }
1985
1986 /**
1987  * Determines whether the player is allowed to join. This depends on cvar
1988  * g_maxplayers, if it isn't used this function always return true, otherwise
1989  * it checks whether the number of currently playing players exceeds g_maxplayers.
1990  * @return int number of free slots for players, 0 if none
1991  */
1992 float nJoinAllowed(entity ignore) {
1993         if(!ignore)
1994         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1995         // so report 0 free slots if restricted
1996         {
1997                 if(autocvar_g_forced_team_otherwise == "spectate")
1998                         return 0;
1999                 if(autocvar_g_forced_team_otherwise == "spectator")
2000                         return 0;
2001         }
2002
2003         if(self.team_forced < 0)
2004                 return 0; // forced spectators can never join
2005
2006         // TODO simplify this
2007         entity e;
2008         float totalClients = 0;
2009         FOR_EACH_CLIENT(e)
2010                 if(e != ignore)
2011                         totalClients += 1;
2012
2013         if (!autocvar_g_maxplayers)
2014                 return maxclients - totalClients;
2015
2016         float currentlyPlaying = 0;
2017         FOR_EACH_REALCLIENT(e)
2018                 if(IS_PLAYER(e) || e.caplayer)
2019                         currentlyPlaying += 1;
2020
2021         if(currentlyPlaying < autocvar_g_maxplayers)
2022                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2023
2024         return 0;
2025 }
2026
2027 /**
2028  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2029  * g_maxplayers_spectator_blocktime seconds
2030  */
2031 void checkSpectatorBlock() {
2032         if(IS_SPEC(self) || IS_OBSERVER(self))
2033         if(!self.caplayer)
2034         if(IS_REAL_CLIENT(self))
2035         {
2036                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2037                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2038                         dropclient(self);
2039                 }
2040         }
2041 }
2042
2043 void PrintWelcomeMessage()
2044 {
2045         if(self.motd_actived_time == 0)
2046         {
2047                 if (autocvar_g_campaign) {
2048                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2049                                 self.motd_actived_time = time;
2050                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2051                         }
2052                 } else {
2053                         if (self.BUTTON_INFO) {
2054                                 self.motd_actived_time = time;
2055                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2056                         }
2057                 }
2058         }
2059         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2060         {
2061                 if (autocvar_g_campaign) {
2062                         if (self.BUTTON_INFO)
2063                                 self.motd_actived_time = time;
2064                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2065                                 self.motd_actived_time = 0;
2066                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2067                         }
2068                 } else {
2069                         if (self.BUTTON_INFO)
2070                                 self.motd_actived_time = time;
2071                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2072                                 self.motd_actived_time = 0;
2073                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2074                         }
2075                 }
2076         }
2077         else //if(self.motd_actived_time < 0) // just connected, motd is active
2078         {
2079                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2080                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2081                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2082                 {
2083                         // instanctly hide MOTD
2084                         self.motd_actived_time = 0;
2085                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2086                 }
2087         }
2088 }
2089
2090 void ObserverThink()
2091 {
2092         float prefered_movetype;
2093         if (self.flags & FL_JUMPRELEASED) {
2094                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2095                         self.flags &= ~FL_JUMPRELEASED;
2096                         self.flags |= FL_SPAWNING;
2097                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2098                         self.flags &= ~FL_JUMPRELEASED;
2099                         if(SpectateNext()) {
2100                                 self.classname = "spectator";
2101                         }
2102                 } else {
2103                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2104                         if (self.movetype != prefered_movetype)
2105                                 self.movetype = prefered_movetype;
2106                 }
2107         } else {
2108                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2109                         self.flags |= FL_JUMPRELEASED;
2110                         if(self.flags & FL_SPAWNING)
2111                         {
2112                                 self.flags &= ~FL_SPAWNING;
2113                                 LeaveSpectatorMode();
2114                                 return;
2115                         }
2116                 }
2117         }
2118 }
2119
2120 void SpectatorThink()
2121 {
2122         if (self.flags & FL_JUMPRELEASED) {
2123                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2124                         self.flags &= ~FL_JUMPRELEASED;
2125                         self.flags |= FL_SPAWNING;
2126                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2127                         self.flags &= ~FL_JUMPRELEASED;
2128                         if(SpectateNext()) {
2129                                 self.classname = "spectator";
2130                         } else {
2131                                 self.classname = "observer";
2132                                 PutClientInServer();
2133                         }
2134                         self.impulse = 0;
2135                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2136                         self.flags &= ~FL_JUMPRELEASED;
2137                         if(SpectatePrev()) {
2138                                 self.classname = "spectator";
2139                         } else {
2140                                 self.classname = "observer";
2141                                 PutClientInServer();
2142                         }
2143                         self.impulse = 0;
2144                 } else if (self.BUTTON_ATCK2) {
2145                         self.flags &= ~FL_JUMPRELEASED;
2146                         self.classname = "observer";
2147                         PutClientInServer();
2148                 } else {
2149                         if(!SpectateUpdate())
2150                                 PutObserverInServer();
2151                 }
2152         } else {
2153                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2154                         self.flags |= FL_JUMPRELEASED;
2155                         if(self.flags & FL_SPAWNING)
2156                         {
2157                                 self.flags &= ~FL_SPAWNING;
2158                                 LeaveSpectatorMode();
2159                                 return;
2160                         }
2161                 }
2162                 if(!SpectateUpdate())
2163                         PutObserverInServer();
2164         }
2165
2166         self.flags |= FL_CLIENT | FL_NOTARGET;
2167 }
2168
2169 void vehicles_enter (entity pl, entity veh);
2170 void PlayerUseKey()
2171 {
2172         if (!IS_PLAYER(self))
2173                 return;
2174
2175         if(self.vehicle)
2176         {
2177                 if(!gameover)
2178                 {
2179                         vehicles_exit(VHEF_NORMAL);
2180                         return;
2181                 }
2182         }
2183         else if(autocvar_g_vehicles_enter)
2184         {
2185                 if(!self.frozen)
2186                 if(self.deadflag == DEAD_NO)
2187                 if(!gameover)
2188                 {
2189                         entity head, closest_target = world;
2190                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2191
2192                         while(head) // find the closest acceptable target to enter
2193                         {
2194                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2195                                 if(head.deadflag == DEAD_NO)
2196                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2197                                 if(head.takedamage != DAMAGE_NO)
2198                                 {
2199                                         if(closest_target)
2200                                         {
2201                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2202                                                 { closest_target = head; }
2203                                         }
2204                                         else { closest_target = head; }
2205                                 }
2206
2207                                 head = head.chain;
2208                         }
2209
2210                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2211                 }
2212         }
2213
2214         // a use key was pressed; call handlers
2215         MUTATOR_CALLHOOK(PlayerUseKey);
2216 }
2217
2218 float isInvisibleString(string s)
2219 {
2220         float i, n, c;
2221         s = strdecolorize(s);
2222         for((i = 0), (n = strlen(s)); i < n; ++i)
2223         {
2224                 c = str2chr(s, i);
2225                 switch(c)
2226                 {
2227                         case 0:
2228                         case 32: // space
2229                                 break;
2230                         case 192: // charmap space
2231                                 if (!autocvar_utf8_enable)
2232                                         break;
2233                                 return false;
2234                         case 160: // space in unicode fonts
2235                         case 0xE000 + 192: // utf8 charmap space
2236                                 if (autocvar_utf8_enable)
2237                                         break;
2238                         default:
2239                                 return false;
2240                 }
2241         }
2242         return true;
2243 }
2244
2245 /*
2246 =============
2247 PlayerPreThink
2248
2249 Called every frame for each client before the physics are run
2250 =============
2251 */
2252 .float usekeypressed;
2253 void() nexball_setstatus;
2254 .float last_vehiclecheck;
2255 .int items_added;
2256 void PlayerPreThink (void)
2257 {
2258         WarpZone_PlayerPhysics_FixVAngle();
2259
2260         self.stat_game_starttime = game_starttime;
2261         self.stat_round_starttime = round_starttime;
2262         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2263         self.stat_leadlimit = autocvar_leadlimit;
2264
2265         if(frametime)
2266         {
2267                 // physics frames: update anticheat stuff
2268                 anticheat_prethink();
2269         }
2270
2271         if(blockSpectators && frametime)
2272                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2273                 checkSpectatorBlock();
2274
2275         zoomstate_set = 0;
2276
2277         // Savage: Check for nameless players
2278         if (isInvisibleString(self.netname)) {
2279                 string new_name = strzone(strcat("Player@", self.netaddress));
2280                 if(autocvar_sv_eventlog)
2281                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2282                 if(self.netname_previous)
2283                         strunzone(self.netname_previous);
2284                 self.netname_previous = strzone(new_name);
2285                 self.netname = self.netname_previous;
2286                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2287         } else if(self.netname_previous != self.netname) {
2288                 if(autocvar_sv_eventlog)
2289                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2290                 if(self.netname_previous)
2291                         strunzone(self.netname_previous);
2292                 self.netname_previous = strzone(self.netname);
2293         }
2294
2295         // version nagging
2296         if(self.version_nagtime)
2297                 if(self.cvar_g_xonoticversion)
2298                         if(time > self.version_nagtime)
2299                         {
2300                                 // don't notify git users
2301                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2302                                 {
2303                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2304                                         {
2305                                                 // notify release users if connecting to git
2306                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2307                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2308                                         }
2309                                         else
2310                                         {
2311                                                 float r;
2312                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2313                                                 if(r < 0)
2314                                                 {
2315                                                         // give users new version
2316                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2317                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2318                                                 }
2319                                                 else if(r > 0)
2320                                                 {
2321                                                         // notify users about old server version
2322                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2323                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2324                                                 }
2325                                         }
2326                                 }
2327                                 self.version_nagtime = 0;
2328                         }
2329
2330         // GOD MODE info
2331         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2332         {
2333                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2334                 self.max_armorvalue = 0;
2335         }
2336
2337 #ifdef TETRIS
2338         if (TetrisPreFrame())
2339                 return;
2340 #endif
2341
2342         if(self.frozen == 2)
2343         {
2344                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2345                 self.health = max(1, self.revive_progress * start_health);
2346                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2347
2348                 if(self.revive_progress >= 1)
2349                         Unfreeze(self);
2350         }
2351         else if(self.frozen == 3)
2352         {
2353                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2354                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2355
2356                 if(self.health < 1)
2357                 {
2358                         if(self.vehicle)
2359                                 vehicles_exit(VHEF_RELEASE);
2360                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2361                 }
2362                 else if ( self.revive_progress <= 0 )
2363                         Unfreeze(self);
2364         }
2365
2366         MUTATOR_CALLHOOK(PlayerPreThink);
2367
2368         if(autocvar_g_vehicles_enter)
2369         if(time > self.last_vehiclecheck)
2370         if(IS_PLAYER(self))
2371         if(!gameover)
2372         if(!self.frozen)
2373         if(!self.vehicle)
2374         if(self.deadflag == DEAD_NO)
2375         {
2376                 entity veh;
2377                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2378                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2379                 if(veh.deadflag == DEAD_NO)
2380                 if(veh.takedamage != DAMAGE_NO)
2381                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2382                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2383                 else if(!veh.owner)
2384                 if(!veh.team || SAME_TEAM(self, veh))
2385                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2386                 else if(autocvar_g_vehicles_steal)
2387                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2388
2389                 self.last_vehiclecheck = time + 1;
2390         }
2391
2392         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2393         {
2394                 if(self.BUTTON_USE && !self.usekeypressed)
2395                         PlayerUseKey();
2396                 self.usekeypressed = self.BUTTON_USE;
2397         }
2398
2399         if(IS_REAL_CLIENT(self))
2400                 PrintWelcomeMessage();
2401
2402         if(IS_PLAYER(self))
2403         {
2404
2405                 CheckRules_Player();
2406
2407                 if (intermission_running)
2408                 {
2409                         IntermissionThink ();   // otherwise a button could be missed between
2410                         return;                                 // the think tics
2411                 }
2412
2413                 //don't allow the player to turn around while game is paused!
2414                 if(timeout_status == TIMEOUT_ACTIVE) {
2415                         // FIXME turn this into CSQC stuff
2416                         self.v_angle = self.lastV_angle;
2417                         self.angles = self.lastV_angle;
2418                         self.fixangle = true;
2419                 }
2420
2421                 if(frametime)
2422                 {
2423                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2424                         {
2425                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2426                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2427                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2428
2429                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2430                                 {
2431                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2432                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2433                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2434                                 }
2435                         }
2436                         else
2437                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2438
2439                         player_powerups();
2440                 }
2441
2442                 if (self.deadflag != DEAD_NO)
2443                 {
2444                         if(self.personal && g_race_qualifying)
2445                         {
2446                                 if(time > self.respawn_time)
2447                                 {
2448                                         self.respawn_time = time + 1; // only retry once a second
2449                                         self.stat_respawn_time = self.respawn_time;
2450                                         respawn();
2451                                         self.impulse = 141;
2452                                 }
2453                         }
2454                         else
2455                         {
2456                                 float button_pressed;
2457                                 if(frametime)
2458                                         player_anim();
2459                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2460
2461                                 if (self.deadflag == DEAD_DYING)
2462                                 {
2463                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2464                                                 self.deadflag = DEAD_RESPAWNING;
2465                                         else if(!button_pressed)
2466                                                 self.deadflag = DEAD_DEAD;
2467                                 }
2468                                 else if (self.deadflag == DEAD_DEAD)
2469                                 {
2470                                         if(button_pressed)
2471                                                 self.deadflag = DEAD_RESPAWNABLE;
2472                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2473                                                 self.deadflag = DEAD_RESPAWNING;
2474                                 }
2475                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2476                                 {
2477                                         if(!button_pressed)
2478                                                 self.deadflag = DEAD_RESPAWNING;
2479                                 }
2480                                 else if (self.deadflag == DEAD_RESPAWNING)
2481                                 {
2482                                         if(time > self.respawn_time)
2483                                         {
2484                                                 self.respawn_time = time + 1; // only retry once a second
2485                                                 self.respawn_time_max = self.respawn_time;
2486                                                 respawn();
2487                                         }
2488                                 }
2489
2490                                 ShowRespawnCountdown();
2491
2492                                 if(self.respawn_flags & RESPAWN_SILENT)
2493                                         self.stat_respawn_time = 0;
2494                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2495                                         self.stat_respawn_time = self.respawn_time_max;
2496                                 else
2497                                         self.stat_respawn_time = self.respawn_time;
2498                         }
2499
2500                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2501                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2502                                 self.stat_respawn_time *= -1;
2503
2504                         return;
2505                 }
2506
2507                 self.prevorigin = self.origin;
2508
2509                 float do_crouch = self.BUTTON_CROUCH;
2510                 if(self.hook.state)
2511                         do_crouch = 0;
2512                 if(self.vehicle)
2513                         do_crouch = 0;
2514                 if(self.frozen)
2515                         do_crouch = 0;
2516
2517                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2518                 // It cannot be predicted by the engine!
2519                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2520                         do_crouch = 0;
2521
2522                 if (do_crouch)
2523                 {
2524                         if (!self.crouch)
2525                         {
2526                                 self.crouch = true;
2527                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2528                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2529                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2530                         }
2531                 }
2532                 else
2533                 {
2534                         if (self.crouch)
2535                         {
2536                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2537                                 if (!trace_startsolid)
2538                                 {
2539                                         self.crouch = false;
2540                                         self.view_ofs = self.stat_pl_view_ofs;
2541                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2542                                 }
2543                         }
2544                 }
2545
2546                 FixPlayermodel();
2547
2548                 GrapplingHookFrame();
2549
2550                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2551                 //if(frametime)
2552                 {
2553                         self.items &= ~self.items_added;
2554
2555                         W_WeaponFrame();
2556
2557                         self.items_added = 0;
2558                         if(self.items & IT_JETPACK)
2559                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2560                                         self.items_added |= IT_FUEL;
2561
2562                         self.items |= self.items_added;
2563                 }
2564
2565                 player_regen();
2566
2567                 // WEAPONTODO: Add a weapon request for this
2568                 // rot vortex charge to the charge limit
2569                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2570                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2571
2572                 if(frametime)
2573                         player_anim();
2574
2575                 // secret status
2576                 secrets_setstatus();
2577
2578                 // monsters status
2579                 monsters_setstatus();
2580
2581                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2582
2583                 //self.angles_y=self.v_angle_y + 90;   // temp
2584         } else if(gameover) {
2585                 if (intermission_running)
2586                         IntermissionThink ();   // otherwise a button could be missed between
2587                 return;
2588         } else if(IS_OBSERVER(self)) {
2589                 ObserverThink();
2590         } else if(IS_SPEC(self)) {
2591                 SpectatorThink();
2592         }
2593
2594         // WEAPONTODO: Add weapon request for this
2595         if(!zoomstate_set)
2596                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2597
2598         float oldspectatee_status;
2599         oldspectatee_status = self.spectatee_status;
2600         if(IS_SPEC(self))
2601                 self.spectatee_status = num_for_edict(self.enemy);
2602         else if(IS_OBSERVER(self))
2603                 self.spectatee_status = num_for_edict(self);
2604         else
2605                 self.spectatee_status = 0;
2606         if(self.spectatee_status != oldspectatee_status)
2607         {
2608                 ClientData_Touch(self);
2609         }
2610
2611         if(self.teamkill_soundtime)
2612         if(time > self.teamkill_soundtime)
2613         {
2614                 self.teamkill_soundtime = 0;
2615
2616                 entity oldpusher, oldself;
2617
2618                 oldself = self; self = self.teamkill_soundsource;
2619                 oldpusher = self.pusher; self.pusher = oldself;
2620
2621                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2622
2623                 self.pusher = oldpusher;
2624                 self = oldself;
2625         }
2626
2627         if(self.taunt_soundtime)
2628         if(time > self.taunt_soundtime)
2629         {
2630                 self.taunt_soundtime = 0;
2631                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2632         }
2633
2634         target_voicescript_next(self);
2635
2636         // WEAPONTODO: Move into weaponsystem somehow
2637         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2638         if(!self.weapon)
2639                 self.clip_load = self.clip_size = 0;
2640 }
2641
2642 /*
2643 =============
2644 PlayerPostThink
2645
2646 Called every frame for each client after the physics are run
2647 =============
2648 */
2649 .float idlekick_lasttimeleft;
2650 void PlayerPostThink (void)
2651 {
2652         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2653         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2654         {
2655                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2656                 {
2657                         if(self.idlekick_lasttimeleft)
2658                         {
2659                                 self.idlekick_lasttimeleft = 0;
2660                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2661                         }
2662                 }
2663                 else
2664                 {
2665                         float timeleft;
2666                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2667                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2668                         {
2669                                 if(!self.idlekick_lasttimeleft)
2670                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2671                         }
2672                         if(timeleft <= 0)
2673                         {
2674                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2675                                 dropclient(self);
2676                                 return;
2677                         }
2678                         else if(timeleft <= 10)
2679                         {
2680                                 if(timeleft != self.idlekick_lasttimeleft)
2681                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2682                                 self.idlekick_lasttimeleft = timeleft;
2683                         }
2684                 }
2685         }
2686
2687 #ifdef TETRIS
2688         if(self.impulse == 100)
2689                 ImpulseCommands();
2690         if (!TetrisPostFrame())
2691         {
2692 #endif
2693
2694         CheatFrame();
2695
2696         //CheckPlayerJump();
2697
2698         if(IS_PLAYER(self)) {
2699                 CheckRules_Player();
2700                 UpdateChatBubble();
2701                 if (self.impulse)
2702                         ImpulseCommands();
2703                 if (intermission_running)
2704                         return;         // intermission or finale
2705                 GetPressedKeys();
2706         }
2707
2708 #ifdef TETRIS
2709         }
2710 #endif
2711
2712         /*
2713         float i;
2714         for(i = 0; i < 1000; ++i)
2715         {
2716                 vector end;
2717                 end = self.origin + '0 0 1024' + 512 * randomvec();
2718                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2719                 if(trace_fraction < 1)
2720                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2721                 {
2722                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2723                         break;
2724                 }
2725         }
2726         */
2727
2728         if(self.waypointsprite_attachedforcarrier)
2729                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2730
2731         playerdemo_write();
2732
2733         CSQCMODEL_AUTOUPDATE();
2734 }