qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 if(cvar("g_playerclip_collisions"))
 870                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 871                 else
 872                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 873                 self.frags = FRAGS_PLAYER;
 874                 if(independent_players)
 875                         MAKE_INDEPENDENT_PLAYER(self);
 876                 self.flags = FL_CLIENT;
 877                 self.takedamage = DAMAGE_AIM;
 878                 if(g_minstagib)
 879                         self.effects = EF_FULLBRIGHT;
 880                 else
 881                         self.effects = 0;
 882                 self.air_finished = time + 12;
 883                 self.dmg = 2;
 884
 885                 if(inWarmupStage)
 886                 {
 887                         self.ammo_shells = warmup_start_ammo_shells;
 888                         self.ammo_nails = warmup_start_ammo_nails;
 889                         self.ammo_rockets = warmup_start_ammo_rockets;
 890                         self.ammo_cells = warmup_start_ammo_cells;
 891                         self.ammo_fuel = warmup_start_ammo_fuel;
 892                         self.health = warmup_start_health;
 893                         self.armorvalue = warmup_start_armorvalue;
 894                         self.weapons = warmup_start_weapons;
 895                 }
 896                 else
 897                 {
 898                         self.ammo_shells = start_ammo_shells;
 899                         self.ammo_nails = start_ammo_nails;
 900                         self.ammo_rockets = start_ammo_rockets;
 901                         self.ammo_cells = start_ammo_cells;
 902                         self.ammo_fuel = start_ammo_fuel;
 903                         self.health = start_health;
 904                         self.armorvalue = start_armorvalue;
 905                         self.weapons = start_weapons;
 906                 }
 907
 908                 if(g_weaponarena_random)
 909                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 910
 911                 self.items = start_items;
 912                 self.jump_interval = time;
 913
 914                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 915                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 916                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 917                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 918                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 919                 //extend the pause of rotting if client was reset at the beginning of the countdown
 920                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 921                         self.spawnshieldtime += game_starttime - time;
 922                         self.pauserotarmor_finished += game_starttime - time;
 923                         self.pauserothealth_finished += game_starttime - time;
 924                         self.pauseregen_finished += game_starttime - time;
 925                 }
 926                 self.damageforcescale = 2;
 927                 self.death_time = 0;
 928                 self.dead_frame = 0;
 929                 self.alpha = 0;
 930                 self.scale = 0;
 931                 self.fade_time = 0;
 932                 self.pain_frame = 0;
 933                 self.pain_finished = 0;
 934                 self.strength_finished = 0;
 935                 self.invincible_finished = 0;
 936                 self.pushltime = 0;
 937                 // players have no think function
 938                 self.think = SUB_Null;
 939                 self.nextthink = 0;
 940                 self.hook_time = 0;
 941                 self.dmg_team = 0;
 942                 self.ballistics_density = cvar("g_ballistics_density_player");
 943
 944                 self.metertime = 0;
 945
 946                 self.runes = 0;
 947
 948                 self.deadflag = DEAD_NO;
 949
 950                 self.angles = spot.angles;
 951
 952                 self.angles_z = 0; // never spawn tilted even if the spot says to
 953                 self.fixangle = TRUE; // turn this way immediately
 954                 self.velocity = '0 0 0';
 955                 self.avelocity = '0 0 0';
 956                 self.punchangle = '0 0 0';
 957                 self.punchvector = '0 0 0';
 958                 self.oldvelocity = self.velocity;
 959                 self.fire_endtime = -1;
 960
 961                 msg_entity = self;
 962                 WRITESPECTATABLE_MSG_ONE({
 963                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 964                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 965                 });
 966
 967                 if(sv_loddistance1)
 968                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 969
 970                 self.model = "";
 971                 FixPlayermodel();
 972
 973                 self.crouch = FALSE;
 974                 self.view_ofs = PL_VIEW_OFS;
 975                 setsize (self, PL_MIN, PL_MAX);
 976                 self.spawnorigin = spot.origin;
 977                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 978                 // don't reset back to last position, even if new position is stuck in solid
 979                 self.oldorigin = self.origin;
 980                 self.prevorigin = self.origin;
 981                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 982
 983                 if(g_arena)
 984                 {
 985                         Spawnqueue_Remove(self);
 986                         Spawnqueue_Mark(self);
 987                 }
 988
 989                 else if(g_ca)
 990                         self.caplayer = 1;
 991
 992                 self.event_damage = PlayerDamage;
 993
 994                 self.bot_attack = TRUE;
 995
 996                 self.statdraintime = time + 5;
 997                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 998
 999                 if(self.killcount == -666) {
1000                         PlayerScore_Clear(self);
1001                         self.killcount = 0;
1002                 }
1003
1004                 self.cnt = WEP_LASER;
1005
1006                 CL_SpawnWeaponentity();
1007                 self.alpha = default_player_alpha;
1008                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1009                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1010
1011                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1012                 self.lms_traveled_distance = 0;
1013                 self.speedrunning = FALSE;
1014
1015                 race_PostSpawn(spot);
1016
1017                 if(cvar("spawn_debug"))
1018                 {
1019                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1020                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1021                 }
1022
1023                 //stuffcmd(self, "chase_active 0");
1024                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1025
1026                 if (cvar("g_spawnsound"))
1027                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1028
1029                 if(g_assault) {
1030                         if(self.team == assault_attacker_team)
1031                                 centerprint(self, "You are attacking!");
1032                         else
1033                                 centerprint(self, "You are defending!");
1034                 }
1035
1036                 target_voicescript_clear(self);
1037
1038                 // reset fields the weapons may use
1039                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1040                         weapon_action(j, WR_RESETPLAYER);
1041
1042                 oldself = self;
1043                 self = spot;
1044                         activator = oldself;
1045                                 SUB_UseTargets();
1046                         activator = world;
1047                 self = oldself;
1048
1049                 MUTATOR_CALLHOOK(PlayerSpawn);
1050
1051                 self.switchweapon = w_getbestweapon(self);
1052                 self.cnt = self.switchweapon;
1053                 self.weapon = 0;
1054         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1055                 PutObserverInServer ();
1056         }
1057
1058         //if(g_ctf)
1059         //      ctf_playerchanged();
1060 }
1061
1062 float ClientInit_SendEntity(entity to, float sf)
1063 {
1064         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1065         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1066         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1067         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1068         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1069         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1070         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1071         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1072         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1073         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1074         if(sv_foginterval && world.fog != "")
1075                 WriteString(MSG_ENTITY, world.fog);
1076         else
1077                 WriteString(MSG_ENTITY, "");
1078         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1079         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1080         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1081         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1082         return TRUE;
1083 }
1084
1085 void ClientInit_CheckUpdate()
1086 {
1087         self.nextthink = time;
1088         if(self.count != cvar("g_balance_armor_blockpercent"))
1089         {
1090                 self.count = cvar("g_balance_armor_blockpercent");
1091                 self.SendFlags |= 1;
1092         }
1093         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1094         {
1095                 self.cnt = cvar("g_balance_weaponswitchdelay");
1096                 self.SendFlags |= 1;
1097         }
1098         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1099         {
1100                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1101                 self.SendFlags |= 1;
1102         }
1103         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1104         {
1105                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1106                 self.SendFlags |= 1;
1107         }
1108 }
1109
1110 void ClientInit_Spawn()
1111 {
1112         entity o;
1113         entity e;
1114         e = spawn();
1115         e.classname = "clientinit";
1116         e.think = ClientInit_CheckUpdate;
1117         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1118
1119         o = self;
1120         self = e;
1121         ClientInit_CheckUpdate();
1122         self = o;
1123 }
1124
1125 /*
1126 =============
1127 SetNewParms
1128 =============
1129 */
1130 void SetNewParms (void)
1131 {
1132         // initialize parms for a new player
1133         parm1 = -(86400 * 366);
1134 }
1135
1136 /*
1137 =============
1138 SetChangeParms
1139 =============
1140 */
1141 void SetChangeParms (void)
1142 {
1143         // save parms for level change
1144         parm1 = self.parm_idlesince - time;
1145 }
1146
1147 /*
1148 =============
1149 DecodeLevelParms
1150 =============
1151 */
1152 void DecodeLevelParms (void)
1153 {
1154         // load parms
1155         self.parm_idlesince = parm1;
1156         if(self.parm_idlesince == -(86400 * 366))
1157                 self.parm_idlesince = time;
1158
1159         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1160         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1161 }
1162
1163 /*
1164 =============
1165 ClientKill
1166
1167 Called when a client types 'kill' in the console
1168 =============
1169 */
1170
1171 void ClientKill_Now_TeamChange()
1172 {
1173         if(self.killindicator_teamchange == -1)
1174         {
1175                 self.team = -1;
1176                 JoinBestTeam( self, FALSE, FALSE );
1177         }
1178         else
1179                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1180 }
1181
1182 void ClientKill_Now()
1183 {
1184         if(self.killindicator_teamchange)
1185                 ClientKill_Now_TeamChange();
1186
1187         // in any case:
1188         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1189
1190         if(self.killindicator)
1191         {
1192                 dprint("Cleaned up after a leaked kill indicator.\n");
1193                 remove(self.killindicator);
1194                 self.killindicator = world;
1195         }
1196 }
1197 void KillIndicator_Think()
1198 {
1199         if (!self.owner.modelindex)
1200         {
1201                 self.owner.killindicator = world;
1202                 remove(self);
1203                 return;
1204         }
1205
1206         if(self.cnt <= 0)
1207         {
1208                 self = self.owner;
1209                 ClientKill_Now(); // no oldself needed
1210                 return;
1211         }
1212         else
1213         {
1214                 if(self.cnt <= 10)
1215                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1216                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1217                 {
1218                         if(self.cnt <= 10)
1219                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1220                         if(self.owner.killindicator_teamchange)
1221                         {
1222                                 if(self.owner.killindicator_teamchange == -1)
1223                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1224                                 else
1225                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1226                         }
1227                         else
1228                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1229                 }
1230                 self.nextthink = time + 1;
1231                 self.cnt -= 1;
1232         }
1233 }
1234
1235 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1236 {
1237         float killtime;
1238         entity e;
1239         killtime = cvar("g_balance_kill_delay");
1240
1241         if(g_race_qualifying)
1242                 killtime = 0;
1243
1244         self.killindicator_teamchange = targetteam;
1245
1246         if(!self.killindicator)
1247         {
1248                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1249                 {
1250                         ClientKill_Now();
1251                 }
1252                 else
1253                 {
1254                         self.killindicator = spawn();
1255                         self.killindicator.owner = self;
1256                         self.killindicator.scale = 0.5;
1257                         setattachment(self.killindicator, self, "");
1258                         setorigin(self.killindicator, '0 0 52');
1259                         self.killindicator.think = KillIndicator_Think;
1260                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1261                         self.killindicator.cnt = ceil(killtime);
1262                         self.killindicator.count = bound(0, ceil(killtime), 10);
1263                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1264
1265                         for(e = world; (e = find(e, classname, "body")) != world; )
1266                         {
1267                                 if(e.enemy != self)
1268                                         continue;
1269                                 e.killindicator = spawn();
1270                                 e.killindicator.owner = e;
1271                                 e.killindicator.scale = 0.5;
1272                                 setattachment(e.killindicator, e, "");
1273                                 setorigin(e.killindicator, '0 0 52');
1274                                 e.killindicator.think = KillIndicator_Think;
1275                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1276                                 e.killindicator.cnt = ceil(killtime);
1277                         }
1278                         self.lip = 0;
1279                 }
1280         }
1281         if(self.killindicator)
1282         {
1283                 if(targetteam)
1284                         self.killindicator.colormod = TeamColor(targetteam);
1285                 else
1286                         self.killindicator.colormod = '0 0 0';
1287         }
1288 }
1289
1290 void ClientKill (void)
1291 {
1292         ClientKill_TeamChange(0);
1293 }
1294
1295 void DoTeamChange(float destteam)
1296 {
1297         float t, c0;
1298         if(!teams_matter)
1299         {
1300                 if(destteam >= 0)
1301                         SetPlayerColors(self, destteam);
1302                 return;
1303         }
1304         if(self.classname == "player")
1305         if(destteam == -1)
1306         {
1307                 CheckAllowedTeams(self);
1308                 t = FindSmallestTeam(self, TRUE);
1309                 switch(self.team)
1310                 {
1311                         case COLOR_TEAM1: c0 = c1; break;
1312                         case COLOR_TEAM2: c0 = c2; break;
1313                         case COLOR_TEAM3: c0 = c3; break;
1314                         case COLOR_TEAM4: c0 = c4; break;
1315                         default:          c0 = 999;
1316                 }
1317                 switch(t)
1318                 {
1319                         case 1:
1320                                 if(c0 > c1)
1321                                         destteam = COLOR_TEAM1;
1322                                 break;
1323                         case 2:
1324                                 if(c0 > c2)
1325                                         destteam = COLOR_TEAM2;
1326                                 break;
1327                         case 3:
1328                                 if(c0 > c3)
1329                                         destteam = COLOR_TEAM3;
1330                                 break;
1331                         case 4:
1332                                 if(c0 > c4)
1333                                         destteam = COLOR_TEAM4;
1334                                 break;
1335                 }
1336                 if(destteam == -1)
1337                         return;
1338         }
1339         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1340                 return;
1341         ClientKill_TeamChange(destteam);
1342 }
1343
1344 void FixClientCvars(entity e)
1345 {
1346         // send prediction settings to the client
1347         stuffcmd(e, "\nin_bindmap 0 0\n");
1348         if(g_race || g_cts)
1349                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1350         if(cvar("g_antilag") == 3) // client side hitscan
1351                 //stuffcmd(e, "cl_cmd settemp cl_prydoncursor -1\ncl_cmd settemp cl_prydoncursor_notrace 0\n");
1352                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1353         /*
1354          * we no longer need to stuff this. Remove this comment block if you feel
1355          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1356         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1357         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1358         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1359         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1360         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1361         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1362         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1363         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1364         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1365         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1366         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1367         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1368         stuffcmd(e, "cl_movement_edgefriction 1\n");
1369          */
1370 }
1371
1372 /*
1373 =============
1374 ClientConnect
1375
1376 Called when a client connects to the server
1377 =============
1378 */
1379 //void ctf_clientconnect();
1380 string ColoredTeamName(float t);
1381 void DecodeLevelParms (void);
1382 //void dom_player_join_team(entity pl);
1383 #ifdef UID
1384 .float uid_kicktime;
1385 .string uid;
1386 #endif
1387 void ClientConnect (void)
1388 {
1389         float t;
1390
1391         if(self.flags & FL_CLIENT)
1392         {
1393                 print("Warning: ClientConnect, but already connected!\n");
1394                 return;
1395         }
1396
1397         if(Ban_MaybeEnforceBan(self))
1398                 return;
1399
1400         DecodeLevelParms();
1401
1402 #ifdef WATERMARK
1403         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1404 #endif
1405
1406         self.classname = "player_joining";
1407
1408         self.flags = FL_CLIENT;
1409         self.version_nagtime = time + 10 + random() * 10;
1410
1411         if(player_count<0)
1412         {
1413                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1414                 player_count = 0;
1415         }
1416
1417         PlayerScore_Attach(self);
1418         ClientData_Attach();
1419
1420         bot_clientconnect();
1421
1422         playerdemo_init();
1423
1424         anticheat_init();
1425
1426         race_PreSpawnObserver();
1427
1428         //if(g_domination)
1429         //      dom_player_join_team(self);
1430
1431         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1432
1433         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1434                 self.classname = "observer";
1435         } else {
1436                 if(teams_matter)
1437                 {
1438                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1439                         {
1440                                 self.classname = "player";
1441                                 campaign_bots_may_start = 1;
1442                         }
1443                         else
1444                         {
1445                                 self.classname = "observer"; // do it anyway
1446                         }
1447                 }
1448                 else
1449                 {
1450                         self.classname = "player";
1451                         campaign_bots_may_start = 1;
1452                 }
1453         }
1454
1455         self.playerid = (playerid_last = playerid_last + 1);
1456
1457         if(cvar("sv_eventlog"))
1458                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1459
1460         LogTeamchange(self.playerid, self.team, 1);
1461
1462         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1463
1464         self.netname_previous = strzone(self.netname);
1465
1466         bprint("^4", self.netname, "^4 connected");
1467
1468         if(self.classname != "observer" && (g_domination || g_ctf))
1469                 bprint(" and joined the ", ColoredTeamName(self.team));
1470
1471         bprint("\n");
1472
1473         self.welcomemessage_time = 0;
1474
1475         stuffcmd(self, strcat(clientstuff, "\n"));
1476         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1477         stuffcmd(self, "cl_particles_reloadeffects\n");
1478
1479         FixClientCvars(self);
1480
1481         // spawnfunc_waypoint sprites
1482         WaypointSprite_InitClient(self);
1483
1484         // Wazat's grappling hook
1485         SetGrappleHookBindings();
1486
1487         // get autoswitch state from player when he toggles it
1488         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1489
1490         // get version info from player
1491         stuffcmd(self, "cmd clientversion $gameversion\n");
1492
1493         // get other cvars from player
1494         GetCvars(0);
1495
1496         // set cvar for team scoreboard
1497         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1498
1499         // notify about available teams
1500         if(teams_matter)
1501         {
1502                 CheckAllowedTeams(self);
1503                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1504                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1505         }
1506         else
1507                 stuffcmd(self, "set _teams_available 0\n");
1508
1509         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1510
1511         if(g_arena || g_ca)
1512         {
1513                 self.classname = "observer";
1514                 if(g_arena)
1515                         Spawnqueue_Insert(self);
1516         }
1517         /*else if(g_ctf)
1518         {
1519                 ctf_clientconnect();
1520         }*/
1521
1522         if(teams_matter || radar_showennemies)
1523                 attach_entcs();
1524
1525         bot_relinkplayerlist();
1526
1527         self.spectatortime = time;
1528         if(blockSpectators)
1529         {
1530                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1531         }
1532
1533         self.jointime = time;
1534         self.allowedTimeouts = cvar("sv_timeout_number");
1535
1536         if(clienttype(self) == CLIENTTYPE_REAL)
1537         {
1538                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1539                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1540         }
1541
1542         if(g_lms)
1543         {
1544                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1545                 {
1546                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1547                         self.frags = FRAGS_SPECTATOR;
1548                 }
1549         }
1550
1551         if(!sv_foginterval && world.fog != "")
1552                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1553
1554         SoundEntity_Attach(self);
1555
1556         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1557         {
1558                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1559                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1560         }
1561         else
1562                 self.hitplotfh = -1;
1563
1564 #ifdef UID
1565         if(clienttype(self) == CLIENTTYPE_REAL)
1566         if not(self.uid)
1567                 self.uid_kicktime = time + 60;
1568 #endif
1569
1570         if(g_race || g_cts) {
1571                 string rr;
1572                 if(g_cts)
1573                         rr = CTS_RECORD;
1574                 else
1575                         rr = RACE_RECORD;
1576                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1577
1578                 race_send_recordtime(MSG_ONE);
1579                 race_send_speedaward(MSG_ONE);
1580
1581                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1582                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1583                 race_send_speedaward_alltimebest(MSG_ONE);
1584
1585                 float i;
1586                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1587                         race_SendRankings(i, 0, 0, MSG_ONE);
1588                 }
1589         }
1590         else if(cvar("sv_teamnagger") && !g_ca) // teamnagger is currently bad for ca
1591                 send_CSQC_teamnagger();
1592
1593         CheatInitClient();
1594 }
1595
1596 /*
1597 =============
1598 ClientDisconnect
1599
1600 Called when a client disconnects from the server
1601 =============
1602 */
1603 .entity chatbubbleentity;
1604 .entity teambubbleentity;
1605 void ReadyCount();
1606 void ClientDisconnect (void)
1607 {
1608         if not(self.flags & FL_CLIENT)
1609         {
1610                 print("Warning: ClientDisconnect without ClientConnect\n");
1611                 return;
1612         }
1613
1614         CheatShutdownClient();
1615
1616         if(self.hitplotfh >= 0)
1617         {
1618                 fclose(self.hitplotfh);
1619                 self.hitplotfh = -1;
1620         }
1621
1622         anticheat_report();
1623         anticheat_shutdown();
1624
1625         playerdemo_shutdown();
1626
1627         bot_clientdisconnect();
1628
1629         if(self.entcs)
1630                 detach_entcs();
1631
1632         if(cvar("sv_eventlog"))
1633                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1634         bprint ("^4",self.netname);
1635         bprint ("^4 disconnected\n");
1636
1637         SoundEntity_Detach(self);
1638
1639         DropAllRunes(self);
1640         MUTATOR_CALLHOOK(ClientDisconnect);
1641
1642         Portal_ClearAll(self);
1643
1644         if(self.flagcarried)
1645                 DropFlag(self.flagcarried, world, world);
1646         if(self.ballcarried)
1647                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1648
1649         // Here, everything has been done that requires this player to be a client.
1650
1651         self.flags &~= FL_CLIENT;
1652
1653         if (self.chatbubbleentity)
1654                 remove (self.chatbubbleentity);
1655
1656         if (self.teambubbleentity)
1657                 remove (self.teambubbleentity);
1658
1659         if (self.killindicator)
1660                 remove (self.killindicator);
1661
1662         WaypointSprite_PlayerGone();
1663
1664         bot_relinkplayerlist();
1665
1666         // remove laserdot
1667         if(self.weaponentity)
1668                 if(self.weaponentity.lasertarget)
1669                         remove(self.weaponentity.lasertarget);
1670
1671         if(g_arena)
1672         {
1673                 Spawnqueue_Unmark(self);
1674                 Spawnqueue_Remove(self);
1675         }
1676
1677         ClientData_Detach();
1678         PlayerScore_Detach(self);
1679
1680         if(self.netname_previous)
1681                 strunzone(self.netname_previous);
1682         if(self.clientstatus)
1683                 strunzone(self.clientstatus);
1684
1685         ClearPlayerSounds();
1686
1687         if(self.personal)
1688                 remove(self.personal);
1689
1690         self.playerid = 0;
1691         ReadyCount();
1692
1693         // free cvars
1694         GetCvars(-1);
1695 }
1696
1697 .float BUTTON_CHAT;
1698 void ChatBubbleThink()
1699 {
1700         self.nextthink = time;
1701         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1702         {
1703                 if(self.owner) // but why can that ever be world?
1704                         self.owner.chatbubbleentity = world;
1705                 remove(self);
1706                 return;
1707         }
1708         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1709 #ifdef TETRIS
1710                 || self.owner.tetris_on
1711 #endif
1712         )
1713                 self.model = self.mdl;
1714         else
1715                 self.model = "";
1716 };
1717
1718 void UpdateChatBubble()
1719 {
1720         if (!self.modelindex)
1721                 return;
1722         // spawn a chatbubble entity if needed
1723         if (!self.chatbubbleentity)
1724         {
1725                 self.chatbubbleentity = spawn();
1726                 self.chatbubbleentity.owner = self;
1727                 self.chatbubbleentity.exteriormodeltoclient = self;
1728                 self.chatbubbleentity.think = ChatBubbleThink;
1729                 self.chatbubbleentity.nextthink = time;
1730                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1731                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1732                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1733                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1734                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1735                 self.chatbubbleentity.model = "";
1736                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1737         }
1738 }
1739
1740
1741 void TeamBubbleThink()
1742 {
1743         self.nextthink = time;
1744         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1745         {
1746                 if(self.owner) // but why can that ever be world?
1747                         self.owner.teambubbleentity = world;
1748                 remove(self);
1749                 return;
1750         }
1751 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1752         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1753                 self.model = "";
1754         else
1755                 self.model = self.mdl;
1756
1757 };
1758
1759 float TeamBubble_customizeentityforclient()
1760 {
1761         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1762 }
1763
1764 void UpdateTeamBubble()
1765 {
1766         if (!self.modelindex || !teams_matter)
1767                 return;
1768         // spawn a teambubble entity if needed
1769         if (!self.teambubbleentity && teams_matter)
1770         {
1771                 self.teambubbleentity = spawn();
1772                 self.teambubbleentity.owner = self;
1773                 self.teambubbleentity.exteriormodeltoclient = self;
1774                 self.teambubbleentity.think = TeamBubbleThink;
1775                 self.teambubbleentity.nextthink = time;
1776                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1777 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1778                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1779                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1780                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1781                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1782                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1783                 self.teambubbleentity.effects = EF_LOWPRECISION;
1784         }
1785 }
1786
1787 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1788 // added to the model skins
1789 /*void UpdateColorModHack()
1790 {
1791         local float c;
1792         c = self.clientcolors & 15;
1793         // LordHavoc: only bothering to support white, green, red, yellow, blue
1794              if (!teams_matter) self.colormod = '0 0 0';
1795         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1796         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1797         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1798         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1799         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1800         else self.colormod = '1 1 1';
1801 };*/
1802
1803 .float oldcolormap;
1804 void respawn(void)
1805 {
1806         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1807         {
1808                 self.solid = SOLID_NOT;
1809                 self.takedamage = DAMAGE_NO;
1810                 self.movetype = MOVETYPE_FLY;
1811                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1812                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1813                 self.effects |= EF_ADDITIVE;
1814                 self.oldcolormap = self.colormap;
1815                 self.colormap = 512;
1816                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1817                 if(cvar("g_respawn_ghosts_maxtime"))
1818                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1819         }
1820
1821         CopyBody(1);
1822         self.effects |= EF_NODRAW; // prevent another CopyBody
1823         if(self.oldcolormap)
1824         {
1825                 self.colormap = self.oldcolormap;
1826                 self.oldcolormap = 0;
1827         }
1828         PutClientInServer();
1829 }
1830
1831 void play_countdown(float finished, string samp)
1832 {
1833         if(clienttype(self) == CLIENTTYPE_REAL)
1834                 if(floor(finished - time - frametime) != floor(finished - time))
1835                         if(finished - time < 6)
1836                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1837 }
1838
1839 /**
1840  * When sv_timeout is used this function returs strings like
1841  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1842  * Called by centerprint functions
1843  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1844  */
1845 string getTimeoutText(float addOneSecond) {
1846         if (!cvar("sv_timeout") || !timeoutStatus)
1847                 return "";
1848
1849         local string retStr;
1850         if (timeoutStatus == 1) {
1851                 if (addOneSecond == 1) {
1852                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1853                 }
1854                 else {
1855                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1856                 }
1857                 return retStr;
1858         }
1859         else if (timeoutStatus == 2) {
1860                 if (addOneSecond) {
1861                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1862                         //don't show messages like "Timeout ends in 0 seconds"...
1863                         if ((remainingTimeoutTime + 1) > 0)
1864                                 return retStr;
1865                         else
1866                                 return "";
1867                 }
1868                 else {
1869                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1870                         //don't show messages like "Timeout ends in 0 seconds"...
1871                         if (remainingTimeoutTime > 0)
1872                                 return retStr;
1873                         else
1874                                 return "";
1875                 }
1876         }
1877         else return "";
1878 }
1879
1880 void player_powerups (void)
1881 {
1882         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1883         {
1884                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1885                 self.modelflags |= MF_ROCKET;
1886         }
1887         else
1888         {
1889                 SoundEntity_StopSound(self, CHAN_PLAYER);
1890                 self.modelflags &~= MF_ROCKET;
1891         }
1892
1893         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1894
1895         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1896                 return;
1897
1898         Fire_ApplyDamage(self);
1899         Fire_ApplyEffect(self);
1900
1901         if (g_minstagib)
1902         {
1903                 self.effects |= EF_FULLBRIGHT;
1904
1905                 if (self.items & IT_STRENGTH)
1906                 {
1907                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1908                         if (time > self.strength_finished)
1909                         {
1910                                 self.alpha = default_player_alpha;
1911                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1912                                 self.items &~= IT_STRENGTH;
1913                                 sprint(self, "^3Invisibility has worn off\n");
1914                         }
1915                 }
1916                 else
1917                 {
1918                         if (time < self.strength_finished)
1919                         {
1920                                 self.alpha = g_minstagib_invis_alpha;
1921                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1922                                 self.items |= IT_STRENGTH;
1923                                 sprint(self, "^3You are invisible\n");
1924                         }
1925                 }
1926
1927                 if (self.items & IT_INVINCIBLE)
1928                 {
1929                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1930                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1931                         {
1932                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1933                                 sprint(self, "^3Speed has worn off\n");
1934                         }
1935                 }
1936                 else
1937                 {
1938                         if (time < self.invincible_finished)
1939                         {
1940                                 self.items = self.items | IT_INVINCIBLE;
1941                                 sprint(self, "^3You are on speed\n");
1942                         }
1943                 }
1944                 return;
1945         }
1946
1947         if (self.items & IT_STRENGTH)
1948         {
1949                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1950                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1951                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1952                 {
1953                         self.items = self.items - (self.items & IT_STRENGTH);
1954                         sprint(self, "^3Strength has worn off\n");
1955                 }
1956         }
1957         else
1958         {
1959                 if (time < self.strength_finished)
1960                 {
1961                         self.items = self.items | IT_STRENGTH;
1962                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1963                 }
1964         }
1965         if (self.items & IT_INVINCIBLE)
1966         {
1967                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1968                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1969                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1970                 {
1971                         self.items = self.items - (self.items & IT_INVINCIBLE);
1972                         sprint(self, "^3Shield has worn off\n");
1973                 }
1974         }
1975         else
1976         {
1977                 if (time < self.invincible_finished)
1978                 {
1979                         self.items = self.items | IT_INVINCIBLE;
1980                         sprint(self, "^3Shield surrounds you\n");
1981                 }
1982         }
1983
1984         if(cvar("g_nodepthtestplayers"))
1985                 self.effects = self.effects | EF_NODEPTHTEST;
1986
1987         if(cvar("g_fullbrightplayers"))
1988                 self.effects = self.effects | EF_FULLBRIGHT;
1989
1990         // midair gamemode: damage only while in the air
1991         // if in midair mode, being on ground grants temporary invulnerability
1992         // (this is so that multishot weapon don't clear the ground flag on the
1993         // first damage in the frame, leaving the player vulnerable to the
1994         // remaining hits in the same frame)
1995         if (self.flags & FL_ONGROUND)
1996         if (g_midair)
1997                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1998
1999         if (time >= game_starttime)
2000         if (time < self.spawnshieldtime)
2001                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2002 }
2003
2004 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2005 {
2006         if(current > stable)
2007                 return current;
2008         else if(current > stable - 0.25) // when close enough, "snap"
2009                 return stable;
2010         else
2011                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2012 }
2013
2014 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2015 {
2016         if(current < stable)
2017                 return current;
2018         else if(current < stable + 0.25) // when close enough, "snap"
2019                 return stable;
2020         else
2021                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2022 }
2023
2024 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2025 {
2026         if(current > rotstable)
2027         {
2028                 if(rotframetime > 0)
2029                 {
2030                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2031                         current = max(rotstable, current - rotlinear * rotframetime);
2032                 }
2033         }
2034         else if(current < regenstable)
2035         {
2036                 if(regenframetime > 0)
2037                 {
2038                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2039                         current = min(regenstable, current + regenlinear * regenframetime);
2040                 }
2041         }
2042
2043         if(current > limit)
2044                 current = limit;
2045
2046         return current;
2047 }
2048
2049 void player_regen (void)
2050 {
2051         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2052         maxh = cvar("g_balance_health_rotstable");
2053         maxa = cvar("g_balance_armor_rotstable");
2054         maxf = cvar("g_balance_fuel_rotstable");
2055         minh = cvar("g_balance_health_regenstable");
2056         mina = cvar("g_balance_armor_regenstable");
2057         minf = cvar("g_balance_fuel_regenstable");
2058         limith = cvar("g_balance_health_limit");
2059         limita = cvar("g_balance_armor_limit");
2060         limitf = cvar("g_balance_fuel_limit");
2061
2062         max_mod = regen_mod = rot_mod = limit_mod = 1;
2063
2064         if (self.runes & RUNE_REGEN)
2065         {
2066                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2067                 {
2068                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2069                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2070                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2071                 }
2072                 else
2073                 {
2074                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2075                         max_mod = cvar("g_balance_rune_regen_hpmod");
2076                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2077                 }
2078         }
2079         else if (self.runes & CURSE_VENOM)
2080         {
2081                 max_mod = cvar("g_balance_curse_venom_hpmod");
2082                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2083                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2084                 else
2085                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2086                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2087                 //if (!self.runes & RUNE_REGEN)
2088                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2089         }
2090         maxh = maxh * max_mod;
2091         //maxa = maxa * max_mod;
2092         //maxf = maxf * max_mod;
2093         minh = minh * max_mod;
2094         //mina = mina * max_mod;
2095         //minf = minf * max_mod;
2096         limith = limith * limit_mod;
2097         limita = limita * limit_mod;
2098         //limitf = limitf * limit_mod;
2099
2100         if(g_lms && g_ca)
2101                 rot_mod = 0;
2102
2103         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2104         {
2105                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2106                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2107
2108                 // if player rotted to death...  die!
2109                 if(self.health < 1)
2110                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2111         }
2112
2113         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2114                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2115 }
2116
2117 float zoomstate_set;
2118 void SetZoomState(float z)
2119 {
2120         if(z != self.zoomstate)
2121         {
2122                 self.zoomstate = z;
2123                 ClientData_Touch(self);
2124         }
2125         zoomstate_set = 1;
2126 }
2127
2128 void GetPressedKeys(void) {
2129         MUTATOR_CALLHOOK(GetPressedKeys);
2130         if (self.movement_x > 0) // get if movement keys are pressed
2131         {       // forward key pressed
2132                 self.pressedkeys |= KEY_FORWARD;
2133                 self.pressedkeys &~= KEY_BACKWARD;
2134         }
2135         else if (self.movement_x < 0)
2136         {       // backward key pressed
2137                 self.pressedkeys |= KEY_BACKWARD;
2138                 self.pressedkeys &~= KEY_FORWARD;
2139         }
2140         else
2141         {       // no x input
2142                 self.pressedkeys &~= KEY_FORWARD;
2143                 self.pressedkeys &~= KEY_BACKWARD;
2144         }
2145
2146         if (self.movement_y > 0)
2147         {       // right key pressed
2148                 self.pressedkeys |= KEY_RIGHT;
2149                 self.pressedkeys &~= KEY_LEFT;
2150         }
2151         else if (self.movement_y < 0)
2152         {       // left key pressed
2153                 self.pressedkeys |= KEY_LEFT;
2154                 self.pressedkeys &~= KEY_RIGHT;
2155         }
2156         else
2157         {       // no y input
2158                 self.pressedkeys &~= KEY_RIGHT;
2159                 self.pressedkeys &~= KEY_LEFT;
2160         }
2161
2162         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2163                 self.pressedkeys |= KEY_JUMP;
2164         else
2165                 self.pressedkeys &~= KEY_JUMP;
2166         if (self.BUTTON_CROUCH)
2167                 self.pressedkeys |= KEY_CROUCH;
2168         else
2169                 self.pressedkeys &~= KEY_CROUCH;
2170 }
2171
2172 void update_stats (float number, float hit, float fired) {
2173 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2174 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2175
2176         if(number) {
2177                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2178                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2179         } else {
2180                 self.stat_hit = hit * sv_accuracy_data_share;
2181                 self.stat_fired = fired * sv_accuracy_data_share;
2182         }
2183 }
2184
2185 /*
2186 ======================
2187 spectate mode routines
2188 ======================
2189 */
2190
2191 .float weapon_count;
2192 void SpectateCopy(entity spectatee) {
2193         if(spectatee.weapon_count < WEP_LAST) {
2194                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2195                 spectatee.weapon_count ++;
2196         } else
2197                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2198
2199         other = spectatee;
2200         MUTATOR_CALLHOOK(SpectateCopy);
2201         self.armortype = spectatee.armortype;
2202         self.armorvalue = spectatee.armorvalue;
2203         self.ammo_cells = spectatee.ammo_cells;
2204         self.ammo_shells = spectatee.ammo_shells;
2205         self.ammo_nails = spectatee.ammo_nails;
2206         self.ammo_rockets = spectatee.ammo_rockets;
2207         self.ammo_fuel = spectatee.ammo_fuel;
2208         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2209         self.health = spectatee.health;
2210         self.impulse = 0;
2211         self.items = spectatee.items;
2212         self.metertime = spectatee.metertime;
2213         self.strength_finished = spectatee.strength_finished;
2214         self.invincible_finished = spectatee.invincible_finished;
2215         self.pressedkeys = spectatee.pressedkeys;
2216         self.weapons = spectatee.weapons;
2217         self.switchweapon = spectatee.switchweapon;
2218         self.weapon = spectatee.weapon;
2219         self.punchangle = spectatee.punchangle;
2220         self.view_ofs = spectatee.view_ofs;
2221         self.v_angle = spectatee.v_angle;
2222         self.velocity = spectatee.velocity;
2223         self.dmg_take = spectatee.dmg_take;
2224         self.dmg_save = spectatee.dmg_save;
2225         self.dmg_inflictor = spectatee.dmg_inflictor;
2226         self.angles = spectatee.v_angle;
2227         self.fixangle = TRUE;
2228         setorigin(self, spectatee.origin);
2229         setsize(self, spectatee.mins, spectatee.maxs);
2230         SetZoomState(spectatee.zoomstate);
2231
2232         anticheat_spectatecopy(spectatee);
2233 }
2234
2235 float SpectateUpdate() {
2236         if(!self.enemy)
2237                 return 0;
2238
2239         if (self == self.enemy)
2240                 return 0;
2241
2242         if(self.enemy.classname != "player")
2243                 return 0;
2244
2245         SpectateCopy(self.enemy);
2246
2247         return 1;
2248 }
2249
2250 float SpectateNext() {
2251         other = find(self.enemy, classname, "player");
2252
2253         if (!other)
2254                 other = find(other, classname, "player");
2255
2256         if (other)
2257                 self.enemy = other;
2258
2259         if(self.enemy.classname == "player") {
2260                 msg_entity = self;
2261                 WriteByte(MSG_ONE, SVC_SETVIEW);
2262                 WriteEntity(MSG_ONE, self.enemy);
2263                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2264                 self.movetype = MOVETYPE_NONE;
2265
2266                 self.enemy.weapon_count = 0;
2267
2268                 if(!SpectateUpdate())
2269                         PutObserverInServer();
2270
2271                 return 1;
2272         } else {
2273                 return 0;
2274         }
2275 }
2276
2277 /*
2278 =============
2279 ShowRespawnCountdown()
2280
2281 Update a respawn countdown display.
2282 =============
2283 */
2284 void ShowRespawnCountdown()
2285 {
2286         float number;
2287         if(self.deadflag == DEAD_NO) // just respawned?
2288                 return;
2289         else
2290         {
2291                 number = ceil(self.death_time - time);
2292                 if(number <= 0)
2293                         return;
2294                 if(number <= self.respawn_countdown)
2295                 {
2296                         self.respawn_countdown = number - 1;
2297                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2298                                 AnnounceTo(self, strcat(ftos(number), ""));
2299                 }
2300         }
2301 }
2302
2303 void LeaveSpectatorMode()
2304 {
2305         if(isJoinAllowed()) {
2306                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2307                         self.classname = "player";
2308
2309                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2310                                 JoinBestTeam(self, FALSE, TRUE);
2311
2312                         if(cvar("g_campaign"))
2313                                 campaign_bots_may_start = 1;
2314
2315                         self.stat_count = WEP_LAST;
2316
2317                         PutClientInServer();
2318
2319                         if(self.classname == "player")
2320                                 bprint ("^4", self.netname, "^4 is playing now\n");
2321
2322                         if(!cvar("g_campaign"))
2323                                 centerprint(self,""); // clear MOTD
2324
2325                         return;
2326                 } else {
2327                         if (g_ca && self.caplayer) {
2328                         }       // do nothing
2329                         else
2330                                 stuffcmd(self,"menu_showteamselect\n");
2331                         return;
2332                 }
2333         }
2334         else {
2335                 //player may not join because of g_maxplayers is set
2336                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2337         }
2338 }
2339
2340 /**
2341  * Determines whether the player is allowed to join. This depends on cvar
2342  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2343  * it checks whether the number of currently playing players exceeds g_maxplayers.
2344  * @return bool TRUE if the player is allowed to join, false otherwise
2345  */
2346 float isJoinAllowed() {
2347         if (!cvar("g_maxplayers"))
2348                 return TRUE;
2349
2350         local entity e;
2351         local float currentlyPlaying;
2352         FOR_EACH_REALPLAYER(e) {
2353                 if(e.classname == "player")
2354                         currentlyPlaying += 1;
2355         }
2356         if(currentlyPlaying < cvar("g_maxplayers"))
2357                 return TRUE;
2358
2359         return FALSE;
2360 }
2361
2362 /**
2363  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2364  * g_maxplayers_spectator_blocktime seconds
2365  */
2366 void checkSpectatorBlock() {
2367         if(self.classname == "spectator" || self.classname == "observer") {
2368                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2369                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2370                         dropclient(self);
2371                 }
2372         }
2373 }
2374
2375 float vercmp_recursive(string v1, string v2)
2376 {
2377         float dot1, dot2;
2378         string s1, s2;
2379         float r;
2380
2381         dot1 = strstrofs(v1, ".", 0);
2382         dot2 = strstrofs(v2, ".", 0);
2383         if(dot1 == -1)
2384                 s1 = v1;
2385         else
2386                 s1 = substring(v1, 0, dot1);
2387         if(dot2 == -1)
2388                 s2 = v2;
2389         else
2390                 s2 = substring(v2, 0, dot2);
2391
2392         r = stof(s1) - stof(s2);
2393         if(r != 0)
2394                 return r;
2395
2396         r = strcasecmp(s1, s2);
2397         if(r != 0)
2398                 return r;
2399
2400         if(dot1 == -1)
2401                 if(dot2 == -1)
2402                         return 0;
2403                 else
2404                         return -1;
2405         else
2406                 if(dot2 == -1)
2407                         return 1;
2408                 else
2409                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2410 }
2411
2412 float vercmp(string v1, string v2)
2413 {
2414         if(strcasecmp(v1, v2) == 0) // early out check
2415                 return 0;
2416         return vercmp_recursive(v1, v2);
2417 }
2418
2419 void ObserverThink()
2420 {
2421         if (self.flags & FL_JUMPRELEASED) {
2422                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2423                         self.welcomemessage_time = 0;
2424                         self.flags &~= FL_JUMPRELEASED;
2425                         self.flags |= FL_SPAWNING;
2426                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2427                         self.welcomemessage_time = 0;
2428                         self.flags &~= FL_JUMPRELEASED;
2429                         if(SpectateNext() == 1) {
2430                                 self.classname = "spectator";
2431                         }
2432                 }
2433         } else {
2434                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2435                         self.flags |= FL_JUMPRELEASED;
2436                         if(self.flags & FL_SPAWNING)
2437                         {
2438                                 self.flags &~= FL_SPAWNING;
2439                                 LeaveSpectatorMode();
2440                                 return;
2441                         }
2442                 }
2443         }
2444         PrintWelcomeMessage(self);
2445 }
2446
2447 void SpectatorThink()
2448 {
2449         if (self.flags & FL_JUMPRELEASED) {
2450                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2451                         self.welcomemessage_time = 0;
2452                         self.flags &~= FL_JUMPRELEASED;
2453                         self.flags |= FL_SPAWNING;
2454                 } else if(self.BUTTON_ATCK) {
2455                         self.welcomemessage_time = 0;
2456                         self.flags &~= FL_JUMPRELEASED;
2457                         if(SpectateNext() == 1) {
2458                                 self.classname = "spectator";
2459                         } else {
2460                                 self.classname = "observer";
2461                                 self.stat_count = WEP_LAST;
2462                                 PutClientInServer();
2463                         }
2464                 } else if (self.BUTTON_ATCK2) {
2465                         self.welcomemessage_time = 0;
2466                         self.flags &~= FL_JUMPRELEASED;
2467                         self.classname = "observer";
2468                         self.stat_count = WEP_LAST;
2469                         PutClientInServer();
2470                 } else {
2471                         if(!SpectateUpdate())
2472                                 PutObserverInServer();
2473                 }
2474         } else {
2475                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2476                         self.flags |= FL_JUMPRELEASED;
2477                         if(self.flags & FL_SPAWNING)
2478                         {
2479                                 self.flags &~= FL_SPAWNING;
2480                                 LeaveSpectatorMode();
2481                                 return;
2482                         }
2483                 }
2484         }
2485
2486         PrintWelcomeMessage(self);
2487         self.flags |= FL_CLIENT | FL_NOTARGET;
2488 }
2489
2490 .float touchexplode_time;
2491
2492 /*
2493 =============
2494 PlayerPreThink
2495
2496 Called every frame for each client before the physics are run
2497 =============
2498 */
2499 void() ctf_setstatus;
2500 void() nexball_setstatus;
2501 .float items_added;
2502 void PlayerPreThink (void)
2503 {
2504         self.stat_game_starttime = game_starttime;
2505         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2506         self.stat_leadlimit = cvar("leadlimit");
2507
2508         if(frametime)
2509         {
2510                 // physics frames: update anticheat stuff
2511                 anticheat_prethink();
2512         }
2513
2514         if(blockSpectators && frametime)
2515                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2516                 checkSpectatorBlock();
2517
2518         zoomstate_set = 0;
2519
2520         if(self.netname_previous != self.netname)
2521         {
2522                 if(cvar("sv_eventlog"))
2523                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2524                 if(self.netname_previous)
2525                         strunzone(self.netname_previous);
2526                 self.netname_previous = strzone(self.netname);
2527         }
2528
2529         // version nagging
2530         if(self.version_nagtime)
2531                 if(self.cvar_g_xonoticversion)
2532                         if(time > self.version_nagtime)
2533                         {
2534                                 if(strstr(self.cvar_g_xonoticversion, "svn", 0) < 0)
2535                                 {
2536                                         if(strstr(cvar_string("g_xonoticversion"), "svn", 0) >= 0)
2537                                         {
2538                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2539                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2540                                         }
2541                                         else
2542                                         {
2543                                                 float r;
2544                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2545                                                 if(r < 0)
2546                                                 {
2547                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2548                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2549                                                 }
2550                                                 else if(r > 0)
2551                                                 {
2552                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2553                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2554                                                 }
2555                                         }
2556                                 }
2557                                 self.version_nagtime = 0;
2558                         }
2559
2560         // GOD MODE info
2561         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2562         {
2563                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2564                 self.max_armorvalue = 0;
2565         }
2566
2567 #ifdef TETRIS
2568         if (TetrisPreFrame())
2569                 return;
2570 #endif
2571
2572         MUTATOR_CALLHOOK(PlayerPreThink);
2573
2574         if(self.classname == "player") {
2575 //              if(self.netname == "Wazat")
2576 //                      bprint(self.classname, "\n");
2577
2578                 CheckRules_Player();
2579
2580                 PrintWelcomeMessage(self);
2581
2582                 if (intermission_running)
2583                 {
2584                         IntermissionThink ();   // otherwise a button could be missed between
2585                         return;                                 // the think tics
2586                 }
2587
2588                 if(self.teleport_time)
2589                 if(time > self.teleport_time)
2590                 {
2591                         self.teleport_time = 0;
2592                         self.effects = self.effects - (self.effects & EF_NODRAW);
2593                 }
2594
2595                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2596                         UpdateSelectedPlayer();
2597
2598                 //don't allow the player to turn around while game is paused!
2599                 if(timeoutStatus == 2) {
2600                         self.v_angle = self.lastV_angle;
2601                         self.angles = self.lastV_angle;
2602                         self.fixangle = TRUE;
2603                 }
2604
2605                 if(frametime)
2606                 {
2607                         self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2608                         player_powerups();
2609                 }
2610
2611                 if (self.deadflag != DEAD_NO)
2612                 {
2613                         float button_pressed, force_respawn;
2614                         if(self.personal && g_race_qualifying)
2615                         {
2616                                 if(time > self.death_time)
2617                                 {
2618                                         self.death_time = time + 1; // only retry once a second
2619                                         respawn();
2620                                         self.impulse = 141;
2621                                 }
2622                         }
2623                         else
2624                         {
2625                                 if(frametime)
2626                                         player_anim();
2627                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2628                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2629                                 if (self.deadflag == DEAD_DYING)
2630                                 {
2631                                         if(force_respawn)
2632                                                 self.deadflag = DEAD_RESPAWNING;
2633                                         else if(!button_pressed)
2634                                                 self.deadflag = DEAD_DEAD;
2635                                 }
2636                                 else if (self.deadflag == DEAD_DEAD)
2637                                 {
2638                                         if(button_pressed)
2639                                                 self.deadflag = DEAD_RESPAWNABLE;
2640                                 }
2641                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2642                                 {
2643                                         if(!button_pressed)
2644                                                 self.deadflag = DEAD_RESPAWNING;
2645                                 }
2646                                 else if (self.deadflag == DEAD_RESPAWNING)
2647                                 {
2648                                         if(time > self.death_time)
2649                                         {
2650                                                 self.death_time = time + 1; // only retry once a second
2651                                                 respawn();
2652                                         }
2653                                 }
2654                                 ShowRespawnCountdown();
2655                         }
2656                         return;
2657                 }
2658
2659                 if(g_touchexplode)
2660                 if(time > self.touchexplode_time)
2661                 if(self.classname == "player")
2662                 if(self.deadflag == DEAD_NO)
2663                 if not(IS_INDEPENDENT_PLAYER(self))
2664                 FOR_EACH_PLAYER(other) if(self != other)
2665                 {
2666                         if(time > other.touchexplode_time)
2667                         if(other.deadflag == DEAD_NO)
2668                         if not(IS_INDEPENDENT_PLAYER(other))
2669                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2670                         {
2671                                 PlayerTouchExplode(self, other);
2672                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2673                         }
2674                 }
2675
2676                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2677                 {
2678                         vector dist;
2679
2680                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2681                         dist = self.prevorigin - self.origin;
2682                         dist_z = 0;
2683                         self.lms_traveled_distance += fabs(vlen(dist));
2684
2685                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2686                         {
2687                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2688                                 self.lms_traveled_distance = 0;
2689                         }
2690
2691                         if(time > self.lms_nextcheck)
2692                         {
2693                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2694                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2695                                 {
2696                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2697                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2698                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2699                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2700                                 }
2701                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2702                                 self.lms_traveled_distance = 0;
2703                         }
2704                 }
2705
2706                 self.prevorigin = self.origin;
2707
2708                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2709                 {
2710                         if (!self.crouch)
2711                         {
2712                                 self.crouch = TRUE;
2713                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2714                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2715                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2716                         }
2717                 }
2718                 else
2719                 {
2720                         if (self.crouch)
2721                         {
2722                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2723                                 if (!trace_startsolid)
2724                                 {
2725                                         self.crouch = FALSE;
2726                                         self.view_ofs = PL_VIEW_OFS;
2727                                         setsize (self, PL_MIN, PL_MAX);
2728                                 }
2729                         }
2730                 }
2731
2732                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2733                 {
2734                         if(self.bloodloss_timer < time)
2735                         {
2736                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2737                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2738                         }
2739                 }
2740
2741                 FixPlayermodel();
2742
2743                 GrapplingHookFrame();
2744
2745                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2746                 //if(frametime)
2747                 {
2748                         self.items &~= self.items_added;
2749
2750                         W_WeaponFrame();
2751
2752                         self.items_added = 0;
2753                         if(self.items & IT_JETPACK)
2754                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2755                                         self.items_added |= IT_FUEL;
2756
2757                         self.items |= self.items_added;
2758                 }
2759
2760                 player_regen();
2761                 if(frametime)
2762                         player_anim();
2763
2764                 if (g_minstagib)
2765                         minstagib_ammocheck();
2766
2767                 ctf_setstatus();
2768                 nexball_setstatus();
2769
2770                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2771
2772                 //self.angles_y=self.v_angle_y + 90;   // temp
2773         } else if(gameover) {
2774                 if (intermission_running)
2775                         IntermissionThink ();   // otherwise a button could be missed between
2776                 return;
2777         } else if(self.classname == "observer") {
2778                 ObserverThink();
2779         } else if(self.classname == "spectator") {
2780                 SpectatorThink();
2781         }
2782
2783         if(!zoomstate_set)
2784                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2785
2786         float oldspectatee_status;
2787         oldspectatee_status = self.spectatee_status;
2788         if(self.classname == "spectator")
2789                 self.spectatee_status = num_for_edict(self.enemy);
2790         else if(self.classname == "observer")
2791                 self.spectatee_status = num_for_edict(self);
2792         else
2793                 self.spectatee_status = 0;
2794         if(self.spectatee_status != oldspectatee_status)
2795         {
2796                 ClientData_Touch(self);
2797                 if(g_race || g_cts)
2798                         race_InitSpectator();
2799         }
2800
2801         if(self.teamkill_soundtime)
2802         if(time > self.teamkill_soundtime)
2803         {
2804                 self.teamkill_soundtime = 0;
2805
2806                 entity oldpusher, oldself;
2807
2808                 oldself = self; self = self.teamkill_soundsource;
2809                 oldpusher = self.pusher; self.pusher = oldself;
2810
2811                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2812
2813                 self.pusher = oldpusher;
2814                 self = oldself;
2815         }
2816
2817         if(self.taunt_soundtime)
2818         if(time > self.taunt_soundtime)
2819         {
2820                 self.taunt_soundtime = 0;
2821                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2822         }
2823
2824         target_voicescript_next(self);
2825 }
2826
2827 float isInvisibleString(string s)
2828 {
2829         float i, n, c;
2830         s = strdecolorize(s);
2831         for((i = 0), (n = strlen(s)); i < n; ++i)
2832         {
2833                 c = str2chr(s, i);
2834                 switch(c)
2835                 {
2836                         case 0:
2837                         case 32:
2838                         case 160:
2839                                 break;
2840                         default:
2841                                 return FALSE;
2842                 }
2843         }
2844         return TRUE;
2845 }
2846
2847 /*
2848 =============
2849 PlayerPostThink
2850
2851 Called every frame for each client after the physics are run
2852 =============
2853 */
2854 .float idlekick_lasttimeleft;
2855 .entity showheadshotbbox;
2856 void showheadshotbbox_think()
2857 {
2858         if(self.owner.showheadshotbbox != self)
2859         {
2860                 remove(self);
2861                 return;
2862         }
2863         self.nextthink = time;
2864         setorigin(self, self.owner.origin);
2865         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2866 }
2867 void PlayerPostThink (void)
2868 {
2869         // Savage: Check for nameless players
2870         if (isInvisibleString(self.netname)) {
2871                 self.netname = "Player";
2872                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2873         }
2874
2875         // send the clients accuracy stats to the client
2876         if(self.stat_count > 0)
2877         if(frametime)
2878         {
2879                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2880                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2881                 self.stat_count -= 1;
2882         }
2883
2884 #ifdef UID
2885         if(self.uid_kicktime)
2886         if(time > self.uid_kicktime)
2887         {
2888                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2889                 dropclient(self);
2890                 return;
2891         }
2892 #endif
2893
2894         if(sv_maxidle && frametime)
2895         {
2896                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2897                 float timeleft;
2898                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2899                 if(timeleft <= 0)
2900                 {
2901                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2902                         AnnounceTo(self, "terminated");
2903                         dropclient(self);
2904                         return;
2905                 }
2906                 else if(timeleft <= 10)
2907                 {
2908                         if(timeleft != self.idlekick_lasttimeleft)
2909                         {
2910                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2911                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2912                         }
2913                 }
2914                 else
2915                 {
2916                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2917                 }
2918                 self.idlekick_lasttimeleft = timeleft;
2919         }
2920
2921 #ifdef TETRIS
2922         if(self.impulse == 100)
2923                 ImpulseCommands();
2924         if (TetrisPostFrame())
2925                 return;
2926 #endif
2927
2928         CheatFrame();
2929
2930         if(self.classname == "player") {
2931                 CheckRules_Player();
2932                 UpdateChatBubble();
2933                 UpdateTeamBubble();
2934                 if (self.impulse)
2935                         ImpulseCommands();
2936                 if (intermission_running)
2937                         return;         // intermission or finale
2938                 GetPressedKeys();
2939         } else if (self.classname == "observer") {
2940                 //do nothing
2941         } else if (self.classname == "spectator") {
2942                 //do nothing
2943         }
2944
2945         /*
2946         float i;
2947         for(i = 0; i < 1000; ++i)
2948         {
2949                 vector end;
2950                 end = self.origin + '0 0 1024' + 512 * randomvec();
2951                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2952                 if(trace_fraction < 1)
2953                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2954                 {
2955                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2956                         break;
2957                 }
2958         }
2959         */
2960
2961         Arena_Warmup();
2962
2963         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2964
2965         if(self.waypointsprite_attachedforcarrier)
2966                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2967
2968         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
2969         {
2970                 if(!self.showheadshotbbox)
2971                 {
2972                         self.showheadshotbbox = spawn();
2973                         self.showheadshotbbox.classname = "headshotbbox";
2974                         self.showheadshotbbox.owner = self;
2975                         self.showheadshotbbox.think = showheadshotbbox_think;
2976                         self.showheadshotbbox.nextthink = time;
2977                         self = self.showheadshotbbox;
2978                         self.think();
2979                         self = self.owner;
2980                 }
2981         }
2982         else
2983         {
2984                 if(self.showheadshotbbox)
2985                         remove(self.showheadshotbbox);
2986         }
2987
2988         playerdemo_write();
2989
2990         /*
2991         if(g_race)
2992                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2993         */
2994 }