qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 142
 143         spot = SelectSpawnPoint (TRUE);
 144         if(!spot)
 145                 error("No spawnpoints for observers?!?\n");
 146         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 147
 148         if(IS_REAL_CLIENT(self))
 149         {
 150                 msg_entity = self;
 151                 WriteByte(MSG_ONE, SVC_SETVIEW);
 152                 WriteEntity(MSG_ONE, self);
 153         }
 154
 155         self.frags = FRAGS_SPECTATOR;
 156
 157         MUTATOR_CALLHOOK(MakePlayerObserver);
 158
 159         Portal_ClearAll(self);
 160
 161         Unfreeze(self);
 162
 163         if(self.alivetime)
 164         {
 165                 if(!warmup_stage)
 166                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 167                 self.alivetime = 0;
 168         }
 169
 170         if(self.vehicle)
 171                 vehicles_exit(VHEF_RELESE);
 172
 173         WaypointSprite_PlayerDead();
 174
 175         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 176                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 177
 178         if(self.killcount != -666)
 179         {
 180                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 181                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 182                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 183
 184                 if(self.just_joined == FALSE) {
 185                         LogTeamchange(self.playerid, -1, 4);
 186                 } else
 187                         self.just_joined = FALSE;
 188         }
 189
 190         PlayerScore_Clear(self); // clear scores when needed
 191
 192         accuracy_resend(self);
 193
 194         self.spectatortime = time;
 195
 196         self.classname = "observer";
 197         self.iscreature = FALSE;
 198         self.teleportable = TELEPORT_SIMPLE;
 199         self.damagedbycontents = FALSE;
 200         self.health = -666;
 201         self.takedamage = DAMAGE_NO;
 202         self.solid = SOLID_NOT;
 203         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 204         self.flags = FL_CLIENT | FL_NOTARGET;
 205         self.armorvalue = 666;
 206         self.effects = 0;
 207         self.armorvalue = autocvar_g_balance_armor_start;
 208         self.pauserotarmor_finished = 0;
 209         self.pauserothealth_finished = 0;
 210         self.pauseregen_finished = 0;
 211         self.damageforcescale = 0;
 212         self.death_time = 0;
 213         self.respawn_flags = 0;
 214         self.respawn_time = 0;
 215         self.stat_respawn_time = 0;
 216         self.alpha = 0;
 217         self.scale = 0;
 218         self.fade_time = 0;
 219         self.pain_frame = 0;
 220         self.pain_finished = 0;
 221         self.strength_finished = 0;
 222         self.invincible_finished = 0;
 223         self.superweapons_finished = 0;
 224         self.pushltime = 0;
 225         self.istypefrag = 0;
 226         self.think = func_null;
 227         self.nextthink = 0;
 228         self.hook_time = 0;
 229         self.deadflag = DEAD_NO;
 230         self.angles = spot.angles;
 231         self.angles_z = 0;
 232         self.fixangle = TRUE;
 233         self.crouch = FALSE;
 234         self.revival_time = 0;
 235
 236         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 237         self.prevorigin = self.origin;
 238         self.items = 0;
 239         self.weapons = '0 0 0';
 240         self.model = "";
 241         FixPlayermodel();
 242         setmodel(self, "null");
 243         self.drawonlytoclient = self;
 244
 245         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247
 248         self.weapon = 0;
 249         self.weaponname = "";
 250         self.switchingweapon = 0;
 251         self.weaponmodel = "";
 252         self.weaponentity = world;
 253         self.exteriorweaponentity = world;
 254         self.killcount = -666;
 255         self.velocity = '0 0 0';
 256         self.avelocity = '0 0 0';
 257         self.punchangle = '0 0 0';
 258         self.punchvector = '0 0 0';
 259         self.oldvelocity = self.velocity;
 260         self.fire_endtime = -1;
 261 }
 262
 263 .float model_randomizer;
 264 void FixPlayermodel()
 265 {
 266         string defaultmodel;
 267         float defaultskin, chmdl, oldskin, n, i;
 268         vector m1, m2;
 269
 270         defaultmodel = "";
 271         defaultskin = 0;
 272         chmdl = FALSE;
 273
 274         if(autocvar_sv_defaultcharacter == 1)
 275         {
 276                 if(teamplay)
 277                 {
 278                         string s;
 279                         s = Static_Team_ColorName_Lower(self.team);
 280                         if(s != "neutral")
 281                         {
 282                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 283                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 284                         }
 285                 }
 286
 287                 if(defaultmodel == "")
 288                 {
 289                         defaultmodel = autocvar_sv_defaultplayermodel;
 290                         defaultskin = autocvar_sv_defaultplayerskin;
 291                 }
 292
 293                 n = tokenize_console(defaultmodel);
 294                 if(n > 0)
 295                 {
 296                         defaultmodel = argv(floor(n * self.model_randomizer));
 297                         // However, do NOT randomize if the player-selected model is in the list.
 298                         for (i = 0; i < n; ++i)
 299                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 300                                         defaultmodel = argv(i);
 301                 }
 302
 303                 i = strstrofs(defaultmodel, ":", 0);
 304                 if(i >= 0)
 305                 {
 306                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 307                         defaultmodel = substring(defaultmodel, 0, i);
 308                 }
 309         }
 310
 311         if(defaultmodel != "")
 312         {
 313                 if (defaultmodel != self.model)
 314                 {
 315                         m1 = self.mins;
 316                         m2 = self.maxs;
 317                         setplayermodel (self, defaultmodel);
 318                         setsize (self, m1, m2);
 319                         chmdl = TRUE;
 320                 }
 321
 322                 oldskin = self.skin;
 323                 self.skin = defaultskin;
 324         } else {
 325                 if (self.playermodel != self.model || self.playermodel == "")
 326                 {
 327                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 328                         m1 = self.mins;
 329                         m2 = self.maxs;
 330                         setplayermodel (self, self.playermodel);
 331                         setsize (self, m1, m2);
 332                         chmdl = TRUE;
 333                 }
 334
 335                 oldskin = self.skin;
 336                 self.skin = stof(self.playerskin);
 337         }
 338
 339         if(chmdl || oldskin != self.skin) // model or skin has changed
 340         {
 341                 self.species = player_getspecies(); // update species
 342                 UpdatePlayerSounds(); // update skin sounds
 343         }
 344
 345         if(!teamplay)
 346                 if(strlen(autocvar_sv_defaultplayercolors))
 347                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 348                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 349 }
 350
 351 /*
 352 =============
 353 PutClientInServer
 354
 355 Called when a client spawns in the server
 356 =============
 357 */
 358 void PutClientInServer (void)
 359 {
 360         if(IS_BOT_CLIENT(self))
 361                 self.classname = "player";
 362         else if(IS_REAL_CLIENT(self))
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         // reset player keys
 370         self.itemkeys = 0;
 371
 372         MUTATOR_CALLHOOK(PutClientInServer);
 373
 374         if(gameover)
 375                 self.classname = "observer";
 376
 377         if(IS_PLAYER(self))
 378         {
 379                 entity spot, oldself;
 380                 float j;
 381
 382                 accuracy_resend(self);
 383
 384                 if(self.team < 0)
 385                         JoinBestTeam(self, FALSE, TRUE);
 386
 387                 spot = SelectSpawnPoint (FALSE);
 388                 if(!spot)
 389                 {
 390                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 391                         return; // spawn failed
 392                 }
 393
 394                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 395
 396                 if(self.vehicle)
 397                         vehicles_exit(VHEF_RELESE);
 398
 399                 self.classname = "player";
 400                 self.wasplayer = TRUE;
 401                 self.iscreature = TRUE;
 402                 self.teleportable = TELEPORT_NORMAL;
 403                 self.damagedbycontents = TRUE;
 404                 self.movetype = MOVETYPE_WALK;
 405                 self.solid = SOLID_SLIDEBOX;
 406                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 407                 if(autocvar_g_playerclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 409                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 410                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 411                 self.frags = FRAGS_PLAYER;
 412                 if(INDEPENDENT_PLAYERS)
 413                         MAKE_INDEPENDENT_PLAYER(self);
 414                 self.flags = FL_CLIENT;
 415                 if(autocvar__notarget)
 416                         self.flags |= FL_NOTARGET;
 417                 self.takedamage = DAMAGE_AIM;
 418                 self.effects = 0;
 419                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 420                 self.air_finished = time + 12;
 421                 self.dmg = 2;
 422                 if(autocvar_g_balance_nex_charge)
 423                 {
 424                         if(autocvar_g_balance_nex_secondary_chargepool)
 425                                 self.nex_chargepool_ammo = 1;
 426                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 427                 }
 428
 429                 if(warmup_stage)
 430                 {
 431                         self.ammo_shells = warmup_start_ammo_shells;
 432                         self.ammo_nails = warmup_start_ammo_nails;
 433                         self.ammo_rockets = warmup_start_ammo_rockets;
 434                         self.ammo_cells = warmup_start_ammo_cells;
 435                         self.ammo_fuel = warmup_start_ammo_fuel;
 436                         self.health = warmup_start_health;
 437                         self.armorvalue = warmup_start_armorvalue;
 438                         self.weapons = WARMUP_START_WEAPONS;
 439                 }
 440                 else
 441                 {
 442                         self.ammo_shells = start_ammo_shells;
 443                         self.ammo_nails = start_ammo_nails;
 444                         self.ammo_rockets = start_ammo_rockets;
 445                         self.ammo_cells = start_ammo_cells;
 446                         self.ammo_fuel = start_ammo_fuel;
 447                         self.health = start_health;
 448                         self.armorvalue = start_armorvalue;
 449                         self.weapons = start_weapons;
 450                 }
 451
 452                 if(self.weapons & WEPSET_SUPERWEAPONS)
 453                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 454                 else
 455                         self.superweapons_finished = 0;
 456
 457                 if(g_weaponarena_random)
 458                 {
 459                         if(g_weaponarena_random_with_laser)
 460                                 self.weapons &= ~WEPSET_LASER;
 461                         W_RandomWeapons(self, g_weaponarena_random);
 462                         if(g_weaponarena_random_with_laser)
 463                                 self.weapons |= WEPSET_LASER;
 464                 }
 465
 466                 self.items = start_items;
 467
 468                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 469                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 470                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 471                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 472                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 473                 //extend the pause of rotting if client was reset at the beginning of the countdown
 474                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 475                         self.spawnshieldtime += game_starttime - time;
 476                         self.pauserotarmor_finished += game_starttime - time;
 477                         self.pauserothealth_finished += game_starttime - time;
 478                         self.pauseregen_finished += game_starttime - time;
 479                 }
 480                 self.damageforcescale = 2;
 481                 self.death_time = 0;
 482                 self.respawn_flags = 0;
 483                 self.respawn_time = 0;
 484                 self.stat_respawn_time = 0;
 485                 self.scale = 0;
 486                 self.fade_time = 0;
 487                 self.pain_frame = 0;
 488                 self.pain_finished = 0;
 489                 self.strength_finished = 0;
 490                 self.invincible_finished = 0;
 491                 self.pushltime = 0;
 492                 // players have no think function
 493                 self.think = func_null;
 494                 self.nextthink = 0;
 495                 self.hook_time = 0;
 496                 self.dmg_team = 0;
 497                 self.ballistics_density = autocvar_g_ballistics_density_player;
 498
 499                 self.metertime = 0;
 500
 501                 self.deadflag = DEAD_NO;
 502
 503                 self.angles = spot.angles;
 504
 505                 self.angles_z = 0; // never spawn tilted even if the spot says to
 506                 if(IS_BOT_CLIENT(self))
 507                         self.v_angle = self.angles;
 508                 self.fixangle = TRUE; // turn this way immediately
 509                 self.velocity = '0 0 0';
 510                 self.avelocity = '0 0 0';
 511                 self.punchangle = '0 0 0';
 512                 self.punchvector = '0 0 0';
 513                 self.oldvelocity = self.velocity;
 514                 self.fire_endtime = -1;
 515                 self.revival_time = 0;
 516
 517                 entity spawnevent = spawn();
 518                 spawnevent.owner = self;
 519                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 520
 521                 // Cut off any still running player sounds.
 522                 stopsound(self, CH_PLAYER_SINGLE);
 523
 524                 self.model = "";
 525                 FixPlayermodel();
 526                 self.drawonlytoclient = world;
 527
 528                 self.crouch = FALSE;
 529                 self.view_ofs = PL_VIEW_OFS;
 530                 setsize (self, PL_MIN, PL_MAX);
 531                 self.spawnorigin = spot.origin;
 532                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 533                 // don't reset back to last position, even if new position is stuck in solid
 534                 self.oldorigin = self.origin;
 535                 self.prevorigin = self.origin;
 536                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 537                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 538         self.hud = HUD_NORMAL;
 539
 540                 self.event_damage = PlayerDamage;
 541
 542                 self.bot_attack = TRUE;
 543                 self.monster_attack = TRUE;
 544
 545                 self.spider_slowness = 0;
 546
 547                 self.statdraintime = time + 5;
 548                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 549
 550                 if(self.killcount == -666) {
 551                         PlayerScore_Clear(self);
 552                         self.killcount = 0;
 553                 }
 554
 555                 CL_SpawnWeaponentity();
 556                 self.alpha = default_player_alpha;
 557                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 558                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 559
 560                 self.speedrunning = FALSE;
 561
 562                 //stuffcmd(self, "chase_active 0");
 563                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 564
 565                 target_voicescript_clear(self);
 566
 567                 // reset fields the weapons may use
 568                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 569                 {
 570                         weapon_action(j, WR_RESETPLAYER);
 571
 572                         // all weapons must be fully loaded when we spawn
 573                         entity e;
 574                         e = get_weaponinfo(j);
 575                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 576                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 577                 }
 578
 579                 oldself = self;
 580                 self = spot;
 581                         activator = oldself;
 582                                 string s;
 583                                 s = self.target;
 584                                 self.target = string_null;
 585                                 SUB_UseTargets();
 586                                 self.target = s;
 587                         activator = world;
 588                 self = oldself;
 589
 590                 Unfreeze(self);
 591
 592                 spawn_spot = spot;
 593                 MUTATOR_CALLHOOK(PlayerSpawn);
 594
 595                 if(autocvar_spawn_debug)
 596                 {
 597                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 598                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 599                 }
 600
 601                 self.switchweapon = w_getbestweapon(self);
 602                 self.cnt = -1; // W_LastWeapon will not complain
 603                 self.weapon = 0;
 604                 self.weaponname = "";
 605                 self.switchingweapon = 0;
 606
 607                 if(!warmup_stage)
 608                         if(!self.alivetime)
 609                                 self.alivetime = time;
 610
 611                 antilag_clear(self);
 612         }
 613         else if(IS_OBSERVER(self))
 614         {
 615                 PutObserverInServer ();
 616         }
 617 }
 618
 619 .float ebouncefactor, ebouncestop; // electro's values
 620 // TODO do we need all these fields, or should we stop autodetecting runtime
 621 // changes and just have a console command to update this?
 622 float ClientInit_SendEntity(entity to, float sf)
 623 {
 624         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 625         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 638         if(sv_foginterval && world.fog != "")
 639                 WriteString(MSG_ENTITY, world.fog);
 640         else
 641                 WriteString(MSG_ENTITY, "");
 642         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 643         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 644         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 645         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 646         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 650         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 651         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 652         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 653         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 654         return TRUE;
 655 }
 656
 657 void ClientInit_CheckUpdate()
 658 {
 659         self.nextthink = time;
 660         if(self.count != autocvar_g_balance_armor_blockpercent)
 661         {
 662                 self.count = autocvar_g_balance_armor_blockpercent;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 666         {
 667                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 671         {
 672                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 673                 self.SendFlags |= 1;
 674         }
 675         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 676         {
 677                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 678                 self.SendFlags |= 1;
 679         }
 680         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 681         {
 682                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 683                 self.SendFlags |= 1;
 684         }
 685 }
 686
 687 void ClientInit_Spawn()
 688 {
 689         entity o;
 690         entity e;
 691         e = spawn();
 692         e.classname = "clientinit";
 693         e.think = ClientInit_CheckUpdate;
 694         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 695
 696         o = self;
 697         self = e;
 698         ClientInit_CheckUpdate();
 699         self = o;
 700 }
 701
 702 /*
 703 =============
 704 SetNewParms
 705 =============
 706 */
 707 void SetNewParms (void)
 708 {
 709         // initialize parms for a new player
 710         parm1 = -(86400 * 366);
 711 }
 712
 713 /*
 714 =============
 715 SetChangeParms
 716 =============
 717 */
 718 void SetChangeParms (void)
 719 {
 720         // save parms for level change
 721         parm1 = self.parm_idlesince - time;
 722 }
 723
 724 /*
 725 =============
 726 DecodeLevelParms
 727 =============
 728 */
 729 void DecodeLevelParms (void)
 730 {
 731         // load parms
 732         self.parm_idlesince = parm1;
 733         if(self.parm_idlesince == -(86400 * 366))
 734                 self.parm_idlesince = time;
 735
 736         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 737         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 738 }
 739
 740 /*
 741 =============
 742 ClientKill
 743
 744 Called when a client types 'kill' in the console
 745 =============
 746 */
 747
 748 .float clientkill_nexttime;
 749 void ClientKill_Now_TeamChange()
 750 {
 751         if(self.killindicator_teamchange == -1)
 752         {
 753                 JoinBestTeam( self, FALSE, TRUE );
 754         }
 755         else if(self.killindicator_teamchange == -2)
 756         {
 757                 if(blockSpectators)
 758                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 759                 PutObserverInServer();
 760         }
 761         else
 762                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 763         self.killindicator_teamchange = 0;
 764 }
 765
 766 void ClientKill_Now()
 767 {
 768         if(self.vehicle)
 769         {
 770             vehicles_exit(VHEF_RELESE);
 771             if(!self.killindicator_teamchange)
 772             {
 773             self.vehicle_health = -1;
 774             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 775             }
 776         }
 777
 778         if(self.killindicator && !wasfreed(self.killindicator))
 779                 remove(self.killindicator);
 780
 781         self.killindicator = world;
 782
 783         if(self.killindicator_teamchange)
 784                 ClientKill_Now_TeamChange();
 785
 786         // in any case:
 787         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 788
 789         // now I am sure the player IS dead
 790 }
 791 void KillIndicator_Think()
 792 {
 793         if (gameover)
 794         {
 795                 self.owner.killindicator = world;
 796                 remove(self);
 797                 return;
 798         }
 799
 800         if (self.owner.alpha < 0 && !self.owner.vehicle)
 801         {
 802                 self.owner.killindicator = world;
 803                 remove(self);
 804                 return;
 805         }
 806
 807         if(self.cnt <= 0)
 808         {
 809                 self = self.owner;
 810                 ClientKill_Now(); // no oldself needed
 811                 return;
 812         }
 813     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 814     {
 815         self.nextthink = time + 1;
 816         self.cnt -= 1;
 817     }
 818         else
 819         {
 820                 if(self.cnt <= 10)
 821                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 822                 if(IS_REAL_CLIENT(self.owner))
 823                 {
 824                         if(self.cnt <= 10)
 825                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 826                 }
 827                 self.nextthink = time + 1;
 828                 self.cnt -= 1;
 829         }
 830 }
 831
 832 float clientkilltime;
 833 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 834 {
 835         float killtime;
 836         float starttime;
 837         entity e;
 838
 839         if (gameover)
 840                 return;
 841
 842         killtime = autocvar_g_balance_kill_delay;
 843
 844         if(g_race_qualifying || g_cts)
 845                 killtime = 0;
 846
 847     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 848     {
 849                 remove(self.killindicator);
 850                 self.killindicator = world;
 851
 852         ClientKill_Now(); // allow instant kill in this case
 853         return;
 854     }
 855
 856         self.killindicator_teamchange = targetteam;
 857
 858     if(!self.killindicator)
 859         {
 860                 if(self.deadflag == DEAD_NO)
 861                 {
 862                         killtime = max(killtime, self.clientkill_nexttime - time);
 863                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 864                 }
 865
 866                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 867                 {
 868                         ClientKill_Now();
 869                 }
 870                 else
 871                 {
 872                         starttime = max(time, clientkilltime);
 873
 874                         self.killindicator = spawn();
 875                         self.killindicator.owner = self;
 876                         self.killindicator.scale = 0.5;
 877                         setattachment(self.killindicator, self, "");
 878                         setorigin(self.killindicator, '0 0 52');
 879                         self.killindicator.think = KillIndicator_Think;
 880                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 881                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 882                         self.killindicator.cnt = ceil(killtime);
 883                         self.killindicator.count = bound(0, ceil(killtime), 10);
 884                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 885
 886                         for(e = world; (e = find(e, classname, "body")) != world; )
 887                         {
 888                                 if(e.enemy != self)
 889                                         continue;
 890                                 e.killindicator = spawn();
 891                                 e.killindicator.owner = e;
 892                                 e.killindicator.scale = 0.5;
 893                                 setattachment(e.killindicator, e, "");
 894                                 setorigin(e.killindicator, '0 0 52');
 895                                 e.killindicator.think = KillIndicator_Think;
 896                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 897                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 898                                 e.killindicator.cnt = ceil(killtime);
 899                         }
 900                         self.lip = 0;
 901                 }
 902         }
 903         if(self.killindicator)
 904         {
 905                 if(targetteam == 0) // just die
 906                 {
 907                         self.killindicator.colormod = '0 0 0';
 908                         if(IS_REAL_CLIENT(self))
 909                         if(self.killindicator.cnt > 0)
 910                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 911                 }
 912                 else if(targetteam == -1) // auto
 913                 {
 914                         self.killindicator.colormod = '0 1 0';
 915                         if(IS_REAL_CLIENT(self))
 916                         if(self.killindicator.cnt > 0)
 917                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 918                 }
 919                 else if(targetteam == -2) // spectate
 920                 {
 921                         self.killindicator.colormod = '0.5 0.5 0.5';
 922                         if(IS_REAL_CLIENT(self))
 923                         if(self.killindicator.cnt > 0)
 924                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 925                 }
 926                 else
 927                 {
 928                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 929                         if(IS_REAL_CLIENT(self))
 930                         if(self.killindicator.cnt > 0)
 931                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 932                 }
 933         }
 934
 935 }
 936
 937 void ClientKill (void)
 938 {
 939         if(gameover) return;
 940         if(self.player_blocked) return;
 941         if(self.frozen) return;
 942
 943         ClientKill_TeamChange(0);
 944 }
 945
 946 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 947 {
 948     e.killindicator = spawn();
 949     e.killindicator.owner = e;
 950     e.killindicator.think = KillIndicator_Think;
 951     e.killindicator.nextthink = time + (e.lip) * 0.05;
 952     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 953     e.killindicator.health = 1; // this is used to indicate that it should be silent
 954     e.lip = 0;
 955 }
 956
 957 void FixClientCvars(entity e)
 958 {
 959         // send prediction settings to the client
 960         stuffcmd(e, "\nin_bindmap 0 0\n");
 961         if(g_race || g_cts)
 962                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 963         if(autocvar_g_antilag == 3) // client side hitscan
 964                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 965         if(autocvar_sv_gentle)
 966                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 967         /*
 968          * we no longer need to stuff this. Remove this comment block if you feel
 969          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 970         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 971         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 972         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 973         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 974         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 975         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 976         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 978         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 979         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 982         stuffcmd(e, "cl_movement_edgefriction 1\n");
 983          */
 984 }
 985
 986 float PlayerInIDList(entity p, string idlist)
 987 {
 988         float n, i;
 989         string s;
 990
 991         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 992         if (!p.crypto_idfp)
 993                 return 0;
 994
 995         // this function allows abbreviated player IDs too!
 996         n = tokenize_console(idlist);
 997         for(i = 0; i < n; ++i)
 998         {
 999                 s = argv(i);
1000                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1001                         return 1;
1002         }
1003
1004         return 0;
1005 }
1006
1007 /*
1008 =============
1009 ClientConnect
1010
1011 Called when a client connects to the server
1012 =============
1013 */
1014 void DecodeLevelParms (void);
1015 //void dom_player_join_team(entity pl);
1016 void set_dom_state(entity e);
1017 void ClientConnect (void)
1018 {
1019         float t;
1020
1021         if(IS_CLIENT(self))
1022         {
1023                 print("Warning: ClientConnect, but already connected!\n");
1024                 return;
1025         }
1026
1027         if(Ban_MaybeEnforceBanOnce(self))
1028                 return;
1029
1030         DecodeLevelParms();
1031
1032 #ifdef WATERMARK
1033         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1034 #endif
1035
1036         self.classname = "player_joining";
1037
1038         self.flags = FL_CLIENT;
1039         self.version_nagtime = time + 10 + random() * 10;
1040
1041         if(player_count<0)
1042         {
1043                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1044                 player_count = 0;
1045         }
1046
1047         PlayerScore_Attach(self);
1048         ClientData_Attach();
1049         accuracy_init(self);
1050
1051         bot_clientconnect();
1052
1053         playerdemo_init();
1054
1055         anticheat_init();
1056
1057         // identify the right forced team
1058         if(autocvar_g_campaign)
1059         {
1060                 if(IS_REAL_CLIENT(self)) // only players, not bots
1061                 {
1062                         switch(autocvar_g_campaign_forceteam)
1063                         {
1064                                 case 1: self.team_forced = NUM_TEAM_1; break;
1065                                 case 2: self.team_forced = NUM_TEAM_2; break;
1066                                 case 3: self.team_forced = NUM_TEAM_3; break;
1067                                 case 4: self.team_forced = NUM_TEAM_4; break;
1068                                 default: self.team_forced = 0;
1069                         }
1070                 }
1071         }
1072         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1073                 self.team_forced = NUM_TEAM_1;
1074         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1075                 self.team_forced = NUM_TEAM_2;
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1077                 self.team_forced = NUM_TEAM_3;
1078         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1079                 self.team_forced = NUM_TEAM_4;
1080         else if(autocvar_g_forced_team_otherwise == "red")
1081                 self.team_forced = NUM_TEAM_1;
1082         else if(autocvar_g_forced_team_otherwise == "blue")
1083                 self.team_forced = NUM_TEAM_2;
1084         else if(autocvar_g_forced_team_otherwise == "yellow")
1085                 self.team_forced = NUM_TEAM_3;
1086         else if(autocvar_g_forced_team_otherwise == "pink")
1087                 self.team_forced = NUM_TEAM_4;
1088         else if(autocvar_g_forced_team_otherwise == "spectate")
1089                 self.team_forced = -1;
1090         else if(autocvar_g_forced_team_otherwise == "spectator")
1091                 self.team_forced = -1;
1092         else
1093                 self.team_forced = 0;
1094
1095         if(!teamplay)
1096                 if(self.team_forced > 0)
1097                         self.team_forced = 0;
1098
1099         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1100
1101         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1102                 self.classname = "observer";
1103         } else {
1104                 if(teamplay)
1105                 {
1106                         if(autocvar_g_balance_teams)
1107                         {
1108                                 self.classname = "player";
1109                                 campaign_bots_may_start = 1;
1110                         }
1111                         else
1112                         {
1113                                 self.classname = "observer"; // do it anyway
1114                         }
1115                 }
1116                 else
1117                 {
1118                         self.classname = "player";
1119                         campaign_bots_may_start = 1;
1120                 }
1121         }
1122
1123         self.playerid = (playerid_last = playerid_last + 1);
1124
1125         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1126
1127     if(IS_BOT_CLIENT(self))
1128         PlayerStats_AddPlayer(self);
1129
1130         if(autocvar_sv_eventlog)
1131                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1132
1133         LogTeamchange(self.playerid, self.team, 1);
1134
1135         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1136
1137         self.netname_previous = strzone(self.netname);
1138
1139         if(IS_PLAYER(self) && teamplay)
1140                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1141         else
1142                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1143
1144         stuffcmd(self, strcat(clientstuff, "\n"));
1145         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1146
1147         FixClientCvars(self);
1148
1149         // spawnfunc_waypoint sprites
1150         WaypointSprite_InitClient(self);
1151
1152         // Wazat's grappling hook
1153         SetGrappleHookBindings();
1154
1155         // get version info from player
1156         stuffcmd(self, "cmd clientversion $gameversion\n");
1157
1158         // get other cvars from player
1159         GetCvars(0);
1160
1161         // notify about available teams
1162         if(teamplay)
1163         {
1164                 CheckAllowedTeams(self);
1165                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1166                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1167         }
1168         else
1169                 stuffcmd(self, "set _teams_available 0\n");
1170
1171         attach_entcs();
1172
1173         bot_relinkplayerlist();
1174
1175         self.spectatortime = time;
1176         if(blockSpectators)
1177         {
1178                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1179         }
1180
1181         self.jointime = time;
1182         self.allowed_timeouts = autocvar_sv_timeout_number;
1183
1184         if(IS_REAL_CLIENT(self))
1185         {
1186                 if(!autocvar_g_campaign)
1187                 {
1188                         self.motd_actived_time = -1;
1189                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1190                 }
1191
1192                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1193                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1194         }
1195
1196         if(!sv_foginterval && world.fog != "")
1197                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1198
1199         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1200         {
1201                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1202                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1203         }
1204         else
1205                 self.hitplotfh = -1;
1206
1207         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1208                 send_CSQC_teamnagger();
1209
1210         CheatInitClient();
1211
1212         CSQCMODEL_AUTOINIT();
1213
1214         self.model_randomizer = random();
1215
1216         if(IS_REAL_CLIENT(self))
1217                 sv_notice_join();
1218
1219         MUTATOR_CALLHOOK(ClientConnect);
1220 }
1221 /*
1222 =============
1223 ClientDisconnect
1224
1225 Called when a client disconnects from the server
1226 =============
1227 */
1228 .entity chatbubbleentity;
1229 void ReadyCount();
1230 void ClientDisconnect (void)
1231 {
1232         if(self.vehicle)
1233             vehicles_exit(VHEF_RELESE);
1234
1235         if (!IS_CLIENT(self))
1236         {
1237                 print("Warning: ClientDisconnect without ClientConnect\n");
1238                 return;
1239         }
1240
1241         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1242
1243         PlayerStats_AddGlobalInfo(self);
1244
1245         CheatShutdownClient();
1246
1247         if(self.hitplotfh >= 0)
1248         {
1249                 fclose(self.hitplotfh);
1250                 self.hitplotfh = -1;
1251         }
1252
1253         anticheat_report();
1254         anticheat_shutdown();
1255
1256         playerdemo_shutdown();
1257
1258         bot_clientdisconnect();
1259
1260         if(self.entcs)
1261                 detach_entcs();
1262
1263         if(autocvar_sv_eventlog)
1264                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1265
1266         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1267
1268         MUTATOR_CALLHOOK(ClientDisconnect);
1269
1270         Portal_ClearAll(self);
1271
1272         Unfreeze(self);
1273
1274         RemoveGrapplingHook(self);
1275
1276         // Here, everything has been done that requires this player to be a client.
1277
1278         self.flags &= ~FL_CLIENT;
1279
1280         if (self.chatbubbleentity)
1281                 remove (self.chatbubbleentity);
1282
1283         if (self.killindicator)
1284                 remove (self.killindicator);
1285
1286         WaypointSprite_PlayerGone();
1287
1288         bot_relinkplayerlist();
1289
1290         accuracy_free(self);
1291         ClientData_Detach();
1292         PlayerScore_Detach(self);
1293
1294         if(self.netname_previous)
1295                 strunzone(self.netname_previous);
1296         if(self.clientstatus)
1297                 strunzone(self.clientstatus);
1298         if(self.weaponorder_byimpulse)
1299                 strunzone(self.weaponorder_byimpulse);
1300
1301         ClearPlayerSounds();
1302
1303         if(self.personal)
1304                 remove(self.personal);
1305
1306         self.playerid = 0;
1307         ReadyCount();
1308
1309         // free cvars
1310         GetCvars(-1);
1311 }
1312
1313 .float BUTTON_CHAT;
1314 void ChatBubbleThink()
1315 {
1316         self.nextthink = time;
1317         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1318         {
1319                 if(self.owner) // but why can that ever be world?
1320                         self.owner.chatbubbleentity = world;
1321                 remove(self);
1322                 return;
1323         }
1324         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1325 #ifdef TETRIS
1326                 || self.owner.tetris_on
1327 #endif
1328         )
1329                 self.model = self.mdl;
1330         else
1331                 self.model = "";
1332 }
1333
1334 void UpdateChatBubble()
1335 {
1336         if (self.alpha < 0)
1337                 return;
1338         // spawn a chatbubble entity if needed
1339         if (!self.chatbubbleentity)
1340         {
1341                 self.chatbubbleentity = spawn();
1342                 self.chatbubbleentity.owner = self;
1343                 self.chatbubbleentity.exteriormodeltoclient = self;
1344                 self.chatbubbleentity.think = ChatBubbleThink;
1345                 self.chatbubbleentity.nextthink = time;
1346                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1347                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1348                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1349                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1350                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1351                 self.chatbubbleentity.model = "";
1352                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1353         }
1354 }
1355
1356
1357 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1358 // added to the model skins
1359 /*void UpdateColorModHack()
1360 {
1361         float c;
1362         c = self.clientcolors & 15;
1363         // LordHavoc: only bothering to support white, green, red, yellow, blue
1364              if (!teamplay) self.colormod = '0 0 0';
1365         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1366         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1367         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1368         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1369         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1370         else self.colormod = '1 1 1';
1371 }*/
1372
1373 void respawn(void)
1374 {
1375         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1376         {
1377                 self.solid = SOLID_NOT;
1378                 self.takedamage = DAMAGE_NO;
1379                 self.movetype = MOVETYPE_FLY;
1380                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1381                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1382                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1383                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1384                 if(autocvar_g_respawn_ghosts_maxtime)
1385                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1386         }
1387
1388         CopyBody(1);
1389
1390         self.effects |= EF_NODRAW; // prevent another CopyBody
1391         PutClientInServer();
1392 }
1393
1394 void play_countdown(float finished, string samp)
1395 {
1396         if(IS_REAL_CLIENT(self))
1397                 if(floor(finished - time - frametime) != floor(finished - time))
1398                         if(finished - time < 6)
1399                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1400 }
1401
1402 void player_powerups (void)
1403 {
1404         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1405         olditems = self.items;
1406
1407         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1408                 self.modelflags |= MF_ROCKET;
1409         else
1410                 self.modelflags &= ~MF_ROCKET;
1411
1412         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1413
1414         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1415                 return;
1416
1417         Fire_ApplyDamage(self);
1418         Fire_ApplyEffect(self);
1419
1420         if (!g_instagib)
1421         {
1422                 if (self.items & IT_STRENGTH)
1423                 {
1424                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1425                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1426                         if (time > self.strength_finished)
1427                         {
1428                                 self.items = self.items - (self.items & IT_STRENGTH);
1429                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1430                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1431                         }
1432                 }
1433                 else
1434                 {
1435                         if (time < self.strength_finished)
1436                         {
1437                                 self.items = self.items | IT_STRENGTH;
1438                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1439                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1440                         }
1441                 }
1442                 if (self.items & IT_INVINCIBLE)
1443                 {
1444                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1445                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1446                         if (time > self.invincible_finished)
1447                         {
1448                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1449                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1450                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1451                         }
1452                 }
1453                 else
1454                 {
1455                         if (time < self.invincible_finished)
1456                         {
1457                                 self.items = self.items | IT_INVINCIBLE;
1458                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1459                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1460                         }
1461                 }
1462                 if (self.items & IT_SUPERWEAPON)
1463                 {
1464                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1465                         {
1466                                 self.superweapons_finished = 0;
1467                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1468                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1469                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1470                         }
1471                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1472                         {
1473                                 // don't let them run out
1474                         }
1475                         else
1476                         {
1477                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1478                                 if (time > self.superweapons_finished)
1479                                 {
1480                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1481                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1482                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1483                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1484                                 }
1485                         }
1486                 }
1487                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1488                 {
1489                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1490                         {
1491                                 self.items = self.items | IT_SUPERWEAPON;
1492                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1493                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1494                         }
1495                         else
1496                         {
1497                                 self.superweapons_finished = 0;
1498                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1499                         }
1500                 }
1501                 else
1502                 {
1503                         self.superweapons_finished = 0;
1504                 }
1505         }
1506
1507         if(autocvar_g_nodepthtestplayers)
1508                 self.effects = self.effects | EF_NODEPTHTEST;
1509
1510         if(autocvar_g_fullbrightplayers)
1511                 self.effects = self.effects | EF_FULLBRIGHT;
1512
1513         if (time >= game_starttime)
1514         if (time < self.spawnshieldtime)
1515                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1516
1517         MUTATOR_CALLHOOK(PlayerPowerups);
1518 }
1519
1520 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1521 {
1522         if(current > stable)
1523                 return current;
1524         else if(current > stable - 0.25) // when close enough, "snap"
1525                 return stable;
1526         else
1527                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1528 }
1529
1530 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1531 {
1532         if(current < stable)
1533                 return current;
1534         else if(current < stable + 0.25) // when close enough, "snap"
1535                 return stable;
1536         else
1537                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1538 }
1539
1540 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1541 {
1542         if(current > rotstable)
1543         {
1544                 if(rotframetime > 0)
1545                 {
1546                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1547                         current = max(rotstable, current - rotlinear * rotframetime);
1548                 }
1549         }
1550         else if(current < regenstable)
1551         {
1552                 if(regenframetime > 0)
1553                 {
1554                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1555                         current = min(regenstable, current + regenlinear * regenframetime);
1556                 }
1557         }
1558
1559         if(current > limit)
1560                 current = limit;
1561
1562         return current;
1563 }
1564
1565 void player_regen (void)
1566 {
1567         float max_mod, regen_mod, rot_mod, limit_mod;
1568         max_mod = regen_mod = rot_mod = limit_mod = 1;
1569         regen_mod_max = max_mod;
1570         regen_mod_regen = regen_mod;
1571         regen_mod_rot = rot_mod;
1572         regen_mod_limit = limit_mod;
1573         if(!MUTATOR_CALLHOOK(PlayerRegen))
1574         if(!self.frozen)
1575         {
1576                 float minh, mina, maxh, maxa, limith, limita;
1577                 maxh = autocvar_g_balance_health_rotstable;
1578                 maxa = autocvar_g_balance_armor_rotstable;
1579                 minh = autocvar_g_balance_health_regenstable;
1580                 mina = autocvar_g_balance_armor_regenstable;
1581                 limith = autocvar_g_balance_health_limit;
1582                 limita = autocvar_g_balance_armor_limit;
1583
1584                 max_mod = regen_mod_max;
1585                 regen_mod = regen_mod_regen;
1586                 rot_mod = regen_mod_rot;
1587                 limit_mod = regen_mod_limit;
1588
1589                 maxh = maxh * max_mod;
1590                 minh = minh * max_mod;
1591                 limith = limith * limit_mod;
1592                 limita = limita * limit_mod;
1593
1594                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1595                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1596         }
1597
1598         // if player rotted to death...  die!
1599         // check this outside above checks, as player may still be able to rot to death
1600         if(self.health < 1)
1601                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1602
1603         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1604         {
1605                 float minf, maxf, limitf;
1606
1607                 maxf = autocvar_g_balance_fuel_rotstable;
1608                 minf = autocvar_g_balance_fuel_regenstable;
1609                 limitf = autocvar_g_balance_fuel_limit;
1610
1611                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1612         }
1613 }
1614
1615 float zoomstate_set;
1616 void SetZoomState(float z)
1617 {
1618         if(z != self.zoomstate)
1619         {
1620                 self.zoomstate = z;
1621                 ClientData_Touch(self);
1622         }
1623         zoomstate_set = 1;
1624 }
1625
1626 void GetPressedKeys(void) {
1627         MUTATOR_CALLHOOK(GetPressedKeys);
1628         if (self.movement_x > 0) // get if movement keys are pressed
1629         {       // forward key pressed
1630                 self.pressedkeys |= KEY_FORWARD;
1631                 self.pressedkeys &= ~KEY_BACKWARD;
1632         }
1633         else if (self.movement_x < 0)
1634         {       // backward key pressed
1635                 self.pressedkeys |= KEY_BACKWARD;
1636                 self.pressedkeys &= ~KEY_FORWARD;
1637         }
1638         else
1639         {       // no x input
1640                 self.pressedkeys &= ~KEY_FORWARD;
1641                 self.pressedkeys &= ~KEY_BACKWARD;
1642         }
1643
1644         if (self.movement_y > 0)
1645         {       // right key pressed
1646                 self.pressedkeys |= KEY_RIGHT;
1647                 self.pressedkeys &= ~KEY_LEFT;
1648         }
1649         else if (self.movement_y < 0)
1650         {       // left key pressed
1651                 self.pressedkeys |= KEY_LEFT;
1652                 self.pressedkeys &= ~KEY_RIGHT;
1653         }
1654         else
1655         {       // no y input
1656                 self.pressedkeys &= ~KEY_RIGHT;
1657                 self.pressedkeys &= ~KEY_LEFT;
1658         }
1659
1660         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1661                 self.pressedkeys |= KEY_JUMP;
1662         else
1663                 self.pressedkeys &= ~KEY_JUMP;
1664         if (self.BUTTON_CROUCH)
1665                 self.pressedkeys |= KEY_CROUCH;
1666         else
1667                 self.pressedkeys &= ~KEY_CROUCH;
1668
1669         if (self.BUTTON_ATCK)
1670                 self.pressedkeys |= KEY_ATCK;
1671         else
1672                 self.pressedkeys &= ~KEY_ATCK;
1673         if (self.BUTTON_ATCK2)
1674                 self.pressedkeys |= KEY_ATCK2;
1675         else
1676                 self.pressedkeys &= ~KEY_ATCK2;
1677 }
1678
1679 /*
1680 ======================
1681 spectate mode routines
1682 ======================
1683 */
1684
1685 void SpectateCopy(entity spectatee) {
1686         other = spectatee;
1687         MUTATOR_CALLHOOK(SpectateCopy);
1688         self.armortype = spectatee.armortype;
1689         self.armorvalue = spectatee.armorvalue;
1690         self.ammo_cells = spectatee.ammo_cells;
1691         self.ammo_shells = spectatee.ammo_shells;
1692         self.ammo_nails = spectatee.ammo_nails;
1693         self.ammo_rockets = spectatee.ammo_rockets;
1694         self.ammo_fuel = spectatee.ammo_fuel;
1695         self.clip_load = spectatee.clip_load;
1696         self.clip_size = spectatee.clip_size;
1697         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1698         self.health = spectatee.health;
1699         self.impulse = 0;
1700         self.items = spectatee.items;
1701         self.last_pickup = spectatee.last_pickup;
1702         self.hit_time = spectatee.hit_time;
1703         self.metertime = spectatee.metertime;
1704         self.strength_finished = spectatee.strength_finished;
1705         self.invincible_finished = spectatee.invincible_finished;
1706         self.pressedkeys = spectatee.pressedkeys;
1707         self.weapons = spectatee.weapons;
1708         self.switchweapon = spectatee.switchweapon;
1709         self.switchingweapon = spectatee.switchingweapon;
1710         self.weapon = spectatee.weapon;
1711         self.nex_charge = spectatee.nex_charge;
1712         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1713         self.hagar_load = spectatee.hagar_load;
1714         self.minelayer_mines = spectatee.minelayer_mines;
1715         self.punchangle = spectatee.punchangle;
1716         self.view_ofs = spectatee.view_ofs;
1717         self.velocity = spectatee.velocity;
1718         self.dmg_take = spectatee.dmg_take;
1719         self.dmg_save = spectatee.dmg_save;
1720         self.dmg_inflictor = spectatee.dmg_inflictor;
1721         self.v_angle = spectatee.v_angle;
1722         self.angles = spectatee.v_angle;
1723         self.frozen = spectatee.frozen;
1724         self.revive_progress = spectatee.revive_progress;
1725         if(!self.BUTTON_USE)
1726                 self.fixangle = TRUE;
1727         setorigin(self, spectatee.origin);
1728         setsize(self, spectatee.mins, spectatee.maxs);
1729         SetZoomState(spectatee.zoomstate);
1730
1731     anticheat_spectatecopy(spectatee);
1732         self.hud = spectatee.hud;
1733         if(spectatee.vehicle)
1734     {
1735         self.fixangle = FALSE;
1736         //self.velocity = spectatee.vehicle.velocity;
1737         self.vehicle_health = spectatee.vehicle_health;
1738         self.vehicle_shield = spectatee.vehicle_shield;
1739         self.vehicle_energy = spectatee.vehicle_energy;
1740         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1741         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1742         self.vehicle_reload1 = spectatee.vehicle_reload1;
1743         self.vehicle_reload2 = spectatee.vehicle_reload2;
1744
1745         msg_entity = self;
1746
1747         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1748             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1749             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1750             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1751
1752         //WriteByte (MSG_ONE, SVC_SETVIEW);
1753         //    WriteEntity(MSG_ONE, self);
1754         //makevectors(spectatee.v_angle);
1755         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1756     }
1757 }
1758
1759 float SpectateUpdate() {
1760         if(!self.enemy)
1761             return 0;
1762
1763         if (self == self.enemy)
1764                 return 0;
1765
1766         if (!IS_PLAYER(self.enemy))
1767                 return 0;
1768
1769         SpectateCopy(self.enemy);
1770
1771         return 1;
1772 }
1773
1774
1775 float SpectateSet()
1776 {
1777         if(self.enemy.classname != "player")
1778                 return FALSE;
1779         /*if(self.enemy.vehicle)
1780         {
1781
1782                 msg_entity = self;
1783                 WriteByte(MSG_ONE, SVC_SETVIEW);
1784                 WriteEntity(MSG_ONE, self.enemy);
1785                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1786
1787                 self.movetype = MOVETYPE_NONE;
1788                 accuracy_resend(self);
1789         }
1790         else
1791         {*/
1792                 msg_entity = self;
1793                 WriteByte(MSG_ONE, SVC_SETVIEW);
1794                 WriteEntity(MSG_ONE, self.enemy);
1795                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1796                 self.movetype = MOVETYPE_NONE;
1797                 accuracy_resend(self);
1798
1799                 if(!SpectateUpdate())
1800                         PutObserverInServer();
1801         //}
1802         return TRUE;
1803 }
1804
1805 float Spectate(entity pl)
1806 {
1807         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1808         if(pl.team != self.team)
1809                 return 0;
1810
1811         self.enemy = pl;
1812         return SpectateSet();
1813 }
1814
1815 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1816 entity CA_SpectateNext(entity start) {
1817         if (start.team == self.team) {
1818                 return start;
1819         }
1820
1821         other = start;
1822         // continue from current player
1823         while(other && other.team != self.team) {
1824                 other = find(other, classname, "player");
1825         }
1826
1827         if (!other) {
1828                 // restart from begining
1829                 other = find(other, classname, "player");
1830                 while(other && other.team != self.team) {
1831                         other = find(other, classname, "player");
1832                 }
1833         }
1834
1835         return other;
1836 }
1837
1838 float SpectateNext()
1839 {
1840         other = find(self.enemy, classname, "player");
1841
1842         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1843                 // CA and ca players when spectating enemies is forbidden
1844                 other = CA_SpectateNext(other);
1845         } else {
1846                 // other modes and ca spectators or spectating enemies is allowed
1847                 if (!other)
1848                         other = find(other, classname, "player");
1849         }
1850
1851         if (other)
1852                 self.enemy = other;
1853
1854         return SpectateSet();
1855 }
1856
1857 float SpectatePrev()
1858 {
1859         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1860         other = findchain(classname, "player");
1861         if (!other) // no player
1862                 return FALSE;
1863
1864         entity first = other;
1865         // skip players until current spectated player
1866         if(self.enemy)
1867         while(other && other != self.enemy)
1868                 other = other.chain;
1869
1870         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1871         {
1872                 do { other = other.chain; }
1873                 while(other && other.team != self.team);
1874
1875                 if (!other)
1876                 {
1877                         other = first;
1878                         while(other.team != self.team)
1879                                 other = other.chain;
1880                         if(other == self.enemy)
1881                                 return TRUE;
1882                 }
1883         }
1884         else
1885         {
1886                 if(other.chain)
1887                         other = other.chain;
1888                 else
1889                         other = first;
1890         }
1891         self.enemy = other;
1892         return SpectateSet();
1893 }
1894
1895 /*
1896 =============
1897 ShowRespawnCountdown()
1898
1899 Update a respawn countdown display.
1900 =============
1901 */
1902 void ShowRespawnCountdown()
1903 {
1904         float number;
1905         if(self.deadflag == DEAD_NO) // just respawned?
1906                 return;
1907         else
1908         {
1909                 number = ceil(self.respawn_time - time);
1910                 if(number <= 0)
1911                         return;
1912                 if(number <= self.respawn_countdown)
1913                 {
1914                         self.respawn_countdown = number - 1;
1915                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1916                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1917                 }
1918         }
1919 }
1920
1921 void LeaveSpectatorMode()
1922 {
1923         if(self.caplayer)
1924                 return;
1925         if(nJoinAllowed(self))
1926         {
1927                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1928                 {
1929                         self.classname = "player";
1930                         nades_RemoveBonus(self);
1931
1932                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1933                                 { JoinBestTeam(self, FALSE, TRUE); }
1934
1935                         if(autocvar_g_campaign)
1936                                 { campaign_bots_may_start = 1; }
1937
1938                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1939
1940                         PutClientInServer();
1941
1942                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1943                 }
1944                 else
1945                         stuffcmd(self, "menu_showteamselect\n");
1946         }
1947         else
1948         {
1949                 // Player may not join because g_maxplayers is set
1950                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1951         }
1952 }
1953
1954 /**
1955  * Determines whether the player is allowed to join. This depends on cvar
1956  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1957  * it checks whether the number of currently playing players exceeds g_maxplayers.
1958  * @return int number of free slots for players, 0 if none
1959  */
1960 float nJoinAllowed(entity ignore) {
1961         if(!ignore)
1962         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1963         // so report 0 free slots if restricted
1964         {
1965                 if(autocvar_g_forced_team_otherwise == "spectate")
1966                         return 0;
1967                 if(autocvar_g_forced_team_otherwise == "spectator")
1968                         return 0;
1969         }
1970
1971         if(self.team_forced < 0)
1972                 return 0; // forced spectators can never join
1973
1974         // TODO simplify this
1975         entity e;
1976         float totalClients = 0;
1977         FOR_EACH_CLIENT(e)
1978                 if(e != ignore)
1979                         totalClients += 1;
1980
1981         if (!autocvar_g_maxplayers)
1982                 return maxclients - totalClients;
1983
1984         float currentlyPlaying = 0;
1985         FOR_EACH_REALCLIENT(e)
1986                 if(IS_PLAYER(e) || e.caplayer == 1)
1987                         currentlyPlaying += 1;
1988
1989         if(currentlyPlaying < autocvar_g_maxplayers)
1990                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1991
1992         return 0;
1993 }
1994
1995 /**
1996  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1997  * g_maxplayers_spectator_blocktime seconds
1998  */
1999 void checkSpectatorBlock() {
2000         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2001                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2002                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2003                         dropclient(self);
2004                 }
2005         }
2006 }
2007
2008 void PrintWelcomeMessage()
2009 {
2010         if(self.motd_actived_time == 0)
2011         {
2012                 if (autocvar_g_campaign) {
2013                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2014                                 self.motd_actived_time = time;
2015                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2016                         }
2017                 } else {
2018                         if (self.BUTTON_INFO) {
2019                                 self.motd_actived_time = time;
2020                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2021                         }
2022                 }
2023         }
2024         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2025         {
2026                 if (autocvar_g_campaign) {
2027                         if (self.BUTTON_INFO)
2028                                 self.motd_actived_time = time;
2029                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2030                                 self.motd_actived_time = 0;
2031                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2032                         }
2033                 } else {
2034                         if (self.BUTTON_INFO)
2035                                 self.motd_actived_time = time;
2036                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2037                                 self.motd_actived_time = 0;
2038                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2039                         }
2040                 }
2041         }
2042         else //if(self.motd_actived_time < 0) // just connected, motd is active
2043         {
2044                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2045                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2046                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2047                 {
2048                         // instanctly hide MOTD
2049                         self.motd_actived_time = 0;
2050                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2051                 }
2052         }
2053 }
2054
2055 void ObserverThink()
2056 {
2057         float prefered_movetype;
2058         if (self.flags & FL_JUMPRELEASED) {
2059                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2060                         self.flags &= ~FL_JUMPRELEASED;
2061                         self.flags |= FL_SPAWNING;
2062                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2063                         self.flags &= ~FL_JUMPRELEASED;
2064                         if(SpectateNext()) {
2065                                 self.classname = "spectator";
2066                         }
2067                 } else {
2068                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2069                         if (self.movetype != prefered_movetype)
2070                                 self.movetype = prefered_movetype;
2071                 }
2072         } else {
2073                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2074                         self.flags |= FL_JUMPRELEASED;
2075                         if(self.flags & FL_SPAWNING)
2076                         {
2077                                 self.flags &= ~FL_SPAWNING;
2078                                 LeaveSpectatorMode();
2079                                 return;
2080                         }
2081                 }
2082         }
2083 }
2084
2085 void SpectatorThink()
2086 {
2087         if (self.flags & FL_JUMPRELEASED) {
2088                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2089                         self.flags &= ~FL_JUMPRELEASED;
2090                         self.flags |= FL_SPAWNING;
2091                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2092                         self.flags &= ~FL_JUMPRELEASED;
2093                         if(SpectateNext()) {
2094                                 self.classname = "spectator";
2095                         } else {
2096                                 self.classname = "observer";
2097                                 PutClientInServer();
2098                         }
2099                         self.impulse = 0;
2100                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2101                         self.flags &= ~FL_JUMPRELEASED;
2102                         if(SpectatePrev()) {
2103                                 self.classname = "spectator";
2104                         } else {
2105                                 self.classname = "observer";
2106                                 PutClientInServer();
2107                         }
2108                         self.impulse = 0;
2109                 } else if (self.BUTTON_ATCK2) {
2110                         self.flags &= ~FL_JUMPRELEASED;
2111                         self.classname = "observer";
2112                         PutClientInServer();
2113                 } else {
2114                         if(!SpectateUpdate())
2115                                 PutObserverInServer();
2116                 }
2117         } else {
2118                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2119                         self.flags |= FL_JUMPRELEASED;
2120                         if(self.flags & FL_SPAWNING)
2121                         {
2122                                 self.flags &= ~FL_SPAWNING;
2123                                 LeaveSpectatorMode();
2124                                 return;
2125                         }
2126                 }
2127                 if(!SpectateUpdate())
2128                         PutObserverInServer();
2129         }
2130
2131         self.flags |= FL_CLIENT | FL_NOTARGET;
2132 }
2133
2134 void PlayerUseKey()
2135 {
2136         if (!IS_PLAYER(self))
2137                 return;
2138
2139         if(self.vehicle)
2140         {
2141         vehicles_exit(VHEF_NORMAL);
2142         return;
2143         }
2144
2145         // a use key was pressed; call handlers
2146         MUTATOR_CALLHOOK(PlayerUseKey);
2147 }
2148
2149 /*
2150 =============
2151 PlayerPreThink
2152
2153 Called every frame for each client before the physics are run
2154 =============
2155 */
2156 .float usekeypressed;
2157 void() nexball_setstatus;
2158 .float items_added;
2159 void PlayerPreThink (void)
2160 {
2161         WarpZone_PlayerPhysics_FixVAngle();
2162
2163         self.stat_game_starttime = game_starttime;
2164         self.stat_round_starttime = round_starttime;
2165         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2166         self.stat_leadlimit = autocvar_leadlimit;
2167
2168         if(frametime)
2169         {
2170                 // physics frames: update anticheat stuff
2171                 anticheat_prethink();
2172         }
2173
2174         if(blockSpectators && frametime)
2175                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2176                 checkSpectatorBlock();
2177
2178         zoomstate_set = 0;
2179
2180         if(self.netname_previous != self.netname)
2181         {
2182                 if(autocvar_sv_eventlog)
2183                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2184                 if(self.netname_previous)
2185                         strunzone(self.netname_previous);
2186                 self.netname_previous = strzone(self.netname);
2187         }
2188
2189         // version nagging
2190         if(self.version_nagtime)
2191                 if(self.cvar_g_xonoticversion)
2192                         if(time > self.version_nagtime)
2193                         {
2194                                 // don't notify git users
2195                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2196                                 {
2197                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2198                                         {
2199                                                 // notify release users if connecting to git
2200                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2201                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2202                                         }
2203                                         else
2204                                         {
2205                                                 float r;
2206                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2207                                                 if(r < 0)
2208                                                 {
2209                                                         // give users new version
2210                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2211                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2212                                                 }
2213                                                 else if(r > 0)
2214                                                 {
2215                                                         // notify users about old server version
2216                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2217                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2218                                                 }
2219                                         }
2220                                 }
2221                                 self.version_nagtime = 0;
2222                         }
2223
2224         // GOD MODE info
2225         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2226         {
2227                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2228                 self.max_armorvalue = 0;
2229         }
2230
2231 #ifdef TETRIS
2232         if (TetrisPreFrame())
2233                 return;
2234 #endif
2235
2236         if(self.frozen == 2)
2237         {
2238                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2239                 self.health = max(1, self.revive_progress * start_health);
2240                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2241
2242                 if(self.revive_progress >= 1)
2243                         Unfreeze(self);
2244         }
2245         else if(self.frozen == 3)
2246         {
2247                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2248                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2249
2250                 if(self.health < 1)
2251                 {
2252                         if(self.vehicle)
2253                                 vehicles_exit(VHEF_RELESE);
2254                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2255                 }
2256                 else if ( self.revive_progress <= 0 )
2257                         Unfreeze(self);
2258         }
2259
2260         MUTATOR_CALLHOOK(PlayerPreThink);
2261
2262         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2263         {
2264                 if(self.BUTTON_USE && !self.usekeypressed)
2265                         PlayerUseKey();
2266                 self.usekeypressed = self.BUTTON_USE;
2267         }
2268
2269         if(IS_REAL_CLIENT(self))
2270                 PrintWelcomeMessage();
2271
2272         if(IS_PLAYER(self))
2273         {
2274
2275                 CheckRules_Player();
2276
2277                 if (intermission_running)
2278                 {
2279                         IntermissionThink ();   // otherwise a button could be missed between
2280                         return;                                 // the think tics
2281                 }
2282
2283                 //don't allow the player to turn around while game is paused!
2284                 if(timeout_status == TIMEOUT_ACTIVE) {
2285                         // FIXME turn this into CSQC stuff
2286                         self.v_angle = self.lastV_angle;
2287                         self.angles = self.lastV_angle;
2288                         self.fixangle = TRUE;
2289                 }
2290
2291                 if(frametime)
2292                 {
2293                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2294                         {
2295                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2296                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2297                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2298
2299                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2300                                 {
2301                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2302                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2303                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2304                                 }
2305                         }
2306                         else
2307                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2308
2309                         player_powerups();
2310                 }
2311
2312                 if (self.deadflag != DEAD_NO)
2313                 {
2314                         if(self.personal && g_race_qualifying)
2315                         {
2316                                 if(time > self.respawn_time)
2317                                 {
2318                                         self.respawn_time = time + 1; // only retry once a second
2319                                         self.stat_respawn_time = self.respawn_time;
2320                                         respawn();
2321                                         self.impulse = 141;
2322                                 }
2323                         }
2324                         else
2325                         {
2326                                 float button_pressed;
2327                                 if(frametime)
2328                                         player_anim();
2329                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2330
2331                                 if (self.deadflag == DEAD_DYING)
2332                                 {
2333                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2334                                                 self.deadflag = DEAD_RESPAWNING;
2335                                         else if(!button_pressed)
2336                                                 self.deadflag = DEAD_DEAD;
2337                                 }
2338                                 else if (self.deadflag == DEAD_DEAD)
2339                                 {
2340                                         if(button_pressed)
2341                                                 self.deadflag = DEAD_RESPAWNABLE;
2342                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2343                                                 self.deadflag = DEAD_RESPAWNING;
2344                                 }
2345                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2346                                 {
2347                                         if(!button_pressed)
2348                                                 self.deadflag = DEAD_RESPAWNING;
2349                                 }
2350                                 else if (self.deadflag == DEAD_RESPAWNING)
2351                                 {
2352                                         if(time > self.respawn_time)
2353                                         {
2354                                                 self.respawn_time = time + 1; // only retry once a second
2355                                                 self.respawn_time_max = self.respawn_time;
2356                                                 respawn();
2357                                         }
2358                                 }
2359
2360                                 ShowRespawnCountdown();
2361
2362                                 if(self.respawn_flags & RESPAWN_SILENT)
2363                                         self.stat_respawn_time = 0;
2364                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2365                                         self.stat_respawn_time = self.respawn_time_max;
2366                                 else
2367                                         self.stat_respawn_time = self.respawn_time;
2368                         }
2369
2370                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2371                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2372                                 self.stat_respawn_time *= -1;
2373
2374                         return;
2375                 }
2376
2377                 self.prevorigin = self.origin;
2378
2379                 float do_crouch = self.BUTTON_CROUCH;
2380                 if(self.hook.state)
2381                         do_crouch = 0;
2382                 if(self.vehicle)
2383                         do_crouch = 0;
2384                 if(self.frozen)
2385                         do_crouch = 0;
2386                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2387                         do_crouch = 0;
2388
2389                 if (do_crouch)
2390                 {
2391                         if (!self.crouch)
2392                         {
2393                                 self.crouch = TRUE;
2394                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2395                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2396                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2397                         }
2398                 }
2399                 else
2400                 {
2401                         if (self.crouch)
2402                         {
2403                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2404                                 if (!trace_startsolid)
2405                                 {
2406                                         self.crouch = FALSE;
2407                                         self.view_ofs = PL_VIEW_OFS;
2408                                         setsize (self, PL_MIN, PL_MAX);
2409                                 }
2410                         }
2411                 }
2412
2413                 FixPlayermodel();
2414
2415                 GrapplingHookFrame();
2416
2417                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2418                 //if(frametime)
2419                 {
2420                         self.items &= ~self.items_added;
2421
2422                         W_WeaponFrame();
2423
2424                         self.items_added = 0;
2425                         if(self.items & IT_JETPACK)
2426                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2427                                         self.items_added |= IT_FUEL;
2428
2429                         self.items |= self.items_added;
2430                 }
2431
2432                 player_regen();
2433
2434                 // rot nex charge to the charge limit
2435                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2436                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2437
2438                 if(frametime)
2439                         player_anim();
2440
2441                 // secret status
2442                 secrets_setstatus();
2443
2444                 // monsters status
2445                 monsters_setstatus();
2446
2447                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2448
2449                 //self.angles_y=self.v_angle_y + 90;   // temp
2450         } else if(gameover) {
2451                 if (intermission_running)
2452                         IntermissionThink ();   // otherwise a button could be missed between
2453                 return;
2454         } else if(IS_OBSERVER(self)) {
2455                 ObserverThink();
2456         } else if(IS_SPEC(self)) {
2457                 SpectatorThink();
2458         }
2459
2460         if(!zoomstate_set)
2461                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2462
2463         float oldspectatee_status;
2464         oldspectatee_status = self.spectatee_status;
2465         if(IS_SPEC(self))
2466                 self.spectatee_status = num_for_edict(self.enemy);
2467         else if(IS_OBSERVER(self))
2468                 self.spectatee_status = num_for_edict(self);
2469         else
2470                 self.spectatee_status = 0;
2471         if(self.spectatee_status != oldspectatee_status)
2472         {
2473                 ClientData_Touch(self);
2474         }
2475
2476         if(self.teamkill_soundtime)
2477         if(time > self.teamkill_soundtime)
2478         {
2479                 self.teamkill_soundtime = 0;
2480
2481                 entity oldpusher, oldself;
2482
2483                 oldself = self; self = self.teamkill_soundsource;
2484                 oldpusher = self.pusher; self.pusher = oldself;
2485
2486                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2487
2488                 self.pusher = oldpusher;
2489                 self = oldself;
2490         }
2491
2492         if(self.taunt_soundtime)
2493         if(time > self.taunt_soundtime)
2494         {
2495                 self.taunt_soundtime = 0;
2496                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2497         }
2498
2499         target_voicescript_next(self);
2500
2501         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2502         if(!self.weapon)
2503                 self.clip_load = self.clip_size = 0;
2504 }
2505
2506 float isInvisibleString(string s)
2507 {
2508         float i, n, c;
2509         s = strdecolorize(s);
2510         for((i = 0), (n = strlen(s)); i < n; ++i)
2511         {
2512                 c = str2chr(s, i);
2513                 switch(c)
2514                 {
2515                         case 0:
2516                         case 32: // space
2517                                 break;
2518                         case 192: // charmap space
2519                                 if (!autocvar_utf8_enable)
2520                                         break;
2521                                 return FALSE;
2522                         case 160: // space in unicode fonts
2523                         case 0xE000 + 192: // utf8 charmap space
2524                                 if (autocvar_utf8_enable)
2525                                         break;
2526                         default:
2527                                 return FALSE;
2528                 }
2529         }
2530         return TRUE;
2531 }
2532
2533 /*
2534 =============
2535 PlayerPostThink
2536
2537 Called every frame for each client after the physics are run
2538 =============
2539 */
2540 .float idlekick_lasttimeleft;
2541 void PlayerPostThink (void)
2542 {
2543         // Savage: Check for nameless players
2544         if (isInvisibleString(self.netname)) {
2545                 self.netname = "Player";
2546                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2547         }
2548
2549         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2550         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2551         {
2552                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2553                 {
2554                         if(self.idlekick_lasttimeleft)
2555                         {
2556                                 self.idlekick_lasttimeleft = 0;
2557                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2558                         }
2559                 }
2560                 else
2561                 {
2562                         float timeleft;
2563                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2564                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2565                         {
2566                                 if(!self.idlekick_lasttimeleft)
2567                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2568                         }
2569                         if(timeleft <= 0)
2570                         {
2571                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2572                                 dropclient(self);
2573                                 return;
2574                         }
2575                         else if(timeleft <= 10)
2576                         {
2577                                 if(timeleft != self.idlekick_lasttimeleft)
2578                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2579                                 self.idlekick_lasttimeleft = timeleft;
2580                         }
2581                 }
2582         }
2583
2584 #ifdef TETRIS
2585         if(self.impulse == 100)
2586                 ImpulseCommands();
2587         if (!TetrisPostFrame())
2588         {
2589 #endif
2590
2591         CheatFrame();
2592
2593         //CheckPlayerJump();
2594
2595         if(IS_PLAYER(self)) {
2596                 CheckRules_Player();
2597                 UpdateChatBubble();
2598                 if (self.impulse)
2599                         ImpulseCommands();
2600                 if (intermission_running)
2601                         return;         // intermission or finale
2602                 GetPressedKeys();
2603         }
2604
2605 #ifdef TETRIS
2606         }
2607 #endif
2608
2609         /*
2610         float i;
2611         for(i = 0; i < 1000; ++i)
2612         {
2613                 vector end;
2614                 end = self.origin + '0 0 1024' + 512 * randomvec();
2615                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2616                 if(trace_fraction < 1)
2617                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2618                 {
2619                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2620                         break;
2621                 }
2622         }
2623         */
2624
2625         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2626
2627         if(self.waypointsprite_attachedforcarrier)
2628                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2629
2630         playerdemo_write();
2631
2632         CSQCMODEL_AUTOUPDATE();
2633 }