fix cvar use of electro bounce params
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void send_CSQC_cr_maxbullets(entity e) {
10         msg_entity = e;
11         WriteByte(MSG_ONE, SVC_TEMPENTITY);
12         WriteByte(MSG_ONE, TE_CSQC_CR_MAXBULLETS);
13         WriteByte(MSG_ONE, cvar("g_balance_campingrifle_magazinecapacity"));
14 }
15
16 void Announce(string snd) {
17         WriteByte(MSG_ALL, SVC_TEMPENTITY);
18         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
19         WriteString(MSG_ALL, snd);
20 }
21
22 void AnnounceTo(entity e, string snd) {
23         if (clienttype(e) == CLIENTTYPE_REAL)
24         {
25                 msg_entity = e;
26                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
27                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
28                 WriteString(MSG_ONE, snd);
29         }
30 }
31
32 float ClientData_Send(entity to, float sf)
33 {
34         if(to != self.owner)
35         {
36                 error("wtf");
37                 return FALSE;
38         }
39
40         entity e;
41
42         e = to;
43         if(to.classname == "spectator")
44                 e = to.enemy;
45
46         sf = 0;
47
48         if(e.race_completed)
49                 sf |= 1; // forced scoreboard
50         if(to.spectatee_status)
51                 sf |= 2; // spectator ent number follows
52         if(e.zoomstate)
53                 sf |= 4; // zoomed
54         if(e.porto_v_angle_held)
55                 sf |= 8; // angles held
56
57         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
58         WriteByte(MSG_ENTITY, sf);
59
60         if(sf & 2)
61                 WriteByte(MSG_ENTITY, to.spectatee_status);
62
63         if(sf & 8)
64         {
65                 WriteAngle(MSG_ENTITY, e.v_angle_x);
66                 WriteAngle(MSG_ENTITY, e.v_angle_y);
67         }
68
69         return TRUE;
70 }
71
72 void ClientData_Attach()
73 {
74         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
75         self.clientdata.drawonlytoclient = self;
76         self.clientdata.owner = self;
77 }
78
79 void ClientData_Detach()
80 {
81         remove(self.clientdata);
82         self.clientdata = world;
83 }
84
85 void ClientData_Touch(entity e)
86 {
87         e.clientdata.SendFlags = 1;
88
89         // make it spectatable
90         entity e2;
91         FOR_EACH_REALCLIENT(e2)
92         {
93                 if(e2 != e)
94                         if(e2.classname == "spectator")
95                                 if(e2.enemy == e)
96                                         e2.clientdata.SendFlags = 1;
97         }
98 }
99
100
101 .vector spawnpoint_score;
102 .string netname_previous;
103
104 void spawnfunc_info_player_survivor (void)
105 {
106         spawnfunc_info_player_deathmatch();
107 }
108
109 void spawnfunc_info_player_start (void)
110 {
111         spawnfunc_info_player_deathmatch();
112 }
113
114 void spawnfunc_info_player_deathmatch (void)
115 {
116         self.classname = "info_player_deathmatch";
117         relocate_spawnpoint();
118 }
119
120 void spawnpoint_use()
121 {
122         if(teams_matter)
123         if(have_team_spawns > 0)
124         {
125                 self.team = activator.team;
126                 some_spawn_has_been_used = 1;
127         }
128 };
129
130 // Returns:
131 //   _x: prio (-1 if unusable)
132 //   _y: weight
133 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
134 {
135         float shortest, thisdist;
136         float prio;
137         entity player;
138
139         prio = 0;
140
141         // filter out spots for the wrong team
142         if(teamcheck)
143         if(spot.team != teamcheck)
144                 return '-1 0 0';
145
146         if(race_spawns)
147                 if(spot.target == "")
148                         return '-1 0 0';
149
150         if(clienttype(self) == CLIENTTYPE_REAL)
151         {
152                 if(spot.restriction == 1)
153                         return '-1 0 0';
154         }
155         else
156         {
157                 if(spot.restriction == 2)
158                         return '-1 0 0';
159         }
160
161         // filter out spots for assault
162         if(spot.target != "") {
163                 local entity ent;
164                 float good, found;
165                 ent = find(world, targetname, spot.target);
166
167                 while(ent) {
168                         if(ent.classname == "target_objective")
169                         {
170                                 found = 1;
171                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
172                                         return '-1 0 0';
173                                 good = 1;
174                         }
175                         else if(ent.classname == "trigger_race_checkpoint")
176                         {
177                                 found = 1;
178                                 if(!anypoint) // spectators may spawn everywhere
179
180                                 {
181                                         if(g_race_qualifying)
182                                         {
183                                                 // spawn at first
184                                                 if(ent.race_checkpoint != 0)
185                                                         return '-1 0 0';
186                                                 if(spot.race_place != race_lowest_place_spawn)
187                                                         return '-1 0 0';
188                                         }
189                                         else
190                                         {
191                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
192                                                         return '-1 0 0';
193                                                 // try reusing the previous spawn
194                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
195                                                         prio += 1;
196                                                 if(ent.race_checkpoint == 0)
197                                                 {
198                                                         float pl;
199                                                         pl = self.race_place;
200                                                         if(pl > race_highest_place_spawn)
201                                                                 pl = 0;
202                                                         if(pl == 0 && !self.race_started)
203                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
204                                                         if(spot.race_place != pl)
205                                                                 return '-1 0 0';
206                                                 }
207                                         }
208                                 }
209                                 good = 1;
210                         }
211                         ent = find(ent, targetname, spot.target);
212                 }
213
214                 if(found && !good)
215                         return '-1 0 0';
216         }
217
218         player = playerlist;
219         shortest = vlen(world.maxs - world.mins);
220         for(player = playerlist; player; player = player.chain)
221                 if (player != self)
222                 {
223                         thisdist = vlen(player.origin - spot.origin);
224                         if (thisdist < shortest)
225                                 shortest = thisdist;
226                 }
227         return prio * '1 0 0' + shortest * '0 1 0';
228 }
229
230 float spawn_allbad;
231 float spawn_allgood;
232 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
233 {
234         local entity spot, spotlist, spotlistend;
235         spawn_allgood = TRUE;
236         spawn_allbad = TRUE;
237
238         spotlist = world;
239         spotlistend = world;
240
241         for(spot = firstspot; spot; spot = spot.chain)
242         {
243                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
244
245                 if(cvar("spawn_debugview"))
246                 {
247                         setmodel(spot, "models/runematch/rune.mdl");
248                         if(spot.spawnpoint_score_y < mindist)
249                         {
250                                 spot.colormod = '1 0 0';
251                                 spot.scale = 1;
252                         }
253                         else
254                         {
255                                 spot.colormod = '0 1 0';
256                                 spot.scale = spot.spawnpoint_score_y / mindist;
257                         }
258                 }
259
260                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
261                 {
262                         if(spot.spawnpoint_score_y < mindist)
263                         {
264                                 // too short distance
265                                 spawn_allgood = FALSE;
266                         }
267                         else
268                         {
269                                 // perfect
270                                 spawn_allbad = FALSE;
271
272                                 if(spotlistend)
273                                         spotlistend.chain = spot;
274                                 spotlistend = spot;
275                                 if(!spotlist)
276                                         spotlist = spot;
277
278                                 /*
279                                 if(teamcheck)
280                                 if(spot.team != teamcheck)
281                                         error("invalid spawn added");
282
283                                 print("added ", etos(spot), "\n");
284                                 */
285                         }
286                 }
287         }
288         if(spotlistend)
289                 spotlistend.chain = world;
290
291         /*
292                 entity e;
293                 if(teamcheck)
294                         for(e = spotlist; e; e = e.chain)
295                         {
296                                 print("seen ", etos(e), "\n");
297                                 if(e.team != teamcheck)
298                                         error("invalid spawn found");
299                         }
300         */
301
302         return spotlist;
303 }
304
305 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
306 {
307         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
308         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
309         local entity spot;
310
311         RandomSelection_Init();
312         for(spot = firstspot; spot; spot = spot.chain)
313                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
314
315         return RandomSelection_chosen_ent;
316 }
317
318 /*
319 =============
320 SelectSpawnPoint
321
322 Finds a point to respawn
323 =============
324 */
325 entity SelectSpawnPoint (float anypoint)
326 {
327         local float teamcheck;
328         local entity firstspot_new;
329         local entity spot, firstspot, playerlist;
330
331         spot = find (world, classname, "testplayerstart");
332         if (spot)
333                 return spot;
334
335         teamcheck = 0;
336
337         if(!anypoint && have_team_spawns > 0)
338                 teamcheck = self.team;
339
340         // get the list of players
341         playerlist = findchain(classname, "player");
342         // get the entire list of spots
343         firstspot = findchain(classname, "info_player_deathmatch");
344         // filter out the bad ones
345         // (note this returns the original list if none survived)
346         if(anypoint)
347         {
348                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
349         }
350         else
351         {
352                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
353                 if(!firstspot_new)
354                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
355                 firstspot = firstspot_new;
356
357                 // there is 50/50 chance of choosing a random spot or the furthest spot
358                 // (this means that roughly every other spawn will be furthest, so you
359                 // usually won't get fragged at spawn twice in a row)
360                 if (arena_roundbased && !g_ca)
361                 {
362                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
363                         if(firstspot_new)
364                                 firstspot = firstspot_new;
365                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
366                 }
367                 else if (random() > cvar("g_spawn_furthest"))
368                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
369                 else
370                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
371         }
372
373         if(cvar("spawn_debugview"))
374         {
375                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
376
377                 entity e;
378                 if(teamcheck)
379                         for(e = firstspot; e; e = e.chain)
380                                 if(e.team != teamcheck)
381                                         error("invalid spawn found");
382         }
383
384         if (!spot)
385         {
386                 if(cvar("spawn_debug"))
387                         GotoNextMap();
388                 else
389                 {
390                         if(some_spawn_has_been_used)
391                                 return world; // team can't spawn any more, because of actions of other team
392                         else
393                                 error("Cannot find a spawn point - please fix the map!");
394                 }
395         }
396
397         return spot;
398 }
399
400 /*
401 =============
402 CheckPlayerModel
403
404 Checks if the argument string can be a valid playermodel.
405 Returns a valid one in doubt.
406 =============
407 */
408 string FallbackPlayerModel;
409 string CheckPlayerModel(string plyermodel) {
410         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
411         {
412                 // note: we cannot summon Don Strunzone here, some player may
413                 // still have the model string set. In case anyone manages how
414                 // to change a cvar default, we'll have a small leak here.
415                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
416         }
417         if(strlen(plyermodel) < 4)
418                 return FallbackPlayerModel;
419         if( substring(plyermodel,0,14) != "models/player/")
420                 return FallbackPlayerModel;
421         else if(cvar("sv_servermodelsonly"))
422         {
423                 if(substring(plyermodel,-4,4) != ".zym")
424                 if(substring(plyermodel,-4,4) != ".dpm")
425                 if(substring(plyermodel,-4,4) != ".iqm")
426                 if(substring(plyermodel,-4,4) != ".md3")
427                 if(substring(plyermodel,-4,4) != ".psk")
428                         return FallbackPlayerModel;
429                 // forbid the LOD models
430                 if(substring(plyermodel, -9,5) == "_lod1")
431                         return FallbackPlayerModel;
432                 if(substring(plyermodel, -9,5) == "_lod2")
433                         return FallbackPlayerModel;
434                 if(plyermodel != strtolower(plyermodel))
435                         return FallbackPlayerModel;
436                 if(!fexists(plyermodel))
437                         return FallbackPlayerModel;
438         }
439         return plyermodel;
440 }
441
442 /*
443 =============
444 Client_customizeentityforclient
445
446 LOD reduction
447 =============
448 */
449 void Client_uncustomizeentityforclient()
450 {
451         if(self.modelindex == 0) // no need to uncustomize then
452                 return;
453         self.modelindex = self.modelindex_lod0;
454         self.skin = self.skinindex;
455 }
456
457 float Client_customizeentityforclient()
458 {
459         entity modelsource;
460
461         if(self.modelindex == 0)
462                 return TRUE;
463
464         // forcemodel stuff
465
466 #ifdef PROFILING
467         float t0;
468         t0 = gettime(GETTIME_HIRES); // reference
469 #endif
470
471         modelsource = self;
472
473 #ifdef ALLOW_FORCEMODELS
474         if(other.cvar_cl_forceplayermodelsfromxonotic)
475                 if not(self.modelindex_lod0_from_xonotic)
476                         modelsource = other;
477         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
478                 modelsource = other;
479 #endif
480
481         self.skin = modelsource.skinindex;
482
483 #if 0
484         if(modelsource == self)
485                 self.skin = modelsource.skinindex;
486         else
487                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
488 #endif
489
490         // self: me
491         // other: the player viewing me
492         float distance;
493         float f;
494
495         if(other.cvar_cl_playerdetailreduction <= 0)
496         {
497                 if(other.cvar_cl_playerdetailreduction <= -2)
498                         self.modelindex = modelsource.modelindex_lod2;
499                 else if(other.cvar_cl_playerdetailreduction <= -1)
500                         self.modelindex = modelsource.modelindex_lod1;
501                 else
502                         self.modelindex = modelsource.modelindex_lod0;
503         }
504         else
505         {
506                 distance = vlen(self.origin - other.origin);
507                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
508                 if(f > sv_loddistance2)
509                         self.modelindex = modelsource.modelindex_lod2;
510                 else if(f > sv_loddistance1)
511                         self.modelindex = modelsource.modelindex_lod1;
512                 else
513                         self.modelindex = modelsource.modelindex_lod0;
514         }
515
516 #ifdef PROFILING
517         float t1;
518         t1 = gettime(GETTIME_HIRES); // reference
519         client_cefc_accumulator += (t1 - t0);
520 #endif
521
522         return TRUE;
523 }
524
525 void setmodel_lod(entity e, string modelname)
526 {
527         string s;
528
529         if(sv_loddistance1)
530         {
531                 // FIXME: this only supports 3-letter extensions
532                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
533                 if(fexists(s))
534                 {
535                         setmodel(e, s); // players have high precision
536                         self.modelindex_lod1 = self.modelindex;
537                 }
538                 else
539                         self.modelindex_lod1 = -1;
540
541                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
542                 if(fexists(s))
543                 {
544                         setmodel(e, s); // players have high precision
545                         self.modelindex_lod2 = self.modelindex;
546                 }
547                 else
548                         self.modelindex_lod2 = -1;
549
550                 precache_model(modelname);
551                 setmodel(e, modelname); // players have high precision
552                 self.modelindex_lod0 = self.modelindex;
553
554                 if(self.modelindex_lod1 < 0)
555                         self.modelindex_lod1 = self.modelindex;
556
557                 if(self.modelindex_lod2 < 0)
558                         self.modelindex_lod2 = self.modelindex;
559         }
560         else
561         {
562                 precache_model(modelname);
563                 setmodel(e, modelname); // players have high precision
564                 self.modelindex_lod0 = self.modelindex;
565                         // save it for possible player model forcing
566         }
567
568         s = whichpack(self.model);
569         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
570
571         player_setupanimsformodel();
572         UpdatePlayerSounds();
573 }
574
575 /*
576 =============
577 PutObserverInServer
578
579 putting a client as observer in the server
580 =============
581 */
582 void FixPlayermodel();
583 void PutObserverInServer (void)
584 {
585         entity  spot;
586
587         race_PreSpawnObserver();
588
589         spot = SelectSpawnPoint (TRUE);
590         if(!spot)
591                 error("No spawnpoints for observers?!?\n");
592         RemoveGrapplingHook(self); // Wazat's Grappling Hook
593
594         if(clienttype(self) == CLIENTTYPE_REAL)
595         {
596                 msg_entity = self;
597                 WriteByte(MSG_ONE, SVC_SETVIEW);
598                 WriteEntity(MSG_ONE, self);
599         }
600
601         DropAllRunes(self);
602
603         Portal_ClearAll(self);
604
605         if(self.flagcarried)
606                 DropFlag(self.flagcarried, world, world);
607
608         if(self.ballcarried)
609                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
610
611         WaypointSprite_PlayerDead();
612
613         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
614                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
615
616         if(self.killcount != -666) {
617                 if(g_lms) {
618                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
619                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
620                         else
621                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
622                 } else
623                         bprint ("^4", self.netname, "^4 is spectating now\n");
624
625                 if(self.just_joined == FALSE) {
626                         LogTeamchange(self.playerid, -1, 4);
627                 } else
628                         self.just_joined = FALSE;
629         }
630
631         PlayerScore_Clear(self); // clear scores when needed
632
633         self.spectatortime = time;
634
635         self.classname = "observer";
636         self.iscreature = FALSE;
637         self.health = -666;
638         self.takedamage = DAMAGE_NO;
639         self.solid = SOLID_NOT;
640         self.movetype = MOVETYPE_NOCLIP;
641         self.flags = FL_CLIENT | FL_NOTARGET;
642         self.armorvalue = 666;
643         self.effects = 0;
644         self.armorvalue = cvar("g_balance_armor_start");
645         self.pauserotarmor_finished = 0;
646         self.pauserothealth_finished = 0;
647         self.pauseregen_finished = 0;
648         self.damageforcescale = 0;
649         self.death_time = 0;
650         self.dead_frame = 0;
651         self.alpha = 0;
652         self.scale = 0;
653         self.fade_time = 0;
654         self.pain_frame = 0;
655         self.pain_finished = 0;
656         self.strength_finished = 0;
657         self.invincible_finished = 0;
658         self.pushltime = 0;
659         self.think = SUB_Null;
660         self.nextthink = 0;
661         self.hook_time = 0;
662         self.runes = 0;
663         self.deadflag = DEAD_NO;
664         self.angles = spot.angles;
665         self.angles_z = 0;
666         self.fixangle = TRUE;
667         self.crouch = FALSE;
668
669         self.view_ofs = PL_VIEW_OFS;
670         setorigin (self, spot.origin);
671         setsize (self, '0 0 0', '0 0 0');
672         self.prevorigin = self.origin;
673         self.items = 0;
674         self.weapons = 0;
675         self.model = "";
676         FixPlayermodel();
677         self.model = "";
678         self.modelindex = 0;
679         self.weapon = 0;
680         self.weaponmodel = "";
681         self.weaponentity = world;
682         self.exteriorweaponentity = world;
683         self.killcount = -666;
684         self.velocity = '0 0 0';
685         self.avelocity = '0 0 0';
686         self.punchangle = '0 0 0';
687         self.punchvector = '0 0 0';
688         self.oldvelocity = self.velocity;
689         self.fire_endtime = -1;
690
691         if(sv_loddistance1)
692                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
693
694         if(g_arena)
695         {
696                 if(self.version_mismatch)
697                 {
698                         Spawnqueue_Unmark(self);
699                         Spawnqueue_Remove(self);
700                 }
701                 else
702                 {
703                         Spawnqueue_Insert(self);
704                 }
705         }
706         else if(g_lms)
707         {
708                 // Only if the player cannot play at all
709                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
710                         self.frags = FRAGS_SPECTATOR;
711                 else
712                         self.frags = FRAGS_LMS_LOSER;
713         }
714         else
715                 self.frags = FRAGS_SPECTATOR;
716
717         MUTATOR_CALLHOOK(MakePlayerObserver);
718 }
719
720 float RestrictSkin(float s)
721 {
722         if(!teams_matter)
723                 return s;
724         if(s == 6)
725                 return 6;
726         return mod(s, 3);
727 }
728
729 void FixPlayermodel()
730 {
731         local string defaultmodel;
732         local float defaultskin, chmdl, oldskin;
733         local vector m1, m2;
734
735         defaultmodel = "";
736
737         if(cvar("sv_defaultcharacter") == 1) {
738                 defaultskin = 0;
739
740                 if(teams_matter)
741                 {
742                         string s;
743                         s = Team_ColorNameLowerCase(self.team);
744                         if(s != "neutral")
745                         {
746                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
747                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
748                         }
749                 }
750
751                 if(defaultmodel == "")
752                 {
753                         defaultmodel = cvar_string("sv_defaultplayermodel");
754                         defaultskin = cvar("sv_defaultplayerskin");
755                 }
756         }
757
758         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
759         {
760                 if(self.model != "")
761                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
762                 self.model = ""; // force the != checks to return true
763         }
764
765         if(defaultmodel != "")
766         {
767                 if (defaultmodel != self.model)
768                 {
769                         m1 = self.mins;
770                         m2 = self.maxs;
771                         setmodel_lod (self, defaultmodel);
772                         setsize (self, m1, m2);
773                         chmdl = TRUE;
774                 }
775
776                 oldskin = self.skinindex;
777                 self.skinindex = defaultskin;
778         } else {
779                 if (self.playermodel != self.model || self.playermodel == "")
780                 {
781                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
782                         m1 = self.mins;
783                         m2 = self.maxs;
784                         setmodel_lod (self, self.playermodel);
785                         setsize (self, m1, m2);
786                         chmdl = TRUE;
787                 }
788
789                 oldskin = self.skinindex;
790                 self.skinindex = RestrictSkin(stof(self.playerskin));
791         }
792
793         if(chmdl || oldskin != self.skinindex)
794                 self.species = player_getspecies(); // model or skin has changed
795
796         if(!teams_matter)
797                 if(strlen(cvar_string("sv_defaultplayercolors")))
798                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
799                                 setcolor(self, cvar("sv_defaultplayercolors"));
800 }
801
802 void PlayerTouchExplode(entity p1, entity p2)
803 {
804         vector org;
805         org = (p1.origin + p2.origin) * 0.5;
806         org_z += (p1.mins_z + p2.mins_z) * 0.5;
807
808         te_explosion(org);
809
810         entity e;
811         e = spawn();
812         setorigin(e, org);
813         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
814         remove(e);
815 }
816
817 /*
818 =============
819 PutClientInServer
820
821 Called when a client spawns in the server
822 =============
823 */
824 //void() ctf_playerchanged;
825 void PutClientInServer (void)
826 {
827         if(clienttype(self) == CLIENTTYPE_BOT)
828         {
829                 self.classname = "player";
830         }
831         else if(clienttype(self) == CLIENTTYPE_REAL)
832         {
833                 msg_entity = self;
834                 WriteByte(MSG_ONE, SVC_SETVIEW);
835                 WriteEntity(MSG_ONE, self);
836         }
837
838         // player is dead and becomes observer
839         // FIXME fix LMS scoring for new system
840         if(g_lms)
841         {
842                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
843                         self.classname = "observer";
844         }
845
846         if(g_arena || (g_ca && !allowed_to_spawn))
847         if(!self.spawned)
848                 self.classname = "observer";
849
850         if(gameover)
851                 self.classname = "observer";
852
853         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
854                 entity spot, oldself;
855                 float j;
856
857                 if(self.team < 0)
858                         JoinBestTeam(self, FALSE, TRUE);
859
860                 race_PreSpawn();
861
862                 spot = SelectSpawnPoint (FALSE);
863                 if(!spot)
864                 {
865                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
866                         return; // spawn failed
867                 }
868
869                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
870
871                 self.classname = "player";
872                 self.wasplayer = TRUE;
873                 self.iscreature = TRUE;
874                 self.movetype = MOVETYPE_WALK;
875                 self.solid = SOLID_SLIDEBOX;
876                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
877                 if(cvar("g_playerclip_collisions"))
878                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
879                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
880                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
881                 self.frags = FRAGS_PLAYER;
882                 if(independent_players)
883                         MAKE_INDEPENDENT_PLAYER(self);
884                 self.flags = FL_CLIENT;
885                 self.takedamage = DAMAGE_AIM;
886                 if(g_minstagib)
887                         self.effects = EF_FULLBRIGHT;
888                 else
889                         self.effects = 0;
890                 self.air_finished = time + 12;
891                 self.dmg = 2;
892                 if(cvar("g_balance_nex_charge"))
893                         self.nex_charge = cvar("g_balance_nex_charge_start");
894
895                 if(inWarmupStage)
896                 {
897                         self.ammo_shells = warmup_start_ammo_shells;
898                         self.ammo_nails = warmup_start_ammo_nails;
899                         self.ammo_rockets = warmup_start_ammo_rockets;
900                         self.ammo_cells = warmup_start_ammo_cells;
901                         self.ammo_fuel = warmup_start_ammo_fuel;
902                         self.health = warmup_start_health;
903                         self.armorvalue = warmup_start_armorvalue;
904                         self.weapons = warmup_start_weapons;
905                 }
906                 else
907                 {
908                         self.ammo_shells = start_ammo_shells;
909                         self.ammo_nails = start_ammo_nails;
910                         self.ammo_rockets = start_ammo_rockets;
911                         self.ammo_cells = start_ammo_cells;
912                         self.ammo_fuel = start_ammo_fuel;
913                         self.health = start_health;
914                         self.armorvalue = start_armorvalue;
915                         self.weapons = start_weapons;
916                 }
917
918                 if(g_weaponarena_random)
919                 {
920                         if(g_weaponarena_random_with_laser)
921                                 self.weapons &~= WEPBIT_LASER;
922                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
923                         if(g_weaponarena_random_with_laser)
924                                 self.weapons |= WEPBIT_LASER;
925                 }
926
927                 self.items = start_items;
928                 self.jump_interval = time;
929
930                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
931                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
932                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
933                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
934                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
935                 //extend the pause of rotting if client was reset at the beginning of the countdown
936                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
937                         self.spawnshieldtime += game_starttime - time;
938                         self.pauserotarmor_finished += game_starttime - time;
939                         self.pauserothealth_finished += game_starttime - time;
940                         self.pauseregen_finished += game_starttime - time;
941                 }
942                 self.damageforcescale = 2;
943                 self.death_time = 0;
944                 self.dead_frame = 0;
945                 self.alpha = 0;
946                 self.scale = 0;
947                 self.fade_time = 0;
948                 self.pain_frame = 0;
949                 self.pain_finished = 0;
950                 self.strength_finished = 0;
951                 self.invincible_finished = 0;
952                 self.pushltime = 0;
953                 // players have no think function
954                 self.think = SUB_Null;
955                 self.nextthink = 0;
956                 self.hook_time = 0;
957                 self.dmg_team = 0;
958                 self.ballistics_density = cvar("g_ballistics_density_player");
959
960                 self.metertime = 0;
961
962                 self.runes = 0;
963
964                 self.deadflag = DEAD_NO;
965
966                 self.angles = spot.angles;
967
968                 self.angles_z = 0; // never spawn tilted even if the spot says to
969                 self.fixangle = TRUE; // turn this way immediately
970                 self.velocity = '0 0 0';
971                 self.avelocity = '0 0 0';
972                 self.punchangle = '0 0 0';
973                 self.punchvector = '0 0 0';
974                 self.oldvelocity = self.velocity;
975                 self.fire_endtime = -1;
976
977                 msg_entity = self;
978                 WRITESPECTATABLE_MSG_ONE({
979                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
980                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
981                 });
982
983                 if(sv_loddistance1)
984                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
985
986                 self.model = "";
987                 FixPlayermodel();
988
989                 self.crouch = FALSE;
990                 self.view_ofs = PL_VIEW_OFS;
991                 setsize (self, PL_MIN, PL_MAX);
992                 self.spawnorigin = spot.origin;
993                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
994                 // don't reset back to last position, even if new position is stuck in solid
995                 self.oldorigin = self.origin;
996                 self.prevorigin = self.origin;
997                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
998
999                 if(g_arena)
1000                 {
1001                         Spawnqueue_Remove(self);
1002                         Spawnqueue_Mark(self);
1003                 }
1004
1005                 else if(g_ca)
1006                         self.caplayer = 1;
1007
1008                 self.event_damage = PlayerDamage;
1009
1010                 self.bot_attack = TRUE;
1011
1012                 self.statdraintime = time + 5;
1013                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1014
1015                 if(self.killcount == -666) {
1016                         PlayerScore_Clear(self);
1017                         self.killcount = 0;
1018                 }
1019
1020                 self.cnt = WEP_LASER;
1021
1022                 CL_SpawnWeaponentity();
1023                 self.alpha = default_player_alpha;
1024                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1025                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1026
1027                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1028                 self.lms_traveled_distance = 0;
1029                 self.speedrunning = FALSE;
1030
1031                 race_PostSpawn(spot);
1032
1033                 if(cvar("spawn_debug"))
1034                 {
1035                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1036                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1037                 }
1038
1039                 //stuffcmd(self, "chase_active 0");
1040                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1041
1042                 if (cvar("g_spawnsound"))
1043                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1044
1045                 if(g_assault) {
1046                         if(self.team == assault_attacker_team)
1047                                 centerprint(self, "You are attacking!");
1048                         else
1049                                 centerprint(self, "You are defending!");
1050                 }
1051
1052                 target_voicescript_clear(self);
1053
1054                 // reset fields the weapons may use
1055                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1056                         weapon_action(j, WR_RESETPLAYER);
1057
1058                 oldself = self;
1059                 self = spot;
1060                         activator = oldself;
1061                                 SUB_UseTargets();
1062                         activator = world;
1063                 self = oldself;
1064
1065                 MUTATOR_CALLHOOK(PlayerSpawn);
1066
1067                 self.switchweapon = w_getbestweapon(self);
1068                 self.cnt = self.switchweapon;
1069                 self.weapon = 0;
1070         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1071                 PutObserverInServer ();
1072         }
1073
1074         //if(g_ctf)
1075         //      ctf_playerchanged();
1076 }
1077
1078 .float ebouncefactor, ebouncestop; // electro's values
1079 // TODO do we need all these fields, or should we stop autodetecting runtime
1080 // changes and just have a console command to update this?
1081 float ClientInit_SendEntity(entity to, float sf)
1082 {
1083         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1084         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1085         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1086         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1087         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1088         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1089         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1090         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1091         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1092         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1093         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1094         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1095         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1096         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1097         if(sv_foginterval && world.fog != "")
1098                 WriteString(MSG_ENTITY, world.fog);
1099         else
1100                 WriteString(MSG_ENTITY, "");
1101         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1102         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1103         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1104         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1105         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1106         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1107         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1108         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1109         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1110         return TRUE;
1111 }
1112
1113 void ClientInit_CheckUpdate()
1114 {
1115         self.nextthink = time;
1116         if(self.count != cvar("g_balance_armor_blockpercent"))
1117         {
1118                 self.count = cvar("g_balance_armor_blockpercent");
1119                 self.SendFlags |= 1;
1120         }
1121         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1122         {
1123                 self.cnt = cvar("g_balance_weaponswitchdelay");
1124                 self.SendFlags |= 1;
1125         }
1126         if(self.bouncefactor != cvar("g_balance_grenadelauncher_bouncefactor"))
1127         {
1128                 self.bouncefactor = cvar("g_balance_grenadelauncher_bouncefactor");
1129                 self.SendFlags |= 1;
1130         }
1131         if(self.bouncestop != cvar("g_balance_grenadelauncher_bouncestop"))
1132         {
1133                 self.bouncestop = cvar("g_balance_grenadelauncher_bouncestop");
1134                 self.SendFlags |= 1;
1135         }
1136         if(self.ebouncefactor != cvar("g_balance_electro_secondary_bouncefactor"))
1137         {
1138                 self.ebouncefactor = cvar("g_balance_electro_secondary_bouncefactor");
1139                 self.SendFlags |= 1;
1140         }
1141         if(self.ebouncestop != cvar("g_balance_electro_secondary_bouncestop"))
1142         {
1143                 self.ebouncestop = cvar("g_balance_electro_secondary_bouncestop");
1144                 self.SendFlags |= 1;
1145         }
1146 }
1147
1148 void ClientInit_Spawn()
1149 {
1150         entity o;
1151         entity e;
1152         e = spawn();
1153         e.classname = "clientinit";
1154         e.think = ClientInit_CheckUpdate;
1155         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1156
1157         o = self;
1158         self = e;
1159         ClientInit_CheckUpdate();
1160         self = o;
1161 }
1162
1163 /*
1164 =============
1165 SetNewParms
1166 =============
1167 */
1168 void SetNewParms (void)
1169 {
1170         // initialize parms for a new player
1171         parm1 = -(86400 * 366);
1172 }
1173
1174 /*
1175 =============
1176 SetChangeParms
1177 =============
1178 */
1179 void SetChangeParms (void)
1180 {
1181         // save parms for level change
1182         parm1 = self.parm_idlesince - time;
1183 }
1184
1185 /*
1186 =============
1187 DecodeLevelParms
1188 =============
1189 */
1190 void DecodeLevelParms (void)
1191 {
1192         // load parms
1193         self.parm_idlesince = parm1;
1194         if(self.parm_idlesince == -(86400 * 366))
1195                 self.parm_idlesince = time;
1196
1197         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1198         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1199 }
1200
1201 /*
1202 =============
1203 ClientKill
1204
1205 Called when a client types 'kill' in the console
1206 =============
1207 */
1208
1209 void ClientKill_Now_TeamChange()
1210 {
1211         if(self.killindicator_teamchange == -1)
1212         {
1213                 self.team = -1;
1214                 JoinBestTeam( self, FALSE, FALSE );
1215         }
1216         else
1217                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1218 }
1219
1220 void ClientKill_Now()
1221 {
1222         if(self.killindicator_teamchange)
1223                 ClientKill_Now_TeamChange();
1224
1225         // in any case:
1226         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1227
1228         if(self.killindicator)
1229         {
1230                 dprint("Cleaned up after a leaked kill indicator.\n");
1231                 remove(self.killindicator);
1232                 self.killindicator = world;
1233         }
1234 }
1235 void KillIndicator_Think()
1236 {
1237         if (!self.owner.modelindex)
1238         {
1239                 self.owner.killindicator = world;
1240                 remove(self);
1241                 return;
1242         }
1243
1244         if(self.cnt <= 0)
1245         {
1246                 self = self.owner;
1247                 ClientKill_Now(); // no oldself needed
1248                 return;
1249         }
1250         else
1251         {
1252                 if(self.cnt <= 10)
1253                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1254                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1255                 {
1256                         if(self.cnt <= 10)
1257                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1258                         if(self.owner.killindicator_teamchange)
1259                         {
1260                                 if(self.owner.killindicator_teamchange == -1)
1261                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1262                                 else
1263                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1264                         }
1265                         else
1266                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1267                 }
1268                 self.nextthink = time + 1;
1269                 self.cnt -= 1;
1270         }
1271 }
1272
1273 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1274 {
1275         float killtime;
1276         entity e;
1277         killtime = cvar("g_balance_kill_delay");
1278
1279         if(g_race_qualifying)
1280                 killtime = 0;
1281
1282         self.killindicator_teamchange = targetteam;
1283
1284         if(!self.killindicator)
1285         {
1286                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1287                 {
1288                         ClientKill_Now();
1289                 }
1290                 else
1291                 {
1292                         self.killindicator = spawn();
1293                         self.killindicator.owner = self;
1294                         self.killindicator.scale = 0.5;
1295                         setattachment(self.killindicator, self, "");
1296                         setorigin(self.killindicator, '0 0 52');
1297                         self.killindicator.think = KillIndicator_Think;
1298                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1299                         self.killindicator.cnt = ceil(killtime);
1300                         self.killindicator.count = bound(0, ceil(killtime), 10);
1301                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1302
1303                         for(e = world; (e = find(e, classname, "body")) != world; )
1304                         {
1305                                 if(e.enemy != self)
1306                                         continue;
1307                                 e.killindicator = spawn();
1308                                 e.killindicator.owner = e;
1309                                 e.killindicator.scale = 0.5;
1310                                 setattachment(e.killindicator, e, "");
1311                                 setorigin(e.killindicator, '0 0 52');
1312                                 e.killindicator.think = KillIndicator_Think;
1313                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1314                                 e.killindicator.cnt = ceil(killtime);
1315                         }
1316                         self.lip = 0;
1317                 }
1318         }
1319         if(self.killindicator)
1320         {
1321                 if(targetteam)
1322                         self.killindicator.colormod = TeamColor(targetteam);
1323                 else
1324                         self.killindicator.colormod = '0 0 0';
1325         }
1326 }
1327
1328 void ClientKill (void)
1329 {
1330         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1331         {
1332                 // do nothing
1333         }
1334         else
1335                 ClientKill_TeamChange(0);
1336 }
1337
1338 void CTS_ClientKill_Think (void)
1339 {
1340         self = self.owner; // set self to the player to be killed
1341         sprint(self, "^1You were killed in order to prevent cheating!");
1342         ClientKill_Now();
1343 }
1344
1345 void CTS_ClientKill (float t) // silent version of ClientKill
1346 {
1347         entity e;
1348         e = spawn();
1349         e.owner = self;
1350         e.think = CTS_ClientKill_Think;
1351         e.nextthink = t;
1352 }
1353
1354 void DoTeamChange(float destteam)
1355 {
1356         float t, c0;
1357         if(!teams_matter)
1358         {
1359                 if(destteam >= 0)
1360                         SetPlayerColors(self, destteam);
1361                 return;
1362         }
1363         if(self.classname == "player")
1364         if(destteam == -1)
1365         {
1366                 CheckAllowedTeams(self);
1367                 t = FindSmallestTeam(self, TRUE);
1368                 switch(self.team)
1369                 {
1370                         case COLOR_TEAM1: c0 = c1; break;
1371                         case COLOR_TEAM2: c0 = c2; break;
1372                         case COLOR_TEAM3: c0 = c3; break;
1373                         case COLOR_TEAM4: c0 = c4; break;
1374                         default:          c0 = 999;
1375                 }
1376                 switch(t)
1377                 {
1378                         case 1:
1379                                 if(c0 > c1)
1380                                         destteam = COLOR_TEAM1;
1381                                 break;
1382                         case 2:
1383                                 if(c0 > c2)
1384                                         destteam = COLOR_TEAM2;
1385                                 break;
1386                         case 3:
1387                                 if(c0 > c3)
1388                                         destteam = COLOR_TEAM3;
1389                                 break;
1390                         case 4:
1391                                 if(c0 > c4)
1392                                         destteam = COLOR_TEAM4;
1393                                 break;
1394                 }
1395                 if(destteam == -1)
1396                         return;
1397         }
1398         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1399                 return;
1400         ClientKill_TeamChange(destteam);
1401 }
1402
1403 void FixClientCvars(entity e)
1404 {
1405         // send prediction settings to the client
1406         stuffcmd(e, "\nin_bindmap 0 0\n");
1407         if(g_race || g_cts)
1408                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1409         if(cvar("g_antilag") == 3) // client side hitscan
1410                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1411         if(sv_gentle)
1412                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1413         /*
1414          * we no longer need to stuff this. Remove this comment block if you feel
1415          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1416         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1417         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1418         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1419         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1420         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1421         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1422         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1423         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1424         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1425         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1426         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1427         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1428         stuffcmd(e, "cl_movement_edgefriction 1\n");
1429          */
1430 }
1431
1432 float PlayerInIDList(entity p, string idlist)
1433 {
1434         float n, i;
1435         string s;
1436
1437         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1438         if not(p.crypto_idfp)
1439                 return 0;
1440
1441         // this function allows abbreviated player IDs too!
1442         n = tokenize_console(idlist);
1443         for(i = 0; i < n; ++i)
1444         {
1445                 s = argv(i);
1446                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1447                         return 1;
1448         }
1449
1450         return 0;
1451 }
1452
1453 /*
1454 =============
1455 ClientConnect
1456
1457 Called when a client connects to the server
1458 =============
1459 */
1460 //void ctf_clientconnect();
1461 string ColoredTeamName(float t);
1462 void DecodeLevelParms (void);
1463 //void dom_player_join_team(entity pl);
1464 void ClientConnect (void)
1465 {
1466         float t;
1467
1468         if(self.flags & FL_CLIENT)
1469         {
1470                 print("Warning: ClientConnect, but already connected!\n");
1471                 return;
1472         }
1473
1474         if(Ban_MaybeEnforceBan(self))
1475                 return;
1476
1477         DecodeLevelParms();
1478
1479 #ifdef WATERMARK
1480         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1481 #endif
1482
1483         self.classname = "player_joining";
1484
1485         self.flags = FL_CLIENT;
1486         self.version_nagtime = time + 10 + random() * 10;
1487
1488         if(player_count<0)
1489         {
1490                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1491                 player_count = 0;
1492         }
1493
1494         PlayerScore_Attach(self);
1495         ClientData_Attach();
1496
1497         bot_clientconnect();
1498
1499         playerdemo_init();
1500
1501         anticheat_init();
1502         
1503         race_PreSpawnObserver();
1504
1505         //if(g_domination)
1506         //      dom_player_join_team(self);
1507
1508         // identify the right forced team
1509         if(PlayerInIDList(self, cvar_string("g_forced_team_red")))
1510                 self.team_forced = COLOR_TEAM1;
1511         else if(PlayerInIDList(self, cvar_string("g_forced_team_blue")))
1512                 self.team_forced = COLOR_TEAM2;
1513         else if(PlayerInIDList(self, cvar_string("g_forced_team_yellow")))
1514                 self.team_forced = COLOR_TEAM3;
1515         else if(PlayerInIDList(self, cvar_string("g_forced_team_pink")))
1516                 self.team_forced = COLOR_TEAM4;
1517         else if(cvar_string("g_forced_team_otherwise") == "red")
1518                 self.team_forced = COLOR_TEAM1;
1519         else if(cvar_string("g_forced_team_otherwise") == "blue")
1520                 self.team_forced = COLOR_TEAM2;
1521         else if(cvar_string("g_forced_team_otherwise") == "yellow")
1522                 self.team_forced = COLOR_TEAM3;
1523         else if(cvar_string("g_forced_team_otherwise") == "pink")
1524                 self.team_forced = COLOR_TEAM4;
1525         else if(cvar_string("g_forced_team_otherwise") == "spectate")
1526                 self.team_forced = -1;
1527         else if(cvar_string("g_forced_team_otherwise") == "spectator")
1528                 self.team_forced = -1;
1529         else
1530                 self.team_forced = 0;
1531
1532         if(!teams_matter)
1533                 if(self.team_forced > 0)
1534                         self.team_forced = 0;
1535
1536         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1537
1538         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign") || self.team_forced < 0) {
1539                 self.classname = "observer";
1540         } else {
1541                 if(teams_matter)
1542                 {
1543                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1544                         {
1545                                 self.classname = "player";
1546                                 campaign_bots_may_start = 1;
1547                         }
1548                         else
1549                         {
1550                                 self.classname = "observer"; // do it anyway
1551                         }
1552                 }
1553                 else
1554                 {
1555                         self.classname = "player";
1556                         campaign_bots_may_start = 1;
1557                 }
1558         }
1559
1560         self.playerid = (playerid_last = playerid_last + 1);
1561
1562         if(cvar("sv_eventlog"))
1563                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1564
1565         LogTeamchange(self.playerid, self.team, 1);
1566
1567         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1568
1569         self.netname_previous = strzone(self.netname);
1570
1571         bprint("^4", self.netname, "^4 connected");
1572
1573         if(self.classname != "observer" && (g_domination || g_ctf))
1574                 bprint(" and joined the ", ColoredTeamName(self.team));
1575
1576         bprint("\n");
1577
1578         self.welcomemessage_time = 0;
1579
1580         stuffcmd(self, strcat(clientstuff, "\n"));
1581         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1582         stuffcmd(self, "cl_particles_reloadeffects\n");
1583
1584         FixClientCvars(self);
1585
1586         // spawnfunc_waypoint sprites
1587         WaypointSprite_InitClient(self);
1588
1589         // Wazat's grappling hook
1590         SetGrappleHookBindings();
1591
1592         // get autoswitch state from player when he toggles it
1593         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1594
1595         // get version info from player
1596         stuffcmd(self, "cmd clientversion $gameversion\n");
1597
1598         // get other cvars from player
1599         GetCvars(0);
1600
1601         // set cvar for team scoreboard
1602         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1603
1604         // notify about available teams
1605         if(teams_matter)
1606         {
1607                 CheckAllowedTeams(self);
1608                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1609                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1610         }
1611         else
1612                 stuffcmd(self, "set _teams_available 0\n");
1613
1614         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1615
1616         if(g_arena || g_ca)
1617         {
1618                 self.classname = "observer";
1619                 if(g_arena)
1620                         Spawnqueue_Insert(self);
1621         }
1622         /*else if(g_ctf)
1623         {
1624                 ctf_clientconnect();
1625         }*/
1626
1627         if(teams_matter || radar_showennemies)
1628                 attach_entcs();
1629
1630         bot_relinkplayerlist();
1631
1632         self.spectatortime = time;
1633         if(blockSpectators)
1634         {
1635                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1636         }
1637
1638         self.jointime = time;
1639         self.allowedTimeouts = cvar("sv_timeout_number");
1640
1641         if(clienttype(self) == CLIENTTYPE_REAL)
1642         {
1643                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1644                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1645         }
1646
1647         if(g_lms)
1648         {
1649                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1650                 {
1651                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1652                         self.frags = FRAGS_SPECTATOR;
1653                 }
1654         }
1655
1656         if(!sv_foginterval && world.fog != "")
1657                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1658
1659         SoundEntity_Attach(self);
1660
1661         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1662         {
1663                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1664                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1665         }
1666         else
1667                 self.hitplotfh = -1;
1668
1669         if(g_race || g_cts) {
1670                 string rr;
1671                 if(g_cts)
1672                         rr = CTS_RECORD;
1673                 else
1674                         rr = RACE_RECORD;
1675                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1676
1677                 msg_entity = self;
1678                 race_send_recordtime(MSG_ONE);
1679                 race_send_speedaward(MSG_ONE);
1680
1681                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1682                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1683                 race_send_speedaward_alltimebest(MSG_ONE);
1684
1685                 float i;
1686                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1687                         race_SendRankings(i, 0, 0, MSG_ONE);
1688                 }
1689         }
1690         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1691                 send_CSQC_teamnagger();
1692
1693         send_CSQC_cr_maxbullets(self);
1694
1695         CheatInitClient();
1696 }
1697
1698 /*
1699 =============
1700 ClientDisconnect
1701
1702 Called when a client disconnects from the server
1703 =============
1704 */
1705 .entity chatbubbleentity;
1706 .entity teambubbleentity;
1707 void ReadyCount();
1708 void ClientDisconnect (void)
1709 {
1710         if not(self.flags & FL_CLIENT)
1711         {
1712                 print("Warning: ClientDisconnect without ClientConnect\n");
1713                 return;
1714         }
1715
1716         CheatShutdownClient();
1717
1718         if(self.hitplotfh >= 0)
1719         {
1720                 fclose(self.hitplotfh);
1721                 self.hitplotfh = -1;
1722         }
1723
1724         anticheat_report();
1725         anticheat_shutdown();
1726
1727         playerdemo_shutdown();
1728
1729         bot_clientdisconnect();
1730
1731         if(self.entcs)
1732                 detach_entcs();
1733
1734         if(cvar("sv_eventlog"))
1735                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1736         bprint ("^4",self.netname);
1737         bprint ("^4 disconnected\n");
1738
1739         SoundEntity_Detach(self);
1740
1741         DropAllRunes(self);
1742         MUTATOR_CALLHOOK(ClientDisconnect);
1743
1744         Portal_ClearAll(self);
1745
1746         if(self.flagcarried)
1747                 DropFlag(self.flagcarried, world, world);
1748         if(self.ballcarried)
1749                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1750
1751         // Here, everything has been done that requires this player to be a client.
1752
1753         self.flags &~= FL_CLIENT;
1754
1755         if (self.chatbubbleentity)
1756                 remove (self.chatbubbleentity);
1757
1758         if (self.teambubbleentity)
1759                 remove (self.teambubbleentity);
1760
1761         if (self.killindicator)
1762                 remove (self.killindicator);
1763
1764         WaypointSprite_PlayerGone();
1765
1766         bot_relinkplayerlist();
1767
1768         if(g_arena)
1769         {
1770                 Spawnqueue_Unmark(self);
1771                 Spawnqueue_Remove(self);
1772         }
1773
1774         ClientData_Detach();
1775         PlayerScore_Detach(self);
1776
1777         if(self.netname_previous)
1778                 strunzone(self.netname_previous);
1779         if(self.clientstatus)
1780                 strunzone(self.clientstatus);
1781         if(self.weaponorder_byimpulse)
1782                 strunzone(self.weaponorder_byimpulse);
1783
1784         ClearPlayerSounds();
1785
1786         if(self.personal)
1787                 remove(self.personal);
1788
1789         self.playerid = 0;
1790         ReadyCount();
1791
1792         // free cvars
1793         GetCvars(-1);
1794 }
1795
1796 .float BUTTON_CHAT;
1797 void ChatBubbleThink()
1798 {
1799         self.nextthink = time;
1800         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1801         {
1802                 if(self.owner) // but why can that ever be world?
1803                         self.owner.chatbubbleentity = world;
1804                 remove(self);
1805                 return;
1806         }
1807         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1808 #ifdef TETRIS
1809                 || self.owner.tetris_on
1810 #endif
1811         )
1812                 self.model = self.mdl;
1813         else
1814                 self.model = "";
1815 };
1816
1817 void UpdateChatBubble()
1818 {
1819         if (!self.modelindex)
1820                 return;
1821         // spawn a chatbubble entity if needed
1822         if (!self.chatbubbleentity)
1823         {
1824                 self.chatbubbleentity = spawn();
1825                 self.chatbubbleentity.owner = self;
1826                 self.chatbubbleentity.exteriormodeltoclient = self;
1827                 self.chatbubbleentity.think = ChatBubbleThink;
1828                 self.chatbubbleentity.nextthink = time;
1829                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1830                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1831                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1832                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1833                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1834                 self.chatbubbleentity.model = "";
1835                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1836         }
1837 }
1838
1839
1840 void TeamBubbleThink()
1841 {
1842         self.nextthink = time;
1843         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1844         {
1845                 if(self.owner) // but why can that ever be world?
1846                         self.owner.teambubbleentity = world;
1847                 remove(self);
1848                 return;
1849         }
1850 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1851         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1852                 self.model = "";
1853         else
1854                 self.model = self.mdl;
1855
1856 };
1857
1858 float TeamBubble_customizeentityforclient()
1859 {
1860         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1861 }
1862
1863 void UpdateTeamBubble()
1864 {
1865         if (!self.modelindex || !teams_matter)
1866                 return;
1867         // spawn a teambubble entity if needed
1868         if (!self.teambubbleentity && teams_matter)
1869         {
1870                 self.teambubbleentity = spawn();
1871                 self.teambubbleentity.owner = self;
1872                 self.teambubbleentity.exteriormodeltoclient = self;
1873                 self.teambubbleentity.think = TeamBubbleThink;
1874                 self.teambubbleentity.nextthink = time;
1875                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1876 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1877                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1878                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1879                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1880                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1881                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1882                 self.teambubbleentity.effects = EF_LOWPRECISION;
1883         }
1884 }
1885
1886 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1887 // added to the model skins
1888 /*void UpdateColorModHack()
1889 {
1890         local float c;
1891         c = self.clientcolors & 15;
1892         // LordHavoc: only bothering to support white, green, red, yellow, blue
1893              if (!teams_matter) self.colormod = '0 0 0';
1894         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1895         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1896         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1897         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1898         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1899         else self.colormod = '1 1 1';
1900 };*/
1901
1902 .float oldcolormap;
1903 void respawn(void)
1904 {
1905         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1906         {
1907                 self.solid = SOLID_NOT;
1908                 self.takedamage = DAMAGE_NO;
1909                 self.movetype = MOVETYPE_FLY;
1910                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1911                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1912                 self.effects |= EF_ADDITIVE;
1913                 self.oldcolormap = self.colormap;
1914                 self.colormap = 512;
1915                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1916                 if(cvar("g_respawn_ghosts_maxtime"))
1917                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1918         }
1919
1920         CopyBody(1);
1921         self.effects |= EF_NODRAW; // prevent another CopyBody
1922         if(self.oldcolormap)
1923         {
1924                 self.colormap = self.oldcolormap;
1925                 self.oldcolormap = 0;
1926         }
1927         PutClientInServer();
1928 }
1929
1930 void play_countdown(float finished, string samp)
1931 {
1932         if(clienttype(self) == CLIENTTYPE_REAL)
1933                 if(floor(finished - time - frametime) != floor(finished - time))
1934                         if(finished - time < 6)
1935                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1936 }
1937
1938 /**
1939  * When sv_timeout is used this function returs strings like
1940  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1941  * Called by centerprint functions
1942  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1943  */
1944 string getTimeoutText(float addOneSecond) {
1945         if (!cvar("sv_timeout") || !timeoutStatus)
1946                 return "";
1947
1948         local string retStr;
1949         if (timeoutStatus == 1) {
1950                 if (addOneSecond == 1) {
1951                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1952                 }
1953                 else {
1954                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1955                 }
1956                 return retStr;
1957         }
1958         else if (timeoutStatus == 2) {
1959                 if (addOneSecond) {
1960                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1961                         //don't show messages like "Timeout ends in 0 seconds"...
1962                         if ((remainingTimeoutTime + 1) > 0)
1963                                 return retStr;
1964                         else
1965                                 return "";
1966                 }
1967                 else {
1968                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1969                         //don't show messages like "Timeout ends in 0 seconds"...
1970                         if (remainingTimeoutTime > 0)
1971                                 return retStr;
1972                         else
1973                                 return "";
1974                 }
1975         }
1976         else return "";
1977 }
1978
1979 void player_powerups (void)
1980 {
1981         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1982         {
1983                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1984                 self.modelflags |= MF_ROCKET;
1985         }
1986         else
1987         {
1988                 SoundEntity_StopSound(self, CHAN_PLAYER);
1989                 self.modelflags &~= MF_ROCKET;
1990         }
1991
1992         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1993
1994         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1995                 return;
1996         
1997         Fire_ApplyDamage(self);
1998         Fire_ApplyEffect(self);
1999
2000         if (g_minstagib)
2001         {
2002                 self.effects |= EF_FULLBRIGHT;
2003
2004                 if (self.items & IT_STRENGTH)
2005                 {
2006                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2007                         if (time > self.strength_finished)
2008                         {
2009                                 self.alpha = default_player_alpha;
2010                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2011                                 self.items &~= IT_STRENGTH;
2012                                 sprint(self, "^3Invisibility has worn off\n");
2013                         }
2014                 }
2015                 else
2016                 {
2017                         if (time < self.strength_finished)
2018                         {
2019                                 self.alpha = g_minstagib_invis_alpha;
2020                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2021                                 self.items |= IT_STRENGTH;
2022                                 sprint(self, "^3You are invisible\n");
2023                         }
2024                 }
2025
2026                 if (self.items & IT_INVINCIBLE)
2027                 {
2028                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2029                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2030                         {
2031                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2032                                 sprint(self, "^3Speed has worn off\n");
2033                         }
2034                 }
2035                 else
2036                 {
2037                         if (time < self.invincible_finished)
2038                         {
2039                                 self.items = self.items | IT_INVINCIBLE;
2040                                 sprint(self, "^3You are on speed\n");
2041                         }
2042                 }
2043                 return;
2044         }
2045
2046         if (self.items & IT_STRENGTH)
2047         {
2048                 play_countdown(self.strength_finished, "misc/poweroff.wav");
2049                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2050                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
2051                 {
2052                         self.items = self.items - (self.items & IT_STRENGTH);
2053                         sprint(self, "^3Strength has worn off\n");
2054                 }
2055         }
2056         else
2057         {
2058                 if (time < self.strength_finished)
2059                 {
2060                         self.items = self.items | IT_STRENGTH;
2061                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
2062                 }
2063         }
2064         if (self.items & IT_INVINCIBLE)
2065         {
2066                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
2067                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2068                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
2069                 {
2070                         self.items = self.items - (self.items & IT_INVINCIBLE);
2071                         sprint(self, "^3Shield has worn off\n");
2072                 }
2073         }
2074         else
2075         {
2076                 if (time < self.invincible_finished)
2077                 {
2078                         self.items = self.items | IT_INVINCIBLE;
2079                         sprint(self, "^3Shield surrounds you\n");
2080                 }
2081         }
2082
2083         if(cvar("g_nodepthtestplayers"))
2084                 self.effects = self.effects | EF_NODEPTHTEST;
2085
2086         if(cvar("g_fullbrightplayers"))
2087                 self.effects = self.effects | EF_FULLBRIGHT;
2088
2089         // midair gamemode: damage only while in the air
2090         // if in midair mode, being on ground grants temporary invulnerability
2091         // (this is so that multishot weapon don't clear the ground flag on the
2092         // first damage in the frame, leaving the player vulnerable to the
2093         // remaining hits in the same frame)
2094         if (self.flags & FL_ONGROUND)
2095         if (g_midair)
2096                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2097
2098         if (time >= game_starttime)
2099         if (time < self.spawnshieldtime)
2100                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2101 }
2102
2103 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2104 {
2105         if(current > stable)
2106                 return current;
2107         else if(current > stable - 0.25) // when close enough, "snap"
2108                 return stable;
2109         else
2110                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2111 }
2112
2113 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2114 {
2115         if(current < stable)
2116                 return current;
2117         else if(current < stable + 0.25) // when close enough, "snap"
2118                 return stable;
2119         else
2120                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2121 }
2122
2123 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2124 {
2125         if(current > rotstable)
2126         {
2127                 if(rotframetime > 0)
2128                 {
2129                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2130                         current = max(rotstable, current - rotlinear * rotframetime);
2131                 }
2132         }
2133         else if(current < regenstable)
2134         {
2135                 if(regenframetime > 0)
2136                 {
2137                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2138                         current = min(regenstable, current + regenlinear * regenframetime);
2139                 }
2140         }
2141
2142         if(current > limit)
2143                 current = limit;
2144
2145         return current;
2146 }
2147
2148 void player_regen (void)
2149 {
2150         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2151         maxh = cvar("g_balance_health_rotstable");
2152         maxa = cvar("g_balance_armor_rotstable");
2153         maxf = cvar("g_balance_fuel_rotstable");
2154         minh = cvar("g_balance_health_regenstable");
2155         mina = cvar("g_balance_armor_regenstable");
2156         minf = cvar("g_balance_fuel_regenstable");
2157         limith = cvar("g_balance_health_limit");
2158         limita = cvar("g_balance_armor_limit");
2159         limitf = cvar("g_balance_fuel_limit");
2160
2161         max_mod = regen_mod = rot_mod = limit_mod = 1;
2162
2163         if (self.runes & RUNE_REGEN)
2164         {
2165                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2166                 {
2167                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2168                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2169                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2170                 }
2171                 else
2172                 {
2173                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2174                         max_mod = cvar("g_balance_rune_regen_hpmod");
2175                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2176                 }
2177         }
2178         else if (self.runes & CURSE_VENOM)
2179         {
2180                 max_mod = cvar("g_balance_curse_venom_hpmod");
2181                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2182                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2183                 else
2184                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2185                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2186                 //if (!self.runes & RUNE_REGEN)
2187                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2188         }
2189         maxh = maxh * max_mod;
2190         //maxa = maxa * max_mod;
2191         //maxf = maxf * max_mod;
2192         minh = minh * max_mod;
2193         //mina = mina * max_mod;
2194         //minf = minf * max_mod;
2195         limith = limith * limit_mod;
2196         limita = limita * limit_mod;
2197         //limitf = limitf * limit_mod;
2198
2199         if(g_lms && g_ca)
2200                 rot_mod = 0;
2201
2202         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2203         {
2204                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2205                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2206
2207                 // if player rotted to death...  die!
2208                 if(self.health < 1)
2209                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2210         }
2211
2212         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2213                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2214 }
2215
2216 float zoomstate_set;
2217 void SetZoomState(float z)
2218 {
2219         if(z != self.zoomstate)
2220         {
2221                 self.zoomstate = z;
2222                 ClientData_Touch(self);
2223         }
2224         zoomstate_set = 1;
2225 }
2226
2227 void GetPressedKeys(void) {
2228         MUTATOR_CALLHOOK(GetPressedKeys);
2229         if (self.movement_x > 0) // get if movement keys are pressed
2230         {       // forward key pressed
2231                 self.pressedkeys |= KEY_FORWARD;
2232                 self.pressedkeys &~= KEY_BACKWARD;
2233         }
2234         else if (self.movement_x < 0)
2235         {       // backward key pressed
2236                 self.pressedkeys |= KEY_BACKWARD;
2237                 self.pressedkeys &~= KEY_FORWARD;
2238         }
2239         else
2240         {       // no x input
2241                 self.pressedkeys &~= KEY_FORWARD;
2242                 self.pressedkeys &~= KEY_BACKWARD;
2243         }
2244
2245         if (self.movement_y > 0)
2246         {       // right key pressed
2247                 self.pressedkeys |= KEY_RIGHT;
2248                 self.pressedkeys &~= KEY_LEFT;
2249         }
2250         else if (self.movement_y < 0)
2251         {       // left key pressed
2252                 self.pressedkeys |= KEY_LEFT;
2253                 self.pressedkeys &~= KEY_RIGHT;
2254         }
2255         else
2256         {       // no y input
2257                 self.pressedkeys &~= KEY_RIGHT;
2258                 self.pressedkeys &~= KEY_LEFT;
2259         }
2260
2261         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2262                 self.pressedkeys |= KEY_JUMP;
2263         else
2264                 self.pressedkeys &~= KEY_JUMP;
2265         if (self.BUTTON_CROUCH)
2266                 self.pressedkeys |= KEY_CROUCH;
2267         else
2268                 self.pressedkeys &~= KEY_CROUCH;
2269 }
2270
2271 void update_stats (float number, float hit, float fired) {
2272 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2273 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2274
2275         if(number) {
2276                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2277                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2278         } else {
2279                 self.stat_hit = hit * sv_accuracy_data_share;
2280                 self.stat_fired = fired * sv_accuracy_data_share;
2281         }
2282 }
2283
2284 /*
2285 ======================
2286 spectate mode routines
2287 ======================
2288 */
2289
2290 .float weapon_count;
2291 void SpectateCopy(entity spectatee) {
2292         if(spectatee.weapon_count < WEP_LAST) {
2293                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2294                 spectatee.weapon_count ++;
2295         } else
2296                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2297
2298         other = spectatee;
2299         MUTATOR_CALLHOOK(SpectateCopy);
2300         self.armortype = spectatee.armortype;
2301         self.armorvalue = spectatee.armorvalue;
2302         self.ammo_cells = spectatee.ammo_cells;
2303         self.ammo_shells = spectatee.ammo_shells;
2304         self.ammo_nails = spectatee.ammo_nails;
2305         self.ammo_rockets = spectatee.ammo_rockets;
2306         self.ammo_fuel = spectatee.ammo_fuel;
2307         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2308         self.health = spectatee.health;
2309         self.impulse = 0;
2310         self.items = spectatee.items;
2311         self.last_pickup = spectatee.last_pickup;
2312         self.metertime = spectatee.metertime;
2313         self.strength_finished = spectatee.strength_finished;
2314         self.invincible_finished = spectatee.invincible_finished;
2315         self.pressedkeys = spectatee.pressedkeys;
2316         self.weapons = spectatee.weapons;
2317         self.switchweapon = spectatee.switchweapon;
2318         self.weapon = spectatee.weapon;
2319         self.punchangle = spectatee.punchangle;
2320         self.view_ofs = spectatee.view_ofs;
2321         self.v_angle = spectatee.v_angle;
2322         self.velocity = spectatee.velocity;
2323         self.dmg_take = spectatee.dmg_take;
2324         self.dmg_save = spectatee.dmg_save;
2325         self.dmg_inflictor = spectatee.dmg_inflictor;
2326         self.angles = spectatee.v_angle;
2327         self.fixangle = TRUE;
2328         setorigin(self, spectatee.origin);
2329         setsize(self, spectatee.mins, spectatee.maxs);
2330         SetZoomState(spectatee.zoomstate);
2331
2332         anticheat_spectatecopy(spectatee);
2333 }
2334
2335 float SpectateUpdate() {
2336         if(!self.enemy)
2337                 return 0;
2338
2339         if (self == self.enemy)
2340                 return 0;
2341
2342         if(self.enemy.classname != "player")
2343                 return 0;
2344
2345         SpectateCopy(self.enemy);
2346
2347         return 1;
2348 }
2349
2350 float SpectateNext() {
2351         other = find(self.enemy, classname, "player");
2352
2353         if (!other)
2354                 other = find(other, classname, "player");
2355
2356         if (other)
2357                 self.enemy = other;
2358
2359         if(self.enemy.classname == "player") {
2360                 msg_entity = self;
2361                 WriteByte(MSG_ONE, SVC_SETVIEW);
2362                 WriteEntity(MSG_ONE, self.enemy);
2363                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2364                 self.movetype = MOVETYPE_NONE;
2365
2366                 self.enemy.weapon_count = 0;
2367
2368                 if(!SpectateUpdate())
2369                         PutObserverInServer();
2370
2371                 return 1;
2372         } else {
2373                 return 0;
2374         }
2375 }
2376
2377 /*
2378 =============
2379 ShowRespawnCountdown()
2380
2381 Update a respawn countdown display.
2382 =============
2383 */
2384 void ShowRespawnCountdown()
2385 {
2386         float number;
2387         if(self.deadflag == DEAD_NO) // just respawned?
2388                 return;
2389         else
2390         {
2391                 number = ceil(self.death_time - time);
2392                 if(number <= 0)
2393                         return;
2394                 if(number <= self.respawn_countdown)
2395                 {
2396                         self.respawn_countdown = number - 1;
2397                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2398                                 AnnounceTo(self, strcat(ftos(number), ""));
2399                 }
2400         }
2401 }
2402
2403 void LeaveSpectatorMode()
2404 {
2405         if(isJoinAllowed()) {
2406                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned")) || self.team_forced > 0) {
2407                         self.classname = "player";
2408
2409                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2410                                 JoinBestTeam(self, FALSE, TRUE);
2411
2412                         if(cvar("g_campaign"))
2413                                 campaign_bots_may_start = 1;
2414
2415                         self.stat_count = WEP_LAST;
2416
2417                         PutClientInServer();
2418
2419                         if(self.classname == "player")
2420                                 bprint ("^4", self.netname, "^4 is playing now\n");
2421
2422                         if(!cvar("g_campaign"))
2423                                 centerprint(self,""); // clear MOTD
2424
2425                         return;
2426                 } else {
2427                         if (g_ca && self.caplayer) {
2428                         }       // do nothing
2429                         else
2430                                 stuffcmd(self,"menu_showteamselect\n");
2431                         return;
2432                 }
2433         }
2434         else {
2435                 //player may not join because of g_maxplayers is set
2436                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2437         }
2438 }
2439
2440 /**
2441  * Determines whether the player is allowed to join. This depends on cvar
2442  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2443  * it checks whether the number of currently playing players exceeds g_maxplayers.
2444  * @return bool TRUE if the player is allowed to join, false otherwise
2445  */
2446 float isJoinAllowed() {
2447         if(self.team_forced < 0)
2448                 return FALSE; // forced spectators can never join
2449
2450         if (!cvar("g_maxplayers"))
2451                 return TRUE;
2452
2453         local entity e;
2454         local float currentlyPlaying;
2455         FOR_EACH_REALPLAYER(e) {
2456                 if(e.classname == "player")
2457                         currentlyPlaying += 1;
2458         }
2459         if(currentlyPlaying < cvar("g_maxplayers"))
2460                 return TRUE;
2461
2462         return FALSE;
2463 }
2464
2465 /**
2466  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2467  * g_maxplayers_spectator_blocktime seconds
2468  */
2469 void checkSpectatorBlock() {
2470         if(self.classname == "spectator" || self.classname == "observer") {
2471                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2472                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2473                         dropclient(self);
2474                 }
2475         }
2476 }
2477
2478 void ObserverThink()
2479 {
2480         if (self.flags & FL_JUMPRELEASED) {
2481                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2482                         self.welcomemessage_time = 0;
2483                         self.flags &~= FL_JUMPRELEASED;
2484                         self.flags |= FL_SPAWNING;
2485                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2486                         self.welcomemessage_time = 0;
2487                         self.flags &~= FL_JUMPRELEASED;
2488                         if(SpectateNext() == 1) {
2489                                 self.classname = "spectator";
2490                         }
2491                 }
2492         } else {
2493                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2494                         self.flags |= FL_JUMPRELEASED;
2495                         if(self.flags & FL_SPAWNING)
2496                         {
2497                                 self.flags &~= FL_SPAWNING;
2498                                 LeaveSpectatorMode();
2499                                 return;
2500                         }
2501                 }
2502         }
2503         PrintWelcomeMessage(self);
2504 }
2505
2506 void SpectatorThink()
2507 {
2508         if (self.flags & FL_JUMPRELEASED) {
2509                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2510                         self.welcomemessage_time = 0;
2511                         self.flags &~= FL_JUMPRELEASED;
2512                         self.flags |= FL_SPAWNING;
2513                 } else if(self.BUTTON_ATCK) {
2514                         self.welcomemessage_time = 0;
2515                         self.flags &~= FL_JUMPRELEASED;
2516                         if(SpectateNext() == 1) {
2517                                 self.classname = "spectator";
2518                         } else {
2519                                 self.classname = "observer";
2520                                 self.stat_count = WEP_LAST;
2521                                 PutClientInServer();
2522                         }
2523                 } else if (self.BUTTON_ATCK2) {
2524                         self.welcomemessage_time = 0;
2525                         self.flags &~= FL_JUMPRELEASED;
2526                         self.classname = "observer";
2527                         self.stat_count = WEP_LAST;
2528                         PutClientInServer();
2529                 } else {
2530                         if(!SpectateUpdate())
2531                                 PutObserverInServer();
2532                 }
2533         } else {
2534                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2535                         self.flags |= FL_JUMPRELEASED;
2536                         if(self.flags & FL_SPAWNING)
2537                         {
2538                                 self.flags &~= FL_SPAWNING;
2539                                 LeaveSpectatorMode();
2540                                 return;
2541                         }
2542                 }
2543         }
2544
2545         PrintWelcomeMessage(self);
2546         self.flags |= FL_CLIENT | FL_NOTARGET;
2547 }
2548
2549 .float touchexplode_time;
2550
2551 /*
2552 =============
2553 PlayerPreThink
2554
2555 Called every frame for each client before the physics are run
2556 =============
2557 */
2558 void() ctf_setstatus;
2559 void() nexball_setstatus;
2560 .float items_added;
2561 void PlayerPreThink (void)
2562 {
2563         self.stat_game_starttime = game_starttime;
2564         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2565         self.stat_leadlimit = cvar("leadlimit");
2566
2567         if(frametime)
2568         {
2569                 // physics frames: update anticheat stuff
2570                 anticheat_prethink();
2571         }
2572
2573         if(blockSpectators && frametime)
2574                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2575                 checkSpectatorBlock();
2576
2577         zoomstate_set = 0;
2578
2579         if(self.netname_previous != self.netname)
2580         {
2581                 if(cvar("sv_eventlog"))
2582                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2583                 if(self.netname_previous)
2584                         strunzone(self.netname_previous);
2585                 self.netname_previous = strzone(self.netname);
2586         }
2587
2588         // version nagging
2589         if(self.version_nagtime)
2590                 if(self.cvar_g_xonoticversion)
2591                         if(time > self.version_nagtime)
2592                         {
2593                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2594                                 {
2595                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2596                                         {
2597                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2598                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2599                                         }
2600                                         else
2601                                         {
2602                                                 float r;
2603                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2604                                                 if(r < 0)
2605                                                 {
2606                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2607                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2608                                                 }
2609                                                 else if(r > 0)
2610                                                 {
2611                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2612                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2613                                                 }
2614                                         }
2615                                 }
2616                                 self.version_nagtime = 0;
2617                         }
2618
2619         // GOD MODE info
2620         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2621         {
2622                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2623                 self.max_armorvalue = 0;
2624         }
2625
2626 #ifdef TETRIS
2627         if (TetrisPreFrame())
2628                 return;
2629 #endif
2630
2631         MUTATOR_CALLHOOK(PlayerPreThink);
2632
2633         if(self.classname == "player") {
2634 //              if(self.netname == "Wazat")
2635 //                      bprint(self.classname, "\n");
2636
2637                 CheckRules_Player();
2638
2639                 PrintWelcomeMessage(self);
2640
2641                 if (intermission_running)
2642                 {
2643                         IntermissionThink ();   // otherwise a button could be missed between
2644                         return;                                 // the think tics
2645                 }
2646
2647                 if(self.teleport_time)
2648                 if(time > self.teleport_time)
2649                 {
2650                         self.teleport_time = 0;
2651                         self.effects = self.effects - (self.effects & EF_NODRAW);
2652                 }
2653
2654                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2655                         UpdateSelectedPlayer();
2656
2657                 //don't allow the player to turn around while game is paused!
2658                 if(timeoutStatus == 2) {
2659                         self.v_angle = self.lastV_angle;
2660                         self.angles = self.lastV_angle;
2661                         self.fixangle = TRUE;
2662                 }
2663
2664                 if(frametime)
2665                 {
2666                         if(self.health <= 0 && cvar("g_deathglow"))
2667                         {
2668                                 if(self.glowmod_x > 0)
2669                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2670                                 else
2671                                         self.glowmod_x = -1;
2672                                 if(self.glowmod_y > 0)
2673                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2674                                 else
2675                                         self.glowmod_y = -1;
2676                                 if(self.glowmod_z > 0)
2677                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2678                                 else
2679                                         self.glowmod_z = -1;
2680                         }
2681                         else
2682                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2683                         player_powerups();
2684                 }
2685
2686                 if (self.deadflag != DEAD_NO)
2687                 {
2688                         float button_pressed, force_respawn;
2689                         if(self.personal && g_race_qualifying)
2690                         {
2691                                 if(time > self.death_time)
2692                                 {
2693                                         self.death_time = time + 1; // only retry once a second
2694                                         respawn();
2695                                         self.impulse = 141;
2696                                 }
2697                         }
2698                         else
2699                         {
2700                                 if(frametime)
2701                                         player_anim();
2702                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2703                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2704                                 if (self.deadflag == DEAD_DYING)
2705                                 {
2706                                         if(force_respawn)
2707                                                 self.deadflag = DEAD_RESPAWNING;
2708                                         else if(!button_pressed)
2709                                                 self.deadflag = DEAD_DEAD;
2710                                 }
2711                                 else if (self.deadflag == DEAD_DEAD)
2712                                 {
2713                                         if(button_pressed)
2714                                                 self.deadflag = DEAD_RESPAWNABLE;
2715                                 }
2716                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2717                                 {
2718                                         if(!button_pressed)
2719                                                 self.deadflag = DEAD_RESPAWNING;
2720                                 }
2721                                 else if (self.deadflag == DEAD_RESPAWNING)
2722                                 {
2723                                         if(time > self.death_time)
2724                                         {
2725                                                 self.death_time = time + 1; // only retry once a second
2726                                                 respawn();
2727                                         }
2728                                 }
2729                                 ShowRespawnCountdown();
2730                         }
2731                         return;
2732                 }
2733
2734                 if(g_touchexplode)
2735                 if(time > self.touchexplode_time)
2736                 if(self.classname == "player")
2737                 if(self.deadflag == DEAD_NO)
2738                 if not(IS_INDEPENDENT_PLAYER(self))
2739                 FOR_EACH_PLAYER(other) if(self != other)
2740                 {
2741                         if(time > other.touchexplode_time)
2742                         if(other.deadflag == DEAD_NO)
2743                         if not(IS_INDEPENDENT_PLAYER(other))
2744                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2745                         {
2746                                 PlayerTouchExplode(self, other);
2747                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2748                         }
2749                 }
2750
2751                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2752                 {
2753                         vector dist;
2754
2755                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2756                         dist = self.prevorigin - self.origin;
2757                         dist_z = 0;
2758                         self.lms_traveled_distance += fabs(vlen(dist));
2759
2760                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2761                         {
2762                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2763                                 self.lms_traveled_distance = 0;
2764                         }
2765
2766                         if(time > self.lms_nextcheck)
2767                         {
2768                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2769                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2770                                 {
2771                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2772                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2773                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2774                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2775                                 }
2776                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2777                                 self.lms_traveled_distance = 0;
2778                         }
2779                 }
2780
2781                 self.prevorigin = self.origin;
2782
2783                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2784                 {
2785                         if (!self.crouch)
2786                         {
2787                                 self.crouch = TRUE;
2788                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2789                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2790                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2791                         }
2792                 }
2793                 else
2794                 {
2795                         if (self.crouch)
2796                         {
2797                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2798                                 if (!trace_startsolid)
2799                                 {
2800                                         self.crouch = FALSE;
2801                                         self.view_ofs = PL_VIEW_OFS;
2802                                         setsize (self, PL_MIN, PL_MAX);
2803                                 }
2804                         }
2805                 }
2806
2807                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2808                 {
2809                         if(self.bloodloss_timer < time)
2810                         {
2811                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2812                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2813                         }
2814                 }
2815
2816                 FixPlayermodel();
2817
2818                 GrapplingHookFrame();
2819
2820                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2821                 //if(frametime)
2822                 {
2823                         self.items &~= self.items_added;
2824
2825                         W_WeaponFrame();
2826
2827                         self.items_added = 0;
2828                         if(self.items & IT_JETPACK)
2829                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2830                                         self.items_added |= IT_FUEL;
2831
2832                         self.items |= self.items_added;
2833                 }
2834
2835                 player_regen();
2836
2837                 // rot nex charge to the charge limit
2838                 if(cvar("g_balance_nex_charge_rot_rate") && self.nex_charge > cvar("g_balance_nex_charge_limit") && self.nex_charge_rottime < time)
2839                         self.nex_charge = bound(cvar("g_balance_nex_charge_limit"), self.nex_charge - cvar("g_balance_nex_charge_rot_rate") * frametime / W_TICSPERFRAME, 1);
2840
2841                 if(frametime)
2842                         player_anim();
2843
2844                 if (g_minstagib)
2845                         minstagib_ammocheck();
2846
2847                 ctf_setstatus();
2848                 nexball_setstatus();
2849
2850                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2851
2852                 //self.angles_y=self.v_angle_y + 90;   // temp
2853         } else if(gameover) {
2854                 if (intermission_running)
2855                         IntermissionThink ();   // otherwise a button could be missed between
2856                 return;
2857         } else if(self.classname == "observer") {
2858                 ObserverThink();
2859         } else if(self.classname == "spectator") {
2860                 SpectatorThink();
2861         }
2862
2863         if(!zoomstate_set)
2864                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2865
2866         float oldspectatee_status;
2867         oldspectatee_status = self.spectatee_status;
2868         if(self.classname == "spectator")
2869                 self.spectatee_status = num_for_edict(self.enemy);
2870         else if(self.classname == "observer")
2871                 self.spectatee_status = num_for_edict(self);
2872         else
2873                 self.spectatee_status = 0;
2874         if(self.spectatee_status != oldspectatee_status)
2875         {
2876                 ClientData_Touch(self);
2877                 if(g_race || g_cts)
2878                         race_InitSpectator();
2879         }
2880
2881         if(self.teamkill_soundtime)
2882         if(time > self.teamkill_soundtime)
2883         {
2884                 self.teamkill_soundtime = 0;
2885
2886                 entity oldpusher, oldself;
2887
2888                 oldself = self; self = self.teamkill_soundsource;
2889                 oldpusher = self.pusher; self.pusher = oldself;
2890
2891                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2892
2893                 self.pusher = oldpusher;
2894                 self = oldself;
2895         }
2896
2897         if(self.taunt_soundtime)
2898         if(time > self.taunt_soundtime)
2899         {
2900                 self.taunt_soundtime = 0;
2901                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2902         }
2903
2904         target_voicescript_next(self);
2905 }
2906
2907 float isInvisibleString(string s)
2908 {
2909         float i, n, c;
2910         s = strdecolorize(s);
2911         for((i = 0), (n = strlen(s)); i < n; ++i)
2912         {
2913                 c = str2chr(s, i);
2914                 switch(c)
2915                 {
2916                         case 0:
2917                         case 32: // space
2918                                 break;
2919                         case 192: // charmap space
2920                                 if (!cvar("utf8_enable"))
2921                                         break;
2922                                 return FALSE;
2923                         case 160: // space in unicode fonts
2924                         case 0xE000 + 192: // utf8 charmap space
2925                                 if (cvar("utf8_enable"))
2926                                         break;
2927                         default:
2928                                 return FALSE;
2929                 }
2930         }
2931         return TRUE;
2932 }
2933
2934 /*
2935 =============
2936 PlayerPostThink
2937
2938 Called every frame for each client after the physics are run
2939 =============
2940 */
2941 .float idlekick_lasttimeleft;
2942 .entity showheadshotbbox;
2943 void showheadshotbbox_think()
2944 {
2945         if(self.owner.showheadshotbbox != self)
2946         {
2947                 remove(self);
2948                 return;
2949         }
2950         self.nextthink = time;
2951         setorigin(self, self.owner.origin);
2952         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2953 }
2954 void PlayerPostThink (void)
2955 {
2956         // Savage: Check for nameless players
2957         if (isInvisibleString(self.netname)) {
2958                 self.netname = "Player";
2959                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2960         }
2961
2962         // send the clients accuracy stats to the client
2963         if(self.stat_count > 0)
2964         if(frametime)
2965         {
2966                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2967                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2968                 self.stat_count -= 1;
2969         }
2970
2971         if(sv_maxidle && frametime)
2972         {
2973                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2974                 float timeleft;
2975                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2976                 if(timeleft <= 0)
2977                 {
2978                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2979                         AnnounceTo(self, "terminated");
2980                         dropclient(self);
2981                         return;
2982                 }
2983                 else if(timeleft <= 10)
2984                 {
2985                         if(timeleft != self.idlekick_lasttimeleft)
2986                         {
2987                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2988                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2989                         }
2990                 }
2991                 else
2992                 {
2993                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2994                 }
2995                 self.idlekick_lasttimeleft = timeleft;
2996         }
2997
2998 #ifdef TETRIS
2999         if(self.impulse == 100)
3000                 ImpulseCommands();
3001         if (TetrisPostFrame())
3002                 return;
3003 #endif
3004
3005         CheatFrame();
3006
3007         if(self.classname == "player") {
3008                 CheckRules_Player();
3009                 UpdateChatBubble();
3010                 UpdateTeamBubble();
3011                 if (self.impulse)
3012                         ImpulseCommands();
3013                 if (intermission_running)
3014                         return;         // intermission or finale
3015                 GetPressedKeys();
3016         } else if (self.classname == "observer") {
3017                 //do nothing
3018         } else if (self.classname == "spectator") {
3019                 //do nothing
3020         }
3021
3022         /*
3023         float i;
3024         for(i = 0; i < 1000; ++i)
3025         {
3026                 vector end;
3027                 end = self.origin + '0 0 1024' + 512 * randomvec();
3028                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3029                 if(trace_fraction < 1)
3030                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3031                 {
3032                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3033                         break;
3034                 }
3035         }
3036         */
3037
3038         Arena_Warmup();
3039
3040         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3041
3042         if(self.waypointsprite_attachedforcarrier)
3043                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
3044         
3045         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3046         {
3047                 if(!self.showheadshotbbox)
3048                 {
3049                         self.showheadshotbbox = spawn();
3050                         self.showheadshotbbox.classname = "headshotbbox";
3051                         self.showheadshotbbox.owner = self;
3052                         self.showheadshotbbox.think = showheadshotbbox_think;
3053                         self.showheadshotbbox.nextthink = time;