f08ef5f5385b7b9dad3eb90bd06a86efbbff21db
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float msg);
2 void race_SendRankings(float pos, float prevpos, float del, float msg);
3
4 void send_CSQC_teamnagger() {
5         WriteByte(0, SVC_TEMPENTITY);
6         WriteByte(0, TE_CSQC_TEAMNAGGER);
7 }
8
9 void Announce(string snd) {
10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
12         WriteString(MSG_ALL, snd);
13 }
14
15 void AnnounceTo(entity e, string snd) {
16         if (clienttype(e) == CLIENTTYPE_REAL)
17         {
18                 msg_entity = e;
19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
21                 WriteString(MSG_ONE, snd);
22         }
23 }
24
25 float ClientData_Send(entity to, float sf)
26 {
27         if(to != self.owner)
28         {
29                 error("wtf");
30                 return FALSE;
31         }
32
33         entity e;
34
35         e = to;
36         if(to.classname == "spectator")
37                 e = to.enemy;
38
39         sf = 0;
40
41         if(e.race_completed)
42                 sf |= 1; // forced scoreboard
43         if(to.spectatee_status)
44                 sf |= 2; // spectator ent number follows
45         if(e.zoomstate)
46                 sf |= 4; // zoomed
47         if(e.porto_v_angle_held)
48                 sf |= 8; // angles held
49
50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
51         WriteByte(MSG_ENTITY, sf);
52
53         if(sf & 2)
54                 WriteByte(MSG_ENTITY, to.spectatee_status);
55
56         if(sf & 8)
57         {
58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
60         }
61
62         return TRUE;
63 }
64
65 void ClientData_Attach()
66 {
67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
68         self.clientdata.drawonlytoclient = self;
69         self.clientdata.owner = self;
70 }
71
72 void ClientData_Detach()
73 {
74         remove(self.clientdata);
75         self.clientdata = world;
76 }
77
78 void ClientData_Touch(entity e)
79 {
80         e.clientdata.SendFlags = 1;
81
82         // make it spectatable
83         entity e2;
84         FOR_EACH_REALCLIENT(e2)
85         {
86                 if(e2 != e)
87                         if(e2.classname == "spectator")
88                                 if(e2.enemy == e)
89                                         e2.clientdata.SendFlags = 1;
90         }
91 }
92
93
94 .vector spawnpoint_score;
95 .string netname_previous;
96
97 void spawnfunc_info_player_survivor (void)
98 {
99         spawnfunc_info_player_deathmatch();
100 }
101
102 void spawnfunc_info_player_start (void)
103 {
104         spawnfunc_info_player_deathmatch();
105 }
106
107 void spawnfunc_info_player_deathmatch (void)
108 {
109         self.classname = "info_player_deathmatch";
110         relocate_spawnpoint();
111 }
112
113 void spawnpoint_use()
114 {
115         if(teams_matter)
116         if(have_team_spawns > 0)
117         {
118                 self.team = activator.team;
119                 some_spawn_has_been_used = 1;
120         }
121 };
122
123 // Returns:
124 //   _x: prio (-1 if unusable)
125 //   _y: weight
126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
127 {
128         float shortest, thisdist;
129         float prio;
130         entity player;
131
132         prio = 0;
133
134         // filter out spots for the wrong team
135         if(teamcheck)
136         if(spot.team != teamcheck)
137                 return '-1 0 0';
138
139         if(race_spawns)
140                 if(spot.target == "")
141                         return '-1 0 0';
142
143         if(clienttype(self) == CLIENTTYPE_REAL)
144         {
145                 if(spot.restriction == 1)
146                         return '-1 0 0';
147         }
148         else
149         {
150                 if(spot.restriction == 2)
151                         return '-1 0 0';
152         }
153
154         // filter out spots for assault
155         if(spot.target != "") {
156                 local entity ent;
157                 float good, found;
158                 ent = find(world, targetname, spot.target);
159
160                 while(ent) {
161                         if(ent.classname == "target_objective")
162                         {
163                                 found = 1;
164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
165                                         return '-1 0 0';
166                                 good = 1;
167                         }
168                         else if(ent.classname == "trigger_race_checkpoint")
169                         {
170                                 found = 1;
171                                 if(!anypoint) // spectators may spawn everywhere
172
173                                 {
174                                         if(g_race_qualifying)
175                                         {
176                                                 // spawn at first
177                                                 if(ent.race_checkpoint != 0)
178                                                         return '-1 0 0';
179                                                 if(spot.race_place != race_lowest_place_spawn)
180                                                         return '-1 0 0';
181                                         }
182                                         else
183                                         {
184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
185                                                         return '-1 0 0';
186                                                 // try reusing the previous spawn
187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
188                                                         prio += 1;
189                                                 if(ent.race_checkpoint == 0)
190                                                 {
191                                                         float pl;
192                                                         pl = self.race_place;
193                                                         if(pl > race_highest_place_spawn)
194                                                                 pl = 0;
195                                                         if(pl == 0 && !self.race_started)
196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
197                                                         if(spot.race_place != pl)
198                                                                 return '-1 0 0';
199                                                 }
200                                         }
201                                 }
202                                 good = 1;
203                         }
204                         ent = find(ent, targetname, spot.target);
205                 }
206
207                 if(found && !good)
208                         return '-1 0 0';
209         }
210
211         player = playerlist;
212         shortest = vlen(world.maxs - world.mins);
213         for(player = playerlist; player; player = player.chain)
214                 if (player != self)
215                 {
216                         thisdist = vlen(player.origin - spot.origin);
217                         if (thisdist < shortest)
218                                 shortest = thisdist;
219                 }
220         return prio * '1 0 0' + shortest * '0 1 0';
221 }
222
223 float spawn_allbad;
224 float spawn_allgood;
225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
226 {
227         local entity spot, spotlist, spotlistend;
228         spawn_allgood = TRUE;
229         spawn_allbad = TRUE;
230
231         spotlist = world;
232         spotlistend = world;
233
234         for(spot = firstspot; spot; spot = spot.chain)
235         {
236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
237
238                 if(cvar("spawn_debugview"))
239                 {
240                         setmodel(spot, "models/runematch/rune.mdl");
241                         if(spot.spawnpoint_score_y < mindist)
242                         {
243                                 spot.colormod = '1 0 0';
244                                 spot.scale = 1;
245                         }
246                         else
247                         {
248                                 spot.colormod = '0 1 0';
249                                 spot.scale = spot.spawnpoint_score_y / mindist;
250                         }
251                 }
252
253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
254                 {
255                         if(spot.spawnpoint_score_y < mindist)
256                         {
257                                 // too short distance
258                                 spawn_allgood = FALSE;
259                         }
260                         else
261                         {
262                                 // perfect
263                                 spawn_allbad = FALSE;
264
265                                 if(spotlistend)
266                                         spotlistend.chain = spot;
267                                 spotlistend = spot;
268                                 if(!spotlist)
269                                         spotlist = spot;
270
271                                 /*
272                                 if(teamcheck)
273                                 if(spot.team != teamcheck)
274                                         error("invalid spawn added");
275
276                                 print("added ", etos(spot), "\n");
277                                 */
278                         }
279                 }
280         }
281         if(spotlistend)
282                 spotlistend.chain = world;
283
284         /*
285                 entity e;
286                 if(teamcheck)
287                         for(e = spotlist; e; e = e.chain)
288                         {
289                                 print("seen ", etos(e), "\n");
290                                 if(e.team != teamcheck)
291                                         error("invalid spawn found");
292                         }
293         */
294
295         return spotlist;
296 }
297
298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
299 {
300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
302         local entity spot;
303
304         RandomSelection_Init();
305         for(spot = firstspot; spot; spot = spot.chain)
306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
307
308         return RandomSelection_chosen_ent;
309 }
310
311 /*
312 =============
313 SelectSpawnPoint
314
315 Finds a point to respawn
316 =============
317 */
318 entity SelectSpawnPoint (float anypoint)
319 {
320         local float teamcheck;
321         local entity firstspot_new;
322         local entity spot, firstspot, playerlist;
323
324         spot = find (world, classname, "testplayerstart");
325         if (spot)
326                 return spot;
327
328         teamcheck = 0;
329
330         if(!anypoint && have_team_spawns > 0)
331                 teamcheck = self.team;
332
333         // get the list of players
334         playerlist = findchain(classname, "player");
335         // get the entire list of spots
336         firstspot = findchain(classname, "info_player_deathmatch");
337         // filter out the bad ones
338         // (note this returns the original list if none survived)
339         if(anypoint)
340         {
341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
342         }
343         else
344         {
345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
346                 if(!firstspot_new)
347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
348                 firstspot = firstspot_new;
349
350                 // there is 50/50 chance of choosing a random spot or the furthest spot
351                 // (this means that roughly every other spawn will be furthest, so you
352                 // usually won't get fragged at spawn twice in a row)
353                 if (arena_roundbased && !g_ca)
354                 {
355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
356                         if(firstspot_new)
357                                 firstspot = firstspot_new;
358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
359                 }
360                 else if (random() > cvar("g_spawn_furthest"))
361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
362                 else
363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
364         }
365
366         if(cvar("spawn_debugview"))
367         {
368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
369
370                 entity e;
371                 if(teamcheck)
372                         for(e = firstspot; e; e = e.chain)
373                                 if(e.team != teamcheck)
374                                         error("invalid spawn found");
375         }
376
377         if (!spot)
378         {
379                 if(cvar("spawn_debug"))
380                         GotoNextMap();
381                 else
382                 {
383                         if(some_spawn_has_been_used)
384                                 return world; // team can't spawn any more, because of actions of other team
385                         else
386                                 error("Cannot find a spawn point - please fix the map!");
387                 }
388         }
389
390         return spot;
391 }
392
393 /*
394 =============
395 CheckPlayerModel
396
397 Checks if the argument string can be a valid playermodel.
398 Returns a valid one in doubt.
399 =============
400 */
401 string FallbackPlayerModel;
402 string CheckPlayerModel(string plyermodel) {
403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
404         {
405                 // note: we cannot summon Don Strunzone here, some player may
406                 // still have the model string set. In case anyone manages how
407                 // to change a cvar default, we'll have a small leak here.
408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
409         }
410         if(strlen(plyermodel) < 4)
411                 return FallbackPlayerModel;
412         if( substring(plyermodel,0,14) != "models/player/")
413                 return FallbackPlayerModel;
414         else if(cvar("sv_servermodelsonly"))
415         {
416                 if(substring(plyermodel,-4,4) != ".zym")
417                 if(substring(plyermodel,-4,4) != ".dpm")
418                 if(substring(plyermodel,-4,4) != ".iqm")
419                 if(substring(plyermodel,-4,4) != ".md3")
420                 if(substring(plyermodel,-4,4) != ".psk")
421                         return FallbackPlayerModel;
422                 // forbid the LOD models
423                 if(substring(plyermodel, -9,5) == "_lod1")
424                         return FallbackPlayerModel;
425                 if(substring(plyermodel, -9,5) == "_lod2")
426                         return FallbackPlayerModel;
427                 if(plyermodel != strtolower(plyermodel))
428                         return FallbackPlayerModel;
429                 if(!fexists(plyermodel))
430                         return FallbackPlayerModel;
431         }
432         return plyermodel;
433 }
434
435 /*
436 =============
437 Client_customizeentityforclient
438
439 LOD reduction
440 =============
441 */
442 void Client_uncustomizeentityforclient()
443 {
444         if(self.modelindex == 0) // no need to uncustomize then
445                 return;
446         self.modelindex = self.modelindex_lod0;
447         self.skin = self.skinindex;
448 }
449
450 float Client_customizeentityforclient()
451 {
452         entity modelsource;
453
454         if(self.modelindex == 0)
455                 return TRUE;
456
457         // forcemodel stuff
458
459 #ifdef PROFILING
460         float t0;
461         t0 = gettime(GETTIME_HIRES); // reference
462 #endif
463
464         modelsource = self;
465
466 #ifdef ALLOW_FORCEMODELS
467         if(other.cvar_cl_forceplayermodelsfromxonotic)
468                 if not(self.modelindex_lod0_from_xonotic)
469                         modelsource = other;
470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
471                 modelsource = other;
472 #endif
473
474         self.skin = modelsource.skinindex;
475
476 #if 0
477         if(modelsource == self)
478                 self.skin = modelsource.skinindex;
479         else
480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
481 #endif
482
483         // self: me
484         // other: the player viewing me
485         float distance;
486         float f;
487
488         if(other.cvar_cl_playerdetailreduction <= 0)
489         {
490                 if(other.cvar_cl_playerdetailreduction <= -2)
491                         self.modelindex = modelsource.modelindex_lod2;
492                 else if(other.cvar_cl_playerdetailreduction <= -1)
493                         self.modelindex = modelsource.modelindex_lod1;
494                 else
495                         self.modelindex = modelsource.modelindex_lod0;
496         }
497         else
498         {
499                 distance = vlen(self.origin - other.origin);
500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
501                 if(f > sv_loddistance2)
502                         self.modelindex = modelsource.modelindex_lod2;
503                 else if(f > sv_loddistance1)
504                         self.modelindex = modelsource.modelindex_lod1;
505                 else
506                         self.modelindex = modelsource.modelindex_lod0;
507         }
508
509 #ifdef PROFILING
510         float t1;
511         t1 = gettime(GETTIME_HIRES); // reference
512         client_cefc_accumulator += (t1 - t0);
513 #endif
514
515         return TRUE;
516 }
517
518 void setmodel_lod(entity e, string modelname)
519 {
520         string s;
521
522         if(sv_loddistance1)
523         {
524                 // FIXME: this only supports 3-letter extensions
525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
526                 if(fexists(s))
527                 {
528                         setmodel(e, s); // players have high precision
529                         self.modelindex_lod1 = self.modelindex;
530                 }
531                 else
532                         self.modelindex_lod1 = -1;
533
534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
535                 if(fexists(s))
536                 {
537                         setmodel(e, s); // players have high precision
538                         self.modelindex_lod2 = self.modelindex;
539                 }
540                 else
541                         self.modelindex_lod2 = -1;
542
543                 precache_model(modelname);
544                 setmodel(e, modelname); // players have high precision
545                 self.modelindex_lod0 = self.modelindex;
546
547                 if(self.modelindex_lod1 < 0)
548                         self.modelindex_lod1 = self.modelindex;
549
550                 if(self.modelindex_lod2 < 0)
551                         self.modelindex_lod2 = self.modelindex;
552         }
553         else
554         {
555                 precache_model(modelname);
556                 setmodel(e, modelname); // players have high precision
557                 self.modelindex_lod0 = self.modelindex;
558                         // save it for possible player model forcing
559         }
560
561         s = whichpack(self.model);
562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
563
564         player_setupanimsformodel();
565         UpdatePlayerSounds();
566 }
567
568 /*
569 =============
570 PutObserverInServer
571
572 putting a client as observer in the server
573 =============
574 */
575 void FixPlayermodel();
576 void PutObserverInServer (void)
577 {
578         entity  spot;
579
580         race_PreSpawnObserver();
581
582         spot = SelectSpawnPoint (TRUE);
583         if(!spot)
584                 error("No spawnpoints for observers?!?\n");
585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
586
587         if(clienttype(self) == CLIENTTYPE_REAL)
588         {
589                 msg_entity = self;
590                 WriteByte(MSG_ONE, SVC_SETVIEW);
591                 WriteEntity(MSG_ONE, self);
592         }
593
594         DropAllRunes(self);
595
596         Portal_ClearAll(self);
597
598         if(self.flagcarried)
599                 DropFlag(self.flagcarried, world, world);
600
601         if(self.ballcarried)
602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
603
604         WaypointSprite_PlayerDead();
605
606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
608
609         if(self.killcount != -666) {
610                 if(g_lms) {
611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
613                         else
614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
615                 } else
616                         bprint ("^4", self.netname, "^4 is spectating now\n");
617
618                 if(self.just_joined == FALSE) {
619                         LogTeamchange(self.playerid, -1, 4);
620                 } else
621                         self.just_joined = FALSE;
622         }
623
624         PlayerScore_Clear(self); // clear scores when needed
625
626         self.spectatortime = time;
627
628         self.classname = "observer";
629         self.iscreature = FALSE;
630         self.health = -666;
631         self.takedamage = DAMAGE_NO;
632         self.solid = SOLID_NOT;
633         self.movetype = MOVETYPE_NOCLIP;
634         self.flags = FL_CLIENT | FL_NOTARGET;
635         self.armorvalue = 666;
636         self.effects = 0;
637         self.armorvalue = cvar("g_balance_armor_start");
638         self.pauserotarmor_finished = 0;
639         self.pauserothealth_finished = 0;
640         self.pauseregen_finished = 0;
641         self.damageforcescale = 0;
642         self.death_time = 0;
643         self.dead_frame = 0;
644         self.alpha = 0;
645         self.scale = 0;
646         self.fade_time = 0;
647         self.pain_frame = 0;
648         self.pain_finished = 0;
649         self.strength_finished = 0;
650         self.invincible_finished = 0;
651         self.pushltime = 0;
652         self.think = SUB_Null;
653         self.nextthink = 0;
654         self.hook_time = 0;
655         self.runes = 0;
656         self.deadflag = DEAD_NO;
657         self.angles = spot.angles;
658         self.angles_z = 0;
659         self.fixangle = TRUE;
660         self.crouch = FALSE;
661
662         self.view_ofs = PL_VIEW_OFS;
663         setorigin (self, spot.origin);
664         setsize (self, '0 0 0', '0 0 0');
665         self.prevorigin = self.origin;
666         self.items = 0;
667         self.weapons = 0;
668         self.model = "";
669         FixPlayermodel();
670         self.model = "";
671         self.modelindex = 0;
672         self.weapon = 0;
673         self.weaponmodel = "";
674         self.weaponentity = world;
675         self.exteriorweaponentity = world;
676         self.killcount = -666;
677         self.velocity = '0 0 0';
678         self.avelocity = '0 0 0';
679         self.punchangle = '0 0 0';
680         self.punchvector = '0 0 0';
681         self.oldvelocity = self.velocity;
682         self.fire_endtime = -1;
683
684         if(sv_loddistance1)
685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
686
687         if(g_arena)
688         {
689                 if(self.version_mismatch)
690                 {
691                         Spawnqueue_Unmark(self);
692                         Spawnqueue_Remove(self);
693                 }
694                 else
695                 {
696                         Spawnqueue_Insert(self);
697                 }
698         }
699         else if(g_lms)
700         {
701                 // Only if the player cannot play at all
702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
703                         self.frags = FRAGS_SPECTATOR;
704                 else
705                         self.frags = FRAGS_LMS_LOSER;
706         }
707         else
708                 self.frags = FRAGS_SPECTATOR;
709
710         MUTATOR_CALLHOOK(MakePlayerObserver);
711 }
712
713 float RestrictSkin(float s)
714 {
715         if(!teams_matter)
716                 return s;
717         if(s == 6)
718                 return 6;
719         return mod(s, 3);
720 }
721
722 void FixPlayermodel()
723 {
724         local string defaultmodel;
725         local float defaultskin, chmdl, oldskin;
726         local vector m1, m2;
727
728         defaultmodel = "";
729
730         if(cvar("sv_defaultcharacter") == 1) {
731                 defaultskin = 0;
732
733                 if(teams_matter)
734                 {
735                         string s;
736                         s = Team_ColorNameLowerCase(self.team);
737                         if(s != "neutral")
738                         {
739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
741                         }
742                 }
743
744                 if(defaultmodel == "")
745                 {
746                         defaultmodel = cvar_string("sv_defaultplayermodel");
747                         defaultskin = cvar("sv_defaultplayerskin");
748                 }
749         }
750
751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
752         {
753                 if(self.model != "")
754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
755                 self.model = ""; // force the != checks to return true
756         }
757
758         if(defaultmodel != "")
759         {
760                 if (defaultmodel != self.model)
761                 {
762                         m1 = self.mins;
763                         m2 = self.maxs;
764                         setmodel_lod (self, defaultmodel);
765                         setsize (self, m1, m2);
766                         chmdl = TRUE;
767                 }
768
769                 oldskin = self.skinindex;
770                 self.skinindex = defaultskin;
771         } else {
772                 if (self.playermodel != self.model || self.playermodel == "")
773                 {
774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
775                         m1 = self.mins;
776                         m2 = self.maxs;
777                         setmodel_lod (self, self.playermodel);
778                         setsize (self, m1, m2);
779                         chmdl = TRUE;
780                 }
781
782                 oldskin = self.skinindex;
783                 self.skinindex = RestrictSkin(stof(self.playerskin));
784         }
785
786         if(chmdl || oldskin != self.skinindex)
787                 self.species = player_getspecies(); // model or skin has changed
788
789         if(!teams_matter)
790                 if(strlen(cvar_string("sv_defaultplayercolors")))
791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
792                                 setcolor(self, cvar("sv_defaultplayercolors"));
793 }
794
795 void PlayerTouchExplode(entity p1, entity p2)
796 {
797         vector org;
798         org = (p1.origin + p2.origin) * 0.5;
799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
800
801         te_explosion(org);
802
803         entity e;
804         e = spawn();
805         setorigin(e, org);
806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
807         remove(e);
808 }
809
810 /*
811 =============
812 PutClientInServer
813
814 Called when a client spawns in the server
815 =============
816 */
817 //void() ctf_playerchanged;
818 void PutClientInServer (void)
819 {
820         if(clienttype(self) == CLIENTTYPE_BOT)
821         {
822                 self.classname = "player";
823         }
824         else if(clienttype(self) == CLIENTTYPE_REAL)
825         {
826                 msg_entity = self;
827                 WriteByte(MSG_ONE, SVC_SETVIEW);
828                 WriteEntity(MSG_ONE, self);
829         }
830
831         // player is dead and becomes observer
832         // FIXME fix LMS scoring for new system
833         if(g_lms)
834         {
835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
836                         self.classname = "observer";
837         }
838
839         if(g_arena || (g_ca && !allowed_to_spawn))
840         if(!self.spawned)
841                 self.classname = "observer";
842
843         if(gameover)
844                 self.classname = "observer";
845
846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
847                 entity spot, oldself;
848                 float j;
849
850                 if(self.team < 0)
851                         JoinBestTeam(self, FALSE, TRUE);
852
853                 race_PreSpawn();
854
855                 spot = SelectSpawnPoint (FALSE);
856                 if(!spot)
857                 {
858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
859                         return; // spawn failed
860                 }
861
862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
863
864                 self.classname = "player";
865                 self.wasplayer = TRUE;
866                 self.iscreature = TRUE;
867                 self.movetype = MOVETYPE_WALK;
868                 self.solid = SOLID_SLIDEBOX;
869                 if(cvar("g_playerclip_collisions"))
870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
871                 else
872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
873                 self.frags = FRAGS_PLAYER;
874                 if(independent_players)
875                         MAKE_INDEPENDENT_PLAYER(self);
876                 self.flags = FL_CLIENT;
877                 self.takedamage = DAMAGE_AIM;
878                 if(g_minstagib)
879                         self.effects = EF_FULLBRIGHT;
880                 else
881                         self.effects = 0;
882                 self.air_finished = time + 12;
883                 self.dmg = 2;
884
885                 if(inWarmupStage)
886                 {
887                         self.ammo_shells = warmup_start_ammo_shells;
888                         self.ammo_nails = warmup_start_ammo_nails;
889                         self.ammo_rockets = warmup_start_ammo_rockets;
890                         self.ammo_cells = warmup_start_ammo_cells;
891                         self.ammo_fuel = warmup_start_ammo_fuel;
892                         self.health = warmup_start_health;
893                         self.armorvalue = warmup_start_armorvalue;
894                         self.weapons = warmup_start_weapons;
895                 }
896                 else
897                 {
898                         self.ammo_shells = start_ammo_shells;
899                         self.ammo_nails = start_ammo_nails;
900                         self.ammo_rockets = start_ammo_rockets;
901                         self.ammo_cells = start_ammo_cells;
902                         self.ammo_fuel = start_ammo_fuel;
903                         self.health = start_health;
904                         self.armorvalue = start_armorvalue;
905                         self.weapons = start_weapons;
906                 }
907
908                 if(g_weaponarena_random)
909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
910
911                 self.items = start_items;
912                 self.jump_interval = time;
913
914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
919                 //extend the pause of rotting if client was reset at the beginning of the countdown
920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
921                         self.spawnshieldtime += game_starttime - time;
922                         self.pauserotarmor_finished += game_starttime - time;
923                         self.pauserothealth_finished += game_starttime - time;
924                         self.pauseregen_finished += game_starttime - time;
925                 }
926                 self.damageforcescale = 2;
927                 self.death_time = 0;
928                 self.dead_frame = 0;
929                 self.alpha = 0;
930                 self.scale = 0;
931                 self.fade_time = 0;
932                 self.pain_frame = 0;
933                 self.pain_finished = 0;
934                 self.strength_finished = 0;
935                 self.invincible_finished = 0;
936                 self.pushltime = 0;
937                 // players have no think function
938                 self.think = SUB_Null;
939                 self.nextthink = 0;
940                 self.hook_time = 0;
941                 self.dmg_team = 0;
942                 self.ballistics_density = cvar("g_ballistics_density_player");
943
944                 self.metertime = 0;
945
946                 self.runes = 0;
947
948                 self.deadflag = DEAD_NO;
949
950                 self.angles = spot.angles;
951
952                 self.angles_z = 0; // never spawn tilted even if the spot says to
953                 self.fixangle = TRUE; // turn this way immediately
954                 self.velocity = '0 0 0';
955                 self.avelocity = '0 0 0';
956                 self.punchangle = '0 0 0';
957                 self.punchvector = '0 0 0';
958                 self.oldvelocity = self.velocity;
959                 self.fire_endtime = -1;
960
961                 msg_entity = self;
962                 WRITESPECTATABLE_MSG_ONE({
963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
965                 });
966
967                 if(sv_loddistance1)
968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
969
970                 self.model = "";
971                 FixPlayermodel();
972
973                 self.crouch = FALSE;
974                 self.view_ofs = PL_VIEW_OFS;
975                 setsize (self, PL_MIN, PL_MAX);
976                 self.spawnorigin = spot.origin;
977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
978                 // don't reset back to last position, even if new position is stuck in solid
979                 self.oldorigin = self.origin;
980                 self.prevorigin = self.origin;
981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
982
983                 if(g_arena)
984                 {
985                         Spawnqueue_Remove(self);
986                         Spawnqueue_Mark(self);
987                 }
988
989                 else if(g_ca)
990                         self.caplayer = 1;
991
992                 self.event_damage = PlayerDamage;
993
994                 self.bot_attack = TRUE;
995
996                 self.statdraintime = time + 5;
997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
998
999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1067         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1068         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1069         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1070         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1071         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1072         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1073         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1074         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1078         if(sv_foginterval && world.fog != "")
1079                 WriteString(MSG_ENTITY, world.fog);
1080         else
1081                 WriteString(MSG_ENTITY, "");
1082         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1083         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1084         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1085         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1086         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1087         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1088         return TRUE;
1089 }
1090
1091 void ClientInit_CheckUpdate()
1092 {
1093         self.nextthink = time;
1094         if(self.count != cvar("g_balance_armor_blockpercent"))
1095         {
1096                 self.count = cvar("g_balance_armor_blockpercent");
1097                 self.SendFlags |= 1;
1098         }
1099         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1100         {
1101                 self.cnt = cvar("g_balance_weaponswitchdelay");
1102                 self.SendFlags |= 1;
1103         }
1104         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1105         {
1106                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1107                 self.SendFlags |= 1;
1108         }
1109         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1110         {
1111                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1112                 self.SendFlags |= 1;
1113         }
1114 }
1115
1116 void ClientInit_Spawn()
1117 {
1118         entity o;
1119         entity e;
1120         e = spawn();
1121         e.classname = "clientinit";
1122         e.think = ClientInit_CheckUpdate;
1123         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1124
1125         o = self;
1126         self = e;
1127         ClientInit_CheckUpdate();
1128         self = o;
1129 }
1130
1131 /*
1132 =============
1133 SetNewParms
1134 =============
1135 */
1136 void SetNewParms (void)
1137 {
1138         // initialize parms for a new player
1139         parm1 = -(86400 * 366);
1140 }
1141
1142 /*
1143 =============
1144 SetChangeParms
1145 =============
1146 */
1147 void SetChangeParms (void)
1148 {
1149         // save parms for level change
1150         parm1 = self.parm_idlesince - time;
1151 }
1152
1153 /*
1154 =============
1155 DecodeLevelParms
1156 =============
1157 */
1158 void DecodeLevelParms (void)
1159 {
1160         // load parms
1161         self.parm_idlesince = parm1;
1162         if(self.parm_idlesince == -(86400 * 366))
1163                 self.parm_idlesince = time;
1164
1165         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1166         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1167 }
1168
1169 /*
1170 =============
1171 ClientKill
1172
1173 Called when a client types 'kill' in the console
1174 =============
1175 */
1176
1177 void ClientKill_Now_TeamChange()
1178 {
1179         if(self.killindicator_teamchange == -1)
1180         {
1181                 self.team = -1;
1182                 JoinBestTeam( self, FALSE, FALSE );
1183         }
1184         else
1185                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1186 }
1187
1188 void ClientKill_Now()
1189 {
1190         if(self.killindicator_teamchange)
1191                 ClientKill_Now_TeamChange();
1192
1193         // in any case:
1194         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1195
1196         if(self.killindicator)
1197         {
1198                 dprint("Cleaned up after a leaked kill indicator.\n");
1199                 remove(self.killindicator);
1200                 self.killindicator = world;
1201         }
1202 }
1203 void KillIndicator_Think()
1204 {
1205         if (!self.owner.modelindex)
1206         {
1207                 self.owner.killindicator = world;
1208                 remove(self);
1209                 return;
1210         }
1211
1212         if(self.cnt <= 0)
1213         {
1214                 self = self.owner;
1215                 ClientKill_Now(); // no oldself needed
1216                 return;
1217         }
1218         else
1219         {
1220                 if(self.cnt <= 10)
1221                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1222                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1223                 {
1224                         if(self.cnt <= 10)
1225                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1226                         if(self.owner.killindicator_teamchange)
1227                         {
1228                                 if(self.owner.killindicator_teamchange == -1)
1229                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1230                                 else
1231                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1232                         }
1233                         else
1234                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1235                 }
1236                 self.nextthink = time + 1;
1237                 self.cnt -= 1;
1238         }
1239 }
1240
1241 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1242 {
1243         float killtime;
1244         entity e;
1245         killtime = cvar("g_balance_kill_delay");
1246
1247         if(g_race_qualifying)
1248                 killtime = 0;
1249
1250         self.killindicator_teamchange = targetteam;
1251
1252         if(!self.killindicator)
1253         {
1254                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1255                 {
1256                         ClientKill_Now();
1257                 }
1258                 else
1259                 {
1260                         self.killindicator = spawn();
1261                         self.killindicator.owner = self;
1262                         self.killindicator.scale = 0.5;
1263                         setattachment(self.killindicator, self, "");
1264                         setorigin(self.killindicator, '0 0 52');
1265                         self.killindicator.think = KillIndicator_Think;
1266                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1267                         self.killindicator.cnt = ceil(killtime);
1268                         self.killindicator.count = bound(0, ceil(killtime), 10);
1269                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1270
1271                         for(e = world; (e = find(e, classname, "body")) != world; )
1272                         {
1273                                 if(e.enemy != self)
1274                                         continue;
1275                                 e.killindicator = spawn();
1276                                 e.killindicator.owner = e;
1277                                 e.killindicator.scale = 0.5;
1278                                 setattachment(e.killindicator, e, "");
1279                                 setorigin(e.killindicator, '0 0 52');
1280                                 e.killindicator.think = KillIndicator_Think;
1281                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1282                                 e.killindicator.cnt = ceil(killtime);
1283                         }
1284                         self.lip = 0;
1285                 }
1286         }
1287         if(self.killindicator)
1288         {
1289                 if(targetteam)
1290                         self.killindicator.colormod = TeamColor(targetteam);
1291                 else
1292                         self.killindicator.colormod = '0 0 0';
1293         }
1294 }
1295
1296 void ClientKill (void)
1297 {
1298         ClientKill_TeamChange(0);
1299 }
1300
1301 void DoTeamChange(float destteam)
1302 {
1303         float t, c0;
1304         if(!teams_matter)
1305         {
1306                 if(destteam >= 0)
1307                         SetPlayerColors(self, destteam);
1308                 return;
1309         }
1310         if(self.classname == "player")
1311         if(destteam == -1)
1312         {
1313                 CheckAllowedTeams(self);
1314                 t = FindSmallestTeam(self, TRUE);
1315                 switch(self.team)
1316                 {
1317                         case COLOR_TEAM1: c0 = c1; break;
1318                         case COLOR_TEAM2: c0 = c2; break;
1319                         case COLOR_TEAM3: c0 = c3; break;
1320                         case COLOR_TEAM4: c0 = c4; break;
1321                         default:          c0 = 999;
1322                 }
1323                 switch(t)
1324                 {
1325                         case 1:
1326                                 if(c0 > c1)
1327                                         destteam = COLOR_TEAM1;
1328                                 break;
1329                         case 2:
1330                                 if(c0 > c2)
1331                                         destteam = COLOR_TEAM2;
1332                                 break;
1333                         case 3:
1334                                 if(c0 > c3)
1335                                         destteam = COLOR_TEAM3;
1336                                 break;
1337                         case 4:
1338                                 if(c0 > c4)
1339                                         destteam = COLOR_TEAM4;
1340                                 break;
1341                 }
1342                 if(destteam == -1)
1343                         return;
1344         }
1345         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1346                 return;
1347         ClientKill_TeamChange(destteam);
1348 }
1349
1350 void FixClientCvars(entity e)
1351 {
1352         // send prediction settings to the client
1353         stuffcmd(e, "\nin_bindmap 0 0\n");
1354         if(g_race || g_cts)
1355                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1356         if(cvar("g_antilag") == 3) // client side hitscan
1357                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1358                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1359         /*
1360          * we no longer need to stuff this. Remove this comment block if you feel
1361          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1362         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1363         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1364         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1365         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1366         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1367         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1368         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1369         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1370         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1371         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1372         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1373         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1374         stuffcmd(e, "cl_movement_edgefriction 1\n");
1375          */
1376 }
1377
1378 /*
1379 =============
1380 ClientConnect
1381
1382 Called when a client connects to the server
1383 =============
1384 */
1385 //void ctf_clientconnect();
1386 string ColoredTeamName(float t);
1387 void DecodeLevelParms (void);
1388 //void dom_player_join_team(entity pl);
1389 #ifdef UID
1390 .float uid_kicktime;
1391 .string uid;
1392 #endif
1393 void ClientConnect (void)
1394 {
1395         float t;
1396
1397         if(self.flags & FL_CLIENT)
1398         {
1399                 print("Warning: ClientConnect, but already connected!\n");
1400                 return;
1401         }
1402
1403         if(Ban_MaybeEnforceBan(self))
1404                 return;
1405
1406         DecodeLevelParms();
1407
1408 #ifdef WATERMARK
1409         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1410 #endif
1411
1412         self.classname = "player_joining";
1413
1414         self.flags = FL_CLIENT;
1415         self.version_nagtime = time + 10 + random() * 10;
1416
1417         if(player_count<0)
1418         {
1419                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1420                 player_count = 0;
1421         }
1422
1423         PlayerScore_Attach(self);
1424         ClientData_Attach();
1425
1426         bot_clientconnect();
1427
1428         playerdemo_init();
1429
1430         anticheat_init();
1431         
1432         race_PreSpawnObserver();
1433
1434         //if(g_domination)
1435         //      dom_player_join_team(self);
1436
1437         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1438
1439         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1440                 self.classname = "observer";
1441         } else {
1442                 if(teams_matter)
1443                 {
1444                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1445                         {
1446                                 self.classname = "player";
1447                                 campaign_bots_may_start = 1;
1448                         }
1449                         else
1450                         {
1451                                 self.classname = "observer"; // do it anyway
1452                         }
1453                 }
1454                 else
1455                 {
1456                         self.classname = "player";
1457                         campaign_bots_may_start = 1;
1458                 }
1459         }
1460
1461         self.playerid = (playerid_last = playerid_last + 1);
1462
1463         if(cvar("sv_eventlog"))
1464                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1465
1466         LogTeamchange(self.playerid, self.team, 1);
1467
1468         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1469
1470         self.netname_previous = strzone(self.netname);
1471
1472         bprint("^4", self.netname, "^4 connected");
1473
1474         if(self.classname != "observer" && (g_domination || g_ctf))
1475                 bprint(" and joined the ", ColoredTeamName(self.team));
1476
1477         bprint("\n");
1478
1479         self.welcomemessage_time = 0;
1480
1481         stuffcmd(self, strcat(clientstuff, "\n"));
1482         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1483         stuffcmd(self, "cl_particles_reloadeffects\n");
1484
1485         FixClientCvars(self);
1486
1487         // spawnfunc_waypoint sprites
1488         WaypointSprite_InitClient(self);
1489
1490         // Wazat's grappling hook
1491         SetGrappleHookBindings();
1492
1493         // get autoswitch state from player when he toggles it
1494         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1495
1496         // get version info from player
1497         stuffcmd(self, "cmd clientversion $gameversion\n");
1498
1499         // get other cvars from player
1500         GetCvars(0);
1501
1502         // set cvar for team scoreboard
1503         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1504
1505         // notify about available teams
1506         if(teams_matter)
1507         {
1508                 CheckAllowedTeams(self);
1509                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1510                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1511         }
1512         else
1513                 stuffcmd(self, "set _teams_available 0\n");
1514
1515         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1516
1517         if(g_arena || g_ca)
1518         {
1519                 self.classname = "observer";
1520                 if(g_arena)
1521                         Spawnqueue_Insert(self);
1522         }
1523         /*else if(g_ctf)
1524         {
1525                 ctf_clientconnect();
1526         }*/
1527
1528         if(teams_matter || radar_showennemies)
1529                 attach_entcs();
1530
1531         bot_relinkplayerlist();
1532
1533         self.spectatortime = time;
1534         if(blockSpectators)
1535         {
1536                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1537         }
1538
1539         self.jointime = time;
1540         self.allowedTimeouts = cvar("sv_timeout_number");
1541
1542         if(clienttype(self) == CLIENTTYPE_REAL)
1543         {
1544                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1545                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1546         }
1547
1548         if(g_lms)
1549         {
1550                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1551                 {
1552                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1553                         self.frags = FRAGS_SPECTATOR;
1554                 }
1555         }
1556
1557         if(!sv_foginterval && world.fog != "")
1558                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1559
1560         SoundEntity_Attach(self);
1561
1562         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1563         {
1564                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1565                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1566         }
1567         else
1568                 self.hitplotfh = -1;
1569
1570 #ifdef UID
1571         if(clienttype(self) == CLIENTTYPE_REAL)
1572         if not(self.uid)
1573                 self.uid_kicktime = time + 60;
1574 #endif
1575
1576         if(g_race || g_cts) {
1577                 string rr;
1578                 if(g_cts)
1579                         rr = CTS_RECORD;
1580                 else
1581                         rr = RACE_RECORD;
1582                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1583
1584                 race_send_recordtime(MSG_ONE);
1585                 race_send_speedaward(MSG_ONE);
1586
1587                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1588                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1589                 race_send_speedaward_alltimebest(MSG_ONE);
1590
1591                 float i;
1592                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1593                         race_SendRankings(i, 0, 0, MSG_ONE);
1594                 }
1595         }
1596         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1597                 send_CSQC_teamnagger();
1598
1599         CheatInitClient();
1600 }
1601
1602 /*
1603 =============
1604 ClientDisconnect
1605
1606 Called when a client disconnects from the server
1607 =============
1608 */
1609 .entity chatbubbleentity;
1610 .entity teambubbleentity;
1611 void ReadyCount();
1612 void ClientDisconnect (void)
1613 {
1614         if not(self.flags & FL_CLIENT)
1615         {
1616                 print("Warning: ClientDisconnect without ClientConnect\n");
1617                 return;
1618         }
1619
1620         CheatShutdownClient();
1621
1622         if(self.hitplotfh >= 0)
1623         {
1624                 fclose(self.hitplotfh);
1625                 self.hitplotfh = -1;
1626         }
1627
1628         anticheat_report();
1629         anticheat_shutdown();
1630
1631         playerdemo_shutdown();
1632
1633         bot_clientdisconnect();
1634
1635         if(self.entcs)
1636                 detach_entcs();
1637
1638         if(cvar("sv_eventlog"))
1639                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1640         bprint ("^4",self.netname);
1641         bprint ("^4 disconnected\n");
1642
1643         SoundEntity_Detach(self);
1644
1645         DropAllRunes(self);
1646         MUTATOR_CALLHOOK(ClientDisconnect);
1647
1648         Portal_ClearAll(self);
1649
1650         if(self.flagcarried)
1651                 DropFlag(self.flagcarried, world, world);
1652         if(self.ballcarried)
1653                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1654
1655         // Here, everything has been done that requires this player to be a client.
1656
1657         self.flags &~= FL_CLIENT;
1658
1659         if (self.chatbubbleentity)
1660                 remove (self.chatbubbleentity);
1661
1662         if (self.teambubbleentity)
1663                 remove (self.teambubbleentity);
1664
1665         if (self.killindicator)
1666                 remove (self.killindicator);
1667
1668         WaypointSprite_PlayerGone();
1669
1670         bot_relinkplayerlist();
1671
1672         // remove laserdot
1673         if(self.weaponentity)
1674                 if(self.weaponentity.lasertarget)
1675                         remove(self.weaponentity.lasertarget);
1676
1677         if(g_arena)
1678         {
1679                 Spawnqueue_Unmark(self);
1680                 Spawnqueue_Remove(self);
1681         }
1682
1683         ClientData_Detach();
1684         PlayerScore_Detach(self);
1685
1686         if(self.netname_previous)
1687                 strunzone(self.netname_previous);
1688         if(self.clientstatus)
1689                 strunzone(self.clientstatus);
1690
1691         ClearPlayerSounds();
1692
1693         if(self.personal)
1694                 remove(self.personal);
1695
1696         self.playerid = 0;
1697         ReadyCount();
1698
1699         // free cvars
1700         GetCvars(-1);
1701 }
1702
1703 .float BUTTON_CHAT;
1704 void ChatBubbleThink()
1705 {
1706         self.nextthink = time;
1707         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1708         {
1709                 if(self.owner) // but why can that ever be world?
1710                         self.owner.chatbubbleentity = world;
1711                 remove(self);
1712                 return;
1713         }
1714         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1715 #ifdef TETRIS
1716                 || self.owner.tetris_on
1717 #endif
1718         )
1719                 self.model = self.mdl;
1720         else
1721                 self.model = "";
1722 };
1723
1724 void UpdateChatBubble()
1725 {
1726         if (!self.modelindex)
1727                 return;
1728         // spawn a chatbubble entity if needed
1729         if (!self.chatbubbleentity)
1730         {
1731                 self.chatbubbleentity = spawn();
1732                 self.chatbubbleentity.owner = self;
1733                 self.chatbubbleentity.exteriormodeltoclient = self;
1734                 self.chatbubbleentity.think = ChatBubbleThink;
1735                 self.chatbubbleentity.nextthink = time;
1736                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1737                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1738                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1739                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1740                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1741                 self.chatbubbleentity.model = "";
1742                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1743         }
1744 }
1745
1746
1747 void TeamBubbleThink()
1748 {
1749         self.nextthink = time;
1750         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1751         {
1752                 if(self.owner) // but why can that ever be world?
1753                         self.owner.teambubbleentity = world;
1754                 remove(self);
1755                 return;
1756         }
1757 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1758         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1759                 self.model = "";
1760         else
1761                 self.model = self.mdl;
1762
1763 };
1764
1765 float TeamBubble_customizeentityforclient()
1766 {
1767         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1768 }
1769
1770 void UpdateTeamBubble()
1771 {
1772         if (!self.modelindex || !teams_matter)
1773                 return;
1774         // spawn a teambubble entity if needed
1775         if (!self.teambubbleentity && teams_matter)
1776         {
1777                 self.teambubbleentity = spawn();
1778                 self.teambubbleentity.owner = self;
1779                 self.teambubbleentity.exteriormodeltoclient = self;
1780                 self.teambubbleentity.think = TeamBubbleThink;
1781                 self.teambubbleentity.nextthink = time;
1782                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1783 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1784                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1785                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1786                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1787                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1788                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1789                 self.teambubbleentity.effects = EF_LOWPRECISION;
1790         }
1791 }
1792
1793 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1794 // added to the model skins
1795 /*void UpdateColorModHack()
1796 {
1797         local float c;
1798         c = self.clientcolors & 15;
1799         // LordHavoc: only bothering to support white, green, red, yellow, blue
1800              if (!teams_matter) self.colormod = '0 0 0';
1801         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1802         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1803         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1804         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1805         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1806         else self.colormod = '1 1 1';
1807 };*/
1808
1809 .float oldcolormap;
1810 void respawn(void)
1811 {
1812         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1813         {
1814                 self.solid = SOLID_NOT;
1815                 self.takedamage = DAMAGE_NO;
1816                 self.movetype = MOVETYPE_FLY;
1817                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1818                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1819                 self.effects |= EF_ADDITIVE;
1820                 self.oldcolormap = self.colormap;
1821                 self.colormap = 512;
1822                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1823                 if(cvar("g_respawn_ghosts_maxtime"))
1824                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1825         }
1826
1827         CopyBody(1);
1828         self.effects |= EF_NODRAW; // prevent another CopyBody
1829         if(self.oldcolormap)
1830         {
1831                 self.colormap = self.oldcolormap;
1832                 self.oldcolormap = 0;
1833         }
1834         PutClientInServer();
1835 }
1836
1837 void play_countdown(float finished, string samp)
1838 {
1839         if(clienttype(self) == CLIENTTYPE_REAL)
1840                 if(floor(finished - time - frametime) != floor(finished - time))
1841                         if(finished - time < 6)
1842                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1843 }
1844
1845 /**
1846  * When sv_timeout is used this function returs strings like
1847  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1848  * Called by centerprint functions
1849  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1850  */
1851 string getTimeoutText(float addOneSecond) {
1852         if (!cvar("sv_timeout") || !timeoutStatus)
1853                 return "";
1854
1855         local string retStr;
1856         if (timeoutStatus == 1) {
1857                 if (addOneSecond == 1) {
1858                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1859                 }
1860                 else {
1861                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1862                 }
1863                 return retStr;
1864         }
1865         else if (timeoutStatus == 2) {
1866                 if (addOneSecond) {
1867                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1868                         //don't show messages like "Timeout ends in 0 seconds"...
1869                         if ((remainingTimeoutTime + 1) > 0)
1870                                 return retStr;
1871                         else
1872                                 return "";
1873                 }
1874                 else {
1875                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1876                         //don't show messages like "Timeout ends in 0 seconds"...
1877                         if (remainingTimeoutTime > 0)
1878                                 return retStr;
1879                         else
1880                                 return "";
1881                 }
1882         }
1883         else return "";
1884 }
1885
1886 void player_powerups (void)
1887 {
1888         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1889         {
1890                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1891                 self.modelflags |= MF_ROCKET;
1892         }
1893         else
1894         {
1895                 SoundEntity_StopSound(self, CHAN_PLAYER);
1896                 self.modelflags &~= MF_ROCKET;
1897         }
1898
1899         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1900
1901         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1902                 return;
1903         
1904         Fire_ApplyDamage(self);
1905         Fire_ApplyEffect(self);
1906
1907         if (g_minstagib)
1908         {
1909                 self.effects |= EF_FULLBRIGHT;
1910
1911                 if (self.items & IT_STRENGTH)
1912                 {
1913                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1914                         if (time > self.strength_finished)
1915                         {
1916                                 self.alpha = default_player_alpha;
1917                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1918                                 self.items &~= IT_STRENGTH;
1919                                 sprint(self, "^3Invisibility has worn off\n");
1920                         }
1921                 }
1922                 else
1923                 {
1924                         if (time < self.strength_finished)
1925                         {
1926                                 self.alpha = g_minstagib_invis_alpha;
1927                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1928                                 self.items |= IT_STRENGTH;
1929                                 sprint(self, "^3You are invisible\n");
1930                         }
1931                 }
1932
1933                 if (self.items & IT_INVINCIBLE)
1934                 {
1935                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1936                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1937                         {
1938                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1939                                 sprint(self, "^3Speed has worn off\n");
1940                         }
1941                 }
1942                 else
1943                 {
1944                         if (time < self.invincible_finished)
1945                         {
1946                                 self.items = self.items | IT_INVINCIBLE;
1947                                 sprint(self, "^3You are on speed\n");
1948                         }
1949                 }
1950                 return;
1951         }
1952
1953         if (self.items & IT_STRENGTH)
1954         {
1955                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1956                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1957                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1958                 {
1959                         self.items = self.items - (self.items & IT_STRENGTH);
1960                         sprint(self, "^3Strength has worn off\n");
1961                 }
1962         }
1963         else
1964         {
1965                 if (time < self.strength_finished)
1966                 {
1967                         self.items = self.items | IT_STRENGTH;
1968                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1969                 }
1970         }
1971         if (self.items & IT_INVINCIBLE)
1972         {
1973                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1974                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1975                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1976                 {
1977                         self.items = self.items - (self.items & IT_INVINCIBLE);
1978                         sprint(self, "^3Shield has worn off\n");
1979                 }
1980         }
1981         else
1982         {
1983                 if (time < self.invincible_finished)
1984                 {
1985                         self.items = self.items | IT_INVINCIBLE;
1986                         sprint(self, "^3Shield surrounds you\n");
1987                 }
1988         }
1989
1990         if(cvar("g_nodepthtestplayers"))
1991                 self.effects = self.effects | EF_NODEPTHTEST;
1992
1993         if(cvar("g_fullbrightplayers"))
1994                 self.effects = self.effects | EF_FULLBRIGHT;
1995
1996         // midair gamemode: damage only while in the air
1997         // if in midair mode, being on ground grants temporary invulnerability
1998         // (this is so that multishot weapon don't clear the ground flag on the
1999         // first damage in the frame, leaving the player vulnerable to the
2000         // remaining hits in the same frame)
2001         if (self.flags & FL_ONGROUND)
2002         if (g_midair)
2003                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2004
2005         if (time >= game_starttime)
2006         if (time < self.spawnshieldtime)
2007                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2008 }
2009
2010 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2011 {
2012         if(current > stable)
2013                 return current;
2014         else if(current > stable - 0.25) // when close enough, "snap"
2015                 return stable;
2016         else
2017                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2018 }
2019
2020 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2021 {
2022         if(current < stable)
2023                 return current;
2024         else if(current < stable + 0.25) // when close enough, "snap"
2025                 return stable;
2026         else
2027                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2028 }
2029
2030 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2031 {
2032         if(current > rotstable)
2033         {
2034                 if(rotframetime > 0)
2035                 {
2036                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2037                         current = max(rotstable, current - rotlinear * rotframetime);
2038                 }
2039         }
2040         else if(current < regenstable)
2041         {
2042                 if(regenframetime > 0)
2043                 {
2044                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2045                         current = min(regenstable, current + regenlinear * regenframetime);
2046                 }
2047         }
2048
2049         if(current > limit)
2050                 current = limit;
2051
2052         return current;
2053 }
2054
2055 void player_regen (void)
2056 {
2057         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2058         maxh = cvar("g_balance_health_rotstable");
2059         maxa = cvar("g_balance_armor_rotstable");
2060         maxf = cvar("g_balance_fuel_rotstable");
2061         minh = cvar("g_balance_health_regenstable");
2062         mina = cvar("g_balance_armor_regenstable");
2063         minf = cvar("g_balance_fuel_regenstable");
2064         limith = cvar("g_balance_health_limit");
2065         limita = cvar("g_balance_armor_limit");
2066         limitf = cvar("g_balance_fuel_limit");
2067
2068         max_mod = regen_mod = rot_mod = limit_mod = 1;
2069
2070         if (self.runes & RUNE_REGEN)
2071         {
2072                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2073                 {
2074                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2075                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2076                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2077                 }
2078                 else
2079                 {
2080                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2081                         max_mod = cvar("g_balance_rune_regen_hpmod");
2082                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2083                 }
2084         }
2085         else if (self.runes & CURSE_VENOM)
2086         {
2087                 max_mod = cvar("g_balance_curse_venom_hpmod");
2088                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2089                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2090                 else
2091                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2092                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2093                 //if (!self.runes & RUNE_REGEN)
2094                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2095         }
2096         maxh = maxh * max_mod;
2097         //maxa = maxa * max_mod;
2098         //maxf = maxf * max_mod;
2099         minh = minh * max_mod;
2100         //mina = mina * max_mod;
2101         //minf = minf * max_mod;
2102         limith = limith * limit_mod;
2103         limita = limita * limit_mod;
2104         //limitf = limitf * limit_mod;
2105
2106         if(g_lms && g_ca)
2107                 rot_mod = 0;
2108
2109         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2110         {
2111                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2112                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2113
2114                 // if player rotted to death...  die!
2115                 if(self.health < 1)
2116                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2117         }
2118
2119         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2120                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2121 }
2122
2123 float zoomstate_set;
2124 void SetZoomState(float z)
2125 {
2126         if(z != self.zoomstate)
2127         {
2128                 self.zoomstate = z;
2129                 ClientData_Touch(self);
2130         }
2131         zoomstate_set = 1;
2132 }
2133
2134 void GetPressedKeys(void) {
2135         MUTATOR_CALLHOOK(GetPressedKeys);
2136         if (self.movement_x > 0) // get if movement keys are pressed
2137         {       // forward key pressed
2138                 self.pressedkeys |= KEY_FORWARD;
2139                 self.pressedkeys &~= KEY_BACKWARD;
2140         }
2141         else if (self.movement_x < 0)
2142         {       // backward key pressed
2143                 self.pressedkeys |= KEY_BACKWARD;
2144                 self.pressedkeys &~= KEY_FORWARD;
2145         }
2146         else
2147         {       // no x input
2148                 self.pressedkeys &~= KEY_FORWARD;
2149                 self.pressedkeys &~= KEY_BACKWARD;
2150         }
2151
2152         if (self.movement_y > 0)
2153         {       // right key pressed
2154                 self.pressedkeys |= KEY_RIGHT;
2155                 self.pressedkeys &~= KEY_LEFT;
2156         }
2157         else if (self.movement_y < 0)
2158         {       // left key pressed
2159                 self.pressedkeys |= KEY_LEFT;
2160                 self.pressedkeys &~= KEY_RIGHT;
2161         }
2162         else
2163         {       // no y input
2164                 self.pressedkeys &~= KEY_RIGHT;
2165                 self.pressedkeys &~= KEY_LEFT;
2166         }
2167
2168         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2169                 self.pressedkeys |= KEY_JUMP;
2170         else
2171                 self.pressedkeys &~= KEY_JUMP;
2172         if (self.BUTTON_CROUCH)
2173                 self.pressedkeys |= KEY_CROUCH;
2174         else
2175                 self.pressedkeys &~= KEY_CROUCH;
2176 }
2177
2178 void update_stats (float number, float hit, float fired) {
2179 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2180 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2181
2182         if(number) {
2183                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2184                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2185         } else {
2186                 self.stat_hit = hit * sv_accuracy_data_share;
2187                 self.stat_fired = fired * sv_accuracy_data_share;
2188         }
2189 }
2190
2191 /*
2192 ======================
2193 spectate mode routines
2194 ======================
2195 */
2196
2197 .float weapon_count;
2198 void SpectateCopy(entity spectatee) {
2199         if(spectatee.weapon_count < WEP_LAST) {
2200                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2201                 spectatee.weapon_count ++;
2202         } else
2203                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2204
2205         other = spectatee;
2206         MUTATOR_CALLHOOK(SpectateCopy);
2207         self.armortype = spectatee.armortype;
2208         self.armorvalue = spectatee.armorvalue;
2209         self.ammo_cells = spectatee.ammo_cells;
2210         self.ammo_shells = spectatee.ammo_shells;
2211         self.ammo_nails = spectatee.ammo_nails;
2212         self.ammo_rockets = spectatee.ammo_rockets;
2213         self.ammo_fuel = spectatee.ammo_fuel;
2214         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2215         self.health = spectatee.health;
2216         self.impulse = 0;
2217         self.items = spectatee.items;
2218         self.metertime = spectatee.metertime;
2219         self.strength_finished = spectatee.strength_finished;
2220         self.invincible_finished = spectatee.invincible_finished;
2221         self.pressedkeys = spectatee.pressedkeys;
2222         self.weapons = spectatee.weapons;
2223         self.switchweapon = spectatee.switchweapon;
2224         self.weapon = spectatee.weapon;
2225         self.punchangle = spectatee.punchangle;
2226         self.view_ofs = spectatee.view_ofs;
2227         self.v_angle = spectatee.v_angle;
2228         self.velocity = spectatee.velocity;
2229         self.dmg_take = spectatee.dmg_take;
2230         self.dmg_save = spectatee.dmg_save;
2231         self.dmg_inflictor = spectatee.dmg_inflictor;
2232         self.angles = spectatee.v_angle;
2233         self.fixangle = TRUE;
2234         setorigin(self, spectatee.origin);
2235         setsize(self, spectatee.mins, spectatee.maxs);
2236         SetZoomState(spectatee.zoomstate);
2237
2238         anticheat_spectatecopy(spectatee);
2239 }
2240
2241 float SpectateUpdate() {
2242         if(!self.enemy)
2243                 return 0;
2244
2245         if (self == self.enemy)
2246                 return 0;
2247
2248         if(self.enemy.classname != "player")
2249                 return 0;
2250
2251         SpectateCopy(self.enemy);
2252
2253         return 1;
2254 }
2255
2256 float SpectateNext() {
2257         other = find(self.enemy, classname, "player");
2258
2259         if (!other)
2260                 other = find(other, classname, "player");
2261
2262         if (other)
2263                 self.enemy = other;
2264
2265         if(self.enemy.classname == "player") {
2266                 msg_entity = self;
2267                 WriteByte(MSG_ONE, SVC_SETVIEW);
2268                 WriteEntity(MSG_ONE, self.enemy);
2269                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2270                 self.movetype = MOVETYPE_NONE;
2271
2272                 self.enemy.weapon_count = 0;
2273
2274                 if(!SpectateUpdate())
2275                         PutObserverInServer();
2276
2277                 return 1;
2278         } else {
2279                 return 0;
2280         }
2281 }
2282
2283 /*
2284 =============
2285 ShowRespawnCountdown()
2286
2287 Update a respawn countdown display.
2288 =============
2289 */
2290 void ShowRespawnCountdown()
2291 {
2292         float number;
2293         if(self.deadflag == DEAD_NO) // just respawned?
2294                 return;
2295         else
2296         {
2297                 number = ceil(self.death_time - time);
2298                 if(number <= 0)
2299                         return;
2300                 if(number <= self.respawn_countdown)
2301                 {
2302                         self.respawn_countdown = number - 1;
2303                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2304                                 AnnounceTo(self, strcat(ftos(number), ""));
2305                 }
2306         }
2307 }
2308
2309 void LeaveSpectatorMode()
2310 {
2311         if(isJoinAllowed()) {
2312                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2313                         self.classname = "player";
2314
2315                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2316                                 JoinBestTeam(self, FALSE, TRUE);
2317
2318                         if(cvar("g_campaign"))
2319                                 campaign_bots_may_start = 1;
2320
2321                         self.stat_count = WEP_LAST;
2322
2323                         PutClientInServer();
2324
2325                         if(self.classname == "player")
2326                                 bprint ("^4", self.netname, "^4 is playing now\n");
2327
2328                         if(!cvar("g_campaign"))
2329                                 centerprint(self,""); // clear MOTD
2330
2331                         return;
2332                 } else {
2333                         if (g_ca && self.caplayer) {
2334                         }       // do nothing
2335                         else
2336                                 stuffcmd(self,"menu_showteamselect\n");
2337                         return;
2338                 }
2339         }
2340         else {
2341                 //player may not join because of g_maxplayers is set
2342                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2343         }
2344 }
2345
2346 /**
2347  * Determines whether the player is allowed to join. This depends on cvar
2348  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2349  * it checks whether the number of currently playing players exceeds g_maxplayers.
2350  * @return bool TRUE if the player is allowed to join, false otherwise
2351  */
2352 float isJoinAllowed() {
2353         if (!cvar("g_maxplayers"))
2354                 return TRUE;
2355
2356         local entity e;
2357         local float currentlyPlaying;
2358         FOR_EACH_REALPLAYER(e) {
2359                 if(e.classname == "player")
2360                         currentlyPlaying += 1;
2361         }
2362         if(currentlyPlaying < cvar("g_maxplayers"))
2363                 return TRUE;
2364
2365         return FALSE;
2366 }
2367
2368 /**
2369  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2370  * g_maxplayers_spectator_blocktime seconds
2371  */
2372 void checkSpectatorBlock() {
2373         if(self.classname == "spectator" || self.classname == "observer") {
2374                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2375                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2376                         dropclient(self);
2377                 }
2378         }
2379 }
2380
2381 float vercmp_recursive(string v1, string v2)
2382 {
2383         float dot1, dot2;
2384         string s1, s2;
2385         float r;
2386
2387         dot1 = strstrofs(v1, ".", 0);
2388         dot2 = strstrofs(v2, ".", 0);
2389         if(dot1 == -1)
2390                 s1 = v1;
2391         else
2392                 s1 = substring(v1, 0, dot1);
2393         if(dot2 == -1)
2394                 s2 = v2;
2395         else
2396                 s2 = substring(v2, 0, dot2);
2397
2398         r = stof(s1) - stof(s2);
2399         if(r != 0)
2400                 return r;
2401
2402         r = strcasecmp(s1, s2);
2403         if(r != 0)
2404                 return r;
2405
2406         if(dot1 == -1)
2407                 if(dot2 == -1)
2408                         return 0;
2409                 else
2410                         return -1;
2411         else
2412                 if(dot2 == -1)
2413                         return 1;
2414                 else
2415                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2416 }
2417
2418 float vercmp(string v1, string v2)
2419 {
2420         if(strcasecmp(v1, v2) == 0) // early out check
2421                 return 0;
2422         return vercmp_recursive(v1, v2);
2423 }
2424
2425 void ObserverThink()
2426 {
2427         if (self.flags & FL_JUMPRELEASED) {
2428                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2429                         self.welcomemessage_time = 0;
2430                         self.flags &~= FL_JUMPRELEASED;
2431                         self.flags |= FL_SPAWNING;
2432                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2433                         self.welcomemessage_time = 0;
2434                         self.flags &~= FL_JUMPRELEASED;
2435                         if(SpectateNext() == 1) {
2436                                 self.classname = "spectator";
2437                         }
2438                 }
2439         } else {
2440                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2441                         self.flags |= FL_JUMPRELEASED;
2442                         if(self.flags & FL_SPAWNING)
2443                         {
2444                                 self.flags &~= FL_SPAWNING;
2445                                 LeaveSpectatorMode();
2446                                 return;
2447                         }
2448                 }
2449         }
2450         PrintWelcomeMessage(self);
2451 }
2452
2453 void SpectatorThink()
2454 {
2455         if (self.flags & FL_JUMPRELEASED) {
2456                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2457                         self.welcomemessage_time = 0;
2458                         self.flags &~= FL_JUMPRELEASED;
2459                         self.flags |= FL_SPAWNING;
2460                 } else if(self.BUTTON_ATCK) {
2461                         self.welcomemessage_time = 0;
2462                         self.flags &~= FL_JUMPRELEASED;
2463                         if(SpectateNext() == 1) {
2464                                 self.classname = "spectator";
2465                         } else {
2466                                 self.classname = "observer";
2467                                 self.stat_count = WEP_LAST;
2468                                 PutClientInServer();
2469                         }
2470                 } else if (self.BUTTON_ATCK2) {
2471                         self.welcomemessage_time = 0;
2472                         self.flags &~= FL_JUMPRELEASED;
2473                         self.classname = "observer";
2474                         self.stat_count = WEP_LAST;
2475                         PutClientInServer();
2476                 } else {
2477                         if(!SpectateUpdate())
2478                                 PutObserverInServer();
2479                 }
2480         } else {
2481                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2482                         self.flags |= FL_JUMPRELEASED;
2483                         if(self.flags & FL_SPAWNING)
2484                         {
2485                                 self.flags &~= FL_SPAWNING;
2486                                 LeaveSpectatorMode();
2487                                 return;
2488                         }
2489                 }
2490         }
2491
2492         PrintWelcomeMessage(self);
2493         self.flags |= FL_CLIENT | FL_NOTARGET;
2494 }
2495
2496 .float touchexplode_time;
2497
2498 /*
2499 =============
2500 PlayerPreThink
2501
2502 Called every frame for each client before the physics are run
2503 =============
2504 */
2505 void() ctf_setstatus;
2506 void() nexball_setstatus;
2507 .float items_added;
2508 void PlayerPreThink (void)
2509 {
2510         self.stat_game_starttime = game_starttime;
2511         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2512         self.stat_leadlimit = cvar("leadlimit");
2513
2514         if(frametime)
2515         {
2516                 // physics frames: update anticheat stuff
2517                 anticheat_prethink();
2518         }
2519
2520         if(blockSpectators && frametime)
2521                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2522                 checkSpectatorBlock();
2523
2524         zoomstate_set = 0;
2525
2526         if(self.netname_previous != self.netname)
2527         {
2528                 if(cvar("sv_eventlog"))
2529                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2530                 if(self.netname_previous)
2531                         strunzone(self.netname_previous);
2532                 self.netname_previous = strzone(self.netname);
2533         }
2534
2535         // version nagging
2536         if(self.version_nagtime)
2537                 if(self.cvar_g_xonoticversion)
2538                         if(time > self.version_nagtime)
2539                         {
2540                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2541                                 {
2542                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2543                                         {
2544                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2545                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2546                                         }
2547                                         else
2548                                         {
2549                                                 float r;
2550                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2551                                                 if(r < 0)
2552                                                 {
2553                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2554                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2555                                                 }
2556                                                 else if(r > 0)
2557                                                 {
2558                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2559                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2560                                                 }
2561                                         }
2562                                 }
2563                                 self.version_nagtime = 0;
2564                         }
2565
2566         // GOD MODE info
2567         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2568         {
2569                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2570                 self.max_armorvalue = 0;
2571         }
2572
2573 #ifdef TETRIS
2574         if (TetrisPreFrame())
2575                 return;
2576 #endif
2577
2578         MUTATOR_CALLHOOK(PlayerPreThink);
2579
2580         if(self.classname == "player") {
2581 //              if(self.netname == "Wazat")
2582 //                      bprint(self.classname, "\n");
2583
2584                 CheckRules_Player();
2585
2586                 PrintWelcomeMessage(self);
2587
2588                 if (intermission_running)
2589                 {
2590                         IntermissionThink ();   // otherwise a button could be missed between
2591                         return;                                 // the think tics
2592                 }
2593
2594                 if(self.teleport_time)
2595                 if(time > self.teleport_time)
2596                 {
2597                         self.teleport_time = 0;
2598                         self.effects = self.effects - (self.effects & EF_NODRAW);
2599                 }
2600
2601                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2602                         UpdateSelectedPlayer();
2603
2604                 //don't allow the player to turn around while game is paused!
2605                 if(timeoutStatus == 2) {
2606                         self.v_angle = self.lastV_angle;
2607                         self.angles = self.lastV_angle;
2608                         self.fixangle = TRUE;
2609                 }
2610
2611                 if(frametime)
2612                 {
2613                         if(self.health <= 0 && cvar("g_deathglow"))
2614                         {
2615                                 if(self.glowmod_x > 0)
2616                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2617                                 else
2618                                         self.glowmod_x = -1;
2619                                 if(self.glowmod_y > 0)
2620                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2621                                 else
2622                                         self.glowmod_y = -1;
2623                                 if(self.glowmod_z > 0)
2624                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2625                                 else
2626                                         self.glowmod_z = -1;
2627                         }
2628                         else
2629                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2630                         player_powerups();
2631                 }
2632
2633                 if (self.deadflag != DEAD_NO)
2634                 {
2635                         float button_pressed, force_respawn;
2636                         if(self.personal && g_race_qualifying)
2637                         {
2638                                 if(time > self.death_time)
2639                                 {
2640                                         self.death_time = time + 1; // only retry once a second
2641                                         respawn();
2642                                         self.impulse = 141;
2643                                 }
2644                         }
2645                         else
2646                         {
2647                                 if(frametime)
2648                                         player_anim();
2649                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2650                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2651                                 if (self.deadflag == DEAD_DYING)
2652                                 {
2653                                         if(force_respawn)
2654                                                 self.deadflag = DEAD_RESPAWNING;
2655                                         else if(!button_pressed)
2656                                                 self.deadflag = DEAD_DEAD;
2657                                 }
2658                                 else if (self.deadflag == DEAD_DEAD)
2659                                 {
2660                                         if(button_pressed)
2661                                                 self.deadflag = DEAD_RESPAWNABLE;
2662                                 }
2663                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2664                                 {
2665                                         if(!button_pressed)
2666                                                 self.deadflag = DEAD_RESPAWNING;
2667                                 }
2668                                 else if (self.deadflag == DEAD_RESPAWNING)
2669                                 {
2670                                         if(time > self.death_time)
2671                                         {
2672                                                 self.death_time = time + 1; // only retry once a second
2673                                                 respawn();
2674                                         }
2675                                 }
2676                                 ShowRespawnCountdown();
2677                         }
2678                         return;
2679                 }
2680
2681                 if(g_touchexplode)
2682                 if(time > self.touchexplode_time)
2683                 if(self.classname == "player")
2684                 if(self.deadflag == DEAD_NO)
2685                 if not(IS_INDEPENDENT_PLAYER(self))
2686                 FOR_EACH_PLAYER(other) if(self != other)
2687                 {
2688                         if(time > other.touchexplode_time)
2689                         if(other.deadflag == DEAD_NO)
2690                         if not(IS_INDEPENDENT_PLAYER(other))
2691                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2692                         {
2693                                 PlayerTouchExplode(self, other);
2694                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2695                         }
2696                 }
2697
2698                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2699                 {
2700                         vector dist;
2701
2702                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2703                         dist = self.prevorigin - self.origin;
2704                         dist_z = 0;
2705                         self.lms_traveled_distance += fabs(vlen(dist));
2706
2707                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2708                         {
2709                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2710                                 self.lms_traveled_distance = 0;
2711                         }
2712
2713                         if(time > self.lms_nextcheck)
2714                         {
2715                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2716                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2717                                 {
2718                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2719                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2720                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2721                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2722                                 }
2723                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2724                                 self.lms_traveled_distance = 0;
2725                         }
2726                 }
2727
2728                 self.prevorigin = self.origin;
2729
2730                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2731                 {
2732                         if (!self.crouch)
2733                         {
2734                                 self.crouch = TRUE;
2735                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2736                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2737                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2738                         }
2739                 }
2740                 else
2741                 {
2742                         if (self.crouch)
2743                         {
2744                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2745                                 if (!trace_startsolid)
2746                                 {
2747                                         self.crouch = FALSE;
2748                                         self.view_ofs = PL_VIEW_OFS;
2749                                         setsize (self, PL_MIN, PL_MAX);
2750                                 }
2751                         }
2752                 }
2753
2754                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2755                 {
2756                         if(self.bloodloss_timer < time)
2757                         {
2758                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2759                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2760                         }
2761                 }
2762
2763                 FixPlayermodel();
2764
2765                 GrapplingHookFrame();
2766
2767                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2768                 //if(frametime)
2769                 {
2770                         self.items &~= self.items_added;
2771
2772                         W_WeaponFrame();
2773
2774                         self.items_added = 0;
2775                         if(self.items & IT_JETPACK)
2776                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2777                                         self.items_added |= IT_FUEL;
2778
2779                         self.items |= self.items_added;
2780                 }
2781
2782                 player_regen();
2783                 if(frametime)
2784                         player_anim();
2785
2786                 if (g_minstagib)
2787                         minstagib_ammocheck();
2788
2789                 ctf_setstatus();
2790                 nexball_setstatus();
2791
2792                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2793
2794                 //self.angles_y=self.v_angle_y + 90;   // temp
2795         } else if(gameover) {
2796                 if (intermission_running)
2797                         IntermissionThink ();   // otherwise a button could be missed between
2798                 return;
2799         } else if(self.classname == "observer") {
2800                 ObserverThink();
2801         } else if(self.classname == "spectator") {
2802                 SpectatorThink();
2803         }
2804
2805         if(!zoomstate_set)
2806                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2807
2808         float oldspectatee_status;
2809         oldspectatee_status = self.spectatee_status;
2810         if(self.classname == "spectator")
2811                 self.spectatee_status = num_for_edict(self.enemy);
2812         else if(self.classname == "observer")
2813                 self.spectatee_status = num_for_edict(self);
2814         else
2815                 self.spectatee_status = 0;
2816         if(self.spectatee_status != oldspectatee_status)
2817         {
2818                 ClientData_Touch(self);
2819                 if(g_race || g_cts)
2820                         race_InitSpectator();
2821         }
2822
2823         if(self.teamkill_soundtime)
2824         if(time > self.teamkill_soundtime)
2825         {
2826                 self.teamkill_soundtime = 0;
2827
2828                 entity oldpusher, oldself;
2829
2830                 oldself = self; self = self.teamkill_soundsource;
2831                 oldpusher = self.pusher; self.pusher = oldself;
2832
2833                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2834
2835                 self.pusher = oldpusher;
2836                 self = oldself;
2837         }
2838
2839         if(self.taunt_soundtime)
2840         if(time > self.taunt_soundtime)
2841         {
2842                 self.taunt_soundtime = 0;
2843                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2844         }
2845
2846         target_voicescript_next(self);
2847 }
2848
2849 float isInvisibleString(string s)
2850 {
2851         float i, n, c;
2852         s = strdecolorize(s);
2853         for((i = 0), (n = strlen(s)); i < n; ++i)
2854         {
2855                 c = str2chr(s, i);
2856                 switch(c)
2857                 {
2858                         case 0:
2859                         case 32:
2860                         case 160:
2861                                 break;
2862                         default:
2863                                 return FALSE;
2864                 }
2865         }
2866         return TRUE;
2867 }
2868
2869 /*
2870 =============
2871 PlayerPostThink
2872
2873 Called every frame for each client after the physics are run
2874 =============
2875 */
2876 .float idlekick_lasttimeleft;
2877 .entity showheadshotbbox;
2878 void showheadshotbbox_think()
2879 {
2880         if(self.owner.showheadshotbbox != self)
2881         {
2882                 remove(self);
2883                 return;
2884         }
2885         self.nextthink = time;
2886         setorigin(self, self.owner.origin);
2887         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2888 }
2889 void PlayerPostThink (void)
2890 {
2891         // Savage: Check for nameless players
2892         if (isInvisibleString(self.netname)) {
2893                 self.netname = "Player";
2894                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2895         }
2896
2897         // send the clients accuracy stats to the client
2898         if(self.stat_count > 0)
2899         if(frametime)
2900         {
2901                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2902                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2903                 self.stat_count -= 1;
2904         }
2905
2906 #ifdef UID
2907         if(self.uid_kicktime)
2908         if(time > self.uid_kicktime)
2909         {
2910                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2911                 dropclient(self);
2912                 return;
2913         }
2914 #endif
2915
2916         if(sv_maxidle && frametime)
2917         {
2918                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2919                 float timeleft;
2920                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2921                 if(timeleft <= 0)
2922                 {
2923                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2924                         AnnounceTo(self, "terminated");
2925                         dropclient(self);
2926                         return;
2927                 }
2928                 else if(timeleft <= 10)
2929                 {
2930                         if(timeleft != self.idlekick_lasttimeleft)
2931                         {
2932                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2933                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2934                         }
2935                 }
2936                 else
2937                 {
2938                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2939                 }
2940                 self.idlekick_lasttimeleft = timeleft;
2941         }
2942
2943 #ifdef TETRIS
2944         if(self.impulse == 100)
2945                 ImpulseCommands();
2946         if (TetrisPostFrame())
2947                 return;
2948 #endif
2949
2950         CheatFrame();
2951
2952         if(self.classname == "player") {
2953                 CheckRules_Player();
2954                 UpdateChatBubble();
2955                 UpdateTeamBubble();
2956                 if (self.impulse)
2957                         ImpulseCommands();
2958                 if (intermission_running)
2959                         return;         // intermission or finale
2960                 GetPressedKeys();
2961         } else if (self.classname == "observer") {
2962                 //do nothing
2963         } else if (self.classname == "spectator") {
2964                 //do nothing
2965         }
2966
2967         /*
2968         float i;
2969         for(i = 0; i < 1000; ++i)
2970         {
2971                 vector end;
2972                 end = self.origin + '0 0 1024' + 512 * randomvec();
2973                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2974                 if(trace_fraction < 1)
2975                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2976                 {
2977                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2978                         break;
2979                 }
2980         }
2981         */
2982
2983         Arena_Warmup();
2984
2985         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2986
2987         if(self.waypointsprite_attachedforcarrier)
2988                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2989         
2990         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2991         {
2992                 if(!self.showheadshotbbox)
2993                 {
2994                         self.showheadshotbbox = spawn();
2995                         self.showheadshotbbox.classname = "headshotbbox";
2996                         self.showheadshotbbox.owner = self;
2997                         self.showheadshotbbox.think = showheadshotbbox_think;
2998                         self.showheadshotbbox.nextthink = time;
2999                         self = self.showheadshotbbox;
3000                         self.think();
3001                         self = self.owner;
3002                 }
3003         }
3004         else
3005         {
3006                 if(self.showheadshotbbox)
3007                         remove(self.showheadshotbbox);
3008         }
3009
3010         playerdemo_write();
3011
3012         /*
3013         if(g_race)
3014                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3015         */
3016 }