qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/all.qc"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     WITHSELF(this, ClientConnect());
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     WITHSELF(this, PutClientInServer());
  63 }
  64
  65 void PutObserverInServer();
  66 void ClientDisconnect();
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     WITHSELF(this, PutClientInServer());
  72     WITHSELF(this, ClientDisconnect());
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 bool ClientData_Send(entity this, entity to, int sf)
  80 {
  81         assert(to == this.owner, return false);
  82
  83         entity e = to;
  84         if (IS_SPEC(e)) e = e.enemy;
  85
  86         sf = 0;
  87         if (e.race_completed)       sf |= 1; // forced scoreboard
  88         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
  89         if (e.zoomstate)            sf |= 4; // zoomed
  90         if (e.porto_v_angle_held)   sf |= 8; // angles held
  91
  92         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  93         WriteByte(MSG_ENTITY, sf);
  94
  95         if (sf & 2)
  96         {
  97                 WriteByte(MSG_ENTITY, to.spectatee_status);
  98         }
  99         if (sf & 8)
 100         {
 101                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 102                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 103         }
 104         return true;
 105 }
 106
 107 void ClientData_Attach(entity this)
 108 {
 109         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 110         this.clientdata.drawonlytoclient = this;
 111         this.clientdata.owner = this;
 112 }
 113
 114 void ClientData_Detach(entity this)
 115 {
 116         remove(this.clientdata);
 117         this.clientdata = NULL;
 118 }
 119
 120 void ClientData_Touch(entity e)
 121 {
 122         e.clientdata.SendFlags = 1;
 123
 124         // make it spectatable
 125         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 126 }
 127
 128 .string netname_previous;
 129
 130 void SetSpectatee(entity player, entity spectatee);
 131
 132
 133 /*
 134 =============
 135 CheckPlayerModel
 136
 137 Checks if the argument string can be a valid playermodel.
 138 Returns a valid one in doubt.
 139 =============
 140 */
 141 string FallbackPlayerModel;
 142 string CheckPlayerModel(string plyermodel) {
 143         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 144         {
 145                 // note: we cannot summon Don Strunzone here, some player may
 146                 // still have the model string set. In case anyone manages how
 147                 // to change a cvar default, we'll have a small leak here.
 148                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 149         }
 150         // only in right path
 151         if( substring(plyermodel,0,14) != "models/player/")
 152                 return FallbackPlayerModel;
 153         // only good file extensions
 154         if(substring(plyermodel,-4,4) != ".zym")
 155         if(substring(plyermodel,-4,4) != ".dpm")
 156         if(substring(plyermodel,-4,4) != ".iqm")
 157         if(substring(plyermodel,-4,4) != ".md3")
 158         if(substring(plyermodel,-4,4) != ".psk")
 159                 return FallbackPlayerModel;
 160         // forbid the LOD models
 161         if(substring(plyermodel, -9,5) == "_lod1")
 162                 return FallbackPlayerModel;
 163         if(substring(plyermodel, -9,5) == "_lod2")
 164                 return FallbackPlayerModel;
 165         if(plyermodel != strtolower(plyermodel))
 166                 return FallbackPlayerModel;
 167         // also, restrict to server models
 168         if(autocvar_sv_servermodelsonly)
 169         {
 170                 if(!fexists(plyermodel))
 171                         return FallbackPlayerModel;
 172         }
 173         return plyermodel;
 174 }
 175
 176 void setplayermodel(entity e, string modelname)
 177 {
 178         precache_model(modelname);
 179         _setmodel(e, modelname);
 180         player_setupanimsformodel();
 181         if(!autocvar_g_debug_globalsounds)
 182                 UpdatePlayerSounds(e);
 183 }
 184
 185 void FixPlayermodel(entity player);
 186 /** putting a client as observer in the server */
 187 void PutObserverInServer()
 188 {
 189         SELFPARAM();
 190     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 191         PlayerState_detach(this);
 192
 193         if (IS_PLAYER(this) && this.health >= 1) {
 194         // despawn effect
 195                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 196     }
 197
 198     {
 199         entity spot = SelectSpawnPoint(true);
 200         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 201         this.angles = spot.angles;
 202         this.angles_z = 0;
 203         this.fixangle = true;
 204         // offset it so that the spectator spawns higher off the ground, looks better this way
 205         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 206         this.prevorigin = this.origin;
 207         if (IS_REAL_CLIENT(this))
 208         {
 209             msg_entity = this;
 210             WriteByte(MSG_ONE, SVC_SETVIEW);
 211             WriteEntity(MSG_ONE, this);
 212         }
 213         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 214         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 215         if(!autocvar_g_debug_globalsounds)
 216         {
 217                 // needed for player sounds
 218                 this.model = "";
 219                 FixPlayermodel(this);
 220         }
 221         setmodel(this, MDL_Null);
 222         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 223         this.view_ofs = '0 0 0';
 224     }
 225
 226     RemoveGrapplingHook(this);
 227         Portal_ClearAll(this);
 228         Unfreeze(this);
 229
 230         if (this.alivetime)
 231         {
 232                 if (!warmup_stage)
 233                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 234                 this.alivetime = 0;
 235         }
 236
 237         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
 238
 239         WaypointSprite_PlayerDead(this);
 240
 241         if (mutator_returnvalue) {
 242             // mutator prevents resetting teams+score
 243         } else {
 244                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 245         this.frags = FRAGS_SPECTATOR;
 246         PlayerScore_Clear(this);  // clear scores when needed
 247     }
 248
 249         if (this.killcount != FRAGS_SPECTATOR)
 250         {
 251                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 252                 if(!intermission_running)
 253                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 254                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 255
 256                 if(this.just_joined == false) {
 257                         LogTeamchange(this.playerid, -1, 4);
 258                 } else
 259                         this.just_joined = false;
 260         }
 261
 262         accuracy_resend(this);
 263
 264         this.spectatortime = time;
 265         this.bot_attack = false;
 266     this.hud = HUD_NORMAL;
 267         TRANSMUTE(Observer, this);
 268         this.iscreature = false;
 269         this.teleportable = TELEPORT_SIMPLE;
 270         this.damagedbycontents = false;
 271         this.health = FRAGS_SPECTATOR;
 272         this.takedamage = DAMAGE_NO;
 273         this.solid = SOLID_NOT;
 274         this.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 275         this.flags = FL_CLIENT | FL_NOTARGET;
 276         this.armorvalue = 666;
 277         this.effects = 0;
 278         this.armorvalue = autocvar_g_balance_armor_start;
 279         this.pauserotarmor_finished = 0;
 280         this.pauserothealth_finished = 0;
 281         this.pauseregen_finished = 0;
 282         this.damageforcescale = 0;
 283         this.death_time = 0;
 284         this.respawn_flags = 0;
 285         this.respawn_time = 0;
 286         this.stat_respawn_time = 0;
 287         this.alpha = 0;
 288         this.scale = 0;
 289         this.fade_time = 0;
 290         this.pain_frame = 0;
 291         this.pain_finished = 0;
 292         this.strength_finished = 0;
 293         this.invincible_finished = 0;
 294         this.superweapons_finished = 0;
 295         this.pushltime = 0;
 296         this.istypefrag = 0;
 297         this.think = func_null;
 298         this.nextthink = 0;
 299         this.hook_time = 0;
 300         this.deadflag = DEAD_NO;
 301         this.crouch = false;
 302         this.revival_time = 0;
 303
 304         this.items = 0;
 305         this.weapons = '0 0 0';
 306         this.drawonlytoclient = this;
 307
 308         this.weaponname = "";
 309         this.weaponmodel = "";
 310         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 311         {
 312                 this.weaponentities[slot] = NULL;
 313         }
 314         this.exteriorweaponentity = NULL;
 315         this.killcount = FRAGS_SPECTATOR;
 316         this.velocity = '0 0 0';
 317         this.avelocity = '0 0 0';
 318         this.punchangle = '0 0 0';
 319         this.punchvector = '0 0 0';
 320         this.oldvelocity = this.velocity;
 321         this.fire_endtime = -1;
 322         this.event_damage = func_null;
 323 }
 324
 325 int player_getspecies(entity this)
 326 {
 327         get_model_parameters(this.model, this.skin);
 328         int s = get_model_parameters_species;
 329         get_model_parameters(string_null, 0);
 330         if (s < 0) return SPECIES_HUMAN;
 331         return s;
 332 }
 333
 334 .float model_randomizer;
 335 void FixPlayermodel(entity player)
 336 {
 337         string defaultmodel = "";
 338         int defaultskin = 0;
 339         if(autocvar_sv_defaultcharacter)
 340         {
 341                 if(teamplay)
 342                 {
 343                         string s = Static_Team_ColorName_Lower(player.team);
 344                         if (s != "neutral")
 345                         {
 346                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 347                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 348                         }
 349                 }
 350
 351                 if(defaultmodel == "")
 352                 {
 353                         defaultmodel = autocvar_sv_defaultplayermodel;
 354                         defaultskin = autocvar_sv_defaultplayerskin;
 355                 }
 356
 357                 int n = tokenize_console(defaultmodel);
 358                 if(n > 0)
 359                 {
 360                         defaultmodel = argv(floor(n * player.model_randomizer));
 361                         // However, do NOT randomize if the player-selected model is in the list.
 362                         for (int i = 0; i < n; ++i)
 363                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 364                                         defaultmodel = argv(i);
 365                 }
 366
 367                 int i = strstrofs(defaultmodel, ":", 0);
 368                 if(i >= 0)
 369                 {
 370                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 371                         defaultmodel = substring(defaultmodel, 0, i);
 372                 }
 373         }
 374         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 375         defaultmodel = ret_string;
 376         defaultskin = ret_int;
 377
 378         bool chmdl = false;
 379         int oldskin;
 380         if(defaultmodel != "")
 381         {
 382                 if (defaultmodel != player.model)
 383                 {
 384                         vector m1 = player.mins;
 385                         vector m2 = player.maxs;
 386                         setplayermodel (player, defaultmodel);
 387                         setsize (player, m1, m2);
 388                         chmdl = true;
 389                 }
 390
 391                 oldskin = player.skin;
 392                 player.skin = defaultskin;
 393         } else {
 394                 if (player.playermodel != player.model || player.playermodel == "")
 395                 {
 396                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 397                         vector m1 = player.mins;
 398                         vector m2 = player.maxs;
 399                         setplayermodel (player, player.playermodel);
 400                         setsize (player, m1, m2);
 401                         chmdl = true;
 402                 }
 403
 404                 oldskin = player.skin;
 405                 player.skin = stof(player.playerskin);
 406         }
 407
 408         if(chmdl || oldskin != player.skin) // model or skin has changed
 409         {
 410                 player.species = player_getspecies(player); // update species
 411                 if(!autocvar_g_debug_globalsounds)
 412                         UpdatePlayerSounds(player); // update skin sounds
 413         }
 414
 415         if(!teamplay)
 416                 if(strlen(autocvar_sv_defaultplayercolors))
 417                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 418                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 419 }
 420
 421
 422 /** Called when a client spawns in the server */
 423 void PutClientInServer()
 424 {
 425         SELFPARAM();
 426         if (IS_BOT_CLIENT(this)) {
 427                 TRANSMUTE(Player, this);
 428         } else if (IS_REAL_CLIENT(this)) {
 429                 msg_entity = this;
 430                 WriteByte(MSG_ONE, SVC_SETVIEW);
 431                 WriteEntity(MSG_ONE, this);
 432         }
 433         if (gameover) {
 434                 TRANSMUTE(Observer, this);
 435         }
 436
 437         SetSpectatee(this, NULL);
 438
 439         // reset player keys
 440         this.itemkeys = 0;
 441
 442         MUTATOR_CALLHOOK(PutClientInServer, this);
 443
 444         if (IS_OBSERVER(this)) {
 445                 PutObserverInServer();
 446         } else if (IS_PLAYER(this)) {
 447                 PlayerState_attach(this);
 448                 accuracy_resend(this);
 449
 450                 if (this.team < 0)
 451                         JoinBestTeam(this, false, true);
 452
 453                 entity spot = SelectSpawnPoint(false);
 454                 if (!spot) {
 455                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 456                         return; // spawn failed
 457                 }
 458
 459                 TRANSMUTE(Player, this);
 460                 this.wasplayer = true;
 461                 this.iscreature = true;
 462                 this.teleportable = TELEPORT_NORMAL;
 463                 this.damagedbycontents = true;
 464                 this.movetype = MOVETYPE_WALK;
 465                 this.solid = SOLID_SLIDEBOX;
 466                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 467                 if (autocvar_g_playerclip_collisions)
 468                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 469                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 470                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 471                 this.frags = FRAGS_PLAYER;
 472                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 473                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 474                 if (autocvar__notarget)
 475                         this.flags |= FL_NOTARGET;
 476                 this.takedamage = DAMAGE_AIM;
 477                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 478                 this.dmg = 2; // WTF
 479
 480                 if (warmup_stage) {
 481                         this.ammo_shells = warmup_start_ammo_shells;
 482                         this.ammo_nails = warmup_start_ammo_nails;
 483                         this.ammo_rockets = warmup_start_ammo_rockets;
 484                         this.ammo_cells = warmup_start_ammo_cells;
 485                         this.ammo_plasma = warmup_start_ammo_plasma;
 486                         this.ammo_fuel = warmup_start_ammo_fuel;
 487                         this.health = warmup_start_health;
 488                         this.armorvalue = warmup_start_armorvalue;
 489                         this.weapons = WARMUP_START_WEAPONS;
 490                 } else {
 491                         this.ammo_shells = start_ammo_shells;
 492                         this.ammo_nails = start_ammo_nails;
 493                         this.ammo_rockets = start_ammo_rockets;
 494                         this.ammo_cells = start_ammo_cells;
 495                         this.ammo_plasma = start_ammo_plasma;
 496                         this.ammo_fuel = start_ammo_fuel;
 497                         this.health = start_health;
 498                         this.armorvalue = start_armorvalue;
 499                         this.weapons = start_weapons;
 500                 }
 501
 502                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 503
 504                 this.items = start_items;
 505
 506                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 507                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 508                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 509                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 510                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 511                 // extend the pause of rotting if client was reset at the beginning of the countdown
 512                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 513                         float f = game_starttime - time;
 514                         this.spawnshieldtime += f;
 515                         this.pauserotarmor_finished += f;
 516                         this.pauserothealth_finished += f;
 517                         this.pauseregen_finished += f;
 518                 }
 519                 this.damageforcescale = 2;
 520                 this.death_time = 0;
 521                 this.respawn_flags = 0;
 522                 this.respawn_time = 0;
 523                 this.stat_respawn_time = 0;
 524                 this.scale = autocvar_sv_player_scale;
 525                 this.fade_time = 0;
 526                 this.pain_frame = 0;
 527                 this.pain_finished = 0;
 528                 this.pushltime = 0;
 529                 this.think = func_null; // players have no think function
 530                 this.nextthink = 0;
 531                 this.dmg_team = 0;
 532                 this.ballistics_density = autocvar_g_ballistics_density_player;
 533
 534                 this.deadflag = DEAD_NO;
 535
 536                 this.angles = spot.angles;
 537                 this.angles_z = 0; // never spawn tilted even if the spot says to
 538                 if (IS_BOT_CLIENT(this))
 539                         this.v_angle = this.angles;
 540                 this.fixangle = true; // turn this way immediately
 541                 this.oldvelocity = this.velocity = '0 0 0';
 542                 this.avelocity = '0 0 0';
 543                 this.punchangle = '0 0 0';
 544                 this.punchvector = '0 0 0';
 545
 546                 this.strength_finished = 0;
 547                 this.invincible_finished = 0;
 548                 this.fire_endtime = -1;
 549                 this.revival_time = 0;
 550                 this.air_finished = time + 12;
 551
 552                 entity spawnevent = new_pure(spawnevent);
 553                 spawnevent.owner = this;
 554                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 555
 556                 // Cut off any still running player sounds.
 557                 stopsound(this, CH_PLAYER_SINGLE);
 558
 559                 this.model = "";
 560                 FixPlayermodel(this);
 561                 this.drawonlytoclient = NULL;
 562
 563                 this.crouch = false;
 564                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 565                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 566                 this.spawnorigin = spot.origin;
 567                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 568                 // don't reset back to last position, even if new position is stuck in solid
 569                 this.oldorigin = this.origin;
 570                 this.prevorigin = this.origin;
 571                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 572         this.hud = HUD_NORMAL;
 573
 574                 this.event_damage = PlayerDamage;
 575
 576                 this.bot_attack = true;
 577                 this.monster_attack = true;
 578
 579                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 580
 581                 if (this.killcount == FRAGS_SPECTATOR) {
 582                         PlayerScore_Clear(this);
 583                         this.killcount = 0;
 584                 }
 585
 586                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 587                 {
 588                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 589                 }
 590                 this.alpha = default_player_alpha;
 591                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 592                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 593
 594                 this.speedrunning = false;
 595
 596                 target_voicescript_clear(this);
 597
 598                 // reset fields the weapons may use
 599                 FOREACH(Weapons, true, LAMBDA(
 600                         it.wr_resetplayer(it);
 601                         // reload all reloadable weapons
 602                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 603                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 604                         }
 605                 ));
 606
 607                 {
 608                         string s = spot.target;
 609                         spot.target = string_null;
 610                         SUB_UseTargets(spot, this, NULL);
 611                         spot.target = s;
 612                 }
 613
 614                 Unfreeze(this);
 615
 616                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 617
 618                 if (autocvar_spawn_debug)
 619                 {
 620                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 621                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 622                 }
 623
 624                 PS(this).m_switchweapon = w_getbestweapon(this);
 625                 this.cnt = -1; // W_LastWeapon will not complain
 626                 PS(this).m_weapon = WEP_Null;
 627                 this.weaponname = "";
 628                 PS(this).m_switchingweapon = WEP_Null;
 629
 630                 if (!warmup_stage && !this.alivetime)
 631                         this.alivetime = time;
 632
 633                 antilag_clear(this, CS(this));
 634         }
 635 }
 636
 637 void ClientInit_misc();
 638
 639 .float ebouncefactor, ebouncestop; // electro's values
 640 // TODO do we need all these fields, or should we stop autodetecting runtime
 641 // changes and just have a console command to update this?
 642 bool ClientInit_SendEntity(entity this, entity to, int sf)
 643 {
 644         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 645         return = true;
 646         msg_entity = to;
 647         // MSG_INIT replacement
 648         // TODO: make easier to use
 649         Registry_send_all();
 650         W_PROP_reload(MSG_ONE, to);
 651         ClientInit_misc();
 652         MUTATOR_CALLHOOK(Ent_Init);
 653 }
 654 void ClientInit_misc()
 655 {
 656     SELFPARAM();
 657         int channel = MSG_ONE;
 658         WriteHeader(channel, ENT_CLIENT_INIT);
 659         WriteByte(channel, g_nexball_meter_period * 32);
 660         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 661         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 662         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 663         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 664         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 665         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 666         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 667         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 668
 669         if(sv_foginterval && world.fog != "")
 670                 WriteString(channel, world.fog);
 671         else
 672                 WriteString(channel, "");
 673         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 674         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 675         WriteCoord(channel, autocvar_g_trueaim_minrange);
 676 }
 677
 678 void ClientInit_CheckUpdate()
 679 {SELFPARAM();
 680         this.nextthink = time;
 681         if(this.count != autocvar_g_balance_armor_blockpercent)
 682         {
 683                 this.count = autocvar_g_balance_armor_blockpercent;
 684                 this.SendFlags |= 1;
 685         }
 686 }
 687
 688 void ClientInit_Spawn()
 689 {SELFPARAM();
 690
 691         entity e = new_pure(clientinit);
 692         e.think = ClientInit_CheckUpdate;
 693         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 694
 695         WITHSELF(e, ClientInit_CheckUpdate());
 696 }
 697
 698 /*
 699 =============
 700 SetNewParms
 701 =============
 702 */
 703 void SetNewParms ()
 704 {
 705         // initialize parms for a new player
 706         parm1 = -(86400 * 366);
 707
 708         MUTATOR_CALLHOOK(SetNewParms);
 709 }
 710
 711 /*
 712 =============
 713 SetChangeParms
 714 =============
 715 */
 716 void SetChangeParms ()
 717 {SELFPARAM();
 718         // save parms for level change
 719         parm1 = this.parm_idlesince - time;
 720
 721         MUTATOR_CALLHOOK(SetChangeParms);
 722 }
 723
 724 /*
 725 =============
 726 DecodeLevelParms
 727 =============
 728 */
 729 void DecodeLevelParms(entity this)
 730 {
 731         // load parms
 732         this.parm_idlesince = parm1;
 733         if (this.parm_idlesince == -(86400 * 366))
 734                 this.parm_idlesince = time;
 735
 736         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 737         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 738
 739         MUTATOR_CALLHOOK(DecodeLevelParms);
 740 }
 741
 742 /*
 743 =============
 744 ClientKill
 745
 746 Called when a client types 'kill' in the console
 747 =============
 748 */
 749
 750 .float clientkill_nexttime;
 751 void ClientKill_Now_TeamChange(entity this)
 752 {
 753         if(this.killindicator_teamchange == -1)
 754         {
 755                 JoinBestTeam( this, false, true );
 756         }
 757         else if(this.killindicator_teamchange == -2)
 758         {
 759                 if(blockSpectators)
 760                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 761                 WITHSELF(this, PutObserverInServer());
 762         }
 763         else
 764                 WITHSELF(this, SV_ChangeTeam(this.killindicator_teamchange - 1));
 765         this.killindicator_teamchange = 0;
 766 }
 767
 768 void ClientKill_Now()
 769 {SELFPARAM();
 770         if(this.vehicle)
 771         {
 772             vehicles_exit(VHEF_RELEASE);
 773             if(!this.killindicator_teamchange)
 774             {
 775             this.vehicle_health = -1;
 776             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 777             }
 778         }
 779
 780         if(this.killindicator && !wasfreed(this.killindicator))
 781                 remove(this.killindicator);
 782
 783         this.killindicator = world;
 784
 785         if(this.killindicator_teamchange)
 786                 ClientKill_Now_TeamChange(this);
 787
 788         if(IS_PLAYER(this))
 789                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 790
 791         // now I am sure the player IS dead
 792 }
 793 void KillIndicator_Think()
 794 {SELFPARAM();
 795         if (gameover)
 796         {
 797                 this.owner.killindicator = world;
 798                 remove(this);
 799                 return;
 800         }
 801
 802         if (this.owner.alpha < 0 && !this.owner.vehicle)
 803         {
 804                 this.owner.killindicator = world;
 805                 remove(this);
 806                 return;
 807         }
 808
 809         if(this.cnt <= 0)
 810         {
 811                 WITHSELF(this.owner, ClientKill_Now());
 812                 return;
 813         }
 814     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 815     {
 816         this.nextthink = time + 1;
 817         this.cnt -= 1;
 818     }
 819         else
 820         {
 821                 if(this.cnt <= 10)
 822                         setmodel(this, MDL_NUM(this.cnt));
 823                 if(IS_REAL_CLIENT(this.owner))
 824                 {
 825                         if(this.cnt <= 10)
 826                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 827                 }
 828                 this.nextthink = time + 1;
 829                 this.cnt -= 1;
 830         }
 831 }
 832
 833 float clientkilltime;
 834 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 835 {SELFPARAM();
 836         float killtime;
 837         float starttime;
 838         entity e;
 839
 840         if (gameover)
 841                 return;
 842
 843         killtime = autocvar_g_balance_kill_delay;
 844
 845         if(g_race_qualifying || g_cts)
 846                 killtime = 0;
 847
 848     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 849         return;
 850
 851         this.killindicator_teamchange = targetteam;
 852
 853     if(!this.killindicator)
 854         {
 855                 if(!IS_DEAD(this))
 856                 {
 857                         killtime = max(killtime, this.clientkill_nexttime - time);
 858                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 859                 }
 860
 861                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 862                 {
 863                         ClientKill_Now();
 864                 }
 865                 else
 866                 {
 867                         starttime = max(time, clientkilltime);
 868
 869                         this.killindicator = spawn();
 870                         this.killindicator.owner = this;
 871                         this.killindicator.scale = 0.5;
 872                         setattachment(this.killindicator, this, "");
 873                         setorigin(this.killindicator, '0 0 52');
 874                         this.killindicator.think = KillIndicator_Think;
 875                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 876                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 877                         this.killindicator.cnt = ceil(killtime);
 878                         this.killindicator.count = bound(0, ceil(killtime), 10);
 879                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 880
 881                         for(e = world; (e = find(e, classname, "body")) != world; )
 882                         {
 883                                 if(e.enemy != this)
 884                                         continue;
 885                                 e.killindicator = spawn();
 886                                 e.killindicator.owner = e;
 887                                 e.killindicator.scale = 0.5;
 888                                 setattachment(e.killindicator, e, "");
 889                                 setorigin(e.killindicator, '0 0 52');
 890                                 e.killindicator.think = KillIndicator_Think;
 891                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 892                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 893                                 e.killindicator.cnt = ceil(killtime);
 894                         }
 895                         this.lip = 0;
 896                 }
 897         }
 898         if(this.killindicator)
 899         {
 900                 if(targetteam == 0) // just die
 901                 {
 902                         this.killindicator.colormod = '0 0 0';
 903                         if(IS_REAL_CLIENT(this))
 904                         if(this.killindicator.cnt > 0)
 905                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 906                 }
 907                 else if(targetteam == -1) // auto
 908                 {
 909                         this.killindicator.colormod = '0 1 0';
 910                         if(IS_REAL_CLIENT(this))
 911                         if(this.killindicator.cnt > 0)
 912                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 913                 }
 914                 else if(targetteam == -2) // spectate
 915                 {
 916                         this.killindicator.colormod = '0.5 0.5 0.5';
 917                         if(IS_REAL_CLIENT(this))
 918                         if(this.killindicator.cnt > 0)
 919                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 920                 }
 921                 else
 922                 {
 923                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 924                         if(IS_REAL_CLIENT(this))
 925                         if(this.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 927                 }
 928         }
 929
 930 }
 931
 932 void ClientKill ()
 933 {SELFPARAM();
 934         if(gameover) return;
 935         if(this.player_blocked) return;
 936         if(STAT(FROZEN, this)) return;
 937
 938         ClientKill_TeamChange(0);
 939 }
 940
 941 void FixClientCvars(entity e)
 942 {
 943         // send prediction settings to the client
 944         stuffcmd(e, "\nin_bindmap 0 0\n");
 945         if(autocvar_g_antilag == 3) // client side hitscan
 946                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 947         if(autocvar_sv_gentle)
 948                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 949
 950         MUTATOR_CALLHOOK(FixClientCvars, e);
 951 }
 952
 953 float PlayerInIDList(entity p, string idlist)
 954 {
 955         float n, i;
 956         string s;
 957
 958         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 959         if (!p.crypto_idfp)
 960                 return 0;
 961
 962         // this function allows abbreviated player IDs too!
 963         n = tokenize_console(idlist);
 964         for(i = 0; i < n; ++i)
 965         {
 966                 s = argv(i);
 967                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 968                         return 1;
 969         }
 970
 971         return 0;
 972 }
 973
 974 #ifdef DP_EXT_PRECONNECT
 975 /*
 976 =============
 977 ClientPreConnect
 978
 979 Called once (not at each match start) when a client begins a connection to the server
 980 =============
 981 */
 982 void ClientPreConnect ()
 983 {SELFPARAM();
 984         if(autocvar_sv_eventlog)
 985         {
 986                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 987                         this.playerid,
 988                         etof(this),
 989                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 990                 ));
 991         }
 992 }
 993 #endif
 994
 995 /**
 996 =============
 997 ClientConnect
 998
 999 Called when a client connects to the server
1000 =============
1001 */
1002 void ClientConnect()
1003 {
1004         SELFPARAM();
1005         if (Ban_MaybeEnforceBanOnce(this)) return;
1006         assert(!IS_CLIENT(this), return);
1007         this.flags |= FL_CLIENT;
1008         assert(player_count >= 0, player_count = 0);
1009
1010 #ifdef WATERMARK
1011         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1012 #endif
1013         this.version_nagtime = time + 10 + random() * 10;
1014         TRANSMUTE(Client, this);
1015
1016         // identify the right forced team
1017         if (autocvar_g_campaign)
1018         {
1019                 if (IS_REAL_CLIENT(this)) // only players, not bots
1020                 {
1021                         switch (autocvar_g_campaign_forceteam)
1022                         {
1023                                 case 1: this.team_forced = NUM_TEAM_1; break;
1024                                 case 2: this.team_forced = NUM_TEAM_2; break;
1025                                 case 3: this.team_forced = NUM_TEAM_3; break;
1026                                 case 4: this.team_forced = NUM_TEAM_4; break;
1027                                 default: this.team_forced = 0;
1028                         }
1029                 }
1030         }
1031         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1032         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1033         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1034         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1035         else switch (autocvar_g_forced_team_otherwise)
1036         {
1037                 default: this.team_forced = 0; break;
1038                 case "red": this.team_forced = NUM_TEAM_1; break;
1039                 case "blue": this.team_forced = NUM_TEAM_2; break;
1040                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1041                 case "pink": this.team_forced = NUM_TEAM_4; break;
1042                 case "spectate":
1043                 case "spectator":
1044                         this.team_forced = -1;
1045                         break;
1046         }
1047         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1048
1049     {
1050         int id = this.playerid;
1051         this.playerid = 0; // silent
1052             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1053             this.playerid = id;
1054     }
1055
1056         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1057                 TRANSMUTE(Observer, this);
1058         } else {
1059                 if (!teamplay || autocvar_g_balance_teams) {
1060                         TRANSMUTE(Player, this);
1061                         campaign_bots_may_start = true;
1062                 } else {
1063                         TRANSMUTE(Observer, this); // do it anyway
1064                 }
1065         }
1066
1067         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1068
1069         // always track bots, don't ask for cl_allow_uidtracking
1070     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1071
1072         if (autocvar_sv_eventlog)
1073                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1074
1075         LogTeamchange(this.playerid, this.team, 1);
1076
1077         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1078
1079         this.netname_previous = strzone(this.netname);
1080
1081         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1082
1083         stuffcmd(this, clientstuff, "\n");
1084         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1085
1086         FixClientCvars(this);
1087
1088         // get version info from player
1089         stuffcmd(this, "cmd clientversion $gameversion\n");
1090
1091         // notify about available teams
1092         if (teamplay)
1093         {
1094                 CheckAllowedTeams(this);
1095                 int t = 0;
1096                 if (c1 >= 0) t |= BIT(0);
1097                 if (c2 >= 0) t |= BIT(1);
1098                 if (c3 >= 0) t |= BIT(2);
1099                 if (c4 >= 0) t |= BIT(3);
1100                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1101         }
1102         else
1103         {
1104                 stuffcmd(this, "set _teams_available 0\n");
1105         }
1106
1107         bot_relinkplayerlist();
1108
1109         this.spectatortime = time;
1110         if (blockSpectators)
1111         {
1112                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1113         }
1114
1115         this.jointime = time;
1116         this.allowed_timeouts = autocvar_sv_timeout_number;
1117
1118         if (IS_REAL_CLIENT(this))
1119         {
1120                 if (!autocvar_g_campaign)
1121                 {
1122                         this.motd_actived_time = -1;
1123                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1124                 }
1125
1126                 if (g_weaponarena_weapons == WEPSET(TUBA))
1127                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1128         }
1129
1130         if (!sv_foginterval && world.fog != "")
1131                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1132
1133         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)))
1134                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1135                         send_CSQC_teamnagger();
1136
1137         CSQCMODEL_AUTOINIT(this);
1138
1139         this.model_randomizer = random();
1140
1141         if (IS_REAL_CLIENT(this))
1142                 sv_notice_join(this);
1143
1144         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1145                 WITHSELF(it, it.init_for_player(it));
1146         });
1147
1148         MUTATOR_CALLHOOK(ClientConnect, this);
1149 }
1150 /*
1151 =============
1152 ClientDisconnect
1153
1154 Called when a client disconnects from the server
1155 =============
1156 */
1157 .entity chatbubbleentity;
1158 void ReadyCount();
1159 void ClientDisconnect()
1160 {
1161         SELFPARAM();
1162         assert(IS_CLIENT(this), return);
1163
1164         PlayerStats_GameReport_FinalizePlayer(this);
1165         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
1166         if (this.active_minigame) part_minigame(this);
1167         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1168
1169         if (autocvar_sv_eventlog)
1170                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1171
1172         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1173
1174     MUTATOR_CALLHOOK(ClientDisconnect);
1175
1176         ClientState_detach(this);
1177
1178         Portal_ClearAll(this);
1179
1180         Unfreeze(this);
1181
1182         RemoveGrapplingHook(this);
1183
1184         // Here, everything has been done that requires this player to be a client.
1185
1186         this.flags &= ~FL_CLIENT;
1187
1188         if (this.chatbubbleentity) remove(this.chatbubbleentity);
1189         if (this.killindicator) remove(this.killindicator);
1190
1191         WaypointSprite_PlayerGone();
1192
1193         bot_relinkplayerlist();
1194
1195         if (this.netname_previous) strunzone(this.netname_previous);
1196         if (this.clientstatus) strunzone(this.clientstatus);
1197         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1198         if (this.personal) remove(this.personal);
1199
1200         this.playerid = 0;
1201         ReadyCount();
1202         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1203 }
1204
1205 void ChatBubbleThink()
1206 {SELFPARAM();
1207         this.nextthink = time;
1208         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1209         {
1210                 if(this.owner) // but why can that ever be world?
1211                         this.owner.chatbubbleentity = world;
1212                 remove(this);
1213                 return;
1214         }
1215
1216         this.mdl = "";
1217
1218         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1219         {
1220                 if ( this.owner.active_minigame )
1221                         this.mdl = "models/sprites/minigame_busy.iqm";
1222                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1223                         this.mdl = "models/misc/chatbubble.spr";
1224         }
1225
1226         if ( this.model != this.mdl )
1227                 _setmodel(this, this.mdl);
1228
1229 }
1230
1231 void UpdateChatBubble()
1232 {SELFPARAM();
1233         if (this.alpha < 0)
1234                 return;
1235         // spawn a chatbubble entity if needed
1236         if (!this.chatbubbleentity)
1237         {
1238                 this.chatbubbleentity = new(chatbubbleentity);
1239                 this.chatbubbleentity.owner = this;
1240                 this.chatbubbleentity.exteriormodeltoclient = this;
1241                 this.chatbubbleentity.think = ChatBubbleThink;
1242                 this.chatbubbleentity.nextthink = time;
1243                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1244                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1245                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1246                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1247                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1248                 //this.chatbubbleentity.model = "";
1249                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1250         }
1251 }
1252
1253
1254 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1255 // added to the model skins
1256 /*void UpdateColorModHack()
1257 {
1258         float c;
1259         c = this.clientcolors & 15;
1260         // LordHavoc: only bothering to support white, green, red, yellow, blue
1261              if (!teamplay) this.colormod = '0 0 0';
1262         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1263         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1264         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1265         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1266         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1267         else this.colormod = '1 1 1';
1268 }*/
1269
1270 void respawn()
1271 {SELFPARAM();
1272         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1273         {
1274                 this.solid = SOLID_NOT;
1275                 this.takedamage = DAMAGE_NO;
1276                 this.movetype = MOVETYPE_FLY;
1277                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1278                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1279                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1280                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1281                 if(autocvar_g_respawn_ghosts_maxtime)
1282                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1283         }
1284
1285         CopyBody(this, 1);
1286
1287         this.effects |= EF_NODRAW; // prevent another CopyBody
1288         PutClientInServer();
1289 }
1290
1291 void play_countdown(float finished, Sound samp)
1292 {SELFPARAM();
1293     TC(Sound, samp);
1294         if(IS_REAL_CLIENT(this))
1295                 if(floor(finished - time - frametime) != floor(finished - time))
1296                         if(finished - time < 6)
1297                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1298 }
1299
1300 void player_powerups ()
1301 {SELFPARAM();
1302         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1303         int items_prev = this.items;
1304
1305         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1306                 this.modelflags |= MF_ROCKET;
1307         else
1308                 this.modelflags &= ~MF_ROCKET;
1309
1310         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1311
1312         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1313                 return;
1314
1315         Fire_ApplyDamage(this);
1316         Fire_ApplyEffect(this);
1317
1318         if (!g_instagib)
1319         {
1320                 if (this.items & ITEM_Strength.m_itemid)
1321                 {
1322                         play_countdown(this.strength_finished, SND_POWEROFF);
1323                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1324                         if (time > this.strength_finished)
1325                         {
1326                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1327                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1328                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1329                         }
1330                 }
1331                 else
1332                 {
1333                         if (time < this.strength_finished)
1334                         {
1335                                 this.items = this.items | ITEM_Strength.m_itemid;
1336                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1337                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1338                         }
1339                 }
1340                 if (this.items & ITEM_Shield.m_itemid)
1341                 {
1342                         play_countdown(this.invincible_finished, SND_POWEROFF);
1343                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1344                         if (time > this.invincible_finished)
1345                         {
1346                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1347                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1348                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1349                         }
1350                 }
1351                 else
1352                 {
1353                         if (time < this.invincible_finished)
1354                         {
1355                                 this.items = this.items | ITEM_Shield.m_itemid;
1356                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1357                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1358                         }
1359                 }
1360                 if (this.items & IT_SUPERWEAPON)
1361                 {
1362                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1363                         {
1364                                 this.superweapons_finished = 0;
1365                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1366                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1367                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1368                         }
1369                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1370                         {
1371                                 // don't let them run out
1372                         }
1373                         else
1374                         {
1375                                 play_countdown(this.superweapons_finished, SND_POWEROFF);
1376                                 if (time > this.superweapons_finished)
1377                                 {
1378                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1379                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1380                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1381                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1382                                 }
1383                         }
1384                 }
1385                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1386                 {
1387                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1388                         {
1389                                 this.items = this.items | IT_SUPERWEAPON;
1390                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1391                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1392                         }
1393                         else
1394                         {
1395                                 this.superweapons_finished = 0;
1396                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1397                         }
1398                 }
1399                 else
1400                 {
1401                         this.superweapons_finished = 0;
1402                 }
1403         }
1404
1405         if(autocvar_g_nodepthtestplayers)
1406                 this.effects = this.effects | EF_NODEPTHTEST;
1407
1408         if(autocvar_g_fullbrightplayers)
1409                 this.effects = this.effects | EF_FULLBRIGHT;
1410
1411         if (time >= game_starttime)
1412         if (time < this.spawnshieldtime)
1413                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1414
1415         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1416 }
1417
1418 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1419 {
1420         if(current > stable)
1421                 return current;
1422         else if(current > stable - 0.25) // when close enough, "snap"
1423                 return stable;
1424         else
1425                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1426 }
1427
1428 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1429 {
1430         if(current < stable)
1431                 return current;
1432         else if(current < stable + 0.25) // when close enough, "snap"
1433                 return stable;
1434         else
1435                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1436 }
1437
1438 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1439 {
1440         if(current > rotstable)
1441         {
1442                 if(rotframetime > 0)
1443                 {
1444                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1445                         current = max(rotstable, current - rotlinear * rotframetime);
1446                 }
1447         }
1448         else if(current < regenstable)
1449         {
1450                 if(regenframetime > 0)
1451                 {
1452                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1453                         current = min(regenstable, current + regenlinear * regenframetime);
1454                 }
1455         }
1456
1457         if(current > limit)
1458                 current = limit;
1459
1460         return current;
1461 }
1462
1463 void player_regen ()
1464 {SELFPARAM();
1465         float max_mod, regen_mod, rot_mod, limit_mod;
1466         max_mod = regen_mod = rot_mod = limit_mod = 1;
1467         regen_mod_max = max_mod;
1468         regen_mod_regen = regen_mod;
1469         regen_mod_rot = rot_mod;
1470         regen_mod_limit = limit_mod;
1471
1472         regen_health = autocvar_g_balance_health_regen;
1473         regen_health_linear = autocvar_g_balance_health_regenlinear;
1474         regen_health_rot = autocvar_g_balance_health_rot;
1475         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1476         regen_health_stable = autocvar_g_balance_health_regenstable;
1477         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1478         if(!MUTATOR_CALLHOOK(PlayerRegen))
1479         if(!STAT(FROZEN, this))
1480         {
1481                 float mina, maxa, limith, limita;
1482                 maxa = autocvar_g_balance_armor_rotstable;
1483                 mina = autocvar_g_balance_armor_regenstable;
1484                 limith = autocvar_g_balance_health_limit;
1485                 limita = autocvar_g_balance_armor_limit;
1486
1487                 max_mod = regen_mod_max;
1488                 regen_mod = regen_mod_regen;
1489                 rot_mod = regen_mod_rot;
1490                 limit_mod = regen_mod_limit;
1491
1492                 regen_health_rotstable = regen_health_rotstable * max_mod;
1493                 regen_health_stable = regen_health_stable * max_mod;
1494                 limith = limith * limit_mod;
1495                 limita = limita * limit_mod;
1496
1497                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1498                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1499         }
1500
1501         // if player rotted to death...  die!
1502         // check this outside above checks, as player may still be able to rot to death
1503         if(this.health < 1)
1504         {
1505                 if(this.vehicle)
1506                         vehicles_exit(VHEF_RELEASE);
1507                 if(this.event_damage)
1508                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1509         }
1510
1511         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1512         {
1513                 float minf, maxf, limitf;
1514
1515                 maxf = autocvar_g_balance_fuel_rotstable;
1516                 minf = autocvar_g_balance_fuel_regenstable;
1517                 limitf = autocvar_g_balance_fuel_limit;
1518
1519                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1520         }
1521 }
1522
1523 bool zoomstate_set;
1524 void SetZoomState(float z)
1525 {SELFPARAM();
1526         if(z != this.zoomstate)
1527         {
1528                 this.zoomstate = z;
1529                 ClientData_Touch(this);
1530         }
1531         zoomstate_set = true;
1532 }
1533
1534 void GetPressedKeys()
1535 {
1536         SELFPARAM();
1537         MUTATOR_CALLHOOK(GetPressedKeys);
1538         int keys = this.pressedkeys;
1539         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1540         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1541         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1542         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1543
1544         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1545         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1546         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1547         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1548         this.pressedkeys = keys;
1549 }
1550
1551 /*
1552 ======================
1553 spectate mode routines
1554 ======================
1555 */
1556
1557 void SpectateCopy(entity this, entity spectatee)
1558 {
1559     TC(Client, this); TC(Client, spectatee);
1560
1561         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1562         PS(this) = PS(spectatee);
1563         this.armortype = spectatee.armortype;
1564         this.armorvalue = spectatee.armorvalue;
1565         this.ammo_cells = spectatee.ammo_cells;
1566         this.ammo_plasma = spectatee.ammo_plasma;
1567         this.ammo_shells = spectatee.ammo_shells;
1568         this.ammo_nails = spectatee.ammo_nails;
1569         this.ammo_rockets = spectatee.ammo_rockets;
1570         this.ammo_fuel = spectatee.ammo_fuel;
1571         this.clip_load = spectatee.clip_load;
1572         this.clip_size = spectatee.clip_size;
1573         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1574         this.health = spectatee.health;
1575         this.impulse = 0;
1576         this.items = spectatee.items;
1577         this.last_pickup = spectatee.last_pickup;
1578         this.hit_time = spectatee.hit_time;
1579         this.strength_finished = spectatee.strength_finished;
1580         this.invincible_finished = spectatee.invincible_finished;
1581         this.pressedkeys = spectatee.pressedkeys;
1582         this.weapons = spectatee.weapons;
1583         this.vortex_charge = spectatee.vortex_charge;
1584         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1585         this.hagar_load = spectatee.hagar_load;
1586         this.arc_heat_percent = spectatee.arc_heat_percent;
1587         this.minelayer_mines = spectatee.minelayer_mines;
1588         this.punchangle = spectatee.punchangle;
1589         this.view_ofs = spectatee.view_ofs;
1590         this.velocity = spectatee.velocity;
1591         this.dmg_take = spectatee.dmg_take;
1592         this.dmg_save = spectatee.dmg_save;
1593         this.dmg_inflictor = spectatee.dmg_inflictor;
1594         this.v_angle = spectatee.v_angle;
1595         this.angles = spectatee.v_angle;
1596         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1597         this.revive_progress = spectatee.revive_progress;
1598         if(!PHYS_INPUT_BUTTON_USE(this))
1599                 this.fixangle = true;
1600         setorigin(this, spectatee.origin);
1601         setsize(this, spectatee.mins, spectatee.maxs);
1602         SetZoomState(spectatee.zoomstate);
1603
1604     anticheat_spectatecopy(this, spectatee);
1605         this.hud = spectatee.hud;
1606         if(spectatee.vehicle)
1607     {
1608         this.fixangle = false;
1609         //this.velocity = spectatee.vehicle.velocity;
1610         this.vehicle_health = spectatee.vehicle_health;
1611         this.vehicle_shield = spectatee.vehicle_shield;
1612         this.vehicle_energy = spectatee.vehicle_energy;
1613         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1614         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1615         this.vehicle_reload1 = spectatee.vehicle_reload1;
1616         this.vehicle_reload2 = spectatee.vehicle_reload2;
1617
1618         msg_entity = this;
1619
1620         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1621             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1622             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1623             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1624
1625         //WriteByte (MSG_ONE, SVC_SETVIEW);
1626         //    WriteEntity(MSG_ONE, this);
1627         //makevectors(spectatee.v_angle);
1628         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1629     }
1630 }
1631
1632 bool SpectateUpdate()
1633 {SELFPARAM();
1634         if(!this.enemy)
1635             return false;
1636
1637         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1638         {
1639                 SetSpectatee(this, NULL);
1640                 return false;
1641         }
1642
1643         SpectateCopy(this, this.enemy);
1644
1645         return true;
1646 }
1647
1648 bool SpectateSet()
1649 {SELFPARAM();
1650         if(!IS_PLAYER(this.enemy))
1651                 return false;
1652
1653         msg_entity = this;
1654         WriteByte(MSG_ONE, SVC_SETVIEW);
1655         WriteEntity(MSG_ONE, this.enemy);
1656         this.movetype = MOVETYPE_NONE;
1657         accuracy_resend(this);
1658
1659         if(!SpectateUpdate())
1660                 PutObserverInServer();
1661
1662         return true;
1663 }
1664
1665 void SetSpectatee(entity player, entity spectatee)
1666 {
1667         entity old_spectatee = player.enemy;
1668
1669         player.enemy = spectatee;
1670
1671         // WEAPONTODO
1672         // these are required to fix the spectator bug with arc
1673         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1674         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1675 }
1676
1677 bool Spectate(entity pl)
1678 {SELFPARAM();
1679         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1680                 return false;
1681         pl = spec_player;
1682
1683         SetSpectatee(this, pl);
1684         return SpectateSet();
1685 }
1686
1687 bool SpectateNext()
1688 {SELFPARAM();
1689         other = find(this.enemy, classname, STR_PLAYER);
1690
1691         if (MUTATOR_CALLHOOK(SpectateNext, this, other))
1692                 other = spec_player;
1693         else if (!other)
1694                 other = find(other, classname, STR_PLAYER);
1695
1696         if(other) { SetSpectatee(this, other); }
1697
1698         return SpectateSet();
1699 }
1700
1701 bool SpectatePrev()
1702 {SELFPARAM();
1703         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1704         other = findchain(classname, STR_PLAYER);
1705         if (!other) // no player
1706                 return false;
1707
1708         entity first = other;
1709         // skip players until current spectated player
1710         if(this.enemy)
1711         while(other && other != this.enemy)
1712                 other = other.chain;
1713
1714         switch (MUTATOR_CALLHOOK(SpectatePrev, this, other, first))
1715         {
1716                 case MUT_SPECPREV_FOUND:
1717                     other = spec_player;
1718                     break;
1719                 case MUT_SPECPREV_RETURN:
1720                     other = spec_player;
1721                     return true;
1722                 case MUT_SPECPREV_CONTINUE:
1723                 default:
1724                 {
1725                         if(other.chain)
1726                                 other = other.chain;
1727                         else
1728                                 other = first;
1729                         break;
1730                 }
1731         }
1732
1733         SetSpectatee(this, other);
1734         return SpectateSet();
1735 }
1736
1737 /*
1738 =============
1739 ShowRespawnCountdown()
1740
1741 Update a respawn countdown display.
1742 =============
1743 */
1744 void ShowRespawnCountdown()
1745 {SELFPARAM();
1746         float number;
1747         if(!IS_DEAD(this)) // just respawned?
1748                 return;
1749         else
1750         {
1751                 number = ceil(this.respawn_time - time);
1752                 if(number <= 0)
1753                         return;
1754                 if(number <= this.respawn_countdown)
1755                 {
1756                         this.respawn_countdown = number - 1;
1757                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1758                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1759                 }
1760         }
1761 }
1762
1763 void LeaveSpectatorMode()
1764 {SELFPARAM();
1765         if(this.caplayer)
1766                 return;
1767         if(nJoinAllowed(this, this))
1768         {
1769                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1770                 {
1771                         TRANSMUTE(Player, this);
1772
1773                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1774                                 { JoinBestTeam(this, false, true); }
1775
1776                         if(autocvar_g_campaign)
1777                                 { campaign_bots_may_start = true; }
1778
1779                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1780
1781                         PutClientInServer();
1782
1783                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1784                 }
1785                 else
1786                         stuffcmd(this, "menu_showteamselect\n");
1787         }
1788         else
1789         {
1790                 // Player may not join because g_maxplayers is set
1791                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1792         }
1793 }
1794
1795 /**
1796  * Determines whether the player is allowed to join. This depends on cvar
1797  * g_maxplayers, if it isn't used this function always return true, otherwise
1798  * it checks whether the number of currently playing players exceeds g_maxplayers.
1799  * @return int number of free slots for players, 0 if none
1800  */
1801 bool nJoinAllowed(entity this, entity ignore)
1802 {
1803         if(!ignore)
1804         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1805         // so report 0 free slots if restricted
1806         {
1807                 if(autocvar_g_forced_team_otherwise == "spectate")
1808                         return false;
1809                 if(autocvar_g_forced_team_otherwise == "spectator")
1810                         return false;
1811         }
1812
1813         if(this.team_forced < 0)
1814                 return false; // forced spectators can never join
1815
1816         // TODO simplify this
1817         int totalClients = 0;
1818         int currentlyPlaying = 0;
1819         FOREACH_CLIENT(true, LAMBDA(
1820                 if(it != ignore)
1821                         ++totalClients;
1822                 if(IS_REAL_CLIENT(it))
1823                 if(IS_PLAYER(it) || it.caplayer)
1824                         ++currentlyPlaying;
1825         ));
1826
1827         if (!autocvar_g_maxplayers)
1828                 return maxclients - totalClients;
1829
1830         if(currentlyPlaying < autocvar_g_maxplayers)
1831                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1832
1833         return false;
1834 }
1835
1836 /**
1837  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1838  * g_maxplayers_spectator_blocktime seconds
1839  */
1840 void checkSpectatorBlock()
1841 {SELFPARAM();
1842         if(IS_SPEC(this) || IS_OBSERVER(this))
1843         if(!this.caplayer)
1844         if(IS_REAL_CLIENT(this))
1845         {
1846                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1847                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1848                         dropclient(this);
1849                 }
1850         }
1851 }
1852
1853 void PrintWelcomeMessage(entity this)
1854 {
1855         if(this.motd_actived_time == 0)
1856         {
1857                 if (autocvar_g_campaign) {
1858                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1859                                 this.motd_actived_time = time;
1860                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1861                         }
1862                 } else {
1863                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1864                                 this.motd_actived_time = time;
1865                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1866                         }
1867                 }
1868         }
1869         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1870         {
1871                 if (autocvar_g_campaign) {
1872                         if (PHYS_INPUT_BUTTON_INFO(this))
1873                                 this.motd_actived_time = time;
1874                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1875                                 this.motd_actived_time = 0;
1876                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1877                         }
1878                 } else {
1879                         if (PHYS_INPUT_BUTTON_INFO(this))
1880                                 this.motd_actived_time = time;
1881                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1882                                 this.motd_actived_time = 0;
1883                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1884                         }
1885                 }
1886         }
1887         else //if(this.motd_actived_time < 0) // just connected, motd is active
1888         {
1889                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1890                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1891                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1892                 {
1893                         // instanctly hide MOTD
1894                         this.motd_actived_time = 0;
1895                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1896                 }
1897         }
1898 }
1899
1900 void ObserverThink()
1901 {SELFPARAM();
1902         if ( this.impulse )
1903         {
1904                 MinigameImpulse(this, this.impulse);
1905                 this.impulse = 0;
1906         }
1907         float prefered_movetype;
1908         if (this.flags & FL_JUMPRELEASED) {
1909                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1910                         this.flags &= ~FL_JUMPRELEASED;
1911                         this.flags |= FL_SPAWNING;
1912                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1913                         this.flags &= ~FL_JUMPRELEASED;
1914                         if(SpectateNext()) {
1915                                 TRANSMUTE(Spectator, this);
1916                         }
1917                 } else {
1918                         prefered_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
1919                         if (this.movetype != prefered_movetype)
1920                                 this.movetype = prefered_movetype;
1921                 }
1922         } else {
1923                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
1924                         this.flags |= FL_JUMPRELEASED;
1925                         if(this.flags & FL_SPAWNING)
1926                         {
1927                                 this.flags &= ~FL_SPAWNING;
1928                                 LeaveSpectatorMode();
1929                                 return;
1930                         }
1931                 }
1932         }
1933 }
1934
1935 void SpectatorThink()
1936 {SELFPARAM();
1937         if ( this.impulse )
1938         {
1939                 if(MinigameImpulse(this, this.impulse))
1940                         this.impulse = 0;
1941         }
1942         if (this.flags & FL_JUMPRELEASED) {
1943                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1944                         this.flags &= ~FL_JUMPRELEASED;
1945                         this.flags |= FL_SPAWNING;
1946                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
1947                         this.flags &= ~FL_JUMPRELEASED;
1948                         if(SpectateNext()) {
1949                                 TRANSMUTE(Spectator, this);
1950                         } else {
1951                                 TRANSMUTE(Observer, this);
1952                                 PutClientInServer();
1953                         }
1954                         this.impulse = 0;
1955                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
1956                         this.flags &= ~FL_JUMPRELEASED;
1957                         if(SpectatePrev()) {
1958                                 TRANSMUTE(Spectator, this);
1959                         } else {
1960                                 TRANSMUTE(Observer, this);
1961                                 PutClientInServer();
1962                         }
1963                         this.impulse = 0;
1964                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
1965                         this.flags &= ~FL_JUMPRELEASED;
1966                         TRANSMUTE(Observer, this);
1967                         PutClientInServer();
1968                 } else {
1969                         if(!SpectateUpdate())
1970                                 PutObserverInServer();
1971                 }
1972         } else {
1973                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
1974                         this.flags |= FL_JUMPRELEASED;
1975                         if(this.flags & FL_SPAWNING)
1976                         {
1977                                 this.flags &= ~FL_SPAWNING;
1978                                 LeaveSpectatorMode();
1979                                 return;
1980                         }
1981                 }
1982                 if(!SpectateUpdate())
1983                         PutObserverInServer();
1984         }
1985
1986         this.flags |= FL_CLIENT | FL_NOTARGET;
1987 }
1988
1989 void vehicles_enter (entity pl, entity veh);
1990 void PlayerUseKey()
1991 {SELFPARAM();
1992         if (!IS_PLAYER(this))
1993                 return;
1994
1995         if(this.vehicle)
1996         {
1997                 if(!gameover)
1998                 {
1999                         vehicles_exit(VHEF_NORMAL);
2000                         return;
2001                 }
2002         }
2003         else if(autocvar_g_vehicles_enter)
2004         {
2005                 if(!STAT(FROZEN, this))
2006                 if(!IS_DEAD(this))
2007                 if(!gameover)
2008                 {
2009                         entity head, closest_target = world;
2010                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2011
2012                         while(head) // find the closest acceptable target to enter
2013                         {
2014                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2015                                 if(!IS_DEAD(head))
2016                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2017                                 if(head.takedamage != DAMAGE_NO)
2018                                 {
2019                                         if(closest_target)
2020                                         {
2021                                                 if(vlen(this.origin - head.origin) < vlen(this.origin - closest_target.origin))
2022                                                 { closest_target = head; }
2023                                         }
2024                                         else { closest_target = head; }
2025                                 }
2026
2027                                 head = head.chain;
2028                         }
2029
2030                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2031                 }
2032         }
2033
2034         // a use key was pressed; call handlers
2035         MUTATOR_CALLHOOK(PlayerUseKey);
2036 }
2037
2038
2039 /*
2040 =============
2041 PlayerPreThink
2042
2043 Called every frame for each client before the physics are run
2044 =============
2045 */
2046 .float usekeypressed;
2047 void() nexball_setstatus;
2048 .float last_vehiclecheck;
2049 .int items_added;
2050 void PlayerPreThink ()
2051 {
2052     SELFPARAM();
2053         WarpZone_PlayerPhysics_FixVAngle(this);
2054
2055     STAT(GAMESTARTTIME, this) = game_starttime;
2056         STAT(ROUNDSTARTTIME, this) = round_starttime;
2057         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2058         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2059
2060         STAT(WEAPONSINMAP, this) = weaponsInMap;
2061
2062         if (frametime) {
2063                 // physics frames: update anticheat stuff
2064                 anticheat_prethink(this);
2065         }
2066
2067         if (blockSpectators && frametime) {
2068                 // WORKAROUND: only use dropclient in server frames (frametime set).
2069                 // Never use it in cl_movement frames (frametime zero).
2070                 checkSpectatorBlock();
2071     }
2072
2073         zoomstate_set = false;
2074
2075         // Check for nameless players
2076         if (isInvisibleString(this.netname)) {
2077                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2078                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2079         }
2080         if (this.netname != this.netname_previous) {
2081                 if (autocvar_sv_eventlog) {
2082                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2083         }
2084                 if (this.netname_previous) strunzone(this.netname_previous);
2085                 this.netname_previous = strzone(this.netname);
2086         }
2087
2088         // version nagging
2089         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2090         this.version_nagtime = 0;
2091         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2092             // git client
2093         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2094             // git server
2095             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2096         } else {
2097             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2098             if (r < 0) { // old client
2099                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2100             } else if (r > 0) { // old server
2101                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2102             }
2103         }
2104     }
2105
2106         // GOD MODE info
2107         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2108         {
2109                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2110                 this.max_armorvalue = 0;
2111         }
2112
2113         if (STAT(FROZEN, this) == 2)
2114         {
2115                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2116                 this.health = max(1, this.revive_progress * start_health);
2117                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2118
2119                 if (this.revive_progress >= 1)
2120                         Unfreeze(this);
2121         }
2122         else if (STAT(FROZEN, this) == 3)
2123         {
2124                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2125                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2126
2127                 if (this.health < 1)
2128                 {
2129                         if (this.vehicle)
2130                                 vehicles_exit(VHEF_RELEASE);
2131                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2132                 }
2133                 else if (this.revive_progress <= 0)
2134                         Unfreeze(this);
2135         }
2136
2137         MUTATOR_CALLHOOK(PlayerPreThink);
2138
2139         if(autocvar_g_vehicles_enter)
2140         if(time > this.last_vehiclecheck)
2141         if(IS_PLAYER(this))
2142         if(!gameover)
2143         if(!STAT(FROZEN, this))
2144         if(!this.vehicle)
2145         if(!IS_DEAD(this))
2146         {
2147                 entity veh;
2148                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2149                 if(vlen(veh.origin - this.origin) < autocvar_g_vehicles_enter_radius)
2150                 if(!IS_DEAD(veh))
2151                 if(veh.takedamage != DAMAGE_NO)
2152                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, this))
2153                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2154                 else if(!veh.owner)
2155                 if(!veh.team || SAME_TEAM(this, veh))
2156                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2157                 else if(autocvar_g_vehicles_steal)
2158                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2159
2160                 this.last_vehiclecheck = time + 1;
2161         }
2162
2163         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2164         {
2165                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2166                         PlayerUseKey();
2167                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2168         }
2169
2170         if (IS_REAL_CLIENT(this))
2171                 PrintWelcomeMessage(this);
2172
2173         if (IS_PLAYER(this)) {
2174                 CheckRules_Player();
2175
2176                 if (intermission_running) {
2177                         IntermissionThink();
2178                         return;
2179                 }
2180
2181                 if (timeout_status == TIMEOUT_ACTIVE) {
2182             // don't allow the player to turn around while game is paused
2183                         // FIXME turn this into CSQC stuff
2184                         this.v_angle = this.lastV_angle;
2185                         this.angles = this.lastV_angle;
2186                         this.fixangle = true;
2187                 }
2188
2189                 if (frametime) player_powerups();
2190
2191                 if (IS_DEAD(this)) {
2192                         if (this.personal && g_race_qualifying) {
2193                                 if (time > this.respawn_time) {
2194                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2195                                         respawn();
2196                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2197                                 }
2198                         } else {
2199                                 if (frametime) player_anim();
2200                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2201
2202                                 if (this.deadflag == DEAD_DYING) {
2203                                         if ((this.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max) {
2204                                                 this.deadflag = DEAD_RESPAWNING;
2205                                         } else if (!button_pressed) {
2206                                                 this.deadflag = DEAD_DEAD;
2207                     }
2208                                 } else if (this.deadflag == DEAD_DEAD) {
2209                                         if (button_pressed) {
2210                                                 this.deadflag = DEAD_RESPAWNABLE;
2211                                         } else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)) {
2212                                                 this.deadflag = DEAD_RESPAWNING;
2213                     }
2214                                 } else if (this.deadflag == DEAD_RESPAWNABLE) {
2215                                         if (!button_pressed) {
2216                                                 this.deadflag = DEAD_RESPAWNING;
2217                     }
2218                                 } else if (this.deadflag == DEAD_RESPAWNING) {
2219                                         if (time > this.respawn_time) {
2220                                                 this.respawn_time = time + 1; // only retry once a second
2221                                                 this.respawn_time_max = this.respawn_time;
2222                                                 respawn();
2223                                         }
2224                                 }
2225
2226                                 ShowRespawnCountdown();
2227
2228                                 if (this.respawn_flags & RESPAWN_SILENT)
2229                                         STAT(RESPAWN_TIME, this) = 0;
2230                                 else if ((this.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2231                                         STAT(RESPAWN_TIME, this) = this.respawn_time_max;
2232                                 else
2233                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2234                         }
2235
2236                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2237                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2238                                 STAT(RESPAWN_TIME, this) *= -1;
2239
2240                         return;
2241                 }
2242
2243                 this.prevorigin = this.origin;
2244
2245                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2246         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2247                 if (this.hook.state) {
2248                         do_crouch = false;
2249                 } else if (this.vehicle) {
2250                         do_crouch = false;
2251                 } else if (STAT(FROZEN, this)) {
2252                         do_crouch = false;
2253         } else if ((PS(this).m_weapon == WEP_SHOTGUN || PS(this).m_weapon == WEP_SHOCKWAVE) && this.(weaponentity).wframe == WFRAME_FIRE2 && time < this.(weaponentity).weapon_nextthink) {
2254                     // WEAPONTODO: predict
2255                         do_crouch = false;
2256         }
2257
2258                 if (do_crouch) {
2259                         if (!this.crouch) {
2260                                 this.crouch = true;
2261                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2262                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2263                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2264                         }
2265                 } else if (this.crouch) {
2266             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2267             if (!trace_startsolid) {
2268                 this.crouch = false;
2269                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2270                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2271             }
2272                 }
2273
2274                 FixPlayermodel(this);
2275
2276                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2277                 //if(frametime)
2278                 {
2279                         this.items &= ~this.items_added;
2280
2281                         W_WeaponFrame(this);
2282
2283                         this.items_added = 0;
2284                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2285                 this.items_added |= IT_FUEL;
2286
2287                         this.items |= this.items_added;
2288                 }
2289
2290                 player_regen();
2291
2292                 // WEAPONTODO: Add a weapon request for this
2293                 // rot vortex charge to the charge limit
2294                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2295                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2296
2297                 if (frametime) player_anim();
2298
2299                 // secret status
2300                 secrets_setstatus();
2301
2302                 // monsters status
2303                 monsters_setstatus(this);
2304
2305                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2306         }
2307         else if (gameover) {
2308                 if (intermission_running) IntermissionThink();
2309                 return;
2310         }
2311         else if (IS_OBSERVER(this)) {
2312                 ObserverThink();
2313         }
2314         else if (IS_SPEC(this)) {
2315                 SpectatorThink();
2316         }
2317
2318         // WEAPONTODO: Add weapon request for this
2319         if (!zoomstate_set) {
2320                 SetZoomState(
2321                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2322                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2323                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2324                 );
2325     }
2326
2327         int oldspectatee_status = this.spectatee_status;
2328         if (IS_SPEC(this)) {
2329                 this.spectatee_status = etof(this.enemy);
2330         } else if (IS_OBSERVER(this)) {
2331                 this.spectatee_status = etof(this);
2332         } else {
2333                 this.spectatee_status = 0;
2334     }
2335         if (this.spectatee_status != oldspectatee_status) {
2336                 ClientData_Touch(this);
2337                 if (g_race || g_cts) race_InitSpectator();
2338         }
2339
2340         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2341         {
2342                 this.teamkill_soundtime = 0;
2343
2344                 entity e = this.teamkill_soundsource;
2345                 entity oldpusher = e.pusher;
2346                 e.pusher = this;
2347                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2348                 e.pusher = oldpusher;
2349         }
2350
2351         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2352                 this.taunt_soundtime = 0;
2353                 PlayerSound(this, playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2354         }
2355
2356         target_voicescript_next(this);
2357
2358         // WEAPONTODO: Move into weaponsystem somehow
2359         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2360         if (PS(this).m_weapon == WEP_Null)
2361                 this.clip_load = this.clip_size = 0;
2362 }
2363
2364 void DrownPlayer(entity this)
2365 {
2366         if(IS_DEAD(this))
2367                 return;
2368
2369         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2370         {
2371                 if(this.air_finished < time)
2372                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
2373                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2374                 this.dmg = 2;
2375         }
2376         else if (this.air_finished < time)
2377         {       // drown!
2378                 if (this.pain_finished < time)
2379                 {
2380                         Damage (this, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2381                         this.pain_finished = time + 0.5;
2382                 }
2383         }
2384 }
2385
2386 /*
2387 =============
2388 PlayerPostThink
2389
2390 Called every frame for each client after the physics are run
2391 =============
2392 */
2393 .float idlekick_lasttimeleft;
2394 void PlayerPostThink ()
2395 {
2396     SELFPARAM();
2397         if (sv_maxidle > 0)
2398         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2399         if (IS_REAL_CLIENT(this))
2400         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2401         {
2402                 if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2403                 {
2404                         if (this.idlekick_lasttimeleft)
2405                         {
2406                                 this.idlekick_lasttimeleft = 0;
2407                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2408                         }
2409                 }
2410                 else
2411                 {
2412                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2413                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2414                                 if (!this.idlekick_lasttimeleft)
2415                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2416                         }
2417                         if (timeleft <= 0) {
2418                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2419                                 dropclient(this);
2420                                 return;
2421                         }
2422                         else if (timeleft <= 10) {
2423                                 if (timeleft != this.idlekick_lasttimeleft) {
2424                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2425                 }
2426                                 this.idlekick_lasttimeleft = timeleft;
2427                         }
2428                 }
2429         }
2430
2431         CheatFrame();
2432
2433         //CheckPlayerJump();
2434
2435         if (IS_PLAYER(this)) {
2436                 DrownPlayer(this);
2437                 CheckRules_Player();
2438                 UpdateChatBubble();
2439                 if (this.impulse) ImpulseCommands(this);
2440                 if (intermission_running) return; // intermission or finale
2441                 GetPressedKeys();
2442         }
2443
2444         if (this.waypointsprite_attachedforcarrier) {
2445             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2446                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2447     }
2448
2449         playerdemo_write();
2450
2451         CSQCMODEL_AUTOUPDATE(this);
2452 }