qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/all.qc"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     WITHSELF(this, ClientConnect());
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     WITHSELF(this, PutClientInServer());
  63 }
  64
  65 void PutObserverInServer();
  66 void ClientDisconnect();
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     WITHSELF(this, PutClientInServer());
  72     WITHSELF(this, ClientDisconnect());
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 bool ClientData_Send(entity this, entity to, int sf)
  80 {
  81         assert(to == this.owner, return false);
  82
  83         entity e = to;
  84         if (IS_SPEC(e)) e = e.enemy;
  85
  86         sf = 0;
  87         if (e.race_completed)       sf |= 1; // forced scoreboard
  88         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
  89         if (e.zoomstate)            sf |= 4; // zoomed
  90         if (e.porto_v_angle_held)   sf |= 8; // angles held
  91
  92         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  93         WriteByte(MSG_ENTITY, sf);
  94
  95         if (sf & 2)
  96         {
  97                 WriteByte(MSG_ENTITY, to.spectatee_status);
  98         }
  99         if (sf & 8)
 100         {
 101                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 102                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 103         }
 104         return true;
 105 }
 106
 107 void ClientData_Attach(entity this)
 108 {
 109         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 110         this.clientdata.drawonlytoclient = this;
 111         this.clientdata.owner = this;
 112 }
 113
 114 void ClientData_Detach(entity this)
 115 {
 116         remove(this.clientdata);
 117         this.clientdata = NULL;
 118 }
 119
 120 void ClientData_Touch(entity e)
 121 {
 122         e.clientdata.SendFlags = 1;
 123
 124         // make it spectatable
 125         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 126 }
 127
 128 .string netname_previous;
 129
 130 void SetSpectatee(entity player, entity spectatee);
 131
 132
 133 /*
 134 =============
 135 CheckPlayerModel
 136
 137 Checks if the argument string can be a valid playermodel.
 138 Returns a valid one in doubt.
 139 =============
 140 */
 141 string FallbackPlayerModel;
 142 string CheckPlayerModel(string plyermodel) {
 143         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 144         {
 145                 // note: we cannot summon Don Strunzone here, some player may
 146                 // still have the model string set. In case anyone manages how
 147                 // to change a cvar default, we'll have a small leak here.
 148                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 149         }
 150         // only in right path
 151         if( substring(plyermodel,0,14) != "models/player/")
 152                 return FallbackPlayerModel;
 153         // only good file extensions
 154         if(substring(plyermodel,-4,4) != ".zym")
 155         if(substring(plyermodel,-4,4) != ".dpm")
 156         if(substring(plyermodel,-4,4) != ".iqm")
 157         if(substring(plyermodel,-4,4) != ".md3")
 158         if(substring(plyermodel,-4,4) != ".psk")
 159                 return FallbackPlayerModel;
 160         // forbid the LOD models
 161         if(substring(plyermodel, -9,5) == "_lod1")
 162                 return FallbackPlayerModel;
 163         if(substring(plyermodel, -9,5) == "_lod2")
 164                 return FallbackPlayerModel;
 165         if(plyermodel != strtolower(plyermodel))
 166                 return FallbackPlayerModel;
 167         // also, restrict to server models
 168         if(autocvar_sv_servermodelsonly)
 169         {
 170                 if(!fexists(plyermodel))
 171                         return FallbackPlayerModel;
 172         }
 173         return plyermodel;
 174 }
 175
 176 void setplayermodel(entity e, string modelname)
 177 {
 178         precache_model(modelname);
 179         _setmodel(e, modelname);
 180         player_setupanimsformodel();
 181         if(!autocvar_g_debug_globalsounds)
 182                 UpdatePlayerSounds(e);
 183 }
 184
 185 void FixPlayermodel(entity player);
 186 /** putting a client as observer in the server */
 187 void PutObserverInServer()
 188 {
 189         SELFPARAM();
 190     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver);
 191         PlayerState_detach(this);
 192
 193         if (IS_PLAYER(this) && this.health >= 1) {
 194         // despawn effect
 195                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 196     }
 197
 198     {
 199         entity spot = SelectSpawnPoint(this, true);
 200         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 201         this.angles = spot.angles;
 202         this.angles_z = 0;
 203         this.fixangle = true;
 204         // offset it so that the spectator spawns higher off the ground, looks better this way
 205         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 206         this.prevorigin = this.origin;
 207         if (IS_REAL_CLIENT(this))
 208         {
 209             msg_entity = this;
 210             WriteByte(MSG_ONE, SVC_SETVIEW);
 211             WriteEntity(MSG_ONE, this);
 212         }
 213         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 214         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 215         if(!autocvar_g_debug_globalsounds)
 216         {
 217                 // needed for player sounds
 218                 this.model = "";
 219                 FixPlayermodel(this);
 220         }
 221         setmodel(this, MDL_Null);
 222         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 223         this.view_ofs = '0 0 0';
 224     }
 225
 226     RemoveGrapplingHook(this);
 227         Portal_ClearAll(this);
 228         Unfreeze(this);
 229
 230         if (this.alivetime)
 231         {
 232                 if (!warmup_stage)
 233                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 234                 this.alivetime = 0;
 235         }
 236
 237         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
 238
 239         WaypointSprite_PlayerDead(this);
 240
 241         if (mutator_returnvalue) {
 242             // mutator prevents resetting teams+score
 243         } else {
 244                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 245         this.frags = FRAGS_SPECTATOR;
 246         PlayerScore_Clear(this);  // clear scores when needed
 247     }
 248
 249         if (this.killcount != FRAGS_SPECTATOR)
 250         {
 251                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 252                 if(!intermission_running)
 253                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 254                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 255
 256                 if(this.just_joined == false) {
 257                         LogTeamchange(this.playerid, -1, 4);
 258                 } else
 259                         this.just_joined = false;
 260         }
 261
 262         accuracy_resend(this);
 263
 264         this.spectatortime = time;
 265         this.bot_attack = false;
 266     this.hud = HUD_NORMAL;
 267         TRANSMUTE(Observer, this);
 268         this.iscreature = false;
 269         this.teleportable = TELEPORT_SIMPLE;
 270         this.damagedbycontents = false;
 271         this.health = FRAGS_SPECTATOR;
 272         this.takedamage = DAMAGE_NO;
 273         this.solid = SOLID_NOT;
 274         this.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 275         this.flags = FL_CLIENT | FL_NOTARGET;
 276         this.armorvalue = 666;
 277         this.effects = 0;
 278         this.armorvalue = autocvar_g_balance_armor_start;
 279         this.pauserotarmor_finished = 0;
 280         this.pauserothealth_finished = 0;
 281         this.pauseregen_finished = 0;
 282         this.damageforcescale = 0;
 283         this.death_time = 0;
 284         this.respawn_flags = 0;
 285         this.respawn_time = 0;
 286         this.stat_respawn_time = 0;
 287         this.alpha = 0;
 288         this.scale = 0;
 289         this.fade_time = 0;
 290         this.pain_frame = 0;
 291         this.pain_finished = 0;
 292         this.strength_finished = 0;
 293         this.invincible_finished = 0;
 294         this.superweapons_finished = 0;
 295         this.pushltime = 0;
 296         this.istypefrag = 0;
 297         this.think = func_null;
 298         this.nextthink = 0;
 299         this.hook_time = 0;
 300         this.deadflag = DEAD_NO;
 301         this.crouch = false;
 302         this.revival_time = 0;
 303
 304         this.items = 0;
 305         this.weapons = '0 0 0';
 306         this.drawonlytoclient = this;
 307
 308         this.weaponname = "";
 309         this.weaponmodel = "";
 310         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 311         {
 312                 this.weaponentities[slot] = NULL;
 313         }
 314         this.exteriorweaponentity = NULL;
 315         this.killcount = FRAGS_SPECTATOR;
 316         this.velocity = '0 0 0';
 317         this.avelocity = '0 0 0';
 318         this.punchangle = '0 0 0';
 319         this.punchvector = '0 0 0';
 320         this.oldvelocity = this.velocity;
 321         this.fire_endtime = -1;
 322         this.event_damage = func_null;
 323 }
 324
 325 int player_getspecies(entity this)
 326 {
 327         get_model_parameters(this.model, this.skin);
 328         int s = get_model_parameters_species;
 329         get_model_parameters(string_null, 0);
 330         if (s < 0) return SPECIES_HUMAN;
 331         return s;
 332 }
 333
 334 .float model_randomizer;
 335 void FixPlayermodel(entity player)
 336 {
 337         string defaultmodel = "";
 338         int defaultskin = 0;
 339         if(autocvar_sv_defaultcharacter)
 340         {
 341                 if(teamplay)
 342                 {
 343                         string s = Static_Team_ColorName_Lower(player.team);
 344                         if (s != "neutral")
 345                         {
 346                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 347                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 348                         }
 349                 }
 350
 351                 if(defaultmodel == "")
 352                 {
 353                         defaultmodel = autocvar_sv_defaultplayermodel;
 354                         defaultskin = autocvar_sv_defaultplayerskin;
 355                 }
 356
 357                 int n = tokenize_console(defaultmodel);
 358                 if(n > 0)
 359                 {
 360                         defaultmodel = argv(floor(n * player.model_randomizer));
 361                         // However, do NOT randomize if the player-selected model is in the list.
 362                         for (int i = 0; i < n; ++i)
 363                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 364                                         defaultmodel = argv(i);
 365                 }
 366
 367                 int i = strstrofs(defaultmodel, ":", 0);
 368                 if(i >= 0)
 369                 {
 370                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 371                         defaultmodel = substring(defaultmodel, 0, i);
 372                 }
 373         }
 374         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 375         {
 376                 if(teamplay)
 377                 {
 378                         string s = Static_Team_ColorName_Lower(player.team);
 379                         if (s != "neutral")
 380                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 381                 }
 382
 383                 if(!defaultskin)
 384                         defaultskin = autocvar_sv_defaultplayerskin;
 385         }
 386
 387         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 388         defaultmodel = ret_string;
 389         defaultskin = ret_int;
 390
 391         bool chmdl = false;
 392         int oldskin;
 393         if(defaultmodel != "")
 394         {
 395                 if (defaultmodel != player.model)
 396                 {
 397                         vector m1 = player.mins;
 398                         vector m2 = player.maxs;
 399                         setplayermodel (player, defaultmodel);
 400                         setsize (player, m1, m2);
 401                         chmdl = true;
 402                 }
 403
 404                 oldskin = player.skin;
 405                 player.skin = defaultskin;
 406         } else {
 407                 if (player.playermodel != player.model || player.playermodel == "")
 408                 {
 409                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 410                         vector m1 = player.mins;
 411                         vector m2 = player.maxs;
 412                         setplayermodel (player, player.playermodel);
 413                         setsize (player, m1, m2);
 414                         chmdl = true;
 415                 }
 416
 417                 if(!autocvar_sv_defaultcharacterskin)
 418                 {
 419                         oldskin = player.skin;
 420                         player.skin = stof(player.playerskin);
 421                 }
 422                 else
 423                 {
 424                         oldskin = player.skin;
 425                         player.skin = defaultskin;
 426                 }
 427         }
 428
 429         if(chmdl || oldskin != player.skin) // model or skin has changed
 430         {
 431                 player.species = player_getspecies(player); // update species
 432                 if(!autocvar_g_debug_globalsounds)
 433                         UpdatePlayerSounds(player); // update skin sounds
 434         }
 435
 436         if(!teamplay)
 437                 if(strlen(autocvar_sv_defaultplayercolors))
 438                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 439                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 440 }
 441
 442
 443 /** Called when a client spawns in the server */
 444 void PutClientInServer()
 445 {
 446         SELFPARAM();
 447         if (IS_BOT_CLIENT(this)) {
 448                 TRANSMUTE(Player, this);
 449         } else if (IS_REAL_CLIENT(this)) {
 450                 msg_entity = this;
 451                 WriteByte(MSG_ONE, SVC_SETVIEW);
 452                 WriteEntity(MSG_ONE, this);
 453         }
 454         if (gameover) {
 455                 TRANSMUTE(Observer, this);
 456         }
 457
 458         SetSpectatee(this, NULL);
 459
 460         // reset player keys
 461         this.itemkeys = 0;
 462
 463         MUTATOR_CALLHOOK(PutClientInServer, this);
 464
 465         if (IS_OBSERVER(this)) {
 466                 PutObserverInServer();
 467         } else if (IS_PLAYER(this)) {
 468                 PlayerState_attach(this);
 469                 accuracy_resend(this);
 470
 471                 if (this.team < 0)
 472                         JoinBestTeam(this, false, true);
 473
 474                 entity spot = SelectSpawnPoint(this, false);
 475                 if (!spot) {
 476                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 477                         return; // spawn failed
 478                 }
 479
 480                 TRANSMUTE(Player, this);
 481                 this.wasplayer = true;
 482                 this.iscreature = true;
 483                 this.teleportable = TELEPORT_NORMAL;
 484                 this.damagedbycontents = true;
 485                 this.movetype = MOVETYPE_WALK;
 486                 this.solid = SOLID_SLIDEBOX;
 487                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 488                 if (autocvar_g_playerclip_collisions)
 489                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 490                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 491                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 492                 this.frags = FRAGS_PLAYER;
 493                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 494                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 495                 if (autocvar__notarget)
 496                         this.flags |= FL_NOTARGET;
 497                 this.takedamage = DAMAGE_AIM;
 498                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 499                 this.dmg = 2; // WTF
 500
 501                 if (warmup_stage) {
 502                         this.ammo_shells = warmup_start_ammo_shells;
 503                         this.ammo_nails = warmup_start_ammo_nails;
 504                         this.ammo_rockets = warmup_start_ammo_rockets;
 505                         this.ammo_cells = warmup_start_ammo_cells;
 506                         this.ammo_plasma = warmup_start_ammo_plasma;
 507                         this.ammo_fuel = warmup_start_ammo_fuel;
 508                         this.health = warmup_start_health;
 509                         this.armorvalue = warmup_start_armorvalue;
 510                         this.weapons = WARMUP_START_WEAPONS;
 511                 } else {
 512                         this.ammo_shells = start_ammo_shells;
 513                         this.ammo_nails = start_ammo_nails;
 514                         this.ammo_rockets = start_ammo_rockets;
 515                         this.ammo_cells = start_ammo_cells;
 516                         this.ammo_plasma = start_ammo_plasma;
 517                         this.ammo_fuel = start_ammo_fuel;
 518                         this.health = start_health;
 519                         this.armorvalue = start_armorvalue;
 520                         this.weapons = start_weapons;
 521                 }
 522
 523                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 524
 525                 this.items = start_items;
 526
 527                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 528                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 529                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 530                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 531                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 532                 // extend the pause of rotting if client was reset at the beginning of the countdown
 533                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 534                         float f = game_starttime - time;
 535                         this.spawnshieldtime += f;
 536                         this.pauserotarmor_finished += f;
 537                         this.pauserothealth_finished += f;
 538                         this.pauseregen_finished += f;
 539                 }
 540                 this.damageforcescale = 2;
 541                 this.death_time = 0;
 542                 this.respawn_flags = 0;
 543                 this.respawn_time = 0;
 544                 this.stat_respawn_time = 0;
 545                 this.scale = autocvar_sv_player_scale;
 546                 this.fade_time = 0;
 547                 this.pain_frame = 0;
 548                 this.pain_finished = 0;
 549                 this.pushltime = 0;
 550                 this.think = func_null; // players have no think function
 551                 this.nextthink = 0;
 552                 this.dmg_team = 0;
 553                 this.ballistics_density = autocvar_g_ballistics_density_player;
 554
 555                 this.deadflag = DEAD_NO;
 556
 557                 this.angles = spot.angles;
 558                 this.angles_z = 0; // never spawn tilted even if the spot says to
 559                 if (IS_BOT_CLIENT(this))
 560                         this.v_angle = this.angles;
 561                 this.fixangle = true; // turn this way immediately
 562                 this.oldvelocity = this.velocity = '0 0 0';
 563                 this.avelocity = '0 0 0';
 564                 this.punchangle = '0 0 0';
 565                 this.punchvector = '0 0 0';
 566
 567                 this.strength_finished = 0;
 568                 this.invincible_finished = 0;
 569                 this.fire_endtime = -1;
 570                 this.revival_time = 0;
 571                 this.air_finished = time + 12;
 572
 573                 entity spawnevent = new_pure(spawnevent);
 574                 spawnevent.owner = this;
 575                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 576
 577                 // Cut off any still running player sounds.
 578                 stopsound(this, CH_PLAYER_SINGLE);
 579
 580                 this.model = "";
 581                 FixPlayermodel(this);
 582                 this.drawonlytoclient = NULL;
 583
 584                 this.crouch = false;
 585                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 586                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 587                 this.spawnorigin = spot.origin;
 588                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 589                 // don't reset back to last position, even if new position is stuck in solid
 590                 this.oldorigin = this.origin;
 591                 this.prevorigin = this.origin;
 592                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 593                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 594                 this.hud = HUD_NORMAL;
 595
 596                 this.event_damage = PlayerDamage;
 597
 598                 this.bot_attack = true;
 599                 this.monster_attack = true;
 600
 601                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 602
 603                 if (this.killcount == FRAGS_SPECTATOR) {
 604                         PlayerScore_Clear(this);
 605                         this.killcount = 0;
 606                 }
 607
 608                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 609                 {
 610                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 611                 }
 612                 this.alpha = default_player_alpha;
 613                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 614                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 615
 616                 this.speedrunning = false;
 617
 618                 target_voicescript_clear(this);
 619
 620                 // reset fields the weapons may use
 621                 FOREACH(Weapons, true, LAMBDA(
 622                         it.wr_resetplayer(it);
 623                         // reload all reloadable weapons
 624                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 625                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 626                         }
 627                 ));
 628
 629                 {
 630                         string s = spot.target;
 631                         spot.target = string_null;
 632                         SUB_UseTargets(spot, this, NULL);
 633                         spot.target = s;
 634                 }
 635
 636                 Unfreeze(this);
 637
 638                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 639
 640                 if (autocvar_spawn_debug)
 641                 {
 642                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 643                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 644                 }
 645
 646                 PS(this).m_switchweapon = w_getbestweapon(this);
 647                 this.cnt = -1; // W_LastWeapon will not complain
 648                 PS(this).m_weapon = WEP_Null;
 649                 this.weaponname = "";
 650                 PS(this).m_switchingweapon = WEP_Null;
 651
 652                 if (!warmup_stage && !this.alivetime)
 653                         this.alivetime = time;
 654
 655                 antilag_clear(this, CS(this));
 656         }
 657 }
 658
 659 void ClientInit_misc(entity this);
 660
 661 .float ebouncefactor, ebouncestop; // electro's values
 662 // TODO do we need all these fields, or should we stop autodetecting runtime
 663 // changes and just have a console command to update this?
 664 bool ClientInit_SendEntity(entity this, entity to, int sf)
 665 {
 666         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 667         return = true;
 668         msg_entity = to;
 669         // MSG_INIT replacement
 670         // TODO: make easier to use
 671         Registry_send_all();
 672         W_PROP_reload(MSG_ONE, to);
 673         ClientInit_misc(this);
 674         MUTATOR_CALLHOOK(Ent_Init);
 675 }
 676 void ClientInit_misc(entity this)
 677 {
 678         int channel = MSG_ONE;
 679         WriteHeader(channel, ENT_CLIENT_INIT);
 680         WriteByte(channel, g_nexball_meter_period * 32);
 681         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 682         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 683         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 684         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 685         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 686         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 687         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 688         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 689
 690         if(sv_foginterval && world.fog != "")
 691                 WriteString(channel, world.fog);
 692         else
 693                 WriteString(channel, "");
 694         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 695         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 696         WriteCoord(channel, autocvar_g_trueaim_minrange);
 697 }
 698
 699 void ClientInit_CheckUpdate()
 700 {SELFPARAM();
 701         this.nextthink = time;
 702         if(this.count != autocvar_g_balance_armor_blockpercent)
 703         {
 704                 this.count = autocvar_g_balance_armor_blockpercent;
 705                 this.SendFlags |= 1;
 706         }
 707 }
 708
 709 void ClientInit_Spawn()
 710 {SELFPARAM();
 711
 712         entity e = new_pure(clientinit);
 713         e.think = ClientInit_CheckUpdate;
 714         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 715
 716         WITHSELF(e, ClientInit_CheckUpdate());
 717 }
 718
 719 /*
 720 =============
 721 SetNewParms
 722 =============
 723 */
 724 void SetNewParms ()
 725 {
 726         // initialize parms for a new player
 727         parm1 = -(86400 * 366);
 728
 729         MUTATOR_CALLHOOK(SetNewParms);
 730 }
 731
 732 /*
 733 =============
 734 SetChangeParms
 735 =============
 736 */
 737 void SetChangeParms ()
 738 {SELFPARAM();
 739         // save parms for level change
 740         parm1 = this.parm_idlesince - time;
 741
 742         MUTATOR_CALLHOOK(SetChangeParms);
 743 }
 744
 745 /*
 746 =============
 747 DecodeLevelParms
 748 =============
 749 */
 750 void DecodeLevelParms(entity this)
 751 {
 752         // load parms
 753         this.parm_idlesince = parm1;
 754         if (this.parm_idlesince == -(86400 * 366))
 755                 this.parm_idlesince = time;
 756
 757         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 758         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 759
 760         MUTATOR_CALLHOOK(DecodeLevelParms);
 761 }
 762
 763 /*
 764 =============
 765 ClientKill
 766
 767 Called when a client types 'kill' in the console
 768 =============
 769 */
 770
 771 .float clientkill_nexttime;
 772 void ClientKill_Now_TeamChange(entity this)
 773 {
 774         if(this.killindicator_teamchange == -1)
 775         {
 776                 JoinBestTeam( this, false, true );
 777         }
 778         else if(this.killindicator_teamchange == -2)
 779         {
 780                 if(blockSpectators)
 781                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 782                 WITHSELF(this, PutObserverInServer());
 783         }
 784         else
 785                 WITHSELF(this, SV_ChangeTeam(this.killindicator_teamchange - 1));
 786         this.killindicator_teamchange = 0;
 787 }
 788
 789 void ClientKill_Now()
 790 {SELFPARAM();
 791         if(this.vehicle)
 792         {
 793             vehicles_exit(VHEF_RELEASE);
 794             if(!this.killindicator_teamchange)
 795             {
 796             this.vehicle_health = -1;
 797             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 798             }
 799         }
 800
 801         if(this.killindicator && !wasfreed(this.killindicator))
 802                 remove(this.killindicator);
 803
 804         this.killindicator = world;
 805
 806         if(this.killindicator_teamchange)
 807                 ClientKill_Now_TeamChange(this);
 808
 809         if(IS_PLAYER(this))
 810                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 811
 812         // now I am sure the player IS dead
 813 }
 814 void KillIndicator_Think()
 815 {SELFPARAM();
 816         if (gameover)
 817         {
 818                 this.owner.killindicator = world;
 819                 remove(this);
 820                 return;
 821         }
 822
 823         if (this.owner.alpha < 0 && !this.owner.vehicle)
 824         {
 825                 this.owner.killindicator = world;
 826                 remove(this);
 827                 return;
 828         }
 829
 830         if(this.cnt <= 0)
 831         {
 832                 WITHSELF(this.owner, ClientKill_Now());
 833                 return;
 834         }
 835     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 836     {
 837         this.nextthink = time + 1;
 838         this.cnt -= 1;
 839     }
 840         else
 841         {
 842                 if(this.cnt <= 10)
 843                         setmodel(this, MDL_NUM(this.cnt));
 844                 if(IS_REAL_CLIENT(this.owner))
 845                 {
 846                         if(this.cnt <= 10)
 847                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 848                 }
 849                 this.nextthink = time + 1;
 850                 this.cnt -= 1;
 851         }
 852 }
 853
 854 float clientkilltime;
 855 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 856 {SELFPARAM();
 857         float killtime;
 858         float starttime;
 859         entity e;
 860
 861         if (gameover)
 862                 return;
 863
 864         killtime = autocvar_g_balance_kill_delay;
 865
 866         if(g_race_qualifying || g_cts)
 867                 killtime = 0;
 868
 869     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 870         return;
 871
 872         this.killindicator_teamchange = targetteam;
 873
 874     if(!this.killindicator)
 875         {
 876                 if(!IS_DEAD(this))
 877                 {
 878                         killtime = max(killtime, this.clientkill_nexttime - time);
 879                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 880                 }
 881
 882                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 883                 {
 884                         ClientKill_Now();
 885                 }
 886                 else
 887                 {
 888                         starttime = max(time, clientkilltime);
 889
 890                         this.killindicator = spawn();
 891                         this.killindicator.owner = this;
 892                         this.killindicator.scale = 0.5;
 893                         setattachment(this.killindicator, this, "");
 894                         setorigin(this.killindicator, '0 0 52');
 895                         this.killindicator.think = KillIndicator_Think;
 896                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 897                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 898                         this.killindicator.cnt = ceil(killtime);
 899                         this.killindicator.count = bound(0, ceil(killtime), 10);
 900                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 901
 902                         for(e = world; (e = find(e, classname, "body")) != world; )
 903                         {
 904                                 if(e.enemy != this)
 905                                         continue;
 906                                 e.killindicator = spawn();
 907                                 e.killindicator.owner = e;
 908                                 e.killindicator.scale = 0.5;
 909                                 setattachment(e.killindicator, e, "");
 910                                 setorigin(e.killindicator, '0 0 52');
 911                                 e.killindicator.think = KillIndicator_Think;
 912                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 913                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 914                                 e.killindicator.cnt = ceil(killtime);
 915                         }
 916                         this.lip = 0;
 917                 }
 918         }
 919         if(this.killindicator)
 920         {
 921                 if(targetteam == 0) // just die
 922                 {
 923                         this.killindicator.colormod = '0 0 0';
 924                         if(IS_REAL_CLIENT(this))
 925                         if(this.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 927                 }
 928                 else if(targetteam == -1) // auto
 929                 {
 930                         this.killindicator.colormod = '0 1 0';
 931                         if(IS_REAL_CLIENT(this))
 932                         if(this.killindicator.cnt > 0)
 933                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 934                 }
 935                 else if(targetteam == -2) // spectate
 936                 {
 937                         this.killindicator.colormod = '0.5 0.5 0.5';
 938                         if(IS_REAL_CLIENT(this))
 939                         if(this.killindicator.cnt > 0)
 940                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 941                 }
 942                 else
 943                 {
 944                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 945                         if(IS_REAL_CLIENT(this))
 946                         if(this.killindicator.cnt > 0)
 947                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 948                 }
 949         }
 950
 951 }
 952
 953 void ClientKill ()
 954 {SELFPARAM();
 955         if(gameover) return;
 956         if(this.player_blocked) return;
 957         if(STAT(FROZEN, this)) return;
 958
 959         ClientKill_TeamChange(0);
 960 }
 961
 962 void FixClientCvars(entity e)
 963 {
 964         // send prediction settings to the client
 965         stuffcmd(e, "\nin_bindmap 0 0\n");
 966         if(autocvar_g_antilag == 3) // client side hitscan
 967                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 968         if(autocvar_sv_gentle)
 969                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 970
 971         MUTATOR_CALLHOOK(FixClientCvars, e);
 972 }
 973
 974 float PlayerInIDList(entity p, string idlist)
 975 {
 976         float n, i;
 977         string s;
 978
 979         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 980         if (!p.crypto_idfp)
 981                 return 0;
 982
 983         // this function allows abbreviated player IDs too!
 984         n = tokenize_console(idlist);
 985         for(i = 0; i < n; ++i)
 986         {
 987                 s = argv(i);
 988                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 989                         return 1;
 990         }
 991
 992         return 0;
 993 }
 994
 995 #ifdef DP_EXT_PRECONNECT
 996 /*
 997 =============
 998 ClientPreConnect
 999
1000 Called once (not at each match start) when a client begins a connection to the server
1001 =============
1002 */
1003 void ClientPreConnect ()
1004 {SELFPARAM();
1005         if(autocvar_sv_eventlog)
1006         {
1007                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1008                         this.playerid,
1009                         etof(this),
1010                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1011                 ));
1012         }
1013 }
1014 #endif
1015
1016 /**
1017 =============
1018 ClientConnect
1019
1020 Called when a client connects to the server
1021 =============
1022 */
1023 void ClientConnect()
1024 {
1025         SELFPARAM();
1026         if (Ban_MaybeEnforceBanOnce(this)) return;
1027         assert(!IS_CLIENT(this), return);
1028         this.flags |= FL_CLIENT;
1029         assert(player_count >= 0, player_count = 0);
1030
1031 #ifdef WATERMARK
1032         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1033 #endif
1034         this.version_nagtime = time + 10 + random() * 10;
1035         TRANSMUTE(Client, this);
1036
1037         // identify the right forced team
1038         if (autocvar_g_campaign)
1039         {
1040                 if (IS_REAL_CLIENT(this)) // only players, not bots
1041                 {
1042                         switch (autocvar_g_campaign_forceteam)
1043                         {
1044                                 case 1: this.team_forced = NUM_TEAM_1; break;
1045                                 case 2: this.team_forced = NUM_TEAM_2; break;
1046                                 case 3: this.team_forced = NUM_TEAM_3; break;
1047                                 case 4: this.team_forced = NUM_TEAM_4; break;
1048                                 default: this.team_forced = 0;
1049                         }
1050                 }
1051         }
1052         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1053         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1054         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1055         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1056         else switch (autocvar_g_forced_team_otherwise)
1057         {
1058                 default: this.team_forced = 0; break;
1059                 case "red": this.team_forced = NUM_TEAM_1; break;
1060                 case "blue": this.team_forced = NUM_TEAM_2; break;
1061                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1062                 case "pink": this.team_forced = NUM_TEAM_4; break;
1063                 case "spectate":
1064                 case "spectator":
1065                         this.team_forced = -1;
1066                         break;
1067         }
1068         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1069
1070     {
1071         int id = this.playerid;
1072         this.playerid = 0; // silent
1073             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1074             this.playerid = id;
1075     }
1076
1077         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1078                 TRANSMUTE(Observer, this);
1079         } else {
1080                 if (!teamplay || autocvar_g_balance_teams) {
1081                         TRANSMUTE(Player, this);
1082                         campaign_bots_may_start = true;
1083                 } else {
1084                         TRANSMUTE(Observer, this); // do it anyway
1085                 }
1086         }
1087
1088         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1089
1090         // always track bots, don't ask for cl_allow_uidtracking
1091     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1092
1093         if (autocvar_sv_eventlog)
1094                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1095
1096         LogTeamchange(this.playerid, this.team, 1);
1097
1098         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1099
1100         this.netname_previous = strzone(this.netname);
1101
1102         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1103
1104         stuffcmd(this, clientstuff, "\n");
1105         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1106
1107         FixClientCvars(this);
1108
1109         // get version info from player
1110         stuffcmd(this, "cmd clientversion $gameversion\n");
1111
1112         // notify about available teams
1113         if (teamplay)
1114         {
1115                 CheckAllowedTeams(this);
1116                 int t = 0;
1117                 if (c1 >= 0) t |= BIT(0);
1118                 if (c2 >= 0) t |= BIT(1);
1119                 if (c3 >= 0) t |= BIT(2);
1120                 if (c4 >= 0) t |= BIT(3);
1121                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1122         }
1123         else
1124         {
1125                 stuffcmd(this, "set _teams_available 0\n");
1126         }
1127
1128         bot_relinkplayerlist();
1129
1130         this.spectatortime = time;
1131         if (blockSpectators)
1132         {
1133                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1134         }
1135
1136         this.jointime = time;
1137         this.allowed_timeouts = autocvar_sv_timeout_number;
1138
1139         if (IS_REAL_CLIENT(this))
1140         {
1141                 if (!autocvar_g_campaign)
1142                 {
1143                         this.motd_actived_time = -1;
1144                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1145                 }
1146
1147                 if (g_weaponarena_weapons == WEPSET(TUBA))
1148                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1149         }
1150
1151         if (!sv_foginterval && world.fog != "")
1152                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1153
1154         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)))
1155                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1156                         send_CSQC_teamnagger();
1157
1158         CSQCMODEL_AUTOINIT(this);
1159
1160         this.model_randomizer = random();
1161
1162         if (IS_REAL_CLIENT(this))
1163                 sv_notice_join(this);
1164
1165         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1166                 WITHSELF(it, it.init_for_player(it));
1167         });
1168
1169         MUTATOR_CALLHOOK(ClientConnect, this);
1170 }
1171 /*
1172 =============
1173 ClientDisconnect
1174
1175 Called when a client disconnects from the server
1176 =============
1177 */
1178 .entity chatbubbleentity;
1179 void ReadyCount();
1180 void ClientDisconnect()
1181 {
1182         SELFPARAM();
1183         assert(IS_CLIENT(this), return);
1184
1185         PlayerStats_GameReport_FinalizePlayer(this);
1186         if (this.vehicle) vehicles_exit(VHEF_RELEASE);
1187         if (this.active_minigame) part_minigame(this);
1188         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1189
1190         if (autocvar_sv_eventlog)
1191                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1192
1193         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1194
1195     MUTATOR_CALLHOOK(ClientDisconnect);
1196
1197         ClientState_detach(this);
1198
1199         Portal_ClearAll(this);
1200
1201         Unfreeze(this);
1202
1203         RemoveGrapplingHook(this);
1204
1205         // Here, everything has been done that requires this player to be a client.
1206
1207         this.flags &= ~FL_CLIENT;
1208
1209         if (this.chatbubbleentity) remove(this.chatbubbleentity);
1210         if (this.killindicator) remove(this.killindicator);
1211
1212         WaypointSprite_PlayerGone();
1213
1214         bot_relinkplayerlist();
1215
1216         if (this.netname_previous) strunzone(this.netname_previous);
1217         if (this.clientstatus) strunzone(this.clientstatus);
1218         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1219         if (this.personal) remove(this.personal);
1220
1221         this.playerid = 0;
1222         ReadyCount();
1223         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1224 }
1225
1226 void ChatBubbleThink()
1227 {SELFPARAM();
1228         this.nextthink = time;
1229         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1230         {
1231                 if(this.owner) // but why can that ever be world?
1232                         this.owner.chatbubbleentity = world;
1233                 remove(this);
1234                 return;
1235         }
1236
1237         this.mdl = "";
1238
1239         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1240         {
1241                 if ( this.owner.active_minigame )
1242                         this.mdl = "models/sprites/minigame_busy.iqm";
1243                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1244                         this.mdl = "models/misc/chatbubble.spr";
1245         }
1246
1247         if ( this.model != this.mdl )
1248                 _setmodel(this, this.mdl);
1249
1250 }
1251
1252 void UpdateChatBubble()
1253 {SELFPARAM();
1254         if (this.alpha < 0)
1255                 return;
1256         // spawn a chatbubble entity if needed
1257         if (!this.chatbubbleentity)
1258         {
1259                 this.chatbubbleentity = new(chatbubbleentity);
1260                 this.chatbubbleentity.owner = this;
1261                 this.chatbubbleentity.exteriormodeltoclient = this;
1262                 this.chatbubbleentity.think = ChatBubbleThink;
1263                 this.chatbubbleentity.nextthink = time;
1264                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1265                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1266                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1267                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1268                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1269                 //this.chatbubbleentity.model = "";
1270                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1271         }
1272 }
1273
1274
1275 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1276 // added to the model skins
1277 /*void UpdateColorModHack()
1278 {
1279         float c;
1280         c = this.clientcolors & 15;
1281         // LordHavoc: only bothering to support white, green, red, yellow, blue
1282              if (!teamplay) this.colormod = '0 0 0';
1283         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1284         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1285         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1286         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1287         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1288         else this.colormod = '1 1 1';
1289 }*/
1290
1291 void respawn()
1292 {SELFPARAM();
1293         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1294         {
1295                 this.solid = SOLID_NOT;
1296                 this.takedamage = DAMAGE_NO;
1297                 this.movetype = MOVETYPE_FLY;
1298                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1299                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1300                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1301                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1302                 if(autocvar_g_respawn_ghosts_maxtime)
1303                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1304         }
1305
1306         CopyBody(this, 1);
1307
1308         this.effects |= EF_NODRAW; // prevent another CopyBody
1309         PutClientInServer();
1310 }
1311
1312 void play_countdown(float finished, Sound samp)
1313 {SELFPARAM();
1314     TC(Sound, samp);
1315         if(IS_REAL_CLIENT(this))
1316                 if(floor(finished - time - frametime) != floor(finished - time))
1317                         if(finished - time < 6)
1318                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1319 }
1320
1321 void player_powerups ()
1322 {SELFPARAM();
1323         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1324         int items_prev = this.items;
1325
1326         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1327                 this.modelflags |= MF_ROCKET;
1328         else
1329                 this.modelflags &= ~MF_ROCKET;
1330
1331         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1332
1333         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1334                 return;
1335
1336         Fire_ApplyDamage(this);
1337         Fire_ApplyEffect(this);
1338
1339         if (!g_instagib)
1340         {
1341                 if (this.items & ITEM_Strength.m_itemid)
1342                 {
1343                         play_countdown(this.strength_finished, SND_POWEROFF);
1344                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1345                         if (time > this.strength_finished)
1346                         {
1347                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1348                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1349                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1350                         }
1351                 }
1352                 else
1353                 {
1354                         if (time < this.strength_finished)
1355                         {
1356                                 this.items = this.items | ITEM_Strength.m_itemid;
1357                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1358                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1359                         }
1360                 }
1361                 if (this.items & ITEM_Shield.m_itemid)
1362                 {
1363                         play_countdown(this.invincible_finished, SND_POWEROFF);
1364                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1365                         if (time > this.invincible_finished)
1366                         {
1367                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1368                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1369                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1370                         }
1371                 }
1372                 else
1373                 {
1374                         if (time < this.invincible_finished)
1375                         {
1376                                 this.items = this.items | ITEM_Shield.m_itemid;
1377                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1378                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1379                         }
1380                 }
1381                 if (this.items & IT_SUPERWEAPON)
1382                 {
1383                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1384                         {
1385                                 this.superweapons_finished = 0;
1386                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1387                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1388                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1389                         }
1390                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1391                         {
1392                                 // don't let them run out
1393                         }
1394                         else
1395                         {
1396                                 play_countdown(this.superweapons_finished, SND_POWEROFF);
1397                                 if (time > this.superweapons_finished)
1398                                 {
1399                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1400                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1401                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1402                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1403                                 }
1404                         }
1405                 }
1406                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1407                 {
1408                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1409                         {
1410                                 this.items = this.items | IT_SUPERWEAPON;
1411                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1412                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1413                         }
1414                         else
1415                         {
1416                                 this.superweapons_finished = 0;
1417                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1418                         }
1419                 }
1420                 else
1421                 {
1422                         this.superweapons_finished = 0;
1423                 }
1424         }
1425
1426         if(autocvar_g_nodepthtestplayers)
1427                 this.effects = this.effects | EF_NODEPTHTEST;
1428
1429         if(autocvar_g_fullbrightplayers)
1430                 this.effects = this.effects | EF_FULLBRIGHT;
1431
1432         if (time >= game_starttime)
1433         if (time < this.spawnshieldtime)
1434                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1435
1436         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1437 }
1438
1439 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1440 {
1441         if(current > stable)
1442                 return current;
1443         else if(current > stable - 0.25) // when close enough, "snap"
1444                 return stable;
1445         else
1446                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1447 }
1448
1449 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1450 {
1451         if(current < stable)
1452                 return current;
1453         else if(current < stable + 0.25) // when close enough, "snap"
1454                 return stable;
1455         else
1456                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1457 }
1458
1459 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1460 {
1461         if(current > rotstable)
1462         {
1463                 if(rotframetime > 0)
1464                 {
1465                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1466                         current = max(rotstable, current - rotlinear * rotframetime);
1467                 }
1468         }
1469         else if(current < regenstable)
1470         {
1471                 if(regenframetime > 0)
1472                 {
1473                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1474                         current = min(regenstable, current + regenlinear * regenframetime);
1475                 }
1476         }
1477
1478         if(current > limit)
1479                 current = limit;
1480
1481         return current;
1482 }
1483
1484 void player_regen ()
1485 {SELFPARAM();
1486         float max_mod, regen_mod, rot_mod, limit_mod;
1487         max_mod = regen_mod = rot_mod = limit_mod = 1;
1488         regen_mod_max = max_mod;
1489         regen_mod_regen = regen_mod;
1490         regen_mod_rot = rot_mod;
1491         regen_mod_limit = limit_mod;
1492
1493         regen_health = autocvar_g_balance_health_regen;
1494         regen_health_linear = autocvar_g_balance_health_regenlinear;
1495         regen_health_rot = autocvar_g_balance_health_rot;
1496         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1497         regen_health_stable = autocvar_g_balance_health_regenstable;
1498         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1499         if(!MUTATOR_CALLHOOK(PlayerRegen))
1500         if(!STAT(FROZEN, this))
1501         {
1502                 float mina, maxa, limith, limita;
1503                 maxa = autocvar_g_balance_armor_rotstable;
1504                 mina = autocvar_g_balance_armor_regenstable;
1505                 limith = autocvar_g_balance_health_limit;
1506                 limita = autocvar_g_balance_armor_limit;
1507
1508                 max_mod = regen_mod_max;
1509                 regen_mod = regen_mod_regen;
1510                 rot_mod = regen_mod_rot;
1511                 limit_mod = regen_mod_limit;
1512
1513                 regen_health_rotstable = regen_health_rotstable * max_mod;
1514                 regen_health_stable = regen_health_stable * max_mod;
1515                 limith = limith * limit_mod;
1516                 limita = limita * limit_mod;
1517
1518                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1519                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1520         }
1521
1522         // if player rotted to death...  die!
1523         // check this outside above checks, as player may still be able to rot to death
1524         if(this.health < 1)
1525         {
1526                 if(this.vehicle)
1527                         vehicles_exit(VHEF_RELEASE);
1528                 if(this.event_damage)
1529                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1530         }
1531
1532         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1533         {
1534                 float minf, maxf, limitf;
1535
1536                 maxf = autocvar_g_balance_fuel_rotstable;
1537                 minf = autocvar_g_balance_fuel_regenstable;
1538                 limitf = autocvar_g_balance_fuel_limit;
1539
1540                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1541         }
1542 }
1543
1544 bool zoomstate_set;
1545 void SetZoomState(float z)
1546 {SELFPARAM();
1547         if(z != this.zoomstate)
1548         {
1549                 this.zoomstate = z;
1550                 ClientData_Touch(this);
1551         }
1552         zoomstate_set = true;
1553 }
1554
1555 void GetPressedKeys()
1556 {
1557         SELFPARAM();
1558         MUTATOR_CALLHOOK(GetPressedKeys);
1559         int keys = this.pressedkeys;
1560         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1561         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1562         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1563         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1564
1565         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1566         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1567         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1568         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1569         this.pressedkeys = keys;
1570 }
1571
1572 /*
1573 ======================
1574 spectate mode routines
1575 ======================
1576 */
1577
1578 void SpectateCopy(entity this, entity spectatee)
1579 {
1580     TC(Client, this); TC(Client, spectatee);
1581
1582         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1583         PS(this) = PS(spectatee);
1584         this.armortype = spectatee.armortype;
1585         this.armorvalue = spectatee.armorvalue;
1586         this.ammo_cells = spectatee.ammo_cells;
1587         this.ammo_plasma = spectatee.ammo_plasma;
1588         this.ammo_shells = spectatee.ammo_shells;
1589         this.ammo_nails = spectatee.ammo_nails;
1590         this.ammo_rockets = spectatee.ammo_rockets;
1591         this.ammo_fuel = spectatee.ammo_fuel;
1592         this.clip_load = spectatee.clip_load;
1593         this.clip_size = spectatee.clip_size;
1594         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1595         this.health = spectatee.health;
1596         this.impulse = 0;
1597         this.items = spectatee.items;
1598         this.last_pickup = spectatee.last_pickup;
1599         this.hit_time = spectatee.hit_time;
1600         this.strength_finished = spectatee.strength_finished;
1601         this.invincible_finished = spectatee.invincible_finished;
1602         this.pressedkeys = spectatee.pressedkeys;
1603         this.weapons = spectatee.weapons;
1604         this.vortex_charge = spectatee.vortex_charge;
1605         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1606         this.hagar_load = spectatee.hagar_load;
1607         this.arc_heat_percent = spectatee.arc_heat_percent;
1608         this.minelayer_mines = spectatee.minelayer_mines;
1609         this.punchangle = spectatee.punchangle;
1610         this.view_ofs = spectatee.view_ofs;
1611         this.velocity = spectatee.velocity;
1612         this.dmg_take = spectatee.dmg_take;
1613         this.dmg_save = spectatee.dmg_save;
1614         this.dmg_inflictor = spectatee.dmg_inflictor;
1615         this.v_angle = spectatee.v_angle;
1616         this.angles = spectatee.v_angle;
1617         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1618         this.revive_progress = spectatee.revive_progress;
1619         if(!PHYS_INPUT_BUTTON_USE(this))
1620                 this.fixangle = true;
1621         setorigin(this, spectatee.origin);
1622         setsize(this, spectatee.mins, spectatee.maxs);
1623         SetZoomState(spectatee.zoomstate);
1624
1625     anticheat_spectatecopy(this, spectatee);
1626         this.hud = spectatee.hud;
1627         if(spectatee.vehicle)
1628     {
1629         this.fixangle = false;
1630         //this.velocity = spectatee.vehicle.velocity;
1631         this.vehicle_health = spectatee.vehicle_health;
1632         this.vehicle_shield = spectatee.vehicle_shield;
1633         this.vehicle_energy = spectatee.vehicle_energy;
1634         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1635         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1636         this.vehicle_reload1 = spectatee.vehicle_reload1;
1637         this.vehicle_reload2 = spectatee.vehicle_reload2;
1638
1639         msg_entity = this;
1640
1641         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1642             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1643             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1644             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1645
1646         //WriteByte (MSG_ONE, SVC_SETVIEW);
1647         //    WriteEntity(MSG_ONE, this);
1648         //makevectors(spectatee.v_angle);
1649         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1650     }
1651 }
1652
1653 bool SpectateUpdate()
1654 {SELFPARAM();
1655         if(!this.enemy)
1656             return false;
1657
1658         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1659         {
1660                 SetSpectatee(this, NULL);
1661                 return false;
1662         }
1663
1664         SpectateCopy(this, this.enemy);
1665
1666         return true;
1667 }
1668
1669 bool SpectateSet()
1670 {SELFPARAM();
1671         if(!IS_PLAYER(this.enemy))
1672                 return false;
1673
1674         msg_entity = this;
1675         WriteByte(MSG_ONE, SVC_SETVIEW);
1676         WriteEntity(MSG_ONE, this.enemy);
1677         this.movetype = MOVETYPE_NONE;
1678         accuracy_resend(this);
1679
1680         if(!SpectateUpdate())
1681                 PutObserverInServer();
1682
1683         return true;
1684 }
1685
1686 void SetSpectatee(entity player, entity spectatee)
1687 {
1688         entity old_spectatee = player.enemy;
1689
1690         player.enemy = spectatee;
1691
1692         // WEAPONTODO
1693         // these are required to fix the spectator bug with arc
1694         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1695         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1696 }
1697
1698 bool Spectate(entity pl)
1699 {SELFPARAM();
1700         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1701                 return false;
1702         pl = spec_player;
1703
1704         SetSpectatee(this, pl);
1705         return SpectateSet();
1706 }
1707
1708 bool SpectateNext()
1709 {SELFPARAM();
1710         other = find(this.enemy, classname, STR_PLAYER);
1711
1712         if (MUTATOR_CALLHOOK(SpectateNext, this, other))
1713                 other = spec_player;
1714         else if (!other)
1715                 other = find(other, classname, STR_PLAYER);
1716
1717         if(other) { SetSpectatee(this, other); }
1718
1719         return SpectateSet();
1720 }
1721
1722 bool SpectatePrev()
1723 {SELFPARAM();
1724         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1725         other = findchain(classname, STR_PLAYER);
1726         if (!other) // no player
1727                 return false;
1728
1729         entity first = other;
1730         // skip players until current spectated player
1731         if(this.enemy)
1732         while(other && other != this.enemy)
1733                 other = other.chain;
1734
1735         switch (MUTATOR_CALLHOOK(SpectatePrev, this, other, first))
1736         {
1737                 case MUT_SPECPREV_FOUND:
1738                     other = spec_player;
1739                     break;
1740                 case MUT_SPECPREV_RETURN:
1741                     other = spec_player;
1742                     return true;
1743                 case MUT_SPECPREV_CONTINUE:
1744                 default:
1745                 {
1746                         if(other.chain)
1747                                 other = other.chain;
1748                         else
1749                                 other = first;
1750                         break;
1751                 }
1752         }
1753
1754         SetSpectatee(this, other);
1755         return SpectateSet();
1756 }
1757
1758 /*
1759 =============
1760 ShowRespawnCountdown()
1761
1762 Update a respawn countdown display.
1763 =============
1764 */
1765 void ShowRespawnCountdown()
1766 {SELFPARAM();
1767         float number;
1768         if(!IS_DEAD(this)) // just respawned?
1769                 return;
1770         else
1771         {
1772                 number = ceil(this.respawn_time - time);
1773                 if(number <= 0)
1774                         return;
1775                 if(number <= this.respawn_countdown)
1776                 {
1777                         this.respawn_countdown = number - 1;
1778                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1779                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1780                 }
1781         }
1782 }
1783
1784 void LeaveSpectatorMode()
1785 {SELFPARAM();
1786         if(this.caplayer)
1787                 return;
1788         if(nJoinAllowed(this, this))
1789         {
1790                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1791                 {
1792                         TRANSMUTE(Player, this);
1793
1794                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1795                                 { JoinBestTeam(this, false, true); }
1796
1797                         if(autocvar_g_campaign)
1798                                 { campaign_bots_may_start = true; }
1799
1800                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1801
1802                         PutClientInServer();
1803
1804                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1805                 }
1806                 else
1807                         stuffcmd(this, "menu_showteamselect\n");
1808         }
1809         else
1810         {
1811                 // Player may not join because g_maxplayers is set
1812                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1813         }
1814 }
1815
1816 /**
1817  * Determines whether the player is allowed to join. This depends on cvar
1818  * g_maxplayers, if it isn't used this function always return true, otherwise
1819  * it checks whether the number of currently playing players exceeds g_maxplayers.
1820  * @return int number of free slots for players, 0 if none
1821  */
1822 bool nJoinAllowed(entity this, entity ignore)
1823 {
1824         if(!ignore)
1825         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1826         // so report 0 free slots if restricted
1827         {
1828                 if(autocvar_g_forced_team_otherwise == "spectate")
1829                         return false;
1830                 if(autocvar_g_forced_team_otherwise == "spectator")
1831                         return false;
1832         }
1833
1834         if(this.team_forced < 0)
1835                 return false; // forced spectators can never join
1836
1837         // TODO simplify this
1838         int totalClients = 0;
1839         int currentlyPlaying = 0;
1840         FOREACH_CLIENT(true, LAMBDA(
1841                 if(it != ignore)
1842                         ++totalClients;
1843                 if(IS_REAL_CLIENT(it))
1844                 if(IS_PLAYER(it) || it.caplayer)
1845                         ++currentlyPlaying;
1846         ));
1847
1848         if (!autocvar_g_maxplayers)
1849                 return maxclients - totalClients;
1850
1851         if(currentlyPlaying < autocvar_g_maxplayers)
1852                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1853
1854         return false;
1855 }
1856
1857 /**
1858  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1859  * g_maxplayers_spectator_blocktime seconds
1860  */
1861 void checkSpectatorBlock()
1862 {SELFPARAM();
1863         if(IS_SPEC(this) || IS_OBSERVER(this))
1864         if(!this.caplayer)
1865         if(IS_REAL_CLIENT(this))
1866         {
1867                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1868                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1869                         dropclient(this);
1870                 }
1871         }
1872 }
1873
1874 void PrintWelcomeMessage(entity this)
1875 {
1876         if(this.motd_actived_time == 0)
1877         {
1878                 if (autocvar_g_campaign) {
1879                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1880                                 this.motd_actived_time = time;
1881                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1882                         }
1883                 } else {
1884                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1885                                 this.motd_actived_time = time;
1886                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1887                         }
1888                 }
1889         }
1890         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1891         {
1892                 if (autocvar_g_campaign) {
1893                         if (PHYS_INPUT_BUTTON_INFO(this))
1894                                 this.motd_actived_time = time;
1895                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1896                                 this.motd_actived_time = 0;
1897                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1898                         }
1899                 } else {
1900                         if (PHYS_INPUT_BUTTON_INFO(this))
1901                                 this.motd_actived_time = time;
1902                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1903                                 this.motd_actived_time = 0;
1904                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1905                         }
1906                 }
1907         }
1908         else //if(this.motd_actived_time < 0) // just connected, motd is active
1909         {
1910                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1911                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1912                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1913                 {
1914                         // instanctly hide MOTD
1915                         this.motd_actived_time = 0;
1916                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1917                 }
1918         }
1919 }
1920
1921 void ObserverThink()
1922 {SELFPARAM();
1923         if ( this.impulse )
1924         {
1925                 MinigameImpulse(this, this.impulse);
1926                 this.impulse = 0;
1927         }
1928         float prefered_movetype;
1929         if (this.flags & FL_JUMPRELEASED) {
1930                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1931                         this.flags &= ~FL_JUMPRELEASED;
1932                         this.flags |= FL_SPAWNING;
1933                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1934                         this.flags &= ~FL_JUMPRELEASED;
1935                         if(SpectateNext()) {
1936                                 TRANSMUTE(Spectator, this);
1937                         }
1938                 } else {
1939                         prefered_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
1940                         if (this.movetype != prefered_movetype)
1941                                 this.movetype = prefered_movetype;
1942                 }
1943         } else {
1944                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
1945                         this.flags |= FL_JUMPRELEASED;
1946                         if(this.flags & FL_SPAWNING)
1947                         {
1948                                 this.flags &= ~FL_SPAWNING;
1949                                 LeaveSpectatorMode();
1950                                 return;
1951                         }
1952                 }
1953         }
1954 }
1955
1956 void SpectatorThink()
1957 {SELFPARAM();
1958         if ( this.impulse )
1959         {
1960                 if(MinigameImpulse(this, this.impulse))
1961                         this.impulse = 0;
1962         }
1963         if (this.flags & FL_JUMPRELEASED) {
1964                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1965                         this.flags &= ~FL_JUMPRELEASED;
1966                         this.flags |= FL_SPAWNING;
1967                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
1968                         this.flags &= ~FL_JUMPRELEASED;
1969                         if(SpectateNext()) {
1970                                 TRANSMUTE(Spectator, this);
1971                         } else {
1972                                 TRANSMUTE(Observer, this);
1973                                 PutClientInServer();
1974                         }
1975                         this.impulse = 0;
1976                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
1977                         this.flags &= ~FL_JUMPRELEASED;
1978                         if(SpectatePrev()) {
1979                                 TRANSMUTE(Spectator, this);
1980                         } else {
1981                                 TRANSMUTE(Observer, this);
1982                                 PutClientInServer();
1983                         }
1984                         this.impulse = 0;
1985                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
1986                         this.flags &= ~FL_JUMPRELEASED;
1987                         TRANSMUTE(Observer, this);
1988                         PutClientInServer();
1989                 } else {
1990                         if(!SpectateUpdate())
1991                                 PutObserverInServer();
1992                 }
1993         } else {
1994                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
1995                         this.flags |= FL_JUMPRELEASED;
1996                         if(this.flags & FL_SPAWNING)
1997                         {
1998                                 this.flags &= ~FL_SPAWNING;
1999                                 LeaveSpectatorMode();
2000                                 return;
2001                         }
2002                 }
2003                 if(!SpectateUpdate())
2004                         PutObserverInServer();
2005         }
2006
2007         this.flags |= FL_CLIENT | FL_NOTARGET;
2008 }
2009
2010 void vehicles_enter (entity pl, entity veh);
2011 void PlayerUseKey()
2012 {SELFPARAM();
2013         if (!IS_PLAYER(this))
2014                 return;
2015
2016         if(this.vehicle)
2017         {
2018                 if(!gameover)
2019                 {
2020                         vehicles_exit(VHEF_NORMAL);
2021                         return;
2022                 }
2023         }
2024         else if(autocvar_g_vehicles_enter)
2025         {
2026                 if(!STAT(FROZEN, this))
2027                 if(!IS_DEAD(this))
2028                 if(!gameover)
2029                 {
2030                         entity head, closest_target = world;
2031                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2032
2033                         while(head) // find the closest acceptable target to enter
2034                         {
2035                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2036                                 if(!IS_DEAD(head))
2037                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2038                                 if(head.takedamage != DAMAGE_NO)
2039                                 {
2040                                         if(closest_target)
2041                                         {
2042                                                 if(vlen(this.origin - head.origin) < vlen(this.origin - closest_target.origin))
2043                                                 { closest_target = head; }
2044                                         }
2045                                         else { closest_target = head; }
2046                                 }
2047
2048                                 head = head.chain;
2049                         }
2050
2051                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2052                 }
2053         }
2054
2055         // a use key was pressed; call handlers
2056         MUTATOR_CALLHOOK(PlayerUseKey);
2057 }
2058
2059
2060 /*
2061 =============
2062 PlayerPreThink
2063
2064 Called every frame for each client before the physics are run
2065 =============
2066 */
2067 .float usekeypressed;
2068 void() nexball_setstatus;
2069 .float last_vehiclecheck;
2070 .int items_added;
2071 void PlayerPreThink ()
2072 {
2073     SELFPARAM();
2074         WarpZone_PlayerPhysics_FixVAngle(this);
2075
2076     STAT(GAMESTARTTIME, this) = game_starttime;
2077         STAT(ROUNDSTARTTIME, this) = round_starttime;
2078         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2079         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2080
2081         STAT(WEAPONSINMAP, this) = weaponsInMap;
2082
2083         if (frametime) {
2084                 // physics frames: update anticheat stuff
2085                 anticheat_prethink(this);
2086         }
2087
2088         if (blockSpectators && frametime) {
2089                 // WORKAROUND: only use dropclient in server frames (frametime set).
2090                 // Never use it in cl_movement frames (frametime zero).
2091                 checkSpectatorBlock();
2092     }
2093
2094         zoomstate_set = false;
2095
2096         // Check for nameless players
2097         if (isInvisibleString(this.netname)) {
2098                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2099                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2100         }
2101         if (this.netname != this.netname_previous) {
2102                 if (autocvar_sv_eventlog) {
2103                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2104         }
2105                 if (this.netname_previous) strunzone(this.netname_previous);
2106                 this.netname_previous = strzone(this.netname);
2107         }
2108
2109         // version nagging
2110         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2111         this.version_nagtime = 0;
2112         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2113             // git client
2114         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2115             // git server
2116             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2117         } else {
2118             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2119             if (r < 0) { // old client
2120                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2121             } else if (r > 0) { // old server
2122                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2123             }
2124         }
2125     }
2126
2127         // GOD MODE info
2128         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2129         {
2130                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2131                 this.max_armorvalue = 0;
2132         }
2133
2134         if (STAT(FROZEN, this) == 2)
2135         {
2136                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2137                 this.health = max(1, this.revive_progress * start_health);
2138                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2139
2140                 if (this.revive_progress >= 1)
2141                         Unfreeze(this);
2142         }
2143         else if (STAT(FROZEN, this) == 3)
2144         {
2145                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2146                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2147
2148                 if (this.health < 1)
2149                 {
2150                         if (this.vehicle)
2151                                 vehicles_exit(VHEF_RELEASE);
2152                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2153                 }
2154                 else if (this.revive_progress <= 0)
2155                         Unfreeze(this);
2156         }
2157
2158         MUTATOR_CALLHOOK(PlayerPreThink);
2159
2160         if(autocvar_g_vehicles_enter)
2161         if(time > this.last_vehiclecheck)
2162         if(IS_PLAYER(this))
2163         if(!gameover)
2164         if(!STAT(FROZEN, this))
2165         if(!this.vehicle)
2166         if(!IS_DEAD(this))
2167         {
2168                 entity veh;
2169                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2170                 if(vlen(veh.origin - this.origin) < autocvar_g_vehicles_enter_radius)
2171                 if(!IS_DEAD(veh))
2172                 if(veh.takedamage != DAMAGE_NO)
2173                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, this))
2174                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2175                 else if(!veh.owner)
2176                 if(!veh.team || SAME_TEAM(this, veh))
2177                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2178                 else if(autocvar_g_vehicles_steal)
2179                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2180
2181                 this.last_vehiclecheck = time + 1;
2182         }
2183
2184         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2185         {
2186                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2187                         PlayerUseKey();
2188                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2189         }
2190
2191         if (IS_REAL_CLIENT(this))
2192                 PrintWelcomeMessage(this);
2193
2194         if (IS_PLAYER(this)) {
2195                 CheckRules_Player();
2196
2197                 if (intermission_running) {
2198                         IntermissionThink();
2199                         return;
2200                 }
2201
2202                 if (timeout_status == TIMEOUT_ACTIVE) {
2203             // don't allow the player to turn around while game is paused
2204                         // FIXME turn this into CSQC stuff
2205                         this.v_angle = this.lastV_angle;
2206                         this.angles = this.lastV_angle;
2207                         this.fixangle = true;
2208                 }
2209
2210                 if (frametime) player_powerups();
2211
2212                 if (IS_DEAD(this)) {
2213                         if (this.personal && g_race_qualifying) {
2214                                 if (time > this.respawn_time) {
2215                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2216                                         respawn();
2217                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2218                                 }
2219                         } else {
2220                                 if (frametime) player_anim();
2221                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2222
2223                                 if (this.deadflag == DEAD_DYING) {
2224                                         if ((this.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max) {
2225                                                 this.deadflag = DEAD_RESPAWNING;
2226                                         } else if (!button_pressed) {
2227                                                 this.deadflag = DEAD_DEAD;
2228                     }
2229                                 } else if (this.deadflag == DEAD_DEAD) {
2230                                         if (button_pressed) {
2231                                                 this.deadflag = DEAD_RESPAWNABLE;
2232                                         } else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)) {
2233                                                 this.deadflag = DEAD_RESPAWNING;
2234                     }
2235                                 } else if (this.deadflag == DEAD_RESPAWNABLE) {
2236                                         if (!button_pressed) {
2237                                                 this.deadflag = DEAD_RESPAWNING;
2238                     }
2239                                 } else if (this.deadflag == DEAD_RESPAWNING) {
2240                                         if (time > this.respawn_time) {
2241                                                 this.respawn_time = time + 1; // only retry once a second
2242                                                 this.respawn_time_max = this.respawn_time;
2243                                                 respawn();
2244                                         }
2245                                 }
2246
2247                                 ShowRespawnCountdown();
2248
2249                                 if (this.respawn_flags & RESPAWN_SILENT)
2250                                         STAT(RESPAWN_TIME, this) = 0;
2251                                 else if ((this.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2252                                         STAT(RESPAWN_TIME, this) = this.respawn_time_max;
2253                                 else
2254                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2255                         }
2256
2257                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2258                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2259                                 STAT(RESPAWN_TIME, this) *= -1;
2260
2261                         return;
2262                 }
2263
2264                 this.prevorigin = this.origin;
2265
2266                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2267         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2268                 if (this.hook.state) {
2269                         do_crouch = false;
2270                 } else if (this.vehicle) {
2271                         do_crouch = false;
2272                 } else if (STAT(FROZEN, this)) {
2273                         do_crouch = false;
2274         } else if ((PS(this).m_weapon == WEP_SHOTGUN || PS(this).m_weapon == WEP_SHOCKWAVE) && this.(weaponentity).wframe == WFRAME_FIRE2 && time < this.(weaponentity).weapon_nextthink) {
2275                     // WEAPONTODO: predict
2276                         do_crouch = false;
2277         }
2278
2279                 if (do_crouch) {
2280                         if (!this.crouch) {
2281                                 this.crouch = true;
2282                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2283                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2284                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2285                         }
2286                 } else if (this.crouch) {
2287             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2288             if (!trace_startsolid) {
2289                 this.crouch = false;
2290                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2291                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2292             }
2293                 }
2294
2295                 FixPlayermodel(this);
2296
2297                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2298                 //if(frametime)
2299                 {
2300                         this.items &= ~this.items_added;
2301
2302                         W_WeaponFrame(this);
2303
2304                         this.items_added = 0;
2305                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2306                 this.items_added |= IT_FUEL;
2307
2308                         this.items |= this.items_added;
2309                 }
2310
2311                 player_regen();
2312
2313                 // WEAPONTODO: Add a weapon request for this
2314                 // rot vortex charge to the charge limit
2315                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2316                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2317
2318                 if (frametime) player_anim();
2319
2320                 // secret status
2321                 secrets_setstatus();
2322
2323                 // monsters status
2324                 monsters_setstatus(this);
2325
2326                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2327         }
2328         else if (gameover) {
2329                 if (intermission_running) IntermissionThink();
2330                 return;
2331         }
2332         else if (IS_OBSERVER(this)) {
2333                 ObserverThink();
2334         }
2335         else if (IS_SPEC(this)) {
2336                 SpectatorThink();
2337         }
2338
2339         // WEAPONTODO: Add weapon request for this
2340         if (!zoomstate_set) {
2341                 SetZoomState(
2342                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2343                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2344                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2345                 );
2346     }
2347
2348         int oldspectatee_status = this.spectatee_status;
2349         if (IS_SPEC(this)) {
2350                 this.spectatee_status = etof(this.enemy);
2351         } else if (IS_OBSERVER(this)) {
2352                 this.spectatee_status = etof(this);
2353         } else {
2354                 this.spectatee_status = 0;
2355     }
2356         if (this.spectatee_status != oldspectatee_status) {
2357                 ClientData_Touch(this);
2358                 if (g_race || g_cts) race_InitSpectator();
2359         }
2360
2361         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2362         {
2363                 this.teamkill_soundtime = 0;
2364
2365                 entity e = this.teamkill_soundsource;
2366                 entity oldpusher = e.pusher;
2367                 e.pusher = this;
2368                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2369                 e.pusher = oldpusher;
2370         }
2371
2372         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2373                 this.taunt_soundtime = 0;
2374                 PlayerSound(this, playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2375         }
2376
2377         target_voicescript_next(this);
2378
2379         // WEAPONTODO: Move into weaponsystem somehow
2380         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2381         if (PS(this).m_weapon == WEP_Null)
2382                 this.clip_load = this.clip_size = 0;
2383 }
2384
2385 void DrownPlayer(entity this)
2386 {
2387         if(IS_DEAD(this))
2388                 return;
2389
2390         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2391         {
2392                 if(this.air_finished < time)
2393                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
2394                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2395                 this.dmg = 2;
2396         }
2397         else if (this.air_finished < time)
2398         {       // drown!
2399                 if (this.pain_finished < time)
2400                 {
2401                         Damage (this, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2402                         this.pain_finished = time + 0.5;
2403                 }
2404         }
2405 }
2406
2407 /*
2408 =============
2409 PlayerPostThink
2410
2411 Called every frame for each client after the physics are run
2412 =============
2413 */
2414 .float idlekick_lasttimeleft;
2415 void PlayerPostThink ()
2416 {
2417     SELFPARAM();
2418         if (sv_maxidle > 0)
2419         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2420         if (IS_REAL_CLIENT(this))
2421         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2422         {
2423                 if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2424                 {
2425                         if (this.idlekick_lasttimeleft)
2426                         {
2427                                 this.idlekick_lasttimeleft = 0;
2428                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2429                         }
2430                 }
2431                 else
2432                 {
2433                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2434                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2435                                 if (!this.idlekick_lasttimeleft)
2436                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2437                         }
2438                         if (timeleft <= 0) {
2439                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2440                                 dropclient(this);
2441                                 return;
2442                         }
2443                         else if (timeleft <= 10) {
2444                                 if (timeleft != this.idlekick_lasttimeleft) {
2445                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2446                 }
2447                                 this.idlekick_lasttimeleft = timeleft;
2448                         }
2449                 }
2450         }
2451
2452         CheatFrame();
2453
2454         //CheckPlayerJump();
2455
2456         if (IS_PLAYER(this)) {
2457                 DrownPlayer(this);
2458                 CheckRules_Player();
2459                 UpdateChatBubble();
2460                 if (this.impulse) ImpulseCommands(this);
2461                 if (intermission_running) return; // intermission or finale
2462                 GetPressedKeys();
2463         }
2464
2465         if (this.waypointsprite_attachedforcarrier) {
2466             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2467                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2468     }
2469
2470         playerdemo_write();
2471
2472         CSQCMODEL_AUTOUPDATE(this);
2473 }